configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.1-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183 AC_PROG_CC_C99
 184 dnl NB: see C11 below
 185
 186 dnl Some special handling for ICC later on
 187 if test "$CC" = "icc"; then
 188     cc_is_icc="yes"
 189 fi
 190
 191 PKG_PROG_PKG_CONFIG
 192
 193 dnl it's 2019, sed is sed.
 194 SED=sed
 195 AC_SUBST([SED])
 196
 197 dnl try and enable CFLAGS that are useful for FRR
 198 dnl - specifically, options to control warnings
 199
 200 AC_SUBST([AC_CFLAGS])
 201 AC_USE_SYSTEM_EXTENSIONS
 202 AC_DEFUN([AC_C_FLAG], [{
 203     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 204     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 205         AC_LANG_PUSH([C])
 206         ac_c_flag_save="$CFLAGS"
 207         CFLAGS="$CFLAGS $1"
 208         AC_COMPILE_IFELSE(
 209                 [AC_LANG_PROGRAM([[$4]])],
 210                 [
 211                         cachename=yes
 212                 ], [
 213                         cachename=no
 214                 ])
 215         CFLAGS="$ac_c_flag_save"
 216         AC_LANG_POP([C])
 217     ])
 218     if test "$cachename" = "yes"; then
 219         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 220     else
 221         :
 222         $2
 223     fi
 224     m4_popdef([cachename])
 225 }])
 226
 227 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 228         AC_LANG_PUSH([C])
 229         ac_cflags_save="$CFLAGS"
 230         ac_libs_save="$LIBS"
 231         CFLAGS="$CFLAGS $1"
 232         LIBS="$LIBS $2"
 233         AC_LINK_IFELSE(
 234                 [$3],
 235                 [
 236                         CFLAGS="$ac_cflags_save"
 237                         LIBS="$ac_libs_save"
 238                         m4_default([$5], [
 239                                 AC_MSG_RESULT([yes])
 240                         ])
 241                 ], [
 242                         CFLAGS="$ac_cflags_save"
 243                         LIBS="$ac_libs_save"
 244                         m4_default([$4], [
 245                                 AC_MSG_RESULT([no])
 246                         ])
 247                 ])
 248         AC_LANG_POP([C])
 249         }])
 250
 251 dnl ICC won't bail on unknown options without -diag-error 10006
 252 dnl need to do this first so we get useful results for the other options
 253 if test "$cc_is_icc" = "yes"; then
 254     AC_C_FLAG([-diag-error 10006])
 255 fi
 256
 257 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 258 ac_cc="$CC"
 259 CC="${CC% -std=gnu99}"
 260 CC="${CC% -std=c99}"
 261
 262 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 263
 264 dnl if the user has specified any CFLAGS, override our settings
 265 if test "$enable_gcov" = "yes"; then
 266    if test "$orig_cflags" = ""; then
 267       AC_C_FLAG([-coverage])
 268       AC_C_FLAG([-O0])
 269    fi
 270
 271    AC_LDFLAGS="${AC_LDFLAGS} -lgcov"
 272 fi
 273
 274 if test "$enable_clang_coverage" = "yes"; then
 275    AC_C_FLAG([-fprofile-instr-generate], [
 276      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 277    ])
 278    AC_C_FLAG([-fcoverage-mapping], [
 279      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 280    ])
 281 fi
 282
 283 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 284
 285 if test "$enable_scripting" = "yes"; then
 286    AX_PROG_LUA([5.3], [5.4], [], [
 287      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 288    ])
 289    AX_LUA_HEADERS([], [
 290      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 291    ])
 292    AX_LUA_LIBS([
 293      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 294      LIBS="$LIBS $LUA_LIB"
 295      SCRIPTING=true
 296    ], [
 297      SCRIPTING=false
 298      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 299    ])
 300 fi
 301
 302 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 303 dnl sense to be overridden by the user
 304 if test "$enable_dev_build" = "yes"; then
 305    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 306    if test "$orig_cflags" = ""; then
 307       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 308       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 309       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 310    fi
 311 else
 312    if test "$orig_cflags" = ""; then
 313       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 314       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 315    fi
 316 fi
 317
 318 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 319
 320 dnl always want these CFLAGS
 321 AC_C_FLAG([-fno-omit-frame-pointer])
 322 AC_C_FLAG([-funwind-tables])
 323 AC_C_FLAG([-Wall])
 324 AC_C_FLAG([-Wextra])
 325 AC_C_FLAG([-Wmissing-prototypes])
 326 AC_C_FLAG([-Wmissing-declarations])
 327 AC_C_FLAG([-Wpointer-arith])
 328 AC_C_FLAG([-Wbad-function-cast])
 329 AC_C_FLAG([-Wwrite-strings])
 330 AC_C_FLAG([-Wundef])
 331 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 332   AC_C_FLAG([-Wcast-qual])
 333   AC_C_FLAG([-Wstrict-prototypes])
 334   AC_C_FLAG([-Wmissing-noreturn])
 335   AC_C_FLAG([-Wmissing-format-attribute])
 336   AC_C_FLAG([-Wunreachable-code])
 337   AC_C_FLAG([-Wpacked])
 338   AC_C_FLAG([-Wpadded])
 339   AC_C_FLAG([-Wshadow])
 340 else
 341   AC_C_FLAG([-Wno-unused-result])
 342 fi
 343 AC_C_FLAG([-Wno-unused-parameter])
 344 AC_C_FLAG([-Wno-missing-field-initializers])
 345
 346 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 347 AC_SUBST([CXX_COMPAT_CFLAGS])
 348
 349 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 350 dnl for some reason the string consts get 'promoted' to char *,
 351 dnl triggering a const to non-const conversion warning.
 352 if test "$cc_is_icc" = "yes"; then
 353     AC_C_FLAG([-diag-disable 3179])
 354 fi
 355
 356 if test "$enable_werror" = "yes" ; then
 357   WERROR="-Werror"
 358 fi
 359 AC_SUBST([WERROR])
 360
 361 SAN_FLAGS=""
 362 if test "$enable_address_sanitizer" = "yes"; then
 363   AC_C_FLAG([-fsanitize=address], [
 364     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 365   ], [
 366     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 367   ])
 368 fi
 369 if test "$enable_thread_sanitizer" = "yes"; then
 370   AC_C_FLAG([-fsanitize=thread], [
 371     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 372   ], [
 373     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 374   ])
 375 fi
 376 if test "$enable_memory_sanitizer" = "yes"; then
 377   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 378     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 379   ], [
 380     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 381   ])
 382 fi
 383 if test "$enable_undefined_sanitizer" = "yes"; then
 384   AC_C_FLAG([-fsanitize=undefined], [
 385     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 386   ], [
 387     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 388   ])
 389 fi
 390 AC_SUBST([SAN_FLAGS])
 391
 392 dnl frr-format.so
 393 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 394   AC_C_FLAG([-fplugin=${with_frr_format}], [
 395     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 396   ],,[
 397 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 398 #error plugin not loaded
 399 #endif
 400 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 401 #error plugin too old
 402 #endif
 403   ])
 404 elif test "$with_frr_format" = "no"; then
 405   : #nothing
 406 else
 407   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 408     AC_C_FLAG([-fplugin=frr-format],[
 409       if test "$with_frr_format" = "yes"; then
 410         AC_MSG_ERROR([frr-format plugin requested but not found])
 411       fi
 412     ],,[
 413 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 414 #error plugin not loaded
 415 #endif
 416 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 417 #error plugin too old
 418 #endif
 419     ])
 420   ],,[
 421 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 422 #error plugin not loaded
 423 #endif
 424 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 425 #error plugin too old
 426 #endif
 427   ])
 428 fi
 429
 430 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 431 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 432 #include <stdio.h>
 433 int __attribute__((section("secttest"))) var = 1;
 434 extern int __start_secttest, __stop_secttest;
 435 ]], [[
 436   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 437   printf("%p %p %p\n", a, b, c);
 438 ]])], [
 439   AC_MSG_RESULT(yes)
 440   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 441 ], [
 442   AC_MSG_RESULT(no)
 443 ])
 444
 445 dnl ----------
 446 dnl Essentials
 447 dnl ----------
 448
 449 AX_PTHREAD([
 450   CC="$PTHREAD_CC"
 451   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 452   LIBS="$PTHREAD_LIBS $LIBS"
 453 ], [
 454   AC_MSG_FAILURE([This FRR version needs pthreads])
 455 ])
 456
 457 orig_cflags="$CFLAGS"
 458 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 459
 460 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 461                 [frr_cv_pthread_condattr_setclock=yes],
 462                 [frr_cv_pthread_condattr_setclock=no])
 463 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 464   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 465 fi
 466
 467 AC_CHECK_HEADERS([pthread_np.h],,, [
 468 #include <pthread.h>
 469 ])
 470 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 471
 472 CFLAGS="$orig_cflags"
 473
 474 dnl --------------
 475 dnl Check programs
 476 dnl --------------
 477 AC_PROG_INSTALL
 478 AC_PROG_LN_S
 479 AC_CHECK_TOOL([AR], [ar])
 480
 481 dnl -------
 482 dnl libtool
 483 dnl -------
 484 AC_ARG_ENABLE([static-bin],
 485   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 486 LT_INIT
 487 _LT_CONFIG_LIBTOOL([
 488   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 489     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 490   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 491   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 492   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 493 ])
 494 if test "$enable_static_bin" = "yes"; then
 495   AC_LDFLAGS="-static"
 496   if test "$enable_static" != "yes"; then
 497     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 498   fi
 499 fi
 500 if test "$enable_shared" != "yes"; then
 501   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 502 fi
 503 AC_SUBST([AC_LDFLAGS])
 504 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 505
 506 AC_ARG_ENABLE([rpath],
 507   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 508   [],
 509   [enable_rpath=yes])
 510
 511 dnl $AR and $RANLIB are set by LT_INIT above
 512 AC_MSG_CHECKING([whether $AR supports D option])
 513 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 514   AC_MSG_RESULT([yes])
 515   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 516   ARFLAGS="crD"
 517   AR_FLAGS="crD"
 518 else
 519   AC_MSG_RESULT([no])
 520   ARFLAGS="cru"
 521   AR_FLAGS="cru"
 522 fi
 523 AC_SUBST([ARFLAGS])
 524 AC_SUBST([AR_FLAGS])
 525
 526 AC_MSG_CHECKING([whether $RANLIB supports D option])
 527 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 528   if grep -q -- '-D' conftest.err; then
 529     AC_MSG_RESULT([no])
 530   else
 531     AC_MSG_RESULT([yes])
 532     RANLIB="$RANLIB -D"
 533   fi
 534 else
 535   AC_MSG_RESULT([no])
 536 fi
 537 AC_SUBST([RANLIB])
 538
 539 test -f conftest.err && rm conftest.err
 540 test -f conftest.a && rm conftest.a
 541
 542 dnl ----------------------
 543 dnl Packages configuration
 544 dnl ----------------------
 545 if test -f config.version; then
 546   . ./config.version
 547 elif test -f "${srcdir}/config.version"; then
 548   . "${srcdir}/config.version"
 549 fi
 550 AC_ARG_WITH([pkg-extra-version],
 551   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 552   if test "$withval" = "no"; then
 553     EXTRAVERSION=
 554   else
 555     EXTRAVERSION=$withval
 556   fi
 557 ], [])
 558 AC_ARG_WITH([pkg-git-version],
 559         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 560         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 561 AC_ARG_WITH([clippy],
 562   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 563 AC_ARG_WITH([vtysh_pager],
 564         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 565         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 566 AC_ARG_ENABLE([vtysh],
 567   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 568 AC_ARG_ENABLE([doc],
 569   AS_HELP_STRING([--disable-doc], [do not build docs]))
 570 AC_ARG_ENABLE([doc-html],
 571   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 572 AC_ARG_ENABLE([zebra],
 573   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 574 AC_ARG_ENABLE([bgpd],
 575   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 576 AC_ARG_ENABLE([ripd],
 577   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 578 AC_ARG_ENABLE([ripngd],
 579   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 580 AC_ARG_ENABLE([ospfd],
 581   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 582 AC_ARG_ENABLE([ospf6d],
 583   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 584 AC_ARG_ENABLE([ldpd],
 585   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 586 AC_ARG_ENABLE([nhrpd],
 587   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 588 AC_ARG_ENABLE([eigrpd],
 589   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 590 AC_ARG_ENABLE([babeld],
 591   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 592 AC_ARG_ENABLE([watchfrr],
 593   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 594 AC_ARG_ENABLE([isisd],
 595   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 596 AC_ARG_ENABLE([pimd],
 597   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 598 AC_ARG_ENABLE([pbrd],
 599   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 600 AC_ARG_ENABLE([sharpd],
 601   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 602 AC_ARG_ENABLE([staticd],
 603   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 604 AC_ARG_ENABLE([fabricd],
 605   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 606 AC_ARG_ENABLE([vrrpd],
 607   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 608 AC_ARG_ENABLE([pathd],
 609   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 610 AC_ARG_ENABLE([bgp-announce],
 611   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 612 AC_ARG_ENABLE([bgp-vnc],
 613   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 614 AC_ARG_ENABLE([bgp-bmp],
 615   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 616 AC_ARG_ENABLE([snmp],
 617   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 618 AC_ARG_ENABLE([config_rollbacks],
 619   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 620 AC_ARG_ENABLE([confd],
 621   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 622 AC_ARG_ENABLE([sysrepo],
 623   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 624 AC_ARG_ENABLE([grpc],
 625   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 626 AC_ARG_ENABLE([zeromq],
 627   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 628 AC_ARG_ENABLE([lttng],
 629   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 630 AC_ARG_ENABLE([usdt],
 631   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 632 AC_ARG_WITH([libpam],
 633   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 634 AC_ARG_ENABLE([ospfapi],
 635   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 636 AC_ARG_ENABLE([ospfclient],
 637   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 638                           (this is the default if --disable-ospfapi is set)]))
 639 AC_ARG_ENABLE([multipath],
 640   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 641 AC_ARG_ENABLE([user],
 642   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 643 AC_ARG_ENABLE([group],
 644   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 645 AC_ARG_ENABLE([vty_group],
 646   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 647 AC_ARG_ENABLE([configfile_mask],
 648   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 649 AC_ARG_ENABLE([logfile_mask],
 650   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 651 AC_ARG_ENABLE([shell_access],
 652   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 653 AC_ARG_ENABLE([realms],
 654   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 655 AC_ARG_ENABLE([rtadv],
 656   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 657 AC_ARG_ENABLE([irdp],
 658   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 659 AC_ARG_ENABLE([capabilities],
 660   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 661 AC_ARG_ENABLE([gcc_ultra_verbose],
 662   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 663 AC_ARG_ENABLE([backtrace],
 664   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 665 AC_ARG_ENABLE([time-check],
 666   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 667 AC_ARG_ENABLE([cpu-time],
 668   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 669 AC_ARG_ENABLE([pcreposix],
 670   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 671 AC_ARG_ENABLE([fpm],
 672   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 673 AC_ARG_ENABLE([pcep],
 674   AS_HELP_STRING([--enable-pcep], [enable PCEP support for pathd]))
 675 AC_ARG_ENABLE([systemd],
 676   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 677 AC_ARG_ENABLE([werror],
 678   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 679 AC_ARG_ENABLE([cumulus],
 680   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 681 AC_ARG_ENABLE([datacenter],
 682   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 683 AC_ARG_ENABLE([rr-semantics],
 684   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 685 AC_ARG_ENABLE([protobuf],
 686   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 687 AC_ARG_ENABLE([oldvpn_commands],
 688   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 689 AC_ARG_ENABLE([rpki],
 690   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 691 AC_ARG_ENABLE([clippy-only],
 692   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 693 AC_ARG_ENABLE([numeric_version],
 694   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 695 AC_ARG_ENABLE([gcov],
 696   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 697 AC_ARG_ENABLE([clang_coverage],
 698   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 699 AC_ARG_ENABLE([bfdd],
 700   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 701 AC_ARG_ENABLE([address-sanitizer],
 702   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 703 AC_ARG_ENABLE([thread-sanitizer],
 704   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 705 AC_ARG_ENABLE([memory-sanitizer],
 706   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 707 AC_ARG_ENABLE([undefined-sanitizer],
 708   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 709 AC_ARG_WITH([crypto],
 710   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 711 AC_ARG_WITH([frr-format],
 712   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 713
 714 AC_ARG_ENABLE([version-build-config],
 715   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 716
 717 #if openssl, else use the internal
 718 AS_IF([test "$with_crypto" = "openssl"], [
 719 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 720 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 721   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 722 else
 723   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 724 fi
 725 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 726 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 727 )
 728
 729 AS_IF([test "$enable_clippy_only" != "yes"], [
 730 AC_CHECK_HEADERS([json-c/json.h])
 731 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 732 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 733   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 734   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 735       AC_MSG_ERROR([libjson is needed to compile])
 736   fi
 737 fi
 738 ])
 739
 740 AC_ARG_ENABLE([dev_build],
 741     AS_HELP_STRING([--enable-dev-build], [build for development]))
 742
 743 AC_ARG_ENABLE([scripting],
 744     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 745
 746 AC_ARG_ENABLE([netlink-debug],
 747   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 748
 749 if test "$enable_netlink_debug" != "no" ; then
 750   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 751 fi
 752
 753 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 754
 755 if test "$enable_time_check" != "no" ; then
 756   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 757     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 758   else
 759     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 760   fi
 761 fi
 762
 763 case "${enable_cpu_time}" in
 764   "no")
 765   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 766   ;;
 767   "*")
 768   ;;
 769 esac
 770
 771 case "${enable_systemd}" in
 772   "no") ;;
 773   "yes")
 774   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 775   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 776     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 777   else
 778     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 779   fi
 780   ;;
 781   "*") ;;
 782 esac
 783
 784 if test "$enable_rr_semantics" != "no" ; then
 785   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 786 fi
 787
 788 if test "$enable_datacenter" = "yes" ; then
 789   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 790   DFLT_NAME="datacenter"
 791 else
 792   DFLT_NAME="traditional"
 793 fi
 794
 795 if test "$enable_cumulus" = "yes" ; then
 796   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 797 fi
 798
 799 AC_SUBST([DFLT_NAME])
 800 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 801
 802 if test "$enable_shell_access" = "yes"; then
 803    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 804 fi
 805
 806 #
 807 # Python for clippy
 808 #
 809
 810 AS_IF([test "$host" = "$build"], [
 811   AC_CHECK_HEADER([gelf.h], [], [
 812     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 813   ])
 814   AC_CHECK_LIB([elf], [elf_memory], [], [
 815     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 816   ])
 817
 818   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 819     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 820   ])
 821   AC_CHECK_LIB([elf], [gelf_getnote], [
 822     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 823   ])
 824
 825   FRR_PYTHON_DEV
 826 ], [
 827   FRR_PYTHON
 828 ])
 829
 830 FRR_PYTHON_MODULES([pytest])
 831
 832 if test "$enable_doc" != "no"; then
 833   FRR_PYTHON_MODULES([sphinx], , [
 834     if test "$enable_doc" = "yes"; then
 835       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 836     fi
 837   ])
 838 fi
 839 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 840 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 841
 842 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 843   PYSPHINX="-m sphinx"
 844 ], [
 845   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 846 ])
 847 AC_SUBST([PYSPHINX])
 848
 849 #
 850 # Logic for old vpn commands support.
 851 #
 852 if test "$enable_oldvpn_commands" = "yes"; then
 853    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 854 fi
 855
 856 #
 857 # End of logic for protobuf support.
 858 #
 859
 860 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 861 if test "$enable_rtadv" != "no"; then
 862   AC_MSG_RESULT([yes])
 863   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 864 else
 865   AC_MSG_RESULT([no])
 866 fi
 867
 868 if test "$enable_user" = "no"; then
 869   enable_user=""
 870 else
 871   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 872     enable_user="frr"
 873   fi
 874   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 875 fi
 876
 877 if test "$enable_group" = "no"; then
 878   enable_group=""
 879 else
 880   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 881     enable_group="frr"
 882   fi
 883   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 884 fi
 885
 886 if test "$enable_vty_group" = "yes" ; then
 887   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 888 elif test "$enable_vty_group" != ""; then
 889   if test "$enable_vty_group" != "no"; then
 890     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 891   fi
 892 fi
 893 AC_SUBST([enable_user])
 894 AC_SUBST([enable_group])
 895 AC_SUBST([enable_vty_group])
 896
 897 enable_configfile_mask=${enable_configfile_mask:-0600}
 898 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 899 AC_SUBST([enable_configfile_mask])
 900
 901 enable_logfile_mask=${enable_logfile_mask:-0600}
 902 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 903
 904 MPATH_NUM=16
 905
 906 case "${enable_multipath}" in
 907   0)
 908     MPATH_NUM=64
 909     ;;
 910   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 911     MPATH_NUM="${enable_multipath}"
 912     ;;
 913   "")
 914     ;;
 915   *)
 916     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 917     ;;
 918 esac
 919
 920 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 921
 922 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 923
 924 dnl --------------------
 925 dnl Enable code coverage
 926 dnl --------------------
 927 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 928
 929 dnl ------------------------------------
 930 dnl Alpine only accepts numeric versions
 931 dnl ------------------------------------
 932 if test "$enable_numeric_version" != "" ; then
 933   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 934   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 935 fi
 936
 937 dnl -----------------------------------
 938 dnl Add extra version string to package
 939 dnl name, string and version fields.
 940 dnl -----------------------------------
 941 if test "$EXTRAVERSION" != "" ; then
 942   VERSION="${VERSION}${EXTRAVERSION}"
 943   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 944   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 945   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 946 fi
 947 AC_SUBST([EXTRAVERSION])
 948
 949 if test "$with_pkg_git_version" = "yes"; then
 950         if test -e "${srcdir}/.git"; then
 951                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 952         else    with_pkg_git_version="no"
 953                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 954         fi
 955 fi
 956 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 957
 958 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 959 if test "$OBJCOPY" != ":"; then
 960   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 961     frr_cv_interp=""
 962     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 963       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 964         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 965       fi
 966       test -f conftest.interp && rm conftest.interp
 967     ])
 968   ])
 969 fi
 970 if test -n "$frr_cv_interp"; then
 971   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 972 fi
 973
 974 dnl -------------------------
 975 dnl Check other header files.
 976 dnl -------------------------
 977 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 978         linux/version.h asm/types.h endian.h sys/endian.h])
 979
 980 ac_stdatomic_ok=false
 981 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 982 AC_CHECK_HEADER([stdatomic.h],[
 983
 984   AC_MSG_CHECKING([whether _Atomic qualifier works])
 985   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 986 #include <stdatomic.h>
 987 int main(int argc, char **argv) {
 988   _Atomic int i = 0;
 989   return i;
 990 }
 991 ]])], [
 992     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 993     AC_MSG_RESULT([yes])
 994     ac_stdatomic_ok=true
 995   ], [
 996     AC_MSG_RESULT([no])
 997   ])
 998 ])
 999
1000 AS_IF([$ac_stdatomic_ok], [true], [
1001   AC_MSG_CHECKING([for __atomic_* builtins])
1002   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1003 int main(int argc, char **argv) {
1004   volatile int i = 1;
1005   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1006   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1007 }
1008 ]])], [
1009     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1010     AC_MSG_RESULT([yes])
1011   ], [
1012     AC_MSG_RESULT([no])
1013
1014     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1015     AC_MSG_CHECKING([for __sync_* builtins])
1016     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1017 int main(int argc, char **argv) {
1018   volatile int i = 1;
1019   __sync_fetch_and_sub (&i, 1);
1020   return __sync_val_compare_and_swap (&i, 0, 1);
1021 }
1022 ]])], [
1023       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1024       AC_MSG_RESULT([yes])
1025
1026       AC_MSG_CHECKING([for __sync_swap builtin])
1027       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1028 int main(int argc, char **argv) {
1029   volatile int i = 1;
1030   return __sync_swap (&i, 2);
1031 }
1032 ]])], [
1033         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1034         AC_MSG_RESULT([yes])
1035       ], [
1036         AC_MSG_RESULT([no])
1037       ])
1038
1039     ], [
1040       AC_MSG_RESULT([no])
1041       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1042     ])
1043   ])
1044 ])
1045
1046 needsync=true
1047
1048 AS_IF([$needsync], [
1049   dnl Linux
1050   AC_MSG_CHECKING([for Linux futex() support])
1051   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1052 #ifndef _GNU_SOURCE
1053 #define _GNU_SOURCE
1054 #endif
1055 #include <unistd.h>
1056 #include <limits.h>
1057 #include <sys/time.h>
1058 #include <sys/syscall.h>
1059 #include <linux/futex.h>
1060
1061 int main(void);
1062 ],
1063 [
1064 {
1065   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1066 }
1067 ])], [
1068     AC_MSG_RESULT([yes])
1069     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1070     needsync=false
1071   ], [
1072     AC_MSG_RESULT([no])
1073   ])
1074 ])
1075
1076 AS_IF([$needsync], [
1077   dnl FreeBSD
1078   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1079   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1080 #include <errno.h>
1081 #include <stdlib.h>
1082 #include <sys/types.h>
1083 #include <sys/umtx.h>
1084 int main(void);
1085 ],
1086 [
1087 {
1088   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1089 }
1090 ])], [
1091     AC_MSG_RESULT([yes])
1092     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1093     needsync=false
1094   ], [
1095     AC_MSG_RESULT([no])
1096   ])
1097 ])
1098
1099 AS_IF([$needsync], [
1100   dnl OpenBSD patch (not upstream at the time of writing this)
1101   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1102   AC_MSG_CHECKING([for OpenBSD futex() support])
1103   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1104 #include <sys/futex.h>
1105 int main(void);
1106 ],
1107 [
1108 {
1109   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1110 }
1111 ])], [
1112     AC_MSG_RESULT([yes])
1113     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1114     needsync=false
1115   ], [
1116     AC_MSG_RESULT([no])
1117   ])
1118 ])
1119
1120 dnl Utility macro to avoid retyping includes all the time
1121 m4_define([FRR_INCLUDES],
1122 [#ifdef SUNOS_5
1123 #define _POSIX_C_SOURCE 200809L
1124 #define __EXTENSIONS__
1125 #endif
1126 #include <stdio.h>
1127 #include <stdlib.h>
1128 #include <stddef.h>
1129 #include <sys/types.h>
1130 /* sys/conf.h depends on param.h on FBSD at least */
1131 #include <sys/param.h>
1132 /* Required for MAXSIG */
1133 #include <signal.h>
1134 #include <sys/socket.h>
1135 #ifdef __APPLE__
1136 # define __APPLE_USE_RFC_3542
1137 #endif
1138 #include <netinet/in.h>
1139 #include <sys/time.h>
1140 #include <time.h>
1141 #include <net/if.h>
1142 ])dnl
1143
1144 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1145 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1146 dnl an additional round for it.
1147
1148 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1149
1150 m4_define([FRR_INCLUDES],
1151 FRR_INCLUDES
1152 [#ifdef HAVE_NET_IF_VAR_H
1153 # include <net/if_var.h>
1154 #endif
1155 ])dnl
1156
1157 AC_CHECK_HEADERS([netinet/in_var.h \
1158         net/if_dl.h net/netopt.h \
1159         inet/nd.h netinet/ip_icmp.h \
1160         sys/sysctl.h sys/sockio.h sys/conf.h],
1161         [], [], [FRR_INCLUDES])
1162
1163 AC_CHECK_HEADERS([ucontext.h], [], [],
1164 [#ifndef __USE_GNU
1165 #define __USE_GNU
1166 #endif /* __USE_GNU */
1167 FRR_INCLUDES
1168 ])
1169
1170 m4_define([UCONTEXT_INCLUDES],
1171 [#include <ucontext.h>])dnl
1172
1173 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1174   [], [], [UCONTEXT_INCLUDES])
1175 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1176   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1177    [], [], [UCONTEXT_INCLUDES])],
1178   [], [UCONTEXT_INCLUDES])
1179 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1180   [], [], [UCONTEXT_INCLUDES])
1181
1182 m4_define([FRR_INCLUDES],
1183 FRR_INCLUDES
1184 [
1185 #include <sys/un.h>
1186 #include <netinet/in_systm.h>
1187 #ifdef HAVE_NETINET_IN_VAR_H
1188 # include <netinet/in_var.h>
1189 #endif
1190 #ifdef HAVE_NET_IF_DL_H
1191 # include <net/if_dl.h>
1192 #endif
1193 #ifdef HAVE_NET_NETOPT_H
1194 # include <net/netopt.h>
1195 #endif
1196 #include <net/route.h>
1197 #ifdef HAVE_INET_ND_H
1198 # include <inet/nd.h>
1199 #endif
1200 #include <arpa/inet.h>
1201 /* Required for IDRP */
1202 #ifdef HAVE_NETINET_IP_ICMP_H
1203 # include <netinet/ip_icmp.h>
1204 #endif
1205 ])dnl
1206
1207 dnl V6 headers are checked below, after we check for v6
1208
1209 is_linux=false
1210
1211 AC_MSG_CHECKING([which operating system interface to use])
1212 case "$host_os" in
1213   sunos* | solaris2*)
1214     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1215     ;;
1216   linux*)
1217     AC_MSG_RESULT([Linux])
1218
1219     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1220     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1221     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1222
1223     dnl Linux has a compilation problem with mixing
1224     dnl netinet/in.h and linux/in6.h they are not
1225     dnl compatible.  There has been discussion on
1226     dnl how to fix it but no real progress on implementation
1227     dnl when they fix it, remove this
1228     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1229
1230     is_linux=true
1231     ;;
1232   openbsd*)
1233     AC_MSG_RESULT([OpenBSD])
1234
1235     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1236     AC_DEFINE([KAME], [1], [KAME IPv6])
1237     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1238     ;;
1239   *)
1240     AC_MSG_RESULT([BSD])
1241
1242     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1243     AC_DEFINE([KAME], [1], [KAME IPv6])
1244     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1245     ;;
1246 esac
1247 AM_CONDITIONAL([LINUX], [${is_linux}])
1248
1249 AC_SYS_LARGEFILE
1250
1251 dnl ------------------------
1252 dnl Integrated REALMS option
1253 dnl ------------------------
1254 if test "$enable_realms" = "yes"; then
1255     case "$host_os" in
1256       linux*)
1257        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1258        ;;
1259       *)
1260        echo "Sorry, only Linux has REALMS support"
1261        exit 1
1262        ;;
1263     esac
1264 fi
1265
1266 dnl ---------------
1267 dnl other functions
1268 dnl ---------------
1269 AC_CHECK_FUNCS([ \
1270         strlcat strlcpy \
1271         getgrouplist \
1272         openat \
1273         unlinkat \
1274         posix_fallocate \
1275         ])
1276
1277 dnl ##########################################################################
1278 dnl LARGE if block spans a lot of "configure"!
1279 if test "$enable_clippy_only" != "yes"; then
1280 dnl ##########################################################################
1281
1282 #
1283 # Logic for protobuf support.
1284 #
1285 PROTO3=false
1286 if test "$enable_protobuf" = "yes"; then
1287   # Check for protoc & protoc-c
1288
1289   # protoc is not required, it's only for a "be nice" helper target
1290   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1291
1292   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1293   if test "$PROTOC_C" = "/bin/false"; then
1294     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1295   fi
1296
1297   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1298     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1299   ])
1300
1301   PROTO3=true
1302   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1303                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1304                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1305                                             [1], [Have Protobuf version 3]),
1306                                   [PROTO3=false],
1307                                   [#include <google/protobuf-c/protobuf-c.h>])],
1308                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1309
1310   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1311 fi
1312
1313
1314 dnl ---------------------
1315 dnl Integrated VTY option
1316 dnl ---------------------
1317 case "${enable_vtysh}" in
1318 "no")
1319   VTYSH="";;
1320 *)
1321   VTYSH="vtysh";
1322   AC_DEFINE([VTYSH], [1], [VTY shell])
1323
1324   prev_libs="$LIBS"
1325   AC_CHECK_LIB([readline], [main], [
1326     LIBREADLINE="-lreadline"
1327   ], [
1328     dnl readline failed - it might be incorrectly linked and missing its
1329     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1330     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1331       LIBREADLINE="$ac_cv_search_tputs"
1332     ], [
1333       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1334     ])
1335
1336     dnl re-try with the lib we found above
1337     unset ac_cv_lib_readline_main
1338     AC_CHECK_LIB([readline], [main], [
1339       LIBREADLINE="-lreadline $LIBREADLINE"
1340     ], [
1341       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1342     ], [$LIBREADLINE])
1343   ], [])
1344   LIBS="$prev_libs"
1345
1346   AC_CHECK_HEADER([readline/history.h])
1347   if test "$ac_cv_header_readline_history_h" = "no"; then
1348     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1349   fi
1350   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1351   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1352     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1353   fi
1354   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1355   if test "$frr_cv_append_history" = "yes"; then
1356     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1357   fi
1358   ;;
1359 esac
1360 AC_SUBST([LIBREADLINE])
1361
1362 dnl ----------
1363 dnl PAM module
1364 dnl
1365 dnl FRR detects the PAM library it is built against by checking for a
1366 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1367 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1368 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1369 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1370 dnl of OpenPAM.
1371 dnl ----------
1372 if test "$with_libpam" = "yes"; then
1373   AC_CHECK_HEADER([security/pam_misc.h],
1374     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1375      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1376      pam_conv_func="misc_conv"
1377     ],
1378     [], FRR_INCLUDES)
1379   AC_CHECK_HEADER([security/openpam.h],
1380     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1381      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1382      pam_conv_func="openpam_ttyconv"
1383     ],
1384     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1385   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1386     AC_MSG_WARN([*** pam support will not be built ***])
1387     with_libpam="no"
1388   fi
1389 fi
1390
1391 if test "$with_libpam" = "yes"; then
1392 dnl took this test from proftpds configure.in and suited to our needs
1393 dnl -------------------------------------------------------------------------
1394 dnl
1395 dnl This next check looks funky due to a linker problem with some versions
1396 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1397 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1398 dnl with RedHat 6.2 and Debian 2.2 or better.
1399 AC_CHECK_LIB([pam], [pam_start],
1400   [AC_CHECK_LIB([pam], [$pam_conv_func],
1401     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1402      LIBPAM="-lpam"],
1403     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1404      LIBPAM="-lpam -lpam_misc"]
1405     )
1406   ],
1407
1408   [AC_CHECK_LIB([pam], [pam_end],
1409     [AC_CHECK_LIB([pam], [$pam_conv_func],
1410       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1411        LIBPAM="-lpam -ldl"],
1412       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1413        LIBPAM="-lpam -ldl -lpam_misc"]
1414      )
1415   ],AC_MSG_WARN([*** pam support will not be built ***]),
1416   [-ldl])
1417   ]
1418 )
1419 fi
1420 AC_SUBST([LIBPAM])
1421
1422 dnl -------------------------------
1423 dnl bgpd needs pow() and hence libm
1424 dnl -------------------------------
1425 TMPLIBS="$LIBS"
1426 LIBS=""
1427 AC_SEARCH_LIBS([pow], [m], [
1428   LIBM="$LIBS"
1429 ], [
1430   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1431 ])
1432 LIBS="$TMPLIBS"
1433 AC_SUBST([LIBM])
1434
1435 AC_CHECK_FUNCS([ppoll], [
1436   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1437 ])
1438 AC_CHECK_FUNCS([pollts], [
1439   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1440 ])
1441
1442 AC_CHECK_HEADER([asm-generic/unistd.h],
1443                 [AC_CHECK_DECL(__NR_setns,
1444                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1445                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1446                                ])
1447                  AC_CHECK_FUNCS([setns])]
1448                )
1449
1450 dnl --------------------------
1451 dnl Determine IS-IS I/O method
1452 dnl --------------------------
1453 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1454 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1455 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1456 AC_CHECK_HEADER([net/bpf.h])
1457 AC_CHECK_HEADER([sys/dlpi.h])
1458 AC_MSG_CHECKING([zebra IS-IS I/O method])
1459
1460 case "$host_os" in
1461   linux*)
1462     AC_MSG_RESULT([pfpacket])
1463     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1464     ;;
1465   *)
1466     if test "$ac_cv_header_net_bpf_h" = "no"; then
1467       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1468         AC_MSG_RESULT([none])
1469         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1470           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1471         fi
1472         AC_MSG_WARN([*** IS-IS support will not be built ***])
1473         enable_isisd="no"
1474         enable_fabricd="no"
1475       else
1476         AC_MSG_RESULT([DLPI])
1477       fi
1478       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1479     else
1480       AC_MSG_RESULT([BPF])
1481       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1482     fi
1483     ;;
1484 esac
1485 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1486
1487 dnl ---------------------------------------------------------------
1488 dnl figure out how to specify an interface in multicast sockets API
1489 dnl ---------------------------------------------------------------
1490 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1491
1492 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1493         #include <sys/socket.h>
1494         #include <netinet/in.h>
1495         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1496         #include <linux/types.h>
1497 ])
1498
1499 m4_define([FRR_INCLUDES],
1500 FRR_INCLUDES
1501 [#ifdef HAVE_LINUX_MROUTE_H
1502 # include <linux/mroute.h>
1503 #endif
1504 ])dnl
1505
1506 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1507         #include <sys/socket.h>
1508         #include <sys/types.h>
1509         #include <netinet/in.h>
1510         #include <net/route.h>
1511 ])
1512
1513 m4_define([FRR_INCLUDES],
1514 FRR_INCLUDES
1515 [#ifdef HAVE_NETINET_IP_MROUTE_H
1516 # include <netinet/ip_mroute.h>
1517 #endif
1518 ])dnl
1519
1520 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1521 AC_COMPILE_IFELSE(
1522 [ AC_LANG_PROGRAM([[
1523       #include <sys/types.h>
1524       #include <netinet/in.h>
1525   ]], [[
1526       struct group_req gr;
1527       int sock;
1528       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1529   ]])
1530 ],[
1531   AC_MSG_RESULT([yes])
1532   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1533 ],[
1534   AC_MSG_RESULT(no)
1535 ])
1536
1537 dnl ---------------------------------------------------------------
1538 dnl figure out how to check link-state
1539 dnl ---------------------------------------------------------------
1540 AC_CHECK_HEADER([net/if_media.h],
1541   [m4_define([LINK_DETECT_INCLUDES],
1542     FRR_INCLUDES
1543     [#include <net/if_media.h>
1544   ])
1545   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1546     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1547     [], LINK_DETECT_INCLUDES)],
1548   [],
1549   FRR_INCLUDES)
1550
1551 dnl ---------------------------------------------------------------
1552 dnl Additional, newer way to check link-state using ifi_link_state.
1553 dnl Not available in all BSD's when ifmediareq available
1554 dnl ---------------------------------------------------------------
1555 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1556   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1557   [], FRR_INCLUDES)
1558
1559 dnl ------------------------
1560 dnl TCP_MD5SIG socket option
1561 dnl ------------------------
1562
1563 AC_CHECK_HEADER([netinet/tcp.h],
1564    [m4_define([MD5_INCLUDES],
1565       FRR_INCLUDES
1566       [#include <netinet/tcp.h>
1567     ])
1568     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1569    [],
1570    FRR_INCLUDES)
1571 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1572   AC_CHECK_HEADER([linux/tcp.h],
1573        [m4_define([MD5_INCLUDES],
1574           FRR_INCLUDES
1575           [#include <linux/tcp.h>
1576         ])
1577        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1578 fi
1579
1580 AC_CHECK_LIB([crypt], [crypt], [],
1581                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1582 AC_CHECK_LIB([resolv], [res_init])
1583
1584 dnl ---------------------------
1585 dnl check system has PCRE regexp
1586 dnl ---------------------------
1587 if test "$enable_pcreposix" = "yes"; then
1588   AC_CHECK_LIB([pcreposix], [regexec], [], [
1589     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1590   ])
1591 fi
1592 AC_SUBST([HAVE_LIBPCREPOSIX])
1593
1594 dnl ##########################################################################
1595 dnl test "$enable_clippy_only" != "yes"
1596 fi
1597 dnl END OF LARGE if block
1598 dnl ##########################################################################
1599
1600 dnl ------------------
1601 dnl check C-Ares library
1602 dnl ------------------
1603 PKG_CHECK_MODULES([CARES], [libcares], [
1604   c_ares_found=true
1605 ],[
1606   c_ares_found=false
1607 ])
1608 AM_CONDITIONAL([CARES], [$c_ares_found])
1609
1610
1611 dnl ----------------------------------------------------------------------------
1612 dnl figure out if domainname is available in the utsname struct (GNU extension).
1613 dnl ----------------------------------------------------------------------------
1614 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1615
1616 dnl ------------------
1617 dnl IPv6 header checks
1618 dnl ------------------
1619 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1620         netinet6/in6_var.h netinet6/nd6.h], [], [],
1621         FRR_INCLUDES)
1622
1623 m4_define([FRR_INCLUDES],dnl
1624 FRR_INCLUDES
1625 [#ifdef HAVE_NETINET6_IN6_H
1626 #include <netinet6/in6.h>
1627 #endif
1628 #ifdef HAVE_NETINET_IN6_VAR_H
1629 #include <netinet/in6_var.h>
1630 #endif
1631 #include <netinet/icmp6.h>
1632 #ifdef HAVE_NETINET6_IN6_VAR_H
1633 # include <netinet6/in6_var.h>
1634 #endif
1635 #ifdef HAVE_NETINET6_ND6_H
1636 # include <netinet6/nd6.h>
1637 #endif
1638 ])dnl
1639
1640 dnl --------------------
1641 dnl Daemon disable check
1642 dnl --------------------
1643
1644 AS_IF([test "$enable_bgpd" != "no"], [
1645   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1646 ])
1647
1648 AS_IF([test "$enable_ripd" != "no"], [
1649   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1650 ])
1651
1652 AS_IF([test "$enable_ripngd" != "no"], [
1653   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1654 ])
1655
1656 AS_IF([test "$enable_ospfd" != "no"], [
1657   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1658 ])
1659
1660 AS_IF([test "$enable_ospf6d" != "no"], [
1661   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1662 ])
1663
1664 AS_IF([test "$enable_ldpd" != "no"], [
1665   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1666 ])
1667
1668 AS_IF([test "$enable_nhrpd" != "no"], [
1669   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1670 ])
1671
1672 AS_IF([test "$enable_eigrpd" != "no"], [
1673   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1674 ])
1675
1676 AS_IF([test "$enable_babeld" != "no"], [
1677   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1678 ])
1679
1680 AS_IF([test "$enable_isisd" != "no"], [
1681   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1682 ])
1683
1684 AS_IF([test "$enable_pimd" != "no"], [
1685   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1686 ])
1687
1688 AS_IF([test "$enable_pbrd" != "no"], [
1689   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1690 ])
1691
1692 AS_IF([test "$enable_sharpd" = "yes"], [
1693   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1694 ])
1695
1696 AS_IF([test "$enable_staticd" != "no"], [
1697   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1698 ])
1699
1700 AS_IF([test "$enable_fabricd" != "no"], [
1701   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1702 ])
1703
1704 AS_IF([test "$enable_vrrpd" != "no"], [
1705   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1706 ])
1707
1708 if test "$enable_bfdd" = "no"; then
1709   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1710   BFDD=""
1711 else
1712   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1713   BFDD="bfdd"
1714
1715   case $host_os in
1716     linux*)
1717       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1718       ;;
1719
1720     *)
1721       AC_DEFINE([BFD_BSD], [1], [bfdd])
1722       ;;
1723   esac
1724 fi
1725
1726 AS_IF([test "$enable_pathd" != "no"], [
1727   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1728   AC_DEFINE([HAVE_PATHD_PCEP], [1], [pathd-pcep])
1729 ])
1730
1731
1732 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1733   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1734 fi
1735
1736 NHRPD=""
1737 case "$host_os" in
1738   linux*)
1739     case "${enable_nhrpd}" in
1740       no)
1741         ;;
1742       yes)
1743         if test "$enable_clippy_only" != "yes"; then
1744         if test "$c_ares_found" != "true" ; then
1745           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1746         fi
1747         fi
1748         NHRPD="nhrpd"
1749         ;;
1750       *)
1751         if test "$c_ares_found" = "true" ; then
1752           NHRPD="nhrpd"
1753         fi
1754         ;;
1755     esac
1756     ;;
1757   *)
1758     if test "$enable_nhrpd" = "yes"; then
1759       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1760     fi
1761     ;;
1762 esac
1763
1764 if test "$enable_watchfrr" = "no";then
1765   WATCHFRR=""
1766 else
1767   WATCHFRR="watchfrr"
1768 fi
1769
1770 OSPFCLIENT=""
1771 if test "$enable_ospfapi" != "no";then
1772     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1773
1774   if test "$enable_ospfclient" != "no";then
1775       OSPFCLIENT="ospfclient"
1776   fi
1777 fi
1778
1779 if test "$enable_bgp_announce" = "no";then
1780   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1781 else
1782   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1783 fi
1784
1785 if test "$enable_bgp_vnc" != "no";then
1786   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1787 fi
1788
1789 bgpd_bmp=false
1790 case "${enable_bmp}" in
1791   no)
1792     ;;
1793   yes)
1794     if test "$c_ares_found" != "true" ; then
1795       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1796     fi
1797     bgpd_bmp=true
1798     ;;
1799   *)
1800     if test "$c_ares_found" = "true" ; then
1801       bgpd_bmp=true
1802     fi
1803     ;;
1804 esac
1805
1806 if test "$enable_version_build_config" != "no";then
1807   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1808 fi
1809
1810 dnl ##########################################################################
1811 dnl LARGE if block
1812 if test "$enable_clippy_only" != "yes"; then
1813 dnl ##########################################################################
1814
1815 dnl ------------------
1816 dnl check Net-SNMP library
1817 dnl ------------------
1818 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1819    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1820    if test "$NETSNMP_CONFIG" = "no"; then
1821       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1822    fi
1823    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1824    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1825    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1826    # among other things we avoid a GPL vs. OpenSSL license conflict here
1827    for removelib in crypto ssl sensors pci wrap; do
1828      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1829    done
1830    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1831    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1832 int main(void);
1833 ],
1834 [
1835 {
1836   return 0;
1837 }
1838 ])], [
1839      AC_MSG_RESULT([no])
1840      AC_MSG_ERROR([--enable-snmp given but not usable])])
1841    case "${enable_snmp}" in
1842      yes)
1843       SNMP_METHOD=agentx
1844       ;;
1845      agentx)
1846       SNMP_METHOD="${enable_snmp}"
1847       ;;
1848      *)
1849       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1850       ;;
1851    esac
1852    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1853    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1854 fi
1855 AC_SUBST([SNMP_LIBS])
1856 AC_SUBST([SNMP_CFLAGS])
1857
1858 dnl ---------------
1859 dnl libyang
1860 dnl ---------------
1861 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1862   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1863 ])
1864 ac_cflags_save="$CFLAGS"
1865 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1866 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1867   AC_MSG_ERROR([m4_normalize([
1868     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1869     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1870   ])
1871 ], [[#include <libyang/libyang.h>]])
1872 CFLAGS="$ac_cflags_save"
1873
1874 dnl ---------------
1875 dnl configuration rollbacks
1876 dnl ---------------
1877 SQLITE3=false
1878 if test "$enable_config_rollbacks" = "yes"; then
1879   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1880     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1881     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1882     SQLITE3=true
1883   ], [
1884     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1885   ])
1886 fi
1887
1888 dnl ---------------
1889 dnl confd
1890 dnl ---------------
1891 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1892    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1893    if test "$CONFD" = "/bin/false"; then
1894       AC_MSG_ERROR([confd was not found on your system.])]
1895    fi
1896    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1897    AC_SUBST([CONFD_CFLAGS])
1898    CONFD_LIBS="-lconfd"
1899    AC_SUBST([CONFD_LIBS])
1900    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1901 fi
1902
1903 dnl ---------------
1904 dnl sysrepo
1905 dnl ---------------
1906 if test "$enable_sysrepo" = "yes"; then
1907   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1908       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1909       SYSREPO=true],
1910       [SYSREPO=false
1911       AC_MSG_ERROR([sysrepo was not found on your system.])]
1912   )
1913 fi
1914
1915 dnl ---------------
1916 dnl gRPC
1917 dnl ---------------
1918 if test "$enable_grpc" = "yes"; then
1919   AC_LANG_PUSH([C++])
1920   AX_CXX_COMPILE_STDCXX([11], [ext])
1921   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
1922     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1923     if test "$PROTOC" = "/bin/false"; then
1924       AC_MSG_FAILURE([grpc requested but protoc not found.])
1925     fi
1926
1927     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1928     GRPC=true
1929   ], [
1930     GRPC=false
1931     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1932   ])
1933   AC_LANG_POP([C++])
1934 fi
1935
1936 dnl -----
1937 dnl LTTng
1938 dnl -----
1939 if test "$enable_lttng" = "yes"; then
1940   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.12.0], [
1941     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1942     LTTNG=true
1943   ], [
1944     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1945   ])
1946 fi
1947
1948 dnl ----
1949 dnl USDT
1950 dnl ----
1951 if test "$enable_usdt" = "yes"; then
1952   AC_CHECK_HEADERS([sys/sdt.h], [
1953     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1954     USDT=true
1955   ], [
1956     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1957   ])
1958 fi
1959
1960 dnl ------
1961 dnl ZeroMQ
1962 dnl ------
1963 if test "$enable_zeromq" != "no"; then
1964   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1965     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1966     ZEROMQ=true
1967   ], [
1968     if test "$enable_zeromq" = "yes"; then
1969       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1970     fi
1971   ])
1972 fi
1973
1974 dnl ------------------------------------
1975 dnl Enable RPKI and add librtr to libs
1976 dnl ------------------------------------
1977 if test "$enable_rpki" = "yes"; then
1978   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1979       [RPKI=true],
1980       [RPKI=false
1981       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1982   )
1983 fi
1984
1985 dnl ------------------------------------
1986 dnl pimd is not supported on OpenBSD and MacOS
1987 dnl ------------------------------------
1988 if test "$enable_pimd" != "no"; then
1989 AC_MSG_CHECKING([for pimd OS support])
1990 case "$host_os" in
1991   darwin*)
1992     AC_MSG_RESULT([no])
1993     enable_pimd="no"
1994     ;;
1995   openbsd*)
1996     AC_MSG_RESULT([no])
1997     enable_pimd="no"
1998     ;;
1999   *)
2000     AC_MSG_RESULT([yes])
2001     ;;
2002 esac
2003 fi
2004
2005 dnl -------------------------------------
2006 dnl VRRP is only supported on linux
2007 dnl -------------------------------------
2008 if test "$enable_vrrpd" != "no"; then
2009 AC_MSG_CHECKING([for VRRP OS support])
2010 case "$host_os" in
2011   linux*)
2012     AC_MSG_RESULT([yes])
2013     ;;
2014   *)
2015     AC_MSG_RESULT([no])
2016     enable_vrrpd="no"
2017     ;;
2018 esac
2019 fi
2020
2021 dnl ------------------------------------------
2022 dnl Check whether rtrlib was build with ssh support
2023 dnl ------------------------------------------
2024 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2025 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2026                         [[struct tr_ssh_config config;]])],
2027         [AC_MSG_RESULT([yes])
2028         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2029         AC_MSG_RESULT([no])
2030 )
2031
2032 dnl ---------------
2033 dnl dlopen & dlinfo
2034 dnl ---------------
2035 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2036   AC_MSG_ERROR([unable to find the dlopen()])
2037 ])
2038
2039 AC_CHECK_HEADERS([link.h])
2040
2041 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2042   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2043 #include <stdlib.h>
2044 #ifdef HAVE_LINK_H
2045 #include <link.h>
2046 #endif
2047 #include <dlfcn.h>
2048 ]], [[
2049   char origin[1];
2050   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2051 ]])], [
2052     frr_cv_rtld_di_origin=yes
2053   ], [
2054     frr_cv_rtld_di_origin=no
2055   ])
2056 ])
2057 if test "$frr_cv_rtld_di_origin" = "yes"; then
2058   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2059 fi
2060
2061 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2062   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2063 #include <stdlib.h>
2064 #ifdef HAVE_LINK_H
2065 #include <link.h>
2066 #endif
2067 #include <dlfcn.h>
2068 ]], [[
2069   struct link_map *lm = NULL;
2070   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2071 ]])], [
2072     frr_cv_rtld_di_linkmap=yes
2073   ], [
2074     frr_cv_rtld_di_linkmap=no
2075   ])
2076 ])
2077 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2078   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2079 fi
2080
2081 dnl ##########################################################################
2082 dnl test "$enable_clippy_only" != "yes"
2083 fi
2084 dnl END OF LARGE if block
2085 dnl ##########################################################################
2086
2087 dnl ---------------------------
2088 dnl sockaddr and netinet checks
2089 dnl ---------------------------
2090 AC_CHECK_TYPES([
2091         struct sockaddr_dl,
2092         struct vifctl, struct mfcctl, struct sioc_sg_req,
2093         vifi_t, struct sioc_vif_req, struct igmpmsg,
2094         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2095         struct nd_opt_adv_interval,
2096         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2097         struct nd_opt_rdnss, struct nd_opt_dnssl],
2098         [], [], FRR_INCLUDES)
2099
2100 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2101         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2102         struct sockaddr_dl.sdl_len,
2103         struct if6_aliasreq.ifra_lifetime,
2104         struct nd_opt_adv_interval.nd_opt_ai_type],
2105         [], [], FRR_INCLUDES)
2106
2107 dnl ---------------------------
2108 dnl IRDP/pktinfo/icmphdr checks
2109 dnl ---------------------------
2110
2111 AC_CHECK_TYPES([struct in_pktinfo], [
2112   AC_CHECK_TYPES([struct icmphdr], [
2113     IRDP=true
2114   ], [
2115     IRDP=false
2116   ], [FRR_INCLUDES])
2117 ], [
2118   IRDP=false
2119 ], [FRR_INCLUDES])
2120
2121 case "${enable_irdp}" in
2122 yes)
2123   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2124   ;;
2125 no)
2126   IRDP=false
2127   ;;
2128 esac
2129
2130
2131 dnl -----------------------
2132 dnl checking for IP_PKTINFO
2133 dnl -----------------------
2134 AC_MSG_CHECKING([for IP_PKTINFO])
2135 AC_COMPILE_IFELSE(
2136 [ AC_LANG_PROGRAM([[
2137         #include <netdb.h>
2138    ]], [[
2139         int opt = IP_PKTINFO;
2140    ]])
2141 ],[
2142   AC_MSG_RESULT([yes])
2143   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2144 ],[
2145   AC_MSG_RESULT([no])
2146 ])
2147
2148 dnl ---------------------------
2149 dnl checking for IP_RECVDSTADDR
2150 dnl ---------------------------
2151 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2152 AC_COMPILE_IFELSE(
2153 [ AC_LANG_PROGRAM([[
2154         #include <netinet/in.h>
2155   ]], [[
2156         int opt = IP_RECVDSTADDR;
2157   ]])
2158 ],[
2159   AC_MSG_RESULT([yes])
2160   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2161 ],[
2162   AC_MSG_RESULT([no])
2163 ])
2164
2165 dnl ----------------------
2166 dnl checking for IP_RECVIF
2167 dnl ----------------------
2168 AC_MSG_CHECKING([for IP_RECVIF])
2169 AC_COMPILE_IFELSE(
2170 [ AC_LANG_PROGRAM([[
2171         #include <netinet/in.h>
2172   ]], [[
2173         int opt = IP_RECVIF;
2174   ]])
2175 ],[
2176   AC_MSG_RESULT([yes])
2177   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2178 ],[
2179   AC_MSG_RESULT([no])
2180 ])
2181
2182 dnl ----------------------
2183 dnl checking for SO_BINDANY
2184 dnl ----------------------
2185 AC_MSG_CHECKING([for SO_BINDANY])
2186 AC_COMPILE_IFELSE(
2187 [ AC_LANG_PROGRAM([[
2188         #include <sys/socket.h>
2189   ]], [[
2190         int opt = SO_BINDANY;
2191   ]])
2192 ],[
2193   AC_MSG_RESULT([yes])
2194   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2195 ],[
2196   AC_MSG_RESULT([no])
2197 ])
2198
2199 dnl ----------------------
2200 dnl checking for IP_FREEBIND
2201 dnl ----------------------
2202 AC_MSG_CHECKING([for IP_FREEBIND])
2203 AC_COMPILE_IFELSE(
2204 [ AC_LANG_PROGRAM([[
2205         #include <netinet/in.h>
2206   ]], [[
2207         int opt = IP_FREEBIND;
2208   ]])
2209 ],[
2210   AC_MSG_RESULT([yes])
2211   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2212 ],[
2213   AC_MSG_RESULT([no])
2214 ])
2215
2216 dnl --------------------------------------
2217 dnl checking for be32dec existence or not
2218 dnl --------------------------------------
2219 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2220         #ifdef HAVE_SYS_ENDIAN_H
2221         #include <sys/endian.h>
2222         #endif
2223         #ifdef HAVE_ENDIAN_H
2224         #include <endian.h>
2225         #endif
2226 ])
2227
2228 dnl --------------------------------------
2229 dnl checking for clock_time monotonic struct and call
2230 dnl --------------------------------------
2231 AC_CHECK_DECL([CLOCK_MONOTONIC],
2232         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2233          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2234 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2235
2236 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2237          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2238 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2239
2240 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2241   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2242 ])
2243
2244 dnl --------------------------------------
2245 dnl checking for flex and bison
2246 dnl --------------------------------------
2247
2248 AM_PROG_LEX
2249 AC_MSG_CHECKING([version of flex])
2250 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2251 frr_ac_flex_version="${frr_ac_flex_version##* }"
2252 AC_MSG_RESULT([$frr_ac_flex_version])
2253 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2254   LEX="$SHELL $missing_dir/missing flex"
2255   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2256     AC_MSG_WARN([using pregenerated flex output files])
2257   else
2258     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2259   fi
2260   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2261   AC_SUBST([LEXLIB], [''])
2262 ])
2263
2264 AC_PROG_YACC
2265 dnl thanks GNU bison for this b*llshit...
2266 AC_MSG_CHECKING([version of bison])
2267 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2268 frr_ac_bison_version="${frr_ac_bison_version##* }"
2269 frr_ac_bison_missing="false"
2270 case "x${frr_ac_bison_version}x" in
2271   x2.7*)
2272     BISON_OPENBRACE='"'
2273     BISON_CLOSEBRACE='"'
2274     BISON_VERBOSE=''
2275     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2276     ;;
2277   x2.*|x1.*)
2278     AC_MSG_RESULT([$frr_ac_bison_version])
2279     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2280     frr_ac_bison_missing="true"
2281     ;;
2282   x)
2283     AC_MSG_RESULT([none])
2284     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2285     frr_ac_bison_missing="true"
2286     ;;
2287   x3.[012][^0-9]*)
2288     BISON_OPENBRACE='{'
2289     BISON_CLOSEBRACE='}'
2290     BISON_VERBOSE='-Dparse.error=verbose'
2291     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2292     ;;
2293   *)
2294     BISON_OPENBRACE='{'
2295     BISON_CLOSEBRACE='}'
2296     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2297     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2298     ;;
2299 esac
2300 AC_SUBST([BISON_OPENBRACE])
2301 AC_SUBST([BISON_CLOSEBRACE])
2302 AC_SUBST([BISON_VERBOSE])
2303
2304 if $frr_ac_bison_missing; then
2305   YACC="$SHELL $missing_dir/missing bison -y"
2306   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2307     AC_MSG_WARN([using pregenerated bison output files])
2308   else
2309     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2310   fi
2311 fi
2312
2313 dnl -------------------
2314 dnl capabilities checks
2315 dnl -------------------
2316 if test "$enable_capabilities" != "no"; then
2317   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2318   AC_COMPILE_IFELSE(
2319   [ AC_LANG_PROGRAM([[
2320         #include <sys/prctl.h>
2321     ]], [[
2322         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2323     ]])
2324   ],[AC_MSG_RESULT([yes])
2325      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2326      frr_ac_keepcaps="yes"
2327   ],[AC_MSG_RESULT(no)
2328   ])
2329   if test "$frr_ac_keepcaps" = "yes"; then
2330     AC_CHECK_HEADERS([sys/capability.h])
2331   fi
2332   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2333     AC_CHECK_LIB([cap], [cap_init],
2334       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2335        LIBCAP="-lcap"
2336        frr_ac_lcaps="yes"]
2337     )
2338   fi
2339   if test "$frr_ac_scaps" = "yes" \
2340        -o "$frr_ac_lcaps" = "yes"; then
2341     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2342   fi
2343
2344   case "$host_os" in
2345   linux*)
2346     if test "$enable_clippy_only" != "yes"; then
2347     if test "$frr_ac_lcaps" != "yes"; then
2348       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2349     fi
2350     fi
2351     ;;
2352   esac
2353 else
2354   case "$host_os" in
2355   linux*)
2356     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2357     ;;
2358   esac
2359 fi
2360 AC_SUBST([LIBCAP])
2361
2362 dnl ---------------------------
2363 dnl check for glibc 'backtrace'
2364 dnl ---------------------------
2365 if test "$enable_backtrace" != "no" ; then
2366   backtrace_ok=no
2367   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2368     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2369     backtrace_ok=yes
2370   ], [
2371     true
2372   ])
2373
2374   if test "$backtrace_ok" = "no"; then
2375     AC_CHECK_HEADER([unwind.h], [
2376       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2377         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2378         backtrace_ok=yes
2379       ])
2380     ])
2381   fi
2382
2383   if test "$backtrace_ok" = "no"; then
2384     AC_CHECK_HEADER([execinfo.h], [
2385       AC_SEARCH_LIBS([backtrace], [execinfo], [
2386         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2387         backtrace_ok=yes
2388       ],, [-lm])
2389     ])
2390   fi
2391
2392   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2393     dnl user explicitly requested backtrace but we failed to find support
2394     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2395   fi
2396 fi
2397
2398 dnl -----------------------------------------
2399 dnl check for malloc mallinfo struct and call
2400 dnl this must try and link using LIBS, in
2401 dnl order to check no alternative allocator
2402 dnl has been specified, which might not provide
2403 dnl mallinfo
2404 dnl -----------------------------------------
2405 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2406
2407 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2408   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2409 #ifdef HAVE_MALLOC_H
2410 #include <malloc.h>
2411 #endif
2412 #ifdef HAVE_MALLOC_NP_H
2413 #include <malloc_np.h>
2414 #endif
2415 #ifdef HAVE_MALLOC_MALLOC_H
2416 #include <malloc/malloc.h>
2417 #endif
2418 ]], [[
2419 struct mallinfo ac_x; ac_x = mallinfo ();
2420 ]])], [
2421     frr_cv_mallinfo=yes
2422   ], [
2423     frr_cv_mallinfo=no
2424   ])
2425 ])
2426 if test "$frr_cv_mallinfo" = "yes"; then
2427   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2428 fi
2429
2430 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2431   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2432 #ifdef HAVE_MALLOC_H
2433 #include <malloc.h>
2434 #endif
2435 #ifdef HAVE_MALLOC_NP_H
2436 #include <malloc_np.h>
2437 #endif
2438 #ifdef HAVE_MALLOC_MALLOC_H
2439 #include <malloc/malloc.h>
2440 #endif
2441 ]], [[
2442 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2443 ]])], [
2444     frr_cv_mallinfo2=yes
2445   ], [
2446     frr_cv_mallinfo2=no
2447   ])
2448 ])
2449 if test "$frr_cv_mallinfo2" = "yes"; then
2450   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2451 fi
2452
2453 AC_MSG_CHECKING([whether malloc_usable_size is available])
2454 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2455 #ifdef HAVE_MALLOC_H
2456 #include <malloc.h>
2457 #endif
2458 #ifdef HAVE_MALLOC_MALLOC_H
2459 #include <malloc/malloc.h>
2460 #endif
2461 ]], [[
2462 size_t ac_x; ac_x = malloc_usable_size(NULL);
2463 ]])], [
2464   AC_MSG_RESULT([yes])
2465   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2466 ], [
2467   AC_MSG_RESULT([no])
2468
2469   AC_MSG_CHECKING([whether malloc_size is available])
2470   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2471 #ifdef HAVE_MALLOC_H
2472 #include <malloc.h>
2473 #endif
2474 #ifdef HAVE_MALLOC_MALLOC_H
2475 #include <malloc/malloc.h>
2476 #endif
2477 ]], [[
2478 size_t ac_x; ac_x = malloc_size(NULL);
2479 ]])], [
2480     AC_MSG_RESULT([yes])
2481     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2482   ], [
2483     AC_MSG_RESULT([no])
2484   ])
2485 ])
2486
2487 dnl ----------
2488 dnl configure date
2489 dnl ----------
2490 dev_version=`echo $VERSION | grep dev`
2491 #don't expire deprecated code in non 'dev' branch
2492 if test "$dev_version" = ""; then
2493    CONFDATE=0
2494 else
2495    CONFDATE=`date '+%Y%m%d'`
2496 fi
2497 AC_SUBST([CONFDATE])
2498
2499 dnl ------------------------------
2500 dnl set paths for state directory
2501 dnl ------------------------------
2502 AC_MSG_CHECKING([directory to use for state file])
2503 if test "$prefix" = "NONE"; then
2504   frr_statedir_prefix="";
2505 else
2506   frr_statedir_prefix=${prefix}
2507 fi
2508 if test "$localstatedir" = '${prefix}/var'; then
2509   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2510                         ${frr_statedir_prefix}/var/adm dnl
2511                         ${frr_statedir_prefix}/etc dnl
2512                         /var/run        dnl
2513                         /var/adm        dnl
2514                         /etc            dnl
2515                         /dev/null;
2516   do
2517     test -d $FRR_STATE_DIR && break
2518   done
2519   frr_statedir=$FRR_STATE_DIR
2520 else
2521   frr_statedir=${localstatedir}
2522 fi
2523 if test "$frr_statedir" = "/dev/null"; then
2524     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2525 fi
2526 AC_MSG_RESULT([${frr_statedir}])
2527 AC_SUBST([frr_statedir])
2528
2529 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2530 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2531 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2532 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2533 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2534
2535 dnl autoconf does this, but it does it too late...
2536 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2537 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2538
2539 dnl get the full path, recursing through variables...
2540 vtysh_bin="$bindir/vtysh"
2541 for I in 1 2 3 4 5 6 7 8 9 10; do
2542         eval vtysh_bin="\"$vtysh_bin\""
2543 done
2544 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2545 AC_SUBST([vtysh_bin])
2546
2547 CFG_SYSCONF="$sysconfdir"
2548 CFG_SBIN="$sbindir"
2549 CFG_STATE="$frr_statedir"
2550 CFG_MODULE="$moduledir"
2551 CFG_YANGMODELS="$yangmodelsdir"
2552 CFG_SCRIPT="$scriptdir"
2553 for I in 1 2 3 4 5 6 7 8 9 10; do
2554         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2555         eval CFG_SBIN="\"$CFG_SBIN\""
2556         eval CFG_STATE="\"$CFG_STATE\""
2557         eval CFG_MODULE="\"$CFG_MODULE\""
2558         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2559         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2560 done
2561 AC_SUBST([CFG_SYSCONF])
2562 AC_SUBST([CFG_SBIN])
2563 AC_SUBST([CFG_STATE])
2564 AC_SUBST([CFG_MODULE])
2565 AC_SUBST([CFG_SCRIPT])
2566 AC_SUBST([CFG_YANGMODELS])
2567 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2568 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2569 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2570 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2571
2572 dnl various features
2573 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2574 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2575 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2576 dnl northbound
2577 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2578 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2579 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2580 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2581 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2582 dnl plugins
2583 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2584 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2585 AM_CONDITIONAL([IRDP], [$IRDP])
2586 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2587 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2588 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2589
2590 dnl PCEP plugin
2591 AS_IF([test "$enable_pathd" != "no"], [
2592        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2593        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2594        ])
2595 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2596 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2597 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2598 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2599
2600 dnl daemons
2601 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2602 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2603 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2604 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2605 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2606 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2607 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2608 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2609 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2610 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2611 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2612 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2613 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2614 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2615 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2616 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2617 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2618 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2619 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2620 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2621 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2622 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2623 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2624
2625 AC_CONFIG_FILES([Makefile],[
2626         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2627         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2628 ], [
2629         PYTHON="$PYTHON"
2630         enable_dev_build="$enable_dev_build"
2631 ])
2632
2633 AC_CONFIG_FILES([
2634           config.version
2635           redhat/frr.spec
2636           alpine/APKBUILD
2637           snapcraft/snapcraft.yaml
2638           lib/version.h
2639           tests/lib/cli/test_cli.refout
2640           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2641           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2642           pkgsrc/eigrpd.sh])
2643
2644 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2645 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2646 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2647 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2648 AC_CONFIG_FILES([tools/frrcommon.sh])
2649 AC_CONFIG_FILES([tools/frr.service])
2650 AC_CONFIG_FILES([tools/frr@.service])
2651
2652 AS_IF([test "$with_pkg_git_version" = "yes"], [
2653     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2654         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2655         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2656                 "${ac_abs_top_srcdir}" \
2657                 > "${dst}.tmp"
2658         test -f "$dst" \
2659                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2660                 && rm "${dst}.tmp" \
2661                 || mv "${dst}.tmp" "${dst}"
2662     ], [
2663         PERL="$PERL"
2664     ])
2665 ])
2666
2667 ## Hack, but working solution to avoid rebuilding of frr.info.
2668 ## It's already in CVS until texinfo 4.7 is more common.
2669 AC_OUTPUT
2670
2671 if test "$enable_rpath" = "yes" ; then
2672         true
2673 else
2674         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2675         sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
2676         sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
2677 fi
2678
2679 echo "
2680 FRRouting configuration
2681 ------------------------------
2682 FRR version             : ${PACKAGE_VERSION}
2683 host operating system   : ${host_os}
2684 source code location    : ${srcdir}
2685 compiler                : ${CC}
2686 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2687 make                    : ${MAKE-make}
2688 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2689 state file directory    : ${frr_statedir}
2690 config file directory   : `eval echo \`echo ${sysconfdir}\``
2691 module directory        : ${CFG_MODULE}
2692 script directory        : ${CFG_SCRIPT}
2693 user to run as          : ${enable_user}
2694 group to run as         : ${enable_group}
2695 group for vty sockets   : ${enable_vty_group}
2696 config file mask        : ${enable_configfile_mask}
2697 log file mask           : ${enable_logfile_mask}
2698 zebra protobuf enabled  : ${enable_protobuf:-no}
2699 vici socket path        : ${vici_socket}
2700
2701 The above user and group must have read/write access to the state file
2702 directory and to the config files in the config file directory."
2703
2704 if test -n "$enable_datacenter"; then
2705   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2706 fi
2707 if test -n "$enable_time_check"; then
2708   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2709 fi
2710 if test -n "$enable_cpu_time"; then
2711   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2712 fi
2713
2714 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2715   AC_MSG_WARN([sphinx is missing but required to build documentation])
2716 fi
2717 if test "$frr_py_mod_pytest" = "false"; then
2718   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2719 fi