configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 3.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl if the user specified any CFLAGS, we don't add "-g -Os/-O2" here
 189 if test "z$orig_cflags" = "z"; then
 190   AC_C_FLAG([-g])
 191   AC_C_FLAG([-Os], [
 192     AC_C_FLAG([-O2])
 193   ])
 194 fi
 195
 196 dnl always want these CFLAGS
 197 AC_C_FLAG([-fno-omit-frame-pointer])
 198 AC_C_FLAG([-Wall])
 199 AC_C_FLAG([-Wextra])
 200 AC_C_FLAG([-Wmissing-prototypes])
 201 AC_C_FLAG([-Wmissing-declarations])
 202 AC_C_FLAG([-Wpointer-arith])
 203 AC_C_FLAG([-Wbad-function-cast])
 204 AC_C_FLAG([-Wwrite-strings])
 205 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 206   AC_C_FLAG([-Wcast-qual])
 207   AC_C_FLAG([-Wstrict-prototypes])
 208   AC_C_FLAG([-Wmissing-noreturn])
 209   AC_C_FLAG([-Wmissing-format-attribute])
 210   AC_C_FLAG([-Wunreachable-code])
 211   AC_C_FLAG([-Wpacked])
 212   AC_C_FLAG([-Wpadded])
 213 else
 214   AC_C_FLAG([-Wno-unused-result])
 215 fi
 216 AC_C_FLAG([-Wno-unused-parameter])
 217 AC_C_FLAG([-Wno-missing-field-initializers])
 218
 219 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 220 dnl for some reason the string consts get 'promoted' to char *,
 221 dnl triggering a const to non-const conversion warning.
 222 AC_C_FLAG([-diag-disable 3179])
 223
 224 if test x"${enable_werror}" = x"yes" ; then
 225   WERROR="-Werror"
 226 fi
 227 AC_SUBST(WERROR)
 228
 229 dnl need link on this one, not compile
 230 AC_LANG_PUSH(C)
 231 ac_ld_flag_save="$LDFLAGS"
 232 LDFLAGS="$LDFLAGS -rdynamic"
 233 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 234 AC_LINK_IFELSE(
 235         [AC_LANG_PROGRAM([[]])],
 236         [AC_MSG_RESULT([yes])],
 237         [
 238                 LDFLAGS="$ac_ld_flag_save"
 239                 AC_MSG_RESULT([no])
 240         ])
 241 AC_LANG_POP(C)
 242
 243 dnl ----------
 244 dnl Essentials
 245 dnl ----------
 246
 247 AX_PTHREAD([
 248   CC="$PTHREAD_CC"
 249   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 250   LIBS="$PTHREAD_LIBS $LIBS"
 251 ], [
 252   AC_MSG_FAILURE([This FRR version needs pthreads])
 253 ])
 254
 255 dnl --------------
 256 dnl Check programs
 257 dnl --------------
 258 AC_PROG_INSTALL
 259 AC_PROG_LN_S
 260 AC_PROG_MAKE_SET
 261 AC_CHECK_TOOL(AR, ar)
 262
 263 dnl -----------------
 264 dnl System extensions
 265 dnl -----------------
 266 AC_GNU_SOURCE
 267
 268 dnl -------
 269 dnl libtool
 270 dnl -------
 271 LT_INIT
 272
 273 dnl ----------------------
 274 dnl Packages configuration
 275 dnl ----------------------
 276 AC_ARG_WITH(pkg-extra-version,
 277         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 278         [EXTRAVERSION=$withval],)
 279 AC_ARG_WITH(pkg-git-version,
 280         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 281         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 282 AC_ARG_WITH(vtysh_pager,
 283         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 284         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 285 AC_ARG_ENABLE(vtysh,
 286   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 287 AC_ARG_ENABLE(doc,
 288   AS_HELP_STRING([--disable-doc], [do not build docs]))
 289 AC_ARG_ENABLE(zebra,
 290   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 291 AC_ARG_ENABLE(bgpd,
 292   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 293 AC_ARG_ENABLE(ripd,
 294   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 295 AC_ARG_ENABLE(ripngd,
 296   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 297 AC_ARG_ENABLE(ospfd,
 298   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 299 AC_ARG_ENABLE(ospf6d,
 300   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 301 AC_ARG_ENABLE(ldpd,
 302   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 303 AC_ARG_ENABLE(nhrpd,
 304   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 305 AC_ARG_ENABLE(eigrpd,
 306   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 307 AC_ARG_ENABLE(babeld,
 308   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 309 AC_ARG_ENABLE(watchfrr,
 310   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 311 AC_ARG_ENABLE(isisd,
 312   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 313 AC_ARG_ENABLE(pimd,
 314   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 315 AC_ARG_ENABLE(bgp-announce,
 316   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 317 AC_ARG_ENABLE(bgp-vnc,
 318   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 319 AC_ARG_WITH(rfp-path,
 320   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 321 AC_ARG_ENABLE(snmp,
 322   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 323 AC_ARG_WITH(libpam,
 324   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 325 AC_ARG_ENABLE(ospfapi,
 326   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 327 AC_ARG_ENABLE(ospfclient,
 328   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 329                           (this is the default if --disable-ospfapi is set)]))
 330 AC_ARG_ENABLE(multipath,
 331   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 332 AC_ARG_ENABLE(user,
 333   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 334 AC_ARG_ENABLE(group,
 335   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 336 AC_ARG_ENABLE(vty_group,
 337   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 338 AC_ARG_ENABLE(configfile_mask,
 339   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 340 AC_ARG_ENABLE(logfile_mask,
 341   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 342 AC_ARG_ENABLE(shell_access,
 343   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 344 AC_ARG_ENABLE(rtadv,
 345   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 346 AC_ARG_ENABLE(irdp,
 347   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 348 AC_ARG_ENABLE(capabilities,
 349   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 350 AC_ARG_ENABLE(rusage,
 351   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 352 AC_ARG_ENABLE(gcc_ultra_verbose,
 353   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 354 AC_ARG_ENABLE(linux24_tcp_md5,
 355   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 356 AC_ARG_ENABLE(backtrace,
 357   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 358 AC_ARG_ENABLE(time-check,
 359   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 360 AC_ARG_ENABLE(pcreposix,
 361   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 362 AC_ARG_ENABLE(fpm,
 363   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 364 AC_ARG_ENABLE(systemd,
 365   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 366 AC_ARG_ENABLE(werror,
 367   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 368 AC_ARG_ENABLE(cumulus,
 369   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 370 AC_ARG_ENABLE(datacenter,
 371   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 372 AC_ARG_ENABLE(rr-semantics,
 373   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 374 AC_ARG_ENABLE([protobuf],
 375   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 376 AC_ARG_ENABLE([oldvpn_commands],
 377   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 378
 379 AC_CHECK_HEADERS(json-c/json.h)
 380 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 381 if test $ac_cv_lib_json_c_json_object_get = no; then
 382   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 383   if test $ac_cv_lib_json_json_object_get = no; then
 384       AC_MSG_ERROR([lib json is needed to compile])
 385   fi
 386 fi
 387
 388 AC_ARG_ENABLE([dev_build],
 389     AS_HELP_STRING([--enable-dev-build], [build for development]))
 390
 391 if test x"${enable_time_check}" != x"no" ; then
 392   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 393     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 394   else
 395     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 396   fi
 397 fi
 398
 399 case "${enable_systemd}" in
 400   "no") ;;
 401   "yes")
 402   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 403   if test $ac_cv_lib_systemd_sd_notify = no; then
 404     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 405   else
 406     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 407   fi
 408   ;;
 409   "*") ;;
 410 esac
 411
 412 if test "${enable_rr_semantics}" != "no" ; then
 413   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 414 fi
 415
 416 if test "${enable_datacenter}" = "yes" ; then
 417   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 418   DFLT_NAME="datacenter"
 419 else
 420   DFLT_NAME="traditional"
 421 fi
 422
 423 if test "${enable_cumulus}" = "yes" ; then
 424   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 425 fi
 426
 427 AC_SUBST(DFLT_NAME)
 428 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 429
 430 if test "${enable_shell_access}" = "yes"; then
 431    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 432 fi
 433
 434 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 435
 436 if test "x${enable_dev_build}" = "xyes"; then
 437    AC_DEFINE(DEV_BUILD,,Build for development)
 438 fi
 439 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 440
 441 #
 442 # Python for clippy
 443 #
 444 AS_IF([test "$host" = "$build"], [
 445   PYTHONCONFIG=""
 446
 447   # ordering:
 448   # 1.  try python3, but respect the user's preference on which minor ver
 449   # 2.  try python, which might be py3 or py2 again on the user's preference
 450   # 3.  try python2 (can really only be 2.7 but eh)
 451   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 452   #
 453   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 454   # (AX_PYTHON does not do what we need)
 455
 456   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 457   if test -n "$PYTHONCONFIG"; then
 458     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 459     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 460
 461     AC_MSG_CHECKING([whether we found a working Python version])
 462     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 463 #include <Python.h>
 464 #if PY_VERSION_HEX < 0x02070000
 465 #error python too old
 466 #endif
 467 int main(void);
 468 ],
 469 [
 470 {
 471   Py_Initialize();
 472   return 0;
 473 }
 474 ])], [
 475       PYTHONCONFIG=""
 476       unset PYTHON_LIBS
 477       unset PYTHON_CFLAGS
 478     ])
 479   fi
 480
 481   if test -z "$PYTHONCONFIG"; then
 482     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 483       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 484         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 485           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 486             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 487               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 488               ])])])])])
 489
 490
 491     AC_MSG_CHECKING([whether we found a working Python version])
 492     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 493 #include <Python.h>
 494 #if PY_VERSION_HEX < 0x02070000
 495 #error python too old
 496 #endif
 497 int main(void);
 498 ],
 499 [
 500 {
 501   Py_Initialize();
 502   return 0;
 503 }
 504 ])], [
 505       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 506     ])
 507   fi
 508 ])
 509 AC_SUBST(PYTHON_CFLAGS)
 510 AC_SUBST(PYTHON_LIBS)
 511
 512 #
 513 # Logic for protobuf support.
 514 #
 515 if test "$enable_protobuf" = "yes"; then
 516    have_protobuf=yes
 517
 518    # Check for protoc-c
 519    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 520    if test "x$PROTOC_C" = "x/bin/false"; then
 521       have_protobuf=no
 522    else
 523       found_protobuf_c=no
 524       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 525                      [found_protobuf_c=yes],
 526                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 527
 528       if test "x$found_protobuf_c" = "xyes"; then
 529          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 530          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 531       else
 532         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 533                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 534       fi
 535    fi
 536 fi
 537
 538 #
 539 # Logic for old vpn commans support.
 540 #
 541 if test "$enable_oldvpn_commands" = "yes"; then
 542    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 543 fi
 544
 545 # Fail if the user explicity enabled protobuf support and we couldn't
 546 # find the compiler or libraries.
 547 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 548    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 549 fi
 550
 551 if test "x$have_protobuf" = "xyes"; then
 552    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 553 fi
 554
 555 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 556
 557 #
 558 # End of logic for protobuf support.
 559 #
 560
 561 if test "${enable_linux24_tcp_md5}" = "yes"; then
 562   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 563 fi
 564
 565 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 566 if test "${enable_rtadv}" != "no"; then
 567   AC_MSG_RESULT(yes)
 568   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 569 else
 570   AC_MSG_RESULT(no)
 571 fi
 572
 573 if test x"${enable_user}" = x"no"; then
 574   enable_user=""
 575 else
 576   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 577     enable_user="frr"
 578   fi
 579   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 580 fi
 581
 582 if test x"${enable_group}" = x"no"; then
 583   enable_group=""
 584 else
 585   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 586     enable_group="frr"
 587   fi
 588   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 589 fi
 590
 591 if test x"${enable_vty_group}" = x"yes" ; then
 592   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 593 elif test x"${enable_vty_group}" != x""; then
 594   if test x"${enable_vty_group}" != x"no"; then
 595     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 596   fi
 597 fi
 598 AC_SUBST([enable_user])
 599 AC_SUBST([enable_group])
 600 AC_SUBST([enable_vty_group])
 601
 602 enable_configfile_mask=${enable_configfile_mask:-0600}
 603 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 604
 605 enable_logfile_mask=${enable_logfile_mask:-0600}
 606 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 607
 608 MPATH_NUM=1
 609
 610 case "${enable_multipath}" in
 611   0)
 612     MPATH_NUM=64
 613     ;;
 614   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 615     MPATH_NUM="${enable_multipath}"
 616     ;;
 617   "")
 618     ;;
 619   *)
 620     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 621     ;;
 622 esac
 623
 624 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 625
 626 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 627
 628 dnl -----------------------------------
 629 dnl Add extra version string to package
 630 dnl name, string and version fields.
 631 dnl -----------------------------------
 632 if test "x${EXTRAVERSION}" != "x" ; then
 633   VERSION="${VERSION}${EXTRAVERSION}"
 634   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 635   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 636   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 637 fi
 638
 639 if test "x$with_pkg_git_version" = "xyes"; then
 640         if test -d "${srcdir}/.git"; then
 641                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 642         else    with_pkg_git_version="no"
 643                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 644         fi
 645 fi
 646 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 647
 648 dnl ------------------------------------
 649 dnl Check C keywords and standard  types
 650 dnl ------------------------------------
 651 AC_C_CONST
 652 AC_C_INLINE
 653 AC_C_VOLATILE
 654 AC_HEADER_STDC
 655 dnl AC_TYPE_PID_T
 656 AC_TYPE_UID_T
 657 AC_TYPE_MODE_T
 658 AC_TYPE_SIZE_T
 659 AC_STRUCT_TM
 660
 661 dnl -------------------------
 662 dnl Check other header files.
 663 dnl -------------------------
 664 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 665         linux/version.h asm/types.h \
 666         sys/cdefs.h])
 667
 668 ac_stdatomic_ok=false
 669 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 670 AC_CHECK_HEADER([stdatomic.h],[
 671
 672   AC_MSG_CHECKING([whether _Atomic qualifier works])
 673   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 674 #include <stdatomic.h>
 675 int main(int argc, char **argv) {
 676   _Atomic int i = 0;
 677   return i;
 678 }
 679 ]])], [
 680     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 681     AC_MSG_RESULT([yes])
 682     ac_stdatomic_ok=true
 683   ], [
 684     AC_MSG_RESULT([no])
 685   ])
 686 ])
 687
 688 AS_IF([$ac_stdatomic_ok], [true], [
 689   AC_MSG_CHECKING([for __atomic_* builtins])
 690   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 691 int main(int argc, char **argv) {
 692   volatile int i = 1;
 693   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 694   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 695 }
 696 ]])], [
 697     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 698     AC_MSG_RESULT([yes])
 699   ], [
 700     AC_MSG_RESULT([no])
 701
 702     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 703     AC_MSG_CHECKING([for __sync_* builtins])
 704     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 705 int main(int argc, char **argv) {
 706   volatile int i = 1;
 707   __sync_fetch_and_sub (&i, 1);
 708   return __sync_val_compare_and_swap (&i, 0, 1);
 709 }
 710 ]])], [
 711       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 712       AC_MSG_RESULT([yes])
 713
 714       AC_MSG_CHECKING([for __sync_swap builtin])
 715       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 716 int main(int argc, char **argv) {
 717   volatile int i = 1;
 718   return __sync_swap (&i, 2);
 719 }
 720 ]])], [
 721         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 722         AC_MSG_RESULT([yes])
 723       ], [
 724         AC_MSG_RESULT([no])
 725       ])
 726
 727     ], [
 728       AC_MSG_RESULT([no])
 729       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 730     ])
 731   ])
 732 ])
 733
 734 dnl Utility macro to avoid retyping includes all the time
 735 m4_define([FRR_INCLUDES],
 736 [#ifdef SUNOS_5
 737 #define _XPG4_2
 738 #define __EXTENSIONS__
 739 #endif
 740 #include <stdio.h>
 741 #include <stdlib.h>
 742 #include <stddef.h>
 743 #include <sys/types.h>
 744 /* sys/conf.h depends on param.h on FBSD at least */
 745 #include <sys/param.h>
 746 /* Required for MAXSIG */
 747 #include <signal.h>
 748 #include <sys/socket.h>
 749 #ifdef __APPLE__
 750 # define __APPLE_USE_RFC_3542
 751 #endif
 752 #include <netinet/in.h>
 753 #include <sys/time.h>
 754 #include <time.h>
 755 #include <net/if.h>
 756 ])dnl
 757
 758 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 759 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 760 dnl an additional round for it.
 761
 762 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 763
 764 m4_define([FRR_INCLUDES],
 765 FRR_INCLUDES
 766 [#if HAVE_NET_IF_VAR_H
 767 # include <net/if_var.h>
 768 #endif
 769 ])dnl
 770
 771 AC_CHECK_HEADERS([netinet/in_var.h \
 772         net/if_dl.h net/netopt.h \
 773         inet/nd.h netinet/ip_icmp.h \
 774         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 775         [], [], FRR_INCLUDES)
 776
 777 AC_CHECK_HEADERS([ucontext.h], [], [],
 778 [#ifndef __USE_GNU
 779 #define __USE_GNU
 780 #endif /* __USE_GNU */
 781 FRR_INCLUDES
 782 ])
 783
 784 m4_define([UCONTEXT_INCLUDES],
 785 [#include <ucontext.h>])dnl
 786
 787 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 788   [], [], [UCONTEXT_INCLUDES])
 789 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 790   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 791    [], [], [UCONTEXT_INCLUDES])],
 792   [], [UCONTEXT_INCLUDES])
 793 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 794   [], [], [UCONTEXT_INCLUDES])
 795
 796 m4_define([FRR_INCLUDES],
 797 FRR_INCLUDES
 798 [
 799 #include <sys/un.h>
 800 #include <netinet/in_systm.h>
 801 #if HAVE_NETINET_IN_VAR_H
 802 # include <netinet/in_var.h>
 803 #endif
 804 #if HAVE_NET_IF_DL_H
 805 # include <net/if_dl.h>
 806 #endif
 807 #if HAVE_NET_NETOPT_H
 808 # include <net/netopt.h>
 809 #endif
 810 #include <net/route.h>
 811 #if HAVE_INET_ND_H
 812 # include <inet/nd.h>
 813 #endif
 814 #include <arpa/inet.h>
 815 /* Required for IDRP */
 816 #if HAVE_NETINET_IP_ICMP_H
 817 # include <netinet/ip_icmp.h>
 818 #endif
 819 ])dnl
 820
 821 dnl V6 headers are checked below, after we check for v6
 822
 823 AC_MSG_CHECKING([which operating system interface to use])
 824 case "$host_os" in
 825   sunos* | solaris2*)
 826     AC_MSG_RESULT([Solaris])
 827
 828     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 829     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 830
 831     AC_CHECK_LIB(socket, main)
 832     AC_CHECK_LIB(nsl, main)
 833     AC_CHECK_LIB(umem, main)
 834     AC_CHECK_FUNCS([printstack], [
 835       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 836       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 837     ])
 838     CURSES=-lcurses
 839     SOLARIS="solaris"
 840     ;;
 841   linux*)
 842     AC_MSG_RESULT([Linux])
 843
 844     AC_DEFINE(GNU_LINUX,,GNU Linux)
 845     AC_DEFINE(HAVE_NETLINK,,netlink)
 846     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 847
 848     dnl Linux has a compilation problem with mixing
 849     dnl netinet/in.h and linux/in6.h they are not
 850     dnl compatible.  There has been discussion on
 851     dnl how to fix it but no real progress on implementation
 852     dnl when they fix it, remove this
 853     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 854
 855     AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
 856     ;;
 857   openbsd*)
 858     AC_MSG_RESULT([OpenBSD])
 859
 860     AC_DEFINE(OPEN_BSD,,OpenBSD)
 861     AC_DEFINE(KAME,1,KAME IPv6)
 862
 863     if test "x${enable_pimd}" != "xno"; then
 864       case "$host_os" in
 865       openbsd6.0)
 866         ;;
 867       openbsd[6-9]*)
 868         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 869         ;;
 870       esac
 871     fi
 872     ;;
 873   *)
 874     AC_MSG_RESULT([BSD])
 875
 876     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 877     AC_DEFINE(KAME,1,KAME IPv6)
 878     ;;
 879 esac
 880
 881 AC_SYS_LARGEFILE
 882
 883 dnl ---------------------
 884 dnl Integrated VTY option
 885 dnl ---------------------
 886 case "${enable_vtysh}" in
 887   "no") VTYSH="";;
 888   *)    VTYSH="vtysh";
 889          AC_DEFINE(VTYSH,,VTY shell)
 890 dnl      Vtysh uses libreadline, which looks for termcap functions at
 891 dnl      configure time.  We follow readlines search order.
 892 dnl      The required procedures are in libtermcap on NetBSD, in
 893 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 894          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 895            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 896              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 897                [AC_CHECK_LIB(ncurses, tputs,
 898                              LIBREADLINE="$LIBREADLINE -lncurses")]
 899               )]
 900             )]
 901           )
 902          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
 903                       "$LIBREADLINE")
 904          if test $ac_cv_lib_readline_main = no; then
 905            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 906          fi
 907          AC_CHECK_HEADER(readline/history.h)
 908          if test $ac_cv_header_readline_history_h = no;then
 909            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 910          fi
 911          AC_CHECK_LIB(readline, rl_completion_matches,
 912                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 913          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 914            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 915          fi
 916          ;;
 917 esac
 918 AC_SUBST(LIBREADLINE)
 919 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
 920
 921 dnl ----------
 922 dnl PAM module
 923 dnl
 924 dnl FRR detects the PAM library it is built against by checking for a
 925 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
 926 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
 927 dnl openpam.h doesn't do that, although depends on the header too. Hence a
 928 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
 929 dnl of OpenPAM.
 930 dnl ----------
 931 if test "$with_libpam" = "yes"; then
 932   AC_CHECK_HEADER([security/pam_misc.h],
 933     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 934      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 935      pam_conv_func="misc_conv"
 936     ],
 937     [], FRR_INCLUDES)
 938   AC_CHECK_HEADER([security/openpam.h],
 939     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 940      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 941      pam_conv_func="openpam_ttyconv"
 942     ],
 943     [], FRR_INCLUDES[#include <security/pam_appl.h>])
 944   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 945     AC_MSG_WARN([*** pam support will not be built ***])
 946     with_libpam="no"
 947   fi
 948 fi
 949
 950 if test "$with_libpam" = "yes"; then
 951 dnl took this test from proftpds configure.in and suited to our needs
 952 dnl -------------------------------------------------------------------------
 953 dnl
 954 dnl This next check looks funky due to a linker problem with some versions
 955 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 956 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 957 dnl with RedHat 6.2 and Debian 2.2 or better.
 958 AC_CHECK_LIB(pam, pam_start,
 959   [AC_CHECK_LIB(pam, $pam_conv_func,
 960     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 961      LIBPAM="-lpam"],
 962     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 963      LIBPAM="-lpam -lpam_misc"]
 964     )
 965   ],
 966
 967   [AC_CHECK_LIB(pam, pam_end,
 968     [AC_CHECK_LIB(pam, $pam_conv_func,
 969       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 970        LIBPAM="-lpam -ldl"],
 971       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 972        LIBPAM="-lpam -ldl -lpam_misc"]
 973      )
 974   ],AC_MSG_WARN([*** pam support will not be built ***]),
 975   [-ldl])
 976   ]
 977 )
 978 fi
 979 AC_SUBST(LIBPAM)
 980
 981 dnl -------------------------------
 982 dnl Endian-ness check
 983 dnl -------------------------------
 984 AC_WORDS_BIGENDIAN
 985
 986 dnl -------------------------------
 987 dnl check the size in byte of the C
 988 dnl -------------------------------
 989 dnl AC_CHECK_SIZEOF(char)
 990 dnl AC_CHECK_SIZEOF(int)
 991 dnl AC_CHECK_SIZEOF(short)
 992 dnl AC_CHECK_SIZEOF(long)
 993
 994 dnl ----------------------------
 995 dnl check existance of functions
 996 dnl ----------------------------
 997 AC_FUNC_FNMATCH
 998 AC_FUNC_FORK
 999 AC_FUNC_MKTIME
