configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lxc], [0.9.0])
   5
   6 AC_CONFIG_SRCDIR([configure.ac])
   7 AC_CONFIG_AUX_DIR([config])
   8 AC_CONFIG_HEADERS([src/config.h])
   9 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  10 AC_CANONICAL_HOST
  11 AM_PROG_CC_C_O
  12 AC_GNU_SOURCE
  13
  14 # Detect the distribution. This is used for the default configuration and
  15 # for some distro-specific build options.
  16 AC_MSG_CHECKING([host distribution])
  17 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, fedora, suse, gentoo, debian, arch, slackware, paldo, mandriva or pardus.]))
  18 if test "z$with_distro" = "z"; then
  19         with_distro=`lsb_release -is`
  20 fi
  21 if test "z$with_distro" = "z"; then
  22         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  23         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  24         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  25         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  26         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  27         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  28         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  29         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  30         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  31         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="mandriva")
  32         AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
  33         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  34 fi
  35 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  36
  37 if test "z$with_distro" = "z"; then
  38         with_distro="unknown"
  39 fi
  40 case $with_distro in
  41         ubuntu)
  42                 distroconf=default.conf.ubuntu
  43                 ;;
  44         redhat|fedora|oracle|oracleserver)
  45                 distroconf=default.conf.libvirt
  46                 ;;
  47         *)
  48                 echo -n "Linux distribution network config unknown, defaulting to lxc.network.type = empty"
  49                 distroconf=default.conf.unknown
  50                 ;;
  51 esac
  52 AC_MSG_RESULT([$with_distro])
  53 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"])
  54
  55 AC_CHECK_PROG([NEWUIDMAP], [newuidmap], [newuidmap])
  56 AM_CONDITIONAL([HAVE_NEWUIDMAP], [test -n "$NEWUIDMAP"])
  57
  58 # Allow disabling rpath
  59 AC_ARG_ENABLE([rpath],
  60         [AC_HELP_STRING([--disable-rpath], [do not set rpath in executables])],
  61         [], [enable_rpath=yes])
  62 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
  63
  64 # Documentation (manpages)
  65 AC_ARG_ENABLE([doc],
  66         [AC_HELP_STRING([--enable-doc], [make mans (requires docbook2man or docbook2x-man to be installed) [default=auto]])],
  67         [], [enable_doc=auto])
  68
  69 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
  70         db2xman=""
  71         dbparsers="docbook2x-man db2x_docbook2man docbook2man"
  72
  73         AC_MSG_CHECKING(for docbook2x-man)
  74         for name in ${dbparsers}; do
  75                 if "$name" --help >/dev/null 2>&1; then
  76                         db2xman="$name"
  77                         break;
  78                 fi
  79         done
  80
  81         if test -n "${db2xman}"; then
  82                 AC_MSG_RESULT([${db2xman}])
  83         else
  84                 AC_MSG_RESULT([no])
  85                 if test "x$enable_doc" = "xyes"; then
  86                         AC_MSG_ERROR([docbook2x-man required by man request, but not found])
  87                 fi
  88         fi
  89
  90         AC_SUBST(db2xman)
  91 fi
  92 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
  93
  94 if test "x$db2xman" = "xdocbook2man"; then
  95         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
  96 else
  97         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
  98 fi
  99 AC_SUBST(docdtd)
 100
 101 # Apparmor
 102 AC_ARG_ENABLE([apparmor],
 103         [AC_HELP_STRING([--enable-apparmor], [enable apparmor])],
 104         [], [enable_apparmor=check])
 105
 106 if test "$enable_apparmor" = "check" ; then
 107         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 108 fi
 109 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 110
 111 AC_CHECK_LIB([gnutls], [gnutls_hash_fast])
 112
 113 AM_COND_IF([ENABLE_APPARMOR],
 114         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 115         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 116         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 117
 118 # Seccomp syscall filter
 119 AC_ARG_ENABLE([seccomp],
 120         [AC_HELP_STRING([--enable-seccomp], [enable seccomp])],
 121         [], [enable_seccomp=check])
 122
 123 if test "$enable_seccomp" = "check" ; then
 124         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 125 fi
 126 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 127
 128 AM_COND_IF([ENABLE_SECCOMP],
 129         [AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 130         AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 131         AC_SUBST([SECCOMP_LIBS], [-lseccomp])])
 132
 133 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 134 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [#include <seccomp.h>])
 135
 136 # Configuration examples
 137 AC_ARG_ENABLE([examples],
 138         [AC_HELP_STRING([--disable-examples], [do not install configuration examples])],
 139         [], [enable_examples=yes])
 140 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 141
 142 # Python3 module and scripts
 143 AC_ARG_ENABLE([python],
 144         [AC_HELP_STRING([--enable-python], [enable python binding])],
 145         [enable_python=yes], [enable_python=no])
 146 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 147
 148 AM_COND_IF([ENABLE_PYTHON],
 149         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 150         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 151         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 152
 153 # Lua module and scripts
 154 if test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" ; then
 155     LUAPKGCONFIG=lua5.1
 156 else
 157     LUAPKGCONFIG=lua
 158 fi
 159
 160 AC_ARG_ENABLE([lua],
 161         [AC_HELP_STRING([--enable-lua], [enable lua binding])],
 162         [enable_lua=yes], [enable_lua=no])
 163
 164 AM_CONDITIONAL([ENABLE_LUA], [test "x$enable_lua" = "xyes"])
 165
 166 AM_COND_IF([ENABLE_LUA],
 167         [PKG_CHECK_MODULES([LUA], [$LUAPKGCONFIG >= 5.1],[],[AC_MSG_ERROR([You must install lua-devel for lua 5.1])])
 168         AC_DEFINE_UNQUOTED([ENABLE_LUA], 1, [Lua is available])])
 169
 170 # Optional test binaries
 171 AC_ARG_ENABLE([tests],
 172         [AC_HELP_STRING([--enable-tests], [build test/example binaries])],
 173         [enable_tests=yes], [enable_tests=no])
 174 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 175
 176 # LXC container path, where the containers are actually stored
 177 # This is overridden by an entry in the file called LXCCONF
 178 # (i.e. /etc/lxc/lxc.conf)
 179 AC_ARG_WITH([config-path],
 180         [AC_HELP_STRING(
 181                 [--with-config-path=dir],
 182                 [lxc configuration repository path]
 183         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 184
 185 # The path of the global lxc configuration file.
 186 AC_ARG_WITH([global-conf],
 187         [AC_HELP_STRING(
 188                 [--with-global-conf=dir],
 189                 [global lxc configuration file]
 190         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 191
 192 AC_ARG_WITH([usernic-conf],
 193         [AC_HELP_STRING(
 194                 [--with-usernic-conf],
 195                 [user network interface configuration file]
 196         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 197
 198 AC_ARG_WITH([usernic-db],
 199         [AC_HELP_STRING(
 200                 [--with-usernic-db],
 201                 [lxc user nic database]
 202         )], [], [with_usernic_db=['/run/lxc/nics']])
 203
 204 # Rootfs path, where the container mount structure is assembled
 205 AC_ARG_WITH([rootfs-path],
 206         [AC_HELP_STRING(
 207                 [--with-rootfs-path=dir],
 208                 [lxc rootfs mount point]
 209         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 210
 211 # Container log path.  By default, use $lxcpath.
 212 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 213 AC_ARG_ENABLE([configpath-log],
 214         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path])],
 215         [use_configpath_logs=yes], [use_configpath_logs=no])
 216 AC_MSG_RESULT([$use_configpath_logs])
 217 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$use_configpath_logs" = "yes"])
 218
 219 if test "$use_configpath_logs" = "yes"; then
 220         default_log_path="${with_config_path}"
 221 else
 222         default_log_path="${localstatedir}/log/lxc"
 223 fi
 224
 225 AC_ARG_WITH([log-path],
 226         [AC_HELP_STRING(
 227                 [--with-log-path=dir],
 228                 [per container log path]
 229         )], [], [with_log_path=['${default_log_path}']])
 230
 231 # Expand some useful variables
 232 AS_AC_EXPAND(PREFIX, "$prefix")
 233 AS_AC_EXPAND(LIBDIR, "$libdir")
 234 AS_AC_EXPAND(BINDIR, "$bindir")
 235 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 236 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 237 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 238 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 239 AS_AC_EXPAND(DATADIR, "$datadir")
 240 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 241 AS_AC_EXPAND(DOCDIR, "$docdir")
 242 AS_AC_EXPAND(LXC_DISTRO_CONF, "$distroconf")
 243 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 244 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 245 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 246 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 247 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 248 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 249 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 250 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 251 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 252 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 253
 254 # Check for some standard kernel headers
 255 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 256                                 [],
 257                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 258                                 [#include <sys/socket.h>])
 259
 260 # Allow disabling libcap support
 261 AC_ARG_ENABLE([capabilities],
 262         [AC_HELP_STRING([--disable-capabilities], [disable kernel capabilities])],
 263         [], [enable_capabilities=yes])
 264
 265 # Check for libcap support
 266 if test "x$enable_capabilities" = "xyes"; then
 267         AC_CHECK_LIB(cap,cap_set_proc,caplib=yes,caplib=no)
 268         AC_MSG_CHECKING([linux capabilities])
 269         if test "x$caplib" = "xyes" ; then
 270                 CAP_LIBS="-lcap"
 271                 AC_MSG_RESULT([$CAP_LIBS])
 272         else
 273                 AC_MSG_RESULT([no])
 274                 AC_MSG_ERROR([You are missing libcap support. If you really want to build without kernel capabilities, use --disable-capabilities])
 275         fi
 276 else
 277         CAP_LIBS=""
 278 fi
 279 AC_SUBST([CAP_LIBS])
 280
 281 # Check for alternate C libraries
 282 AC_MSG_CHECKING(for bionic libc)
 283 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 284         [[#ifndef __ANDROID__
 285 error: Not bionic!
 286 #endif]])],
 287         [is_bionic=yes],
 288         [is_bionic=no])
 289 if test "x$is_bionic" = "xyes"; then
 290         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 291         AC_MSG_RESULT([yes])
 292 else
 293         AC_MSG_RESULT([no])
 294 fi
 295 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 296
 297 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 298 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 299
 300 # Check for some headers
 301 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 302
 303 # Check for some syscalls functions
 304 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr])
 305
 306 # Check for some functions
 307 AC_CHECK_LIB(util, openpty)
 308 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent])
 309 AC_CHECK_FUNCS([getline],
 310         AM_CONDITIONAL(HAVE_GETLINE, true)
 311         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 312         AM_CONDITIONAL(HAVE_GETLINE, false))
 313 AC_CHECK_FUNCS([fgetln],
 314         AM_CONDITIONAL(HAVE_FGETLN, true)
 315         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 316         AM_CONDITIONAL(HAVE_FGETLN, false))
 317
 318 # Check for some libraries
 319 AC_SEARCH_LIBS(sem_open, [rt pthread])
 320 AC_SEARCH_LIBS(clock_gettime, [rt])
 321
 322 # Check for some standard binaries
 323 AC_PROG_GCC_TRADITIONAL
 324 AC_PROG_SED
 325
 326 if test "x$GCC" = "xyes"; then
 327         CFLAGS="$CFLAGS -Wall -Werror"
 328 fi
 329
 330 # Files requiring some variable expansion
 331 AC_CONFIG_FILES([
 332         Makefile
 333         lxc.pc
 334         lxc.spec
 335         config/Makefile
 336
 337         doc/Makefile
 338         doc/legacy/lxc-ls.sgml
 339         doc/lxc-attach.sgml
 340         doc/lxc-cgroup.sgml
 341         doc/lxc-checkconfig.sgml
 342         doc/lxc-checkpoint.sgml
 343         doc/lxc-clone.sgml
 344         doc/lxc-console.sgml
 345         doc/lxc-create.sgml
 346         doc/lxc-destroy.sgml
 347         doc/lxc-device.sgml
 348         doc/lxc-execute.sgml
 349         doc/lxc-freeze.sgml
 350         doc/lxc-info.sgml
 351         doc/lxc-kill.sgml
 352         doc/lxc-ls.sgml
 353         doc/lxc-monitor.sgml
 354         doc/lxc-netstat.sgml
 355         doc/lxc-ps.sgml
 356         doc/lxc-restart.sgml
 357         doc/lxc-start-ephemeral.sgml
 358         doc/lxc-start.sgml
 359         doc/lxc-stop.sgml
 360         doc/lxc-top.sgml
 361         doc/lxc-unfreeze.sgml
 362         doc/lxc-unshare.sgml
 363         doc/lxc-version.sgml
 364         doc/lxc-wait.sgml
 365
 366         doc/lxc.conf.sgml
 367         doc/lxc.sgml
 368         doc/common_options.sgml
 369         doc/see_also.sgml
 370
 371         doc/rootfs/Makefile
 372
 373         doc/examples/Makefile
 374         doc/examples/lxc-macvlan.conf
 375         doc/examples/lxc-vlan.conf
 376         doc/examples/lxc-no-netns.conf
 377         doc/examples/lxc-empty-netns.conf
 378         doc/examples/lxc-phys.conf
 379         doc/examples/lxc-veth.conf
 380         doc/examples/lxc-complex.conf
 381
 382         hooks/Makefile
 383
 384         templates/Makefile
 385         templates/lxc-cirros
 386         templates/lxc-debian
 387         templates/lxc-ubuntu
 388         templates/lxc-ubuntu-cloud
 389         templates/lxc-opensuse
 390         templates/lxc-busybox
 391         templates/lxc-fedora
 392         templates/lxc-oracle
 393         templates/lxc-altlinux
 394         templates/lxc-sshd
 395         templates/lxc-archlinux
 396         templates/lxc-alpine
 397
 398         src/Makefile
 399         src/lxc/Makefile
 400         src/lxc/lxc-ps
 401         src/lxc/lxc-netstat
 402         src/lxc/lxc-checkconfig
 403         src/lxc/lxc-version
 404         src/lxc/lxc-start-ephemeral
 405         src/lxc/legacy/lxc-ls
 406         src/lxc/lxc.functions
 407
 408         src/python-lxc/Makefile
 409
 410         src/lua-lxc/Makefile
 411
 412         src/tests/Makefile
 413 ])
 414 AC_CONFIG_COMMANDS([default],[[]],[[]])
 415 AC_OUTPUT