configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 3.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl if the user specified any CFLAGS, we don't add "-g -Os/-O2" here
 189 if test "z$orig_cflags" = "z"; then
 190   AC_C_FLAG([-g])
 191   AC_C_FLAG([-Os], [
 192     AC_C_FLAG([-O2])
 193   ])
 194 fi
 195
 196 dnl always want these CFLAGS
 197 AC_C_FLAG([-fno-omit-frame-pointer])
 198 AC_C_FLAG([-funwind-tables])
 199 AC_C_FLAG([-Wall])
 200 AC_C_FLAG([-Wextra])
 201 AC_C_FLAG([-Wmissing-prototypes])
 202 AC_C_FLAG([-Wmissing-declarations])
 203 AC_C_FLAG([-Wpointer-arith])
 204 AC_C_FLAG([-Wbad-function-cast])
 205 AC_C_FLAG([-Wwrite-strings])
 206 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 207   AC_C_FLAG([-Wcast-qual])
 208   AC_C_FLAG([-Wstrict-prototypes])
 209   AC_C_FLAG([-Wmissing-noreturn])
 210   AC_C_FLAG([-Wmissing-format-attribute])
 211   AC_C_FLAG([-Wunreachable-code])
 212   AC_C_FLAG([-Wpacked])
 213   AC_C_FLAG([-Wpadded])
 214 else
 215   AC_C_FLAG([-Wno-unused-result])
 216 fi
 217 AC_C_FLAG([-Wno-unused-parameter])
 218 AC_C_FLAG([-Wno-missing-field-initializers])
 219
 220 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 221 dnl for some reason the string consts get 'promoted' to char *,
 222 dnl triggering a const to non-const conversion warning.
 223 AC_C_FLAG([-diag-disable 3179])
 224
 225 if test x"${enable_werror}" = x"yes" ; then
 226   WERROR="-Werror"
 227 fi
 228 AC_SUBST(WERROR)
 229
 230 dnl need link on this one, not compile
 231 AC_LANG_PUSH(C)
 232 ac_ld_flag_save="$LDFLAGS"
 233 LDFLAGS="$LDFLAGS -rdynamic"
 234 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 235 AC_LINK_IFELSE(
 236         [AC_LANG_PROGRAM([[]])],
 237         [AC_MSG_RESULT([yes])],
 238         [
 239                 LDFLAGS="$ac_ld_flag_save"
 240                 AC_MSG_RESULT([no])
 241         ])
 242 AC_LANG_POP(C)
 243
 244 dnl ----------
 245 dnl Essentials
 246 dnl ----------
 247
 248 AX_PTHREAD([
 249   CC="$PTHREAD_CC"
 250   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 251   LIBS="$PTHREAD_LIBS $LIBS"
 252 ], [
 253   AC_MSG_FAILURE([This FRR version needs pthreads])
 254 ])
 255
 256 dnl --------------
 257 dnl Check programs
 258 dnl --------------
 259 AC_PROG_INSTALL
 260 AC_PROG_LN_S
 261 AC_PROG_MAKE_SET
 262 AC_CHECK_TOOL(AR, ar)
 263
 264 dnl -----------------
 265 dnl System extensions
 266 dnl -----------------
 267 AC_GNU_SOURCE
 268
 269 dnl -------
 270 dnl libtool
 271 dnl -------
 272 LT_INIT
 273
 274 dnl ----------------------
 275 dnl Packages configuration
 276 dnl ----------------------
 277 AC_ARG_WITH(pkg-extra-version,
 278         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 279         [EXTRAVERSION=$withval],)
 280 AC_ARG_WITH(pkg-git-version,
 281         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 282         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 283 AC_ARG_WITH(vtysh_pager,
 284         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 285         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 286 AC_ARG_ENABLE(vtysh,
 287   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 288 AC_ARG_ENABLE(doc,
 289   AS_HELP_STRING([--disable-doc], [do not build docs]))
 290 AC_ARG_ENABLE(zebra,
 291   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 292 AC_ARG_ENABLE(bgpd,
 293   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 294 AC_ARG_ENABLE(ripd,
 295   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 296 AC_ARG_ENABLE(ripngd,
 297   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 298 AC_ARG_ENABLE(ospfd,
 299   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 300 AC_ARG_ENABLE(ospf6d,
 301   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 302 AC_ARG_ENABLE(ldpd,
 303   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 304 AC_ARG_ENABLE(nhrpd,
 305   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 306 AC_ARG_ENABLE(eigrpd,
 307   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 308 AC_ARG_ENABLE(babeld,
 309   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 310 AC_ARG_ENABLE(watchfrr,
 311   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 312 AC_ARG_ENABLE(isisd,
 313   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 314 AC_ARG_ENABLE(pimd,
 315   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 316 AC_ARG_ENABLE(bgp-announce,
 317   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 318 AC_ARG_ENABLE(bgp-vnc,
 319   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 320 AC_ARG_WITH(rfp-path,
 321   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 322 AC_ARG_ENABLE(snmp,
 323   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 324 AC_ARG_ENABLE(zeromq,
 325   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 326 AC_ARG_WITH(libpam,
 327   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 328 AC_ARG_ENABLE(ospfapi,
 329   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 330 AC_ARG_ENABLE(ospfclient,
 331   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 332                           (this is the default if --disable-ospfapi is set)]))
 333 AC_ARG_ENABLE(multipath,
 334   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 335 AC_ARG_ENABLE(user,
 336   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 337 AC_ARG_ENABLE(group,
 338   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 339 AC_ARG_ENABLE(vty_group,
 340   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 341 AC_ARG_ENABLE(configfile_mask,
 342   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 343 AC_ARG_ENABLE(logfile_mask,
 344   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 345 AC_ARG_ENABLE(shell_access,
 346   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 347 AC_ARG_ENABLE(rtadv,
 348   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 349 AC_ARG_ENABLE(irdp,
 350   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 351 AC_ARG_ENABLE(capabilities,
 352   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 353 AC_ARG_ENABLE(rusage,
 354   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 355 AC_ARG_ENABLE(gcc_ultra_verbose,
 356   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 357 AC_ARG_ENABLE(linux24_tcp_md5,
 358   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 359 AC_ARG_ENABLE(backtrace,
 360   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 361 AC_ARG_ENABLE(time-check,
 362   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 363 AC_ARG_ENABLE(pcreposix,
 364   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 365 AC_ARG_ENABLE(fpm,
 366   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 367 AC_ARG_ENABLE(systemd,
 368   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 369 AC_ARG_ENABLE(werror,
 370   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 371 AC_ARG_ENABLE(cumulus,
 372   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 373 AC_ARG_ENABLE(datacenter,
 374   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 375 AC_ARG_ENABLE(rr-semantics,
 376   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 377 AC_ARG_ENABLE([protobuf],
 378   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 379 AC_ARG_ENABLE([oldvpn_commands],
 380   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 381
 382 AC_CHECK_HEADERS(json-c/json.h)
 383 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 384 if test $ac_cv_lib_json_c_json_object_get = no; then
 385   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 386   if test $ac_cv_lib_json_json_object_get = no; then
 387       AC_MSG_ERROR([lib json is needed to compile])
 388   fi
 389 fi
 390
 391 AC_ARG_ENABLE([dev_build],
 392     AS_HELP_STRING([--enable-dev-build], [build for development]))
 393
 394 if test x"${enable_time_check}" != x"no" ; then
 395   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 396     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 397   else
 398     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 399   fi
 400 fi
 401
 402 case "${enable_systemd}" in
 403   "no") ;;
 404   "yes")
 405   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 406   if test $ac_cv_lib_systemd_sd_notify = no; then
 407     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 408   else
 409     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 410   fi
 411   ;;
 412   "*") ;;
 413 esac
 414
 415 if test "${enable_rr_semantics}" != "no" ; then
 416   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 417 fi
 418
 419 if test "${enable_datacenter}" = "yes" ; then
 420   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 421   DFLT_NAME="datacenter"
 422 else
 423   DFLT_NAME="traditional"
 424 fi
 425
 426 if test "${enable_cumulus}" = "yes" ; then
 427   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 428 fi
 429
 430 AC_SUBST(DFLT_NAME)
 431 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 432
 433 if test "${enable_shell_access}" = "yes"; then
 434    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 435 fi
 436
 437 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 438
 439 if test "x${enable_dev_build}" = "xyes"; then
 440    AC_DEFINE(DEV_BUILD,,Build for development)
 441 fi
 442 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 443
 444 #
 445 # Python for clippy
 446 #
 447 AS_IF([test "$host" = "$build"], [
 448   PYTHONCONFIG=""
 449
 450   # ordering:
 451   # 1.  try python3, but respect the user's preference on which minor ver
 452   # 2.  try python, which might be py3 or py2 again on the user's preference
 453   # 3.  try python2 (can really only be 2.7 but eh)
 454   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 455   #
 456   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 457   # (AX_PYTHON does not do what we need)
 458
 459   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 460   if test -n "$PYTHONCONFIG"; then
 461     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 462     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 463
 464     AC_MSG_CHECKING([whether we found a working Python version])
 465     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 466 #include <Python.h>
 467 #if PY_VERSION_HEX < 0x02070000
 468 #error python too old
 469 #endif
 470 int main(void);
 471 ],
 472 [
 473 {
 474   Py_Initialize();
 475   return 0;
 476 }
 477 ])], [
 478       PYTHONCONFIG=""
 479       unset PYTHON_LIBS
 480       unset PYTHON_CFLAGS
 481     ])
 482   fi
 483
 484   if test -z "$PYTHONCONFIG"; then
 485     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 486       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 487         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 488           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 489             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 490               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 491               ])])])])])
 492
 493
 494     AC_MSG_CHECKING([whether we found a working Python version])
 495     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 496 #include <Python.h>
 497 #if PY_VERSION_HEX < 0x02070000
 498 #error python too old
 499 #endif
 500 int main(void);
 501 ],
 502 [
 503 {
 504   Py_Initialize();
 505   return 0;
 506 }
 507 ])], [
 508       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 509     ])
 510   fi
 511 ])
 512 AC_SUBST(PYTHON_CFLAGS)
 513 AC_SUBST(PYTHON_LIBS)
 514
 515 #
 516 # Logic for protobuf support.
 517 #
 518 if test "$enable_protobuf" = "yes"; then
 519    have_protobuf=yes
 520
 521    # Check for protoc-c
 522    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 523    if test "x$PROTOC_C" = "x/bin/false"; then
 524       have_protobuf=no
 525    else
 526       found_protobuf_c=no
 527       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 528                      [found_protobuf_c=yes],
 529                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 530
 531       if test "x$found_protobuf_c" = "xyes"; then
 532          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 533          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 534       else
 535         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 536                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 537       fi
 538    fi
 539 fi
 540
 541 #
 542 # Logic for old vpn commans support.
 543 #
 544 if test "$enable_oldvpn_commands" = "yes"; then
 545    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 546 fi
 547
 548 # Fail if the user explicity enabled protobuf support and we couldn't
 549 # find the compiler or libraries.
 550 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 551    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 552 fi
 553
 554 if test "x$have_protobuf" = "xyes"; then
 555    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 556 fi
 557
 558 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 559
 560 #
 561 # End of logic for protobuf support.
 562 #
 563
 564 if test "${enable_linux24_tcp_md5}" = "yes"; then
 565   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 566 fi
 567
 568 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 569 if test "${enable_rtadv}" != "no"; then
 570   AC_MSG_RESULT(yes)
 571   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 572 else
 573   AC_MSG_RESULT(no)
 574 fi
 575
 576 if test x"${enable_user}" = x"no"; then
 577   enable_user=""
 578 else
 579   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 580     enable_user="frr"
 581   fi
 582   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 583 fi
 584
 585 if test x"${enable_group}" = x"no"; then
 586   enable_group=""
 587 else
 588   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 589     enable_group="frr"
 590   fi
 591   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 592 fi
 593
 594 if test x"${enable_vty_group}" = x"yes" ; then
 595   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 596 elif test x"${enable_vty_group}" != x""; then
 597   if test x"${enable_vty_group}" != x"no"; then
 598     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 599   fi
 600 fi
 601 AC_SUBST([enable_user])
 602 AC_SUBST([enable_group])
 603 AC_SUBST([enable_vty_group])
 604
 605 enable_configfile_mask=${enable_configfile_mask:-0600}
 606 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 607
 608 enable_logfile_mask=${enable_logfile_mask:-0600}
 609 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 610
 611 MPATH_NUM=1
 612
 613 case "${enable_multipath}" in
 614   0)
 615     MPATH_NUM=64
 616     ;;
 617   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 618     MPATH_NUM="${enable_multipath}"
 619     ;;
 620   "")
 621     ;;
 622   *)
 623     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 624     ;;
 625 esac
 626
 627 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 628
 629 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 630
 631 dnl -----------------------------------
 632 dnl Add extra version string to package
 633 dnl name, string and version fields.
 634 dnl -----------------------------------
 635 if test "x${EXTRAVERSION}" != "x" ; then
 636   VERSION="${VERSION}${EXTRAVERSION}"
 637   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 638   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 639   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 640 fi
 641
 642 if test "x$with_pkg_git_version" = "xyes"; then
 643         if test -d "${srcdir}/.git"; then
 644                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 645         else    with_pkg_git_version="no"
 646                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 647         fi
 648 fi
 649 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 650
 651 dnl ------------------------------------
 652 dnl Check C keywords and standard  types
 653 dnl ------------------------------------
 654 AC_C_CONST
 655 AC_C_INLINE
 656 AC_C_VOLATILE
 657 AC_HEADER_STDC
 658 dnl AC_TYPE_PID_T
 659 AC_TYPE_UID_T
 660 AC_TYPE_MODE_T
 661 AC_TYPE_SIZE_T
 662 AC_STRUCT_TM
 663
 664 dnl -------------------------
 665 dnl Check other header files.
 666 dnl -------------------------
 667 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 668         linux/version.h asm/types.h \
 669         sys/cdefs.h])
 670
 671 ac_stdatomic_ok=false
 672 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 673 AC_CHECK_HEADER([stdatomic.h],[
 674
 675   AC_MSG_CHECKING([whether _Atomic qualifier works])
 676   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 677 #include <stdatomic.h>
 678 int main(int argc, char **argv) {
 679   _Atomic int i = 0;
 680   return i;
 681 }
 682 ]])], [
 683     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 684     AC_MSG_RESULT([yes])
 685     ac_stdatomic_ok=true
 686   ], [
 687     AC_MSG_RESULT([no])
 688   ])
 689 ])
 690
 691 AS_IF([$ac_stdatomic_ok], [true], [
 692   AC_MSG_CHECKING([for __atomic_* builtins])
 693   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 694 int main(int argc, char **argv) {
 695   volatile int i = 1;
 696   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 697   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 698 }
 699 ]])], [
 700     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 701     AC_MSG_RESULT([yes])
 702   ], [
 703     AC_MSG_RESULT([no])
 704
 705     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 706     AC_MSG_CHECKING([for __sync_* builtins])
 707     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 708 int main(int argc, char **argv) {
 709   volatile int i = 1;
 710   __sync_fetch_and_sub (&i, 1);
 711   return __sync_val_compare_and_swap (&i, 0, 1);
 712 }
 713 ]])], [
 714       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 715       AC_MSG_RESULT([yes])
 716
 717       AC_MSG_CHECKING([for __sync_swap builtin])
 718       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 719 int main(int argc, char **argv) {
 720   volatile int i = 1;
 721   return __sync_swap (&i, 2);
 722 }
 723 ]])], [
 724         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 725         AC_MSG_RESULT([yes])
 726       ], [
 727         AC_MSG_RESULT([no])
 728       ])
 729
 730     ], [
 731       AC_MSG_RESULT([no])
 732       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 733     ])
 734   ])
 735 ])
 736
 737 dnl Utility macro to avoid retyping includes all the time
 738 m4_define([FRR_INCLUDES],
 739 [#ifdef SUNOS_5
 740 #define _XPG4_2
 741 #define __EXTENSIONS__
 742 #endif
 743 #include <stdio.h>
 744 #include <stdlib.h>
 745 #include <stddef.h>
 746 #include <sys/types.h>
 747 /* sys/conf.h depends on param.h on FBSD at least */
 748 #include <sys/param.h>
 749 /* Required for MAXSIG */
 750 #include <signal.h>
 751 #include <sys/socket.h>
 752 #ifdef __APPLE__
 753 # define __APPLE_USE_RFC_3542
 754 #endif
 755 #include <netinet/in.h>
 756 #include <sys/time.h>
 757 #include <time.h>
 758 #include <net/if.h>
 759 ])dnl
 760
 761 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 762 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 763 dnl an additional round for it.
 764
 765 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 766
 767 m4_define([FRR_INCLUDES],
 768 FRR_INCLUDES
 769 [#if HAVE_NET_IF_VAR_H
 770 # include <net/if_var.h>
 771 #endif
 772 ])dnl
 773
 774 AC_CHECK_HEADERS([netinet/in_var.h \
 775         net/if_dl.h net/netopt.h \
 776         inet/nd.h netinet/ip_icmp.h \
 777         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 778         [], [], FRR_INCLUDES)
 779
 780 AC_CHECK_HEADERS([ucontext.h], [], [],
 781 [#ifndef __USE_GNU
 782 #define __USE_GNU
 783 #endif /* __USE_GNU */
 784 FRR_INCLUDES
 785 ])
 786
 787 m4_define([UCONTEXT_INCLUDES],
 788 [#include <ucontext.h>])dnl
 789
 790 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 791   [], [], [UCONTEXT_INCLUDES])
 792 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 793   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 794    [], [], [UCONTEXT_INCLUDES])],
 795   [], [UCONTEXT_INCLUDES])
 796 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 797   [], [], [UCONTEXT_INCLUDES])
 798
 799 m4_define([FRR_INCLUDES],
 800 FRR_INCLUDES
 801 [
 802 #include <sys/un.h>
 803 #include <netinet/in_systm.h>
 804 #if HAVE_NETINET_IN_VAR_H
 805 # include <netinet/in_var.h>
 806 #endif
 807 #if HAVE_NET_IF_DL_H
 808 # include <net/if_dl.h>
 809 #endif
 810 #if HAVE_NET_NETOPT_H
 811 # include <net/netopt.h>
 812 #endif
 813 #include <net/route.h>
 814 #if HAVE_INET_ND_H
 815 # include <inet/nd.h>
 816 #endif
 817 #include <arpa/inet.h>
 818 /* Required for IDRP */
 819 #if HAVE_NETINET_IP_ICMP_H
 820 # include <netinet/ip_icmp.h>
 821 #endif
 822 ])dnl
 823
 824 dnl V6 headers are checked below, after we check for v6
 825
 826 AC_MSG_CHECKING([which operating system interface to use])
 827 case "$host_os" in
 828   sunos* | solaris2*)
 829     AC_MSG_RESULT([Solaris])
 830
 831     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 832     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 833
 834     AC_CHECK_LIB(socket, main)
 835     AC_CHECK_LIB(nsl, main)
 836     AC_CHECK_LIB(umem, main)
 837     AC_CHECK_FUNCS([printstack], [
 838       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 839       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 840     ])
 841     CURSES=-lcurses
 842     SOLARIS="solaris"
 843     ;;
 844   linux*)
 845     AC_MSG_RESULT([Linux])
 846
 847     AC_DEFINE(GNU_LINUX,,GNU Linux)
 848     AC_DEFINE(HAVE_NETLINK,,netlink)
 849     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 850
 851     dnl Linux has a compilation problem with mixing
 852     dnl netinet/in.h and linux/in6.h they are not
 853     dnl compatible.  There has been discussion on
 854     dnl how to fix it but no real progress on implementation
 855     dnl when they fix it, remove this
 856     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 857
 858     AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
 859     ;;
 860   openbsd*)
 861     AC_MSG_RESULT([OpenBSD])
 862
 863     AC_DEFINE(OPEN_BSD,,OpenBSD)
 864     AC_DEFINE(KAME,1,KAME IPv6)
 865
 866     if test "x${enable_pimd}" != "xno"; then
 867       case "$host_os" in
 868       openbsd6.0)
 869         ;;
 870       openbsd[6-9]*)
 871         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 872         ;;
 873       esac
 874     fi
 875     ;;
 876   *)
 877     AC_MSG_RESULT([BSD])
 878
 879     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 880     AC_DEFINE(KAME,1,KAME IPv6)
 881     ;;
 882 esac
 883
 884 AC_SYS_LARGEFILE
 885
 886 dnl ---------------------
 887 dnl Integrated VTY option
 888 dnl ---------------------
 889 case "${enable_vtysh}" in
 890   "no") VTYSH="";;
 891   *)    VTYSH="vtysh";
 892          AC_DEFINE(VTYSH,,VTY shell)
 893 dnl      Vtysh uses libreadline, which looks for termcap functions at
 894 dnl      configure time.  We follow readlines search order.
 895 dnl      The required procedures are in libtermcap on NetBSD, in
 896 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 897          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 898            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 899              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 900                [AC_CHECK_LIB(ncurses, tputs,
 901                              LIBREADLINE="$LIBREADLINE -lncurses")]
 902               )]
 903             )]
 904           )
 905          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
 906                       "$LIBREADLINE")
 907          if test $ac_cv_lib_readline_main = no; then
 908            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 909          fi
 910          AC_CHECK_HEADER(readline/history.h)
 911          if test $ac_cv_header_readline_history_h = no;then
 912            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 913          fi
 914          AC_CHECK_LIB(readline, rl_completion_matches,
 915                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 916          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 917            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 918          fi
 919          ;;
 920 esac
 921 AC_SUBST(LIBREADLINE)
 922 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
 923
 924 dnl ----------
 925 dnl PAM module
 926 dnl
 927 dnl FRR detects the PAM library it is built against by checking for a
 928 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
 929 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
 930 dnl openpam.h doesn't do that, although depends on the header too. Hence a
 931 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
 932 dnl of OpenPAM.
 933 dnl ----------
 934 if test "$with_libpam" = "yes"; then
 935   AC_CHECK_HEADER([security/pam_misc.h],
 936     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 937      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 938      pam_conv_func="misc_conv"
 939     ],
 940     [], FRR_INCLUDES)
 941   AC_CHECK_HEADER([security/openpam.h],
 942     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 943      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 944      pam_conv_func="openpam_ttyconv"
 945     ],
 946     [], FRR_INCLUDES[#include <security/pam_appl.h>])
 947   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 948     AC_MSG_WARN([*** pam support will not be built ***])
 949     with_libpam="no"
 950   fi
 951 fi
 952
 953 if test "$with_libpam" = "yes"; then
 954 dnl took this test from proftpds configure.in and suited to our needs
 955 dnl -------------------------------------------------------------------------
 956 dnl
 957 dnl This next check looks funky due to a linker problem with some versions
 958 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 959 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 960 dnl with RedHat 6.2 and Debian 2.2 or better.
 961 AC_CHECK_LIB(pam, pam_start,
 962   [AC_CHECK_LIB(pam, $pam_conv_func,
 963     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 964      LIBPAM="-lpam"],
 965     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 966      LIBPAM="-lpam -lpam_misc"]
 967     )
 968   ],
 969
 970   [AC_CHECK_LIB(pam, pam_end,
 971     [AC_CHECK_LIB(pam, $pam_conv_func,
 972       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 973        LIBPAM="-lpam -ldl"],
 974       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 975        LIBPAM="-lpam -ldl -lpam_misc"]
 976      )
 977   ],AC_MSG_WARN([*** pam support will not be built ***]),
 978   [-ldl])
 979   ]
 980 )
 981 fi
 982 AC_SUBST(LIBPAM)
 983
 984 dnl -------------------------------
 985 dnl Endian-ness check
 986 dnl -------------------------------
 987 AC_WORDS_BIGENDIAN
 988
 989 dnl -------------------------------
 990 dnl check the size in byte of the C
 991 dnl -------------------------------
 992 dnl AC_CHECK_SIZEOF(char)
 993 dnl AC_CHECK_SIZEOF(int)
 994 dnl AC_CHECK_SIZEOF(short)
 995 dnl AC_CHECK_SIZEOF(long)
 996
 997 dnl ----------------------------
 998 dnl check existance of functions
 999 dnl ----------------------------
