configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.2-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST([HOSTTOOLS])
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS([config.h])
  64
  65 AC_PATH_PROG([PERL], [perl])
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST([exampledir])
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST([pkgsrcrcdir])
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94
  95 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
  96         yangmodelsdir="$withval"
  97 ], [
  98         yangmodelsdir="\${datarootdir}/yang"
  99 ])
 100 AC_SUBST([yangmodelsdir])
 101
 102 AC_ARG_WITH([libyang_pluginsdir], [AS_HELP_STRING([--with-libyang-pluginsdir=DIR], [yangmodule plugins directory (${libdir}/frr/libyang_plugins)])], [
 103         libyang_pluginsdir="$withval"
 104 ], [
 105    libyang_pluginsdir="\${libdir}/frr/libyang_plugins"
 106 ])
 107 AC_SUBST([libyang_pluginsdir])
 108
 109 AC_ARG_ENABLE(tcmalloc,
 110         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 111 [case "${enableval}" in
 112   yes) tcmalloc_enabled=true
 113 LIBS="$LIBS -ltcmalloc_minimal"
 114  ;;
 115   no)  tcmalloc_enabled=false ;;
 116   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 117 esac],[tcmalloc_enabled=false])
 118
 119
 120 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 121 dnl flag determination logic.
 122 CFLAGS="${CFLAGS:-}"
 123
 124 dnl --------------------
 125 dnl Check CC and friends
 126 dnl --------------------
 127 dnl note orig_cflags is also used further down
 128 orig_cflags="$CFLAGS"
 129 orig_cxxflags="$CXXFLAGS"
 130 AC_LANG([C])
 131 AC_PROG_CC
 132 AC_PROG_CPP
 133 AC_PROG_CXX
 134 AM_PROG_CC_C_O
 135 dnl remove autoconf default "-g -O2"
 136 CFLAGS="$orig_cflags"
 137 CXXFLAGS="$orig_cxxflags"
 138 AC_PROG_CC_C99
 139 dnl NB: see C11 below
 140
 141 AC_PROG_EGREP
 142 PKG_PROG_PKG_CONFIG
 143
 144 dnl autoconf 2.59 appears not to support AC_PROG_SED
 145 dnl AC_PROG_SED
 146 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 147
 148 dnl try and enable CFLAGS that are useful for FRR
 149 dnl - specifically, options to control warnings
 150
 151 AC_USE_SYSTEM_EXTENSIONS
 152 AC_DEFUN([AC_C_FLAG], [{
 153     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 154     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 155         AC_LANG_PUSH([C])
 156         ac_c_flag_save="$CFLAGS"
 157         CFLAGS="$CFLAGS $1"
 158         AC_COMPILE_IFELSE(
 159                 [AC_LANG_PROGRAM([[]])],
 160                 [
 161                         cachename=yes
 162                 ], [
 163                         cachename=no
 164                 ])
 165         CFLAGS="$ac_c_flag_save"
 166         AC_LANG_POP([C])
 167     ])
 168     if test "${cachename}" = yes; then
 169         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 170     else
 171         :
 172         $2
 173     fi
 174     m4_popdef([cachename])
 175 }])
 176
 177 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 178         AC_LANG_PUSH([C])
 179         ac_cflags_save="$CFLAGS"
 180         ac_libs_save="$LIBS"
 181         CFLAGS="$CFLAGS $1"
 182         LIBS="$LIBS $2"
 183         AC_LINK_IFELSE(
 184                 [$3],
 185                 [
 186                         AC_MSG_RESULT([yes])
 187                         CFLAGS="$ac_cflags_save"
 188                         LIBS="$ac_libs_save"
 189                         $5
 190                 ], [
 191                         AC_MSG_RESULT([no])
 192                         CFLAGS="$ac_cflags_save"
 193                         LIBS="$ac_libs_save"
 194                         $4
 195                 ])
 196         AC_LANG_POP([C])
 197         }])
 198
 199 dnl ICC won't bail on unknown options without -diag-error 10006
 200 dnl need to do this first so we get useful results for the other options
 201 AC_C_FLAG([-diag-error 10006])
 202
 203 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 204 ac_cc="$CC"
 205 CC="${CC% -std=gnu99}"
 206 CC="${CC% -std=c99}"
 207
 208 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 209
 210 dnl if the user has specified any CFLAGS, override our settings
 211 if test "x${enable_gcov}" = "xyes"; then
 212    if test "z$orig_cflags" = "z"; then
 213       AC_C_FLAG([-coverage])
 214       AC_C_FLAG([-O0])
 215    fi
 216
 217    LDFLAGS="${LDFLAGS} -lgcov"
 218 elif test "x${enable_dev_build}" = "xyes"; then
 219    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 220    if test "z$orig_cflags" = "z"; then
 221       AC_C_FLAG([-g3])
 222       AC_C_FLAG([-O0])
 223    fi
 224    if test "x${enable_lua}" = "xyes"; then
 225       AX_PROG_LUA([5.3])
 226       AX_LUA_HEADERS
 227       AX_LUA_LIBS([
 228          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 229          LIBS="$LIBS $LUA_LIB"
 230       ])
 231    fi
 232 else
 233    if test "x${enable_lua}" = "xyes"; then
 234       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 235    fi
 236    if test "z$orig_cflags" = "z"; then
 237       AC_C_FLAG([-g])
 238       AC_C_FLAG([-Os], [
 239         AC_C_FLAG([-O2])
 240       ])
 241    fi
 242 fi
 243 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 244
 245 dnl always want these CFLAGS
 246 AC_C_FLAG([-fno-omit-frame-pointer])
 247 AC_C_FLAG([-funwind-tables])
 248 AC_C_FLAG([-Wall])
 249 AC_C_FLAG([-Wextra])
 250 AC_C_FLAG([-Wmissing-prototypes])
 251 AC_C_FLAG([-Wmissing-declarations])
 252 AC_C_FLAG([-Wpointer-arith])
 253 AC_C_FLAG([-Wbad-function-cast])
 254 AC_C_FLAG([-Wwrite-strings])
 255 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 256   AC_C_FLAG([-Wcast-qual])
 257   AC_C_FLAG([-Wstrict-prototypes])
 258   AC_C_FLAG([-Wmissing-noreturn])
 259   AC_C_FLAG([-Wmissing-format-attribute])
 260   AC_C_FLAG([-Wunreachable-code])
 261   AC_C_FLAG([-Wpacked])
 262   AC_C_FLAG([-Wpadded])
 263   AC_C_FLAG([-Wshadow])
 264 else
 265   AC_C_FLAG([-Wno-unused-result])
 266 fi
 267 AC_C_FLAG([-Wno-unused-parameter])
 268 AC_C_FLAG([-Wno-missing-field-initializers])
 269
 270 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 271 AC_SUBST([CXX_COMPAT_CFLAGS])
 272
 273 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 274 dnl for some reason the string consts get 'promoted' to char *,
 275 dnl triggering a const to non-const conversion warning.
 276 AC_C_FLAG([-diag-disable 3179])
 277
 278 if test x"${enable_werror}" = x"yes" ; then
 279   WERROR="-Werror"
 280 fi
 281 AC_SUBST([WERROR])
 282
 283 SAN_FLAGS=""
 284 if test "$enable_address_sanitizer" = "yes"; then
 285   AC_C_FLAG([-fsanitize=address], [
 286     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 287   ], [
 288     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 289   ])
 290 fi
 291 if test "$enable_thread_sanitizer" = "yes"; then
 292   AC_C_FLAG([-fsanitize=thread], [
 293     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 294   ], [
 295     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 296   ])
 297 fi
 298 if test "$enable_memory_sanitizer" = "yes"; then
 299   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 300     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 301   ], [
 302     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 303   ])
 304 fi
 305 AC_SUBST([SAN_FLAGS])
 306
 307 dnl ----------
 308 dnl Essentials
 309 dnl ----------
 310
 311 AX_PTHREAD([
 312   CC="$PTHREAD_CC"
 313   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 314   LIBS="$PTHREAD_LIBS $LIBS"
 315 ], [
 316   AC_MSG_FAILURE([This FRR version needs pthreads])
 317 ])
 318
 319 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 320                 [frr_cv_pthread_condattr_setclock=yes],
 321                 [frr_cv_pthread_condattr_setclock=no])
 322 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 323   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 324 fi
 325
 326 dnl --------------
 327 dnl Check programs
 328 dnl --------------
 329 AC_PROG_INSTALL
 330 AC_PROG_LN_S
 331 AC_PROG_MAKE_SET
 332 AC_CHECK_TOOL([AR], [ar])
 333
 334 dnl -------
 335 dnl libtool
 336 dnl -------
 337 AC_ARG_ENABLE([static-bin],
 338   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 339 LT_INIT
 340 _LT_CONFIG_LIBTOOL([
 341   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 342     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 343 ])
 344 if test "$enable_static_bin" = "yes"; then
 345   AC_LDFLAGS="-static"
 346   if test "$enable_static" != "yes"; then
 347     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 348   fi
 349 fi
 350 if test "$enable_shared" != "yes"; then
 351   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 352 fi
 353 AC_SUBST([AC_LDFLAGS])
 354 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 355
 356 dnl $AR and $RANLIB are set by LT_INIT above
 357 AC_MSG_CHECKING([whether $AR supports D option])
 358 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 359   AC_MSG_RESULT([yes])
 360   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 361   ARFLAGS="crD"
 362   AR_FLAGS="crD"
 363 else
 364   AC_MSG_RESULT([no])
 365   ARFLAGS="cru"
 366   AR_FLAGS="cru"
 367 fi
 368 AC_SUBST([ARFLAGS])
 369 AC_SUBST([AR_FLAGS])
 370
 371 AC_MSG_CHECKING([whether $RANLIB supports D option])
 372 if $RANLIB -D conftest.a >/dev/null 2>/dev/null; then
 373   AC_MSG_RESULT([yes])
 374   RANLIB="$RANLIB -D"
 375 else
 376   AC_MSG_RESULT([no])
 377 fi
 378 AC_SUBST([RANLIB])
 379
 380 test -f conftest.a && rm conftest.a
 381
 382 dnl ----------------------
 383 dnl Packages configuration
 384 dnl ----------------------
 385 if test -f config.version; then
 386   . ./config.version
 387 elif test -f "${srcdir}/config.version"; then
 388   . "${srcdir}/config.version"
 389 fi
 390 AC_ARG_WITH([pkg-extra-version],
 391   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 392   if test "$withval" = "no"; then
 393     EXTRAVERSION=
 394   else
 395     EXTRAVERSION=$withval
 396   fi
 397 ], [])
 398 AC_ARG_WITH([pkg-git-version],
 399         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 400         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 401 AC_ARG_WITH([vtysh_pager],
 402         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 403         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 404 AC_ARG_ENABLE([vtysh],
 405   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 406 AC_ARG_ENABLE([doc],
 407   AS_HELP_STRING([--disable-doc], [do not build docs]))
 408 AC_ARG_ENABLE([doc-html],
 409   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 410 AC_ARG_ENABLE([zebra],
 411   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 412 AC_ARG_ENABLE([bgpd],
 413   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 414 AC_ARG_ENABLE([ripd],
 415   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 416 AC_ARG_ENABLE([ripngd],
 417   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 418 AC_ARG_ENABLE([ospfd],
 419   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 420 AC_ARG_ENABLE([ospf6d],
 421   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 422 AC_ARG_ENABLE([ldpd],
 423   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 424 AC_ARG_ENABLE([nhrpd],
 425   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 426 AC_ARG_ENABLE([eigrpd],
 427   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 428 AC_ARG_ENABLE([babeld],
 429   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 430 AC_ARG_ENABLE([watchfrr],
 431   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 432 AC_ARG_ENABLE([isisd],
 433   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 434 AC_ARG_ENABLE([pimd],
 435   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 436 AC_ARG_ENABLE([pbrd],
 437   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 438 AC_ARG_ENABLE([sharpd],
 439   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 440 AC_ARG_ENABLE([staticd],
 441   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 442 AC_ARG_ENABLE([fabricd],
 443   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 444 AC_ARG_ENABLE([bgp-announce],
 445   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 446 AC_ARG_ENABLE([vrrpd],
 447   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 448 AC_ARG_ENABLE([bgp-vnc],
 449   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 450 AC_ARG_ENABLE([snmp],
 451   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 452 AC_ARG_ENABLE([config_rollbacks],
 453   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 454 AC_ARG_ENABLE([confd],
 455   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 456 AC_ARG_ENABLE([sysrepo],
 457   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 458 AC_ARG_ENABLE([grpc],
 459   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 460 AC_ARG_ENABLE([zeromq],
 461   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 462 AC_ARG_WITH([libpam],
 463   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 464 AC_ARG_ENABLE([ospfapi],
 465   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 466 AC_ARG_ENABLE([ospfclient],
 467   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 468                           (this is the default if --disable-ospfapi is set)]))
 469 AC_ARG_ENABLE([multipath],
 470   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 471 AC_ARG_ENABLE([user],
 472   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 473 AC_ARG_ENABLE([group],
 474   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 475 AC_ARG_ENABLE([vty_group],
 476   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 477 AC_ARG_ENABLE([configfile_mask],
 478   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 479 AC_ARG_ENABLE([logfile_mask],
 480   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 481 AC_ARG_ENABLE([shell_access],
 482   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 483 AC_ARG_ENABLE([realms],
 484   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 485 AC_ARG_ENABLE([rtadv],
 486   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 487 AC_ARG_ENABLE([irdp],
 488   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 489 AC_ARG_ENABLE([capabilities],
 490   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 491 AC_ARG_ENABLE([rusage],
 492   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 493 AC_ARG_ENABLE([gcc_ultra_verbose],
 494   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 495 AC_ARG_ENABLE([backtrace],
 496   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 497 AC_ARG_ENABLE([time-check],
 498   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 499 AC_ARG_ENABLE([pcreposix],
 500   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 501 AC_ARG_ENABLE([fpm],
 502   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 503 AC_ARG_ENABLE([systemd],
 504   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 505 AC_ARG_ENABLE([werror],
 506   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 507 AC_ARG_ENABLE([cumulus],
 508   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 509 AC_ARG_ENABLE([datacenter],
 510   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 511 AC_ARG_ENABLE([fuzzing],
 512   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 513 AC_ARG_ENABLE([netlink_fuzzing],
 514   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 515 AC_ARG_ENABLE([rr-semantics],
 516   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 517 AC_ARG_ENABLE([protobuf],
 518   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 519 AC_ARG_ENABLE([oldvpn_commands],
 520   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 521 AC_ARG_ENABLE([rpki],
 522   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 523 AC_ARG_ENABLE([clippy-only],
 524   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 525 AC_ARG_ENABLE([numeric_version],
 526   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 527 AC_ARG_ENABLE([gcov],
 528   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 529 AC_ARG_ENABLE([bfdd],
 530   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 531 AC_ARG_ENABLE([address-sanitizer],
 532   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 533 AC_ARG_ENABLE([thread-sanitizer],
 534   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 535 AC_ARG_ENABLE([memory-sanitizer],
 536   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 537
 538 AS_IF([test "${enable_clippy_only}" != "yes"], [
 539 AC_CHECK_HEADERS([json-c/json.h])
 540 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 541 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 542   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 543   if test "$ac_cv_lib_json_json_object_get" = no; then
 544       AC_MSG_ERROR([libjson is needed to compile])
 545   fi
 546 fi
 547 ])
 548
 549 AC_ARG_ENABLE([dev_build],
 550     AS_HELP_STRING([--enable-dev-build], [build for development]))
 551
 552 AC_ARG_ENABLE([lua],
 553     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 554
 555 if test x"${enable_time_check}" != x"no" ; then
 556   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 557     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 558   else
 559     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 560   fi
 561 fi
 562
 563 case "${enable_systemd}" in
 564   "no") ;;
 565   "yes")
 566   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 567   if test $ac_cv_lib_systemd_sd_notify = no; then
 568     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 569   else
 570     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 571   fi
 572   ;;
 573   "*") ;;
 574 esac
 575
 576 if test "${enable_rr_semantics}" != "no" ; then
 577   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 578 fi
 579
 580 if test "${enable_datacenter}" = "yes" ; then
 581   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 582   DFLT_NAME="datacenter"
 583 else
 584   DFLT_NAME="traditional"
 585 fi
 586
 587 if test "${enable_fuzzing}" = "yes" ; then
 588   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 589 fi
 590
 591 if test "${enable_netlink_fuzzing}" = "yes" ; then
 592   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 593 fi
 594
 595 if test "${enable_cumulus}" = "yes" ; then
 596   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 597 fi
 598
 599 AC_SUBST([DFLT_NAME])
 600 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 601
 602 if test "${enable_shell_access}" = "yes"; then
 603    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 604 fi
 605
 606 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 607
 608 #
 609 # Python for clippy
 610 #
 611
 612 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 613   AC_MSG_CHECKING([whether we found a working Python version])
 614   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 615 #include <Python.h>
 616 #if PY_VERSION_HEX < 0x02070000
 617 #error python too old
 618 #endif
 619 int main(void);
 620 ],
 621 [
 622 {
 623   Py_Initialize();
 624   return 0;
 625 }
 626 ])], [
 627     # some python installs are missing the zlib dependency...
 628     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 629     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 630 #include <Python.h>
 631 #if PY_VERSION_HEX < 0x02070000
 632 #error python too old
 633 #endif
 634 int main(void);
 635 ],
 636 [
 637 {
 638   Py_Initialize();
 639   return 0;
 640 }
 641 ])], [
 642       m4_if([$1], [], [
 643         PYTHONCONFIG=""
 644         unset PYTHON_LIBS
 645         unset PYTHON_CFLAGS
 646       ], [$1])
 647     ])
 648   ])
 649 ])
 650
 651 AS_IF([test "$host" = "$build"], [
 652   PYTHONCONFIG=""
 653
 654   # ordering:
 655   # 1.  try python3, but respect the user's preference on which minor ver
 656   # 2.  try python, which might be py3 or py2 again on the user's preference
 657   # 3.  try python2 (can really only be 2.7 but eh)
 658   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 659   #
 660   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 661   # (AX_PYTHON does not do what we need)
 662
 663   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 664         python3-config \
 665         python-config \
 666         python2-config \
 667         python3.6-config \
 668         python3.5-config \
 669         python3.4-config \
 670         python3.3-config \
 671         python3.2-config \
 672         python2.7-config ])
 673   if test -n "$PYTHONCONFIG"; then
 674     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 675     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 676
 677     FRR_PYTHON_CHECK_WORKING([])
 678   fi
 679
 680   if test -z "$PYTHONCONFIG"; then
 681     PKG_CHECK_MODULES([PYTHON], [python-3.6], [], [
 682       PKG_CHECK_MODULES([PYTHON], [python-3.5], [], [
 683         PKG_CHECK_MODULES([PYTHON], [python-3.4], [], [
 684           PKG_CHECK_MODULES([PYTHON], [python-3.3], [], [
 685             PKG_CHECK_MODULES([PYTHON], [python-3.2], [], [
 686               PKG_CHECK_MODULES([PYTHON], [python-2.7], [], [
 687                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 688                 ])])])])])])
 689
 690
 691     FRR_PYTHON_CHECK_WORKING([
 692       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 693     ])
 694   fi
 695 ])
 696 AC_SUBST([PYTHON_CFLAGS])
 697 AC_SUBST([PYTHON_LIBS])
 698
 699 #
 700 # Logic for protobuf support.
 701 #
 702 if test "$enable_protobuf" = "yes"; then
 703   # Check for protoc & protoc-c
 704
 705   # protoc is not required, it's only for a "be nice" helper target
 706   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 707
 708   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 709   if test "$PROTOC_C" = "/bin/false"; then
 710     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 711   fi
 712
 713   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 714     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 715   ])
 716   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 717     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 718   ])
 719
 720   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
 721 fi
 722 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 723
 724 #
 725 # Logic for old vpn commands support.
 726 #
 727 if test "$enable_oldvpn_commands" = "yes"; then
 728    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 729 fi
 730
 731 #
 732 # End of logic for protobuf support.
 733 #
 734
 735 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 736 if test "${enable_rtadv}" != "no"; then
 737   AC_MSG_RESULT([yes])
 738   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 739 else
 740   AC_MSG_RESULT([no])
 741 fi
 742
 743 if test x"${enable_user}" = x"no"; then
 744   enable_user=""
 745 else
 746   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 747     enable_user="frr"
 748   fi
 749   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 750 fi
 751
 752 if test x"${enable_group}" = x"no"; then
 753   enable_group=""
 754 else
 755   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 756     enable_group="frr"
 757   fi
 758   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 759 fi
 760
 761 if test x"${enable_vty_group}" = x"yes" ; then
 762   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 763 elif test x"${enable_vty_group}" != x""; then
 764   if test x"${enable_vty_group}" != x"no"; then
 765     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 766   fi
 767 fi
 768 AC_SUBST([enable_user])
 769 AC_SUBST([enable_group])
 770 AC_SUBST([enable_vty_group])
 771
 772 enable_configfile_mask=${enable_configfile_mask:-0600}
 773 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 774
 775 enable_logfile_mask=${enable_logfile_mask:-0600}
 776 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 777
 778 MPATH_NUM=16
 779
 780 case "${enable_multipath}" in
 781   0)
 782     MPATH_NUM=64
 783     ;;
 784   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 785     MPATH_NUM="${enable_multipath}"
 786     ;;
 787   "")
 788     ;;
 789   *)
 790     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 791     ;;
 792 esac
 793
 794 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 795
 796 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 797
 798 dnl --------------------
 799 dnl Enable code coverage
 800 dnl --------------------
 801 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 802
 803 dnl ------------------------------------
 804 dnl Alpine only accepts numeric versions
 805 dnl ------------------------------------
 806 if test "x${enable_numeric_version}" != "x" ; then
 807   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 808   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 809 fi
 810
 811 dnl -----------------------------------
 812 dnl Add extra version string to package
 813 dnl name, string and version fields.
 814 dnl -----------------------------------
 815 if test "x${EXTRAVERSION}" != "x" ; then
 816   VERSION="${VERSION}${EXTRAVERSION}"
 817   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 818   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 819   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 820 fi
 821 AC_SUBST([EXTRAVERSION])
 822
 823 if test "x$with_pkg_git_version" = "xyes"; then
 824         if test -d "${srcdir}/.git"; then
 825                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 826         else    with_pkg_git_version="no"
 827                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 828         fi
 829 fi
 830 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 831
 832 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 833 if test "x${OBJCOPY}" != "x:"; then
 834   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 835     frr_cv_interp=""
 836     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 837       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 838         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 839       fi
 840       test -f conftest.interp && rm conftest.interp
 841     ])
 842   ])
 843 fi
 844 if test -n "$frr_cv_interp"; then
 845   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 846 fi
 847
 848 dnl ------------------------------------
 849 dnl Check C keywords and standard  types
 850 dnl ------------------------------------
 851 AC_C_CONST
 852 AC_C_INLINE
 853 AC_C_VOLATILE
 854 AC_HEADER_STDC
 855 dnl AC_TYPE_PID_T
 856 AC_TYPE_UID_T
 857 AC_TYPE_MODE_T
 858 AC_TYPE_SIZE_T
 859 AC_STRUCT_TM
 860
 861 dnl -------------------------
 862 dnl Check other header files.
 863 dnl -------------------------
 864 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 865         linux/version.h asm/types.h \
 866         sys/cdefs.h])
 867
 868 ac_stdatomic_ok=false
 869 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 870 AC_CHECK_HEADER([stdatomic.h],[
 871
 872   AC_MSG_CHECKING([whether _Atomic qualifier works])
 873   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 874 #include <stdatomic.h>
 875 int main(int argc, char **argv) {
 876   _Atomic int i = 0;
 877   return i;
 878 }
 879 ]])], [
 880     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 881     AC_MSG_RESULT([yes])
 882     ac_stdatomic_ok=true
 883   ], [
 884     AC_MSG_RESULT([no])
 885   ])
 886 ])
 887
 888 AS_IF([$ac_stdatomic_ok], [true], [
 889   AC_MSG_CHECKING([for __atomic_* builtins])
 890   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 891 int main(int argc, char **argv) {
 892   volatile int i = 1;
 893   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 894   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 895 }
 896 ]])], [
 897     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 898     AC_MSG_RESULT([yes])
 899   ], [
 900     AC_MSG_RESULT([no])
 901
 902     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 903     AC_MSG_CHECKING([for __sync_* builtins])
 904     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 905 int main(int argc, char **argv) {
 906   volatile int i = 1;
 907   __sync_fetch_and_sub (&i, 1);
 908   return __sync_val_compare_and_swap (&i, 0, 1);
 909 }
 910 ]])], [
 911       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 912       AC_MSG_RESULT([yes])
 913
 914       AC_MSG_CHECKING([for __sync_swap builtin])
 915       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 916 int main(int argc, char **argv) {
 917   volatile int i = 1;
 918   return __sync_swap (&i, 2);
 919 }
 920 ]])], [
 921         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 922         AC_MSG_RESULT([yes])
 923       ], [
 924         AC_MSG_RESULT([no])
 925       ])
 926
 927     ], [
 928       AC_MSG_RESULT([no])
 929       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 930     ])
 931   ])
 932 ])
 933
 934 AC_CHECK_HEADERS([pthread_np.h],,, [
 935 #include <pthread.h>
 936 ])
 937 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 938
 939 needsync=true
 940
 941 AS_IF([$needsync], [
 942   dnl Linux
 943   AC_MSG_CHECKING([for Linux futex() support])
 944   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 945 #ifndef _GNU_SOURCE
 946 #define _GNU_SOURCE
 947 #endif
 948 #include <unistd.h>
 949 #include <limits.h>
 950 #include <sys/time.h>
 951 #include <sys/syscall.h>
 952 #include <linux/futex.h>
 953
 954 int main(void);
 955 ],
 956 [
 957 {
 958   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 959 }
 960 ])], [
 961     AC_MSG_RESULT([yes])
 962     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 963     needsync=false
 964   ], [
 965     AC_MSG_RESULT([no])
 966   ])
 967 ])
 968
 969 AS_IF([$needsync], [
 970   dnl FreeBSD
 971   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 972   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 973 #include <errno.h>
 974 #include <stdlib.h>
 975 #include <sys/types.h>
 976 #include <sys/umtx.h>
 977 int main(void);
 978 ],
 979 [
 980 {
 981   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
 982 }
 983 ])], [
 984     AC_MSG_RESULT([yes])
 985     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
 986     needsync=false
 987   ], [
 988     AC_MSG_RESULT([no])
 989   ])
 990 ])
 991
 992 AS_IF([$needsync], [
 993   dnl OpenBSD patch (not upstream at the time of writing this)
 994   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
 995   AC_MSG_CHECKING([for OpenBSD futex() support])
 996   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 997 #include <sys/futex.h>
 998 int main(void);
 999 ],
1000 [
1001 {
1002   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1003 }
1004 ])], [
1005     AC_MSG_RESULT([yes])
1006     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1007     needsync=false
1008   ], [
1009     AC_MSG_RESULT([no])
1010   ])
1011 ])
1012
1013 dnl Utility macro to avoid retyping includes all the time
1014 m4_define([FRR_INCLUDES],
1015 [#ifdef SUNOS_5
1016 #define _POSIX_C_SOURCE 200809L
1017 #define __EXTENSIONS__
1018 #endif
1019 #include <stdio.h>
1020 #include <stdlib.h>
1021 #include <stddef.h>
1022 #include <sys/types.h>
1023 /* sys/conf.h depends on param.h on FBSD at least */
1024 #include <sys/param.h>
1025 /* Required for MAXSIG */
1026 #include <signal.h>
1027 #include <sys/socket.h>
1028 #ifdef __APPLE__
1029 # define __APPLE_USE_RFC_3542
1030 #endif
1031 #include <netinet/in.h>
1032 #include <sys/time.h>
1033 #include <time.h>
1034 #include <net/if.h>
1035 ])dnl
1036
1037 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1038 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1039 dnl an additional round for it.
1040
1041 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1042
1043 m4_define([FRR_INCLUDES],
1044 FRR_INCLUDES
1045 [#if HAVE_NET_IF_VAR_H
1046 # include <net/if_var.h>
1047 #endif
1048 ])dnl
1049
1050 AC_CHECK_HEADERS([netinet/in_var.h \
1051         net/if_dl.h net/netopt.h \
1052         inet/nd.h netinet/ip_icmp.h \
1053         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
1054         [], [], [FRR_INCLUDES])
1055
1056 AC_CHECK_HEADERS([ucontext.h], [], [],
1057 [#ifndef __USE_GNU
1058 #define __USE_GNU
1059 #endif /* __USE_GNU */
1060 FRR_INCLUDES
1061 ])
1062
1063 m4_define([UCONTEXT_INCLUDES],
1064 [#include <ucontext.h>])dnl
1065
1066 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1067   [], [], [UCONTEXT_INCLUDES])
1068 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1069   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1070    [], [], [UCONTEXT_INCLUDES])],
1071   [], [UCONTEXT_INCLUDES])
1072 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1073   [], [], [UCONTEXT_INCLUDES])
1074
1075 m4_define([FRR_INCLUDES],
1076 FRR_INCLUDES
1077 [
1078 #include <sys/un.h>
1079 #include <netinet/in_systm.h>
1080 #if HAVE_NETINET_IN_VAR_H
1081 # include <netinet/in_var.h>
1082 #endif
1083 #if HAVE_NET_IF_DL_H
1084 # include <net/if_dl.h>
1085 #endif
1086 #if HAVE_NET_NETOPT_H
1087 # include <net/netopt.h>
1088 #endif
1089 #include <net/route.h>
1090 #if HAVE_INET_ND_H
1091 # include <inet/nd.h>
1092 #endif
1093 #include <arpa/inet.h>
1094 /* Required for IDRP */
1095 #if HAVE_NETINET_IP_ICMP_H
1096 # include <netinet/ip_icmp.h>
1097 #endif
1098 ])dnl
1099
1100 dnl V6 headers are checked below, after we check for v6
1101
1102 AC_MSG_CHECKING([which operating system interface to use])
1103 case "$host_os" in
1104   sunos* | solaris2*)
1105     AC_MSG_RESULT([Solaris])
1106
1107     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1108     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1109     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1110
1111     AC_CHECK_LIB([socket], [main])
1112     AC_CHECK_LIB([nsl], [main])
1113     AC_CHECK_LIB([umem], [main])
1114     SOLARIS="solaris"
1115     ;;
1116   linux*)
1117     AC_MSG_RESULT([Linux])
1118
1119     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1120     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1121     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1122
1123     dnl Linux has a compilation problem with mixing
1124     dnl netinet/in.h and linux/in6.h they are not
1125     dnl compatible.  There has been discussion on
1126     dnl how to fix it but no real progress on implementation
1127     dnl when they fix it, remove this
1128     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1129     ;;
1130   openbsd*)
1131     AC_MSG_RESULT([OpenBSD])
1132
1133     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1134     AC_DEFINE([KAME], [1], [KAME IPv6])
1135     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1136
1137     if test "x${enable_pimd}" != "xno"; then
1138       case "$host_os" in
1139       openbsd6.0)
1140         ;;
1141       openbsd[6-9]*)
1142         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1143         ;;
1144       esac
1145     fi
1146     ;;
1147   *)
1148     AC_MSG_RESULT([BSD])
1149
1150     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1151     AC_DEFINE([KAME], [1], [KAME IPv6])
1152     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1153     ;;
1154 esac
1155 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1156
1157 AC_SYS_LARGEFILE
1158
1159 dnl ------------------------
1160 dnl Integrated REALMS option
1161 dnl ------------------------
1162 if test "${enable_realms}" = "yes"; then
1163     case "$host_os" in
1164       linux*)
1165        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1166        ;;
1167       *)
1168        echo "Sorry, only Linux has REALMS support"
1169        exit 1
1170        ;;
1171     esac
1172 fi
1173 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1174
1175 dnl ---------------------
1176 dnl Integrated VTY option
1177 dnl ---------------------
1178 case "${enable_vtysh}" in
1179 "no")
1180   VTYSH="";;
1181 *)
1182   VTYSH="vtysh";
1183   AC_DEFINE([VTYSH], [1], [VTY shell])
1184
1185   prev_libs="$LIBS"
1186   AC_CHECK_LIB([readline], [main], [
1187     LIBREADLINE="-lreadline"
1188   ], [
1189     dnl readline failed - it might be incorrectly linked and missing its
1190     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1191     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1192       LIBREADLINE="$ac_cv_search_tputs"
1193     ], [
1194       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1195     ])
1196
1197     dnl re-try with the lib we found above
1198     unset ac_cv_lib_readline_main
1199     AC_CHECK_LIB([readline], [main], [
1200       LIBREADLINE="-lreadline $LIBREADLINE"
1201     ], [
1202       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1203     ], [$LIBREADLINE])
1204   ], [])
1205   LIBS="$prev_libs"
1206
1207   AC_CHECK_HEADER([readline/history.h])
1208   if test $ac_cv_header_readline_history_h = no;then
1209     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1210   fi
1211   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1212   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1213     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1214   fi
1215   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1216   if test "$frr_cv_append_history" = yes; then
1217     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1218   fi
1219   ;;
1220 esac
1221 AC_SUBST([LIBREADLINE])
1222 AM_CONDITIONAL([VTYSH], test "x$VTYSH" = "xvtysh")
1223
1224 dnl ----------
1225 dnl PAM module
1226 dnl
1227 dnl FRR detects the PAM library it is built against by checking for a
1228 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1229 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1230 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1231 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1232 dnl of OpenPAM.
1233 dnl ----------
1234 if test "$with_libpam" = "yes"; then
1235   AC_CHECK_HEADER([security/pam_misc.h],
1236     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1237      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1238      pam_conv_func="misc_conv"
1239     ],
1240     [], FRR_INCLUDES)
1241   AC_CHECK_HEADER([security/openpam.h],
1242     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1243      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1244      pam_conv_func="openpam_ttyconv"
1245     ],
1246     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1247   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1248     AC_MSG_WARN([*** pam support will not be built ***])
1249     with_libpam="no"
1250   fi
1251 fi
1252
1253 if test "$with_libpam" = "yes"; then
1254 dnl took this test from proftpds configure.in and suited to our needs
1255 dnl -------------------------------------------------------------------------
1256 dnl
1257 dnl This next check looks funky due to a linker problem with some versions
1258 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1259 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1260 dnl with RedHat 6.2 and Debian 2.2 or better.
1261 AC_CHECK_LIB([pam], [pam_start],
1262   [AC_CHECK_LIB([pam], [$pam_conv_func],
1263     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1264      LIBPAM="-lpam"],
1265     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1266      LIBPAM="-lpam -lpam_misc"]
1267     )
1268   ],
1269
1270   [AC_CHECK_LIB([pam], [pam_end],
1271     [AC_CHECK_LIB([pam], [$pam_conv_func],
1272       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1273        LIBPAM="-lpam -ldl"],
1274       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1275        LIBPAM="-lpam -ldl -lpam_misc"]
1276      )
1277   ],AC_MSG_WARN([*** pam support will not be built ***]),
1278   [-ldl])
1279   ]
1280 )
1281 fi
1282 AC_SUBST([LIBPAM])
1283
1284 dnl -------------------------------
1285 dnl Endian-ness check
1286 dnl -------------------------------
1287 AC_WORDS_BIGENDIAN
1288
1289 dnl -------------------------------
1290 dnl check the size in byte of the C
1291 dnl -------------------------------
1292 dnl AC_CHECK_SIZEOF(char)
1293 dnl AC_CHECK_SIZEOF(int)
1294 dnl AC_CHECK_SIZEOF(short)
1295 dnl AC_CHECK_SIZEOF(long)
1296
1297 dnl ----------------------------
1298 dnl check existance of functions
1299 dnl ----------------------------
1300 AC_FUNC_FNMATCH
1301 AC_FUNC_FORK
1302 AC_FUNC_MKTIME
1303 AC_FUNC_STAT
1304
1305 dnl -------------------------------
1306 dnl bgpd needs pow() and hence libm
1307 dnl -------------------------------
1308 TMPLIBS="$LIBS"
1309 AC_CHECK_HEADER([math.h],
1310   [AC_CHECK_LIB([m], [pow],
1311     [LIBM="-lm"
1312      LIBS="$LIBS $LIBM"
1313      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1314     ])
1315 ])
1316 if test x"$LIBM" = x ; then
1317   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1318 fi
1319 LIBS="$TMPLIBS"
1320
1321 AC_SUBST([LIBM])
1322
1323 AC_CHECK_FUNCS([ppoll], [
1324   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1325 ])
1326 AC_CHECK_FUNCS([pollts], [
1327   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1328 ])
1329
1330 dnl ---------------
1331 dnl other functions
1332 dnl ---------------
1333 AC_CHECK_FUNCS([ \
1334         strlcat strlcpy \
1335         getgrouplist])
1336
1337 AC_CHECK_HEADER([asm-generic/unistd.h],
1338                 [AC_CHECK_DECL(__NR_setns,
1339                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1340                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1341                                ])
1342                  AC_CHECK_FUNCS([setns])]
1343                )
1344
1345 dnl --------------------------
1346 dnl Determine IS-IS I/O method
1347 dnl --------------------------
1348 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1349 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1350 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1351 AC_CHECK_HEADER([net/bpf.h])
1352 AC_CHECK_HEADER([sys/dlpi.h])
1353 AC_MSG_CHECKING([zebra IS-IS I/O method])
1354
1355 case "$host_os" in
1356   linux*)
1357     AC_MSG_RESULT([pfpacket])
1358     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1359     ;;
1360   solaris* | sunos*)
1361     AC_MSG_RESULT([DLPI])
1362     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1363     ;;
1364   *)
1365     if test $ac_cv_header_net_bpf_h = no; then
1366       if test $ac_cv_header_sys_dlpi_h = no; then
1367         AC_MSG_RESULT([none])
1368         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1369           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1370         fi
1371         AC_MSG_WARN([*** IS-IS support will not be built ***])
1372         enable_isisd="no"
1373         enable_fabricd="no"
1374       else
1375         AC_MSG_RESULT([DLPI])
1376       fi
1377       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1378     else
1379       AC_MSG_RESULT([BPF])
1380       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1381     fi
1382     ;;
1383 esac
1384 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1385
1386 dnl ---------------------------------------------------------------
1387 dnl figure out how to specify an interface in multicast sockets API
1388 dnl ---------------------------------------------------------------
1389 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1390
1391 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1392         #include <sys/socket.h>
1393         #include <netinet/in.h>
1394         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1395         #include <linux/types.h>
1396 ])
1397
1398 m4_define([FRR_INCLUDES],
1399 FRR_INCLUDES
1400 [#if HAVE_LINUX_MROUTE_H
1401 # include <linux/mroute.h>
1402 #endif
1403 ])dnl
1404
1405 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1406         #include <sys/socket.h>
1407         #include <sys/types.h>
1408         #include <netinet/in.h>
1409         #include <net/route.h>
1410 ])
1411
1412 m4_define([FRR_INCLUDES],
1413 FRR_INCLUDES
1414 [#if HAVE_NETINET_IP_MROUTE_H
1415 # include <netinet/ip_mroute.h>
1416 #endif
1417 ])dnl
1418
1419 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1420 AC_TRY_COMPILE([#include <sys/param.h>],
1421 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1422   return (0);
1423 #else
1424   #error No support for BSD struct ip_mreq hack detected
1425 #endif],[AC_MSG_RESULT([yes])
1426 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1427 AC_MSG_RESULT([no]))
1428
1429 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1430 AC_TRY_COMPILE([
1431 #include <sys/types.h>
1432 #include <netinet/in.h>
1433 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1434 ], [AC_MSG_RESULT([yes])
1435 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1436 AC_MSG_RESULT([no]))
1437
1438 dnl ---------------------------------------------------------------
1439 dnl figure out how to check link-state
1440 dnl ---------------------------------------------------------------
1441 AC_CHECK_HEADER([net/if_media.h],
1442   [m4_define([LINK_DETECT_INCLUDES],
1443     FRR_INCLUDES
1444     [#include <net/if_media.h>
1445   ])
1446   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1447     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1448     [], LINK_DETECT_INCLUDES)],
1449   [],
1450   FRR_INCLUDES)
1451
1452 dnl ---------------------------------------------------------------
1453 dnl Additional, newer way to check link-state using ifi_link_state.
1454 dnl Not available in all BSD's when ifmediareq available
1455 dnl ---------------------------------------------------------------
1456 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1457   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1458   [], FRR_INCLUDES)
1459
1460 dnl ------------------------
1461 dnl TCP_MD5SIG socket option
1462 dnl ------------------------
1463
1464 AC_CHECK_HEADER([netinet/tcp.h],
1465    [m4_define([MD5_INCLUDES],
1466       FRR_INCLUDES
1467       [#include <netinet/tcp.h>
1468     ])
1469     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1470    [],
1471    FRR_INCLUDES)
1472 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1473   AC_CHECK_HEADER([linux/tcp.h],
1474        [m4_define([MD5_INCLUDES],
1475           FRR_INCLUDES
1476           [#include <linux/tcp.h>
1477         ])
1478        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1479 fi
1480
1481 dnl ----------------------------------------------------------------------------
1482 dnl figure out if domainname is available in the utsname struct (GNU extension).
1483 dnl ----------------------------------------------------------------------------
1484 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1485
1486 dnl ------------------
1487 dnl IPv6 header checks
1488 dnl ------------------
1489 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1490         netinet6/in6_var.h netinet6/nd6.h], [], [],
1491         FRR_INCLUDES)
1492
1493 m4_define([FRR_INCLUDES],dnl
1494 FRR_INCLUDES
1495 [#if HAVE_NETINET6_IN6_H
1496 #include <netinet6/in6.h>
1497 #endif
1498 #if HAVE_NETINET_IN6_VAR_H
1499 #include <netinet/in6_var.h>
1500 #endif
1501 #include <netinet/icmp6.h>
1502 #if HAVE_NETINET6_IN6_VAR_H
1503 # include <netinet6/in6_var.h>
1504 #endif
1505 #if HAVE_NETINET6_ND6_H
1506 # include <netinet6/nd6.h>
1507 #endif
1508 ])dnl
1509
1510 dnl disable doc check
1511 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1512 if test "$SPHINXBUILD" = "/bin/false"; then
1513   if test "${enable_doc}" = "yes"; then
1514     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1515   fi
1516 fi
1517 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false"])
1518 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
1519
1520 dnl --------------------
1521 dnl Daemon disable check
1522 dnl --------------------
1523 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
1524
1525 if test "${enable_bgpd}" = "no";then
1526   BGPD=""
1527 else
1528   BGPD="bgpd"
1529 fi
1530 AM_CONDITIONAL([BGPD], [test "x$BGPD" = "xbgpd"])
1531
1532 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
1533 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
1534 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
1535
1536 AS_IF([test "${enable_ldpd}" != "no"], [
1537   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1538 ])
1539
1540 if test "$enable_bfdd" = "no"; then
1541   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1542   BFDD=""
1543 else
1544   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1545   BFDD="bfdd"
1546
1547   case $host_os in
1548     linux*)
1549       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1550       ;;
1551
1552     *)
1553       AC_DEFINE([BFD_BSD], [1], [bfdd])
1554       ;;
1555   esac
1556 fi
1557
1558 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
1559
1560 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1561   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1562 fi
1563
1564 NHRPD=""
1565 case "$host_os" in
1566   linux*)
1567     if test "${enable_nhrpd}" != "no"; then
1568       NHRPD="nhrpd"
1569     fi
1570     ;;
1571   *)
1572     if test "${enable_nhrpd}" = "yes"; then
1573       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1574     fi
1575     ;;
1576 esac
1577 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
1578
1579 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
1580
1581 if test "${enable_watchfrr}" = "no";then
1582   WATCHFRR=""
1583 else
1584   WATCHFRR="watchfrr"
1585 fi
1586 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
1587
1588 OSPFCLIENT=""
1589 if test "${enable_ospfapi}" != "no";then
1590     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1591
1592   if test "${enable_ospfclient}" != "no";then
1593       OSPFCLIENT="ospfclient"
1594   fi
1595 fi
1596
1597 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
1598 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
1599 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
1600 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
1601 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
1602 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
1603 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
1604 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
1605 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
1606 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
1607 AM_CONDITIONAL([VRRPD], [test "${enable_vrrpd}" != "no"])
1608
1609 if test "${enable_bgp_announce}" = "no";then
1610   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1611 else
1612   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1613 fi
1614
1615 if test "${enable_bgp_vnc}" != "no";then
1616   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1617 fi
1618 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1619
1620 AC_SUBST([SOLARIS])
1621 AC_CHECK_LIB([crypt], [crypt], [],
1622                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1623 AC_CHECK_LIB([resolv], [res_init])
1624
1625 dnl ---------------------------
1626 dnl check system has PCRE regexp
1627 dnl ---------------------------
1628 if test "x$enable_pcreposix" = "xyes"; then
1629   AC_CHECK_LIB([pcreposix], [regexec], [], [
1630     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1631   ])
1632 fi
1633 AC_SUBST([HAVE_LIBPCREPOSIX])
1634
1635 dnl ------------------
1636 dnl check C-Ares library
1637 dnl ------------------
1638 if test "${NHRPD}" != ""; then
1639   PKG_CHECK_MODULES([CARES], [libcares], ,[
1640     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1641   ])
1642 fi
1643
1644
1645 dnl ------------------
1646 dnl check Net-SNMP library
1647 dnl ------------------
1648 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1649    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1650    if test x"$NETSNMP_CONFIG" = x"no"; then
1651       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1652    fi
1653    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1654    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1655    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1656    # among other things we avoid a GPL vs. OpenSSL license conflict here
1657    for removelib in crypto ssl sensors pci wrap; do
1658      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1659    done
1660    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1661    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1662 int main(void);
1663 ],
1664 [
1665 {
1666   return 0;
1667 }
1668 ])], [
1669      AC_MSG_ERROR([--enable-snmp given but not usable])])
1670    case "${enable_snmp}" in
1671      yes)
1672       SNMP_METHOD=agentx
1673       ;;
1674      agentx)
1675       SNMP_METHOD="${enable_snmp}"
1676       ;;
1677      *)
1678       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1679       ;;
1680    esac
1681    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1682    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1683 fi
1684 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1685 AC_SUBST([SNMP_LIBS])
1686 AC_SUBST([SNMP_CFLAGS])
1687
1688 dnl ---------------
1689 dnl libyang
1690 dnl ---------------
1691 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.7], , [
1692   AC_MSG_ERROR([libyang (>= 0.16.7) was not found on your system.])
1693 ])
1694 ac_cflags_save="$CFLAGS"
1695 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1696 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1697   AC_MSG_ERROR([m4_normalize([
1698     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1699     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1700   ])
1701 ], [[#include <libyang/libyang.h>]])
1702 CFLAGS="$ac_cflags_save"
1703
1704 dnl ---------------
1705 dnl configuration rollbacks
1706 dnl ---------------
1707 SQLITE3=false
1708 if test "$enable_config_rollbacks" = "yes"; then
1709   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1710     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1711     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1712     SQLITE3=true
1713   ], [
1714     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1715   ])
1716 fi
1717 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
1718
1719 dnl ---------------
1720 dnl confd
1721 dnl ---------------
1722 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1723    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1724    if test "x$CONFD" = "x/bin/false"; then
1725       AC_MSG_ERROR([confd was not found on your system.])]
1726    fi
1727    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1728    AC_SUBST([CONFD_CFLAGS])
1729    CONFD_LIBS="-lconfd"
1730    AC_SUBST([CONFD_LIBS])
1731    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1732 fi
1733 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
1734
1735 dnl ---------------
1736 dnl sysrepo
1737 dnl ---------------
1738 if test "$enable_sysrepo" = "yes"; then
1739   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1740       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1741       SYSREPO=true],
1742       [SYSREPO=false
1743       AC_MSG_ERROR([sysrepo was not found on your system.])]
1744   )
1745 fi
1746 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
1747
1748 dnl ---------------
1749 dnl gRPC
1750 dnl ---------------
1751 if test "$enable_grpc" = "yes"; then
1752   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1753     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1754     if test "$PROTOC" = "/bin/false"; then
1755       AC_MSG_FAILURE([grpc requested but protoc not found.])
1756     fi
1757
1758     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1759     GRPC=true
1760   ], [
1761     GRPC=false
1762     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1763   ])
1764 fi
1765 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
1766
1767 dnl ---------------
1768 dnl math
1769 dnl ---------------
1770 AC_SEARCH_LIBS([sqrt], [m])
1771
1772 dnl ---------------
1773 dnl dlopen & dlinfo
1774 dnl ---------------
1775 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1776   AC_MSG_ERROR([unable to find the dlopen()])
1777 ])
1778
1779 AC_CHECK_HEADERS([link.h])
1780
1781 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1782   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1783 #include <stdlib.h>
1784 #ifdef HAVE_LINK_H
1785 #include <link.h>
1786 #endif
1787 #include <dlfcn.h>
1788 ]], [[
1789   char origin[1];
1790   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1791 ]])], [
1792     frr_cv_rtld_di_origin=yes
1793   ], [
1794     frr_cv_rtld_di_origin=no
1795   ])
1796 ])
1797 if test "$frr_cv_rtld_di_origin" = yes; then
1798   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1799 fi
1800
1801 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1802   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1803 #include <stdlib.h>
1804 #ifdef HAVE_LINK_H
1805 #include <link.h>
1806 #endif
1807 #include <dlfcn.h>
1808 ]], [[
1809   struct link_map *lm = NULL;
1810   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1811 ]])], [
1812     frr_cv_rtld_di_linkmap=yes
1813   ], [
1814     frr_cv_rtld_di_linkmap=no
1815   ])
1816 ])
1817 if test "$frr_cv_rtld_di_linkmap" = yes; then
1818   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1819 fi
1820
1821 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
1822
1823 dnl ---------------------------
1824 dnl sockaddr and netinet checks
1825 dnl ---------------------------
1826 AC_CHECK_TYPES([
1827         struct sockaddr_dl,
1828         struct vifctl, struct mfcctl, struct sioc_sg_req,
1829         vifi_t, struct sioc_vif_req, struct igmpmsg,
1830         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1831         struct nd_opt_adv_interval, struct rt_addrinfo,
1832         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1833         struct nd_opt_rdnss, struct nd_opt_dnssl],
1834         [], [], FRR_INCLUDES)
1835
1836 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1837         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1838         struct sockaddr_dl.sdl_len,
1839         struct if6_aliasreq.ifra_lifetime,
1840         struct nd_opt_adv_interval.nd_opt_ai_type],
1841         [], [], FRR_INCLUDES)
1842
1843 dnl ---------------------------
1844 dnl IRDP/pktinfo/icmphdr checks
1845 dnl ---------------------------
1846
1847 AC_CHECK_TYPES([struct in_pktinfo], [
1848   AC_CHECK_TYPES([struct icmphdr], [
1849     IRDP=true
1850   ], [
1851     IRDP=false
1852   ], [FRR_INCLUDES])
1853 ], [
1854   IRDP=false
1855 ], [FRR_INCLUDES])
1856
1857 case "${enable_irdp}" in
1858 yes)
1859   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1860   ;;
1861 no)
1862   IRDP=false
1863   ;;
1864 esac
1865
1866 AM_CONDITIONAL([IRDP], [$IRDP])
1867
1868 dnl -----------------------
1869 dnl checking for IP_PKTINFO
1870 dnl -----------------------
1871 AC_MSG_CHECKING([for IP_PKTINFO])
1872 AC_TRY_COMPILE([#include <netdb.h>], [
1873   int opt = IP_PKTINFO;
1874 ], [
1875   AC_MSG_RESULT([yes])
1876   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1877 ], [
1878   AC_MSG_RESULT([no])
1879 ])
1880
1881 dnl ---------------------------
1882 dnl checking for IP_RECVDSTADDR
1883 dnl ---------------------------
1884 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1885 AC_TRY_COMPILE([#include <netinet/in.h>], [
1886   int opt = IP_RECVDSTADDR;
1887 ], [
1888   AC_MSG_RESULT([yes])
1889   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1890 ], [
1891   AC_MSG_RESULT([no])
1892 ])
1893
1894 dnl ----------------------
1895 dnl checking for IP_RECVIF
1896 dnl ----------------------
1897 AC_MSG_CHECKING([for IP_RECVIF])
1898 AC_TRY_COMPILE([#include <netinet/in.h>], [
1899   int opt = IP_RECVIF;
1900 ], [
1901   AC_MSG_RESULT([yes])
1902   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1903 ], [
1904   AC_MSG_RESULT([no])
1905 ])
1906
1907 dnl ----------------------
1908 dnl checking for SO_BINDANY
1909 dnl ----------------------
1910 AC_MSG_CHECKING([for SO_BINDANY])
1911 AC_TRY_COMPILE([#include <sys/socket.h>], [
1912   int opt = SO_BINDANY;
1913 ], [
1914   AC_MSG_RESULT([yes])
1915   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1916 ], [
1917   AC_MSG_RESULT([no])
1918 ])
1919
1920 dnl ----------------------
1921 dnl checking for IP_FREEBIND
1922 dnl ----------------------
1923 AC_MSG_CHECKING([for IP_FREEBIND])
1924 AC_TRY_COMPILE([#include <netinet/in.h>], [
1925   int opt = IP_FREEBIND;
1926 ], [
1927   AC_MSG_RESULT([yes])
1928   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1929 ], [
1930   AC_MSG_RESULT([no])
1931 ])
1932
1933 dnl --------------------------------------
1934 dnl checking for be32dec existence or not
1935 dnl --------------------------------------
1936 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1937                [#include <sys/endian.h>])
1938
1939 dnl --------------------------------------
1940 dnl checking for clock_time monotonic struct and call
1941 dnl --------------------------------------
1942 AC_CHECK_DECL([CLOCK_MONOTONIC],
1943         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1944          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1945 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1946
1947 dnl --------------------------------------
1948 dnl checking for flex and bison
1949 dnl --------------------------------------
1950
1951 AM_PROG_LEX
1952 AC_MSG_CHECKING([version of flex])
1953 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1954 frr_ac_flex_version="${frr_ac_flex_version##* }"
1955 AC_MSG_RESULT([$frr_ac_flex_version])
1956 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1957   LEX="$SHELL $missing_dir/missing flex"
1958   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1959     AC_MSG_WARN([using pregenerated flex output files])
1960   else
1961     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1962   fi
1963   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1964   AC_SUBST([LEXLIB], [''])
1965 ])
1966
1967 AC_PROG_YACC
1968 dnl thanks GNU bison for this b*llshit...
1969 AC_MSG_CHECKING([version of bison])
1970 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1971 frr_ac_bison_version="${frr_ac_bison_version##* }"
1972 frr_ac_bison_missing="false"
1973 case "x${frr_ac_bison_version}" in
1974   x2.7*)
1975     BISON_OPENBRACE='"'
1976     BISON_CLOSEBRACE='"'
1977     BISON_VERBOSE=''
1978     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1979     ;;
1980   x2.*|x1.*)
1981     AC_MSG_RESULT([$frr_ac_bison_version])
1982     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1983     frr_ac_bison_missing="true"
1984     ;;
1985   x)
1986     AC_MSG_RESULT([none])
1987     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1988     frr_ac_bison_missing="true"
1989     ;;
1990   *)
1991     BISON_OPENBRACE='{'
1992     BISON_CLOSEBRACE='}'
1993     BISON_VERBOSE='-Dparse.error=verbose'
1994     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1995     ;;
1996 esac
1997 AC_SUBST([BISON_OPENBRACE])
1998 AC_SUBST([BISON_CLOSEBRACE])
1999 AC_SUBST([BISON_VERBOSE])
2000
2001 if $frr_ac_bison_missing; then
2002   YACC="$SHELL $missing_dir/missing bison -y"
2003   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2004     AC_MSG_WARN([using pregenerated bison output files])
2005   else
2006     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2007   fi
2008 fi
2009
2010 dnl -------------------
2011 dnl capabilities checks
2012 dnl -------------------
2013 if test "${enable_capabilities}" != "no"; then
2014   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2015   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2016     [AC_MSG_RESULT([yes])
2017      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2018      frr_ac_keepcaps="yes"],
2019      AC_MSG_RESULT([no])
2020   )
2021   if test x"${frr_ac_keepcaps}" = x"yes"; then
2022     AC_CHECK_HEADERS([sys/capability.h])
2023   fi
2024   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
2025     AC_CHECK_LIB([cap], [cap_init],
2026       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2027        LIBCAP="-lcap"
2028        frr_ac_lcaps="yes"]
2029     )
2030   else
2031     AC_CHECK_HEADERS([priv.h],
2032      [AC_MSG_CHECKING([Solaris style privileges are available])
2033       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
2034           [AC_MSG_RESULT([yes])
2035            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
2036            frr_ac_scaps="yes"],
2037            AC_MSG_RESULT(no)
2038       )
2039      ]
2040    )
2041   fi
2042   if test x"${frr_ac_scaps}" = x"yes" \
2043        -o x"${frr_ac_lcaps}" = x"yes"; then
2044     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2045   fi
2046 fi
2047 AC_SUBST([LIBCAP])
2048
2049 dnl ---------------------------
2050 dnl check for glibc 'backtrace'
2051 dnl ---------------------------
2052 if test x"${enable_backtrace}" != x"no" ; then
2053   backtrace_ok=no
2054   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2055     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2056     backtrace_ok=yes
2057   ], [
2058     case "$host_os" in
2059     sunos* | solaris2*)
2060       AC_CHECK_FUNCS([printstack], [
2061         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2062         backtrace_ok=yes
2063       ])
2064       ;;
2065     esac
2066     if test "$backtrace_ok" = no; then
2067       AC_CHECK_HEADER([execinfo.h], [
2068         AC_SEARCH_LIBS([backtrace], [execinfo], [
2069           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2070           backtrace_ok=yes
2071         ],, [-lm])
2072       ])
2073     fi
2074   ])
2075
2076   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2077     dnl user explicitly requested backtrace but we failed to find support
2078     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2079   fi
2080 fi
2081
2082 dnl -----------------------------------------
2083 dnl check for malloc mallinfo struct and call
2084 dnl this must try and link using LIBS, in
2085 dnl order to check no alternative allocator
2086 dnl has been specified, which might not provide
2087 dnl mallinfo, e.g. such as Umem on Solaris.
2088 dnl -----------------------------------------
2089 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2090
2091 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2092   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2093 #ifdef HAVE_MALLOC_H
2094 #include <malloc.h>
2095 #endif
2096 #ifdef HAVE_MALLOC_NP_H
2097 #include <malloc_np.h>
2098 #endif
2099 #ifdef HAVE_MALLOC_MALLOC_H
2100 #include <malloc/malloc.h>
2101 #endif
2102 ]], [[
2103 struct mallinfo ac_x; ac_x = mallinfo ();
2104 ]])], [
2105     frr_cv_mallinfo=yes
2106   ], [
2107     frr_cv_mallinfo=no
2108   ])
2109 ])
2110 if test "$frr_cv_mallinfo" = yes; then
2111   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2112 fi
2113
2114 AC_MSG_CHECKING([whether malloc_usable_size is available])
2115 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2116 #ifdef HAVE_MALLOC_H
2117 #include <malloc.h>
2118 #endif
2119 #ifdef HAVE_MALLOC_MALLOC_H
2120 #include <malloc/malloc.h>
2121 #endif
2122 ]], [[
2123 size_t ac_x; ac_x = malloc_usable_size(NULL);
2124 ]])], [
2125   AC_MSG_RESULT([yes])
2126   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2127 ], [
2128   AC_MSG_RESULT([no])
2129
2130   AC_MSG_CHECKING([whether malloc_size is available])
2131   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2132 #ifdef HAVE_MALLOC_H
2133 #include <malloc.h>
2134 #endif
2135 #ifdef HAVE_MALLOC_MALLOC_H
2136 #include <malloc/malloc.h>
2137 #endif
2138 ]], [[
2139 size_t ac_x; ac_x = malloc_size(NULL);
2140 ]])], [
2141     AC_MSG_RESULT([yes])
2142     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2143   ], [
2144     AC_MSG_RESULT([no])
2145   ])
2146 ])
2147
2148 dnl ------
2149 dnl ZeroMQ
2150 dnl ------
2151 if test "x$enable_zeromq" != "xno"; then
2152   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2153     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2154     ZEROMQ=true
2155   ], [
2156     if test "x$enable_zeromq" = "xyes"; then
2157       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2158     fi
2159   ])
2160 fi
2161 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2162
2163 dnl ----------
2164 dnl configure date
2165 dnl ----------
2166 dev_version=`echo $VERSION | grep dev`
2167 #don't expire deprecated code in non 'dev' branch
2168 if test "${dev_version}" = ""; then
2169    CONFDATE=0
2170 else
2171    CONFDATE=`date '+%Y%m%d'`
2172 fi
2173 AC_SUBST([CONFDATE])
2174
2175 dnl ------------------------------
2176 dnl set paths for state directory
2177 dnl ------------------------------
2178 AC_MSG_CHECKING([directory to use for state file])
2179 if test "${prefix}" = "NONE"; then
2180   frr_statedir_prefix="";
2181 else
2182   frr_statedir_prefix=${prefix}
2183 fi
2184 if test "${localstatedir}" = '${prefix}/var'; then
2185   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2186                         ${frr_statedir_prefix}/var/adm dnl
2187                         ${frr_statedir_prefix}/etc dnl
2188                         /var/run        dnl
2189                         /var/adm        dnl
2190                         /etc            dnl
2191                         /dev/null;
2192   do
2193     test -d $FRR_STATE_DIR && break
2194   done
2195   frr_statedir=$FRR_STATE_DIR
2196 else
2197   frr_statedir=${localstatedir}
2198 fi
2199 if test $frr_statedir = "/dev/null"; then
2200     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2201 fi
2202 AC_MSG_RESULT([${frr_statedir}])
2203 AC_SUBST([frr_statedir])
2204
2205 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir/ldpd.sock"], [ldpd control socket])
2206 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir/zserv.api"], [zebra api socket])
2207 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir/bfdd.sock"], [bfdd control socket])
2208 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir"], [daemon vty directory])
2209 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2210
2211 dnl autoconf does this, but it does it too late...
2212 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2213 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2214
2215 dnl get the full path, recursing through variables...
2216 vtysh_bin="$bindir/vtysh"
2217 for I in 1 2 3 4 5 6 7 8 9 10; do
2218         eval vtysh_bin="\"$vtysh_bin\""
2219 done
2220 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2221 AC_SUBST([vtysh_bin])
2222
2223 CFG_SYSCONF="$sysconfdir"
2224 CFG_SBIN="$sbindir"
2225 CFG_STATE="$frr_statedir"
2226 CFG_MODULE="$moduledir"
2227 CFG_YANGMODELS="$yangmodelsdir"
2228 CFG_LIBYANG_PLUGINS="$libyang_pluginsdir"
2229 for I in 1 2 3 4 5 6 7 8 9 10; do
2230         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2231         eval CFG_SBIN="\"$CFG_SBIN\""
2232         eval CFG_STATE="\"$CFG_STATE\""
2233         eval CFG_MODULE="\"$CFG_MODULE\""
2234         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2235         eval CFG_LIBYANG_PLUGINS="\"$CFG_LIBYANG_PLUGINS\""
2236 done
2237 AC_SUBST([CFG_SYSCONF])
2238 AC_SUBST([CFG_SBIN])
2239 AC_SUBST([CFG_STATE])
2240 AC_SUBST([CFG_MODULE])
2241 AC_SUBST([CFG_YANGMODELS])
2242 AC_SUBST([CFG_LIBYANG_PLUGINS])
2243 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2244 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2245 AC_DEFINE_UNQUOTED([LIBYANG_PLUGINS_PATH], ["$CFG_LIBYANG_PLUGINS"], [path to libyang plugins])
2246 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2247
2248 dnl ------------------------------------
2249 dnl Enable RPKI and add librtr to libs
2250 dnl ------------------------------------
2251 if test "${enable_rpki}" = "yes"; then
2252   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
2253       [RPKI=true],
2254       [RPKI=false
2255       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2256   )
2257 fi
2258 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2259
2260 dnl ------------------------------------------
2261 dnl Check whether rtrlib was build with ssh support
2262 dnl ------------------------------------------
2263 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2264 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2265                         [[struct tr_ssh_config config;]])],
2266         [AC_MSG_RESULT([yes])
2267         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2268         AC_MSG_RESULT([no])
2269 )
2270
2271 dnl ---------------------------
2272 dnl Check htonl works correctly
2273 dnl ---------------------------
2274 AC_MSG_CHECKING([for working htonl])
2275 AC_CACHE_VAL(ac_cv_htonl_works,
2276  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2277                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2278  ]
2279 )
2280 AC_MSG_RESULT([$ac_cv_htonl_works])
2281
2282 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2283
2284 AC_CONFIG_FILES([
2285           config.version
2286           changelog-auto
2287           redhat/frr.spec
2288           solaris/Makefile
2289           alpine/APKBUILD
2290           snapcraft/snapcraft.yaml
2291           lib/version.h
2292           tests/lib/cli/test_cli.refout
2293           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2294           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2295           pkgsrc/eigrpd.sh])
2296
2297 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2298 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2299 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2300 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2301 AC_CONFIG_FILES([tools/frrcommon.sh])
2302
2303 AC_CONFIG_COMMANDS([lib/route_types.h], [
2304         dst="${ac_abs_top_builddir}/lib/route_types.h"
2305         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2306                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2307                 > "${dst}.tmp"
2308         test -f "${dst}" \
2309                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2310                 && rm "${dst}.tmp" \
2311                 || mv "${dst}.tmp" "${dst}"
2312 ], [
2313         PERL="$PERL"
2314 ])
2315
2316 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2317     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2318         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2319         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2320                 "${ac_abs_top_srcdir}" \
2321                 > "${dst}.tmp"
2322         test -f "${dst}" \
2323                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2324                 && rm "${dst}.tmp" \
2325                 || mv "${dst}.tmp" "${dst}"
2326     ], [
2327         PERL="$PERL"
2328     ])
2329 ])
2330
2331 ## Hack, but working solution to avoid rebuilding of frr.info.
2332 ## It's already in CVS until texinfo 4.7 is more common.
2333 AC_OUTPUT
2334
2335 echo "
2336 FRRouting configuration
2337 ------------------------------
2338 FRR version             : ${PACKAGE_VERSION}
2339 host operating system   : ${host_os}
2340 source code location    : ${srcdir}
2341 compiler                : ${CC}
2342 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2343 make                    : ${MAKE-make}
2344 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2345 state file directory    : ${frr_statedir}
2346 config file directory   : `eval echo \`echo ${sysconfdir}\``
2347 example directory       : `eval echo \`echo ${exampledir}\``
2348 module directory        : ${CFG_MODULE}
2349 user to run as          : ${enable_user}
2350 group to run as         : ${enable_group}
2351 group for vty sockets   : ${enable_vty_group}
2352 config file mask        : ${enable_configfile_mask}
2353 log file mask           : ${enable_logfile_mask}
2354 zebra protobuf enabled  : ${enable_protobuf:-no}
2355
2356 The above user and group must have read/write access to the state file
2357 directory and to the config files in the config file directory."
2358
2359 if test "${enable_doc}" != "no";then
2360   AS_IF([test "$SPHINXBUILD" = /bin/false],
2361      AC_MSG_WARN([sphinx-build is missing but required to build documentation]))
2362 fi