configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.0, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl if the user has specified any CFLAGS, override our settings
 193 if test "x${enable_gcov}" = "xyes"; then
 194    if test "z$orig_cflags" = "z"; then
 195       AC_C_FLAG([-coverage])
 196       AC_C_FLAG([-O0])
 197    fi
 198
 199    LDFLAGS="${LDFLAGS} -lgcov"
 200 elif test "x${enable_dev_build}" = "xyes"; then
 201    AC_DEFINE(DEV_BUILD,,Build for development)
 202    if test "z$orig_cflags" = "z"; then
 203       AC_C_FLAG([-g3])
 204       AC_C_FLAG([-O0])
 205    fi
 206 else
 207    if test "z$orig_cflags" = "z"; then
 208       AC_C_FLAG([-g])
 209       AC_C_FLAG([-Os], [
 210         AC_C_FLAG([-O2])
 211       ])
 212    fi
 213 fi
 214 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 215
 216 dnl always want these CFLAGS
 217 AC_C_FLAG([-fno-omit-frame-pointer])
 218 AC_C_FLAG([-funwind-tables])
 219 AC_C_FLAG([-Wall])
 220 AC_C_FLAG([-Wextra])
 221 AC_C_FLAG([-Wmissing-prototypes])
 222 AC_C_FLAG([-Wmissing-declarations])
 223 AC_C_FLAG([-Wpointer-arith])
 224 AC_C_FLAG([-Wbad-function-cast])
 225 AC_C_FLAG([-Wwrite-strings])
 226 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 227   AC_C_FLAG([-Wcast-qual])
 228   AC_C_FLAG([-Wstrict-prototypes])
 229   AC_C_FLAG([-Wmissing-noreturn])
 230   AC_C_FLAG([-Wmissing-format-attribute])
 231   AC_C_FLAG([-Wunreachable-code])
 232   AC_C_FLAG([-Wpacked])
 233   AC_C_FLAG([-Wpadded])
 234 else
 235   AC_C_FLAG([-Wno-unused-result])
 236 fi
 237 AC_C_FLAG([-Wno-unused-parameter])
 238 AC_C_FLAG([-Wno-missing-field-initializers])
 239
 240 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 241 dnl for some reason the string consts get 'promoted' to char *,
 242 dnl triggering a const to non-const conversion warning.
 243 AC_C_FLAG([-diag-disable 3179])
 244
 245 if test x"${enable_werror}" = x"yes" ; then
 246   WERROR="-Werror"
 247 fi
 248 AC_SUBST(WERROR)
 249
 250 SAN_FLAGS=""
 251 if test "$enable_address_sanitizer" = "yes"; then
 252   AC_C_FLAG([-fsanitize=address], [
 253     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 254   ], [
 255     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 256   ])
 257 fi
 258 if test "$enable_thread_sanitizer" = "yes"; then
 259   AC_C_FLAG([-fsanitize=thread], [
 260     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 261   ], [
 262     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 263   ])
 264 fi
 265 if test "$enable_memory_sanitizer" = "yes"; then
 266   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 267     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 268   ], [
 269     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 270   ])
 271 fi
 272 AC_SUBST([SAN_FLAGS])
 273
 274 dnl ----------
 275 dnl Essentials
 276 dnl ----------
 277
 278 AX_PTHREAD([
 279   CC="$PTHREAD_CC"
 280   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 281   LIBS="$PTHREAD_LIBS $LIBS"
 282 ], [
 283   AC_MSG_FAILURE([This FRR version needs pthreads])
 284 ])
 285
 286 dnl --------------
 287 dnl Check programs
 288 dnl --------------
 289 AC_PROG_INSTALL
 290 AC_PROG_LN_S
 291 AC_PROG_MAKE_SET
 292 AC_CHECK_TOOL(AR, ar)
 293
 294 dnl -----------------
 295 dnl System extensions
 296 dnl -----------------
 297 AC_GNU_SOURCE
 298
 299 dnl -------
 300 dnl libtool
 301 dnl -------
 302 LT_INIT
 303
 304 dnl $AR and $RANLIB are set by LT_INIT above
 305 AC_MSG_CHECKING([whether $AR supports D option])
 306 if $AR crD conftest.a; then
 307   AC_MSG_RESULT([yes])
 308   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 309   ARFLAGS="crD"
 310   AR_FLAGS="crD"
 311 else
 312   AC_MSG_RESULT([no])
 313   ARFLAGS="cru"
 314   AR_FLAGS="cru"
 315 fi
 316 AC_SUBST(ARFLAGS)
 317 AC_SUBST(AR_FLAGS)
 318
 319 AC_MSG_CHECKING([whether $RANLIB supports D option])
 320 if $RANLIB -D conftest.a; then
 321   AC_MSG_RESULT([yes])
 322   RANLIB="$RANLIB -D"
 323 else
 324   AC_MSG_RESULT([no])
 325 fi
 326 AC_SUBST(RANLIB)
 327
 328 test -f conftest.a && rm conftest.a
 329
 330 dnl ----------------------
 331 dnl Packages configuration
 332 dnl ----------------------
 333 AC_ARG_WITH(pkg-extra-version,
 334         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 335         [EXTRAVERSION=$withval],)
 336 AC_ARG_WITH(pkg-git-version,
 337         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 338         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 339 AC_ARG_WITH(vtysh_pager,
 340         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 341         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 342 AC_ARG_ENABLE(vtysh,
 343   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 344 AC_ARG_ENABLE(doc,
 345   AS_HELP_STRING([--disable-doc], [do not build docs]))
 346 AC_ARG_ENABLE(doc-html,
 347   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 348 AC_ARG_ENABLE(zebra,
 349   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 350 AC_ARG_ENABLE(bgpd,
 351   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 352 AC_ARG_ENABLE(ripd,
 353   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 354 AC_ARG_ENABLE(ripngd,
 355   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 356 AC_ARG_ENABLE(ospfd,
 357   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 358 AC_ARG_ENABLE(ospf6d,
 359   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 360 AC_ARG_ENABLE(ldpd,
 361   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 362 AC_ARG_ENABLE(nhrpd,
 363   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 364 AC_ARG_ENABLE(eigrpd,
 365   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 366 AC_ARG_ENABLE(babeld,
 367   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 368 AC_ARG_ENABLE(watchfrr,
 369   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 370 AC_ARG_ENABLE(isisd,
 371   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 372 AC_ARG_ENABLE(pimd,
 373   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 374 AC_ARG_ENABLE(pbrd,
 375   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 376 AC_ARG_ENABLE(sharpd,
 377   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 378 AC_ARG_ENABLE(staticd,
 379   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 380 AC_ARG_ENABLE(bgp-announce,
 381   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 382 AC_ARG_ENABLE(bgp-vnc,
 383   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 384 AC_ARG_ENABLE(snmp,
 385   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 386 AC_ARG_ENABLE(zeromq,
 387   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 388 AC_ARG_WITH(libpam,
 389   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 390 AC_ARG_ENABLE(ospfapi,
 391   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 392 AC_ARG_ENABLE(ospfclient,
 393   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 394                           (this is the default if --disable-ospfapi is set)]))
 395 AC_ARG_ENABLE(multipath,
 396   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 397 AC_ARG_ENABLE(user,
 398   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 399 AC_ARG_ENABLE(group,
 400   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 401 AC_ARG_ENABLE(vty_group,
 402   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 403 AC_ARG_ENABLE(configfile_mask,
 404   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 405 AC_ARG_ENABLE(logfile_mask,
 406   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 407 AC_ARG_ENABLE(shell_access,
 408   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 409 AC_ARG_ENABLE(realms,
 410   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 411 AC_ARG_ENABLE(rtadv,
 412   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 413 AC_ARG_ENABLE(irdp,
 414   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 415 AC_ARG_ENABLE(capabilities,
 416   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 417 AC_ARG_ENABLE(rusage,
 418   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 419 AC_ARG_ENABLE(gcc_ultra_verbose,
 420   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 421 AC_ARG_ENABLE(backtrace,
 422   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 423 AC_ARG_ENABLE(time-check,
 424   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 425 AC_ARG_ENABLE(pcreposix,
 426   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 427 AC_ARG_ENABLE(fpm,
 428   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 429 AC_ARG_ENABLE(systemd,
 430   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 431 AC_ARG_ENABLE(werror,
 432   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 433 AC_ARG_ENABLE(cumulus,
 434   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 435 AC_ARG_ENABLE(datacenter,
 436   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 437 AC_ARG_ENABLE(fuzzing,
 438   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 439 AC_ARG_ENABLE(netlink_fuzzing,
 440   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 441 AC_ARG_ENABLE(rr-semantics,
 442   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 443 AC_ARG_ENABLE([protobuf],
 444   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 445 AC_ARG_ENABLE([oldvpn_commands],
 446   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 447 AC_ARG_ENABLE(rpki,
 448   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 449 AC_ARG_ENABLE([clippy-only],
 450   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 451 AC_ARG_ENABLE([numeric_version],
 452   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 453 AC_ARG_ENABLE([gcov],
 454   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 455 AC_ARG_ENABLE(bfdd,
 456   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 457 AC_ARG_ENABLE([address-sanitizer],
 458   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 459 AC_ARG_ENABLE([thread-sanitizer],
 460   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 461 AC_ARG_ENABLE([memory-sanitizer],
 462   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 463
 464 AS_IF([test "${enable_clippy_only}" != "yes"], [
 465 AC_CHECK_HEADERS(json-c/json.h)
 466 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 467 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 468   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 469   if test "$ac_cv_lib_json_json_object_get" = no; then
 470       AC_MSG_ERROR([lib json is needed to compile])
 471   fi
 472 fi
 473 ])
 474
 475 AC_ARG_ENABLE([dev_build],
 476     AS_HELP_STRING([--enable-dev-build], [build for development]))
 477
 478 if test x"${enable_time_check}" != x"no" ; then
 479   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 480     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 481   else
 482     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 483   fi
 484 fi
 485
 486 case "${enable_systemd}" in
 487   "no") ;;
 488   "yes")
 489   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 490   if test $ac_cv_lib_systemd_sd_notify = no; then
 491     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 492   else
 493     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 494   fi
 495   ;;
 496   "*") ;;
 497 esac
 498
 499 if test "${enable_rr_semantics}" != "no" ; then
 500   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 501 fi
 502
 503 if test "${enable_datacenter}" = "yes" ; then
 504   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 505   DFLT_NAME="datacenter"
 506 else
 507   DFLT_NAME="traditional"
 508 fi
 509
 510 if test "${enable_fuzzing}" = "yes" ; then
 511   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 512 fi
 513
 514 if test "${enable_netlink_fuzzing}" = "yes" ; then
 515   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 516 fi
 517
 518 if test "${enable_cumulus}" = "yes" ; then
 519   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 520 fi
 521
 522 AC_SUBST(DFLT_NAME)
 523 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 524
 525 if test "${enable_shell_access}" = "yes"; then
 526    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 527 fi
 528
 529 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 530
 531 #
 532 # Python for clippy
 533 #
 534
 535 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 536   AC_MSG_CHECKING([whether we found a working Python version])
 537   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 538 #include <Python.h>
 539 #if PY_VERSION_HEX < 0x02070000
 540 #error python too old
 541 #endif
 542 int main(void);
 543 ],
 544 [
 545 {
 546   Py_Initialize();
 547   return 0;
 548 }
 549 ])], [
 550     # some python installs are missing the zlib dependency...
 551     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 552     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 553 #include <Python.h>
 554 #if PY_VERSION_HEX < 0x02070000
 555 #error python too old
 556 #endif
 557 int main(void);
 558 ],
 559 [
 560 {
 561   Py_Initialize();
 562   return 0;
 563 }
 564 ])], [
 565       m4_if([$1], [], [
 566         PYTHONCONFIG=""
 567         unset PYTHON_LIBS
 568         unset PYTHON_CFLAGS
 569       ], [$1])
 570     ])
 571   ])
 572 ])
 573
 574 AS_IF([test "$host" = "$build"], [
 575   PYTHONCONFIG=""
 576
 577   # ordering:
 578   # 1.  try python3, but respect the user's preference on which minor ver
 579   # 2.  try python, which might be py3 or py2 again on the user's preference
 580   # 3.  try python2 (can really only be 2.7 but eh)
 581   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 582   #
 583   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 584   # (AX_PYTHON does not do what we need)
 585
 586   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 587         python3-config \
 588         python-config \
 589         python2-config \
 590         python3.6-config \
 591         python3.5-config \
 592         python3.4-config \
 593         python3.3-config \
 594         python3.2-config \
 595         python2.7-config ])
 596   if test -n "$PYTHONCONFIG"; then
 597     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 598     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 599
 600     FRR_PYTHON_CHECK_WORKING([])
 601   fi
 602
 603   if test -z "$PYTHONCONFIG"; then
 604     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 605       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 606         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 607           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 608             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 609               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 610                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 611                 ])])])])])])
 612
 613
 614     FRR_PYTHON_CHECK_WORKING([
 615       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 616     ])
 617   fi
 618 ])
 619 AC_SUBST(PYTHON_CFLAGS)
 620 AC_SUBST(PYTHON_LIBS)
 621
 622 #
 623 # Logic for protobuf support.
 624 #
 625 if test "$enable_protobuf" = "yes"; then
 626   # Check for protoc & protoc-c
 627
 628   # protoc is not required, it's only for a "be nice" helper target
 629   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 630
 631   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 632   if test "$PROTOC_C" = "/bin/false"; then
 633     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 634   fi
 635
 636   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 637     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 638   ])
 639   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 640     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 641   ])
 642
 643   AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 644 fi
 645 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 646
 647 #
 648 # Logic for old vpn commans support.
 649 #
 650 if test "$enable_oldvpn_commands" = "yes"; then
 651    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 652 fi
 653
 654 #
 655 # End of logic for protobuf support.
 656 #
 657
 658 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 659 if test "${enable_rtadv}" != "no"; then
 660   AC_MSG_RESULT(yes)
 661   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 662 else
 663   AC_MSG_RESULT(no)
 664 fi
 665
 666 if test x"${enable_user}" = x"no"; then
 667   enable_user=""
 668 else
 669   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 670     enable_user="frr"
 671   fi
 672   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 673 fi
 674
 675 if test x"${enable_group}" = x"no"; then
 676   enable_group=""
 677 else
 678   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 679     enable_group="frr"
 680   fi
 681   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 682 fi
 683
 684 if test x"${enable_vty_group}" = x"yes" ; then
 685   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 686 elif test x"${enable_vty_group}" != x""; then
 687   if test x"${enable_vty_group}" != x"no"; then
 688     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 689   fi
 690 fi
 691 AC_SUBST([enable_user])
 692 AC_SUBST([enable_group])
 693 AC_SUBST([enable_vty_group])
 694
 695 enable_configfile_mask=${enable_configfile_mask:-0600}
 696 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 697
 698 enable_logfile_mask=${enable_logfile_mask:-0600}
 699 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 700
 701 MPATH_NUM=1
 702
 703 case "${enable_multipath}" in
 704   0)
 705     MPATH_NUM=64
 706     ;;
 707   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 708     MPATH_NUM="${enable_multipath}"
 709     ;;
 710   "")
 711     ;;
 712   *)
 713     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 714     ;;
 715 esac
 716
 717 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 718
 719 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 720
 721 dnl --------------------
 722 dnl Enable code coverage
 723 dnl --------------------
 724 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 725
 726 dnl ------------------------------------
 727 dnl Alpine only accepts numeric versions
 728 dnl ------------------------------------
 729 if test "x${enable_numeric_version}" != "x" ; then
 730   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 731   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 732 fi
 733
 734 dnl -----------------------------------
 735 dnl Add extra version string to package
 736 dnl name, string and version fields.
 737 dnl -----------------------------------
 738 if test "x${EXTRAVERSION}" != "x" ; then
 739   VERSION="${VERSION}${EXTRAVERSION}"
 740   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 741   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 742   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 743 fi
 744
 745 if test "x$with_pkg_git_version" = "xyes"; then
 746         if test -d "${srcdir}/.git"; then
 747                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 748         else    with_pkg_git_version="no"
 749                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 750         fi
 751 fi
 752 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 753
 754 dnl ------------------------------------
 755 dnl Check C keywords and standard  types
 756 dnl ------------------------------------
 757 AC_C_CONST
 758 AC_C_INLINE
 759 AC_C_VOLATILE
 760 AC_HEADER_STDC
 761 dnl AC_TYPE_PID_T
 762 AC_TYPE_UID_T
 763 AC_TYPE_MODE_T
 764 AC_TYPE_SIZE_T
 765 AC_STRUCT_TM
 766
 767 dnl -------------------------
 768 dnl Check other header files.
 769 dnl -------------------------
 770 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 771         linux/version.h asm/types.h \
 772         sys/cdefs.h])
 773
 774 ac_stdatomic_ok=false
 775 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 776 AC_CHECK_HEADER([stdatomic.h],[
 777
 778   AC_MSG_CHECKING([whether _Atomic qualifier works])
 779   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 780 #include <stdatomic.h>
 781 int main(int argc, char **argv) {
 782   _Atomic int i = 0;
 783   return i;
 784 }
 785 ]])], [
 786     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 787     AC_MSG_RESULT([yes])
 788     ac_stdatomic_ok=true
 789   ], [
 790     AC_MSG_RESULT([no])
 791   ])
 792 ])
 793
 794 AS_IF([$ac_stdatomic_ok], [true], [
 795   AC_MSG_CHECKING([for __atomic_* builtins])
 796   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 797 int main(int argc, char **argv) {
 798   volatile int i = 1;
 799   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 800   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 801 }
 802 ]])], [
 803     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 804     AC_MSG_RESULT([yes])
 805   ], [
 806     AC_MSG_RESULT([no])
 807
 808     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 809     AC_MSG_CHECKING([for __sync_* builtins])
 810     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 811 int main(int argc, char **argv) {
 812   volatile int i = 1;
 813   __sync_fetch_and_sub (&i, 1);
 814   return __sync_val_compare_and_swap (&i, 0, 1);
 815 }
 816 ]])], [
 817       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 818       AC_MSG_RESULT([yes])
 819
 820       AC_MSG_CHECKING([for __sync_swap builtin])
 821       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 822 int main(int argc, char **argv) {
 823   volatile int i = 1;
 824   return __sync_swap (&i, 2);
 825 }
 826 ]])], [
 827         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 828         AC_MSG_RESULT([yes])
 829       ], [
 830         AC_MSG_RESULT([no])
 831       ])
 832
 833     ], [
 834       AC_MSG_RESULT([no])
 835       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 836     ])
 837   ])
 838 ])
 839
 840 dnl Utility macro to avoid retyping includes all the time
 841 m4_define([FRR_INCLUDES],
 842 [#ifdef SUNOS_5
 843 #define _XPG4_2
 844 #define __EXTENSIONS__
 845 #endif
 846 #include <stdio.h>
 847 #include <stdlib.h>
 848 #include <stddef.h>
 849 #include <sys/types.h>
 850 /* sys/conf.h depends on param.h on FBSD at least */
 851 #include <sys/param.h>
 852 /* Required for MAXSIG */
 853 #include <signal.h>
 854 #include <sys/socket.h>
 855 #ifdef __APPLE__
 856 # define __APPLE_USE_RFC_3542
 857 #endif
 858 #include <netinet/in.h>
 859 #include <sys/time.h>
 860 #include <time.h>
 861 #include <net/if.h>
 862 ])dnl
 863
 864 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 865 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 866 dnl an additional round for it.
 867
 868 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 869
 870 m4_define([FRR_INCLUDES],
 871 FRR_INCLUDES
 872 [#if HAVE_NET_IF_VAR_H
 873 # include <net/if_var.h>
 874 #endif
 875 ])dnl
 876
 877 AC_CHECK_HEADERS([netinet/in_var.h \
 878         net/if_dl.h net/netopt.h \
 879         inet/nd.h netinet/ip_icmp.h \
 880         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 881         [], [], FRR_INCLUDES)
 882
 883 AC_CHECK_HEADERS([ucontext.h], [], [],
 884 [#ifndef __USE_GNU
 885 #define __USE_GNU
 886 #endif /* __USE_GNU */
 887 FRR_INCLUDES
 888 ])
 889
 890 m4_define([UCONTEXT_INCLUDES],
 891 [#include <ucontext.h>])dnl
 892
 893 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 894   [], [], [UCONTEXT_INCLUDES])
 895 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 896   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 897    [], [], [UCONTEXT_INCLUDES])],
 898   [], [UCONTEXT_INCLUDES])
 899 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 900   [], [], [UCONTEXT_INCLUDES])
 901
 902 m4_define([FRR_INCLUDES],
 903 FRR_INCLUDES
 904 [
 905 #include <sys/un.h>
 906 #include <netinet/in_systm.h>
 907 #if HAVE_NETINET_IN_VAR_H
 908 # include <netinet/in_var.h>
 909 #endif
 910 #if HAVE_NET_IF_DL_H
 911 # include <net/if_dl.h>
 912 #endif
 913 #if HAVE_NET_NETOPT_H
 914 # include <net/netopt.h>
 915 #endif
 916 #include <net/route.h>
 917 #if HAVE_INET_ND_H
 918 # include <inet/nd.h>
 919 #endif
 920 #include <arpa/inet.h>
 921 /* Required for IDRP */
 922 #if HAVE_NETINET_IP_ICMP_H
 923 # include <netinet/ip_icmp.h>
 924 #endif
 925 ])dnl
 926
 927 dnl V6 headers are checked below, after we check for v6
 928
 929 AC_MSG_CHECKING([which operating system interface to use])
 930 case "$host_os" in
 931   sunos* | solaris2*)
 932     AC_MSG_RESULT([Solaris])
 933
 934     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 935     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 936
 937     AC_CHECK_LIB(socket, main)
 938     AC_CHECK_LIB(nsl, main)
 939     AC_CHECK_LIB(umem, main)
 940     AC_CHECK_FUNCS([printstack], [
 941       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 942       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 943     ])
 944     CURSES=-lcurses
 945     SOLARIS="solaris"
 946     ;;
 947   linux*)
 948     AC_MSG_RESULT([Linux])
 949
 950     AC_DEFINE(GNU_LINUX,,GNU Linux)
 951     AC_DEFINE(HAVE_NETLINK,,netlink)
 952     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 953
 954     dnl Linux has a compilation problem with mixing
 955     dnl netinet/in.h and linux/in6.h they are not
 956     dnl compatible.  There has been discussion on
 957     dnl how to fix it but no real progress on implementation
 958     dnl when they fix it, remove this
 959     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 960     ;;
 961   openbsd*)
 962     AC_MSG_RESULT([OpenBSD])
 963
 964     AC_DEFINE(OPEN_BSD,,OpenBSD)
 965     AC_DEFINE(KAME,1,KAME IPv6)
 966     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 967
 968     if test "x${enable_pimd}" != "xno"; then
 969       case "$host_os" in
 970       openbsd6.0)
 971         ;;
 972       openbsd[6-9]*)
 973         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 974         ;;
 975       esac
 976     fi
 977     ;;
 978   *)
 979     AC_MSG_RESULT([BSD])
 980
 981     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 982     AC_DEFINE(KAME,1,KAME IPv6)
 983     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 984     ;;
 985 esac
 986 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 987
 988 AC_SYS_LARGEFILE
 989
 990 dnl ------------------------
 991 dnl Integrated REALMS option
 992 dnl ------------------------
 993 if test "${enable_realms}" = "yes"; then
 994     case "$host_os" in
 995       linux*)
 996        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 997        ;;
 998       *)
 999        echo "Sorry, only Linux has REALMS support"
