configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.0, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl AddressSanitizer support
 193 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 194               [enabled AddressSanitizer support for detecting a wide variety of \
 195                memory allocation and deallocation errors]), \
 196               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 197               ASAN_FLAGS="-fsanitize=address"
 198               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 199               AC_SUBST([ASAN_FLAGS])
 200               AC_SUBST([SAN_CLIPPY_FLAGS])
 201               LIBS="-ldl $LIBS"
 202               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 203                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 204               ])
 205
 206 dnl ThreadSanitizer support
 207 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 208               [enabled ThreadSanitizer support for detecting data races]), \
 209               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 210               TSAN_FLAGS="-fsanitize=thread"
 211               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 212               AC_SUBST([TSAN_FLAGS])
 213               AC_SUBST([SAN_CLIPPY_FLAGS])
 214               LIBS="-ldl $LIBS"
 215               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 216                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 217               ])
 218
 219 dnl MemorySanitizer support
 220 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 221               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 222               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 223               MSAN_FLAGS="-fsanitize=memory -fPIE -pie"
 224               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 225               AC_SUBST([MSAN_FLAGS])
 226               AC_SUBST([SAN_CLIPPY_FLAGS])
 227               LIBS="-ldl $LIBS"
 228               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 229                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 230               ])
 231
 232 dnl if the user has specified any CFLAGS, override our settings
 233 if test "x${enable_gcov}" = "xyes"; then
 234    if test "z$orig_cflags" = "z"; then
 235       AC_C_FLAG([-coverage])
 236       AC_C_FLAG([-O0])
 237    fi
 238
 239    LDFLAGS="${LDFLAGS} -lgcov"
 240 elif test "x${enable_dev_build}" = "xyes"; then
 241    AC_DEFINE(DEV_BUILD,,Build for development)
 242    if test "z$orig_cflags" = "z"; then
 243       AC_C_FLAG([-g3])
 244       AC_C_FLAG([-O0])
 245    fi
 246 else
 247    if test "z$orig_cflags" = "z"; then
 248       AC_C_FLAG([-g])
 249       AC_C_FLAG([-Os], [
 250         AC_C_FLAG([-O2])
 251       ])
 252    fi
 253 fi
 254 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 255
 256 dnl always want these CFLAGS
 257 AC_C_FLAG([-fno-omit-frame-pointer])
 258 AC_C_FLAG([-funwind-tables])
 259 AC_C_FLAG([-Wall])
 260 AC_C_FLAG([-Wextra])
 261 AC_C_FLAG([-Wmissing-prototypes])
 262 AC_C_FLAG([-Wmissing-declarations])
 263 AC_C_FLAG([-Wpointer-arith])
 264 AC_C_FLAG([-Wbad-function-cast])
 265 AC_C_FLAG([-Wwrite-strings])
 266 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 267   AC_C_FLAG([-Wcast-qual])
 268   AC_C_FLAG([-Wstrict-prototypes])
 269   AC_C_FLAG([-Wmissing-noreturn])
 270   AC_C_FLAG([-Wmissing-format-attribute])
 271   AC_C_FLAG([-Wunreachable-code])
 272   AC_C_FLAG([-Wpacked])
 273   AC_C_FLAG([-Wpadded])
 274 else
 275   AC_C_FLAG([-Wno-unused-result])
 276 fi
 277 AC_C_FLAG([-Wno-unused-parameter])
 278 AC_C_FLAG([-Wno-missing-field-initializers])
 279
 280 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 281 dnl for some reason the string consts get 'promoted' to char *,
 282 dnl triggering a const to non-const conversion warning.
 283 AC_C_FLAG([-diag-disable 3179])
 284
 285 if test x"${enable_werror}" = x"yes" ; then
 286   WERROR="-Werror"
 287 fi
 288 AC_SUBST(WERROR)
 289
 290 dnl need link on this one, not compile
 291 AC_LANG_PUSH(C)
 292 ac_ld_flag_save="$LDFLAGS"
 293 LDFLAGS="$LDFLAGS -rdynamic"
 294 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 295 AC_LINK_IFELSE(
 296         [AC_LANG_PROGRAM([[]])],
 297         [AC_MSG_RESULT([yes])],
 298         [
 299                 LDFLAGS="$ac_ld_flag_save"
 300                 AC_MSG_RESULT([no])
 301         ])
 302 AC_LANG_POP(C)
 303
 304 dnl ----------
 305 dnl Essentials
 306 dnl ----------
 307
 308 AX_PTHREAD([
 309   CC="$PTHREAD_CC"
 310   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 311   LIBS="$PTHREAD_LIBS $LIBS"
 312 ], [
 313   AC_MSG_FAILURE([This FRR version needs pthreads])
 314 ])
 315
 316 dnl --------------
 317 dnl Check programs
 318 dnl --------------
 319 AC_PROG_INSTALL
 320 AC_PROG_LN_S
 321 AC_PROG_MAKE_SET
 322 AC_CHECK_TOOL(AR, ar)
 323
 324 dnl -----------------
 325 dnl System extensions
 326 dnl -----------------
 327 AC_GNU_SOURCE
 328
 329 dnl -------
 330 dnl libtool
 331 dnl -------
 332 LT_INIT
 333
 334 dnl ----------------------
 335 dnl Packages configuration
 336 dnl ----------------------
 337 AC_ARG_WITH(pkg-extra-version,
 338         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 339         [EXTRAVERSION=$withval],)
 340 AC_ARG_WITH(pkg-git-version,
 341         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 342         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 343 AC_ARG_WITH(vtysh_pager,
 344         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 345         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 346 AC_ARG_ENABLE(vtysh,
 347   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 348 AC_ARG_ENABLE(doc,
 349   AS_HELP_STRING([--disable-doc], [do not build docs]))
 350 AC_ARG_ENABLE(doc-html,
 351   AS_HELP_STRING([--disable-doc-html], [do not build HTML docs]))
 352 AC_ARG_ENABLE(zebra,
 353   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 354 AC_ARG_ENABLE(bgpd,
 355   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 356 AC_ARG_ENABLE(ripd,
 357   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 358 AC_ARG_ENABLE(ripngd,
 359   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 360 AC_ARG_ENABLE(ospfd,
 361   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 362 AC_ARG_ENABLE(ospf6d,
 363   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 364 AC_ARG_ENABLE(ldpd,
 365   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 366 AC_ARG_ENABLE(nhrpd,
 367   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 368 AC_ARG_ENABLE(eigrpd,
 369   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 370 AC_ARG_ENABLE(babeld,
 371   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 372 AC_ARG_ENABLE(watchfrr,
 373   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 374 AC_ARG_ENABLE(isisd,
 375   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 376 AC_ARG_ENABLE(pimd,
 377   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 378 AC_ARG_ENABLE(pbrd,
 379   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 380 AC_ARG_ENABLE(sharpd,
 381   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 382 AC_ARG_ENABLE(staticd,
 383   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 384 AC_ARG_ENABLE(bgp-announce,
 385   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 386 AC_ARG_ENABLE(bgp-vnc,
 387   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 388 AC_ARG_WITH(rfp-path,
 389   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 390 AC_ARG_ENABLE(snmp,
 391   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 392 AC_ARG_ENABLE(zeromq,
 393   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 394 AC_ARG_WITH(libpam,
 395   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 396 AC_ARG_ENABLE(ospfapi,
 397   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 398 AC_ARG_ENABLE(ospfclient,
 399   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 400                           (this is the default if --disable-ospfapi is set)]))
 401 AC_ARG_ENABLE(multipath,
 402   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 403 AC_ARG_ENABLE(user,
 404   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 405 AC_ARG_ENABLE(group,
 406   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 407 AC_ARG_ENABLE(vty_group,
 408   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 409 AC_ARG_ENABLE(configfile_mask,
 410   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 411 AC_ARG_ENABLE(logfile_mask,
 412   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 413 AC_ARG_ENABLE(shell_access,
 414   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 415 AC_ARG_ENABLE(realms,
 416   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 417 AC_ARG_ENABLE(rtadv,
 418   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 419 AC_ARG_ENABLE(irdp,
 420   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 421 AC_ARG_ENABLE(capabilities,
 422   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 423 AC_ARG_ENABLE(rusage,
 424   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 425 AC_ARG_ENABLE(gcc_ultra_verbose,
 426   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 427 AC_ARG_ENABLE(backtrace,
 428   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 429 AC_ARG_ENABLE(time-check,
 430   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 431 AC_ARG_ENABLE(pcreposix,
 432   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 433 AC_ARG_ENABLE(fpm,
 434   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 435 AC_ARG_ENABLE(systemd,
 436   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 437 AC_ARG_ENABLE(werror,
 438   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 439 AC_ARG_ENABLE(cumulus,
 440   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 441 AC_ARG_ENABLE(datacenter,
 442   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 443 AC_ARG_ENABLE(fuzzing,
 444   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 445 AC_ARG_ENABLE(netlink_fuzzing,
 446   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 447 AC_ARG_ENABLE(rr-semantics,
 448   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 449 AC_ARG_ENABLE([protobuf],
 450   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 451 AC_ARG_ENABLE([oldvpn_commands],
 452   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 453 AC_ARG_ENABLE(rpki,
 454   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 455 AC_ARG_ENABLE([clippy-only],
 456   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 457 AC_ARG_ENABLE([numeric_version],
 458   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 459 AC_ARG_ENABLE([gcov],
 460   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 461 AC_ARG_ENABLE(bfdd,
 462   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 463
 464 AS_IF([test "${enable_clippy_only}" != "yes"], [
 465 AC_CHECK_HEADERS(json-c/json.h)
 466 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 467 if test $ac_cv_lib_json_c_json_object_get = no; then
 468   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 469   if test $ac_cv_lib_json_json_object_get = no; then
 470       AC_MSG_ERROR([lib json is needed to compile])
 471   fi
 472 fi
 473 ])
 474
 475 AC_ARG_ENABLE([dev_build],
 476     AS_HELP_STRING([--enable-dev-build], [build for development]))
 477
 478 if test x"${enable_time_check}" != x"no" ; then
 479   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 480     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 481   else
 482     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 483   fi
 484 fi
 485
 486 case "${enable_systemd}" in
 487   "no") ;;
 488   "yes")
 489   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 490   if test $ac_cv_lib_systemd_sd_notify = no; then
 491     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 492   else
 493     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 494   fi
 495   ;;
 496   "*") ;;
 497 esac
 498
 499 if test "${enable_rr_semantics}" != "no" ; then
 500   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 501 fi
 502
 503 if test "${enable_datacenter}" = "yes" ; then
 504   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 505   DFLT_NAME="datacenter"
 506 else
 507   DFLT_NAME="traditional"
 508 fi
 509
 510 if test "${enable_fuzzing}" = "yes" ; then
 511   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 512 fi
 513
 514 if test "${enable_netlink_fuzzing}" = "yes" ; then
 515   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 516 fi
 517
 518 if test "${enable_cumulus}" = "yes" ; then
 519   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 520 fi
 521
 522 AC_SUBST(DFLT_NAME)
 523 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 524
 525 if test "${enable_shell_access}" = "yes"; then
 526    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 527 fi
 528
 529 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 530
 531 #
 532 # Python for clippy
 533 #
 534 AS_IF([test "$host" = "$build"], [
 535   PYTHONCONFIG=""
 536
 537   # ordering:
 538   # 1.  try python3, but respect the user's preference on which minor ver
 539   # 2.  try python, which might be py3 or py2 again on the user's preference
 540   # 3.  try python2 (can really only be 2.7 but eh)
 541   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 542   #
 543   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 544   # (AX_PYTHON does not do what we need)
 545
 546   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 547   if test -n "$PYTHONCONFIG"; then
 548     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 549     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 550
 551     AC_MSG_CHECKING([whether we found a working Python version])
 552     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 553 #include <Python.h>
 554 #if PY_VERSION_HEX < 0x02070000
 555 #error python too old
 556 #endif
 557 int main(void);
 558 ],
 559 [
 560 {
 561   Py_Initialize();
 562   return 0;
 563 }
 564 ])], [
 565       PYTHONCONFIG=""
 566       unset PYTHON_LIBS
 567       unset PYTHON_CFLAGS
 568     ])
 569   fi
 570
 571   if test -z "$PYTHONCONFIG"; then
 572     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 573       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 574         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 575           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 576             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 577               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 578               ])])])])])
 579
 580
 581     AC_MSG_CHECKING([whether we found a working Python version])
 582     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 583 #include <Python.h>
 584 #if PY_VERSION_HEX < 0x02070000
 585 #error python too old
 586 #endif
 587 int main(void);
 588 ],
 589 [
 590 {
 591   Py_Initialize();
 592   return 0;
 593 }
 594 ])], [
 595       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 596     ])
 597   fi
 598 ])
 599 AC_SUBST(PYTHON_CFLAGS)
 600 AC_SUBST(PYTHON_LIBS)
 601
 602 #
 603 # Logic for protobuf support.
 604 #
 605 if test "$enable_protobuf" = "yes"; then
 606    have_protobuf=yes
 607
 608    # Check for protoc-c
 609    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 610    if test "x$PROTOC_C" = "x/bin/false"; then
 611       have_protobuf=no
 612    else
 613       found_protobuf_c=no
 614       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 615                      [found_protobuf_c=yes],
 616                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 617
 618       if test "x$found_protobuf_c" = "xyes"; then
 619          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 620          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 621       else
 622         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 623                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 624       fi
 625    fi
 626 fi
 627
 628 #
 629 # Logic for old vpn commans support.
 630 #
 631 if test "$enable_oldvpn_commands" = "yes"; then
 632    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 633 fi
 634
 635 # Fail if the user explicity enabled protobuf support and we couldn't
 636 # find the compiler or libraries.
 637 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 638    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 639 fi
 640
 641 if test "x$have_protobuf" = "xyes"; then
 642    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 643 fi
 644
 645 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 646
 647 #
 648 # End of logic for protobuf support.
 649 #
 650
 651 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 652 if test "${enable_rtadv}" != "no"; then
 653   AC_MSG_RESULT(yes)
 654   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 655 else
 656   AC_MSG_RESULT(no)
 657 fi
 658
 659 if test x"${enable_user}" = x"no"; then
 660   enable_user=""
 661 else
 662   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 663     enable_user="frr"
 664   fi
 665   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 666 fi
 667
 668 if test x"${enable_group}" = x"no"; then
 669   enable_group=""
 670 else
 671   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 672     enable_group="frr"
 673   fi
 674   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 675 fi
 676
 677 if test x"${enable_vty_group}" = x"yes" ; then
 678   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 679 elif test x"${enable_vty_group}" != x""; then
 680   if test x"${enable_vty_group}" != x"no"; then
 681     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 682   fi
 683 fi
 684 AC_SUBST([enable_user])
 685 AC_SUBST([enable_group])
 686 AC_SUBST([enable_vty_group])
 687
 688 enable_configfile_mask=${enable_configfile_mask:-0600}
 689 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 690
 691 enable_logfile_mask=${enable_logfile_mask:-0600}
 692 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 693
 694 MPATH_NUM=1
 695
 696 case "${enable_multipath}" in
 697   0)
 698     MPATH_NUM=64
 699     ;;
 700   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 701     MPATH_NUM="${enable_multipath}"
 702     ;;
 703   "")
 704     ;;
 705   *)
 706     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 707     ;;
 708 esac
 709
 710 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 711
 712 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 713
 714 dnl --------------------
 715 dnl Enable code coverage
 716 dnl --------------------
 717 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 718
 719 dnl ------------------------------------
 720 dnl Alpine only accepts numeric versions
 721 dnl ------------------------------------
 722 if test "x${enable_numeric_version}" != "x" ; then
 723   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 724   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 725 fi
 726
 727 dnl -----------------------------------
 728 dnl Add extra version string to package
 729 dnl name, string and version fields.
 730 dnl -----------------------------------
 731 if test "x${EXTRAVERSION}" != "x" ; then
 732   VERSION="${VERSION}${EXTRAVERSION}"
 733   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 734   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 735   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 736 fi
 737
 738 if test "x$with_pkg_git_version" = "xyes"; then
 739         if test -d "${srcdir}/.git"; then
 740                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 741         else    with_pkg_git_version="no"
 742                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 743         fi
 744 fi
 745 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 746
 747 dnl ------------------------------------
 748 dnl Check C keywords and standard  types
 749 dnl ------------------------------------
 750 AC_C_CONST
 751 AC_C_INLINE
 752 AC_C_VOLATILE
 753 AC_HEADER_STDC
 754 dnl AC_TYPE_PID_T
 755 AC_TYPE_UID_T
 756 AC_TYPE_MODE_T
 757 AC_TYPE_SIZE_T
 758 AC_STRUCT_TM
 759
 760 dnl -------------------------
 761 dnl Check other header files.
 762 dnl -------------------------
 763 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 764         linux/version.h asm/types.h \
 765         sys/cdefs.h])
 766
 767 ac_stdatomic_ok=false
 768 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 769 AC_CHECK_HEADER([stdatomic.h],[
 770
 771   AC_MSG_CHECKING([whether _Atomic qualifier works])
 772   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 773 #include <stdatomic.h>
 774 int main(int argc, char **argv) {
 775   _Atomic int i = 0;
 776   return i;
 777 }
 778 ]])], [
 779     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 780     AC_MSG_RESULT([yes])
 781     ac_stdatomic_ok=true
 782   ], [
 783     AC_MSG_RESULT([no])
 784   ])
 785 ])
 786
 787 AS_IF([$ac_stdatomic_ok], [true], [
 788   AC_MSG_CHECKING([for __atomic_* builtins])
 789   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 790 int main(int argc, char **argv) {
 791   volatile int i = 1;
 792   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 793   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 794 }
 795 ]])], [
 796     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 797     AC_MSG_RESULT([yes])
 798   ], [
 799     AC_MSG_RESULT([no])
 800
 801     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 802     AC_MSG_CHECKING([for __sync_* builtins])
 803     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 804 int main(int argc, char **argv) {
 805   volatile int i = 1;
 806   __sync_fetch_and_sub (&i, 1);
 807   return __sync_val_compare_and_swap (&i, 0, 1);
 808 }
 809 ]])], [
 810       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 811       AC_MSG_RESULT([yes])
 812
 813       AC_MSG_CHECKING([for __sync_swap builtin])
 814       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 815 int main(int argc, char **argv) {
 816   volatile int i = 1;
 817   return __sync_swap (&i, 2);
 818 }
 819 ]])], [
 820         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 821         AC_MSG_RESULT([yes])
 822       ], [
 823         AC_MSG_RESULT([no])
 824       ])
 825
 826     ], [
 827       AC_MSG_RESULT([no])
 828       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 829     ])
 830   ])
 831 ])
 832
 833 dnl Utility macro to avoid retyping includes all the time
 834 m4_define([FRR_INCLUDES],
 835 [#ifdef SUNOS_5
 836 #define _XPG4_2
 837 #define __EXTENSIONS__
 838 #endif
 839 #include <stdio.h>
 840 #include <stdlib.h>
 841 #include <stddef.h>
 842 #include <sys/types.h>
 843 /* sys/conf.h depends on param.h on FBSD at least */
 844 #include <sys/param.h>
 845 /* Required for MAXSIG */
 846 #include <signal.h>
 847 #include <sys/socket.h>
 848 #ifdef __APPLE__
 849 # define __APPLE_USE_RFC_3542
 850 #endif
 851 #include <netinet/in.h>
 852 #include <sys/time.h>
 853 #include <time.h>
 854 #include <net/if.h>
 855 ])dnl
 856
 857 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 858 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 859 dnl an additional round for it.
 860
 861 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 862
 863 m4_define([FRR_INCLUDES],
 864 FRR_INCLUDES
 865 [#if HAVE_NET_IF_VAR_H
 866 # include <net/if_var.h>
 867 #endif
 868 ])dnl
 869
 870 AC_CHECK_HEADERS([netinet/in_var.h \
 871         net/if_dl.h net/netopt.h \
 872         inet/nd.h netinet/ip_icmp.h \
 873         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 874         [], [], FRR_INCLUDES)
 875
 876 AC_CHECK_HEADERS([ucontext.h], [], [],
 877 [#ifndef __USE_GNU
 878 #define __USE_GNU
 879 #endif /* __USE_GNU */
 880 FRR_INCLUDES
 881 ])
 882
 883 m4_define([UCONTEXT_INCLUDES],
 884 [#include <ucontext.h>])dnl
 885
 886 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 887   [], [], [UCONTEXT_INCLUDES])
 888 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 889   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 890    [], [], [UCONTEXT_INCLUDES])],
 891   [], [UCONTEXT_INCLUDES])
 892 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 893   [], [], [UCONTEXT_INCLUDES])
 894
 895 m4_define([FRR_INCLUDES],
 896 FRR_INCLUDES
 897 [
 898 #include <sys/un.h>
 899 #include <netinet/in_systm.h>
 900 #if HAVE_NETINET_IN_VAR_H
 901 # include <netinet/in_var.h>
 902 #endif
 903 #if HAVE_NET_IF_DL_H
 904 # include <net/if_dl.h>
 905 #endif
 906 #if HAVE_NET_NETOPT_H
 907 # include <net/netopt.h>
 908 #endif
 909 #include <net/route.h>
 910 #if HAVE_INET_ND_H
 911 # include <inet/nd.h>
 912 #endif
 913 #include <arpa/inet.h>
 914 /* Required for IDRP */
 915 #if HAVE_NETINET_IP_ICMP_H
 916 # include <netinet/ip_icmp.h>
 917 #endif
 918 ])dnl
 919
 920 dnl V6 headers are checked below, after we check for v6
 921
 922 AC_MSG_CHECKING([which operating system interface to use])
 923 case "$host_os" in
 924   sunos* | solaris2*)
 925     AC_MSG_RESULT([Solaris])
 926
 927     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 928     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 929
 930     AC_CHECK_LIB(socket, main)
 931     AC_CHECK_LIB(nsl, main)
 932     AC_CHECK_LIB(umem, main)
 933     AC_CHECK_FUNCS([printstack], [
 934       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 935       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 936     ])
 937     CURSES=-lcurses
 938     SOLARIS="solaris"
 939     ;;
 940   linux*)
 941     AC_MSG_RESULT([Linux])
 942
 943     AC_DEFINE(GNU_LINUX,,GNU Linux)
 944     AC_DEFINE(HAVE_NETLINK,,netlink)
 945     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 946
 947     dnl Linux has a compilation problem with mixing
 948     dnl netinet/in.h and linux/in6.h they are not
 949     dnl compatible.  There has been discussion on
 950     dnl how to fix it but no real progress on implementation
 951     dnl when they fix it, remove this
 952     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 953     ;;
 954   openbsd*)
 955     AC_MSG_RESULT([OpenBSD])
 956
 957     AC_DEFINE(OPEN_BSD,,OpenBSD)
 958     AC_DEFINE(KAME,1,KAME IPv6)
 959     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 960
 961     if test "x${enable_pimd}" != "xno"; then
 962       case "$host_os" in
 963       openbsd6.0)
 964         ;;
 965       openbsd[6-9]*)
 966         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 967         ;;
 968       esac
 969     fi
 970     ;;
 971   *)
 972     AC_MSG_RESULT([BSD])
 973
 974     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 975     AC_DEFINE(KAME,1,KAME IPv6)
 976     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 977     ;;
 978 esac
 979 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 980
 981 AC_SYS_LARGEFILE
 982
 983 dnl ------------------------
 984 dnl Integrated REALMS option
 985 dnl ------------------------
 986 if test "${enable_realms}" = "yes"; then
 987     case "$host_os" in
 988       linux*)
 989        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 990        ;;
 991       *)
 992        echo "Sorry, only Linux has REALMS support"
 993        exit 1
 994        ;;
 995     esac
 996 fi
 997 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 998
 999 dnl ---------------------
