configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.5-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if necessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183
 184 dnl Some special handling for ICC later on
 185 if test "$CC" = "icc"; then
 186     cc_is_icc="yes"
 187 fi
 188
 189 PKG_PROG_PKG_CONFIG
 190
 191 dnl it's 2019, sed is sed.
 192 SED=sed
 193 AC_SUBST([SED])
 194
 195 dnl try and enable CFLAGS that are useful for FRR
 196 dnl - specifically, options to control warnings
 197
 198 AC_SUBST([AC_CFLAGS])
 199 AC_USE_SYSTEM_EXTENSIONS
 200 AC_DEFUN([AC_C_FLAG], [{
 201     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 202     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 203         AC_LANG_PUSH([C])
 204         ac_c_flag_save="$CFLAGS"
 205         CFLAGS="$CFLAGS $1"
 206         AC_COMPILE_IFELSE(
 207                 [AC_LANG_PROGRAM([[$4]])],
 208                 [
 209                         cachename=yes
 210                 ], [
 211                         cachename=no
 212                 ])
 213         CFLAGS="$ac_c_flag_save"
 214         AC_LANG_POP([C])
 215     ])
 216     if test "$cachename" = "yes"; then
 217         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 218     else
 219         :
 220         $2
 221     fi
 222     m4_popdef([cachename])
 223 }])
 224
 225 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 226         AC_LANG_PUSH([C])
 227         ac_cflags_save="$CFLAGS"
 228         ac_libs_save="$LIBS"
 229         CFLAGS="$CFLAGS $1"
 230         LIBS="$LIBS $2"
 231         AC_LINK_IFELSE(
 232                 [$3],
 233                 [
 234                         CFLAGS="$ac_cflags_save"
 235                         LIBS="$ac_libs_save"
 236                         m4_default([$5], [
 237                                 AC_MSG_RESULT([yes])
 238                         ])
 239                 ], [
 240                         CFLAGS="$ac_cflags_save"
 241                         LIBS="$ac_libs_save"
 242                         m4_default([$4], [
 243                                 AC_MSG_RESULT([no])
 244                         ])
 245                 ])
 246         AC_LANG_POP([C])
 247         }])
 248
 249 dnl ICC won't bail on unknown options without -diag-error 10006
 250 dnl need to do this first so we get useful results for the other options
 251 if test "$cc_is_icc" = "yes"; then
 252     AC_C_FLAG([-diag-error 10006])
 253 fi
 254
 255 dnl autoconf 2.69 AC_PROG_CC_C99 is "state of the art"
 256 dnl autoconf 2.70 AC_PROG_CC_C99 is deprecated and AC_PROC_CC tries to do C11
 257 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
 258   dnl autoconf < 2.70
 259   AC_PROG_CC_C99
 260
 261   dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 262   ac_cc="$CC"
 263   CC="${CC% -std=gnu99}"
 264   CC="${CC% -std=c99}"
 265
 266   AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 267 ], [
 268   dnl autoconf >= 2.70
 269   if test "$ac_cv_prog_cc_c11" = "no"; then
 270     AC_MSG_ERROR([ISO C11 compiler support (with GNU extensions) is required.])
 271   fi
 272 ])
 273
 274 dnl if the user has specified any CFLAGS, override our settings
 275 if test "$enable_gcov" = "yes"; then
 276    if test "$orig_cflags" = ""; then
 277       AC_C_FLAG([--coverage])
 278       AC_C_FLAG([-O0])
 279    fi
 280
 281    AC_LDFLAGS="${AC_LDFLAGS} --coverage"
 282 fi
 283
 284 if test "$enable_clang_coverage" = "yes"; then
 285    AC_C_FLAG([-fprofile-instr-generate], [
 286      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 287    ])
 288    AC_C_FLAG([-fcoverage-mapping], [
 289      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 290    ])
 291 fi
 292
 293 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 294
 295 if test "$enable_scripting" = "yes"; then
 296    AX_PROG_LUA([5.3], [5.4], [], [
 297      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 298    ])
 299    AX_LUA_HEADERS([], [
 300      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 301    ])
 302    AX_LUA_LIBS([
 303      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 304      LIBS="$LIBS $LUA_LIB"
 305      SCRIPTING=true
 306    ], [
 307      SCRIPTING=false
 308      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 309    ])
 310 fi
 311
 312 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 313 dnl sense to be overridden by the user
 314 if test "$enable_dev_build" = "yes"; then
 315    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 316    if test "$orig_cflags" = ""; then
 317       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 318       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 319       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 320    fi
 321 else
 322    if test "$orig_cflags" = ""; then
 323       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 324       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 325    fi
 326 fi
 327
 328 dnl just stick -g into LDFLAGS, if we don't have it in CFLAGS it won't do much
 329 LDFLAGS="$LDFLAGS -g"
 330
 331 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 332
 333 dnl -fms-extensions causes clang to have a built-in __wchar_t on OpenBSD,
 334 dnl which just straight up breaks compiling any code.
 335 dnl (2022-04-04 / OpenBSD 7 / clang 11.1.0)
 336 AH_VERBATIM([OpenBSD], [
 337 #ifdef __OpenBSD__
 338 #define __wchar_t __wchar_t_ignore
 339 #include <stdint.h>
 340 #undef __wchar_t
 341 #endif
 342 ])
 343
 344 dnl always want these CFLAGS
 345 AC_C_FLAG([-fms-extensions], [
 346   AC_MSG_ERROR([$CC does not support unnamed struct fields (-fms-extensions)])
 347 ])
 348 AC_C_FLAG([-fno-omit-frame-pointer])
 349 AC_C_FLAG([-funwind-tables])
 350 AC_C_FLAG([-Wall])
 351 AC_C_FLAG([-Wextra])
 352 AC_C_FLAG([-Wstrict-prototypes])
 353 AC_C_FLAG([-Wmissing-prototypes])
 354 AC_C_FLAG([-Wmissing-declarations])
 355 AC_C_FLAG([-Wpointer-arith])
 356 AC_C_FLAG([-Wbad-function-cast])
 357 AC_C_FLAG([-Wwrite-strings])
 358 AC_C_FLAG([-Wundef])
 359 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 360   AC_C_FLAG([-Wcast-qual])
 361   AC_C_FLAG([-Wmissing-noreturn])
 362   AC_C_FLAG([-Wmissing-format-attribute])
 363   AC_C_FLAG([-Wunreachable-code])
 364   AC_C_FLAG([-Wpacked])
 365   AC_C_FLAG([-Wpadded])
 366   AC_C_FLAG([-Wshadow])
 367 else
 368   AC_C_FLAG([-Wno-unused-result])
 369 fi
 370 AC_C_FLAG([-Wno-unused-parameter])
 371 AC_C_FLAG([-Wno-missing-field-initializers])
 372
 373 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 374 AC_SUBST([CXX_COMPAT_CFLAGS])
 375
 376 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 377 dnl for some reason the string consts get 'promoted' to char *,
 378 dnl triggering a const to non-const conversion warning.
 379 if test "$cc_is_icc" = "yes"; then
 380     AC_C_FLAG([-diag-disable 3179])
 381 fi
 382
 383 if test "$enable_werror" = "yes" ; then
 384   WERROR="-Werror"
 385 fi
 386 AC_SUBST([WERROR])
 387
 388 SAN_FLAGS=""
 389 if test "$enable_address_sanitizer" = "yes"; then
 390   AC_C_FLAG([-fsanitize=address], [
 391     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 392   ], [
 393     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 394   ])
 395 fi
 396 if test "$enable_thread_sanitizer" = "yes"; then
 397   AC_C_FLAG([-fsanitize=thread], [
 398     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 399   ], [
 400     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 401   ])
 402 fi
 403 if test "$enable_memory_sanitizer" = "yes"; then
 404   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 405     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 406   ], [
 407     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 408   ])
 409 fi
 410 if test "$enable_undefined_sanitizer" = "yes"; then
 411   AC_C_FLAG([-fsanitize=undefined], [
 412     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 413   ], [
 414     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 415   ])
 416 fi
 417 AC_SUBST([SAN_FLAGS])
 418
 419 dnl frr-format.so
 420 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 421   AC_C_FLAG([-fplugin=${with_frr_format}], [
 422     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 423   ],,[
 424 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 425 #error plugin not loaded
 426 #endif
 427 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 428 #error plugin too old
 429 #endif
 430   ])
 431 elif test "$with_frr_format" = "no"; then
 432   : #nothing
 433 else
 434   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 435     AC_C_FLAG([-fplugin=frr-format],[
 436       if test "$with_frr_format" = "yes"; then
 437         AC_MSG_ERROR([frr-format plugin requested but not found])
 438       fi
 439     ],,[
 440 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 441 #error plugin not loaded
 442 #endif
 443 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 444 #error plugin too old
 445 #endif
 446     ])
 447   ],,[
 448 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 449 #error plugin not loaded
 450 #endif
 451 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 452 #error plugin too old
 453 #endif
 454   ])
 455 fi
 456
 457 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 458 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 459 #include <stdio.h>
 460 int __attribute__((section("secttest"))) var = 1;
 461 extern int __start_secttest, __stop_secttest;
 462 ]], [[
 463   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 464   printf("%p %p %p\n", a, b, c);
 465 ]])], [
 466   AC_MSG_RESULT(yes)
 467   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 468 ], [
 469   AC_MSG_RESULT(no)
 470 ])
 471
 472 dnl ----------
 473 dnl Essentials
 474 dnl ----------
 475
 476 AX_PTHREAD([
 477   CC="$PTHREAD_CC"
 478   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 479   LIBS="$PTHREAD_LIBS $LIBS"
 480 ], [
 481   AC_MSG_FAILURE([This FRR version needs pthreads])
 482 ])
 483
 484 orig_cflags="$CFLAGS"
 485 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 486
 487 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 488                 [frr_cv_pthread_condattr_setclock=yes],
 489                 [frr_cv_pthread_condattr_setclock=no])
 490 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 491   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 492 fi
 493
 494 AC_CHECK_HEADERS([pthread_np.h],,, [
 495 #include <pthread.h>
 496 ])
 497 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 498
 499 CFLAGS="$orig_cflags"
 500
 501 dnl --------------
 502 dnl Check programs
 503 dnl --------------
 504 AC_PROG_INSTALL
 505 AC_PROG_LN_S
 506 AC_CHECK_TOOL([AR], [ar])
 507
 508 dnl -------
 509 dnl libtool
 510 dnl -------
 511 AC_ARG_ENABLE([static-bin],
 512   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 513 LT_INIT
 514 _LT_CONFIG_LIBTOOL([
 515   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 516     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 517 dnl the -i option is not POSIX sed and the BSDs implement it differently
 518 dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact
 519   sed -e 's%func_warning "relinking%true #\0%'                   libtool > libtool.sed && cat libtool.sed > libtool
 520   sed -e 's%func_warning "remember to run%true #\0%'             libtool > libtool.sed && cat libtool.sed > libtool
 521   sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool
 522   test -f libtool.sed && rm libtool.sed
 523 ])
 524 if test "$enable_static_bin" = "yes"; then
 525   AC_LDFLAGS_EXEC="-static"
 526   if test "$enable_static" != "yes"; then
 527     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 528   fi
 529 fi
 530 if test "$enable_shared" != "yes"; then
 531   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 532 fi
 533 AC_SUBST([AC_LDFLAGS])
 534 AC_SUBST([AC_LDFLAGS_EXEC])
 535 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 536
 537 dnl libtool, the repository of all knowledge related linkers, is too stupid to
 538 dnl correctly tell the linker how to build modules.
 539 if test -z "$module_cmds"; then
 540   module_cmds="`echo \"$archive_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 541 fi
 542 if test -z "$module_expsym_cmds"; then
 543   module_expsym_cmds="`echo \"$archive_expsym_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 544 fi
 545
 546 AC_ARG_ENABLE([rpath],
 547   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 548   [],
 549   [enable_rpath=yes])
 550
 551 dnl $AR and $RANLIB are set by LT_INIT above
 552 AC_MSG_CHECKING([whether $AR supports D option])
 553 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 554   AC_MSG_RESULT([yes])
 555   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 556   ARFLAGS="crD"
 557   AR_FLAGS="crD"
 558 else
 559   AC_MSG_RESULT([no])
 560   ARFLAGS="cru"
 561   AR_FLAGS="cru"
 562 fi
 563 AC_SUBST([ARFLAGS])
 564 AC_SUBST([AR_FLAGS])
 565
 566 AC_MSG_CHECKING([whether $RANLIB supports D option])
 567 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 568   if grep -q -- '-D' conftest.err; then
 569     AC_MSG_RESULT([no])
 570   else
 571     AC_MSG_RESULT([yes])
 572     RANLIB="$RANLIB -D"
 573   fi
 574 else
 575   AC_MSG_RESULT([no])
 576 fi
 577 AC_SUBST([RANLIB])
 578
 579 test -f conftest.err && rm conftest.err
 580 test -f conftest.a && rm conftest.a
 581
 582 dnl ----------------------
 583 dnl Packages configuration
 584 dnl ----------------------
 585 if test -f config.version; then
 586   . ./config.version
 587 elif test -f "${srcdir}/config.version"; then
 588   . "${srcdir}/config.version"
 589 fi
 590 AC_ARG_WITH([pkg-extra-version],
 591   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 592   if test "$withval" = "no"; then
 593     EXTRAVERSION=
 594   else
 595     EXTRAVERSION=$withval
 596   fi
 597 ], [])
 598 AC_ARG_WITH([pkg-git-version],
 599         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 600         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 601 AC_ARG_WITH([clippy],
 602   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 603 AC_ARG_WITH([vtysh_pager],
 604         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 605         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 606 AC_ARG_ENABLE([vtysh],
 607   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 608 AC_ARG_ENABLE([doc],
 609   AS_HELP_STRING([--disable-doc], [do not build docs]))
 610 AC_ARG_ENABLE([doc-html],
 611   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 612 AC_ARG_ENABLE([zebra],
 613   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 614 AC_ARG_ENABLE([bgpd],
 615   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 616 AC_ARG_ENABLE([ripd],
 617   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 618 AC_ARG_ENABLE([ripngd],
 619   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 620 AC_ARG_ENABLE([ospfd],
 621   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 622 AC_ARG_ENABLE([ospf6d],
 623   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 624 AC_ARG_ENABLE([ldpd],
 625   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 626 AC_ARG_ENABLE([nhrpd],
 627   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 628 AC_ARG_ENABLE([eigrpd],
 629   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 630 AC_ARG_ENABLE([babeld],
 631   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 632 AC_ARG_ENABLE([watchfrr],
 633   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 634 AC_ARG_ENABLE([isisd],
 635   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 636 AC_ARG_ENABLE([pimd],
 637   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 638 AC_ARG_ENABLE([pim6d],
 639   AS_HELP_STRING([--enable-pim6d], [build pim6d]))
 640 AC_ARG_ENABLE([pbrd],
 641   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 642 AC_ARG_ENABLE([sharpd],
 643   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 644 AC_ARG_ENABLE([staticd],
 645   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 646 AC_ARG_ENABLE([fabricd],
 647   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 648 AC_ARG_ENABLE([vrrpd],
 649   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 650 AC_ARG_ENABLE([pathd],
 651   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 652 AC_ARG_ENABLE([bgp-announce],
 653   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 654 AC_ARG_ENABLE([bgp-vnc],
 655   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 656 AC_ARG_ENABLE([bgp-bmp],
 657   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 658 AC_ARG_ENABLE([snmp],
 659   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 660 AC_ARG_ENABLE([config_rollbacks],
 661   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 662 AC_ARG_ENABLE([confd],
 663   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 664 AC_ARG_ENABLE([sysrepo],
 665   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 666 AC_ARG_ENABLE([grpc],
 667   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 668 AC_ARG_ENABLE([zeromq],
 669   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 670 AC_ARG_ENABLE([lttng],
 671   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 672 AC_ARG_ENABLE([usdt],
 673   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 674 AC_ARG_WITH([libpam],
 675   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 676 AC_ARG_ENABLE([ospfapi],
 677   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 678 AC_ARG_ENABLE([ospfclient],
 679   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 680                           (this is the default if --disable-ospfapi is set)]))
 681 AC_ARG_ENABLE([multipath],
 682   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 683 AC_ARG_WITH([service_timeout],
 684   AS_HELP_STRING([--with-service-timeout=ARG], [set service timeout value (2 minutes by default), ARG must be digit]))
 685 AC_ARG_ENABLE([user],
 686   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 687 AC_ARG_ENABLE([group],
 688   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 689 AC_ARG_ENABLE([vty_group],
 690   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 691 AC_ARG_ENABLE([configfile_mask],
 692   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 693 AC_ARG_ENABLE([logfile_mask],
 694   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 695 AC_ARG_ENABLE([shell_access],
 696   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 697 AC_ARG_ENABLE([realms],
 698   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 699 AC_ARG_ENABLE([rtadv],
 700   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 701 AC_ARG_ENABLE([irdp],
 702   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 703 AC_ARG_ENABLE([capabilities],
 704   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 705 AC_ARG_ENABLE([gcc_ultra_verbose],
 706   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 707 AC_ARG_ENABLE([backtrace],
 708   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 709 AC_ARG_ENABLE([time-check],
 710   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 711 AC_ARG_ENABLE([cpu-time],
 712   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 713 AC_ARG_ENABLE([pcreposix],
 714   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 715 AC_ARG_ENABLE([pcre2posix],
 716   AS_HELP_STRING([--enable-pcre2posix], [enable using PCRE2 Posix libs for regex functions]))
 717 AC_ARG_ENABLE([fpm],
 718   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 719 AC_ARG_ENABLE([werror],
 720   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 721 AC_ARG_ENABLE([cumulus],
 722   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 723 AC_ARG_ENABLE([datacenter],
 724   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 725 AC_ARG_ENABLE([rr-semantics],
 726   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 727 AC_ARG_ENABLE([protobuf],
 728   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 729 AC_ARG_ENABLE([oldvpn_commands],
 730   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 731 AC_ARG_ENABLE([rpki],
 732   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 733 AC_ARG_ENABLE([clippy-only],
 734   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 735 AC_ARG_ENABLE([numeric_version],
 736   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 737 AC_ARG_ENABLE([gcov],
 738   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 739 AC_ARG_ENABLE([clang_coverage],
 740   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 741 AC_ARG_ENABLE([bfdd],
 742   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 743 AC_ARG_ENABLE([address-sanitizer],
 744   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 745 AC_ARG_ENABLE([thread-sanitizer],
 746   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 747 AC_ARG_ENABLE([memory-sanitizer],
 748   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 749 AC_ARG_ENABLE([undefined-sanitizer],
 750   AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 751 AC_ARG_WITH([crypto],
 752   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 753 AC_ARG_WITH([frr-format],
 754   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 755
 756 AC_ARG_ENABLE([version-build-config],
 757   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 758
 759 #if openssl, else use the internal
 760 AS_IF([test "$with_crypto" = "openssl"], [
 761 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 762 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 763   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 764 else
 765   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 766 fi
 767 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 768 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 769 )
 770
 771 AS_IF([test "$enable_clippy_only" != "yes"], [
 772 AC_CHECK_HEADERS([json-c/json.h])
 773 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 774 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 775   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 776   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 777       AC_MSG_ERROR([libjson is needed to compile])
 778   fi
 779 fi
 780 ])
 781
 782 AC_ARG_ENABLE([dev_build],
 783     AS_HELP_STRING([--enable-dev-build], [build for development]))
 784
 785 AC_ARG_ENABLE([scripting],
 786     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 787
 788 AC_ARG_ENABLE([netlink-debug],
 789   AS_HELP_STRING([--disable-netlink-debug], [don't pretty print netlink debug messages]))
 790
 791 if test "$enable_netlink_debug" != "no" ; then
 792   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 793 fi
 794
 795 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 796
 797 if test "$enable_time_check" != "no" ; then
 798   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 799     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 800   else
 801     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 802   fi
 803 fi
 804
 805 case "${enable_cpu_time}" in
 806   "no")
 807   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 808   ;;
 809   "*")
 810   ;;
 811 esac
 812
 813 if test "$enable_rr_semantics" != "no" ; then
 814   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 815 fi
 816
 817 if test "$enable_datacenter" = "yes" ; then
 818   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 819   DFLT_NAME="datacenter"
 820 else
 821   DFLT_NAME="traditional"
 822 fi
 823
 824 if test "$enable_cumulus" = "yes" ; then
 825   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 826 fi
 827
 828 AC_SUBST([DFLT_NAME])
 829 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 830
 831 if test "$enable_shell_access" = "yes"; then
 832    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 833 fi
 834
 835 #
 836 # Python for clippy
 837 #
 838
 839 AS_IF([test "$host" = "$build"], [
 840   AM_PATH_PYTHON([3])
 841   AC_CHECK_HEADER([gelf.h], [], [
 842     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 843   ])
 844
 845   LIBS_save="$LIBS"
 846   AC_CHECK_LIB([elf], [elf_memory], [], [
 847     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 848   ])
 849
 850   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 851     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 852   ])
 853   AC_CHECK_LIB([elf], [gelf_getnote], [
 854     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 855   ])
 856   LIBS="$LIBS_save"
 857   unset LIBS_save
 858
 859   FRR_PYTHON_DEV
 860 ], [
 861   FRR_PYTHON
 862 ])
 863
 864 FRR_PYTHON_MODULES([pytest])
 865
 866 if test "$enable_doc" != "no"; then
 867   FRR_PYTHON_MODULES([sphinx], , [
 868     if test "$enable_doc" = "yes"; then
 869       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 870     fi
 871   ])
 872 fi
 873 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 874 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 875
 876 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 877   PYSPHINX="-m sphinx"
 878 ], [
 879   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 880 ])
 881 AC_SUBST([PYSPHINX])
 882
 883 #
 884 # Logic for old vpn commands support.
 885 #
 886 if test "$enable_oldvpn_commands" = "yes"; then
 887    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 888 fi
 889
 890 #
 891 # End of logic for protobuf support.
 892 #
 893
 894 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 895 if test "$enable_rtadv" != "no"; then
 896   AC_MSG_RESULT([yes])
 897   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 898 else
 899   AC_MSG_RESULT([no])
 900 fi
 901
 902 if test "$enable_user" = "no"; then
 903   enable_user=""
 904 else
 905   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 906     enable_user="frr"
 907   fi
 908   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 909 fi
 910
 911 if test "$enable_group" = "no"; then
 912   enable_group=""
 913 else
 914   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 915     enable_group="frr"
 916   fi
 917   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 918 fi
 919
 920 if test "$enable_vty_group" = "yes" ; then
 921   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 922 elif test "$enable_vty_group" != ""; then
 923   if test "$enable_vty_group" != "no"; then
 924     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 925   fi
 926 fi
 927 AC_SUBST([enable_user])
 928 AC_SUBST([enable_group])
 929 AC_SUBST([enable_vty_group])
 930
 931 enable_configfile_mask=${enable_configfile_mask:-0600}
 932 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 933 AC_SUBST([enable_configfile_mask])
 934
 935 enable_logfile_mask=${enable_logfile_mask:-0600}
 936 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 937
 938 MPATH_NUM=16
 939
 940 case "${enable_multipath}" in
 941   0)
 942     MPATH_NUM=64
 943     ;;
 944   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 945     MPATH_NUM="${enable_multipath}"
 946     ;;
 947   "")
 948     ;;
 949   *)
 950     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 951     ;;
 952 esac
 953
 954 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 955
 956 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 957
 958
 959 TIMEOUT_MIN=2
 960 case "${with_service_timeout}" in
 961   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 962     TIMEOUT_MIN="${with_service_timeout}"
 963     ;;
 964   0|"")
 965     ;;
 966   *)
 967     AC_MSG_FAILURE([Please specify digit for timeout ARG])
 968     ;;
 969 esac
 970 AC_SUBST([TIMEOUT_MIN])
 971
 972 dnl --------------------
 973 dnl Enable code coverage
 974 dnl --------------------
 975 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 976
 977 dnl ------------------------------------
 978 dnl Alpine only accepts numeric versions
 979 dnl ------------------------------------
 980 if test "$enable_numeric_version" != "" ; then
 981   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 982   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 983 fi
 984
 985 dnl -----------------------------------
 986 dnl Add extra version string to package
 987 dnl name, string and version fields.
 988 dnl -----------------------------------
 989 if test "$EXTRAVERSION" != "" ; then
 990   VERSION="${VERSION}${EXTRAVERSION}"
 991   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 992   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 993   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 994 fi
 995 AC_SUBST([EXTRAVERSION])
 996
 997 if test "$with_pkg_git_version" = "yes"; then
 998         if test -e "${srcdir}/.git"; then
 999                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
1000         else    with_pkg_git_version="no"
1001                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
1002         fi
1003 fi
1004 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
1005
1006 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
1007 if test "$OBJCOPY" != ":"; then
1008   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
1009     frr_cv_interp=""
1010     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
1011       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
1012         frr_cv_interp="`xargs -0 echo < conftest.interp`"
1013       fi
1014       test -f conftest.interp && rm conftest.interp
1015     ])
1016   ])
1017 fi
1018 if test -n "$frr_cv_interp"; then
1019   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
1020 fi
1021
1022 dnl -------------------------
1023 dnl Check other header files.
1024 dnl -------------------------
1025 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
1026         linux/version.h asm/types.h endian.h sys/endian.h])
1027
1028 ac_stdatomic_ok=false
1029 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
1030 AC_CHECK_HEADER([stdatomic.h],[
1031
1032   AC_MSG_CHECKING([whether _Atomic qualifier works])
1033   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1034 #include <stdatomic.h>
1035 int main(int argc, char **argv) {
1036   _Atomic int i = 0;
1037   return i;
1038 }
1039 ]])], [
1040     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
1041     AC_MSG_RESULT([yes])
1042     ac_stdatomic_ok=true
1043   ], [
1044     AC_MSG_RESULT([no])
1045   ])
1046 ])
1047
1048 AS_IF([$ac_stdatomic_ok], [true], [
1049   AC_MSG_CHECKING([for __atomic_* builtins])
1050   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1051 int main(int argc, char **argv) {
1052   volatile int i = 1;
1053   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1054   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1055 }
1056 ]])], [
1057     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1058     AC_MSG_RESULT([yes])
1059   ], [
1060     AC_MSG_RESULT([no])
1061
1062     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1063     AC_MSG_CHECKING([for __sync_* builtins])
1064     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1065 int main(int argc, char **argv) {
1066   volatile int i = 1;
1067   __sync_fetch_and_sub (&i, 1);
1068   return __sync_val_compare_and_swap (&i, 0, 1);
1069 }
1070 ]])], [
1071       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1072       AC_MSG_RESULT([yes])
1073
1074       AC_MSG_CHECKING([for __sync_swap builtin])
1075       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1076 int main(int argc, char **argv) {
1077   volatile int i = 1;
1078   return __sync_swap (&i, 2);
1079 }
1080 ]])], [
1081         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1082         AC_MSG_RESULT([yes])
1083       ], [
1084         AC_MSG_RESULT([no])
1085       ])
1086
1087     ], [
1088       AC_MSG_RESULT([no])
1089       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1090     ])
1091   ])
1092 ])
1093
1094 needsync=true
1095
1096 AS_IF([$needsync], [
1097   dnl Linux
1098   AC_MSG_CHECKING([for Linux futex() support])
1099   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1100 #ifndef _GNU_SOURCE
1101 #define _GNU_SOURCE
1102 #endif
1103 #include <unistd.h>
1104 #include <limits.h>
1105 #include <sys/time.h>
1106 #include <sys/syscall.h>
1107 #include <linux/futex.h>
1108
1109 int main(void);
1110 ],
1111 [
1112 {
1113   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1114 }
1115 ])], [
1116     AC_MSG_RESULT([yes])
1117     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1118     needsync=false
1119   ], [
1120     AC_MSG_RESULT([no])
1121   ])
1122 ])
1123
1124 AS_IF([$needsync], [
1125   dnl FreeBSD
1126   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1127   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1128 #include <errno.h>
1129 #include <stdlib.h>
1130 #include <sys/types.h>
1131 #include <sys/umtx.h>
1132 int main(void);
1133 ],
1134 [
1135 {
1136   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1137 }
1138 ])], [
1139     AC_MSG_RESULT([yes])
1140     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1141     needsync=false
1142   ], [
1143     AC_MSG_RESULT([no])
1144   ])
1145 ])
1146
1147 AS_IF([$needsync], [
1148   dnl OpenBSD patch (not upstream at the time of writing this)
1149   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1150   AC_MSG_CHECKING([for OpenBSD futex() support])
1151   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1152 #include <sys/futex.h>
1153 int main(void);
1154 ],
1155 [
1156 {
1157   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1158 }
1159 ])], [
1160     AC_MSG_RESULT([yes])
1161     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1162     needsync=false
1163   ], [
1164     AC_MSG_RESULT([no])
1165   ])
1166 ])
1167
1168 dnl Utility macro to avoid retyping includes all the time
1169 m4_define([FRR_INCLUDES],
1170 [#ifdef SUNOS_5
1171 #define _POSIX_C_SOURCE 200809L
1172 #define __EXTENSIONS__
1173 #endif
1174 #include <stdio.h>
1175 #include <stdlib.h>
1176 #include <stddef.h>
1177 #include <sys/types.h>
1178 /* sys/conf.h depends on param.h on FBSD at least */
1179 #include <sys/param.h>
1180 /* Required for MAXSIG */
1181 #include <signal.h>
1182 #include <sys/socket.h>
1183 #ifdef __APPLE__
1184 # define __APPLE_USE_RFC_3542
1185 #endif
1186 #include <netinet/in.h>
1187 #include <sys/time.h>
1188 #include <time.h>
1189 #include <net/if.h>
1190 ])dnl
1191
1192 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1193 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1194 dnl an additional round for it.
1195
1196 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1197
1198 m4_define([FRR_INCLUDES],
1199 FRR_INCLUDES
1200 [#ifdef HAVE_NET_IF_VAR_H
1201 # include <net/if_var.h>
1202 #endif
1203 ])dnl
1204
1205 AC_CHECK_HEADERS([netinet/in_var.h \
1206         net/if_dl.h net/netopt.h \
1207         inet/nd.h netinet/ip_icmp.h \
1208         sys/sysctl.h sys/sockio.h sys/conf.h],
1209         [], [], [FRR_INCLUDES])
1210
1211 AC_CHECK_HEADERS([ucontext.h], [], [],
1212 [#ifndef __USE_GNU
1213 #define __USE_GNU
1214 #endif /* __USE_GNU */
1215 FRR_INCLUDES
1216 ])
1217
1218 m4_define([UCONTEXT_INCLUDES],
1219 [#include <ucontext.h>])dnl
1220
1221 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1222   [], [], [UCONTEXT_INCLUDES])
1223 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1224   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1225    [], [], [UCONTEXT_INCLUDES])],
1226   [], [UCONTEXT_INCLUDES])
1227 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1228   [], [], [UCONTEXT_INCLUDES])
1229
1230 m4_define([FRR_INCLUDES],
1231 FRR_INCLUDES
1232 [
1233 #include <sys/un.h>
1234 #include <netinet/in_systm.h>
1235 #ifdef HAVE_NETINET_IN_VAR_H
1236 # include <netinet/in_var.h>
1237 #endif
1238 #ifdef HAVE_NET_IF_DL_H
1239 # include <net/if_dl.h>
1240 #endif
1241 #ifdef HAVE_NET_NETOPT_H
1242 # include <net/netopt.h>
1243 #endif
1244 #include <net/route.h>
1245 #ifdef HAVE_INET_ND_H
1246 # include <inet/nd.h>
1247 #endif
1248 #include <arpa/inet.h>
1249 /* Required for IDRP */
1250 #ifdef HAVE_NETINET_IP_ICMP_H
1251 # include <netinet/ip_icmp.h>
1252 #endif
1253 ])dnl
1254
1255 dnl V6 headers are checked below, after we check for v6
1256
1257 is_linux=false
1258
1259 AC_MSG_CHECKING([which operating system interface to use])
1260 case "$host_os" in
1261   sunos* | solaris2*)
1262     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1263     ;;
1264   linux*)
1265     AC_MSG_RESULT([Linux])
1266
1267     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1268     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1269     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1270
1271     dnl Linux has a compilation problem with mixing
1272     dnl netinet/in.h and linux/in6.h they are not
1273     dnl compatible.  There has been discussion on
1274     dnl how to fix it but no real progress on implementation
1275     dnl when they fix it, remove this
1276     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1277
1278     is_linux=true
1279     ;;
1280   openbsd*)
1281     AC_MSG_RESULT([OpenBSD])
1282
1283     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1284     AC_DEFINE([KAME], [1], [KAME IPv6])
1285     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1286     ;;
1287   *)
1288     AC_MSG_RESULT([BSD])
1289
1290     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1291     AC_DEFINE([KAME], [1], [KAME IPv6])
1292     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1293     ;;
1294 esac
1295 AM_CONDITIONAL([LINUX], [${is_linux}])
1296
1297 AC_SYS_LARGEFILE
1298
1299 dnl ------------------------
1300 dnl Integrated REALMS option
1301 dnl ------------------------
1302 if test "$enable_realms" = "yes"; then
1303     case "$host_os" in
1304       linux*)
1305        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1306        ;;
1307       *)
1308        echo "Sorry, only Linux has REALMS support"
1309        exit 1
1310        ;;
1311     esac
1312 fi
1313
1314 dnl ---------------
1315 dnl other functions
1316 dnl ---------------
1317 AC_CHECK_FUNCS([ \
1318         strlcat strlcpy \
1319         getgrouplist \
1320         openat \
1321         unlinkat \
1322         posix_fallocate \
1323         sendmmsg \
1324         explicit_bzero \
1325         ])
1326
1327 AC_CHECK_MEMBERS([struct mmsghdr.msg_hdr], [], [], FRR_INCLUDES)
1328
1329 dnl ##########################################################################
1330 dnl LARGE if block spans a lot of "configure"!
1331 if test "$enable_clippy_only" != "yes"; then
1332 dnl ##########################################################################
1333
1334 #
1335 # Logic for protobuf support.
1336 #
1337 PROTO3=false
1338 if test "$enable_protobuf" = "yes"; then
1339   # Check for protoc & protoc-c
1340
1341   # protoc is not required, it's only for a "be nice" helper target
1342   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1343
1344   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1345   if test "$PROTOC_C" = "/bin/false"; then
1346     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1347   fi
1348
1349   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1350     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1351   ])
1352
1353   PROTO3=true
1354   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1355                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1356                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1357                                             [1], [Have Protobuf version 3]),
1358                                   [PROTO3=false],
1359                                   [#include <google/protobuf-c/protobuf-c.h>])],
1360                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1361
1362   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1363 fi
1364
1365
1366 dnl ---------------------
1367 dnl Integrated VTY option
1368 dnl ---------------------
1369 case "${enable_vtysh}" in
1370 "no")
1371   VTYSH="";;
1372 *)
1373   VTYSH="vtysh";
1374   AC_DEFINE([VTYSH], [1], [VTY shell])
1375
1376   prev_libs="$LIBS"
1377   AC_CHECK_LIB([readline], [readline], [
1378     LIBREADLINE="-lreadline"
1379   ], [
1380     dnl readline failed - it might be incorrectly linked and missing its
1381     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1382     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1383       LIBREADLINE="$ac_cv_search_tputs"
1384     ], [
1385       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1386     ])
1387
1388     dnl re-try with the lib we found above
1389     unset ac_cv_lib_readline_main
1390     AC_CHECK_LIB([readline], [main], [
1391       LIBREADLINE="-lreadline $LIBREADLINE"
1392     ], [
1393       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1394     ], [$LIBREADLINE])
1395   ], [])
1396   LIBS="$LIBS -lreadline"
1397   AC_CHECK_FUNCS([rl_clear_visible_line])
1398   LIBS="$prev_libs"
1399
1400   AC_CHECK_HEADER([readline/history.h])
1401   if test "$ac_cv_header_readline_history_h" = "no"; then
1402     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1403   fi
1404   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1405   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1406     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1407   fi
1408   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1409   if test "$frr_cv_append_history" = "yes"; then
1410     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1411   fi
1412   ;;
1413 esac
1414 AC_SUBST([LIBREADLINE])
1415
1416 dnl ----------
1417 dnl PAM module
1418 dnl
1419 dnl FRR detects the PAM library it is built against by checking for a
1420 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1421 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1422 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1423 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1424 dnl of OpenPAM.
1425 dnl ----------
1426 if test "$with_libpam" = "yes"; then
1427   AC_CHECK_HEADER([security/pam_misc.h],
1428     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1429      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1430      pam_conv_func="misc_conv"
1431     ],
1432     [], FRR_INCLUDES)
1433   AC_CHECK_HEADER([security/openpam.h],
1434     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1435      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1436      pam_conv_func="openpam_ttyconv"
1437     ],
1438     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1439   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1440     AC_MSG_WARN([*** pam support will not be built ***])
1441     with_libpam="no"
1442   fi
1443 fi
1444
1445 if test "$with_libpam" = "yes"; then
1446 dnl took this test from proftpds configure.in and suited to our needs
1447 dnl -------------------------------------------------------------------------
1448 dnl
1449 dnl This next check looks funky due to a linker problem with some versions
1450 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1451 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1452 dnl with RedHat 6.2 and Debian 2.2 or better.
1453 AC_CHECK_LIB([pam], [pam_start],
1454   [AC_CHECK_LIB([pam], [$pam_conv_func],
1455     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1456      LIBPAM="-lpam"],
1457     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1458      LIBPAM="-lpam -lpam_misc"]
1459     )
1460   ],
1461
1462   [AC_CHECK_LIB([pam], [pam_end],
1463     [AC_CHECK_LIB([pam], [$pam_conv_func],
1464       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1465        LIBPAM="-lpam -ldl"],
1466       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1467        LIBPAM="-lpam -ldl -lpam_misc"]
1468      )
1469   ],AC_MSG_WARN([*** pam support will not be built ***]),
1470   [-ldl])
1471   ]
1472 )
1473 fi
1474 AC_SUBST([LIBPAM])
1475
1476 dnl -------------------------------
1477 dnl bgpd needs pow() and hence libm
1478 dnl -------------------------------
1479 TMPLIBS="$LIBS"
1480 LIBS=""
1481 AC_SEARCH_LIBS([pow], [m], [
1482   LIBM="$LIBS"
1483 ], [
1484   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1485 ])
1486 LIBS="$TMPLIBS"
1487 AC_SUBST([LIBM])
1488
1489 AC_CHECK_FUNCS([ppoll], [
1490   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1491 ])
1492 AC_CHECK_FUNCS([pollts], [
1493   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1494 ])
1495
1496 AC_CHECK_HEADER([asm-generic/unistd.h],
1497                 [AC_CHECK_DECL(__NR_setns,
1498                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1499                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1500                                ])
1501                  AC_CHECK_FUNCS([setns])]
1502                )
1503
1504 dnl --------------------------
1505 dnl Determine IS-IS I/O method
1506 dnl --------------------------
1507 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1508 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1509 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1510 AC_CHECK_HEADER([net/bpf.h])
1511 AC_CHECK_HEADER([sys/dlpi.h])
1512 AC_MSG_CHECKING([zebra IS-IS I/O method])
1513
1514 case "$host_os" in
1515   linux*)
1516     AC_MSG_RESULT([pfpacket])
1517     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1518     ;;
1519   *)
1520     if test "$ac_cv_header_net_bpf_h" = "no"; then
1521       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1522         AC_MSG_RESULT([none])
1523         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1524           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1525         fi
1526         AC_MSG_WARN([*** IS-IS support will not be built ***])
1527         enable_isisd="no"
1528         enable_fabricd="no"
1529       else
1530         AC_MSG_RESULT([DLPI])
1531       fi
1532       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1533     else
1534       AC_MSG_RESULT([BPF])
1535       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1536     fi
1537     ;;
1538 esac
1539 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1540
1541 dnl ---------------------------------------------------------------
1542 dnl figure out how to specify an interface in multicast sockets API
1543 dnl ---------------------------------------------------------------
1544 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1545
1546 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1547         #include <sys/socket.h>
1548         #include <netinet/in.h>
1549         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1550         #include <linux/types.h>
1551 ])
1552
1553 AC_CHECK_HEADERS([linux/mroute6.h], [], [],[
1554         #include <sys/socket.h>
1555         #include <netinet/in.h>
1556         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1557         #include <linux/types.h>
1558 ])
1559
1560 m4_define([FRR_INCLUDES],
1561 FRR_INCLUDES
1562 [#ifdef HAVE_LINUX_MROUTE_H
1563 # include <linux/mroute.h>
1564 #endif
1565 ])dnl
1566
1567 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1568         #include <sys/socket.h>
1569         #include <sys/types.h>
1570         #include <netinet/in.h>
1571         #include <net/route.h>
1572 ])
1573
1574 m4_define([FRR_INCLUDES],
1575 FRR_INCLUDES
1576 [#ifdef HAVE_NETINET_IP_MROUTE_H
1577 # include <netinet/ip_mroute.h>
1578 #endif
1579 ])dnl
1580
1581 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1582 AC_COMPILE_IFELSE(
1583 [ AC_LANG_PROGRAM([[
1584       #include <sys/types.h>
1585       #include <netinet/in.h>
1586   ]], [[
1587       struct group_req gr;
1588       int sock;
1589       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1590   ]])
1591 ],[
1592   AC_MSG_RESULT([yes])
1593   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1594 ],[
1595   AC_MSG_RESULT(no)
1596 ])
1597
1598 dnl ---------------------------------------------------------------
1599 dnl figure out how to check link-state
1600 dnl ---------------------------------------------------------------
1601 AC_CHECK_HEADER([net/if_media.h],
1602   [m4_define([LINK_DETECT_INCLUDES],
1603     FRR_INCLUDES
1604     [#include <net/if_media.h>
1605   ])
1606   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1607     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1608     [], LINK_DETECT_INCLUDES)],
1609   [],
1610   FRR_INCLUDES)
1611
1612 dnl ---------------------------------------------------------------
1613 dnl Additional, newer way to check link-state using ifi_link_state.
1614 dnl Not available in all BSD's when ifmediareq available
1615 dnl ---------------------------------------------------------------
1616 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1617   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1618   [], FRR_INCLUDES)
1619
1620 dnl ------------------------
1621 dnl TCP_MD5SIG socket option
1622 dnl ------------------------
1623
1624 AC_CHECK_HEADER([netinet/tcp.h],
1625    [m4_define([MD5_INCLUDES],
1626       FRR_INCLUDES
1627       [#include <netinet/tcp.h>
1628     ])
1629     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1630    [],
1631    FRR_INCLUDES)
1632 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1633   AC_CHECK_HEADER([linux/tcp.h],
1634        [m4_define([MD5_INCLUDES],
1635           FRR_INCLUDES
1636           [#include <linux/tcp.h>
1637         ])
1638        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1639 fi
1640
1641 LIBS_save="$LIBS"
1642 AC_CHECK_LIB([crypt], [crypt], [], [
1643   AC_CHECK_LIB([crypto], [DES_crypt])
1644 ])
1645 LIBCRYPT="$LIBS"
1646 LIBCRYPT="${LIBCRYPT%$LIBS_save}"
1647 LIBCRYPT="${LIBCRYPT#$LIBS_save}"
1648 AC_SUBST([LIBCRYPT])
1649 LIBS="$LIBS_save"
1650 unset LIBS_save
1651
1652 AC_CHECK_LIB([resolv], [res_init])
1653
1654 dnl ---------------------------
1655 dnl check system has PCRE regexp
1656 dnl ---------------------------
1657 if test "$enable_pcreposix" = "yes"; then
1658   AC_CHECK_LIB([pcreposix], [regexec], [], [
1659     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1660   ])
1661 fi
1662 AC_SUBST([HAVE_LIBPCREPOSIX])
1663
1664 dnl ---------------------------
1665 dnl check system has PCRE2 regexp
1666 dnl ---------------------------
1667 if test "$enable_pcre2posix" = "yes"; then
1668   AC_CHECK_LIB([pcre2-posix], [regexec], [], [
1669     AC_MSG_ERROR([--enable-pcre2posix given but unable to find libpcre2-posix])
1670   ])
1671 fi
1672 AC_SUBST([HAVE_LIBPCRE2_POSIX])
1673
1674 dnl ##########################################################################
1675 dnl test "$enable_clippy_only" != "yes"
1676 fi
1677 dnl END OF LARGE if block
1678 dnl ##########################################################################
1679
1680 dnl ------------------
1681 dnl check C-Ares library
1682 dnl ------------------
1683 PKG_CHECK_MODULES([CARES], [libcares], [
1684   c_ares_found=true
1685 ],[
1686   c_ares_found=false
1687 ])
1688 AM_CONDITIONAL([CARES], [$c_ares_found])
1689
1690
1691 dnl ----------------------------------------------------------------------------
1692 dnl figure out if domainname is available in the utsname struct (GNU extension).
1693 dnl ----------------------------------------------------------------------------
1694 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1695
1696 dnl ------------------
1697 dnl IPv6 header checks
1698 dnl ------------------
1699 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1700         netinet6/in6_var.h netinet6/nd6.h], [], [],
1701         FRR_INCLUDES)
1702
1703 m4_define([FRR_INCLUDES],dnl
1704 FRR_INCLUDES
1705 [#ifdef HAVE_NETINET6_IN6_H
1706 #include <netinet6/in6.h>
1707 #endif
1708 #ifdef HAVE_NETINET_IN6_VAR_H
1709 #include <netinet/in6_var.h>
1710 #endif
1711 #include <netinet/icmp6.h>
1712 #ifdef HAVE_NETINET6_IN6_VAR_H
1713 # include <netinet6/in6_var.h>
1714 #endif
1715 #ifdef HAVE_NETINET6_ND6_H
1716 # include <netinet6/nd6.h>
1717 #endif
1718 ])dnl
1719
1720 dnl --------------------
1721 dnl Daemon disable check
1722 dnl --------------------
1723
1724 AS_IF([test "$enable_bgpd" != "no"], [
1725   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1726 ])
1727
1728 AS_IF([test "$enable_ripd" != "no"], [
1729   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1730 ])
1731
1732 AS_IF([test "$enable_ripngd" != "no"], [
1733   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1734 ])
1735
1736 AS_IF([test "$enable_ospfd" != "no"], [
1737   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1738 ])
1739
1740 AS_IF([test "$enable_ospf6d" != "no"], [
1741   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1742 ])
1743
1744 AS_IF([test "$enable_ldpd" != "no"], [
1745   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1746 ])
1747
1748 AS_IF([test "$enable_nhrpd" != "no"], [
1749   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1750 ])
1751
1752 AS_IF([test "$enable_eigrpd" != "no"], [
1753   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1754 ])
1755
1756 AS_IF([test "$enable_babeld" != "no"], [
1757   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1758 ])
1759
1760 AS_IF([test "$enable_isisd" != "no"], [
1761   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1762 ])
1763
1764 AS_IF([test "$enable_pimd" != "no"], [
1765   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1766 ])
1767
1768 AS_IF([test "$enable_pim6d" = "yes"], [
1769   AC_DEFINE([HAVE_PIM6D], [1], [pim6d])
1770 ])
1771
1772 AS_IF([test "$enable_pbrd" != "no"], [
1773   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1774 ])
1775
1776 AS_IF([test "$enable_sharpd" = "yes"], [
1777   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1778 ])
1779
1780 AS_IF([test "$enable_staticd" != "no"], [
1781   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1782 ])
1783
1784 AS_IF([test "$enable_fabricd" != "no"], [
1785   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1786 ])
1787
1788 AS_IF([test "$enable_vrrpd" != "no"], [
1789   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1790 ])
1791
1792 if test "$enable_bfdd" = "no"; then
1793   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1794   BFDD=""
1795 else
1796   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1797   BFDD="bfdd"
1798
1799   case $host_os in
1800     linux*)
1801       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1802       ;;
1803
1804     *)
1805       AC_DEFINE([BFD_BSD], [1], [bfdd])
1806       ;;
1807   esac
1808 fi
1809
1810 AS_IF([test "$enable_pathd" != "no"], [
1811   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1812 ])
1813
1814 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1815   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1816 fi
1817
1818 NHRPD=""
1819 case "$host_os" in
1820   linux*)
1821     case "${enable_nhrpd}" in
1822       no)
1823         ;;
1824       yes)
1825         if test "$enable_clippy_only" != "yes"; then
1826         if test "$c_ares_found" != "true" ; then
1827           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1828         fi
1829         fi
1830         NHRPD="nhrpd"
1831         ;;
1832       *)
1833         if test "$c_ares_found" = "true" ; then
1834           NHRPD="nhrpd"
1835         fi
1836         ;;
1837     esac
1838     ;;
1839   *)
1840     if test "$enable_nhrpd" = "yes"; then
1841       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1842     fi
1843     ;;
1844 esac
1845
1846 if test "$enable_watchfrr" = "no";then
1847   WATCHFRR=""
1848 else
1849   WATCHFRR="watchfrr"
1850 fi
1851
1852 OSPFCLIENT=""
1853 if test "$enable_ospfapi" != "no";then
1854     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1855
1856   if test "$enable_ospfclient" != "no";then
1857       OSPFCLIENT="ospfclient"
1858   fi
1859 fi
1860
1861 if test "$enable_bgp_announce" = "no";then
1862   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1863 else
1864   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1865 fi
1866
1867 if test "$enable_bgp_vnc" != "no";then
1868   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1869 fi
1870
1871 bgpd_bmp=false
1872 case "${enable_bgp_bmp}" in
1873   no)
1874     ;;
1875   yes)
1876     if test "$c_ares_found" != "true" ; then
1877       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1878     fi
1879     bgpd_bmp=true
1880     ;;
1881   *)
1882     if test "$c_ares_found" = "true" ; then
1883       bgpd_bmp=true
1884     fi
1885     ;;
1886 esac
1887
1888 if test "$enable_version_build_config" != "no";then
1889   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1890 fi
1891
1892 dnl ##########################################################################
1893 dnl LARGE if block
1894 if test "$enable_clippy_only" != "yes"; then
1895 dnl ##########################################################################
1896
1897 dnl ------------------
1898 dnl check Net-SNMP library
1899 dnl ------------------
1900 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1901    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1902    if test "$NETSNMP_CONFIG" = "no"; then
1903       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1904    fi
1905    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1906    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1907    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1908    # among other things we avoid a GPL vs. OpenSSL license conflict here
1909    for removelib in crypto ssl sensors pci wrap; do
1910      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1911    done
1912    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1913    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1914 int main(void);
1915 ],
1916 [
1917 {
1918   return 0;
1919 }
1920 ])], [
1921      AC_MSG_RESULT([no])
1922      AC_MSG_ERROR([--enable-snmp given but not usable])])
1923    case "${enable_snmp}" in
1924      yes)
1925       SNMP_METHOD=agentx
1926       ;;
1927      agentx)
1928       SNMP_METHOD="${enable_snmp}"
1929       ;;
1930      *)
1931       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1932       ;;
1933    esac
1934    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1935    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1936 fi
1937 AC_SUBST([SNMP_LIBS])
1938 AC_SUBST([SNMP_CFLAGS])
1939
1940 dnl ---------------
1941 dnl libyang
1942 dnl ---------------
1943 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1944   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1945 ])
1946 ac_cflags_save="$CFLAGS"
1947 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1948 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1949   AC_MSG_ERROR([m4_normalize([
1950     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1951     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1952   ])
1953 ], [[#include <libyang/libyang.h>]])
1954 CFLAGS="$ac_cflags_save"
1955
1956 dnl ---------------
1957 dnl configuration rollbacks
1958 dnl ---------------
1959 SQLITE3=false
1960 if test "$enable_config_rollbacks" = "yes"; then
1961   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1962     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1963     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1964     SQLITE3=true
1965   ], [
1966     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1967   ])
1968 fi
1969
1970 dnl ---------------
1971 dnl confd
1972 dnl ---------------
1973 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1974    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1975    if test "$CONFD" = "/bin/false"; then
1976       AC_MSG_ERROR([confd was not found on your system.])]
1977    fi
1978    AC_CHECK_PROG([CONFDC], [confdc], [confdc], [/bin/false], "${enable_confd}/bin")
1979    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1980    AC_SUBST([CONFD_CFLAGS])
1981    CONFD_LIBS="-lconfd"
1982    AC_SUBST([CONFD_LIBS])
1983    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1984 fi
1985
1986 dnl ---------------
1987 dnl sysrepo
1988 dnl ---------------
1989 if test "$enable_sysrepo" = "yes"; then
1990   PKG_CHECK_MODULES([SYSREPO], [sysrepo >= 2.1.42],
1991       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1992       SYSREPO=true],
1993       [SYSREPO=false
1994       AC_MSG_ERROR([sysrepo was not found on your system.])]
1995   )
1996 fi
1997
1998 dnl ---------------
1999 dnl gRPC
2000 dnl ---------------
2001 if test "$enable_grpc" = "yes"; then
2002   AC_LANG_PUSH([C++])
2003   AX_CXX_COMPILE_STDCXX([11], [ext])
2004   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
2005     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
2006     if test "$PROTOC" = "/bin/false"; then
2007       AC_MSG_FAILURE([grpc requested but protoc not found.])
2008     fi
2009
2010     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
2011     GRPC=true
2012   ], [
2013     GRPC=false
2014     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
2015   ])
2016   AC_LANG_POP([C++])
2017 fi
2018
2019 dnl ---------
2020 dnl DPDK
2021 dnl ---------
2022 if test "$enable_dp_dpdk" = "yes"; then
2023   PKG_CHECK_MODULES([DPDK], [libdpdk], [
2024     AC_DEFINE([HAVE_DPDK], [1], [Enable DPDK backend])
2025     DPDK=true
2026   ], [
2027     AC_MSG_ERROR([configuration specifies --enable-dp-dpdk but DPDK libs were not found])
2028   ])
2029 fi
2030
2031 dnl -----
2032 dnl LTTng
2033 dnl -----
2034 if test "$enable_lttng" = "yes"; then
2035   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.9.0], [
2036     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
2037     LTTNG=true
2038   ], [
2039     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
2040   ])
2041 fi
2042
2043 dnl ----
2044 dnl USDT
2045 dnl ----
2046 if test "$enable_usdt" = "yes"; then
2047   AC_CHECK_HEADERS([sys/sdt.h], [
2048     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
2049     USDT=true
2050   ], [
2051     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
2052   ])
2053 fi
2054
2055 dnl ------
2056 dnl ZeroMQ
2057 dnl ------
2058 if test "$enable_zeromq" != "no"; then
2059   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2060     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2061     ZEROMQ=true
2062   ], [
2063     if test "$enable_zeromq" = "yes"; then
2064       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2065     fi
2066   ])
2067 fi
2068
2069 dnl ------------------------------------
2070 dnl Enable RPKI and add librtr to libs
2071 dnl ------------------------------------
2072 if test "$enable_rpki" = "yes"; then
2073   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.8.0],
2074       [RPKI=true],
2075       [RPKI=false
2076       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2077   )
2078 fi
2079
2080 dnl ------------------------------------
2081 dnl pimd is not supported on OpenBSD and MacOS
2082 dnl ------------------------------------
2083 if test "$enable_pimd" != "no"; then
2084 AC_MSG_CHECKING([for pimd OS support])
2085 case "$host_os" in
2086   darwin*)
2087     AC_MSG_RESULT([no])
2088     enable_pimd="no"
2089     ;;
2090   openbsd*)
2091     AC_MSG_RESULT([no])
2092     enable_pimd="no"
2093     ;;
2094   *)
2095     AC_MSG_RESULT([yes])
2096     ;;
2097 esac
2098 fi
2099
2100 dnl -------------------------------------
2101 dnl VRRP is only supported on linux
2102 dnl -------------------------------------
2103 if test "$enable_vrrpd" != "no"; then
2104 AC_MSG_CHECKING([for VRRP OS support])
2105 case "$host_os" in
2106   linux*)
2107     AC_MSG_RESULT([yes])
2108     ;;
2109   *)
2110     AC_MSG_RESULT([no])
2111     enable_vrrpd="no"
2112     ;;
2113 esac
2114 fi
2115
2116 dnl ------------------------------------------
2117 dnl Check whether rtrlib was build with ssh support
2118 dnl ------------------------------------------
2119 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2120 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2121                         [[struct tr_ssh_config config;]])],
2122         [AC_MSG_RESULT([yes])
2123         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2124         AC_MSG_RESULT([no])
2125 )
2126
2127 dnl ---------------
2128 dnl dlopen & dlinfo
2129 dnl ---------------
2130 LIBS_save="$LIBS"
2131 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2132   AC_MSG_ERROR([unable to find the dlopen()])
2133 ])
2134
2135 AC_CHECK_HEADERS([link.h])
2136
2137 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2138   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2139 #include <stdlib.h>
2140 #ifdef HAVE_LINK_H
2141 #include <link.h>
2142 #endif
2143 #include <dlfcn.h>
2144 ]], [[
2145   char origin[1];
2146   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2147 ]])], [
2148     frr_cv_rtld_di_origin=yes
2149   ], [
2150     frr_cv_rtld_di_origin=no
2151   ])
2152 ])
2153 if test "$frr_cv_rtld_di_origin" = "yes"; then
2154   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2155 fi
2156
2157 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2158   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2159 #include <stdlib.h>
2160 #ifdef HAVE_LINK_H
2161 #include <link.h>
2162 #endif
2163 #include <dlfcn.h>
2164 ]], [[
2165   struct link_map *lm = NULL;
2166   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2167 ]])], [
2168     frr_cv_rtld_di_linkmap=yes
2169   ], [
2170     frr_cv_rtld_di_linkmap=no
2171   ])
2172 ])
2173 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2174   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2175 fi
2176
2177 LIBDL="$LIBS"
2178 LIBDL="${LIBDL%$LIBS_save}"
2179 LIBDL="${LIBDL#$LIBS_save}"
2180 AC_SUBST([LIBDL])
2181 LIBS="$LIBS_save"
2182 unset LIBS_save
2183
2184 dnl ##########################################################################
2185 dnl test "$enable_clippy_only" != "yes"
2186 fi
2187 dnl END OF LARGE if block
2188 dnl ##########################################################################
2189
2190 dnl ---------------------------
2191 dnl sockaddr and netinet checks
2192 dnl ---------------------------
2193 AC_CHECK_TYPES([
2194         struct sockaddr_dl,
2195         struct vifctl, struct mfcctl, struct sioc_sg_req,
2196         vifi_t, struct sioc_vif_req, struct igmpmsg,
2197         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2198         struct nd_opt_adv_interval,
2199         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2200         struct nd_opt_rdnss, struct nd_opt_dnssl],
2201         [], [], FRR_INCLUDES)
2202
2203 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2204         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2205         struct sockaddr_dl.sdl_len,
2206         struct if6_aliasreq.ifra_lifetime,
2207         struct nd_opt_adv_interval.nd_opt_ai_type],
2208         [], [], FRR_INCLUDES)
2209
2210 dnl ---------------------------
2211 dnl IRDP/pktinfo/icmphdr checks
2212 dnl ---------------------------
2213
2214 AC_CHECK_TYPES([struct in_pktinfo], [
2215   AC_CHECK_TYPES([struct icmphdr], [
2216     IRDP=true
2217   ], [
2218     IRDP=false
2219   ], [FRR_INCLUDES])
2220 ], [
2221   IRDP=false
2222 ], [FRR_INCLUDES])
2223
2224 case "${enable_irdp}" in
2225 yes)
2226   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2227   ;;
2228 no)
2229   IRDP=false
2230   ;;
2231 esac
2232
2233
2234 dnl -----------------------
2235 dnl checking for IP_PKTINFO
2236 dnl -----------------------
2237 AC_MSG_CHECKING([for IP_PKTINFO])
2238 AC_COMPILE_IFELSE(
2239 [ AC_LANG_PROGRAM([[
2240         #include <netdb.h>
2241    ]], [[
2242         int opt = IP_PKTINFO;
2243    ]])
2244 ],[
2245   AC_MSG_RESULT([yes])
2246   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2247 ],[
2248   AC_MSG_RESULT([no])
2249 ])
2250
2251 dnl ---------------------------
2252 dnl checking for IP_RECVDSTADDR
2253 dnl ---------------------------
2254 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2255 AC_COMPILE_IFELSE(
2256 [ AC_LANG_PROGRAM([[
2257         #include <netinet/in.h>
2258   ]], [[
2259         int opt = IP_RECVDSTADDR;
2260   ]])
2261 ],[
2262   AC_MSG_RESULT([yes])
2263   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2264 ],[
2265   AC_MSG_RESULT([no])
2266 ])
2267
2268 dnl ----------------------
2269 dnl checking for IP_RECVIF
2270 dnl ----------------------
2271 AC_MSG_CHECKING([for IP_RECVIF])
2272 AC_COMPILE_IFELSE(
2273 [ AC_LANG_PROGRAM([[
2274         #include <netinet/in.h>
2275   ]], [[
2276         int opt = IP_RECVIF;
2277   ]])
2278 ],[
2279   AC_MSG_RESULT([yes])
2280   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2281 ],[
2282   AC_MSG_RESULT([no])
2283 ])
2284
2285 dnl ----------------------
2286 dnl checking for SO_BINDANY
2287 dnl ----------------------
2288 AC_MSG_CHECKING([for SO_BINDANY])
2289 AC_COMPILE_IFELSE(
2290 [ AC_LANG_PROGRAM([[
2291         #include <sys/socket.h>
2292   ]], [[
2293         int opt = SO_BINDANY;
2294   ]])
2295 ],[
2296   AC_MSG_RESULT([yes])
2297   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2298 ],[
2299   AC_MSG_RESULT([no])
2300 ])
2301
2302 dnl ----------------------
2303 dnl checking for IP_FREEBIND
2304 dnl ----------------------
2305 AC_MSG_CHECKING([for IP_FREEBIND])
2306 AC_COMPILE_IFELSE(
2307 [ AC_LANG_PROGRAM([[
2308         #include <netinet/in.h>
2309   ]], [[
2310         int opt = IP_FREEBIND;
2311   ]])
2312 ],[
2313   AC_MSG_RESULT([yes])
2314   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2315 ],[
2316   AC_MSG_RESULT([no])
2317 ])
2318
2319 dnl --------------------------------------
2320 dnl checking for be32dec existence or not
2321 dnl --------------------------------------
2322 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2323         #ifdef HAVE_SYS_ENDIAN_H
2324         #include <sys/endian.h>
2325         #endif
2326         #ifdef HAVE_ENDIAN_H
2327         #include <endian.h>
2328         #endif
2329 ])
2330
2331 dnl --------------------------------------
2332 dnl checking for clock_time monotonic struct and call
2333 dnl --------------------------------------
2334 AC_CHECK_DECL([CLOCK_MONOTONIC],
2335         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2336          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2337 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2338
2339 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2340          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2341 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2342
2343 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2344   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2345 ])
2346
2347 dnl --------------------------------------
2348 dnl checking for flex and bison
2349 dnl --------------------------------------
2350
2351 dnl autoconf 2.69 AC_PROG_LEX has no parameters
2352 dnl autoconf 2.70 AC_PROG_LEX prints a deprecation warning without params
2353 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
2354   dnl autoconf < 2.70
2355   AC_PROG_LEX
2356 ], [
2357   dnl autoconf >= 2.70
2358   AC_PROG_LEX([noyywrap])
2359 ])
2360
2361 AC_MSG_CHECKING([version of flex])
2362 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2363 frr_ac_flex_version="${frr_ac_flex_version##* }"
2364 AC_MSG_RESULT([$frr_ac_flex_version])
2365 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2366   LEX="$SHELL $missing_dir/missing flex"
2367   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2368     AC_MSG_WARN([using pregenerated flex output files])
2369   else
2370     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2371   fi
2372   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2373   AC_SUBST([LEXLIB], [''])
2374 ])
2375
2376 AC_PROG_YACC
2377 dnl thanks GNU bison for this b*llshit...
2378 AC_MSG_CHECKING([version of bison])
2379 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2380 frr_ac_bison_version="${frr_ac_bison_version##* }"
2381 frr_ac_bison_missing="false"
2382 case "x${frr_ac_bison_version}x" in
2383   x2.7*)
2384     BISON_OPENBRACE='"'
2385     BISON_CLOSEBRACE='"'
2386     BISON_VERBOSE=''
2387     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2388     ;;
2389   x2.*|x1.*)
2390     AC_MSG_RESULT([$frr_ac_bison_version])
2391     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2392     frr_ac_bison_missing="true"
2393     ;;
2394   x)
2395     AC_MSG_RESULT([none])
2396     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2397     frr_ac_bison_missing="true"
2398     ;;
2399   x3.[012][^0-9]*)
2400     BISON_OPENBRACE='{'
2401     BISON_CLOSEBRACE='}'
2402     BISON_VERBOSE='-Dparse.error=verbose'
2403     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2404     ;;
2405   *)
2406     BISON_OPENBRACE='{'
2407     BISON_CLOSEBRACE='}'
2408     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2409     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2410     ;;
2411 esac
2412 AC_SUBST([BISON_OPENBRACE])
2413 AC_SUBST([BISON_CLOSEBRACE])
2414 AC_SUBST([BISON_VERBOSE])
2415
2416 if $frr_ac_bison_missing; then
2417   YACC="$SHELL $missing_dir/missing bison -y"
2418   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2419     AC_MSG_WARN([using pregenerated bison output files])
2420   else
2421     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2422   fi
2423 fi
2424
2425 dnl -------------------
2426 dnl capabilities checks
2427 dnl -------------------
2428 if test "$enable_capabilities" != "no"; then
2429   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2430   AC_COMPILE_IFELSE(
2431   [ AC_LANG_PROGRAM([[
2432         #include <sys/prctl.h>
2433     ]], [[
2434         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2435     ]])
2436   ],[AC_MSG_RESULT([yes])
2437      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2438      frr_ac_keepcaps="yes"
2439   ],[AC_MSG_RESULT(no)
2440   ])
2441   if test "$frr_ac_keepcaps" = "yes"; then
2442     AC_CHECK_HEADERS([sys/capability.h])
2443   fi
2444   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2445     AC_CHECK_LIB([cap], [cap_init],
2446       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2447        LIBCAP="-lcap"
2448        frr_ac_lcaps="yes"]
2449     )
2450   fi
2451   if test "$frr_ac_scaps" = "yes" \
2452        -o "$frr_ac_lcaps" = "yes"; then
2453     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2454   fi
2455
2456   case "$host_os" in
2457   linux*)
2458     if test "$enable_clippy_only" != "yes"; then
2459     if test "$frr_ac_lcaps" != "yes"; then
2460       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2461     fi
2462     fi
2463     ;;
2464   esac
2465 else
2466   case "$host_os" in
2467   linux*)
2468     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2469     ;;
2470   esac
2471 fi
2472 AC_SUBST([LIBCAP])
2473
2474 dnl ---------------------------
2475 dnl check for glibc 'backtrace'
2476 dnl ---------------------------
2477 if test "$enable_backtrace" != "no" ; then
2478   backtrace_ok=no
2479   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2480     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2481     backtrace_ok=yes
2482   ], [
2483     true
2484   ])
2485
2486   if test "$backtrace_ok" = "no"; then
2487     AC_CHECK_HEADER([unwind.h], [
2488       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2489         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2490         backtrace_ok=yes
2491       ])
2492     ])
2493   fi
2494
2495   if test "$backtrace_ok" = "no"; then
2496     AC_CHECK_HEADER([execinfo.h], [
2497       AC_SEARCH_LIBS([backtrace], [execinfo], [
2498         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2499         backtrace_ok=yes
2500       ],, [-lm])
2501     ])
2502   fi
2503
2504   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2505     dnl user explicitly requested backtrace but we failed to find support
2506     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2507   fi
2508 fi
2509
2510 dnl -----------------------------------------
2511 dnl check for malloc mallinfo struct and call
2512 dnl this must try and link using LIBS, in
2513 dnl order to check no alternative allocator
2514 dnl has been specified, which might not provide
2515 dnl mallinfo
2516 dnl -----------------------------------------
2517 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2518
2519 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2520   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2521 #ifdef HAVE_MALLOC_H
2522 #include <malloc.h>
2523 #endif
2524 #ifdef HAVE_MALLOC_NP_H
2525 #include <malloc_np.h>
2526 #endif
2527 #ifdef HAVE_MALLOC_MALLOC_H
2528 #include <malloc/malloc.h>
2529 #endif
2530 ]], [[
2531 struct mallinfo ac_x; ac_x = mallinfo ();
2532 ]])], [
2533     frr_cv_mallinfo=yes
2534   ], [
2535     frr_cv_mallinfo=no
2536   ])
2537 ])
2538 if test "$frr_cv_mallinfo" = "yes"; then
2539   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2540 fi
2541
2542 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2543   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2544 #ifdef HAVE_MALLOC_H
2545 #include <malloc.h>
2546 #endif
2547 #ifdef HAVE_MALLOC_NP_H
2548 #include <malloc_np.h>
2549 #endif
2550 #ifdef HAVE_MALLOC_MALLOC_H
2551 #include <malloc/malloc.h>
2552 #endif
2553 ]], [[
2554 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2555 ]])], [
2556     frr_cv_mallinfo2=yes
2557   ], [
2558     frr_cv_mallinfo2=no
2559   ])
2560 ])
2561 if test "$frr_cv_mallinfo2" = "yes"; then
2562   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2563 fi
2564
2565 AC_MSG_CHECKING([whether malloc_usable_size is available])
2566 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2567 #ifdef HAVE_MALLOC_H
2568 #include <malloc.h>
2569 #endif
2570 #ifdef HAVE_MALLOC_MALLOC_H
2571 #include <malloc/malloc.h>
2572 #endif
2573 ]], [[
2574 size_t ac_x; ac_x = malloc_usable_size(NULL);
2575 ]])], [
2576   AC_MSG_RESULT([yes])
2577   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2578 ], [
2579   AC_MSG_RESULT([no])
2580
2581   AC_MSG_CHECKING([whether malloc_size is available])
2582   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2583 #ifdef HAVE_MALLOC_H
2584 #include <malloc.h>
2585 #endif
2586 #ifdef HAVE_MALLOC_MALLOC_H
2587 #include <malloc/malloc.h>
2588 #endif
2589 ]], [[
2590 size_t ac_x; ac_x = malloc_size(NULL);
2591 ]])], [
2592     AC_MSG_RESULT([yes])
2593     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2594   ], [
2595     AC_MSG_RESULT([no])
2596   ])
2597 ])
2598
2599 dnl ----------
2600 dnl configure date
2601 dnl ----------
2602 dev_version=`echo $VERSION | grep dev`
2603 #don't expire deprecated code in non 'dev' branch
2604 if test "$dev_version" = ""; then
2605    CONFDATE=0
2606 else
2607    CONFDATE=`date '+%Y%m%d'`
2608 fi
2609 AC_SUBST([CONFDATE])
2610
2611 dnl ------------------------------
2612 dnl set paths for state directory
2613 dnl ------------------------------
2614 AC_MSG_CHECKING([directory to use for state file])
2615 if test "$prefix" = "NONE"; then
2616   frr_statedir_prefix="";
2617 else
2618   frr_statedir_prefix=${prefix}
2619 fi
2620 if test "$localstatedir" = '${prefix}/var'; then
2621   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2622                         ${frr_statedir_prefix}/var/adm dnl
2623                         ${frr_statedir_prefix}/etc dnl
2624                         /var/run        dnl
2625                         /var/adm        dnl
2626                         /etc            dnl
2627                         /dev/null;
2628   do
2629     test -d $FRR_STATE_DIR && break
2630   done
2631   frr_statedir=$FRR_STATE_DIR
2632 else
2633   frr_statedir=${localstatedir}
2634 fi
2635 if test "$frr_statedir" = "/dev/null"; then
2636     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2637 fi
2638 AC_MSG_RESULT([${frr_statedir}])
2639 AC_SUBST([frr_statedir])
2640
2641 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2642 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2643 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2644 AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information])
2645 AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information])
2646 AC_DEFINE_UNQUOTED([ISISD_RESTART], ["$frr_statedir%s/isid-restart.json"], [isisd restart information])
2647 AC_DEFINE_UNQUOTED([OSPF6_AUTH_SEQ_NUM_FILE], ["$frr_statedir/ospf6d-at-seq-no.dat"], [ospf6d AT Sequence number information])
2648 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2649 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2650
2651 dnl autoconf does this, but it does it too late...
2652 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2653 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2654
2655 dnl get the full path, recursing through variables...
2656 vtysh_bin="$bindir/vtysh"
2657 for I in 1 2 3 4 5 6 7 8 9 10; do
2658         eval vtysh_bin="\"$vtysh_bin\""
2659 done
2660 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2661 AC_SUBST([vtysh_bin])
2662
2663 CFG_SYSCONF="$sysconfdir"
2664 CFG_SBIN="$sbindir"
2665 CFG_STATE="$frr_statedir"
2666 CFG_MODULE="$moduledir"
2667 CFG_YANGMODELS="$yangmodelsdir"
2668 CFG_SCRIPT="$scriptdir"
2669 for I in 1 2 3 4 5 6 7 8 9 10; do
2670         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2671         eval CFG_SBIN="\"$CFG_SBIN\""
2672         eval CFG_STATE="\"$CFG_STATE\""
2673         eval CFG_MODULE="\"$CFG_MODULE\""
2674         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2675         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2676 done
2677 AC_SUBST([CFG_SYSCONF])
2678 AC_SUBST([CFG_SBIN])
2679 AC_SUBST([CFG_STATE])
2680 AC_SUBST([CFG_MODULE])
2681 AC_SUBST([CFG_SCRIPT])
2682 AC_SUBST([CFG_YANGMODELS])
2683 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2684 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2685 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2686 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2687
2688 dnl various features
2689 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2690 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2691 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2692 dnl northbound
2693 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2694 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2695 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2696 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2697 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2698 dnl plugins
2699 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2700 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2701 AM_CONDITIONAL([IRDP], [$IRDP])
2702 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2703 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2704 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2705
2706 dnl PCEP plugin
2707 AS_IF([test "$enable_pathd" != "no"], [
2708        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2709        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2710        ])
2711 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2712 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2713 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2714 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2715
2716 dnl daemons
2717 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2718 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2719 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2720 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2721 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2722 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2723 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2724 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2725 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2726 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2727 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2728 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2729 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2730 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2731 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2732 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2733 AM_CONDITIONAL([PIM6D], [test "$enable_pim6d" = "yes"])
2734 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2735 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2736 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2737 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2738 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2739 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2740 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2741 AM_CONDITIONAL([DP_DPDK], [test "$enable_dp_dpdk" = "yes"])
2742
2743 AC_CONFIG_FILES([Makefile],[
2744         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2745         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2746 ], [
2747         PYTHON="$PYTHON"
2748         enable_dev_build="$enable_dev_build"
2749 ])
2750
2751 AC_CONFIG_FILES([
2752           config.version
2753           redhat/frr.spec
2754           alpine/APKBUILD
2755           snapcraft/snapcraft.yaml
2756           lib/version.h
2757           tests/lib/cli/test_cli.refout
2758           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2759           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2760           pkgsrc/eigrpd.sh])
2761
2762 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2763 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2764 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2765 AC_CONFIG_FILES([tools/frrcommon.sh])
2766 AC_CONFIG_FILES([tools/frr.service])
2767 AC_CONFIG_FILES([tools/frr@.service])
2768
2769 AS_IF([test "$with_pkg_git_version" = "yes"], [
2770     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2771         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2772         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2773                 "${ac_abs_top_srcdir}" \
2774                 > "${dst}.tmp"
2775         test -f "$dst" \
2776                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2777                 && rm "${dst}.tmp" \
2778                 || mv "${dst}.tmp" "${dst}"
2779     ], [
2780         PERL="$PERL"
2781     ])
2782 ])
2783
2784 ## Hack, but working solution to avoid rebuilding of frr.info.
2785 ## It's already in CVS until texinfo 4.7 is more common.
2786 AC_OUTPUT
2787
2788 if test "$enable_rpath" = "yes" ; then
2789         true
2790 else
2791         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2792         sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool
2793         sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g'         libtool > libtool.sed && cat libtool.sed > libtool
2794         test -f libtool.sed && rm libtool.sed
2795 fi
2796
2797 echo "
2798 FRRouting configuration
2799 ------------------------------
2800 FRR version             : ${PACKAGE_VERSION}
2801 host operating system   : ${host_os}
2802 source code location    : ${srcdir}
2803 compiler                : ${CC}
2804 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2805 make                    : ${MAKE-make}
2806 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2807 state file directory    : ${frr_statedir}
2808 config file directory   : `eval echo \`echo ${sysconfdir}\``
2809 module directory        : ${CFG_MODULE}
2810 script directory        : ${CFG_SCRIPT}
2811 user to run as          : ${enable_user}
2812 group to run as         : ${enable_group}
2813 group for vty sockets   : ${enable_vty_group}
2814 config file mask        : ${enable_configfile_mask}
2815 log file mask           : ${enable_logfile_mask}
2816 zebra protobuf enabled  : ${enable_protobuf:-no}
2817 vici socket path        : ${vici_socket}
2818
2819 The above user and group must have read/write access to the state file
2820 directory and to the config files in the config file directory."
2821
2822 if test -n "$enable_datacenter"; then
2823   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2824 fi
2825 if test -n "$enable_time_check"; then
2826   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2827 fi
2828 if test -n "$enable_cpu_time"; then
2829   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2830 fi
2831
2832 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2833   AC_MSG_WARN([sphinx is missing but required to build documentation])
2834 fi
2835 if test "$frr_py_mod_pytest" = "false"; then
2836   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2837 fi