configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.2-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" == "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_ENABLE(tcmalloc,
 143         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 144 [case "${enableval}" in
 145   yes) tcmalloc_enabled=true
 146 LIBS="$LIBS -ltcmalloc_minimal"
 147  ;;
 148   no)  tcmalloc_enabled=false ;;
 149   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 150 esac],[tcmalloc_enabled=false])
 151
 152
 153 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 154 dnl flag determination logic.
 155 CFLAGS="${CFLAGS:-}"
 156
 157 dnl --------------------
 158 dnl Check CC and friends
 159 dnl --------------------
 160 dnl note orig_cflags is also used further down
 161 orig_cflags="$CFLAGS"
 162 orig_cxxflags="$CXXFLAGS"
 163 AC_LANG([C])
 164 AC_PROG_CC
 165 AC_PROG_CPP
 166 AC_PROG_CXX
 167 AM_PROG_CC_C_O
 168 dnl remove autoconf default "-g -O2"
 169 CFLAGS="$orig_cflags"
 170 CXXFLAGS="$orig_cxxflags"
 171 AC_PROG_CC_C99
 172 dnl NB: see C11 below
 173
 174 PKG_PROG_PKG_CONFIG
 175
 176 dnl it's 2019, sed is sed.
 177 SED=sed
 178 AC_SUBST([SED])
 179
 180 dnl try and enable CFLAGS that are useful for FRR
 181 dnl - specifically, options to control warnings
 182
 183 AC_USE_SYSTEM_EXTENSIONS
 184 AC_DEFUN([AC_C_FLAG], [{
 185     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 186     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 187         AC_LANG_PUSH([C])
 188         ac_c_flag_save="$CFLAGS"
 189         CFLAGS="$CFLAGS $1"
 190         AC_COMPILE_IFELSE(
 191                 [AC_LANG_PROGRAM([[]])],
 192                 [
 193                         cachename=yes
 194                 ], [
 195                         cachename=no
 196                 ])
 197         CFLAGS="$ac_c_flag_save"
 198         AC_LANG_POP([C])
 199     ])
 200     if test "${cachename}" = yes; then
 201         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 202     else
 203         :
 204         $2
 205     fi
 206     m4_popdef([cachename])
 207 }])
 208
 209 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 210         AC_LANG_PUSH([C])
 211         ac_cflags_save="$CFLAGS"
 212         ac_libs_save="$LIBS"
 213         CFLAGS="$CFLAGS $1"
 214         LIBS="$LIBS $2"
 215         AC_LINK_IFELSE(
 216                 [$3],
 217                 [
 218                         CFLAGS="$ac_cflags_save"
 219                         LIBS="$ac_libs_save"
 220                         m4_default([$5], [
 221                                 AC_MSG_RESULT([yes])
 222                         ])
 223                 ], [
 224                         CFLAGS="$ac_cflags_save"
 225                         LIBS="$ac_libs_save"
 226                         m4_default([$4], [
 227                                 AC_MSG_RESULT([no])
 228                         ])
 229                 ])
 230         AC_LANG_POP([C])
 231         }])
 232
 233 dnl ICC won't bail on unknown options without -diag-error 10006
 234 dnl need to do this first so we get useful results for the other options
 235 AC_C_FLAG([-diag-error 10006])
 236
 237 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 238 ac_cc="$CC"
 239 CC="${CC% -std=gnu99}"
 240 CC="${CC% -std=c99}"
 241
 242 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 243
 244 dnl if the user has specified any CFLAGS, override our settings
 245 if test "x${enable_gcov}" = "xyes"; then
 246    if test "z$orig_cflags" = "z"; then
 247       AC_C_FLAG([-coverage])
 248       AC_C_FLAG([-O0])
 249    fi
 250
 251    LDFLAGS="${LDFLAGS} -lgcov"
 252 elif test "x${enable_dev_build}" = "xyes"; then
 253    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 254    if test "z$orig_cflags" = "z"; then
 255       AC_C_FLAG([-g3])
 256       AC_C_FLAG([-O0])
 257    fi
 258    if test "x${enable_lua}" = "xyes"; then
 259       AX_PROG_LUA([5.3])
 260       AX_LUA_HEADERS
 261       AX_LUA_LIBS([
 262          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 263          LIBS="$LIBS $LUA_LIB"
 264       ])
 265    fi
 266 else
 267    if test "x${enable_lua}" = "xyes"; then
 268       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 269    fi
 270    if test "z$orig_cflags" = "z"; then
 271       AC_C_FLAG([-g])
 272       AC_C_FLAG([-O2])
 273    fi
 274 fi
 275 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 276
 277 dnl always want these CFLAGS
 278 AC_C_FLAG([-fno-omit-frame-pointer])
 279 AC_C_FLAG([-funwind-tables])
 280 AC_C_FLAG([-Wall])
 281 AC_C_FLAG([-Wextra])
 282 AC_C_FLAG([-Wmissing-prototypes])
 283 AC_C_FLAG([-Wmissing-declarations])
 284 AC_C_FLAG([-Wpointer-arith])
 285 AC_C_FLAG([-Wbad-function-cast])
 286 AC_C_FLAG([-Wwrite-strings])
 287 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 288   AC_C_FLAG([-Wcast-qual])
 289   AC_C_FLAG([-Wstrict-prototypes])
 290   AC_C_FLAG([-Wmissing-noreturn])
 291   AC_C_FLAG([-Wmissing-format-attribute])
 292   AC_C_FLAG([-Wunreachable-code])
 293   AC_C_FLAG([-Wpacked])
 294   AC_C_FLAG([-Wpadded])
 295   AC_C_FLAG([-Wshadow])
 296 else
 297   AC_C_FLAG([-Wno-unused-result])
 298 fi
 299 AC_C_FLAG([-Wno-unused-parameter])
 300 AC_C_FLAG([-Wno-missing-field-initializers])
 301
 302 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 303 AC_SUBST([CXX_COMPAT_CFLAGS])
 304
 305 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 306 dnl for some reason the string consts get 'promoted' to char *,
 307 dnl triggering a const to non-const conversion warning.
 308 AC_C_FLAG([-diag-disable 3179])
 309
 310 if test x"${enable_werror}" = x"yes" ; then
 311   WERROR="-Werror"
 312 fi
 313 AC_SUBST([WERROR])
 314
 315 SAN_FLAGS=""
 316 if test "$enable_address_sanitizer" = "yes"; then
 317   AC_C_FLAG([-fsanitize=address], [
 318     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 319   ], [
 320     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 321   ])
 322 fi
 323 if test "$enable_thread_sanitizer" = "yes"; then
 324   AC_C_FLAG([-fsanitize=thread], [
 325     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 326   ], [
 327     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 328   ])
 329 fi
 330 if test "$enable_memory_sanitizer" = "yes"; then
 331   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 332     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 333   ], [
 334     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 335   ])
 336 fi
 337 AC_SUBST([SAN_FLAGS])
 338
 339 dnl ----------
 340 dnl Essentials
 341 dnl ----------
 342
 343 AX_PTHREAD([
 344   CC="$PTHREAD_CC"
 345   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 346   LIBS="$PTHREAD_LIBS $LIBS"
 347 ], [
 348   AC_MSG_FAILURE([This FRR version needs pthreads])
 349 ])
 350
 351 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 352                 [frr_cv_pthread_condattr_setclock=yes],
 353                 [frr_cv_pthread_condattr_setclock=no])
 354 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 355   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 356 fi
 357
 358 dnl --------------
 359 dnl Check programs
 360 dnl --------------
 361 AC_PROG_INSTALL
 362 AC_PROG_LN_S
 363 AC_CHECK_TOOL([AR], [ar])
 364
 365 dnl -------
 366 dnl libtool
 367 dnl -------
 368 AC_ARG_ENABLE([static-bin],
 369   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 370 LT_INIT
 371 _LT_CONFIG_LIBTOOL([
 372   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 373     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 374 ])
 375 if test "$enable_static_bin" = "yes"; then
 376   AC_LDFLAGS="-static"
 377   if test "$enable_static" != "yes"; then
 378     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 379   fi
 380 fi
 381 if test "$enable_shared" != "yes"; then
 382   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 383 fi
 384 AC_SUBST([AC_LDFLAGS])
 385 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 386
 387 dnl $AR and $RANLIB are set by LT_INIT above
 388 AC_MSG_CHECKING([whether $AR supports D option])
 389 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 390   AC_MSG_RESULT([yes])
 391   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 392   ARFLAGS="crD"
 393   AR_FLAGS="crD"
 394 else
 395   AC_MSG_RESULT([no])
 396   ARFLAGS="cru"
 397   AR_FLAGS="cru"
 398 fi
 399 AC_SUBST([ARFLAGS])
 400 AC_SUBST([AR_FLAGS])
 401
 402 AC_MSG_CHECKING([whether $RANLIB supports D option])
 403 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 404   if grep -q -- '-D' conftest.err; then
 405     AC_MSG_RESULT([no])
 406   else
 407     AC_MSG_RESULT([yes])
 408     RANLIB="$RANLIB -D"
 409   fi
 410 else
 411   AC_MSG_RESULT([no])
 412 fi
 413 AC_SUBST([RANLIB])
 414
 415 test -f conftest.err && rm conftest.err
 416 test -f conftest.a && rm conftest.a
 417
 418 dnl ----------------------
 419 dnl Packages configuration
 420 dnl ----------------------
 421 if test -f config.version; then
 422   . ./config.version
 423 elif test -f "${srcdir}/config.version"; then
 424   . "${srcdir}/config.version"
 425 fi
 426 AC_ARG_WITH([pkg-extra-version],
 427   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 428   if test "$withval" = "no"; then
 429     EXTRAVERSION=
 430   else
 431     EXTRAVERSION=$withval
 432   fi
 433 ], [])
 434 AC_ARG_WITH([pkg-git-version],
 435         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 436         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 437 AC_ARG_WITH([clippy],
 438   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 439 AC_ARG_WITH([vtysh_pager],
 440         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 441         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 442 AC_ARG_ENABLE([vtysh],
 443   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 444 AC_ARG_ENABLE([doc],
 445   AS_HELP_STRING([--disable-doc], [do not build docs]))
 446 AC_ARG_ENABLE([doc-html],
 447   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 448 AC_ARG_ENABLE([zebra],
 449   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 450 AC_ARG_ENABLE([bgpd],
 451   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 452 AC_ARG_ENABLE([ripd],
 453   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 454 AC_ARG_ENABLE([ripngd],
 455   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 456 AC_ARG_ENABLE([ospfd],
 457   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 458 AC_ARG_ENABLE([ospf6d],
 459   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 460 AC_ARG_ENABLE([ldpd],
 461   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 462 AC_ARG_ENABLE([nhrpd],
 463   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 464 AC_ARG_ENABLE([eigrpd],
 465   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 466 AC_ARG_ENABLE([babeld],
 467   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 468 AC_ARG_ENABLE([watchfrr],
 469   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 470 AC_ARG_ENABLE([isisd],
 471   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 472 AC_ARG_ENABLE([pimd],
 473   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 474 AC_ARG_ENABLE([pbrd],
 475   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 476 AC_ARG_ENABLE([sharpd],
 477   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 478 AC_ARG_ENABLE([staticd],
 479   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 480 AC_ARG_ENABLE([fabricd],
 481   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 482 AC_ARG_ENABLE([bgp-announce],
 483   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 484 AC_ARG_ENABLE([vrrpd],
 485   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 486 AC_ARG_ENABLE([bgp-vnc],
 487   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 488 AC_ARG_ENABLE([snmp],
 489   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 490 AC_ARG_ENABLE([config_rollbacks],
 491   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 492 AC_ARG_ENABLE([confd],
 493   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 494 AC_ARG_ENABLE([sysrepo],
 495   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 496 AC_ARG_ENABLE([grpc],
 497   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 498 AC_ARG_ENABLE([zeromq],
 499   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 500 AC_ARG_WITH([libpam],
 501   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 502 AC_ARG_ENABLE([ospfapi],
 503   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 504 AC_ARG_ENABLE([ospfclient],
 505   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 506                           (this is the default if --disable-ospfapi is set)]))
 507 AC_ARG_ENABLE([multipath],
 508   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 509 AC_ARG_ENABLE([user],
 510   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 511 AC_ARG_ENABLE([group],
 512   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 513 AC_ARG_ENABLE([vty_group],
 514   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 515 AC_ARG_ENABLE([configfile_mask],
 516   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 517 AC_ARG_ENABLE([logfile_mask],
 518   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 519 AC_ARG_ENABLE([shell_access],
 520   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 521 AC_ARG_ENABLE([realms],
 522   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 523 AC_ARG_ENABLE([rtadv],
 524   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 525 AC_ARG_ENABLE([irdp],
 526   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 527 AC_ARG_ENABLE([capabilities],
 528   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 529 AC_ARG_ENABLE([rusage],
 530   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 531 AC_ARG_ENABLE([gcc_ultra_verbose],
 532   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 533 AC_ARG_ENABLE([backtrace],
 534   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 535 AC_ARG_ENABLE([time-check],
 536   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 537 AC_ARG_ENABLE([pcreposix],
 538   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 539 AC_ARG_ENABLE([fpm],
 540   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 541 AC_ARG_ENABLE([systemd],
 542   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 543 AC_ARG_ENABLE([werror],
 544   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 545 AC_ARG_ENABLE([cumulus],
 546   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 547 AC_ARG_ENABLE([datacenter],
 548   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 549 AC_ARG_ENABLE([fuzzing],
 550   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 551 AC_ARG_ENABLE([netlink_fuzzing],
 552   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 553 AC_ARG_ENABLE([rr-semantics],
 554   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 555 AC_ARG_ENABLE([protobuf],
 556   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 557 AC_ARG_ENABLE([oldvpn_commands],
 558   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 559 AC_ARG_ENABLE([rpki],
 560   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 561 AC_ARG_ENABLE([clippy-only],
 562   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 563 AC_ARG_ENABLE([numeric_version],
 564   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 565 AC_ARG_ENABLE([gcov],
 566   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 567 AC_ARG_ENABLE([bfdd],
 568   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 569 AC_ARG_ENABLE([address-sanitizer],
 570   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 571 AC_ARG_ENABLE([thread-sanitizer],
 572   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 573 AC_ARG_ENABLE([memory-sanitizer],
 574   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 575
 576 AS_IF([test "${enable_clippy_only}" != "yes"], [
 577 AC_CHECK_HEADERS([json-c/json.h])
 578 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 579 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 580   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 581   if test "$ac_cv_lib_json_json_object_get" = no; then
 582       AC_MSG_ERROR([libjson is needed to compile])
 583   fi
 584 fi
 585 ])
 586
 587 AC_ARG_ENABLE([dev_build],
 588     AS_HELP_STRING([--enable-dev-build], [build for development]))
 589
 590 AC_ARG_ENABLE([lua],
 591     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 592
 593 if test x"${enable_time_check}" != x"no" ; then
 594   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 595     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 596   else
 597     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 598   fi
 599 fi
 600
 601 case "${enable_systemd}" in
 602   "no") ;;
 603   "yes")
 604   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 605   if test $ac_cv_lib_systemd_sd_notify = no; then
 606     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 607   else
 608     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 609   fi
 610   ;;
 611   "*") ;;
 612 esac
 613
 614 if test "${enable_rr_semantics}" != "no" ; then
 615   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 616 fi
 617
 618 if test "${enable_datacenter}" = "yes" ; then
 619   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 620   DFLT_NAME="datacenter"
 621 else
 622   DFLT_NAME="traditional"
 623 fi
 624
 625 if test "${enable_fuzzing}" = "yes" ; then
 626   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 627 fi
 628
 629 if test "${enable_netlink_fuzzing}" = "yes" ; then
 630   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 631 fi
 632
 633 if test "${enable_cumulus}" = "yes" ; then
 634   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 635 fi
 636
 637 AC_SUBST([DFLT_NAME])
 638 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 639
 640 if test "${enable_shell_access}" = "yes"; then
 641    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 642 fi
 643
 644 #
 645 # Python for clippy
 646 #
 647
 648 AS_IF([test "$host" = "$build"], [
 649   FRR_PYTHON_DEV
 650 ], [
 651   FRR_PYTHON
 652 ])
 653
 654 FRR_PYTHON_MODULES([pytest])
 655
 656 if test "${enable_doc}" != "no"; then
 657   FRR_PYTHON_MODULES([sphinx], , [
 658     if test "${enable_doc}" = "yes"; then
 659       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 660     fi
 661   ])
 662 fi
 663 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" != "false"])
 664 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
 665
 666 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 667   PYSPHINX="-m sphinx"
 668 ], [
 669   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 670 ])
 671 AC_SUBST([PYSPHINX])
 672
 673 #
 674 # Logic for old vpn commands support.
 675 #
 676 if test "$enable_oldvpn_commands" = "yes"; then
 677    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 678 fi
 679
 680 #
 681 # End of logic for protobuf support.
 682 #
 683
 684 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 685 if test "${enable_rtadv}" != "no"; then
 686   AC_MSG_RESULT([yes])
 687   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 688 else
 689   AC_MSG_RESULT([no])
 690 fi
 691
 692 if test x"${enable_user}" = x"no"; then
 693   enable_user=""
 694 else
 695   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 696     enable_user="frr"
 697   fi
 698   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 699 fi
 700
 701 if test x"${enable_group}" = x"no"; then
 702   enable_group=""
 703 else
 704   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 705     enable_group="frr"
 706   fi
 707   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 708 fi
 709
 710 if test x"${enable_vty_group}" = x"yes" ; then
 711   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 712 elif test x"${enable_vty_group}" != x""; then
 713   if test x"${enable_vty_group}" != x"no"; then
 714     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 715   fi
 716 fi
 717 AC_SUBST([enable_user])
 718 AC_SUBST([enable_group])
 719 AC_SUBST([enable_vty_group])
 720
 721 enable_configfile_mask=${enable_configfile_mask:-0600}
 722 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 723
 724 enable_logfile_mask=${enable_logfile_mask:-0600}
 725 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 726
 727 MPATH_NUM=16
 728
 729 case "${enable_multipath}" in
 730   0)
 731     MPATH_NUM=64
 732     ;;
 733   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 734     MPATH_NUM="${enable_multipath}"
 735     ;;
 736   "")
 737     ;;
 738   *)
 739     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 740     ;;
 741 esac
 742
 743 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 744
 745 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 746
 747 dnl --------------------
 748 dnl Enable code coverage
 749 dnl --------------------
 750 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 751
 752 dnl ------------------------------------
 753 dnl Alpine only accepts numeric versions
 754 dnl ------------------------------------
 755 if test "x${enable_numeric_version}" != "x" ; then
 756   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 757   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 758 fi
 759
 760 dnl -----------------------------------
 761 dnl Add extra version string to package
 762 dnl name, string and version fields.
 763 dnl -----------------------------------
 764 if test "x${EXTRAVERSION}" != "x" ; then
 765   VERSION="${VERSION}${EXTRAVERSION}"
 766   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 767   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 768   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 769 fi
 770 AC_SUBST([EXTRAVERSION])
 771
 772 if test "x$with_pkg_git_version" = "xyes"; then
 773         if test -d "${srcdir}/.git"; then
 774                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 775         else    with_pkg_git_version="no"
 776                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 777         fi
 778 fi
 779 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 780
 781 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 782 if test "x${OBJCOPY}" != "x:"; then
 783   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 784     frr_cv_interp=""
 785     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 786       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 787         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 788       fi
 789       test -f conftest.interp && rm conftest.interp
 790     ])
 791   ])
 792 fi
 793 if test -n "$frr_cv_interp"; then
 794   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 795 fi
 796
 797 dnl -------------------------
 798 dnl Check other header files.
 799 dnl -------------------------
 800 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 801         linux/version.h asm/types.h])
 802
 803 ac_stdatomic_ok=false
 804 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 805 AC_CHECK_HEADER([stdatomic.h],[
 806
 807   AC_MSG_CHECKING([whether _Atomic qualifier works])
 808   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 809 #include <stdatomic.h>
 810 int main(int argc, char **argv) {
 811   _Atomic int i = 0;
 812   return i;
 813 }
 814 ]])], [
 815     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 816     AC_MSG_RESULT([yes])
 817     ac_stdatomic_ok=true
 818   ], [
 819     AC_MSG_RESULT([no])
 820   ])
 821 ])
 822
 823 AS_IF([$ac_stdatomic_ok], [true], [
 824   AC_MSG_CHECKING([for __atomic_* builtins])
 825   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 826 int main(int argc, char **argv) {
 827   volatile int i = 1;
 828   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 829   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 830 }
 831 ]])], [
 832     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 833     AC_MSG_RESULT([yes])
 834   ], [
 835     AC_MSG_RESULT([no])
 836
 837     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 838     AC_MSG_CHECKING([for __sync_* builtins])
 839     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 840 int main(int argc, char **argv) {
 841   volatile int i = 1;
 842   __sync_fetch_and_sub (&i, 1);
 843   return __sync_val_compare_and_swap (&i, 0, 1);
 844 }
 845 ]])], [
 846       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 847       AC_MSG_RESULT([yes])
 848
 849       AC_MSG_CHECKING([for __sync_swap builtin])
 850       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 851 int main(int argc, char **argv) {
 852   volatile int i = 1;
 853   return __sync_swap (&i, 2);
 854 }
 855 ]])], [
 856         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 857         AC_MSG_RESULT([yes])
 858       ], [
 859         AC_MSG_RESULT([no])
 860       ])
 861
 862     ], [
 863       AC_MSG_RESULT([no])
 864       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 865     ])
 866   ])
 867 ])
 868
 869 AC_CHECK_HEADERS([pthread_np.h],,, [
 870 #include <pthread.h>
 871 ])
 872 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 873
 874 needsync=true
 875
 876 AS_IF([$needsync], [
 877   dnl Linux
 878   AC_MSG_CHECKING([for Linux futex() support])
 879   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 880 #ifndef _GNU_SOURCE
 881 #define _GNU_SOURCE
 882 #endif
 883 #include <unistd.h>
 884 #include <limits.h>
 885 #include <sys/time.h>
 886 #include <sys/syscall.h>
 887 #include <linux/futex.h>
 888
 889 int main(void);
 890 ],
 891 [
 892 {
 893   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 894 }
 895 ])], [
 896     AC_MSG_RESULT([yes])
 897     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 898     needsync=false
 899   ], [
 900     AC_MSG_RESULT([no])
 901   ])
 902 ])
 903
 904 AS_IF([$needsync], [
 905   dnl FreeBSD
 906   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 907   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 908 #include <errno.h>
 909 #include <stdlib.h>
 910 #include <sys/types.h>
 911 #include <sys/umtx.h>
 912 int main(void);
 913 ],
 914 [
 915 {
 916   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
 917 }
 918 ])], [
 919     AC_MSG_RESULT([yes])
 920     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
 921     needsync=false
 922   ], [
 923     AC_MSG_RESULT([no])
 924   ])
 925 ])
 926
 927 AS_IF([$needsync], [
 928   dnl OpenBSD patch (not upstream at the time of writing this)
 929   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
 930   AC_MSG_CHECKING([for OpenBSD futex() support])
 931   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 932 #include <sys/futex.h>
 933 int main(void);
 934 ],
 935 [
 936 {
 937   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 938 }
 939 ])], [
 940     AC_MSG_RESULT([yes])
 941     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
 942     needsync=false
 943   ], [
 944     AC_MSG_RESULT([no])
 945   ])
 946 ])
 947
 948 dnl Utility macro to avoid retyping includes all the time
 949 m4_define([FRR_INCLUDES],
 950 [#ifdef SUNOS_5
 951 #define _POSIX_C_SOURCE 200809L
 952 #define __EXTENSIONS__
 953 #endif
 954 #include <stdio.h>
 955 #include <stdlib.h>
 956 #include <stddef.h>
 957 #include <sys/types.h>
 958 /* sys/conf.h depends on param.h on FBSD at least */
 959 #include <sys/param.h>
 960 /* Required for MAXSIG */
 961 #include <signal.h>
 962 #include <sys/socket.h>
 963 #ifdef __APPLE__
 964 # define __APPLE_USE_RFC_3542
 965 #endif
 966 #include <netinet/in.h>
 967 #include <sys/time.h>
 968 #include <time.h>
 969 #include <net/if.h>
 970 ])dnl
 971
 972 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 973 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 974 dnl an additional round for it.
 975
 976 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
 977
 978 m4_define([FRR_INCLUDES],
 979 FRR_INCLUDES
 980 [#if HAVE_NET_IF_VAR_H
 981 # include <net/if_var.h>
 982 #endif
 983 ])dnl
 984
 985 AC_CHECK_HEADERS([netinet/in_var.h \
 986         net/if_dl.h net/netopt.h \
 987         inet/nd.h netinet/ip_icmp.h \
 988         sys/sysctl.h sys/sockio.h sys/conf.h],
 989         [], [], [FRR_INCLUDES])
 990
 991 AC_CHECK_HEADERS([ucontext.h], [], [],
 992 [#ifndef __USE_GNU
 993 #define __USE_GNU
 994 #endif /* __USE_GNU */
 995 FRR_INCLUDES
 996 ])
 997
 998 m4_define([UCONTEXT_INCLUDES],
 999 [#include <ucontext.h>])dnl
1000
1001 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1002   [], [], [UCONTEXT_INCLUDES])
1003 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1004   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1005    [], [], [UCONTEXT_INCLUDES])],
1006   [], [UCONTEXT_INCLUDES])
1007 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1008   [], [], [UCONTEXT_INCLUDES])
1009
1010 m4_define([FRR_INCLUDES],
1011 FRR_INCLUDES
1012 [
1013 #include <sys/un.h>
1014 #include <netinet/in_systm.h>
1015 #if HAVE_NETINET_IN_VAR_H
1016 # include <netinet/in_var.h>
1017 #endif
1018 #if HAVE_NET_IF_DL_H
1019 # include <net/if_dl.h>
1020 #endif
1021 #if HAVE_NET_NETOPT_H
1022 # include <net/netopt.h>
1023 #endif
1024 #include <net/route.h>
1025 #if HAVE_INET_ND_H
1026 # include <inet/nd.h>
1027 #endif
1028 #include <arpa/inet.h>
1029 /* Required for IDRP */
1030 #if HAVE_NETINET_IP_ICMP_H
1031 # include <netinet/ip_icmp.h>
1032 #endif
1033 ])dnl
1034
1035 dnl V6 headers are checked below, after we check for v6
1036
1037 AC_MSG_CHECKING([which operating system interface to use])
1038 case "$host_os" in
1039   sunos* | solaris2*)
1040     AC_MSG_RESULT([Solaris])
1041
1042     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1043     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1044     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1045
1046     AC_CHECK_LIB([socket], [main])
1047     AC_CHECK_LIB([nsl], [main])
1048     AC_CHECK_LIB([umem], [main])
1049     SOLARIS="solaris"
1050     ;;
1051   linux*)
1052     AC_MSG_RESULT([Linux])
1053
1054     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1055     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1056     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1057
1058     dnl Linux has a compilation problem with mixing
1059     dnl netinet/in.h and linux/in6.h they are not
1060     dnl compatible.  There has been discussion on
1061     dnl how to fix it but no real progress on implementation
1062     dnl when they fix it, remove this
1063     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1064     ;;
1065   openbsd*)
1066     AC_MSG_RESULT([OpenBSD])
1067
1068     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1069     AC_DEFINE([KAME], [1], [KAME IPv6])
1070     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1071
1072     if test "x${enable_pimd}" != "xno"; then
1073       case "$host_os" in
1074       openbsd6.0)
1075         ;;
1076       openbsd[6-9]*)
1077         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1078         ;;
1079       esac
1080     fi
1081     ;;
1082   *)
1083     AC_MSG_RESULT([BSD])
1084
1085     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1086     AC_DEFINE([KAME], [1], [KAME IPv6])
1087     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1088     ;;
1089 esac
1090 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1091
1092 AC_SYS_LARGEFILE
1093
1094 dnl ------------------------
1095 dnl Integrated REALMS option
1096 dnl ------------------------
1097 if test "${enable_realms}" = "yes"; then
1098     case "$host_os" in
1099       linux*)
1100        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1101        ;;
1102       *)
1103        echo "Sorry, only Linux has REALMS support"
1104        exit 1
1105        ;;
1106     esac
1107 fi
1108
1109 dnl -------------------------------
1110 dnl Endian-ness check
1111 dnl -------------------------------
1112 AC_WORDS_BIGENDIAN
1113
1114 dnl ---------------
1115 dnl other functions
1116 dnl ---------------
1117 AC_CHECK_FUNCS([ \
1118         strlcat strlcpy \
1119         getgrouplist])
1120
1121 dnl ##########################################################################
1122 dnl LARGE if block spans a lot of "configure"!
1123 if test "${enable_clippy_only}" != "yes"; then
1124 dnl ##########################################################################
1125
1126 #
1127 # Logic for protobuf support.
1128 #
1129 if test "$enable_protobuf" = "yes"; then
1130   # Check for protoc & protoc-c
1131
1132   # protoc is not required, it's only for a "be nice" helper target
1133   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1134
1135   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1136   if test "$PROTOC_C" = "/bin/false"; then
1137     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1138   fi
1139
1140   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1141     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1142   ])
1143   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
1144     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
1145   ])
1146
1147   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1148 fi
1149
1150
1151 dnl ---------------------
1152 dnl Integrated VTY option
1153 dnl ---------------------
1154 case "${enable_vtysh}" in
1155 "no")
1156   VTYSH="";;
1157 *)
1158   VTYSH="vtysh";
1159   AC_DEFINE([VTYSH], [1], [VTY shell])
1160
1161   prev_libs="$LIBS"
1162   AC_CHECK_LIB([readline], [main], [
1163     LIBREADLINE="-lreadline"
1164   ], [
1165     dnl readline failed - it might be incorrectly linked and missing its
1166     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1167     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1168       LIBREADLINE="$ac_cv_search_tputs"
1169     ], [
1170       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1171     ])
1172
1173     dnl re-try with the lib we found above
1174     unset ac_cv_lib_readline_main
1175     AC_CHECK_LIB([readline], [main], [
1176       LIBREADLINE="-lreadline $LIBREADLINE"
1177     ], [
1178       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1179     ], [$LIBREADLINE])
1180   ], [])
1181   LIBS="$prev_libs"
1182
1183   AC_CHECK_HEADER([readline/history.h])
1184   if test $ac_cv_header_readline_history_h = no;then
1185     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1186   fi
1187   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1188   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1189     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1190   fi
1191   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1192   if test "$frr_cv_append_history" = yes; then
1193     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1194   fi
1195   ;;
1196 esac
1197 AC_SUBST([LIBREADLINE])
1198
1199 dnl ----------
1200 dnl PAM module
1201 dnl
1202 dnl FRR detects the PAM library it is built against by checking for a
1203 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1204 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1205 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1206 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1207 dnl of OpenPAM.
1208 dnl ----------
1209 if test "$with_libpam" = "yes"; then
1210   AC_CHECK_HEADER([security/pam_misc.h],
1211     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1212      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1213      pam_conv_func="misc_conv"
1214     ],
1215     [], FRR_INCLUDES)
1216   AC_CHECK_HEADER([security/openpam.h],
1217     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1218      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1219      pam_conv_func="openpam_ttyconv"
1220     ],
1221     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1222   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1223     AC_MSG_WARN([*** pam support will not be built ***])
1224     with_libpam="no"
1225   fi
1226 fi
1227
1228 if test "$with_libpam" = "yes"; then
1229 dnl took this test from proftpds configure.in and suited to our needs
1230 dnl -------------------------------------------------------------------------
1231 dnl
1232 dnl This next check looks funky due to a linker problem with some versions
1233 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1234 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1235 dnl with RedHat 6.2 and Debian 2.2 or better.
1236 AC_CHECK_LIB([pam], [pam_start],
1237   [AC_CHECK_LIB([pam], [$pam_conv_func],
1238     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1239      LIBPAM="-lpam"],
1240     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1241      LIBPAM="-lpam -lpam_misc"]
1242     )
1243   ],
1244
1245   [AC_CHECK_LIB([pam], [pam_end],
1246     [AC_CHECK_LIB([pam], [$pam_conv_func],
1247       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1248        LIBPAM="-lpam -ldl"],
1249       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1250        LIBPAM="-lpam -ldl -lpam_misc"]
1251      )
1252   ],AC_MSG_WARN([*** pam support will not be built ***]),
1253   [-ldl])
1254   ]
1255 )
1256 fi
1257 AC_SUBST([LIBPAM])
1258
1259 dnl -------------------------------
1260 dnl bgpd needs pow() and hence libm
1261 dnl -------------------------------
1262 TMPLIBS="$LIBS"
1263 LIBS=""
1264 AC_SEARCH_LIBS([pow], [m], [
1265   LIBM="$LIBS"
1266 ], [
1267   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1268 ])
1269 LIBS="$TMPLIBS"
1270 AC_SUBST([LIBM])
1271
1272 AC_CHECK_FUNCS([ppoll], [
1273   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1274 ])
1275 AC_CHECK_FUNCS([pollts], [
1276   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1277 ])
1278
1279 AC_CHECK_HEADER([asm-generic/unistd.h],
1280                 [AC_CHECK_DECL(__NR_setns,
1281                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1282                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1283                                ])
1284                  AC_CHECK_FUNCS([setns])]
1285                )
1286
1287 dnl --------------------------
1288 dnl Determine IS-IS I/O method
1289 dnl --------------------------
1290 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1291 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1292 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1293 AC_CHECK_HEADER([net/bpf.h])
1294 AC_CHECK_HEADER([sys/dlpi.h])
1295 AC_MSG_CHECKING([zebra IS-IS I/O method])
1296
1297 case "$host_os" in
1298   linux*)
1299     AC_MSG_RESULT([pfpacket])
1300     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1301     ;;
1302   solaris* | sunos*)
1303     AC_MSG_RESULT([DLPI])
1304     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1305     ;;
1306   *)
1307     if test $ac_cv_header_net_bpf_h = no; then
1308       if test $ac_cv_header_sys_dlpi_h = no; then
1309         AC_MSG_RESULT([none])
1310         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1311           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1312         fi
1313         AC_MSG_WARN([*** IS-IS support will not be built ***])
1314         enable_isisd="no"
1315         enable_fabricd="no"
1316       else
1317         AC_MSG_RESULT([DLPI])
1318       fi
1319       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1320     else
1321       AC_MSG_RESULT([BPF])
1322       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1323     fi
1324     ;;
1325 esac
1326 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1327
1328 dnl ---------------------------------------------------------------
1329 dnl figure out how to specify an interface in multicast sockets API
1330 dnl ---------------------------------------------------------------
1331 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1332
1333 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1334         #include <sys/socket.h>
1335         #include <netinet/in.h>
1336         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1337         #include <linux/types.h>
1338 ])
1339
1340 m4_define([FRR_INCLUDES],
1341 FRR_INCLUDES
1342 [#if HAVE_LINUX_MROUTE_H
1343 # include <linux/mroute.h>
1344 #endif
1345 ])dnl
1346
1347 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1348         #include <sys/socket.h>
1349         #include <sys/types.h>
1350         #include <netinet/in.h>
1351         #include <net/route.h>
1352 ])
1353
1354 m4_define([FRR_INCLUDES],
1355 FRR_INCLUDES
1356 [#if HAVE_NETINET_IP_MROUTE_H
1357 # include <netinet/ip_mroute.h>
1358 #endif
1359 ])dnl
1360
1361 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1362 AC_TRY_COMPILE([#include <sys/param.h>],
1363 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1364   return (0);
1365 #else
1366   #error No support for BSD struct ip_mreq hack detected
1367 #endif],[AC_MSG_RESULT([yes])
1368 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1369 AC_MSG_RESULT([no]))
1370
1371 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1372 AC_TRY_COMPILE([
1373 #include <sys/types.h>
1374 #include <netinet/in.h>
1375 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1376 ], [AC_MSG_RESULT([yes])
1377 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1378 AC_MSG_RESULT([no]))
1379
1380 dnl ---------------------------------------------------------------
1381 dnl figure out how to check link-state
1382 dnl ---------------------------------------------------------------
1383 AC_CHECK_HEADER([net/if_media.h],
1384   [m4_define([LINK_DETECT_INCLUDES],
1385     FRR_INCLUDES
1386     [#include <net/if_media.h>
1387   ])
1388   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1389     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1390     [], LINK_DETECT_INCLUDES)],
1391   [],
1392   FRR_INCLUDES)
1393
1394 dnl ---------------------------------------------------------------
1395 dnl Additional, newer way to check link-state using ifi_link_state.
1396 dnl Not available in all BSD's when ifmediareq available
1397 dnl ---------------------------------------------------------------
1398 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1399   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1400   [], FRR_INCLUDES)
1401
1402 dnl ------------------------
1403 dnl TCP_MD5SIG socket option
1404 dnl ------------------------
1405
1406 AC_CHECK_HEADER([netinet/tcp.h],
1407    [m4_define([MD5_INCLUDES],
1408       FRR_INCLUDES
1409       [#include <netinet/tcp.h>
1410     ])
1411     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1412    [],
1413    FRR_INCLUDES)
1414 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1415   AC_CHECK_HEADER([linux/tcp.h],
1416        [m4_define([MD5_INCLUDES],
1417           FRR_INCLUDES
1418           [#include <linux/tcp.h>
1419         ])
1420        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1421 fi
1422
1423 AC_SUBST([SOLARIS])
1424 AC_CHECK_LIB([crypt], [crypt], [],
1425                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1426 AC_CHECK_LIB([resolv], [res_init])
1427
1428 dnl ---------------------------
1429 dnl check system has PCRE regexp
1430 dnl ---------------------------
1431 if test "x$enable_pcreposix" = "xyes"; then
1432   AC_CHECK_LIB([pcreposix], [regexec], [], [
1433     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1434   ])
1435 fi
1436 AC_SUBST([HAVE_LIBPCREPOSIX])
1437
1438 dnl ##########################################################################
1439 dnl test "${enable_clippy_only}" != "yes"
1440 fi
1441 dnl END OF LARGE if block
1442 dnl ##########################################################################
1443
1444
1445 dnl ----------------------------------------------------------------------------
1446 dnl figure out if domainname is available in the utsname struct (GNU extension).
1447 dnl ----------------------------------------------------------------------------
1448 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1449
1450 dnl ------------------
1451 dnl IPv6 header checks
1452 dnl ------------------
1453 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1454         netinet6/in6_var.h netinet6/nd6.h], [], [],
1455         FRR_INCLUDES)
1456
1457 m4_define([FRR_INCLUDES],dnl
1458 FRR_INCLUDES
1459 [#if HAVE_NETINET6_IN6_H
1460 #include <netinet6/in6.h>
1461 #endif
1462 #if HAVE_NETINET_IN6_VAR_H
1463 #include <netinet/in6_var.h>
1464 #endif
1465 #include <netinet/icmp6.h>
1466 #if HAVE_NETINET6_IN6_VAR_H
1467 # include <netinet6/in6_var.h>
1468 #endif
1469 #if HAVE_NETINET6_ND6_H
1470 # include <netinet6/nd6.h>
1471 #endif
1472 ])dnl
1473
1474 dnl --------------------
1475 dnl Daemon disable check
1476 dnl --------------------
1477
1478 AS_IF([test "${enable_ldpd}" != "no"], [
1479   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1480 ])
1481
1482 if test "$enable_bfdd" = "no"; then
1483   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1484   BFDD=""
1485 else
1486   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1487   BFDD="bfdd"
1488
1489   case $host_os in
1490     linux*)
1491       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1492       ;;
1493
1494     *)
1495       AC_DEFINE([BFD_BSD], [1], [bfdd])
1496       ;;
1497   esac
1498 fi
1499
1500 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1501   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1502 fi
1503
1504 NHRPD=""
1505 case "$host_os" in
1506   linux*)
1507     if test "${enable_nhrpd}" != "no"; then
1508       NHRPD="nhrpd"
1509     fi
1510     ;;
1511   *)
1512     if test "${enable_nhrpd}" = "yes"; then
1513       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1514     fi
1515     ;;
1516 esac
1517
1518 if test "${enable_watchfrr}" = "no";then
1519   WATCHFRR=""
1520 else
1521   WATCHFRR="watchfrr"
1522 fi
1523
1524 OSPFCLIENT=""
1525 if test "${enable_ospfapi}" != "no";then
1526     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1527
1528   if test "${enable_ospfclient}" != "no";then
1529       OSPFCLIENT="ospfclient"
1530   fi
1531 fi
1532
1533 if test "${enable_bgp_announce}" = "no";then
1534   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1535 else
1536   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1537 fi
1538
1539 if test "${enable_bgp_vnc}" != "no";then
1540   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1541 fi
1542
1543 dnl ##########################################################################
1544 dnl LARGE if block
1545 if test "${enable_clippy_only}" != "yes"; then
1546 dnl ##########################################################################
1547
1548 dnl ------------------
1549 dnl check C-Ares library
1550 dnl ------------------
1551 if test "${NHRPD}" != ""; then
1552   PKG_CHECK_MODULES([CARES], [libcares], ,[
1553     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1554   ])
1555 fi
1556
1557
1558 dnl ------------------
1559 dnl check Net-SNMP library
1560 dnl ------------------
1561 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1562    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1563    if test x"$NETSNMP_CONFIG" = x"no"; then
1564       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1565    fi
1566    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1567    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1568    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1569    # among other things we avoid a GPL vs. OpenSSL license conflict here
1570    for removelib in crypto ssl sensors pci wrap; do
1571      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1572    done
1573    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1574    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1575 int main(void);
1576 ],
1577 [
1578 {
1579   return 0;
1580 }
1581 ])], [
1582      AC_MSG_RESULT([no])
1583      AC_MSG_ERROR([--enable-snmp given but not usable])])
1584    case "${enable_snmp}" in
1585      yes)
1586       SNMP_METHOD=agentx
1587       ;;
1588      agentx)
1589       SNMP_METHOD="${enable_snmp}"
1590       ;;
1591      *)
1592       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1593       ;;
1594    esac
1595    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1596    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1597 fi
1598 AC_SUBST([SNMP_LIBS])
1599 AC_SUBST([SNMP_CFLAGS])
1600
1601 dnl ---------------
1602 dnl libyang
1603 dnl ---------------
1604 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.105], , [
1605   AC_MSG_ERROR([libyang (>= 0.16.105) was not found on your system.])
1606 ])
1607 ac_cflags_save="$CFLAGS"
1608 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1609 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1610   AC_MSG_ERROR([m4_normalize([
1611     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1612     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1613   ])
1614 ], [[#include <libyang/libyang.h>]])
1615 CFLAGS="$ac_cflags_save"
1616
1617 dnl ---------------
1618 dnl configuration rollbacks
1619 dnl ---------------
1620 SQLITE3=false
1621 if test "$enable_config_rollbacks" = "yes"; then
1622   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1623     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1624     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1625     SQLITE3=true
1626   ], [
1627     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1628   ])
1629 fi
1630
1631 dnl ---------------
1632 dnl confd
1633 dnl ---------------
1634 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1635    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1636    if test "x$CONFD" = "x/bin/false"; then
1637       AC_MSG_ERROR([confd was not found on your system.])]
1638    fi
1639    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1640    AC_SUBST([CONFD_CFLAGS])
1641    CONFD_LIBS="-lconfd"
1642    AC_SUBST([CONFD_LIBS])
1643    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1644 fi
1645
1646 dnl ---------------
1647 dnl sysrepo
1648 dnl ---------------
1649 if test "$enable_sysrepo" = "yes"; then
1650   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1651       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1652       SYSREPO=true],
1653       [SYSREPO=false
1654       AC_MSG_ERROR([sysrepo was not found on your system.])]
1655   )
1656 fi
1657
1658 dnl ---------------
1659 dnl gRPC
1660 dnl ---------------
1661 if test "$enable_grpc" = "yes"; then
1662   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1663     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1664     if test "$PROTOC" = "/bin/false"; then
1665       AC_MSG_FAILURE([grpc requested but protoc not found.])
1666     fi
1667
1668     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1669     GRPC=true
1670   ], [
1671     GRPC=false
1672     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1673   ])
1674 fi
1675
1676 dnl ------
1677 dnl ZeroMQ
1678 dnl ------
1679 if test "x$enable_zeromq" != "xno"; then
1680   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1681     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1682     ZEROMQ=true
1683   ], [
1684     if test "x$enable_zeromq" = "xyes"; then
1685       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1686     fi
1687   ])
1688 fi
1689
1690 dnl ------------------------------------
1691 dnl Enable RPKI and add librtr to libs
1692 dnl ------------------------------------
1693 if test "${enable_rpki}" = "yes"; then
1694   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1695       [RPKI=true],
1696       [RPKI=false
1697       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1698   )
1699 fi
1700
1701 dnl ------------------------------------------
1702 dnl Check whether rtrlib was build with ssh support
1703 dnl ------------------------------------------
1704 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1705 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1706                         [[struct tr_ssh_config config;]])],
1707         [AC_MSG_RESULT([yes])
1708         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1709         AC_MSG_RESULT([no])
1710 )
1711
1712 dnl ---------------
1713 dnl dlopen & dlinfo
1714 dnl ---------------
1715 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1716   AC_MSG_ERROR([unable to find the dlopen()])
1717 ])
1718
1719 AC_CHECK_HEADERS([link.h])
1720
1721 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1722   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1723 #include <stdlib.h>
1724 #ifdef HAVE_LINK_H
1725 #include <link.h>
1726 #endif
1727 #include <dlfcn.h>
1728 ]], [[
1729   char origin[1];
1730   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1731 ]])], [
1732     frr_cv_rtld_di_origin=yes
1733   ], [
1734     frr_cv_rtld_di_origin=no
1735   ])
1736 ])
1737 if test "$frr_cv_rtld_di_origin" = yes; then
1738   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1739 fi
1740
1741 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1742   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1743 #include <stdlib.h>
1744 #ifdef HAVE_LINK_H
1745 #include <link.h>
1746 #endif
1747 #include <dlfcn.h>
1748 ]], [[
1749   struct link_map *lm = NULL;
1750   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1751 ]])], [
1752     frr_cv_rtld_di_linkmap=yes
1753   ], [
1754     frr_cv_rtld_di_linkmap=no
1755   ])
1756 ])
1757 if test "$frr_cv_rtld_di_linkmap" = yes; then
1758   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1759 fi
1760
1761 dnl ##########################################################################
1762 dnl test "${enable_clippy_only}" != "yes"
1763 fi
1764 dnl END OF LARGE if block
1765 dnl ##########################################################################
1766
1767 dnl ---------------------------
1768 dnl sockaddr and netinet checks
1769 dnl ---------------------------
1770 AC_CHECK_TYPES([
1771         struct sockaddr_dl,
1772         struct vifctl, struct mfcctl, struct sioc_sg_req,
1773         vifi_t, struct sioc_vif_req, struct igmpmsg,
1774         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1775         struct nd_opt_adv_interval,
1776         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1777         struct nd_opt_rdnss, struct nd_opt_dnssl],
1778         [], [], FRR_INCLUDES)
1779
1780 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1781         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1782         struct sockaddr_dl.sdl_len,
1783         struct if6_aliasreq.ifra_lifetime,
1784         struct nd_opt_adv_interval.nd_opt_ai_type],
1785         [], [], FRR_INCLUDES)
1786
1787 dnl ---------------------------
1788 dnl IRDP/pktinfo/icmphdr checks
1789 dnl ---------------------------
1790
1791 AC_CHECK_TYPES([struct in_pktinfo], [
1792   AC_CHECK_TYPES([struct icmphdr], [
1793     IRDP=true
1794   ], [
1795     IRDP=false
1796   ], [FRR_INCLUDES])
1797 ], [
1798   IRDP=false
1799 ], [FRR_INCLUDES])
1800
1801 case "${enable_irdp}" in
1802 yes)
1803   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1804   ;;
1805 no)
1806   IRDP=false
1807   ;;
1808 esac
1809
1810
1811 dnl -----------------------
1812 dnl checking for IP_PKTINFO
1813 dnl -----------------------
1814 AC_MSG_CHECKING([for IP_PKTINFO])
1815 AC_TRY_COMPILE([#include <netdb.h>], [
1816   int opt = IP_PKTINFO;
1817 ], [
1818   AC_MSG_RESULT([yes])
1819   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1820 ], [
1821   AC_MSG_RESULT([no])
1822 ])
1823
1824 dnl ---------------------------
1825 dnl checking for IP_RECVDSTADDR
1826 dnl ---------------------------
1827 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1828 AC_TRY_COMPILE([#include <netinet/in.h>], [
1829   int opt = IP_RECVDSTADDR;
1830 ], [
1831   AC_MSG_RESULT([yes])
1832   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1833 ], [
1834   AC_MSG_RESULT([no])
1835 ])
1836
1837 dnl ----------------------
1838 dnl checking for IP_RECVIF
1839 dnl ----------------------
1840 AC_MSG_CHECKING([for IP_RECVIF])
1841 AC_TRY_COMPILE([#include <netinet/in.h>], [
1842   int opt = IP_RECVIF;
1843 ], [
1844   AC_MSG_RESULT([yes])
1845   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1846 ], [
1847   AC_MSG_RESULT([no])
1848 ])
1849
1850 dnl ----------------------
1851 dnl checking for SO_BINDANY
1852 dnl ----------------------
1853 AC_MSG_CHECKING([for SO_BINDANY])
1854 AC_TRY_COMPILE([#include <sys/socket.h>], [
1855   int opt = SO_BINDANY;
1856 ], [
1857   AC_MSG_RESULT([yes])
1858   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1859 ], [
1860   AC_MSG_RESULT([no])
1861 ])
1862
1863 dnl ----------------------
1864 dnl checking for IP_FREEBIND
1865 dnl ----------------------
1866 AC_MSG_CHECKING([for IP_FREEBIND])
1867 AC_TRY_COMPILE([#include <netinet/in.h>], [
1868   int opt = IP_FREEBIND;
1869 ], [
1870   AC_MSG_RESULT([yes])
1871   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1872 ], [
1873   AC_MSG_RESULT([no])
1874 ])
1875
1876 dnl --------------------------------------
1877 dnl checking for be32dec existence or not
1878 dnl --------------------------------------
1879 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1880                [#include <sys/endian.h>])
1881
1882 dnl --------------------------------------
1883 dnl checking for clock_time monotonic struct and call
1884 dnl --------------------------------------
1885 AC_CHECK_DECL([CLOCK_MONOTONIC],
1886         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1887          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1888 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1889
1890 dnl --------------------------------------
1891 dnl checking for flex and bison
1892 dnl --------------------------------------
1893
1894 AM_PROG_LEX
1895 AC_MSG_CHECKING([version of flex])
1896 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1897 frr_ac_flex_version="${frr_ac_flex_version##* }"
1898 AC_MSG_RESULT([$frr_ac_flex_version])
1899 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1900   LEX="$SHELL $missing_dir/missing flex"
1901   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1902     AC_MSG_WARN([using pregenerated flex output files])
1903   else
1904     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1905   fi
1906   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1907   AC_SUBST([LEXLIB], [''])
1908 ])
1909
1910 AC_PROG_YACC
1911 dnl thanks GNU bison for this b*llshit...
1912 AC_MSG_CHECKING([version of bison])
1913 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1914 frr_ac_bison_version="${frr_ac_bison_version##* }"
1915 frr_ac_bison_missing="false"
1916 case "x${frr_ac_bison_version}x" in
1917   x2.7*)
1918     BISON_OPENBRACE='"'
1919     BISON_CLOSEBRACE='"'
1920     BISON_VERBOSE=''
1921     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1922     ;;
1923   x2.*|x1.*)
1924     AC_MSG_RESULT([$frr_ac_bison_version])
1925     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1926     frr_ac_bison_missing="true"
1927     ;;
1928   x)
1929     AC_MSG_RESULT([none])
1930     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1931     frr_ac_bison_missing="true"
1932     ;;
1933   x3.[012][^0-9]*)
1934     BISON_OPENBRACE='{'
1935     BISON_CLOSEBRACE='}'
1936     BISON_VERBOSE='-Dparse.error=verbose'
1937     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
1938     ;;
1939   *)
1940     BISON_OPENBRACE='{'
1941     BISON_CLOSEBRACE='}'
1942     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
1943     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
1944     ;;
1945 esac
1946 AC_SUBST([BISON_OPENBRACE])
1947 AC_SUBST([BISON_CLOSEBRACE])
1948 AC_SUBST([BISON_VERBOSE])
1949
1950 if $frr_ac_bison_missing; then
1951   YACC="$SHELL $missing_dir/missing bison -y"
1952   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1953     AC_MSG_WARN([using pregenerated bison output files])
1954   else
1955     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1956   fi
1957 fi
1958
1959 dnl -------------------
1960 dnl capabilities checks
1961 dnl -------------------
1962 if test "${enable_capabilities}" != "no"; then
1963   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
1964   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1965     [AC_MSG_RESULT([yes])
1966      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
1967      frr_ac_keepcaps="yes"],
1968      AC_MSG_RESULT([no])
1969   )
1970   if test x"${frr_ac_keepcaps}" = x"yes"; then
1971     AC_CHECK_HEADERS([sys/capability.h])
1972   fi
1973   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1974     AC_CHECK_LIB([cap], [cap_init],
1975       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
1976        LIBCAP="-lcap"
1977        frr_ac_lcaps="yes"]
1978     )
1979   else
1980     AC_CHECK_HEADERS([priv.h],
1981      [AC_MSG_CHECKING([Solaris style privileges are available])
1982       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
1983           [AC_MSG_RESULT([yes])
1984            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
1985            frr_ac_scaps="yes"],
1986            AC_MSG_RESULT(no)
1987       )
1988      ]
1989    )
1990   fi
1991   if test x"${frr_ac_scaps}" = x"yes" \
1992        -o x"${frr_ac_lcaps}" = x"yes"; then
1993     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
1994   fi
1995 fi
1996 AC_SUBST([LIBCAP])
1997
1998 dnl ---------------------------
1999 dnl check for glibc 'backtrace'
2000 dnl ---------------------------
2001 if test x"${enable_backtrace}" != x"no" ; then
2002   backtrace_ok=no
2003   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2004     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2005     backtrace_ok=yes
2006   ], [
2007     case "$host_os" in
2008     sunos* | solaris2*)
2009       AC_CHECK_FUNCS([printstack], [
2010         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2011         backtrace_ok=yes
2012       ])
2013       ;;
2014     esac
2015     if test "$backtrace_ok" = no; then
2016       AC_CHECK_HEADER([execinfo.h], [
2017         AC_SEARCH_LIBS([backtrace], [execinfo], [
2018           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2019           backtrace_ok=yes
2020         ],, [-lm])
2021       ])
2022     fi
2023   ])
2024
2025   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2026     dnl user explicitly requested backtrace but we failed to find support
2027     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2028   fi
2029 fi
2030
2031 dnl -----------------------------------------
2032 dnl check for malloc mallinfo struct and call
2033 dnl this must try and link using LIBS, in
2034 dnl order to check no alternative allocator
2035 dnl has been specified, which might not provide
2036 dnl mallinfo, e.g. such as Umem on Solaris.
2037 dnl -----------------------------------------
2038 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2039
2040 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2041   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2042 #ifdef HAVE_MALLOC_H
2043 #include <malloc.h>
2044 #endif
2045 #ifdef HAVE_MALLOC_NP_H
2046 #include <malloc_np.h>
2047 #endif
2048 #ifdef HAVE_MALLOC_MALLOC_H
2049 #include <malloc/malloc.h>
2050 #endif
2051 ]], [[
2052 struct mallinfo ac_x; ac_x = mallinfo ();
2053 ]])], [
2054     frr_cv_mallinfo=yes
2055   ], [
2056     frr_cv_mallinfo=no
2057   ])
2058 ])
2059 if test "$frr_cv_mallinfo" = yes; then
2060   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2061 fi
2062
2063 AC_MSG_CHECKING([whether malloc_usable_size is available])
2064 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2065 #ifdef HAVE_MALLOC_H
2066 #include <malloc.h>
2067 #endif
2068 #ifdef HAVE_MALLOC_MALLOC_H
2069 #include <malloc/malloc.h>
2070 #endif
2071 ]], [[
2072 size_t ac_x; ac_x = malloc_usable_size(NULL);
2073 ]])], [
2074   AC_MSG_RESULT([yes])
2075   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2076 ], [
2077   AC_MSG_RESULT([no])
2078
2079   AC_MSG_CHECKING([whether malloc_size is available])
2080   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2081 #ifdef HAVE_MALLOC_H
2082 #include <malloc.h>
2083 #endif
2084 #ifdef HAVE_MALLOC_MALLOC_H
2085 #include <malloc/malloc.h>
2086 #endif
2087 ]], [[
2088 size_t ac_x; ac_x = malloc_size(NULL);
2089 ]])], [
2090     AC_MSG_RESULT([yes])
2091     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2092   ], [
2093     AC_MSG_RESULT([no])
2094   ])
2095 ])
2096
2097 dnl ----------
2098 dnl configure date
2099 dnl ----------
2100 dev_version=`echo $VERSION | grep dev`
2101 #don't expire deprecated code in non 'dev' branch
2102 if test "${dev_version}" = ""; then
2103    CONFDATE=0
2104 else
2105    CONFDATE=`date '+%Y%m%d'`
2106 fi
2107 AC_SUBST([CONFDATE])
2108
2109 dnl ------------------------------
2110 dnl set paths for state directory
2111 dnl ------------------------------
2112 AC_MSG_CHECKING([directory to use for state file])
2113 if test "${prefix}" = "NONE"; then
2114   frr_statedir_prefix="";
2115 else
2116   frr_statedir_prefix=${prefix}
2117 fi
2118 if test "${localstatedir}" = '${prefix}/var'; then
2119   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2120                         ${frr_statedir_prefix}/var/adm dnl
2121                         ${frr_statedir_prefix}/etc dnl
2122                         /var/run        dnl
2123                         /var/adm        dnl
2124                         /etc            dnl
2125                         /dev/null;
2126   do
2127     test -d $FRR_STATE_DIR && break
2128   done
2129   frr_statedir=$FRR_STATE_DIR
2130 else
2131   frr_statedir=${localstatedir}
2132 fi
2133 if test $frr_statedir = "/dev/null"; then
2134     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2135 fi
2136 AC_MSG_RESULT([${frr_statedir}])
2137 AC_SUBST([frr_statedir])
2138
2139 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2140 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2141 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2142 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2143 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2144
2145 dnl autoconf does this, but it does it too late...
2146 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2147 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2148
2149 dnl get the full path, recursing through variables...
2150 vtysh_bin="$bindir/vtysh"
2151 for I in 1 2 3 4 5 6 7 8 9 10; do
2152         eval vtysh_bin="\"$vtysh_bin\""
2153 done
2154 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2155 AC_SUBST([vtysh_bin])
2156
2157 CFG_SYSCONF="$sysconfdir"
2158 CFG_SBIN="$sbindir"
2159 CFG_STATE="$frr_statedir"
2160 CFG_MODULE="$moduledir"
2161 CFG_YANGMODELS="$yangmodelsdir"
2162 for I in 1 2 3 4 5 6 7 8 9 10; do
2163         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2164         eval CFG_SBIN="\"$CFG_SBIN\""
2165         eval CFG_STATE="\"$CFG_STATE\""
2166         eval CFG_MODULE="\"$CFG_MODULE\""
2167         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2168 done
2169 AC_SUBST([CFG_SYSCONF])
2170 AC_SUBST([CFG_SBIN])
2171 AC_SUBST([CFG_STATE])
2172 AC_SUBST([CFG_MODULE])
2173 AC_SUBST([CFG_YANGMODELS])
2174 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2175 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2176 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2177
2178 dnl various features
2179 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
2180 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
2181 dnl northbound
2182 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2183 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
2184 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
2185 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
2186 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2187 dnl plugins
2188 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2189 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
2190 AM_CONDITIONAL([IRDP], [$IRDP])
2191 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
2192 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
2193 dnl daemons
2194 AM_CONDITIONAL([VTYSH], [test "x$VTYSH" = "xvtysh"])
2195 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
2196 AM_CONDITIONAL([BGPD], [test "x${enable_bgpd}" != "no"])
2197 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
2198 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
2199 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
2200 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
2201 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
2202 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
2203 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
2204 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
2205 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
2206 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
2207 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
2208 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
2209 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
2210 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
2211 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
2212 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
2213 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
2214 AM_CONDITIONAL([VRRPD], [test "${enable_vrrpd}" != "no"])
2215
2216 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2217
2218 AC_CONFIG_FILES([
2219           config.version
2220           changelog-auto
2221           redhat/frr.spec
2222           solaris/Makefile
2223           alpine/APKBUILD
2224           snapcraft/snapcraft.yaml
2225           lib/version.h
2226           tests/lib/cli/test_cli.refout
2227           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2228           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2229           pkgsrc/eigrpd.sh])
2230
2231 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2232 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2233 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2234 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2235 AC_CONFIG_FILES([tools/frrcommon.sh])
2236
2237 AC_CONFIG_COMMANDS([lib/route_types.h], [
2238         dst="${ac_abs_top_builddir}/lib/route_types.h"
2239         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2240                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2241                 > "${dst}.tmp"
2242         test -f "${dst}" \
2243                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2244                 && rm "${dst}.tmp" \
2245                 || mv "${dst}.tmp" "${dst}"
2246 ], [
2247         PERL="$PERL"
2248 ])
2249
2250 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2251     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2252         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2253         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2254                 "${ac_abs_top_srcdir}" \
2255                 > "${dst}.tmp"
2256         test -f "${dst}" \
2257                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2258                 && rm "${dst}.tmp" \
2259                 || mv "${dst}.tmp" "${dst}"
2260     ], [
2261         PERL="$PERL"
2262     ])
2263 ])
2264
2265 ## Hack, but working solution to avoid rebuilding of frr.info.
2266 ## It's already in CVS until texinfo 4.7 is more common.
2267 AC_OUTPUT
2268
2269 echo "
2270 FRRouting configuration
2271 ------------------------------
2272 FRR version             : ${PACKAGE_VERSION}
2273 host operating system   : ${host_os}
2274 source code location    : ${srcdir}
2275 compiler                : ${CC}
2276 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2277 make                    : ${MAKE-make}
2278 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2279 state file directory    : ${frr_statedir}
2280 config file directory   : `eval echo \`echo ${sysconfdir}\``
2281 example directory       : `eval echo \`echo ${exampledir}\``
2282 module directory        : ${CFG_MODULE}
2283 user to run as          : ${enable_user}
2284 group to run as         : ${enable_group}
2285 group for vty sockets   : ${enable_vty_group}
2286 config file mask        : ${enable_configfile_mask}
2287 log file mask           : ${enable_logfile_mask}
2288 zebra protobuf enabled  : ${enable_protobuf:-no}
2289
2290 The above user and group must have read/write access to the state file
2291 directory and to the config files in the config file directory."
2292
2293 if test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" = false; then
2294   AC_MSG_WARN([sphinx is missing but required to build documentation])
2295 fi
2296 if test "$frr_py_mod_pytest" = false; then
2297   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2298 fi