configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [9.0-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if necessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183
 184 dnl Some special handling for ICC later on
 185 if test "$CC" = "icc"; then
 186     cc_is_icc="yes"
 187 fi
 188
 189 PKG_PROG_PKG_CONFIG
 190
 191 dnl it's 2019, sed is sed.
 192 SED=sed
 193 AC_SUBST([SED])
 194
 195 dnl try and enable CFLAGS that are useful for FRR
 196 dnl - specifically, options to control warnings
 197
 198 AC_SUBST([AC_CFLAGS])
 199 AC_USE_SYSTEM_EXTENSIONS
 200 AC_DEFUN([AC_C_FLAG], [{
 201     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 202     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 203         AC_LANG_PUSH([C])
 204         ac_c_flag_save="$CFLAGS"
 205         CFLAGS="$CFLAGS $1"
 206         AC_COMPILE_IFELSE(
 207                 [AC_LANG_PROGRAM([[$4]])],
 208                 [
 209                         cachename=yes
 210                 ], [
 211                         cachename=no
 212                 ])
 213         CFLAGS="$ac_c_flag_save"
 214         AC_LANG_POP([C])
 215     ])
 216     if test "$cachename" = "yes"; then
 217         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 218     else
 219         :
 220         $2
 221     fi
 222     m4_popdef([cachename])
 223 }])
 224
 225 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 226         AC_LANG_PUSH([C])
 227         ac_cflags_save="$CFLAGS"
 228         ac_libs_save="$LIBS"
 229         CFLAGS="$CFLAGS $1"
 230         LIBS="$LIBS $2"
 231         AC_LINK_IFELSE(
 232                 [$3],
 233                 [
 234                         CFLAGS="$ac_cflags_save"
 235                         LIBS="$ac_libs_save"
 236                         m4_default([$5], [
 237                                 AC_MSG_RESULT([yes])
 238                         ])
 239                 ], [
 240                         CFLAGS="$ac_cflags_save"
 241                         LIBS="$ac_libs_save"
 242                         m4_default([$4], [
 243                                 AC_MSG_RESULT([no])
 244                         ])
 245                 ])
 246         AC_LANG_POP([C])
 247         }])
 248
 249 dnl ICC won't bail on unknown options without -diag-error 10006
 250 dnl need to do this first so we get useful results for the other options
 251 if test "$cc_is_icc" = "yes"; then
 252     AC_C_FLAG([-diag-error 10006])
 253 fi
 254
 255 dnl autoconf 2.69 AC_PROG_CC_C99 is "state of the art"
 256 dnl autoconf 2.70 AC_PROG_CC_C99 is deprecated and AC_PROC_CC tries to do C11
 257 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
 258   dnl autoconf < 2.70
 259   AC_PROG_CC_C99
 260
 261   dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 262   ac_cc="$CC"
 263   CC="${CC% -std=gnu99}"
 264   CC="${CC% -std=c99}"
 265
 266   AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 267 ], [
 268   dnl autoconf >= 2.70
 269   if test "$ac_cv_prog_cc_c11" = "no"; then
 270     AC_MSG_ERROR([ISO C11 compiler support (with GNU extensions) is required.])
 271   fi
 272 ])
 273
 274 dnl if the user has specified any CFLAGS, override our settings
 275 if test "$enable_gcov" = "yes"; then
 276    if test "$orig_cflags" = ""; then
 277       AC_C_FLAG([--coverage])
 278       AC_C_FLAG([-O0])
 279    fi
 280
 281    AC_LDFLAGS="${AC_LDFLAGS} --coverage"
 282 fi
 283
 284 if test "$enable_clang_coverage" = "yes"; then
 285    AC_C_FLAG([-fprofile-instr-generate], [
 286      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 287    ])
 288    AC_C_FLAG([-fcoverage-mapping], [
 289      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 290    ])
 291 fi
 292
 293 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 294
 295 if test "$enable_scripting" = "yes"; then
 296    AX_PROG_LUA([5.3], [5.4], [], [
 297      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 298    ])
 299    AX_LUA_HEADERS([], [
 300      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 301    ])
 302    AX_LUA_LIBS([
 303      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 304      LIBS="$LIBS $LUA_LIB"
 305      SCRIPTING=true
 306    ], [
 307      SCRIPTING=false
 308      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 309    ])
 310 fi
 311
 312 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 313 dnl sense to be overridden by the user
 314 if test "$enable_dev_build" = "yes"; then
 315    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 316    if test "$orig_cflags" = ""; then
 317       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 318       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 319       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 320    fi
 321 else
 322    if test "$orig_cflags" = ""; then
 323       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 324       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 325    fi
 326 fi
 327
 328 dnl just stick -g into LDFLAGS, if we don't have it in CFLAGS it won't do much
 329 LDFLAGS="$LDFLAGS -g"
 330
 331 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 332
 333 dnl -fms-extensions causes clang to have a built-in __wchar_t on OpenBSD,
 334 dnl which just straight up breaks compiling any code.
 335 dnl (2022-04-04 / OpenBSD 7 / clang 11.1.0)
 336 AH_VERBATIM([OpenBSD], [
 337 #ifdef __OpenBSD__
 338 #define __wchar_t __wchar_t_ignore
 339 #include <stdint.h>
 340 #undef __wchar_t
 341 #endif
 342 ])
 343
 344 dnl always want these CFLAGS
 345 AC_C_FLAG([-fms-extensions], [
 346   AC_MSG_ERROR([$CC does not support unnamed struct fields (-fms-extensions)])
 347 ])
 348 AC_C_FLAG([-fno-omit-frame-pointer])
 349 AC_C_FLAG([-funwind-tables])
 350 AC_C_FLAG([-Wall])
 351 AC_C_FLAG([-Wextra])
 352 AC_C_FLAG([-Wformat-nonliteral])
 353 AC_C_FLAG([-Wformat-security])
 354 AC_C_FLAG([-Wswitch-enum])
 355 AC_C_FLAG([-Wstrict-prototypes])
 356 AC_C_FLAG([-Wmissing-prototypes])
 357 AC_C_FLAG([-Wmissing-declarations])
 358 AC_C_FLAG([-Wpointer-arith])
 359 AC_C_FLAG([-Wbad-function-cast])
 360 AC_C_FLAG([-Wwrite-strings])
 361 AC_C_FLAG([-Wundef])
 362 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 363   AC_C_FLAG([-Wcast-qual])
 364   AC_C_FLAG([-Wmissing-noreturn])
 365   AC_C_FLAG([-Wmissing-format-attribute])
 366   AC_C_FLAG([-Wunreachable-code])
 367   AC_C_FLAG([-Wpacked])
 368   AC_C_FLAG([-Wpadded])
 369   AC_C_FLAG([-Wshadow])
 370 else
 371   AC_C_FLAG([-Wno-unused-result])
 372 fi
 373 AC_C_FLAG([-Wno-unused-parameter])
 374 AC_C_FLAG([-Wno-missing-field-initializers])
 375
 376 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 377 AC_SUBST([CXX_COMPAT_CFLAGS])
 378
 379 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 380 dnl for some reason the string consts get 'promoted' to char *,
 381 dnl triggering a const to non-const conversion warning.
 382 if test "$cc_is_icc" = "yes"; then
 383     AC_C_FLAG([-diag-disable 3179])
 384 fi
 385
 386 if test "$enable_werror" = "yes" ; then
 387   WERROR="-Werror"
 388 fi
 389 AC_SUBST([WERROR])
 390
 391 SAN_FLAGS=""
 392 if test "$enable_address_sanitizer" = "yes"; then
 393   AC_C_FLAG([-fsanitize=address], [
 394     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 395   ], [
 396     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 397   ])
 398 fi
 399 if test "$enable_thread_sanitizer" = "yes"; then
 400   AC_C_FLAG([-fsanitize=thread], [
 401     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 402   ], [
 403     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 404   ])
 405 fi
 406 if test "$enable_memory_sanitizer" = "yes"; then
 407   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 408     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 409   ], [
 410     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 411   ])
 412 fi
 413 if test "$enable_undefined_sanitizer" = "yes"; then
 414   AC_C_FLAG([-fsanitize=undefined], [
 415     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 416   ], [
 417     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 418   ])
 419 fi
 420 AC_SUBST([SAN_FLAGS])
 421
 422 dnl frr-format.so
 423 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 424   AC_C_FLAG([-fplugin=${with_frr_format}], [
 425     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 426   ],,[
 427 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 428 #error plugin not loaded
 429 #endif
 430 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 431 #error plugin too old
 432 #endif
 433   ])
 434 elif test "$with_frr_format" = "no"; then
 435   : #nothing
 436 else
 437   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 438     AC_C_FLAG([-fplugin=frr-format],[
 439       if test "$with_frr_format" = "yes"; then
 440         AC_MSG_ERROR([frr-format plugin requested but not found])
 441       fi
 442     ],,[
 443 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 444 #error plugin not loaded
 445 #endif
 446 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 447 #error plugin too old
 448 #endif
 449     ])
 450   ],,[
 451 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 452 #error plugin not loaded
 453 #endif
 454 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 455 #error plugin too old
 456 #endif
 457   ])
 458 fi
 459
 460 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 461 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 462 #include <stdio.h>
 463 int __attribute__((section("secttest"))) var = 1;
 464 extern int __start_secttest, __stop_secttest;
 465 ]], [[
 466   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 467   printf("%p %p %p\n", a, b, c);
 468 ]])], [
 469   AC_MSG_RESULT(yes)
 470   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 471 ], [
 472   AC_MSG_RESULT(no)
 473 ])
 474
 475 dnl ----------
 476 dnl Essentials
 477 dnl ----------
 478
 479 AX_PTHREAD([
 480   CC="$PTHREAD_CC"
 481   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 482   LIBS="$PTHREAD_LIBS $LIBS"
 483 ], [
 484   AC_MSG_FAILURE([This FRR version needs pthreads])
 485 ])
 486
 487 orig_cflags="$CFLAGS"
 488 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 489
 490 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 491                 [frr_cv_pthread_condattr_setclock=yes],
 492                 [frr_cv_pthread_condattr_setclock=no])
 493 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 494   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 495 fi
 496
 497 AC_CHECK_HEADERS([pthread_np.h],,, [
 498 #include <pthread.h>
 499 ])
 500 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 501
 502 CFLAGS="$orig_cflags"
 503
 504 dnl --------------
 505 dnl Check programs
 506 dnl --------------
 507 AC_PROG_INSTALL
 508 AC_PROG_LN_S
 509 AC_CHECK_TOOL([AR], [ar])
 510
 511 dnl -------
 512 dnl libtool
 513 dnl -------
 514 AC_ARG_ENABLE([static-bin],
 515   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 516 LT_INIT
 517 _LT_CONFIG_LIBTOOL([
 518   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 519     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 520 dnl the -i option is not POSIX sed and the BSDs implement it differently
 521 dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact
 522   sed -e 's%func_warning "relinking%true #\0%'                   libtool > libtool.sed && cat libtool.sed > libtool
 523   sed -e 's%func_warning "remember to run%true #\0%'             libtool > libtool.sed && cat libtool.sed > libtool
 524   sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool
 525   test -f libtool.sed && rm libtool.sed
 526 ])
 527 if test "$enable_static_bin" = "yes"; then
 528   AC_LDFLAGS_EXEC="-static"
 529   if test "$enable_static" != "yes"; then
 530     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 531   fi
 532 fi
 533 if test "$enable_shared" != "yes"; then
 534   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 535 fi
 536 AC_SUBST([AC_LDFLAGS])
 537 AC_SUBST([AC_LDFLAGS_EXEC])
 538 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 539
 540 dnl libtool, the repository of all knowledge related linkers, is too stupid to
 541 dnl correctly tell the linker how to build modules.
 542 if test -z "$module_cmds"; then
 543   module_cmds="`echo \"$archive_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 544 fi
 545 if test -z "$module_expsym_cmds"; then
 546   module_expsym_cmds="`echo \"$archive_expsym_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 547 fi
 548
 549 AC_ARG_ENABLE([rpath],
 550   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 551   [],
 552   [enable_rpath=yes])
 553
 554 dnl $AR and $RANLIB are set by LT_INIT above
 555 AC_MSG_CHECKING([whether $AR supports D option])
 556 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 557   AC_MSG_RESULT([yes])
 558   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 559   ARFLAGS="crD"
 560   AR_FLAGS="crD"
 561 else
 562   AC_MSG_RESULT([no])
 563   ARFLAGS="cru"
 564   AR_FLAGS="cru"
 565 fi
 566 AC_SUBST([ARFLAGS])
 567 AC_SUBST([AR_FLAGS])
 568
 569 AC_MSG_CHECKING([whether $RANLIB supports D option])
 570 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 571   if grep -q -- '-D' conftest.err; then
 572     AC_MSG_RESULT([no])
 573   else
 574     AC_MSG_RESULT([yes])
 575     RANLIB="$RANLIB -D"
 576   fi
 577 else
 578   AC_MSG_RESULT([no])
 579 fi
 580 AC_SUBST([RANLIB])
 581
 582 test -f conftest.err && rm conftest.err
 583 test -f conftest.a && rm conftest.a
 584
 585 dnl ----------------------
 586 dnl Packages configuration
 587 dnl ----------------------
 588 if test -f config.version; then
 589   . ./config.version
 590 elif test -f "${srcdir}/config.version"; then
 591   . "${srcdir}/config.version"
 592 fi
 593 AC_ARG_WITH([pkg-extra-version],
 594   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 595   if test "$withval" = "no"; then
 596     EXTRAVERSION=
 597   else
 598     EXTRAVERSION=$withval
 599   fi
 600 ], [])
 601 AC_ARG_WITH([pkg-git-version],
 602         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 603         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 604 AC_ARG_WITH([clippy],
 605   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 606 AC_ARG_WITH([vtysh_pager],
 607         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 608         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 609 AC_ARG_ENABLE([vtysh],
 610   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 611 AC_ARG_ENABLE([doc],
 612   AS_HELP_STRING([--disable-doc], [do not build docs]))
 613 AC_ARG_ENABLE([doc-html],
 614   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 615 AC_ARG_ENABLE([zebra],
 616   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 617 AC_ARG_ENABLE([bgpd],
 618   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 619 AC_ARG_ENABLE([mgmtd],
 620   AS_HELP_STRING([--disable-mgmtd], [do not build mgmtd]))
 621 AC_ARG_ENABLE([mgmtd_local_validations],
 622   AS_HELP_STRING([--enable-mgmtd-local-validations], [dev: unimplemented local validation]))
 623 AC_ARG_ENABLE([ripd],
 624   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 625 AC_ARG_ENABLE([ripngd],
 626   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 627 AC_ARG_ENABLE([ospfd],
 628   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 629 AC_ARG_ENABLE([ospf6d],
 630   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 631 AC_ARG_ENABLE([ldpd],
 632   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 633 AC_ARG_ENABLE([nhrpd],
 634   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 635 AC_ARG_ENABLE([eigrpd],
 636   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 637 AC_ARG_ENABLE([babeld],
 638   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 639 AC_ARG_ENABLE([watchfrr],
 640   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 641 AC_ARG_ENABLE([isisd],
 642   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 643 AC_ARG_ENABLE([pimd],
 644   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 645 AC_ARG_ENABLE([pim6d],
 646   AS_HELP_STRING([--disable-pim6d], [do not build pim6d]))
 647 AC_ARG_ENABLE([pbrd],
 648   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 649 AC_ARG_ENABLE([sharpd],
 650   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 651 AC_ARG_ENABLE([staticd],
 652   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 653 AC_ARG_ENABLE([fabricd],
 654   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 655 AC_ARG_ENABLE([vrrpd],
 656   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 657 AC_ARG_ENABLE([pathd],
 658   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 659 AC_ARG_ENABLE([bgp-announce],
 660   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 661 AC_ARG_ENABLE([bgp-vnc],
 662   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 663 AC_ARG_ENABLE([bgp-bmp],
 664   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 665 AC_ARG_ENABLE([snmp],
 666   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 667 AC_ARG_ENABLE([config_rollbacks],
 668   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 669 AC_ARG_ENABLE([confd],
 670   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 671 AC_ARG_ENABLE([sysrepo],
 672   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 673 AC_ARG_ENABLE([grpc],
 674   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 675 AC_ARG_ENABLE([zeromq],
 676   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 677 AC_ARG_ENABLE([lttng],
 678   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 679 AC_ARG_ENABLE([usdt],
 680   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 681 AC_ARG_WITH([libpam],
 682   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 683 AC_ARG_ENABLE([ospfapi],
 684   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 685 AC_ARG_ENABLE([ospfclient],
 686   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 687                           (this is the default if --disable-ospfapi is set)]))
 688 AC_ARG_ENABLE([multipath],
 689   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 690 AC_ARG_WITH([service_timeout],
 691   AS_HELP_STRING([--with-service-timeout=ARG], [set service timeout value (2 minutes by default), ARG must be digit]))
 692 AC_ARG_ENABLE([user],
 693   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 694 AC_ARG_ENABLE([group],
 695   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 696 AC_ARG_ENABLE([vty_group],
 697   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 698 AC_ARG_ENABLE([configfile_mask],
 699   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 700 AC_ARG_ENABLE([logfile_mask],
 701   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 702 AC_ARG_ENABLE([shell_access],
 703   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 704 AC_ARG_ENABLE([realms],
 705   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 706 AC_ARG_ENABLE([rtadv],
 707   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 708 AC_ARG_ENABLE([irdp],
 709   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 710 AC_ARG_ENABLE([capabilities],
 711   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 712 AC_ARG_ENABLE([gcc_ultra_verbose],
 713   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 714 AC_ARG_ENABLE([backtrace],
 715   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 716 AC_ARG_ENABLE([time-check],
 717   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 718 AC_ARG_ENABLE([cpu-time],
 719   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 720 AC_ARG_ENABLE([pcreposix],
 721   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 722 AC_ARG_ENABLE([pcre2posix],
 723   AS_HELP_STRING([--enable-pcre2posix], [enable using PCRE2 Posix libs for regex functions]))
 724 AC_ARG_ENABLE([fpm],
 725   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 726 AC_ARG_ENABLE([werror],
 727   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 728 AC_ARG_ENABLE([cumulus],
 729   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 730 AC_ARG_ENABLE([datacenter],
 731   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 732 AC_ARG_ENABLE([rr-semantics],
 733   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 734 AC_ARG_ENABLE([protobuf],
 735   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 736 AC_ARG_ENABLE([oldvpn_commands],
 737   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 738 AC_ARG_ENABLE([rpki],
 739   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 740 AC_ARG_ENABLE([clippy-only],
 741   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 742 AC_ARG_ENABLE([numeric_version],
 743   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 744 AC_ARG_ENABLE([gcov],
 745   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 746 AC_ARG_ENABLE([clang_coverage],
 747   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 748 AC_ARG_ENABLE([bfdd],
 749   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 750 AC_ARG_ENABLE([address-sanitizer],
 751   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 752 AC_ARG_ENABLE([thread-sanitizer],
 753   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 754 AC_ARG_ENABLE([memory-sanitizer],
 755   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 756 AC_ARG_ENABLE([undefined-sanitizer],
 757   AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 758 AC_ARG_WITH([crypto],
 759   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 760 AC_ARG_WITH([frr-format],
 761   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 762
 763 AC_ARG_ENABLE([version-build-config],
 764   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 765
 766 #if openssl, else use the internal
 767 AS_IF([test "$with_crypto" = "openssl"], [
 768 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 769 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 770   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 771 else
 772   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 773 fi
 774 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 775 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 776 )
 777
 778 AS_IF([test "$enable_clippy_only" != "yes"], [
 779 AC_CHECK_HEADERS([json-c/json.h])
 780 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 781 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 782   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 783   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 784       AC_MSG_ERROR([libjson is needed to compile])
 785   fi
 786 fi
 787 ])
 788
 789 AC_ARG_ENABLE([dev_build],
 790     AS_HELP_STRING([--enable-dev-build], [build for development]))
 791
 792 AC_ARG_ENABLE([scripting],
 793     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 794
 795 AC_ARG_ENABLE([netlink-debug],
 796   AS_HELP_STRING([--disable-netlink-debug], [don't pretty print netlink debug messages]))
 797
 798 if test "$enable_netlink_debug" != "no" ; then
 799   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 800 fi
 801
 802 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 803
 804 if test "$enable_time_check" != "no" ; then
 805   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 806     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 807   else
 808     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 809   fi
 810 fi
 811
 812 case "${enable_cpu_time}" in
 813   "no")
 814   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 815   ;;
 816   "*")
 817   ;;
 818 esac
 819
 820 if test "$enable_rr_semantics" != "no" ; then
 821   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 822 fi
 823
 824 if test "$enable_datacenter" = "yes" ; then
 825   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 826   DFLT_NAME="datacenter"
 827 else
 828   DFLT_NAME="traditional"
 829 fi
 830
 831 if test "$enable_cumulus" = "yes" ; then
 832   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 833 fi
 834
 835 AC_SUBST([DFLT_NAME])
 836 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 837
 838 if test "$enable_shell_access" = "yes"; then
 839    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 840 fi
 841
 842 #
 843 # Python for clippy
 844 #
 845
 846 AS_IF([test "$host" = "$build"], [
 847   AM_PATH_PYTHON([3])
 848   AC_CHECK_HEADER([gelf.h], [], [
 849     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 850   ])
 851
 852   LIBS_save="$LIBS"
 853   AC_CHECK_LIB([elf], [elf_memory], [], [
 854     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 855   ])
 856
 857   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 858     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 859   ])
 860   AC_CHECK_LIB([elf], [gelf_getnote], [
 861     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 862   ])
 863   LIBS="$LIBS_save"
 864   unset LIBS_save
 865
 866   FRR_PYTHON_DEV
 867 ], [
 868   FRR_PYTHON
 869 ])
 870
 871 FRR_PYTHON_MODULES([pytest])
 872
 873 if test "$enable_doc" != "no"; then
 874   FRR_PYTHON_MODULES([sphinx], , [
 875     if test "$enable_doc" = "yes"; then
 876       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 877     fi
 878   ])
 879 fi
 880 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 881 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 882
 883 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 884   PYSPHINX="-m sphinx"
 885 ], [
 886   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 887 ])
 888 AC_SUBST([PYSPHINX])
 889
 890 #
 891 # Logic for old vpn commands support.
 892 #
 893 if test "$enable_oldvpn_commands" = "yes"; then
 894    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 895 fi
 896
 897 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 898 if test "$enable_rtadv" != "no"; then
 899   AC_MSG_RESULT([yes])
 900   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 901 else
 902   AC_MSG_RESULT([no])
 903 fi
 904
 905 if test "$enable_user" = "no"; then
 906   enable_user=""
 907 else
 908   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 909     enable_user="frr"
 910   fi
 911   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 912 fi
 913
 914 if test "$enable_group" = "no"; then
 915   enable_group=""
 916 else
 917   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 918     enable_group="frr"
 919   fi
 920   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 921 fi
 922
 923 if test "$enable_vty_group" = "yes" ; then
 924   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 925 elif test "$enable_vty_group" != ""; then
 926   if test "$enable_vty_group" != "no"; then
 927     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 928   fi
 929 fi
 930 AC_SUBST([enable_user])
 931 AC_SUBST([enable_group])
 932 AC_SUBST([enable_vty_group])
 933
 934 enable_configfile_mask=${enable_configfile_mask:-0600}
 935 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 936 AC_SUBST([enable_configfile_mask])
 937
 938 enable_logfile_mask=${enable_logfile_mask:-0600}
 939 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 940
 941 MPATH_NUM=16
 942
 943 case "${enable_multipath}" in
 944   0)
 945     MPATH_NUM=64
 946     ;;
 947   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 948     MPATH_NUM="${enable_multipath}"
 949     ;;
 950   "")
 951     ;;
 952   *)
 953     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 954     ;;
 955 esac
 956
 957 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 958
 959 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 960
 961
 962 TIMEOUT_MIN=2
 963 case "${with_service_timeout}" in
 964   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 965     TIMEOUT_MIN="${with_service_timeout}"
 966     ;;
 967   0|"")
 968     ;;
 969   *)
 970     AC_MSG_FAILURE([Please specify digit for timeout ARG])
 971     ;;
 972 esac
 973 AC_SUBST([TIMEOUT_MIN])
 974
 975 dnl --------------------
 976 dnl Enable code coverage
 977 dnl --------------------
 978 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 979
 980 dnl ------------------------------------
 981 dnl Alpine only accepts numeric versions
 982 dnl ------------------------------------
 983 if test "$enable_numeric_version" != "" ; then
 984   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 985   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 986 fi
 987
 988 dnl -----------------------------------
 989 dnl Add extra version string to package
 990 dnl name, string and version fields.
 991 dnl -----------------------------------
 992 if test "$EXTRAVERSION" != "" ; then
 993   VERSION="${VERSION}${EXTRAVERSION}"
 994   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 995   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 996   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 997 fi
 998 AC_SUBST([EXTRAVERSION])
 999
1000 if test "$with_pkg_git_version" = "yes"; then
1001         if test -e "${srcdir}/.git"; then
1002                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
1003         else    with_pkg_git_version="no"
1004                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
1005         fi
1006 fi
1007 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
1008
1009 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
1010 if test "$OBJCOPY" != ":"; then
1011   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
1012     frr_cv_interp=""
1013     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
1014       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
1015         frr_cv_interp="`xargs -0 echo < conftest.interp`"
1016       fi
1017       test -f conftest.interp && rm conftest.interp
1018     ])
1019   ])
1020 fi
1021 if test -n "$frr_cv_interp"; then
1022   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
1023 fi
1024
1025 dnl -------------------------
1026 dnl Check other header files.
1027 dnl -------------------------
1028 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
1029         linux/version.h asm/types.h endian.h sys/endian.h])
1030
1031 ac_stdatomic_ok=false
1032 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
1033 AC_CHECK_HEADER([stdatomic.h],[
1034
1035   AC_MSG_CHECKING([whether _Atomic qualifier works])
1036   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1037 #include <stdatomic.h>
1038 int main(int argc, char **argv) {
1039   _Atomic int i = 0;
1040   return i;
1041 }
1042 ]])], [
1043     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
1044     AC_MSG_RESULT([yes])
1045     ac_stdatomic_ok=true
1046   ], [
1047     AC_MSG_RESULT([no])
1048   ])
1049 ])
1050
1051 AS_IF([$ac_stdatomic_ok], [true], [
1052   AC_MSG_CHECKING([for __atomic_* builtins])
1053   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1054 int main(int argc, char **argv) {
1055   volatile int i = 1;
1056   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1057   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1058 }
1059 ]])], [
1060     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1061     AC_MSG_RESULT([yes])
1062   ], [
1063     AC_MSG_RESULT([no])
1064
1065     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1066     AC_MSG_CHECKING([for __sync_* builtins])
1067     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1068 int main(int argc, char **argv) {
1069   volatile int i = 1;
1070   __sync_fetch_and_sub (&i, 1);
1071   return __sync_val_compare_and_swap (&i, 0, 1);
1072 }
1073 ]])], [
1074       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1075       AC_MSG_RESULT([yes])
1076
1077       AC_MSG_CHECKING([for __sync_swap builtin])
1078       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1079 int main(int argc, char **argv) {
1080   volatile int i = 1;
1081   return __sync_swap (&i, 2);
1082 }
1083 ]])], [
1084         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1085         AC_MSG_RESULT([yes])
1086       ], [
1087         AC_MSG_RESULT([no])
1088       ])
1089
1090     ], [
1091       AC_MSG_RESULT([no])
1092       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1093     ])
1094   ])
1095 ])
1096
1097 needsync=true
1098
1099 AS_IF([$needsync], [
1100   dnl Linux
1101   AC_MSG_CHECKING([for Linux futex() support])
1102   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1103 #ifndef _GNU_SOURCE
1104 #define _GNU_SOURCE
1105 #endif
1106 #include <unistd.h>
1107 #include <limits.h>
1108 #include <sys/time.h>
1109 #include <sys/syscall.h>
1110 #include <linux/futex.h>
1111
1112 int main(void);
1113 ],
1114 [
1115 {
1116   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1117 }
1118 ])], [
1119     AC_MSG_RESULT([yes])
1120     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1121     needsync=false
1122   ], [
1123     AC_MSG_RESULT([no])
1124   ])
1125 ])
1126
1127 AS_IF([$needsync], [
1128   dnl FreeBSD
1129   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1130   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1131 #include <errno.h>
1132 #include <stdlib.h>
1133 #include <sys/types.h>
1134 #include <sys/umtx.h>
1135 int main(void);
1136 ],
1137 [
1138 {
1139   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1140 }
1141 ])], [
1142     AC_MSG_RESULT([yes])
1143     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1144     needsync=false
1145   ], [
1146     AC_MSG_RESULT([no])
1147   ])
1148 ])
1149
1150 AS_IF([$needsync], [
1151   dnl OpenBSD patch (not upstream at the time of writing this)
1152   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1153   AC_MSG_CHECKING([for OpenBSD futex() support])
1154   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1155 #include <sys/futex.h>
1156 int main(void);
1157 ],
1158 [
1159 {
1160   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1161 }
1162 ])], [
1163     AC_MSG_RESULT([yes])
1164     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1165     needsync=false
1166   ], [
1167     AC_MSG_RESULT([no])
1168   ])
1169 ])
1170
1171 dnl Utility macro to avoid retyping includes all the time
1172 m4_define([FRR_INCLUDES],
1173 [#ifdef SUNOS_5
1174 #define _POSIX_C_SOURCE 200809L
1175 #define __EXTENSIONS__
1176 #endif
1177 #include <stdio.h>
1178 #include <stdlib.h>
1179 #include <stddef.h>
1180 #include <sys/types.h>
1181 /* sys/conf.h depends on param.h on FBSD at least */
1182 #include <sys/param.h>
1183 /* Required for MAXSIG */
1184 #include <signal.h>
1185 #include <sys/socket.h>
1186 #ifdef __APPLE__
1187 # define __APPLE_USE_RFC_3542
1188 #endif
1189 #include <netinet/in.h>
1190 #include <sys/time.h>
1191 #include <time.h>
1192 #include <net/if.h>
1193 ])dnl
1194
1195 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1196 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1197 dnl an additional round for it.
1198
1199 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1200
1201 m4_define([FRR_INCLUDES],
1202 FRR_INCLUDES
1203 [#ifdef HAVE_NET_IF_VAR_H
1204 # include <net/if_var.h>
1205 #endif
1206 ])dnl
1207
1208 AC_CHECK_HEADERS([netinet/in_var.h \
1209         net/if_dl.h net/netopt.h \
1210         inet/nd.h netinet/ip_icmp.h \
1211         sys/sysctl.h sys/sockio.h sys/conf.h],
1212         [], [], [FRR_INCLUDES])
1213
1214 AC_CHECK_HEADERS([ucontext.h], [], [],
1215 [#ifndef __USE_GNU
1216 #define __USE_GNU
1217 #endif /* __USE_GNU */
1218 FRR_INCLUDES
1219 ])
1220
1221 m4_define([UCONTEXT_INCLUDES],
1222 [#include <ucontext.h>])dnl
1223
1224 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1225   [], [], [UCONTEXT_INCLUDES])
1226 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1227   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1228    [], [], [UCONTEXT_INCLUDES])],
1229   [], [UCONTEXT_INCLUDES])
1230 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1231   [], [], [UCONTEXT_INCLUDES])
1232
1233 m4_define([FRR_INCLUDES],
1234 FRR_INCLUDES
1235 [
1236 #include <sys/un.h>
1237 #include <netinet/in_systm.h>
1238 #ifdef HAVE_NETINET_IN_VAR_H
1239 # include <netinet/in_var.h>
1240 #endif
1241 #ifdef HAVE_NET_IF_DL_H
1242 # include <net/if_dl.h>
1243 #endif
1244 #ifdef HAVE_NET_NETOPT_H
1245 # include <net/netopt.h>
1246 #endif
1247 #include <net/route.h>
1248 #ifdef HAVE_INET_ND_H
1249 # include <inet/nd.h>
1250 #endif
1251 #include <arpa/inet.h>
1252 /* Required for IDRP */
1253 #ifdef HAVE_NETINET_IP_ICMP_H
1254 # include <netinet/ip_icmp.h>
1255 #endif
1256 ])dnl
1257
1258 dnl V6 headers are checked below, after we check for v6
1259
1260 is_linux=false
1261
1262 AC_MSG_CHECKING([which operating system interface to use])
1263 case "$host_os" in
1264   sunos* | solaris2*)
1265     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1266     ;;
1267   linux*)
1268     AC_MSG_RESULT([Linux])
1269
1270     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1271     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1272     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1273
1274     dnl Linux has a compilation problem with mixing
1275     dnl netinet/in.h and linux/in6.h they are not
1276     dnl compatible.  There has been discussion on
1277     dnl how to fix it but no real progress on implementation
1278     dnl when they fix it, remove this
1279     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1280
1281     is_linux=true
1282     ;;
1283   openbsd*)
1284     AC_MSG_RESULT([OpenBSD])
1285
1286     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1287     AC_DEFINE([KAME], [1], [KAME IPv6])
1288     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1289     ;;
1290   *)
1291     AC_MSG_RESULT([BSD])
1292
1293     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1294     AC_DEFINE([KAME], [1], [KAME IPv6])
1295     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1296     ;;
1297 esac
1298 AM_CONDITIONAL([LINUX], [${is_linux}])
1299
1300 AC_SYS_LARGEFILE
1301
1302 dnl ------------------------
1303 dnl Integrated REALMS option
1304 dnl ------------------------
1305 if test "$enable_realms" = "yes"; then
1306     case "$host_os" in
1307       linux*)
1308        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1309        ;;
1310       *)
1311        echo "Sorry, only Linux has REALMS support"
1312        exit 1
1313        ;;
1314     esac
1315 fi
1316
1317 dnl ---------------
1318 dnl other functions
1319 dnl ---------------
1320 AC_CHECK_FUNCS([ \
1321         strlcat strlcpy \
1322         getgrouplist \
1323         openat \
1324         unlinkat \
1325         posix_fallocate \
1326         sendmmsg \
1327         explicit_bzero \
1328         ])
1329
1330 AC_CHECK_MEMBERS([struct mmsghdr.msg_hdr], [], [], FRR_INCLUDES)
1331
1332 dnl ##########################################################################
1333 dnl LARGE if block spans a lot of "configure"!
1334 if test "$enable_clippy_only" != "yes"; then
1335 dnl ##########################################################################
1336
1337 #
1338 # Logic for protobuf support.
1339 #
1340 PROTO3=false
1341 # Enable Protobuf by default at all times.
1342 # Check for protoc & protoc-c
1343 # protoc is not required, it's only for a "be nice" helper target
1344 AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1345
1346 AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1347 if test "$PROTOC_C" = "/bin/false"; then
1348   AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1349 fi
1350
1351 PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 1.1.0],, [
1352   AC_MSG_FAILURE([minimum version (1.1.0) of libprotobuf-c not found.  Install minimum required version of protobuf-c.])
1353 ])
1354
1355 if test "$enable_protobuf3" = "yes"; then
1356   PROTO3=true
1357   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1358                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1359                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1360                                             [1], [Have Protobuf version 3]),
1361                                   [PROTO3=false],
1362                                   [#include <google/protobuf-c/protobuf-c.h>])],
1363                   [PROTO3=false && AC_MSG_FAILURE([protobuf3 requested but protobuf-c.h not found.  Install protobuf-c.])])
1364 fi
1365
1366 AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1367 #
1368 # End of logic for protobuf support.
1369 #
1370
1371
1372 dnl ---------------------
1373 dnl Integrated VTY option
1374 dnl ---------------------
1375 case "${enable_vtysh}" in
1376 "no")
1377   VTYSH="";;
1378 *)
1379   VTYSH="vtysh";
1380   AC_DEFINE([VTYSH], [1], [VTY shell])
1381
1382   prev_libs="$LIBS"
1383   AC_CHECK_LIB([readline], [readline], [
1384     LIBREADLINE="-lreadline"
1385   ], [
1386     dnl readline failed - it might be incorrectly linked and missing its
1387     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1388     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1389       LIBREADLINE="$ac_cv_search_tputs"
1390     ], [
1391       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1392     ])
1393
1394     dnl re-try with the lib we found above
1395     unset ac_cv_lib_readline_main
1396     AC_CHECK_LIB([readline], [main], [
1397       LIBREADLINE="-lreadline $LIBREADLINE"
1398     ], [
1399       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1400     ], [$LIBREADLINE])
1401   ], [])
1402   LIBS="$LIBS -lreadline"
1403   AC_CHECK_FUNCS([rl_clear_visible_line])
1404   LIBS="$prev_libs"
1405
1406   AC_CHECK_HEADER([readline/history.h])
1407   if test "$ac_cv_header_readline_history_h" = "no"; then
1408     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1409   fi
1410   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1411   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1412     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1413   fi
1414   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1415   if test "$frr_cv_append_history" = "yes"; then
1416     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1417   fi
1418   ;;
1419 esac
1420 AC_SUBST([LIBREADLINE])
1421
1422 dnl ----------
1423 dnl PAM module
1424 dnl
1425 dnl FRR detects the PAM library it is built against by checking for a
1426 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1427 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1428 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1429 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1430 dnl of OpenPAM.
1431 dnl ----------
1432 if test "$with_libpam" = "yes"; then
1433   AC_CHECK_HEADER([security/pam_misc.h],
1434     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1435      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1436      pam_conv_func="misc_conv"
1437     ],
1438     [], FRR_INCLUDES)
1439   AC_CHECK_HEADER([security/openpam.h],
1440     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1441      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1442      pam_conv_func="openpam_ttyconv"
1443     ],
1444     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1445   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1446     AC_MSG_WARN([*** pam support will not be built ***])
1447     with_libpam="no"
1448   fi
1449 fi
1450
1451 if test "$with_libpam" = "yes"; then
1452 dnl took this test from proftpds configure.in and suited to our needs
1453 dnl -------------------------------------------------------------------------
1454 dnl
1455 dnl This next check looks funky due to a linker problem with some versions
1456 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1457 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1458 dnl with RedHat 6.2 and Debian 2.2 or better.
1459 AC_CHECK_LIB([pam], [pam_start],
1460   [AC_CHECK_LIB([pam], [$pam_conv_func],
1461     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1462      LIBPAM="-lpam"],
1463     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1464      LIBPAM="-lpam -lpam_misc"]
1465     )
1466   ],
1467
1468   [AC_CHECK_LIB([pam], [pam_end],
1469     [AC_CHECK_LIB([pam], [$pam_conv_func],
1470       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1471        LIBPAM="-lpam -ldl"],
1472       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1473        LIBPAM="-lpam -ldl -lpam_misc"]
1474      )
1475   ],AC_MSG_WARN([*** pam support will not be built ***]),
1476   [-ldl])
1477   ]
1478 )
1479 fi
1480 AC_SUBST([LIBPAM])
1481
1482 dnl -------------------------------
1483 dnl bgpd needs pow() and hence libm
1484 dnl -------------------------------
1485 TMPLIBS="$LIBS"
1486 LIBS=""
1487 AC_SEARCH_LIBS([pow], [m], [
1488   LIBM="$LIBS"
1489 ], [
1490   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1491 ])
1492 LIBS="$TMPLIBS"
1493 AC_SUBST([LIBM])
1494
1495 AC_CHECK_FUNCS([ppoll], [
1496   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1497 ])
1498 AC_CHECK_FUNCS([pollts], [
1499   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1500 ])
1501
1502 AC_CHECK_HEADER([asm-generic/unistd.h],
1503                 [AC_CHECK_DECL(__NR_setns,
1504                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1505                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1506                                ])
1507                  AC_CHECK_FUNCS([setns])]
1508                )
1509
1510 dnl --------------------------
1511 dnl Determine IS-IS I/O method
1512 dnl --------------------------
1513 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1514 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1515 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1516 AC_CHECK_HEADER([net/bpf.h])
1517 AC_CHECK_HEADER([sys/dlpi.h])
1518 AC_MSG_CHECKING([zebra IS-IS I/O method])
1519
1520 case "$host_os" in
1521   linux*)
1522     AC_MSG_RESULT([pfpacket])
1523     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1524     ;;
1525   *)
1526     if test "$ac_cv_header_net_bpf_h" = "no"; then
1527       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1528         AC_MSG_RESULT([none])
1529         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1530           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1531         fi
1532         AC_MSG_WARN([*** IS-IS support will not be built ***])
1533         enable_isisd="no"
1534         enable_fabricd="no"
1535       else
1536         AC_MSG_RESULT([DLPI])
1537       fi
1538       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1539     else
1540       AC_MSG_RESULT([BPF])
1541       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1542     fi
1543     ;;
1544 esac
1545 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1546
1547 dnl ---------------------------------------------------------------
1548 dnl figure out how to specify an interface in multicast sockets API
1549 dnl ---------------------------------------------------------------
1550 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1551
1552 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1553         #include <sys/socket.h>
1554         #include <netinet/in.h>
1555         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1556         #include <linux/types.h>
1557 ])
1558
1559 AC_CHECK_HEADERS([linux/mroute6.h], [], [],[
1560         #include <sys/socket.h>
1561         #include <netinet/in.h>
1562         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1563         #include <linux/types.h>
1564 ])
1565
1566 m4_define([FRR_INCLUDES],
1567 FRR_INCLUDES
1568 [#ifdef HAVE_LINUX_MROUTE_H
1569 # include <linux/mroute.h>
1570 #endif
1571 ])dnl
1572
1573 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1574         #include <sys/socket.h>
1575         #include <sys/types.h>
1576         #include <netinet/in.h>
1577         #include <net/route.h>
1578 ])
1579
1580 m4_define([FRR_INCLUDES],
1581 FRR_INCLUDES
1582 [#ifdef HAVE_NETINET_IP_MROUTE_H
1583 # include <netinet/ip_mroute.h>
1584 #endif
1585 ])dnl
1586
1587 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1588 AC_COMPILE_IFELSE(
1589 [ AC_LANG_PROGRAM([[
1590       #include <sys/types.h>
1591       #include <netinet/in.h>
1592   ]], [[
1593       struct group_req gr;
1594       int sock;
1595       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1596   ]])
1597 ],[
1598   AC_MSG_RESULT([yes])
1599   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1600 ],[
1601   AC_MSG_RESULT(no)
1602 ])
1603
1604 dnl ---------------------------------------------------------------
1605 dnl figure out how to check link-state
1606 dnl ---------------------------------------------------------------
1607 AC_CHECK_HEADER([net/if_media.h],
1608   [m4_define([LINK_DETECT_INCLUDES],
1609     FRR_INCLUDES
1610     [#include <net/if_media.h>
1611   ])
1612   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1613     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1614     [], LINK_DETECT_INCLUDES)],
1615   [],
1616   FRR_INCLUDES)
1617
1618 dnl ---------------------------------------------------------------
1619 dnl Additional, newer way to check link-state using ifi_link_state.
1620 dnl Not available in all BSD's when ifmediareq available
1621 dnl ---------------------------------------------------------------
1622 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1623   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1624   [], FRR_INCLUDES)
1625
1626 dnl ------------------------
1627 dnl TCP_MD5SIG socket option
1628 dnl ------------------------
1629
1630 AC_CHECK_HEADER([netinet/tcp.h],
1631    [m4_define([MD5_INCLUDES],
1632       FRR_INCLUDES
1633       [#include <netinet/tcp.h>
1634     ])
1635     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1636    [],
1637    FRR_INCLUDES)
1638 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1639   AC_CHECK_HEADER([linux/tcp.h],
1640        [m4_define([MD5_INCLUDES],
1641           FRR_INCLUDES
1642           [#include <linux/tcp.h>
1643         ])
1644        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1645 fi
1646
1647 LIBS_save="$LIBS"
1648 AC_CHECK_LIB([crypt], [crypt], [], [
1649   AC_CHECK_LIB([crypto], [DES_crypt])
1650 ])
1651 LIBCRYPT="$LIBS"
1652 LIBCRYPT="${LIBCRYPT%$LIBS_save}"
1653 LIBCRYPT="${LIBCRYPT#$LIBS_save}"
1654 AC_SUBST([LIBCRYPT])
1655 LIBS="$LIBS_save"
1656 unset LIBS_save
1657
1658 AC_CHECK_LIB([resolv], [res_init])
1659
1660 dnl ---------------------------
1661 dnl check system has PCRE regexp
1662 dnl ---------------------------
1663 if test "$enable_pcreposix" = "yes"; then
1664   AC_CHECK_LIB([pcreposix], [regexec], [], [
1665     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1666   ])
1667 fi
1668 AC_SUBST([HAVE_LIBPCREPOSIX])
1669
1670 dnl ---------------------------
1671 dnl check system has PCRE2 regexp
1672 dnl ---------------------------
1673 if test "$enable_pcre2posix" = "yes"; then
1674   AC_CHECK_LIB([pcre2-posix], [regexec], [], [
1675     AC_MSG_ERROR([--enable-pcre2posix given but unable to find libpcre2-posix])
1676   ])
1677 fi
1678 AC_SUBST([HAVE_LIBPCRE2_POSIX])
1679
1680 dnl ##########################################################################
1681 dnl test "$enable_clippy_only" != "yes"
1682 fi
1683 dnl END OF LARGE if block
1684 dnl ##########################################################################
1685
1686 dnl ------------------
1687 dnl check C-Ares library
1688 dnl ------------------
1689 PKG_CHECK_MODULES([CARES], [libcares], [
1690   c_ares_found=true
1691 ],[
1692   c_ares_found=false
1693 ])
1694 AM_CONDITIONAL([CARES], [$c_ares_found])
1695
1696
1697 dnl ----------------------------------------------------------------------------
1698 dnl figure out if domainname is available in the utsname struct (GNU extension).
1699 dnl ----------------------------------------------------------------------------
1700 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1701
1702 dnl ------------------
1703 dnl IPv6 header checks
1704 dnl ------------------
1705 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1706         netinet6/in6_var.h netinet6/nd6.h], [], [],
1707         FRR_INCLUDES)
1708
1709 m4_define([FRR_INCLUDES],dnl
1710 FRR_INCLUDES
1711 [#ifdef HAVE_NETINET6_IN6_H
1712 #include <netinet6/in6.h>
1713 #endif
1714 #ifdef HAVE_NETINET_IN6_VAR_H
1715 #include <netinet/in6_var.h>
1716 #endif
1717 #include <netinet/icmp6.h>
1718 #ifdef HAVE_NETINET6_IN6_VAR_H
1719 # include <netinet6/in6_var.h>
1720 #endif
1721 #ifdef HAVE_NETINET6_ND6_H
1722 # include <netinet6/nd6.h>
1723 #endif
1724 ])dnl
1725
1726 dnl --------------------
1727 dnl Daemon disable check
1728 dnl --------------------
1729
1730 AS_IF([test "$enable_bgpd" != "no"], [
1731   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1732 ])
1733
1734 AS_IF([test "$enable_mgmtd" != "no"], [
1735
1736   AC_DEFINE([HAVE_MGMTD], [1], [mgmtd])
1737
1738   # Enable MGMTD local validations
1739   AS_IF([test "$enable_mgmtd_local_validations" == "yes"], [
1740     AC_DEFINE([MGMTD_LOCAL_VALIDATIONS_ENABLED], [1], [Enable mgmtd local validations.])
1741   ])
1742 ])
1743
1744 AS_IF([test "$enable_ripd" != "no"], [
1745   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1746 ])
1747
1748 AS_IF([test "$enable_ripngd" != "no"], [
1749   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1750 ])
1751
1752 AS_IF([test "$enable_ospfd" != "no"], [
1753   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1754 ])
1755
1756 AS_IF([test "$enable_ospf6d" != "no"], [
1757   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1758 ])
1759
1760 AS_IF([test "$enable_ldpd" != "no"], [
1761   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1762 ])
1763
1764 AS_IF([test "$enable_nhrpd" != "no"], [
1765   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1766 ])
1767
1768 AS_IF([test "$enable_eigrpd" != "no"], [
1769   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1770 ])
1771
1772 AS_IF([test "$enable_babeld" != "no"], [
1773   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1774 ])
1775
1776 AS_IF([test "$enable_isisd" != "no"], [
1777   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1778 ])
1779
1780 AS_IF([test "$enable_pimd" != "no"], [
1781   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1782 ])
1783
1784 AS_IF([test "$enable_pim6d" != "no"], [
1785   AC_DEFINE([HAVE_PIM6D], [1], [pim6d])
1786 ])
1787
1788 AS_IF([test "$enable_pbrd" != "no"], [
1789   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1790 ])
1791
1792 AS_IF([test "$enable_sharpd" = "yes"], [
1793   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1794 ])
1795
1796 AS_IF([test "$enable_staticd" != "no"], [
1797   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1798 ])
1799
1800 AS_IF([test "$enable_fabricd" != "no"], [
1801   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1802 ])
1803
1804 AS_IF([test "$enable_vrrpd" != "no"], [
1805   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1806 ])
1807
1808 if test "$enable_bfdd" = "no"; then
1809   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1810   BFDD=""
1811 else
1812   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1813   BFDD="bfdd"
1814
1815   case $host_os in
1816     linux*)
1817       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1818       ;;
1819
1820     *)
1821       AC_DEFINE([BFD_BSD], [1], [bfdd])
1822       ;;
1823   esac
1824 fi
1825
1826 AS_IF([test "$enable_pathd" != "no"], [
1827   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1828 ])
1829
1830 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1831   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1832 fi
1833
1834 NHRPD=""
1835 case "$host_os" in
1836   linux*)
1837     case "${enable_nhrpd}" in
1838       no)
1839         ;;
1840       yes)
1841         if test "$enable_clippy_only" != "yes"; then
1842         if test "$c_ares_found" != "true" ; then
1843           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1844         fi
1845         fi
1846         NHRPD="nhrpd"
1847         ;;
1848       *)
1849         if test "$c_ares_found" = "true" ; then
1850           NHRPD="nhrpd"
1851         fi
1852         ;;
1853     esac
1854     ;;
1855   *)
1856     if test "$enable_nhrpd" = "yes"; then
1857       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1858     fi
1859     ;;
1860 esac
1861
1862 if test "$enable_watchfrr" = "no";then
1863   WATCHFRR=""
1864 else
1865   WATCHFRR="watchfrr"
1866 fi
1867
1868 OSPFCLIENT=""
1869 if test "$enable_ospfapi" != "no";then
1870     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1871
1872   if test "$enable_ospfclient" != "no";then
1873       OSPFCLIENT="ospfclient"
1874   fi
1875 fi
1876
1877 if test "$enable_bgp_announce" = "no";then
1878   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1879 else
1880   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1881 fi
1882
1883 if test "$enable_bgp_vnc" != "no";then
1884   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1885 fi
1886
1887 bgpd_bmp=false
1888 case "${enable_bgp_bmp}" in
1889   no)
1890     ;;
1891   yes)
1892     if test "$c_ares_found" != "true" ; then
1893       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1894     fi
1895     bgpd_bmp=true
1896     ;;
1897   *)
1898     if test "$c_ares_found" = "true" ; then
1899       bgpd_bmp=true
1900     fi
1901     ;;
1902 esac
1903
1904 if test "$enable_version_build_config" != "no";then
1905   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1906 fi
1907
1908 dnl ##########################################################################
1909 dnl LARGE if block
1910 if test "$enable_clippy_only" != "yes"; then
1911 dnl ##########################################################################
1912
1913 dnl ------------------
1914 dnl check Net-SNMP library
1915 dnl ------------------
1916 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1917    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1918    if test "$NETSNMP_CONFIG" = "no"; then
1919       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1920    fi
1921    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1922    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1923    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1924    # among other things we avoid a GPL vs. OpenSSL license conflict here
1925    for removelib in crypto ssl sensors pci wrap; do
1926      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1927    done
1928    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1929    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1930 int main(void);
1931 ],
1932 [
1933 {
1934   return 0;
1935 }
1936 ])], [
1937      AC_MSG_RESULT([no])
1938      AC_MSG_ERROR([--enable-snmp given but not usable])])
1939    case "${enable_snmp}" in
1940      yes)
1941       SNMP_METHOD=agentx
1942       ;;
1943      agentx)
1944       SNMP_METHOD="${enable_snmp}"
1945       ;;
1946      *)
1947       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1948       ;;
1949    esac
1950    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1951    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1952 fi
1953 AC_SUBST([SNMP_LIBS])
1954 AC_SUBST([SNMP_CFLAGS])
1955
1956 dnl ---------------
1957 dnl libyang
1958 dnl ---------------
1959 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1960   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1961 ])
1962 ac_cflags_save="$CFLAGS"
1963 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1964 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1965   AC_MSG_ERROR([m4_normalize([
1966     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1967     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1968   ])
1969 ], [[#include <libyang/libyang.h>]])
1970 CFLAGS="$ac_cflags_save"
1971
1972 dnl ---------------
1973 dnl configuration rollbacks
1974 dnl ---------------
1975 SQLITE3=false
1976 if test "$enable_config_rollbacks" = "yes"; then
1977   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1978     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1979     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1980     SQLITE3=true
1981   ], [
1982     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1983   ])
1984 fi
1985
1986 dnl ---------------
1987 dnl confd
1988 dnl ---------------
1989 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1990    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1991    if test "$CONFD" = "/bin/false"; then
1992       AC_MSG_ERROR([confd was not found on your system.])]
1993    fi
1994    AC_CHECK_PROG([CONFDC], [confdc], [confdc], [/bin/false], "${enable_confd}/bin")
1995    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1996    AC_SUBST([CONFD_CFLAGS])
1997    CONFD_LIBS="-lconfd"
1998    AC_SUBST([CONFD_LIBS])
1999    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
2000 fi
2001
2002 dnl ---------------
2003 dnl sysrepo
2004 dnl ---------------
2005 if test "$enable_sysrepo" = "yes"; then
2006   PKG_CHECK_MODULES([SYSREPO], [sysrepo >= 2.1.42],
2007       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
2008       SYSREPO=true],
2009       [SYSREPO=false
2010       AC_MSG_ERROR([sysrepo was not found on your system.])]
2011   )
2012 fi
2013
2014 dnl ---------------
2015 dnl gRPC
2016 dnl ---------------
2017 if test "$enable_grpc" = "yes"; then
2018   AC_LANG_PUSH([C++])
2019   AX_CXX_COMPILE_STDCXX([11], [ext])
2020   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
2021     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
2022     if test "$PROTOC" = "/bin/false"; then
2023       AC_MSG_FAILURE([grpc requested but protoc not found.])
2024     fi
2025
2026     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
2027     GRPC=true
2028   ], [
2029     GRPC=false
2030     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
2031   ])
2032   AC_LANG_POP([C++])
2033 fi
2034
2035 dnl ---------
2036 dnl DPDK
2037 dnl ---------
2038 if test "$enable_dp_dpdk" = "yes"; then
2039   PKG_CHECK_MODULES([DPDK], [libdpdk], [
2040     AC_DEFINE([HAVE_DPDK], [1], [Enable DPDK backend])
2041     DPDK=true
2042   ], [
2043     AC_MSG_ERROR([configuration specifies --enable-dp-dpdk but DPDK libs were not found])
2044   ])
2045 fi
2046
2047 dnl -----
2048 dnl LTTng
2049 dnl -----
2050 if test "$enable_lttng" = "yes"; then
2051   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.9.0], [
2052     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
2053     LTTNG=true
2054   ], [
2055     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
2056   ])
2057 fi
2058
2059 dnl ----
2060 dnl USDT
2061 dnl ----
2062 if test "$enable_usdt" = "yes"; then
2063   AC_CHECK_HEADERS([sys/sdt.h], [
2064     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
2065     USDT=true
2066   ], [
2067     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
2068   ])
2069 fi
2070
2071 dnl ------
2072 dnl ZeroMQ
2073 dnl ------
2074 if test "$enable_zeromq" != "no"; then
2075   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2076     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2077     ZEROMQ=true
2078   ], [
2079     if test "$enable_zeromq" = "yes"; then
2080       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2081     fi
2082   ])
2083 fi
2084
2085 dnl ------------------------------------
2086 dnl Enable RPKI and add librtr to libs
2087 dnl ------------------------------------
2088 if test "$enable_rpki" = "yes"; then
2089   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.8.0],
2090       [RPKI=true],
2091       [RPKI=false
2092       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2093   )
2094 fi
2095
2096 dnl ------------------------------------
2097 dnl pimd and pim6d not supported on OpenBSD and MacOS
2098 dnl ------------------------------------
2099 if test "$enable_pimd" != "no"; then
2100 AC_MSG_CHECKING([for pimd OS support])
2101 case "$host_os" in
2102   darwin*)
2103     AC_MSG_RESULT([no])
2104     enable_pimd="no"
2105     ;;
2106   openbsd*)
2107     AC_MSG_RESULT([no])
2108     enable_pimd="no"
2109     ;;
2110   *)
2111     AC_MSG_RESULT([yes])
2112     ;;
2113 esac
2114 fi
2115
2116 if test "$enable_pim6d" != "no"; then
2117 AC_MSG_CHECKING([for pim6d OS support])
2118 case "$host_os" in
2119   linux*)
2120     AC_MSG_RESULT([yes])
2121     ;;
2122   *)
2123     AC_MSG_RESULT([no])
2124     enable_pim6d="no"
2125     ;;
2126 esac
2127 fi
2128
2129 dnl -------------------------------------
2130 dnl VRRP is only supported on linux
2131 dnl -------------------------------------
2132 if test "$enable_vrrpd" != "no"; then
2133 AC_MSG_CHECKING([for VRRP OS support])
2134 case "$host_os" in
2135   linux*)
2136     AC_MSG_RESULT([yes])
2137     ;;
2138   *)
2139     AC_MSG_RESULT([no])
2140     enable_vrrpd="no"
2141     ;;
2142 esac
2143 fi
2144
2145 dnl ------------------------------------------
2146 dnl Check whether rtrlib was build with ssh support
2147 dnl ------------------------------------------
2148 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2149 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2150                         [[struct tr_ssh_config config;]])],
2151         [AC_MSG_RESULT([yes])
2152         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2153         AC_MSG_RESULT([no])
2154 )
2155
2156 dnl ---------------
2157 dnl dlopen & dlinfo
2158 dnl ---------------
2159 LIBS_save="$LIBS"
2160 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2161   AC_MSG_ERROR([unable to find the dlopen()])
2162 ])
2163
2164 AC_CHECK_HEADERS([link.h])
2165
2166 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2167   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2168 #include <stdlib.h>
2169 #ifdef HAVE_LINK_H
2170 #include <link.h>
2171 #endif
2172 #include <dlfcn.h>
2173 ]], [[
2174   char origin[1];
2175   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2176 ]])], [
2177     frr_cv_rtld_di_origin=yes
2178   ], [
2179     frr_cv_rtld_di_origin=no
2180   ])
2181 ])
2182 if test "$frr_cv_rtld_di_origin" = "yes"; then
2183   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2184 fi
2185
2186 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2187   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2188 #include <stdlib.h>
2189 #ifdef HAVE_LINK_H
2190 #include <link.h>
2191 #endif
2192 #include <dlfcn.h>
2193 ]], [[
2194   struct link_map *lm = NULL;
2195   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2196 ]])], [
2197     frr_cv_rtld_di_linkmap=yes
2198   ], [
2199     frr_cv_rtld_di_linkmap=no
2200   ])
2201 ])
2202 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2203   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2204 fi
2205
2206 LIBDL="$LIBS"
2207 LIBDL="${LIBDL%$LIBS_save}"
2208 LIBDL="${LIBDL#$LIBS_save}"
2209 AC_SUBST([LIBDL])
2210 LIBS="$LIBS_save"
2211 unset LIBS_save
2212
2213 dnl ##########################################################################
2214 dnl test "$enable_clippy_only" != "yes"
2215 fi
2216 dnl END OF LARGE if block
2217 dnl ##########################################################################
2218
2219 dnl ---------------------------
2220 dnl sockaddr and netinet checks
2221 dnl ---------------------------
2222 AC_CHECK_TYPES([
2223         struct sockaddr_dl,
2224         struct vifctl, struct mfcctl, struct sioc_sg_req,
2225         vifi_t, struct sioc_vif_req, struct igmpmsg,
2226         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2227         struct nd_opt_adv_interval,
2228         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2229         struct nd_opt_rdnss, struct nd_opt_dnssl],
2230         [], [], FRR_INCLUDES)
2231
2232 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2233         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2234         struct sockaddr_dl.sdl_len,
2235         struct if6_aliasreq.ifra_lifetime,
2236         struct nd_opt_adv_interval.nd_opt_ai_type],
2237         [], [], FRR_INCLUDES)
2238
2239 dnl ---------------------------
2240 dnl IRDP/pktinfo/icmphdr checks
2241 dnl ---------------------------
2242
2243 AC_CHECK_TYPES([struct in_pktinfo], [
2244   AC_CHECK_TYPES([struct icmphdr], [
2245     IRDP=true
2246   ], [
2247     IRDP=false
2248   ], [FRR_INCLUDES])
2249 ], [
2250   IRDP=false
2251 ], [FRR_INCLUDES])
2252
2253 case "${enable_irdp}" in
2254 yes)
2255   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2256   ;;
2257 no)
2258   IRDP=false
2259   ;;
2260 esac
2261
2262
2263 dnl -----------------------
2264 dnl checking for IP_PKTINFO
2265 dnl -----------------------
2266 AC_MSG_CHECKING([for IP_PKTINFO])
2267 AC_COMPILE_IFELSE(
2268 [ AC_LANG_PROGRAM([[
2269         #include <netdb.h>
2270    ]], [[
2271         int opt = IP_PKTINFO;
2272    ]])
2273 ],[
2274   AC_MSG_RESULT([yes])
2275   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2276 ],[
2277   AC_MSG_RESULT([no])
2278 ])
2279
2280 dnl ---------------------------
2281 dnl checking for IP_RECVDSTADDR
2282 dnl ---------------------------
2283 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2284 AC_COMPILE_IFELSE(
2285 [ AC_LANG_PROGRAM([[
2286         #include <netinet/in.h>
2287   ]], [[
2288         int opt = IP_RECVDSTADDR;
2289   ]])
2290 ],[
2291   AC_MSG_RESULT([yes])
2292   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2293 ],[
2294   AC_MSG_RESULT([no])
2295 ])
2296
2297 dnl ----------------------
2298 dnl checking for IP_RECVIF
2299 dnl ----------------------
2300 AC_MSG_CHECKING([for IP_RECVIF])
2301 AC_COMPILE_IFELSE(
2302 [ AC_LANG_PROGRAM([[
2303         #include <netinet/in.h>
2304   ]], [[
2305         int opt = IP_RECVIF;
2306   ]])
2307 ],[
2308   AC_MSG_RESULT([yes])
2309   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2310 ],[
2311   AC_MSG_RESULT([no])
2312 ])
2313
2314 dnl ----------------------
2315 dnl checking for SO_BINDANY
2316 dnl ----------------------
2317 AC_MSG_CHECKING([for SO_BINDANY])
2318 AC_COMPILE_IFELSE(
2319 [ AC_LANG_PROGRAM([[
2320         #include <sys/socket.h>
2321   ]], [[
2322         int opt = SO_BINDANY;
2323   ]])
2324 ],[
2325   AC_MSG_RESULT([yes])
2326   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2327 ],[
2328   AC_MSG_RESULT([no])
2329 ])
2330
2331 dnl ----------------------
2332 dnl checking for IP_FREEBIND
2333 dnl ----------------------
2334 AC_MSG_CHECKING([for IP_FREEBIND])
2335 AC_COMPILE_IFELSE(
2336 [ AC_LANG_PROGRAM([[
2337         #include <netinet/in.h>
2338   ]], [[
2339         int opt = IP_FREEBIND;
2340   ]])
2341 ],[
2342   AC_MSG_RESULT([yes])
2343   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2344 ],[
2345   AC_MSG_RESULT([no])
2346 ])
2347
2348 dnl --------------------------------------
2349 dnl checking for be32dec existence or not
2350 dnl --------------------------------------
2351 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2352         #ifdef HAVE_SYS_ENDIAN_H
2353         #include <sys/endian.h>
2354         #endif
2355         #ifdef HAVE_ENDIAN_H
2356         #include <endian.h>
2357         #endif
2358 ])
2359
2360 dnl --------------------------------------
2361 dnl checking for clock_time monotonic struct and call
2362 dnl --------------------------------------
2363 AC_CHECK_DECL([CLOCK_MONOTONIC],
2364         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2365          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2366 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2367
2368 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2369          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2370 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2371
2372 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2373   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2374 ])
2375
2376 dnl --------------------------------------
2377 dnl checking for flex and bison
2378 dnl --------------------------------------
2379
2380 dnl autoconf 2.69 AC_PROG_LEX has no parameters
2381 dnl autoconf 2.70 AC_PROG_LEX prints a deprecation warning without params
2382 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
2383   dnl autoconf < 2.70
2384   AC_PROG_LEX
2385 ], [
2386   dnl autoconf >= 2.70
2387   AC_PROG_LEX([noyywrap])
2388 ])
2389
2390 AC_MSG_CHECKING([version of flex])
2391 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2392 frr_ac_flex_version="${frr_ac_flex_version##* }"
2393 AC_MSG_RESULT([$frr_ac_flex_version])
2394 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2395   LEX="$SHELL $missing_dir/missing flex"
2396   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2397     AC_MSG_WARN([using pregenerated flex output files])
2398   else
2399     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2400   fi
2401   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2402   AC_SUBST([LEXLIB], [''])
2403 ])
2404
2405 AC_PROG_YACC
2406 dnl thanks GNU bison for this b*llshit...
2407 AC_MSG_CHECKING([version of bison])
2408 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2409 frr_ac_bison_version="${frr_ac_bison_version##* }"
2410 frr_ac_bison_missing="false"
2411 case "x${frr_ac_bison_version}x" in
2412   x2.7*)
2413     BISON_OPENBRACE='"'
2414     BISON_CLOSEBRACE='"'
2415     BISON_VERBOSE=''
2416     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2417     ;;
2418   x2.*|x1.*)
2419     AC_MSG_RESULT([$frr_ac_bison_version])
2420     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2421     frr_ac_bison_missing="true"
2422     ;;
2423   x)
2424     AC_MSG_RESULT([none])
2425     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2426     frr_ac_bison_missing="true"
2427     ;;
2428   x3.[012][^0-9]*)
2429     BISON_OPENBRACE='{'
2430     BISON_CLOSEBRACE='}'
2431     BISON_VERBOSE='-Dparse.error=verbose'
2432     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2433     ;;
2434   *)
2435     BISON_OPENBRACE='{'
2436     BISON_CLOSEBRACE='}'
2437     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2438     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2439     ;;
2440 esac
2441 AC_SUBST([BISON_OPENBRACE])
2442 AC_SUBST([BISON_CLOSEBRACE])
2443 AC_SUBST([BISON_VERBOSE])
2444
2445 if $frr_ac_bison_missing; then
2446   YACC="$SHELL $missing_dir/missing bison -y"
2447   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2448     AC_MSG_WARN([using pregenerated bison output files])
2449   else
2450     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2451   fi
2452 fi
2453
2454 dnl -------------------
2455 dnl capabilities checks
2456 dnl -------------------
2457 if test "$enable_capabilities" != "no"; then
2458   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2459   AC_COMPILE_IFELSE(
2460   [ AC_LANG_PROGRAM([[
2461         #include <sys/prctl.h>
2462     ]], [[
2463         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2464     ]])
2465   ],[AC_MSG_RESULT([yes])
2466      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2467      frr_ac_keepcaps="yes"
2468   ],[AC_MSG_RESULT(no)
2469   ])
2470   if test "$frr_ac_keepcaps" = "yes"; then
2471     AC_CHECK_HEADERS([sys/capability.h])
2472   fi
2473   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2474     AC_CHECK_LIB([cap], [cap_init],
2475       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2476        LIBCAP="-lcap"
2477        frr_ac_lcaps="yes"]
2478     )
2479   fi
2480   if test "$frr_ac_scaps" = "yes" \
2481        -o "$frr_ac_lcaps" = "yes"; then
2482     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2483   fi
2484
2485   case "$host_os" in
2486   linux*)
2487     if test "$enable_clippy_only" != "yes"; then
2488     if test "$frr_ac_lcaps" != "yes"; then
2489       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2490     fi
2491     fi
2492     ;;
2493   esac
2494 else
2495   case "$host_os" in
2496   linux*)
2497     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2498     ;;
2499   esac
2500 fi
2501 AC_SUBST([LIBCAP])
2502
2503 dnl ---------------------------
2504 dnl check for glibc 'backtrace'
2505 dnl ---------------------------
2506 if test "$enable_backtrace" != "no" ; then
2507   backtrace_ok=no
2508   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2509     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2510     backtrace_ok=yes
2511   ], [
2512     true
2513   ])
2514
2515   if test "$backtrace_ok" = "no"; then
2516     AC_CHECK_HEADER([unwind.h], [
2517       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2518         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2519         backtrace_ok=yes
2520       ])
2521     ])
2522   fi
2523
2524   if test "$backtrace_ok" = "no"; then
2525     AC_CHECK_HEADER([execinfo.h], [
2526       AC_SEARCH_LIBS([backtrace], [execinfo], [
2527         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2528         backtrace_ok=yes
2529       ],, [-lm])
2530     ])
2531   fi
2532
2533   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2534     dnl user explicitly requested backtrace but we failed to find support
2535     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2536   fi
2537 fi
2538
2539 dnl -----------------------------------------
2540 dnl check for malloc mallinfo struct and call
2541 dnl this must try and link using LIBS, in
2542 dnl order to check no alternative allocator
2543 dnl has been specified, which might not provide
2544 dnl mallinfo
2545 dnl -----------------------------------------
2546 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2547
2548 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2549   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2550 #ifdef HAVE_MALLOC_H
2551 #include <malloc.h>
2552 #endif
2553 #ifdef HAVE_MALLOC_NP_H
2554 #include <malloc_np.h>
2555 #endif
2556 #ifdef HAVE_MALLOC_MALLOC_H
2557 #include <malloc/malloc.h>
2558 #endif
2559 ]], [[
2560 struct mallinfo ac_x; ac_x = mallinfo ();
2561 ]])], [
2562     frr_cv_mallinfo=yes
2563   ], [
2564     frr_cv_mallinfo=no
2565   ])
2566 ])
2567 if test "$frr_cv_mallinfo" = "yes"; then
2568   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2569 fi
2570
2571 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2572   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2573 #ifdef HAVE_MALLOC_H
2574 #include <malloc.h>
2575 #endif
2576 #ifdef HAVE_MALLOC_NP_H
2577 #include <malloc_np.h>
2578 #endif
2579 #ifdef HAVE_MALLOC_MALLOC_H
2580 #include <malloc/malloc.h>
2581 #endif
2582 ]], [[
2583 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2584 ]])], [
2585     frr_cv_mallinfo2=yes
2586   ], [
2587     frr_cv_mallinfo2=no
2588   ])
2589 ])
2590 if test "$frr_cv_mallinfo2" = "yes"; then
2591   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2592 fi
2593
2594 AC_MSG_CHECKING([whether malloc_usable_size is available])
2595 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2596 #ifdef HAVE_MALLOC_H
2597 #include <malloc.h>
2598 #endif
2599 #ifdef HAVE_MALLOC_MALLOC_H
2600 #include <malloc/malloc.h>
2601 #endif
2602 ]], [[
2603 size_t ac_x; ac_x = malloc_usable_size(NULL);
2604 ]])], [
2605   AC_MSG_RESULT([yes])
2606   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2607 ], [
2608   AC_MSG_RESULT([no])
2609
2610   AC_MSG_CHECKING([whether malloc_size is available])
2611   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2612 #ifdef HAVE_MALLOC_H
2613 #include <malloc.h>
2614 #endif
2615 #ifdef HAVE_MALLOC_MALLOC_H
2616 #include <malloc/malloc.h>
2617 #endif
2618 ]], [[
2619 size_t ac_x; ac_x = malloc_size(NULL);
2620 ]])], [
2621     AC_MSG_RESULT([yes])
2622     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2623   ], [
2624     AC_MSG_RESULT([no])
2625   ])
2626 ])
2627
2628 dnl ----------
2629 dnl configure date
2630 dnl ----------
2631 dev_version=`echo $VERSION | grep dev`
2632 #don't expire deprecated code in non 'dev' branch
2633 if test "$dev_version" = ""; then
2634    CONFDATE=0
2635 else
2636    CONFDATE=`date '+%Y%m%d'`
2637 fi
2638 AC_SUBST([CONFDATE])
2639
2640 dnl ------------------------------
2641 dnl set paths for state directory
2642 dnl ------------------------------
2643 AC_MSG_CHECKING([directory to use for state file])
2644 if test "$prefix" = "NONE"; then
2645   frr_statedir_prefix="";
2646 else
2647   frr_statedir_prefix=${prefix}
2648 fi
2649 if test "$localstatedir" = '${prefix}/var'; then
2650   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2651                         ${frr_statedir_prefix}/var/adm dnl
2652                         ${frr_statedir_prefix}/etc dnl
2653                         /var/run        dnl
2654                         /var/adm        dnl
2655                         /etc            dnl
2656                         /dev/null;
2657   do
2658     test -d $FRR_STATE_DIR && break
2659   done
2660   frr_statedir=$FRR_STATE_DIR
2661 else
2662   frr_statedir=${localstatedir}
2663 fi
2664 if test "$frr_statedir" = "/dev/null"; then
2665     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2666 fi
2667 AC_MSG_RESULT([${frr_statedir}])
2668 AC_SUBST([frr_statedir])
2669
2670 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2671 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2672 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2673 AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information])
2674 AC_DEFINE_UNQUOTED([MGMTD_FE_SERVER_PATH], ["$frr_statedir/mgmtd_fe.sock"], [mgmtd frontend server socket])
2675 AC_DEFINE_UNQUOTED([MGMTD_BE_SERVER_PATH], ["$frr_statedir/mgmtd_be.sock"], [mgmtd backend server socket])
2676 AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information])
2677 AC_DEFINE_UNQUOTED([ISISD_RESTART], ["$frr_statedir%s/isid-restart.json"], [isisd restart information])
2678 AC_DEFINE_UNQUOTED([OSPF6_AUTH_SEQ_NUM_FILE], ["$frr_statedir/ospf6d-at-seq-no.dat"], [ospf6d AT Sequence number information])
2679 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2680 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2681
2682 dnl autoconf does this, but it does it too late...
2683 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2684 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2685
2686 dnl get the full path, recursing through variables...
2687 vtysh_bin="$bindir/vtysh"
2688 for I in 1 2 3 4 5 6 7 8 9 10; do
2689         eval vtysh_bin="\"$vtysh_bin\""
2690 done
2691 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2692 AC_SUBST([vtysh_bin])
2693
2694 CFG_SYSCONF="$sysconfdir"
2695 CFG_SBIN="$sbindir"
2696 CFG_BIN="$bindir"
2697 CFG_STATE="$frr_statedir"
2698 CFG_MODULE="$moduledir"
2699 CFG_YANGMODELS="$yangmodelsdir"
2700 CFG_SCRIPT="$scriptdir"
2701 for I in 1 2 3 4 5 6 7 8 9 10; do
2702         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2703         eval CFG_SBIN="\"$CFG_SBIN\""
2704         eval CFG_BIN="\"$CFG_BIN\""
2705         eval CFG_STATE="\"$CFG_STATE\""
2706         eval CFG_MODULE="\"$CFG_MODULE\""
2707         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2708         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2709 done
2710 AC_SUBST([CFG_SYSCONF])
2711 AC_SUBST([CFG_SBIN])
2712 AC_SUBST([CFG_BIN])
2713 AC_SUBST([CFG_STATE])
2714 AC_SUBST([CFG_MODULE])
2715 AC_SUBST([CFG_SCRIPT])
2716 AC_SUBST([CFG_YANGMODELS])
2717 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2718 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2719 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2720 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2721
2722 dnl various features
2723 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2724 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2725 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2726 dnl northbound
2727 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2728 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2729 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2730 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2731 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2732 dnl plugins
2733 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2734 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2735 AM_CONDITIONAL([IRDP], [$IRDP])
2736 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2737 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" != "no"])
2738 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2739
2740 dnl PCEP plugin
2741 AS_IF([test "$enable_pathd" != "no"], [
2742        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2743        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2744        ])
2745 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2746 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2747 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2748 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2749
2750 dnl daemons
2751 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2752 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2753 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2754 AM_CONDITIONAL([MGMTD], [test "$enable_mgmtd" != "no"])
2755 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2756 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2757 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2758 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2759 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2760 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2761 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2762 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2763 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2764 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2765 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2766 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2767 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2768 AM_CONDITIONAL([PIM6D], [test "$enable_pim6d" != "no"])
2769 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2770 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2771 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2772 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2773 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2774 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2775 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2776 AM_CONDITIONAL([DP_DPDK], [test "$enable_dp_dpdk" = "yes"])
2777
2778 AC_CONFIG_FILES([Makefile],[
2779         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2780         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2781 ], [
2782         PYTHON="$PYTHON"
2783         enable_dev_build="$enable_dev_build"
2784 ])
2785
2786 AC_CONFIG_FILES([
2787           config.version
2788           redhat/frr.spec
2789           alpine/APKBUILD
2790           snapcraft/snapcraft.yaml
2791           lib/version.h
2792           tests/lib/cli/test_cli.refout pkgsrc/mgmtd.sh
2793           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2794           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2795           pkgsrc/eigrpd.sh])
2796
2797 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2798 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2799 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2800 AC_CONFIG_FILES([tools/frrcommon.sh])
2801 AC_CONFIG_FILES([tools/frr.service])
2802 AC_CONFIG_FILES([tools/frr@.service])
2803
2804 AS_IF([test "$with_pkg_git_version" = "yes"], [
2805     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2806         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2807         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2808                 "${ac_abs_top_srcdir}" \
2809                 > "${dst}.tmp"
2810         test -f "$dst" \
2811                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2812                 && rm "${dst}.tmp" \
2813                 || mv "${dst}.tmp" "${dst}"
2814     ], [
2815         PERL="$PERL"
2816     ])
2817 ])
2818
2819 ## Hack, but working solution to avoid rebuilding of frr.info.
2820 ## It's already in CVS until texinfo 4.7 is more common.
2821 AC_OUTPUT
2822
2823 if test "$enable_rpath" = "yes" ; then
2824         true
2825 else
2826         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2827         sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool
2828         sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g'         libtool > libtool.sed && cat libtool.sed > libtool
2829         test -f libtool.sed && rm libtool.sed
2830 fi
2831
2832 echo "
2833 FRRouting configuration
2834 ------------------------------
2835 FRR version             : ${PACKAGE_VERSION}
2836 host operating system   : ${host_os}
2837 source code location    : ${srcdir}
2838 compiler                : ${CC}
2839 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2840 make                    : ${MAKE-make}
2841 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2842 state file directory    : ${frr_statedir}
2843 config file directory   : `eval echo \`echo ${sysconfdir}\``
2844 module directory        : ${CFG_MODULE}
2845 script directory        : ${CFG_SCRIPT}
2846 user to run as          : ${enable_user}
2847 group to run as         : ${enable_group}
2848 group for vty sockets   : ${enable_vty_group}
2849 config file mask        : ${enable_configfile_mask}
2850 log file mask           : ${enable_logfile_mask}
2851 zebra protobuf enabled  : ${enable_protobuf:-no}
2852 vici socket path        : ${vici_socket}
2853
2854 The above user and group must have read/write access to the state file
2855 directory and to the config files in the config file directory."
2856
2857 if test -n "$enable_datacenter"; then
2858   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2859 fi
2860 if test -n "$enable_time_check"; then
2861   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2862 fi
2863 if test -n "$enable_cpu_time"; then
2864   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2865 fi
2866
2867 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2868   AC_MSG_WARN([sphinx is missing but required to build documentation])
2869 fi
2870 if test "$frr_py_mod_pytest" = "false"; then
2871   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2872 fi