configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 5.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl AddressSanitizer support
 189 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 190               [enabled AddressSanitizer support for detecting a wide variety of \
 191                memory allocation and deallocation errors]), \
 192               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 193               ASAN_FLAGS="-fsanitize=address"
 194               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 195               AC_SUBST([ASAN_FLAGS])
 196               AC_SUBST([SAN_CLIPPY_FLAGS])
 197               LIBS="-ldl $LIBS"
 198               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 199                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 200               ])
 201
 202 dnl ThreadSanitizer support
 203 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 204               [enabled ThreadSanitizer support for detecting data races]), \
 205               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 206               TSAN_FLAGS="-fsanitize=thread"
 207               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 208               AC_SUBST([TSAN_FLAGS])
 209               AC_SUBST([SAN_CLIPPY_FLAGS])
 210               LIBS="-ldl $LIBS"
 211               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 212                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 213               ])
 214
 215 dnl MemorySanitizer support
 216 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 217               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 218               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 219               MSAN_FLAGS="-fsanitize=memory -fPIE -pie"
 220               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 221               AC_SUBST([MSAN_FLAGS])
 222               AC_SUBST([SAN_CLIPPY_FLAGS])
 223               LIBS="-ldl $LIBS"
 224               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 225                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 226               ])
 227
 228 dnl if the user has specified any CFLAGS, override our settings
 229 if test "x${enable_gcov}" = "xyes"; then
 230    if test "z$orig_cflags" = "z"; then
 231       AC_C_FLAG([-coverage])
 232       AC_C_FLAG([-O0])
 233    fi
 234
 235    LDFLAGS="${LDFLAGS} -lgcov"
 236 elif test "x${enable_dev_build}" = "xyes"; then
 237    AC_DEFINE(DEV_BUILD,,Build for development)
 238    if test "z$orig_cflags" = "z"; then
 239       AC_C_FLAG([-g3])
 240       AC_C_FLAG([-O0])
 241    fi
 242 else
 243    if test "z$orig_cflags" = "z"; then
 244       AC_C_FLAG([-g])
 245       AC_C_FLAG([-Os], [
 246         AC_C_FLAG([-O2])
 247       ])
 248    fi
 249 fi
 250 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 251
 252 dnl always want these CFLAGS
 253 AC_C_FLAG([-fno-omit-frame-pointer])
 254 AC_C_FLAG([-funwind-tables])
 255 AC_C_FLAG([-Wall])
 256 AC_C_FLAG([-Wextra])
 257 AC_C_FLAG([-Wmissing-prototypes])
 258 AC_C_FLAG([-Wmissing-declarations])
 259 AC_C_FLAG([-Wpointer-arith])
 260 AC_C_FLAG([-Wbad-function-cast])
 261 AC_C_FLAG([-Wwrite-strings])
 262 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 263   AC_C_FLAG([-Wcast-qual])
 264   AC_C_FLAG([-Wstrict-prototypes])
 265   AC_C_FLAG([-Wmissing-noreturn])
 266   AC_C_FLAG([-Wmissing-format-attribute])
 267   AC_C_FLAG([-Wunreachable-code])
 268   AC_C_FLAG([-Wpacked])
 269   AC_C_FLAG([-Wpadded])
 270 else
 271   AC_C_FLAG([-Wno-unused-result])
 272 fi
 273 AC_C_FLAG([-Wno-unused-parameter])
 274 AC_C_FLAG([-Wno-missing-field-initializers])
 275
 276 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 277 dnl for some reason the string consts get 'promoted' to char *,
 278 dnl triggering a const to non-const conversion warning.
 279 AC_C_FLAG([-diag-disable 3179])
 280
 281 if test x"${enable_werror}" = x"yes" ; then
 282   WERROR="-Werror"
 283 fi
 284 AC_SUBST(WERROR)
 285
 286 dnl need link on this one, not compile
 287 AC_LANG_PUSH(C)
 288 ac_ld_flag_save="$LDFLAGS"
 289 LDFLAGS="$LDFLAGS -rdynamic"
 290 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 291 AC_LINK_IFELSE(
 292         [AC_LANG_PROGRAM([[]])],
 293         [AC_MSG_RESULT([yes])],
 294         [
 295                 LDFLAGS="$ac_ld_flag_save"
 296                 AC_MSG_RESULT([no])
 297         ])
 298 AC_LANG_POP(C)
 299
 300 dnl ----------
 301 dnl Essentials
 302 dnl ----------
 303
 304 AX_PTHREAD([
 305   CC="$PTHREAD_CC"
 306   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 307   LIBS="$PTHREAD_LIBS $LIBS"
 308 ], [
 309   AC_MSG_FAILURE([This FRR version needs pthreads])
 310 ])
 311
 312 dnl --------------
 313 dnl Check programs
 314 dnl --------------
 315 AC_PROG_INSTALL
 316 AC_PROG_LN_S
 317 AC_PROG_MAKE_SET
 318 AC_CHECK_TOOL(AR, ar)
 319
 320 dnl -----------------
 321 dnl System extensions
 322 dnl -----------------
 323 AC_GNU_SOURCE
 324
 325 dnl -------
 326 dnl libtool
 327 dnl -------
 328 LT_INIT
 329
 330 dnl ----------------------
 331 dnl Packages configuration
 332 dnl ----------------------
 333 AC_ARG_WITH(pkg-extra-version,
 334         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 335         [EXTRAVERSION=$withval],)
 336 AC_ARG_WITH(pkg-git-version,
 337         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 338         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 339 AC_ARG_WITH(vtysh_pager,
 340         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 341         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 342 AC_ARG_ENABLE(vtysh,
 343   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 344 AC_ARG_ENABLE(doc,
 345   AS_HELP_STRING([--disable-doc], [do not build docs]))
 346 AC_ARG_ENABLE(zebra,
 347   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 348 AC_ARG_ENABLE(bgpd,
 349   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 350 AC_ARG_ENABLE(ripd,
 351   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 352 AC_ARG_ENABLE(ripngd,
 353   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 354 AC_ARG_ENABLE(ospfd,
 355   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 356 AC_ARG_ENABLE(ospf6d,
 357   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 358 AC_ARG_ENABLE(ldpd,
 359   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 360 AC_ARG_ENABLE(nhrpd,
 361   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 362 AC_ARG_ENABLE(eigrpd,
 363   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 364 AC_ARG_ENABLE(babeld,
 365   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 366 AC_ARG_ENABLE(watchfrr,
 367   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 368 AC_ARG_ENABLE(isisd,
 369   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 370 AC_ARG_ENABLE(pimd,
 371   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 372 AC_ARG_ENABLE(pbrd,
 373   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 374 AC_ARG_ENABLE(sharpd,
 375   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 376 AC_ARG_ENABLE(staticd,
 377   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 378 AC_ARG_ENABLE(bgp-announce,
 379   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 380 AC_ARG_ENABLE(bgp-vnc,
 381   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 382 AC_ARG_WITH(rfp-path,
 383   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 384 AC_ARG_ENABLE(snmp,
 385   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 386 AC_ARG_ENABLE(zeromq,
 387   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 388 AC_ARG_WITH(libpam,
 389   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 390 AC_ARG_ENABLE(ospfapi,
 391   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 392 AC_ARG_ENABLE(ospfclient,
 393   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 394                           (this is the default if --disable-ospfapi is set)]))
 395 AC_ARG_ENABLE(multipath,
 396   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 397 AC_ARG_ENABLE(user,
 398   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 399 AC_ARG_ENABLE(group,
 400   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 401 AC_ARG_ENABLE(vty_group,
 402   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 403 AC_ARG_ENABLE(configfile_mask,
 404   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 405 AC_ARG_ENABLE(logfile_mask,
 406   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 407 AC_ARG_ENABLE(shell_access,
 408   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 409 AC_ARG_ENABLE(realms,
 410   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 411 AC_ARG_ENABLE(rtadv,
 412   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 413 AC_ARG_ENABLE(irdp,
 414   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 415 AC_ARG_ENABLE(capabilities,
 416   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 417 AC_ARG_ENABLE(rusage,
 418   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 419 AC_ARG_ENABLE(gcc_ultra_verbose,
 420   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 421 AC_ARG_ENABLE(backtrace,
 422   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 423 AC_ARG_ENABLE(time-check,
 424   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 425 AC_ARG_ENABLE(pcreposix,
 426   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 427 AC_ARG_ENABLE(fpm,
 428   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 429 AC_ARG_ENABLE(systemd,
 430   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 431 AC_ARG_ENABLE(werror,
 432   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 433 AC_ARG_ENABLE(cumulus,
 434   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 435 AC_ARG_ENABLE(datacenter,
 436   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 437 AC_ARG_ENABLE(fuzzing,
 438   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 439 AC_ARG_ENABLE(netlink_fuzzing,
 440   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 441 AC_ARG_ENABLE(rr-semantics,
 442   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 443 AC_ARG_ENABLE([protobuf],
 444   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 445 AC_ARG_ENABLE([oldvpn_commands],
 446   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 447 AC_ARG_ENABLE(rpki,
 448   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 449 AC_ARG_ENABLE([clippy-only],
 450   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 451 AC_ARG_ENABLE([numeric_version],
 452   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 453 AC_ARG_ENABLE([gcov],
 454   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 455 AC_ARG_ENABLE(bfdd,
 456   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 457
 458 AS_IF([test "${enable_clippy_only}" != "yes"], [
 459 AC_CHECK_HEADERS(json-c/json.h)
 460 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 461 if test $ac_cv_lib_json_c_json_object_get = no; then
 462   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 463   if test $ac_cv_lib_json_json_object_get = no; then
 464       AC_MSG_ERROR([lib json is needed to compile])
 465   fi
 466 fi
 467 ])
 468
 469 AC_ARG_ENABLE([dev_build],
 470     AS_HELP_STRING([--enable-dev-build], [build for development]))
 471
 472 if test x"${enable_time_check}" != x"no" ; then
 473   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 474     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 475   else
 476     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 477   fi
 478 fi
 479
 480 case "${enable_systemd}" in
 481   "no") ;;
 482   "yes")
 483   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 484   if test $ac_cv_lib_systemd_sd_notify = no; then
 485     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 486   else
 487     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 488   fi
 489   ;;
 490   "*") ;;
 491 esac
 492
 493 if test "${enable_rr_semantics}" != "no" ; then
 494   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 495 fi
 496
 497 if test "${enable_datacenter}" = "yes" ; then
 498   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 499   DFLT_NAME="datacenter"
 500 else
 501   DFLT_NAME="traditional"
 502 fi
 503
 504 if test "${enable_fuzzing}" = "yes" ; then
 505   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 506 fi
 507
 508 if test "${enable_netlink_fuzzing}" = "yes" ; then
 509   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 510 fi
 511
 512 if test "${enable_cumulus}" = "yes" ; then
 513   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 514 fi
 515
 516 AC_SUBST(DFLT_NAME)
 517 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 518
 519 if test "${enable_shell_access}" = "yes"; then
 520    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 521 fi
 522
 523 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 524
 525 #
 526 # Python for clippy
 527 #
 528 AS_IF([test "$host" = "$build"], [
 529   PYTHONCONFIG=""
 530
 531   # ordering:
 532   # 1.  try python3, but respect the user's preference on which minor ver
 533   # 2.  try python, which might be py3 or py2 again on the user's preference
 534   # 3.  try python2 (can really only be 2.7 but eh)
 535   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 536   #
 537   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 538   # (AX_PYTHON does not do what we need)
 539
 540   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 541   if test -n "$PYTHONCONFIG"; then
 542     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 543     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 544
 545     AC_MSG_CHECKING([whether we found a working Python version])
 546     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 547 #include <Python.h>
 548 #if PY_VERSION_HEX < 0x02070000
 549 #error python too old
 550 #endif
 551 int main(void);
 552 ],
 553 [
 554 {
 555   Py_Initialize();
 556   return 0;
 557 }
 558 ])], [
 559       PYTHONCONFIG=""
 560       unset PYTHON_LIBS
 561       unset PYTHON_CFLAGS
 562     ])
 563   fi
 564
 565   if test -z "$PYTHONCONFIG"; then
 566     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 567       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 568         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 569           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 570             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 571               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 572               ])])])])])
 573
 574
 575     AC_MSG_CHECKING([whether we found a working Python version])
 576     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 577 #include <Python.h>
 578 #if PY_VERSION_HEX < 0x02070000
 579 #error python too old
 580 #endif
 581 int main(void);
 582 ],
 583 [
 584 {
 585   Py_Initialize();
 586   return 0;
 587 }
 588 ])], [
 589       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 590     ])
 591   fi
 592 ])
 593 AC_SUBST(PYTHON_CFLAGS)
 594 AC_SUBST(PYTHON_LIBS)
 595
 596 #
 597 # Logic for protobuf support.
 598 #
 599 if test "$enable_protobuf" = "yes"; then
 600    have_protobuf=yes
 601
 602    # Check for protoc-c
 603    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 604    if test "x$PROTOC_C" = "x/bin/false"; then
 605       have_protobuf=no
 606    else
 607       found_protobuf_c=no
 608       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 609                      [found_protobuf_c=yes],
 610                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 611
 612       if test "x$found_protobuf_c" = "xyes"; then
 613          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 614          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 615       else
 616         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 617                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 618       fi
 619    fi
 620 fi
 621
 622 #
 623 # Logic for old vpn commans support.
 624 #
 625 if test "$enable_oldvpn_commands" = "yes"; then
 626    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 627 fi
 628
 629 # Fail if the user explicity enabled protobuf support and we couldn't
 630 # find the compiler or libraries.
 631 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 632    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 633 fi
 634
 635 if test "x$have_protobuf" = "xyes"; then
 636    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 637 fi
 638
 639 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 640
 641 #
 642 # End of logic for protobuf support.
 643 #
 644
 645 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 646 if test "${enable_rtadv}" != "no"; then
 647   AC_MSG_RESULT(yes)
 648   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 649 else
 650   AC_MSG_RESULT(no)
 651 fi
 652
 653 if test x"${enable_user}" = x"no"; then
 654   enable_user=""
 655 else
 656   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 657     enable_user="frr"
 658   fi
 659   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 660 fi
 661
 662 if test x"${enable_group}" = x"no"; then
 663   enable_group=""
 664 else
 665   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 666     enable_group="frr"
 667   fi
 668   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 669 fi
 670
 671 if test x"${enable_vty_group}" = x"yes" ; then
 672   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 673 elif test x"${enable_vty_group}" != x""; then
 674   if test x"${enable_vty_group}" != x"no"; then
 675     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 676   fi
 677 fi
 678 AC_SUBST([enable_user])
 679 AC_SUBST([enable_group])
 680 AC_SUBST([enable_vty_group])
 681
 682 enable_configfile_mask=${enable_configfile_mask:-0600}
 683 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 684
 685 enable_logfile_mask=${enable_logfile_mask:-0600}
 686 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 687
 688 MPATH_NUM=1
 689
 690 case "${enable_multipath}" in
 691   0)
 692     MPATH_NUM=64
 693     ;;
 694   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 695     MPATH_NUM="${enable_multipath}"
 696     ;;
 697   "")
 698     ;;
 699   *)
 700     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 701     ;;
 702 esac
 703
 704 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 705
 706 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 707
 708 dnl --------------------
 709 dnl Enable code coverage
 710 dnl --------------------
 711 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 712
 713 dnl ------------------------------------
 714 dnl Alpine only accepts numeric versions
 715 dnl ------------------------------------
 716 if test "x${enable_numeric_version}" != "x" ; then
 717   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 718   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 719 fi
 720
 721 dnl -----------------------------------
 722 dnl Add extra version string to package
 723 dnl name, string and version fields.
 724 dnl -----------------------------------
 725 if test "x${EXTRAVERSION}" != "x" ; then
 726   VERSION="${VERSION}${EXTRAVERSION}"
 727   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 728   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 729   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 730 fi
 731
 732 if test "x$with_pkg_git_version" = "xyes"; then
 733         if test -d "${srcdir}/.git"; then
 734                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 735         else    with_pkg_git_version="no"
 736                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 737         fi
 738 fi
 739 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 740
 741 dnl ------------------------------------
 742 dnl Check C keywords and standard  types
 743 dnl ------------------------------------
 744 AC_C_CONST
 745 AC_C_INLINE
 746 AC_C_VOLATILE
 747 AC_HEADER_STDC
 748 dnl AC_TYPE_PID_T
 749 AC_TYPE_UID_T
 750 AC_TYPE_MODE_T
 751 AC_TYPE_SIZE_T
 752 AC_STRUCT_TM
 753
 754 dnl -------------------------
 755 dnl Check other header files.
 756 dnl -------------------------
 757 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 758         linux/version.h asm/types.h \
 759         sys/cdefs.h])
 760
 761 ac_stdatomic_ok=false
 762 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 763 AC_CHECK_HEADER([stdatomic.h],[
 764
 765   AC_MSG_CHECKING([whether _Atomic qualifier works])
 766   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 767 #include <stdatomic.h>
 768 int main(int argc, char **argv) {
 769   _Atomic int i = 0;
 770   return i;
 771 }
 772 ]])], [
 773     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 774     AC_MSG_RESULT([yes])
 775     ac_stdatomic_ok=true
 776   ], [
 777     AC_MSG_RESULT([no])
 778   ])
 779 ])
 780
 781 AS_IF([$ac_stdatomic_ok], [true], [
 782   AC_MSG_CHECKING([for __atomic_* builtins])
 783   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 784 int main(int argc, char **argv) {
 785   volatile int i = 1;
 786   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 787   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 788 }
 789 ]])], [
 790     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 791     AC_MSG_RESULT([yes])
 792   ], [
 793     AC_MSG_RESULT([no])
 794
 795     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 796     AC_MSG_CHECKING([for __sync_* builtins])
 797     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 798 int main(int argc, char **argv) {
 799   volatile int i = 1;
 800   __sync_fetch_and_sub (&i, 1);
 801   return __sync_val_compare_and_swap (&i, 0, 1);
 802 }
 803 ]])], [
 804       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 805       AC_MSG_RESULT([yes])
 806
 807       AC_MSG_CHECKING([for __sync_swap builtin])
 808       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 809 int main(int argc, char **argv) {
 810   volatile int i = 1;
 811   return __sync_swap (&i, 2);
 812 }
 813 ]])], [
 814         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 815         AC_MSG_RESULT([yes])
 816       ], [
 817         AC_MSG_RESULT([no])
 818       ])
 819
 820     ], [
 821       AC_MSG_RESULT([no])
 822       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 823     ])
 824   ])
 825 ])
 826
 827 dnl Utility macro to avoid retyping includes all the time
 828 m4_define([FRR_INCLUDES],
 829 [#ifdef SUNOS_5
 830 #define _XPG4_2
 831 #define __EXTENSIONS__
 832 #endif
 833 #include <stdio.h>
 834 #include <stdlib.h>
 835 #include <stddef.h>
 836 #include <sys/types.h>
 837 /* sys/conf.h depends on param.h on FBSD at least */
 838 #include <sys/param.h>
 839 /* Required for MAXSIG */
 840 #include <signal.h>
 841 #include <sys/socket.h>
 842 #ifdef __APPLE__
 843 # define __APPLE_USE_RFC_3542
 844 #endif
 845 #include <netinet/in.h>
 846 #include <sys/time.h>
 847 #include <time.h>
 848 #include <net/if.h>
 849 ])dnl
 850
 851 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 852 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 853 dnl an additional round for it.
 854
 855 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 856
 857 m4_define([FRR_INCLUDES],
 858 FRR_INCLUDES
 859 [#if HAVE_NET_IF_VAR_H
 860 # include <net/if_var.h>
 861 #endif
 862 ])dnl
 863
 864 AC_CHECK_HEADERS([netinet/in_var.h \
 865         net/if_dl.h net/netopt.h \
 866         inet/nd.h netinet/ip_icmp.h \
 867         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 868         [], [], FRR_INCLUDES)
 869
 870 AC_CHECK_HEADERS([ucontext.h], [], [],
 871 [#ifndef __USE_GNU
 872 #define __USE_GNU
 873 #endif /* __USE_GNU */
 874 FRR_INCLUDES
 875 ])
 876
 877 m4_define([UCONTEXT_INCLUDES],
 878 [#include <ucontext.h>])dnl
 879
 880 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 881   [], [], [UCONTEXT_INCLUDES])
 882 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 883   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 884    [], [], [UCONTEXT_INCLUDES])],
 885   [], [UCONTEXT_INCLUDES])
 886 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 887   [], [], [UCONTEXT_INCLUDES])
 888
 889 m4_define([FRR_INCLUDES],
 890 FRR_INCLUDES
 891 [
 892 #include <sys/un.h>
 893 #include <netinet/in_systm.h>
 894 #if HAVE_NETINET_IN_VAR_H
 895 # include <netinet/in_var.h>
 896 #endif
 897 #if HAVE_NET_IF_DL_H
 898 # include <net/if_dl.h>
 899 #endif
 900 #if HAVE_NET_NETOPT_H
 901 # include <net/netopt.h>
 902 #endif
 903 #include <net/route.h>
 904 #if HAVE_INET_ND_H
 905 # include <inet/nd.h>
 906 #endif
 907 #include <arpa/inet.h>
 908 /* Required for IDRP */
 909 #if HAVE_NETINET_IP_ICMP_H
 910 # include <netinet/ip_icmp.h>
 911 #endif
 912 ])dnl
 913
 914 dnl V6 headers are checked below, after we check for v6
 915
 916 AC_MSG_CHECKING([which operating system interface to use])
 917 case "$host_os" in
 918   sunos* | solaris2*)
 919     AC_MSG_RESULT([Solaris])
 920
 921     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 922     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 923
 924     AC_CHECK_LIB(socket, main)
 925     AC_CHECK_LIB(nsl, main)
 926     AC_CHECK_LIB(umem, main)
 927     AC_CHECK_FUNCS([printstack], [
 928       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 929       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 930     ])
 931     CURSES=-lcurses
 932     SOLARIS="solaris"
 933     ;;
 934   linux*)
 935     AC_MSG_RESULT([Linux])
 936
 937     AC_DEFINE(GNU_LINUX,,GNU Linux)
 938     AC_DEFINE(HAVE_NETLINK,,netlink)
 939     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 940
 941     dnl Linux has a compilation problem with mixing
 942     dnl netinet/in.h and linux/in6.h they are not
 943     dnl compatible.  There has been discussion on
 944     dnl how to fix it but no real progress on implementation
 945     dnl when they fix it, remove this
 946     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 947     ;;
 948   openbsd*)
 949     AC_MSG_RESULT([OpenBSD])
 950
 951     AC_DEFINE(OPEN_BSD,,OpenBSD)
 952     AC_DEFINE(KAME,1,KAME IPv6)
 953     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 954
 955     if test "x${enable_pimd}" != "xno"; then
 956       case "$host_os" in
 957       openbsd6.0)
 958         ;;
 959       openbsd[6-9]*)
 960         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 961         ;;
 962       esac
 963     fi
 964     ;;
 965   *)
 966     AC_MSG_RESULT([BSD])
 967
 968     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 969     AC_DEFINE(KAME,1,KAME IPv6)
 970     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 971     ;;
 972 esac
 973 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 974
 975 AC_SYS_LARGEFILE
 976
 977 dnl ------------------------
 978 dnl Integrated REALMS option
 979 dnl ------------------------
 980 if test "${enable_realms}" = "yes"; then
 981     case "$host_os" in
 982       linux*)
 983        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 984        ;;
 985       *)
 986        echo "Sorry, only Linux has REALMS support"
 987        exit 1
 988        ;;
 989     esac
 990 fi
 991 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 992
 993 dnl ---------------------
 994 dnl Integrated VTY option
 995 dnl ---------------------
 996 case "${enable_vtysh}" in
 997   "no") VTYSH="";;
 998   *)    VTYSH="vtysh";
 999          AC_DEFINE(VTYSH,,VTY shell)
