configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl AddressSanitizer support
 193 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 194               [enabled AddressSanitizer support for detecting a wide variety of \
 195                memory allocation and deallocation errors]), \
 196               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 197               ASAN_FLAGS="-fsanitize=address"
 198               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 199               AC_SUBST([ASAN_FLAGS])
 200               AC_SUBST([SAN_CLIPPY_FLAGS])
 201               LIBS="-ldl $LIBS"
 202               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 203                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 204               ])
 205
 206 dnl ThreadSanitizer support
 207 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 208               [enabled ThreadSanitizer support for detecting data races]), \
 209               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 210               TSAN_FLAGS="-fsanitize=thread"
 211               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 212               AC_SUBST([TSAN_FLAGS])
 213               AC_SUBST([SAN_CLIPPY_FLAGS])
 214               LIBS="-ldl $LIBS"
 215               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 216                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 217               ])
 218
 219 dnl MemorySanitizer support
 220 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 221               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 222               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 223               MSAN_FLAGS="-fsanitize=memory -fPIE -pie"
 224               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 225               AC_SUBST([MSAN_FLAGS])
 226               AC_SUBST([SAN_CLIPPY_FLAGS])
 227               LIBS="-ldl $LIBS"
 228               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 229                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 230               ])
 231
 232 dnl if the user has specified any CFLAGS, override our settings
 233 if test "x${enable_gcov}" = "xyes"; then
 234    if test "z$orig_cflags" = "z"; then
 235       AC_C_FLAG([-coverage])
 236       AC_C_FLAG([-O0])
 237    fi
 238
 239    LDFLAGS="${LDFLAGS} -lgcov"
 240 elif test "x${enable_dev_build}" = "xyes"; then
 241    AC_DEFINE(DEV_BUILD,,Build for development)
 242    if test "z$orig_cflags" = "z"; then
 243       AC_C_FLAG([-g3])
 244       AC_C_FLAG([-O0])
 245    fi
 246 else
 247    if test "z$orig_cflags" = "z"; then
 248       AC_C_FLAG([-g])
 249       AC_C_FLAG([-Os], [
 250         AC_C_FLAG([-O2])
 251       ])
 252    fi
 253 fi
 254 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 255
 256 dnl always want these CFLAGS
 257 AC_C_FLAG([-fno-omit-frame-pointer])
 258 AC_C_FLAG([-funwind-tables])
 259 AC_C_FLAG([-Wall])
 260 AC_C_FLAG([-Wextra])
 261 AC_C_FLAG([-Wmissing-prototypes])
 262 AC_C_FLAG([-Wmissing-declarations])
 263 AC_C_FLAG([-Wpointer-arith])
 264 AC_C_FLAG([-Wbad-function-cast])
 265 AC_C_FLAG([-Wwrite-strings])
 266 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 267   AC_C_FLAG([-Wcast-qual])
 268   AC_C_FLAG([-Wstrict-prototypes])
 269   AC_C_FLAG([-Wmissing-noreturn])
 270   AC_C_FLAG([-Wmissing-format-attribute])
 271   AC_C_FLAG([-Wunreachable-code])
 272   AC_C_FLAG([-Wpacked])
 273   AC_C_FLAG([-Wpadded])
 274 else
 275   AC_C_FLAG([-Wno-unused-result])
 276 fi
 277 AC_C_FLAG([-Wno-unused-parameter])
 278 AC_C_FLAG([-Wno-missing-field-initializers])
 279
 280 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 281 dnl for some reason the string consts get 'promoted' to char *,
 282 dnl triggering a const to non-const conversion warning.
 283 AC_C_FLAG([-diag-disable 3179])
 284
 285 if test x"${enable_werror}" = x"yes" ; then
 286   WERROR="-Werror"
 287 fi
 288 AC_SUBST(WERROR)
 289
 290 dnl need link on this one, not compile
 291 AC_LANG_PUSH(C)
 292 ac_ld_flag_save="$LDFLAGS"
 293 LDFLAGS="$LDFLAGS -rdynamic"
 294 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 295 AC_LINK_IFELSE(
 296         [AC_LANG_PROGRAM([[]])],
 297         [AC_MSG_RESULT([yes])],
 298         [
 299                 LDFLAGS="$ac_ld_flag_save"
 300                 AC_MSG_RESULT([no])
 301         ])
 302 AC_LANG_POP(C)
 303
 304 dnl ----------
 305 dnl Essentials
 306 dnl ----------
 307
 308 AX_PTHREAD([
 309   CC="$PTHREAD_CC"
 310   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 311   LIBS="$PTHREAD_LIBS $LIBS"
 312 ], [
 313   AC_MSG_FAILURE([This FRR version needs pthreads])
 314 ])
 315
 316 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 317                 [frr_cv_pthread_condattr_setclock=yes],
 318                 [frr_cv_pthread_condattr_setclock=no])
 319 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 320   AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK, 1, [Have pthread.h pthread_condattr_setclock])
 321 fi
 322
 323 dnl --------------
 324 dnl Check programs
 325 dnl --------------
 326 AC_PROG_INSTALL
 327 AC_PROG_LN_S
 328 AC_PROG_MAKE_SET
 329 AC_CHECK_TOOL(AR, ar)
 330
 331 dnl -----------------
 332 dnl System extensions
 333 dnl -----------------
 334 AC_GNU_SOURCE
 335
 336 dnl -------
 337 dnl libtool
 338 dnl -------
 339 LT_INIT
 340
 341 dnl ----------------------
 342 dnl Packages configuration
 343 dnl ----------------------
 344 AC_ARG_WITH(pkg-extra-version,
 345         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 346         [EXTRAVERSION=$withval],)
 347 AC_ARG_WITH(pkg-git-version,
 348         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 349         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 350 AC_ARG_WITH(vtysh_pager,
 351         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 352         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 353 AC_ARG_ENABLE(vtysh,
 354   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 355 AC_ARG_ENABLE(doc,
 356   AS_HELP_STRING([--disable-doc], [do not build docs]))
 357 AC_ARG_ENABLE(doc-html,
 358   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 359 AC_ARG_ENABLE(zebra,
 360   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 361 AC_ARG_ENABLE(bgpd,
 362   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 363 AC_ARG_ENABLE(ripd,
 364   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 365 AC_ARG_ENABLE(ripngd,
 366   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 367 AC_ARG_ENABLE(ospfd,
 368   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 369 AC_ARG_ENABLE(ospf6d,
 370   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 371 AC_ARG_ENABLE(ldpd,
 372   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 373 AC_ARG_ENABLE(nhrpd,
 374   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 375 AC_ARG_ENABLE(eigrpd,
 376   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 377 AC_ARG_ENABLE(babeld,
 378   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 379 AC_ARG_ENABLE(watchfrr,
 380   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 381 AC_ARG_ENABLE(isisd,
 382   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 383 AC_ARG_ENABLE(pimd,
 384   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 385 AC_ARG_ENABLE(pbrd,
 386   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 387 AC_ARG_ENABLE(sharpd,
 388   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 389 AC_ARG_ENABLE(staticd,
 390   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 391 AC_ARG_ENABLE(fabricd,
 392   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 393 AC_ARG_ENABLE(bgp-announce,
 394   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 395 AC_ARG_ENABLE(bgp-vnc,
 396   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 397 AC_ARG_ENABLE(snmp,
 398   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 399 AC_ARG_ENABLE(zeromq,
 400   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 401 AC_ARG_WITH(libpam,
 402   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 403 AC_ARG_ENABLE(ospfapi,
 404   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 405 AC_ARG_ENABLE(ospfclient,
 406   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 407                           (this is the default if --disable-ospfapi is set)]))
 408 AC_ARG_ENABLE(multipath,
 409   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 410 AC_ARG_ENABLE(user,
 411   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 412 AC_ARG_ENABLE(group,
 413   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 414 AC_ARG_ENABLE(vty_group,
 415   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 416 AC_ARG_ENABLE(configfile_mask,
 417   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 418 AC_ARG_ENABLE(logfile_mask,
 419   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 420 AC_ARG_ENABLE(shell_access,
 421   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 422 AC_ARG_ENABLE(realms,
 423   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 424 AC_ARG_ENABLE(rtadv,
 425   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 426 AC_ARG_ENABLE(irdp,
 427   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 428 AC_ARG_ENABLE(capabilities,
 429   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 430 AC_ARG_ENABLE(rusage,
 431   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 432 AC_ARG_ENABLE(gcc_ultra_verbose,
 433   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 434 AC_ARG_ENABLE(backtrace,
 435   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 436 AC_ARG_ENABLE(time-check,
 437   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 438 AC_ARG_ENABLE(pcreposix,
 439   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 440 AC_ARG_ENABLE(fpm,
 441   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 442 AC_ARG_ENABLE(systemd,
 443   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 444 AC_ARG_ENABLE(werror,
 445   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 446 AC_ARG_ENABLE(cumulus,
 447   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 448 AC_ARG_ENABLE(datacenter,
 449   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 450 AC_ARG_ENABLE(fuzzing,
 451   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 452 AC_ARG_ENABLE(netlink_fuzzing,
 453   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 454 AC_ARG_ENABLE(rr-semantics,
 455   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 456 AC_ARG_ENABLE([protobuf],
 457   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 458 AC_ARG_ENABLE([oldvpn_commands],
 459   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 460 AC_ARG_ENABLE(rpki,
 461   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 462 AC_ARG_ENABLE([clippy-only],
 463   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 464 AC_ARG_ENABLE([numeric_version],
 465   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 466 AC_ARG_ENABLE([gcov],
 467   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 468 AC_ARG_ENABLE(bfdd,
 469   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 470
 471 AS_IF([test "${enable_clippy_only}" != "yes"], [
 472 AC_CHECK_HEADERS(json-c/json.h)
 473 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 474 if test $ac_cv_lib_json_c_json_object_get = no; then
 475   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 476   if test $ac_cv_lib_json_json_object_get = no; then
 477       AC_MSG_ERROR([lib json is needed to compile])
 478   fi
 479 fi
 480 ])
 481
 482 AC_ARG_ENABLE([dev_build],
 483     AS_HELP_STRING([--enable-dev-build], [build for development]))
 484
 485 if test x"${enable_time_check}" != x"no" ; then
 486   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 487     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 488   else
 489     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 490   fi
 491 fi
 492
 493 case "${enable_systemd}" in
 494   "no") ;;
 495   "yes")
 496   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 497   if test $ac_cv_lib_systemd_sd_notify = no; then
 498     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 499   else
 500     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 501   fi
 502   ;;
 503   "*") ;;
 504 esac
 505
 506 if test "${enable_rr_semantics}" != "no" ; then
 507   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 508 fi
 509
 510 if test "${enable_datacenter}" = "yes" ; then
 511   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 512   DFLT_NAME="datacenter"
 513 else
 514   DFLT_NAME="traditional"
 515 fi
 516
 517 if test "${enable_fuzzing}" = "yes" ; then
 518   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 519 fi
 520
 521 if test "${enable_netlink_fuzzing}" = "yes" ; then
 522   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 523 fi
 524
 525 if test "${enable_cumulus}" = "yes" ; then
 526   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 527 fi
 528
 529 AC_SUBST(DFLT_NAME)
 530 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 531
 532 if test "${enable_shell_access}" = "yes"; then
 533    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 534 fi
 535
 536 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 537
 538 #
 539 # Python for clippy
 540 #
 541
 542 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 543   AC_MSG_CHECKING([whether we found a working Python version])
 544   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 545 #include <Python.h>
 546 #if PY_VERSION_HEX < 0x02070000
 547 #error python too old
 548 #endif
 549 int main(void);
 550 ],
 551 [
 552 {
 553   Py_Initialize();
 554   return 0;
 555 }
 556 ])], [
 557     # some python installs are missing the zlib dependency...
 558     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 559     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 560 #include <Python.h>
 561 #if PY_VERSION_HEX < 0x02070000
 562 #error python too old
 563 #endif
 564 int main(void);
 565 ],
 566 [
 567 {
 568   Py_Initialize();
 569   return 0;
 570 }
 571 ])], [
 572       m4_if([$1], [], [
 573         PYTHONCONFIG=""
 574         unset PYTHON_LIBS
 575         unset PYTHON_CFLAGS
 576       ], [$1])
 577     ])
 578   ])
 579 ])
 580
 581 AS_IF([test "$host" = "$build"], [
 582   PYTHONCONFIG=""
 583
 584   # ordering:
 585   # 1.  try python3, but respect the user's preference on which minor ver
 586   # 2.  try python, which might be py3 or py2 again on the user's preference
 587   # 3.  try python2 (can really only be 2.7 but eh)
 588   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 589   #
 590   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 591   # (AX_PYTHON does not do what we need)
 592
 593   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 594         python3-config \
 595         python-config \
 596         python2-config \
 597         python3.6-config \
 598         python3.5-config \
 599         python3.4-config \
 600         python3.3-config \
 601         python3.2-config \
 602         python2.7-config ])
 603   if test -n "$PYTHONCONFIG"; then
 604     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 605     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 606
 607     FRR_PYTHON_CHECK_WORKING([])
 608   fi
 609
 610   if test -z "$PYTHONCONFIG"; then
 611     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 612       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 613         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 614           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 615             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 616               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 617                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 618                 ])])])])])])
 619
 620
 621     FRR_PYTHON_CHECK_WORKING([
 622       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 623     ])
 624   fi
 625 ])
 626 AC_SUBST(PYTHON_CFLAGS)
 627 AC_SUBST(PYTHON_LIBS)
 628
 629 #
 630 # Logic for protobuf support.
 631 #
 632 if test "$enable_protobuf" = "yes"; then
 633    have_protobuf=yes
 634
 635    # Check for protoc-c
 636    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 637    if test "x$PROTOC_C" = "x/bin/false"; then
 638       have_protobuf=no
 639    else
 640       found_protobuf_c=no
 641       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 642                      [found_protobuf_c=yes],
 643                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 644
 645       if test "x$found_protobuf_c" = "xyes"; then
 646          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 647          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 648       else
 649         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 650                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 651       fi
 652    fi
 653 fi
 654
 655 #
 656 # Logic for old vpn commans support.
 657 #
 658 if test "$enable_oldvpn_commands" = "yes"; then
 659    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 660 fi
 661
 662 # Fail if the user explicity enabled protobuf support and we couldn't
 663 # find the compiler or libraries.
 664 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 665    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 666 fi
 667
 668 if test "x$have_protobuf" = "xyes"; then
 669    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 670 fi
 671
 672 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 673
 674 #
 675 # End of logic for protobuf support.
 676 #
 677
 678 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 679 if test "${enable_rtadv}" != "no"; then
 680   AC_MSG_RESULT(yes)
 681   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 682 else
 683   AC_MSG_RESULT(no)
 684 fi
 685
 686 if test x"${enable_user}" = x"no"; then
 687   enable_user=""
 688 else
 689   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 690     enable_user="frr"
 691   fi
 692   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 693 fi
 694
 695 if test x"${enable_group}" = x"no"; then
 696   enable_group=""
 697 else
 698   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 699     enable_group="frr"
 700   fi
 701   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 702 fi
 703
 704 if test x"${enable_vty_group}" = x"yes" ; then
 705   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 706 elif test x"${enable_vty_group}" != x""; then
 707   if test x"${enable_vty_group}" != x"no"; then
 708     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 709   fi
 710 fi
 711 AC_SUBST([enable_user])
 712 AC_SUBST([enable_group])
 713 AC_SUBST([enable_vty_group])
 714
 715 enable_configfile_mask=${enable_configfile_mask:-0600}
 716 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 717
 718 enable_logfile_mask=${enable_logfile_mask:-0600}
 719 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 720
 721 MPATH_NUM=1
 722
 723 case "${enable_multipath}" in
 724   0)
 725     MPATH_NUM=64
 726     ;;
 727   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 728     MPATH_NUM="${enable_multipath}"
 729     ;;
 730   "")
 731     ;;
 732   *)
 733     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 734     ;;
 735 esac
 736
 737 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 738
 739 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 740
 741 dnl --------------------
 742 dnl Enable code coverage
 743 dnl --------------------
 744 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 745
 746 dnl ------------------------------------
 747 dnl Alpine only accepts numeric versions
 748 dnl ------------------------------------
 749 if test "x${enable_numeric_version}" != "x" ; then
 750   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 751   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 752 fi
 753
 754 dnl -----------------------------------
 755 dnl Add extra version string to package
 756 dnl name, string and version fields.
 757 dnl -----------------------------------
 758 if test "x${EXTRAVERSION}" != "x" ; then
 759   VERSION="${VERSION}${EXTRAVERSION}"
 760   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 761   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 762   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 763 fi
 764
 765 if test "x$with_pkg_git_version" = "xyes"; then
 766         if test -d "${srcdir}/.git"; then
 767                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 768         else    with_pkg_git_version="no"
 769                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 770         fi
 771 fi
 772 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 773
 774 dnl ------------------------------------
 775 dnl Check C keywords and standard  types
 776 dnl ------------------------------------
 777 AC_C_CONST
 778 AC_C_INLINE
 779 AC_C_VOLATILE
 780 AC_HEADER_STDC
 781 dnl AC_TYPE_PID_T
 782 AC_TYPE_UID_T
 783 AC_TYPE_MODE_T
 784 AC_TYPE_SIZE_T
 785 AC_STRUCT_TM
 786
 787 dnl -------------------------
 788 dnl Check other header files.
 789 dnl -------------------------
 790 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 791         linux/version.h asm/types.h \
 792         sys/cdefs.h])
 793
 794 ac_stdatomic_ok=false
 795 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 796 AC_CHECK_HEADER([stdatomic.h],[
 797
 798   AC_MSG_CHECKING([whether _Atomic qualifier works])
 799   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 800 #include <stdatomic.h>
 801 int main(int argc, char **argv) {
 802   _Atomic int i = 0;
 803   return i;
 804 }
 805 ]])], [
 806     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 807     AC_MSG_RESULT([yes])
 808     ac_stdatomic_ok=true
 809   ], [
 810     AC_MSG_RESULT([no])
 811   ])
 812 ])
 813
 814 AS_IF([$ac_stdatomic_ok], [true], [
 815   AC_MSG_CHECKING([for __atomic_* builtins])
 816   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 817 int main(int argc, char **argv) {
 818   volatile int i = 1;
 819   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 820   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 821 }
 822 ]])], [
 823     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 824     AC_MSG_RESULT([yes])
 825   ], [
 826     AC_MSG_RESULT([no])
 827
 828     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 829     AC_MSG_CHECKING([for __sync_* builtins])
 830     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 831 int main(int argc, char **argv) {
 832   volatile int i = 1;
 833   __sync_fetch_and_sub (&i, 1);
 834   return __sync_val_compare_and_swap (&i, 0, 1);
 835 }
 836 ]])], [
 837       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 838       AC_MSG_RESULT([yes])
 839
 840       AC_MSG_CHECKING([for __sync_swap builtin])
 841       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 842 int main(int argc, char **argv) {
 843   volatile int i = 1;
 844   return __sync_swap (&i, 2);
 845 }
 846 ]])], [
 847         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 848         AC_MSG_RESULT([yes])
 849       ], [
 850         AC_MSG_RESULT([no])
 851       ])
 852
 853     ], [
 854       AC_MSG_RESULT([no])
 855       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 856     ])
 857   ])
 858 ])
 859
 860 dnl Utility macro to avoid retyping includes all the time
 861 m4_define([FRR_INCLUDES],
 862 [#ifdef SUNOS_5
 863 #define _XPG4_2
 864 #define __EXTENSIONS__
 865 #endif
 866 #include <stdio.h>
 867 #include <stdlib.h>
 868 #include <stddef.h>
 869 #include <sys/types.h>
 870 /* sys/conf.h depends on param.h on FBSD at least */
 871 #include <sys/param.h>
 872 /* Required for MAXSIG */
 873 #include <signal.h>
 874 #include <sys/socket.h>
 875 #ifdef __APPLE__
 876 # define __APPLE_USE_RFC_3542
 877 #endif
 878 #include <netinet/in.h>
 879 #include <sys/time.h>
 880 #include <time.h>
 881 #include <net/if.h>
 882 ])dnl
 883
 884 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 885 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 886 dnl an additional round for it.
 887
 888 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 889
 890 m4_define([FRR_INCLUDES],
 891 FRR_INCLUDES
 892 [#if HAVE_NET_IF_VAR_H
 893 # include <net/if_var.h>
 894 #endif
 895 ])dnl
 896
 897 AC_CHECK_HEADERS([netinet/in_var.h \
 898         net/if_dl.h net/netopt.h \
 899         inet/nd.h netinet/ip_icmp.h \
 900         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 901         [], [], FRR_INCLUDES)
 902
 903 AC_CHECK_HEADERS([ucontext.h], [], [],
 904 [#ifndef __USE_GNU
 905 #define __USE_GNU
 906 #endif /* __USE_GNU */
 907 FRR_INCLUDES
 908 ])
 909
 910 m4_define([UCONTEXT_INCLUDES],
 911 [#include <ucontext.h>])dnl
 912
 913 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 914   [], [], [UCONTEXT_INCLUDES])
 915 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 916   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 917    [], [], [UCONTEXT_INCLUDES])],
 918   [], [UCONTEXT_INCLUDES])
 919 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 920   [], [], [UCONTEXT_INCLUDES])
 921
 922 m4_define([FRR_INCLUDES],
 923 FRR_INCLUDES
 924 [
 925 #include <sys/un.h>
 926 #include <netinet/in_systm.h>
 927 #if HAVE_NETINET_IN_VAR_H
 928 # include <netinet/in_var.h>
 929 #endif
 930 #if HAVE_NET_IF_DL_H
 931 # include <net/if_dl.h>
 932 #endif
 933 #if HAVE_NET_NETOPT_H
 934 # include <net/netopt.h>
 935 #endif
 936 #include <net/route.h>
 937 #if HAVE_INET_ND_H
 938 # include <inet/nd.h>
 939 #endif
 940 #include <arpa/inet.h>
 941 /* Required for IDRP */
 942 #if HAVE_NETINET_IP_ICMP_H
 943 # include <netinet/ip_icmp.h>
 944 #endif
 945 ])dnl
 946
 947 dnl V6 headers are checked below, after we check for v6
 948
 949 AC_MSG_CHECKING([which operating system interface to use])
 950 case "$host_os" in
 951   sunos* | solaris2*)
 952     AC_MSG_RESULT([Solaris])
 953
 954     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 955     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 956
 957     AC_CHECK_LIB(socket, main)
 958     AC_CHECK_LIB(nsl, main)
 959     AC_CHECK_LIB(umem, main)
 960     AC_CHECK_FUNCS([printstack], [
 961       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 962       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 963     ])
 964     CURSES=-lcurses
 965     SOLARIS="solaris"
 966     ;;
 967   linux*)
 968     AC_MSG_RESULT([Linux])
 969
 970     AC_DEFINE(GNU_LINUX,,GNU Linux)
 971     AC_DEFINE(HAVE_NETLINK,,netlink)
 972     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 973
 974     dnl Linux has a compilation problem with mixing
 975     dnl netinet/in.h and linux/in6.h they are not
 976     dnl compatible.  There has been discussion on
 977     dnl how to fix it but no real progress on implementation
 978     dnl when they fix it, remove this
 979     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 980     ;;
 981   openbsd*)
 982     AC_MSG_RESULT([OpenBSD])
 983
 984     AC_DEFINE(OPEN_BSD,,OpenBSD)
 985     AC_DEFINE(KAME,1,KAME IPv6)
 986     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 987
 988     if test "x${enable_pimd}" != "xno"; then
 989       case "$host_os" in
 990       openbsd6.0)
 991         ;;
 992       openbsd[6-9]*)
 993         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 994         ;;
 995       esac
 996     fi
 997     ;;
 998   *)
 999     AC_MSG_RESULT([BSD])
