configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 4.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl AddressSanitizer support
 189 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 190               [enabled AddressSanitizer support for detecting a wide variety of \
 191                memory allocation and deallocation errors]), \
 192               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 193               CFLAGS="$CFLAGS -fsanitize=address"
 194               CXXFLAGS="$CXXFLAGS -fsanitize=address"
 195               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 196                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 197               ])
 198
 199 dnl ThreadSanitizer support
 200 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 201               [enabled ThreadSanitizer support for detecting data races]), \
 202               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 203               CFLAGS="$CFLAGS -fsanitize=thread"
 204               CXXFLAGS="$CXXFLAGS -fsanitize=thread"
 205               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 206                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 207               ])
 208
 209 dnl MemorySanitizer support
 210 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 211               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 212               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 213               CFLAGS="$CFLAGS -fsanitize=memory -fPIE -pie"
 214               CXXFLAGS="$CXXFLAGS -fsanitize=memory -fPIE -pie"
 215               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 216                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 217               ])
 218
 219 dnl if the user has specified any CFLAGS, override our settings
 220 if test "x${enable_dev_build}" = "xyes"; then
 221    AC_DEFINE(DEV_BUILD,,Build for development)
 222    if test "z$orig_cflags" = "z"; then
 223       AC_C_FLAG([-g3])
 224       AC_C_FLAG([-O0])
 225    fi
 226 else
 227    if test "z$orig_cflags" = "z"; then
 228       AC_C_FLAG([-g])
 229       AC_C_FLAG([-Os], [
 230         AC_C_FLAG([-O2])
 231       ])
 232    fi
 233 fi
 234 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 235 AM_CONDITIONAL([SHARPD], [test "x$enable_dev_build" = "xyes"])
 236
 237 dnl always want these CFLAGS
 238 AC_C_FLAG([-fno-omit-frame-pointer])
 239 AC_C_FLAG([-funwind-tables])
 240 AC_C_FLAG([-Wall])
 241 AC_C_FLAG([-Wextra])
 242 AC_C_FLAG([-Wmissing-prototypes])
 243 AC_C_FLAG([-Wmissing-declarations])
 244 AC_C_FLAG([-Wpointer-arith])
 245 AC_C_FLAG([-Wbad-function-cast])
 246 AC_C_FLAG([-Wwrite-strings])
 247 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 248   AC_C_FLAG([-Wcast-qual])
 249   AC_C_FLAG([-Wstrict-prototypes])
 250   AC_C_FLAG([-Wmissing-noreturn])
 251   AC_C_FLAG([-Wmissing-format-attribute])
 252   AC_C_FLAG([-Wunreachable-code])
 253   AC_C_FLAG([-Wpacked])
 254   AC_C_FLAG([-Wpadded])
 255 else
 256   AC_C_FLAG([-Wno-unused-result])
 257 fi
 258 AC_C_FLAG([-Wno-unused-parameter])
 259 AC_C_FLAG([-Wno-missing-field-initializers])
 260
 261 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 262 dnl for some reason the string consts get 'promoted' to char *,
 263 dnl triggering a const to non-const conversion warning.
 264 AC_C_FLAG([-diag-disable 3179])
 265
 266 if test x"${enable_werror}" = x"yes" ; then
 267   WERROR="-Werror"
 268 fi
 269 AC_SUBST(WERROR)
 270
 271 dnl need link on this one, not compile
 272 AC_LANG_PUSH(C)
 273 ac_ld_flag_save="$LDFLAGS"
 274 LDFLAGS="$LDFLAGS -rdynamic"
 275 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 276 AC_LINK_IFELSE(
 277         [AC_LANG_PROGRAM([[]])],
 278         [AC_MSG_RESULT([yes])],
 279         [
 280                 LDFLAGS="$ac_ld_flag_save"
 281                 AC_MSG_RESULT([no])
 282         ])
 283 AC_LANG_POP(C)
 284
 285 dnl ----------
 286 dnl Essentials
 287 dnl ----------
 288
 289 AX_PTHREAD([
 290   CC="$PTHREAD_CC"
 291   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 292   LIBS="$PTHREAD_LIBS $LIBS"
 293 ], [
 294   AC_MSG_FAILURE([This FRR version needs pthreads])
 295 ])
 296
 297 dnl --------------
 298 dnl Check programs
 299 dnl --------------
 300 AC_PROG_INSTALL
 301 AC_PROG_LN_S
 302 AC_PROG_MAKE_SET
 303 AC_CHECK_TOOL(AR, ar)
 304
 305 dnl -----------------
 306 dnl System extensions
 307 dnl -----------------
 308 AC_GNU_SOURCE
 309
 310 dnl -------
 311 dnl libtool
 312 dnl -------
 313 LT_INIT
 314
 315 dnl ----------------------
 316 dnl Packages configuration
 317 dnl ----------------------
 318 AC_ARG_WITH(pkg-extra-version,
 319         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 320         [EXTRAVERSION=$withval],)
 321 AC_ARG_WITH(pkg-git-version,
 322         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 323         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 324 AC_ARG_WITH(vtysh_pager,
 325         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 326         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 327 AC_ARG_ENABLE(vtysh,
 328   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 329 AC_ARG_ENABLE(doc,
 330   AS_HELP_STRING([--disable-doc], [do not build docs]))
 331 AC_ARG_ENABLE(zebra,
 332   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 333 AC_ARG_ENABLE(bgpd,
 334   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 335 AC_ARG_ENABLE(ripd,
 336   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 337 AC_ARG_ENABLE(ripngd,
 338   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 339 AC_ARG_ENABLE(ospfd,
 340   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 341 AC_ARG_ENABLE(ospf6d,
 342   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 343 AC_ARG_ENABLE(ldpd,
 344   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 345 AC_ARG_ENABLE(nhrpd,
 346   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 347 AC_ARG_ENABLE(eigrpd,
 348   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 349 AC_ARG_ENABLE(babeld,
 350   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 351 AC_ARG_ENABLE(watchfrr,
 352   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 353 AC_ARG_ENABLE(isisd,
 354   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 355 AC_ARG_ENABLE(pimd,
 356   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 357 AC_ARG_ENABLE(bgp-announce,
 358   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 359 AC_ARG_ENABLE(bgp-vnc,
 360   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 361 AC_ARG_WITH(rfp-path,
 362   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 363 AC_ARG_ENABLE(snmp,
 364   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 365 AC_ARG_ENABLE(zeromq,
 366   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 367 AC_ARG_WITH(libpam,
 368   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 369 AC_ARG_ENABLE(ospfapi,
 370   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 371 AC_ARG_ENABLE(ospfclient,
 372   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 373                           (this is the default if --disable-ospfapi is set)]))
 374 AC_ARG_ENABLE(multipath,
 375   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 376 AC_ARG_ENABLE(user,
 377   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 378 AC_ARG_ENABLE(group,
 379   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 380 AC_ARG_ENABLE(vty_group,
 381   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 382 AC_ARG_ENABLE(configfile_mask,
 383   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 384 AC_ARG_ENABLE(logfile_mask,
 385   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 386 AC_ARG_ENABLE(shell_access,
 387   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 388 AC_ARG_ENABLE(realms,
 389   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 390 AC_ARG_ENABLE(rtadv,
 391   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 392 AC_ARG_ENABLE(irdp,
 393   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 394 AC_ARG_ENABLE(capabilities,
 395   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 396 AC_ARG_ENABLE(rusage,
 397   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 398 AC_ARG_ENABLE(gcc_ultra_verbose,
 399   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 400 AC_ARG_ENABLE(linux24_tcp_md5,
 401   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 402 AC_ARG_ENABLE(backtrace,
 403   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 404 AC_ARG_ENABLE(time-check,
 405   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 406 AC_ARG_ENABLE(pcreposix,
 407   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 408 AC_ARG_ENABLE(fpm,
 409   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 410 AC_ARG_ENABLE(systemd,
 411   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 412 AC_ARG_ENABLE(werror,
 413   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 414 AC_ARG_ENABLE(cumulus,
 415   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 416 AC_ARG_ENABLE(datacenter,
 417   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 418 AC_ARG_ENABLE(fuzzing,
 419   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 420 AC_ARG_ENABLE(rr-semantics,
 421   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 422 AC_ARG_ENABLE([protobuf],
 423   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 424 AC_ARG_ENABLE([oldvpn_commands],
 425   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 426 AC_ARG_ENABLE(rpki,
 427   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 428 AC_ARG_ENABLE([clippy-only],
 429   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 430 AC_ARG_ENABLE([numeric_version],
 431   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 432
 433 AS_IF([test "${enable_clippy_only}" != "yes"], [
 434 AC_CHECK_HEADERS(json-c/json.h)
 435 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 436 if test $ac_cv_lib_json_c_json_object_get = no; then
 437   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 438   if test $ac_cv_lib_json_json_object_get = no; then
 439       AC_MSG_ERROR([lib json is needed to compile])
 440   fi
 441 fi
 442 ])
 443
 444 AC_ARG_ENABLE([dev_build],
 445     AS_HELP_STRING([--enable-dev-build], [build for development]))
 446
 447 if test x"${enable_time_check}" != x"no" ; then
 448   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 449     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 450   else
 451     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 452   fi
 453 fi
 454
 455 case "${enable_systemd}" in
 456   "no") ;;
 457   "yes")
 458   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 459   if test $ac_cv_lib_systemd_sd_notify = no; then
 460     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 461   else
 462     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 463   fi
 464   ;;
 465   "*") ;;
 466 esac
 467
 468 if test "${enable_rr_semantics}" != "no" ; then
 469   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 470 fi
 471
 472 if test "${enable_datacenter}" = "yes" ; then
 473   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 474   DFLT_NAME="datacenter"
 475 else
 476   DFLT_NAME="traditional"
 477 fi
 478
 479 if test "${enable_fuzzing}" = "yes" ; then
 480   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 481 fi
 482
 483 if test "${enable_cumulus}" = "yes" ; then
 484   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 485 fi
 486
 487 AC_SUBST(DFLT_NAME)
 488 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 489
 490 if test "${enable_shell_access}" = "yes"; then
 491    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 492 fi
 493
 494 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 495
 496 #
 497 # Python for clippy
 498 #
 499 AS_IF([test "$host" = "$build"], [
 500   PYTHONCONFIG=""
 501
 502   # ordering:
 503   # 1.  try python3, but respect the user's preference on which minor ver
 504   # 2.  try python, which might be py3 or py2 again on the user's preference
 505   # 3.  try python2 (can really only be 2.7 but eh)
 506   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 507   #
 508   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 509   # (AX_PYTHON does not do what we need)
 510
 511   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 512   if test -n "$PYTHONCONFIG"; then
 513     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 514     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 515
 516     AC_MSG_CHECKING([whether we found a working Python version])
 517     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 518 #include <Python.h>
 519 #if PY_VERSION_HEX < 0x02070000
 520 #error python too old
 521 #endif
 522 int main(void);
 523 ],
 524 [
 525 {
 526   Py_Initialize();
 527   return 0;
 528 }
 529 ])], [
 530       PYTHONCONFIG=""
 531       unset PYTHON_LIBS
 532       unset PYTHON_CFLAGS
 533     ])
 534   fi
 535
 536   if test -z "$PYTHONCONFIG"; then
 537     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 538       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 539         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 540           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 541             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 542               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 543               ])])])])])
 544
 545
 546     AC_MSG_CHECKING([whether we found a working Python version])
 547     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 548 #include <Python.h>
 549 #if PY_VERSION_HEX < 0x02070000
 550 #error python too old
 551 #endif
 552 int main(void);
 553 ],
 554 [
 555 {
 556   Py_Initialize();
 557   return 0;
 558 }
 559 ])], [
 560       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 561     ])
 562   fi
 563 ])
 564 AC_SUBST(PYTHON_CFLAGS)
 565 AC_SUBST(PYTHON_LIBS)
 566
 567 #
 568 # Logic for protobuf support.
 569 #
 570 if test "$enable_protobuf" = "yes"; then
 571    have_protobuf=yes
 572
 573    # Check for protoc-c
 574    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 575    if test "x$PROTOC_C" = "x/bin/false"; then
 576       have_protobuf=no
 577    else
 578       found_protobuf_c=no
 579       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 580                      [found_protobuf_c=yes],
 581                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 582
 583       if test "x$found_protobuf_c" = "xyes"; then
 584          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 585          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 586       else
 587         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 588                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 589       fi
 590    fi
 591 fi
 592
 593 #
 594 # Logic for old vpn commans support.
 595 #
 596 if test "$enable_oldvpn_commands" = "yes"; then
 597    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 598 fi
 599
 600 # Fail if the user explicity enabled protobuf support and we couldn't
 601 # find the compiler or libraries.
 602 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 603    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 604 fi
 605
 606 if test "x$have_protobuf" = "xyes"; then
 607    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 608 fi
 609
 610 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 611
 612 #
 613 # End of logic for protobuf support.
 614 #
 615
 616 if test "${enable_linux24_tcp_md5}" = "yes"; then
 617   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 618 fi
 619
 620 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 621 if test "${enable_rtadv}" != "no"; then
 622   AC_MSG_RESULT(yes)
 623   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 624 else
 625   AC_MSG_RESULT(no)
 626 fi
 627
 628 if test x"${enable_user}" = x"no"; then
 629   enable_user=""
 630 else
 631   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 632     enable_user="frr"
 633   fi
 634   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 635 fi
 636
 637 if test x"${enable_group}" = x"no"; then
 638   enable_group=""
 639 else
 640   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 641     enable_group="frr"
 642   fi
 643   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 644 fi
 645
 646 if test x"${enable_vty_group}" = x"yes" ; then
 647   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 648 elif test x"${enable_vty_group}" != x""; then
 649   if test x"${enable_vty_group}" != x"no"; then
 650     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 651   fi
 652 fi
 653 AC_SUBST([enable_user])
 654 AC_SUBST([enable_group])
 655 AC_SUBST([enable_vty_group])
 656
 657 enable_configfile_mask=${enable_configfile_mask:-0600}
 658 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 659
 660 enable_logfile_mask=${enable_logfile_mask:-0600}
 661 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 662
 663 MPATH_NUM=1
 664
 665 case "${enable_multipath}" in
 666   0)
 667     MPATH_NUM=64
 668     ;;
 669   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 670     MPATH_NUM="${enable_multipath}"
 671     ;;
 672   "")
 673     ;;
 674   *)
 675     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 676     ;;
 677 esac
 678
 679 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 680
 681 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 682
 683 dnl ------------------------------------
 684 dnl Alpine only accepts numeric versions
 685 dnl ------------------------------------
 686 if test "x${enable_numeric_version}" != "x" ; then
 687   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 688   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 689 fi
 690
 691 dnl -----------------------------------
 692 dnl Add extra version string to package
 693 dnl name, string and version fields.
 694 dnl -----------------------------------
 695 if test "x${EXTRAVERSION}" != "x" ; then
 696   VERSION="${VERSION}${EXTRAVERSION}"
 697   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 698   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 699   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 700 fi
 701
 702 if test "x$with_pkg_git_version" = "xyes"; then
 703         if test -d "${srcdir}/.git"; then
 704                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 705         else    with_pkg_git_version="no"
 706                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 707         fi
 708 fi
 709 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 710
 711 dnl ------------------------------------
 712 dnl Check C keywords and standard  types
 713 dnl ------------------------------------
 714 AC_C_CONST
 715 AC_C_INLINE
 716 AC_C_VOLATILE
 717 AC_HEADER_STDC
 718 dnl AC_TYPE_PID_T
 719 AC_TYPE_UID_T
 720 AC_TYPE_MODE_T
 721 AC_TYPE_SIZE_T
 722 AC_STRUCT_TM
 723
 724 dnl -------------------------
 725 dnl Check other header files.
 726 dnl -------------------------
 727 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 728         linux/version.h asm/types.h \
 729         sys/cdefs.h])
 730
 731 ac_stdatomic_ok=false
 732 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 733 AC_CHECK_HEADER([stdatomic.h],[
 734
 735   AC_MSG_CHECKING([whether _Atomic qualifier works])
 736   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 737 #include <stdatomic.h>
 738 int main(int argc, char **argv) {
 739   _Atomic int i = 0;
 740   return i;
 741 }
 742 ]])], [
 743     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 744     AC_MSG_RESULT([yes])
 745     ac_stdatomic_ok=true
 746   ], [
 747     AC_MSG_RESULT([no])
 748   ])
 749 ])
 750
 751 AS_IF([$ac_stdatomic_ok], [true], [
 752   AC_MSG_CHECKING([for __atomic_* builtins])
 753   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 754 int main(int argc, char **argv) {
 755   volatile int i = 1;
 756   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 757   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 758 }
 759 ]])], [
 760     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 761     AC_MSG_RESULT([yes])
 762   ], [
 763     AC_MSG_RESULT([no])
 764
 765     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 766     AC_MSG_CHECKING([for __sync_* builtins])
 767     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 768 int main(int argc, char **argv) {
 769   volatile int i = 1;
 770   __sync_fetch_and_sub (&i, 1);
 771   return __sync_val_compare_and_swap (&i, 0, 1);
 772 }
 773 ]])], [
 774       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 775       AC_MSG_RESULT([yes])
 776
 777       AC_MSG_CHECKING([for __sync_swap builtin])
 778       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 779 int main(int argc, char **argv) {
 780   volatile int i = 1;
 781   return __sync_swap (&i, 2);
 782 }
 783 ]])], [
 784         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 785         AC_MSG_RESULT([yes])
 786       ], [
 787         AC_MSG_RESULT([no])
 788       ])
 789
 790     ], [
 791       AC_MSG_RESULT([no])
 792       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 793     ])
 794   ])
 795 ])
 796
 797 dnl Utility macro to avoid retyping includes all the time
 798 m4_define([FRR_INCLUDES],
 799 [#ifdef SUNOS_5
 800 #define _XPG4_2
 801 #define __EXTENSIONS__
 802 #endif
 803 #include <stdio.h>
 804 #include <stdlib.h>
 805 #include <stddef.h>
 806 #include <sys/types.h>
 807 /* sys/conf.h depends on param.h on FBSD at least */
 808 #include <sys/param.h>
 809 /* Required for MAXSIG */
 810 #include <signal.h>
 811 #include <sys/socket.h>
 812 #ifdef __APPLE__
 813 # define __APPLE_USE_RFC_3542
 814 #endif
 815 #include <netinet/in.h>
 816 #include <sys/time.h>
 817 #include <time.h>
 818 #include <net/if.h>
 819 ])dnl
 820
 821 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 822 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 823 dnl an additional round for it.
 824
 825 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 826
 827 m4_define([FRR_INCLUDES],
 828 FRR_INCLUDES
 829 [#if HAVE_NET_IF_VAR_H
 830 # include <net/if_var.h>
 831 #endif
 832 ])dnl
 833
 834 AC_CHECK_HEADERS([netinet/in_var.h \
 835         net/if_dl.h net/netopt.h \
 836         inet/nd.h netinet/ip_icmp.h \
 837         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 838         [], [], FRR_INCLUDES)
 839
 840 AC_CHECK_HEADERS([ucontext.h], [], [],
 841 [#ifndef __USE_GNU
 842 #define __USE_GNU
 843 #endif /* __USE_GNU */
 844 FRR_INCLUDES
 845 ])
 846
 847 m4_define([UCONTEXT_INCLUDES],
 848 [#include <ucontext.h>])dnl
 849
 850 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 851   [], [], [UCONTEXT_INCLUDES])
 852 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 853   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 854    [], [], [UCONTEXT_INCLUDES])],
 855   [], [UCONTEXT_INCLUDES])
 856 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 857   [], [], [UCONTEXT_INCLUDES])
 858
 859 m4_define([FRR_INCLUDES],
 860 FRR_INCLUDES
 861 [
 862 #include <sys/un.h>
 863 #include <netinet/in_systm.h>
 864 #if HAVE_NETINET_IN_VAR_H
 865 # include <netinet/in_var.h>
 866 #endif
 867 #if HAVE_NET_IF_DL_H
 868 # include <net/if_dl.h>
 869 #endif
 870 #if HAVE_NET_NETOPT_H
 871 # include <net/netopt.h>
 872 #endif
 873 #include <net/route.h>
 874 #if HAVE_INET_ND_H
 875 # include <inet/nd.h>
 876 #endif
 877 #include <arpa/inet.h>
 878 /* Required for IDRP */
 879 #if HAVE_NETINET_IP_ICMP_H
 880 # include <netinet/ip_icmp.h>
 881 #endif
 882 ])dnl
 883
 884 dnl V6 headers are checked below, after we check for v6
 885
 886 AC_MSG_CHECKING([which operating system interface to use])
 887 case "$host_os" in
 888   sunos* | solaris2*)
 889     AC_MSG_RESULT([Solaris])
 890
 891     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 892     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 893
 894     AC_CHECK_LIB(socket, main)
 895     AC_CHECK_LIB(nsl, main)
 896     AC_CHECK_LIB(umem, main)
 897     AC_CHECK_FUNCS([printstack], [
 898       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 899       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 900     ])
 901     CURSES=-lcurses
 902     SOLARIS="solaris"
 903     ;;
 904   linux*)
 905     AC_MSG_RESULT([Linux])
 906
 907     AC_DEFINE(GNU_LINUX,,GNU Linux)
 908     AC_DEFINE(HAVE_NETLINK,,netlink)
 909     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 910
 911     dnl Linux has a compilation problem with mixing
 912     dnl netinet/in.h and linux/in6.h they are not
 913     dnl compatible.  There has been discussion on
 914     dnl how to fix it but no real progress on implementation
 915     dnl when they fix it, remove this
 916     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 917
 918     AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
 919     ;;
 920   openbsd*)
 921     AC_MSG_RESULT([OpenBSD])
 922
 923     AC_DEFINE(OPEN_BSD,,OpenBSD)
 924     AC_DEFINE(KAME,1,KAME IPv6)
 925     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 926
 927     if test "x${enable_pimd}" != "xno"; then
 928       case "$host_os" in
 929       openbsd6.0)
 930         ;;
 931       openbsd[6-9]*)
 932         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 933         ;;
 934       esac
 935     fi
 936     ;;
 937   *)
 938     AC_MSG_RESULT([BSD])
 939
 940     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 941     AC_DEFINE(KAME,1,KAME IPv6)
 942     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 943     ;;
 944 esac
 945 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 946
 947 AC_SYS_LARGEFILE
 948
 949 dnl ------------------------
 950 dnl Integrated REALMS option
 951 dnl ------------------------
 952 if test "${enable_realms}" = "yes"; then
 953     case "$host_os" in
 954       linux*)
 955        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 956        ;;
 957       *)
 958        echo "Sorry, only Linux has REALMS support"
 959        exit 1
 960        ;;
 961     esac
 962 fi
 963 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 964
 965 dnl ---------------------
 966 dnl Integrated VTY option
 967 dnl ---------------------
 968 case "${enable_vtysh}" in
 969   "no") VTYSH="";;
 970   *)    VTYSH="vtysh";
 971          AC_DEFINE(VTYSH,,VTY shell)
 972 dnl      Vtysh uses libreadline, which looks for termcap functions at
 973 dnl      configure time.  We follow readlines search order.
 974 dnl      The required procedures are in libtermcap on NetBSD, in
 975 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 976          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 977            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 978              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 979                [AC_CHECK_LIB(ncurses, tputs,
 980                              LIBREADLINE="$LIBREADLINE -lncurses")]
 981               )]
 982             )]
 983           )
 984          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
 985                       "$LIBREADLINE")
 986          if test $ac_cv_lib_readline_main = no; then
 987            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 988          fi
 989          AC_CHECK_HEADER(readline/history.h)
 990          if test $ac_cv_header_readline_history_h = no;then
 991            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 992          fi
 993          AC_CHECK_LIB(readline, rl_completion_matches,
 994                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 995          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 996            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 997          fi
 998          ;;
 999 esac
1000 AC_SUBST(LIBREADLINE)
1001 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1002
1003 dnl ----------
1004 dnl PAM module
1005 dnl
1006 dnl FRR detects the PAM library it is built against by checking for a
1007 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1008 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1009 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1010 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1011 dnl of OpenPAM.
1012 dnl ----------
1013 if test "$with_libpam" = "yes"; then
1014   AC_CHECK_HEADER([security/pam_misc.h],
1015     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1016      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1017      pam_conv_func="misc_conv"
1018     ],
1019     [], FRR_INCLUDES)
1020   AC_CHECK_HEADER([security/openpam.h],
1021     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1022      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1023      pam_conv_func="openpam_ttyconv"
1024     ],
1025     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1026   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1027     AC_MSG_WARN([*** pam support will not be built ***])
1028     with_libpam="no"
1029   fi
1030 fi
1031
1032 if test "$with_libpam" = "yes"; then
1033 dnl took this test from proftpds configure.in and suited to our needs
1034 dnl -------------------------------------------------------------------------
1035 dnl
1036 dnl This next check looks funky due to a linker problem with some versions
1037 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1038 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1039 dnl with RedHat 6.2 and Debian 2.2 or better.
1040 AC_CHECK_LIB(pam, pam_start,
1041   [AC_CHECK_LIB(pam, $pam_conv_func,
1042     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1043      LIBPAM="-lpam"],
1044     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1045      LIBPAM="-lpam -lpam_misc"]
1046     )
1047   ],
1048
1049   [AC_CHECK_LIB(pam, pam_end,
1050     [AC_CHECK_LIB(pam, $pam_conv_func,
1051       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1052        LIBPAM="-lpam -ldl"],
1053       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1054        LIBPAM="-lpam -ldl -lpam_misc"]
1055      )
1056   ],AC_MSG_WARN([*** pam support will not be built ***]),
1057   [-ldl])
1058   ]
1059 )
1060 fi
1061 AC_SUBST(LIBPAM)
1062
1063 dnl -------------------------------
1064 dnl Endian-ness check
1065 dnl -------------------------------
1066 AC_WORDS_BIGENDIAN
1067
1068 dnl -------------------------------
1069 dnl check the size in byte of the C
1070 dnl -------------------------------
1071 dnl AC_CHECK_SIZEOF(char)
1072 dnl AC_CHECK_SIZEOF(int)
1073 dnl AC_CHECK_SIZEOF(short)
1074 dnl AC_CHECK_SIZEOF(long)
1075
1076 dnl ----------------------------
1077 dnl check existance of functions
1078 dnl ----------------------------
1079 AC_FUNC_FNMATCH
1080 AC_FUNC_FORK
1081 AC_FUNC_MKTIME
1082 AC_FUNC_STAT
1083
1084 dnl -------------------------------
1085 dnl bgpd needs pow() and hence libm
1086 dnl -------------------------------
1087 TMPLIBS="$LIBS"
1088 AC_CHECK_HEADER([math.h],
1089   [AC_CHECK_LIB([m], [pow],
1090     [LIBM="-lm"
1091      LIBS="$LIBS $LIBM"
1092      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1093     ])
1094 ])
1095 if test x"$LIBM" = x ; then
1096   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1097 fi
1098 LIBS="$TMPLIBS"
1099 AC_SUBST(LIBM)
1100
1101 AC_CHECK_FUNCS([ppoll], [
1102   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1103 ])
1104 AC_CHECK_FUNCS([pollts], [
1105   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1106 ])
1107
1108 dnl ---------------
1109 dnl other functions
1110 dnl ---------------
1111 AC_CHECK_FUNCS([ \
1112         strlcat strlcpy \
1113         getgrouplist])
1114
1115 AC_CHECK_HEADER([asm-generic/unistd.h],
1116                 [AC_CHECK_DECL(__NR_setns,
1117                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1118                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1119                                ])
1120                  AC_CHECK_FUNCS(setns)]
1121                )
1122
1123 dnl --------------------------
1124 dnl Determine IS-IS I/O method
1125 dnl --------------------------
1126 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1127 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1128 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1129 AC_CHECK_HEADER(net/bpf.h)
1130 AC_CHECK_HEADER(sys/dlpi.h)
1131 AC_MSG_CHECKING(zebra IS-IS I/O method)
1132
1133 case "$host_os" in
1134   linux*)
1135     AC_MSG_RESULT(pfpacket)
1136     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1137     ;;
1138   solaris* | sunos*)
1139     AC_MSG_RESULT(DLPI)
1140     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1141     ;;
1142   *)
1143     if test $ac_cv_header_net_bpf_h = no; then
1144       if test $ac_cv_header_sys_dlpi_h = no; then
1145         AC_MSG_RESULT(none)
1146         if test "${enable_isisd}" = yes; then
1147           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1148         fi
1149         AC_MSG_WARN([*** IS-IS support will not be built ***])
1150         enable_isisd="no"
1151       else
1152         AC_MSG_RESULT(DLPI)
1153       fi
1154       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1155     else
1156       AC_MSG_RESULT(BPF)
1157       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1158     fi
1159     ;;
1160 esac
1161 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1162
1163 dnl ------------------------------------
1164 dnl check for broken CMSG_FIRSTHDR macro
1165 dnl ------------------------------------
1166 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1167 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1168 #ifdef SUNOS_5
1169 #define _XPG4_2
1170 #define __EXTENSIONS__
1171 #endif
1172 #include <stdlib.h>
1173 #include <sys/types.h>
1174 #include <sys/socket.h>
1175
1176 main()
1177 {
1178   struct msghdr msg;
1179   char buf[4];
1180
1181   msg.msg_control = buf;
1182   msg.msg_controllen = 0;
1183
1184   if (CMSG_FIRSTHDR(&msg) != NULL)
1185     exit(0);
1186   exit (1);
1187 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1188 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1189
1190 dnl ---------------------------------------------------------------
1191 dnl figure out how to specify an interface in multicast sockets API
1192 dnl ---------------------------------------------------------------
1193 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1194
1195 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1196         #include <sys/socket.h>
1197         #include <netinet/in.h>
1198         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1199         #include <linux/types.h>
1200 ])
1201
1202 m4_define([FRR_INCLUDES],
1203 FRR_INCLUDES
1204 [#if HAVE_LINUX_MROUTE_H
1205 # include <linux/mroute.h>
1206 #endif
1207 ])dnl
1208
1209 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1210         #include <sys/socket.h>
1211         #include <sys/types.h>
1212         #include <netinet/in.h>
1213         #include <net/route.h>
1214 ])
1215
1216 m4_define([FRR_INCLUDES],
1217 FRR_INCLUDES
1218 [#if HAVE_NETINET_IP_MROUTE_H
1219 # include <netinet/ip_mroute.h>
1220 #endif
1221 ])dnl
1222
1223 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1224 AC_TRY_COMPILE([#include <sys/param.h>],
1225 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1226   return (0);
1227 #else
1228   #error No support for BSD struct ip_mreq hack detected
1229 #endif],[AC_MSG_RESULT(yes)
1230 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1231 AC_MSG_RESULT(no))
1232
1233 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1234 AC_TRY_COMPILE([
1235 #include <sys/types.h>
1236 #include <netinet/in.h>
1237 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1238 ], [AC_MSG_RESULT(yes)
1239 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1240 AC_MSG_RESULT(no))
1241
1242 dnl ---------------------------------------------------------------
1243 dnl figure out how to check link-state
1244 dnl ---------------------------------------------------------------
1245 AC_CHECK_HEADER( [net/if_media.h],
1246   [m4_define([LINK_DETECT_INCLUDES],
1247     FRR_INCLUDES
1248     [#include <net/if_media.h>
1249   ])
1250   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1251     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1252     [], LINK_DETECT_INCLUDES)],
1253   [],
1254   FRR_INCLUDES)
1255
1256 dnl ---------------------------------------------------------------
1257 dnl Additional, newer way to check link-state using ifi_link_state.
1258 dnl Not available in all BSD's when ifmediareq available
1259 dnl ---------------------------------------------------------------
1260 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1261   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1262   [], FRR_INCLUDES)
1263
1264 dnl ------------------------
1265 dnl TCP_MD5SIG socket option
1266 dnl ------------------------
1267
1268 AC_CHECK_HEADER([netinet/tcp.h],
1269    [m4_define([MD5_INCLUDES],
1270       FRR_INCLUDES
1271       [#include <netinet/tcp.h>
1272     ])
1273     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1274    [],
1275    FRR_INCLUDES)
1276 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1277   AC_CHECK_HEADER([linux/tcp.h],
1278        [m4_define([MD5_INCLUDES],
1279           FRR_INCLUDES
1280           [#include <linux/tcp.h>
1281         ])
1282        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1283 fi
1284
1285 dnl ----------------------------------------------------------------------------
1286 dnl figure out if domainname is available in the utsname struct (GNU extension).
1287 dnl ----------------------------------------------------------------------------
1288 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1289
1290 dnl ------------------
1291 dnl IPv6 header checks
1292 dnl ------------------
1293 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1294         netinet6/in6_var.h netinet6/nd6.h], [], [],
1295         FRR_INCLUDES)
1296
1297 m4_define([FRR_INCLUDES],dnl
1298 FRR_INCLUDES
1299 [#if HAVE_NETINET6_IN6_H
1300 #include <netinet6/in6.h>
1301 #endif
1302 #if HAVE_NETINET_IN6_VAR_H
1303 #include <netinet/in6_var.h>
1304 #endif
1305 #include <netinet/icmp6.h>
1306 #if HAVE_NETINET6_IN6_VAR_H
1307 # include <netinet6/in6_var.h>
1308 #endif
1309 #if HAVE_NETINET6_ND6_H
1310 # include <netinet6/nd6.h>
1311 #endif
1312 ])dnl
1313
1314 dnl disable doc check
1315 if test "${enable_doc}" = "no";then
1316   DOC=""
1317 else
1318   DOC="doc"
1319 fi
1320
1321 dnl --------------------
1322 dnl Daemon disable check
1323 dnl --------------------
1324 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1325
1326 if test "${enable_bgpd}" = "no";then
1327   BGPD=""
1328 else
1329   BGPD="bgpd"
1330 fi
1331 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1332
1333 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1334 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1335 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1336
1337 AS_IF([test "${enable_ldpd}" != "no"], [
1338   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1339 ])
1340
1341 NHRPD=""
1342 case "$host_os" in
1343   linux*)
1344     if test "${enable_nhrpd}" != "no"; then
1345       NHRPD="nhrpd"
1346     fi
1347     ;;
1348   *)
1349     if test "${enable_nhrpd}" = "yes"; then
1350       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1351     fi
1352     ;;
1353 esac
1354 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1355
1356 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1357
1358 if test "${enable_watchfrr}" = "no";then
1359   WATCHFRR=""
1360 else
1361   WATCHFRR="watchfrr"
1362 fi
1363 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1364
1365 OSPFCLIENT=""
1366 if test "${enable_ospfapi}" != "no";then
1367     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1368
1369   if test "${enable_ospfclient}" != "no";then
1370       OSPFCLIENT="ospfclient"
1371   fi
1372 fi
1373
1374 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1375 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1376 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1377 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1378 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1379 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1380
1381 if test "${enable_bgp_announce}" = "no";then
1382   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1383 else
1384   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1385 fi
1386
1387 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1388   with_rfp_path="bgpd/rfp-example"
1389 fi
1390 if test "${with_rfp_path}" != "no"; then
1391   VNC_RFP_PATH="${with_rfp_path}"
1392   AC_SUBST(VNC_RFP_PATH)
1393 fi
1394
1395 if test "${enable_bgp_vnc}" != "no";then
1396   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1397   RFPTEST="${with_rfp_path}/rfptest"
1398   LIBRFP="${with_rfp_path}/librfp"
1399   RFPINC="${with_rfp_path}/librfp"
1400 else
1401   RFPTEST=
1402   LIBRFP=
1403   RFPINC="bgpd/rfp-example/librfp"
1404 fi
1405 # set
1406 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1407
1408 AC_SUBST(DOC)
1409 AC_SUBST(RFPTEST)
1410 AC_SUBST(LIBRFP)
1411 AC_SUBST(RFPINC)
1412 AC_SUBST(BGPD)
1413 AC_SUBST(SOLARIS)
1414 AC_SUBST(VTYSH)
1415 AC_SUBST(CURSES)
1416 AC_CHECK_LIB(crypt, crypt, [],
1417                     [AC_CHECK_LIB(crypto, DES_crypt)])
1418 AC_CHECK_LIB(resolv, res_init)
1419
1420 dnl ---------------------------
1421 dnl check system has PCRE regexp
1422 dnl ---------------------------
1423 if test "x$enable_pcreposix" = "xyes"; then
1424   AC_CHECK_LIB(pcreposix, regexec, [], [
1425     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1426   ])
1427 fi
1428 AC_SUBST(HAVE_LIBPCREPOSIX)
1429
1430 dnl ------------------
1431 dnl check C-Ares library
1432 dnl ------------------
1433 if test "${NHRPD}" != ""; then
1434   PKG_CHECK_MODULES([CARES], [libcares], , [
1435     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1436   ])
1437 fi
1438
1439
1440 dnl ------------------
1441 dnl check Net-SNMP library
1442 dnl ------------------
1443 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1444    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1445    if test x"$NETSNMP_CONFIG" = x"no"; then
1446       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1447    fi
1448    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1449    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1450    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1451    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1452 int main(void);
1453 ],
1454 [
1455 {
1456   return 0;
1457 }
1458 ])], [
1459      AC_MSG_ERROR([--enable-snmp given but not usable])])
1460    case "${enable_snmp}" in
1461      yes)
1462       SNMP_METHOD=agentx
1463       ;;
1464      smux|agentx)
1465       SNMP_METHOD="${enable_snmp}"
1466       ;;
1467      *)
1468       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1469       ;;
1470    esac
1471    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1472    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1473    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1474 fi
1475 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1476 AC_SUBST(SNMP_LIBS)
1477 AC_SUBST(SNMP_CFLAGS)
1478
1479 dnl ---------------
1480 dnl math
1481 dnl ---------------
1482 AC_SEARCH_LIBS([sqrt], [m])
1483
1484 dnl ---------------
1485 dnl dlopen & dlinfo
1486 dnl ---------------
1487 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1488   AC_MSG_ERROR([unable to find the dlopen()])
1489 ])
1490
1491 AC_CHECK_HEADERS([link.h])
1492
1493 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1494 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1495 #include <stdlib.h>
1496 #ifdef HAVE_LINK_H
1497 #include <link.h>
1498 #endif
1499 #include <dlfcn.h>
1500 ]], [[
1501   char origin[1];
1502   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1503 ]])], [
1504   AC_MSG_RESULT(yes)
1505   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1506 ], [
1507   AC_MSG_RESULT(no)
1508 ])
1509
1510 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1511 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1512 #include <stdlib.h>
1513 #ifdef HAVE_LINK_H
1514 #include <link.h>
1515 #endif
1516 #include <dlfcn.h>
1517 ]], [[
1518   struct link_map *lm = NULL;
1519   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1520 ]])], [
1521   AC_MSG_RESULT(yes)
1522   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1523 ], [
1524   AC_MSG_RESULT(no)
1525 ])
1526
1527
1528 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1529
1530 dnl ---------------------------
1531 dnl sockaddr and netinet checks
1532 dnl ---------------------------
1533 AC_CHECK_TYPES([
1534         struct sockaddr_dl,
1535         struct vifctl, struct mfcctl, struct sioc_sg_req,
1536         vifi_t, struct sioc_vif_req, struct igmpmsg,
1537         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1538         struct nd_opt_adv_interval, struct rt_addrinfo,
1539         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1540         [], [], FRR_INCLUDES)
1541
1542 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1543         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1544         struct sockaddr_dl.sdl_len,
1545         struct if6_aliasreq.ifra_lifetime,
1546         struct nd_opt_adv_interval.nd_opt_ai_type],
1547         [], [], FRR_INCLUDES)
1548
1549 dnl ---------------------------
1550 dnl IRDP/pktinfo/icmphdr checks
1551 dnl ---------------------------
1552
1553 AC_CHECK_TYPES([struct in_pktinfo], [
1554   AC_CHECK_TYPES([struct icmphdr], [
1555     IRDP=true
1556   ], [
1557     IRDP=false
1558   ], [FRR_INCLUDES])
1559 ], [
1560   IRDP=false
1561 ], [FRR_INCLUDES])
1562
1563 case "${enable_irdp}" in
1564 yes)
1565   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1566   ;;
1567 no)
1568   IRDP=false
1569   ;;
1570 esac
1571
1572 AM_CONDITIONAL(IRDP, $IRDP)
1573
1574 dnl -----------------------
1575 dnl checking for IP_PKTINFO
1576 dnl -----------------------
1577 AC_MSG_CHECKING(for IP_PKTINFO)
1578 AC_TRY_COMPILE([#include <netdb.h>], [
1579   int opt = IP_PKTINFO;
1580 ], [
1581   AC_MSG_RESULT(yes)
1582   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1583 ], [
1584   AC_MSG_RESULT(no)
1585 ])
1586
1587 dnl ---------------------------
1588 dnl checking for IP_RECVDSTADDR
1589 dnl ---------------------------
1590 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1591 AC_TRY_COMPILE([#include <netinet/in.h>], [
1592   int opt = IP_RECVDSTADDR;
1593 ], [
1594   AC_MSG_RESULT(yes)
1595   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1596 ], [
1597   AC_MSG_RESULT(no)
1598 ])
1599
1600 dnl ----------------------
1601 dnl checking for IP_RECVIF
1602 dnl ----------------------
1603 AC_MSG_CHECKING(for IP_RECVIF)
1604 AC_TRY_COMPILE([#include <netinet/in.h>], [
1605   int opt = IP_RECVIF;
1606 ], [
1607   AC_MSG_RESULT(yes)
1608   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1609 ], [
1610   AC_MSG_RESULT(no)
1611 ])
1612
1613 dnl ----------------------
1614 dnl checking for SO_BINDANY
1615 dnl ----------------------
1616 AC_MSG_CHECKING(for SO_BINDANY)
1617 AC_TRY_COMPILE([#include <sys/socket.h>], [
1618   int opt = SO_BINDANY;
1619 ], [
1620   AC_MSG_RESULT(yes)
1621   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1622 ], [
1623   AC_MSG_RESULT(no)
1624 ])
1625
1626 dnl ----------------------
1627 dnl checking for IP_FREEBIND
1628 dnl ----------------------
1629 AC_MSG_CHECKING(for IP_FREEBIND)
1630 AC_TRY_COMPILE([#include <netinet/in.h>], [
1631   int opt = IP_FREEBIND;
1632 ], [
1633   AC_MSG_RESULT(yes)
1634   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1635 ], [
1636   AC_MSG_RESULT(no)
1637 ])
1638
1639 dnl --------------------------------------
1640 dnl checking for be32dec existence or not
1641 dnl --------------------------------------
1642 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1643                [#include <sys/endian.h>])
1644
1645 dnl --------------------------------------
1646 dnl checking for clock_time monotonic struct and call
1647 dnl --------------------------------------
1648 AC_CHECK_DECL(CLOCK_MONOTONIC,
1649         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1650          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1651 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1652
1653 dnl --------------------------------------
1654 dnl checking for flex and bison
1655 dnl --------------------------------------
1656
1657 AM_PROG_LEX
1658 AC_MSG_CHECKING(version of flex)
1659 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1660 frr_ac_flex_version="${frr_ac_flex_version##* }"
1661 AC_MSG_RESULT([$frr_ac_flex_version])
1662 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1663   LEX="$SHELL $missing_dir/missing flex"
1664   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1665     AC_MSG_WARN([using pregenerated flex output files])
1666   else
1667     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1668   fi
1669   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1670   AC_SUBST([LEXLIB], [''])
1671 ])
1672
1673 AC_PROG_YACC
1674 dnl thanks GNU bison for this b*llshit...
1675 AC_MSG_CHECKING(version of bison)
1676 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1677 frr_ac_bison_version="${frr_ac_bison_version##* }"
1678 frr_ac_bison_missing="false"
1679 case "x${frr_ac_bison_version}" in
1680   x2.7*)
1681     BISON_OPENBRACE='"'
1682     BISON_CLOSEBRACE='"'
1683     BISON_VERBOSE=''
1684     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1685     ;;
1686   x2.*|x1.*)
1687     AC_MSG_RESULT([$frr_ac_bison_version])
1688     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1689     frr_ac_bison_missing="true"
1690     ;;
1691   x)
1692     AC_MSG_RESULT([none])
1693     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1694     frr_ac_bison_missing="true"
1695     ;;
1696   *)
1697     BISON_OPENBRACE='{'
1698     BISON_CLOSEBRACE='}'
1699     BISON_VERBOSE='-Dparse.error=verbose'
1700     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1701     ;;
1702 esac
1703 AC_SUBST(BISON_OPENBRACE)
1704 AC_SUBST(BISON_CLOSEBRACE)
1705 AC_SUBST(BISON_VERBOSE)
1706
1707 if $frr_ac_bison_missing; then
1708   YACC="$SHELL $missing_dir/missing bison -y"
1709   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1710     AC_MSG_WARN([using pregenerated bison output files])
1711   else
1712     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1713   fi
1714 fi
1715
1716 dnl -------------------
1717 dnl capabilities checks
1718 dnl -------------------
1719 if test "${enable_capabilities}" != "no"; then
1720   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1721   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1722     [AC_MSG_RESULT(yes)
1723      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1724      frr_ac_keepcaps="yes"],
1725      AC_MSG_RESULT(no)
1726   )
1727   if test x"${frr_ac_keepcaps}" = x"yes"; then
1728     AC_CHECK_HEADERS(sys/capability.h)
1729   fi
1730   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1731     AC_CHECK_LIB(cap, cap_init,
1732       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1733        LIBCAP="-lcap"
1734        frr_ac_lcaps="yes"]
1735     )
1736   else
1737     AC_CHECK_HEADERS(priv.h,
1738      [AC_MSG_CHECKING(Solaris style privileges are available)
1739       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1740           [AC_MSG_RESULT(yes)
1741            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1742            frr_ac_scaps="yes"],
1743            AC_MSG_RESULT(no)
1744       )
1745      ]
1746    )
1747   fi
1748   if test x"${frr_ac_scaps}" = x"yes" \
1749        -o x"${frr_ac_lcaps}" = x"yes"; then
1750     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1751   fi
1752 fi
1753 AC_SUBST(LIBCAP)
1754
1755 dnl ---------------------------
1756 dnl check for glibc 'backtrace'
1757 dnl ---------------------------
1758 if test x"${enable_backtrace}" != x"no" ; then
1759   backtrace_ok=no
1760   AC_CHECK_HEADER([execinfo.h], [
1761     AC_SEARCH_LIBS([backtrace], [execinfo], [
1762       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1763       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1764       backtrace_ok=yes
1765     ],, [-lm])
1766   ])
1767
1768   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1769     dnl user explicitly requested backtrace but we failed to find support
1770     AC_MSG_FAILURE([failed to find backtrace support])
1771   fi
1772 fi
1773
1774 dnl -----------------------------------------
1775 dnl check for malloc mallinfo struct and call
1776 dnl this must try and link using LIBS, in
1777 dnl order to check no alternative allocator
1778 dnl has been specified, which might not provide
1779 dnl mallinfo, e.g. such as Umem on Solaris.
1780 dnl -----------------------------------------
1781 AC_CHECK_HEADER([malloc.h],
1782  [AC_MSG_CHECKING(whether mallinfo is available)
1783   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1784                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1785       [AC_MSG_RESULT(yes)
1786        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1787        AC_MSG_RESULT(no)
1788   )
1789  ], [], FRR_INCLUDES)
1790
1791 dnl ------
1792 dnl ZeroMQ
1793 dnl ------
1794 if test "x$enable_zeromq" != "xno"; then
1795   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1796     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1797     ZEROMQ=true
1798   ], [
1799     if test "x$enable_zeromq" = "xyes"; then
1800       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1801     fi
1802   ])
1803 fi
1804 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1805
1806 dnl ----------
1807 dnl configure date
1808 dnl ----------
1809 CONFDATE=`date '+%Y%m%d'`
1810 AC_SUBST(CONFDATE)
1811
1812 dnl ------------------------------
1813 dnl set paths for state directory
1814 dnl ------------------------------
1815 AC_MSG_CHECKING(directory to use for state file)
1816 if test "${prefix}" = "NONE"; then
1817   frr_statedir_prefix="";
1818 else
1819   frr_statedir_prefix=${prefix}
1820 fi
1821 if test "${localstatedir}" = '${prefix}/var'; then
1822   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1823                         ${frr_statedir_prefix}/var/adm dnl
1824                         ${frr_statedir_prefix}/etc dnl
1825                         /var/run        dnl
1826                         /var/adm        dnl
1827                         /etc            dnl
1828                         /dev/null;
1829   do
1830     test -d $FRR_STATE_DIR && break
1831   done
1832   frr_statedir=$FRR_STATE_DIR
1833 else
1834   frr_statedir=${localstatedir}
1835 fi
1836 if test $frr_statedir = "/dev/null"; then
1837     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1838 fi
1839 AC_MSG_RESULT(${frr_statedir})
1840 AC_SUBST(frr_statedir)
1841
1842 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1843 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1844 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1845
1846 dnl autoconf does this, but it does it too late...
1847 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1848 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1849
1850 dnl get the full path, recursing through variables...
1851 vtysh_bin="$bindir/vtysh"
1852 for I in 1 2 3 4 5 6 7 8 9 10; do
1853         eval vtysh_bin="\"$vtysh_bin\""
1854 done
1855 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1856
1857 CFG_SYSCONF="$sysconfdir"
1858 CFG_SBIN="$sbindir"
1859 CFG_STATE="$frr_statedir"
1860 CFG_MODULE="$moduledir"
1861 for I in 1 2 3 4 5 6 7 8 9 10; do
1862         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1863         eval CFG_SBIN="\"$CFG_SBIN\""
1864         eval CFG_STATE="\"$CFG_STATE\""
1865         eval CFG_MODULE="\"$CFG_MODULE\""
1866 done
1867 AC_SUBST(CFG_SYSCONF)
1868 AC_SUBST(CFG_SBIN)
1869 AC_SUBST(CFG_STATE)
1870 AC_SUBST(CFG_MODULE)
1871 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1872
1873 dnl ------------------------------------
1874 dnl Enable RPKI and add librtr to libs
1875 dnl ------------------------------------
1876 if test "${enable_rpki}" = "yes"; then
1877   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1878       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1879       RPKI=true],
1880       [RPKI=false
1881       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1882   )
1883 fi
1884 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1885
1886 dnl ------------------------------------------
1887 dnl Check whether rtrlib was build with ssh support
1888 dnl ------------------------------------------
1889 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1890 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1891                         [[struct tr_ssh_config config;]])],
1892         [AC_MSG_RESULT(yes)
1893         AC_DEFINE(FOUND_SSH,,found_ssh)],
1894         AC_MSG_RESULT(no)
1895 )
1896
1897 dnl ---------------------------
1898 dnl Check htonl works correctly
1899 dnl ---------------------------
1900 AC_MSG_CHECKING(for working htonl)
1901 AC_CACHE_VAL(ac_cv_htonl_works,
1902  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1903                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1904  ]
1905 )
1906 AC_MSG_RESULT($ac_cv_htonl_works)
1907
1908 AC_CONFIG_FILES([Makefile
1909           bgpd/Makefile
1910           vtysh/Makefile
1911           doc/Makefile tests/Makefile
1912           bgpd/rfp-example/rfptest/Makefile bgpd/rfp-example/librfp/Makefile
1913           redhat/frr.spec
1914           debianpkg/Makefile
1915           debianpkg/changelog
1916           alpine/APKBUILD
1917           snapcraft/snapcraft.yaml
1918           lib/version.h
1919           tests/lib/cli/test_cli.refout
1920           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1921           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1922           pkgsrc/eigrpd.sh])
1923
1924 if test "${enable_bgp_vnc}" != "no"; then
1925    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
1926       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
1927    fi
1928 fi
1929
1930 AC_CONFIG_FILES([solaris/Makefile])
1931
1932 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1933
1934 AC_CONFIG_COMMANDS([lib/route_types.h], [
1935         dst="${ac_abs_top_builddir}/lib/route_types.h"
1936         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1937                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1938                 > "${dst}.tmp"
1939         test -f "${dst}" \
1940                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1941                 && rm "${dst}.tmp" \
1942                 || mv "${dst}.tmp" "${dst}"
1943 ], [
1944         PERL="$PERL"
1945 ])
1946
1947 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1948     AC_CONFIG_COMMANDS([lib/gitversion.h], [
1949         dst="${ac_abs_top_builddir}/lib/gitversion.h"
1950         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1951                 "${ac_abs_top_srcdir}" \
1952                 > "${dst}.tmp"
1953         test -f "${dst}" \
1954                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1955                 && rm "${dst}.tmp" \
1956                 || mv "${dst}.tmp" "${dst}"
1957     ], [
1958         PERL="$PERL"
1959     ])
1960 ])
1961
1962 ## Hack, but working solution to avoid rebuilding of frr.info.
1963 ## It's already in CVS until texinfo 4.7 is more common.
1964 AC_OUTPUT
1965
1966 echo "
1967 FRRouting configuration
1968 ------------------------------
1969 FRR version             : ${PACKAGE_VERSION}
1970 host operating system   : ${host_os}
1971 source code location    : ${srcdir}
1972 compiler                : ${CC}
1973 compiler flags          : ${CFLAGS}
1974 make                    : ${MAKE-make}
1975 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1976 state file directory    : ${frr_statedir}
1977 config file directory   : `eval echo \`echo ${sysconfdir}\``
1978 example directory       : `eval echo \`echo ${exampledir}\``
1979 module directory        : ${CFG_MODULE}
1980 user to run as          : ${enable_user}
1981 group to run as         : ${enable_group}
1982 group for vty sockets   : ${enable_vty_group}
1983 config file mask        : ${enable_configfile_mask}
1984 log file mask           : ${enable_logfile_mask}
1985 zebra protobuf enabled  : ${have_protobuf:-no}
1986
1987 The above user and group must have read/write access to the state file
1988 directory and to the config files in the config file directory."