configure.ac

   1 ##
   2 ## Configure template file for Quagga.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.53)
   9
  10 AC_INIT(quagga, 0.96.4, [bug-zebra@gnu.org])
  11 AC_CONFIG_SRCDIR(lib/zebra.h)
  12 AM_INIT_AUTOMAKE()
  13 AM_CONFIG_HEADER(config.h)
  14
  15 dnl default is to match previous behavior
  16 exampledir=${sysconfdir}
  17 AC_ARG_ENABLE([exampledir],
  18           AC_HELP_STRING([--enable-exampledir],
  19                          [specify alternate directory for examples]),
  20                          exampledir="$enableval",)
  21 dnl XXX add --exampledir to autoconf standard directory list somehow
  22 AC_SUBST(exampledir)
  23
  24 dnl -----------------------------------
  25 dnl Get hostname and other information.
  26 dnl -----------------------------------
  27 AC_CANONICAL_HOST
  28
  29 dnl ------------
  30 dnl Check CFLAGS
  31 dnl ------------
  32 AC_ARG_WITH(cflags,
  33 [  --with-cflags           Set CFLAGS for use in compilation.])
  34 if test "x$with_cflags" != "x" ; then
  35   CFLAGS="$with_cflags" ; cflags_specified=yes ;
  36 elif test -n "$CFLAGS" ; then
  37   cflags_specified=yes ;
  38 fi
  39
  40 dnl --------
  41 dnl Check CC
  42 dnl --------
  43 AC_PROG_CC
  44
  45 dnl -----------------------------------------
  46 dnl If CLFAGS doesn\'t exist set default value
  47 dnl -----------------------------------------
  48 if test "x$cflags_specified" = "x" ; then
  49   CFLAGS="$CFLAGS -Wall"
  50 fi
  51
  52 dnl --------------
  53 dnl Check programs
  54 dnl --------------
  55 AC_PROG_CPP
  56 AC_PROG_INSTALL
  57 AC_PROG_MAKE_SET
  58 AC_CHECK_TOOL(AR, ar)
  59 AC_CHECK_TOOL(RANLIB, ranlib, :)
  60
  61 dnl ---------
  62 dnl AIX check
  63 dnl ---------
  64 AC_AIX
  65
  66 dnl ----------------------
  67 dnl Packages configuration
  68 dnl ----------------------
  69 AC_ARG_ENABLE(vtysh,
  70 [  --enable-vtysh,       Make integrated vty shell for Quagga])
  71 AC_ARG_ENABLE(ipv6,
  72 [  --disable-ipv6          turn off IPv6 related features and daemons])
  73 AC_ARG_ENABLE(zebra,
  74 [  --disable-zebra         do not build zebra daemon])
  75 AC_ARG_ENABLE(bgpd,
  76 [  --disable-bgpd          do not build bgpd])
  77 AC_ARG_ENABLE(ripd,
  78 [  --disable-ripd          do not build ripd])
  79 AC_ARG_ENABLE(ripngd,
  80 [  --disable-ripngd        do not build ripngd])
  81 AC_ARG_ENABLE(ospfd,
  82 [  --disable-ospfd         do not build ospfd])
  83 AC_ARG_ENABLE(ospf6d,
  84 [  --disable-ospf6d        do not build ospf6d])
  85 AC_ARG_ENABLE(bgp-announce,
  86 [  --disable-bgp-announce, turn off BGP route announcement])
  87 AC_ARG_ENABLE(netlink,
  88 [  --enable-netlink        force to use Linux netlink interface])
  89 AC_ARG_ENABLE(broken-aliases,
  90 [  --enable-broken-aliases enable aliases as distinct interfaces for Linux 2.2.X])
  91 AC_ARG_ENABLE(snmp,
  92 [  --enable-snmp           enable SNMP support])
  93 AC_ARG_WITH(libpam,
  94 [  --with-libpam           use libpam for PAM support in vtysh])
  95 AC_ARG_ENABLE(tcp-zebra,
  96 [  --enable-tcp-zebra      enable TCP/IP socket connection between zebra and protocol daemon])
  97 dnl Temporary option until OSPF NSSA implementation complete
  98 AC_ARG_ENABLE(nssa,
  99 [  --enable-nssa           enable OSPF NSSA option])
 100 AC_ARG_ENABLE(opaque-lsa,
 101 [  --enable-opaque-lsa     enable OSPF Opaque-LSA with OSPFAPI support (RFC2370)])
 102 AC_ARG_ENABLE(ospfapi,
 103 [  --disable-ospfapi       do not build OSPFAPI to access the OSPF LSA Database,
 104                           (this is the default if --enable-opaque-lsa is not set)])
 105 AC_ARG_ENABLE(ospfclient,
 106 [  --disable-ospfclient    do not build OSPFAPI client for OSPFAPI,
 107                           (this is the default if --disable-ospfapi is set)])
 108 AC_ARG_ENABLE(ospf-te,
 109 [  --enable-ospf-te        enable Traffic Engineering Extension to OSPF])
 110 AC_ARG_ENABLE(multipath,
 111 [  --enable-multipath=ARG  enable multipath function, ARG must be digit])
 112 AC_ARG_ENABLE(quagga_user,
 113 [  --enable-user=ARG       user to run Quagga suite as (default quagga)])
 114 AC_ARG_ENABLE(quagga_group,
 115 [  --enable-group=ARG      group to run Quagga suite as (default quagga)])
 116 AC_ARG_ENABLE(vty_group,
 117 [  --enable-vty-group=ARG      set vty sockets to have specified group as owner])
 118 AC_ARG_ENABLE(configfile_mask,
 119 [  --enable-configfile-mask=ARG  set mask for config files])
 120 AC_ARG_ENABLE(logfile_mask,
 121 [  --enable-logfile-mask=ARG     set mask for log files])
 122
 123 AC_ARG_ENABLE(rtadv,
 124 [  --disable-rtadv         disable IPV6 router advertisement feature])
 125
 126 if test "${enable_broken_aliases}" = "yes"; then
 127   if test "${enable_netlink}" = "yes"
 128   then
 129     echo "Sorry, you can't use netlink with broken aliases"
 130     exit 1
 131   fi
 132   AC_DEFINE(HAVE_BROKEN_ALIASES,,Broken Alias)
 133   enable_netlink=no
 134 fi
 135
 136 if test "${enable_tcp_zebra}" = "yes"; then
 137   AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
 138 fi
 139
 140 if test "${enable_nssa}" = "yes"; then
 141   AC_DEFINE(HAVE_NSSA,,OSPF NSSA)
 142 fi
 143
 144 if test "${enable_opaque_lsa}" = "yes"; then
 145   AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
 146 fi
 147
 148 if test "${enable_ospf_te}" = "yes"; then
 149   AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
 150   AC_DEFINE(HAVE_OSPF_TE,,OSPF TE)
 151 fi
 152
 153 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 154 if test "${enable_rtadv}" != "no"; then
 155   AC_MSG_RESULT(yes)
 156   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 157 else
 158   AC_MSG_RESULT(no)
 159 fi
 160
 161 if test "${enable_user}" = "yes" || test x"${enable_user}" = x""; then
 162   enable_user="quagga"
 163 elif test "${enable_user}" = "no"; then
 164   enable_user="root"
 165 fi
 166 AC_DEFINE_UNQUOTED(QUAGGA_USER, "${enable_user}", Quagga User)
 167
 168 if test "${enable_group}" = "yes" || test x"${enable_group}" = x""; then
 169   enable_group="quagga"
 170 elif test "${enable_group}" = "no"; then
 171   enable_group="root"
 172 fi
 173 AC_DEFINE_UNQUOTED(QUAGGA_GROUP, "${enable_group}", Quagga Group)
 174
 175 if test x"${enable_vty_group}" = x"yes" ; then
 176   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 177 elif test x"${enable_vty_group}" != x""; then
 178   if test x"${enable_vty_group}" != x"no"; then
 179     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 180   fi
 181 fi
 182
 183 enable_configfile_mask=${enable_configfile_mask:-0600}
 184 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 185
 186 enable_logfile_mask=${enable_logfile_mask:-0600}
 187 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 188
 189 changequote(, )dnl
 190
 191 MULTIPATH_NUM=1
 192
 193 case "${enable_multipath}" in
 194   [0-9]|[1-9][0-9])
 195     MULTIPATH_NUM="${enable_multipath}"
 196     ;;
 197   "")
 198     ;;
 199   *)
 200     echo "Please specify digit to --enable-multipath ARG."
 201     exit 1
 202     ;;
 203 esac
 204
 205 changequote([, ])dnl
 206
 207 AC_SUBST(MULTIPATH_NUM)
 208
 209 dnl -------------------
 210 dnl Check header files.
 211 dnl -------------------
 212 AC_HEADER_STDC
 213 AC_CHECK_HEADERS([string.h stropts.h sys/conf.h sys/ksym.h sys/time.h \
 214                  sys/times.h sys/select.h sys/sysctl.h sys/sockio.h \
 215                  sys/types.h linux/version.h kvm.h netdb.h asm/types.h \
 216                  libutil.h limits.h])
 217
 218 AC_CHECK_HEADERS([sys/socket.h netinet/in_systm.h netinet/in.h \
 219                  net/if_dl.h net/netopt.h inet/nd.h net/route.h \
 220                  net/if.h net/if_var.h netinet/in_var.h])
 221
 222 dnl V6 headers are checked below, after we check for v6
 223
 224 dnl check some types
 225 AC_C_CONST
 226 dnl AC_TYPE_PID_T
 227 AC_TYPE_SIGNAL
 228
 229 dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
 230 case "$host" in
 231   *-sunos5.6* | *-solaris2.6*)
 232       opsys=sol2-6
 233       AC_DEFINE(SUNOS_5,,SunOS 5)
 234       AC_CHECK_LIB(xnet, main)
 235       CURSES=-lcurses
 236   ;;
 237   *-sunos5* | *-solaris2*)
 238       AC_DEFINE(SUNOS_5,,SunOS 5)
 239       AC_CHECK_LIB(socket, main)
 240       AC_CHECK_LIB(nsl, main)
 241       CURSES=-lcurses
 242   ;;
 243   *-linux-*)
 244       opsys=gnu-linux
 245       AC_DEFINE(GNU_LINUX,,GNU Linux)
 246   ;;
 247   *-nec-sysv4*)
 248       AC_CHECK_LIB(nsl, gethostbyname)
 249       AC_CHECK_LIB(socket, socket)
 250   ;;
 251   *-freebsd3.2)
 252       AC_DEFINE(FREEBSD_32,,FreeBSD 3.2)
 253   ;;
 254   *-openbsd*)
 255       opsys=openbsd
 256       AC_DEFINE(OPEN_BSD,,OpenBSD)
 257   ;;
 258   *-bsdi*)
 259       opsys=bsdi
 260       OTHER_METHOD="mtu_kvm.o"
 261       AC_CHECK_LIB(kvm, main)
 262   ;;
 263   *-irix6.5)
 264       opsys=irix
 265       AC_DEFINE(IRIX_65,,IRIX 6.5)
 266   ;;
 267 esac
 268
 269 dnl ---------------------
 270 dnl Integrated VTY option
 271 dnl ---------------------
 272 case "${enable_vtysh}" in
 273   "yes") VTYSH="vtysh";
 274          AC_DEFINE(VTYSH,,VTY shell)
 275          AC_CHECK_LIB(tinfo, tputs, , AC_CHECK_LIB(ncurses, tputs))
 276          AC_CHECK_LIB(readline, main)
 277          if test $ac_cv_lib_readline_main = no; then
 278            AC_MSG_ERROR([vtysh needs libreadline but was not found on your system.])
 279          fi
 280          AC_CHECK_HEADER(readline/history.h)
 281          if test $ac_cv_header_readline_history_h = no;then
 282            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 283          fi
 284          AC_CHECK_LIB(readline, rl_completion_matches)
 285          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 286            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 287          fi
 288          ;;
 289   "no" ) VTYSH="";;
 290   *    ) ;;
 291 esac
 292
 293 dnl ----------
 294 dnl PAM module
 295 dnl ----------
 296 if test "$with_libpam" = "yes"; then
 297   AC_CHECK_HEADER(security/pam_misc.h)
 298   if test "$ac_cv_header_security_pam_misc_h" = yes; then
 299     AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 300     AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 301     pam_conv_func="misc_conv"
 302   fi
 303   AC_CHECK_HEADER(security/openpam.h)
 304   if test "$ac_cv_header_security_openpam_h" = yes; then
 305     AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 306     AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 307     pam_conv_func="openpam_ttyconv"
 308   fi
 309   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 310     AC_MSG_WARN([*** pam support will not be built ***])
 311     with_libpam="no"
 312   fi
 313 fi
 314
 315 if test "$with_libpam" = "yes"; then
 316 dnl took this test from proftpd's configure.in and suited to our needs
 317 dnl -------------------------------------------------------------------------
 318 dnl
 319 dnl This next check looks funky due to a linker problem with some versions
 320 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 321 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 322 dnl with RedHat 6.2 and Debian 2.2 or better.
 323 AC_CHECK_LIB(pam, pam_start,
 324   [AC_CHECK_LIB(pam, $pam_conv_func,
 325     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 326      LIBPAM="-lpam"],
 327     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 328      LIBPAM="-lpam -lpam_misc"]
 329     )
 330   ],
 331
 332   [AC_CHECK_LIB(pam, pam_end,
 333     [AC_CHECK_LIB(pam, $pam_conv_func,
 334       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 335        LIBPAM="-lpam -ldl"],
 336       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 337        LIBPAM="-lpam -ldl -lpam_misc"]
 338      )
 339   ],AC_MSG_WARN([*** pam support will not be built ***]),
 340   [-ldl])
 341   ]
 342 )
 343 fi
 344 AC_SUBST(LIBPAM)
 345
 346 dnl -------------------------------
 347 dnl Endian-ness check
 348 dnl -------------------------------
 349 AC_WORDS_BIGENDIAN
 350
 351 dnl -------------------------------
 352 dnl check the size in byte of the C
 353 dnl -------------------------------
 354 dnl AC_CHECK_SIZEOF(char)
 355 dnl AC_CHECK_SIZEOF(int)
 356 dnl AC_CHECK_SIZEOF(short)
 357 dnl AC_CHECK_SIZEOF(long)
 358
 359 dnl ----------------------------
 360 dnl check existance of functions
 361 dnl ----------------------------
 362 AC_CHECK_FUNCS(memset memcpy strerror inet_aton daemon snprintf vsnprintf \
 363                strlcat strlcpy if_nametoindex if_indextoname getifaddrs \
 364                fcntl)
 365 AC_CHECK_FUNCS(setproctitle, ,
 366   [AC_CHECK_LIB(util, setproctitle,
 367      [LIBS="$LIBS -lutil"
 368       AC_DEFINE(HAVE_SETPROCTITLE,, Have setproctitle)
 369      ]
 370    )
 371   ]
 372 )
 373
 374 dnl ------------------------------------
 375 dnl Determine routing get and set method
 376 dnl ------------------------------------
 377 AC_MSG_CHECKING(zebra between kernel interface method)
 378 if test x"$opsys" = x"gnu-linux"; then
 379   if test "${enable_netlink}" = "yes";then
 380     AC_MSG_RESULT(netlink)
 381     RT_METHOD=rt_netlink.o
 382     AC_DEFINE(HAVE_NETLINK,,netlink)
 383     netlink=yes
 384   elif test "${enable_netlink}" = "no"; then
 385     AC_MSG_RESULT(ioctl)
 386     RT_METHOD=rt_ioctl.o
 387     netlink=no
 388   else
 389     AC_MSG_RESULT(netlink)
 390     RT_METHOD=rt_netlink.o
 391     AC_DEFINE(HAVE_NETLINK,,netlink)
 392     netlink=yes
 393   fi
 394 else
 395   if test "$opsys" = "sol2-6";then
 396     AC_MSG_RESULT(solaris)
 397     KERNEL_METHOD="kernel_socket.o"
 398     RT_METHOD="rt_socket.o"
 399   elif test "$opsys" = "irix" ; then
 400     AC_MSG_RESULT(irix)
 401     KERNEL_METHOD="kernel_socket.o"
 402     RT_METHOD="rt_socket.o"
 403   else
 404     AC_TRY_RUN([#include <errno.h>
 405 #include <sys/types.h>
 406 #include <sys/socket.h>
 407
 408 main ()
 409 {
 410   int ac_sock;
 411
 412   ac_sock = socket (AF_ROUTE, SOCK_RAW, 0);
 413   if (ac_sock < 0 && errno == EINVAL)
 414     exit (1);
 415   exit (0);
 416 }],
 417   [KERNEL_METHOD=kernel_socket.o
 418    RT_METHOD=rt_socket.o
 419    AC_MSG_RESULT(socket)],
 420   [RT_METHOD=rt_ioctl.o
 421    AC_MSG_RESULT(ioctl)],
 422   [KERNEL_METHOD=kernel_socket.o
 423    RT_METHOD=rt_socket.o
 424    AC_MSG_RESULT(socket)])
 425   fi
 426 fi
 427 AC_SUBST(RT_METHOD)
 428 AC_SUBST(KERNEL_METHOD)
 429 AC_SUBST(OTHER_METHOD)
 430
 431 dnl ------------------------------
 432 dnl check kernel route read method
 433 dnl ------------------------------
 434 AC_CACHE_CHECK(route read method check, zebra_rtread,
 435 [if test "$netlink" = yes; then
 436   RTREAD_METHOD="rtread_netlink.o"
 437   zebra_rtread="netlink"
 438 else
 439 for zebra_rtread in /proc/net/route /dev/ip /dev/null;
 440 do
 441   test x`ls $zebra_rtread 2>/dev/null` = x"$zebra_rtread" && break
 442 done
 443 case $zebra_rtread in
 444   "/proc/net/route") RTREAD_METHOD="rtread_proc.o"
 445                      zebra_rtread="proc";;
 446   "/dev/ip")
 447                      case "$host" in
 448                        *-freebsd*)    RTREAD_METHOD=rtread_sysctl.o
 449                                       zebra_rtread="sysctl";;
 450                        *)             RTREAD_METHOD="rtread_getmsg.o"
 451                                       zebra_rtread="getmsg";;
 452                      esac;;
 453   *)                 RTREAD_METHOD="rtread_sysctl.o"
 454                      zebra_rtread="sysctl";;
 455 esac
 456 fi])
 457 AC_SUBST(RTREAD_METHOD)
 458
 459 dnl -----------------------------
 460 dnl check interface lookup method
 461 dnl -----------------------------
 462 AC_MSG_CHECKING(interface looking up method)
 463 if test "$netlink" = yes; then
 464   AC_MSG_RESULT(netlink)
 465   IF_METHOD=if_netlink.o
 466 else
 467   if test "$opsys" = "sol2-6";then
 468     AC_MSG_RESULT(solaris)
 469     IF_METHOD=if_ioctl.o
 470   elif test "$opsys" = "irix" ; then
 471     AC_MSG_RESULT(irix)
 472      IF_METHOD=if_ioctl.o
 473   elif test "$opsys" = "openbsd";then
 474     AC_MSG_RESULT(openbsd)
 475     IF_METHOD=if_ioctl.o
 476   elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
 477     AC_MSG_RESULT(sysctl)
 478     IF_METHOD=if_sysctl.o
 479     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 480   else
 481     AC_MSG_RESULT(ioctl)
 482     IF_METHOD=if_ioctl.o
 483   fi
 484 fi
 485 AC_SUBST(IF_METHOD)
 486
 487 dnl -----------------------
 488 dnl check proc file system.
 489 dnl -----------------------
 490 if test -r /proc/net/dev; then
 491   AC_DEFINE(HAVE_PROC_NET_DEV,,/proc/net/dev)
 492   IF_PROC=if_proc.o
 493 fi
 494
 495 if test -r /proc/net/if_inet6; then
 496   AC_DEFINE(HAVE_PROC_NET_IF_INET6,,/proc/net/if_inet6)
 497   IF_PROC=if_proc.o
 498 fi
 499 AC_SUBST(IF_PROC)
 500
 501 dnl -----------------------------
 502 dnl check ipforward detect method
 503 dnl -----------------------------
 504 AC_CACHE_CHECK(ipforward method check, zebra_ipforward_path,
 505 [for zebra_ipforward_path in /proc/net/snmp /dev/ip /dev/null;
 506 do
 507   test x`ls $zebra_ipforward_path 2>/dev/null` = x"$zebra_ipforward_path" && break
 508 done
 509 case $zebra_ipforward_path in
 510   "/proc/net/snmp")  IPFORWARD=ipforward_proc.o
 511                      zebra_ipforward_path="proc";;
 512   "/dev/ip")
 513                      case "$host" in
 514                        *-nec-sysv4*)  IPFORWARD=ipforward_ews.o
 515                                       zebra_ipforward_path="ews";;
 516                        *-freebsd*)    IPFORWARD=ipforward_sysctl.o
 517                                       zebra_ipforward_path="sysctl";;
 518                        *)             IPFORWARD=ipforward_solaris.o
 519                                       zebra_ipforward_path="solaris";;
 520                      esac;;
 521   *)                 IPFORWARD=ipforward_sysctl.o
 522                      zebra_ipforward_path="sysctl";;
 523 esac])
 524 AC_SUBST(IPFORWARD)
 525
 526 AC_CHECK_FUNCS(getaddrinfo, [have_getaddrinfo=yes], [have_getaddrinfo=no])
 527
 528 dnl ----------
 529 dnl IPv6 check
 530 dnl ----------
 531 AC_MSG_CHECKING(whether does this OS have IPv6 stack)
 532 if test "${enable_ipv6}" = "no"; then
 533   AC_MSG_RESULT(disabled)
 534 else
 535 dnl ----------
 536 dnl INRIA IPv6
 537 dnl ----------
 538   if grep IPV6_INRIA_VERSION /usr/include/netinet/in.h >/dev/null 2>&1; then
 539     zebra_cv_ipv6=yes
 540     AC_DEFINE(HAVE_IPV6,1,INRIA IPv6)
 541     AC_DEFINE(INRIA_IPV6,1,INRIA IPv6)
 542     RIPNGD="ripngd"
 543     OSPF6D="ospf6d"
 544     LIB_IPV6=""
 545     AC_MSG_RESULT(INRIA IPv6)
 546 dnl ---------
 547 dnl KAME IPv6
 548 dnl ---------
 549   elif grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
 550     zebra_cv_ipv6=yes
 551     AC_DEFINE(HAVE_IPV6,1,KAME IPv6)
 552     AC_DEFINE(KAME,1,KAME IPv6)
 553     RIPNGD="ripngd"
 554     OSPF6D="ospf6d"
 555     if test -d /usr/local/v6/lib -a -f /usr/local/v6/lib/libinet6.a; then
 556       LIB_IPV6="-L/usr/local/v6/lib -linet6"
 557     fi
 558     AC_MSG_RESULT(KAME)
 559 dnl -------------------------
 560 dnl MUSICA IPv6
 561 dnl  default host check
 562 dnl  It is not used by Kheops
 563 dnl -------------------------
 564   elif grep MUSICA /usr/include6/netinet6/in6.h >/dev/null 2>&1; then
 565     zebra_cv_ipv6=yes
 566     AC_DEFINE(HAVE_IPV6,1,Musicia IPv6)
 567     AC_DEFINE(MUSICA,1,Musica IPv6 stack)
 568     AC_DEFINE(KAME,1,KAME IPv6 stack)
 569     RIPNGD="ripngd"
 570     OSPF6D="ospf6d"
 571     if test -d /usr/local/v6/lib -a -f /usr/local/v6/lib/libinet6.a; then
 572       LIB_IPV6="-L/usr/local/v6/lib -linet6"
 573     fi
 574     AC_MSG_RESULT(MUSICA)
 575 dnl ---------
 576 dnl NRL check
 577 dnl ---------
 578   elif grep NRL /usr/include/netinet6/in6.h >/dev/null 2>&1; then
 579     zebra_cv_ipv6=yes
 580     AC_DEFINE(HAVE_IPV6,1,NRL IPv6)
 581     AC_DEFINE(NRL,1,NRL)
 582     RIPNGD="ripngd"
 583     OSPF6D="ospf6d"
 584     if test x"$opsys" = x"bsdi";then
 585       AC_DEFINE(BSDI_NRL,,BSDI)
 586       AC_MSG_RESULT(BSDI_NRL)
 587     else
 588       AC_MSG_RESULT(NRL)
 589     fi
 590 dnl ----------
 591 dnl Linux IPv6
 592 dnl ----------
 593   elif test "${enable_ipv6}" = "yes"; then
 594     AC_EGREP_CPP(yes, [
 595       #include <linux/version.h>
 596       /* 2.1.128 or later */
 597       #if LINUX_VERSION_CODE >= 0x020180
 598       yes
 599       #endif],
 600       [zebra_cv_ipv6=yes
 601        zebra_cv_linux_ipv6=yes
 602        AC_MSG_RESULT(Linux IPv6)])
 603   else
 604     if test x`ls /proc/net/ipv6_route 2>/dev/null` = x"/proc/net/ipv6_route"
 605      then
 606       zebra_cv_ipv6=yes
 607       zebra_cv_linux_ipv6=yes
 608       AC_MSG_RESULT(Linux IPv6)
 609     fi
 610   fi
 611
 612   if test "$zebra_cv_linux_ipv6" = "yes";then
 613     AC_MSG_CHECKING(for GNU libc >= 2.1)
 614     AC_DEFINE(HAVE_IPV6,1,Linux IPv6)
 615     AC_EGREP_CPP(yes, [
 616 #include <features.h>
 617 #if __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 618   yes
 619 #endif],
 620       [glibc=yes
 621        AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 622        AC_MSG_RESULT(yes)],
 623       AC_MSG_RESULT(no)
 624     )
 625     RIPNGD="ripngd"
 626     OSPF6D="ospf6d"
 627     if test "$glibc" != "yes"; then
 628       INCLUDES="-I/usr/inet6/include"
 629       if test x`ls /usr/inet6/lib/libinet6.a 2>/dev/null` != x;then
 630          LIB_IPV6="-L/usr/inet6/lib -linet6"
 631       fi
 632     fi
 633   fi
 634
 635 dnl -----------------------
 636 dnl Set IPv6 related values
 637 dnl -----------------------
 638   LIBS="$LIB_IPV6 $LIBS"
 639   AC_SUBST(LIB_IPV6)
 640
 641   if test x"$RIPNGD" = x""; then
 642     AC_MSG_RESULT(IPv4 only)
 643   fi
 644 fi
 645
 646 dnl ------------------
 647 dnl IPv6 header checks
 648 dnl ------------------
 649 if test "x${zebra_cv_ipv6}" = "xyes"; then
 650 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h netinet/icmp6.h \
 651                  netinet6/in6_var.h netinet6/nd6.h])
 652 fi
 653
 654 dnl --------------------
 655 dnl Daemon disable check
 656 dnl --------------------
 657 if test "${enable_zebra}" = "no";then
 658   ZEBRA=""
 659 else
 660   ZEBRA="zebra"
 661 fi
 662
 663 if test "${enable_bgpd}" = "no";then
 664   BGPD=""
 665 else
 666   BGPD="bgpd"
 667 fi
 668
 669 if test "${enable_ripd}" = "no";then
 670   RIPD=""
 671 else
 672   RIPD="ripd"
 673 fi
 674
 675 if test "${enable_ospfd}" = "no";then
 676   OSPFD=""
 677 else
 678   OSPFD="ospfd"
 679 fi
 680
 681 OSPFCLIENT=""
 682 if test "${enable_opaque_lsa}" = "yes"; then
 683   if test "${enable_ospfapi}" != "no";then
 684     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
 685
 686     if test "${enable_ospfclient}" != "no";then
 687       OSPFCLIENT="ospfclient"
 688     fi
 689   fi
 690
 691 fi
 692
 693 case "${enable_ripngd}" in
 694   "yes") RIPNGD="ripngd";;
 695   "no" ) RIPNGD="";;
 696   *    ) ;;
 697 esac
 698
 699 case "${enable_ospf6d}" in
 700   "yes") OSPF6D="ospf6d";;
 701   "no" ) OSPF6D="";;
 702   *    ) ;;
 703 esac
 704
 705 if test "${enable_bgp_announce}" = "no";then
 706   AC_DEFINE(DISABLE_BGP_ANNOUNCE,,Disable BGP installation to zebra)
 707 fi
 708
 709 AC_SUBST(ZEBRA)
 710 AC_SUBST(BGPD)
 711 AC_SUBST(RIPD)
 712 AC_SUBST(RIPNGD)
 713 AC_SUBST(OSPFD)
 714 AC_SUBST(OSPF6D)
 715 AC_SUBST(VTYSH)
 716 AC_SUBST(INCLUDES)
 717 AC_SUBST(CURSES)
 718 AC_SUBST(OSPFCLIENT)
 719 AC_SUBST(OSPFAPI)
 720 AC_CHECK_LIB(c, inet_ntop, [AC_DEFINE(HAVE_INET_NTOP,,inet_ntop)])
 721 AC_CHECK_LIB(c, inet_pton, [AC_DEFINE(HAVE_INET_PTON,,inet_pton)])
 722 AC_CHECK_LIB(crypt, crypt)
 723 AC_CHECK_LIB(resolv, res_init)
 724 AC_CHECK_LIB(m, main)
 725
 726 dnl ---------------------------------------------------
 727 dnl BSD/OS 4.1 define inet_XtoY function as __inet_XtoY
 728 dnl ---------------------------------------------------
 729 AC_CHECK_FUNC(__inet_ntop, AC_DEFINE(HAVE_INET_NTOP,,__inet_ntop))
 730 AC_CHECK_FUNC(__inet_pton, AC_DEFINE(HAVE_INET_PTON,,__inet_pton))
 731 AC_CHECK_FUNC(__inet_aton, AC_DEFINE(HAVE_INET_ATON,,__inet_aton))
 732
 733 dnl ---------------------------
 734 dnl check system has GNU regexp
 735 dnl ---------------------------
 736 dnl AC_MSG_CHECKING(whether system has GNU regex)
 737 AC_CHECK_LIB(c, regexec,
 738 [AC_DEFINE(HAVE_GNU_REGEX,,GNU regexp library)
 739  LIB_REGEX=""],
 740 [LIB_REGEX="regex.o"])
 741 AC_SUBST(LIB_REGEX)
 742
 743 dnl ------------------
 744 dnl check SNMP library
 745 dnl ------------------
 746 if test "${enable_snmp}" = "yes";then
 747 dnl  AC_CHECK_LIB(snmp, asn_parse_int, HAVE_SNMP=yes)
 748   if test "${HAVE_SNMP}" = ""; then
 749     old_libs="${LIBS}"
 750     LIBS="-L/usr/lib"
 751     unset ac_cv_lib_snmp_asn_parse_int
 752     AC_CHECK_LIB(crypto, main, NEED_CRYPTO=yes, )
 753     if test "${NEED_CRYPTO}" = ""; then
 754       AC_CHECK_LIB(netsnmp, asn_parse_int, [HAVE_NETSNMP=yes; HAVE_SNMP=yes ])
 755     else
 756       AC_CHECK_LIB(netsnmp, asn_parse_int, [HAVE_NETSNMP=yes; HAVE_SNMP=yes; NEED_CRYPTO=yes;LIBS="$LIBS -lcrypto" ],,"-lcrypto")
 757     fi
 758     LIBS="${old_libs}"
 759   fi
 760   if test "${HAVE_SNMP}" = ""; then
 761     old_libs="${LIBS}"
 762     LIBS="-L/usr/lib"
 763     unset ac_cv_lib_snmp_asn_parse_int
 764     AC_CHECK_LIB(snmp, asn_parse_int, HAVE_SNMP=yes, )
 765     if test "${HAVE_SNMP}" = ""; then
 766       unset ac_cv_lib_snmp_asn_parse_int
 767       AC_CHECK_LIB(crypto, main, NEED_CRYPTO=yes, )
 768       if test "${NEED_CRYPTO}" = "yes"; then
 769         AC_CHECK_LIB(snmp, asn_parse_int, [HAVE_SNMP=yes; NEED_CRYPTO=yes; LIBS="$LIBS -lcrypto" ],,"-lcrypto")
 770       fi
 771     fi
 772     LIBS="${old_libs}"
 773   fi
 774
 775   if test "${HAVE_SNMP}" = ""; then
 776     old_libs="${LIBS}"
 777     LIBS="-L/usr/local/lib"
 778     unset ac_cv_lib_snmp_asn_parse_int
 779     AC_CHECK_LIB(snmp, asn_parse_int, HAVE_SNMP=yes)
 780     if test "${HAVE_SNMP}" = ""; then
 781       unset ac_cv_lib_snmp_asn_parse_int
 782       AC_CHECK_LIB(crypto, main, NEED_CRYPTO=yes, )
 783       if test "${NEED_CRYPTO}" = "yes"; then
 784         AC_CHECK_LIB(snmp, asn_parse_int, [HAVE_SNMP=yes; NEED_CRYPTO=yes; LIBS="$LIBS -lcrypto" ],,"-lcrypto")
 785       fi
 786     fi
 787     LIBS="${old_libs}"
 788   fi
 789
 790   if test "${HAVE_SNMP}" = "yes"; then
 791     for ac_snmp in /usr/include/net-snmp/library/asn1.h /usr/include/ucd-snmp/asn1.h /usr/local/include/ucd-snmp/asn1.h /dev/null
 792     do
 793       test -f "${ac_snmp}" && break
 794     done
 795
 796     case ${ac_snmp} in
 797       /usr/include/net-snmp/*)
 798                   AC_DEFINE(HAVE_SNMP,,SNMP)
 799                   AC_DEFINE(HAVE_NETSNMP,,SNMP)
 800                   AC_DEFINE(UCD_COMPATIBLE,,SNMP)
 801                   CFLAGS="${CFLAGS} -I/usr/include/net-snmp -I/usr/include/net-snmp/library"
 802                   if test "${HAVE_NETSNMP}" = "yes"; then
 803                         LIBS="${LIBS} -lnetsnmp"
 804                   else
 805                         LIBS="${LIBS} -lsnmp"
 806                   fi
 807                   ;;
 808       /usr/include/ucd-snmp/*)
 809                   AC_DEFINE(HAVE_SNMP,,SNMP)
 810                   CFLAGS="${CFLAGS} -I/usr/include/ucd-snmp"
 811                   LIBS="${LIBS} -lsnmp"
 812                   ;;
 813       /usr/local/include/ucd-snmp/*)
 814                   AC_DEFINE(HAVE_SNMP,,SNMP)
 815                   CFLAGS="${CFLAGS} -I/usr/local/include/ucd-snmp"
 816                   LIBS="${LIBS} -L/usr/local/lib -lsnmp"
 817                   ;;
 818       /usr/local/include/net-snmp/*)
 819                 AC_DEFINE(HAVE_SNMP,,SNMP)
 820                 AC_DEFINE(HAVE_NET_SNMP,,SNMP)
 821                 AC_DEFINE(UCD_COMPATIBLE,,SNMP)
 822                 CFLAGS="${CFLAGS} -I/usr/local/include/net-snmp"
 823                 LIBS="${LIBS} -L/usr/local/lib -lnetsnmp"
 824                 ;;
 825     esac
 826     if test "${NEED_CRYPTO}" = "yes"; then
 827       LIBS="${LIBS} -lcrypto"
 828     fi
 829   fi
 830 fi
 831
 832 dnl ----------------------------
 833 dnl check sa_len of sockaddr
 834 dnl ----------------------------
 835 AC_MSG_CHECKING(whether struct sockaddr has a sa_len field)
 836 AC_TRY_COMPILE([#include <sys/types.h>
 837 #include <sys/socket.h>
 838 ],[static struct sockaddr ac_i;int ac_j = sizeof (ac_i.sa_len);],
 839 [AC_MSG_RESULT(yes)
 840  AC_DEFINE(HAVE_SA_LEN,,sa_len)],
 841  AC_MSG_RESULT(no))
 842
 843 dnl ----------------------------
 844 dnl check sin_len of sockaddr_in
 845 dnl ----------------------------
 846 AC_MSG_CHECKING(whether struct sockaddr_in has a sin_len field)
 847 AC_TRY_COMPILE([#include <sys/types.h>
 848 #include <netinet/in.h>
 849 ],[static struct sockaddr_in ac_i;int ac_j = sizeof (ac_i.sin_len);],
 850 [AC_MSG_RESULT(yes)
 851  AC_DEFINE(HAVE_SIN_LEN,,sin_len)],
 852  AC_MSG_RESULT(no))
 853
 854 dnl ----------------------------
 855 dnl check sun_len of sockaddr_un
 856 dnl ----------------------------
 857 AC_MSG_CHECKING(whether struct sockaddr_un has a sun_len field)
 858 AC_TRY_COMPILE([#include <sys/types.h>
 859 #include <sys/un.h>
 860 ],[static struct sockaddr_un ac_i;int ac_j = sizeof (ac_i.sun_len);],
 861 [AC_MSG_RESULT(yes)
 862  AC_DEFINE(HAVE_SUN_LEN,,sun_len)],
 863  AC_MSG_RESULT(no))
 864
 865 dnl -----------------------------------
 866 dnl check sin6_scope_id of sockaddr_in6
 867 dnl -----------------------------------
 868 if test "$zebra_cv_ipv6" = yes; then
 869   AC_MSG_CHECKING(whether struct sockaddr_in6 has a sin6_scope_id field)
 870   AC_TRY_COMPILE([#include <sys/types.h>
 871 #include <netinet/in.h>
 872 ],[static struct sockaddr_in6 ac_i;int ac_j = sizeof (ac_i.sin6_scope_id);],
 873 [AC_MSG_RESULT(yes)
 874  AC_DEFINE(HAVE_SIN6_SCOPE_ID,,scope id)],
 875  AC_MSG_RESULT(no))
 876 fi
 877
 878 dnl ----------------------------
 879 dnl check socklen_t exist or not
 880 dnl ----------------------------
 881 AC_MSG_CHECKING(whther socklen_t is defined)
 882 AC_TRY_COMPILE([#include <sys/types.h>
 883 #include <sys/socket.h>
 884 #include <netinet/in.h>
 885 ],[socklen_t ac_x;],
 886 [AC_MSG_RESULT(yes)
 887  AC_DEFINE(HAVE_SOCKLEN_T,,socklen_t)],
 888  AC_MSG_RESULT(no))
 889
 890 dnl ------------------------
 891 dnl check struct sockaddr_dl
 892 dnl ------------------------
 893 AC_MSG_CHECKING(whether struct sockaddr_dl exist)
 894 AC_EGREP_HEADER(sockaddr_dl,
 895 net/if_dl.h,
 896 [AC_MSG_RESULT(yes)
 897  AC_DEFINE(HAVE_SOCKADDR_DL,,sockaddr_dl)],
 898  AC_MSG_RESULT(no))
 899
 900 dnl --------------------------
 901 dnl check structure ifaliasreq
 902 dnl --------------------------
 903 AC_MSG_CHECKING(whether struct ifaliasreq exist)
 904 AC_EGREP_HEADER(ifaliasreq,
 905 net/if.h,
 906 [AC_MSG_RESULT(yes)
 907  AC_DEFINE(HAVE_IFALIASREQ,,ifaliasreq)],
 908  AC_MSG_RESULT(no))
 909
 910 dnl ----------------------------
 911 dnl check structure in6_aliasreq
 912 dnl ----------------------------
 913 AC_MSG_CHECKING(whether struct in6_aliasreq exist)
 914 AC_EGREP_HEADER(in6_aliasreq,
 915 netinet6/in6_var.h,
 916 [AC_MSG_RESULT(yes)
 917  AC_DEFINE(HAVE_IN6_ALIASREQ,,in6_aliasreq)],
 918  AC_MSG_RESULT(no))
 919
 920 dnl -----------------------------------
 921 dnl check ifra_lifetime of in6_aliasreq
 922 dnl -----------------------------------
 923 AC_MSG_CHECKING(whether in6_aliasreq.ifra_lifetime exist)
 924 AC_TRY_COMPILE([#include <sys/types.h>
 925 #include <netinet6/in6_var.h>
 926 ],[static struct if6_aliasreq ac_i;int ac_j = sizeof (ac_i.ifra_lifetime);],
 927 [AC_MSG_RESULT(yes)
 928  AC_DEFINE(HAVE_IFRA_LIFETIME,,Have in6_aliasreq.ifra_lifetime)],
 929  AC_MSG_RESULT(no))
 930
 931 dnl ---------------------------
 932 dnl check structure rt_addrinfo
 933 dnl ---------------------------
 934 AC_MSG_CHECKING(whether struct rt_addrinfo exist)
 935 AC_EGREP_HEADER(rt_addrinfo,
 936 net/route.h,
 937 [AC_MSG_RESULT(yes)
 938  AC_DEFINE(HAVE_RT_ADDRINFO,,rt_addrinfo)],
 939  AC_MSG_RESULT(no))
 940
 941 dnl --------------------------
 942 dnl check structure in_pktinfo
 943 dnl --------------------------
 944 AC_MSG_CHECKING(whether struct in_pktinfo exist)
 945 AC_TRY_COMPILE([#include <netinet/in.h>
 946 ],[struct in_pktinfo ac_x;],
 947 [AC_MSG_RESULT(yes)
 948  AC_DEFINE(HAVE_INPKTINFO,,in_pktinfo)],
 949  AC_MSG_RESULT(no))
 950
 951 dnl --------------------------------------
 952 dnl checking for getrusage struct and call
 953 dnl --------------------------------------
 954 AC_MSG_CHECKING(whether getrusage is available)
 955 AC_TRY_COMPILE([#include <sys/resource.h>
 956 ],[struct rusage ac_x; getrusage (RUSAGE_SELF, &ac_x);],
 957 [AC_MSG_RESULT(yes)
 958  AC_DEFINE(HAVE_RUSAGE,,rusage)],
 959  AC_MSG_RESULT(no))
 960
 961 dnl -------------------
 962 dnl capabilities checks
 963 dnl -------------------
 964 AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
 965 AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
 966   [AC_MSG_RESULT(yes)
 967    AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
 968    quagga_ac_keepcaps="yes"],
 969    AC_MSG_RESULT(no)
 970 )
 971 if test x"${quagga_ac_keepcaps}" = x"yes"; then
 972   AC_CHECK_HEADERS(sys/capability.h)
 973 fi
 974 if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
 975   AC_CHECK_LIB(cap, cap_init,
 976     [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
 977      LIBCAP="-lcap"
 978     ]
 979   )
 980 fi
 981 AC_SUBST(LIBCAP)
 982
 983 dnl ---------------------------
 984 dnl check for glibc 'backtrace'
 985 dnl ---------------------------
 986 if test "${glibc}" = "yes"; then
 987    AC_CHECK_HEADER(execinfo.h)
 988 fi
 989 if test x"${ac_cv_header_execinfo_h}" = x"yes"; then
 990   AC_CHECK_FUNC(backtrace,
 991     [AC_DEFINE(HAVE_GLIBC_BACKTRACE,,Glibc backtrace)]
 992   )
 993 fi
 994
 995 dnl ----------
 996 dnl configure date
 997 dnl ----------
 998 CONFDATE=`date '+%Y%m%d'`
 999 AC_SUBST(CONFDATE)
1000
1001 dnl ------------------------------
1002 dnl set paths for state directory
1003 dnl ------------------------------
1004 if test "${prefix}" = "NONE"; then
1005   quagga_statedir_prefix="";
1006 else
1007   quagga_statedir_prefix=${prefix}
1008 fi
1009 if test "${localstatedir}" = '${prefix}/var'; then
1010   AC_CACHE_CHECK(state directory,ac_statedir,
1011   [for QUAGGA_STATE_DIR in ${quagga_statedir_prefix}/var/run dnl
1012                         ${quagga_statedir_prefix}/var/adm dnl
1013                         ${quagga_statedir_prefix}/etc dnl
1014                         /var/run        dnl
1015                         /var/adm        dnl
1016                         /etc            dnl
1017                         /dev/null;
1018   do
1019     test -d $QUAGGA_STATE_DIR && break
1020   done
1021   quagga_statedir=$QUAGGA_STATE_DIR])
1022 else
1023   quagga_statedir=${localstatedir}
1024   AC_MSG_CHECKING(directory to use for state file)
1025   AC_MSG_RESULT(${quagga_statedir})
1026 fi
1027 if test $quagga_statedir = "/dev/null"; then
1028     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1029 fi
1030
1031 AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$quagga_statedir/zebra.pid",zebra PID)
1032 AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$quagga_statedir/ripd.pid",ripd PID)
1033 AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$quagga_statedir/ripngd.pid",ripngd PID)
1034 AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$quagga_statedir/bgpd.pid",bgpd PID)
1035 AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$quagga_statedir/ospfd.pid",ospfd PID)
1036 AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$quagga_statedir/ospf6d.pid",ospf6d PID)
1037 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$quagga_statedir/zserv.api",zebra api socket)
1038 AC_DEFINE_UNQUOTED(ZEBRA_VTYSH_PATH, "$quagga_statedir/zebra.vty",zebra vty socket)
1039 AC_DEFINE_UNQUOTED(RIP_VTYSH_PATH, "$quagga_statedir/ripd.vty",rip vty socket)
1040 AC_DEFINE_UNQUOTED(RIPNG_VTYSH_PATH, "$quagga_statedir/ripngd.vty",ripng vty socket)
1041 AC_DEFINE_UNQUOTED(BGP_VTYSH_PATH, "$quagga_statedir/bgpd.vty",bgpd vty socket)
1042 AC_DEFINE_UNQUOTED(OSPF_VTYSH_PATH, "$quagga_statedir/ospfd.vty",ospfd vty socket)
1043 AC_DEFINE_UNQUOTED(OSPF6_VTYSH_PATH, "$quagga_statedir/ospf6d.vty",ospf6d vty socket)
1044
1045 dnl ---------------------------
1046 dnl Check htonl works correctly
1047 dnl ---------------------------
1048 AC_MSG_CHECKING(for working htonl)
1049 AC_CACHE_VAL(ac_cv_htonl_works, [
1050 AC_TRY_LINK([#ifdef HAVE_SYS_TYPES_H
1051 #include <sys/types.h>
1052 #endif
1053 #ifdef HAVE_NETDB_H
1054 #include <netdb.h>
1055 #endif
1056 #ifdef HAVE_NETINET_IN_H
1057 #include <netinet/in.h>
1058 #endif],
1059 [htonl (0);],
1060 ac_cv_htonl_works=yes,
1061 ac_cv_htonl_works=no)])
1062 AC_MSG_RESULT($ac_cv_htonl_works)
1063
1064 AC_OUTPUT(Makefile lib/Makefile zebra/Makefile ripd/Makefile
1065           ripngd/Makefile bgpd/Makefile ospfd/Makefile
1066           ospf6d/Makefile vtysh/Makefile doc/Makefile
1067           ospfclient/Makefile
1068           redhat/quagga.spec
1069           lib/version.h)
1070
1071 echo "
1072 zebra configuration
1073 -------------------
1074 quagga version           : ${PACKAGE_VERSION}
1075 host operationg system  : ${host_os}
1076 source code location    : ${srcdir}
1077 compiler                : ${CC}
1078 compiler flags          : ${CFLAGS}
1079 linker flags            : ${LDFLAGS} ${LIBS}
1080 state file directory    : ${quagga_statedir}
1081 config file directory   : `eval echo \`echo ${sysconfdir}\``
1082 example directory       : `eval echo \`echo ${exampledir}\``
1083 user to run as          : ${enable_user}
1084 group to run as         : ${enable_group}
1085 group for vty sockets   : ${enable_vty_group}
1086 config file mask        : ${enable_configfile_mask}
1087 log file mask           : ${enable_logfile_mask}
1088
1089 The above user and group must have read/write access to the state file
1090 directory and to the config files in the config file directory.
1091 "