1000 AC_FUNC_STAT
1001
1002 dnl -------------------------------
1003 dnl bgpd needs pow() and hence libm
1004 dnl -------------------------------
1005 TMPLIBS="$LIBS"
1006 AC_CHECK_HEADER([math.h],
1007   [AC_CHECK_LIB([m], [pow],
1008     [LIBM="-lm"
1009      LIBS="$LIBS $LIBM"
1010      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1011     ])
1012 ])
1013 if test x"$LIBM" = x ; then
1014   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1015 fi
1016 LIBS="$TMPLIBS"
1017 AC_SUBST(LIBM)
1018
1019 AC_CHECK_FUNCS([ppoll], [
1020   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1021 ])
1022 AC_CHECK_FUNCS([pollts], [
1023   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1024 ])
1025
1026 dnl ---------------
1027 dnl other functions
1028 dnl ---------------
1029 AC_CHECK_FUNCS([ \
1030         strlcat strlcpy \
1031         getgrouplist])
1032
1033 AC_CHECK_HEADER([asm-generic/unistd.h],
1034                 [AC_CHECK_DECL(__NR_setns,
1035                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1036                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1037                                ])
1038                  AC_CHECK_FUNCS(setns)]
1039                )
1040
1041 dnl --------------------------
1042 dnl Determine IS-IS I/O method
1043 dnl --------------------------
1044 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1045 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1046 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1047 AC_CHECK_HEADER(net/bpf.h)
1048 AC_CHECK_HEADER(sys/dlpi.h)
1049 AC_MSG_CHECKING(zebra IS-IS I/O method)
1050
1051 case "$host_os" in
1052   linux*)
1053     AC_MSG_RESULT(pfpacket)
1054     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1055     ;;
1056   solaris* | sunos*)
1057     AC_MSG_RESULT(DLPI)
1058     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1059     ;;
1060   *)
1061     if test $ac_cv_header_net_bpf_h = no; then
1062       if test $ac_cv_header_sys_dlpi_h = no; then
1063         AC_MSG_RESULT(none)
1064         if test "${enable_isisd}" = yes; then
1065           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1066         fi
1067         AC_MSG_WARN([*** IS-IS support will not be built ***])
1068         enable_isisd="no"
1069       else
1070         AC_MSG_RESULT(DLPI)
1071       fi
1072       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1073     else
1074       AC_MSG_RESULT(BPF)
1075       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1076     fi
1077     ;;
1078 esac
1079 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1080
1081 dnl ------------------------------------
1082 dnl check for broken CMSG_FIRSTHDR macro
1083 dnl ------------------------------------
1084 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1085 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1086 #ifdef SUNOS_5
1087 #define _XPG4_2
1088 #define __EXTENSIONS__
1089 #endif
1090 #include <stdlib.h>
1091 #include <sys/types.h>
1092 #include <sys/socket.h>
1093
1094 main()
1095 {
1096   struct msghdr msg;
1097   char buf[4];
1098
1099   msg.msg_control = buf;
1100   msg.msg_controllen = 0;
1101
1102   if (CMSG_FIRSTHDR(&msg) != NULL)
1103     exit(0);
1104   exit (1);
1105 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1106 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1107
1108 dnl ---------------------------------------------------------------
1109 dnl figure out how to specify an interface in multicast sockets API
1110 dnl ---------------------------------------------------------------
1111 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1112
1113 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1114         #include <sys/socket.h>
1115         #include <netinet/in.h>
1116         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1117         #include <linux/types.h>
1118 ])
1119
1120 m4_define([FRR_INCLUDES],
1121 FRR_INCLUDES
1122 [#if HAVE_LINUX_MROUTE_H
1123 # include <linux/mroute.h>
1124 #endif
1125 ])dnl
1126
1127 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1128         #include <sys/socket.h>
1129         #include <sys/types.h>
1130         #include <netinet/in.h>
1131         #include <net/route.h>
1132 ])
1133
1134 m4_define([FRR_INCLUDES],
1135 FRR_INCLUDES
1136 [#if HAVE_NETINET_IP_MROUTE_H
1137 # include <netinet/ip_mroute.h>
1138 #endif
1139 ])dnl
1140
1141 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1142 AC_TRY_COMPILE([#include <sys/param.h>],
1143 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1144   return (0);
1145 #else
1146   #error No support for BSD struct ip_mreq hack detected
1147 #endif],[AC_MSG_RESULT(yes)
1148 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1149 AC_MSG_RESULT(no))
1150
1151 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1152 AC_TRY_COMPILE([
1153 #include <sys/types.h>
1154 #include <netinet/in.h>
1155 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1156 ], [AC_MSG_RESULT(yes)
1157 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1158 AC_MSG_RESULT(no))
1159
1160 dnl ---------------------------------------------------------------
1161 dnl figure out how to check link-state
1162 dnl ---------------------------------------------------------------
1163 AC_CHECK_HEADER( [net/if_media.h],
1164   [m4_define([LINK_DETECT_INCLUDES],
1165     FRR_INCLUDES
1166     [#include <net/if_media.h>
1167   ])
1168   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1169     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1170     [], LINK_DETECT_INCLUDES)],
1171   [],
1172   FRR_INCLUDES)
1173
1174 dnl ---------------------------------------------------------------
1175 dnl Additional, newer way to check link-state using ifi_link_state.
1176 dnl Not available in all BSD's when ifmediareq available
1177 dnl ---------------------------------------------------------------
1178 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1179   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1180   [], FRR_INCLUDES)
1181
1182 dnl ------------------------
1183 dnl TCP_MD5SIG socket option
1184 dnl ------------------------
1185
1186 AC_CHECK_HEADER([netinet/tcp.h],
1187    [m4_define([MD5_INCLUDES],
1188       FRR_INCLUDES
1189       [#include <netinet/tcp.h>
1190     ])
1191     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1192    [],
1193    FRR_INCLUDES)
1194 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1195   AC_CHECK_HEADER([linux/tcp.h],
1196        [m4_define([MD5_INCLUDES],
1197           FRR_INCLUDES
1198           [#include <linux/tcp.h>
1199         ])
1200        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1201 fi
1202
1203 dnl ----------------------------------------------------------------------------
1204 dnl figure out if domainname is available in the utsname struct (GNU extension).
1205 dnl ----------------------------------------------------------------------------
1206 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1207
1208 dnl ------------------
1209 dnl IPv6 header checks
1210 dnl ------------------
1211 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1212         netinet6/in6_var.h netinet6/nd6.h], [], [],
1213         FRR_INCLUDES)
1214
1215 m4_define([FRR_INCLUDES],dnl
1216 FRR_INCLUDES
1217 [#if HAVE_NETINET6_IN6_H
1218 #include <netinet6/in6.h>
1219 #endif
1220 #if HAVE_NETINET_IN6_VAR_H
1221 #include <netinet/in6_var.h>
1222 #endif
1223 #include <netinet/icmp6.h>
1224 #if HAVE_NETINET6_IN6_VAR_H
1225 # include <netinet6/in6_var.h>
1226 #endif
1227 #if HAVE_NETINET6_ND6_H
1228 # include <netinet6/nd6.h>
1229 #endif
1230 ])dnl
1231
1232 dnl disable doc check
1233 if test "${enable_doc}" = "no";then
1234   DOC=""
1235 else
1236   DOC="doc"
1237 fi
1238
1239 dnl --------------------
1240 dnl Daemon disable check
1241 dnl --------------------
1242 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1243
1244 if test "${enable_bgpd}" = "no";then
1245   BGPD=""
1246 else
1247   BGPD="bgpd"
1248 fi
1249 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1250
1251 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1252 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1253 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1254
1255 AS_IF([test "${enable_ldpd}" != "no"], [
1256   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1257 ])
1258
1259 NHRPD=""
1260 case "$host_os" in
1261   linux*)
1262     if test "${enable_nhrpd}" != "no"; then
1263       NHRPD="nhrpd"
1264     fi
1265     ;;
1266   *)
1267     if test "${enable_nhrpd}" = "yes"; then
1268       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1269     fi
1270     ;;
1271 esac
1272 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1273
1274 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1275
1276 if test "${enable_watchfrr}" = "no";then
1277   WATCHFRR=""
1278 else
1279   WATCHFRR="watchfrr"
1280 fi
1281 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1282
1283 OSPFCLIENT=""
1284 if test "${enable_ospfapi}" != "no";then
1285     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1286
1287   if test "${enable_ospfclient}" != "no";then
1288       OSPFCLIENT="ospfclient"
1289   fi
1290 fi
1291
1292 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1293 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1294 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1295 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1296 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1297
1298 case "${enable_pimd}" in
1299   "no" ) PIMD="";;
1300   *    ) PIMD="pimd";;
1301 esac
1302 AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
1303
1304 if test "${enable_bgp_announce}" = "no";then
1305   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1306 else
1307   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1308 fi
1309
1310 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1311   with_rfp_path="bgpd/rfp-example"
1312 fi
1313 if test "${with_rfp_path}" != "no"; then
1314   VNC_RFP_PATH="${with_rfp_path}"
1315   AC_SUBST(VNC_RFP_PATH)
1316 fi
1317
1318 if test "${enable_bgp_vnc}" != "no";then
1319   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1320   RFPTEST="${with_rfp_path}/rfptest"
1321   LIBRFP="${with_rfp_path}/librfp"
1322   RFPINC="${with_rfp_path}/librfp"
1323 else
1324   RFPTEST=
1325   LIBRFP=
1326   RFPINC="bgpd/rfp-example/librfp"
1327 fi
1328 # set
1329 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1330
1331 AC_SUBST(DOC)
1332 AC_SUBST(RFPTEST)
1333 AC_SUBST(LIBRFP)
1334 AC_SUBST(RFPINC)
1335 AC_SUBST(BGPD)
1336 AC_SUBST(WATCHFRR)
1337 AC_SUBST(ISISD)
1338 AC_SUBST(PIMD)
1339 AC_SUBST(SOLARIS)
1340 AC_SUBST(VTYSH)
1341 AC_SUBST(CURSES)
1342 AC_CHECK_LIB(crypt, crypt, [],
1343                     [AC_CHECK_LIB(crypto, DES_crypt)])
1344 AC_CHECK_LIB(resolv, res_init)
1345
1346 dnl ---------------------------
1347 dnl check system has PCRE regexp
1348 dnl ---------------------------
1349 if test "x$enable_pcreposix" = "xyes"; then
1350   AC_CHECK_LIB(pcreposix, regexec, [], [
1351     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1352   ])
1353 fi
1354 AC_SUBST(HAVE_LIBPCREPOSIX)
1355
1356 dnl ------------------
1357 dnl check C-Ares library
1358 dnl ------------------
1359 if test "${NHRPD}" != ""; then
1360   PKG_CHECK_MODULES([CARES], [libcares], , [
1361     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1362   ])
1363 fi
1364
1365
1366 dnl ------------------
1367 dnl check Net-SNMP library
1368 dnl ------------------
1369 if test "${enable_snmp}" != ""; then
1370    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1371    if test x"$NETSNMP_CONFIG" = x"no"; then
1372       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1373    fi
1374    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1375    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1376    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1377    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1378 int main(void);
1379 ],
1380 [
1381 {
1382   return 0;
1383 }
1384 ])], [
1385      AC_MSG_ERROR([--enable-snmp given but not usable])])
1386    case "${enable_snmp}" in
1387      yes)
1388       SNMP_METHOD=agentx
1389       ;;
1390      smux|agentx)
1391       SNMP_METHOD="${enable_snmp}"
1392       ;;
1393      *)
1394       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1395       ;;
1396    esac
1397    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1398    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1399    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1400 fi
1401 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1402 AC_SUBST(SNMP_LIBS)
1403 AC_SUBST(SNMP_CFLAGS)
1404
1405 dnl ---------------
1406 dnl math
1407 dnl ---------------
1408 AC_SEARCH_LIBS([sqrt], [m])
1409
1410 dnl ---------------
1411 dnl dlopen & dlinfo
1412 dnl ---------------
1413 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1414   AC_MSG_ERROR([unable to find the dlopen()])
1415 ])
1416
1417 AC_CHECK_HEADERS([link.h])
1418
1419 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1420 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1421 #include <stdlib.h>
1422 #ifdef HAVE_LINK_H
1423 #include <link.h>
1424 #endif
1425 #include <dlfcn.h>
1426 ]], [[
1427   char origin[1];
1428   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1429 ]])], [
1430   AC_MSG_RESULT(yes)
1431   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1432 ], [
1433   AC_MSG_RESULT(no)
1434 ])
1435
1436 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1437 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1438 #include <stdlib.h>
1439 #ifdef HAVE_LINK_H
1440 #include <link.h>
1441 #endif
1442 #include <dlfcn.h>
1443 ]], [[
1444   struct link_map *lm = NULL;
1445   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1446 ]])], [
1447   AC_MSG_RESULT(yes)
1448   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1449 ], [
1450   AC_MSG_RESULT(no)
1451 ])
1452
1453
1454 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1455
1456 dnl ---------------------------
1457 dnl sockaddr and netinet checks
1458 dnl ---------------------------
1459 AC_CHECK_TYPES([
1460         struct sockaddr_dl,
1461         struct vifctl, struct mfcctl, struct sioc_sg_req,
1462         vifi_t, struct sioc_vif_req, struct igmpmsg,
1463         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1464         struct nd_opt_adv_interval, struct rt_addrinfo,
1465         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1466         [], [], FRR_INCLUDES)
1467
1468 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1469         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1470         struct sockaddr_dl.sdl_len,
1471         struct if6_aliasreq.ifra_lifetime,
1472         struct nd_opt_adv_interval.nd_opt_ai_type],
1473         [], [], FRR_INCLUDES)
1474
1475 dnl ---------------------------
1476 dnl IRDP/pktinfo/icmphdr checks
1477 dnl ---------------------------
1478
1479 AC_CHECK_TYPES([struct in_pktinfo], [
1480   AC_CHECK_TYPES([struct icmphdr], [
1481     IRDP=true
1482   ], [
1483     IRDP=false
1484   ], [FRR_INCLUDES])
1485 ], [
1486   IRDP=false
1487 ], [FRR_INCLUDES])
1488
1489 case "${enable_irdp}" in
1490 yes)
1491   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1492   ;;
1493 no)
1494   IRDP=false
1495   ;;
1496 esac
1497
1498 AM_CONDITIONAL(IRDP, $IRDP)
1499
1500 dnl -----------------------
1501 dnl checking for IP_PKTINFO
1502 dnl -----------------------
1503 AC_MSG_CHECKING(for IP_PKTINFO)
1504 AC_TRY_COMPILE([#include <netdb.h>], [
1505   int opt = IP_PKTINFO;
1506 ], [
1507   AC_MSG_RESULT(yes)
1508   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1509 ], [
1510   AC_MSG_RESULT(no)
1511 ])
1512
1513 dnl ---------------------------
1514 dnl checking for IP_RECVDSTADDR
1515 dnl ---------------------------
1516 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1517 AC_TRY_COMPILE([#include <netinet/in.h>], [
1518   int opt = IP_RECVDSTADDR;
1519 ], [
1520   AC_MSG_RESULT(yes)
1521   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1522 ], [
1523   AC_MSG_RESULT(no)
1524 ])
1525
1526 dnl ----------------------
1527 dnl checking for IP_RECVIF
1528 dnl ----------------------
1529 AC_MSG_CHECKING(for IP_RECVIF)
1530 AC_TRY_COMPILE([#include <netinet/in.h>], [
1531   int opt = IP_RECVIF;
1532 ], [
1533   AC_MSG_RESULT(yes)
1534   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1535 ], [
1536   AC_MSG_RESULT(no)
1537 ])
1538
1539 dnl ----------------------
1540 dnl checking for SO_BINDANY
1541 dnl ----------------------
1542 AC_MSG_CHECKING(for SO_BINDANY)
1543 AC_TRY_COMPILE([#include <sys/socket.h>], [
1544   int opt = SO_BINDANY;
1545 ], [
1546   AC_MSG_RESULT(yes)
1547   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1548 ], [
1549   AC_MSG_RESULT(no)
1550 ])
1551
1552 dnl ----------------------
1553 dnl checking for IP_FREEBIND
1554 dnl ----------------------
1555 AC_MSG_CHECKING(for IP_FREEBIND)
1556 AC_TRY_COMPILE([#include <netinet/in.h>], [
1557   int opt = IP_FREEBIND;
1558 ], [
1559   AC_MSG_RESULT(yes)
1560   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1561 ], [
1562   AC_MSG_RESULT(no)
1563 ])
1564
1565 dnl --------------------------------------
1566 dnl checking for be32dec existence or not
1567 dnl --------------------------------------
1568 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1569                [#include <sys/endian.h>])
1570
1571 dnl --------------------------------------
1572 dnl checking for clock_time monotonic struct and call
1573 dnl --------------------------------------
1574 AC_CHECK_DECL(CLOCK_MONOTONIC,
1575         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1576          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1577 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1578
1579 dnl --------------------------------------
1580 dnl checking for flex and bison
1581 dnl --------------------------------------
1582
1583 AM_PROG_LEX
1584 AC_MSG_CHECKING(version of flex)
1585 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1586 frr_ac_flex_version="${frr_ac_flex_version##* }"
1587 AC_MSG_RESULT([$frr_ac_flex_version])
1588 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1589   LEX="$SHELL $missing_dir/missing flex"
1590   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1591     AC_MSG_WARN([using pregenerated flex output files])
1592   else
1593     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1594   fi
1595   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1596   AC_SUBST([LEXLIB], [''])
1597 ])
1598
1599 AC_PROG_YACC
1600 dnl thanks GNU bison for this b*llshit...
1601 AC_MSG_CHECKING(version of bison)
1602 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1603 frr_ac_bison_version="${frr_ac_bison_version##* }"
1604 frr_ac_bison_missing="false"
1605 case "x${frr_ac_bison_version}" in
1606   x2.7*)
1607     BISON_OPENBRACE='"'
1608     BISON_CLOSEBRACE='"'
1609     BISON_VERBOSE=''
1610     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1611     ;;
1612   x2.*|x1.*)
1613     AC_MSG_RESULT([$frr_ac_bison_version])
1614     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1615     frr_ac_bison_missing="true"
1616     ;;
1617   x)
1618     AC_MSG_RESULT([none])
1619     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1620     frr_ac_bison_missing="true"
1621     ;;
1622   *)
1623     BISON_OPENBRACE='{'
1624     BISON_CLOSEBRACE='}'
1625     BISON_VERBOSE='-Dparse.error=verbose'
1626     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1627     ;;
1628 esac
1629 AC_SUBST(BISON_OPENBRACE)
1630 AC_SUBST(BISON_CLOSEBRACE)
1631 AC_SUBST(BISON_VERBOSE)
1632
1633 if $frr_ac_bison_missing; then
1634   YACC="$SHELL $missing_dir/missing bison -y"
1635   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1636     AC_MSG_WARN([using pregenerated bison output files])
1637   else
1638     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1639   fi
1640 fi
1641
1642 dnl -------------------
1643 dnl capabilities checks
1644 dnl -------------------
1645 if test "${enable_capabilities}" != "no"; then
1646   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1647   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1648     [AC_MSG_RESULT(yes)
1649      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1650      frr_ac_keepcaps="yes"],
1651      AC_MSG_RESULT(no)
1652   )
1653   if test x"${frr_ac_keepcaps}" = x"yes"; then
1654     AC_CHECK_HEADERS(sys/capability.h)
1655   fi
1656   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1657     AC_CHECK_LIB(cap, cap_init,
1658       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1659        LIBCAP="-lcap"
1660        frr_ac_lcaps="yes"]
1661     )
1662   else
1663     AC_CHECK_HEADERS(priv.h,
1664      [AC_MSG_CHECKING(Solaris style privileges are available)
1665       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1666           [AC_MSG_RESULT(yes)
1667            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1668            frr_ac_scaps="yes"],
1669            AC_MSG_RESULT(no)
1670       )
1671      ]
1672    )
1673   fi
1674   if test x"${frr_ac_scaps}" = x"yes" \
1675        -o x"${frr_ac_lcaps}" = x"yes"; then
1676     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1677   fi
1678 fi
1679 AC_SUBST(LIBCAP)
1680
1681 dnl ---------------------------
1682 dnl check for glibc 'backtrace'
1683 dnl ---------------------------
1684 if test x"${enable_backtrace}" != x"no" ; then
1685   backtrace_ok=no
1686   AC_CHECK_HEADER([execinfo.h], [
1687     AC_SEARCH_LIBS([backtrace], [execinfo], [
1688       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1689       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1690       backtrace_ok=yes
1691     ],, [-lm])
1692   ])
1693
1694   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1695     dnl user explicitly requested backtrace but we failed to find support
1696     AC_MSG_FAILURE([failed to find backtrace support])
1697   fi
1698 fi
1699
1700 dnl -----------------------------------------
1701 dnl check for malloc mallinfo struct and call
1702 dnl this must try and link using LIBS, in
1703 dnl order to check no alternative allocator
1704 dnl has been specified, which might not provide
1705 dnl mallinfo, e.g. such as Umem on Solaris.
1706 dnl -----------------------------------------
1707 AC_CHECK_HEADER([malloc.h],
1708  [AC_MSG_CHECKING(whether mallinfo is available)
1709   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1710                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1711       [AC_MSG_RESULT(yes)
1712        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1713        AC_MSG_RESULT(no)
1714   )
1715  ], [], FRR_INCLUDES)
1716
1717 dnl ----------
1718 dnl configure date
1719 dnl ----------
1720 CONFDATE=`date '+%Y%m%d'`
1721 AC_SUBST(CONFDATE)
1722
1723 dnl ------------------------------
1724 dnl set paths for state directory
1725 dnl ------------------------------
1726 AC_MSG_CHECKING(directory to use for state file)
1727 if test "${prefix}" = "NONE"; then
1728   frr_statedir_prefix="";
1729 else
1730   frr_statedir_prefix=${prefix}
1731 fi
1732 if test "${localstatedir}" = '${prefix}/var'; then
1733   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1734                         ${frr_statedir_prefix}/var/adm dnl
1735                         ${frr_statedir_prefix}/etc dnl
1736                         /var/run        dnl
1737                         /var/adm        dnl
1738                         /etc            dnl
1739                         /dev/null;
1740   do
1741     test -d $FRR_STATE_DIR && break
1742   done
1743   frr_statedir=$FRR_STATE_DIR
1744 else
1745   frr_statedir=${localstatedir}
1746 fi
1747 if test $frr_statedir = "/dev/null"; then
1748     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1749 fi
1750 AC_MSG_RESULT(${frr_statedir})
1751 AC_SUBST(frr_statedir)
1752
1753 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1754 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1755 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1756
1757 dnl autoconf does this, but it does it too late...
1758 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1759 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1760
1761 dnl get the full path, recursing through variables...
1762 vtysh_bin="$bindir/vtysh"
1763 for I in 1 2 3 4 5 6 7 8 9 10; do
1764         eval vtysh_bin="\"$vtysh_bin\""
1765 done
1766 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1767
1768 CFG_SYSCONF="$sysconfdir"
1769 CFG_SBIN="$sbindir"
1770 CFG_STATE="$frr_statedir"
1771 CFG_MODULE="$moduledir"
1772 for I in 1 2 3 4 5 6 7 8 9 10; do
1773         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1774         eval CFG_SBIN="\"$CFG_SBIN\""
1775         eval CFG_STATE="\"$CFG_STATE\""
1776         eval CFG_MODULE="\"$CFG_MODULE\""
1777 done
1778 AC_SUBST(CFG_SYSCONF)
1779 AC_SUBST(CFG_SBIN)
1780 AC_SUBST(CFG_STATE)
1781 AC_SUBST(CFG_MODULE)
1782 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1783
1784 dnl ---------------------------
1785 dnl Check htonl works correctly
1786 dnl ---------------------------
1787 AC_MSG_CHECKING(for working htonl)
1788 AC_CACHE_VAL(ac_cv_htonl_works,
1789  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1790                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1791  ]
1792 )
1793 AC_MSG_RESULT($ac_cv_htonl_works)
1794
1795 AC_CONFIG_FILES([Makefile
1796           bgpd/Makefile watchfrr/Makefile
1797           vtysh/Makefile
1798           doc/Makefile tests/Makefile
1799           bgpd/rfp-example/rfptest/Makefile bgpd/rfp-example/librfp/Makefile
1800           pimd/Makefile
1801           tools/Makefile
1802           redhat/frr.spec
1803           snapcraft/snapcraft.yaml
1804           lib/version.h
1805           tests/lib/cli/test_cli.refout
1806           doc/defines.texi
1807           doc/bgpd.8
1808           doc/isisd.8
1809           doc/ospf6d.8
1810           doc/ospfclient.8
1811           doc/ospfd.8
1812           doc/ldpd.8
1813           doc/ripd.8
1814           doc/eigrpd.8
1815           doc/ripngd.8
1816           doc/pimd.8
1817           doc/nhrpd.8
1818           doc/vtysh.1
1819           doc/watchfrr.8
1820           doc/zebra.8
1821           doc/frr.1
1822           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1823           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1824           pkgsrc/eigrpd.sh])
1825
1826 if test "${enable_bgp_vnc}" != "no"; then
1827    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
1828       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
1829    fi
1830 fi
1831
1832 AC_CONFIG_FILES([solaris/Makefile])
1833
1834 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1835
1836 AC_CONFIG_COMMANDS([lib/route_types.h], [
1837         dst="${ac_abs_top_builddir}/lib/route_types.h"
1838         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1839                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1840                 > "${dst}.tmp"
1841         test -f "${dst}" \
1842                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1843                 && rm "${dst}.tmp" \
1844                 || mv "${dst}.tmp" "${dst}"
1845 ], [
1846         PERL="$PERL"
1847 ])
1848
1849 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1850     AC_CONFIG_COMMANDS([lib/gitversion.h], [
1851         dst="${ac_abs_top_builddir}/lib/gitversion.h"
1852         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1853                 "${ac_abs_top_srcdir}" \
1854                 > "${dst}.tmp"
1855         test -f "${dst}" \
1856                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1857                 && rm "${dst}.tmp" \
1858                 || mv "${dst}.tmp" "${dst}"
1859     ], [
1860         PERL="$PERL"
1861     ])
1862 ])
1863
1864 ## Hack, but working solution to avoid rebuilding of frr.info.
1865 ## It's already in CVS until texinfo 4.7 is more common.
1866 AC_OUTPUT
1867
1868 echo "
1869 FRRouting configuration
1870 ------------------------------
1871 FRR version             : ${PACKAGE_VERSION}
1872 host operating system   : ${host_os}
1873 source code location    : ${srcdir}
1874 compiler                : ${CC}
1875 compiler flags          : ${CFLAGS}
1876 make                    : ${MAKE-make}
1877 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1878 state file directory    : ${frr_statedir}
1879 config file directory   : `eval echo \`echo ${sysconfdir}\``
1880 example directory       : `eval echo \`echo ${exampledir}\``
1881 module directory        : ${CFG_MODULE}
1882 user to run as          : ${enable_user}
1883 group to run as         : ${enable_group}
1884 group for vty sockets   : ${enable_vty_group}
1885 config file mask        : ${enable_configfile_mask}
1886 log file mask           : ${enable_logfile_mask}
1887 zebra protobuf enabled  : ${have_protobuf:-no}
1888
1889 The above user and group must have read/write access to the state file
1890 directory and to the config files in the config file directory."