configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [9.0-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if necessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183
 184 dnl Some special handling for ICC later on
 185 if test "$CC" = "icc"; then
 186     cc_is_icc="yes"
 187 fi
 188
 189 PKG_PROG_PKG_CONFIG
 190
 191 dnl it's 2019, sed is sed.
 192 SED=sed
 193 AC_SUBST([SED])
 194
 195 dnl try and enable CFLAGS that are useful for FRR
 196 dnl - specifically, options to control warnings
 197
 198 AC_SUBST([AC_CFLAGS])
 199 AC_USE_SYSTEM_EXTENSIONS
 200 AC_DEFUN([AC_C_FLAG], [{
 201     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 202     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 203         AC_LANG_PUSH([C])
 204         ac_c_flag_save="$CFLAGS"
 205         CFLAGS="$CFLAGS $1"
 206         AC_COMPILE_IFELSE(
 207                 [AC_LANG_PROGRAM([[$4]])],
 208                 [
 209                         cachename=yes
 210                 ], [
 211                         cachename=no
 212                 ])
 213         CFLAGS="$ac_c_flag_save"
 214         AC_LANG_POP([C])
 215     ])
 216     if test "$cachename" = "yes"; then
 217         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 218     else
 219         :
 220         $2
 221     fi
 222     m4_popdef([cachename])
 223 }])
 224
 225 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 226         AC_LANG_PUSH([C])
 227         ac_cflags_save="$CFLAGS"
 228         ac_libs_save="$LIBS"
 229         CFLAGS="$CFLAGS $1"
 230         LIBS="$LIBS $2"
 231         AC_LINK_IFELSE(
 232                 [$3],
 233                 [
 234                         CFLAGS="$ac_cflags_save"
 235                         LIBS="$ac_libs_save"
 236                         m4_default([$5], [
 237                                 AC_MSG_RESULT([yes])
 238                         ])
 239                 ], [
 240                         CFLAGS="$ac_cflags_save"
 241                         LIBS="$ac_libs_save"
 242                         m4_default([$4], [
 243                                 AC_MSG_RESULT([no])
 244                         ])
 245                 ])
 246         AC_LANG_POP([C])
 247         }])
 248
 249 dnl ICC won't bail on unknown options without -diag-error 10006
 250 dnl need to do this first so we get useful results for the other options
 251 if test "$cc_is_icc" = "yes"; then
 252     AC_C_FLAG([-diag-error 10006])
 253 fi
 254
 255 dnl autoconf 2.69 AC_PROG_CC_C99 is "state of the art"
 256 dnl autoconf 2.70 AC_PROG_CC_C99 is deprecated and AC_PROC_CC tries to do C11
 257 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
 258   dnl autoconf < 2.70
 259   AC_PROG_CC_C99
 260
 261   dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 262   ac_cc="$CC"
 263   CC="${CC% -std=gnu99}"
 264   CC="${CC% -std=c99}"
 265
 266   AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 267 ], [
 268   dnl autoconf >= 2.70
 269   if test "$ac_cv_prog_cc_c11" = "no"; then
 270     AC_MSG_ERROR([ISO C11 compiler support (with GNU extensions) is required.])
 271   fi
 272 ])
 273
 274 dnl if the user has specified any CFLAGS, override our settings
 275 if test "$enable_gcov" = "yes"; then
 276    if test "$orig_cflags" = ""; then
 277       AC_C_FLAG([--coverage])
 278       AC_C_FLAG([-O0])
 279    fi
 280
 281    AC_LDFLAGS="${AC_LDFLAGS} --coverage"
 282 fi
 283
 284 if test "$enable_clang_coverage" = "yes"; then
 285    AC_C_FLAG([-fprofile-instr-generate], [
 286      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 287    ])
 288    AC_C_FLAG([-fcoverage-mapping], [
 289      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 290    ])
 291 fi
 292
 293 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 294
 295 if test "$enable_scripting" = "yes"; then
 296    AX_PROG_LUA([5.3], [5.4], [], [
 297      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 298    ])
 299    AX_LUA_HEADERS([], [
 300      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 301    ])
 302    PKG_CHECK_MODULES([LUA], [lua5.3], [
 303      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 304      LIBS="$LIBS $LUA_LIBS"
 305      SCRIPTING=true
 306    ], [
 307       AX_LUA_LIBS([
 308         AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 309         LIBS="$LIBS $LUA_LIB"
 310         SCRIPTING=true
 311       ], [
 312         SCRIPTING=false
 313         AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 314       ])
 315     ])
 316 fi
 317
 318 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 319 dnl sense to be overridden by the user
 320 if test "$enable_dev_build" = "yes"; then
 321    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 322    if test "$orig_cflags" = ""; then
 323       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 324       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 325       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 326    fi
 327 else
 328    if test "$orig_cflags" = ""; then
 329       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 330       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 331    fi
 332 fi
 333
 334 dnl just stick -g into LDFLAGS, if we don't have it in CFLAGS it won't do much
 335 LDFLAGS="$LDFLAGS -g"
 336
 337 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 338
 339 dnl -fms-extensions causes clang to have a built-in __wchar_t on OpenBSD,
 340 dnl which just straight up breaks compiling any code.
 341 dnl (2022-04-04 / OpenBSD 7 / clang 11.1.0)
 342 AH_VERBATIM([OpenBSD], [
 343 #ifdef __OpenBSD__
 344 #define __wchar_t __wchar_t_ignore
 345 #include <stdint.h>
 346 #undef __wchar_t
 347 #endif
 348 ])
 349
 350 dnl always want these CFLAGS
 351 AC_C_FLAG([-fms-extensions], [
 352   AC_MSG_ERROR([$CC does not support unnamed struct fields (-fms-extensions)])
 353 ])
 354 AC_C_FLAG([-fno-omit-frame-pointer])
 355 AC_C_FLAG([-funwind-tables])
 356 AC_C_FLAG([-Wall])
 357 AC_C_FLAG([-Wextra])
 358 AC_C_FLAG([-Wformat-nonliteral])
 359 AC_C_FLAG([-Wformat-security])
 360 AC_C_FLAG([-Wswitch-enum])
 361 AC_C_FLAG([-Wstrict-prototypes])
 362 AC_C_FLAG([-Wmissing-prototypes])
 363 AC_C_FLAG([-Wmissing-declarations])
 364 AC_C_FLAG([-Wpointer-arith])
 365 AC_C_FLAG([-Wbad-function-cast])
 366 AC_C_FLAG([-Wwrite-strings])
 367 AC_C_FLAG([-Wundef])
 368 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 369   AC_C_FLAG([-Wcast-qual])
 370   AC_C_FLAG([-Wmissing-noreturn])
 371   AC_C_FLAG([-Wmissing-format-attribute])
 372   AC_C_FLAG([-Wunreachable-code])
 373   AC_C_FLAG([-Wpacked])
 374   AC_C_FLAG([-Wpadded])
 375   AC_C_FLAG([-Wshadow])
 376 else
 377   AC_C_FLAG([-Wno-unused-result])
 378 fi
 379 AC_C_FLAG([-Wno-unused-parameter])
 380 AC_C_FLAG([-Wno-missing-field-initializers])
 381
 382 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 383 AC_SUBST([CXX_COMPAT_CFLAGS])
 384
 385 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 386 dnl for some reason the string consts get 'promoted' to char *,
 387 dnl triggering a const to non-const conversion warning.
 388 if test "$cc_is_icc" = "yes"; then
 389     AC_C_FLAG([-diag-disable 3179])
 390 fi
 391
 392 if test "$enable_werror" = "yes" ; then
 393   WERROR="-Werror"
 394 fi
 395 AC_SUBST([WERROR])
 396
 397 SAN_FLAGS=""
 398 if test "$enable_address_sanitizer" = "yes"; then
 399   AC_C_FLAG([-fsanitize=address], [
 400     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 401   ], [
 402     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 403   ])
 404 fi
 405 if test "$enable_thread_sanitizer" = "yes"; then
 406   AC_C_FLAG([-fsanitize=thread], [
 407     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 408   ], [
 409     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 410   ])
 411 fi
 412 if test "$enable_memory_sanitizer" = "yes"; then
 413   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 414     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 415   ], [
 416     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 417   ])
 418 fi
 419 if test "$enable_undefined_sanitizer" = "yes"; then
 420   AC_C_FLAG([-fsanitize=undefined], [
 421     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 422   ], [
 423     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 424   ])
 425 fi
 426 AC_SUBST([SAN_FLAGS])
 427
 428 dnl frr-format.so
 429 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 430   AC_C_FLAG([-fplugin=${with_frr_format}], [
 431     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 432   ],,[
 433 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 434 #error plugin not loaded
 435 #endif
 436 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 437 #error plugin too old
 438 #endif
 439   ])
 440 elif test "$with_frr_format" = "no"; then
 441   : #nothing
 442 else
 443   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 444     AC_C_FLAG([-fplugin=frr-format],[
 445       if test "$with_frr_format" = "yes"; then
 446         AC_MSG_ERROR([frr-format plugin requested but not found])
 447       fi
 448     ],,[
 449 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 450 #error plugin not loaded
 451 #endif
 452 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 453 #error plugin too old
 454 #endif
 455     ])
 456   ],,[
 457 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 458 #error plugin not loaded
 459 #endif
 460 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 461 #error plugin too old
 462 #endif
 463   ])
 464 fi
 465
 466 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 467 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 468 #include <stdio.h>
 469 int __attribute__((section("secttest"))) var = 1;
 470 extern int __start_secttest, __stop_secttest;
 471 ]], [[
 472   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 473   printf("%p %p %p\n", a, b, c);
 474 ]])], [
 475   AC_MSG_RESULT(yes)
 476   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 477 ], [
 478   AC_MSG_RESULT(no)
 479 ])
 480
 481 dnl ----------
 482 dnl Essentials
 483 dnl ----------
 484
 485 AX_PTHREAD([
 486   CC="$PTHREAD_CC"
 487   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 488   LIBS="$PTHREAD_LIBS $LIBS"
 489 ], [
 490   AC_MSG_FAILURE([This FRR version needs pthreads])
 491 ])
 492
 493 orig_cflags="$CFLAGS"
 494 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 495
 496 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 497                 [frr_cv_pthread_condattr_setclock=yes],
 498                 [frr_cv_pthread_condattr_setclock=no])
 499 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 500   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 501 fi
 502
 503 AC_CHECK_HEADERS([pthread_np.h],,, [
 504 #include <pthread.h>
 505 ])
 506 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 507
 508 CFLAGS="$orig_cflags"
 509
 510 dnl --------------
 511 dnl Check programs
 512 dnl --------------
 513 AC_PROG_INSTALL
 514 AC_PROG_LN_S
 515 AC_CHECK_TOOL([AR], [ar])
 516
 517 dnl -------
 518 dnl libtool
 519 dnl -------
 520 AC_ARG_ENABLE([static-bin],
 521   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 522 LT_INIT
 523 _LT_CONFIG_LIBTOOL([
 524   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 525     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 526 dnl the -i option is not POSIX sed and the BSDs implement it differently
 527 dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact
 528   sed -e 's%func_warning "relinking%true #\0%'                   libtool > libtool.sed && cat libtool.sed > libtool
 529   sed -e 's%func_warning "remember to run%true #\0%'             libtool > libtool.sed && cat libtool.sed > libtool
 530   sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool
 531   test -f libtool.sed && rm libtool.sed
 532 ])
 533 if test "$enable_static_bin" = "yes"; then
 534   AC_LDFLAGS_EXEC="-static"
 535   if test "$enable_static" != "yes"; then
 536     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 537   fi
 538 fi
 539 if test "$enable_shared" != "yes"; then
 540   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 541 fi
 542 AC_SUBST([AC_LDFLAGS])
 543 AC_SUBST([AC_LDFLAGS_EXEC])
 544 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 545
 546 dnl libtool, the repository of all knowledge related linkers, is too stupid to
 547 dnl correctly tell the linker how to build modules.
 548 if test -z "$module_cmds"; then
 549   module_cmds="`echo \"$archive_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 550 fi
 551 if test -z "$module_expsym_cmds"; then
 552   module_expsym_cmds="`echo \"$archive_expsym_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 553 fi
 554
 555 AC_ARG_ENABLE([rpath],
 556   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 557   [],
 558   [enable_rpath=yes])
 559
 560 dnl $AR and $RANLIB are set by LT_INIT above
 561 AC_MSG_CHECKING([whether $AR supports D option])
 562 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 563   AC_MSG_RESULT([yes])
 564   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 565   ARFLAGS="crD"
 566   AR_FLAGS="crD"
 567 else
 568   AC_MSG_RESULT([no])
 569   ARFLAGS="cru"
 570   AR_FLAGS="cru"
 571 fi
 572 AC_SUBST([ARFLAGS])
 573 AC_SUBST([AR_FLAGS])
 574
 575 AC_MSG_CHECKING([whether $RANLIB supports D option])
 576 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 577   if grep -q -- '-D' conftest.err; then
 578     AC_MSG_RESULT([no])
 579   else
 580     AC_MSG_RESULT([yes])
 581     RANLIB="$RANLIB -D"
 582   fi
 583 else
 584   AC_MSG_RESULT([no])
 585 fi
 586 AC_SUBST([RANLIB])
 587
 588 test -f conftest.err && rm conftest.err
 589 test -f conftest.a && rm conftest.a
 590
 591 dnl ----------------------
 592 dnl Packages configuration
 593 dnl ----------------------
 594 if test -f config.version; then
 595   . ./config.version
 596 elif test -f "${srcdir}/config.version"; then
 597   . "${srcdir}/config.version"
 598 fi
 599 AC_ARG_WITH([pkg-extra-version],
 600   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 601   if test "$withval" = "no"; then
 602     EXTRAVERSION=
 603   else
 604     EXTRAVERSION=$withval
 605   fi
 606 ], [])
 607 AC_ARG_WITH([pkg-git-version],
 608         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 609         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 610 AC_ARG_WITH([clippy],
 611   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 612 AC_ARG_WITH([vtysh_pager],
 613         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 614         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 615 AC_ARG_ENABLE([vtysh],
 616   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 617 AC_ARG_ENABLE([doc],
 618   AS_HELP_STRING([--disable-doc], [do not build docs]))
 619 AC_ARG_ENABLE([doc-html],
 620   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 621 AC_ARG_ENABLE([zebra],
 622   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 623 AC_ARG_ENABLE([bgpd],
 624   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 625 AC_ARG_ENABLE([mgmtd],
 626   AS_HELP_STRING([--disable-mgmtd], [do not build mgmtd]))
 627 AC_ARG_ENABLE([mgmtd_local_validations],
 628   AS_HELP_STRING([--enable-mgmtd-local-validations], [dev: unimplemented local validation]))
 629 AC_ARG_ENABLE([ripd],
 630   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 631 AC_ARG_ENABLE([ripngd],
 632   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 633 AC_ARG_ENABLE([ospfd],
 634   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 635 AC_ARG_ENABLE([ospf6d],
 636   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 637 AC_ARG_ENABLE([ldpd],
 638   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 639 AC_ARG_ENABLE([nhrpd],
 640   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 641 AC_ARG_ENABLE([eigrpd],
 642   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 643 AC_ARG_ENABLE([babeld],
 644   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 645 AC_ARG_ENABLE([watchfrr],
 646   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 647 AC_ARG_ENABLE([isisd],
 648   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 649 AC_ARG_ENABLE([pimd],
 650   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 651 AC_ARG_ENABLE([pim6d],
 652   AS_HELP_STRING([--disable-pim6d], [do not build pim6d]))
 653 AC_ARG_ENABLE([pbrd],
 654   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 655 AC_ARG_ENABLE([sharpd],
 656   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 657 AC_ARG_ENABLE([staticd],
 658   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 659 AC_ARG_ENABLE([fabricd],
 660   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 661 AC_ARG_ENABLE([vrrpd],
 662   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 663 AC_ARG_ENABLE([pathd],
 664   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 665 AC_ARG_ENABLE([bgp-announce],
 666   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 667 AC_ARG_ENABLE([bgp-vnc],
 668   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 669 AC_ARG_ENABLE([bgp-bmp],
 670   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 671 AC_ARG_ENABLE([snmp],
 672   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 673 AC_ARG_ENABLE([config_rollbacks],
 674   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 675 AC_ARG_ENABLE([confd],
 676   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 677 AC_ARG_ENABLE([sysrepo],
 678   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 679 AC_ARG_ENABLE([grpc],
 680   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 681 AC_ARG_ENABLE([zeromq],
 682   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 683 AC_ARG_ENABLE([lttng],
 684   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 685 AC_ARG_ENABLE([usdt],
 686   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 687 AC_ARG_WITH([libpam],
 688   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 689 AC_ARG_ENABLE([ospfapi],
 690   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 691 AC_ARG_ENABLE([ospfclient],
 692   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 693                           (this is the default if --disable-ospfapi is set)]))
 694 AC_ARG_ENABLE([multipath],
 695   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 696 AC_ARG_WITH([service_timeout],
 697   AS_HELP_STRING([--with-service-timeout=ARG], [set service timeout value (2 minutes by default), ARG must be digit]))
 698 AC_ARG_ENABLE([user],
 699   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 700 AC_ARG_ENABLE([group],
 701   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 702 AC_ARG_ENABLE([vty_group],
 703   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 704 AC_ARG_ENABLE([configfile_mask],
 705   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 706 AC_ARG_ENABLE([logfile_mask],
 707   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 708 AC_ARG_ENABLE([shell_access],
 709   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 710 AC_ARG_ENABLE([realms],
 711   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 712 AC_ARG_ENABLE([rtadv],
 713   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 714 AC_ARG_ENABLE([irdp],
 715   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 716 AC_ARG_ENABLE([capabilities],
 717   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 718 AC_ARG_ENABLE([gcc_ultra_verbose],
 719   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 720 AC_ARG_ENABLE([backtrace],
 721   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 722 AC_ARG_ENABLE([time-check],
 723   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 724 AC_ARG_ENABLE([cpu-time],
 725   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 726 AC_ARG_ENABLE([pcreposix],
 727   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 728 AC_ARG_ENABLE([pcre2posix],
 729   AS_HELP_STRING([--enable-pcre2posix], [enable using PCRE2 Posix libs for regex functions]))
 730 AC_ARG_ENABLE([fpm],
 731   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 732 AC_ARG_ENABLE([werror],
 733   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 734 AC_ARG_ENABLE([cumulus],
 735   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 736 AC_ARG_ENABLE([datacenter],
 737   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 738 AC_ARG_ENABLE([rr-semantics],
 739   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 740 AC_ARG_ENABLE([protobuf],
 741   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 742 AC_ARG_ENABLE([oldvpn_commands],
 743   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 744 AC_ARG_ENABLE([rpki],
 745   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 746 AC_ARG_ENABLE([clippy-only],
 747   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 748 AC_ARG_ENABLE([numeric_version],
 749   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 750 AC_ARG_ENABLE([gcov],
 751   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 752 AC_ARG_ENABLE([clang_coverage],
 753   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 754 AC_ARG_ENABLE([bfdd],
 755   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 756 AC_ARG_ENABLE([address-sanitizer],
 757   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 758 AC_ARG_ENABLE([thread-sanitizer],
 759   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 760 AC_ARG_ENABLE([memory-sanitizer],
 761   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 762 AC_ARG_ENABLE([undefined-sanitizer],
 763   AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 764 AC_ARG_WITH([crypto],
 765   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 766 AC_ARG_WITH([frr-format],
 767   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 768
 769 AC_ARG_ENABLE([version-build-config],
 770   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 771
 772 #if openssl, else use the internal
 773 AS_IF([test "$with_crypto" = "openssl"], [
 774 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 775 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 776   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 777 else
 778   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 779 fi
 780 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 781 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 782 )
 783
 784 AS_IF([test "$enable_clippy_only" != "yes"], [
 785 AC_CHECK_HEADERS([json-c/json.h])
 786 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 787 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 788   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 789   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 790       AC_MSG_ERROR([libjson is needed to compile])
 791   fi
 792 fi
 793 ])
 794
 795 AC_ARG_ENABLE([dev_build],
 796     AS_HELP_STRING([--enable-dev-build], [build for development]))
 797
 798 AC_ARG_ENABLE([scripting],
 799     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 800
 801 AC_ARG_ENABLE([netlink-debug],
 802   AS_HELP_STRING([--disable-netlink-debug], [don't pretty print netlink debug messages]))
 803
 804 if test "$enable_netlink_debug" != "no" ; then
 805   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 806 fi
 807
 808 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 809
 810 if test "$enable_time_check" != "no" ; then
 811   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 812     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 813   else
 814     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 815   fi
 816 fi
 817
 818 case "${enable_cpu_time}" in
 819   "no")
 820   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 821   ;;
 822   "*")
 823   ;;
 824 esac
 825
 826 if test "$enable_rr_semantics" != "no" ; then
 827   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 828 fi
 829
 830 if test "$enable_datacenter" = "yes" ; then
 831   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 832   DFLT_NAME="datacenter"
 833 else
 834   DFLT_NAME="traditional"
 835 fi
 836
 837 if test "$enable_cumulus" = "yes" ; then
 838   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 839 fi
 840
 841 AC_SUBST([DFLT_NAME])
 842 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 843
 844 if test "$enable_shell_access" = "yes"; then
 845    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 846 fi
 847
 848 #
 849 # Python for clippy
 850 #
 851
 852 AS_IF([test "$host" = "$build"], [
 853   AM_PATH_PYTHON([3])
 854   AC_CHECK_HEADER([gelf.h], [], [
 855     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 856   ])
 857
 858   LIBS_save="$LIBS"
 859   AC_CHECK_LIB([elf], [elf_memory], [], [
 860     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 861   ])
 862
 863   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 864     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 865   ])
 866   AC_CHECK_LIB([elf], [gelf_getnote], [
 867     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 868   ])
 869   LIBS="$LIBS_save"
 870   unset LIBS_save
 871
 872   FRR_PYTHON_DEV
 873 ], [
 874   FRR_PYTHON
 875 ])
 876
 877 FRR_PYTHON_MODULES([pytest])
 878
 879 if test "$enable_doc" != "no"; then
 880   FRR_PYTHON_MODULES([sphinx], , [
 881     if test "$enable_doc" = "yes"; then
 882       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 883     fi
 884   ])
 885 fi
 886 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 887 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 888
 889 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 890   PYSPHINX="-m sphinx"
 891 ], [
 892   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 893 ])
 894 AC_SUBST([PYSPHINX])
 895
 896 #
 897 # Logic for old vpn commands support.
 898 #
 899 if test "$enable_oldvpn_commands" = "yes"; then
 900    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 901 fi
 902
 903 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 904 if test "$enable_rtadv" != "no"; then
 905   AC_MSG_RESULT([yes])
 906   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 907 else
 908   AC_MSG_RESULT([no])
 909 fi
 910
 911 if test "$enable_user" = "no"; then
 912   enable_user=""
 913 else
 914   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 915     enable_user="frr"
 916   fi
 917   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 918 fi
 919
 920 if test "$enable_group" = "no"; then
 921   enable_group=""
 922 else
 923   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 924     enable_group="frr"
 925   fi
 926   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 927 fi
 928
 929 if test "$enable_vty_group" = "yes" ; then
 930   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 931 elif test "$enable_vty_group" != ""; then
 932   if test "$enable_vty_group" != "no"; then
 933     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 934   fi
 935 fi
 936 AC_SUBST([enable_user])
 937 AC_SUBST([enable_group])
 938 AC_SUBST([enable_vty_group])
 939
 940 enable_configfile_mask=${enable_configfile_mask:-0600}
 941 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 942 AC_SUBST([enable_configfile_mask])
 943
 944 enable_logfile_mask=${enable_logfile_mask:-0600}
 945 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 946
 947 MPATH_NUM=16
 948
 949 case "${enable_multipath}" in
 950   0)
 951     MPATH_NUM=64
 952     ;;
 953   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 954     MPATH_NUM="${enable_multipath}"
 955     ;;
 956   "")
 957     ;;
 958   *)
 959     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 960     ;;
 961 esac
 962
 963 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 964
 965 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 966
 967
 968 TIMEOUT_MIN=2
 969 case "${with_service_timeout}" in
 970   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 971     TIMEOUT_MIN="${with_service_timeout}"
 972     ;;
 973   0|"")
 974     ;;
 975   *)
 976     AC_MSG_FAILURE([Please specify digit for timeout ARG])
 977     ;;
 978 esac
 979 AC_SUBST([TIMEOUT_MIN])
 980
 981 dnl --------------------
 982 dnl Enable code coverage
 983 dnl --------------------
 984 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 985
 986 dnl ------------------------------------
 987 dnl Alpine only accepts numeric versions
 988 dnl ------------------------------------
 989 if test "$enable_numeric_version" != "" ; then
 990   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 991   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 992 fi
 993
 994 dnl -----------------------------------
 995 dnl Add extra version string to package
 996 dnl name, string and version fields.
 997 dnl -----------------------------------
 998 if test "$EXTRAVERSION" != "" ; then
 999   VERSION="${VERSION}${EXTRAVERSION}"
1000   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
1001   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
1002   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
1003 fi
1004 AC_SUBST([EXTRAVERSION])
1005
1006 if test "$with_pkg_git_version" = "yes"; then
1007         if test -e "${srcdir}/.git"; then
1008                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
1009         else    with_pkg_git_version="no"
1010                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
1011         fi
1012 fi
1013 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
1014
1015 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
1016 if test "$OBJCOPY" != ":"; then
1017   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
1018     frr_cv_interp=""
1019     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
1020       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
1021         frr_cv_interp="`xargs -0 echo < conftest.interp`"
1022       fi
1023       test -f conftest.interp && rm conftest.interp
1024     ])
1025   ])
1026 fi
1027 if test -n "$frr_cv_interp"; then
1028   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
1029 fi
1030
1031 dnl -------------------------
1032 dnl Check other header files.
1033 dnl -------------------------
1034 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
1035         linux/version.h asm/types.h endian.h sys/endian.h])
1036
1037 ac_stdatomic_ok=false
1038 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
1039 AC_CHECK_HEADER([stdatomic.h],[
1040
1041   AC_MSG_CHECKING([whether _Atomic qualifier works])
1042   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1043 #include <stdatomic.h>
1044 int main(int argc, char **argv) {
1045   _Atomic int i = 0;
1046   return i;
1047 }
1048 ]])], [
1049     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
1050     AC_MSG_RESULT([yes])
1051     ac_stdatomic_ok=true
1052   ], [
1053     AC_MSG_RESULT([no])
1054   ])
1055 ])
1056
1057 AS_IF([$ac_stdatomic_ok], [true], [
1058   AC_MSG_CHECKING([for __atomic_* builtins])
1059   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1060 int main(int argc, char **argv) {
1061   volatile int i = 1;
1062   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1063   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1064 }
1065 ]])], [
1066     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1067     AC_MSG_RESULT([yes])
1068   ], [
1069     AC_MSG_RESULT([no])
1070
1071     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1072     AC_MSG_CHECKING([for __sync_* builtins])
1073     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1074 int main(int argc, char **argv) {
1075   volatile int i = 1;
1076   __sync_fetch_and_sub (&i, 1);
1077   return __sync_val_compare_and_swap (&i, 0, 1);
1078 }
1079 ]])], [
1080       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1081       AC_MSG_RESULT([yes])
1082
1083       AC_MSG_CHECKING([for __sync_swap builtin])
1084       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1085 int main(int argc, char **argv) {
1086   volatile int i = 1;
1087   return __sync_swap (&i, 2);
1088 }
1089 ]])], [
1090         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1091         AC_MSG_RESULT([yes])
1092       ], [
1093         AC_MSG_RESULT([no])
1094       ])
1095
1096     ], [
1097       AC_MSG_RESULT([no])
1098       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1099     ])
1100   ])
1101 ])
1102
1103 needsync=true
1104
1105 AS_IF([$needsync], [
1106   dnl Linux
1107   AC_MSG_CHECKING([for Linux futex() support])
1108   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1109 #ifndef _GNU_SOURCE
1110 #define _GNU_SOURCE
1111 #endif
1112 #include <unistd.h>
1113 #include <limits.h>
1114 #include <sys/time.h>
1115 #include <sys/syscall.h>
1116 #include <linux/futex.h>
1117
1118 int main(void);
1119 ],
1120 [
1121 {
1122   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1123 }
1124 ])], [
1125     AC_MSG_RESULT([yes])
1126     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1127     needsync=false
1128   ], [
1129     AC_MSG_RESULT([no])
1130   ])
1131 ])
1132
1133 AS_IF([$needsync], [
1134   dnl FreeBSD
1135   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1136   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1137 #include <errno.h>
1138 #include <stdlib.h>
1139 #include <sys/types.h>
1140 #include <sys/umtx.h>
1141 int main(void);
1142 ],
1143 [
1144 {
1145   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1146 }
1147 ])], [
1148     AC_MSG_RESULT([yes])
1149     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1150     needsync=false
1151   ], [
1152     AC_MSG_RESULT([no])
1153   ])
1154 ])
1155
1156 AS_IF([$needsync], [
1157   dnl OpenBSD patch (not upstream at the time of writing this)
1158   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1159   AC_MSG_CHECKING([for OpenBSD futex() support])
1160   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1161 #include <sys/futex.h>
1162 int main(void);
1163 ],
1164 [
1165 {
1166   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1167 }
1168 ])], [
1169     AC_MSG_RESULT([yes])
1170     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1171     needsync=false
1172   ], [
1173     AC_MSG_RESULT([no])
1174   ])
1175 ])
1176
1177 dnl Utility macro to avoid retyping includes all the time
1178 m4_define([FRR_INCLUDES],
1179 [#ifdef SUNOS_5
1180 #define _POSIX_C_SOURCE 200809L
1181 #define __EXTENSIONS__
1182 #endif
1183 #include <stdio.h>
1184 #include <stdlib.h>
1185 #include <stddef.h>
1186 #include <sys/types.h>
1187 /* sys/conf.h depends on param.h on FBSD at least */
1188 #include <sys/param.h>
1189 /* Required for MAXSIG */
1190 #include <signal.h>
1191 #include <sys/socket.h>
1192 #ifdef __APPLE__
1193 # define __APPLE_USE_RFC_3542
1194 #endif
1195 #include <netinet/in.h>
1196 #include <sys/time.h>
1197 #include <time.h>
1198 #include <net/if.h>
1199 ])dnl
1200
1201 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1202 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1203 dnl an additional round for it.
1204
1205 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1206
1207 m4_define([FRR_INCLUDES],
1208 FRR_INCLUDES
1209 [#ifdef HAVE_NET_IF_VAR_H
1210 # include <net/if_var.h>
1211 #endif
1212 ])dnl
1213
1214 AC_CHECK_HEADERS([netinet/in_var.h \
1215         net/if_dl.h net/netopt.h \
1216         inet/nd.h netinet/ip_icmp.h \
1217         sys/sysctl.h sys/sockio.h sys/conf.h],
1218         [], [], [FRR_INCLUDES])
1219
1220 AC_CHECK_HEADERS([ucontext.h], [], [],
1221 [#ifndef __USE_GNU
1222 #define __USE_GNU
1223 #endif /* __USE_GNU */
1224 FRR_INCLUDES
1225 ])
1226
1227 m4_define([UCONTEXT_INCLUDES],
1228 [#include <ucontext.h>])dnl
1229
1230 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1231   [], [], [UCONTEXT_INCLUDES])
1232 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1233   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1234    [], [], [UCONTEXT_INCLUDES])],
1235   [], [UCONTEXT_INCLUDES])
1236 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1237   [], [], [UCONTEXT_INCLUDES])
1238
1239 m4_define([FRR_INCLUDES],
1240 FRR_INCLUDES
1241 [
1242 #include <sys/un.h>
1243 #include <netinet/in_systm.h>
1244 #ifdef HAVE_NETINET_IN_VAR_H
1245 # include <netinet/in_var.h>
1246 #endif
1247 #ifdef HAVE_NET_IF_DL_H
1248 # include <net/if_dl.h>
1249 #endif
1250 #ifdef HAVE_NET_NETOPT_H
1251 # include <net/netopt.h>
1252 #endif
1253 #include <net/route.h>
1254 #ifdef HAVE_INET_ND_H
1255 # include <inet/nd.h>
1256 #endif
1257 #include <arpa/inet.h>
1258 /* Required for IDRP */
1259 #ifdef HAVE_NETINET_IP_ICMP_H
1260 # include <netinet/ip_icmp.h>
1261 #endif
1262 ])dnl
1263
1264 dnl V6 headers are checked below, after we check for v6
1265
1266 is_linux=false
1267
1268 AC_MSG_CHECKING([which operating system interface to use])
1269 case "$host_os" in
1270   sunos* | solaris2*)
1271     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1272     ;;
1273   linux*)
1274     AC_MSG_RESULT([Linux])
1275
1276     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1277     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1278     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1279
1280     dnl Linux has a compilation problem with mixing
1281     dnl netinet/in.h and linux/in6.h they are not
1282     dnl compatible.  There has been discussion on
1283     dnl how to fix it but no real progress on implementation
1284     dnl when they fix it, remove this
1285     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1286
1287     is_linux=true
1288     ;;
1289   openbsd*)
1290     AC_MSG_RESULT([OpenBSD])
1291
1292     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1293     AC_DEFINE([KAME], [1], [KAME IPv6])
1294     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1295     ;;
1296   *)
1297     AC_MSG_RESULT([BSD])
1298
1299     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1300     AC_DEFINE([KAME], [1], [KAME IPv6])
1301     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1302     ;;
1303 esac
1304 AM_CONDITIONAL([LINUX], [${is_linux}])
1305
1306 AC_SYS_LARGEFILE
1307
1308 dnl ------------------------
1309 dnl Integrated REALMS option
1310 dnl ------------------------
1311 if test "$enable_realms" = "yes"; then
1312     case "$host_os" in
1313       linux*)
1314        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1315        ;;
1316       *)
1317        echo "Sorry, only Linux has REALMS support"
1318        exit 1
1319        ;;
1320     esac
1321 fi
1322
1323 dnl ---------------
1324 dnl other functions
1325 dnl ---------------
1326 AC_CHECK_FUNCS([ \
1327         strlcat strlcpy \
1328         getgrouplist \
1329         openat \
1330         unlinkat \
1331         posix_fallocate \
1332         sendmmsg \
1333         explicit_bzero \
1334         ])
1335
1336 AC_CHECK_MEMBERS([struct mmsghdr.msg_hdr], [], [], FRR_INCLUDES)
1337
1338 dnl ##########################################################################
1339 dnl LARGE if block spans a lot of "configure"!
1340 if test "$enable_clippy_only" != "yes"; then
1341 dnl ##########################################################################
1342
1343 #
1344 # Logic for protobuf support.
1345 #
1346 PROTO3=false
1347 # Enable Protobuf by default at all times.
1348 # Check for protoc & protoc-c
1349 # protoc is not required, it's only for a "be nice" helper target
1350 AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1351
1352 AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1353 if test "$PROTOC_C" = "/bin/false"; then
1354   AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1355 fi
1356
1357 PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 1.1.0],, [
1358   AC_MSG_FAILURE([minimum version (1.1.0) of libprotobuf-c not found.  Install minimum required version of protobuf-c.])
1359 ])
1360
1361 if test "$enable_protobuf3" = "yes"; then
1362   PROTO3=true
1363   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1364                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1365                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1366                                             [1], [Have Protobuf version 3]),
1367                                   [PROTO3=false],
1368                                   [#include <google/protobuf-c/protobuf-c.h>])],
1369                   [PROTO3=false && AC_MSG_FAILURE([protobuf3 requested but protobuf-c.h not found.  Install protobuf-c.])])
1370 fi
1371
1372 AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1373 #
1374 # End of logic for protobuf support.
1375 #
1376
1377
1378 dnl ---------------------
1379 dnl Integrated VTY option
1380 dnl ---------------------
1381 case "${enable_vtysh}" in
1382 "no")
1383   VTYSH="";;
1384 *)
1385   VTYSH="vtysh";
1386   AC_DEFINE([VTYSH], [1], [VTY shell])
1387
1388   prev_libs="$LIBS"
1389   AC_CHECK_LIB([readline], [readline], [
1390     LIBREADLINE="-lreadline"
1391   ], [
1392     dnl readline failed - it might be incorrectly linked and missing its
1393     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1394     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1395       LIBREADLINE="$ac_cv_search_tputs"
1396     ], [
1397       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1398     ])
1399
1400     dnl re-try with the lib we found above
1401     unset ac_cv_lib_readline_main
1402     AC_CHECK_LIB([readline], [main], [
1403       LIBREADLINE="-lreadline $LIBREADLINE"
1404     ], [
1405       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1406     ], [$LIBREADLINE])
1407   ], [])
1408   LIBS="$LIBS -lreadline"
1409   AC_CHECK_FUNCS([rl_clear_visible_line])
1410   LIBS="$prev_libs"
1411
1412   AC_CHECK_HEADER([readline/history.h])
1413   if test "$ac_cv_header_readline_history_h" = "no"; then
1414     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1415   fi
1416   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1417   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1418     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1419   fi
1420   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1421   if test "$frr_cv_append_history" = "yes"; then
1422     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1423   fi
1424   ;;
1425 esac
1426 AC_SUBST([LIBREADLINE])
1427
1428 dnl ----------
1429 dnl PAM module
1430 dnl
1431 dnl FRR detects the PAM library it is built against by checking for a
1432 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1433 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1434 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1435 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1436 dnl of OpenPAM.
1437 dnl ----------
1438 if test "$with_libpam" = "yes"; then
1439   AC_CHECK_HEADER([security/pam_misc.h],
1440     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1441      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1442      pam_conv_func="misc_conv"
1443     ],
1444     [], FRR_INCLUDES)
1445   AC_CHECK_HEADER([security/openpam.h],
1446     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1447      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1448      pam_conv_func="openpam_ttyconv"
1449     ],
1450     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1451   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1452     AC_MSG_WARN([*** pam support will not be built ***])
1453     with_libpam="no"
1454   fi
1455 fi
1456
1457 if test "$with_libpam" = "yes"; then
1458 dnl took this test from proftpds configure.in and suited to our needs
1459 dnl -------------------------------------------------------------------------
1460 dnl
1461 dnl This next check looks funky due to a linker problem with some versions
1462 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1463 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1464 dnl with RedHat 6.2 and Debian 2.2 or better.
1465 AC_CHECK_LIB([pam], [pam_start],
1466   [AC_CHECK_LIB([pam], [$pam_conv_func],
1467     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1468      LIBPAM="-lpam"],
1469     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1470      LIBPAM="-lpam -lpam_misc"]
1471     )
1472   ],
1473
1474   [AC_CHECK_LIB([pam], [pam_end],
1475     [AC_CHECK_LIB([pam], [$pam_conv_func],
1476       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1477        LIBPAM="-lpam -ldl"],
1478       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1479        LIBPAM="-lpam -ldl -lpam_misc"]
1480      )
1481   ],AC_MSG_WARN([*** pam support will not be built ***]),
1482   [-ldl])
1483   ]
1484 )
1485 fi
1486 AC_SUBST([LIBPAM])
1487
1488 dnl -------------------------------
1489 dnl bgpd needs pow() and hence libm
1490 dnl -------------------------------
1491 TMPLIBS="$LIBS"
1492 LIBS=""
1493 AC_SEARCH_LIBS([pow], [m], [
1494   LIBM="$LIBS"
1495 ], [
1496   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1497 ])
1498 LIBS="$TMPLIBS"
1499 AC_SUBST([LIBM])
1500
1501 AC_CHECK_FUNCS([ppoll], [
1502   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1503 ])
1504 AC_CHECK_FUNCS([pollts], [
1505   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1506 ])
1507
1508 AC_CHECK_HEADER([asm-generic/unistd.h],
1509                 [AC_CHECK_DECL(__NR_setns,
1510                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1511                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1512                                ])
1513                  AC_CHECK_FUNCS([setns])]
1514                )
1515
1516 dnl --------------------------
1517 dnl Determine IS-IS I/O method
1518 dnl --------------------------
1519 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1520 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1521 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1522 AC_CHECK_HEADER([net/bpf.h])
1523 AC_CHECK_HEADER([sys/dlpi.h])
1524 AC_MSG_CHECKING([zebra IS-IS I/O method])
1525
1526 case "$host_os" in
1527   linux*)
1528     AC_MSG_RESULT([pfpacket])
1529     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1530     ;;
1531   *)
1532     if test "$ac_cv_header_net_bpf_h" = "no"; then
1533       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1534         AC_MSG_RESULT([none])
1535         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1536           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1537         fi
1538         AC_MSG_WARN([*** IS-IS support will not be built ***])
1539         enable_isisd="no"
1540         enable_fabricd="no"
1541       else
1542         AC_MSG_RESULT([DLPI])
1543       fi
1544       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1545     else
1546       AC_MSG_RESULT([BPF])
1547       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1548     fi
1549     ;;
1550 esac
1551 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1552
1553 dnl ---------------------------------------------------------------
1554 dnl figure out how to specify an interface in multicast sockets API
1555 dnl ---------------------------------------------------------------
1556 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1557
1558 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1559         #include <sys/socket.h>
1560         #include <netinet/in.h>
1561         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1562         #include <linux/types.h>
1563 ])
1564
1565 AC_CHECK_HEADERS([linux/mroute6.h], [], [],[
1566         #include <sys/socket.h>
1567         #include <netinet/in.h>
1568         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1569         #include <linux/types.h>
1570 ])
1571
1572 m4_define([FRR_INCLUDES],
1573 FRR_INCLUDES
1574 [#ifdef HAVE_LINUX_MROUTE_H
1575 # include <linux/mroute.h>
1576 #endif
1577 ])dnl
1578
1579 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1580         #include <sys/socket.h>
1581         #include <sys/types.h>
1582         #include <netinet/in.h>
1583         #include <net/route.h>
1584 ])
1585
1586 m4_define([FRR_INCLUDES],
1587 FRR_INCLUDES
1588 [#ifdef HAVE_NETINET_IP_MROUTE_H
1589 # include <netinet/ip_mroute.h>
1590 #endif
1591 ])dnl
1592
1593 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1594 AC_COMPILE_IFELSE(
1595 [ AC_LANG_PROGRAM([[
1596       #include <sys/types.h>
1597       #include <netinet/in.h>
1598   ]], [[
1599       struct group_req gr;
1600       int sock;
1601       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1602   ]])
1603 ],[
1604   AC_MSG_RESULT([yes])
1605   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1606 ],[
1607   AC_MSG_RESULT(no)
1608 ])
1609
1610 dnl ---------------------------------------------------------------
1611 dnl figure out how to check link-state
1612 dnl ---------------------------------------------------------------
1613 AC_CHECK_HEADER([net/if_media.h],
1614   [m4_define([LINK_DETECT_INCLUDES],
1615     FRR_INCLUDES
1616     [#include <net/if_media.h>
1617   ])
1618   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1619     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1620     [], LINK_DETECT_INCLUDES)],
1621   [],
1622   FRR_INCLUDES)
1623
1624 dnl ---------------------------------------------------------------
1625 dnl Additional, newer way to check link-state using ifi_link_state.
1626 dnl Not available in all BSD's when ifmediareq available
1627 dnl ---------------------------------------------------------------
1628 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1629   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1630   [], FRR_INCLUDES)
1631
1632 dnl ------------------------
1633 dnl TCP_MD5SIG socket option
1634 dnl ------------------------
1635
1636 AC_CHECK_HEADER([netinet/tcp.h],
1637    [m4_define([MD5_INCLUDES],
1638       FRR_INCLUDES
1639       [#include <netinet/tcp.h>
1640     ])
1641     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1642    [],
1643    FRR_INCLUDES)
1644 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1645   AC_CHECK_HEADER([linux/tcp.h],
1646        [m4_define([MD5_INCLUDES],
1647           FRR_INCLUDES
1648           [#include <linux/tcp.h>
1649         ])
1650        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1651 fi
1652
1653 LIBS_save="$LIBS"
1654 AC_CHECK_LIB([crypt], [crypt], [], [
1655   AC_CHECK_LIB([crypto], [DES_crypt])
1656 ])
1657 LIBCRYPT="$LIBS"
1658 LIBCRYPT="${LIBCRYPT%$LIBS_save}"
1659 LIBCRYPT="${LIBCRYPT#$LIBS_save}"
1660 AC_SUBST([LIBCRYPT])
1661 LIBS="$LIBS_save"
1662 unset LIBS_save
1663
1664 AC_CHECK_LIB([resolv], [res_init])
1665
1666 dnl ---------------------------
1667 dnl check system has PCRE regexp
1668 dnl ---------------------------
1669 if test "$enable_pcreposix" = "yes"; then
1670   AC_CHECK_LIB([pcreposix], [regexec], [], [
1671     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1672   ])
1673 fi
1674 AC_SUBST([HAVE_LIBPCREPOSIX])
1675
1676 dnl ---------------------------
1677 dnl check system has PCRE2 regexp
1678 dnl ---------------------------
1679 if test "$enable_pcre2posix" = "yes"; then
1680   AC_CHECK_LIB([pcre2-posix], [regexec], [], [
1681     AC_MSG_ERROR([--enable-pcre2posix given but unable to find libpcre2-posix])
1682   ])
1683 fi
1684 AC_SUBST([HAVE_LIBPCRE2_POSIX])
1685
1686 dnl ##########################################################################
1687 dnl test "$enable_clippy_only" != "yes"
1688 fi
1689 dnl END OF LARGE if block
1690 dnl ##########################################################################
1691
1692 dnl ------------------
1693 dnl check C-Ares library
1694 dnl ------------------
1695 PKG_CHECK_MODULES([CARES], [libcares], [
1696   c_ares_found=true
1697 ],[
1698   c_ares_found=false
1699 ])
1700 AM_CONDITIONAL([CARES], [$c_ares_found])
1701
1702
1703 dnl ----------------------------------------------------------------------------
1704 dnl figure out if domainname is available in the utsname struct (GNU extension).
1705 dnl ----------------------------------------------------------------------------
1706 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1707
1708 dnl ------------------
1709 dnl IPv6 header checks
1710 dnl ------------------
1711 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1712         netinet6/in6_var.h netinet6/nd6.h], [], [],
1713         FRR_INCLUDES)
1714
1715 m4_define([FRR_INCLUDES],dnl
1716 FRR_INCLUDES
1717 [#ifdef HAVE_NETINET6_IN6_H
1718 #include <netinet6/in6.h>
1719 #endif
1720 #ifdef HAVE_NETINET_IN6_VAR_H
1721 #include <netinet/in6_var.h>
1722 #endif
1723 #include <netinet/icmp6.h>
1724 #ifdef HAVE_NETINET6_IN6_VAR_H
1725 # include <netinet6/in6_var.h>
1726 #endif
1727 #ifdef HAVE_NETINET6_ND6_H
1728 # include <netinet6/nd6.h>
1729 #endif
1730 ])dnl
1731
1732 dnl --------------------
1733 dnl Daemon disable check
1734 dnl --------------------
1735
1736 AS_IF([test "$enable_bgpd" != "no"], [
1737   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1738 ])
1739
1740 AS_IF([test "$enable_mgmtd" != "no"], [
1741
1742   AC_DEFINE([HAVE_MGMTD], [1], [mgmtd])
1743
1744   # Enable MGMTD local validations
1745   AS_IF([test "$enable_mgmtd_local_validations" == "yes"], [
1746     AC_DEFINE([MGMTD_LOCAL_VALIDATIONS_ENABLED], [1], [Enable mgmtd local validations.])
1747   ])
1748 ])
1749
1750 AS_IF([test "$enable_ripd" != "no"], [
1751   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1752 ])
1753
1754 AS_IF([test "$enable_ripngd" != "no"], [
1755   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1756 ])
1757
1758 AS_IF([test "$enable_ospfd" != "no"], [
1759   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1760 ])
1761
1762 AS_IF([test "$enable_ospf6d" != "no"], [
1763   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1764 ])
1765
1766 AS_IF([test "$enable_ldpd" != "no"], [
1767   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1768 ])
1769
1770 AS_IF([test "$enable_nhrpd" != "no"], [
1771   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1772 ])
1773
1774 AS_IF([test "$enable_eigrpd" != "no"], [
1775   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1776 ])
1777
1778 AS_IF([test "$enable_babeld" != "no"], [
1779   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1780 ])
1781
1782 AS_IF([test "$enable_isisd" != "no"], [
1783   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1784 ])
1785
1786 AS_IF([test "$enable_pimd" != "no"], [
1787   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1788 ])
1789
1790 AS_IF([test "$enable_pim6d" != "no"], [
1791   AC_DEFINE([HAVE_PIM6D], [1], [pim6d])
1792 ])
1793
1794 AS_IF([test "$enable_pbrd" != "no"], [
1795   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1796 ])
1797
1798 AS_IF([test "$enable_sharpd" = "yes"], [
1799   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1800 ])
1801
1802 AS_IF([test "$enable_staticd" != "no"], [
1803   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1804 ])
1805
1806 AS_IF([test "$enable_fabricd" != "no"], [
1807   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1808 ])
1809
1810 AS_IF([test "$enable_vrrpd" != "no"], [
1811   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1812 ])
1813
1814 if test "$enable_bfdd" = "no"; then
1815   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1816   BFDD=""
1817 else
1818   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1819   BFDD="bfdd"
1820
1821   case $host_os in
1822     linux*)
1823       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1824       ;;
1825
1826     *)
1827       AC_DEFINE([BFD_BSD], [1], [bfdd])
1828       ;;
1829   esac
1830 fi
1831
1832 AS_IF([test "$enable_pathd" != "no"], [
1833   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1834 ])
1835
1836 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1837   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1838 fi
1839
1840 NHRPD=""
1841 case "$host_os" in
1842   linux*)
1843     case "${enable_nhrpd}" in
1844       no)
1845         ;;
1846       yes)
1847         if test "$enable_clippy_only" != "yes"; then
1848         if test "$c_ares_found" != "true" ; then
1849           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1850         fi
1851         fi
1852         NHRPD="nhrpd"
1853         ;;
1854       *)
1855         if test "$c_ares_found" = "true" ; then
1856           NHRPD="nhrpd"
1857         fi
1858         ;;
1859     esac
1860     ;;
1861   *)
1862     if test "$enable_nhrpd" = "yes"; then
1863       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1864     fi
1865     ;;
1866 esac
1867
1868 if test "$enable_watchfrr" = "no";then
1869   WATCHFRR=""
1870 else
1871   WATCHFRR="watchfrr"
1872 fi
1873
1874 OSPFCLIENT=""
1875 if test "$enable_ospfapi" != "no";then
1876     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1877
1878   if test "$enable_ospfclient" != "no";then
1879       OSPFCLIENT="ospfclient"
1880   fi
1881 fi
1882
1883 if test "$enable_bgp_announce" = "no";then
1884   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1885 else
1886   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1887 fi
1888
1889 if test "$enable_bgp_vnc" != "no";then
1890   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1891 fi
1892
1893 bgpd_bmp=false
1894 case "${enable_bgp_bmp}" in
1895   no)
1896     ;;
1897   yes)
1898     if test "$c_ares_found" != "true" ; then
1899       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1900     fi
1901     bgpd_bmp=true
1902     ;;
1903   *)
1904     if test "$c_ares_found" = "true" ; then
1905       bgpd_bmp=true
1906     fi
1907     ;;
1908 esac
1909
1910 if test "$enable_version_build_config" != "no";then
1911   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1912 fi
1913
1914 dnl ##########################################################################
1915 dnl LARGE if block
1916 if test "$enable_clippy_only" != "yes"; then
1917 dnl ##########################################################################
1918
1919 dnl ------------------
1920 dnl check Net-SNMP library
1921 dnl ------------------
1922 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1923    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1924    if test "$NETSNMP_CONFIG" = "no"; then
1925       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1926    fi
1927    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1928    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1929    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1930    # among other things we avoid a GPL vs. OpenSSL license conflict here
1931    for removelib in crypto ssl sensors pci wrap; do
1932      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1933    done
1934    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1935    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1936 int main(void);
1937 ],
1938 [
1939 {
1940   return 0;
1941 }
1942 ])], [
1943      AC_MSG_RESULT([no])
1944      AC_MSG_ERROR([--enable-snmp given but not usable])])
1945    case "${enable_snmp}" in
1946      yes)
1947       SNMP_METHOD=agentx
1948       ;;
1949      agentx)
1950       SNMP_METHOD="${enable_snmp}"
1951       ;;
1952      *)
1953       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1954       ;;
1955    esac
1956    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1957    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1958 fi
1959 AC_SUBST([SNMP_LIBS])
1960 AC_SUBST([SNMP_CFLAGS])
1961
1962 dnl ---------------
1963 dnl libyang
1964 dnl ---------------
1965 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1966   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1967 ])
1968 ac_cflags_save="$CFLAGS"
1969 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1970 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1971   AC_MSG_ERROR([m4_normalize([
1972     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1973     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1974   ])
1975 ], [[#include <libyang/libyang.h>]])
1976 CFLAGS="$ac_cflags_save"
1977
1978 dnl ---------------
1979 dnl configuration rollbacks
1980 dnl ---------------
1981 SQLITE3=false
1982 if test "$enable_config_rollbacks" = "yes"; then
1983   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1984     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1985     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1986     SQLITE3=true
1987   ], [
1988     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1989   ])
1990 fi
1991
1992 dnl ---------------
1993 dnl confd
1994 dnl ---------------
1995 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1996    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1997    if test "$CONFD" = "/bin/false"; then
1998       AC_MSG_ERROR([confd was not found on your system.])]
1999    fi
2000    AC_CHECK_PROG([CONFDC], [confdc], [confdc], [/bin/false], "${enable_confd}/bin")
2001    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
2002    AC_SUBST([CONFD_CFLAGS])
2003    CONFD_LIBS="-lconfd"
2004    AC_SUBST([CONFD_LIBS])
2005    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
2006 fi
2007
2008 dnl ---------------
2009 dnl sysrepo
2010 dnl ---------------
2011 if test "$enable_sysrepo" = "yes"; then
2012   PKG_CHECK_MODULES([SYSREPO], [sysrepo >= 2.1.42],
2013       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
2014       SYSREPO=true],
2015       [SYSREPO=false
2016       AC_MSG_ERROR([sysrepo was not found on your system.])]
2017   )
2018 fi
2019
2020 dnl ---------------
2021 dnl gRPC
2022 dnl ---------------
2023 if test "$enable_grpc" = "yes"; then
2024   AC_LANG_PUSH([C++])
2025   AX_CXX_COMPILE_STDCXX([11], [ext])
2026   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
2027     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
2028     if test "$PROTOC" = "/bin/false"; then
2029       AC_MSG_FAILURE([grpc requested but protoc not found.])
2030     fi
2031
2032     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
2033     GRPC=true
2034   ], [
2035     GRPC=false
2036     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
2037   ])
2038   AC_LANG_POP([C++])
2039 fi
2040
2041 dnl ---------
2042 dnl DPDK
2043 dnl ---------
2044 if test "$enable_dp_dpdk" = "yes"; then
2045   PKG_CHECK_MODULES([DPDK], [libdpdk], [
2046     AC_DEFINE([HAVE_DPDK], [1], [Enable DPDK backend])
2047     DPDK=true
2048   ], [
2049     AC_MSG_ERROR([configuration specifies --enable-dp-dpdk but DPDK libs were not found])
2050   ])
2051 fi
2052
2053 dnl -----
2054 dnl LTTng
2055 dnl -----
2056 if test "$enable_lttng" = "yes"; then
2057   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.9.0], [
2058     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
2059     LTTNG=true
2060   ], [
2061     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
2062   ])
2063 fi
2064
2065 dnl ----
2066 dnl USDT
2067 dnl ----
2068 if test "$enable_usdt" = "yes"; then
2069   AC_CHECK_HEADERS([sys/sdt.h], [
2070     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
2071     USDT=true
2072   ], [
2073     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
2074   ])
2075 fi
2076
2077 dnl ------
2078 dnl ZeroMQ
2079 dnl ------
2080 if test "$enable_zeromq" != "no"; then
2081   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2082     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2083     ZEROMQ=true
2084   ], [
2085     if test "$enable_zeromq" = "yes"; then
2086       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2087     fi
2088   ])
2089 fi
2090
2091 dnl ------------------------------------
2092 dnl Enable RPKI and add librtr to libs
2093 dnl ------------------------------------
2094 if test "$enable_rpki" = "yes"; then
2095   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.8.0],
2096       [RPKI=true],
2097       [RPKI=false
2098       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2099   )
2100 fi
2101
2102 dnl ------------------------------------
2103 dnl pimd and pim6d not supported on OpenBSD and MacOS
2104 dnl ------------------------------------
2105 if test "$enable_pimd" != "no"; then
2106 AC_MSG_CHECKING([for pimd OS support])
2107 case "$host_os" in
2108   darwin*)
2109     AC_MSG_RESULT([no])
2110     enable_pimd="no"
2111     ;;
2112   openbsd*)
2113     AC_MSG_RESULT([no])
2114     enable_pimd="no"
2115     ;;
2116   *)
2117     AC_MSG_RESULT([yes])
2118     ;;
2119 esac
2120 fi
2121
2122 if test "$enable_pim6d" != "no"; then
2123 AC_MSG_CHECKING([for pim6d OS support])
2124 case "$host_os" in
2125   linux*)
2126     AC_MSG_RESULT([yes])
2127     ;;
2128   *)
2129     AC_MSG_RESULT([no])
2130     enable_pim6d="no"
2131     ;;
2132 esac
2133 fi
2134
2135 dnl -------------------------------------
2136 dnl VRRP is only supported on linux
2137 dnl -------------------------------------
2138 if test "$enable_vrrpd" != "no"; then
2139 AC_MSG_CHECKING([for VRRP OS support])
2140 case "$host_os" in
2141   linux*)
2142     AC_MSG_RESULT([yes])
2143     ;;
2144   *)
2145     AC_MSG_RESULT([no])
2146     enable_vrrpd="no"
2147     ;;
2148 esac
2149 fi
2150
2151 dnl ------------------------------------------
2152 dnl Check whether rtrlib was build with ssh support
2153 dnl ------------------------------------------
2154 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2155 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2156                         [[struct tr_ssh_config config;]])],
2157         [AC_MSG_RESULT([yes])
2158         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2159         AC_MSG_RESULT([no])
2160 )
2161
2162 dnl ---------------
2163 dnl dlopen & dlinfo
2164 dnl ---------------
2165 LIBS_save="$LIBS"
2166 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2167   AC_MSG_ERROR([unable to find the dlopen()])
2168 ])
2169
2170 AC_CHECK_HEADERS([link.h])
2171
2172 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2173   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2174 #include <stdlib.h>
2175 #ifdef HAVE_LINK_H
2176 #include <link.h>
2177 #endif
2178 #include <dlfcn.h>
2179 ]], [[
2180   char origin[1];
2181   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2182 ]])], [
2183     frr_cv_rtld_di_origin=yes
2184   ], [
2185     frr_cv_rtld_di_origin=no
2186   ])
2187 ])
2188 if test "$frr_cv_rtld_di_origin" = "yes"; then
2189   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2190 fi
2191
2192 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2193   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2194 #include <stdlib.h>
2195 #ifdef HAVE_LINK_H
2196 #include <link.h>
2197 #endif
2198 #include <dlfcn.h>
2199 ]], [[
2200   struct link_map *lm = NULL;
2201   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2202 ]])], [
2203     frr_cv_rtld_di_linkmap=yes
2204   ], [
2205     frr_cv_rtld_di_linkmap=no
2206   ])
2207 ])
2208 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2209   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2210 fi
2211
2212 LIBDL="$LIBS"
2213 LIBDL="${LIBDL%$LIBS_save}"
2214 LIBDL="${LIBDL#$LIBS_save}"
2215 AC_SUBST([LIBDL])
2216 LIBS="$LIBS_save"
2217 unset LIBS_save
2218
2219 dnl ##########################################################################
2220 dnl test "$enable_clippy_only" != "yes"
2221 fi
2222 dnl END OF LARGE if block
2223 dnl ##########################################################################
2224
2225 dnl ---------------------------
2226 dnl sockaddr and netinet checks
2227 dnl ---------------------------
2228 AC_CHECK_TYPES([
2229         struct sockaddr_dl,
2230         struct vifctl, struct mfcctl, struct sioc_sg_req,
2231         vifi_t, struct sioc_vif_req, struct igmpmsg,
2232         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2233         struct nd_opt_adv_interval,
2234         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2235         struct nd_opt_rdnss, struct nd_opt_dnssl],
2236         [], [], FRR_INCLUDES)
2237
2238 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2239         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2240         struct sockaddr_dl.sdl_len,
2241         struct if6_aliasreq.ifra_lifetime,
2242         struct nd_opt_adv_interval.nd_opt_ai_type],
2243         [], [], FRR_INCLUDES)
2244
2245 dnl ---------------------------
2246 dnl IRDP/pktinfo/icmphdr checks
2247 dnl ---------------------------
2248
2249 AC_CHECK_TYPES([struct in_pktinfo], [
2250   AC_CHECK_TYPES([struct icmphdr], [
2251     IRDP=true
2252   ], [
2253     IRDP=false
2254   ], [FRR_INCLUDES])
2255 ], [
2256   IRDP=false
2257 ], [FRR_INCLUDES])
2258
2259 case "${enable_irdp}" in
2260 yes)
2261   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2262   ;;
2263 no)
2264   IRDP=false
2265   ;;
2266 esac
2267
2268
2269 dnl -----------------------
2270 dnl checking for IP_PKTINFO
2271 dnl -----------------------
2272 AC_MSG_CHECKING([for IP_PKTINFO])
2273 AC_COMPILE_IFELSE(
2274 [ AC_LANG_PROGRAM([[
2275         #include <netdb.h>
2276    ]], [[
2277         int opt = IP_PKTINFO;
2278    ]])
2279 ],[
2280   AC_MSG_RESULT([yes])
2281   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2282 ],[
2283   AC_MSG_RESULT([no])
2284 ])
2285
2286 dnl ---------------------------
2287 dnl checking for IP_RECVDSTADDR
2288 dnl ---------------------------
2289 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2290 AC_COMPILE_IFELSE(
2291 [ AC_LANG_PROGRAM([[
2292         #include <netinet/in.h>
2293   ]], [[
2294         int opt = IP_RECVDSTADDR;
2295   ]])
2296 ],[
2297   AC_MSG_RESULT([yes])
2298   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2299 ],[
2300   AC_MSG_RESULT([no])
2301 ])
2302
2303 dnl ----------------------
2304 dnl checking for IP_RECVIF
2305 dnl ----------------------
2306 AC_MSG_CHECKING([for IP_RECVIF])
2307 AC_COMPILE_IFELSE(
2308 [ AC_LANG_PROGRAM([[
2309         #include <netinet/in.h>
2310   ]], [[
2311         int opt = IP_RECVIF;
2312   ]])
2313 ],[
2314   AC_MSG_RESULT([yes])
2315   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2316 ],[
2317   AC_MSG_RESULT([no])
2318 ])
2319
2320 dnl ----------------------
2321 dnl checking for SO_BINDANY
2322 dnl ----------------------
2323 AC_MSG_CHECKING([for SO_BINDANY])
2324 AC_COMPILE_IFELSE(
2325 [ AC_LANG_PROGRAM([[
2326         #include <sys/socket.h>
2327   ]], [[
2328         int opt = SO_BINDANY;
2329   ]])
2330 ],[
2331   AC_MSG_RESULT([yes])
2332   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2333 ],[
2334   AC_MSG_RESULT([no])
2335 ])
2336
2337 dnl ----------------------
2338 dnl checking for IP_FREEBIND
2339 dnl ----------------------
2340 AC_MSG_CHECKING([for IP_FREEBIND])
2341 AC_COMPILE_IFELSE(
2342 [ AC_LANG_PROGRAM([[
2343         #include <netinet/in.h>
2344   ]], [[
2345         int opt = IP_FREEBIND;
2346   ]])
2347 ],[
2348   AC_MSG_RESULT([yes])
2349   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2350 ],[
2351   AC_MSG_RESULT([no])
2352 ])
2353
2354 dnl --------------------------------------
2355 dnl checking for be32dec existence or not
2356 dnl --------------------------------------
2357 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2358         #ifdef HAVE_SYS_ENDIAN_H
2359         #include <sys/endian.h>
2360         #endif
2361         #ifdef HAVE_ENDIAN_H
2362         #include <endian.h>
2363         #endif
2364 ])
2365
2366 dnl --------------------------------------
2367 dnl checking for clock_time monotonic struct and call
2368 dnl --------------------------------------
2369 AC_CHECK_DECL([CLOCK_MONOTONIC],
2370         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2371          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2372 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2373
2374 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2375          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2376 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2377
2378 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2379   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2380 ])
2381
2382 dnl --------------------------------------
2383 dnl checking for flex and bison
2384 dnl --------------------------------------
2385
2386 dnl autoconf 2.69 AC_PROG_LEX has no parameters
2387 dnl autoconf 2.70 AC_PROG_LEX prints a deprecation warning without params
2388 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
2389   dnl autoconf < 2.70
2390   AC_PROG_LEX
2391 ], [
2392   dnl autoconf >= 2.70
2393   AC_PROG_LEX([noyywrap])
2394 ])
2395
2396 AC_MSG_CHECKING([version of flex])
2397 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2398 frr_ac_flex_version="${frr_ac_flex_version##* }"
2399 AC_MSG_RESULT([$frr_ac_flex_version])
2400 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2401   LEX="$SHELL $missing_dir/missing flex"
2402   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2403     AC_MSG_WARN([using pregenerated flex output files])
2404   else
2405     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2406   fi
2407   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2408   AC_SUBST([LEXLIB], [''])
2409 ])
2410
2411 AC_PROG_YACC
2412 dnl thanks GNU bison for this b*llshit...
2413 AC_MSG_CHECKING([version of bison])
2414 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2415 frr_ac_bison_version="${frr_ac_bison_version##* }"
2416 frr_ac_bison_missing="false"
2417 case "x${frr_ac_bison_version}x" in
2418   x2.7*)
2419     BISON_OPENBRACE='"'
2420     BISON_CLOSEBRACE='"'
2421     BISON_VERBOSE=''
2422     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2423     ;;
2424   x2.*|x1.*)
2425     AC_MSG_RESULT([$frr_ac_bison_version])
2426     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2427     frr_ac_bison_missing="true"
2428     ;;
2429   x)
2430     AC_MSG_RESULT([none])
2431     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2432     frr_ac_bison_missing="true"
2433     ;;
2434   x3.[012][^0-9]*)
2435     BISON_OPENBRACE='{'
2436     BISON_CLOSEBRACE='}'
2437     BISON_VERBOSE='-Dparse.error=verbose'
2438     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2439     ;;
2440   *)
2441     BISON_OPENBRACE='{'
2442     BISON_CLOSEBRACE='}'
2443     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2444     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2445     ;;
2446 esac
2447 AC_SUBST([BISON_OPENBRACE])
2448 AC_SUBST([BISON_CLOSEBRACE])
2449 AC_SUBST([BISON_VERBOSE])
2450
2451 if $frr_ac_bison_missing; then
2452   YACC="$SHELL $missing_dir/missing bison -y"
2453   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2454     AC_MSG_WARN([using pregenerated bison output files])
2455   else
2456     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2457   fi
2458 fi
2459
2460 dnl -------------------
2461 dnl capabilities checks
2462 dnl -------------------
2463 if test "$enable_capabilities" != "no"; then
2464   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2465   AC_COMPILE_IFELSE(
2466   [ AC_LANG_PROGRAM([[
2467         #include <sys/prctl.h>
2468     ]], [[
2469         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2470     ]])
2471   ],[AC_MSG_RESULT([yes])
2472      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2473      frr_ac_keepcaps="yes"
2474   ],[AC_MSG_RESULT(no)
2475   ])
2476   if test "$frr_ac_keepcaps" = "yes"; then
2477     AC_CHECK_HEADERS([sys/capability.h])
2478   fi
2479   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2480     AC_CHECK_LIB([cap], [cap_init],
2481       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2482        LIBCAP="-lcap"
2483        frr_ac_lcaps="yes"]
2484     )
2485   fi
2486   if test "$frr_ac_scaps" = "yes" \
2487        -o "$frr_ac_lcaps" = "yes"; then
2488     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2489   fi
2490
2491   case "$host_os" in
2492   linux*)
2493     if test "$enable_clippy_only" != "yes"; then
2494     if test "$frr_ac_lcaps" != "yes"; then
2495       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2496     fi
2497     fi
2498     ;;
2499   esac
2500 else
2501   case "$host_os" in
2502   linux*)
2503     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2504     ;;
2505   esac
2506 fi
2507 AC_SUBST([LIBCAP])
2508
2509 dnl ---------------------------
2510 dnl check for glibc 'backtrace'
2511 dnl ---------------------------
2512 if test "$enable_backtrace" != "no" ; then
2513   backtrace_ok=no
2514   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2515     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2516     backtrace_ok=yes
2517   ], [
2518     true
2519   ])
2520
2521   if test "$backtrace_ok" = "no"; then
2522     AC_CHECK_HEADER([unwind.h], [
2523       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2524         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2525         backtrace_ok=yes
2526       ])
2527     ])
2528   fi
2529
2530   if test "$backtrace_ok" = "no"; then
2531     AC_CHECK_HEADER([execinfo.h], [
2532       AC_SEARCH_LIBS([backtrace], [execinfo], [
2533         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2534         backtrace_ok=yes
2535       ],, [-lm])
2536     ])
2537   fi
2538
2539   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2540     dnl user explicitly requested backtrace but we failed to find support
2541     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2542   fi
2543 fi
2544
2545 dnl -----------------------------------------
2546 dnl check for malloc mallinfo struct and call
2547 dnl this must try and link using LIBS, in
2548 dnl order to check no alternative allocator
2549 dnl has been specified, which might not provide
2550 dnl mallinfo
2551 dnl -----------------------------------------
2552 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2553
2554 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2555   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2556 #ifdef HAVE_MALLOC_H
2557 #include <malloc.h>
2558 #endif
2559 #ifdef HAVE_MALLOC_NP_H
2560 #include <malloc_np.h>
2561 #endif
2562 #ifdef HAVE_MALLOC_MALLOC_H
2563 #include <malloc/malloc.h>
2564 #endif
2565 ]], [[
2566 struct mallinfo ac_x; ac_x = mallinfo ();
2567 ]])], [
2568     frr_cv_mallinfo=yes
2569   ], [
2570     frr_cv_mallinfo=no
2571   ])
2572 ])
2573 if test "$frr_cv_mallinfo" = "yes"; then
2574   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2575 fi
2576
2577 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2578   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2579 #ifdef HAVE_MALLOC_H
2580 #include <malloc.h>
2581 #endif
2582 #ifdef HAVE_MALLOC_NP_H
2583 #include <malloc_np.h>
2584 #endif
2585 #ifdef HAVE_MALLOC_MALLOC_H
2586 #include <malloc/malloc.h>
2587 #endif
2588 ]], [[
2589 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2590 ]])], [
2591     frr_cv_mallinfo2=yes
2592   ], [
2593     frr_cv_mallinfo2=no
2594   ])
2595 ])
2596 if test "$frr_cv_mallinfo2" = "yes"; then
2597   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2598 fi
2599
2600 AC_MSG_CHECKING([whether malloc_usable_size is available])
2601 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2602 #ifdef HAVE_MALLOC_H
2603 #include <malloc.h>
2604 #endif
2605 #ifdef HAVE_MALLOC_MALLOC_H
2606 #include <malloc/malloc.h>
2607 #endif
2608 ]], [[
2609 size_t ac_x; ac_x = malloc_usable_size(NULL);
2610 ]])], [
2611   AC_MSG_RESULT([yes])
2612   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2613 ], [
2614   AC_MSG_RESULT([no])
2615
2616   AC_MSG_CHECKING([whether malloc_size is available])
2617   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2618 #ifdef HAVE_MALLOC_H
2619 #include <malloc.h>
2620 #endif
2621 #ifdef HAVE_MALLOC_MALLOC_H
2622 #include <malloc/malloc.h>
2623 #endif
2624 ]], [[
2625 size_t ac_x; ac_x = malloc_size(NULL);
2626 ]])], [
2627     AC_MSG_RESULT([yes])
2628     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2629   ], [
2630     AC_MSG_RESULT([no])
2631   ])
2632 ])
2633
2634 dnl ----------
2635 dnl configure date
2636 dnl ----------
2637 dev_version=`echo $VERSION | grep dev`
2638 #don't expire deprecated code in non 'dev' branch
2639 if test "$dev_version" = ""; then
2640    CONFDATE=0
2641 else
2642    CONFDATE=`date '+%Y%m%d'`
2643 fi
2644 AC_SUBST([CONFDATE])
2645
2646 dnl ------------------------------
2647 dnl set paths for state directory
2648 dnl ------------------------------
2649 AC_MSG_CHECKING([directory to use for state file])
2650 if test "$prefix" = "NONE"; then
2651   frr_statedir_prefix="";
2652 else
2653   frr_statedir_prefix=${prefix}
2654 fi
2655 if test "$localstatedir" = '${prefix}/var'; then
2656   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2657                         ${frr_statedir_prefix}/var/adm dnl
2658                         ${frr_statedir_prefix}/etc dnl
2659                         /var/run        dnl
2660                         /var/adm        dnl
2661                         /etc            dnl
2662                         /dev/null;
2663   do
2664     test -d $FRR_STATE_DIR && break
2665   done
2666   frr_statedir=$FRR_STATE_DIR
2667 else
2668   frr_statedir=${localstatedir}
2669 fi
2670 if test "$frr_statedir" = "/dev/null"; then
2671     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2672 fi
2673 AC_MSG_RESULT([${frr_statedir}])
2674 AC_SUBST([frr_statedir])
2675
2676 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2677 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2678 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2679 AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information])
2680 AC_DEFINE_UNQUOTED([MGMTD_FE_SERVER_PATH], ["$frr_statedir/mgmtd_fe.sock"], [mgmtd frontend server socket])
2681 AC_DEFINE_UNQUOTED([MGMTD_BE_SERVER_PATH], ["$frr_statedir/mgmtd_be.sock"], [mgmtd backend server socket])
2682 AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information])
2683 AC_DEFINE_UNQUOTED([ISISD_RESTART], ["$frr_statedir%s/isid-restart.json"], [isisd restart information])
2684 AC_DEFINE_UNQUOTED([OSPF6_AUTH_SEQ_NUM_FILE], ["$frr_statedir/ospf6d-at-seq-no.dat"], [ospf6d AT Sequence number information])
2685 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2686 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2687
2688 dnl autoconf does this, but it does it too late...
2689 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2690 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2691
2692 dnl get the full path, recursing through variables...
2693 vtysh_bin="$bindir/vtysh"
2694 for I in 1 2 3 4 5 6 7 8 9 10; do
2695         eval vtysh_bin="\"$vtysh_bin\""
2696 done
2697 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2698 AC_SUBST([vtysh_bin])
2699
2700 CFG_SYSCONF="$sysconfdir"
2701 CFG_SBIN="$sbindir"
2702 CFG_BIN="$bindir"
2703 CFG_STATE="$frr_statedir"
2704 CFG_MODULE="$moduledir"
2705 CFG_YANGMODELS="$yangmodelsdir"
2706 CFG_SCRIPT="$scriptdir"
2707 for I in 1 2 3 4 5 6 7 8 9 10; do
2708         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2709         eval CFG_SBIN="\"$CFG_SBIN\""
2710         eval CFG_BIN="\"$CFG_BIN\""
2711         eval CFG_STATE="\"$CFG_STATE\""
2712         eval CFG_MODULE="\"$CFG_MODULE\""
2713         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2714         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2715 done
2716 AC_SUBST([CFG_SYSCONF])
2717 AC_SUBST([CFG_SBIN])
2718 AC_SUBST([CFG_BIN])
2719 AC_SUBST([CFG_STATE])
2720 AC_SUBST([CFG_MODULE])
2721 AC_SUBST([CFG_SCRIPT])
2722 AC_SUBST([CFG_YANGMODELS])
2723 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2724 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2725 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2726 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2727
2728 dnl various features
2729 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2730 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2731 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2732 dnl northbound
2733 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2734 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2735 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2736 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2737 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2738 dnl plugins
2739 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2740 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2741 AM_CONDITIONAL([IRDP], [$IRDP])
2742 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2743 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" != "no"])
2744 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2745
2746 dnl PCEP plugin
2747 AS_IF([test "$enable_pathd" != "no"], [
2748        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2749        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2750        ])
2751 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2752 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2753 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2754 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2755
2756 dnl daemons
2757 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2758 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2759 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2760 AM_CONDITIONAL([MGMTD], [test "$enable_mgmtd" != "no"])
2761 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2762 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2763 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2764 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2765 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2766 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2767 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2768 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2769 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2770 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2771 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2772 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2773 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2774 AM_CONDITIONAL([PIM6D], [test "$enable_pim6d" != "no"])
2775 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2776 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2777 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2778 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2779 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2780 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2781 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2782 AM_CONDITIONAL([DP_DPDK], [test "$enable_dp_dpdk" = "yes"])
2783
2784 AC_CONFIG_FILES([Makefile],[
2785         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2786         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2787 ], [
2788         PYTHON="$PYTHON"
2789         enable_dev_build="$enable_dev_build"
2790 ])
2791
2792 AC_CONFIG_FILES([
2793           config.version
2794           redhat/frr.spec
2795           alpine/APKBUILD
2796           snapcraft/snapcraft.yaml
2797           lib/version.h
2798           tests/lib/cli/test_cli.refout pkgsrc/mgmtd.sh
2799           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2800           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2801           pkgsrc/eigrpd.sh])
2802
2803 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2804 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2805 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2806 AC_CONFIG_FILES([tools/frrcommon.sh])
2807 AC_CONFIG_FILES([tools/frr.service])
2808 AC_CONFIG_FILES([tools/frr@.service])
2809
2810 AS_IF([test "$with_pkg_git_version" = "yes"], [
2811     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2812         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2813         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2814                 "${ac_abs_top_srcdir}" \
2815                 > "${dst}.tmp"
2816         test -f "$dst" \
2817                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2818                 && rm "${dst}.tmp" \
2819                 || mv "${dst}.tmp" "${dst}"
2820     ], [
2821         PERL="$PERL"
2822     ])
2823 ])
2824
2825 ## Hack, but working solution to avoid rebuilding of frr.info.
2826 ## It's already in CVS until texinfo 4.7 is more common.
2827 AC_OUTPUT
2828
2829 if test "$enable_rpath" = "yes" ; then
2830         true
2831 else
2832         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2833         sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool
2834         sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g'         libtool > libtool.sed && cat libtool.sed > libtool
2835         test -f libtool.sed && rm libtool.sed
2836 fi
2837
2838 echo "
2839 FRRouting configuration
2840 ------------------------------
2841 FRR version             : ${PACKAGE_VERSION}
2842 host operating system   : ${host_os}
2843 source code location    : ${srcdir}
2844 compiler                : ${CC}
2845 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2846 make                    : ${MAKE-make}
2847 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2848 state file directory    : ${frr_statedir}
2849 config file directory   : `eval echo \`echo ${sysconfdir}\``
2850 module directory        : ${CFG_MODULE}
2851 script directory        : ${CFG_SCRIPT}
2852 user to run as          : ${enable_user}
2853 group to run as         : ${enable_group}
2854 group for vty sockets   : ${enable_vty_group}
2855 config file mask        : ${enable_configfile_mask}
2856 log file mask           : ${enable_logfile_mask}
2857 zebra protobuf enabled  : ${enable_protobuf:-no}
2858 vici socket path        : ${vici_socket}
2859
2860 The above user and group must have read/write access to the state file
2861 directory and to the config files in the config file directory."
2862
2863 if test -n "$enable_datacenter"; then
2864   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2865 fi
2866 if test -n "$enable_time_check"; then
2867   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2868 fi
2869 if test -n "$enable_cpu_time"; then
2870   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2871 fi
2872
2873 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2874   AC_MSG_WARN([sphinx is missing but required to build documentation])
2875 fi
2876 if test "$frr_py_mod_pytest" = "false"; then
2877   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2878 fi