configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.0, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl AddressSanitizer support
 193 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 194               [enabled AddressSanitizer support for detecting a wide variety of \
 195                memory allocation and deallocation errors]), \
 196               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 197               ASAN_FLAGS="-fsanitize=address"
 198               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 199               AC_SUBST([ASAN_FLAGS])
 200               AC_SUBST([SAN_CLIPPY_FLAGS])
 201               LIBS="-ldl $LIBS"
 202               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 203                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 204               ])
 205
 206 dnl ThreadSanitizer support
 207 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 208               [enabled ThreadSanitizer support for detecting data races]), \
 209               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 210               TSAN_FLAGS="-fsanitize=thread"
 211               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 212               AC_SUBST([TSAN_FLAGS])
 213               AC_SUBST([SAN_CLIPPY_FLAGS])
 214               LIBS="-ldl $LIBS"
 215               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 216                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 217               ])
 218
 219 dnl MemorySanitizer support
 220 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 221               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 222               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 223               MSAN_FLAGS="-fsanitize=memory -fPIE -pie"
 224               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 225               AC_SUBST([MSAN_FLAGS])
 226               AC_SUBST([SAN_CLIPPY_FLAGS])
 227               LIBS="-ldl $LIBS"
 228               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 229                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 230               ])
 231
 232 dnl if the user has specified any CFLAGS, override our settings
 233 if test "x${enable_gcov}" = "xyes"; then
 234    if test "z$orig_cflags" = "z"; then
 235       AC_C_FLAG([-coverage])
 236       AC_C_FLAG([-O0])
 237    fi
 238
 239    LDFLAGS="${LDFLAGS} -lgcov"
 240 elif test "x${enable_dev_build}" = "xyes"; then
 241    AC_DEFINE(DEV_BUILD,,Build for development)
 242    if test "z$orig_cflags" = "z"; then
 243       AC_C_FLAG([-g3])
 244       AC_C_FLAG([-O0])
 245    fi
 246 else
 247    if test "z$orig_cflags" = "z"; then
 248       AC_C_FLAG([-g])
 249       AC_C_FLAG([-Os], [
 250         AC_C_FLAG([-O2])
 251       ])
 252    fi
 253 fi
 254 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 255
 256 dnl always want these CFLAGS
 257 AC_C_FLAG([-fno-omit-frame-pointer])
 258 AC_C_FLAG([-funwind-tables])
 259 AC_C_FLAG([-Wall])
 260 AC_C_FLAG([-Wextra])
 261 AC_C_FLAG([-Wmissing-prototypes])
 262 AC_C_FLAG([-Wmissing-declarations])
 263 AC_C_FLAG([-Wpointer-arith])
 264 AC_C_FLAG([-Wbad-function-cast])
 265 AC_C_FLAG([-Wwrite-strings])
 266 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 267   AC_C_FLAG([-Wcast-qual])
 268   AC_C_FLAG([-Wstrict-prototypes])
 269   AC_C_FLAG([-Wmissing-noreturn])
 270   AC_C_FLAG([-Wmissing-format-attribute])
 271   AC_C_FLAG([-Wunreachable-code])
 272   AC_C_FLAG([-Wpacked])
 273   AC_C_FLAG([-Wpadded])
 274 else
 275   AC_C_FLAG([-Wno-unused-result])
 276 fi
 277 AC_C_FLAG([-Wno-unused-parameter])
 278 AC_C_FLAG([-Wno-missing-field-initializers])
 279
 280 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 281 dnl for some reason the string consts get 'promoted' to char *,
 282 dnl triggering a const to non-const conversion warning.
 283 AC_C_FLAG([-diag-disable 3179])
 284
 285 if test x"${enable_werror}" = x"yes" ; then
 286   WERROR="-Werror"
 287 fi
 288 AC_SUBST(WERROR)
 289
 290 dnl need link on this one, not compile
 291 AC_LANG_PUSH(C)
 292 ac_ld_flag_save="$LDFLAGS"
 293 LDFLAGS="$LDFLAGS -rdynamic"
 294 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 295 AC_LINK_IFELSE(
 296         [AC_LANG_PROGRAM([[]])],
 297         [AC_MSG_RESULT([yes])],
 298         [
 299                 LDFLAGS="$ac_ld_flag_save"
 300                 AC_MSG_RESULT([no])
 301         ])
 302 AC_LANG_POP(C)
 303
 304 dnl ----------
 305 dnl Essentials
 306 dnl ----------
 307
 308 AX_PTHREAD([
 309   CC="$PTHREAD_CC"
 310   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 311   LIBS="$PTHREAD_LIBS $LIBS"
 312 ], [
 313   AC_MSG_FAILURE([This FRR version needs pthreads])
 314 ])
 315
 316 dnl --------------
 317 dnl Check programs
 318 dnl --------------
 319 AC_PROG_INSTALL
 320 AC_PROG_LN_S
 321 AC_PROG_MAKE_SET
 322 AC_CHECK_TOOL(AR, ar)
 323
 324 dnl -----------------
 325 dnl System extensions
 326 dnl -----------------
 327 AC_GNU_SOURCE
 328
 329 dnl -------
 330 dnl libtool
 331 dnl -------
 332 LT_INIT
 333
 334 dnl ----------------------
 335 dnl Packages configuration
 336 dnl ----------------------
 337 AC_ARG_WITH(pkg-extra-version,
 338         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 339         [EXTRAVERSION=$withval],)
 340 AC_ARG_WITH(pkg-git-version,
 341         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 342         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 343 AC_ARG_WITH(vtysh_pager,
 344         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 345         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 346 AC_ARG_ENABLE(vtysh,
 347   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 348 AC_ARG_ENABLE(doc,
 349   AS_HELP_STRING([--disable-doc], [do not build docs]))
 350 AC_ARG_ENABLE(doc-html,
 351   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 352 AC_ARG_ENABLE(zebra,
 353   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 354 AC_ARG_ENABLE(bgpd,
 355   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 356 AC_ARG_ENABLE(ripd,
 357   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 358 AC_ARG_ENABLE(ripngd,
 359   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 360 AC_ARG_ENABLE(ospfd,
 361   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 362 AC_ARG_ENABLE(ospf6d,
 363   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 364 AC_ARG_ENABLE(ldpd,
 365   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 366 AC_ARG_ENABLE(nhrpd,
 367   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 368 AC_ARG_ENABLE(eigrpd,
 369   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 370 AC_ARG_ENABLE(babeld,
 371   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 372 AC_ARG_ENABLE(watchfrr,
 373   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 374 AC_ARG_ENABLE(isisd,
 375   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 376 AC_ARG_ENABLE(pimd,
 377   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 378 AC_ARG_ENABLE(pbrd,
 379   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 380 AC_ARG_ENABLE(sharpd,
 381   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 382 AC_ARG_ENABLE(staticd,
 383   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 384 AC_ARG_ENABLE(bgp-announce,
 385   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 386 AC_ARG_ENABLE(bgp-vnc,
 387   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 388 AC_ARG_ENABLE(snmp,
 389   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 390 AC_ARG_ENABLE(zeromq,
 391   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 392 AC_ARG_WITH(libpam,
 393   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 394 AC_ARG_ENABLE(ospfapi,
 395   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 396 AC_ARG_ENABLE(ospfclient,
 397   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 398                           (this is the default if --disable-ospfapi is set)]))
 399 AC_ARG_ENABLE(multipath,
 400   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 401 AC_ARG_ENABLE(user,
 402   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 403 AC_ARG_ENABLE(group,
 404   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 405 AC_ARG_ENABLE(vty_group,
 406   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 407 AC_ARG_ENABLE(configfile_mask,
 408   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 409 AC_ARG_ENABLE(logfile_mask,
 410   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 411 AC_ARG_ENABLE(shell_access,
 412   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 413 AC_ARG_ENABLE(realms,
 414   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 415 AC_ARG_ENABLE(rtadv,
 416   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 417 AC_ARG_ENABLE(irdp,
 418   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 419 AC_ARG_ENABLE(capabilities,
 420   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 421 AC_ARG_ENABLE(rusage,
 422   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 423 AC_ARG_ENABLE(gcc_ultra_verbose,
 424   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 425 AC_ARG_ENABLE(backtrace,
 426   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 427 AC_ARG_ENABLE(time-check,
 428   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 429 AC_ARG_ENABLE(pcreposix,
 430   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 431 AC_ARG_ENABLE(fpm,
 432   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 433 AC_ARG_ENABLE(systemd,
 434   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 435 AC_ARG_ENABLE(werror,
 436   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 437 AC_ARG_ENABLE(cumulus,
 438   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 439 AC_ARG_ENABLE(datacenter,
 440   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 441 AC_ARG_ENABLE(fuzzing,
 442   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 443 AC_ARG_ENABLE(netlink_fuzzing,
 444   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 445 AC_ARG_ENABLE(rr-semantics,
 446   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 447 AC_ARG_ENABLE([protobuf],
 448   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 449 AC_ARG_ENABLE([oldvpn_commands],
 450   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 451 AC_ARG_ENABLE(rpki,
 452   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 453 AC_ARG_ENABLE([clippy-only],
 454   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 455 AC_ARG_ENABLE([numeric_version],
 456   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 457 AC_ARG_ENABLE([gcov],
 458   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 459 AC_ARG_ENABLE(bfdd,
 460   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 461
 462 AS_IF([test "${enable_clippy_only}" != "yes"], [
 463 AC_CHECK_HEADERS(json-c/json.h)
 464 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 465 if test $ac_cv_lib_json_c_json_object_get = no; then
 466   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 467   if test $ac_cv_lib_json_json_object_get = no; then
 468       AC_MSG_ERROR([lib json is needed to compile])
 469   fi
 470 fi
 471 ])
 472
 473 AC_ARG_ENABLE([dev_build],
 474     AS_HELP_STRING([--enable-dev-build], [build for development]))
 475
 476 if test x"${enable_time_check}" != x"no" ; then
 477   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 478     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 479   else
 480     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 481   fi
 482 fi
 483
 484 case "${enable_systemd}" in
 485   "no") ;;
 486   "yes")
 487   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 488   if test $ac_cv_lib_systemd_sd_notify = no; then
 489     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 490   else
 491     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 492   fi
 493   ;;
 494   "*") ;;
 495 esac
 496
 497 if test "${enable_rr_semantics}" != "no" ; then
 498   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 499 fi
 500
 501 if test "${enable_datacenter}" = "yes" ; then
 502   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 503   DFLT_NAME="datacenter"
 504 else
 505   DFLT_NAME="traditional"
 506 fi
 507
 508 if test "${enable_fuzzing}" = "yes" ; then
 509   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 510 fi
 511
 512 if test "${enable_netlink_fuzzing}" = "yes" ; then
 513   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 514 fi
 515
 516 if test "${enable_cumulus}" = "yes" ; then
 517   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 518 fi
 519
 520 AC_SUBST(DFLT_NAME)
 521 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 522
 523 if test "${enable_shell_access}" = "yes"; then
 524    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 525 fi
 526
 527 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 528
 529 #
 530 # Python for clippy
 531 #
 532
 533 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 534   AC_MSG_CHECKING([whether we found a working Python version])
 535   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 536 #include <Python.h>
 537 #if PY_VERSION_HEX < 0x02070000
 538 #error python too old
 539 #endif
 540 int main(void);
 541 ],
 542 [
 543 {
 544   Py_Initialize();
 545   return 0;
 546 }
 547 ])], [
 548     # some python installs are missing the zlib dependency...
 549     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 550     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 551 #include <Python.h>
 552 #if PY_VERSION_HEX < 0x02070000
 553 #error python too old
 554 #endif
 555 int main(void);
 556 ],
 557 [
 558 {
 559   Py_Initialize();
 560   return 0;
 561 }
 562 ])], [
 563       m4_if([$1], [], [
 564         PYTHONCONFIG=""
 565         unset PYTHON_LIBS
 566         unset PYTHON_CFLAGS
 567       ], [$1])
 568     ])
 569   ])
 570 ])
 571
 572 AS_IF([test "$host" = "$build"], [
 573   PYTHONCONFIG=""
 574
 575   # ordering:
 576   # 1.  try python3, but respect the user's preference on which minor ver
 577   # 2.  try python, which might be py3 or py2 again on the user's preference
 578   # 3.  try python2 (can really only be 2.7 but eh)
 579   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 580   #
 581   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 582   # (AX_PYTHON does not do what we need)
 583
 584   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 585         python3-config \
 586         python-config \
 587         python2-config \
 588         python3.6-config \
 589         python3.5-config \
 590         python3.4-config \
 591         python3.3-config \
 592         python3.2-config \
 593         python2.7-config ])
 594   if test -n "$PYTHONCONFIG"; then
 595     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 596     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 597
 598     FRR_PYTHON_CHECK_WORKING([])
 599   fi
 600
 601   if test -z "$PYTHONCONFIG"; then
 602     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 603       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 604         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 605           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 606             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 607               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 608                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 609                 ])])])])])])
 610
 611
 612     FRR_PYTHON_CHECK_WORKING([
 613       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 614     ])
 615   fi
 616 ])
 617 AC_SUBST(PYTHON_CFLAGS)
 618 AC_SUBST(PYTHON_LIBS)
 619
 620 #
 621 # Logic for protobuf support.
 622 #
 623 if test "$enable_protobuf" = "yes"; then
 624    have_protobuf=yes
 625
 626    # Check for protoc-c
 627    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 628    if test "x$PROTOC_C" = "x/bin/false"; then
 629       have_protobuf=no
 630    else
 631       found_protobuf_c=no
 632       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 633                      [found_protobuf_c=yes],
 634                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 635
 636       if test "x$found_protobuf_c" = "xyes"; then
 637          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 638          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 639       else
 640         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 641                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 642       fi
 643    fi
 644 fi
 645
 646 #
 647 # Logic for old vpn commans support.
 648 #
 649 if test "$enable_oldvpn_commands" = "yes"; then
 650    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 651 fi
 652
 653 # Fail if the user explicity enabled protobuf support and we couldn't
 654 # find the compiler or libraries.
 655 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 656    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 657 fi
 658
 659 if test "x$have_protobuf" = "xyes"; then
 660    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 661 fi
 662
 663 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 664
 665 #
 666 # End of logic for protobuf support.
 667 #
 668
 669 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 670 if test "${enable_rtadv}" != "no"; then
 671   AC_MSG_RESULT(yes)
 672   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 673 else
 674   AC_MSG_RESULT(no)
 675 fi
 676
 677 if test x"${enable_user}" = x"no"; then
 678   enable_user=""
 679 else
 680   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 681     enable_user="frr"
 682   fi
 683   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 684 fi
 685
 686 if test x"${enable_group}" = x"no"; then
 687   enable_group=""
 688 else
 689   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 690     enable_group="frr"
 691   fi
 692   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 693 fi
 694
 695 if test x"${enable_vty_group}" = x"yes" ; then
 696   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 697 elif test x"${enable_vty_group}" != x""; then
 698   if test x"${enable_vty_group}" != x"no"; then
 699     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 700   fi
 701 fi
 702 AC_SUBST([enable_user])
 703 AC_SUBST([enable_group])
 704 AC_SUBST([enable_vty_group])
 705
 706 enable_configfile_mask=${enable_configfile_mask:-0600}
 707 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 708
 709 enable_logfile_mask=${enable_logfile_mask:-0600}
 710 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 711
 712 MPATH_NUM=1
 713
 714 case "${enable_multipath}" in
 715   0)
 716     MPATH_NUM=64
 717     ;;
 718   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 719     MPATH_NUM="${enable_multipath}"
 720     ;;
 721   "")
 722     ;;
 723   *)
 724     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 725     ;;
 726 esac
 727
 728 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 729
 730 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 731
 732 dnl --------------------
 733 dnl Enable code coverage
 734 dnl --------------------
 735 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 736
 737 dnl ------------------------------------
 738 dnl Alpine only accepts numeric versions
 739 dnl ------------------------------------
 740 if test "x${enable_numeric_version}" != "x" ; then
 741   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 742   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 743 fi
 744
 745 dnl -----------------------------------
 746 dnl Add extra version string to package
 747 dnl name, string and version fields.
 748 dnl -----------------------------------
 749 if test "x${EXTRAVERSION}" != "x" ; then
 750   VERSION="${VERSION}${EXTRAVERSION}"
 751   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 752   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 753   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 754 fi
 755
 756 if test "x$with_pkg_git_version" = "xyes"; then
 757         if test -d "${srcdir}/.git"; then
 758                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 759         else    with_pkg_git_version="no"
 760                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 761         fi
 762 fi
 763 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 764
 765 dnl ------------------------------------
 766 dnl Check C keywords and standard  types
 767 dnl ------------------------------------
 768 AC_C_CONST
 769 AC_C_INLINE
 770 AC_C_VOLATILE
 771 AC_HEADER_STDC
 772 dnl AC_TYPE_PID_T
 773 AC_TYPE_UID_T
 774 AC_TYPE_MODE_T
 775 AC_TYPE_SIZE_T
 776 AC_STRUCT_TM
 777
 778 dnl -------------------------
 779 dnl Check other header files.
 780 dnl -------------------------
 781 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 782         linux/version.h asm/types.h \
 783         sys/cdefs.h])
 784
 785 ac_stdatomic_ok=false
 786 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 787 AC_CHECK_HEADER([stdatomic.h],[
 788
 789   AC_MSG_CHECKING([whether _Atomic qualifier works])
 790   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 791 #include <stdatomic.h>
 792 int main(int argc, char **argv) {
 793   _Atomic int i = 0;
 794   return i;
 795 }
 796 ]])], [
 797     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 798     AC_MSG_RESULT([yes])
 799     ac_stdatomic_ok=true
 800   ], [
 801     AC_MSG_RESULT([no])
 802   ])
 803 ])
 804
 805 AS_IF([$ac_stdatomic_ok], [true], [
 806   AC_MSG_CHECKING([for __atomic_* builtins])
 807   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 808 int main(int argc, char **argv) {
 809   volatile int i = 1;
 810   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 811   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 812 }
 813 ]])], [
 814     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 815     AC_MSG_RESULT([yes])
 816   ], [
 817     AC_MSG_RESULT([no])
 818
 819     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 820     AC_MSG_CHECKING([for __sync_* builtins])
 821     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 822 int main(int argc, char **argv) {
 823   volatile int i = 1;
 824   __sync_fetch_and_sub (&i, 1);
 825   return __sync_val_compare_and_swap (&i, 0, 1);
 826 }
 827 ]])], [
 828       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 829       AC_MSG_RESULT([yes])
 830
 831       AC_MSG_CHECKING([for __sync_swap builtin])
 832       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 833 int main(int argc, char **argv) {
 834   volatile int i = 1;
 835   return __sync_swap (&i, 2);
 836 }
 837 ]])], [
 838         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 839         AC_MSG_RESULT([yes])
 840       ], [
 841         AC_MSG_RESULT([no])
 842       ])
 843
 844     ], [
 845       AC_MSG_RESULT([no])
 846       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 847     ])
 848   ])
 849 ])
 850
 851 dnl Utility macro to avoid retyping includes all the time
 852 m4_define([FRR_INCLUDES],
 853 [#ifdef SUNOS_5
 854 #define _XPG4_2
 855 #define __EXTENSIONS__
 856 #endif
 857 #include <stdio.h>
 858 #include <stdlib.h>
 859 #include <stddef.h>
 860 #include <sys/types.h>
 861 /* sys/conf.h depends on param.h on FBSD at least */
 862 #include <sys/param.h>
 863 /* Required for MAXSIG */
 864 #include <signal.h>
 865 #include <sys/socket.h>
 866 #ifdef __APPLE__
 867 # define __APPLE_USE_RFC_3542
 868 #endif
 869 #include <netinet/in.h>
 870 #include <sys/time.h>
 871 #include <time.h>
 872 #include <net/if.h>
 873 ])dnl
 874
 875 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 876 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 877 dnl an additional round for it.
 878
 879 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 880
 881 m4_define([FRR_INCLUDES],
 882 FRR_INCLUDES
 883 [#if HAVE_NET_IF_VAR_H
 884 # include <net/if_var.h>
 885 #endif
 886 ])dnl
 887
 888 AC_CHECK_HEADERS([netinet/in_var.h \
 889         net/if_dl.h net/netopt.h \
 890         inet/nd.h netinet/ip_icmp.h \
 891         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 892         [], [], FRR_INCLUDES)
 893
 894 AC_CHECK_HEADERS([ucontext.h], [], [],
 895 [#ifndef __USE_GNU
 896 #define __USE_GNU
 897 #endif /* __USE_GNU */
 898 FRR_INCLUDES
 899 ])
 900
 901 m4_define([UCONTEXT_INCLUDES],
 902 [#include <ucontext.h>])dnl
 903
 904 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 905   [], [], [UCONTEXT_INCLUDES])
 906 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 907   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 908    [], [], [UCONTEXT_INCLUDES])],
 909   [], [UCONTEXT_INCLUDES])
 910 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 911   [], [], [UCONTEXT_INCLUDES])
 912
 913 m4_define([FRR_INCLUDES],
 914 FRR_INCLUDES
 915 [
 916 #include <sys/un.h>
 917 #include <netinet/in_systm.h>
 918 #if HAVE_NETINET_IN_VAR_H
 919 # include <netinet/in_var.h>
 920 #endif
 921 #if HAVE_NET_IF_DL_H
 922 # include <net/if_dl.h>
 923 #endif
 924 #if HAVE_NET_NETOPT_H
 925 # include <net/netopt.h>
 926 #endif
 927 #include <net/route.h>
 928 #if HAVE_INET_ND_H
 929 # include <inet/nd.h>
 930 #endif
 931 #include <arpa/inet.h>
 932 /* Required for IDRP */
 933 #if HAVE_NETINET_IP_ICMP_H
 934 # include <netinet/ip_icmp.h>
 935 #endif
 936 ])dnl
 937
 938 dnl V6 headers are checked below, after we check for v6
 939
 940 AC_MSG_CHECKING([which operating system interface to use])
 941 case "$host_os" in
 942   sunos* | solaris2*)
 943     AC_MSG_RESULT([Solaris])
 944
 945     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 946     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 947
 948     AC_CHECK_LIB(socket, main)
 949     AC_CHECK_LIB(nsl, main)
 950     AC_CHECK_LIB(umem, main)
 951     AC_CHECK_FUNCS([printstack], [
 952       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 953       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 954     ])
 955     CURSES=-lcurses
 956     SOLARIS="solaris"
 957     ;;
 958   linux*)
 959     AC_MSG_RESULT([Linux])
 960
 961     AC_DEFINE(GNU_LINUX,,GNU Linux)
 962     AC_DEFINE(HAVE_NETLINK,,netlink)
 963     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 964
 965     dnl Linux has a compilation problem with mixing
 966     dnl netinet/in.h and linux/in6.h they are not
 967     dnl compatible.  There has been discussion on
 968     dnl how to fix it but no real progress on implementation
 969     dnl when they fix it, remove this
 970     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 971     ;;
 972   openbsd*)
 973     AC_MSG_RESULT([OpenBSD])
 974
 975     AC_DEFINE(OPEN_BSD,,OpenBSD)
 976     AC_DEFINE(KAME,1,KAME IPv6)
 977     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 978
 979     if test "x${enable_pimd}" != "xno"; then
 980       case "$host_os" in
 981       openbsd6.0)
 982         ;;
 983       openbsd[6-9]*)
 984         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 985         ;;
 986       esac
 987     fi
 988     ;;
 989   *)
 990     AC_MSG_RESULT([BSD])
 991
 992     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 993     AC_DEFINE(KAME,1,KAME IPv6)
 994     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 995     ;;
 996 esac
 997 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 998
 999 AC_SYS_LARGEFILE
