configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.3-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" == "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_ENABLE(tcmalloc,
 143         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 144 [case "${enableval}" in
 145   yes) tcmalloc_enabled=true
 146 LIBS="$LIBS -ltcmalloc_minimal"
 147  ;;
 148   no)  tcmalloc_enabled=false ;;
 149   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 150 esac],[tcmalloc_enabled=false])
 151
 152
 153 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 154 dnl flag determination logic.
 155 CFLAGS="${CFLAGS:-}"
 156
 157 dnl --------------------
 158 dnl Check CC and friends
 159 dnl --------------------
 160 dnl note orig_cflags is also used further down
 161 orig_cflags="$CFLAGS"
 162 orig_cxxflags="$CXXFLAGS"
 163 AC_LANG([C])
 164 AC_PROG_CC
 165 AC_PROG_CPP
 166 AC_PROG_CXX
 167 AM_PROG_CC_C_O
 168 dnl remove autoconf default "-g -O2"
 169 CFLAGS="$orig_cflags"
 170 CXXFLAGS="$orig_cxxflags"
 171 AC_PROG_CC_C99
 172 dnl NB: see C11 below
 173
 174 PKG_PROG_PKG_CONFIG
 175
 176 dnl it's 2019, sed is sed.
 177 SED=sed
 178 AC_SUBST([SED])
 179
 180 dnl try and enable CFLAGS that are useful for FRR
 181 dnl - specifically, options to control warnings
 182
 183 AC_USE_SYSTEM_EXTENSIONS
 184 AC_DEFUN([AC_C_FLAG], [{
 185     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 186     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 187         AC_LANG_PUSH([C])
 188         ac_c_flag_save="$CFLAGS"
 189         CFLAGS="$CFLAGS $1"
 190         AC_COMPILE_IFELSE(
 191                 [AC_LANG_PROGRAM([[]])],
 192                 [
 193                         cachename=yes
 194                 ], [
 195                         cachename=no
 196                 ])
 197         CFLAGS="$ac_c_flag_save"
 198         AC_LANG_POP([C])
 199     ])
 200     if test "${cachename}" = yes; then
 201         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 202     else
 203         :
 204         $2
 205     fi
 206     m4_popdef([cachename])
 207 }])
 208
 209 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 210         AC_LANG_PUSH([C])
 211         ac_cflags_save="$CFLAGS"
 212         ac_libs_save="$LIBS"
 213         CFLAGS="$CFLAGS $1"
 214         LIBS="$LIBS $2"
 215         AC_LINK_IFELSE(
 216                 [$3],
 217                 [
 218                         CFLAGS="$ac_cflags_save"
 219                         LIBS="$ac_libs_save"
 220                         m4_default([$5], [
 221                                 AC_MSG_RESULT([yes])
 222                         ])
 223                 ], [
 224                         CFLAGS="$ac_cflags_save"
 225                         LIBS="$ac_libs_save"
 226                         m4_default([$4], [
 227                                 AC_MSG_RESULT([no])
 228                         ])
 229                 ])
 230         AC_LANG_POP([C])
 231         }])
 232
 233 dnl ICC won't bail on unknown options without -diag-error 10006
 234 dnl need to do this first so we get useful results for the other options
 235 AC_C_FLAG([-diag-error 10006])
 236
 237 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 238 ac_cc="$CC"
 239 CC="${CC% -std=gnu99}"
 240 CC="${CC% -std=c99}"
 241
 242 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 243
 244 dnl if the user has specified any CFLAGS, override our settings
 245 if test "x${enable_gcov}" = "xyes"; then
 246    if test "z$orig_cflags" = "z"; then
 247       AC_C_FLAG([-coverage])
 248       AC_C_FLAG([-O0])
 249    fi
 250
 251    LDFLAGS="${LDFLAGS} -lgcov"
 252 elif test "x${enable_dev_build}" = "xyes"; then
 253    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 254    if test "z$orig_cflags" = "z"; then
 255       AC_C_FLAG([-g3])
 256       AC_C_FLAG([-O0])
 257    fi
 258    if test "x${enable_lua}" = "xyes"; then
 259       AX_PROG_LUA([5.3])
 260       AX_LUA_HEADERS
 261       AX_LUA_LIBS([
 262          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 263          LIBS="$LIBS $LUA_LIB"
 264       ])
 265    fi
 266 else
 267    if test "x${enable_lua}" = "xyes"; then
 268       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 269    fi
 270    if test "z$orig_cflags" = "z"; then
 271       AC_C_FLAG([-g])
 272       AC_C_FLAG([-O2])
 273    fi
 274 fi
 275 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 276
 277 dnl always want these CFLAGS
 278 AC_C_FLAG([-fno-omit-frame-pointer])
 279 AC_C_FLAG([-funwind-tables])
 280 AC_C_FLAG([-Wall])
 281 AC_C_FLAG([-Wextra])
 282 AC_C_FLAG([-Wmissing-prototypes])
 283 AC_C_FLAG([-Wmissing-declarations])
 284 AC_C_FLAG([-Wpointer-arith])
 285 AC_C_FLAG([-Wbad-function-cast])
 286 AC_C_FLAG([-Wwrite-strings])
 287 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 288   AC_C_FLAG([-Wcast-qual])
 289   AC_C_FLAG([-Wstrict-prototypes])
 290   AC_C_FLAG([-Wmissing-noreturn])
 291   AC_C_FLAG([-Wmissing-format-attribute])
 292   AC_C_FLAG([-Wunreachable-code])
 293   AC_C_FLAG([-Wpacked])
 294   AC_C_FLAG([-Wpadded])
 295   AC_C_FLAG([-Wshadow])
 296 else
 297   AC_C_FLAG([-Wno-unused-result])
 298 fi
 299 AC_C_FLAG([-Wno-unused-parameter])
 300 AC_C_FLAG([-Wno-missing-field-initializers])
 301
 302 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 303 AC_SUBST([CXX_COMPAT_CFLAGS])
 304
 305 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 306 dnl for some reason the string consts get 'promoted' to char *,
 307 dnl triggering a const to non-const conversion warning.
 308 AC_C_FLAG([-diag-disable 3179])
 309
 310 if test x"${enable_werror}" = x"yes" ; then
 311   WERROR="-Werror"
 312 fi
 313 AC_SUBST([WERROR])
 314
 315 SAN_FLAGS=""
 316 if test "$enable_address_sanitizer" = "yes"; then
 317   AC_C_FLAG([-fsanitize=address], [
 318     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 319   ], [
 320     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 321   ])
 322 fi
 323 if test "$enable_thread_sanitizer" = "yes"; then
 324   AC_C_FLAG([-fsanitize=thread], [
 325     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 326   ], [
 327     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 328   ])
 329 fi
 330 if test "$enable_memory_sanitizer" = "yes"; then
 331   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 332     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 333   ], [
 334     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 335   ])
 336 fi
 337 AC_SUBST([SAN_FLAGS])
 338
 339 dnl ----------
 340 dnl Essentials
 341 dnl ----------
 342
 343 AX_PTHREAD([
 344   CC="$PTHREAD_CC"
 345   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 346   LIBS="$PTHREAD_LIBS $LIBS"
 347 ], [
 348   AC_MSG_FAILURE([This FRR version needs pthreads])
 349 ])
 350
 351 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 352                 [frr_cv_pthread_condattr_setclock=yes],
 353                 [frr_cv_pthread_condattr_setclock=no])
 354 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 355   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 356 fi
 357
 358 dnl --------------
 359 dnl Check programs
 360 dnl --------------
 361 AC_PROG_INSTALL
 362 AC_PROG_LN_S
 363 AC_CHECK_TOOL([AR], [ar])
 364
 365 dnl -------
 366 dnl libtool
 367 dnl -------
 368 AC_ARG_ENABLE([static-bin],
 369   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 370 LT_INIT
 371 _LT_CONFIG_LIBTOOL([
 372   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 373     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 374 ])
 375 if test "$enable_static_bin" = "yes"; then
 376   AC_LDFLAGS="-static"
 377   if test "$enable_static" != "yes"; then
 378     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 379   fi
 380 fi
 381 if test "$enable_shared" != "yes"; then
 382   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 383 fi
 384 AC_SUBST([AC_LDFLAGS])
 385 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 386
 387 dnl $AR and $RANLIB are set by LT_INIT above
 388 AC_MSG_CHECKING([whether $AR supports D option])
 389 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 390   AC_MSG_RESULT([yes])
 391   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 392   ARFLAGS="crD"
 393   AR_FLAGS="crD"
 394 else
 395   AC_MSG_RESULT([no])
 396   ARFLAGS="cru"
 397   AR_FLAGS="cru"
 398 fi
 399 AC_SUBST([ARFLAGS])
 400 AC_SUBST([AR_FLAGS])
 401
 402 AC_MSG_CHECKING([whether $RANLIB supports D option])
 403 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 404   if grep -q -- '-D' conftest.err; then
 405     AC_MSG_RESULT([no])
 406   else
 407     AC_MSG_RESULT([yes])
 408     RANLIB="$RANLIB -D"
 409   fi
 410 else
 411   AC_MSG_RESULT([no])
 412 fi
 413 AC_SUBST([RANLIB])
 414
 415 test -f conftest.err && rm conftest.err
 416 test -f conftest.a && rm conftest.a
 417
 418 dnl ----------------------
 419 dnl Packages configuration
 420 dnl ----------------------
 421 if test -f config.version; then
 422   . ./config.version
 423 elif test -f "${srcdir}/config.version"; then
 424   . "${srcdir}/config.version"
 425 fi
 426 AC_ARG_WITH([pkg-extra-version],
 427   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 428   if test "$withval" = "no"; then
 429     EXTRAVERSION=
 430   else
 431     EXTRAVERSION=$withval
 432   fi
 433 ], [])
 434 AC_ARG_WITH([pkg-git-version],
 435         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 436         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 437 AC_ARG_WITH([clippy],
 438   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 439 AC_ARG_WITH([vtysh_pager],
 440         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 441         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 442 AC_ARG_ENABLE([vtysh],
 443   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 444 AC_ARG_ENABLE([doc],
 445   AS_HELP_STRING([--disable-doc], [do not build docs]))
 446 AC_ARG_ENABLE([doc-html],
 447   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 448 AC_ARG_ENABLE([zebra],
 449   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 450 AC_ARG_ENABLE([bgpd],
 451   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 452 AC_ARG_ENABLE([ripd],
 453   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 454 AC_ARG_ENABLE([ripngd],
 455   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 456 AC_ARG_ENABLE([ospfd],
 457   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 458 AC_ARG_ENABLE([ospf6d],
 459   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 460 AC_ARG_ENABLE([ldpd],
 461   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 462 AC_ARG_ENABLE([nhrpd],
 463   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 464 AC_ARG_ENABLE([eigrpd],
 465   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 466 AC_ARG_ENABLE([babeld],
 467   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 468 AC_ARG_ENABLE([watchfrr],
 469   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 470 AC_ARG_ENABLE([isisd],
 471   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 472 AC_ARG_ENABLE([pimd],
 473   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 474 AC_ARG_ENABLE([pbrd],
 475   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 476 AC_ARG_ENABLE([sharpd],
 477   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 478 AC_ARG_ENABLE([staticd],
 479   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 480 AC_ARG_ENABLE([fabricd],
 481   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 482 AC_ARG_ENABLE([vrrpd],
 483   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 484 AC_ARG_ENABLE([bgp-announce],
 485   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 486 AC_ARG_ENABLE([bgp-vnc],
 487   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 488 AC_ARG_ENABLE([bgp-bmp],
 489   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 490 AC_ARG_ENABLE([snmp],
 491   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 492 AC_ARG_ENABLE([config_rollbacks],
 493   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 494 AC_ARG_ENABLE([confd],
 495   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 496 AC_ARG_ENABLE([sysrepo],
 497   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 498 AC_ARG_ENABLE([grpc],
 499   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 500 AC_ARG_ENABLE([zeromq],
 501   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 502 AC_ARG_WITH([libpam],
 503   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 504 AC_ARG_ENABLE([ospfapi],
 505   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 506 AC_ARG_ENABLE([ospfclient],
 507   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 508                           (this is the default if --disable-ospfapi is set)]))
 509 AC_ARG_ENABLE([multipath],
 510   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 511 AC_ARG_ENABLE([user],
 512   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 513 AC_ARG_ENABLE([group],
 514   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 515 AC_ARG_ENABLE([vty_group],
 516   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 517 AC_ARG_ENABLE([configfile_mask],
 518   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 519 AC_ARG_ENABLE([logfile_mask],
 520   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 521 AC_ARG_ENABLE([shell_access],
 522   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 523 AC_ARG_ENABLE([realms],
 524   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 525 AC_ARG_ENABLE([rtadv],
 526   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 527 AC_ARG_ENABLE([irdp],
 528   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 529 AC_ARG_ENABLE([capabilities],
 530   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 531 AC_ARG_ENABLE([rusage],
 532   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 533 AC_ARG_ENABLE([gcc_ultra_verbose],
 534   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 535 AC_ARG_ENABLE([backtrace],
 536   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 537 AC_ARG_ENABLE([time-check],
 538   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 539 AC_ARG_ENABLE([cpu-time],
 540   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 541 AC_ARG_ENABLE([pcreposix],
 542   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 543 AC_ARG_ENABLE([fpm],
 544   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 545 AC_ARG_ENABLE([systemd],
 546   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 547 AC_ARG_ENABLE([werror],
 548   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 549 AC_ARG_ENABLE([cumulus],
 550   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 551 AC_ARG_ENABLE([datacenter],
 552   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 553 AC_ARG_ENABLE([fuzzing],
 554   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 555 AC_ARG_ENABLE([netlink_fuzzing],
 556   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 557 AC_ARG_ENABLE([rr-semantics],
 558   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 559 AC_ARG_ENABLE([protobuf],
 560   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 561 AC_ARG_ENABLE([oldvpn_commands],
 562   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 563 AC_ARG_ENABLE([rpki],
 564   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 565 AC_ARG_ENABLE([clippy-only],
 566   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 567 AC_ARG_ENABLE([numeric_version],
 568   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 569 AC_ARG_ENABLE([gcov],
 570   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 571 AC_ARG_ENABLE([bfdd],
 572   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 573 AC_ARG_ENABLE([address-sanitizer],
 574   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 575 AC_ARG_ENABLE([thread-sanitizer],
 576   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 577 AC_ARG_ENABLE([memory-sanitizer],
 578   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 579 AC_ARG_WITH([crypto],
 580   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 581
 582 #if openssl, else use the internal
 583 AS_IF([test x"${with_crypto}" = x"openssl"], [
 584 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 585 if test $ac_cv_lib_crypto_EVP_DigestInit = no; then
 586   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 587 else
 588   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 589 fi
 590 ], [test x"${with_crypto}" = x"internal" || test x"${with_crypto}" = x"" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 591 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 592 )
 593
 594 AS_IF([test "${enable_clippy_only}" != "yes"], [
 595 AC_CHECK_HEADERS([json-c/json.h])
 596 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 597 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 598   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 599   if test "$ac_cv_lib_json_json_object_get" = no; then
 600       AC_MSG_ERROR([libjson is needed to compile])
 601   fi
 602 fi
 603 ])
 604
 605 AC_ARG_ENABLE([dev_build],
 606     AS_HELP_STRING([--enable-dev-build], [build for development]))
 607
 608 AC_ARG_ENABLE([lua],
 609     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 610
 611 if test x"${enable_time_check}" != x"no" ; then
 612   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 613     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 614   else
 615     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 616   fi
 617 fi
 618
 619 case "${enable_cpu_time}" in
 620   "no")
 621   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 622   ;;
 623   "*")
 624   ;;
 625 esac
 626
 627 case "${enable_systemd}" in
 628   "no") ;;
 629   "yes")
 630   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 631   if test $ac_cv_lib_systemd_sd_notify = no; then
 632     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 633   else
 634     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 635   fi
 636   ;;
 637   "*") ;;
 638 esac
 639
 640 if test "${enable_rr_semantics}" != "no" ; then
 641   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 642 fi
 643
 644 if test "${enable_datacenter}" = "yes" ; then
 645   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 646   DFLT_NAME="datacenter"
 647 else
 648   DFLT_NAME="traditional"
 649 fi
 650
 651 if test "${enable_fuzzing}" = "yes" ; then
 652   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 653 fi
 654
 655 if test "${enable_netlink_fuzzing}" = "yes" ; then
 656   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 657 fi
 658
 659 if test "${enable_cumulus}" = "yes" ; then
 660   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 661 fi
 662
 663 AC_SUBST([DFLT_NAME])
 664 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 665
 666 if test "${enable_shell_access}" = "yes"; then
 667    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 668 fi
 669
 670 #
 671 # Python for clippy
 672 #
 673
 674 AS_IF([test "$host" = "$build"], [
 675   FRR_PYTHON_DEV
 676 ], [
 677   FRR_PYTHON
 678 ])
 679
 680 FRR_PYTHON_MODULES([pytest])
 681
 682 if test "${enable_doc}" != "no"; then
 683   FRR_PYTHON_MODULES([sphinx], , [
 684     if test "${enable_doc}" = "yes"; then
 685       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 686     fi
 687   ])
 688 fi
 689 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" != "false"])
 690 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
 691
 692 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 693   PYSPHINX="-m sphinx"
 694 ], [
 695   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 696 ])
 697 AC_SUBST([PYSPHINX])
 698
 699 #
 700 # Logic for old vpn commands support.
 701 #
 702 if test "$enable_oldvpn_commands" = "yes"; then
 703    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 704 fi
 705
 706 #
 707 # End of logic for protobuf support.
 708 #
 709
 710 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 711 if test "${enable_rtadv}" != "no"; then
 712   AC_MSG_RESULT([yes])
 713   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 714 else
 715   AC_MSG_RESULT([no])
 716 fi
 717
 718 if test x"${enable_user}" = x"no"; then
 719   enable_user=""
 720 else
 721   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 722     enable_user="frr"
 723   fi
 724   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 725 fi
 726
 727 if test x"${enable_group}" = x"no"; then
 728   enable_group=""
 729 else
 730   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 731     enable_group="frr"
 732   fi
 733   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 734 fi
 735
 736 if test x"${enable_vty_group}" = x"yes" ; then
 737   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 738 elif test x"${enable_vty_group}" != x""; then
 739   if test x"${enable_vty_group}" != x"no"; then
 740     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 741   fi
 742 fi
 743 AC_SUBST([enable_user])
 744 AC_SUBST([enable_group])
 745 AC_SUBST([enable_vty_group])
 746
 747 enable_configfile_mask=${enable_configfile_mask:-0600}
 748 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 749
 750 enable_logfile_mask=${enable_logfile_mask:-0600}
 751 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 752
 753 MPATH_NUM=16
 754
 755 case "${enable_multipath}" in
 756   0)
 757     MPATH_NUM=64
 758     ;;
 759   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 760     MPATH_NUM="${enable_multipath}"
 761     ;;
 762   "")
 763     ;;
 764   *)
 765     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 766     ;;
 767 esac
 768
 769 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 770
 771 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 772
 773 dnl --------------------
 774 dnl Enable code coverage
 775 dnl --------------------
 776 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 777
 778 dnl ------------------------------------
 779 dnl Alpine only accepts numeric versions
 780 dnl ------------------------------------
 781 if test "x${enable_numeric_version}" != "x" ; then
 782   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 783   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 784 fi
 785
 786 dnl -----------------------------------
 787 dnl Add extra version string to package
 788 dnl name, string and version fields.
 789 dnl -----------------------------------
 790 if test "x${EXTRAVERSION}" != "x" ; then
 791   VERSION="${VERSION}${EXTRAVERSION}"
 792   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 793   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 794   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 795 fi
 796 AC_SUBST([EXTRAVERSION])
 797
 798 if test "x$with_pkg_git_version" = "xyes"; then
 799         if test -d "${srcdir}/.git"; then
 800                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 801         else    with_pkg_git_version="no"
 802                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 803         fi
 804 fi
 805 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 806
 807 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 808 if test "x${OBJCOPY}" != "x:"; then
 809   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 810     frr_cv_interp=""
 811     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 812       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 813         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 814       fi
 815       test -f conftest.interp && rm conftest.interp
 816     ])
 817   ])
 818 fi
 819 if test -n "$frr_cv_interp"; then
 820   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 821 fi
 822
 823 dnl -------------------------
 824 dnl Check other header files.
 825 dnl -------------------------
 826 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 827         linux/version.h asm/types.h])
 828
 829 ac_stdatomic_ok=false
 830 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 831 AC_CHECK_HEADER([stdatomic.h],[
 832
 833   AC_MSG_CHECKING([whether _Atomic qualifier works])
 834   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 835 #include <stdatomic.h>
 836 int main(int argc, char **argv) {
 837   _Atomic int i = 0;
 838   return i;
 839 }
 840 ]])], [
 841     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 842     AC_MSG_RESULT([yes])
 843     ac_stdatomic_ok=true
 844   ], [
 845     AC_MSG_RESULT([no])
 846   ])
 847 ])
 848
 849 AS_IF([$ac_stdatomic_ok], [true], [
 850   AC_MSG_CHECKING([for __atomic_* builtins])
 851   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 852 int main(int argc, char **argv) {
 853   volatile int i = 1;
 854   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 855   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 856 }
 857 ]])], [
 858     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 859     AC_MSG_RESULT([yes])
 860   ], [
 861     AC_MSG_RESULT([no])
 862
 863     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 864     AC_MSG_CHECKING([for __sync_* builtins])
 865     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 866 int main(int argc, char **argv) {
 867   volatile int i = 1;
 868   __sync_fetch_and_sub (&i, 1);
 869   return __sync_val_compare_and_swap (&i, 0, 1);
 870 }
 871 ]])], [
 872       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 873       AC_MSG_RESULT([yes])
 874
 875       AC_MSG_CHECKING([for __sync_swap builtin])
 876       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 877 int main(int argc, char **argv) {
 878   volatile int i = 1;
 879   return __sync_swap (&i, 2);
 880 }
 881 ]])], [
 882         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 883         AC_MSG_RESULT([yes])
 884       ], [
 885         AC_MSG_RESULT([no])
 886       ])
 887
 888     ], [
 889       AC_MSG_RESULT([no])
 890       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 891     ])
 892   ])
 893 ])
 894
 895 AC_CHECK_HEADERS([pthread_np.h],,, [
 896 #include <pthread.h>
 897 ])
 898 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 899
 900 needsync=true
 901
 902 AS_IF([$needsync], [
 903   dnl Linux
 904   AC_MSG_CHECKING([for Linux futex() support])
 905   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 906 #ifndef _GNU_SOURCE
 907 #define _GNU_SOURCE
 908 #endif
 909 #include <unistd.h>
 910 #include <limits.h>
 911 #include <sys/time.h>
 912 #include <sys/syscall.h>
 913 #include <linux/futex.h>
 914
 915 int main(void);
 916 ],
 917 [
 918 {
 919   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 920 }
 921 ])], [
 922     AC_MSG_RESULT([yes])
 923     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 924     needsync=false
 925   ], [
 926     AC_MSG_RESULT([no])
 927   ])
 928 ])
 929
 930 AS_IF([$needsync], [
 931   dnl FreeBSD
 932   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 933   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 934 #include <errno.h>
 935 #include <stdlib.h>
 936 #include <sys/types.h>
 937 #include <sys/umtx.h>
 938 int main(void);
 939 ],
 940 [
 941 {
 942   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
 943 }
 944 ])], [
 945     AC_MSG_RESULT([yes])
 946     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
 947     needsync=false
 948   ], [
 949     AC_MSG_RESULT([no])
 950   ])
 951 ])
 952
 953 AS_IF([$needsync], [
 954   dnl OpenBSD patch (not upstream at the time of writing this)
 955   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
 956   AC_MSG_CHECKING([for OpenBSD futex() support])
 957   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 958 #include <sys/futex.h>
 959 int main(void);
 960 ],
 961 [
 962 {
 963   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 964 }
 965 ])], [
 966     AC_MSG_RESULT([yes])
 967     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
 968     needsync=false
 969   ], [
 970     AC_MSG_RESULT([no])
 971   ])
 972 ])
 973
 974 dnl Utility macro to avoid retyping includes all the time
 975 m4_define([FRR_INCLUDES],
 976 [#ifdef SUNOS_5
 977 #define _POSIX_C_SOURCE 200809L
 978 #define __EXTENSIONS__
 979 #endif
 980 #include <stdio.h>
 981 #include <stdlib.h>
 982 #include <stddef.h>
 983 #include <sys/types.h>
 984 /* sys/conf.h depends on param.h on FBSD at least */
 985 #include <sys/param.h>
 986 /* Required for MAXSIG */
 987 #include <signal.h>
 988 #include <sys/socket.h>
 989 #ifdef __APPLE__
 990 # define __APPLE_USE_RFC_3542
 991 #endif
 992 #include <netinet/in.h>
 993 #include <sys/time.h>
 994 #include <time.h>
 995 #include <net/if.h>
 996 ])dnl
 997
 998 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 999 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1000 dnl an additional round for it.
1001
1002 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1003
1004 m4_define([FRR_INCLUDES],
1005 FRR_INCLUDES
1006 [#if HAVE_NET_IF_VAR_H
1007 # include <net/if_var.h>
1008 #endif
1009 ])dnl
1010
1011 AC_CHECK_HEADERS([netinet/in_var.h \
1012         net/if_dl.h net/netopt.h \
1013         inet/nd.h netinet/ip_icmp.h \
1014         sys/sysctl.h sys/sockio.h sys/conf.h],
1015         [], [], [FRR_INCLUDES])
1016
1017 AC_CHECK_HEADERS([ucontext.h], [], [],
1018 [#ifndef __USE_GNU
1019 #define __USE_GNU
1020 #endif /* __USE_GNU */
1021 FRR_INCLUDES
1022 ])
1023
1024 m4_define([UCONTEXT_INCLUDES],
1025 [#include <ucontext.h>])dnl
1026
1027 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1028   [], [], [UCONTEXT_INCLUDES])
1029 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1030   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1031    [], [], [UCONTEXT_INCLUDES])],
1032   [], [UCONTEXT_INCLUDES])
1033 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1034   [], [], [UCONTEXT_INCLUDES])
1035
1036 m4_define([FRR_INCLUDES],
1037 FRR_INCLUDES
1038 [
1039 #include <sys/un.h>
1040 #include <netinet/in_systm.h>
1041 #if HAVE_NETINET_IN_VAR_H
1042 # include <netinet/in_var.h>
1043 #endif
1044 #if HAVE_NET_IF_DL_H
1045 # include <net/if_dl.h>
1046 #endif
1047 #if HAVE_NET_NETOPT_H
1048 # include <net/netopt.h>
1049 #endif
1050 #include <net/route.h>
1051 #if HAVE_INET_ND_H
1052 # include <inet/nd.h>
1053 #endif
1054 #include <arpa/inet.h>
1055 /* Required for IDRP */
1056 #if HAVE_NETINET_IP_ICMP_H
1057 # include <netinet/ip_icmp.h>
1058 #endif
1059 ])dnl
1060
1061 dnl V6 headers are checked below, after we check for v6
1062
1063 AC_MSG_CHECKING([which operating system interface to use])
1064 case "$host_os" in
1065   sunos* | solaris2*)
1066     AC_MSG_RESULT([Solaris])
1067
1068     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1069     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1070     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1071
1072     AC_CHECK_LIB([socket], [main])
1073     AC_CHECK_LIB([nsl], [main])
1074     AC_CHECK_LIB([umem], [main])
1075     SOLARIS="solaris"
1076     AC_MSG_WARN([--Solaris support is being considered for deprecation, please let us know if you are still using this--])
1077     ;;
1078   linux*)
1079     AC_MSG_RESULT([Linux])
1080
1081     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1082     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1083     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1084
1085     dnl Linux has a compilation problem with mixing
1086     dnl netinet/in.h and linux/in6.h they are not
1087     dnl compatible.  There has been discussion on
1088     dnl how to fix it but no real progress on implementation
1089     dnl when they fix it, remove this
1090     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1091     ;;
1092   openbsd*)
1093     AC_MSG_RESULT([OpenBSD])
1094
1095     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1096     AC_DEFINE([KAME], [1], [KAME IPv6])
1097     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1098
1099     if test "x${enable_pimd}" != "xno"; then
1100       case "$host_os" in
1101       openbsd6.0)
1102         ;;
1103       openbsd[6-9]*)
1104         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1105         ;;
1106       esac
1107     fi
1108     ;;
1109   *)
1110     AC_MSG_RESULT([BSD])
1111
1112     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1113     AC_DEFINE([KAME], [1], [KAME IPv6])
1114     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1115     ;;
1116 esac
1117 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1118
1119 AC_SYS_LARGEFILE
1120
1121 dnl ------------------------
1122 dnl Integrated REALMS option
1123 dnl ------------------------
1124 if test "${enable_realms}" = "yes"; then
1125     case "$host_os" in
1126       linux*)
1127        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1128        ;;
1129       *)
1130        echo "Sorry, only Linux has REALMS support"
1131        exit 1
1132        ;;
1133     esac
1134 fi
1135
1136 dnl -------------------------------
1137 dnl Endian-ness check
1138 dnl -------------------------------
1139 AC_WORDS_BIGENDIAN
1140
1141 dnl ---------------
1142 dnl other functions
1143 dnl ---------------
1144 AC_CHECK_FUNCS([ \
1145         strlcat strlcpy \
1146         getgrouplist])
1147
1148 dnl ##########################################################################
1149 dnl LARGE if block spans a lot of "configure"!
1150 if test "${enable_clippy_only}" != "yes"; then
1151 dnl ##########################################################################
1152
1153 #
1154 # Logic for protobuf support.
1155 #
1156 if test "$enable_protobuf" = "yes"; then
1157   # Check for protoc & protoc-c
1158
1159   # protoc is not required, it's only for a "be nice" helper target
1160   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1161
1162   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1163   if test "$PROTOC_C" = "/bin/false"; then
1164     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1165   fi
1166
1167   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1168     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1169   ])
1170   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
1171     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
1172   ])
1173
1174   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1175 fi
1176
1177
1178 dnl ---------------------
1179 dnl Integrated VTY option
1180 dnl ---------------------
1181 case "${enable_vtysh}" in
1182 "no")
1183   VTYSH="";;
1184 *)
1185   VTYSH="vtysh";
1186   AC_DEFINE([VTYSH], [1], [VTY shell])
1187
1188   prev_libs="$LIBS"
1189   AC_CHECK_LIB([readline], [main], [
1190     LIBREADLINE="-lreadline"
1191   ], [
1192     dnl readline failed - it might be incorrectly linked and missing its
1193     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1194     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1195       LIBREADLINE="$ac_cv_search_tputs"
1196     ], [
1197       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1198     ])
1199
1200     dnl re-try with the lib we found above
1201     unset ac_cv_lib_readline_main
1202     AC_CHECK_LIB([readline], [main], [
1203       LIBREADLINE="-lreadline $LIBREADLINE"
1204     ], [
1205       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1206     ], [$LIBREADLINE])
1207   ], [])
1208   LIBS="$prev_libs"
1209
1210   AC_CHECK_HEADER([readline/history.h])
1211   if test $ac_cv_header_readline_history_h = no;then
1212     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1213   fi
1214   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1215   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1216     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1217   fi
1218   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1219   if test "$frr_cv_append_history" = yes; then
1220     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1221   fi
1222   ;;
1223 esac
1224 AC_SUBST([LIBREADLINE])
1225
1226 dnl ----------
1227 dnl PAM module
1228 dnl
1229 dnl FRR detects the PAM library it is built against by checking for a
1230 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1231 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1232 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1233 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1234 dnl of OpenPAM.
1235 dnl ----------
1236 if test "$with_libpam" = "yes"; then
1237   AC_CHECK_HEADER([security/pam_misc.h],
1238     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1239      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1240      pam_conv_func="misc_conv"
1241     ],
1242     [], FRR_INCLUDES)
1243   AC_CHECK_HEADER([security/openpam.h],
1244     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1245      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1246      pam_conv_func="openpam_ttyconv"
1247     ],
1248     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1249   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1250     AC_MSG_WARN([*** pam support will not be built ***])
1251     with_libpam="no"
1252   fi
1253 fi
1254
1255 if test "$with_libpam" = "yes"; then
1256 dnl took this test from proftpds configure.in and suited to our needs
1257 dnl -------------------------------------------------------------------------
1258 dnl
1259 dnl This next check looks funky due to a linker problem with some versions
1260 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1261 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1262 dnl with RedHat 6.2 and Debian 2.2 or better.
1263 AC_CHECK_LIB([pam], [pam_start],
1264   [AC_CHECK_LIB([pam], [$pam_conv_func],
1265     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1266      LIBPAM="-lpam"],
1267     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1268      LIBPAM="-lpam -lpam_misc"]
1269     )
1270   ],
1271
1272   [AC_CHECK_LIB([pam], [pam_end],
1273     [AC_CHECK_LIB([pam], [$pam_conv_func],
1274       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1275        LIBPAM="-lpam -ldl"],
1276       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1277        LIBPAM="-lpam -ldl -lpam_misc"]
1278      )
1279   ],AC_MSG_WARN([*** pam support will not be built ***]),
1280   [-ldl])
1281   ]
1282 )
1283 fi
1284 AC_SUBST([LIBPAM])
1285
1286 dnl -------------------------------
1287 dnl bgpd needs pow() and hence libm
1288 dnl -------------------------------
1289 TMPLIBS="$LIBS"
1290 LIBS=""
1291 AC_SEARCH_LIBS([pow], [m], [
1292   LIBM="$LIBS"
1293 ], [
1294   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1295 ])
1296 LIBS="$TMPLIBS"
1297 AC_SUBST([LIBM])
1298
1299 AC_CHECK_FUNCS([ppoll], [
1300   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1301 ])
1302 AC_CHECK_FUNCS([pollts], [
1303   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1304 ])
1305
1306 AC_CHECK_HEADER([asm-generic/unistd.h],
1307                 [AC_CHECK_DECL(__NR_setns,
1308                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1309                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1310                                ])
1311                  AC_CHECK_FUNCS([setns])]
1312                )
1313
1314 dnl --------------------------
1315 dnl Determine IS-IS I/O method
1316 dnl --------------------------
1317 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1318 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1319 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1320 AC_CHECK_HEADER([net/bpf.h])
1321 AC_CHECK_HEADER([sys/dlpi.h])
1322 AC_MSG_CHECKING([zebra IS-IS I/O method])
1323
1324 case "$host_os" in
1325   linux*)
1326     AC_MSG_RESULT([pfpacket])
1327     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1328     ;;
1329   solaris* | sunos*)
1330     AC_MSG_RESULT([DLPI])
1331     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1332     ;;
1333   *)
1334     if test $ac_cv_header_net_bpf_h = no; then
1335       if test $ac_cv_header_sys_dlpi_h = no; then
1336         AC_MSG_RESULT([none])
1337         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1338           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1339         fi
1340         AC_MSG_WARN([*** IS-IS support will not be built ***])
1341         enable_isisd="no"
1342         enable_fabricd="no"
1343       else
1344         AC_MSG_RESULT([DLPI])
1345       fi
1346       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1347     else
1348       AC_MSG_RESULT([BPF])
1349       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1350     fi
1351     ;;
1352 esac
1353 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1354
1355 dnl ---------------------------------------------------------------
1356 dnl figure out how to specify an interface in multicast sockets API
1357 dnl ---------------------------------------------------------------
1358 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1359
1360 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1361         #include <sys/socket.h>
1362         #include <netinet/in.h>
1363         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1364         #include <linux/types.h>
1365 ])
1366
1367 m4_define([FRR_INCLUDES],
1368 FRR_INCLUDES
1369 [#if HAVE_LINUX_MROUTE_H
1370 # include <linux/mroute.h>
1371 #endif
1372 ])dnl
1373
1374 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1375         #include <sys/socket.h>
1376         #include <sys/types.h>
1377         #include <netinet/in.h>
1378         #include <net/route.h>
1379 ])
1380
1381 m4_define([FRR_INCLUDES],
1382 FRR_INCLUDES
1383 [#if HAVE_NETINET_IP_MROUTE_H
1384 # include <netinet/ip_mroute.h>
1385 #endif
1386 ])dnl
1387
1388 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1389 AC_TRY_COMPILE([#include <sys/param.h>],
1390 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1391   return (0);
1392 #else
1393   #error No support for BSD struct ip_mreq hack detected
1394 #endif],[AC_MSG_RESULT([yes])
1395 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1396 AC_MSG_RESULT([no]))
1397
1398 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1399 AC_TRY_COMPILE([
1400 #include <sys/types.h>
1401 #include <netinet/in.h>
1402 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1403 ], [AC_MSG_RESULT([yes])
1404 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1405 AC_MSG_RESULT([no]))
1406
1407 dnl ---------------------------------------------------------------
1408 dnl figure out how to check link-state
1409 dnl ---------------------------------------------------------------
1410 AC_CHECK_HEADER([net/if_media.h],
1411   [m4_define([LINK_DETECT_INCLUDES],
1412     FRR_INCLUDES
1413     [#include <net/if_media.h>
1414   ])
1415   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1416     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1417     [], LINK_DETECT_INCLUDES)],
1418   [],
1419   FRR_INCLUDES)
1420
1421 dnl ---------------------------------------------------------------
1422 dnl Additional, newer way to check link-state using ifi_link_state.
1423 dnl Not available in all BSD's when ifmediareq available
1424 dnl ---------------------------------------------------------------
1425 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1426   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1427   [], FRR_INCLUDES)
1428
1429 dnl ------------------------
1430 dnl TCP_MD5SIG socket option
1431 dnl ------------------------
1432
1433 AC_CHECK_HEADER([netinet/tcp.h],
1434    [m4_define([MD5_INCLUDES],
1435       FRR_INCLUDES
1436       [#include <netinet/tcp.h>
1437     ])
1438     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1439    [],
1440    FRR_INCLUDES)
1441 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1442   AC_CHECK_HEADER([linux/tcp.h],
1443        [m4_define([MD5_INCLUDES],
1444           FRR_INCLUDES
1445           [#include <linux/tcp.h>
1446         ])
1447        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1448 fi
1449
1450 AC_SUBST([SOLARIS])
1451 AC_CHECK_LIB([crypt], [crypt], [],
1452                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1453 AC_CHECK_LIB([resolv], [res_init])
1454
1455 dnl ---------------------------
1456 dnl check system has PCRE regexp
1457 dnl ---------------------------
1458 if test "x$enable_pcreposix" = "xyes"; then
1459   AC_CHECK_LIB([pcreposix], [regexec], [], [
1460     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1461   ])
1462 fi
1463 AC_SUBST([HAVE_LIBPCREPOSIX])
1464
1465 dnl ##########################################################################
1466 dnl test "${enable_clippy_only}" != "yes"
1467 fi
1468 dnl END OF LARGE if block
1469 dnl ##########################################################################
1470
1471 dnl ------------------
1472 dnl check C-Ares library
1473 dnl ------------------
1474 PKG_CHECK_MODULES([CARES], [libcares], [
1475   c_ares_found=true
1476 ],[
1477   c_ares_found=false
1478 ])
1479 AM_CONDITIONAL([CARES], [$c_ares_found])
1480
1481
1482 dnl ----------------------------------------------------------------------------
1483 dnl figure out if domainname is available in the utsname struct (GNU extension).
1484 dnl ----------------------------------------------------------------------------
1485 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1486
1487 dnl ------------------
1488 dnl IPv6 header checks
1489 dnl ------------------
1490 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1491         netinet6/in6_var.h netinet6/nd6.h], [], [],
1492         FRR_INCLUDES)
1493
1494 m4_define([FRR_INCLUDES],dnl
1495 FRR_INCLUDES
1496 [#if HAVE_NETINET6_IN6_H
1497 #include <netinet6/in6.h>
1498 #endif
1499 #if HAVE_NETINET_IN6_VAR_H
1500 #include <netinet/in6_var.h>
1501 #endif
1502 #include <netinet/icmp6.h>
1503 #if HAVE_NETINET6_IN6_VAR_H
1504 # include <netinet6/in6_var.h>
1505 #endif
1506 #if HAVE_NETINET6_ND6_H
1507 # include <netinet6/nd6.h>
1508 #endif
1509 ])dnl
1510
1511 dnl --------------------
1512 dnl Daemon disable check
1513 dnl --------------------
1514
1515 AS_IF([test "${enable_ldpd}" != "no"], [
1516   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1517 ])
1518
1519 if test "$enable_bfdd" = "no"; then
1520   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1521   BFDD=""
1522 else
1523   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1524   BFDD="bfdd"
1525
1526   case $host_os in
1527     linux*)
1528       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1529       ;;
1530
1531     *)
1532       AC_DEFINE([BFD_BSD], [1], [bfdd])
1533       ;;
1534   esac
1535 fi
1536
1537 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1538   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1539 fi
1540
1541 NHRPD=""
1542 case "$host_os" in
1543   linux*)
1544     case "${enable_nhrpd}" in
1545       no)
1546         ;;
1547       yes)
1548         if test "${enable_clippy_only}" != "yes"; then
1549         if test "$c_ares_found" != "true" ; then
1550           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1551         fi
1552         fi
1553         NHRPD="nhrpd"
1554         ;;
1555       *)
1556         if test "$c_ares_found" = "true" ; then
1557           NHRPD="nhrpd"
1558         fi
1559         ;;
1560     esac
1561     ;;
1562   *)
1563     if test "${enable_nhrpd}" = "yes"; then
1564       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1565     fi
1566     ;;
1567 esac
1568
1569 if test "${enable_watchfrr}" = "no";then
1570   WATCHFRR=""
1571 else
1572   WATCHFRR="watchfrr"
1573 fi
1574
1575 OSPFCLIENT=""
1576 if test "${enable_ospfapi}" != "no";then
1577     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1578
1579   if test "${enable_ospfclient}" != "no";then
1580       OSPFCLIENT="ospfclient"
1581   fi
1582 fi
1583
1584 if test "${enable_bgp_announce}" = "no";then
1585   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1586 else
1587   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1588 fi
1589
1590 if test "${enable_bgp_vnc}" != "no";then
1591   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1592 fi
1593
1594 bgpd_bmp=false
1595 case "${enable_bmp}" in
1596   no)
1597     ;;
1598   yes)
1599     if test "$c_ares_found" != "true" ; then
1600       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1601     fi
1602     bgpd_bmp=true
1603     ;;
1604   *)
1605     if test "$c_ares_found" = "true" ; then
1606       bgpd_bmp=true
1607     fi
1608     ;;
1609 esac
1610
1611 dnl ##########################################################################
1612 dnl LARGE if block
1613 if test "${enable_clippy_only}" != "yes"; then
1614 dnl ##########################################################################
1615
1616 dnl ------------------
1617 dnl check Net-SNMP library
1618 dnl ------------------
1619 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1620    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1621    if test x"$NETSNMP_CONFIG" = x"no"; then
1622       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1623    fi
1624    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1625    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1626    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1627    # among other things we avoid a GPL vs. OpenSSL license conflict here
1628    for removelib in crypto ssl sensors pci wrap; do
1629      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1630    done
1631    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1632    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1633 int main(void);
1634 ],
1635 [
1636 {
1637   return 0;
1638 }
1639 ])], [
1640      AC_MSG_RESULT([no])
1641      AC_MSG_ERROR([--enable-snmp given but not usable])])
1642    case "${enable_snmp}" in
1643      yes)
1644       SNMP_METHOD=agentx
1645       ;;
1646      agentx)
1647       SNMP_METHOD="${enable_snmp}"
1648       ;;
1649      *)
1650       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1651       ;;
1652    esac
1653    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1654    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1655 fi
1656 AC_SUBST([SNMP_LIBS])
1657 AC_SUBST([SNMP_CFLAGS])
1658
1659 dnl ---------------
1660 dnl libyang
1661 dnl ---------------
1662 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.105], , [
1663   AC_MSG_ERROR([libyang (>= 0.16.105) was not found on your system.])
1664 ])
1665 ac_cflags_save="$CFLAGS"
1666 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1667 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1668   AC_MSG_ERROR([m4_normalize([
1669     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1670     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1671   ])
1672 ], [[#include <libyang/libyang.h>]])
1673 CFLAGS="$ac_cflags_save"
1674
1675 dnl ---------------
1676 dnl configuration rollbacks
1677 dnl ---------------
1678 SQLITE3=false
1679 if test "$enable_config_rollbacks" = "yes"; then
1680   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1681     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1682     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1683     SQLITE3=true
1684   ], [
1685     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1686   ])
1687 fi
1688
1689 dnl ---------------
1690 dnl confd
1691 dnl ---------------
1692 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1693    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1694    if test "x$CONFD" = "x/bin/false"; then
1695       AC_MSG_ERROR([confd was not found on your system.])]
1696    fi
1697    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1698    AC_SUBST([CONFD_CFLAGS])
1699    CONFD_LIBS="-lconfd"
1700    AC_SUBST([CONFD_LIBS])
1701    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1702 fi
1703
1704 dnl ---------------
1705 dnl sysrepo
1706 dnl ---------------
1707 if test "$enable_sysrepo" = "yes"; then
1708   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1709       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1710       SYSREPO=true],
1711       [SYSREPO=false
1712       AC_MSG_ERROR([sysrepo was not found on your system.])]
1713   )
1714 fi
1715
1716 dnl ---------------
1717 dnl gRPC
1718 dnl ---------------
1719 if test "$enable_grpc" = "yes"; then
1720   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1721     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1722     if test "$PROTOC" = "/bin/false"; then
1723       AC_MSG_FAILURE([grpc requested but protoc not found.])
1724     fi
1725
1726     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1727     GRPC=true
1728   ], [
1729     GRPC=false
1730     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1731   ])
1732 fi
1733
1734 dnl ------
1735 dnl ZeroMQ
1736 dnl ------
1737 if test "x$enable_zeromq" != "xno"; then
1738   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1739     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1740     ZEROMQ=true
1741   ], [
1742     if test "x$enable_zeromq" = "xyes"; then
1743       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1744     fi
1745   ])
1746 fi
1747
1748 dnl ------------------------------------
1749 dnl Enable RPKI and add librtr to libs
1750 dnl ------------------------------------
1751 if test "${enable_rpki}" = "yes"; then
1752   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1753       [RPKI=true],
1754       [RPKI=false
1755       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1756   )
1757 fi
1758
1759 dnl ------------------------------------------
1760 dnl Check whether rtrlib was build with ssh support
1761 dnl ------------------------------------------
1762 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1763 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1764                         [[struct tr_ssh_config config;]])],
1765         [AC_MSG_RESULT([yes])
1766         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1767         AC_MSG_RESULT([no])
1768 )
1769
1770 dnl ---------------
1771 dnl dlopen & dlinfo
1772 dnl ---------------
1773 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1774   AC_MSG_ERROR([unable to find the dlopen()])
1775 ])
1776
1777 AC_CHECK_HEADERS([link.h])
1778
1779 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1780   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1781 #include <stdlib.h>
1782 #ifdef HAVE_LINK_H
1783 #include <link.h>
1784 #endif
1785 #include <dlfcn.h>
1786 ]], [[
1787   char origin[1];
1788   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1789 ]])], [
1790     frr_cv_rtld_di_origin=yes
1791   ], [
1792     frr_cv_rtld_di_origin=no
1793   ])
1794 ])
1795 if test "$frr_cv_rtld_di_origin" = yes; then
1796   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1797 fi
1798
1799 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1800   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1801 #include <stdlib.h>
1802 #ifdef HAVE_LINK_H
1803 #include <link.h>
1804 #endif
1805 #include <dlfcn.h>
1806 ]], [[
1807   struct link_map *lm = NULL;
1808   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1809 ]])], [
1810     frr_cv_rtld_di_linkmap=yes
1811   ], [
1812     frr_cv_rtld_di_linkmap=no
1813   ])
1814 ])
1815 if test "$frr_cv_rtld_di_linkmap" = yes; then
1816   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1817 fi
1818
1819 dnl ##########################################################################
1820 dnl test "${enable_clippy_only}" != "yes"
1821 fi
1822 dnl END OF LARGE if block
1823 dnl ##########################################################################
1824
1825 dnl ---------------------------
1826 dnl sockaddr and netinet checks
1827 dnl ---------------------------
1828 AC_CHECK_TYPES([
1829         struct sockaddr_dl,
1830         struct vifctl, struct mfcctl, struct sioc_sg_req,
1831         vifi_t, struct sioc_vif_req, struct igmpmsg,
1832         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1833         struct nd_opt_adv_interval,
1834         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1835         struct nd_opt_rdnss, struct nd_opt_dnssl],
1836         [], [], FRR_INCLUDES)
1837
1838 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1839         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1840         struct sockaddr_dl.sdl_len,
1841         struct if6_aliasreq.ifra_lifetime,
1842         struct nd_opt_adv_interval.nd_opt_ai_type],
1843         [], [], FRR_INCLUDES)
1844
1845 dnl ---------------------------
1846 dnl IRDP/pktinfo/icmphdr checks
1847 dnl ---------------------------
1848
1849 AC_CHECK_TYPES([struct in_pktinfo], [
1850   AC_CHECK_TYPES([struct icmphdr], [
1851     IRDP=true
1852   ], [
1853     IRDP=false
1854   ], [FRR_INCLUDES])
1855 ], [
1856   IRDP=false
1857 ], [FRR_INCLUDES])
1858
1859 case "${enable_irdp}" in
1860 yes)
1861   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1862   ;;
1863 no)
1864   IRDP=false
1865   ;;
1866 esac
1867
1868
1869 dnl -----------------------
1870 dnl checking for IP_PKTINFO
1871 dnl -----------------------
1872 AC_MSG_CHECKING([for IP_PKTINFO])
1873 AC_TRY_COMPILE([#include <netdb.h>], [
1874   int opt = IP_PKTINFO;
1875 ], [
1876   AC_MSG_RESULT([yes])
1877   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1878 ], [
1879   AC_MSG_RESULT([no])
1880 ])
1881
1882 dnl ---------------------------
1883 dnl checking for IP_RECVDSTADDR
1884 dnl ---------------------------
1885 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1886 AC_TRY_COMPILE([#include <netinet/in.h>], [
1887   int opt = IP_RECVDSTADDR;
1888 ], [
1889   AC_MSG_RESULT([yes])
1890   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1891 ], [
1892   AC_MSG_RESULT([no])
1893 ])
1894
1895 dnl ----------------------
1896 dnl checking for IP_RECVIF
1897 dnl ----------------------
1898 AC_MSG_CHECKING([for IP_RECVIF])
1899 AC_TRY_COMPILE([#include <netinet/in.h>], [
1900   int opt = IP_RECVIF;
1901 ], [
1902   AC_MSG_RESULT([yes])
1903   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1904 ], [
1905   AC_MSG_RESULT([no])
1906 ])
1907
1908 dnl ----------------------
1909 dnl checking for SO_BINDANY
1910 dnl ----------------------
1911 AC_MSG_CHECKING([for SO_BINDANY])
1912 AC_TRY_COMPILE([#include <sys/socket.h>], [
1913   int opt = SO_BINDANY;
1914 ], [
1915   AC_MSG_RESULT([yes])
1916   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1917 ], [
1918   AC_MSG_RESULT([no])
1919 ])
1920
1921 dnl ----------------------
1922 dnl checking for IP_FREEBIND
1923 dnl ----------------------
1924 AC_MSG_CHECKING([for IP_FREEBIND])
1925 AC_TRY_COMPILE([#include <netinet/in.h>], [
1926   int opt = IP_FREEBIND;
1927 ], [
1928   AC_MSG_RESULT([yes])
1929   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1930 ], [
1931   AC_MSG_RESULT([no])
1932 ])
1933
1934 dnl --------------------------------------
1935 dnl checking for be32dec existence or not
1936 dnl --------------------------------------
1937 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1938                [#include <sys/endian.h>])
1939
1940 dnl --------------------------------------
1941 dnl checking for clock_time monotonic struct and call
1942 dnl --------------------------------------
1943 AC_CHECK_DECL([CLOCK_MONOTONIC],
1944         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1945          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1946 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1947
1948 dnl --------------------------------------
1949 dnl checking for flex and bison
1950 dnl --------------------------------------
1951
1952 AM_PROG_LEX
1953 AC_MSG_CHECKING([version of flex])
1954 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1955 frr_ac_flex_version="${frr_ac_flex_version##* }"
1956 AC_MSG_RESULT([$frr_ac_flex_version])
1957 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1958   LEX="$SHELL $missing_dir/missing flex"
1959   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1960     AC_MSG_WARN([using pregenerated flex output files])
1961   else
1962     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1963   fi
1964   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1965   AC_SUBST([LEXLIB], [''])
1966 ])
1967
1968 AC_PROG_YACC
1969 dnl thanks GNU bison for this b*llshit...
1970 AC_MSG_CHECKING([version of bison])
1971 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1972 frr_ac_bison_version="${frr_ac_bison_version##* }"
1973 frr_ac_bison_missing="false"
1974 case "x${frr_ac_bison_version}x" in
1975   x2.7*)
1976     BISON_OPENBRACE='"'
1977     BISON_CLOSEBRACE='"'
1978     BISON_VERBOSE=''
1979     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1980     ;;
1981   x2.*|x1.*)
1982     AC_MSG_RESULT([$frr_ac_bison_version])
1983     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1984     frr_ac_bison_missing="true"
1985     ;;
1986   x)
1987     AC_MSG_RESULT([none])
1988     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1989     frr_ac_bison_missing="true"
1990     ;;
1991   x3.[012][^0-9]*)
1992     BISON_OPENBRACE='{'
1993     BISON_CLOSEBRACE='}'
1994     BISON_VERBOSE='-Dparse.error=verbose'
1995     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
1996     ;;
1997   *)
1998     BISON_OPENBRACE='{'
1999     BISON_CLOSEBRACE='}'
2000     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2001     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2002     ;;
2003 esac
2004 AC_SUBST([BISON_OPENBRACE])
2005 AC_SUBST([BISON_CLOSEBRACE])
2006 AC_SUBST([BISON_VERBOSE])
2007
2008 if $frr_ac_bison_missing; then
2009   YACC="$SHELL $missing_dir/missing bison -y"
2010   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2011     AC_MSG_WARN([using pregenerated bison output files])
2012   else
2013     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2014   fi
2015 fi
2016
2017 dnl -------------------
2018 dnl capabilities checks
2019 dnl -------------------
2020 if test "${enable_capabilities}" != "no"; then
2021   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2022   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2023     [AC_MSG_RESULT([yes])
2024      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2025      frr_ac_keepcaps="yes"],
2026      AC_MSG_RESULT([no])
2027   )
2028   if test x"${frr_ac_keepcaps}" = x"yes"; then
2029     AC_CHECK_HEADERS([sys/capability.h])
2030   fi
2031   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
2032     AC_CHECK_LIB([cap], [cap_init],
2033       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2034        LIBCAP="-lcap"
2035        frr_ac_lcaps="yes"]
2036     )
2037   else
2038     AC_CHECK_HEADERS([priv.h],
2039      [AC_MSG_CHECKING([Solaris style privileges are available])
2040       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
2041           [AC_MSG_RESULT([yes])
2042            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
2043            frr_ac_scaps="yes"],
2044            AC_MSG_RESULT(no)
2045       )
2046      ]
2047    )
2048   fi
2049   if test x"${frr_ac_scaps}" = x"yes" \
2050        -o x"${frr_ac_lcaps}" = x"yes"; then
2051     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2052   fi
2053
2054   case "$host_os" in
2055   linux*)
2056     if test "${enable_clippy_only}" != "yes"; then
2057     if test "$frr_ac_lcaps" != "yes"; then
2058       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2059     fi
2060     fi
2061     ;;
2062   esac
2063 else
2064   case "$host_os" in
2065   linux*)
2066     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2067     ;;
2068   esac
2069 fi
2070 AC_SUBST([LIBCAP])
2071
2072 dnl ---------------------------
2073 dnl check for glibc 'backtrace'
2074 dnl ---------------------------
2075 if test x"${enable_backtrace}" != x"no" ; then
2076   backtrace_ok=no
2077   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2078     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2079     backtrace_ok=yes
2080   ], [
2081     case "$host_os" in
2082     sunos* | solaris2*)
2083       AC_CHECK_FUNCS([printstack], [
2084         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2085         backtrace_ok=yes
2086       ])
2087       ;;
2088     esac
2089     if test "$backtrace_ok" = no; then
2090       AC_CHECK_HEADER([execinfo.h], [
2091         AC_SEARCH_LIBS([backtrace], [execinfo], [
2092           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2093           backtrace_ok=yes
2094         ],, [-lm])
2095       ])
2096     fi
2097   ])
2098
2099   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2100     dnl user explicitly requested backtrace but we failed to find support
2101     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2102   fi
2103 fi
2104
2105 dnl -----------------------------------------
2106 dnl check for malloc mallinfo struct and call
2107 dnl this must try and link using LIBS, in
2108 dnl order to check no alternative allocator
2109 dnl has been specified, which might not provide
2110 dnl mallinfo, e.g. such as Umem on Solaris.
2111 dnl -----------------------------------------
2112 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2113
2114 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2115   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2116 #ifdef HAVE_MALLOC_H
2117 #include <malloc.h>
2118 #endif
2119 #ifdef HAVE_MALLOC_NP_H
2120 #include <malloc_np.h>
2121 #endif
2122 #ifdef HAVE_MALLOC_MALLOC_H
2123 #include <malloc/malloc.h>
2124 #endif
2125 ]], [[
2126 struct mallinfo ac_x; ac_x = mallinfo ();
2127 ]])], [
2128     frr_cv_mallinfo=yes
2129   ], [
2130     frr_cv_mallinfo=no
2131   ])
2132 ])
2133 if test "$frr_cv_mallinfo" = yes; then
2134   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2135 fi
2136
2137 AC_MSG_CHECKING([whether malloc_usable_size is available])
2138 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2139 #ifdef HAVE_MALLOC_H
2140 #include <malloc.h>
2141 #endif
2142 #ifdef HAVE_MALLOC_MALLOC_H
2143 #include <malloc/malloc.h>
2144 #endif
2145 ]], [[
2146 size_t ac_x; ac_x = malloc_usable_size(NULL);
2147 ]])], [
2148   AC_MSG_RESULT([yes])
2149   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2150 ], [
2151   AC_MSG_RESULT([no])
2152
2153   AC_MSG_CHECKING([whether malloc_size is available])
2154   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2155 #ifdef HAVE_MALLOC_H
2156 #include <malloc.h>
2157 #endif
2158 #ifdef HAVE_MALLOC_MALLOC_H
2159 #include <malloc/malloc.h>
2160 #endif
2161 ]], [[
2162 size_t ac_x; ac_x = malloc_size(NULL);
2163 ]])], [
2164     AC_MSG_RESULT([yes])
2165     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2166   ], [
2167     AC_MSG_RESULT([no])
2168   ])
2169 ])
2170
2171 dnl ----------
2172 dnl configure date
2173 dnl ----------
2174 dev_version=`echo $VERSION | grep dev`
2175 #don't expire deprecated code in non 'dev' branch
2176 if test "${dev_version}" = ""; then
2177    CONFDATE=0
2178 else
2179    CONFDATE=`date '+%Y%m%d'`
2180 fi
2181 AC_SUBST([CONFDATE])
2182
2183 dnl ------------------------------
2184 dnl set paths for state directory
2185 dnl ------------------------------
2186 AC_MSG_CHECKING([directory to use for state file])
2187 if test "${prefix}" = "NONE"; then
2188   frr_statedir_prefix="";
2189 else
2190   frr_statedir_prefix=${prefix}
2191 fi
2192 if test "${localstatedir}" = '${prefix}/var'; then
2193   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2194                         ${frr_statedir_prefix}/var/adm dnl
2195                         ${frr_statedir_prefix}/etc dnl
2196                         /var/run        dnl
2197                         /var/adm        dnl
2198                         /etc            dnl
2199                         /dev/null;
2200   do
2201     test -d $FRR_STATE_DIR && break
2202   done
2203   frr_statedir=$FRR_STATE_DIR
2204 else
2205   frr_statedir=${localstatedir}
2206 fi
2207 if test $frr_statedir = "/dev/null"; then
2208     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2209 fi
2210 AC_MSG_RESULT([${frr_statedir}])
2211 AC_SUBST([frr_statedir])
2212
2213 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2214 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2215 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2216 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2217 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2218
2219 dnl autoconf does this, but it does it too late...
2220 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2221 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2222
2223 dnl get the full path, recursing through variables...
2224 vtysh_bin="$bindir/vtysh"
2225 for I in 1 2 3 4 5 6 7 8 9 10; do
2226         eval vtysh_bin="\"$vtysh_bin\""
2227 done
2228 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2229 AC_SUBST([vtysh_bin])
2230
2231 CFG_SYSCONF="$sysconfdir"
2232 CFG_SBIN="$sbindir"
2233 CFG_STATE="$frr_statedir"
2234 CFG_MODULE="$moduledir"
2235 CFG_YANGMODELS="$yangmodelsdir"
2236 for I in 1 2 3 4 5 6 7 8 9 10; do
2237         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2238         eval CFG_SBIN="\"$CFG_SBIN\""
2239         eval CFG_STATE="\"$CFG_STATE\""
2240         eval CFG_MODULE="\"$CFG_MODULE\""
2241         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2242 done
2243 AC_SUBST([CFG_SYSCONF])
2244 AC_SUBST([CFG_SBIN])
2245 AC_SUBST([CFG_STATE])
2246 AC_SUBST([CFG_MODULE])
2247 AC_SUBST([CFG_YANGMODELS])
2248 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2249 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2250 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2251
2252 dnl various features
2253 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
2254 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
2255 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2256 dnl northbound
2257 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2258 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
2259 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
2260 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
2261 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2262 dnl plugins
2263 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2264 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
2265 AM_CONDITIONAL([IRDP], [$IRDP])
2266 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
2267 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
2268 dnl daemons
2269 AM_CONDITIONAL([VTYSH], [test "x$VTYSH" = "xvtysh"])
2270 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
2271 AM_CONDITIONAL([BGPD], [test "x${enable_bgpd}" != "no"])
2272 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
2273 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
2274 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
2275 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
2276 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
2277 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
2278 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
2279 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
2280 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
2281 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
2282 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
2283 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
2284 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
2285 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
2286 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
2287 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
2288 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
2289 AM_CONDITIONAL([VRRPD], [test "${enable_vrrpd}" != "no"])
2290
2291 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2292
2293 AC_CONFIG_FILES([
2294           config.version
2295           changelog-auto
2296           redhat/frr.spec
2297           solaris/Makefile
2298           alpine/APKBUILD
2299           snapcraft/snapcraft.yaml
2300           lib/version.h
2301           tests/lib/cli/test_cli.refout
2302           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2303           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2304           pkgsrc/eigrpd.sh])
2305
2306 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2307 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2308 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2309 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2310 AC_CONFIG_FILES([tools/frrcommon.sh])
2311
2312 AC_CONFIG_COMMANDS([lib/route_types.h], [
2313         dst="${ac_abs_top_builddir}/lib/route_types.h"
2314         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2315                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2316                 > "${dst}.tmp"
2317         test -f "${dst}" \
2318                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2319                 && rm "${dst}.tmp" \
2320                 || mv "${dst}.tmp" "${dst}"
2321 ], [
2322         PERL="$PERL"
2323 ])
2324
2325 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2326     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2327         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2328         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2329                 "${ac_abs_top_srcdir}" \
2330                 > "${dst}.tmp"
2331         test -f "${dst}" \
2332                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2333                 && rm "${dst}.tmp" \
2334                 || mv "${dst}.tmp" "${dst}"
2335     ], [
2336         PERL="$PERL"
2337     ])
2338 ])
2339
2340 ## Hack, but working solution to avoid rebuilding of frr.info.
2341 ## It's already in CVS until texinfo 4.7 is more common.
2342 AC_OUTPUT
2343
2344 echo "
2345 FRRouting configuration
2346 ------------------------------
2347 FRR version             : ${PACKAGE_VERSION}
2348 host operating system   : ${host_os}
2349 source code location    : ${srcdir}
2350 compiler                : ${CC}
2351 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2352 make                    : ${MAKE-make}
2353 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2354 state file directory    : ${frr_statedir}
2355 config file directory   : `eval echo \`echo ${sysconfdir}\``
2356 example directory       : `eval echo \`echo ${exampledir}\``
2357 module directory        : ${CFG_MODULE}
2358 user to run as          : ${enable_user}
2359 group to run as         : ${enable_group}
2360 group for vty sockets   : ${enable_vty_group}
2361 config file mask        : ${enable_configfile_mask}
2362 log file mask           : ${enable_logfile_mask}
2363 zebra protobuf enabled  : ${enable_protobuf:-no}
2364
2365 The above user and group must have read/write access to the state file
2366 directory and to the config files in the config file directory."
2367
2368 if test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" = false; then
2369   AC_MSG_WARN([sphinx is missing but required to build documentation])
2370 fi
2371 if test "$frr_py_mod_pytest" = false; then
2372   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2373 fi