1000 AC_FUNC_FNMATCH
1001 AC_FUNC_FORK
1002 AC_FUNC_MKTIME
1003 AC_FUNC_STAT
1004
1005 dnl -------------------------------
1006 dnl bgpd needs pow() and hence libm
1007 dnl -------------------------------
1008 TMPLIBS="$LIBS"
1009 AC_CHECK_HEADER([math.h],
1010   [AC_CHECK_LIB([m], [pow],
1011     [LIBM="-lm"
1012      LIBS="$LIBS $LIBM"
1013      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1014     ])
1015 ])
1016 if test x"$LIBM" = x ; then
1017   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1018 fi
1019 LIBS="$TMPLIBS"
1020 AC_SUBST(LIBM)
1021
1022 AC_CHECK_FUNCS([ppoll], [
1023   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1024 ])
1025 AC_CHECK_FUNCS([pollts], [
1026   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1027 ])
1028
1029 dnl ---------------
1030 dnl other functions
1031 dnl ---------------
1032 AC_CHECK_FUNCS([ \
1033         strlcat strlcpy \
1034         getgrouplist])
1035
1036 AC_CHECK_HEADER([asm-generic/unistd.h],
1037                 [AC_CHECK_DECL(__NR_setns,
1038                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1039                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1040                                ])
1041                  AC_CHECK_FUNCS(setns)]
1042                )
1043
1044 dnl --------------------------
1045 dnl Determine IS-IS I/O method
1046 dnl --------------------------
1047 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1048 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1049 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1050 AC_CHECK_HEADER(net/bpf.h)
1051 AC_CHECK_HEADER(sys/dlpi.h)
1052 AC_MSG_CHECKING(zebra IS-IS I/O method)
1053
1054 case "$host_os" in
1055   linux*)
1056     AC_MSG_RESULT(pfpacket)
1057     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1058     ;;
1059   solaris* | sunos*)
1060     AC_MSG_RESULT(DLPI)
1061     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1062     ;;
1063   *)
1064     if test $ac_cv_header_net_bpf_h = no; then
1065       if test $ac_cv_header_sys_dlpi_h = no; then
1066         AC_MSG_RESULT(none)
1067         if test "${enable_isisd}" = yes; then
1068           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1069         fi
1070         AC_MSG_WARN([*** IS-IS support will not be built ***])
1071         enable_isisd="no"
1072       else
1073         AC_MSG_RESULT(DLPI)
1074       fi
1075       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1076     else
1077       AC_MSG_RESULT(BPF)
1078       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1079     fi
1080     ;;
1081 esac
1082 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1083
1084 dnl ------------------------------------
1085 dnl check for broken CMSG_FIRSTHDR macro
1086 dnl ------------------------------------
1087 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1088 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1089 #ifdef SUNOS_5
1090 #define _XPG4_2
1091 #define __EXTENSIONS__
1092 #endif
1093 #include <stdlib.h>
1094 #include <sys/types.h>
1095 #include <sys/socket.h>
1096
1097 main()
1098 {
1099   struct msghdr msg;
1100   char buf[4];
1101
1102   msg.msg_control = buf;
1103   msg.msg_controllen = 0;
1104
1105   if (CMSG_FIRSTHDR(&msg) != NULL)
1106     exit(0);
1107   exit (1);
1108 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1109 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1110
1111 dnl ---------------------------------------------------------------
1112 dnl figure out how to specify an interface in multicast sockets API
1113 dnl ---------------------------------------------------------------
1114 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1115
1116 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1117         #include <sys/socket.h>
1118         #include <netinet/in.h>
1119         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1120         #include <linux/types.h>
1121 ])
1122
1123 m4_define([FRR_INCLUDES],
1124 FRR_INCLUDES
1125 [#if HAVE_LINUX_MROUTE_H
1126 # include <linux/mroute.h>
1127 #endif
1128 ])dnl
1129
1130 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1131         #include <sys/socket.h>
1132         #include <sys/types.h>
1133         #include <netinet/in.h>
1134         #include <net/route.h>
1135 ])
1136
1137 m4_define([FRR_INCLUDES],
1138 FRR_INCLUDES
1139 [#if HAVE_NETINET_IP_MROUTE_H
1140 # include <netinet/ip_mroute.h>
1141 #endif
1142 ])dnl
1143
1144 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1145 AC_TRY_COMPILE([#include <sys/param.h>],
1146 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1147   return (0);
1148 #else
1149   #error No support for BSD struct ip_mreq hack detected
1150 #endif],[AC_MSG_RESULT(yes)
1151 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1152 AC_MSG_RESULT(no))
1153
1154 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1155 AC_TRY_COMPILE([
1156 #include <sys/types.h>
1157 #include <netinet/in.h>
1158 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1159 ], [AC_MSG_RESULT(yes)
1160 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1161 AC_MSG_RESULT(no))
1162
1163 dnl ---------------------------------------------------------------
1164 dnl figure out how to check link-state
1165 dnl ---------------------------------------------------------------
1166 AC_CHECK_HEADER( [net/if_media.h],
1167   [m4_define([LINK_DETECT_INCLUDES],
1168     FRR_INCLUDES
1169     [#include <net/if_media.h>
1170   ])
1171   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1172     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1173     [], LINK_DETECT_INCLUDES)],
1174   [],
1175   FRR_INCLUDES)
1176
1177 dnl ---------------------------------------------------------------
1178 dnl Additional, newer way to check link-state using ifi_link_state.
1179 dnl Not available in all BSD's when ifmediareq available
1180 dnl ---------------------------------------------------------------
1181 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1182   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1183   [], FRR_INCLUDES)
1184
1185 dnl ------------------------
1186 dnl TCP_MD5SIG socket option
1187 dnl ------------------------
1188
1189 AC_CHECK_HEADER([netinet/tcp.h],
1190    [m4_define([MD5_INCLUDES],
1191       FRR_INCLUDES
1192       [#include <netinet/tcp.h>
1193     ])
1194     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1195    [],
1196    FRR_INCLUDES)
1197 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1198   AC_CHECK_HEADER([linux/tcp.h],
1199        [m4_define([MD5_INCLUDES],
1200           FRR_INCLUDES
1201           [#include <linux/tcp.h>
1202         ])
1203        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1204 fi
1205
1206 dnl ----------------------------------------------------------------------------
1207 dnl figure out if domainname is available in the utsname struct (GNU extension).
1208 dnl ----------------------------------------------------------------------------
1209 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1210
1211 dnl ------------------
1212 dnl IPv6 header checks
1213 dnl ------------------
1214 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1215         netinet6/in6_var.h netinet6/nd6.h], [], [],
1216         FRR_INCLUDES)
1217
1218 m4_define([FRR_INCLUDES],dnl
1219 FRR_INCLUDES
1220 [#if HAVE_NETINET6_IN6_H
1221 #include <netinet6/in6.h>
1222 #endif
1223 #if HAVE_NETINET_IN6_VAR_H
1224 #include <netinet/in6_var.h>
1225 #endif
1226 #include <netinet/icmp6.h>
1227 #if HAVE_NETINET6_IN6_VAR_H
1228 # include <netinet6/in6_var.h>
1229 #endif
1230 #if HAVE_NETINET6_ND6_H
1231 # include <netinet6/nd6.h>
1232 #endif
1233 ])dnl
1234
1235 dnl disable doc check
1236 if test "${enable_doc}" = "no";then
1237   DOC=""
1238 else
1239   DOC="doc"
1240 fi
1241
1242 dnl --------------------
1243 dnl Daemon disable check
1244 dnl --------------------
1245 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1246
1247 if test "${enable_bgpd}" = "no";then
1248   BGPD=""
1249 else
1250   BGPD="bgpd"
1251 fi
1252 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1253
1254 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1255 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1256 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1257
1258 AS_IF([test "${enable_ldpd}" != "no"], [
1259   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1260 ])
1261
1262 NHRPD=""
1263 case "$host_os" in
1264   linux*)
1265     if test "${enable_nhrpd}" != "no"; then
1266       NHRPD="nhrpd"
1267     fi
1268     ;;
1269   *)
1270     if test "${enable_nhrpd}" = "yes"; then
1271       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1272     fi
1273     ;;
1274 esac
1275 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1276
1277 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1278
1279 if test "${enable_watchfrr}" = "no";then
1280   WATCHFRR=""
1281 else
1282   WATCHFRR="watchfrr"
1283 fi
1284 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1285
1286 OSPFCLIENT=""
1287 if test "${enable_ospfapi}" != "no";then
1288     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1289
1290   if test "${enable_ospfclient}" != "no";then
1291       OSPFCLIENT="ospfclient"
1292   fi
1293 fi
1294
1295 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1296 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1297 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1298 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1299 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1300
1301 case "${enable_pimd}" in
1302   "no" ) PIMD="";;
1303   *    ) PIMD="pimd";;
1304 esac
1305 AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
1306
1307 if test "${enable_bgp_announce}" = "no";then
1308   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1309 else
1310   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1311 fi
1312
1313 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1314   with_rfp_path="bgpd/rfp-example"
1315 fi
1316 if test "${with_rfp_path}" != "no"; then
1317   VNC_RFP_PATH="${with_rfp_path}"
1318   AC_SUBST(VNC_RFP_PATH)
1319 fi
1320
1321 if test "${enable_bgp_vnc}" != "no";then
1322   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1323   RFPTEST="${with_rfp_path}/rfptest"
1324   LIBRFP="${with_rfp_path}/librfp"
1325   RFPINC="${with_rfp_path}/librfp"
1326 else
1327   RFPTEST=
1328   LIBRFP=
1329   RFPINC="bgpd/rfp-example/librfp"
1330 fi
1331 # set
1332 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1333
1334 AC_SUBST(DOC)
1335 AC_SUBST(RFPTEST)
1336 AC_SUBST(LIBRFP)
1337 AC_SUBST(RFPINC)
1338 AC_SUBST(BGPD)
1339 AC_SUBST(WATCHFRR)
1340 AC_SUBST(ISISD)
1341 AC_SUBST(PIMD)
1342 AC_SUBST(SOLARIS)
1343 AC_SUBST(VTYSH)
1344 AC_SUBST(CURSES)
1345 AC_CHECK_LIB(crypt, crypt, [],
1346                     [AC_CHECK_LIB(crypto, DES_crypt)])
1347 AC_CHECK_LIB(resolv, res_init)
1348
1349 dnl ---------------------------
1350 dnl check system has PCRE regexp
1351 dnl ---------------------------
1352 if test "x$enable_pcreposix" = "xyes"; then
1353   AC_CHECK_LIB(pcreposix, regexec, [], [
1354     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1355   ])
1356 fi
1357 AC_SUBST(HAVE_LIBPCREPOSIX)
1358
1359 dnl ------------------
1360 dnl check C-Ares library
1361 dnl ------------------
1362 if test "${NHRPD}" != ""; then
1363   PKG_CHECK_MODULES([CARES], [libcares], , [
1364     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1365   ])
1366 fi
1367
1368
1369 dnl ------------------
1370 dnl check Net-SNMP library
1371 dnl ------------------
1372 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1373    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1374    if test x"$NETSNMP_CONFIG" = x"no"; then
1375       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1376    fi
1377    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1378    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1379    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1380    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1381 int main(void);
1382 ],
1383 [
1384 {
1385   return 0;
1386 }
1387 ])], [
1388      AC_MSG_ERROR([--enable-snmp given but not usable])])
1389    case "${enable_snmp}" in
1390      yes)
1391       SNMP_METHOD=agentx
1392       ;;
1393      smux|agentx)
1394       SNMP_METHOD="${enable_snmp}"
1395       ;;
1396      *)
1397       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1398       ;;
1399    esac
1400    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1401    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1402    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1403 fi
1404 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1405 AC_SUBST(SNMP_LIBS)
1406 AC_SUBST(SNMP_CFLAGS)
1407
1408 dnl ---------------
1409 dnl math
1410 dnl ---------------
1411 AC_SEARCH_LIBS([sqrt], [m])
1412
1413 dnl ---------------
1414 dnl dlopen & dlinfo
1415 dnl ---------------
1416 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1417   AC_MSG_ERROR([unable to find the dlopen()])
1418 ])
1419
1420 AC_CHECK_HEADERS([link.h])
1421
1422 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1423 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1424 #include <stdlib.h>
1425 #ifdef HAVE_LINK_H
1426 #include <link.h>
1427 #endif
1428 #include <dlfcn.h>
1429 ]], [[
1430   char origin[1];
1431   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1432 ]])], [
1433   AC_MSG_RESULT(yes)
1434   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1435 ], [
1436   AC_MSG_RESULT(no)
1437 ])
1438
1439 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1440 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1441 #include <stdlib.h>
1442 #ifdef HAVE_LINK_H
1443 #include <link.h>
1444 #endif
1445 #include <dlfcn.h>
1446 ]], [[
1447   struct link_map *lm = NULL;
1448   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1449 ]])], [
1450   AC_MSG_RESULT(yes)
1451   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1452 ], [
1453   AC_MSG_RESULT(no)
1454 ])
1455
1456
1457 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1458
1459 dnl ---------------------------
1460 dnl sockaddr and netinet checks
1461 dnl ---------------------------
1462 AC_CHECK_TYPES([
1463         struct sockaddr_dl,
1464         struct vifctl, struct mfcctl, struct sioc_sg_req,
1465         vifi_t, struct sioc_vif_req, struct igmpmsg,
1466         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1467         struct nd_opt_adv_interval, struct rt_addrinfo,
1468         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1469         [], [], FRR_INCLUDES)
1470
1471 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1472         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1473         struct sockaddr_dl.sdl_len,
1474         struct if6_aliasreq.ifra_lifetime,
1475         struct nd_opt_adv_interval.nd_opt_ai_type],
1476         [], [], FRR_INCLUDES)
1477
1478 dnl ---------------------------
1479 dnl IRDP/pktinfo/icmphdr checks
1480 dnl ---------------------------
1481
1482 AC_CHECK_TYPES([struct in_pktinfo], [
1483   AC_CHECK_TYPES([struct icmphdr], [
1484     IRDP=true
1485   ], [
1486     IRDP=false
1487   ], [FRR_INCLUDES])
1488 ], [
1489   IRDP=false
1490 ], [FRR_INCLUDES])
1491
1492 case "${enable_irdp}" in
1493 yes)
1494   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1495   ;;
1496 no)
1497   IRDP=false
1498   ;;
1499 esac
1500
1501 AM_CONDITIONAL(IRDP, $IRDP)
1502
1503 dnl -----------------------
1504 dnl checking for IP_PKTINFO
1505 dnl -----------------------
1506 AC_MSG_CHECKING(for IP_PKTINFO)
1507 AC_TRY_COMPILE([#include <netdb.h>], [
1508   int opt = IP_PKTINFO;
1509 ], [
1510   AC_MSG_RESULT(yes)
1511   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1512 ], [
1513   AC_MSG_RESULT(no)
1514 ])
1515
1516 dnl ---------------------------
1517 dnl checking for IP_RECVDSTADDR
1518 dnl ---------------------------
1519 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1520 AC_TRY_COMPILE([#include <netinet/in.h>], [
1521   int opt = IP_RECVDSTADDR;
1522 ], [
1523   AC_MSG_RESULT(yes)
1524   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1525 ], [
1526   AC_MSG_RESULT(no)
1527 ])
1528
1529 dnl ----------------------
1530 dnl checking for IP_RECVIF
1531 dnl ----------------------
1532 AC_MSG_CHECKING(for IP_RECVIF)
1533 AC_TRY_COMPILE([#include <netinet/in.h>], [
1534   int opt = IP_RECVIF;
1535 ], [
1536   AC_MSG_RESULT(yes)
1537   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1538 ], [
1539   AC_MSG_RESULT(no)
1540 ])
1541
1542 dnl ----------------------
1543 dnl checking for SO_BINDANY
1544 dnl ----------------------
1545 AC_MSG_CHECKING(for SO_BINDANY)
1546 AC_TRY_COMPILE([#include <sys/socket.h>], [
1547   int opt = SO_BINDANY;
1548 ], [
1549   AC_MSG_RESULT(yes)
1550   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1551 ], [
1552   AC_MSG_RESULT(no)
1553 ])
1554
1555 dnl ----------------------
1556 dnl checking for IP_FREEBIND
1557 dnl ----------------------
1558 AC_MSG_CHECKING(for IP_FREEBIND)
1559 AC_TRY_COMPILE([#include <netinet/in.h>], [
1560   int opt = IP_FREEBIND;
1561 ], [
1562   AC_MSG_RESULT(yes)
1563   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1564 ], [
1565   AC_MSG_RESULT(no)
1566 ])
1567
1568 dnl --------------------------------------
1569 dnl checking for be32dec existence or not
1570 dnl --------------------------------------
1571 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1572                [#include <sys/endian.h>])
1573
1574 dnl --------------------------------------
1575 dnl checking for clock_time monotonic struct and call
1576 dnl --------------------------------------
1577 AC_CHECK_DECL(CLOCK_MONOTONIC,
1578         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1579          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1580 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1581
1582 dnl --------------------------------------
1583 dnl checking for flex and bison
1584 dnl --------------------------------------
1585
1586 AM_PROG_LEX
1587 AC_MSG_CHECKING(version of flex)
1588 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1589 frr_ac_flex_version="${frr_ac_flex_version##* }"
1590 AC_MSG_RESULT([$frr_ac_flex_version])
1591 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1592   LEX="$SHELL $missing_dir/missing flex"
1593   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1594     AC_MSG_WARN([using pregenerated flex output files])
1595   else
1596     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1597   fi
1598   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1599   AC_SUBST([LEXLIB], [''])
1600 ])
1601
1602 AC_PROG_YACC
1603 dnl thanks GNU bison for this b*llshit...
1604 AC_MSG_CHECKING(version of bison)
1605 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1606 frr_ac_bison_version="${frr_ac_bison_version##* }"
1607 frr_ac_bison_missing="false"
1608 case "x${frr_ac_bison_version}" in
1609   x2.7*)
1610     BISON_OPENBRACE='"'
1611     BISON_CLOSEBRACE='"'
1612     BISON_VERBOSE=''
1613     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1614     ;;
1615   x2.*|x1.*)
1616     AC_MSG_RESULT([$frr_ac_bison_version])
1617     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1618     frr_ac_bison_missing="true"
1619     ;;
1620   x)
1621     AC_MSG_RESULT([none])
1622     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1623     frr_ac_bison_missing="true"
1624     ;;
1625   *)
1626     BISON_OPENBRACE='{'
1627     BISON_CLOSEBRACE='}'
1628     BISON_VERBOSE='-Dparse.error=verbose'
1629     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1630     ;;
1631 esac
1632 AC_SUBST(BISON_OPENBRACE)
1633 AC_SUBST(BISON_CLOSEBRACE)
1634 AC_SUBST(BISON_VERBOSE)
1635
1636 if $frr_ac_bison_missing; then
1637   YACC="$SHELL $missing_dir/missing bison -y"
1638   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1639     AC_MSG_WARN([using pregenerated bison output files])
1640   else
1641     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1642   fi
1643 fi
1644
1645 dnl -------------------
1646 dnl capabilities checks
1647 dnl -------------------
1648 if test "${enable_capabilities}" != "no"; then
1649   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1650   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1651     [AC_MSG_RESULT(yes)
1652      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1653      frr_ac_keepcaps="yes"],
1654      AC_MSG_RESULT(no)
1655   )
1656   if test x"${frr_ac_keepcaps}" = x"yes"; then
1657     AC_CHECK_HEADERS(sys/capability.h)
1658   fi
1659   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1660     AC_CHECK_LIB(cap, cap_init,
1661       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1662        LIBCAP="-lcap"
1663        frr_ac_lcaps="yes"]
1664     )
1665   else
1666     AC_CHECK_HEADERS(priv.h,
1667      [AC_MSG_CHECKING(Solaris style privileges are available)
1668       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1669           [AC_MSG_RESULT(yes)
1670            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1671            frr_ac_scaps="yes"],
1672            AC_MSG_RESULT(no)
1673       )
1674      ]
1675    )
1676   fi
1677   if test x"${frr_ac_scaps}" = x"yes" \
1678        -o x"${frr_ac_lcaps}" = x"yes"; then
1679     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1680   fi
1681 fi
1682 AC_SUBST(LIBCAP)
1683
1684 dnl ---------------------------
1685 dnl check for glibc 'backtrace'
1686 dnl ---------------------------
1687 if test x"${enable_backtrace}" != x"no" ; then
1688   backtrace_ok=no
1689   AC_CHECK_HEADER([execinfo.h], [
1690     AC_SEARCH_LIBS([backtrace], [execinfo], [
1691       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1692       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1693       backtrace_ok=yes
1694     ],, [-lm])
1695   ])
1696
1697   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1698     dnl user explicitly requested backtrace but we failed to find support
1699     AC_MSG_FAILURE([failed to find backtrace support])
1700   fi
1701 fi
1702
1703 dnl -----------------------------------------
1704 dnl check for malloc mallinfo struct and call
1705 dnl this must try and link using LIBS, in
1706 dnl order to check no alternative allocator
1707 dnl has been specified, which might not provide
1708 dnl mallinfo, e.g. such as Umem on Solaris.
1709 dnl -----------------------------------------
1710 AC_CHECK_HEADER([malloc.h],
1711  [AC_MSG_CHECKING(whether mallinfo is available)
1712   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1713                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1714       [AC_MSG_RESULT(yes)
1715        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1716        AC_MSG_RESULT(no)
1717   )
1718  ], [], FRR_INCLUDES)
1719
1720 dnl ------
1721 dnl ZeroMQ
1722 dnl ------
1723 if test "x$enable_zeromq" != "xno"; then
1724   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1725     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1726     ZEROMQ=true
1727   ], [
1728     if test "x$enable_zeromq" = "xyes"; then
1729       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1730     fi
1731   ])
1732 fi
1733 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1734
1735 dnl ----------
1736 dnl configure date
1737 dnl ----------
1738 CONFDATE=`date '+%Y%m%d'`
1739 AC_SUBST(CONFDATE)
1740
1741 dnl ------------------------------
1742 dnl set paths for state directory
1743 dnl ------------------------------
1744 AC_MSG_CHECKING(directory to use for state file)
1745 if test "${prefix}" = "NONE"; then
1746   frr_statedir_prefix="";
1747 else
1748   frr_statedir_prefix=${prefix}
1749 fi
1750 if test "${localstatedir}" = '${prefix}/var'; then
1751   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1752                         ${frr_statedir_prefix}/var/adm dnl
1753                         ${frr_statedir_prefix}/etc dnl
1754                         /var/run        dnl
1755                         /var/adm        dnl
1756                         /etc            dnl
1757                         /dev/null;
1758   do
1759     test -d $FRR_STATE_DIR && break
1760   done
1761   frr_statedir=$FRR_STATE_DIR
1762 else
1763   frr_statedir=${localstatedir}
1764 fi
1765 if test $frr_statedir = "/dev/null"; then
1766     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1767 fi
1768 AC_MSG_RESULT(${frr_statedir})
1769 AC_SUBST(frr_statedir)
1770
1771 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1772 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1773 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1774
1775 dnl autoconf does this, but it does it too late...
1776 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1777 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1778
1779 dnl get the full path, recursing through variables...
1780 vtysh_bin="$bindir/vtysh"
1781 for I in 1 2 3 4 5 6 7 8 9 10; do
1782         eval vtysh_bin="\"$vtysh_bin\""
1783 done
1784 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1785
1786 CFG_SYSCONF="$sysconfdir"
1787 CFG_SBIN="$sbindir"
1788 CFG_STATE="$frr_statedir"
1789 CFG_MODULE="$moduledir"
1790 for I in 1 2 3 4 5 6 7 8 9 10; do
1791         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1792         eval CFG_SBIN="\"$CFG_SBIN\""
1793         eval CFG_STATE="\"$CFG_STATE\""
1794         eval CFG_MODULE="\"$CFG_MODULE\""
1795 done
1796 AC_SUBST(CFG_SYSCONF)
1797 AC_SUBST(CFG_SBIN)
1798 AC_SUBST(CFG_STATE)
1799 AC_SUBST(CFG_MODULE)
1800 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1801
1802 dnl ---------------------------
1803 dnl Check htonl works correctly
1804 dnl ---------------------------
1805 AC_MSG_CHECKING(for working htonl)
1806 AC_CACHE_VAL(ac_cv_htonl_works,
1807  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1808                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1809  ]
1810 )
1811 AC_MSG_RESULT($ac_cv_htonl_works)
1812
1813 AC_CONFIG_FILES([Makefile
1814           bgpd/Makefile watchfrr/Makefile
1815           vtysh/Makefile
1816           doc/Makefile tests/Makefile
1817           bgpd/rfp-example/rfptest/Makefile bgpd/rfp-example/librfp/Makefile
1818           pimd/Makefile
1819           tools/Makefile
1820           redhat/frr.spec
1821           snapcraft/snapcraft.yaml
1822           lib/version.h
1823           tests/lib/cli/test_cli.refout
1824           doc/defines.texi
1825           doc/bgpd.8
1826           doc/isisd.8
1827           doc/ospf6d.8
1828           doc/ospfclient.8
1829           doc/ospfd.8
1830           doc/ldpd.8
1831           doc/ripd.8
1832           doc/eigrpd.8
1833           doc/ripngd.8
1834           doc/pimd.8
1835           doc/nhrpd.8
1836           doc/vtysh.1
1837           doc/watchfrr.8
1838           doc/zebra.8
1839           doc/frr.1
1840           doc/frr-args.8
1841           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1842           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1843           pkgsrc/eigrpd.sh])
1844
1845 if test "${enable_bgp_vnc}" != "no"; then
1846    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
1847       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
1848    fi
1849 fi
1850
1851 AC_CONFIG_FILES([solaris/Makefile])
1852
1853 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1854
1855 AC_CONFIG_COMMANDS([lib/route_types.h], [
1856         dst="${ac_abs_top_builddir}/lib/route_types.h"
1857         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1858                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1859                 > "${dst}.tmp"
1860         test -f "${dst}" \
1861                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1862                 && rm "${dst}.tmp" \
1863                 || mv "${dst}.tmp" "${dst}"
1864 ], [
1865         PERL="$PERL"
1866 ])
1867
1868 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1869     AC_CONFIG_COMMANDS([lib/gitversion.h], [
1870         dst="${ac_abs_top_builddir}/lib/gitversion.h"
1871         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1872                 "${ac_abs_top_srcdir}" \
1873                 > "${dst}.tmp"
1874         test -f "${dst}" \
1875                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1876                 && rm "${dst}.tmp" \
1877                 || mv "${dst}.tmp" "${dst}"
1878     ], [
1879         PERL="$PERL"
1880     ])
1881 ])
1882
1883 ## Hack, but working solution to avoid rebuilding of frr.info.
1884 ## It's already in CVS until texinfo 4.7 is more common.
1885 AC_OUTPUT
1886
1887 echo "
1888 FRRouting configuration
1889 ------------------------------
1890 FRR version             : ${PACKAGE_VERSION}
1891 host operating system   : ${host_os}
1892 source code location    : ${srcdir}
1893 compiler                : ${CC}
1894 compiler flags          : ${CFLAGS}
1895 make                    : ${MAKE-make}
1896 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1897 state file directory    : ${frr_statedir}
1898 config file directory   : `eval echo \`echo ${sysconfdir}\``
1899 example directory       : `eval echo \`echo ${exampledir}\``
1900 module directory        : ${CFG_MODULE}
1901 user to run as          : ${enable_user}
1902 group to run as         : ${enable_group}
1903 group for vty sockets   : ${enable_vty_group}
1904 config file mask        : ${enable_configfile_mask}
1905 log file mask           : ${enable_logfile_mask}
1906 zebra protobuf enabled  : ${have_protobuf:-no}
1907
1908 The above user and group must have read/write access to the state file
1909 directory and to the config files in the config file directory."