1000
1001 dnl ------------------------
1002 dnl Integrated REALMS option
1003 dnl ------------------------
1004 if test "${enable_realms}" = "yes"; then
1005     case "$host_os" in
1006       linux*)
1007        AC_DEFINE(SUPPORT_REALMS,, Realms support)
1008        ;;
1009       *)
1010        echo "Sorry, only Linux has REALMS support"
1011        exit 1
1012        ;;
1013     esac
1014 fi
1015 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1016
1017 dnl ---------------------
1018 dnl Integrated VTY option
1019 dnl ---------------------
1020 case "${enable_vtysh}" in
1021   "no") VTYSH="";;
1022   *)    VTYSH="vtysh";
1023          AC_DEFINE(VTYSH,,VTY shell)
1024 dnl      Vtysh uses libreadline, which looks for termcap functions at
1025 dnl      configure time.  We follow readlines search order.
1026 dnl      The required procedures are in libtermcap on NetBSD, in
1027 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1028          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1029            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1030              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1031                [AC_CHECK_LIB(ncurses, tputs,
1032                              LIBREADLINE="$LIBREADLINE -lncurses")]
1033               )]
1034             )]
1035           )
1036          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1037                       "$LIBREADLINE")
1038          if test $ac_cv_lib_readline_main = no; then
1039            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1040          fi
1041          AC_CHECK_HEADER(readline/history.h)
1042          if test $ac_cv_header_readline_history_h = no;then
1043            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1044          fi
1045          AC_CHECK_LIB(readline, rl_completion_matches,
1046                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1047          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1048            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1049          fi
1050          ;;
1051 esac
1052 AC_SUBST(LIBREADLINE)
1053 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1054
1055 dnl ----------
1056 dnl PAM module
1057 dnl
1058 dnl FRR detects the PAM library it is built against by checking for a
1059 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1060 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1061 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1062 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1063 dnl of OpenPAM.
1064 dnl ----------
1065 if test "$with_libpam" = "yes"; then
1066   AC_CHECK_HEADER([security/pam_misc.h],
1067     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1068      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1069      pam_conv_func="misc_conv"
1070     ],
1071     [], FRR_INCLUDES)
1072   AC_CHECK_HEADER([security/openpam.h],
1073     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1074      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1075      pam_conv_func="openpam_ttyconv"
1076     ],
1077     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1078   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1079     AC_MSG_WARN([*** pam support will not be built ***])
1080     with_libpam="no"
1081   fi
1082 fi
1083
1084 if test "$with_libpam" = "yes"; then
1085 dnl took this test from proftpds configure.in and suited to our needs
1086 dnl -------------------------------------------------------------------------
1087 dnl
1088 dnl This next check looks funky due to a linker problem with some versions
1089 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1090 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1091 dnl with RedHat 6.2 and Debian 2.2 or better.
1092 AC_CHECK_LIB(pam, pam_start,
1093   [AC_CHECK_LIB(pam, $pam_conv_func,
1094     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1095      LIBPAM="-lpam"],
1096     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1097      LIBPAM="-lpam -lpam_misc"]
1098     )
1099   ],
1100
1101   [AC_CHECK_LIB(pam, pam_end,
1102     [AC_CHECK_LIB(pam, $pam_conv_func,
1103       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1104        LIBPAM="-lpam -ldl"],
1105       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1106        LIBPAM="-lpam -ldl -lpam_misc"]
1107      )
1108   ],AC_MSG_WARN([*** pam support will not be built ***]),
1109   [-ldl])
1110   ]
1111 )
1112 fi
1113 AC_SUBST(LIBPAM)
1114
1115 dnl -------------------------------
1116 dnl Endian-ness check
1117 dnl -------------------------------
1118 AC_WORDS_BIGENDIAN
1119
1120 dnl -------------------------------
1121 dnl check the size in byte of the C
1122 dnl -------------------------------
1123 dnl AC_CHECK_SIZEOF(char)
1124 dnl AC_CHECK_SIZEOF(int)
1125 dnl AC_CHECK_SIZEOF(short)
1126 dnl AC_CHECK_SIZEOF(long)
1127
1128 dnl ----------------------------
1129 dnl check existance of functions
1130 dnl ----------------------------
1131 AC_FUNC_FNMATCH
1132 AC_FUNC_FORK
1133 AC_FUNC_MKTIME
1134 AC_FUNC_STAT
1135
1136 dnl -------------------------------
1137 dnl bgpd needs pow() and hence libm
1138 dnl -------------------------------
1139 TMPLIBS="$LIBS"
1140 AC_CHECK_HEADER([math.h],
1141   [AC_CHECK_LIB([m], [pow],
1142     [LIBM="-lm"
1143      LIBS="$LIBS $LIBM"
1144      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1145     ])
1146 ])
1147 if test x"$LIBM" = x ; then
1148   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1149 fi
1150 LIBS="$TMPLIBS"
1151 AC_SUBST(LIBM)
1152
1153 AC_CHECK_FUNCS([ppoll], [
1154   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1155 ])
1156 AC_CHECK_FUNCS([pollts], [
1157   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1158 ])
1159
1160 dnl ---------------
1161 dnl other functions
1162 dnl ---------------
1163 AC_CHECK_FUNCS([ \
1164         strlcat strlcpy \
1165         getgrouplist])
1166
1167 AC_CHECK_HEADER([asm-generic/unistd.h],
1168                 [AC_CHECK_DECL(__NR_setns,
1169                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1170                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1171                                ])
1172                  AC_CHECK_FUNCS(setns)]
1173                )
1174
1175 dnl --------------------------
1176 dnl Determine IS-IS I/O method
1177 dnl --------------------------
1178 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1179 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1180 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1181 AC_CHECK_HEADER(net/bpf.h)
1182 AC_CHECK_HEADER(sys/dlpi.h)
1183 AC_MSG_CHECKING(zebra IS-IS I/O method)
1184
1185 case "$host_os" in
1186   linux*)
1187     AC_MSG_RESULT(pfpacket)
1188     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1189     ;;
1190   solaris* | sunos*)
1191     AC_MSG_RESULT(DLPI)
1192     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1193     ;;
1194   *)
1195     if test $ac_cv_header_net_bpf_h = no; then
1196       if test $ac_cv_header_sys_dlpi_h = no; then
1197         AC_MSG_RESULT(none)
1198         if test "${enable_isisd}" = yes; then
1199           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1200         fi
1201         AC_MSG_WARN([*** IS-IS support will not be built ***])
1202         enable_isisd="no"
1203       else
1204         AC_MSG_RESULT(DLPI)
1205       fi
1206       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1207     else
1208       AC_MSG_RESULT(BPF)
1209       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1210     fi
1211     ;;
1212 esac
1213 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1214
1215 dnl ---------------------------------------------------------------
1216 dnl figure out how to specify an interface in multicast sockets API
1217 dnl ---------------------------------------------------------------
1218 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1219
1220 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1221         #include <sys/socket.h>
1222         #include <netinet/in.h>
1223         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1224         #include <linux/types.h>
1225 ])
1226
1227 m4_define([FRR_INCLUDES],
1228 FRR_INCLUDES
1229 [#if HAVE_LINUX_MROUTE_H
1230 # include <linux/mroute.h>
1231 #endif
1232 ])dnl
1233
1234 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1235         #include <sys/socket.h>
1236         #include <sys/types.h>
1237         #include <netinet/in.h>
1238         #include <net/route.h>
1239 ])
1240
1241 m4_define([FRR_INCLUDES],
1242 FRR_INCLUDES
1243 [#if HAVE_NETINET_IP_MROUTE_H
1244 # include <netinet/ip_mroute.h>
1245 #endif
1246 ])dnl
1247
1248 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1249 AC_TRY_COMPILE([#include <sys/param.h>],
1250 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1251   return (0);
1252 #else
1253   #error No support for BSD struct ip_mreq hack detected
1254 #endif],[AC_MSG_RESULT(yes)
1255 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1256 AC_MSG_RESULT(no))
1257
1258 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1259 AC_TRY_COMPILE([
1260 #include <sys/types.h>
1261 #include <netinet/in.h>
1262 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1263 ], [AC_MSG_RESULT(yes)
1264 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1265 AC_MSG_RESULT(no))
1266
1267 dnl ---------------------------------------------------------------
1268 dnl figure out how to check link-state
1269 dnl ---------------------------------------------------------------
1270 AC_CHECK_HEADER( [net/if_media.h],
1271   [m4_define([LINK_DETECT_INCLUDES],
1272     FRR_INCLUDES
1273     [#include <net/if_media.h>
1274   ])
1275   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1276     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1277     [], LINK_DETECT_INCLUDES)],
1278   [],
1279   FRR_INCLUDES)
1280
1281 dnl ---------------------------------------------------------------
1282 dnl Additional, newer way to check link-state using ifi_link_state.
1283 dnl Not available in all BSD's when ifmediareq available
1284 dnl ---------------------------------------------------------------
1285 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1286   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1287   [], FRR_INCLUDES)
1288
1289 dnl ------------------------
1290 dnl TCP_MD5SIG socket option
1291 dnl ------------------------
1292
1293 AC_CHECK_HEADER([netinet/tcp.h],
1294    [m4_define([MD5_INCLUDES],
1295       FRR_INCLUDES
1296       [#include <netinet/tcp.h>
1297     ])
1298     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1299    [],
1300    FRR_INCLUDES)
1301 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1302   AC_CHECK_HEADER([linux/tcp.h],
1303        [m4_define([MD5_INCLUDES],
1304           FRR_INCLUDES
1305           [#include <linux/tcp.h>
1306         ])
1307        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1308 fi
1309
1310 dnl ----------------------------------------------------------------------------
1311 dnl figure out if domainname is available in the utsname struct (GNU extension).
1312 dnl ----------------------------------------------------------------------------
1313 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1314
1315 dnl ------------------
1316 dnl IPv6 header checks
1317 dnl ------------------
1318 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1319         netinet6/in6_var.h netinet6/nd6.h], [], [],
1320         FRR_INCLUDES)
1321
1322 m4_define([FRR_INCLUDES],dnl
1323 FRR_INCLUDES
1324 [#if HAVE_NETINET6_IN6_H
1325 #include <netinet6/in6.h>
1326 #endif
1327 #if HAVE_NETINET_IN6_VAR_H
1328 #include <netinet/in6_var.h>
1329 #endif
1330 #include <netinet/icmp6.h>
1331 #if HAVE_NETINET6_IN6_VAR_H
1332 # include <netinet6/in6_var.h>
1333 #endif
1334 #if HAVE_NETINET6_ND6_H
1335 # include <netinet6/nd6.h>
1336 #endif
1337 ])dnl
1338
1339 dnl disable doc check
1340 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [no])
1341 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no")
1342 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1343
1344 dnl --------------------
1345 dnl Daemon disable check
1346 dnl --------------------
1347 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1348
1349 if test "${enable_bgpd}" = "no";then
1350   BGPD=""
1351 else
1352   BGPD="bgpd"
1353 fi
1354 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1355
1356 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1357 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1358 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1359
1360 AS_IF([test "${enable_ldpd}" != "no"], [
1361   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1362 ])
1363
1364 if test "$enable_bfdd" = "no"; then
1365   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1366   BFDD=""
1367 else
1368   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1369   BFDD="bfdd"
1370
1371   case $host_os in
1372     linux*)
1373       AC_DEFINE(BFD_LINUX, 1, bfdd)
1374       ;;
1375
1376     *)
1377       AC_DEFINE(BFD_BSD, 1, bfdd)
1378       ;;
1379   esac
1380 fi
1381
1382 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1383
1384 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1385   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1386 fi
1387
1388 NHRPD=""
1389 case "$host_os" in
1390   linux*)
1391     if test "${enable_nhrpd}" != "no"; then
1392       NHRPD="nhrpd"
1393     fi
1394     ;;
1395   *)
1396     if test "${enable_nhrpd}" = "yes"; then
1397       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1398     fi
1399     ;;
1400 esac
1401 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1402
1403 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1404
1405 if test "${enable_watchfrr}" = "no";then
1406   WATCHFRR=""
1407 else
1408   WATCHFRR="watchfrr"
1409 fi
1410 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1411
1412 OSPFCLIENT=""
1413 if test "${enable_ospfapi}" != "no";then
1414     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1415
1416   if test "${enable_ospfclient}" != "no";then
1417       OSPFCLIENT="ospfclient"
1418   fi
1419 fi
1420
1421 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1422 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1423 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1424 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1425 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1426 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1427 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1428 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1429 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1430
1431 if test "${enable_bgp_announce}" = "no";then
1432   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1433 else
1434   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1435 fi
1436
1437 if test "${enable_bgp_vnc}" != "no";then
1438   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1439 fi
1440 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1441
1442 AC_SUBST(SOLARIS)
1443 AC_SUBST(CURSES)
1444 AC_CHECK_LIB(crypt, crypt, [],
1445                     [AC_CHECK_LIB(crypto, DES_crypt)])
1446 AC_CHECK_LIB(resolv, res_init)
1447
1448 dnl ---------------------------
1449 dnl check system has PCRE regexp
1450 dnl ---------------------------
1451 if test "x$enable_pcreposix" = "xyes"; then
1452   AC_CHECK_LIB(pcreposix, regexec, [], [
1453     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1454   ])
1455 fi
1456 AC_SUBST(HAVE_LIBPCREPOSIX)
1457
1458 dnl ------------------
1459 dnl check C-Ares library
1460 dnl ------------------
1461 if test "${NHRPD}" != ""; then
1462   PKG_CHECK_MODULES([CARES], [libcares], , [
1463     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1464   ])
1465 fi
1466
1467
1468 dnl ------------------
1469 dnl check Net-SNMP library
1470 dnl ------------------
1471 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1472    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1473    if test x"$NETSNMP_CONFIG" = x"no"; then
1474       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1475    fi
1476    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1477    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1478    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1479    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1480 int main(void);
1481 ],
1482 [
1483 {
1484   return 0;
1485 }
1486 ])], [
1487      AC_MSG_ERROR([--enable-snmp given but not usable])])
1488    case "${enable_snmp}" in
1489      yes)
1490       SNMP_METHOD=agentx
1491       ;;
1492      agentx)
1493       SNMP_METHOD="${enable_snmp}"
1494       ;;
1495      *)
1496       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1497       ;;
1498    esac
1499    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1500    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1501 fi
1502 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1503 AC_SUBST(SNMP_LIBS)
1504 AC_SUBST(SNMP_CFLAGS)
1505
1506 dnl ---------------
1507 dnl math
1508 dnl ---------------
1509 AC_SEARCH_LIBS([sqrt], [m])
1510
1511 dnl ---------------
1512 dnl dlopen & dlinfo
1513 dnl ---------------
1514 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1515   AC_MSG_ERROR([unable to find the dlopen()])
1516 ])
1517
1518 AC_CHECK_HEADERS([link.h])
1519
1520 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1521   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1522 #include <stdlib.h>
1523 #ifdef HAVE_LINK_H
1524 #include <link.h>
1525 #endif
1526 #include <dlfcn.h>
1527 ]], [[
1528   char origin[1];
1529   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1530 ]])], [
1531     frr_cv_rtld_di_origin=yes
1532   ], [
1533     frr_cv_rtld_di_origin=no
1534   ])
1535 ])
1536 if test "$frr_cv_rtld_di_origin" = yes; then
1537   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1538 fi
1539
1540 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1541   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1542 #include <stdlib.h>
1543 #ifdef HAVE_LINK_H
1544 #include <link.h>
1545 #endif
1546 #include <dlfcn.h>
1547 ]], [[
1548   struct link_map *lm = NULL;
1549   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1550 ]])], [
1551     frr_cv_rtld_di_linkmap=yes
1552   ], [
1553     frr_cv_rtld_di_linkmap=no
1554   ])
1555 ])
1556 if test "$frr_cv_rtld_di_linkmap" = yes; then
1557   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1558 fi
1559
1560 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1561
1562 dnl ---------------------------
1563 dnl sockaddr and netinet checks
1564 dnl ---------------------------
1565 AC_CHECK_TYPES([
1566         struct sockaddr_dl,
1567         struct vifctl, struct mfcctl, struct sioc_sg_req,
1568         vifi_t, struct sioc_vif_req, struct igmpmsg,
1569         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1570         struct nd_opt_adv_interval, struct rt_addrinfo,
1571         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1572         [], [], FRR_INCLUDES)
1573
1574 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1575         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1576         struct sockaddr_dl.sdl_len,
1577         struct if6_aliasreq.ifra_lifetime,
1578         struct nd_opt_adv_interval.nd_opt_ai_type],
1579         [], [], FRR_INCLUDES)
1580
1581 dnl ---------------------------
1582 dnl IRDP/pktinfo/icmphdr checks
1583 dnl ---------------------------
1584
1585 AC_CHECK_TYPES([struct in_pktinfo], [
1586   AC_CHECK_TYPES([struct icmphdr], [
1587     IRDP=true
1588   ], [
1589     IRDP=false
1590   ], [FRR_INCLUDES])
1591 ], [
1592   IRDP=false
1593 ], [FRR_INCLUDES])
1594
1595 case "${enable_irdp}" in
1596 yes)
1597   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1598   ;;
1599 no)
1600   IRDP=false
1601   ;;
1602 esac
1603
1604 AM_CONDITIONAL(IRDP, $IRDP)
1605
1606 dnl -----------------------
1607 dnl checking for IP_PKTINFO
1608 dnl -----------------------
1609 AC_MSG_CHECKING(for IP_PKTINFO)
1610 AC_TRY_COMPILE([#include <netdb.h>], [
1611   int opt = IP_PKTINFO;
1612 ], [
1613   AC_MSG_RESULT(yes)
1614   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1615 ], [
1616   AC_MSG_RESULT(no)
1617 ])
1618
1619 dnl ---------------------------
1620 dnl checking for IP_RECVDSTADDR
1621 dnl ---------------------------
1622 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1623 AC_TRY_COMPILE([#include <netinet/in.h>], [
1624   int opt = IP_RECVDSTADDR;
1625 ], [
1626   AC_MSG_RESULT(yes)
1627   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1628 ], [
1629   AC_MSG_RESULT(no)
1630 ])
1631
1632 dnl ----------------------
1633 dnl checking for IP_RECVIF
1634 dnl ----------------------
1635 AC_MSG_CHECKING(for IP_RECVIF)
1636 AC_TRY_COMPILE([#include <netinet/in.h>], [
1637   int opt = IP_RECVIF;
1638 ], [
1639   AC_MSG_RESULT(yes)
1640   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1641 ], [
1642   AC_MSG_RESULT(no)
1643 ])
1644
1645 dnl ----------------------
1646 dnl checking for SO_BINDANY
1647 dnl ----------------------
1648 AC_MSG_CHECKING(for SO_BINDANY)
1649 AC_TRY_COMPILE([#include <sys/socket.h>], [
1650   int opt = SO_BINDANY;
1651 ], [
1652   AC_MSG_RESULT(yes)
1653   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1654 ], [
1655   AC_MSG_RESULT(no)
1656 ])
1657
1658 dnl ----------------------
1659 dnl checking for IP_FREEBIND
1660 dnl ----------------------
1661 AC_MSG_CHECKING(for IP_FREEBIND)
1662 AC_TRY_COMPILE([#include <netinet/in.h>], [
1663   int opt = IP_FREEBIND;
1664 ], [
1665   AC_MSG_RESULT(yes)
1666   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1667 ], [
1668   AC_MSG_RESULT(no)
1669 ])
1670
1671 dnl --------------------------------------
1672 dnl checking for be32dec existence or not
1673 dnl --------------------------------------
1674 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1675                [#include <sys/endian.h>])
1676
1677 dnl --------------------------------------
1678 dnl checking for clock_time monotonic struct and call
1679 dnl --------------------------------------
1680 AC_CHECK_DECL(CLOCK_MONOTONIC,
1681         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1682          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1683 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1684
1685 dnl --------------------------------------
1686 dnl checking for flex and bison
1687 dnl --------------------------------------
1688
1689 AM_PROG_LEX
1690 AC_MSG_CHECKING(version of flex)
1691 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1692 frr_ac_flex_version="${frr_ac_flex_version##* }"
1693 AC_MSG_RESULT([$frr_ac_flex_version])
1694 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1695   LEX="$SHELL $missing_dir/missing flex"
1696   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1697     AC_MSG_WARN([using pregenerated flex output files])
1698   else
1699     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1700   fi
1701   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1702   AC_SUBST([LEXLIB], [''])
1703 ])
1704
1705 AC_PROG_YACC
1706 dnl thanks GNU bison for this b*llshit...
1707 AC_MSG_CHECKING(version of bison)
1708 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1709 frr_ac_bison_version="${frr_ac_bison_version##* }"
1710 frr_ac_bison_missing="false"
1711 case "x${frr_ac_bison_version}" in
1712   x2.7*)
1713     BISON_OPENBRACE='"'
1714     BISON_CLOSEBRACE='"'
1715     BISON_VERBOSE=''
1716     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1717     ;;
1718   x2.*|x1.*)
1719     AC_MSG_RESULT([$frr_ac_bison_version])
1720     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1721     frr_ac_bison_missing="true"
1722     ;;
1723   x)
1724     AC_MSG_RESULT([none])
1725     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1726     frr_ac_bison_missing="true"
1727     ;;
1728   *)
1729     BISON_OPENBRACE='{'
1730     BISON_CLOSEBRACE='}'
1731     BISON_VERBOSE='-Dparse.error=verbose'
1732     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1733     ;;
1734 esac
1735 AC_SUBST(BISON_OPENBRACE)
1736 AC_SUBST(BISON_CLOSEBRACE)
1737 AC_SUBST(BISON_VERBOSE)
1738
1739 if $frr_ac_bison_missing; then
1740   YACC="$SHELL $missing_dir/missing bison -y"
1741   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1742     AC_MSG_WARN([using pregenerated bison output files])
1743   else
1744     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1745   fi
1746 fi
1747
1748 dnl -------------------
1749 dnl capabilities checks
1750 dnl -------------------
1751 if test "${enable_capabilities}" != "no"; then
1752   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1753   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1754     [AC_MSG_RESULT(yes)
1755      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1756      frr_ac_keepcaps="yes"],
1757      AC_MSG_RESULT(no)
1758   )
1759   if test x"${frr_ac_keepcaps}" = x"yes"; then
1760     AC_CHECK_HEADERS(sys/capability.h)
1761   fi
1762   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1763     AC_CHECK_LIB(cap, cap_init,
1764       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1765        LIBCAP="-lcap"
1766        frr_ac_lcaps="yes"]
1767     )
1768   else
1769     AC_CHECK_HEADERS(priv.h,
1770      [AC_MSG_CHECKING(Solaris style privileges are available)
1771       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1772           [AC_MSG_RESULT(yes)
1773            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1774            frr_ac_scaps="yes"],
1775            AC_MSG_RESULT(no)
1776       )
1777      ]
1778    )
1779   fi
1780   if test x"${frr_ac_scaps}" = x"yes" \
1781        -o x"${frr_ac_lcaps}" = x"yes"; then
1782     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1783   fi
1784 fi
1785 AC_SUBST(LIBCAP)
1786
1787 dnl ---------------------------
1788 dnl check for glibc 'backtrace'
1789 dnl ---------------------------
1790 if test x"${enable_backtrace}" != x"no" ; then
1791   backtrace_ok=no
1792   AC_CHECK_HEADER([execinfo.h], [
1793     AC_SEARCH_LIBS([backtrace], [execinfo], [
1794       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1795       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1796       backtrace_ok=yes
1797     ],, [-lm])
1798   ])
1799
1800   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1801     dnl user explicitly requested backtrace but we failed to find support
1802     AC_MSG_FAILURE([failed to find backtrace support])
1803   fi
1804 fi
1805
1806 dnl -----------------------------------------
1807 dnl check for malloc mallinfo struct and call
1808 dnl this must try and link using LIBS, in
1809 dnl order to check no alternative allocator
1810 dnl has been specified, which might not provide
1811 dnl mallinfo, e.g. such as Umem on Solaris.
1812 dnl -----------------------------------------
1813 AC_CHECK_HEADERS([malloc.h malloc/malloc.h],,, [FRR_INCLUDES])
1814
1815 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1816   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1817 #ifdef HAVE_MALLOC_H
1818 #include <malloc.h>
1819 #endif
1820 #ifdef HAVE_MALLOC_MALLOC_H
1821 #include <malloc/malloc.h>
1822 #endif
1823 ]], [[
1824 struct mallinfo ac_x; ac_x = mallinfo ();
1825 ]])], [
1826     frr_cv_mallinfo=yes
1827   ], [
1828     frr_cv_mallinfo=no
1829   ])
1830 ])
1831 if test "$frr_cv_mallinfo" = yes; then
1832   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1833 fi
1834
1835 AC_MSG_CHECKING(whether malloc_usable_size is available)
1836 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1837 #ifdef HAVE_MALLOC_H
1838 #include <malloc.h>
1839 #endif
1840 #ifdef HAVE_MALLOC_MALLOC_H
1841 #include <malloc/malloc.h>
1842 #endif
1843 ]], [[
1844 size_t ac_x; ac_x = malloc_usable_size(NULL);
1845 ]])], [
1846   AC_MSG_RESULT(yes)
1847   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1848 ], [
1849   AC_MSG_RESULT(no)
1850
1851   AC_MSG_CHECKING(whether malloc_size is available)
1852   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1853 #ifdef HAVE_MALLOC_H
1854 #include <malloc.h>
1855 #endif
1856 #ifdef HAVE_MALLOC_MALLOC_H
1857 #include <malloc/malloc.h>
1858 #endif
1859 ]], [[
1860 size_t ac_x; ac_x = malloc_size(NULL);
1861 ]])], [
1862     AC_MSG_RESULT(yes)
1863     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1864   ], [
1865     AC_MSG_RESULT(no)
1866   ])
1867 ])
1868
1869 dnl ------
1870 dnl ZeroMQ
1871 dnl ------
1872 if test "x$enable_zeromq" != "xno"; then
1873   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1874     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1875     ZEROMQ=true
1876   ], [
1877     if test "x$enable_zeromq" = "xyes"; then
1878       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1879     fi
1880   ])
1881 fi
1882 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1883
1884 dnl ----------
1885 dnl configure date
1886 dnl ----------
1887 dev_version=`echo $VERSION | grep dev`
1888 #don't expire deprecated code in non 'dev' branch
1889 if test "${dev_version}" = ""; then
1890    CONFDATE=0
1891 else
1892    CONFDATE=`date '+%Y%m%d'`
1893 fi
1894 AC_SUBST(CONFDATE)
1895
1896 dnl ------------------------------
1897 dnl set paths for state directory
1898 dnl ------------------------------
1899 AC_MSG_CHECKING(directory to use for state file)
1900 if test "${prefix}" = "NONE"; then
1901   frr_statedir_prefix="";
1902 else
1903   frr_statedir_prefix=${prefix}
1904 fi
1905 if test "${localstatedir}" = '${prefix}/var'; then
1906   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1907                         ${frr_statedir_prefix}/var/adm dnl
1908                         ${frr_statedir_prefix}/etc dnl
1909                         /var/run        dnl
1910                         /var/adm        dnl
1911                         /etc            dnl
1912                         /dev/null;
1913   do
1914     test -d $FRR_STATE_DIR && break
1915   done
1916   frr_statedir=$FRR_STATE_DIR
1917 else
1918   frr_statedir=${localstatedir}
1919 fi
1920 if test $frr_statedir = "/dev/null"; then
1921     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1922 fi
1923 AC_MSG_RESULT(${frr_statedir})
1924 AC_SUBST(frr_statedir)
1925
1926 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1927 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1928 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1929 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1930
1931 dnl autoconf does this, but it does it too late...
1932 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1933 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1934
1935 dnl get the full path, recursing through variables...
1936 vtysh_bin="$bindir/vtysh"
1937 for I in 1 2 3 4 5 6 7 8 9 10; do
1938         eval vtysh_bin="\"$vtysh_bin\""
1939 done
1940 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1941
1942 CFG_SYSCONF="$sysconfdir"
1943 CFG_SBIN="$sbindir"
1944 CFG_STATE="$frr_statedir"
1945 CFG_MODULE="$moduledir"
1946 for I in 1 2 3 4 5 6 7 8 9 10; do
1947         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1948         eval CFG_SBIN="\"$CFG_SBIN\""
1949         eval CFG_STATE="\"$CFG_STATE\""
1950         eval CFG_MODULE="\"$CFG_MODULE\""
1951 done
1952 AC_SUBST(CFG_SYSCONF)
1953 AC_SUBST(CFG_SBIN)
1954 AC_SUBST(CFG_STATE)
1955 AC_SUBST(CFG_MODULE)
1956 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1957
1958 dnl ------------------------------------
1959 dnl Enable RPKI and add librtr to libs
1960 dnl ------------------------------------
1961 if test "${enable_rpki}" = "yes"; then
1962   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1963       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1964       RPKI=true],
1965       [RPKI=false
1966       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1967   )
1968 fi
1969 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1970
1971 dnl ------------------------------------------
1972 dnl Check whether rtrlib was build with ssh support
1973 dnl ------------------------------------------
1974 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1975 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1976                         [[struct tr_ssh_config config;]])],
1977         [AC_MSG_RESULT(yes)
1978         AC_DEFINE(FOUND_SSH,,found_ssh)],
1979         AC_MSG_RESULT(no)
1980 )
1981
1982 dnl ---------------------------
1983 dnl Check htonl works correctly
1984 dnl ---------------------------
1985 AC_MSG_CHECKING(for working htonl)
1986 AC_CACHE_VAL(ac_cv_htonl_works,
1987  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1988                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1989  ]
1990 )
1991 AC_MSG_RESULT($ac_cv_htonl_works)
1992
1993 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
1994
1995 AC_CONFIG_FILES([
1996           tests/Makefile
1997           redhat/frr.spec
1998           solaris/Makefile
1999           debianpkg/changelog
2000           alpine/APKBUILD
2001           snapcraft/snapcraft.yaml
2002           lib/version.h
2003           tests/lib/cli/test_cli.refout
2004           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2005           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2006           pkgsrc/eigrpd.sh])
2007
2008 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2009
2010 AC_CONFIG_COMMANDS([lib/route_types.h], [
2011         dst="${ac_abs_top_builddir}/lib/route_types.h"
2012         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2013                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2014                 > "${dst}.tmp"
2015         test -f "${dst}" \
2016                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2017                 && rm "${dst}.tmp" \
2018                 || mv "${dst}.tmp" "${dst}"
2019 ], [
2020         PERL="$PERL"
2021 ])
2022
2023 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2024     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2025         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2026         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2027                 "${ac_abs_top_srcdir}" \
2028                 > "${dst}.tmp"
2029         test -f "${dst}" \
2030                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2031                 && rm "${dst}.tmp" \
2032                 || mv "${dst}.tmp" "${dst}"
2033     ], [
2034         PERL="$PERL"
2035     ])
2036 ])
2037
2038 ## Hack, but working solution to avoid rebuilding of frr.info.
2039 ## It's already in CVS until texinfo 4.7 is more common.
2040 AC_OUTPUT
2041
2042 echo "
2043 FRRouting configuration
2044 ------------------------------
2045 FRR version             : ${PACKAGE_VERSION}
2046 host operating system   : ${host_os}
2047 source code location    : ${srcdir}
2048 compiler                : ${CC}
2049 compiler flags          : ${CFLAGS}
2050 make                    : ${MAKE-make}
2051 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2052 state file directory    : ${frr_statedir}
2053 config file directory   : `eval echo \`echo ${sysconfdir}\``
2054 example directory       : `eval echo \`echo ${exampledir}\``
2055 module directory        : ${CFG_MODULE}
2056 user to run as          : ${enable_user}
2057 group to run as         : ${enable_group}
2058 group for vty sockets   : ${enable_vty_group}
2059 config file mask        : ${enable_configfile_mask}
2060 log file mask           : ${enable_logfile_mask}
2061 zebra protobuf enabled  : ${have_protobuf:-no}
2062
2063 The above user and group must have read/write access to the state file
2064 directory and to the config files in the config file directory."
2065
2066 if test "${enable_doc}" != "no";then
2067   AS_IF([test "x$SPHINXBUILD" = xno],
2068      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2069 fi