configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.1-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST([HOSTTOOLS])
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS([config.h])
  64
  65 AC_PATH_PROG([PERL], [perl])
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST([exampledir])
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST([pkgsrcrcdir])
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94
  95 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
  96         yangmodelsdir="$withval"
  97 ], [
  98         yangmodelsdir="\${datarootdir}/yang"
  99 ])
 100 AC_SUBST([yangmodelsdir])
 101
 102 AC_ARG_WITH([libyang_pluginsdir], [AS_HELP_STRING([--with-libyang-pluginsdir=DIR], [yangmodule plugins directory (${libdir}/frr/libyang_plugins)])], [
 103         libyang_pluginsdir="$withval"
 104 ], [
 105    libyang_pluginsdir="\${libdir}/frr/libyang_plugins"
 106 ])
 107 AC_SUBST([libyang_pluginsdir])
 108
 109 AC_ARG_ENABLE(tcmalloc,
 110         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 111 [case "${enableval}" in
 112   yes) tcmalloc_enabled=true
 113 LIBS="$LIBS -ltcmalloc_minimal"
 114  ;;
 115   no)  tcmalloc_enabled=false ;;
 116   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 117 esac],[tcmalloc_enabled=false])
 118
 119
 120 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 121 dnl flag determination logic.
 122 CFLAGS="${CFLAGS:-}"
 123
 124 dnl --------------------
 125 dnl Check CC and friends
 126 dnl --------------------
 127 dnl note orig_cflags is also used further down
 128 orig_cflags="$CFLAGS"
 129 AC_LANG([C])
 130 AC_PROG_CC
 131 AC_PROG_CPP
 132 AM_PROG_CC_C_O
 133 dnl remove autoconf default "-g -O2"
 134 CFLAGS="$orig_cflags"
 135 AC_PROG_CC_C99
 136 dnl NB: see C11 below
 137
 138 AC_PROG_EGREP
 139 PKG_PROG_PKG_CONFIG
 140
 141 dnl autoconf 2.59 appears not to support AC_PROG_SED
 142 dnl AC_PROG_SED
 143 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 144
 145 dnl try and enable CFLAGS that are useful for FRR
 146 dnl - specifically, options to control warnings
 147
 148 AC_USE_SYSTEM_EXTENSIONS
 149 AC_DEFUN([AC_C_FLAG], [{
 150     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 151     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 152         AC_LANG_PUSH([C])
 153         ac_c_flag_save="$CFLAGS"
 154         CFLAGS="$CFLAGS $1"
 155         AC_COMPILE_IFELSE(
 156                 [AC_LANG_PROGRAM([[]])],
 157                 [
 158                         cachename=yes
 159                 ], [
 160                         cachename=no
 161                 ])
 162         CFLAGS="$ac_c_flag_save"
 163         AC_LANG_POP([C])
 164     ])
 165     if test "${cachename}" = yes; then
 166         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 167     else
 168         :
 169         $2
 170     fi
 171     m4_popdef([cachename])
 172 }])
 173
 174 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 175         AC_LANG_PUSH([C])
 176         ac_cflags_save="$CFLAGS"
 177         ac_libs_save="$LIBS"
 178         CFLAGS="$CFLAGS $1"
 179         LIBS="$LIBS $2"
 180         AC_LINK_IFELSE(
 181                 [$3],
 182                 [
 183                         AC_MSG_RESULT([yes])
 184                         CFLAGS="$ac_cflags_save"
 185                         LIBS="$ac_libs_save"
 186                         $5
 187                 ], [
 188                         AC_MSG_RESULT([no])
 189                         CFLAGS="$ac_cflags_save"
 190                         LIBS="$ac_libs_save"
 191                         $4
 192                 ])
 193         AC_LANG_POP([C])
 194         }])
 195
 196 dnl ICC won't bail on unknown options without -diag-error 10006
 197 dnl need to do this first so we get useful results for the other options
 198 AC_C_FLAG([-diag-error 10006])
 199
 200 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 201 ac_cc="$CC"
 202 CC="${CC% -std=gnu99}"
 203 CC="${CC% -std=c99}"
 204
 205 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 206
 207 dnl if the user has specified any CFLAGS, override our settings
 208 if test "x${enable_gcov}" = "xyes"; then
 209    if test "z$orig_cflags" = "z"; then
 210       AC_C_FLAG([-coverage])
 211       AC_C_FLAG([-O0])
 212    fi
 213
 214    LDFLAGS="${LDFLAGS} -lgcov"
 215 elif test "x${enable_dev_build}" = "xyes"; then
 216    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 217    if test "z$orig_cflags" = "z"; then
 218       AC_C_FLAG([-g3])
 219       AC_C_FLAG([-O0])
 220    fi
 221    if test "x${enable_lua}" = "xyes"; then
 222       AC_CHECK_LIB([lua], [lua_newstate],
 223       [LIBS="$LIBS -llua"])
 224       AC_DEFINE([HAVE_LUA], [1], [Lua enabled for development])
 225    fi
 226 else
 227    if test "x${enable_lua}" = "xyes"; then
 228       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 229    fi
 230    if test "z$orig_cflags" = "z"; then
 231       AC_C_FLAG([-g])
 232       AC_C_FLAG([-Os], [
 233         AC_C_FLAG([-O2])
 234       ])
 235    fi
 236 fi
 237 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 238
 239 dnl always want these CFLAGS
 240 AC_C_FLAG([-fno-omit-frame-pointer])
 241 AC_C_FLAG([-funwind-tables])
 242 AC_C_FLAG([-Wall])
 243 AC_C_FLAG([-Wextra])
 244 AC_C_FLAG([-Wmissing-prototypes])
 245 AC_C_FLAG([-Wmissing-declarations])
 246 AC_C_FLAG([-Wpointer-arith])
 247 AC_C_FLAG([-Wbad-function-cast])
 248 AC_C_FLAG([-Wwrite-strings])
 249 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 250   AC_C_FLAG([-Wcast-qual])
 251   AC_C_FLAG([-Wstrict-prototypes])
 252   AC_C_FLAG([-Wmissing-noreturn])
 253   AC_C_FLAG([-Wmissing-format-attribute])
 254   AC_C_FLAG([-Wunreachable-code])
 255   AC_C_FLAG([-Wpacked])
 256   AC_C_FLAG([-Wpadded])
 257   AC_C_FLAG([-Wshadow])
 258 else
 259   AC_C_FLAG([-Wno-unused-result])
 260 fi
 261 AC_C_FLAG([-Wno-unused-parameter])
 262 AC_C_FLAG([-Wno-missing-field-initializers])
 263
 264 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 265 AC_SUBST([CXX_COMPAT_CFLAGS])
 266
 267 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 268 dnl for some reason the string consts get 'promoted' to char *,
 269 dnl triggering a const to non-const conversion warning.
 270 AC_C_FLAG([-diag-disable 3179])
 271
 272 if test x"${enable_werror}" = x"yes" ; then
 273   WERROR="-Werror"
 274 fi
 275 AC_SUBST([WERROR])
 276
 277 SAN_FLAGS=""
 278 if test "$enable_address_sanitizer" = "yes"; then
 279   AC_C_FLAG([-fsanitize=address], [
 280     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 281   ], [
 282     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 283   ])
 284 fi
 285 if test "$enable_thread_sanitizer" = "yes"; then
 286   AC_C_FLAG([-fsanitize=thread], [
 287     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 288   ], [
 289     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 290   ])
 291 fi
 292 if test "$enable_memory_sanitizer" = "yes"; then
 293   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 294     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 295   ], [
 296     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 297   ])
 298 fi
 299 AC_SUBST([SAN_FLAGS])
 300
 301 dnl ----------
 302 dnl Essentials
 303 dnl ----------
 304
 305 AX_PTHREAD([
 306   CC="$PTHREAD_CC"
 307   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 308   LIBS="$PTHREAD_LIBS $LIBS"
 309 ], [
 310   AC_MSG_FAILURE([This FRR version needs pthreads])
 311 ])
 312
 313 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 314                 [frr_cv_pthread_condattr_setclock=yes],
 315                 [frr_cv_pthread_condattr_setclock=no])
 316 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 317   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 318 fi
 319
 320 dnl --------------
 321 dnl Check programs
 322 dnl --------------
 323 AC_PROG_INSTALL
 324 AC_PROG_LN_S
 325 AC_PROG_MAKE_SET
 326 AC_CHECK_TOOL([AR], [ar])
 327
 328 dnl -------
 329 dnl libtool
 330 dnl -------
 331 AC_ARG_ENABLE([static-bin],
 332   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 333 LT_INIT
 334 _LT_CONFIG_LIBTOOL([
 335   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 336     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 337 ])
 338 if test "$enable_static_bin" = "yes"; then
 339   AC_LDFLAGS="-static"
 340   if test "$enable_static" != "yes"; then
 341     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 342   fi
 343 fi
 344 if test "$enable_shared" != "yes"; then
 345   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 346 fi
 347 AC_SUBST([AC_LDFLAGS])
 348 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 349
 350 dnl $AR and $RANLIB are set by LT_INIT above
 351 AC_MSG_CHECKING([whether $AR supports D option])
 352 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 353   AC_MSG_RESULT([yes])
 354   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 355   ARFLAGS="crD"
 356   AR_FLAGS="crD"
 357 else
 358   AC_MSG_RESULT([no])
 359   ARFLAGS="cru"
 360   AR_FLAGS="cru"
 361 fi
 362 AC_SUBST([ARFLAGS])
 363 AC_SUBST([AR_FLAGS])
 364
 365 AC_MSG_CHECKING([whether $RANLIB supports D option])
 366 if $RANLIB -D conftest.a >/dev/null 2>/dev/null; then
 367   AC_MSG_RESULT([yes])
 368   RANLIB="$RANLIB -D"
 369 else
 370   AC_MSG_RESULT([no])
 371 fi
 372 AC_SUBST([RANLIB])
 373
 374 test -f conftest.a && rm conftest.a
 375
 376 dnl ----------------------
 377 dnl Packages configuration
 378 dnl ----------------------
 379 if test -f config.version; then
 380   . ./config.version
 381 elif test -f "${srcdir}/config.version"; then
 382   . "${srcdir}/config.version"
 383 fi
 384 AC_ARG_WITH([pkg-extra-version],
 385   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 386   if test "$withval" = "no"; then
 387     EXTRAVERSION=
 388   else
 389     EXTRAVERSION=$withval
 390   fi
 391 ], [])
 392 AC_ARG_WITH([pkg-git-version],
 393         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 394         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 395 AC_ARG_WITH([vtysh_pager],
 396         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 397         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 398 AC_ARG_ENABLE([vtysh],
 399   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 400 AC_ARG_ENABLE([doc],
 401   AS_HELP_STRING([--disable-doc], [do not build docs]))
 402 AC_ARG_ENABLE([doc-html],
 403   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 404 AC_ARG_ENABLE([zebra],
 405   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 406 AC_ARG_ENABLE([bgpd],
 407   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 408 AC_ARG_ENABLE([ripd],
 409   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 410 AC_ARG_ENABLE([ripngd],
 411   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 412 AC_ARG_ENABLE([ospfd],
 413   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 414 AC_ARG_ENABLE([ospf6d],
 415   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 416 AC_ARG_ENABLE([ldpd],
 417   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 418 AC_ARG_ENABLE([nhrpd],
 419   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 420 AC_ARG_ENABLE([eigrpd],
 421   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 422 AC_ARG_ENABLE([babeld],
 423   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 424 AC_ARG_ENABLE([watchfrr],
 425   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 426 AC_ARG_ENABLE([isisd],
 427   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 428 AC_ARG_ENABLE([pimd],
 429   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 430 AC_ARG_ENABLE([pbrd],
 431   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 432 AC_ARG_ENABLE([sharpd],
 433   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 434 AC_ARG_ENABLE([staticd],
 435   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 436 AC_ARG_ENABLE([fabricd],
 437   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 438 AC_ARG_ENABLE([bgp-announce],
 439   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 440 AC_ARG_ENABLE([bgp-vnc],
 441   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 442 AC_ARG_ENABLE([snmp],
 443   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 444 AC_ARG_ENABLE([config_rollbacks],
 445   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 446 AC_ARG_ENABLE([confd],
 447   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 448 AC_ARG_ENABLE([sysrepo],
 449   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 450 AC_ARG_ENABLE([zeromq],
 451   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 452 AC_ARG_WITH([libpam],
 453   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 454 AC_ARG_ENABLE([ospfapi],
 455   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 456 AC_ARG_ENABLE([ospfclient],
 457   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 458                           (this is the default if --disable-ospfapi is set)]))
 459 AC_ARG_ENABLE([multipath],
 460   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 461 AC_ARG_ENABLE([user],
 462   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 463 AC_ARG_ENABLE([group],
 464   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 465 AC_ARG_ENABLE([vty_group],
 466   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 467 AC_ARG_ENABLE([configfile_mask],
 468   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 469 AC_ARG_ENABLE([logfile_mask],
 470   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 471 AC_ARG_ENABLE([shell_access],
 472   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 473 AC_ARG_ENABLE([realms],
 474   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 475 AC_ARG_ENABLE([rtadv],
 476   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 477 AC_ARG_ENABLE([irdp],
 478   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 479 AC_ARG_ENABLE([capabilities],
 480   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 481 AC_ARG_ENABLE([rusage],
 482   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 483 AC_ARG_ENABLE([gcc_ultra_verbose],
 484   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 485 AC_ARG_ENABLE([backtrace],
 486   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 487 AC_ARG_ENABLE([time-check],
 488   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 489 AC_ARG_ENABLE([pcreposix],
 490   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 491 AC_ARG_ENABLE([fpm],
 492   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 493 AC_ARG_ENABLE([systemd],
 494   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 495 AC_ARG_ENABLE([werror],
 496   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 497 AC_ARG_ENABLE([cumulus],
 498   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 499 AC_ARG_ENABLE([datacenter],
 500   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 501 AC_ARG_ENABLE([fuzzing],
 502   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 503 AC_ARG_ENABLE([netlink_fuzzing],
 504   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 505 AC_ARG_ENABLE([rr-semantics],
 506   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 507 AC_ARG_ENABLE([protobuf],
 508   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 509 AC_ARG_ENABLE([oldvpn_commands],
 510   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 511 AC_ARG_ENABLE([rpki],
 512   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 513 AC_ARG_ENABLE([clippy-only],
 514   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 515 AC_ARG_ENABLE([numeric_version],
 516   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 517 AC_ARG_ENABLE([gcov],
 518   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 519 AC_ARG_ENABLE([bfdd],
 520   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 521 AC_ARG_ENABLE([address-sanitizer],
 522   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 523 AC_ARG_ENABLE([thread-sanitizer],
 524   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 525 AC_ARG_ENABLE([memory-sanitizer],
 526   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 527
 528 AS_IF([test "${enable_clippy_only}" != "yes"], [
 529 AC_CHECK_HEADERS([json-c/json.h])
 530 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 531 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 532   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 533   if test "$ac_cv_lib_json_json_object_get" = no; then
 534       AC_MSG_ERROR([libjson is needed to compile])
 535   fi
 536 fi
 537 ])
 538
 539 AC_ARG_ENABLE([dev_build],
 540     AS_HELP_STRING([--enable-dev-build], [build for development]))
 541
 542 AC_ARG_ENABLE([lua],
 543     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 544
 545 if test x"${enable_time_check}" != x"no" ; then
 546   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 547     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 548   else
 549     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 550   fi
 551 fi
 552
 553 case "${enable_systemd}" in
 554   "no") ;;
 555   "yes")
 556   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 557   if test $ac_cv_lib_systemd_sd_notify = no; then
 558     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 559   else
 560     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 561   fi
 562   ;;
 563   "*") ;;
 564 esac
 565
 566 if test "${enable_rr_semantics}" != "no" ; then
 567   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 568 fi
 569
 570 if test "${enable_datacenter}" = "yes" ; then
 571   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 572   DFLT_NAME="datacenter"
 573 else
 574   DFLT_NAME="traditional"
 575 fi
 576
 577 if test "${enable_fuzzing}" = "yes" ; then
 578   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 579 fi
 580
 581 if test "${enable_netlink_fuzzing}" = "yes" ; then
 582   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 583 fi
 584
 585 if test "${enable_cumulus}" = "yes" ; then
 586   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 587 fi
 588
 589 AC_SUBST([DFLT_NAME])
 590 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 591
 592 if test "${enable_shell_access}" = "yes"; then
 593    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 594 fi
 595
 596 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 597
 598 #
 599 # Python for clippy
 600 #
 601
 602 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 603   AC_MSG_CHECKING([whether we found a working Python version])
 604   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 605 #include <Python.h>
 606 #if PY_VERSION_HEX < 0x02070000
 607 #error python too old
 608 #endif
 609 int main(void);
 610 ],
 611 [
 612 {
 613   Py_Initialize();
 614   return 0;
 615 }
 616 ])], [
 617     # some python installs are missing the zlib dependency...
 618     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 619     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 620 #include <Python.h>
 621 #if PY_VERSION_HEX < 0x02070000
 622 #error python too old
 623 #endif
 624 int main(void);
 625 ],
 626 [
 627 {
 628   Py_Initialize();
 629   return 0;
 630 }
 631 ])], [
 632       m4_if([$1], [], [
 633         PYTHONCONFIG=""
 634         unset PYTHON_LIBS
 635         unset PYTHON_CFLAGS
 636       ], [$1])
 637     ])
 638   ])
 639 ])
 640
 641 AS_IF([test "$host" = "$build"], [
 642   PYTHONCONFIG=""
 643
 644   # ordering:
 645   # 1.  try python3, but respect the user's preference on which minor ver
 646   # 2.  try python, which might be py3 or py2 again on the user's preference
 647   # 3.  try python2 (can really only be 2.7 but eh)
 648   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 649   #
 650   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 651   # (AX_PYTHON does not do what we need)
 652
 653   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 654         python3-config \
 655         python-config \
 656         python2-config \
 657         python3.6-config \
 658         python3.5-config \
 659         python3.4-config \
 660         python3.3-config \
 661         python3.2-config \
 662         python2.7-config ])
 663   if test -n "$PYTHONCONFIG"; then
 664     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 665     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 666
 667     FRR_PYTHON_CHECK_WORKING([])
 668   fi
 669
 670   if test -z "$PYTHONCONFIG"; then
 671     PKG_CHECK_MODULES([PYTHON], [python-3.6], [], [
 672       PKG_CHECK_MODULES([PYTHON], [python-3.5], [], [
 673         PKG_CHECK_MODULES([PYTHON], [python-3.4], [], [
 674           PKG_CHECK_MODULES([PYTHON], [python-3.3], [], [
 675             PKG_CHECK_MODULES([PYTHON], [python-3.2], [], [
 676               PKG_CHECK_MODULES([PYTHON], [python-2.7], [], [
 677                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 678                 ])])])])])])
 679
 680
 681     FRR_PYTHON_CHECK_WORKING([
 682       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 683     ])
 684   fi
 685 ])
 686 AC_SUBST([PYTHON_CFLAGS])
 687 AC_SUBST([PYTHON_LIBS])
 688
 689 #
 690 # Logic for protobuf support.
 691 #
 692 if test "$enable_protobuf" = "yes"; then
 693   # Check for protoc & protoc-c
 694
 695   # protoc is not required, it's only for a "be nice" helper target
 696   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 697
 698   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 699   if test "$PROTOC_C" = "/bin/false"; then
 700     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 701   fi
 702
 703   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 704     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 705   ])
 706   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 707     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 708   ])
 709
 710   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
 711 fi
 712 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 713
 714 #
 715 # Logic for old vpn commands support.
 716 #
 717 if test "$enable_oldvpn_commands" = "yes"; then
 718    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 719 fi
 720
 721 #
 722 # End of logic for protobuf support.
 723 #
 724
 725 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 726 if test "${enable_rtadv}" != "no"; then
 727   AC_MSG_RESULT([yes])
 728   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 729 else
 730   AC_MSG_RESULT([no])
 731 fi
 732
 733 if test x"${enable_user}" = x"no"; then
 734   enable_user=""
 735 else
 736   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 737     enable_user="frr"
 738   fi
 739   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 740 fi
 741
 742 if test x"${enable_group}" = x"no"; then
 743   enable_group=""
 744 else
 745   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 746     enable_group="frr"
 747   fi
 748   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 749 fi
 750
 751 if test x"${enable_vty_group}" = x"yes" ; then
 752   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 753 elif test x"${enable_vty_group}" != x""; then
 754   if test x"${enable_vty_group}" != x"no"; then
 755     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 756   fi
 757 fi
 758 AC_SUBST([enable_user])
 759 AC_SUBST([enable_group])
 760 AC_SUBST([enable_vty_group])
 761
 762 enable_configfile_mask=${enable_configfile_mask:-0600}
 763 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 764
 765 enable_logfile_mask=${enable_logfile_mask:-0600}
 766 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 767
 768 MPATH_NUM=1
 769
 770 case "${enable_multipath}" in
 771   0)
 772     MPATH_NUM=64
 773     ;;
 774   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 775     MPATH_NUM="${enable_multipath}"
 776     ;;
 777   "")
 778     ;;
 779   *)
 780     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 781     ;;
 782 esac
 783
 784 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 785
 786 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 787
 788 dnl --------------------
 789 dnl Enable code coverage
 790 dnl --------------------
 791 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 792
 793 dnl ------------------------------------
 794 dnl Alpine only accepts numeric versions
 795 dnl ------------------------------------
 796 if test "x${enable_numeric_version}" != "x" ; then
 797   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 798   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 799 fi
 800
 801 dnl -----------------------------------
 802 dnl Add extra version string to package
 803 dnl name, string and version fields.
 804 dnl -----------------------------------
 805 if test "x${EXTRAVERSION}" != "x" ; then
 806   VERSION="${VERSION}${EXTRAVERSION}"
 807   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 808   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 809   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 810 fi
 811 AC_SUBST([EXTRAVERSION])
 812
 813 if test "x$with_pkg_git_version" = "xyes"; then
 814         if test -d "${srcdir}/.git"; then
 815                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 816         else    with_pkg_git_version="no"
 817                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 818         fi
 819 fi
 820 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 821
 822 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 823 if test "x${OBJCOPY}" != "x:"; then
 824   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 825     frr_cv_interp=""
 826     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 827       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 828         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 829       fi
 830       test -f conftest.interp && rm conftest.interp
 831     ])
 832   ])
 833 fi
 834 if test -n "$frr_cv_interp"; then
 835   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 836 fi
 837
 838 dnl ------------------------------------
 839 dnl Check C keywords and standard  types
 840 dnl ------------------------------------
 841 AC_C_CONST
 842 AC_C_INLINE
 843 AC_C_VOLATILE
 844 AC_HEADER_STDC
 845 dnl AC_TYPE_PID_T
 846 AC_TYPE_UID_T
 847 AC_TYPE_MODE_T
 848 AC_TYPE_SIZE_T
 849 AC_STRUCT_TM
 850
 851 dnl -------------------------
 852 dnl Check other header files.
 853 dnl -------------------------
 854 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 855         linux/version.h asm/types.h \
 856         sys/cdefs.h])
 857
 858 ac_stdatomic_ok=false
 859 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 860 AC_CHECK_HEADER([stdatomic.h],[
 861
 862   AC_MSG_CHECKING([whether _Atomic qualifier works])
 863   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 864 #include <stdatomic.h>
 865 int main(int argc, char **argv) {
 866   _Atomic int i = 0;
 867   return i;
 868 }
 869 ]])], [
 870     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 871     AC_MSG_RESULT([yes])
 872     ac_stdatomic_ok=true
 873   ], [
 874     AC_MSG_RESULT([no])
 875   ])
 876 ])
 877
 878 AS_IF([$ac_stdatomic_ok], [true], [
 879   AC_MSG_CHECKING([for __atomic_* builtins])
 880   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 881 int main(int argc, char **argv) {
 882   volatile int i = 1;
 883   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 884   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 885 }
 886 ]])], [
 887     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 888     AC_MSG_RESULT([yes])
 889   ], [
 890     AC_MSG_RESULT([no])
 891
 892     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 893     AC_MSG_CHECKING([for __sync_* builtins])
 894     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 895 int main(int argc, char **argv) {
 896   volatile int i = 1;
 897   __sync_fetch_and_sub (&i, 1);
 898   return __sync_val_compare_and_swap (&i, 0, 1);
 899 }
 900 ]])], [
 901       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 902       AC_MSG_RESULT([yes])
 903
 904       AC_MSG_CHECKING([for __sync_swap builtin])
 905       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 906 int main(int argc, char **argv) {
 907   volatile int i = 1;
 908   return __sync_swap (&i, 2);
 909 }
 910 ]])], [
 911         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 912         AC_MSG_RESULT([yes])
 913       ], [
 914         AC_MSG_RESULT([no])
 915       ])
 916
 917     ], [
 918       AC_MSG_RESULT([no])
 919       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 920     ])
 921   ])
 922 ])
 923
 924 AC_CHECK_HEADERS([pthread_np.h],,, [
 925 #include <pthread.h>
 926 ])
 927 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 928
 929 dnl Utility macro to avoid retyping includes all the time
 930 m4_define([FRR_INCLUDES],
 931 [#ifdef SUNOS_5
 932 #define _POSIX_C_SOURCE 200809L
 933 #define __EXTENSIONS__
 934 #endif
 935 #include <stdio.h>
 936 #include <stdlib.h>
 937 #include <stddef.h>
 938 #include <sys/types.h>
 939 /* sys/conf.h depends on param.h on FBSD at least */
 940 #include <sys/param.h>
 941 /* Required for MAXSIG */
 942 #include <signal.h>
 943 #include <sys/socket.h>
 944 #ifdef __APPLE__
 945 # define __APPLE_USE_RFC_3542
 946 #endif
 947 #include <netinet/in.h>
 948 #include <sys/time.h>
 949 #include <time.h>
 950 #include <net/if.h>
 951 ])dnl
 952
 953 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 954 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 955 dnl an additional round for it.
 956
 957 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
 958
 959 m4_define([FRR_INCLUDES],
 960 FRR_INCLUDES
 961 [#if HAVE_NET_IF_VAR_H
 962 # include <net/if_var.h>
 963 #endif
 964 ])dnl
 965
 966 AC_CHECK_HEADERS([netinet/in_var.h \
 967         net/if_dl.h net/netopt.h \
 968         inet/nd.h netinet/ip_icmp.h \
 969         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 970         [], [], [FRR_INCLUDES])
 971
 972 AC_CHECK_HEADERS([ucontext.h], [], [],
 973 [#ifndef __USE_GNU
 974 #define __USE_GNU
 975 #endif /* __USE_GNU */
 976 FRR_INCLUDES
 977 ])
 978
 979 m4_define([UCONTEXT_INCLUDES],
 980 [#include <ucontext.h>])dnl
 981
 982 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 983   [], [], [UCONTEXT_INCLUDES])
 984 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 985   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 986    [], [], [UCONTEXT_INCLUDES])],
 987   [], [UCONTEXT_INCLUDES])
 988 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 989   [], [], [UCONTEXT_INCLUDES])
 990
 991 m4_define([FRR_INCLUDES],
 992 FRR_INCLUDES
 993 [
 994 #include <sys/un.h>
 995 #include <netinet/in_systm.h>
 996 #if HAVE_NETINET_IN_VAR_H
 997 # include <netinet/in_var.h>
 998 #endif
 999 #if HAVE_NET_IF_DL_H
1000 # include <net/if_dl.h>
1001 #endif
1002 #if HAVE_NET_NETOPT_H
1003 # include <net/netopt.h>
1004 #endif
1005 #include <net/route.h>
1006 #if HAVE_INET_ND_H
1007 # include <inet/nd.h>
1008 #endif
1009 #include <arpa/inet.h>
1010 /* Required for IDRP */
1011 #if HAVE_NETINET_IP_ICMP_H
1012 # include <netinet/ip_icmp.h>
1013 #endif
1014 ])dnl
1015
1016 dnl V6 headers are checked below, after we check for v6
1017
1018 AC_MSG_CHECKING([which operating system interface to use])
1019 case "$host_os" in
1020   sunos* | solaris2*)
1021     AC_MSG_RESULT([Solaris])
1022
1023     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1024     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1025     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1026
1027     AC_CHECK_LIB([socket], [main])
1028     AC_CHECK_LIB([nsl], [main])
1029     AC_CHECK_LIB([umem], [main])
1030     SOLARIS="solaris"
1031     ;;
1032   linux*)
1033     AC_MSG_RESULT([Linux])
1034
1035     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1036     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1037     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1038
1039     dnl Linux has a compilation problem with mixing
1040     dnl netinet/in.h and linux/in6.h they are not
1041     dnl compatible.  There has been discussion on
1042     dnl how to fix it but no real progress on implementation
1043     dnl when they fix it, remove this
1044     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1045     ;;
1046   openbsd*)
1047     AC_MSG_RESULT([OpenBSD])
1048
1049     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1050     AC_DEFINE([KAME], [1], [KAME IPv6])
1051     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1052
1053     if test "x${enable_pimd}" != "xno"; then
1054       case "$host_os" in
1055       openbsd6.0)
1056         ;;
1057       openbsd[6-9]*)
1058         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1059         ;;
1060       esac
1061     fi
1062     ;;
1063   *)
1064     AC_MSG_RESULT([BSD])
1065
1066     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1067     AC_DEFINE([KAME], [1], [KAME IPv6])
1068     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1069     ;;
1070 esac
1071 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1072
1073 AC_SYS_LARGEFILE
1074
1075 dnl ------------------------
1076 dnl Integrated REALMS option
1077 dnl ------------------------
1078 if test "${enable_realms}" = "yes"; then
1079     case "$host_os" in
1080       linux*)
1081        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1082        ;;
1083       *)
1084        echo "Sorry, only Linux has REALMS support"
1085        exit 1
1086        ;;
1087     esac
1088 fi
1089 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1090
1091 dnl ---------------------
1092 dnl Integrated VTY option
1093 dnl ---------------------
1094 case "${enable_vtysh}" in
1095 "no")
1096   VTYSH="";;
1097 *)
1098   VTYSH="vtysh";
1099   AC_DEFINE([VTYSH], [1], [VTY shell])
1100
1101   prev_libs="$LIBS"
1102   AC_CHECK_LIB([readline], [main], [
1103     LIBREADLINE="-lreadline"
1104   ], [
1105     dnl readline failed - it might be incorrectly linked and missing its
1106     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1107     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1108       LIBREADLINE="$ac_cv_search_tputs"
1109     ], [
1110       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1111     ])
1112
1113     dnl re-try with the lib we found above
1114     unset ac_cv_lib_readline_main
1115     AC_CHECK_LIB([readline], [main], [
1116       LIBREADLINE="-lreadline $LIBREADLINE"
1117     ], [
1118       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1119     ], [$LIBREADLINE])
1120   ], [])
1121   LIBS="$prev_libs"
1122
1123   AC_CHECK_HEADER([readline/history.h])
1124   if test $ac_cv_header_readline_history_h = no;then
1125     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1126   fi
1127   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1128   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1129     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1130   fi
1131   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1132   if test "$frr_cv_append_history" = yes; then
1133     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1134   fi
1135   ;;
1136 esac
1137 AC_SUBST([LIBREADLINE])
1138 AM_CONDITIONAL([VTYSH], test "x$VTYSH" = "xvtysh")
1139
1140 dnl ----------
1141 dnl PAM module
1142 dnl
1143 dnl FRR detects the PAM library it is built against by checking for a
1144 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1145 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1146 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1147 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1148 dnl of OpenPAM.
1149 dnl ----------
1150 if test "$with_libpam" = "yes"; then
1151   AC_CHECK_HEADER([security/pam_misc.h],
1152     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1153      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1154      pam_conv_func="misc_conv"
1155     ],
1156     [], FRR_INCLUDES)
1157   AC_CHECK_HEADER([security/openpam.h],
1158     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1159      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1160      pam_conv_func="openpam_ttyconv"
1161     ],
1162     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1163   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1164     AC_MSG_WARN([*** pam support will not be built ***])
1165     with_libpam="no"
1166   fi
1167 fi
1168
1169 if test "$with_libpam" = "yes"; then
1170 dnl took this test from proftpds configure.in and suited to our needs
1171 dnl -------------------------------------------------------------------------
1172 dnl
1173 dnl This next check looks funky due to a linker problem with some versions
1174 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1175 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1176 dnl with RedHat 6.2 and Debian 2.2 or better.
1177 AC_CHECK_LIB([pam], [pam_start],
1178   [AC_CHECK_LIB([pam], [$pam_conv_func],
1179     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1180      LIBPAM="-lpam"],
1181     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1182      LIBPAM="-lpam -lpam_misc"]
1183     )
1184   ],
1185
1186   [AC_CHECK_LIB([pam], [pam_end],
1187     [AC_CHECK_LIB([pam], [$pam_conv_func],
1188       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1189        LIBPAM="-lpam -ldl"],
1190       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1191        LIBPAM="-lpam -ldl -lpam_misc"]
1192      )
1193   ],AC_MSG_WARN([*** pam support will not be built ***]),
1194   [-ldl])
1195   ]
1196 )
1197 fi
1198 AC_SUBST([LIBPAM])
1199
1200 dnl -------------------------------
1201 dnl Endian-ness check
1202 dnl -------------------------------
1203 AC_WORDS_BIGENDIAN
1204
1205 dnl -------------------------------
1206 dnl check the size in byte of the C
1207 dnl -------------------------------
1208 dnl AC_CHECK_SIZEOF(char)
1209 dnl AC_CHECK_SIZEOF(int)
1210 dnl AC_CHECK_SIZEOF(short)
1211 dnl AC_CHECK_SIZEOF(long)
1212
1213 dnl ----------------------------
1214 dnl check existance of functions
1215 dnl ----------------------------
1216 AC_FUNC_FNMATCH
1217 AC_FUNC_FORK
1218 AC_FUNC_MKTIME
1219 AC_FUNC_STAT
1220
1221 dnl -------------------------------
1222 dnl bgpd needs pow() and hence libm
1223 dnl -------------------------------
1224 TMPLIBS="$LIBS"
1225 AC_CHECK_HEADER([math.h],
1226   [AC_CHECK_LIB([m], [pow],
1227     [LIBM="-lm"
1228      LIBS="$LIBS $LIBM"
1229      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1230     ])
1231 ])
1232 if test x"$LIBM" = x ; then
1233   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1234 fi
1235 LIBS="$TMPLIBS"
1236
1237 AC_SUBST([LIBM])
1238
1239 AC_CHECK_FUNCS([ppoll], [
1240   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1241 ])
1242 AC_CHECK_FUNCS([pollts], [
1243   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1244 ])
1245
1246 dnl ---------------
1247 dnl other functions
1248 dnl ---------------
1249 AC_CHECK_FUNCS([ \
1250         strlcat strlcpy \
1251         getgrouplist])
1252
1253 AC_CHECK_HEADER([asm-generic/unistd.h],
1254                 [AC_CHECK_DECL(__NR_setns,
1255                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1256                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1257                                ])
1258                  AC_CHECK_FUNCS([setns])]
1259                )
1260
1261 dnl --------------------------
1262 dnl Determine IS-IS I/O method
1263 dnl --------------------------
1264 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1265 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1266 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1267 AC_CHECK_HEADER([net/bpf.h])
1268 AC_CHECK_HEADER([sys/dlpi.h])
1269 AC_MSG_CHECKING([zebra IS-IS I/O method])
1270
1271 case "$host_os" in
1272   linux*)
1273     AC_MSG_RESULT([pfpacket])
1274     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1275     ;;
1276   solaris* | sunos*)
1277     AC_MSG_RESULT([DLPI])
1278     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1279     ;;
1280   *)
1281     if test $ac_cv_header_net_bpf_h = no; then
1282       if test $ac_cv_header_sys_dlpi_h = no; then
1283         AC_MSG_RESULT([none])
1284         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1285           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1286         fi
1287         AC_MSG_WARN([*** IS-IS support will not be built ***])
1288         enable_isisd="no"
1289         enable_fabricd="no"
1290       else
1291         AC_MSG_RESULT([DLPI])
1292       fi
1293       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1294     else
1295       AC_MSG_RESULT([BPF])
1296       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1297     fi
1298     ;;
1299 esac
1300 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1301
1302 dnl ---------------------------------------------------------------
1303 dnl figure out how to specify an interface in multicast sockets API
1304 dnl ---------------------------------------------------------------
1305 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1306
1307 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1308         #include <sys/socket.h>
1309         #include <netinet/in.h>
1310         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1311         #include <linux/types.h>
1312 ])
1313
1314 m4_define([FRR_INCLUDES],
1315 FRR_INCLUDES
1316 [#if HAVE_LINUX_MROUTE_H
1317 # include <linux/mroute.h>
1318 #endif
1319 ])dnl
1320
1321 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1322         #include <sys/socket.h>
1323         #include <sys/types.h>
1324         #include <netinet/in.h>
1325         #include <net/route.h>
1326 ])
1327
1328 m4_define([FRR_INCLUDES],
1329 FRR_INCLUDES
1330 [#if HAVE_NETINET_IP_MROUTE_H
1331 # include <netinet/ip_mroute.h>
1332 #endif
1333 ])dnl
1334
1335 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1336 AC_TRY_COMPILE([#include <sys/param.h>],
1337 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1338   return (0);
1339 #else
1340   #error No support for BSD struct ip_mreq hack detected
1341 #endif],[AC_MSG_RESULT([yes])
1342 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1343 AC_MSG_RESULT([no]))
1344
1345 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1346 AC_TRY_COMPILE([
1347 #include <sys/types.h>
1348 #include <netinet/in.h>
1349 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1350 ], [AC_MSG_RESULT([yes])
1351 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1352 AC_MSG_RESULT([no]))
1353
1354 dnl ---------------------------------------------------------------
1355 dnl figure out how to check link-state
1356 dnl ---------------------------------------------------------------
1357 AC_CHECK_HEADER([net/if_media.h],
1358   [m4_define([LINK_DETECT_INCLUDES],
1359     FRR_INCLUDES
1360     [#include <net/if_media.h>
1361   ])
1362   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1363     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1364     [], LINK_DETECT_INCLUDES)],
1365   [],
1366   FRR_INCLUDES)
1367
1368 dnl ---------------------------------------------------------------
1369 dnl Additional, newer way to check link-state using ifi_link_state.
1370 dnl Not available in all BSD's when ifmediareq available
1371 dnl ---------------------------------------------------------------
1372 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1373   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1374   [], FRR_INCLUDES)
1375
1376 dnl ------------------------
1377 dnl TCP_MD5SIG socket option
1378 dnl ------------------------
1379
1380 AC_CHECK_HEADER([netinet/tcp.h],
1381    [m4_define([MD5_INCLUDES],
1382       FRR_INCLUDES
1383       [#include <netinet/tcp.h>
1384     ])
1385     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1386    [],
1387    FRR_INCLUDES)
1388 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1389   AC_CHECK_HEADER([linux/tcp.h],
1390        [m4_define([MD5_INCLUDES],
1391           FRR_INCLUDES
1392           [#include <linux/tcp.h>
1393         ])
1394        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1395 fi
1396
1397 dnl ----------------------------------------------------------------------------
1398 dnl figure out if domainname is available in the utsname struct (GNU extension).
1399 dnl ----------------------------------------------------------------------------
1400 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1401
1402 dnl ------------------
1403 dnl IPv6 header checks
1404 dnl ------------------
1405 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1406         netinet6/in6_var.h netinet6/nd6.h], [], [],
1407         FRR_INCLUDES)
1408
1409 m4_define([FRR_INCLUDES],dnl
1410 FRR_INCLUDES
1411 [#if HAVE_NETINET6_IN6_H
1412 #include <netinet6/in6.h>
1413 #endif
1414 #if HAVE_NETINET_IN6_VAR_H
1415 #include <netinet/in6_var.h>
1416 #endif
1417 #include <netinet/icmp6.h>
1418 #if HAVE_NETINET6_IN6_VAR_H
1419 # include <netinet6/in6_var.h>
1420 #endif
1421 #if HAVE_NETINET6_ND6_H
1422 # include <netinet6/nd6.h>
1423 #endif
1424 ])dnl
1425
1426 dnl disable doc check
1427 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1428 if test "$SPHINXBUILD" = "/bin/false"; then
1429   if test "${enable_doc}" = "yes"; then
1430     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1431   fi
1432 fi
1433 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false"])
1434 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
1435
1436 dnl --------------------
1437 dnl Daemon disable check
1438 dnl --------------------
1439 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
1440
1441 if test "${enable_bgpd}" = "no";then
1442   BGPD=""
1443 else
1444   BGPD="bgpd"
1445 fi
1446 AM_CONDITIONAL([BGPD], [test "x$BGPD" = "xbgpd"])
1447
1448 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
1449 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
1450 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
1451
1452 AS_IF([test "${enable_ldpd}" != "no"], [
1453   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1454 ])
1455
1456 if test "$enable_bfdd" = "no"; then
1457   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1458   BFDD=""
1459 else
1460   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1461   BFDD="bfdd"
1462
1463   case $host_os in
1464     linux*)
1465       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1466       ;;
1467
1468     *)
1469       AC_DEFINE([BFD_BSD], [1], [bfdd])
1470       ;;
1471   esac
1472 fi
1473
1474 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
1475
1476 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1477   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1478 fi
1479
1480 NHRPD=""
1481 case "$host_os" in
1482   linux*)
1483     if test "${enable_nhrpd}" != "no"; then
1484       NHRPD="nhrpd"
1485     fi
1486     ;;
1487   *)
1488     if test "${enable_nhrpd}" = "yes"; then
1489       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1490     fi
1491     ;;
1492 esac
1493 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
1494
1495 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
1496
1497 if test "${enable_watchfrr}" = "no";then
1498   WATCHFRR=""
1499 else
1500   WATCHFRR="watchfrr"
1501 fi
1502 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
1503
1504 OSPFCLIENT=""
1505 if test "${enable_ospfapi}" != "no";then
1506     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1507
1508   if test "${enable_ospfclient}" != "no";then
1509       OSPFCLIENT="ospfclient"
1510   fi
1511 fi
1512
1513 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
1514 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
1515 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
1516 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
1517 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
1518 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
1519 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
1520 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
1521 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
1522 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
1523
1524 if test "${enable_bgp_announce}" = "no";then
1525   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1526 else
1527   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1528 fi
1529
1530 if test "${enable_bgp_vnc}" != "no";then
1531   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1532 fi
1533 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1534
1535 AC_SUBST([SOLARIS])
1536 AC_CHECK_LIB([crypt], [crypt], [],
1537                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1538 AC_CHECK_LIB([resolv], [res_init])
1539
1540 dnl ---------------------------
1541 dnl check system has PCRE regexp
1542 dnl ---------------------------
1543 if test "x$enable_pcreposix" = "xyes"; then
1544   AC_CHECK_LIB([pcreposix], [regexec], [], [
1545     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1546   ])
1547 fi
1548 AC_SUBST([HAVE_LIBPCREPOSIX])
1549
1550 dnl ------------------
1551 dnl check C-Ares library
1552 dnl ------------------
1553 if test "${NHRPD}" != ""; then
1554   PKG_CHECK_MODULES([CARES], [libcares], ,[
1555     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1556   ])
1557 fi
1558
1559
1560 dnl ------------------
1561 dnl check Net-SNMP library
1562 dnl ------------------
1563 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1564    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1565    if test x"$NETSNMP_CONFIG" = x"no"; then
1566       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1567    fi
1568    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1569    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1570    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1571    # among other things we avoid a GPL vs. OpenSSL license conflict here
1572    for removelib in crypto ssl sensors pci wrap; do
1573      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1574    done
1575    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1576    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1577 int main(void);
1578 ],
1579 [
1580 {
1581   return 0;
1582 }
1583 ])], [
1584      AC_MSG_ERROR([--enable-snmp given but not usable])])
1585    case "${enable_snmp}" in
1586      yes)
1587       SNMP_METHOD=agentx
1588       ;;
1589      agentx)
1590       SNMP_METHOD="${enable_snmp}"
1591       ;;
1592      *)
1593       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1594       ;;
1595    esac
1596    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1597    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1598 fi
1599 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1600 AC_SUBST([SNMP_LIBS])
1601 AC_SUBST([SNMP_CFLAGS])
1602
1603 dnl ---------------
1604 dnl libyang
1605 dnl ---------------
1606 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.7], , [
1607   AC_MSG_ERROR([libyang (>= 0.16.7) was not found on your system.])
1608 ])
1609 ac_cflags_save="$CFLAGS"
1610 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1611 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1612   AC_MSG_ERROR([m4_normalize([
1613     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1614     See http://docs.frrouting.org/projects/dev-guide/en/latest/building-libyang.html for details.])
1615   ])
1616 ], [[#include <libyang/libyang.h>]])
1617 CFLAGS="$ac_cflags_save"
1618
1619 ac_libs_save="$LIBS"
1620 LIBS="$LIBS $LIBYANG_LIBS"
1621 AC_CHECK_FUNC([ly_register_types], [
1622   libyang_ext_builtin=true
1623   AC_DEFINE([LIBYANG_EXT_BUILTIN], [1], [have ly_register_types()])
1624 ], [
1625   libyang_ext_builtin=false
1626   AC_MSG_WARN([===== old libyang (before 0.16.74) detected =====])
1627   AC_MSG_WARN([The available version of libyang does not seem to support])
1628   AC_MSG_WARN([built-in YANG extension modules.  This will cause "make check"])
1629   AC_MSG_WARN([to fail and may create installation and version mismatch issues.])
1630   AC_MSG_WARN([Support for the old mechanism will be removed at some point.])
1631   AC_MSG_WARN([Please update libyang to version 0.16.74 or newer.])
1632   AC_MSG_WARN([===== old libyang (before 0.16.74) detected =====])
1633 ])
1634 AM_CONDITIONAL([LIBYANG_EXT_BUILTIN], [$libyang_ext_builtin])
1635 LIBS="$ac_libs_save"
1636
1637 dnl ---------------
1638 dnl configuration rollbacks
1639 dnl ---------------
1640 SQLITE3=false
1641 if test "$enable_config_rollbacks" = "yes"; then
1642   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1643     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1644     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1645     SQLITE3=true
1646   ], [
1647     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1648   ])
1649 fi
1650 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
1651
1652 dnl ---------------
1653 dnl confd
1654 dnl ---------------
1655 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1656    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1657    if test "x$CONFD" = "x/bin/false"; then
1658       AC_MSG_ERROR([confd was not found on your system.])]
1659    fi
1660    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1661    AC_SUBST([CONFD_CFLAGS])
1662    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1663 fi
1664 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
1665
1666 dnl ---------------
1667 dnl sysrepo
1668 dnl ---------------
1669 if test "$enable_sysrepo" = "yes"; then
1670   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1671       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1672       SYSREPO=true],
1673       [SYSREPO=false
1674       AC_MSG_ERROR([sysrepo was not found on your system.])]
1675   )
1676 fi
1677 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
1678
1679 dnl ---------------
1680 dnl math
1681 dnl ---------------
1682 AC_SEARCH_LIBS([sqrt], [m])
1683
1684 dnl ---------------
1685 dnl dlopen & dlinfo
1686 dnl ---------------
1687 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1688   AC_MSG_ERROR([unable to find the dlopen()])
1689 ])
1690
1691 AC_CHECK_HEADERS([link.h])
1692
1693 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1694   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1695 #include <stdlib.h>
1696 #ifdef HAVE_LINK_H
1697 #include <link.h>
1698 #endif
1699 #include <dlfcn.h>
1700 ]], [[
1701   char origin[1];
1702   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1703 ]])], [
1704     frr_cv_rtld_di_origin=yes
1705   ], [
1706     frr_cv_rtld_di_origin=no
1707   ])
1708 ])
1709 if test "$frr_cv_rtld_di_origin" = yes; then
1710   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1711 fi
1712
1713 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1714   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1715 #include <stdlib.h>
1716 #ifdef HAVE_LINK_H
1717 #include <link.h>
1718 #endif
1719 #include <dlfcn.h>
1720 ]], [[
1721   struct link_map *lm = NULL;
1722   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1723 ]])], [
1724     frr_cv_rtld_di_linkmap=yes
1725   ], [
1726     frr_cv_rtld_di_linkmap=no
1727   ])
1728 ])
1729 if test "$frr_cv_rtld_di_linkmap" = yes; then
1730   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1731 fi
1732
1733 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
1734
1735 dnl ---------------------------
1736 dnl sockaddr and netinet checks
1737 dnl ---------------------------
1738 AC_CHECK_TYPES([
1739         struct sockaddr_dl,
1740         struct vifctl, struct mfcctl, struct sioc_sg_req,
1741         vifi_t, struct sioc_vif_req, struct igmpmsg,
1742         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1743         struct nd_opt_adv_interval, struct rt_addrinfo,
1744         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1745         struct nd_opt_rdnss, struct nd_opt_dnssl],
1746         [], [], FRR_INCLUDES)
1747
1748 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1749         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1750         struct sockaddr_dl.sdl_len,
1751         struct if6_aliasreq.ifra_lifetime,
1752         struct nd_opt_adv_interval.nd_opt_ai_type],
1753         [], [], FRR_INCLUDES)
1754
1755 dnl ---------------------------
1756 dnl IRDP/pktinfo/icmphdr checks
1757 dnl ---------------------------
1758
1759 AC_CHECK_TYPES([struct in_pktinfo], [
1760   AC_CHECK_TYPES([struct icmphdr], [
1761     IRDP=true
1762   ], [
1763     IRDP=false
1764   ], [FRR_INCLUDES])
1765 ], [
1766   IRDP=false
1767 ], [FRR_INCLUDES])
1768
1769 case "${enable_irdp}" in
1770 yes)
1771   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1772   ;;
1773 no)
1774   IRDP=false
1775   ;;
1776 esac
1777
1778 AM_CONDITIONAL([IRDP], [$IRDP])
1779
1780 dnl -----------------------
1781 dnl checking for IP_PKTINFO
1782 dnl -----------------------
1783 AC_MSG_CHECKING([for IP_PKTINFO])
1784 AC_TRY_COMPILE([#include <netdb.h>], [
1785   int opt = IP_PKTINFO;
1786 ], [
1787   AC_MSG_RESULT([yes])
1788   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1789 ], [
1790   AC_MSG_RESULT([no])
1791 ])
1792
1793 dnl ---------------------------
1794 dnl checking for IP_RECVDSTADDR
1795 dnl ---------------------------
1796 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1797 AC_TRY_COMPILE([#include <netinet/in.h>], [
1798   int opt = IP_RECVDSTADDR;
1799 ], [
1800   AC_MSG_RESULT([yes])
1801   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1802 ], [
1803   AC_MSG_RESULT([no])
1804 ])
1805
1806 dnl ----------------------
1807 dnl checking for IP_RECVIF
1808 dnl ----------------------
1809 AC_MSG_CHECKING([for IP_RECVIF])
1810 AC_TRY_COMPILE([#include <netinet/in.h>], [
1811   int opt = IP_RECVIF;
1812 ], [
1813   AC_MSG_RESULT([yes])
1814   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1815 ], [
1816   AC_MSG_RESULT([no])
1817 ])
1818
1819 dnl ----------------------
1820 dnl checking for SO_BINDANY
1821 dnl ----------------------
1822 AC_MSG_CHECKING([for SO_BINDANY])
1823 AC_TRY_COMPILE([#include <sys/socket.h>], [
1824   int opt = SO_BINDANY;
1825 ], [
1826   AC_MSG_RESULT([yes])
1827   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1828 ], [
1829   AC_MSG_RESULT([no])
1830 ])
1831
1832 dnl ----------------------
1833 dnl checking for IP_FREEBIND
1834 dnl ----------------------
1835 AC_MSG_CHECKING([for IP_FREEBIND])
1836 AC_TRY_COMPILE([#include <netinet/in.h>], [
1837   int opt = IP_FREEBIND;
1838 ], [
1839   AC_MSG_RESULT([yes])
1840   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1841 ], [
1842   AC_MSG_RESULT([no])
1843 ])
1844
1845 dnl --------------------------------------
1846 dnl checking for be32dec existence or not
1847 dnl --------------------------------------
1848 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1849                [#include <sys/endian.h>])
1850
1851 dnl --------------------------------------
1852 dnl checking for clock_time monotonic struct and call
1853 dnl --------------------------------------
1854 AC_CHECK_DECL([CLOCK_MONOTONIC],
1855         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1856          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1857 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1858
1859 dnl --------------------------------------
1860 dnl checking for flex and bison
1861 dnl --------------------------------------
1862
1863 AM_PROG_LEX
1864 AC_MSG_CHECKING([version of flex])
1865 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1866 frr_ac_flex_version="${frr_ac_flex_version##* }"
1867 AC_MSG_RESULT([$frr_ac_flex_version])
1868 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1869   LEX="$SHELL $missing_dir/missing flex"
1870   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1871     AC_MSG_WARN([using pregenerated flex output files])
1872   else
1873     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1874   fi
1875   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1876   AC_SUBST([LEXLIB], [''])
1877 ])
1878
1879 AC_PROG_YACC
1880 dnl thanks GNU bison for this b*llshit...
1881 AC_MSG_CHECKING([version of bison])
1882 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1883 frr_ac_bison_version="${frr_ac_bison_version##* }"
1884 frr_ac_bison_missing="false"
1885 case "x${frr_ac_bison_version}" in
1886   x2.7*)
1887     BISON_OPENBRACE='"'
1888     BISON_CLOSEBRACE='"'
1889     BISON_VERBOSE=''
1890     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1891     ;;
1892   x2.*|x1.*)
1893     AC_MSG_RESULT([$frr_ac_bison_version])
1894     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1895     frr_ac_bison_missing="true"
1896     ;;
1897   x)
1898     AC_MSG_RESULT([none])
1899     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1900     frr_ac_bison_missing="true"
1901     ;;
1902   *)
1903     BISON_OPENBRACE='{'
1904     BISON_CLOSEBRACE='}'
1905     BISON_VERBOSE='-Dparse.error=verbose'
1906     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1907     ;;
1908 esac
1909 AC_SUBST([BISON_OPENBRACE])
1910 AC_SUBST([BISON_CLOSEBRACE])
1911 AC_SUBST([BISON_VERBOSE])
1912
1913 if $frr_ac_bison_missing; then
1914   YACC="$SHELL $missing_dir/missing bison -y"
1915   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1916     AC_MSG_WARN([using pregenerated bison output files])
1917   else
1918     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1919   fi
1920 fi
1921
1922 dnl -------------------
1923 dnl capabilities checks
1924 dnl -------------------
1925 if test "${enable_capabilities}" != "no"; then
1926   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
1927   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1928     [AC_MSG_RESULT([yes])
1929      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
1930      frr_ac_keepcaps="yes"],
1931      AC_MSG_RESULT([no])
1932   )
1933   if test x"${frr_ac_keepcaps}" = x"yes"; then
1934     AC_CHECK_HEADERS([sys/capability.h])
1935   fi
1936   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1937     AC_CHECK_LIB([cap], [cap_init],
1938       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
1939        LIBCAP="-lcap"
1940        frr_ac_lcaps="yes"]
1941     )
1942   else
1943     AC_CHECK_HEADERS([priv.h],
1944      [AC_MSG_CHECKING([Solaris style privileges are available])
1945       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
1946           [AC_MSG_RESULT([yes])
1947            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
1948            frr_ac_scaps="yes"],
1949            AC_MSG_RESULT(no)
1950       )
1951      ]
1952    )
1953   fi
1954   if test x"${frr_ac_scaps}" = x"yes" \
1955        -o x"${frr_ac_lcaps}" = x"yes"; then
1956     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
1957   fi
1958 fi
1959 AC_SUBST([LIBCAP])
1960
1961 dnl ---------------------------
1962 dnl check for glibc 'backtrace'
1963 dnl ---------------------------
1964 if test x"${enable_backtrace}" != x"no" ; then
1965   backtrace_ok=no
1966   PKG_CHECK_MODULES([UNWIND], [libunwind], [
1967     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
1968     backtrace_ok=yes
1969   ], [
1970     case "$host_os" in
1971     sunos* | solaris2*)
1972       AC_CHECK_FUNCS([printstack], [
1973         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
1974         backtrace_ok=yes
1975       ])
1976       ;;
1977     esac
1978     if test "$backtrace_ok" = no; then
1979       AC_CHECK_HEADER([execinfo.h], [
1980         AC_SEARCH_LIBS([backtrace], [execinfo], [
1981           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
1982           backtrace_ok=yes
1983         ],, [-lm])
1984       ])
1985     fi
1986   ])
1987
1988   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1989     dnl user explicitly requested backtrace but we failed to find support
1990     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
1991   fi
1992 fi
1993
1994 dnl -----------------------------------------
1995 dnl check for malloc mallinfo struct and call
1996 dnl this must try and link using LIBS, in
1997 dnl order to check no alternative allocator
1998 dnl has been specified, which might not provide
1999 dnl mallinfo, e.g. such as Umem on Solaris.
2000 dnl -----------------------------------------
2001 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2002
2003 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2004   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2005 #ifdef HAVE_MALLOC_H
2006 #include <malloc.h>
2007 #endif
2008 #ifdef HAVE_MALLOC_NP_H
2009 #include <malloc_np.h>
2010 #endif
2011 #ifdef HAVE_MALLOC_MALLOC_H
2012 #include <malloc/malloc.h>
2013 #endif
2014 ]], [[
2015 struct mallinfo ac_x; ac_x = mallinfo ();
2016 ]])], [
2017     frr_cv_mallinfo=yes
2018   ], [
2019     frr_cv_mallinfo=no
2020   ])
2021 ])
2022 if test "$frr_cv_mallinfo" = yes; then
2023   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2024 fi
2025
2026 AC_MSG_CHECKING([whether malloc_usable_size is available])
2027 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2028 #ifdef HAVE_MALLOC_H
2029 #include <malloc.h>
2030 #endif
2031 #ifdef HAVE_MALLOC_MALLOC_H
2032 #include <malloc/malloc.h>
2033 #endif
2034 ]], [[
2035 size_t ac_x; ac_x = malloc_usable_size(NULL);
2036 ]])], [
2037   AC_MSG_RESULT([yes])
2038   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2039 ], [
2040   AC_MSG_RESULT([no])
2041
2042   AC_MSG_CHECKING([whether malloc_size is available])
2043   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2044 #ifdef HAVE_MALLOC_H
2045 #include <malloc.h>
2046 #endif
2047 #ifdef HAVE_MALLOC_MALLOC_H
2048 #include <malloc/malloc.h>
2049 #endif
2050 ]], [[
2051 size_t ac_x; ac_x = malloc_size(NULL);
2052 ]])], [
2053     AC_MSG_RESULT([yes])
2054     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2055   ], [
2056     AC_MSG_RESULT([no])
2057   ])
2058 ])
2059
2060 dnl ------
2061 dnl ZeroMQ
2062 dnl ------
2063 if test "x$enable_zeromq" != "xno"; then
2064   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2065     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2066     ZEROMQ=true
2067   ], [
2068     if test "x$enable_zeromq" = "xyes"; then
2069       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2070     fi
2071   ])
2072 fi
2073 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2074
2075 dnl ----------
2076 dnl configure date
2077 dnl ----------
2078 dev_version=`echo $VERSION | grep dev`
2079 #don't expire deprecated code in non 'dev' branch
2080 if test "${dev_version}" = ""; then
2081    CONFDATE=0
2082 else
2083    CONFDATE=`date '+%Y%m%d'`
2084 fi
2085 AC_SUBST([CONFDATE])
2086
2087 dnl ------------------------------
2088 dnl set paths for state directory
2089 dnl ------------------------------
2090 AC_MSG_CHECKING([directory to use for state file])
2091 if test "${prefix}" = "NONE"; then
2092   frr_statedir_prefix="";
2093 else
2094   frr_statedir_prefix=${prefix}
2095 fi
2096 if test "${localstatedir}" = '${prefix}/var'; then
2097   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2098                         ${frr_statedir_prefix}/var/adm dnl
2099                         ${frr_statedir_prefix}/etc dnl
2100                         /var/run        dnl
2101                         /var/adm        dnl
2102                         /etc            dnl
2103                         /dev/null;
2104   do
2105     test -d $FRR_STATE_DIR && break
2106   done
2107   frr_statedir=$FRR_STATE_DIR
2108 else
2109   frr_statedir=${localstatedir}
2110 fi
2111 if test $frr_statedir = "/dev/null"; then
2112     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2113 fi
2114 AC_MSG_RESULT([${frr_statedir}])
2115 AC_SUBST([frr_statedir])
2116
2117 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir/ldpd.sock"], [ldpd control socket])
2118 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir/zserv.api"], [zebra api socket])
2119 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir/bfdd.sock"], [bfdd control socket])
2120 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir"], [daemon vty directory])
2121 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2122
2123 dnl autoconf does this, but it does it too late...
2124 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2125 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2126
2127 dnl get the full path, recursing through variables...
2128 vtysh_bin="$bindir/vtysh"
2129 for I in 1 2 3 4 5 6 7 8 9 10; do
2130         eval vtysh_bin="\"$vtysh_bin\""
2131 done
2132 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2133 AC_SUBST([vtysh_bin])
2134
2135 CFG_SYSCONF="$sysconfdir"
2136 CFG_SBIN="$sbindir"
2137 CFG_STATE="$frr_statedir"
2138 CFG_MODULE="$moduledir"
2139 CFG_YANGMODELS="$yangmodelsdir"
2140 CFG_LIBYANG_PLUGINS="$libyang_pluginsdir"
2141 for I in 1 2 3 4 5 6 7 8 9 10; do
2142         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2143         eval CFG_SBIN="\"$CFG_SBIN\""
2144         eval CFG_STATE="\"$CFG_STATE\""
2145         eval CFG_MODULE="\"$CFG_MODULE\""
2146         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2147         eval CFG_LIBYANG_PLUGINS="\"$CFG_LIBYANG_PLUGINS\""
2148 done
2149 AC_SUBST([CFG_SYSCONF])
2150 AC_SUBST([CFG_SBIN])
2151 AC_SUBST([CFG_STATE])
2152 AC_SUBST([CFG_MODULE])
2153 AC_SUBST([CFG_YANGMODELS])
2154 AC_SUBST([CFG_LIBYANG_PLUGINS])
2155 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2156 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2157 AC_DEFINE_UNQUOTED([LIBYANG_PLUGINS_PATH], ["$CFG_LIBYANG_PLUGINS"], [path to libyang plugins])
2158
2159 dnl ------------------------------------
2160 dnl Enable RPKI and add librtr to libs
2161 dnl ------------------------------------
2162 if test "${enable_rpki}" = "yes"; then
2163   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
2164       [RPKI=true],
2165       [RPKI=false
2166       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2167   )
2168 fi
2169 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2170
2171 dnl ------------------------------------------
2172 dnl Check whether rtrlib was build with ssh support
2173 dnl ------------------------------------------
2174 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2175 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2176                         [[struct tr_ssh_config config;]])],
2177         [AC_MSG_RESULT([yes])
2178         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2179         AC_MSG_RESULT([no])
2180 )
2181
2182 dnl ---------------------------
2183 dnl Check htonl works correctly
2184 dnl ---------------------------
2185 AC_MSG_CHECKING([for working htonl])
2186 AC_CACHE_VAL(ac_cv_htonl_works,
2187  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2188                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2189  ]
2190 )
2191 AC_MSG_RESULT([$ac_cv_htonl_works])
2192
2193 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2194
2195 AC_CONFIG_FILES([
2196           config.version
2197           redhat/frr.spec
2198           solaris/Makefile
2199           debianpkg/changelog
2200           alpine/APKBUILD
2201           snapcraft/snapcraft.yaml
2202           lib/version.h
2203           tests/lib/cli/test_cli.refout
2204           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2205           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2206           pkgsrc/eigrpd.sh])
2207
2208 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2209 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2210 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2211 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2212 AC_CONFIG_FILES([tools/frrcommon.sh])
2213
2214 AC_CONFIG_COMMANDS([lib/route_types.h], [
2215         dst="${ac_abs_top_builddir}/lib/route_types.h"
2216         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2217                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2218                 > "${dst}.tmp"
2219         test -f "${dst}" \
2220                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2221                 && rm "${dst}.tmp" \
2222                 || mv "${dst}.tmp" "${dst}"
2223 ], [
2224         PERL="$PERL"
2225 ])
2226
2227 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2228     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2229         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2230         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2231                 "${ac_abs_top_srcdir}" \
2232                 > "${dst}.tmp"
2233         test -f "${dst}" \
2234                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2235                 && rm "${dst}.tmp" \
2236                 || mv "${dst}.tmp" "${dst}"
2237     ], [
2238         PERL="$PERL"
2239     ])
2240 ])
2241
2242 ## Hack, but working solution to avoid rebuilding of frr.info.
2243 ## It's already in CVS until texinfo 4.7 is more common.
2244 AC_OUTPUT
2245
2246 echo "
2247 FRRouting configuration
2248 ------------------------------
2249 FRR version             : ${PACKAGE_VERSION}
2250 host operating system   : ${host_os}
2251 source code location    : ${srcdir}
2252 compiler                : ${CC}
2253 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2254 make                    : ${MAKE-make}
2255 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2256 state file directory    : ${frr_statedir}
2257 config file directory   : `eval echo \`echo ${sysconfdir}\``
2258 example directory       : `eval echo \`echo ${exampledir}\``
2259 module directory        : ${CFG_MODULE}
2260 user to run as          : ${enable_user}
2261 group to run as         : ${enable_group}
2262 group for vty sockets   : ${enable_vty_group}
2263 config file mask        : ${enable_configfile_mask}
2264 log file mask           : ${enable_logfile_mask}
2265 zebra protobuf enabled  : ${enable_protobuf:-no}
2266
2267 The above user and group must have read/write access to the state file
2268 directory and to the config files in the config file directory."
2269
2270 if test "${enable_doc}" != "no";then
2271   AS_IF([test "$SPHINXBUILD" = /bin/false],
2272      AC_MSG_WARN([sphinx-build is missing but required to build documentation]))
2273 fi