1000 dnl Integrated VTY option
1001 dnl ---------------------
1002 case "${enable_vtysh}" in
1003   "no") VTYSH="";;
1004   *)    VTYSH="vtysh";
1005          AC_DEFINE(VTYSH,,VTY shell)
1006 dnl      Vtysh uses libreadline, which looks for termcap functions at
1007 dnl      configure time.  We follow readlines search order.
1008 dnl      The required procedures are in libtermcap on NetBSD, in
1009 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1010          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1011            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1012              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1013                [AC_CHECK_LIB(ncurses, tputs,
1014                              LIBREADLINE="$LIBREADLINE -lncurses")]
1015               )]
1016             )]
1017           )
1018          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1019                       "$LIBREADLINE")
1020          if test $ac_cv_lib_readline_main = no; then
1021            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1022          fi
1023          AC_CHECK_HEADER(readline/history.h)
1024          if test $ac_cv_header_readline_history_h = no;then
1025            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1026          fi
1027          AC_CHECK_LIB(readline, rl_completion_matches,
1028                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1029          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1030            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1031          fi
1032          ;;
1033 esac
1034 AC_SUBST(LIBREADLINE)
1035 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1036
1037 dnl ----------
1038 dnl PAM module
1039 dnl
1040 dnl FRR detects the PAM library it is built against by checking for a
1041 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1042 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1043 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1044 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1045 dnl of OpenPAM.
1046 dnl ----------
1047 if test "$with_libpam" = "yes"; then
1048   AC_CHECK_HEADER([security/pam_misc.h],
1049     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1050      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1051      pam_conv_func="misc_conv"
1052     ],
1053     [], FRR_INCLUDES)
1054   AC_CHECK_HEADER([security/openpam.h],
1055     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1056      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1057      pam_conv_func="openpam_ttyconv"
1058     ],
1059     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1060   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1061     AC_MSG_WARN([*** pam support will not be built ***])
1062     with_libpam="no"
1063   fi
1064 fi
1065
1066 if test "$with_libpam" = "yes"; then
1067 dnl took this test from proftpds configure.in and suited to our needs
1068 dnl -------------------------------------------------------------------------
1069 dnl
1070 dnl This next check looks funky due to a linker problem with some versions
1071 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1072 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1073 dnl with RedHat 6.2 and Debian 2.2 or better.
1074 AC_CHECK_LIB(pam, pam_start,
1075   [AC_CHECK_LIB(pam, $pam_conv_func,
1076     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1077      LIBPAM="-lpam"],
1078     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1079      LIBPAM="-lpam -lpam_misc"]
1080     )
1081   ],
1082
1083   [AC_CHECK_LIB(pam, pam_end,
1084     [AC_CHECK_LIB(pam, $pam_conv_func,
1085       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1086        LIBPAM="-lpam -ldl"],
1087       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1088        LIBPAM="-lpam -ldl -lpam_misc"]
1089      )
1090   ],AC_MSG_WARN([*** pam support will not be built ***]),
1091   [-ldl])
1092   ]
1093 )
1094 fi
1095 AC_SUBST(LIBPAM)
1096
1097 dnl -------------------------------
1098 dnl Endian-ness check
1099 dnl -------------------------------
1100 AC_WORDS_BIGENDIAN
1101
1102 dnl -------------------------------
1103 dnl check the size in byte of the C
1104 dnl -------------------------------
1105 dnl AC_CHECK_SIZEOF(char)
1106 dnl AC_CHECK_SIZEOF(int)
1107 dnl AC_CHECK_SIZEOF(short)
1108 dnl AC_CHECK_SIZEOF(long)
1109
1110 dnl ----------------------------
1111 dnl check existance of functions
1112 dnl ----------------------------
1113 AC_FUNC_FNMATCH
1114 AC_FUNC_FORK
1115 AC_FUNC_MKTIME
1116 AC_FUNC_STAT
1117
1118 dnl -------------------------------
1119 dnl bgpd needs pow() and hence libm
1120 dnl -------------------------------
1121 TMPLIBS="$LIBS"
1122 AC_CHECK_HEADER([math.h],
1123   [AC_CHECK_LIB([m], [pow],
1124     [LIBM="-lm"
1125      LIBS="$LIBS $LIBM"
1126      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1127     ])
1128 ])
1129 if test x"$LIBM" = x ; then
1130   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1131 fi
1132 LIBS="$TMPLIBS"
1133 AC_SUBST(LIBM)
1134
1135 AC_CHECK_FUNCS([ppoll], [
1136   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1137 ])
1138 AC_CHECK_FUNCS([pollts], [
1139   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1140 ])
1141
1142 dnl ---------------
1143 dnl other functions
1144 dnl ---------------
1145 AC_CHECK_FUNCS([ \
1146         strlcat strlcpy \
1147         getgrouplist])
1148
1149 AC_CHECK_HEADER([asm-generic/unistd.h],
1150                 [AC_CHECK_DECL(__NR_setns,
1151                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1152                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1153                                ])
1154                  AC_CHECK_FUNCS(setns)]
1155                )
1156
1157 dnl --------------------------
1158 dnl Determine IS-IS I/O method
1159 dnl --------------------------
1160 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1161 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1162 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1163 AC_CHECK_HEADER(net/bpf.h)
1164 AC_CHECK_HEADER(sys/dlpi.h)
1165 AC_MSG_CHECKING(zebra IS-IS I/O method)
1166
1167 case "$host_os" in
1168   linux*)
1169     AC_MSG_RESULT(pfpacket)
1170     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1171     ;;
1172   solaris* | sunos*)
1173     AC_MSG_RESULT(DLPI)
1174     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1175     ;;
1176   *)
1177     if test $ac_cv_header_net_bpf_h = no; then
1178       if test $ac_cv_header_sys_dlpi_h = no; then
1179         AC_MSG_RESULT(none)
1180         if test "${enable_isisd}" = yes; then
1181           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1182         fi
1183         AC_MSG_WARN([*** IS-IS support will not be built ***])
1184         enable_isisd="no"
1185       else
1186         AC_MSG_RESULT(DLPI)
1187       fi
1188       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1189     else
1190       AC_MSG_RESULT(BPF)
1191       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1192     fi
1193     ;;
1194 esac
1195 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1196
1197 dnl ---------------------------------------------------------------
1198 dnl figure out how to specify an interface in multicast sockets API
1199 dnl ---------------------------------------------------------------
1200 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1201
1202 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1203         #include <sys/socket.h>
1204         #include <netinet/in.h>
1205         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1206         #include <linux/types.h>
1207 ])
1208
1209 m4_define([FRR_INCLUDES],
1210 FRR_INCLUDES
1211 [#if HAVE_LINUX_MROUTE_H
1212 # include <linux/mroute.h>
1213 #endif
1214 ])dnl
1215
1216 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1217         #include <sys/socket.h>
1218         #include <sys/types.h>
1219         #include <netinet/in.h>
1220         #include <net/route.h>
1221 ])
1222
1223 m4_define([FRR_INCLUDES],
1224 FRR_INCLUDES
1225 [#if HAVE_NETINET_IP_MROUTE_H
1226 # include <netinet/ip_mroute.h>
1227 #endif
1228 ])dnl
1229
1230 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1231 AC_TRY_COMPILE([#include <sys/param.h>],
1232 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1233   return (0);
1234 #else
1235   #error No support for BSD struct ip_mreq hack detected
1236 #endif],[AC_MSG_RESULT(yes)
1237 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1238 AC_MSG_RESULT(no))
1239
1240 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1241 AC_TRY_COMPILE([
1242 #include <sys/types.h>
1243 #include <netinet/in.h>
1244 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1245 ], [AC_MSG_RESULT(yes)
1246 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1247 AC_MSG_RESULT(no))
1248
1249 dnl ---------------------------------------------------------------
1250 dnl figure out how to check link-state
1251 dnl ---------------------------------------------------------------
1252 AC_CHECK_HEADER( [net/if_media.h],
1253   [m4_define([LINK_DETECT_INCLUDES],
1254     FRR_INCLUDES
1255     [#include <net/if_media.h>
1256   ])
1257   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1258     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1259     [], LINK_DETECT_INCLUDES)],
1260   [],
1261   FRR_INCLUDES)
1262
1263 dnl ---------------------------------------------------------------
1264 dnl Additional, newer way to check link-state using ifi_link_state.
1265 dnl Not available in all BSD's when ifmediareq available
1266 dnl ---------------------------------------------------------------
1267 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1268   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1269   [], FRR_INCLUDES)
1270
1271 dnl ------------------------
1272 dnl TCP_MD5SIG socket option
1273 dnl ------------------------
1274
1275 AC_CHECK_HEADER([netinet/tcp.h],
1276    [m4_define([MD5_INCLUDES],
1277       FRR_INCLUDES
1278       [#include <netinet/tcp.h>
1279     ])
1280     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1281    [],
1282    FRR_INCLUDES)
1283 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1284   AC_CHECK_HEADER([linux/tcp.h],
1285        [m4_define([MD5_INCLUDES],
1286           FRR_INCLUDES
1287           [#include <linux/tcp.h>
1288         ])
1289        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1290 fi
1291
1292 dnl ----------------------------------------------------------------------------
1293 dnl figure out if domainname is available in the utsname struct (GNU extension).
1294 dnl ----------------------------------------------------------------------------
1295 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1296
1297 dnl ------------------
1298 dnl IPv6 header checks
1299 dnl ------------------
1300 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1301         netinet6/in6_var.h netinet6/nd6.h], [], [],
1302         FRR_INCLUDES)
1303
1304 m4_define([FRR_INCLUDES],dnl
1305 FRR_INCLUDES
1306 [#if HAVE_NETINET6_IN6_H
1307 #include <netinet6/in6.h>
1308 #endif
1309 #if HAVE_NETINET_IN6_VAR_H
1310 #include <netinet/in6_var.h>
1311 #endif
1312 #include <netinet/icmp6.h>
1313 #if HAVE_NETINET6_IN6_VAR_H
1314 # include <netinet6/in6_var.h>
1315 #endif
1316 #if HAVE_NETINET6_ND6_H
1317 # include <netinet6/nd6.h>
1318 #endif
1319 ])dnl
1320
1321 dnl disable doc check
1322 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [no])
1323 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no")
1324 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" != "no")
1325
1326 dnl --------------------
1327 dnl Daemon disable check
1328 dnl --------------------
1329 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1330
1331 if test "${enable_bgpd}" = "no";then
1332   BGPD=""
1333 else
1334   BGPD="bgpd"
1335 fi
1336 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1337
1338 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1339 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1340 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1341
1342 AS_IF([test "${enable_ldpd}" != "no"], [
1343   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1344 ])
1345
1346 if test "$enable_bfdd" = "no"; then
1347   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1348   BFDD=""
1349 else
1350   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1351   BFDD="bfdd"
1352
1353   case $host_os in
1354     linux*)
1355       AC_DEFINE(BFD_LINUX, 1, bfdd)
1356       ;;
1357
1358     *)
1359       AC_DEFINE(BFD_BSD, 1, bfdd)
1360       ;;
1361   esac
1362 fi
1363
1364 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1365
1366 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1367   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1368 fi
1369
1370 NHRPD=""
1371 case "$host_os" in
1372   linux*)
1373     if test "${enable_nhrpd}" != "no"; then
1374       NHRPD="nhrpd"
1375     fi
1376     ;;
1377   *)
1378     if test "${enable_nhrpd}" = "yes"; then
1379       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1380     fi
1381     ;;
1382 esac
1383 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1384
1385 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1386
1387 if test "${enable_watchfrr}" = "no";then
1388   WATCHFRR=""
1389 else
1390   WATCHFRR="watchfrr"
1391 fi
1392 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1393
1394 OSPFCLIENT=""
1395 if test "${enable_ospfapi}" != "no";then
1396     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1397
1398   if test "${enable_ospfclient}" != "no";then
1399       OSPFCLIENT="ospfclient"
1400   fi
1401 fi
1402
1403 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1404 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1405 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1406 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1407 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1408 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1409 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1410 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1411 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1412
1413 if test "${enable_bgp_announce}" = "no";then
1414   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1415 else
1416   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1417 fi
1418
1419 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1420   with_rfp_path="bgpd/rfp-example"
1421 fi
1422 if test "${with_rfp_path}" != "no"; then
1423   VNC_RFP_PATH="${with_rfp_path}"
1424   AC_SUBST(VNC_RFP_PATH)
1425 fi
1426
1427 if test "${enable_bgp_vnc}" != "no";then
1428   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1429   RFPTEST="${with_rfp_path}/rfptest"
1430   LIBRFP="${with_rfp_path}/librfp"
1431   RFPINC="${with_rfp_path}/librfp"
1432 else
1433   RFPTEST=
1434   LIBRFP=
1435   RFPINC="bgpd/rfp-example/librfp"
1436 fi
1437 # set
1438 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1439
1440 AC_SUBST(RFPTEST)
1441 AC_SUBST(LIBRFP)
1442 AC_SUBST(RFPINC)
1443 AC_SUBST(BGPD)
1444 AC_SUBST(SOLARIS)
1445 AC_SUBST(VTYSH)
1446 AC_SUBST(CURSES)
1447 AC_CHECK_LIB(crypt, crypt, [],
1448                     [AC_CHECK_LIB(crypto, DES_crypt)])
1449 AC_CHECK_LIB(resolv, res_init)
1450
1451 dnl ---------------------------
1452 dnl check system has PCRE regexp
1453 dnl ---------------------------
1454 if test "x$enable_pcreposix" = "xyes"; then
1455   AC_CHECK_LIB(pcreposix, regexec, [], [
1456     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1457   ])
1458 fi
1459 AC_SUBST(HAVE_LIBPCREPOSIX)
1460
1461 dnl ------------------
1462 dnl check C-Ares library
1463 dnl ------------------
1464 if test "${NHRPD}" != ""; then
1465   PKG_CHECK_MODULES([CARES], [libcares], , [
1466     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1467   ])
1468 fi
1469
1470
1471 dnl ------------------
1472 dnl check Net-SNMP library
1473 dnl ------------------
1474 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1475    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1476    if test x"$NETSNMP_CONFIG" = x"no"; then
1477       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1478    fi
1479    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1480    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1481    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1482    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1483 int main(void);
1484 ],
1485 [
1486 {
1487   return 0;
1488 }
1489 ])], [
1490      AC_MSG_ERROR([--enable-snmp given but not usable])])
1491    case "${enable_snmp}" in
1492      yes)
1493       SNMP_METHOD=agentx
1494       ;;
1495      agentx)
1496       SNMP_METHOD="${enable_snmp}"
1497       ;;
1498      *)
1499       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1500       ;;
1501    esac
1502    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1503    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1504 fi
1505 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1506 AC_SUBST(SNMP_LIBS)
1507 AC_SUBST(SNMP_CFLAGS)
1508
1509 dnl ---------------
1510 dnl math
1511 dnl ---------------
1512 AC_SEARCH_LIBS([sqrt], [m])
1513
1514 dnl ---------------
1515 dnl dlopen & dlinfo
1516 dnl ---------------
1517 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1518   AC_MSG_ERROR([unable to find the dlopen()])
1519 ])
1520
1521 AC_CHECK_HEADERS([link.h])
1522
1523 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1524   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1525 #include <stdlib.h>
1526 #ifdef HAVE_LINK_H
1527 #include <link.h>
1528 #endif
1529 #include <dlfcn.h>
1530 ]], [[
1531   char origin[1];
1532   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1533 ]])], [
1534     frr_cv_rtld_di_origin=yes
1535   ], [
1536     frr_cv_rtld_di_origin=no
1537   ])
1538 ])
1539 if test "$frr_cv_rtld_di_origin" = yes; then
1540   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1541 fi
1542
1543 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1544   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1545 #include <stdlib.h>
1546 #ifdef HAVE_LINK_H
1547 #include <link.h>
1548 #endif
1549 #include <dlfcn.h>
1550 ]], [[
1551   struct link_map *lm = NULL;
1552   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1553 ]])], [
1554     frr_cv_rtld_di_linkmap=yes
1555   ], [
1556     frr_cv_rtld_di_linkmap=no
1557   ])
1558 ])
1559 if test "$frr_cv_rtld_di_linkmap" = yes; then
1560   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1561 fi
1562
1563 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1564
1565 dnl ---------------------------
1566 dnl sockaddr and netinet checks
1567 dnl ---------------------------
1568 AC_CHECK_TYPES([
1569         struct sockaddr_dl,
1570         struct vifctl, struct mfcctl, struct sioc_sg_req,
1571         vifi_t, struct sioc_vif_req, struct igmpmsg,
1572         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1573         struct nd_opt_adv_interval, struct rt_addrinfo,
1574         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1575         [], [], FRR_INCLUDES)
1576
1577 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1578         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1579         struct sockaddr_dl.sdl_len,
1580         struct if6_aliasreq.ifra_lifetime,
1581         struct nd_opt_adv_interval.nd_opt_ai_type],
1582         [], [], FRR_INCLUDES)
1583
1584 dnl ---------------------------
1585 dnl IRDP/pktinfo/icmphdr checks
1586 dnl ---------------------------
1587
1588 AC_CHECK_TYPES([struct in_pktinfo], [
1589   AC_CHECK_TYPES([struct icmphdr], [
1590     IRDP=true
1591   ], [
1592     IRDP=false
1593   ], [FRR_INCLUDES])
1594 ], [
1595   IRDP=false
1596 ], [FRR_INCLUDES])
1597
1598 case "${enable_irdp}" in
1599 yes)
1600   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1601   ;;
1602 no)
1603   IRDP=false
1604   ;;
1605 esac
1606
1607 AM_CONDITIONAL(IRDP, $IRDP)
1608
1609 dnl -----------------------
1610 dnl checking for IP_PKTINFO
1611 dnl -----------------------
1612 AC_MSG_CHECKING(for IP_PKTINFO)
1613 AC_TRY_COMPILE([#include <netdb.h>], [
1614   int opt = IP_PKTINFO;
1615 ], [
1616   AC_MSG_RESULT(yes)
1617   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1618 ], [
1619   AC_MSG_RESULT(no)
1620 ])
1621
1622 dnl ---------------------------
1623 dnl checking for IP_RECVDSTADDR
1624 dnl ---------------------------
1625 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1626 AC_TRY_COMPILE([#include <netinet/in.h>], [
1627   int opt = IP_RECVDSTADDR;
1628 ], [
1629   AC_MSG_RESULT(yes)
1630   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1631 ], [
1632   AC_MSG_RESULT(no)
1633 ])
1634
1635 dnl ----------------------
1636 dnl checking for IP_RECVIF
1637 dnl ----------------------
1638 AC_MSG_CHECKING(for IP_RECVIF)
1639 AC_TRY_COMPILE([#include <netinet/in.h>], [
1640   int opt = IP_RECVIF;
1641 ], [
1642   AC_MSG_RESULT(yes)
1643   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1644 ], [
1645   AC_MSG_RESULT(no)
1646 ])
1647
1648 dnl ----------------------
1649 dnl checking for SO_BINDANY
1650 dnl ----------------------
1651 AC_MSG_CHECKING(for SO_BINDANY)
1652 AC_TRY_COMPILE([#include <sys/socket.h>], [
1653   int opt = SO_BINDANY;
1654 ], [
1655   AC_MSG_RESULT(yes)
1656   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1657 ], [
1658   AC_MSG_RESULT(no)
1659 ])
1660
1661 dnl ----------------------
1662 dnl checking for IP_FREEBIND
1663 dnl ----------------------
1664 AC_MSG_CHECKING(for IP_FREEBIND)
1665 AC_TRY_COMPILE([#include <netinet/in.h>], [
1666   int opt = IP_FREEBIND;
1667 ], [
1668   AC_MSG_RESULT(yes)
1669   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1670 ], [
1671   AC_MSG_RESULT(no)
1672 ])
1673
1674 dnl --------------------------------------
1675 dnl checking for be32dec existence or not
1676 dnl --------------------------------------
1677 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1678                [#include <sys/endian.h>])
1679
1680 dnl --------------------------------------
1681 dnl checking for clock_time monotonic struct and call
1682 dnl --------------------------------------
1683 AC_CHECK_DECL(CLOCK_MONOTONIC,
1684         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1685          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1686 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1687
1688 dnl --------------------------------------
1689 dnl checking for flex and bison
1690 dnl --------------------------------------
1691
1692 AM_PROG_LEX
1693 AC_MSG_CHECKING(version of flex)
1694 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1695 frr_ac_flex_version="${frr_ac_flex_version##* }"
1696 AC_MSG_RESULT([$frr_ac_flex_version])
1697 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1698   LEX="$SHELL $missing_dir/missing flex"
1699   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1700     AC_MSG_WARN([using pregenerated flex output files])
1701   else
1702     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1703   fi
1704   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1705   AC_SUBST([LEXLIB], [''])
1706 ])
1707
1708 AC_PROG_YACC
1709 dnl thanks GNU bison for this b*llshit...
1710 AC_MSG_CHECKING(version of bison)
1711 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1712 frr_ac_bison_version="${frr_ac_bison_version##* }"
1713 frr_ac_bison_missing="false"
1714 case "x${frr_ac_bison_version}" in
1715   x2.7*)
1716     BISON_OPENBRACE='"'
1717     BISON_CLOSEBRACE='"'
1718     BISON_VERBOSE=''
1719     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1720     ;;
1721   x2.*|x1.*)
1722     AC_MSG_RESULT([$frr_ac_bison_version])
1723     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1724     frr_ac_bison_missing="true"
1725     ;;
1726   x)
1727     AC_MSG_RESULT([none])
1728     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1729     frr_ac_bison_missing="true"
1730     ;;
1731   *)
1732     BISON_OPENBRACE='{'
1733     BISON_CLOSEBRACE='}'
1734     BISON_VERBOSE='-Dparse.error=verbose'
1735     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1736     ;;
1737 esac
1738 AC_SUBST(BISON_OPENBRACE)
1739 AC_SUBST(BISON_CLOSEBRACE)
1740 AC_SUBST(BISON_VERBOSE)
1741
1742 if $frr_ac_bison_missing; then
1743   YACC="$SHELL $missing_dir/missing bison -y"
1744   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1745     AC_MSG_WARN([using pregenerated bison output files])
1746   else
1747     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1748   fi
1749 fi
1750
1751 dnl -------------------
1752 dnl capabilities checks
1753 dnl -------------------
1754 if test "${enable_capabilities}" != "no"; then
1755   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1756   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1757     [AC_MSG_RESULT(yes)
1758      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1759      frr_ac_keepcaps="yes"],
1760      AC_MSG_RESULT(no)
1761   )
1762   if test x"${frr_ac_keepcaps}" = x"yes"; then
1763     AC_CHECK_HEADERS(sys/capability.h)
1764   fi
1765   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1766     AC_CHECK_LIB(cap, cap_init,
1767       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1768        LIBCAP="-lcap"
1769        frr_ac_lcaps="yes"]
1770     )
1771   else
1772     AC_CHECK_HEADERS(priv.h,
1773      [AC_MSG_CHECKING(Solaris style privileges are available)
1774       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1775           [AC_MSG_RESULT(yes)
1776            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1777            frr_ac_scaps="yes"],
1778            AC_MSG_RESULT(no)
1779       )
1780      ]
1781    )
1782   fi
1783   if test x"${frr_ac_scaps}" = x"yes" \
1784        -o x"${frr_ac_lcaps}" = x"yes"; then
1785     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1786   fi
1787 fi
1788 AC_SUBST(LIBCAP)
1789
1790 dnl ---------------------------
1791 dnl check for glibc 'backtrace'
1792 dnl ---------------------------
1793 if test x"${enable_backtrace}" != x"no" ; then
1794   backtrace_ok=no
1795   AC_CHECK_HEADER([execinfo.h], [
1796     AC_SEARCH_LIBS([backtrace], [execinfo], [
1797       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1798       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1799       backtrace_ok=yes
1800     ],, [-lm])
1801   ])
1802
1803   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1804     dnl user explicitly requested backtrace but we failed to find support
1805     AC_MSG_FAILURE([failed to find backtrace support])
1806   fi
1807 fi
1808
1809 dnl -----------------------------------------
1810 dnl check for malloc mallinfo struct and call
1811 dnl this must try and link using LIBS, in
1812 dnl order to check no alternative allocator
1813 dnl has been specified, which might not provide
1814 dnl mallinfo, e.g. such as Umem on Solaris.
1815 dnl -----------------------------------------
1816 AC_CHECK_HEADERS([malloc.h malloc/malloc.h],,, [FRR_INCLUDES])
1817
1818 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1819   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1820 #ifdef HAVE_MALLOC_H
1821 #include <malloc.h>
1822 #endif
1823 #ifdef HAVE_MALLOC_MALLOC_H
1824 #include <malloc/malloc.h>
1825 #endif
1826 ]], [[
1827 struct mallinfo ac_x; ac_x = mallinfo ();
1828 ]])], [
1829     frr_cv_mallinfo=yes
1830   ], [
1831     frr_cv_mallinfo=no
1832   ])
1833 ])
1834 if test "$frr_cv_mallinfo" = yes; then
1835   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1836 fi
1837
1838 AC_MSG_CHECKING(whether malloc_usable_size is available)
1839 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1840 #ifdef HAVE_MALLOC_H
1841 #include <malloc.h>
1842 #endif
1843 #ifdef HAVE_MALLOC_MALLOC_H
1844 #include <malloc/malloc.h>
1845 #endif
1846 ]], [[
1847 size_t ac_x; ac_x = malloc_usable_size(NULL);
1848 ]])], [
1849   AC_MSG_RESULT(yes)
1850   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1851 ], [
1852   AC_MSG_RESULT(no)
1853
1854   AC_MSG_CHECKING(whether malloc_size is available)
1855   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1856 #ifdef HAVE_MALLOC_H
1857 #include <malloc.h>
1858 #endif
1859 #ifdef HAVE_MALLOC_MALLOC_H
1860 #include <malloc/malloc.h>
1861 #endif
1862 ]], [[
1863 size_t ac_x; ac_x = malloc_size(NULL);
1864 ]])], [
1865     AC_MSG_RESULT(yes)
1866     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1867   ], [
1868     AC_MSG_RESULT(no)
1869   ])
1870 ])
1871
1872 dnl ------
1873 dnl ZeroMQ
1874 dnl ------
1875 if test "x$enable_zeromq" != "xno"; then
1876   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1877     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1878     ZEROMQ=true
1879   ], [
1880     if test "x$enable_zeromq" = "xyes"; then
1881       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1882     fi
1883   ])
1884 fi
1885 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1886
1887 dnl ----------
1888 dnl configure date
1889 dnl ----------
1890 dev_version=`echo $VERSION | grep dev`
1891 #don't expire deprecated code in non 'dev' branch
1892 if test "${dev_version}" = ""; then
1893    CONFDATE=0
1894 else
1895    CONFDATE=`date '+%Y%m%d'`
1896 fi
1897 AC_SUBST(CONFDATE)
1898
1899 dnl ------------------------------
1900 dnl set paths for state directory
1901 dnl ------------------------------
1902 AC_MSG_CHECKING(directory to use for state file)
1903 if test "${prefix}" = "NONE"; then
1904   frr_statedir_prefix="";
1905 else
1906   frr_statedir_prefix=${prefix}
1907 fi
1908 if test "${localstatedir}" = '${prefix}/var'; then
1909   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1910                         ${frr_statedir_prefix}/var/adm dnl
1911                         ${frr_statedir_prefix}/etc dnl
1912                         /var/run        dnl
1913                         /var/adm        dnl
1914                         /etc            dnl
1915                         /dev/null;
1916   do
1917     test -d $FRR_STATE_DIR && break
1918   done
1919   frr_statedir=$FRR_STATE_DIR
1920 else
1921   frr_statedir=${localstatedir}
1922 fi
1923 if test $frr_statedir = "/dev/null"; then
1924     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1925 fi
1926 AC_MSG_RESULT(${frr_statedir})
1927 AC_SUBST(frr_statedir)
1928
1929 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1930 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1931 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1932 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1933
1934 dnl autoconf does this, but it does it too late...
1935 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1936 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1937
1938 dnl get the full path, recursing through variables...
1939 vtysh_bin="$bindir/vtysh"
1940 for I in 1 2 3 4 5 6 7 8 9 10; do
1941         eval vtysh_bin="\"$vtysh_bin\""
1942 done
1943 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1944
1945 CFG_SYSCONF="$sysconfdir"
1946 CFG_SBIN="$sbindir"
1947 CFG_STATE="$frr_statedir"
1948 CFG_MODULE="$moduledir"
1949 for I in 1 2 3 4 5 6 7 8 9 10; do
1950         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1951         eval CFG_SBIN="\"$CFG_SBIN\""
1952         eval CFG_STATE="\"$CFG_STATE\""
1953         eval CFG_MODULE="\"$CFG_MODULE\""
1954 done
1955 AC_SUBST(CFG_SYSCONF)
1956 AC_SUBST(CFG_SBIN)
1957 AC_SUBST(CFG_STATE)
1958 AC_SUBST(CFG_MODULE)
1959 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1960
1961 dnl ------------------------------------
1962 dnl Enable RPKI and add librtr to libs
1963 dnl ------------------------------------
1964 if test "${enable_rpki}" = "yes"; then
1965   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1966       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1967       RPKI=true],
1968       [RPKI=false
1969       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1970   )
1971 fi
1972 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1973
1974 dnl ------------------------------------------
1975 dnl Check whether rtrlib was build with ssh support
1976 dnl ------------------------------------------
1977 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1978 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1979                         [[struct tr_ssh_config config;]])],
1980         [AC_MSG_RESULT(yes)
1981         AC_DEFINE(FOUND_SSH,,found_ssh)],
1982         AC_MSG_RESULT(no)
1983 )
1984
1985 dnl ---------------------------
1986 dnl Check htonl works correctly
1987 dnl ---------------------------
1988 AC_MSG_CHECKING(for working htonl)
1989 AC_CACHE_VAL(ac_cv_htonl_works,
1990  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1991                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1992  ]
1993 )
1994 AC_MSG_RESULT($ac_cv_htonl_works)
1995
1996 AC_CONFIG_FILES([Makefile
1997           bgpd/Makefile
1998           vtysh/Makefile
1999           tests/Makefile
2000           bgpd/rfp-example/rfptest/Makefile
2001           bgpd/rfp-example/librfp/Makefile
2002           redhat/frr.spec
2003           solaris/Makefile
2004           debianpkg/changelog
2005           alpine/APKBUILD
2006           snapcraft/snapcraft.yaml
2007           lib/version.h
2008           tests/lib/cli/test_cli.refout
2009           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2010           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2011           pkgsrc/eigrpd.sh])
2012
2013 if test "${enable_bgp_vnc}" != "no"; then
2014    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
2015       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
2016    fi
2017 fi
2018
2019 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2020
2021 AC_CONFIG_COMMANDS([lib/route_types.h], [
2022         dst="${ac_abs_top_builddir}/lib/route_types.h"
2023         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2024                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2025                 > "${dst}.tmp"
2026         test -f "${dst}" \
2027                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2028                 && rm "${dst}.tmp" \
2029                 || mv "${dst}.tmp" "${dst}"
2030 ], [
2031         PERL="$PERL"
2032 ])
2033
2034 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2035     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2036         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2037         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2038                 "${ac_abs_top_srcdir}" \
2039                 > "${dst}.tmp"
2040         test -f "${dst}" \
2041                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2042                 && rm "${dst}.tmp" \
2043                 || mv "${dst}.tmp" "${dst}"
2044     ], [
2045         PERL="$PERL"
2046     ])
2047 ])
2048
2049 ## Hack, but working solution to avoid rebuilding of frr.info.
2050 ## It's already in CVS until texinfo 4.7 is more common.
2051 AC_OUTPUT
2052
2053 echo "
2054 FRRouting configuration
2055 ------------------------------
2056 FRR version             : ${PACKAGE_VERSION}
2057 host operating system   : ${host_os}
2058 source code location    : ${srcdir}
2059 compiler                : ${CC}
2060 compiler flags          : ${CFLAGS}
2061 make                    : ${MAKE-make}
2062 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2063 state file directory    : ${frr_statedir}
2064 config file directory   : `eval echo \`echo ${sysconfdir}\``
2065 example directory       : `eval echo \`echo ${exampledir}\``
2066 module directory        : ${CFG_MODULE}
2067 user to run as          : ${enable_user}
2068 group to run as         : ${enable_group}
2069 group for vty sockets   : ${enable_vty_group}
2070 config file mask        : ${enable_configfile_mask}
2071 log file mask           : ${enable_logfile_mask}
2072 zebra protobuf enabled  : ${have_protobuf:-no}
2073
2074 The above user and group must have read/write access to the state file
2075 directory and to the config files in the config file directory."
2076
2077 if test "${enable_doc}" != "no";then
2078   AS_IF([test "x$SPHINXBUILD" = xno],
2079      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2080 fi