configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_version_major], 2)
   5 m4_define([lxc_version_minor], 0)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], rc5)
   8 m4_define([lxc_version_abi], 1.2.0)
   9
  10 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  11 m4_define([lxc_version],
  12           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  13
  14 AC_INIT([lxc], [lxc_version])
  15
  16 # We need pkg-config
  17 PKG_PROG_PKG_CONFIG
  18
  19 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  20 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  21
  22 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  23 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  24 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  25 AC_SUBST([LXC_VERSION_ABI], [lxc_version_abi])
  26 AC_SUBST([LXC_VERSION], [lxc_version])
  27
  28 AC_CONFIG_SRCDIR([configure.ac])
  29 AC_CONFIG_AUX_DIR([config])
  30 AC_CONFIG_HEADERS([src/config.h])
  31 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  32 AC_CANONICAL_HOST
  33 AM_PROG_CC_C_O
  34 AC_GNU_SOURCE
  35
  36 # Detect the distribution. This is used for the default configuration and
  37 # for some distro-specific build options.
  38 AC_MSG_CHECKING([host distribution])
  39 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux.]))
  40 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  41         with_distro=`lsb_release -is`
  42 fi
  43 if test "z$with_distro" = "z"; then
  44         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  45         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  46         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  47         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  48         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  49         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  50         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  51         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  52         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  53         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  54         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  55         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  56         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  57         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  58         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  59 fi
  60 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  61
  62 if test "z$with_distro" = "zforsparc"; then
  63         with_distro="sparclinux"
  64 fi
  65
  66 if test "z$with_distro" = "z"; then
  67         with_distro="unknown"
  68 fi
  69 case $with_distro in
  70         ubuntu|raspbian)
  71                 distroconf=default.conf.lxcbr
  72                 distrosysconf="$sysconfdir/default"
  73                 ;;
  74         redhat|centos|fedora|oracle|oracleserver|sparclinux|suse|opensuse*|plamo)
  75                 distroconf=default.conf.lxcbr
  76                 distrosysconf="$sysconfdir/sysconfig"
  77                 ;;
  78         *)
  79                 distroconf=default.conf.unknown
  80                 distrosysconf="$sysconfdir/default"
  81                 ;;
  82 esac
  83 AC_MSG_RESULT([$with_distro])
  84 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
  85 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  86
  87 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
  88
  89 # Check for init system type
  90 AC_MSG_CHECKING([for init system type])
  91 AC_ARG_WITH([init-script],
  92             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  93                             [Type(s) of init script to install: sysvinit, systemd, upstart,
  94                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  95 case "$with_init_script" in
  96         distro)
  97                 case $with_distro in
  98                         fedora|opensuse*)
  99                                 init_script=systemd
 100                                 ;;
 101                         redhat|centos|oracle|oracleserver|sparclinux|plamo)
 102                                 init_script=sysvinit
 103                                 ;;
 104                         debian|raspbian)
 105                                 init_script=upstart,systemd
 106                                 ;;
 107                         ubuntu)
 108                                 init_script=upstart,systemd
 109                                 ;;
 110                         *)
 111                                 echo -n "Linux distribution init system unknown."
 112                                 init_script=
 113                                 ;;
 114                 esac
 115                 ;;
 116         *)
 117                 init_script=$with_init_script
 118                 ;;
 119 esac
 120
 121 # Check valid init systems were given, run in subshell so we don't mess up IFS
 122 (IFS="," ; for init_sys in $init_script;
 123 do
 124         case "$init_sys" in
 125                 none|sysvinit|systemd|upstart)
 126                         ;;
 127                 *)
 128                         exit 1
 129                         ;;
 130         esac
 131 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 132
 133 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 134 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 135 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 136 AC_MSG_RESULT($init_script)
 137
 138 # systemd unit dir
 139 AC_ARG_WITH([systemdsystemunitdir],
 140             AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 141             [],
 142             [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 143 if test -z "$with_systemdsystemunitdir"; then
 144   with_systemdsystemunitdir=/lib/systemd/system
 145 fi
 146 if test "x$with_systemdsystemunitdir" != "xno"; then
 147   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 148 fi
 149
 150 # Allow enabling deprecated executables
 151 AC_ARG_ENABLE([deprecated],
 152         [AC_HELP_STRING([--enable-deprecated],
 153         [enable deprecated executables [default=no]])],
 154         [], [enable_deprecated=false])
 155 AM_CONDITIONAL([ENABLE_DEPRECATED], [test "x$enable_deprecated" = "xyes"])
 156
 157 # Allow disabling rpath
 158 AC_ARG_ENABLE([rpath],
 159         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 160         [], [enable_rpath=no])
 161 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 162
 163 # Documentation (manpages)
 164 AC_ARG_ENABLE([doc],
 165         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 166         [], [enable_doc=auto])
 167
 168 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 169         db2xman=""
 170         dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 171
 172         AC_MSG_CHECKING(for docbook2x-man)
 173         for name in ${dbparsers}; do
 174                 if "$name" --help >/dev/null 2>&1; then
 175                         db2xman="$name"
 176                         break;
 177                 fi
 178         done
 179
 180         if test -n "${db2xman}"; then
 181                 AC_MSG_RESULT([${db2xman}])
 182                 enable_doc="yes"
 183         else
 184                 AC_MSG_RESULT([no])
 185                 if test "x$enable_doc" = "xyes"; then
 186                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 187                 fi
 188                 enable_doc="no"
 189         fi
 190
 191         AC_SUBST(db2xman)
 192 fi
 193 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 194 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 195
 196 if test "x$db2xman" = "xdocbook2man"; then
 197         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 198 else
 199         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 200 fi
 201 AC_SUBST(docdtd)
 202
 203 # Documentation (API)
 204 AC_ARG_ENABLE([api-docs],
 205         [AC_HELP_STRING([--enable-api-docs],
 206         [make API documentation [default=auto]])],
 207         [], [enable_api_docs=auto])
 208
 209 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 210         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 211         AC_SUBST([HAVE_DOXYGEN])
 212
 213         if test "x$HAVE_DOXYGEN" != "x"; then
 214                 enable_api_docs="yes"
 215         else
 216                 if test "x$enable_api_docs" = "xyes"; then
 217                         AC_MSG_ERROR([doxygen is required, but could not be found])
 218                 fi
 219                 enable_api_docs="no"
 220         fi
 221 fi
 222
 223 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 224
 225 # Apparmor
 226 AC_ARG_ENABLE([apparmor],
 227         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 228         [], [enable_apparmor=auto])
 229
 230 if test "$enable_apparmor" = "auto" ; then
 231         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 232 fi
 233 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 234
 235 AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 236
 237 AM_COND_IF([ENABLE_APPARMOR],
 238         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 239         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 240         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 241
 242 # SELinux
 243 AC_ARG_ENABLE([selinux],
 244         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 245         [], [enable_selinux=auto])
 246
 247 if test "x$enable_selinux" = xauto; then
 248         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 249 fi
 250 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 251 AM_COND_IF([ENABLE_SELINUX],
 252         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 253         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 254         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 255
 256 # Seccomp syscall filter
 257 AC_ARG_ENABLE([seccomp],
 258         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 259         [], [enable_seccomp=auto])
 260
 261 if test "x$enable_seccomp" = "xauto" ; then
 262         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 263 fi
 264 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 265
 266 AM_COND_IF([ENABLE_SECCOMP],
 267         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 268                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 269                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 270                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 271                 ])
 272         ])
 273
 274 # cgmanager
 275 AC_ARG_ENABLE([cgmanager],
 276         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 277         [], [enable_cgmanager=auto])
 278
 279 if test "x$enable_cgmanager" = "xauto" ; then
 280         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1])
 281 fi
 282 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 283
 284 AM_COND_IF([ENABLE_CGMANAGER],
 285         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 286         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 287         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 288         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 289         ])
 290
 291 AC_MSG_CHECKING(for get_pid_cgroup_abs_sync)
 292 save_LIBS=$LIBS
 293 AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1])
 294 LIBS=$save_LIBS
 295 if test "x$have_abs_cgroups" = "xyes"; then
 296         AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync])
 297         AC_MSG_RESULT([yes])
 298 else
 299         AC_MSG_RESULT([no])
 300 fi
 301
 302 AC_MSG_CHECKING(for cgmanager_list_controllers)
 303 save_LIBS=$LIBS
 304 AC_SEARCH_LIBS([cgmanager_list_controllers_sync], [cgmanager], [have_list_controllers=yes], [have_list_controllers=no], [-lnih -lnih-dbus -ldbus-1])
 305 LIBS=$save_LIBS
 306 if test "x$have_list_controllers" = "xyes"; then
 307         AC_DEFINE([HAVE_CGMANAGER_LIST_CONTROLLERS], 1, [Have cgmanager_list_controllers])
 308         AC_MSG_RESULT([yes])
 309 else
 310         AC_MSG_RESULT([no])
 311 fi
 312
 313 # Check for static libcap, make sure the function checked for differs from the
 314 # the one checked below so the cache doesn't give a wrong answer
 315 OLD_CFLAGS="$CFLAGS"
 316 CFLAGS="$CFLAGS -static"
 317 AC_CHECK_LIB([cap],[cap_init],[have_static_libcap=yes],[have_static_libcap=no])
 318 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 319 if test "x$have_static_libcap" = "xyes"; then
 320         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 321 fi
 322 CFLAGS="$OLD_CFLAGS"
 323
 324
 325 # Linux capabilities
 326 AC_ARG_ENABLE([capabilities],
 327         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 328         [], [enable_capabilities=auto])
 329
 330 if test "x$enable_capabilities" = "xauto"; then
 331         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 332 fi
 333 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 334
 335 AM_COND_IF([ENABLE_CAP],
 336         [AC_CHECK_LIB(cap,cap_set_proc,[true],[AC_MSG_ERROR([You are missing libcap support.])])
 337         AC_SUBST([CAP_LIBS], [-lcap])])
 338
 339 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 340 OLD_CFLAGS="$CFLAGS"
 341 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 342 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 343 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 344 CFLAGS="$OLD_CFLAGS"
 345
 346 # Configuration examples
 347 AC_ARG_ENABLE([examples],
 348         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 349         [], [enable_examples=yes])
 350 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 351
 352 # Python3 module and scripts
 353 AC_ARG_ENABLE([python],
 354         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 355         [], [enable_python=auto])
 356
 357 if test "x$enable_python" = "xauto"; then
 358         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 359         if test "$CC" = "clang"; then
 360                 enable_python=no
 361         fi
 362 fi
 363
 364 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 365         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 366 fi
 367
 368 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 369
 370 AM_COND_IF([ENABLE_PYTHON],
 371         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 372         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 373         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 374
 375 # Enable dumping stack traces
 376 AC_ARG_ENABLE([mutex-debugging],
 377         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 378         [], [enable_mutex_debugging=no])
 379 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 380
 381 AM_COND_IF([MUTEX_DEBUGGING],
 382         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 383
 384 # Not in older autoconf versions
 385 # AS_VAR_COPY(DEST, SOURCE)
 386 # -------------------------
 387 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 388 # shell variable SOURCE.
 389 m4_ifdef([AS_VAR_COPY], [],
 390 [AC_DEFUN([AS_VAR_COPY],
 391     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 392 ])
 393
 394 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 395 m4_ifdef([PKG_CHECK_VAR], [],
 396 [AC_DEFUN([PKG_CHECK_VAR],
 397     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 398      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 399      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 400      AS_VAR_COPY([$1], [pkg_cv_][$1])
 401      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 402     ])# PKG_CHECK_VAR
 403 ])
 404
 405 # Lua module and scripts
 406 AC_ARG_ENABLE([lua],
 407         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 408         [], [enable_lua=auto])
 409
 410 AC_ARG_WITH([lua-pc],
 411         [AS_HELP_STRING(
 412                 [--with-lua-pc=PKG],
 413                 [Specify pkg-config package name for lua]
 414         )], [], [with_lua_pc=no])
 415
 416 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 417         # exit with error if not found
 418         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 419 fi
 420
 421 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 422         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 423                 [LUAPKGCONFIG=$with_lua_pc
 424                 enable_lua=yes],
 425                 [enable_lua=no])
 426 fi
 427
 428 if test "x$enable_lua" != "xno"; then
 429         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 430                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 431                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 432                                 [AS_IF([test "x$enable_lua" = "xyes"],
 433                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 434                                         [enable_lua=no])]
 435                         )]
 436                 )])
 437         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 438 fi
 439
 440 AM_CONDITIONAL([ENABLE_LUA],
 441         [test "x$enable_lua" = "xyes"])
 442
 443 AM_COND_IF([ENABLE_LUA],
 444         [AC_MSG_CHECKING([Lua version])
 445         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 446                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 447         AC_MSG_RESULT([$LUA_VERSION])
 448         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 449         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 450         ])
 451
 452 # Optional bash integration
 453 AC_ARG_ENABLE([bash],
 454         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 455         [], [enable_bash=yes])
 456 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 457
 458 # Optional test binaries
 459 AC_ARG_ENABLE([tests],
 460         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 461         [], [enable_tests=no])
 462 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 463
 464 # Allow overriding the default runtime dir (/run)
 465 AC_ARG_WITH([runtime-path],
 466         [AC_HELP_STRING(
 467                 [--with-runtime-path=dir],
 468                 [runtime directory (default: /run)]
 469         )], [], [with_runtime_path=['/run']])
 470
 471 # LXC container path, where the containers are actually stored
 472 # This is overridden by an entry in the file called LXCCONF
 473 # (i.e. /etc/lxc/lxc.conf)
 474 AC_ARG_WITH([config-path],
 475         [AC_HELP_STRING(
 476                 [--with-config-path=dir],
 477                 [lxc configuration repository path]
 478         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 479
 480 # The path of the global lxc configuration file.
 481 AC_ARG_WITH([global-conf],
 482         [AC_HELP_STRING(
 483                 [--with-global-conf=dir],
 484                 [global lxc configuration file]
 485         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 486
 487 # The path of the userns network configuration file
 488 AC_ARG_WITH([usernic-conf],
 489         [AC_HELP_STRING(
 490                 [--with-usernic-conf],
 491                 [user network interface configuration file]
 492         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 493
 494 # The path of the runtime usernic database
 495 AC_ARG_WITH([usernic-db],
 496         [AC_HELP_STRING(
 497                 [--with-usernic-db],
 498                 [lxc user nic database]
 499         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 500
 501 # Rootfs path, where the container mount structure is assembled
 502 AC_ARG_WITH([rootfs-path],
 503         [AC_HELP_STRING(
 504                 [--with-rootfs-path=dir],
 505                 [lxc rootfs mount point]
 506         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 507
 508 # cgroup pattern specification
 509 AC_ARG_WITH([cgroup-pattern],
 510         [AC_HELP_STRING(
 511                 [--with-cgroup-pattern=pattern],
 512                 [pattern for container cgroups]
 513         )], [], [with_cgroup_pattern=['/lxc/%n']])
 514
 515 # Container log path.  By default, use $lxcpath.
 516 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 517 AC_ARG_ENABLE([configpath-log],
 518         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 519         [], [enable_configpath_log=no])
 520 AC_MSG_RESULT([$enable_configpath_log])
 521 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 522
 523 if test "$enable_configpath_log" = "yes"; then
 524         default_log_path="${with_config_path}"
 525 else
 526         default_log_path="${localstatedir}/log/lxc"
 527 fi
 528
 529 AC_ARG_WITH([log-path],
 530         [AC_HELP_STRING(
 531                 [--with-log-path=dir],
 532                 [per container log path]
 533         )], [], [with_log_path=['${default_log_path}']])
 534
 535 # Expand some useful variables
 536 AS_AC_EXPAND(PREFIX, "$prefix")
 537 AS_AC_EXPAND(LIBDIR, "$libdir")
 538 AS_AC_EXPAND(BINDIR, "$bindir")
 539 AS_AC_EXPAND(SBINDIR, "$sbindir")
 540 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 541 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 542 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 543 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 544 AS_AC_EXPAND(DATADIR, "$datadir")
 545 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 546 AS_AC_EXPAND(DOCDIR, "$docdir")
 547 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 548 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 549 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 550 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 551 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 552 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 553 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 554 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 555 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 556 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 557 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 558 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 559 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 560 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 561 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 562
 563 # We need the install path so criu knows where to reference the hook scripts.
 564 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 565
 566 # Check for some standard kernel headers
 567 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 568                                 [],
 569                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 570                                 [#include <sys/socket.h>])
 571
 572 # Check for alternate C libraries
 573 AC_MSG_CHECKING(for bionic libc)
 574 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 575         [[#ifndef __ANDROID__
 576 error: Not bionic!
 577 #endif]])],
 578         [is_bionic=yes],
 579         [is_bionic=no])
 580 if test "x$is_bionic" = "xyes"; then
 581         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 582         AC_MSG_RESULT([yes])
 583 else
 584         AC_MSG_RESULT([no])
 585 fi
 586 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 587
 588 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 589 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 590
 591 # Check for some headers
 592 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 593
 594 # Check for some syscalls functions
 595 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat])
 596
 597 # Check for some functions
 598 AC_CHECK_LIB(pthread, main)
 599 AC_CHECK_FUNCS(pthread_atfork)
 600 AC_CHECK_FUNCS(statvfs)
 601 AC_CHECK_LIB(util, openpty)
 602 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 603 AC_CHECK_FUNCS([getline],
 604         AM_CONDITIONAL(HAVE_GETLINE, true)
 605         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 606         AM_CONDITIONAL(HAVE_GETLINE, false))
 607 AC_CHECK_FUNCS([getsubopt],
 608         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 609         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 610         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 611 AC_CHECK_FUNCS([fgetln],
 612         AM_CONDITIONAL(HAVE_FGETLN, true)
 613         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 614         AM_CONDITIONAL(HAVE_FGETLN, false))
 615
 616 # Check for some libraries
 617 AC_SEARCH_LIBS(sem_open, [rt pthread])
 618 AC_SEARCH_LIBS(clock_gettime, [rt])
 619
 620 # Check for some standard binaries
 621 AC_PROG_GCC_TRADITIONAL
 622 AC_PROG_SED
 623
 624 # See if we support thread-local storage.
 625 LXC_CHECK_TLS
 626
 627 if test "x$GCC" = "xyes"; then
 628         CFLAGS="$CFLAGS -Wall -Werror"
 629 fi
 630
 631 # Files requiring some variable expansion
 632 AC_CONFIG_FILES([
 633         Makefile
 634         lxc.pc
 635         lxc.spec
 636
 637         config/Makefile
 638         config/apparmor/Makefile
 639         config/selinux/Makefile
 640         config/bash/Makefile
 641         config/bash/lxc
 642         config/init/Makefile
 643         config/init/common/Makefile
 644         config/init/common/lxc-containers
 645         config/init/common/lxc-net
 646         config/init/systemd/Makefile
 647         config/init/systemd/lxc.service
 648         config/init/systemd/lxc@.service
 649         config/init/systemd/lxc-net.service
 650         config/init/sysvinit/Makefile
 651         config/init/sysvinit/lxc-containers
 652         config/init/sysvinit/lxc-net
 653         config/init/upstart/lxc.conf
 654         config/init/upstart/lxc-net.conf
 655         config/init/upstart/Makefile
 656         config/etc/Makefile
 657         config/templates/Makefile
 658         config/templates/alpine.common.conf
 659         config/templates/alpine.userns.conf
 660         config/templates/archlinux.common.conf
 661         config/templates/archlinux.userns.conf
 662         config/templates/centos.common.conf
 663         config/templates/centos.userns.conf
 664         config/templates/common.conf
 665         config/templates/common.conf.d/Makefile
 666         config/templates/debian.common.conf
 667         config/templates/debian.userns.conf
 668         config/templates/fedora.common.conf
 669         config/templates/fedora.userns.conf
 670         config/templates/gentoo.common.conf
 671         config/templates/gentoo.moresecure.conf
 672         config/templates/gentoo.userns.conf
 673         config/templates/nesting.conf
 674         config/templates/opensuse.common.conf
 675         config/templates/opensuse.userns.conf
 676         config/templates/oracle.common.conf
 677         config/templates/oracle.userns.conf
 678         config/templates/plamo.common.conf
 679         config/templates/plamo.userns.conf
 680         config/templates/slackware.common.conf
 681         config/templates/slackware.userns.conf
 682         config/templates/ubuntu-cloud.common.conf
 683         config/templates/ubuntu-cloud.lucid.conf
 684         config/templates/ubuntu-cloud.userns.conf
 685         config/templates/ubuntu.common.conf
 686         config/templates/ubuntu.lucid.conf
 687         config/templates/ubuntu.userns.conf
 688         config/templates/openwrt.common.conf
 689         config/templates/sparclinux.common.conf
 690         config/templates/sparclinux.userns.conf
 691         config/templates/userns.conf
 692         config/yum/Makefile
 693         config/sysconfig/Makefile
 694         config/sysconfig/lxc
 695
 696         doc/Makefile
 697         doc/api/Makefile
 698         doc/lxc-attach.sgml
 699         doc/lxc-autostart.sgml
 700         doc/lxc-cgroup.sgml
 701         doc/lxc-checkconfig.sgml
 702         doc/lxc-checkpoint.sgml
 703         doc/lxc-clone.sgml
 704         doc/lxc-config.sgml
 705         doc/lxc-console.sgml
 706         doc/lxc-copy.sgml
 707         doc/lxc-create.sgml
 708         doc/lxc-destroy.sgml
 709         doc/lxc-device.sgml
 710         doc/lxc-execute.sgml
 711         doc/lxc-freeze.sgml
 712         doc/lxc-info.sgml
 713         doc/lxc-ls.sgml
 714         doc/lxc-monitor.sgml
 715         doc/lxc-snapshot.sgml
 716         doc/lxc-start-ephemeral.sgml
 717         doc/lxc-start.sgml
 718         doc/lxc-stop.sgml
 719         doc/lxc-top.sgml
 720         doc/lxc-unfreeze.sgml
 721         doc/lxc-unshare.sgml
 722         doc/lxc-user-nic.sgml
 723         doc/lxc-usernsexec.sgml
 724         doc/lxc-wait.sgml
 725
 726         doc/lxc.conf.sgml
 727         doc/lxc.container.conf.sgml
 728         doc/lxc.system.conf.sgml
 729         doc/lxc-usernet.sgml
 730         doc/lxc.sgml
 731         doc/common_options.sgml
 732         doc/see_also.sgml
 733
 734         doc/rootfs/Makefile
 735
 736         doc/examples/Makefile
 737         doc/examples/lxc-macvlan.conf
 738         doc/examples/lxc-vlan.conf
 739         doc/examples/lxc-no-netns.conf
 740         doc/examples/lxc-empty-netns.conf
 741         doc/examples/lxc-phys.conf
 742         doc/examples/lxc-veth.conf
 743         doc/examples/lxc-complex.conf
 744
 745         doc/ja/Makefile
 746         doc/ja/lxc-attach.sgml
 747         doc/ja/lxc-autostart.sgml
 748         doc/ja/lxc-cgroup.sgml
 749         doc/ja/lxc-checkconfig.sgml
 750         doc/ja/lxc-checkpoint.sgml
 751         doc/ja/lxc-clone.sgml
 752         doc/ja/lxc-config.sgml
 753         doc/ja/lxc-console.sgml
 754         doc/ja/lxc-copy.sgml
 755         doc/ja/lxc-create.sgml
 756         doc/ja/lxc-destroy.sgml
 757         doc/ja/lxc-device.sgml
 758         doc/ja/lxc-execute.sgml
 759         doc/ja/lxc-freeze.sgml
 760         doc/ja/lxc-info.sgml
 761         doc/ja/lxc-ls.sgml
 762         doc/ja/lxc-monitor.sgml
 763         doc/ja/lxc-snapshot.sgml
 764         doc/ja/lxc-start-ephemeral.sgml
 765         doc/ja/lxc-start.sgml
 766         doc/ja/lxc-stop.sgml
 767         doc/ja/lxc-top.sgml
 768         doc/ja/lxc-unfreeze.sgml
 769         doc/ja/lxc-unshare.sgml
 770         doc/ja/lxc-user-nic.sgml
 771         doc/ja/lxc-usernsexec.sgml
 772         doc/ja/lxc-wait.sgml
 773
 774         doc/ja/lxc.conf.sgml
 775         doc/ja/lxc.container.conf.sgml
 776         doc/ja/lxc.system.conf.sgml
 777         doc/ja/lxc-usernet.sgml
 778         doc/ja/lxc.sgml
 779         doc/ja/common_options.sgml
 780         doc/ja/see_also.sgml
 781
 782         doc/ko/Makefile
 783         doc/ko/lxc-attach.sgml
 784         doc/ko/lxc-autostart.sgml
 785         doc/ko/lxc-cgroup.sgml
 786         doc/ko/lxc-checkconfig.sgml
 787         doc/ko/lxc-checkpoint.sgml
 788         doc/ko/lxc-clone.sgml
 789         doc/ko/lxc-config.sgml
 790         doc/ko/lxc-console.sgml
 791         doc/ko/lxc-copy.sgml
 792         doc/ko/lxc-create.sgml
 793         doc/ko/lxc-destroy.sgml
 794         doc/ko/lxc-device.sgml
 795         doc/ko/lxc-execute.sgml
 796         doc/ko/lxc-freeze.sgml
 797         doc/ko/lxc-info.sgml
 798         doc/ko/lxc-ls.sgml
 799         doc/ko/lxc-monitor.sgml
 800         doc/ko/lxc-snapshot.sgml
 801         doc/ko/lxc-start-ephemeral.sgml
 802         doc/ko/lxc-start.sgml
 803         doc/ko/lxc-stop.sgml
 804         doc/ko/lxc-top.sgml
 805         doc/ko/lxc-unfreeze.sgml
 806         doc/ko/lxc-unshare.sgml
 807         doc/ko/lxc-user-nic.sgml
 808         doc/ko/lxc-usernsexec.sgml
 809         doc/ko/lxc-wait.sgml
 810
 811         doc/ko/lxc.conf.sgml
 812         doc/ko/lxc.container.conf.sgml
 813         doc/ko/lxc.system.conf.sgml
 814         doc/ko/lxc-usernet.sgml
 815         doc/ko/lxc.sgml
 816         doc/ko/common_options.sgml
 817         doc/ko/see_also.sgml
 818
 819         hooks/Makefile
 820
 821         templates/Makefile
 822         templates/lxc-alpine
 823         templates/lxc-altlinux
 824         templates/lxc-archlinux
 825         templates/lxc-busybox
 826         templates/lxc-centos
 827         templates/lxc-cirros
 828         templates/lxc-debian
 829         templates/lxc-download
 830         templates/lxc-fedora
 831         templates/lxc-gentoo
 832         templates/lxc-openmandriva
 833         templates/lxc-opensuse
 834         templates/lxc-oracle
 835         templates/lxc-plamo
 836         templates/lxc-slackware
 837         templates/lxc-sshd
 838         templates/lxc-ubuntu
 839         templates/lxc-ubuntu-cloud
 840         templates/lxc-sparclinux
 841
 842         src/Makefile
 843         src/lxc/Makefile
 844         src/lxc/lxc-checkconfig
 845         src/lxc/lxc-start-ephemeral
 846         src/lxc/lxc.functions
 847         src/lxc/version.h
 848         src/python-lxc/Makefile
 849         src/python-lxc/setup.py
 850
 851         src/lua-lxc/Makefile
 852
 853         src/tests/Makefile
 854         src/tests/lxc-test-usernic
 855 ])
 856 AC_CONFIG_COMMANDS([default],[[]],[[]])
 857 AC_OUTPUT
 858
 859 # Configuration overview
 860 cat << EOF
 861
 862 ----------------------------
 863 Environment:
 864  - compiler: $CC
 865  - distribution: $with_distro
 866  - init script type(s): $init_script
 867  - rpath: $enable_rpath
 868  - GnuTLS: $enable_gnutls
 869  - Bash integration: $enable_bash
 870
 871 Security features:
 872  - Apparmor: $enable_apparmor
 873  - Linux capabilities: $enable_capabilities
 874  - seccomp: $enable_seccomp
 875  - SELinux: $enable_selinux
 876  - cgmanager: $enable_cgmanager
 877
 878 Bindings:
 879  - lua: $enable_lua
 880  - python3: $enable_python
 881
 882 Documentation:
 883  - examples: $enable_examples
 884  - API documentation: $enable_api_docs
 885  - user documentation: $enable_doc
 886
 887 Debugging:
 888  - tests: $enable_tests
 889  - mutex debugging: $enable_mutex_debugging
 890
 891 Paths:
 892  - Logs in configpath: $enable_configpath_log
 893 EOF
 894
 895 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 896 cat << EOF
 897
 898 WARNING: Threading not supported on your platform
 899
 900         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 901         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 902 EOF
 903 fi