1000
1001     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
1002     AC_DEFINE(KAME,1,KAME IPv6)
1003     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
1004     ;;
1005 esac
1006 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
1007
1008 AC_SYS_LARGEFILE
1009
1010 dnl ------------------------
1011 dnl Integrated REALMS option
1012 dnl ------------------------
1013 if test "${enable_realms}" = "yes"; then
1014     case "$host_os" in
1015       linux*)
1016        AC_DEFINE(SUPPORT_REALMS,, Realms support)
1017        ;;
1018       *)
1019        echo "Sorry, only Linux has REALMS support"
1020        exit 1
1021        ;;
1022     esac
1023 fi
1024 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1025
1026 dnl ---------------------
1027 dnl Integrated VTY option
1028 dnl ---------------------
1029 case "${enable_vtysh}" in
1030   "no") VTYSH="";;
1031   *)    VTYSH="vtysh";
1032          AC_DEFINE(VTYSH,,VTY shell)
1033 dnl      Vtysh uses libreadline, which looks for termcap functions at
1034 dnl      configure time.  We follow readlines search order.
1035 dnl      The required procedures are in libtermcap on NetBSD, in
1036 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1037          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1038            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1039              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1040                [AC_CHECK_LIB(ncurses, tputs,
1041                              LIBREADLINE="$LIBREADLINE -lncurses")]
1042               )]
1043             )]
1044           )
1045          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1046                       "$LIBREADLINE")
1047          if test $ac_cv_lib_readline_main = no; then
1048            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1049          fi
1050          AC_CHECK_HEADER(readline/history.h)
1051          if test $ac_cv_header_readline_history_h = no;then
1052            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1053          fi
1054          AC_CHECK_LIB(readline, rl_completion_matches,
1055                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1056          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1057            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1058          fi
1059          AC_SEARCH_LIBS([append_history], [readline], [frr_cv_append_history=yes], [frr_cv_append_history=no])
1060          if test "$frr_cv_append_history" = yes; then
1061            AC_DEFINE(HAVE_APPEND_HISTORY, 1, [Have history.h append_history])
1062          fi
1063          ;;
1064 esac
1065 AC_SUBST(LIBREADLINE)
1066 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1067
1068 dnl ----------
1069 dnl PAM module
1070 dnl
1071 dnl FRR detects the PAM library it is built against by checking for a
1072 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1073 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1074 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1075 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1076 dnl of OpenPAM.
1077 dnl ----------
1078 if test "$with_libpam" = "yes"; then
1079   AC_CHECK_HEADER([security/pam_misc.h],
1080     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1081      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1082      pam_conv_func="misc_conv"
1083     ],
1084     [], FRR_INCLUDES)
1085   AC_CHECK_HEADER([security/openpam.h],
1086     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1087      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1088      pam_conv_func="openpam_ttyconv"
1089     ],
1090     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1091   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1092     AC_MSG_WARN([*** pam support will not be built ***])
1093     with_libpam="no"
1094   fi
1095 fi
1096
1097 if test "$with_libpam" = "yes"; then
1098 dnl took this test from proftpds configure.in and suited to our needs
1099 dnl -------------------------------------------------------------------------
1100 dnl
1101 dnl This next check looks funky due to a linker problem with some versions
1102 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1103 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1104 dnl with RedHat 6.2 and Debian 2.2 or better.
1105 AC_CHECK_LIB(pam, pam_start,
1106   [AC_CHECK_LIB(pam, $pam_conv_func,
1107     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1108      LIBPAM="-lpam"],
1109     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1110      LIBPAM="-lpam -lpam_misc"]
1111     )
1112   ],
1113
1114   [AC_CHECK_LIB(pam, pam_end,
1115     [AC_CHECK_LIB(pam, $pam_conv_func,
1116       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1117        LIBPAM="-lpam -ldl"],
1118       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1119        LIBPAM="-lpam -ldl -lpam_misc"]
1120      )
1121   ],AC_MSG_WARN([*** pam support will not be built ***]),
1122   [-ldl])
1123   ]
1124 )
1125 fi
1126 AC_SUBST(LIBPAM)
1127
1128 dnl -------------------------------
1129 dnl Endian-ness check
1130 dnl -------------------------------
1131 AC_WORDS_BIGENDIAN
1132
1133 dnl -------------------------------
1134 dnl check the size in byte of the C
1135 dnl -------------------------------
1136 dnl AC_CHECK_SIZEOF(char)
1137 dnl AC_CHECK_SIZEOF(int)
1138 dnl AC_CHECK_SIZEOF(short)
1139 dnl AC_CHECK_SIZEOF(long)
1140
1141 dnl ----------------------------
1142 dnl check existance of functions
1143 dnl ----------------------------
1144 AC_FUNC_FNMATCH
1145 AC_FUNC_FORK
1146 AC_FUNC_MKTIME
1147 AC_FUNC_STAT
1148
1149 dnl -------------------------------
1150 dnl bgpd needs pow() and hence libm
1151 dnl -------------------------------
1152 TMPLIBS="$LIBS"
1153 AC_CHECK_HEADER([math.h],
1154   [AC_CHECK_LIB([m], [pow],
1155     [LIBM="-lm"
1156      LIBS="$LIBS $LIBM"
1157      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1158     ])
1159 ])
1160 if test x"$LIBM" = x ; then
1161   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1162 fi
1163 LIBS="$TMPLIBS"
1164 AC_SUBST(LIBM)
1165
1166 AC_CHECK_FUNCS([ppoll], [
1167   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1168 ])
1169 AC_CHECK_FUNCS([pollts], [
1170   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1171 ])
1172
1173 dnl ---------------
1174 dnl other functions
1175 dnl ---------------
1176 AC_CHECK_FUNCS([ \
1177         strlcat strlcpy \
1178         getgrouplist])
1179
1180 AC_CHECK_HEADER([asm-generic/unistd.h],
1181                 [AC_CHECK_DECL(__NR_setns,
1182                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1183                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1184                                ])
1185                  AC_CHECK_FUNCS(setns)]
1186                )
1187
1188 dnl --------------------------
1189 dnl Determine IS-IS I/O method
1190 dnl --------------------------
1191 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1192 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1193 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1194 AC_CHECK_HEADER(net/bpf.h)
1195 AC_CHECK_HEADER(sys/dlpi.h)
1196 AC_MSG_CHECKING(zebra IS-IS I/O method)
1197
1198 case "$host_os" in
1199   linux*)
1200     AC_MSG_RESULT(pfpacket)
1201     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1202     ;;
1203   solaris* | sunos*)
1204     AC_MSG_RESULT(DLPI)
1205     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1206     ;;
1207   *)
1208     if test $ac_cv_header_net_bpf_h = no; then
1209       if test $ac_cv_header_sys_dlpi_h = no; then
1210         AC_MSG_RESULT(none)
1211         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1212           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1213         fi
1214         AC_MSG_WARN([*** IS-IS support will not be built ***])
1215         enable_isisd="no"
1216         enable_fabricd="no"
1217       else
1218         AC_MSG_RESULT(DLPI)
1219       fi
1220       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1221     else
1222       AC_MSG_RESULT(BPF)
1223       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1224     fi
1225     ;;
1226 esac
1227 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1228
1229 dnl ---------------------------------------------------------------
1230 dnl figure out how to specify an interface in multicast sockets API
1231 dnl ---------------------------------------------------------------
1232 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1233
1234 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1235         #include <sys/socket.h>
1236         #include <netinet/in.h>
1237         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1238         #include <linux/types.h>
1239 ])
1240
1241 m4_define([FRR_INCLUDES],
1242 FRR_INCLUDES
1243 [#if HAVE_LINUX_MROUTE_H
1244 # include <linux/mroute.h>
1245 #endif
1246 ])dnl
1247
1248 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1249         #include <sys/socket.h>
1250         #include <sys/types.h>
1251         #include <netinet/in.h>
1252         #include <net/route.h>
1253 ])
1254
1255 m4_define([FRR_INCLUDES],
1256 FRR_INCLUDES
1257 [#if HAVE_NETINET_IP_MROUTE_H
1258 # include <netinet/ip_mroute.h>
1259 #endif
1260 ])dnl
1261
1262 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1263 AC_TRY_COMPILE([#include <sys/param.h>],
1264 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1265   return (0);
1266 #else
1267   #error No support for BSD struct ip_mreq hack detected
1268 #endif],[AC_MSG_RESULT(yes)
1269 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1270 AC_MSG_RESULT(no))
1271
1272 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1273 AC_TRY_COMPILE([
1274 #include <sys/types.h>
1275 #include <netinet/in.h>
1276 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1277 ], [AC_MSG_RESULT(yes)
1278 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1279 AC_MSG_RESULT(no))
1280
1281 dnl ---------------------------------------------------------------
1282 dnl figure out how to check link-state
1283 dnl ---------------------------------------------------------------
1284 AC_CHECK_HEADER( [net/if_media.h],
1285   [m4_define([LINK_DETECT_INCLUDES],
1286     FRR_INCLUDES
1287     [#include <net/if_media.h>
1288   ])
1289   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1290     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1291     [], LINK_DETECT_INCLUDES)],
1292   [],
1293   FRR_INCLUDES)
1294
1295 dnl ---------------------------------------------------------------
1296 dnl Additional, newer way to check link-state using ifi_link_state.
1297 dnl Not available in all BSD's when ifmediareq available
1298 dnl ---------------------------------------------------------------
1299 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1300   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1301   [], FRR_INCLUDES)
1302
1303 dnl ------------------------
1304 dnl TCP_MD5SIG socket option
1305 dnl ------------------------
1306
1307 AC_CHECK_HEADER([netinet/tcp.h],
1308    [m4_define([MD5_INCLUDES],
1309       FRR_INCLUDES
1310       [#include <netinet/tcp.h>
1311     ])
1312     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1313    [],
1314    FRR_INCLUDES)
1315 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1316   AC_CHECK_HEADER([linux/tcp.h],
1317        [m4_define([MD5_INCLUDES],
1318           FRR_INCLUDES
1319           [#include <linux/tcp.h>
1320         ])
1321        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1322 fi
1323
1324 dnl ----------------------------------------------------------------------------
1325 dnl figure out if domainname is available in the utsname struct (GNU extension).
1326 dnl ----------------------------------------------------------------------------
1327 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1328
1329 dnl ------------------
1330 dnl IPv6 header checks
1331 dnl ------------------
1332 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1333         netinet6/in6_var.h netinet6/nd6.h], [], [],
1334         FRR_INCLUDES)
1335
1336 m4_define([FRR_INCLUDES],dnl
1337 FRR_INCLUDES
1338 [#if HAVE_NETINET6_IN6_H
1339 #include <netinet6/in6.h>
1340 #endif
1341 #if HAVE_NETINET_IN6_VAR_H
1342 #include <netinet/in6_var.h>
1343 #endif
1344 #include <netinet/icmp6.h>
1345 #if HAVE_NETINET6_IN6_VAR_H
1346 # include <netinet6/in6_var.h>
1347 #endif
1348 #if HAVE_NETINET6_ND6_H
1349 # include <netinet6/nd6.h>
1350 #endif
1351 ])dnl
1352
1353 dnl disable doc check
1354 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [no])
1355 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no")
1356 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1357
1358 dnl --------------------
1359 dnl Daemon disable check
1360 dnl --------------------
1361 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1362
1363 if test "${enable_bgpd}" = "no";then
1364   BGPD=""
1365 else
1366   BGPD="bgpd"
1367 fi
1368 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1369
1370 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1371 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1372 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1373
1374 AS_IF([test "${enable_ldpd}" != "no"], [
1375   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1376 ])
1377
1378 if test "$enable_bfdd" = "no"; then
1379   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1380   BFDD=""
1381 else
1382   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1383   BFDD="bfdd"
1384
1385   case $host_os in
1386     linux*)
1387       AC_DEFINE(BFD_LINUX, 1, bfdd)
1388       ;;
1389
1390     *)
1391       AC_DEFINE(BFD_BSD, 1, bfdd)
1392       ;;
1393   esac
1394 fi
1395
1396 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1397
1398 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1399   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1400 fi
1401
1402 NHRPD=""
1403 case "$host_os" in
1404   linux*)
1405     if test "${enable_nhrpd}" != "no"; then
1406       NHRPD="nhrpd"
1407     fi
1408     ;;
1409   *)
1410     if test "${enable_nhrpd}" = "yes"; then
1411       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1412     fi
1413     ;;
1414 esac
1415 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1416
1417 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1418
1419 if test "${enable_watchfrr}" = "no";then
1420   WATCHFRR=""
1421 else
1422   WATCHFRR="watchfrr"
1423 fi
1424 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1425
1426 OSPFCLIENT=""
1427 if test "${enable_ospfapi}" != "no";then
1428     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1429
1430   if test "${enable_ospfclient}" != "no";then
1431       OSPFCLIENT="ospfclient"
1432   fi
1433 fi
1434
1435 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1436 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1437 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1438 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1439 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1440 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1441 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1442 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1443 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1444 AM_CONDITIONAL(FABRICD, test "${enable_fabricd}" != "no")
1445
1446 if test "${enable_bgp_announce}" = "no";then
1447   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1448 else
1449   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1450 fi
1451
1452 if test "${enable_bgp_vnc}" != "no";then
1453   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1454 fi
1455 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1456
1457 AC_SUBST(SOLARIS)
1458 AC_SUBST(CURSES)
1459 AC_CHECK_LIB(crypt, crypt, [],
1460                     [AC_CHECK_LIB(crypto, DES_crypt)])
1461 AC_CHECK_LIB(resolv, res_init)
1462
1463 dnl ---------------------------
1464 dnl check system has PCRE regexp
1465 dnl ---------------------------
1466 if test "x$enable_pcreposix" = "xyes"; then
1467   AC_CHECK_LIB(pcreposix, regexec, [], [
1468     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1469   ])
1470 fi
1471 AC_SUBST(HAVE_LIBPCREPOSIX)
1472
1473 dnl ------------------
1474 dnl check C-Ares library
1475 dnl ------------------
1476 if test "${NHRPD}" != ""; then
1477   PKG_CHECK_MODULES([CARES], [libcares], , [
1478     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1479   ])
1480 fi
1481
1482
1483 dnl ------------------
1484 dnl check Net-SNMP library
1485 dnl ------------------
1486 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1487    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1488    if test x"$NETSNMP_CONFIG" = x"no"; then
1489       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1490    fi
1491    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1492    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1493    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1494    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1495 int main(void);
1496 ],
1497 [
1498 {
1499   return 0;
1500 }
1501 ])], [
1502      AC_MSG_ERROR([--enable-snmp given but not usable])])
1503    case "${enable_snmp}" in
1504      yes)
1505       SNMP_METHOD=agentx
1506       ;;
1507      agentx)
1508       SNMP_METHOD="${enable_snmp}"
1509       ;;
1510      *)
1511       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1512       ;;
1513    esac
1514    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1515    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1516 fi
1517 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1518 AC_SUBST(SNMP_LIBS)
1519 AC_SUBST(SNMP_CFLAGS)
1520
1521 dnl ---------------
1522 dnl math
1523 dnl ---------------
1524 AC_SEARCH_LIBS([sqrt], [m])
1525
1526 dnl ---------------
1527 dnl dlopen & dlinfo
1528 dnl ---------------
1529 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1530   AC_MSG_ERROR([unable to find the dlopen()])
1531 ])
1532
1533 AC_CHECK_HEADERS([link.h])
1534
1535 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1536   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1537 #include <stdlib.h>
1538 #ifdef HAVE_LINK_H
1539 #include <link.h>
1540 #endif
1541 #include <dlfcn.h>
1542 ]], [[
1543   char origin[1];
1544   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1545 ]])], [
1546     frr_cv_rtld_di_origin=yes
1547   ], [
1548     frr_cv_rtld_di_origin=no
1549   ])
1550 ])
1551 if test "$frr_cv_rtld_di_origin" = yes; then
1552   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1553 fi
1554
1555 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1556   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1557 #include <stdlib.h>
1558 #ifdef HAVE_LINK_H
1559 #include <link.h>
1560 #endif
1561 #include <dlfcn.h>
1562 ]], [[
1563   struct link_map *lm = NULL;
1564   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1565 ]])], [
1566     frr_cv_rtld_di_linkmap=yes
1567   ], [
1568     frr_cv_rtld_di_linkmap=no
1569   ])
1570 ])
1571 if test "$frr_cv_rtld_di_linkmap" = yes; then
1572   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1573 fi
1574
1575 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1576
1577 dnl ---------------------------
1578 dnl sockaddr and netinet checks
1579 dnl ---------------------------
1580 AC_CHECK_TYPES([
1581         struct sockaddr_dl,
1582         struct vifctl, struct mfcctl, struct sioc_sg_req,
1583         vifi_t, struct sioc_vif_req, struct igmpmsg,
1584         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1585         struct nd_opt_adv_interval, struct rt_addrinfo,
1586         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1587         [], [], FRR_INCLUDES)
1588
1589 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1590         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1591         struct sockaddr_dl.sdl_len,
1592         struct if6_aliasreq.ifra_lifetime,
1593         struct nd_opt_adv_interval.nd_opt_ai_type],
1594         [], [], FRR_INCLUDES)
1595
1596 dnl ---------------------------
1597 dnl IRDP/pktinfo/icmphdr checks
1598 dnl ---------------------------
1599
1600 AC_CHECK_TYPES([struct in_pktinfo], [
1601   AC_CHECK_TYPES([struct icmphdr], [
1602     IRDP=true
1603   ], [
1604     IRDP=false
1605   ], [FRR_INCLUDES])
1606 ], [
1607   IRDP=false
1608 ], [FRR_INCLUDES])
1609
1610 case "${enable_irdp}" in
1611 yes)
1612   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1613   ;;
1614 no)
1615   IRDP=false
1616   ;;
1617 esac
1618
1619 AM_CONDITIONAL(IRDP, $IRDP)
1620
1621 dnl -----------------------
1622 dnl checking for IP_PKTINFO
1623 dnl -----------------------
1624 AC_MSG_CHECKING(for IP_PKTINFO)
1625 AC_TRY_COMPILE([#include <netdb.h>], [
1626   int opt = IP_PKTINFO;
1627 ], [
1628   AC_MSG_RESULT(yes)
1629   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1630 ], [
1631   AC_MSG_RESULT(no)
1632 ])
1633
1634 dnl ---------------------------
1635 dnl checking for IP_RECVDSTADDR
1636 dnl ---------------------------
1637 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1638 AC_TRY_COMPILE([#include <netinet/in.h>], [
1639   int opt = IP_RECVDSTADDR;
1640 ], [
1641   AC_MSG_RESULT(yes)
1642   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1643 ], [
1644   AC_MSG_RESULT(no)
1645 ])
1646
1647 dnl ----------------------
1648 dnl checking for IP_RECVIF
1649 dnl ----------------------
1650 AC_MSG_CHECKING(for IP_RECVIF)
1651 AC_TRY_COMPILE([#include <netinet/in.h>], [
1652   int opt = IP_RECVIF;
1653 ], [
1654   AC_MSG_RESULT(yes)
1655   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1656 ], [
1657   AC_MSG_RESULT(no)
1658 ])
1659
1660 dnl ----------------------
1661 dnl checking for SO_BINDANY
1662 dnl ----------------------
1663 AC_MSG_CHECKING(for SO_BINDANY)
1664 AC_TRY_COMPILE([#include <sys/socket.h>], [
1665   int opt = SO_BINDANY;
1666 ], [
1667   AC_MSG_RESULT(yes)
1668   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1669 ], [
1670   AC_MSG_RESULT(no)
1671 ])
1672
1673 dnl ----------------------
1674 dnl checking for IP_FREEBIND
1675 dnl ----------------------
1676 AC_MSG_CHECKING(for IP_FREEBIND)
1677 AC_TRY_COMPILE([#include <netinet/in.h>], [
1678   int opt = IP_FREEBIND;
1679 ], [
1680   AC_MSG_RESULT(yes)
1681   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1682 ], [
1683   AC_MSG_RESULT(no)
1684 ])
1685
1686 dnl --------------------------------------
1687 dnl checking for be32dec existence or not
1688 dnl --------------------------------------
1689 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1690                [#include <sys/endian.h>])
1691
1692 dnl --------------------------------------
1693 dnl checking for clock_time monotonic struct and call
1694 dnl --------------------------------------
1695 AC_CHECK_DECL(CLOCK_MONOTONIC,
1696         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1697          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1698 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1699
1700 dnl --------------------------------------
1701 dnl checking for flex and bison
1702 dnl --------------------------------------
1703
1704 AM_PROG_LEX
1705 AC_MSG_CHECKING(version of flex)
1706 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1707 frr_ac_flex_version="${frr_ac_flex_version##* }"
1708 AC_MSG_RESULT([$frr_ac_flex_version])
1709 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1710   LEX="$SHELL $missing_dir/missing flex"
1711   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1712     AC_MSG_WARN([using pregenerated flex output files])
1713   else
1714     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1715   fi
1716   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1717   AC_SUBST([LEXLIB], [''])
1718 ])
1719
1720 AC_PROG_YACC
1721 dnl thanks GNU bison for this b*llshit...
1722 AC_MSG_CHECKING(version of bison)
1723 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1724 frr_ac_bison_version="${frr_ac_bison_version##* }"
1725 frr_ac_bison_missing="false"
1726 case "x${frr_ac_bison_version}" in
1727   x2.7*)
1728     BISON_OPENBRACE='"'
1729     BISON_CLOSEBRACE='"'
1730     BISON_VERBOSE=''
1731     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1732     ;;
1733   x2.*|x1.*)
1734     AC_MSG_RESULT([$frr_ac_bison_version])
1735     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1736     frr_ac_bison_missing="true"
1737     ;;
1738   x)
1739     AC_MSG_RESULT([none])
1740     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1741     frr_ac_bison_missing="true"
1742     ;;
1743   *)
1744     BISON_OPENBRACE='{'
1745     BISON_CLOSEBRACE='}'
1746     BISON_VERBOSE='-Dparse.error=verbose'
1747     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1748     ;;
1749 esac
1750 AC_SUBST(BISON_OPENBRACE)
1751 AC_SUBST(BISON_CLOSEBRACE)
1752 AC_SUBST(BISON_VERBOSE)
1753
1754 if $frr_ac_bison_missing; then
1755   YACC="$SHELL $missing_dir/missing bison -y"
1756   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1757     AC_MSG_WARN([using pregenerated bison output files])
1758   else
1759     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1760   fi
1761 fi
1762
1763 dnl -------------------
1764 dnl capabilities checks
1765 dnl -------------------
1766 if test "${enable_capabilities}" != "no"; then
1767   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1768   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1769     [AC_MSG_RESULT(yes)
1770      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1771      frr_ac_keepcaps="yes"],
1772      AC_MSG_RESULT(no)
1773   )
1774   if test x"${frr_ac_keepcaps}" = x"yes"; then
1775     AC_CHECK_HEADERS(sys/capability.h)
1776   fi
1777   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1778     AC_CHECK_LIB(cap, cap_init,
1779       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1780        LIBCAP="-lcap"
1781        frr_ac_lcaps="yes"]
1782     )
1783   else
1784     AC_CHECK_HEADERS(priv.h,
1785      [AC_MSG_CHECKING(Solaris style privileges are available)
1786       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1787           [AC_MSG_RESULT(yes)
1788            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1789            frr_ac_scaps="yes"],
1790            AC_MSG_RESULT(no)
1791       )
1792      ]
1793    )
1794   fi
1795   if test x"${frr_ac_scaps}" = x"yes" \
1796        -o x"${frr_ac_lcaps}" = x"yes"; then
1797     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1798   fi
1799 fi
1800 AC_SUBST(LIBCAP)
1801
1802 dnl ---------------------------
1803 dnl check for glibc 'backtrace'
1804 dnl ---------------------------
1805 if test x"${enable_backtrace}" != x"no" ; then
1806   backtrace_ok=no
1807   AC_CHECK_HEADER([execinfo.h], [
1808     AC_SEARCH_LIBS([backtrace], [execinfo], [
1809       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1810       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1811       backtrace_ok=yes
1812     ],, [-lm])
1813   ])
1814
1815   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1816     dnl user explicitly requested backtrace but we failed to find support
1817     AC_MSG_FAILURE([failed to find backtrace support])
1818   fi
1819 fi
1820
1821 dnl -----------------------------------------
1822 dnl check for malloc mallinfo struct and call
1823 dnl this must try and link using LIBS, in
1824 dnl order to check no alternative allocator
1825 dnl has been specified, which might not provide
1826 dnl mallinfo, e.g. such as Umem on Solaris.
1827 dnl -----------------------------------------
1828 AC_CHECK_HEADERS([malloc.h malloc/malloc.h],,, [FRR_INCLUDES])
1829
1830 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1831   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1832 #ifdef HAVE_MALLOC_H
1833 #include <malloc.h>
1834 #endif
1835 #ifdef HAVE_MALLOC_MALLOC_H
1836 #include <malloc/malloc.h>
1837 #endif
1838 ]], [[
1839 struct mallinfo ac_x; ac_x = mallinfo ();
1840 ]])], [
1841     frr_cv_mallinfo=yes
1842   ], [
1843     frr_cv_mallinfo=no
1844   ])
1845 ])
1846 if test "$frr_cv_mallinfo" = yes; then
1847   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1848 fi
1849
1850 AC_MSG_CHECKING(whether malloc_usable_size is available)
1851 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1852 #ifdef HAVE_MALLOC_H
1853 #include <malloc.h>
1854 #endif
1855 #ifdef HAVE_MALLOC_MALLOC_H
1856 #include <malloc/malloc.h>
1857 #endif
1858 ]], [[
1859 size_t ac_x; ac_x = malloc_usable_size(NULL);
1860 ]])], [
1861   AC_MSG_RESULT(yes)
1862   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1863 ], [
1864   AC_MSG_RESULT(no)
1865
1866   AC_MSG_CHECKING(whether malloc_size is available)
1867   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1868 #ifdef HAVE_MALLOC_H
1869 #include <malloc.h>
1870 #endif
1871 #ifdef HAVE_MALLOC_MALLOC_H
1872 #include <malloc/malloc.h>
1873 #endif
1874 ]], [[
1875 size_t ac_x; ac_x = malloc_size(NULL);
1876 ]])], [
1877     AC_MSG_RESULT(yes)
1878     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1879   ], [
1880     AC_MSG_RESULT(no)
1881   ])
1882 ])
1883
1884 dnl ------
1885 dnl ZeroMQ
1886 dnl ------
1887 if test "x$enable_zeromq" != "xno"; then
1888   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1889     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1890     ZEROMQ=true
1891   ], [
1892     if test "x$enable_zeromq" = "xyes"; then
1893       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1894     fi
1895   ])
1896 fi
1897 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1898
1899 dnl ----------
1900 dnl configure date
1901 dnl ----------
1902 dev_version=`echo $VERSION | grep dev`
1903 #don't expire deprecated code in non 'dev' branch
1904 if test "${dev_version}" = ""; then
1905    CONFDATE=0
1906 else
1907    CONFDATE=`date '+%Y%m%d'`
1908 fi
1909 AC_SUBST(CONFDATE)
1910
1911 dnl ------------------------------
1912 dnl set paths for state directory
1913 dnl ------------------------------
1914 AC_MSG_CHECKING(directory to use for state file)
1915 if test "${prefix}" = "NONE"; then
1916   frr_statedir_prefix="";
1917 else
1918   frr_statedir_prefix=${prefix}
1919 fi
1920 if test "${localstatedir}" = '${prefix}/var'; then
1921   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1922                         ${frr_statedir_prefix}/var/adm dnl
1923                         ${frr_statedir_prefix}/etc dnl
1924                         /var/run        dnl
1925                         /var/adm        dnl
1926                         /etc            dnl
1927                         /dev/null;
1928   do
1929     test -d $FRR_STATE_DIR && break
1930   done
1931   frr_statedir=$FRR_STATE_DIR
1932 else
1933   frr_statedir=${localstatedir}
1934 fi
1935 if test $frr_statedir = "/dev/null"; then
1936     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1937 fi
1938 AC_MSG_RESULT(${frr_statedir})
1939 AC_SUBST(frr_statedir)
1940
1941 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1942 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1943 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1944 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1945
1946 dnl autoconf does this, but it does it too late...
1947 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1948 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1949
1950 dnl get the full path, recursing through variables...
1951 vtysh_bin="$bindir/vtysh"
1952 for I in 1 2 3 4 5 6 7 8 9 10; do
1953         eval vtysh_bin="\"$vtysh_bin\""
1954 done
1955 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1956
1957 CFG_SYSCONF="$sysconfdir"
1958 CFG_SBIN="$sbindir"
1959 CFG_STATE="$frr_statedir"
1960 CFG_MODULE="$moduledir"
1961 for I in 1 2 3 4 5 6 7 8 9 10; do
1962         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1963         eval CFG_SBIN="\"$CFG_SBIN\""
1964         eval CFG_STATE="\"$CFG_STATE\""
1965         eval CFG_MODULE="\"$CFG_MODULE\""
1966 done
1967 AC_SUBST(CFG_SYSCONF)
1968 AC_SUBST(CFG_SBIN)
1969 AC_SUBST(CFG_STATE)
1970 AC_SUBST(CFG_MODULE)
1971 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1972
1973 dnl ------------------------------------
1974 dnl Enable RPKI and add librtr to libs
1975 dnl ------------------------------------
1976 if test "${enable_rpki}" = "yes"; then
1977   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1978       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1979       RPKI=true],
1980       [RPKI=false
1981       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1982   )
1983 fi
1984 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1985
1986 dnl ------------------------------------------
1987 dnl Check whether rtrlib was build with ssh support
1988 dnl ------------------------------------------
1989 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1990 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1991                         [[struct tr_ssh_config config;]])],
1992         [AC_MSG_RESULT(yes)
1993         AC_DEFINE(FOUND_SSH,,found_ssh)],
1994         AC_MSG_RESULT(no)
1995 )
1996
1997 dnl ---------------------------
1998 dnl Check htonl works correctly
1999 dnl ---------------------------
2000 AC_MSG_CHECKING(for working htonl)
2001 AC_CACHE_VAL(ac_cv_htonl_works,
2002  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2003                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2004  ]
2005 )
2006 AC_MSG_RESULT($ac_cv_htonl_works)
2007
2008 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2009
2010 AC_CONFIG_FILES([
2011           tests/Makefile
2012           redhat/frr.spec
2013           solaris/Makefile
2014           debianpkg/changelog
2015           alpine/APKBUILD
2016           snapcraft/snapcraft.yaml
2017           lib/version.h
2018           tests/lib/cli/test_cli.refout
2019           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2020           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2021           pkgsrc/eigrpd.sh])
2022
2023 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2024
2025 AC_CONFIG_COMMANDS([lib/route_types.h], [
2026         dst="${ac_abs_top_builddir}/lib/route_types.h"
2027         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2028                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2029                 > "${dst}.tmp"
2030         test -f "${dst}" \
2031                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2032                 && rm "${dst}.tmp" \
2033                 || mv "${dst}.tmp" "${dst}"
2034 ], [
2035         PERL="$PERL"
2036 ])
2037
2038 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2039     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2040         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2041         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2042                 "${ac_abs_top_srcdir}" \
2043                 > "${dst}.tmp"
2044         test -f "${dst}" \
2045                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2046                 && rm "${dst}.tmp" \
2047                 || mv "${dst}.tmp" "${dst}"
2048     ], [
2049         PERL="$PERL"
2050     ])
2051 ])
2052
2053 ## Hack, but working solution to avoid rebuilding of frr.info.
2054 ## It's already in CVS until texinfo 4.7 is more common.
2055 AC_OUTPUT
2056
2057 echo "
2058 FRRouting configuration
2059 ------------------------------
2060 FRR version             : ${PACKAGE_VERSION}
2061 host operating system   : ${host_os}
2062 source code location    : ${srcdir}
2063 compiler                : ${CC}
2064 compiler flags          : ${CFLAGS}
2065 make                    : ${MAKE-make}
2066 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2067 state file directory    : ${frr_statedir}
2068 config file directory   : `eval echo \`echo ${sysconfdir}\``
2069 example directory       : `eval echo \`echo ${exampledir}\``
2070 module directory        : ${CFG_MODULE}
2071 user to run as          : ${enable_user}
2072 group to run as         : ${enable_group}
2073 group for vty sockets   : ${enable_vty_group}
2074 config file mask        : ${enable_configfile_mask}
2075 log file mask           : ${enable_logfile_mask}
2076 zebra protobuf enabled  : ${have_protobuf:-no}
2077
2078 The above user and group must have read/write access to the state file
2079 directory and to the config files in the config file directory."
2080
2081 if test "${enable_doc}" != "no";then
2082   AS_IF([test "x$SPHINXBUILD" = xno],
2083      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2084 fi