1000 dnl      Vtysh uses libreadline, which looks for termcap functions at
1001 dnl      configure time.  We follow readlines search order.
1002 dnl      The required procedures are in libtermcap on NetBSD, in
1003 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1004          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1005            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1006              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1007                [AC_CHECK_LIB(ncurses, tputs,
1008                              LIBREADLINE="$LIBREADLINE -lncurses")]
1009               )]
1010             )]
1011           )
1012          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1013                       "$LIBREADLINE")
1014          if test $ac_cv_lib_readline_main = no; then
1015            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1016          fi
1017          AC_CHECK_HEADER(readline/history.h)
1018          if test $ac_cv_header_readline_history_h = no;then
1019            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1020          fi
1021          AC_CHECK_LIB(readline, rl_completion_matches,
1022                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1023          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1024            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1025          fi
1026          ;;
1027 esac
1028 AC_SUBST(LIBREADLINE)
1029 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1030
1031 dnl ----------
1032 dnl PAM module
1033 dnl
1034 dnl FRR detects the PAM library it is built against by checking for a
1035 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1036 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1037 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1038 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1039 dnl of OpenPAM.
1040 dnl ----------
1041 if test "$with_libpam" = "yes"; then
1042   AC_CHECK_HEADER([security/pam_misc.h],
1043     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1044      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1045      pam_conv_func="misc_conv"
1046     ],
1047     [], FRR_INCLUDES)
1048   AC_CHECK_HEADER([security/openpam.h],
1049     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1050      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1051      pam_conv_func="openpam_ttyconv"
1052     ],
1053     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1054   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1055     AC_MSG_WARN([*** pam support will not be built ***])
1056     with_libpam="no"
1057   fi
1058 fi
1059
1060 if test "$with_libpam" = "yes"; then
1061 dnl took this test from proftpds configure.in and suited to our needs
1062 dnl -------------------------------------------------------------------------
1063 dnl
1064 dnl This next check looks funky due to a linker problem with some versions
1065 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1066 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1067 dnl with RedHat 6.2 and Debian 2.2 or better.
1068 AC_CHECK_LIB(pam, pam_start,
1069   [AC_CHECK_LIB(pam, $pam_conv_func,
1070     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1071      LIBPAM="-lpam"],
1072     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1073      LIBPAM="-lpam -lpam_misc"]
1074     )
1075   ],
1076
1077   [AC_CHECK_LIB(pam, pam_end,
1078     [AC_CHECK_LIB(pam, $pam_conv_func,
1079       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1080        LIBPAM="-lpam -ldl"],
1081       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1082        LIBPAM="-lpam -ldl -lpam_misc"]
1083      )
1084   ],AC_MSG_WARN([*** pam support will not be built ***]),
1085   [-ldl])
1086   ]
1087 )
1088 fi
1089 AC_SUBST(LIBPAM)
1090
1091 dnl -------------------------------
1092 dnl Endian-ness check
1093 dnl -------------------------------
1094 AC_WORDS_BIGENDIAN
1095
1096 dnl -------------------------------
1097 dnl check the size in byte of the C
1098 dnl -------------------------------
1099 dnl AC_CHECK_SIZEOF(char)
1100 dnl AC_CHECK_SIZEOF(int)
1101 dnl AC_CHECK_SIZEOF(short)
1102 dnl AC_CHECK_SIZEOF(long)
1103
1104 dnl ----------------------------
1105 dnl check existance of functions
1106 dnl ----------------------------
1107 AC_FUNC_FNMATCH
1108 AC_FUNC_FORK
1109 AC_FUNC_MKTIME
1110 AC_FUNC_STAT
1111
1112 dnl -------------------------------
1113 dnl bgpd needs pow() and hence libm
1114 dnl -------------------------------
1115 TMPLIBS="$LIBS"
1116 AC_CHECK_HEADER([math.h],
1117   [AC_CHECK_LIB([m], [pow],
1118     [LIBM="-lm"
1119      LIBS="$LIBS $LIBM"
1120      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1121     ])
1122 ])
1123 if test x"$LIBM" = x ; then
1124   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1125 fi
1126 LIBS="$TMPLIBS"
1127 AC_SUBST(LIBM)
1128
1129 AC_CHECK_FUNCS([ppoll], [
1130   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1131 ])
1132 AC_CHECK_FUNCS([pollts], [
1133   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1134 ])
1135
1136 dnl ---------------
1137 dnl other functions
1138 dnl ---------------
1139 AC_CHECK_FUNCS([ \
1140         strlcat strlcpy \
1141         getgrouplist])
1142
1143 AC_CHECK_HEADER([asm-generic/unistd.h],
1144                 [AC_CHECK_DECL(__NR_setns,
1145                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1146                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1147                                ])
1148                  AC_CHECK_FUNCS(setns)]
1149                )
1150
1151 dnl --------------------------
1152 dnl Determine IS-IS I/O method
1153 dnl --------------------------
1154 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1155 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1156 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1157 AC_CHECK_HEADER(net/bpf.h)
1158 AC_CHECK_HEADER(sys/dlpi.h)
1159 AC_MSG_CHECKING(zebra IS-IS I/O method)
1160
1161 case "$host_os" in
1162   linux*)
1163     AC_MSG_RESULT(pfpacket)
1164     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1165     ;;
1166   solaris* | sunos*)
1167     AC_MSG_RESULT(DLPI)
1168     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1169     ;;
1170   *)
1171     if test $ac_cv_header_net_bpf_h = no; then
1172       if test $ac_cv_header_sys_dlpi_h = no; then
1173         AC_MSG_RESULT(none)
1174         if test "${enable_isisd}" = yes; then
1175           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1176         fi
1177         AC_MSG_WARN([*** IS-IS support will not be built ***])
1178         enable_isisd="no"
1179       else
1180         AC_MSG_RESULT(DLPI)
1181       fi
1182       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1183     else
1184       AC_MSG_RESULT(BPF)
1185       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1186     fi
1187     ;;
1188 esac
1189 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1190
1191 dnl ---------------------------------------------------------------
1192 dnl figure out how to specify an interface in multicast sockets API
1193 dnl ---------------------------------------------------------------
1194 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1195
1196 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1197         #include <sys/socket.h>
1198         #include <netinet/in.h>
1199         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1200         #include <linux/types.h>
1201 ])
1202
1203 m4_define([FRR_INCLUDES],
1204 FRR_INCLUDES
1205 [#if HAVE_LINUX_MROUTE_H
1206 # include <linux/mroute.h>
1207 #endif
1208 ])dnl
1209
1210 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1211         #include <sys/socket.h>
1212         #include <sys/types.h>
1213         #include <netinet/in.h>
1214         #include <net/route.h>
1215 ])
1216
1217 m4_define([FRR_INCLUDES],
1218 FRR_INCLUDES
1219 [#if HAVE_NETINET_IP_MROUTE_H
1220 # include <netinet/ip_mroute.h>
1221 #endif
1222 ])dnl
1223
1224 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1225 AC_TRY_COMPILE([#include <sys/param.h>],
1226 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1227   return (0);
1228 #else
1229   #error No support for BSD struct ip_mreq hack detected
1230 #endif],[AC_MSG_RESULT(yes)
1231 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1232 AC_MSG_RESULT(no))
1233
1234 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1235 AC_TRY_COMPILE([
1236 #include <sys/types.h>
1237 #include <netinet/in.h>
1238 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1239 ], [AC_MSG_RESULT(yes)
1240 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1241 AC_MSG_RESULT(no))
1242
1243 dnl ---------------------------------------------------------------
1244 dnl figure out how to check link-state
1245 dnl ---------------------------------------------------------------
1246 AC_CHECK_HEADER( [net/if_media.h],
1247   [m4_define([LINK_DETECT_INCLUDES],
1248     FRR_INCLUDES
1249     [#include <net/if_media.h>
1250   ])
1251   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1252     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1253     [], LINK_DETECT_INCLUDES)],
1254   [],
1255   FRR_INCLUDES)
1256
1257 dnl ---------------------------------------------------------------
1258 dnl Additional, newer way to check link-state using ifi_link_state.
1259 dnl Not available in all BSD's when ifmediareq available
1260 dnl ---------------------------------------------------------------
1261 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1262   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1263   [], FRR_INCLUDES)
1264
1265 dnl ------------------------
1266 dnl TCP_MD5SIG socket option
1267 dnl ------------------------
1268
1269 AC_CHECK_HEADER([netinet/tcp.h],
1270    [m4_define([MD5_INCLUDES],
1271       FRR_INCLUDES
1272       [#include <netinet/tcp.h>
1273     ])
1274     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1275    [],
1276    FRR_INCLUDES)
1277 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1278   AC_CHECK_HEADER([linux/tcp.h],
1279        [m4_define([MD5_INCLUDES],
1280           FRR_INCLUDES
1281           [#include <linux/tcp.h>
1282         ])
1283        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1284 fi
1285
1286 dnl ----------------------------------------------------------------------------
1287 dnl figure out if domainname is available in the utsname struct (GNU extension).
1288 dnl ----------------------------------------------------------------------------
1289 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1290
1291 dnl ------------------
1292 dnl IPv6 header checks
1293 dnl ------------------
1294 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1295         netinet6/in6_var.h netinet6/nd6.h], [], [],
1296         FRR_INCLUDES)
1297
1298 m4_define([FRR_INCLUDES],dnl
1299 FRR_INCLUDES
1300 [#if HAVE_NETINET6_IN6_H
1301 #include <netinet6/in6.h>
1302 #endif
1303 #if HAVE_NETINET_IN6_VAR_H
1304 #include <netinet/in6_var.h>
1305 #endif
1306 #include <netinet/icmp6.h>
1307 #if HAVE_NETINET6_IN6_VAR_H
1308 # include <netinet6/in6_var.h>
1309 #endif
1310 #if HAVE_NETINET6_ND6_H
1311 # include <netinet6/nd6.h>
1312 #endif
1313 ])dnl
1314
1315 dnl disable doc check
1316 if test "${enable_doc}" = "no";then
1317   DOC=""
1318 else
1319   AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [no])
1320   DOC="doc"
1321 fi
1322
1323 dnl --------------------
1324 dnl Daemon disable check
1325 dnl --------------------
1326 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1327
1328 if test "${enable_bgpd}" = "no";then
1329   BGPD=""
1330 else
1331   BGPD="bgpd"
1332 fi
1333 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1334
1335 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1336 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1337 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1338
1339 AS_IF([test "${enable_ldpd}" != "no"], [
1340   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1341 ])
1342
1343 if test "$enable_bfdd" = "no"; then
1344   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1345   BFDD=""
1346 else
1347   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1348   BFDD="bfdd"
1349
1350   case $host_os in
1351     linux*)
1352       AC_DEFINE(BFD_LINUX, 1, bfdd)
1353       ;;
1354
1355     *)
1356       AC_DEFINE(BFD_BSD, 1, bfdd)
1357       ;;
1358   esac
1359 fi
1360
1361 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1362
1363 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1364   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1365 fi
1366
1367 NHRPD=""
1368 case "$host_os" in
1369   linux*)
1370     if test "${enable_nhrpd}" != "no"; then
1371       NHRPD="nhrpd"
1372     fi
1373     ;;
1374   *)
1375     if test "${enable_nhrpd}" = "yes"; then
1376       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1377     fi
1378     ;;
1379 esac
1380 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1381
1382 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1383
1384 if test "${enable_watchfrr}" = "no";then
1385   WATCHFRR=""
1386 else
1387   WATCHFRR="watchfrr"
1388 fi
1389 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1390
1391 OSPFCLIENT=""
1392 if test "${enable_ospfapi}" != "no";then
1393     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1394
1395   if test "${enable_ospfclient}" != "no";then
1396       OSPFCLIENT="ospfclient"
1397   fi
1398 fi
1399
1400 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1401 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1402 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1403 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1404 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1405 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1406 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1407 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1408 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1409
1410 if test "${enable_bgp_announce}" = "no";then
1411   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1412 else
1413   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1414 fi
1415
1416 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1417   with_rfp_path="bgpd/rfp-example"
1418 fi
1419 if test "${with_rfp_path}" != "no"; then
1420   VNC_RFP_PATH="${with_rfp_path}"
1421   AC_SUBST(VNC_RFP_PATH)
1422 fi
1423
1424 if test "${enable_bgp_vnc}" != "no";then
1425   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1426   RFPTEST="${with_rfp_path}/rfptest"
1427   LIBRFP="${with_rfp_path}/librfp"
1428   RFPINC="${with_rfp_path}/librfp"
1429 else
1430   RFPTEST=
1431   LIBRFP=
1432   RFPINC="bgpd/rfp-example/librfp"
1433 fi
1434 # set
1435 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1436
1437 AC_SUBST(DOC)
1438 AC_SUBST(RFPTEST)
1439 AC_SUBST(LIBRFP)
1440 AC_SUBST(RFPINC)
1441 AC_SUBST(BGPD)
1442 AC_SUBST(SOLARIS)
1443 AC_SUBST(VTYSH)
1444 AC_SUBST(CURSES)
1445 AC_CHECK_LIB(crypt, crypt, [],
1446                     [AC_CHECK_LIB(crypto, DES_crypt)])
1447 AC_CHECK_LIB(resolv, res_init)
1448
1449 dnl ---------------------------
1450 dnl check system has PCRE regexp
1451 dnl ---------------------------
1452 if test "x$enable_pcreposix" = "xyes"; then
1453   AC_CHECK_LIB(pcreposix, regexec, [], [
1454     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1455   ])
1456 fi
1457 AC_SUBST(HAVE_LIBPCREPOSIX)
1458
1459 dnl ------------------
1460 dnl check C-Ares library
1461 dnl ------------------
1462 if test "${NHRPD}" != ""; then
1463   PKG_CHECK_MODULES([CARES], [libcares], , [
1464     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1465   ])
1466 fi
1467
1468
1469 dnl ------------------
1470 dnl check Net-SNMP library
1471 dnl ------------------
1472 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1473    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1474    if test x"$NETSNMP_CONFIG" = x"no"; then
1475       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1476    fi
1477    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1478    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1479    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1480    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1481 int main(void);
1482 ],
1483 [
1484 {
1485   return 0;
1486 }
1487 ])], [
1488      AC_MSG_ERROR([--enable-snmp given but not usable])])
1489    case "${enable_snmp}" in
1490      yes)
1491       SNMP_METHOD=agentx
1492       ;;
1493      agentx)
1494       SNMP_METHOD="${enable_snmp}"
1495       ;;
1496      *)
1497       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1498       ;;
1499    esac
1500    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1501    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1502 fi
1503 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1504 AC_SUBST(SNMP_LIBS)
1505 AC_SUBST(SNMP_CFLAGS)
1506
1507 dnl ---------------
1508 dnl math
1509 dnl ---------------
1510 AC_SEARCH_LIBS([sqrt], [m])
1511
1512 dnl ---------------
1513 dnl dlopen & dlinfo
1514 dnl ---------------
1515 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1516   AC_MSG_ERROR([unable to find the dlopen()])
1517 ])
1518
1519 AC_CHECK_HEADERS([link.h])
1520
1521 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1522 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1523 #include <stdlib.h>
1524 #ifdef HAVE_LINK_H
1525 #include <link.h>
1526 #endif
1527 #include <dlfcn.h>
1528 ]], [[
1529   char origin[1];
1530   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1531 ]])], [
1532   AC_MSG_RESULT(yes)
1533   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1534 ], [
1535   AC_MSG_RESULT(no)
1536 ])
1537
1538 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1539 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1540 #include <stdlib.h>
1541 #ifdef HAVE_LINK_H
1542 #include <link.h>
1543 #endif
1544 #include <dlfcn.h>
1545 ]], [[
1546   struct link_map *lm = NULL;
1547   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1548 ]])], [
1549   AC_MSG_RESULT(yes)
1550   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1551 ], [
1552   AC_MSG_RESULT(no)
1553 ])
1554
1555
1556 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1557
1558 dnl ---------------------------
1559 dnl sockaddr and netinet checks
1560 dnl ---------------------------
1561 AC_CHECK_TYPES([
1562         struct sockaddr_dl,
1563         struct vifctl, struct mfcctl, struct sioc_sg_req,
1564         vifi_t, struct sioc_vif_req, struct igmpmsg,
1565         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1566         struct nd_opt_adv_interval, struct rt_addrinfo,
1567         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1568         [], [], FRR_INCLUDES)
1569
1570 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1571         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1572         struct sockaddr_dl.sdl_len,
1573         struct if6_aliasreq.ifra_lifetime,
1574         struct nd_opt_adv_interval.nd_opt_ai_type],
1575         [], [], FRR_INCLUDES)
1576
1577 dnl ---------------------------
1578 dnl IRDP/pktinfo/icmphdr checks
1579 dnl ---------------------------
1580
1581 AC_CHECK_TYPES([struct in_pktinfo], [
1582   AC_CHECK_TYPES([struct icmphdr], [
1583     IRDP=true
1584   ], [
1585     IRDP=false
1586   ], [FRR_INCLUDES])
1587 ], [
1588   IRDP=false
1589 ], [FRR_INCLUDES])
1590
1591 case "${enable_irdp}" in
1592 yes)
1593   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1594   ;;
1595 no)
1596   IRDP=false
1597   ;;
1598 esac
1599
1600 AM_CONDITIONAL(IRDP, $IRDP)
1601
1602 dnl -----------------------
1603 dnl checking for IP_PKTINFO
1604 dnl -----------------------
1605 AC_MSG_CHECKING(for IP_PKTINFO)
1606 AC_TRY_COMPILE([#include <netdb.h>], [
1607   int opt = IP_PKTINFO;
1608 ], [
1609   AC_MSG_RESULT(yes)
1610   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1611 ], [
1612   AC_MSG_RESULT(no)
1613 ])
1614
1615 dnl ---------------------------
1616 dnl checking for IP_RECVDSTADDR
1617 dnl ---------------------------
1618 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1619 AC_TRY_COMPILE([#include <netinet/in.h>], [
1620   int opt = IP_RECVDSTADDR;
1621 ], [
1622   AC_MSG_RESULT(yes)
1623   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1624 ], [
1625   AC_MSG_RESULT(no)
1626 ])
1627
1628 dnl ----------------------
1629 dnl checking for IP_RECVIF
1630 dnl ----------------------
1631 AC_MSG_CHECKING(for IP_RECVIF)
1632 AC_TRY_COMPILE([#include <netinet/in.h>], [
1633   int opt = IP_RECVIF;
1634 ], [
1635   AC_MSG_RESULT(yes)
1636   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1637 ], [
1638   AC_MSG_RESULT(no)
1639 ])
1640
1641 dnl ----------------------
1642 dnl checking for SO_BINDANY
1643 dnl ----------------------
1644 AC_MSG_CHECKING(for SO_BINDANY)
1645 AC_TRY_COMPILE([#include <sys/socket.h>], [
1646   int opt = SO_BINDANY;
1647 ], [
1648   AC_MSG_RESULT(yes)
1649   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1650 ], [
1651   AC_MSG_RESULT(no)
1652 ])
1653
1654 dnl ----------------------
1655 dnl checking for IP_FREEBIND
1656 dnl ----------------------
1657 AC_MSG_CHECKING(for IP_FREEBIND)
1658 AC_TRY_COMPILE([#include <netinet/in.h>], [
1659   int opt = IP_FREEBIND;
1660 ], [
1661   AC_MSG_RESULT(yes)
1662   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1663 ], [
1664   AC_MSG_RESULT(no)
1665 ])
1666
1667 dnl --------------------------------------
1668 dnl checking for be32dec existence or not
1669 dnl --------------------------------------
1670 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1671                [#include <sys/endian.h>])
1672
1673 dnl --------------------------------------
1674 dnl checking for clock_time monotonic struct and call
1675 dnl --------------------------------------
1676 AC_CHECK_DECL(CLOCK_MONOTONIC,
1677         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1678          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1679 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1680
1681 dnl --------------------------------------
1682 dnl checking for flex and bison
1683 dnl --------------------------------------
1684
1685 AM_PROG_LEX
1686 AC_MSG_CHECKING(version of flex)
1687 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1688 frr_ac_flex_version="${frr_ac_flex_version##* }"
1689 AC_MSG_RESULT([$frr_ac_flex_version])
1690 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1691   LEX="$SHELL $missing_dir/missing flex"
1692   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1693     AC_MSG_WARN([using pregenerated flex output files])
1694   else
1695     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1696   fi
1697   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1698   AC_SUBST([LEXLIB], [''])
1699 ])
1700
1701 AC_PROG_YACC
1702 dnl thanks GNU bison for this b*llshit...
1703 AC_MSG_CHECKING(version of bison)
1704 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1705 frr_ac_bison_version="${frr_ac_bison_version##* }"
1706 frr_ac_bison_missing="false"
1707 case "x${frr_ac_bison_version}" in
1708   x2.7*)
1709     BISON_OPENBRACE='"'
1710     BISON_CLOSEBRACE='"'
1711     BISON_VERBOSE=''
1712     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1713     ;;
1714   x2.*|x1.*)
1715     AC_MSG_RESULT([$frr_ac_bison_version])
1716     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1717     frr_ac_bison_missing="true"
1718     ;;
1719   x)
1720     AC_MSG_RESULT([none])
1721     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1722     frr_ac_bison_missing="true"
1723     ;;
1724   *)
1725     BISON_OPENBRACE='{'
1726     BISON_CLOSEBRACE='}'
1727     BISON_VERBOSE='-Dparse.error=verbose'
1728     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1729     ;;
1730 esac
1731 AC_SUBST(BISON_OPENBRACE)
1732 AC_SUBST(BISON_CLOSEBRACE)
1733 AC_SUBST(BISON_VERBOSE)
1734
1735 if $frr_ac_bison_missing; then
1736   YACC="$SHELL $missing_dir/missing bison -y"
1737   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1738     AC_MSG_WARN([using pregenerated bison output files])
1739   else
1740     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1741   fi
1742 fi
1743
1744 dnl -------------------
1745 dnl capabilities checks
1746 dnl -------------------
1747 if test "${enable_capabilities}" != "no"; then
1748   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1749   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1750     [AC_MSG_RESULT(yes)
1751      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1752      frr_ac_keepcaps="yes"],
1753      AC_MSG_RESULT(no)
1754   )
1755   if test x"${frr_ac_keepcaps}" = x"yes"; then
1756     AC_CHECK_HEADERS(sys/capability.h)
1757   fi
1758   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1759     AC_CHECK_LIB(cap, cap_init,
1760       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1761        LIBCAP="-lcap"
1762        frr_ac_lcaps="yes"]
1763     )
1764   else
1765     AC_CHECK_HEADERS(priv.h,
1766      [AC_MSG_CHECKING(Solaris style privileges are available)
1767       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1768           [AC_MSG_RESULT(yes)
1769            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1770            frr_ac_scaps="yes"],
1771            AC_MSG_RESULT(no)
1772       )
1773      ]
1774    )
1775   fi
1776   if test x"${frr_ac_scaps}" = x"yes" \
1777        -o x"${frr_ac_lcaps}" = x"yes"; then
1778     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1779   fi
1780 fi
1781 AC_SUBST(LIBCAP)
1782
1783 dnl ---------------------------
1784 dnl check for glibc 'backtrace'
1785 dnl ---------------------------
1786 if test x"${enable_backtrace}" != x"no" ; then
1787   backtrace_ok=no
1788   AC_CHECK_HEADER([execinfo.h], [
1789     AC_SEARCH_LIBS([backtrace], [execinfo], [
1790       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1791       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1792       backtrace_ok=yes
1793     ],, [-lm])
1794   ])
1795
1796   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1797     dnl user explicitly requested backtrace but we failed to find support
1798     AC_MSG_FAILURE([failed to find backtrace support])
1799   fi
1800 fi
1801
1802 dnl -----------------------------------------
1803 dnl check for malloc mallinfo struct and call
1804 dnl this must try and link using LIBS, in
1805 dnl order to check no alternative allocator
1806 dnl has been specified, which might not provide
1807 dnl mallinfo, e.g. such as Umem on Solaris.
1808 dnl -----------------------------------------
1809 AC_CHECK_HEADERS([malloc.h malloc/malloc.h],,, [FRR_INCLUDES])
1810
1811 AC_MSG_CHECKING(whether mallinfo is available)
1812 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1813 #ifdef HAVE_MALLOC_H
1814 #include <malloc.h>
1815 #endif
1816 #ifdef HAVE_MALLOC_MALLOC_H
1817 #include <malloc/malloc.h>
1818 #endif
1819 ]], [[
1820 struct mallinfo ac_x; ac_x = mallinfo ();
1821 ]])], [
1822   AC_MSG_RESULT(yes)
1823   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1824 ], [
1825   AC_MSG_RESULT(no)
1826 ])
1827
1828 AC_MSG_CHECKING(whether malloc_usable_size is available)
1829 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1830 #ifdef HAVE_MALLOC_H
1831 #include <malloc.h>
1832 #endif
1833 #ifdef HAVE_MALLOC_MALLOC_H
1834 #include <malloc/malloc.h>
1835 #endif
1836 ]], [[
1837 size_t ac_x; ac_x = malloc_usable_size(NULL);
1838 ]])], [
1839   AC_MSG_RESULT(yes)
1840   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1841 ], [
1842   AC_MSG_RESULT(no)
1843
1844   AC_MSG_CHECKING(whether malloc_size is available)
1845   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1846 #ifdef HAVE_MALLOC_H
1847 #include <malloc.h>
1848 #endif
1849 #ifdef HAVE_MALLOC_MALLOC_H
1850 #include <malloc/malloc.h>
1851 #endif
1852 ]], [[
1853 size_t ac_x; ac_x = malloc_size(NULL);
1854 ]])], [
1855     AC_MSG_RESULT(yes)
1856     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1857   ], [
1858     AC_MSG_RESULT(no)
1859   ])
1860 ])
1861
1862 dnl ------
1863 dnl ZeroMQ
1864 dnl ------
1865 if test "x$enable_zeromq" != "xno"; then
1866   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1867     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1868     ZEROMQ=true
1869   ], [
1870     if test "x$enable_zeromq" = "xyes"; then
1871       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1872     fi
1873   ])
1874 fi
1875 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1876
1877 dnl ----------
1878 dnl configure date
1879 dnl ----------
1880 dev_version=`echo $VERSION | grep dev`
1881 #don't expire deprecated code in non 'dev' branch
1882 if test "${dev_version}" = ""; then
1883    CONFDATE=0
1884 else
1885    CONFDATE=`date '+%Y%m%d'`
1886 fi
1887 AC_SUBST(CONFDATE)
1888
1889 dnl ------------------------------
1890 dnl set paths for state directory
1891 dnl ------------------------------
1892 AC_MSG_CHECKING(directory to use for state file)
1893 if test "${prefix}" = "NONE"; then
1894   frr_statedir_prefix="";
1895 else
1896   frr_statedir_prefix=${prefix}
1897 fi
1898 if test "${localstatedir}" = '${prefix}/var'; then
1899   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1900                         ${frr_statedir_prefix}/var/adm dnl
1901                         ${frr_statedir_prefix}/etc dnl
1902                         /var/run        dnl
1903                         /var/adm        dnl
1904                         /etc            dnl
1905                         /dev/null;
1906   do
1907     test -d $FRR_STATE_DIR && break
1908   done
1909   frr_statedir=$FRR_STATE_DIR
1910 else
1911   frr_statedir=${localstatedir}
1912 fi
1913 if test $frr_statedir = "/dev/null"; then
1914     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1915 fi
1916 AC_MSG_RESULT(${frr_statedir})
1917 AC_SUBST(frr_statedir)
1918
1919 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1920 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1921 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1922 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1923
1924 dnl autoconf does this, but it does it too late...
1925 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1926 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1927
1928 dnl get the full path, recursing through variables...
1929 vtysh_bin="$bindir/vtysh"
1930 for I in 1 2 3 4 5 6 7 8 9 10; do
1931         eval vtysh_bin="\"$vtysh_bin\""
1932 done
1933 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1934
1935 CFG_SYSCONF="$sysconfdir"
1936 CFG_SBIN="$sbindir"
1937 CFG_STATE="$frr_statedir"
1938 CFG_MODULE="$moduledir"
1939 for I in 1 2 3 4 5 6 7 8 9 10; do
1940         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1941         eval CFG_SBIN="\"$CFG_SBIN\""
1942         eval CFG_STATE="\"$CFG_STATE\""
1943         eval CFG_MODULE="\"$CFG_MODULE\""
1944 done
1945 AC_SUBST(CFG_SYSCONF)
1946 AC_SUBST(CFG_SBIN)
1947 AC_SUBST(CFG_STATE)
1948 AC_SUBST(CFG_MODULE)
1949 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1950
1951 dnl ------------------------------------
1952 dnl Enable RPKI and add librtr to libs
1953 dnl ------------------------------------
1954 if test "${enable_rpki}" = "yes"; then
1955   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1956       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1957       RPKI=true],
1958       [RPKI=false
1959       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1960   )
1961 fi
1962 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1963
1964 dnl ------------------------------------------
1965 dnl Check whether rtrlib was build with ssh support
1966 dnl ------------------------------------------
1967 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1968 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1969                         [[struct tr_ssh_config config;]])],
1970         [AC_MSG_RESULT(yes)
1971         AC_DEFINE(FOUND_SSH,,found_ssh)],
1972         AC_MSG_RESULT(no)
1973 )
1974
1975 dnl ---------------------------
1976 dnl Check htonl works correctly
1977 dnl ---------------------------
1978 AC_MSG_CHECKING(for working htonl)
1979 AC_CACHE_VAL(ac_cv_htonl_works,
1980  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1981                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1982  ]
1983 )
1984 AC_MSG_RESULT($ac_cv_htonl_works)
1985
1986 AC_CONFIG_FILES([Makefile
1987           bgpd/Makefile
1988           vtysh/Makefile
1989           doc/Makefile
1990           doc/user/Makefile
1991           doc/manpages/Makefile
1992           doc/developer/Makefile
1993           tests/Makefile
1994           bgpd/rfp-example/rfptest/Makefile
1995           bgpd/rfp-example/librfp/Makefile
1996           redhat/frr.spec
1997           debianpkg/Makefile
1998           debianpkg/changelog
1999           alpine/APKBUILD
2000           snapcraft/snapcraft.yaml
2001           lib/version.h
2002           tests/lib/cli/test_cli.refout
2003           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2004           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2005           pkgsrc/eigrpd.sh])
2006
2007 if test "${enable_bgp_vnc}" != "no"; then
2008    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
2009       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
2010    fi
2011 fi
2012
2013 AC_CONFIG_FILES([solaris/Makefile])
2014
2015 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2016
2017 AC_CONFIG_COMMANDS([lib/route_types.h], [
2018         dst="${ac_abs_top_builddir}/lib/route_types.h"
2019         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2020                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2021                 > "${dst}.tmp"
2022         test -f "${dst}" \
2023                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2024                 && rm "${dst}.tmp" \
2025                 || mv "${dst}.tmp" "${dst}"
2026 ], [
2027         PERL="$PERL"
2028 ])
2029
2030 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2031     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2032         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2033         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2034                 "${ac_abs_top_srcdir}" \
2035                 > "${dst}.tmp"
2036         test -f "${dst}" \
2037                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2038                 && rm "${dst}.tmp" \
2039                 || mv "${dst}.tmp" "${dst}"
2040     ], [
2041         PERL="$PERL"
2042     ])
2043 ])
2044
2045 ## Hack, but working solution to avoid rebuilding of frr.info.
2046 ## It's already in CVS until texinfo 4.7 is more common.
2047 AC_OUTPUT
2048
2049 echo "
2050 FRRouting configuration
2051 ------------------------------
2052 FRR version             : ${PACKAGE_VERSION}
2053 host operating system   : ${host_os}
2054 source code location    : ${srcdir}
2055 compiler                : ${CC}
2056 compiler flags          : ${CFLAGS}
2057 make                    : ${MAKE-make}
2058 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2059 state file directory    : ${frr_statedir}
2060 config file directory   : `eval echo \`echo ${sysconfdir}\``
2061 example directory       : `eval echo \`echo ${exampledir}\``
2062 module directory        : ${CFG_MODULE}
2063 user to run as          : ${enable_user}
2064 group to run as         : ${enable_group}
2065 group for vty sockets   : ${enable_vty_group}
2066 config file mask        : ${enable_configfile_mask}
2067 log file mask           : ${enable_logfile_mask}
2068 zebra protobuf enabled  : ${have_protobuf:-no}
2069
2070 The above user and group must have read/write access to the state file
2071 directory and to the config files in the config file directory."
2072
2073 if test "${enable_doc}" != "no";then
2074   AS_IF([test "x$SPHINXBUILD" = xno],
2075      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2076 fi