configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.2-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST([HOSTTOOLS])
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS([config.h])
  64
  65 AC_PATH_PROG([PERL], [perl])
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST([exampledir])
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST([pkgsrcrcdir])
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94
  95 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
  96         yangmodelsdir="$withval"
  97 ], [
  98         yangmodelsdir="\${datarootdir}/yang"
  99 ])
 100 AC_SUBST([yangmodelsdir])
 101
 102 AC_ARG_WITH([libyang_pluginsdir], [AS_HELP_STRING([--with-libyang-pluginsdir=DIR], [yangmodule plugins directory (${libdir}/frr/libyang_plugins)])], [
 103         libyang_pluginsdir="$withval"
 104 ], [
 105    libyang_pluginsdir="\${libdir}/frr/libyang_plugins"
 106 ])
 107 AC_SUBST([libyang_pluginsdir])
 108
 109 AC_ARG_ENABLE(tcmalloc,
 110         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 111 [case "${enableval}" in
 112   yes) tcmalloc_enabled=true
 113 LIBS="$LIBS -ltcmalloc_minimal"
 114  ;;
 115   no)  tcmalloc_enabled=false ;;
 116   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 117 esac],[tcmalloc_enabled=false])
 118
 119
 120 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 121 dnl flag determination logic.
 122 CFLAGS="${CFLAGS:-}"
 123
 124 dnl --------------------
 125 dnl Check CC and friends
 126 dnl --------------------
 127 dnl note orig_cflags is also used further down
 128 orig_cflags="$CFLAGS"
 129 orig_cxxflags="$CXXFLAGS"
 130 AC_LANG([C])
 131 AC_PROG_CC
 132 AC_PROG_CPP
 133 AC_PROG_CXX
 134 AM_PROG_CC_C_O
 135 dnl remove autoconf default "-g -O2"
 136 CFLAGS="$orig_cflags"
 137 CXXFLAGS="$orig_cxxflags"
 138 AC_PROG_CC_C99
 139 dnl NB: see C11 below
 140
 141 AC_PROG_EGREP
 142 PKG_PROG_PKG_CONFIG
 143
 144 dnl autoconf 2.59 appears not to support AC_PROG_SED
 145 dnl AC_PROG_SED
 146 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 147
 148 dnl try and enable CFLAGS that are useful for FRR
 149 dnl - specifically, options to control warnings
 150
 151 AC_USE_SYSTEM_EXTENSIONS
 152 AC_DEFUN([AC_C_FLAG], [{
 153     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 154     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 155         AC_LANG_PUSH([C])
 156         ac_c_flag_save="$CFLAGS"
 157         CFLAGS="$CFLAGS $1"
 158         AC_COMPILE_IFELSE(
 159                 [AC_LANG_PROGRAM([[]])],
 160                 [
 161                         cachename=yes
 162                 ], [
 163                         cachename=no
 164                 ])
 165         CFLAGS="$ac_c_flag_save"
 166         AC_LANG_POP([C])
 167     ])
 168     if test "${cachename}" = yes; then
 169         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 170     else
 171         :
 172         $2
 173     fi
 174     m4_popdef([cachename])
 175 }])
 176
 177 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 178         AC_LANG_PUSH([C])
 179         ac_cflags_save="$CFLAGS"
 180         ac_libs_save="$LIBS"
 181         CFLAGS="$CFLAGS $1"
 182         LIBS="$LIBS $2"
 183         AC_LINK_IFELSE(
 184                 [$3],
 185                 [
 186                         CFLAGS="$ac_cflags_save"
 187                         LIBS="$ac_libs_save"
 188                         m4_default([$5], [
 189                                 AC_MSG_RESULT([yes])
 190                         ])
 191                 ], [
 192                         CFLAGS="$ac_cflags_save"
 193                         LIBS="$ac_libs_save"
 194                         m4_default([$4], [
 195                                 AC_MSG_RESULT([no])
 196                         ])
 197                 ])
 198         AC_LANG_POP([C])
 199         }])
 200
 201 dnl ICC won't bail on unknown options without -diag-error 10006
 202 dnl need to do this first so we get useful results for the other options
 203 AC_C_FLAG([-diag-error 10006])
 204
 205 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 206 ac_cc="$CC"
 207 CC="${CC% -std=gnu99}"
 208 CC="${CC% -std=c99}"
 209
 210 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 211
 212 dnl if the user has specified any CFLAGS, override our settings
 213 if test "x${enable_gcov}" = "xyes"; then
 214    if test "z$orig_cflags" = "z"; then
 215       AC_C_FLAG([-coverage])
 216       AC_C_FLAG([-O0])
 217    fi
 218
 219    LDFLAGS="${LDFLAGS} -lgcov"
 220 elif test "x${enable_dev_build}" = "xyes"; then
 221    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 222    if test "z$orig_cflags" = "z"; then
 223       AC_C_FLAG([-g3])
 224       AC_C_FLAG([-O0])
 225    fi
 226    if test "x${enable_lua}" = "xyes"; then
 227       AX_PROG_LUA([5.3])
 228       AX_LUA_HEADERS
 229       AX_LUA_LIBS([
 230          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 231          LIBS="$LIBS $LUA_LIB"
 232       ])
 233    fi
 234 else
 235    if test "x${enable_lua}" = "xyes"; then
 236       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 237    fi
 238    if test "z$orig_cflags" = "z"; then
 239       AC_C_FLAG([-g])
 240       AC_C_FLAG([-Os], [
 241         AC_C_FLAG([-O2])
 242       ])
 243    fi
 244 fi
 245 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 246
 247 dnl always want these CFLAGS
 248 AC_C_FLAG([-fno-omit-frame-pointer])
 249 AC_C_FLAG([-funwind-tables])
 250 AC_C_FLAG([-Wall])
 251 AC_C_FLAG([-Wextra])
 252 AC_C_FLAG([-Wmissing-prototypes])
 253 AC_C_FLAG([-Wmissing-declarations])
 254 AC_C_FLAG([-Wpointer-arith])
 255 AC_C_FLAG([-Wbad-function-cast])
 256 AC_C_FLAG([-Wwrite-strings])
 257 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 258   AC_C_FLAG([-Wcast-qual])
 259   AC_C_FLAG([-Wstrict-prototypes])
 260   AC_C_FLAG([-Wmissing-noreturn])
 261   AC_C_FLAG([-Wmissing-format-attribute])
 262   AC_C_FLAG([-Wunreachable-code])
 263   AC_C_FLAG([-Wpacked])
 264   AC_C_FLAG([-Wpadded])
 265   AC_C_FLAG([-Wshadow])
 266 else
 267   AC_C_FLAG([-Wno-unused-result])
 268 fi
 269 AC_C_FLAG([-Wno-unused-parameter])
 270 AC_C_FLAG([-Wno-missing-field-initializers])
 271
 272 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 273 AC_SUBST([CXX_COMPAT_CFLAGS])
 274
 275 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 276 dnl for some reason the string consts get 'promoted' to char *,
 277 dnl triggering a const to non-const conversion warning.
 278 AC_C_FLAG([-diag-disable 3179])
 279
 280 if test x"${enable_werror}" = x"yes" ; then
 281   WERROR="-Werror"
 282 fi
 283 AC_SUBST([WERROR])
 284
 285 SAN_FLAGS=""
 286 if test "$enable_address_sanitizer" = "yes"; then
 287   AC_C_FLAG([-fsanitize=address], [
 288     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 289   ], [
 290     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 291   ])
 292 fi
 293 if test "$enable_thread_sanitizer" = "yes"; then
 294   AC_C_FLAG([-fsanitize=thread], [
 295     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 296   ], [
 297     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 298   ])
 299 fi
 300 if test "$enable_memory_sanitizer" = "yes"; then
 301   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 302     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 303   ], [
 304     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 305   ])
 306 fi
 307 AC_SUBST([SAN_FLAGS])
 308
 309 dnl ----------
 310 dnl Essentials
 311 dnl ----------
 312
 313 AX_PTHREAD([
 314   CC="$PTHREAD_CC"
 315   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 316   LIBS="$PTHREAD_LIBS $LIBS"
 317 ], [
 318   AC_MSG_FAILURE([This FRR version needs pthreads])
 319 ])
 320
 321 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 322                 [frr_cv_pthread_condattr_setclock=yes],
 323                 [frr_cv_pthread_condattr_setclock=no])
 324 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 325   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 326 fi
 327
 328 dnl --------------
 329 dnl Check programs
 330 dnl --------------
 331 AC_PROG_INSTALL
 332 AC_PROG_LN_S
 333 AC_PROG_MAKE_SET
 334 AC_CHECK_TOOL([AR], [ar])
 335
 336 dnl -------
 337 dnl libtool
 338 dnl -------
 339 AC_ARG_ENABLE([static-bin],
 340   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 341 LT_INIT
 342 _LT_CONFIG_LIBTOOL([
 343   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 344     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 345 ])
 346 if test "$enable_static_bin" = "yes"; then
 347   AC_LDFLAGS="-static"
 348   if test "$enable_static" != "yes"; then
 349     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 350   fi
 351 fi
 352 if test "$enable_shared" != "yes"; then
 353   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 354 fi
 355 AC_SUBST([AC_LDFLAGS])
 356 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 357
 358 dnl $AR and $RANLIB are set by LT_INIT above
 359 AC_MSG_CHECKING([whether $AR supports D option])
 360 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 361   AC_MSG_RESULT([yes])
 362   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 363   ARFLAGS="crD"
 364   AR_FLAGS="crD"
 365 else
 366   AC_MSG_RESULT([no])
 367   ARFLAGS="cru"
 368   AR_FLAGS="cru"
 369 fi
 370 AC_SUBST([ARFLAGS])
 371 AC_SUBST([AR_FLAGS])
 372
 373 AC_MSG_CHECKING([whether $RANLIB supports D option])
 374 if $RANLIB -D conftest.a >/dev/null 2>/dev/null; then
 375   AC_MSG_RESULT([yes])
 376   RANLIB="$RANLIB -D"
 377 else
 378   AC_MSG_RESULT([no])
 379 fi
 380 AC_SUBST([RANLIB])
 381
 382 test -f conftest.a && rm conftest.a
 383
 384 dnl ----------------------
 385 dnl Packages configuration
 386 dnl ----------------------
 387 if test -f config.version; then
 388   . ./config.version
 389 elif test -f "${srcdir}/config.version"; then
 390   . "${srcdir}/config.version"
 391 fi
 392 AC_ARG_WITH([pkg-extra-version],
 393   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 394   if test "$withval" = "no"; then
 395     EXTRAVERSION=
 396   else
 397     EXTRAVERSION=$withval
 398   fi
 399 ], [])
 400 AC_ARG_WITH([pkg-git-version],
 401         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 402         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 403 AC_ARG_WITH([vtysh_pager],
 404         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 405         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 406 AC_ARG_ENABLE([vtysh],
 407   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 408 AC_ARG_ENABLE([doc],
 409   AS_HELP_STRING([--disable-doc], [do not build docs]))
 410 AC_ARG_ENABLE([doc-html],
 411   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 412 AC_ARG_ENABLE([zebra],
 413   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 414 AC_ARG_ENABLE([bgpd],
 415   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 416 AC_ARG_ENABLE([ripd],
 417   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 418 AC_ARG_ENABLE([ripngd],
 419   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 420 AC_ARG_ENABLE([ospfd],
 421   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 422 AC_ARG_ENABLE([ospf6d],
 423   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 424 AC_ARG_ENABLE([ldpd],
 425   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 426 AC_ARG_ENABLE([nhrpd],
 427   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 428 AC_ARG_ENABLE([eigrpd],
 429   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 430 AC_ARG_ENABLE([babeld],
 431   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 432 AC_ARG_ENABLE([watchfrr],
 433   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 434 AC_ARG_ENABLE([isisd],
 435   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 436 AC_ARG_ENABLE([pimd],
 437   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 438 AC_ARG_ENABLE([pbrd],
 439   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 440 AC_ARG_ENABLE([sharpd],
 441   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 442 AC_ARG_ENABLE([staticd],
 443   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 444 AC_ARG_ENABLE([fabricd],
 445   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 446 AC_ARG_ENABLE([bgp-announce],
 447   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 448 AC_ARG_ENABLE([vrrpd],
 449   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 450 AC_ARG_ENABLE([bgp-vnc],
 451   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 452 AC_ARG_ENABLE([snmp],
 453   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 454 AC_ARG_ENABLE([config_rollbacks],
 455   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 456 AC_ARG_ENABLE([confd],
 457   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 458 AC_ARG_ENABLE([sysrepo],
 459   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 460 AC_ARG_ENABLE([grpc],
 461   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 462 AC_ARG_ENABLE([zeromq],
 463   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 464 AC_ARG_WITH([libpam],
 465   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 466 AC_ARG_ENABLE([ospfapi],
 467   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 468 AC_ARG_ENABLE([ospfclient],
 469   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 470                           (this is the default if --disable-ospfapi is set)]))
 471 AC_ARG_ENABLE([multipath],
 472   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 473 AC_ARG_ENABLE([user],
 474   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 475 AC_ARG_ENABLE([group],
 476   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 477 AC_ARG_ENABLE([vty_group],
 478   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 479 AC_ARG_ENABLE([configfile_mask],
 480   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 481 AC_ARG_ENABLE([logfile_mask],
 482   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 483 AC_ARG_ENABLE([shell_access],
 484   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 485 AC_ARG_ENABLE([realms],
 486   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 487 AC_ARG_ENABLE([rtadv],
 488   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 489 AC_ARG_ENABLE([irdp],
 490   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 491 AC_ARG_ENABLE([capabilities],
 492   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 493 AC_ARG_ENABLE([rusage],
 494   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 495 AC_ARG_ENABLE([gcc_ultra_verbose],
 496   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 497 AC_ARG_ENABLE([backtrace],
 498   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 499 AC_ARG_ENABLE([time-check],
 500   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 501 AC_ARG_ENABLE([pcreposix],
 502   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 503 AC_ARG_ENABLE([fpm],
 504   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 505 AC_ARG_ENABLE([systemd],
 506   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 507 AC_ARG_ENABLE([werror],
 508   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 509 AC_ARG_ENABLE([cumulus],
 510   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 511 AC_ARG_ENABLE([datacenter],
 512   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 513 AC_ARG_ENABLE([fuzzing],
 514   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 515 AC_ARG_ENABLE([netlink_fuzzing],
 516   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 517 AC_ARG_ENABLE([rr-semantics],
 518   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 519 AC_ARG_ENABLE([protobuf],
 520   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 521 AC_ARG_ENABLE([oldvpn_commands],
 522   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 523 AC_ARG_ENABLE([rpki],
 524   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 525 AC_ARG_ENABLE([clippy-only],
 526   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 527 AC_ARG_ENABLE([numeric_version],
 528   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 529 AC_ARG_ENABLE([gcov],
 530   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 531 AC_ARG_ENABLE([bfdd],
 532   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 533 AC_ARG_ENABLE([address-sanitizer],
 534   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 535 AC_ARG_ENABLE([thread-sanitizer],
 536   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 537 AC_ARG_ENABLE([memory-sanitizer],
 538   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 539
 540 AS_IF([test "${enable_clippy_only}" != "yes"], [
 541 AC_CHECK_HEADERS([json-c/json.h])
 542 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 543 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 544   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 545   if test "$ac_cv_lib_json_json_object_get" = no; then
 546       AC_MSG_ERROR([libjson is needed to compile])
 547   fi
 548 fi
 549 ])
 550
 551 AC_ARG_ENABLE([dev_build],
 552     AS_HELP_STRING([--enable-dev-build], [build for development]))
 553
 554 AC_ARG_ENABLE([lua],
 555     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 556
 557 if test x"${enable_time_check}" != x"no" ; then
 558   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 559     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 560   else
 561     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 562   fi
 563 fi
 564
 565 case "${enable_systemd}" in
 566   "no") ;;
 567   "yes")
 568   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 569   if test $ac_cv_lib_systemd_sd_notify = no; then
 570     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 571   else
 572     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 573   fi
 574   ;;
 575   "*") ;;
 576 esac
 577
 578 if test "${enable_rr_semantics}" != "no" ; then
 579   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 580 fi
 581
 582 if test "${enable_datacenter}" = "yes" ; then
 583   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 584   DFLT_NAME="datacenter"
 585 else
 586   DFLT_NAME="traditional"
 587 fi
 588
 589 if test "${enable_fuzzing}" = "yes" ; then
 590   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 591 fi
 592
 593 if test "${enable_netlink_fuzzing}" = "yes" ; then
 594   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 595 fi
 596
 597 if test "${enable_cumulus}" = "yes" ; then
 598   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 599 fi
 600
 601 AC_SUBST([DFLT_NAME])
 602 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 603
 604 if test "${enable_shell_access}" = "yes"; then
 605    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 606 fi
 607
 608 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 609
 610 #
 611 # Python for clippy
 612 #
 613
 614 AS_IF([test "$host" = "$build"], [
 615   FRR_PYTHON_DEV
 616 ], [
 617   FRR_PYTHON
 618 ])
 619
 620 FRR_PYTHON_MODULES([pytest])
 621
 622 if test "${enable_doc}" != "no"; then
 623   FRR_PYTHON_MODULES([sphinx], , [
 624     if test "${enable_doc}" = "yes"; then
 625       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 626     fi
 627   ])
 628 fi
 629 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" != "false"])
 630 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
 631
 632 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 633   PYSPHINX="-m sphinx"
 634 ], [
 635   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 636 ])
 637 AC_SUBST([PYSPHINX])
 638
 639 #
 640 # Logic for protobuf support.
 641 #
 642 if test "$enable_protobuf" = "yes"; then
 643   # Check for protoc & protoc-c
 644
 645   # protoc is not required, it's only for a "be nice" helper target
 646   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 647
 648   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 649   if test "$PROTOC_C" = "/bin/false"; then
 650     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 651   fi
 652
 653   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 654     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 655   ])
 656   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 657     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 658   ])
 659
 660   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
 661 fi
 662 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 663
 664 #
 665 # Logic for old vpn commands support.
 666 #
 667 if test "$enable_oldvpn_commands" = "yes"; then
 668    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 669 fi
 670
 671 #
 672 # End of logic for protobuf support.
 673 #
 674
 675 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 676 if test "${enable_rtadv}" != "no"; then
 677   AC_MSG_RESULT([yes])
 678   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 679 else
 680   AC_MSG_RESULT([no])
 681 fi
 682
 683 if test x"${enable_user}" = x"no"; then
 684   enable_user=""
 685 else
 686   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 687     enable_user="frr"
 688   fi
 689   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 690 fi
 691
 692 if test x"${enable_group}" = x"no"; then
 693   enable_group=""
 694 else
 695   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 696     enable_group="frr"
 697   fi
 698   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 699 fi
 700
 701 if test x"${enable_vty_group}" = x"yes" ; then
 702   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 703 elif test x"${enable_vty_group}" != x""; then
 704   if test x"${enable_vty_group}" != x"no"; then
 705     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 706   fi
 707 fi
 708 AC_SUBST([enable_user])
 709 AC_SUBST([enable_group])
 710 AC_SUBST([enable_vty_group])
 711
 712 enable_configfile_mask=${enable_configfile_mask:-0600}
 713 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 714
 715 enable_logfile_mask=${enable_logfile_mask:-0600}
 716 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 717
 718 MPATH_NUM=16
 719
 720 case "${enable_multipath}" in
 721   0)
 722     MPATH_NUM=64
 723     ;;
 724   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 725     MPATH_NUM="${enable_multipath}"
 726     ;;
 727   "")
 728     ;;
 729   *)
 730     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 731     ;;
 732 esac
 733
 734 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 735
 736 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 737
 738 dnl --------------------
 739 dnl Enable code coverage
 740 dnl --------------------
 741 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 742
 743 dnl ------------------------------------
 744 dnl Alpine only accepts numeric versions
 745 dnl ------------------------------------
 746 if test "x${enable_numeric_version}" != "x" ; then
 747   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 748   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 749 fi
 750
 751 dnl -----------------------------------
 752 dnl Add extra version string to package
 753 dnl name, string and version fields.
 754 dnl -----------------------------------
 755 if test "x${EXTRAVERSION}" != "x" ; then
 756   VERSION="${VERSION}${EXTRAVERSION}"
 757   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 758   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 759   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 760 fi
 761 AC_SUBST([EXTRAVERSION])
 762
 763 if test "x$with_pkg_git_version" = "xyes"; then
 764         if test -d "${srcdir}/.git"; then
 765                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 766         else    with_pkg_git_version="no"
 767                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 768         fi
 769 fi
 770 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 771
 772 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 773 if test "x${OBJCOPY}" != "x:"; then
 774   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 775     frr_cv_interp=""
 776     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 777       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 778         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 779       fi
 780       test -f conftest.interp && rm conftest.interp
 781     ])
 782   ])
 783 fi
 784 if test -n "$frr_cv_interp"; then
 785   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 786 fi
 787
 788 dnl ------------------------------------
 789 dnl Check C keywords and standard  types
 790 dnl ------------------------------------
 791 AC_C_CONST
 792 AC_C_INLINE
 793 AC_C_VOLATILE
 794 AC_HEADER_STDC
 795 dnl AC_TYPE_PID_T
 796 AC_TYPE_UID_T
 797 AC_TYPE_MODE_T
 798 AC_TYPE_SIZE_T
 799 AC_STRUCT_TM
 800
 801 dnl -------------------------
 802 dnl Check other header files.
 803 dnl -------------------------
 804 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 805         linux/version.h asm/types.h \
 806         sys/cdefs.h])
 807
 808 ac_stdatomic_ok=false
 809 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 810 AC_CHECK_HEADER([stdatomic.h],[
 811
 812   AC_MSG_CHECKING([whether _Atomic qualifier works])
 813   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 814 #include <stdatomic.h>
 815 int main(int argc, char **argv) {
 816   _Atomic int i = 0;
 817   return i;
 818 }
 819 ]])], [
 820     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 821     AC_MSG_RESULT([yes])
 822     ac_stdatomic_ok=true
 823   ], [
 824     AC_MSG_RESULT([no])
 825   ])
 826 ])
 827
 828 AS_IF([$ac_stdatomic_ok], [true], [
 829   AC_MSG_CHECKING([for __atomic_* builtins])
 830   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 831 int main(int argc, char **argv) {
 832   volatile int i = 1;
 833   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 834   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 835 }
 836 ]])], [
 837     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 838     AC_MSG_RESULT([yes])
 839   ], [
 840     AC_MSG_RESULT([no])
 841
 842     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 843     AC_MSG_CHECKING([for __sync_* builtins])
 844     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 845 int main(int argc, char **argv) {
 846   volatile int i = 1;
 847   __sync_fetch_and_sub (&i, 1);
 848   return __sync_val_compare_and_swap (&i, 0, 1);
 849 }
 850 ]])], [
 851       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 852       AC_MSG_RESULT([yes])
 853
 854       AC_MSG_CHECKING([for __sync_swap builtin])
 855       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 856 int main(int argc, char **argv) {
 857   volatile int i = 1;
 858   return __sync_swap (&i, 2);
 859 }
 860 ]])], [
 861         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 862         AC_MSG_RESULT([yes])
 863       ], [
 864         AC_MSG_RESULT([no])
 865       ])
 866
 867     ], [
 868       AC_MSG_RESULT([no])
 869       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 870     ])
 871   ])
 872 ])
 873
 874 AC_CHECK_HEADERS([pthread_np.h],,, [
 875 #include <pthread.h>
 876 ])
 877 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 878
 879 needsync=true
 880
 881 AS_IF([$needsync], [
 882   dnl Linux
 883   AC_MSG_CHECKING([for Linux futex() support])
 884   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 885 #ifndef _GNU_SOURCE
 886 #define _GNU_SOURCE
 887 #endif
 888 #include <unistd.h>
 889 #include <limits.h>
 890 #include <sys/time.h>
 891 #include <sys/syscall.h>
 892 #include <linux/futex.h>
 893
 894 int main(void);
 895 ],
 896 [
 897 {
 898   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 899 }
 900 ])], [
 901     AC_MSG_RESULT([yes])
 902     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 903     needsync=false
 904   ], [
 905     AC_MSG_RESULT([no])
 906   ])
 907 ])
 908
 909 AS_IF([$needsync], [
 910   dnl FreeBSD
 911   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 912   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 913 #include <errno.h>
 914 #include <stdlib.h>
 915 #include <sys/types.h>
 916 #include <sys/umtx.h>
 917 int main(void);
 918 ],
 919 [
 920 {
 921   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
 922 }
 923 ])], [
 924     AC_MSG_RESULT([yes])
 925     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
 926     needsync=false
 927   ], [
 928     AC_MSG_RESULT([no])
 929   ])
 930 ])
 931
 932 AS_IF([$needsync], [
 933   dnl OpenBSD patch (not upstream at the time of writing this)
 934   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
 935   AC_MSG_CHECKING([for OpenBSD futex() support])
 936   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 937 #include <sys/futex.h>
 938 int main(void);
 939 ],
 940 [
 941 {
 942   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 943 }
 944 ])], [
 945     AC_MSG_RESULT([yes])
 946     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
 947     needsync=false
 948   ], [
 949     AC_MSG_RESULT([no])
 950   ])
 951 ])
 952
 953 dnl Utility macro to avoid retyping includes all the time
 954 m4_define([FRR_INCLUDES],
 955 [#ifdef SUNOS_5
 956 #define _POSIX_C_SOURCE 200809L
 957 #define __EXTENSIONS__
 958 #endif
 959 #include <stdio.h>
 960 #include <stdlib.h>
 961 #include <stddef.h>
 962 #include <sys/types.h>
 963 /* sys/conf.h depends on param.h on FBSD at least */
 964 #include <sys/param.h>
 965 /* Required for MAXSIG */
 966 #include <signal.h>
 967 #include <sys/socket.h>
 968 #ifdef __APPLE__
 969 # define __APPLE_USE_RFC_3542
 970 #endif
 971 #include <netinet/in.h>
 972 #include <sys/time.h>
 973 #include <time.h>
 974 #include <net/if.h>
 975 ])dnl
 976
 977 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 978 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 979 dnl an additional round for it.
 980
 981 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
 982
 983 m4_define([FRR_INCLUDES],
 984 FRR_INCLUDES
 985 [#if HAVE_NET_IF_VAR_H
 986 # include <net/if_var.h>
 987 #endif
 988 ])dnl
 989
 990 AC_CHECK_HEADERS([netinet/in_var.h \
 991         net/if_dl.h net/netopt.h \
 992         inet/nd.h netinet/ip_icmp.h \
 993         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 994         [], [], [FRR_INCLUDES])
 995
 996 AC_CHECK_HEADERS([ucontext.h], [], [],
 997 [#ifndef __USE_GNU
 998 #define __USE_GNU
 999 #endif /* __USE_GNU */
1000 FRR_INCLUDES
1001 ])
1002
1003 m4_define([UCONTEXT_INCLUDES],
1004 [#include <ucontext.h>])dnl
1005
1006 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1007   [], [], [UCONTEXT_INCLUDES])
1008 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1009   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1010    [], [], [UCONTEXT_INCLUDES])],
1011   [], [UCONTEXT_INCLUDES])
1012 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1013   [], [], [UCONTEXT_INCLUDES])
1014
1015 m4_define([FRR_INCLUDES],
1016 FRR_INCLUDES
1017 [
1018 #include <sys/un.h>
1019 #include <netinet/in_systm.h>
1020 #if HAVE_NETINET_IN_VAR_H
1021 # include <netinet/in_var.h>
1022 #endif
1023 #if HAVE_NET_IF_DL_H
1024 # include <net/if_dl.h>
1025 #endif
1026 #if HAVE_NET_NETOPT_H
1027 # include <net/netopt.h>
1028 #endif
1029 #include <net/route.h>
1030 #if HAVE_INET_ND_H
1031 # include <inet/nd.h>
1032 #endif
1033 #include <arpa/inet.h>
1034 /* Required for IDRP */
1035 #if HAVE_NETINET_IP_ICMP_H
1036 # include <netinet/ip_icmp.h>
1037 #endif
1038 ])dnl
1039
1040 dnl V6 headers are checked below, after we check for v6
1041
1042 AC_MSG_CHECKING([which operating system interface to use])
1043 case "$host_os" in
1044   sunos* | solaris2*)
1045     AC_MSG_RESULT([Solaris])
1046
1047     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1048     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1049     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1050
1051     AC_CHECK_LIB([socket], [main])
1052     AC_CHECK_LIB([nsl], [main])
1053     AC_CHECK_LIB([umem], [main])
1054     SOLARIS="solaris"
1055     ;;
1056   linux*)
1057     AC_MSG_RESULT([Linux])
1058
1059     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1060     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1061     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1062
1063     dnl Linux has a compilation problem with mixing
1064     dnl netinet/in.h and linux/in6.h they are not
1065     dnl compatible.  There has been discussion on
1066     dnl how to fix it but no real progress on implementation
1067     dnl when they fix it, remove this
1068     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1069     ;;
1070   openbsd*)
1071     AC_MSG_RESULT([OpenBSD])
1072
1073     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1074     AC_DEFINE([KAME], [1], [KAME IPv6])
1075     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1076
1077     if test "x${enable_pimd}" != "xno"; then
1078       case "$host_os" in
1079       openbsd6.0)
1080         ;;
1081       openbsd[6-9]*)
1082         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1083         ;;
1084       esac
1085     fi
1086     ;;
1087   *)
1088     AC_MSG_RESULT([BSD])
1089
1090     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1091     AC_DEFINE([KAME], [1], [KAME IPv6])
1092     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1093     ;;
1094 esac
1095 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1096
1097 AC_SYS_LARGEFILE
1098
1099 dnl ------------------------
1100 dnl Integrated REALMS option
1101 dnl ------------------------
1102 if test "${enable_realms}" = "yes"; then
1103     case "$host_os" in
1104       linux*)
1105        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1106        ;;
1107       *)
1108        echo "Sorry, only Linux has REALMS support"
1109        exit 1
1110        ;;
1111     esac
1112 fi
1113 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1114
1115 dnl ---------------------
1116 dnl Integrated VTY option
1117 dnl ---------------------
1118 case "${enable_vtysh}" in
1119 "no")
1120   VTYSH="";;
1121 *)
1122   VTYSH="vtysh";
1123   AC_DEFINE([VTYSH], [1], [VTY shell])
1124
1125   prev_libs="$LIBS"
1126   AC_CHECK_LIB([readline], [main], [
1127     LIBREADLINE="-lreadline"
1128   ], [
1129     dnl readline failed - it might be incorrectly linked and missing its
1130     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1131     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1132       LIBREADLINE="$ac_cv_search_tputs"
1133     ], [
1134       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1135     ])
1136
1137     dnl re-try with the lib we found above
1138     unset ac_cv_lib_readline_main
1139     AC_CHECK_LIB([readline], [main], [
1140       LIBREADLINE="-lreadline $LIBREADLINE"
1141     ], [
1142       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1143     ], [$LIBREADLINE])
1144   ], [])
1145   LIBS="$prev_libs"
1146
1147   AC_CHECK_HEADER([readline/history.h])
1148   if test $ac_cv_header_readline_history_h = no;then
1149     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1150   fi
1151   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1152   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1153     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1154   fi
1155   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1156   if test "$frr_cv_append_history" = yes; then
1157     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1158   fi
1159   ;;
1160 esac
1161 AC_SUBST([LIBREADLINE])
1162 AM_CONDITIONAL([VTYSH], test "x$VTYSH" = "xvtysh")
1163
1164 dnl ----------
1165 dnl PAM module
1166 dnl
1167 dnl FRR detects the PAM library it is built against by checking for a
1168 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1169 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1170 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1171 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1172 dnl of OpenPAM.
1173 dnl ----------
1174 if test "$with_libpam" = "yes"; then
1175   AC_CHECK_HEADER([security/pam_misc.h],
1176     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1177      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1178      pam_conv_func="misc_conv"
1179     ],
1180     [], FRR_INCLUDES)
1181   AC_CHECK_HEADER([security/openpam.h],
1182     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1183      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1184      pam_conv_func="openpam_ttyconv"
1185     ],
1186     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1187   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1188     AC_MSG_WARN([*** pam support will not be built ***])
1189     with_libpam="no"
1190   fi
1191 fi
1192
1193 if test "$with_libpam" = "yes"; then
1194 dnl took this test from proftpds configure.in and suited to our needs
1195 dnl -------------------------------------------------------------------------
1196 dnl
1197 dnl This next check looks funky due to a linker problem with some versions
1198 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1199 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1200 dnl with RedHat 6.2 and Debian 2.2 or better.
1201 AC_CHECK_LIB([pam], [pam_start],
1202   [AC_CHECK_LIB([pam], [$pam_conv_func],
1203     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1204      LIBPAM="-lpam"],
1205     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1206      LIBPAM="-lpam -lpam_misc"]
1207     )
1208   ],
1209
1210   [AC_CHECK_LIB([pam], [pam_end],
1211     [AC_CHECK_LIB([pam], [$pam_conv_func],
1212       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1213        LIBPAM="-lpam -ldl"],
1214       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1215        LIBPAM="-lpam -ldl -lpam_misc"]
1216      )
1217   ],AC_MSG_WARN([*** pam support will not be built ***]),
1218   [-ldl])
1219   ]
1220 )
1221 fi
1222 AC_SUBST([LIBPAM])
1223
1224 dnl -------------------------------
1225 dnl Endian-ness check
1226 dnl -------------------------------
1227 AC_WORDS_BIGENDIAN
1228
1229 dnl -------------------------------
1230 dnl check the size in byte of the C
1231 dnl -------------------------------
1232 dnl AC_CHECK_SIZEOF(char)
1233 dnl AC_CHECK_SIZEOF(int)
1234 dnl AC_CHECK_SIZEOF(short)
1235 dnl AC_CHECK_SIZEOF(long)
1236
1237 dnl ----------------------------
1238 dnl check existance of functions
1239 dnl ----------------------------
1240 AC_FUNC_FNMATCH
1241 AC_FUNC_FORK
1242 AC_FUNC_MKTIME
1243 AC_FUNC_STAT
1244
1245 dnl -------------------------------
1246 dnl bgpd needs pow() and hence libm
1247 dnl -------------------------------
1248 TMPLIBS="$LIBS"
1249 AC_CHECK_HEADER([math.h],
1250   [AC_CHECK_LIB([m], [pow],
1251     [LIBM="-lm"
1252      LIBS="$LIBS $LIBM"
1253      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1254     ])
1255 ])
1256 if test x"$LIBM" = x ; then
1257   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1258 fi
1259 LIBS="$TMPLIBS"
1260
1261 AC_SUBST([LIBM])
1262
1263 AC_CHECK_FUNCS([ppoll], [
1264   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1265 ])
1266 AC_CHECK_FUNCS([pollts], [
1267   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1268 ])
1269
1270 dnl ---------------
1271 dnl other functions
1272 dnl ---------------
1273 AC_CHECK_FUNCS([ \
1274         strlcat strlcpy \
1275         getgrouplist])
1276
1277 AC_CHECK_HEADER([asm-generic/unistd.h],
1278                 [AC_CHECK_DECL(__NR_setns,
1279                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1280                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1281                                ])
1282                  AC_CHECK_FUNCS([setns])]
1283                )
1284
1285 dnl --------------------------
1286 dnl Determine IS-IS I/O method
1287 dnl --------------------------
1288 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1289 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1290 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1291 AC_CHECK_HEADER([net/bpf.h])
1292 AC_CHECK_HEADER([sys/dlpi.h])
1293 AC_MSG_CHECKING([zebra IS-IS I/O method])
1294
1295 case "$host_os" in
1296   linux*)
1297     AC_MSG_RESULT([pfpacket])
1298     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1299     ;;
1300   solaris* | sunos*)
1301     AC_MSG_RESULT([DLPI])
1302     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1303     ;;
1304   *)
1305     if test $ac_cv_header_net_bpf_h = no; then
1306       if test $ac_cv_header_sys_dlpi_h = no; then
1307         AC_MSG_RESULT([none])
1308         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1309           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1310         fi
1311         AC_MSG_WARN([*** IS-IS support will not be built ***])
1312         enable_isisd="no"
1313         enable_fabricd="no"
1314       else
1315         AC_MSG_RESULT([DLPI])
1316       fi
1317       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1318     else
1319       AC_MSG_RESULT([BPF])
1320       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1321     fi
1322     ;;
1323 esac
1324 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1325
1326 dnl ---------------------------------------------------------------
1327 dnl figure out how to specify an interface in multicast sockets API
1328 dnl ---------------------------------------------------------------
1329 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1330
1331 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1332         #include <sys/socket.h>
1333         #include <netinet/in.h>
1334         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1335         #include <linux/types.h>
1336 ])
1337
1338 m4_define([FRR_INCLUDES],
1339 FRR_INCLUDES
1340 [#if HAVE_LINUX_MROUTE_H
1341 # include <linux/mroute.h>
1342 #endif
1343 ])dnl
1344
1345 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1346         #include <sys/socket.h>
1347         #include <sys/types.h>
1348         #include <netinet/in.h>
1349         #include <net/route.h>
1350 ])
1351
1352 m4_define([FRR_INCLUDES],
1353 FRR_INCLUDES
1354 [#if HAVE_NETINET_IP_MROUTE_H
1355 # include <netinet/ip_mroute.h>
1356 #endif
1357 ])dnl
1358
1359 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1360 AC_TRY_COMPILE([#include <sys/param.h>],
1361 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1362   return (0);
1363 #else
1364   #error No support for BSD struct ip_mreq hack detected
1365 #endif],[AC_MSG_RESULT([yes])
1366 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1367 AC_MSG_RESULT([no]))
1368
1369 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1370 AC_TRY_COMPILE([
1371 #include <sys/types.h>
1372 #include <netinet/in.h>
1373 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1374 ], [AC_MSG_RESULT([yes])
1375 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1376 AC_MSG_RESULT([no]))
1377
1378 dnl ---------------------------------------------------------------
1379 dnl figure out how to check link-state
1380 dnl ---------------------------------------------------------------
1381 AC_CHECK_HEADER([net/if_media.h],
1382   [m4_define([LINK_DETECT_INCLUDES],
1383     FRR_INCLUDES
1384     [#include <net/if_media.h>
1385   ])
1386   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1387     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1388     [], LINK_DETECT_INCLUDES)],
1389   [],
1390   FRR_INCLUDES)
1391
1392 dnl ---------------------------------------------------------------
1393 dnl Additional, newer way to check link-state using ifi_link_state.
1394 dnl Not available in all BSD's when ifmediareq available
1395 dnl ---------------------------------------------------------------
1396 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1397   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1398   [], FRR_INCLUDES)
1399
1400 dnl ------------------------
1401 dnl TCP_MD5SIG socket option
1402 dnl ------------------------
1403
1404 AC_CHECK_HEADER([netinet/tcp.h],
1405    [m4_define([MD5_INCLUDES],
1406       FRR_INCLUDES
1407       [#include <netinet/tcp.h>
1408     ])
1409     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1410    [],
1411    FRR_INCLUDES)
1412 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1413   AC_CHECK_HEADER([linux/tcp.h],
1414        [m4_define([MD5_INCLUDES],
1415           FRR_INCLUDES
1416           [#include <linux/tcp.h>
1417         ])
1418        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1419 fi
1420
1421 dnl ----------------------------------------------------------------------------
1422 dnl figure out if domainname is available in the utsname struct (GNU extension).
1423 dnl ----------------------------------------------------------------------------
1424 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1425
1426 dnl ------------------
1427 dnl IPv6 header checks
1428 dnl ------------------
1429 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1430         netinet6/in6_var.h netinet6/nd6.h], [], [],
1431         FRR_INCLUDES)
1432
1433 m4_define([FRR_INCLUDES],dnl
1434 FRR_INCLUDES
1435 [#if HAVE_NETINET6_IN6_H
1436 #include <netinet6/in6.h>
1437 #endif
1438 #if HAVE_NETINET_IN6_VAR_H
1439 #include <netinet/in6_var.h>
1440 #endif
1441 #include <netinet/icmp6.h>
1442 #if HAVE_NETINET6_IN6_VAR_H
1443 # include <netinet6/in6_var.h>
1444 #endif
1445 #if HAVE_NETINET6_ND6_H
1446 # include <netinet6/nd6.h>
1447 #endif
1448 ])dnl
1449
1450 dnl --------------------
1451 dnl Daemon disable check
1452 dnl --------------------
1453 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
1454
1455 if test "${enable_bgpd}" = "no";then
1456   BGPD=""
1457 else
1458   BGPD="bgpd"
1459 fi
1460 AM_CONDITIONAL([BGPD], [test "x$BGPD" = "xbgpd"])
1461
1462 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
1463 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
1464 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
1465
1466 AS_IF([test "${enable_ldpd}" != "no"], [
1467   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1468 ])
1469
1470 if test "$enable_bfdd" = "no"; then
1471   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1472   BFDD=""
1473 else
1474   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1475   BFDD="bfdd"
1476
1477   case $host_os in
1478     linux*)
1479       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1480       ;;
1481
1482     *)
1483       AC_DEFINE([BFD_BSD], [1], [bfdd])
1484       ;;
1485   esac
1486 fi
1487
1488 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
1489
1490 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1491   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1492 fi
1493
1494 NHRPD=""
1495 case "$host_os" in
1496   linux*)
1497     if test "${enable_nhrpd}" != "no"; then
1498       NHRPD="nhrpd"
1499     fi
1500     ;;
1501   *)
1502     if test "${enable_nhrpd}" = "yes"; then
1503       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1504     fi
1505     ;;
1506 esac
1507 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
1508
1509 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
1510
1511 if test "${enable_watchfrr}" = "no";then
1512   WATCHFRR=""
1513 else
1514   WATCHFRR="watchfrr"
1515 fi
1516 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
1517
1518 OSPFCLIENT=""
1519 if test "${enable_ospfapi}" != "no";then
1520     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1521
1522   if test "${enable_ospfclient}" != "no";then
1523       OSPFCLIENT="ospfclient"
1524   fi
1525 fi
1526
1527 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
1528 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
1529 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
1530 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
1531 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
1532 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
1533 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
1534 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
1535 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
1536 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
1537 AM_CONDITIONAL([VRRPD], [test "${enable_vrrpd}" != "no"])
1538
1539 if test "${enable_bgp_announce}" = "no";then
1540   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1541 else
1542   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1543 fi
1544
1545 if test "${enable_bgp_vnc}" != "no";then
1546   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1547 fi
1548 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1549
1550 AC_SUBST([SOLARIS])
1551 AC_CHECK_LIB([crypt], [crypt], [],
1552                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1553 AC_CHECK_LIB([resolv], [res_init])
1554
1555 dnl ---------------------------
1556 dnl check system has PCRE regexp
1557 dnl ---------------------------
1558 if test "x$enable_pcreposix" = "xyes"; then
1559   AC_CHECK_LIB([pcreposix], [regexec], [], [
1560     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1561   ])
1562 fi
1563 AC_SUBST([HAVE_LIBPCREPOSIX])
1564
1565 dnl ------------------
1566 dnl check C-Ares library
1567 dnl ------------------
1568 if test "${NHRPD}" != ""; then
1569   PKG_CHECK_MODULES([CARES], [libcares], ,[
1570     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1571   ])
1572 fi
1573
1574
1575 dnl ------------------
1576 dnl check Net-SNMP library
1577 dnl ------------------
1578 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1579    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1580    if test x"$NETSNMP_CONFIG" = x"no"; then
1581       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1582    fi
1583    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1584    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1585    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1586    # among other things we avoid a GPL vs. OpenSSL license conflict here
1587    for removelib in crypto ssl sensors pci wrap; do
1588      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1589    done
1590    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1591    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1592 int main(void);
1593 ],
1594 [
1595 {
1596   return 0;
1597 }
1598 ])], [
1599      AC_MSG_RESULT([no])
1600      AC_MSG_ERROR([--enable-snmp given but not usable])])
1601    case "${enable_snmp}" in
1602      yes)
1603       SNMP_METHOD=agentx
1604       ;;
1605      agentx)
1606       SNMP_METHOD="${enable_snmp}"
1607       ;;
1608      *)
1609       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1610       ;;
1611    esac
1612    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1613    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1614 fi
1615 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1616 AC_SUBST([SNMP_LIBS])
1617 AC_SUBST([SNMP_CFLAGS])
1618
1619 dnl ---------------
1620 dnl libyang
1621 dnl ---------------
1622 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.7], , [
1623   AC_MSG_ERROR([libyang (>= 0.16.7) was not found on your system.])
1624 ])
1625 ac_cflags_save="$CFLAGS"
1626 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1627 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1628   AC_MSG_ERROR([m4_normalize([
1629     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1630     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1631   ])
1632 ], [[#include <libyang/libyang.h>]])
1633 CFLAGS="$ac_cflags_save"
1634
1635 dnl ---------------
1636 dnl configuration rollbacks
1637 dnl ---------------
1638 SQLITE3=false
1639 if test "$enable_config_rollbacks" = "yes"; then
1640   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1641     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1642     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1643     SQLITE3=true
1644   ], [
1645     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1646   ])
1647 fi
1648 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
1649
1650 dnl ---------------
1651 dnl confd
1652 dnl ---------------
1653 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1654    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1655    if test "x$CONFD" = "x/bin/false"; then
1656       AC_MSG_ERROR([confd was not found on your system.])]
1657    fi
1658    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1659    AC_SUBST([CONFD_CFLAGS])
1660    CONFD_LIBS="-lconfd"
1661    AC_SUBST([CONFD_LIBS])
1662    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1663 fi
1664 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
1665
1666 dnl ---------------
1667 dnl sysrepo
1668 dnl ---------------
1669 if test "$enable_sysrepo" = "yes"; then
1670   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1671       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1672       SYSREPO=true],
1673       [SYSREPO=false
1674       AC_MSG_ERROR([sysrepo was not found on your system.])]
1675   )
1676 fi
1677 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
1678
1679 dnl ---------------
1680 dnl gRPC
1681 dnl ---------------
1682 if test "$enable_grpc" = "yes"; then
1683   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1684     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1685     if test "$PROTOC" = "/bin/false"; then
1686       AC_MSG_FAILURE([grpc requested but protoc not found.])
1687     fi
1688
1689     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1690     GRPC=true
1691   ], [
1692     GRPC=false
1693     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1694   ])
1695 fi
1696 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
1697
1698 dnl ---------------
1699 dnl math
1700 dnl ---------------
1701 AC_SEARCH_LIBS([sqrt], [m])
1702
1703 dnl ---------------
1704 dnl dlopen & dlinfo
1705 dnl ---------------
1706 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1707   AC_MSG_ERROR([unable to find the dlopen()])
1708 ])
1709
1710 AC_CHECK_HEADERS([link.h])
1711
1712 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1713   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1714 #include <stdlib.h>
1715 #ifdef HAVE_LINK_H
1716 #include <link.h>
1717 #endif
1718 #include <dlfcn.h>
1719 ]], [[
1720   char origin[1];
1721   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1722 ]])], [
1723     frr_cv_rtld_di_origin=yes
1724   ], [
1725     frr_cv_rtld_di_origin=no
1726   ])
1727 ])
1728 if test "$frr_cv_rtld_di_origin" = yes; then
1729   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1730 fi
1731
1732 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1733   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1734 #include <stdlib.h>
1735 #ifdef HAVE_LINK_H
1736 #include <link.h>
1737 #endif
1738 #include <dlfcn.h>
1739 ]], [[
1740   struct link_map *lm = NULL;
1741   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1742 ]])], [
1743     frr_cv_rtld_di_linkmap=yes
1744   ], [
1745     frr_cv_rtld_di_linkmap=no
1746   ])
1747 ])
1748 if test "$frr_cv_rtld_di_linkmap" = yes; then
1749   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1750 fi
1751
1752 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
1753
1754 dnl ---------------------------
1755 dnl sockaddr and netinet checks
1756 dnl ---------------------------
1757 AC_CHECK_TYPES([
1758         struct sockaddr_dl,
1759         struct vifctl, struct mfcctl, struct sioc_sg_req,
1760         vifi_t, struct sioc_vif_req, struct igmpmsg,
1761         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1762         struct nd_opt_adv_interval, struct rt_addrinfo,
1763         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1764         struct nd_opt_rdnss, struct nd_opt_dnssl],
1765         [], [], FRR_INCLUDES)
1766
1767 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1768         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1769         struct sockaddr_dl.sdl_len,
1770         struct if6_aliasreq.ifra_lifetime,
1771         struct nd_opt_adv_interval.nd_opt_ai_type],
1772         [], [], FRR_INCLUDES)
1773
1774 dnl ---------------------------
1775 dnl IRDP/pktinfo/icmphdr checks
1776 dnl ---------------------------
1777
1778 AC_CHECK_TYPES([struct in_pktinfo], [
1779   AC_CHECK_TYPES([struct icmphdr], [
1780     IRDP=true
1781   ], [
1782     IRDP=false
1783   ], [FRR_INCLUDES])
1784 ], [
1785   IRDP=false
1786 ], [FRR_INCLUDES])
1787
1788 case "${enable_irdp}" in
1789 yes)
1790   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1791   ;;
1792 no)
1793   IRDP=false
1794   ;;
1795 esac
1796
1797 AM_CONDITIONAL([IRDP], [$IRDP])
1798
1799 dnl -----------------------
1800 dnl checking for IP_PKTINFO
1801 dnl -----------------------
1802 AC_MSG_CHECKING([for IP_PKTINFO])
1803 AC_TRY_COMPILE([#include <netdb.h>], [
1804   int opt = IP_PKTINFO;
1805 ], [
1806   AC_MSG_RESULT([yes])
1807   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1808 ], [
1809   AC_MSG_RESULT([no])
1810 ])
1811
1812 dnl ---------------------------
1813 dnl checking for IP_RECVDSTADDR
1814 dnl ---------------------------
1815 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1816 AC_TRY_COMPILE([#include <netinet/in.h>], [
1817   int opt = IP_RECVDSTADDR;
1818 ], [
1819   AC_MSG_RESULT([yes])
1820   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1821 ], [
1822   AC_MSG_RESULT([no])
1823 ])
1824
1825 dnl ----------------------
1826 dnl checking for IP_RECVIF
1827 dnl ----------------------
1828 AC_MSG_CHECKING([for IP_RECVIF])
1829 AC_TRY_COMPILE([#include <netinet/in.h>], [
1830   int opt = IP_RECVIF;
1831 ], [
1832   AC_MSG_RESULT([yes])
1833   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1834 ], [
1835   AC_MSG_RESULT([no])
1836 ])
1837
1838 dnl ----------------------
1839 dnl checking for SO_BINDANY
1840 dnl ----------------------
1841 AC_MSG_CHECKING([for SO_BINDANY])
1842 AC_TRY_COMPILE([#include <sys/socket.h>], [
1843   int opt = SO_BINDANY;
1844 ], [
1845   AC_MSG_RESULT([yes])
1846   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1847 ], [
1848   AC_MSG_RESULT([no])
1849 ])
1850
1851 dnl ----------------------
1852 dnl checking for IP_FREEBIND
1853 dnl ----------------------
1854 AC_MSG_CHECKING([for IP_FREEBIND])
1855 AC_TRY_COMPILE([#include <netinet/in.h>], [
1856   int opt = IP_FREEBIND;
1857 ], [
1858   AC_MSG_RESULT([yes])
1859   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1860 ], [
1861   AC_MSG_RESULT([no])
1862 ])
1863
1864 dnl --------------------------------------
1865 dnl checking for be32dec existence or not
1866 dnl --------------------------------------
1867 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1868                [#include <sys/endian.h>])
1869
1870 dnl --------------------------------------
1871 dnl checking for clock_time monotonic struct and call
1872 dnl --------------------------------------
1873 AC_CHECK_DECL([CLOCK_MONOTONIC],
1874         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1875          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1876 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1877
1878 dnl --------------------------------------
1879 dnl checking for flex and bison
1880 dnl --------------------------------------
1881
1882 AM_PROG_LEX
1883 AC_MSG_CHECKING([version of flex])
1884 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1885 frr_ac_flex_version="${frr_ac_flex_version##* }"
1886 AC_MSG_RESULT([$frr_ac_flex_version])
1887 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1888   LEX="$SHELL $missing_dir/missing flex"
1889   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1890     AC_MSG_WARN([using pregenerated flex output files])
1891   else
1892     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1893   fi
1894   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1895   AC_SUBST([LEXLIB], [''])
1896 ])
1897
1898 AC_PROG_YACC
1899 dnl thanks GNU bison for this b*llshit...
1900 AC_MSG_CHECKING([version of bison])
1901 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1902 frr_ac_bison_version="${frr_ac_bison_version##* }"
1903 frr_ac_bison_missing="false"
1904 case "x${frr_ac_bison_version}" in
1905   x2.7*)
1906     BISON_OPENBRACE='"'
1907     BISON_CLOSEBRACE='"'
1908     BISON_VERBOSE=''
1909     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1910     ;;
1911   x2.*|x1.*)
1912     AC_MSG_RESULT([$frr_ac_bison_version])
1913     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1914     frr_ac_bison_missing="true"
1915     ;;
1916   x)
1917     AC_MSG_RESULT([none])
1918     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1919     frr_ac_bison_missing="true"
1920     ;;
1921   *)
1922     BISON_OPENBRACE='{'
1923     BISON_CLOSEBRACE='}'
1924     BISON_VERBOSE='-Dparse.error=verbose'
1925     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1926     ;;
1927 esac
1928 AC_SUBST([BISON_OPENBRACE])
1929 AC_SUBST([BISON_CLOSEBRACE])
1930 AC_SUBST([BISON_VERBOSE])
1931
1932 if $frr_ac_bison_missing; then
1933   YACC="$SHELL $missing_dir/missing bison -y"
1934   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1935     AC_MSG_WARN([using pregenerated bison output files])
1936   else
1937     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1938   fi
1939 fi
1940
1941 dnl -------------------
1942 dnl capabilities checks
1943 dnl -------------------
1944 if test "${enable_capabilities}" != "no"; then
1945   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
1946   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1947     [AC_MSG_RESULT([yes])
1948      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
1949      frr_ac_keepcaps="yes"],
1950      AC_MSG_RESULT([no])
1951   )
1952   if test x"${frr_ac_keepcaps}" = x"yes"; then
1953     AC_CHECK_HEADERS([sys/capability.h])
1954   fi
1955   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1956     AC_CHECK_LIB([cap], [cap_init],
1957       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
1958        LIBCAP="-lcap"
1959        frr_ac_lcaps="yes"]
1960     )
1961   else
1962     AC_CHECK_HEADERS([priv.h],
1963      [AC_MSG_CHECKING([Solaris style privileges are available])
1964       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
1965           [AC_MSG_RESULT([yes])
1966            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
1967            frr_ac_scaps="yes"],
1968            AC_MSG_RESULT(no)
1969       )
1970      ]
1971    )
1972   fi
1973   if test x"${frr_ac_scaps}" = x"yes" \
1974        -o x"${frr_ac_lcaps}" = x"yes"; then
1975     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
1976   fi
1977 fi
1978 AC_SUBST([LIBCAP])
1979
1980 dnl ---------------------------
1981 dnl check for glibc 'backtrace'
1982 dnl ---------------------------
1983 if test x"${enable_backtrace}" != x"no" ; then
1984   backtrace_ok=no
1985   PKG_CHECK_MODULES([UNWIND], [libunwind], [
1986     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
1987     backtrace_ok=yes
1988   ], [
1989     case "$host_os" in
1990     sunos* | solaris2*)
1991       AC_CHECK_FUNCS([printstack], [
1992         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
1993         backtrace_ok=yes
1994       ])
1995       ;;
1996     esac
1997     if test "$backtrace_ok" = no; then
1998       AC_CHECK_HEADER([execinfo.h], [
1999         AC_SEARCH_LIBS([backtrace], [execinfo], [
2000           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2001           backtrace_ok=yes
2002         ],, [-lm])
2003       ])
2004     fi
2005   ])
2006
2007   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2008     dnl user explicitly requested backtrace but we failed to find support
2009     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2010   fi
2011 fi
2012
2013 dnl -----------------------------------------
2014 dnl check for malloc mallinfo struct and call
2015 dnl this must try and link using LIBS, in
2016 dnl order to check no alternative allocator
2017 dnl has been specified, which might not provide
2018 dnl mallinfo, e.g. such as Umem on Solaris.
2019 dnl -----------------------------------------
2020 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2021
2022 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2023   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2024 #ifdef HAVE_MALLOC_H
2025 #include <malloc.h>
2026 #endif
2027 #ifdef HAVE_MALLOC_NP_H
2028 #include <malloc_np.h>
2029 #endif
2030 #ifdef HAVE_MALLOC_MALLOC_H
2031 #include <malloc/malloc.h>
2032 #endif
2033 ]], [[
2034 struct mallinfo ac_x; ac_x = mallinfo ();
2035 ]])], [
2036     frr_cv_mallinfo=yes
2037   ], [
2038     frr_cv_mallinfo=no
2039   ])
2040 ])
2041 if test "$frr_cv_mallinfo" = yes; then
2042   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2043 fi
2044
2045 AC_MSG_CHECKING([whether malloc_usable_size is available])
2046 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2047 #ifdef HAVE_MALLOC_H
2048 #include <malloc.h>
2049 #endif
2050 #ifdef HAVE_MALLOC_MALLOC_H
2051 #include <malloc/malloc.h>
2052 #endif
2053 ]], [[
2054 size_t ac_x; ac_x = malloc_usable_size(NULL);
2055 ]])], [
2056   AC_MSG_RESULT([yes])
2057   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2058 ], [
2059   AC_MSG_RESULT([no])
2060
2061   AC_MSG_CHECKING([whether malloc_size is available])
2062   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2063 #ifdef HAVE_MALLOC_H
2064 #include <malloc.h>
2065 #endif
2066 #ifdef HAVE_MALLOC_MALLOC_H
2067 #include <malloc/malloc.h>
2068 #endif
2069 ]], [[
2070 size_t ac_x; ac_x = malloc_size(NULL);
2071 ]])], [
2072     AC_MSG_RESULT([yes])
2073     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2074   ], [
2075     AC_MSG_RESULT([no])
2076   ])
2077 ])
2078
2079 dnl ------
2080 dnl ZeroMQ
2081 dnl ------
2082 if test "x$enable_zeromq" != "xno"; then
2083   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2084     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2085     ZEROMQ=true
2086   ], [
2087     if test "x$enable_zeromq" = "xyes"; then
2088       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2089     fi
2090   ])
2091 fi
2092 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2093
2094 dnl ----------
2095 dnl configure date
2096 dnl ----------
2097 dev_version=`echo $VERSION | grep dev`
2098 #don't expire deprecated code in non 'dev' branch
2099 if test "${dev_version}" = ""; then
2100    CONFDATE=0
2101 else
2102    CONFDATE=`date '+%Y%m%d'`
2103 fi
2104 AC_SUBST([CONFDATE])
2105
2106 dnl ------------------------------
2107 dnl set paths for state directory
2108 dnl ------------------------------
2109 AC_MSG_CHECKING([directory to use for state file])
2110 if test "${prefix}" = "NONE"; then
2111   frr_statedir_prefix="";
2112 else
2113   frr_statedir_prefix=${prefix}
2114 fi
2115 if test "${localstatedir}" = '${prefix}/var'; then
2116   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2117                         ${frr_statedir_prefix}/var/adm dnl
2118                         ${frr_statedir_prefix}/etc dnl
2119                         /var/run        dnl
2120                         /var/adm        dnl
2121                         /etc            dnl
2122                         /dev/null;
2123   do
2124     test -d $FRR_STATE_DIR && break
2125   done
2126   frr_statedir=$FRR_STATE_DIR
2127 else
2128   frr_statedir=${localstatedir}
2129 fi
2130 if test $frr_statedir = "/dev/null"; then
2131     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2132 fi
2133 AC_MSG_RESULT([${frr_statedir}])
2134 AC_SUBST([frr_statedir])
2135
2136 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2137 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2138 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2139 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2140 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2141
2142 dnl autoconf does this, but it does it too late...
2143 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2144 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2145
2146 dnl get the full path, recursing through variables...
2147 vtysh_bin="$bindir/vtysh"
2148 for I in 1 2 3 4 5 6 7 8 9 10; do
2149         eval vtysh_bin="\"$vtysh_bin\""
2150 done
2151 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2152 AC_SUBST([vtysh_bin])
2153
2154 CFG_SYSCONF="$sysconfdir"
2155 CFG_SBIN="$sbindir"
2156 CFG_STATE="$frr_statedir"
2157 CFG_MODULE="$moduledir"
2158 CFG_YANGMODELS="$yangmodelsdir"
2159 CFG_LIBYANG_PLUGINS="$libyang_pluginsdir"
2160 for I in 1 2 3 4 5 6 7 8 9 10; do
2161         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2162         eval CFG_SBIN="\"$CFG_SBIN\""
2163         eval CFG_STATE="\"$CFG_STATE\""
2164         eval CFG_MODULE="\"$CFG_MODULE\""
2165         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2166         eval CFG_LIBYANG_PLUGINS="\"$CFG_LIBYANG_PLUGINS\""
2167 done
2168 AC_SUBST([CFG_SYSCONF])
2169 AC_SUBST([CFG_SBIN])
2170 AC_SUBST([CFG_STATE])
2171 AC_SUBST([CFG_MODULE])
2172 AC_SUBST([CFG_YANGMODELS])
2173 AC_SUBST([CFG_LIBYANG_PLUGINS])
2174 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2175 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2176 AC_DEFINE_UNQUOTED([LIBYANG_PLUGINS_PATH], ["$CFG_LIBYANG_PLUGINS"], [path to libyang plugins])
2177 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2178
2179 dnl ------------------------------------
2180 dnl Enable RPKI and add librtr to libs
2181 dnl ------------------------------------
2182 if test "${enable_rpki}" = "yes"; then
2183   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
2184       [RPKI=true],
2185       [RPKI=false
2186       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2187   )
2188 fi
2189 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2190
2191 dnl ------------------------------------------
2192 dnl Check whether rtrlib was build with ssh support
2193 dnl ------------------------------------------
2194 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2195 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2196                         [[struct tr_ssh_config config;]])],
2197         [AC_MSG_RESULT([yes])
2198         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2199         AC_MSG_RESULT([no])
2200 )
2201
2202 dnl ---------------------------
2203 dnl Check htonl works correctly
2204 dnl ---------------------------
2205 AC_MSG_CHECKING([for working htonl])
2206 AC_CACHE_VAL(ac_cv_htonl_works,
2207  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2208                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2209  ]
2210 )
2211 AC_MSG_RESULT([$ac_cv_htonl_works])
2212
2213 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2214
2215 AC_CONFIG_FILES([
2216           config.version
2217           changelog-auto
2218           redhat/frr.spec
2219           solaris/Makefile
2220           alpine/APKBUILD
2221           snapcraft/snapcraft.yaml
2222           lib/version.h
2223           tests/lib/cli/test_cli.refout
2224           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2225           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2226           pkgsrc/eigrpd.sh])
2227
2228 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2229 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2230 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2231 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2232 AC_CONFIG_FILES([tools/frrcommon.sh])
2233
2234 AC_CONFIG_COMMANDS([lib/route_types.h], [
2235         dst="${ac_abs_top_builddir}/lib/route_types.h"
2236         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2237                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2238                 > "${dst}.tmp"
2239         test -f "${dst}" \
2240                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2241                 && rm "${dst}.tmp" \
2242                 || mv "${dst}.tmp" "${dst}"
2243 ], [
2244         PERL="$PERL"
2245 ])
2246
2247 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2248     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2249         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2250         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2251                 "${ac_abs_top_srcdir}" \
2252                 > "${dst}.tmp"
2253         test -f "${dst}" \
2254                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2255                 && rm "${dst}.tmp" \
2256                 || mv "${dst}.tmp" "${dst}"
2257     ], [
2258         PERL="$PERL"
2259     ])
2260 ])
2261
2262 ## Hack, but working solution to avoid rebuilding of frr.info.
2263 ## It's already in CVS until texinfo 4.7 is more common.
2264 AC_OUTPUT
2265
2266 echo "
2267 FRRouting configuration
2268 ------------------------------
2269 FRR version             : ${PACKAGE_VERSION}
2270 host operating system   : ${host_os}
2271 source code location    : ${srcdir}
2272 compiler                : ${CC}
2273 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2274 make                    : ${MAKE-make}
2275 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2276 state file directory    : ${frr_statedir}
2277 config file directory   : `eval echo \`echo ${sysconfdir}\``
2278 example directory       : `eval echo \`echo ${exampledir}\``
2279 module directory        : ${CFG_MODULE}
2280 user to run as          : ${enable_user}
2281 group to run as         : ${enable_group}
2282 group for vty sockets   : ${enable_vty_group}
2283 config file mask        : ${enable_configfile_mask}
2284 log file mask           : ${enable_logfile_mask}
2285 zebra protobuf enabled  : ${enable_protobuf:-no}
2286
2287 The above user and group must have read/write access to the state file
2288 directory and to the config files in the config file directory."
2289
2290 if test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" = false; then
2291   AC_MSG_WARN([sphinx is missing but required to build documentation])
2292 fi
2293 if test "$frr_py_mod_pytest" = false; then
2294   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2295 fi