1000        exit 1
1001        ;;
1002     esac
1003 fi
1004 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1005
1006 dnl ---------------------
1007 dnl Integrated VTY option
1008 dnl ---------------------
1009 case "${enable_vtysh}" in
1010   "no") VTYSH="";;
1011   *)    VTYSH="vtysh";
1012          AC_DEFINE(VTYSH,,VTY shell)
1013 dnl      Vtysh uses libreadline, which looks for termcap functions at
1014 dnl      configure time.  We follow readlines search order.
1015 dnl      The required procedures are in libtermcap on NetBSD, in
1016 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1017          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1018            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1019              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1020                [AC_CHECK_LIB(ncurses, tputs,
1021                              LIBREADLINE="$LIBREADLINE -lncurses")]
1022               )]
1023             )]
1024           )
1025          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1026                       "$LIBREADLINE")
1027          if test $ac_cv_lib_readline_main = no; then
1028            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1029          fi
1030          AC_CHECK_HEADER(readline/history.h)
1031          if test $ac_cv_header_readline_history_h = no;then
1032            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1033          fi
1034          AC_CHECK_LIB(readline, rl_completion_matches,
1035                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1036          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1037            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1038          fi
1039          ;;
1040 esac
1041 AC_SUBST(LIBREADLINE)
1042 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1043
1044 dnl ----------
1045 dnl PAM module
1046 dnl
1047 dnl FRR detects the PAM library it is built against by checking for a
1048 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1049 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1050 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1051 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1052 dnl of OpenPAM.
1053 dnl ----------
1054 if test "$with_libpam" = "yes"; then
1055   AC_CHECK_HEADER([security/pam_misc.h],
1056     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1057      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1058      pam_conv_func="misc_conv"
1059     ],
1060     [], FRR_INCLUDES)
1061   AC_CHECK_HEADER([security/openpam.h],
1062     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1063      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1064      pam_conv_func="openpam_ttyconv"
1065     ],
1066     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1067   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1068     AC_MSG_WARN([*** pam support will not be built ***])
1069     with_libpam="no"
1070   fi
1071 fi
1072
1073 if test "$with_libpam" = "yes"; then
1074 dnl took this test from proftpds configure.in and suited to our needs
1075 dnl -------------------------------------------------------------------------
1076 dnl
1077 dnl This next check looks funky due to a linker problem with some versions
1078 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1079 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1080 dnl with RedHat 6.2 and Debian 2.2 or better.
1081 AC_CHECK_LIB(pam, pam_start,
1082   [AC_CHECK_LIB(pam, $pam_conv_func,
1083     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1084      LIBPAM="-lpam"],
1085     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1086      LIBPAM="-lpam -lpam_misc"]
1087     )
1088   ],
1089
1090   [AC_CHECK_LIB(pam, pam_end,
1091     [AC_CHECK_LIB(pam, $pam_conv_func,
1092       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1093        LIBPAM="-lpam -ldl"],
1094       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1095        LIBPAM="-lpam -ldl -lpam_misc"]
1096      )
1097   ],AC_MSG_WARN([*** pam support will not be built ***]),
1098   [-ldl])
1099   ]
1100 )
1101 fi
1102 AC_SUBST(LIBPAM)
1103
1104 dnl -------------------------------
1105 dnl Endian-ness check
1106 dnl -------------------------------
1107 AC_WORDS_BIGENDIAN
1108
1109 dnl -------------------------------
1110 dnl check the size in byte of the C
1111 dnl -------------------------------
1112 dnl AC_CHECK_SIZEOF(char)
1113 dnl AC_CHECK_SIZEOF(int)
1114 dnl AC_CHECK_SIZEOF(short)
1115 dnl AC_CHECK_SIZEOF(long)
1116
1117 dnl ----------------------------
1118 dnl check existance of functions
1119 dnl ----------------------------
1120 AC_FUNC_FNMATCH
1121 AC_FUNC_FORK
1122 AC_FUNC_MKTIME
1123 AC_FUNC_STAT
1124
1125 dnl -------------------------------
1126 dnl bgpd needs pow() and hence libm
1127 dnl -------------------------------
1128 TMPLIBS="$LIBS"
1129 AC_CHECK_HEADER([math.h],
1130   [AC_CHECK_LIB([m], [pow],
1131     [LIBM="-lm"
1132      LIBS="$LIBS $LIBM"
1133      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1134     ])
1135 ])
1136 if test x"$LIBM" = x ; then
1137   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1138 fi
1139 LIBS="$TMPLIBS"
1140 AC_SUBST(LIBM)
1141
1142 AC_CHECK_FUNCS([ppoll], [
1143   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1144 ])
1145 AC_CHECK_FUNCS([pollts], [
1146   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1147 ])
1148
1149 dnl ---------------
1150 dnl other functions
1151 dnl ---------------
1152 AC_CHECK_FUNCS([ \
1153         strlcat strlcpy \
1154         getgrouplist])
1155
1156 AC_CHECK_HEADER([asm-generic/unistd.h],
1157                 [AC_CHECK_DECL(__NR_setns,
1158                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1159                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1160                                ])
1161                  AC_CHECK_FUNCS(setns)]
1162                )
1163
1164 dnl --------------------------
1165 dnl Determine IS-IS I/O method
1166 dnl --------------------------
1167 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1168 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1169 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1170 AC_CHECK_HEADER(net/bpf.h)
1171 AC_CHECK_HEADER(sys/dlpi.h)
1172 AC_MSG_CHECKING(zebra IS-IS I/O method)
1173
1174 case "$host_os" in
1175   linux*)
1176     AC_MSG_RESULT(pfpacket)
1177     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1178     ;;
1179   solaris* | sunos*)
1180     AC_MSG_RESULT(DLPI)
1181     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1182     ;;
1183   *)
1184     if test $ac_cv_header_net_bpf_h = no; then
1185       if test $ac_cv_header_sys_dlpi_h = no; then
1186         AC_MSG_RESULT(none)
1187         if test "${enable_isisd}" = yes; then
1188           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1189         fi
1190         AC_MSG_WARN([*** IS-IS support will not be built ***])
1191         enable_isisd="no"
1192       else
1193         AC_MSG_RESULT(DLPI)
1194       fi
1195       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1196     else
1197       AC_MSG_RESULT(BPF)
1198       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1199     fi
1200     ;;
1201 esac
1202 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1203
1204 dnl ---------------------------------------------------------------
1205 dnl figure out how to specify an interface in multicast sockets API
1206 dnl ---------------------------------------------------------------
1207 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1208
1209 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1210         #include <sys/socket.h>
1211         #include <netinet/in.h>
1212         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1213         #include <linux/types.h>
1214 ])
1215
1216 m4_define([FRR_INCLUDES],
1217 FRR_INCLUDES
1218 [#if HAVE_LINUX_MROUTE_H
1219 # include <linux/mroute.h>
1220 #endif
1221 ])dnl
1222
1223 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1224         #include <sys/socket.h>
1225         #include <sys/types.h>
1226         #include <netinet/in.h>
1227         #include <net/route.h>
1228 ])
1229
1230 m4_define([FRR_INCLUDES],
1231 FRR_INCLUDES
1232 [#if HAVE_NETINET_IP_MROUTE_H
1233 # include <netinet/ip_mroute.h>
1234 #endif
1235 ])dnl
1236
1237 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1238 AC_TRY_COMPILE([#include <sys/param.h>],
1239 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1240   return (0);
1241 #else
1242   #error No support for BSD struct ip_mreq hack detected
1243 #endif],[AC_MSG_RESULT(yes)
1244 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1245 AC_MSG_RESULT(no))
1246
1247 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1248 AC_TRY_COMPILE([
1249 #include <sys/types.h>
1250 #include <netinet/in.h>
1251 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1252 ], [AC_MSG_RESULT(yes)
1253 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1254 AC_MSG_RESULT(no))
1255
1256 dnl ---------------------------------------------------------------
1257 dnl figure out how to check link-state
1258 dnl ---------------------------------------------------------------
1259 AC_CHECK_HEADER( [net/if_media.h],
1260   [m4_define([LINK_DETECT_INCLUDES],
1261     FRR_INCLUDES
1262     [#include <net/if_media.h>
1263   ])
1264   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1265     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1266     [], LINK_DETECT_INCLUDES)],
1267   [],
1268   FRR_INCLUDES)
1269
1270 dnl ---------------------------------------------------------------
1271 dnl Additional, newer way to check link-state using ifi_link_state.
1272 dnl Not available in all BSD's when ifmediareq available
1273 dnl ---------------------------------------------------------------
1274 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1275   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1276   [], FRR_INCLUDES)
1277
1278 dnl ------------------------
1279 dnl TCP_MD5SIG socket option
1280 dnl ------------------------
1281
1282 AC_CHECK_HEADER([netinet/tcp.h],
1283    [m4_define([MD5_INCLUDES],
1284       FRR_INCLUDES
1285       [#include <netinet/tcp.h>
1286     ])
1287     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1288    [],
1289    FRR_INCLUDES)
1290 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1291   AC_CHECK_HEADER([linux/tcp.h],
1292        [m4_define([MD5_INCLUDES],
1293           FRR_INCLUDES
1294           [#include <linux/tcp.h>
1295         ])
1296        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1297 fi
1298
1299 dnl ----------------------------------------------------------------------------
1300 dnl figure out if domainname is available in the utsname struct (GNU extension).
1301 dnl ----------------------------------------------------------------------------
1302 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1303
1304 dnl ------------------
1305 dnl IPv6 header checks
1306 dnl ------------------
1307 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1308         netinet6/in6_var.h netinet6/nd6.h], [], [],
1309         FRR_INCLUDES)
1310
1311 m4_define([FRR_INCLUDES],dnl
1312 FRR_INCLUDES
1313 [#if HAVE_NETINET6_IN6_H
1314 #include <netinet6/in6.h>
1315 #endif
1316 #if HAVE_NETINET_IN6_VAR_H
1317 #include <netinet/in6_var.h>
1318 #endif
1319 #include <netinet/icmp6.h>
1320 #if HAVE_NETINET6_IN6_VAR_H
1321 # include <netinet6/in6_var.h>
1322 #endif
1323 #if HAVE_NETINET6_ND6_H
1324 # include <netinet6/nd6.h>
1325 #endif
1326 ])dnl
1327
1328 dnl disable doc check
1329 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1330 if test "$SPHINXBUILD" = "/bin/false"; then
1331   if test "${enable_doc}" = "yes"; then
1332     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1333   fi
1334 fi
1335 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false")
1336 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1337
1338 dnl --------------------
1339 dnl Daemon disable check
1340 dnl --------------------
1341 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1342
1343 if test "${enable_bgpd}" = "no";then
1344   BGPD=""
1345 else
1346   BGPD="bgpd"
1347 fi
1348 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1349
1350 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1351 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1352 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1353
1354 AS_IF([test "${enable_ldpd}" != "no"], [
1355   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1356 ])
1357
1358 if test "$enable_bfdd" = "no"; then
1359   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1360   BFDD=""
1361 else
1362   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1363   BFDD="bfdd"
1364
1365   case $host_os in
1366     linux*)
1367       AC_DEFINE(BFD_LINUX, 1, bfdd)
1368       ;;
1369
1370     *)
1371       AC_DEFINE(BFD_BSD, 1, bfdd)
1372       ;;
1373   esac
1374 fi
1375
1376 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1377
1378 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1379   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1380 fi
1381
1382 NHRPD=""
1383 case "$host_os" in
1384   linux*)
1385     if test "${enable_nhrpd}" != "no"; then
1386       NHRPD="nhrpd"
1387     fi
1388     ;;
1389   *)
1390     if test "${enable_nhrpd}" = "yes"; then
1391       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1392     fi
1393     ;;
1394 esac
1395 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1396
1397 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1398
1399 if test "${enable_watchfrr}" = "no";then
1400   WATCHFRR=""
1401 else
1402   WATCHFRR="watchfrr"
1403 fi
1404 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1405
1406 OSPFCLIENT=""
1407 if test "${enable_ospfapi}" != "no";then
1408     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1409
1410   if test "${enable_ospfclient}" != "no";then
1411       OSPFCLIENT="ospfclient"
1412   fi
1413 fi
1414
1415 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1416 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1417 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1418 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1419 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1420 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1421 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1422 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1423 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1424
1425 if test "${enable_bgp_announce}" = "no";then
1426   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1427 else
1428   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1429 fi
1430
1431 if test "${enable_bgp_vnc}" != "no";then
1432   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1433 fi
1434 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1435
1436 AC_SUBST(SOLARIS)
1437 AC_SUBST(CURSES)
1438 AC_CHECK_LIB(crypt, crypt, [],
1439                     [AC_CHECK_LIB(crypto, DES_crypt)])
1440 AC_CHECK_LIB(resolv, res_init)
1441
1442 dnl ---------------------------
1443 dnl check system has PCRE regexp
1444 dnl ---------------------------
1445 if test "x$enable_pcreposix" = "xyes"; then
1446   AC_CHECK_LIB(pcreposix, regexec, [], [
1447     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1448   ])
1449 fi
1450 AC_SUBST(HAVE_LIBPCREPOSIX)
1451
1452 dnl ------------------
1453 dnl check C-Ares library
1454 dnl ------------------
1455 if test "${NHRPD}" != ""; then
1456   PKG_CHECK_MODULES([CARES], [libcares], , [
1457     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1458   ])
1459 fi
1460
1461
1462 dnl ------------------
1463 dnl check Net-SNMP library
1464 dnl ------------------
1465 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1466    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1467    if test x"$NETSNMP_CONFIG" = x"no"; then
1468       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1469    fi
1470    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1471    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1472    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1473    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1474 int main(void);
1475 ],
1476 [
1477 {
1478   return 0;
1479 }
1480 ])], [
1481      AC_MSG_ERROR([--enable-snmp given but not usable])])
1482    case "${enable_snmp}" in
1483      yes)
1484       SNMP_METHOD=agentx
1485       ;;
1486      agentx)
1487       SNMP_METHOD="${enable_snmp}"
1488       ;;
1489      *)
1490       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1491       ;;
1492    esac
1493    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1494    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1495 fi
1496 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1497 AC_SUBST(SNMP_LIBS)
1498 AC_SUBST(SNMP_CFLAGS)
1499
1500 dnl ---------------
1501 dnl math
1502 dnl ---------------
1503 AC_SEARCH_LIBS([sqrt], [m])
1504
1505 dnl ---------------
1506 dnl dlopen & dlinfo
1507 dnl ---------------
1508 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1509   AC_MSG_ERROR([unable to find the dlopen()])
1510 ])
1511
1512 AC_CHECK_HEADERS([link.h])
1513
1514 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1515   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1516 #include <stdlib.h>
1517 #ifdef HAVE_LINK_H
1518 #include <link.h>
1519 #endif
1520 #include <dlfcn.h>
1521 ]], [[
1522   char origin[1];
1523   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1524 ]])], [
1525     frr_cv_rtld_di_origin=yes
1526   ], [
1527     frr_cv_rtld_di_origin=no
1528   ])
1529 ])
1530 if test "$frr_cv_rtld_di_origin" = yes; then
1531   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1532 fi
1533
1534 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1535   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1536 #include <stdlib.h>
1537 #ifdef HAVE_LINK_H
1538 #include <link.h>
1539 #endif
1540 #include <dlfcn.h>
1541 ]], [[
1542   struct link_map *lm = NULL;
1543   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1544 ]])], [
1545     frr_cv_rtld_di_linkmap=yes
1546   ], [
1547     frr_cv_rtld_di_linkmap=no
1548   ])
1549 ])
1550 if test "$frr_cv_rtld_di_linkmap" = yes; then
1551   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1552 fi
1553
1554 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1555
1556 dnl ---------------------------
1557 dnl sockaddr and netinet checks
1558 dnl ---------------------------
1559 AC_CHECK_TYPES([
1560         struct sockaddr_dl,
1561         struct vifctl, struct mfcctl, struct sioc_sg_req,
1562         vifi_t, struct sioc_vif_req, struct igmpmsg,
1563         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1564         struct nd_opt_adv_interval, struct rt_addrinfo,
1565         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1566         [], [], FRR_INCLUDES)
1567
1568 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1569         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1570         struct sockaddr_dl.sdl_len,
1571         struct if6_aliasreq.ifra_lifetime,
1572         struct nd_opt_adv_interval.nd_opt_ai_type],
1573         [], [], FRR_INCLUDES)
1574
1575 dnl ---------------------------
1576 dnl IRDP/pktinfo/icmphdr checks
1577 dnl ---------------------------
1578
1579 AC_CHECK_TYPES([struct in_pktinfo], [
1580   AC_CHECK_TYPES([struct icmphdr], [
1581     IRDP=true
1582   ], [
1583     IRDP=false
1584   ], [FRR_INCLUDES])
1585 ], [
1586   IRDP=false
1587 ], [FRR_INCLUDES])
1588
1589 case "${enable_irdp}" in
1590 yes)
1591   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1592   ;;
1593 no)
1594   IRDP=false
1595   ;;
1596 esac
1597
1598 AM_CONDITIONAL(IRDP, $IRDP)
1599
1600 dnl -----------------------
1601 dnl checking for IP_PKTINFO
1602 dnl -----------------------
1603 AC_MSG_CHECKING(for IP_PKTINFO)
1604 AC_TRY_COMPILE([#include <netdb.h>], [
1605   int opt = IP_PKTINFO;
1606 ], [
1607   AC_MSG_RESULT(yes)
1608   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1609 ], [
1610   AC_MSG_RESULT(no)
1611 ])
1612
1613 dnl ---------------------------
1614 dnl checking for IP_RECVDSTADDR
1615 dnl ---------------------------
1616 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1617 AC_TRY_COMPILE([#include <netinet/in.h>], [
1618   int opt = IP_RECVDSTADDR;
1619 ], [
1620   AC_MSG_RESULT(yes)
1621   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1622 ], [
1623   AC_MSG_RESULT(no)
1624 ])
1625
1626 dnl ----------------------
1627 dnl checking for IP_RECVIF
1628 dnl ----------------------
1629 AC_MSG_CHECKING(for IP_RECVIF)
1630 AC_TRY_COMPILE([#include <netinet/in.h>], [
1631   int opt = IP_RECVIF;
1632 ], [
1633   AC_MSG_RESULT(yes)
1634   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1635 ], [
1636   AC_MSG_RESULT(no)
1637 ])
1638
1639 dnl ----------------------
1640 dnl checking for SO_BINDANY
1641 dnl ----------------------
1642 AC_MSG_CHECKING(for SO_BINDANY)
1643 AC_TRY_COMPILE([#include <sys/socket.h>], [
1644   int opt = SO_BINDANY;
1645 ], [
1646   AC_MSG_RESULT(yes)
1647   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1648 ], [
1649   AC_MSG_RESULT(no)
1650 ])
1651
1652 dnl ----------------------
1653 dnl checking for IP_FREEBIND
1654 dnl ----------------------
1655 AC_MSG_CHECKING(for IP_FREEBIND)
1656 AC_TRY_COMPILE([#include <netinet/in.h>], [
1657   int opt = IP_FREEBIND;
1658 ], [
1659   AC_MSG_RESULT(yes)
1660   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1661 ], [
1662   AC_MSG_RESULT(no)
1663 ])
1664
1665 dnl --------------------------------------
1666 dnl checking for be32dec existence or not
1667 dnl --------------------------------------
1668 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1669                [#include <sys/endian.h>])
1670
1671 dnl --------------------------------------
1672 dnl checking for clock_time monotonic struct and call
1673 dnl --------------------------------------
1674 AC_CHECK_DECL(CLOCK_MONOTONIC,
1675         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1676          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1677 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1678
1679 dnl --------------------------------------
1680 dnl checking for flex and bison
1681 dnl --------------------------------------
1682
1683 AM_PROG_LEX
1684 AC_MSG_CHECKING(version of flex)
1685 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1686 frr_ac_flex_version="${frr_ac_flex_version##* }"
1687 AC_MSG_RESULT([$frr_ac_flex_version])
1688 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1689   LEX="$SHELL $missing_dir/missing flex"
1690   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1691     AC_MSG_WARN([using pregenerated flex output files])
1692   else
1693     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1694   fi
1695   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1696   AC_SUBST([LEXLIB], [''])
1697 ])
1698
1699 AC_PROG_YACC
1700 dnl thanks GNU bison for this b*llshit...
1701 AC_MSG_CHECKING(version of bison)
1702 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1703 frr_ac_bison_version="${frr_ac_bison_version##* }"
1704 frr_ac_bison_missing="false"
1705 case "x${frr_ac_bison_version}" in
1706   x2.7*)
1707     BISON_OPENBRACE='"'
1708     BISON_CLOSEBRACE='"'
1709     BISON_VERBOSE=''
1710     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1711     ;;
1712   x2.*|x1.*)
1713     AC_MSG_RESULT([$frr_ac_bison_version])
1714     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1715     frr_ac_bison_missing="true"
1716     ;;
1717   x)
1718     AC_MSG_RESULT([none])
1719     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1720     frr_ac_bison_missing="true"
1721     ;;
1722   *)
1723     BISON_OPENBRACE='{'
1724     BISON_CLOSEBRACE='}'
1725     BISON_VERBOSE='-Dparse.error=verbose'
1726     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1727     ;;
1728 esac
1729 AC_SUBST(BISON_OPENBRACE)
1730 AC_SUBST(BISON_CLOSEBRACE)
1731 AC_SUBST(BISON_VERBOSE)
1732
1733 if $frr_ac_bison_missing; then
1734   YACC="$SHELL $missing_dir/missing bison -y"
1735   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1736     AC_MSG_WARN([using pregenerated bison output files])
1737   else
1738     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1739   fi
1740 fi
1741
1742 dnl -------------------
1743 dnl capabilities checks
1744 dnl -------------------
1745 if test "${enable_capabilities}" != "no"; then
1746   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1747   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1748     [AC_MSG_RESULT(yes)
1749      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1750      frr_ac_keepcaps="yes"],
1751      AC_MSG_RESULT(no)
1752   )
1753   if test x"${frr_ac_keepcaps}" = x"yes"; then
1754     AC_CHECK_HEADERS(sys/capability.h)
1755   fi
1756   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1757     AC_CHECK_LIB(cap, cap_init,
1758       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1759        LIBCAP="-lcap"
1760        frr_ac_lcaps="yes"]
1761     )
1762   else
1763     AC_CHECK_HEADERS(priv.h,
1764      [AC_MSG_CHECKING(Solaris style privileges are available)
1765       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1766           [AC_MSG_RESULT(yes)
1767            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1768            frr_ac_scaps="yes"],
1769            AC_MSG_RESULT(no)
1770       )
1771      ]
1772    )
1773   fi
1774   if test x"${frr_ac_scaps}" = x"yes" \
1775        -o x"${frr_ac_lcaps}" = x"yes"; then
1776     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1777   fi
1778 fi
1779 AC_SUBST(LIBCAP)
1780
1781 dnl ---------------------------
1782 dnl check for glibc 'backtrace'
1783 dnl ---------------------------
1784 if test x"${enable_backtrace}" != x"no" ; then
1785   backtrace_ok=no
1786   AC_CHECK_HEADER([execinfo.h], [
1787     AC_SEARCH_LIBS([backtrace], [execinfo], [
1788       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1789       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1790       backtrace_ok=yes
1791     ],, [-lm])
1792   ])
1793
1794   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1795     dnl user explicitly requested backtrace but we failed to find support
1796     AC_MSG_FAILURE([failed to find backtrace support])
1797   fi
1798 fi
1799
1800 dnl -----------------------------------------
1801 dnl check for malloc mallinfo struct and call
1802 dnl this must try and link using LIBS, in
1803 dnl order to check no alternative allocator
1804 dnl has been specified, which might not provide
1805 dnl mallinfo, e.g. such as Umem on Solaris.
1806 dnl -----------------------------------------
1807 AC_CHECK_HEADERS([malloc.h malloc/malloc.h],,, [FRR_INCLUDES])
1808
1809 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1810   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1811 #ifdef HAVE_MALLOC_H
1812 #include <malloc.h>
1813 #endif
1814 #ifdef HAVE_MALLOC_MALLOC_H
1815 #include <malloc/malloc.h>
1816 #endif
1817 ]], [[
1818 struct mallinfo ac_x; ac_x = mallinfo ();
1819 ]])], [
1820     frr_cv_mallinfo=yes
1821   ], [
1822     frr_cv_mallinfo=no
1823   ])
1824 ])
1825 if test "$frr_cv_mallinfo" = yes; then
1826   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1827 fi
1828
1829 AC_MSG_CHECKING(whether malloc_usable_size is available)
1830 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1831 #ifdef HAVE_MALLOC_H
1832 #include <malloc.h>
1833 #endif
1834 #ifdef HAVE_MALLOC_MALLOC_H
1835 #include <malloc/malloc.h>
1836 #endif
1837 ]], [[
1838 size_t ac_x; ac_x = malloc_usable_size(NULL);
1839 ]])], [
1840   AC_MSG_RESULT(yes)
1841   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1842 ], [
1843   AC_MSG_RESULT(no)
1844
1845   AC_MSG_CHECKING(whether malloc_size is available)
1846   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1847 #ifdef HAVE_MALLOC_H
1848 #include <malloc.h>
1849 #endif
1850 #ifdef HAVE_MALLOC_MALLOC_H
1851 #include <malloc/malloc.h>
1852 #endif
1853 ]], [[
1854 size_t ac_x; ac_x = malloc_size(NULL);
1855 ]])], [
1856     AC_MSG_RESULT(yes)
1857     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1858   ], [
1859     AC_MSG_RESULT(no)
1860   ])
1861 ])
1862
1863 dnl ------
1864 dnl ZeroMQ
1865 dnl ------
1866 if test "x$enable_zeromq" != "xno"; then
1867   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1868     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1869     ZEROMQ=true
1870   ], [
1871     if test "x$enable_zeromq" = "xyes"; then
1872       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1873     fi
1874   ])
1875 fi
1876 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1877
1878 dnl ----------
1879 dnl configure date
1880 dnl ----------
1881 dev_version=`echo $VERSION | grep dev`
1882 #don't expire deprecated code in non 'dev' branch
1883 if test "${dev_version}" = ""; then
1884    CONFDATE=0
1885 else
1886    CONFDATE=`date '+%Y%m%d'`
1887 fi
1888 AC_SUBST(CONFDATE)
1889
1890 dnl ------------------------------
1891 dnl set paths for state directory
1892 dnl ------------------------------
1893 AC_MSG_CHECKING(directory to use for state file)
1894 if test "${prefix}" = "NONE"; then
1895   frr_statedir_prefix="";
1896 else
1897   frr_statedir_prefix=${prefix}
1898 fi
1899 if test "${localstatedir}" = '${prefix}/var'; then
1900   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1901                         ${frr_statedir_prefix}/var/adm dnl
1902                         ${frr_statedir_prefix}/etc dnl
1903                         /var/run        dnl
1904                         /var/adm        dnl
1905                         /etc            dnl
1906                         /dev/null;
1907   do
1908     test -d $FRR_STATE_DIR && break
1909   done
1910   frr_statedir=$FRR_STATE_DIR
1911 else
1912   frr_statedir=${localstatedir}
1913 fi
1914 if test $frr_statedir = "/dev/null"; then
1915     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1916 fi
1917 AC_MSG_RESULT(${frr_statedir})
1918 AC_SUBST(frr_statedir)
1919
1920 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1921 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1922 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1923 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1924
1925 dnl autoconf does this, but it does it too late...
1926 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1927 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1928
1929 dnl get the full path, recursing through variables...
1930 vtysh_bin="$bindir/vtysh"
1931 for I in 1 2 3 4 5 6 7 8 9 10; do
1932         eval vtysh_bin="\"$vtysh_bin\""
1933 done
1934 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1935 AC_SUBST(vtysh_bin)
1936
1937 CFG_SYSCONF="$sysconfdir"
1938 CFG_SBIN="$sbindir"
1939 CFG_STATE="$frr_statedir"
1940 CFG_MODULE="$moduledir"
1941 for I in 1 2 3 4 5 6 7 8 9 10; do
1942         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1943         eval CFG_SBIN="\"$CFG_SBIN\""
1944         eval CFG_STATE="\"$CFG_STATE\""
1945         eval CFG_MODULE="\"$CFG_MODULE\""
1946 done
1947 AC_SUBST(CFG_SYSCONF)
1948 AC_SUBST(CFG_SBIN)
1949 AC_SUBST(CFG_STATE)
1950 AC_SUBST(CFG_MODULE)
1951 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1952
1953 dnl ------------------------------------
1954 dnl Enable RPKI and add librtr to libs
1955 dnl ------------------------------------
1956 if test "${enable_rpki}" = "yes"; then
1957   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1958       [RPKI=true],
1959       [RPKI=false
1960       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1961   )
1962 fi
1963 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1964
1965 dnl ------------------------------------------
1966 dnl Check whether rtrlib was build with ssh support
1967 dnl ------------------------------------------
1968 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1969 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1970                         [[struct tr_ssh_config config;]])],
1971         [AC_MSG_RESULT(yes)
1972         AC_DEFINE(FOUND_SSH,,found_ssh)],
1973         AC_MSG_RESULT(no)
1974 )
1975
1976 dnl ---------------------------
1977 dnl Check htonl works correctly
1978 dnl ---------------------------
1979 AC_MSG_CHECKING(for working htonl)
1980 AC_CACHE_VAL(ac_cv_htonl_works,
1981  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1982                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1983  ]
1984 )
1985 AC_MSG_RESULT($ac_cv_htonl_works)
1986
1987 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
1988
1989 AC_CONFIG_FILES([
1990           redhat/frr.spec
1991           solaris/Makefile
1992           debianpkg/changelog
1993           alpine/APKBUILD
1994           snapcraft/snapcraft.yaml
1995           lib/version.h
1996           tests/lib/cli/test_cli.refout
1997           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1998           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1999           pkgsrc/eigrpd.sh])
2000
2001 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2002 AC_CONFIG_FILES([tools/frr],[chmod +x tools/frr])
2003
2004 AC_CONFIG_COMMANDS([lib/route_types.h], [
2005         dst="${ac_abs_top_builddir}/lib/route_types.h"
2006         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2007                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2008                 > "${dst}.tmp"
2009         test -f "${dst}" \
2010                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2011                 && rm "${dst}.tmp" \
2012                 || mv "${dst}.tmp" "${dst}"
2013 ], [
2014         PERL="$PERL"
2015 ])
2016
2017 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2018     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2019         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2020         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2021                 "${ac_abs_top_srcdir}" \
2022                 > "${dst}.tmp"
2023         test -f "${dst}" \
2024                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2025                 && rm "${dst}.tmp" \
2026                 || mv "${dst}.tmp" "${dst}"
2027     ], [
2028         PERL="$PERL"
2029     ])
2030 ])
2031
2032 ## Hack, but working solution to avoid rebuilding of frr.info.
2033 ## It's already in CVS until texinfo 4.7 is more common.
2034 AC_OUTPUT
2035
2036 echo "
2037 FRRouting configuration
2038 ------------------------------
2039 FRR version             : ${PACKAGE_VERSION}
2040 host operating system   : ${host_os}
2041 source code location    : ${srcdir}
2042 compiler                : ${CC}
2043 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2044 make                    : ${MAKE-make}
2045 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2046 state file directory    : ${frr_statedir}
2047 config file directory   : `eval echo \`echo ${sysconfdir}\``
2048 example directory       : `eval echo \`echo ${exampledir}\``
2049 module directory        : ${CFG_MODULE}
2050 user to run as          : ${enable_user}
2051 group to run as         : ${enable_group}
2052 group for vty sockets   : ${enable_vty_group}
2053 config file mask        : ${enable_configfile_mask}
2054 log file mask           : ${enable_logfile_mask}
2055 zebra protobuf enabled  : ${enable_protobuf:-no}
2056
2057 The above user and group must have read/write access to the state file
2058 directory and to the config files in the config file directory."
2059
2060 if test "${enable_doc}" != "no";then
2061   AS_IF([test "$SPHINXBUILD" = /bin/false],
2062      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2063 fi