configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lxc], [1.0.0.alpha1])
   5
   6 AC_CONFIG_SRCDIR([configure.ac])
   7 AC_CONFIG_AUX_DIR([config])
   8 AC_CONFIG_HEADERS([src/config.h])
   9 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  10 AC_CANONICAL_HOST
  11 AM_PROG_CC_C_O
  12 AC_GNU_SOURCE
  13
  14 # Detect the distribution. This is used for the default configuration and
  15 # for some distro-specific build options.
  16 AC_MSG_CHECKING([host distribution])
  17 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, fedora, suse, gentoo, debian, arch, slackware, paldo, mandriva or pardus.]))
  18 if test "z$with_distro" = "z"; then
  19         with_distro=`lsb_release -is`
  20 fi
  21 if test "z$with_distro" = "z"; then
  22         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  23         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  24         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  25         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  26         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  27         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  28         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  29         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  30         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  31         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="mandriva")
  32         AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
  33         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  34 fi
  35 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  36
  37 if test "z$with_distro" = "z"; then
  38         with_distro="unknown"
  39 fi
  40 case $with_distro in
  41         ubuntu)
  42                 distroconf=default.conf.ubuntu
  43                 ;;
  44         redhat|fedora|oracle|oracleserver)
  45                 distroconf=default.conf.libvirt
  46                 ;;
  47         *)
  48                 echo -n "Linux distribution network config unknown, defaulting to lxc.network.type = empty"
  49                 distroconf=default.conf.unknown
  50                 ;;
  51 esac
  52 AC_MSG_RESULT([$with_distro])
  53 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"])
  54
  55 AC_CHECK_PROG([NEWUIDMAP], [newuidmap], [newuidmap])
  56 AM_CONDITIONAL([HAVE_NEWUIDMAP], [test -n "$NEWUIDMAP"])
  57
  58 # Allow disabling rpath
  59 AC_ARG_ENABLE([rpath],
  60         [AC_HELP_STRING([--disable-rpath], [do not set rpath in executables])],
  61         [], [enable_rpath=yes])
  62 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
  63
  64 # Documentation (manpages)
  65 AC_ARG_ENABLE([doc],
  66         [AC_HELP_STRING([--enable-doc], [make mans (requires docbook2man or docbook2x-man to be installed) [default=auto]])],
  67         [], [enable_doc=auto])
  68
  69 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
  70         db2xman=""
  71         dbparsers="docbook2x-man db2x_docbook2man docbook2man"
  72
  73         AC_MSG_CHECKING(for docbook2x-man)
  74         for name in ${dbparsers}; do
  75                 if "$name" --help >/dev/null 2>&1; then
  76                         db2xman="$name"
  77                         break;
  78                 fi
  79         done
  80
  81         if test -n "${db2xman}"; then
  82                 AC_MSG_RESULT([${db2xman}])
  83         else
  84                 AC_MSG_RESULT([no])
  85                 if test "x$enable_doc" = "xyes"; then
  86                         AC_MSG_ERROR([docbook2x-man required by man request, but not found])
  87                 fi
  88         fi
  89
  90         AC_SUBST(db2xman)
  91 fi
  92 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
  93
  94 if test "x$db2xman" = "xdocbook2man"; then
  95         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
  96 else
  97         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
  98 fi
  99 AC_SUBST(docdtd)
 100
 101 # Apparmor
 102 AC_ARG_ENABLE([apparmor],
 103         [AC_HELP_STRING([--enable-apparmor], [enable apparmor])],
 104         [], [enable_apparmor=check])
 105
 106 if test "$enable_apparmor" = "check" ; then
 107         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 108 fi
 109 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 110
 111 AC_CHECK_LIB([gnutls], [gnutls_hash_fast])
 112
 113 AM_COND_IF([ENABLE_APPARMOR],
 114         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 115         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 116         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 117
 118 # Seccomp syscall filter
 119 AC_ARG_ENABLE([seccomp],
 120         [AC_HELP_STRING([--enable-seccomp], [enable seccomp])],
 121         [], [enable_seccomp=check])
 122
 123 if test "$enable_seccomp" = "check" ; then
 124         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 125 fi
 126 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 127
 128 AM_COND_IF([ENABLE_SECCOMP],
 129         [AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 130         AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 131         AC_SUBST([SECCOMP_LIBS], [-lseccomp])])
 132
 133 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 134 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [#include <seccomp.h>])
 135
 136 # Configuration examples
 137 AC_ARG_ENABLE([examples],
 138         [AC_HELP_STRING([--disable-examples], [do not install configuration examples])],
 139         [], [enable_examples=yes])
 140 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 141
 142 # Python3 module and scripts
 143 AC_ARG_ENABLE([python],
 144         [AC_HELP_STRING([--enable-python], [enable python binding])],
 145         [enable_python=yes], [enable_python=no])
 146 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 147
 148 AM_COND_IF([ENABLE_PYTHON],
 149         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 150         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 151         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 152
 153 # Not in older autoconf versions
 154 # AS_VAR_COPY(DEST, SOURCE)
 155 # -------------------------
 156 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 157 # shell variable SOURCE.
 158 m4_ifdef([AS_VAR_COPY], [],
 159 [AC_DEFUN([AS_VAR_COPY],
 160     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 161 ])
 162
 163 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 164 m4_ifdef([PKG_CHECK_VAR], [],
 165 [AC_DEFUN([PKG_CHECK_VAR],
 166     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 167      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 168      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 169      AS_VAR_COPY([$1], [pkg_cv_][$1])
 170      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 171     ])# PKG_CHECK_VAR
 172 ])
 173
 174 # Lua module and scripts
 175 AC_ARG_ENABLE([lua],
 176         [AC_HELP_STRING([--enable-lua], [enable lua binding])],
 177         [], [enable_lua=check])
 178
 179 AC_ARG_WITH([lua-pc],
 180         [AS_HELP_STRING(
 181                 [--with-lua-pc=PKG],
 182                 [Specify pkg-config package name for lua]
 183         )], [], [with_lua_pc=no])
 184
 185 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 186         # exit with error if not found
 187         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 188 fi
 189
 190 if test "x$enable_lua" = "xcheck" -a "x$with_lua_pc" != "xno"; then
 191         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 192                 [LUAPKGCONFIG=$with_lua_pc
 193                 enable_lua=yes],
 194                 [enable_lua=no])
 195 fi
 196
 197 if test "x$enable_lua" != "xno"; then
 198         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 199                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 200                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 201                                 [AS_IF([test "x$enable_lua" = "xyes"],
 202                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 203                                         [enable_lua=no])]
 204                         )]
 205                 )])
 206         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 207 fi
 208
 209 AM_CONDITIONAL([ENABLE_LUA],
 210         [test "x$enable_lua" = "xyes"])
 211
 212 AM_COND_IF([ENABLE_LUA],
 213         [AC_MSG_CHECKING([Lua version])
 214         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 215                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 216         AC_MSG_RESULT([$LUA_VERSION])
 217         PKG_CHECK_VAR([LUA_INSTALL_CMOD], [$LUAPKGCONFIG], [INSTALL_CMOD],,
 218                 [LUA_INSTALL_CMOD=$libdir/lua/$LUA_VERSION])
 219         PKG_CHECK_VAR([LUA_INSTALL_LMOD], [$LUAPKGCONFIG], [INSTALL_LMOD],,
 220                 [LUA_INSTALL_LMOD=$datadir/lua/$LUA_VERSION])
 221         ])
 222
 223 # Optional test binaries
 224 AC_ARG_ENABLE([tests],
 225         [AC_HELP_STRING([--enable-tests], [build test/example binaries])],
 226         [enable_tests=yes], [enable_tests=no])
 227 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 228
 229 # LXC container path, where the containers are actually stored
 230 # This is overridden by an entry in the file called LXCCONF
 231 # (i.e. /etc/lxc/lxc.conf)
 232 AC_ARG_WITH([config-path],
 233         [AC_HELP_STRING(
 234                 [--with-config-path=dir],
 235                 [lxc configuration repository path]
 236         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 237
 238 # The path of the global lxc configuration file.
 239 AC_ARG_WITH([global-conf],
 240         [AC_HELP_STRING(
 241                 [--with-global-conf=dir],
 242                 [global lxc configuration file]
 243         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 244
 245 AC_ARG_WITH([usernic-conf],
 246         [AC_HELP_STRING(
 247                 [--with-usernic-conf],
 248                 [user network interface configuration file]
 249         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 250
 251 AC_ARG_WITH([usernic-db],
 252         [AC_HELP_STRING(
 253                 [--with-usernic-db],
 254                 [lxc user nic database]
 255         )], [], [with_usernic_db=['/run/lxc/nics']])
 256
 257 # Rootfs path, where the container mount structure is assembled
 258 AC_ARG_WITH([rootfs-path],
 259         [AC_HELP_STRING(
 260                 [--with-rootfs-path=dir],
 261                 [lxc rootfs mount point]
 262         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 263 # cgroup pattern specification
 264 AC_ARG_WITH([cgroup-pattern],
 265         [AC_HELP_STRING(
 266                 [--with-cgroup-pattern=pattern],
 267                 [pattern for container cgroups]
 268         )], [], [with_cgroup_pattern=['/lxc/%n']])
 269
 270 # Container log path.  By default, use $lxcpath.
 271 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 272 AC_ARG_ENABLE([configpath-log],
 273         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path])],
 274         [use_configpath_logs=yes], [use_configpath_logs=no])
 275 AC_MSG_RESULT([$use_configpath_logs])
 276 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$use_configpath_logs" = "yes"])
 277
 278 if test "$use_configpath_logs" = "yes"; then
 279         default_log_path="${with_config_path}"
 280 else
 281         default_log_path="${localstatedir}/log/lxc"
 282 fi
 283
 284 AC_ARG_WITH([log-path],
 285         [AC_HELP_STRING(
 286                 [--with-log-path=dir],
 287                 [per container log path]
 288         )], [], [with_log_path=['${default_log_path}']])
 289
 290 # Expand some useful variables
 291 AS_AC_EXPAND(PREFIX, "$prefix")
 292 AS_AC_EXPAND(LIBDIR, "$libdir")
 293 AS_AC_EXPAND(BINDIR, "$bindir")
 294 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 295 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 296 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 297 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 298 AS_AC_EXPAND(DATADIR, "$datadir")
 299 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 300 AS_AC_EXPAND(DOCDIR, "$docdir")
 301 AS_AC_EXPAND(LXC_DISTRO_CONF, "$distroconf")
 302 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 303 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 304 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 305 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 306 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 307 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 308 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 309 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 310 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 311 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 312 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 313
 314 # Check for some standard kernel headers
 315 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 316                                 [],
 317                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 318                                 [#include <sys/socket.h>])
 319
 320 # Allow disabling libcap support
 321 AC_ARG_ENABLE([capabilities],
 322         [AC_HELP_STRING([--disable-capabilities], [disable kernel capabilities])],
 323         [], [enable_capabilities=yes])
 324
 325 # Check for libcap support
 326 if test "x$enable_capabilities" = "xyes"; then
 327         AC_CHECK_LIB(cap,cap_set_proc,caplib=yes,caplib=no)
 328         AC_MSG_CHECKING([linux capabilities])
 329         if test "x$caplib" = "xyes" ; then
 330                 CAP_LIBS="-lcap"
 331                 AC_MSG_RESULT([$CAP_LIBS])
 332         else
 333                 AC_MSG_RESULT([no])
 334                 AC_MSG_ERROR([You are missing libcap support. If you really want to build without kernel capabilities, use --disable-capabilities])
 335         fi
 336 else
 337         CAP_LIBS=""
 338 fi
 339 AC_SUBST([CAP_LIBS])
 340
 341 # Check for alternate C libraries
 342 AC_MSG_CHECKING(for bionic libc)
 343 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 344         [[#ifndef __ANDROID__
 345 error: Not bionic!
 346 #endif]])],
 347         [is_bionic=yes],
 348         [is_bionic=no])
 349 if test "x$is_bionic" = "xyes"; then
 350         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 351         AC_MSG_RESULT([yes])
 352 else
 353         AC_MSG_RESULT([no])
 354 fi
 355 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 356
 357 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 358 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 359
 360 # Check for some headers
 361 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 362
 363 # Check for some syscalls functions
 364 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr])
 365
 366 # Check for some functions
 367 AC_CHECK_LIB(util, openpty)
 368 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent])
 369 AC_CHECK_FUNCS([getline],
 370         AM_CONDITIONAL(HAVE_GETLINE, true)
 371         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 372         AM_CONDITIONAL(HAVE_GETLINE, false))
 373 AC_CHECK_FUNCS([fgetln],
 374         AM_CONDITIONAL(HAVE_FGETLN, true)
 375         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 376         AM_CONDITIONAL(HAVE_FGETLN, false))
 377
 378 # Check for some libraries
 379 AC_SEARCH_LIBS(sem_open, [rt pthread])
 380 AC_SEARCH_LIBS(clock_gettime, [rt])
 381
 382 # Check for some standard binaries
 383 AC_PROG_GCC_TRADITIONAL
 384 AC_PROG_SED
 385
 386 if test "x$GCC" = "xyes"; then
 387         CFLAGS="$CFLAGS -Wall -Werror"
 388 fi
 389
 390 # Files requiring some variable expansion
 391 AC_CONFIG_FILES([
 392         Makefile
 393         lxc.pc
 394         lxc.spec
 395         config/Makefile
 396
 397         doc/Makefile
 398         doc/legacy/lxc-ls.sgml
 399         doc/lxc-attach.sgml
 400         doc/lxc-cgroup.sgml
 401         doc/lxc-checkconfig.sgml
 402         doc/lxc-checkpoint.sgml
 403         doc/lxc-clone.sgml
 404         doc/lxc-console.sgml
 405         doc/lxc-create.sgml
 406         doc/lxc-destroy.sgml
 407         doc/lxc-device.sgml
 408         doc/lxc-execute.sgml
 409         doc/lxc-freeze.sgml
 410         doc/lxc-info.sgml
 411         doc/lxc-kill.sgml
 412         doc/lxc-ls.sgml
 413         doc/lxc-monitor.sgml
 414         doc/lxc-netstat.sgml
 415         doc/lxc-ps.sgml
 416         doc/lxc-restart.sgml
 417         doc/lxc-snapshot.sgml
 418         doc/lxc-start-ephemeral.sgml
 419         doc/lxc-start.sgml
 420         doc/lxc-stop.sgml
 421         doc/lxc-top.sgml
 422         doc/lxc-unfreeze.sgml
 423         doc/lxc-unshare.sgml
 424         doc/lxc-version.sgml
 425         doc/lxc-wait.sgml
 426
 427         doc/lxc.conf.sgml
 428         doc/lxc.sgml
 429         doc/common_options.sgml
 430         doc/see_also.sgml
 431
 432         doc/rootfs/Makefile
 433
 434         doc/examples/Makefile
 435         doc/examples/lxc-macvlan.conf
 436         doc/examples/lxc-vlan.conf
 437         doc/examples/lxc-no-netns.conf
 438         doc/examples/lxc-empty-netns.conf
 439         doc/examples/lxc-phys.conf
 440         doc/examples/lxc-veth.conf
 441         doc/examples/lxc-complex.conf
 442
 443         doc/ja/Makefile
 444         doc/ja/legacy/lxc-ls.sgml
 445         doc/ja/lxc-attach.sgml
 446         doc/ja/lxc-cgroup.sgml
 447         doc/ja/lxc-checkconfig.sgml
 448         doc/ja/lxc-checkpoint.sgml
 449         doc/ja/lxc-clone.sgml
 450         doc/ja/lxc-console.sgml
 451         doc/ja/lxc-create.sgml
 452         doc/ja/lxc-destroy.sgml
 453         doc/ja/lxc-device.sgml
 454         doc/ja/lxc-execute.sgml
 455         doc/ja/lxc-freeze.sgml
 456         doc/ja/lxc-info.sgml
 457         doc/ja/lxc-kill.sgml
 458         doc/ja/lxc-ls.sgml
 459         doc/ja/lxc-monitor.sgml
 460         doc/ja/lxc-netstat.sgml
 461         doc/ja/lxc-ps.sgml
 462         doc/ja/lxc-restart.sgml
 463         doc/ja/lxc-start-ephemeral.sgml
 464         doc/ja/lxc-start.sgml
 465         doc/ja/lxc-stop.sgml
 466         doc/ja/lxc-top.sgml
 467         doc/ja/lxc-unfreeze.sgml
 468         doc/ja/lxc-unshare.sgml
 469         doc/ja/lxc-version.sgml
 470         doc/ja/lxc-wait.sgml
 471
 472         doc/ja/lxc.conf.sgml
 473         doc/ja/lxc.sgml
 474         doc/ja/common_options.sgml
 475         doc/ja/see_also.sgml
 476
 477         hooks/Makefile
 478
 479         templates/Makefile
 480         templates/lxc-cirros
 481         templates/lxc-debian
 482         templates/lxc-ubuntu
 483         templates/lxc-ubuntu-cloud
 484         templates/lxc-opensuse
 485         templates/lxc-busybox
 486         templates/lxc-fedora
 487         templates/lxc-oracle
 488         templates/lxc-altlinux
 489         templates/lxc-sshd
 490         templates/lxc-archlinux
 491         templates/lxc-alpine
 492
 493         src/Makefile
 494         src/lxc/Makefile
 495         src/lxc/lxc-ps
 496         src/lxc/lxc-netstat
 497         src/lxc/lxc-checkconfig
 498         src/lxc/lxc-version
 499         src/lxc/lxc-start-ephemeral
 500         src/lxc/legacy/lxc-ls
 501         src/lxc/lxc.functions
 502
 503         src/python-lxc/Makefile
 504
 505         src/lua-lxc/Makefile
 506
 507         src/tests/Makefile
 508 ])
 509 AC_CONFIG_COMMANDS([default],[[]],[[]])
 510 AC_OUTPUT