configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [9.0-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if necessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183
 184 dnl Some special handling for ICC later on
 185 if test "$CC" = "icc"; then
 186     cc_is_icc="yes"
 187 fi
 188
 189 PKG_PROG_PKG_CONFIG
 190
 191 dnl it's 2019, sed is sed.
 192 SED=sed
 193 AC_SUBST([SED])
 194
 195 dnl try and enable CFLAGS that are useful for FRR
 196 dnl - specifically, options to control warnings
 197
 198 AC_SUBST([AC_CFLAGS])
 199 AC_USE_SYSTEM_EXTENSIONS
 200 AC_DEFUN([AC_C_FLAG], [{
 201     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 202     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 203         AC_LANG_PUSH([C])
 204         ac_c_flag_save="$CFLAGS"
 205         CFLAGS="$CFLAGS $1"
 206         AC_COMPILE_IFELSE(
 207                 [AC_LANG_PROGRAM([[$4]])],
 208                 [
 209                         cachename=yes
 210                 ], [
 211                         cachename=no
 212                 ])
 213         CFLAGS="$ac_c_flag_save"
 214         AC_LANG_POP([C])
 215     ])
 216     if test "$cachename" = "yes"; then
 217         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 218     else
 219         :
 220         $2
 221     fi
 222     m4_popdef([cachename])
 223 }])
 224
 225 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 226         AC_LANG_PUSH([C])
 227         ac_cflags_save="$CFLAGS"
 228         ac_libs_save="$LIBS"
 229         CFLAGS="$CFLAGS $1"
 230         LIBS="$LIBS $2"
 231         AC_LINK_IFELSE(
 232                 [$3],
 233                 [
 234                         CFLAGS="$ac_cflags_save"
 235                         LIBS="$ac_libs_save"
 236                         m4_default([$5], [
 237                                 AC_MSG_RESULT([yes])
 238                         ])
 239                 ], [
 240                         CFLAGS="$ac_cflags_save"
 241                         LIBS="$ac_libs_save"
 242                         m4_default([$4], [
 243                                 AC_MSG_RESULT([no])
 244                         ])
 245                 ])
 246         AC_LANG_POP([C])
 247         }])
 248
 249 dnl ICC won't bail on unknown options without -diag-error 10006
 250 dnl need to do this first so we get useful results for the other options
 251 if test "$cc_is_icc" = "yes"; then
 252     AC_C_FLAG([-diag-error 10006])
 253 fi
 254
 255 dnl autoconf 2.69 AC_PROG_CC_C99 is "state of the art"
 256 dnl autoconf 2.70 AC_PROG_CC_C99 is deprecated and AC_PROC_CC tries to do C11
 257 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
 258   dnl autoconf < 2.70
 259   AC_PROG_CC_C99
 260
 261   dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 262   ac_cc="$CC"
 263   CC="${CC% -std=gnu99}"
 264   CC="${CC% -std=c99}"
 265
 266   AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 267 ], [
 268   dnl autoconf >= 2.70
 269   if test "$ac_cv_prog_cc_c11" = "no"; then
 270     AC_MSG_ERROR([ISO C11 compiler support (with GNU extensions) is required.])
 271   fi
 272 ])
 273
 274 dnl if the user has specified any CFLAGS, override our settings
 275 if test "$enable_gcov" = "yes"; then
 276    if test "$orig_cflags" = ""; then
 277       AC_C_FLAG([--coverage])
 278       AC_C_FLAG([-O0])
 279    fi
 280
 281    AC_LDFLAGS="${AC_LDFLAGS} --coverage"
 282 fi
 283
 284 if test "$enable_clang_coverage" = "yes"; then
 285    AC_C_FLAG([-fprofile-instr-generate], [
 286      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 287    ])
 288    AC_C_FLAG([-fcoverage-mapping], [
 289      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 290    ])
 291 fi
 292
 293 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 294
 295 if test "$enable_scripting" = "yes"; then
 296    AX_PROG_LUA([5.3], [5.4], [], [
 297      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 298    ])
 299    AX_LUA_HEADERS([], [
 300      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 301    ])
 302    PKG_CHECK_MODULES([LUA], [lua5.3], [
 303      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 304      LIBS="$LIBS $LUA_LIBS"
 305      SCRIPTING=true
 306    ], [
 307       AX_LUA_LIBS([
 308         AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 309         LIBS="$LIBS $LUA_LIB"
 310         SCRIPTING=true
 311       ], [
 312         SCRIPTING=false
 313         AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 314       ])
 315     ])
 316 fi
 317
 318 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 319 dnl sense to be overridden by the user
 320 if test "$enable_dev_build" = "yes"; then
 321    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 322    if test "$orig_cflags" = ""; then
 323       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 324       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 325       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 326    fi
 327 else
 328    if test "$orig_cflags" = ""; then
 329       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 330       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 331    fi
 332 fi
 333
 334 dnl just stick -g into LDFLAGS, if we don't have it in CFLAGS it won't do much
 335 LDFLAGS="$LDFLAGS -g"
 336
 337 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 338
 339 dnl -fms-extensions causes clang to have a built-in __wchar_t on OpenBSD,
 340 dnl which just straight up breaks compiling any code.
 341 dnl (2022-04-04 / OpenBSD 7 / clang 11.1.0)
 342 AH_VERBATIM([OpenBSD], [
 343 #ifdef __OpenBSD__
 344 #define __wchar_t __wchar_t_ignore
 345 #include <stdint.h>
 346 #undef __wchar_t
 347 #endif
 348 ])
 349
 350 dnl always want these CFLAGS
 351 AC_C_FLAG([-fms-extensions], [
 352   AC_MSG_ERROR([$CC does not support unnamed struct fields (-fms-extensions)])
 353 ])
 354 AC_C_FLAG([-fno-omit-frame-pointer])
 355 AC_C_FLAG([-funwind-tables])
 356 AC_C_FLAG([-Wall])
 357 AC_C_FLAG([-Wextra])
 358 AC_C_FLAG([-Wformat-nonliteral])
 359 AC_C_FLAG([-Wformat-security])
 360 AC_C_FLAG([-Wswitch-enum])
 361 AC_C_FLAG([-Wstrict-prototypes])
 362 AC_C_FLAG([-Wmissing-prototypes])
 363 AC_C_FLAG([-Wmissing-declarations])
 364 AC_C_FLAG([-Wpointer-arith])
 365 AC_C_FLAG([-Wbad-function-cast])
 366 AC_C_FLAG([-Wwrite-strings])
 367 AC_C_FLAG([-Wundef])
 368 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 369   AC_C_FLAG([-Wcast-qual])
 370   AC_C_FLAG([-Wmissing-noreturn])
 371   AC_C_FLAG([-Wmissing-format-attribute])
 372   AC_C_FLAG([-Wunreachable-code])
 373   AC_C_FLAG([-Wpacked])
 374   AC_C_FLAG([-Wpadded])
 375   AC_C_FLAG([-Wshadow])
 376 else
 377   AC_C_FLAG([-Wno-unused-result])
 378 fi
 379 AC_C_FLAG([-Wno-unused-parameter])
 380 AC_C_FLAG([-Wno-missing-field-initializers])
 381
 382 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 383 AC_SUBST([CXX_COMPAT_CFLAGS])
 384
 385 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 386 dnl for some reason the string consts get 'promoted' to char *,
 387 dnl triggering a const to non-const conversion warning.
 388 if test "$cc_is_icc" = "yes"; then
 389     AC_C_FLAG([-diag-disable 3179])
 390 fi
 391
 392 if test "$enable_werror" = "yes" ; then
 393   WERROR="-Werror"
 394 fi
 395 AC_SUBST([WERROR])
 396
 397 SAN_FLAGS=""
 398 if test "$enable_address_sanitizer" = "yes"; then
 399   AC_C_FLAG([-fsanitize=address], [
 400     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 401   ], [
 402     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 403   ])
 404 fi
 405 if test "$enable_thread_sanitizer" = "yes"; then
 406   AC_C_FLAG([-fsanitize=thread], [
 407     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 408   ], [
 409     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 410   ])
 411 fi
 412 if test "$enable_memory_sanitizer" = "yes"; then
 413   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 414     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 415   ], [
 416     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 417   ])
 418 fi
 419 if test "$enable_undefined_sanitizer" = "yes"; then
 420   AC_C_FLAG([-fsanitize=undefined], [
 421     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 422   ], [
 423     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 424   ])
 425 fi
 426 AC_SUBST([SAN_FLAGS])
 427
 428 dnl frr-format.so
 429 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 430   AC_C_FLAG([-fplugin=${with_frr_format}], [
 431     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 432   ],,[
 433 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 434 #error plugin not loaded
 435 #endif
 436 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 437 #error plugin too old
 438 #endif
 439   ])
 440 elif test "$with_frr_format" = "no"; then
 441   : #nothing
 442 else
 443   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 444     AC_C_FLAG([-fplugin=frr-format],[
 445       if test "$with_frr_format" = "yes"; then
 446         AC_MSG_ERROR([frr-format plugin requested but not found])
 447       fi
 448     ],,[
 449 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 450 #error plugin not loaded
 451 #endif
 452 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 453 #error plugin too old
 454 #endif
 455     ])
 456   ],,[
 457 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 458 #error plugin not loaded
 459 #endif
 460 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 461 #error plugin too old
 462 #endif
 463   ])
 464 fi
 465
 466 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 467 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 468 #include <stdio.h>
 469 int __attribute__((section("secttest"))) var = 1;
 470 extern int __start_secttest, __stop_secttest;
 471 ]], [[
 472   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 473   printf("%p %p %p\n", a, b, c);
 474 ]])], [
 475   AC_MSG_RESULT(yes)
 476   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 477 ], [
 478   AC_MSG_RESULT(no)
 479 ])
 480
 481 dnl ----------
 482 dnl Essentials
 483 dnl ----------
 484
 485 AX_PTHREAD([
 486   CC="$PTHREAD_CC"
 487   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 488   LIBS="$PTHREAD_LIBS $LIBS"
 489 ], [
 490   AC_MSG_FAILURE([This FRR version needs pthreads])
 491 ])
 492
 493 orig_cflags="$CFLAGS"
 494 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 495
 496 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 497                 [frr_cv_pthread_condattr_setclock=yes],
 498                 [frr_cv_pthread_condattr_setclock=no])
 499 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 500   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 501 fi
 502
 503 AC_CHECK_HEADERS([pthread_np.h],,, [
 504 #include <pthread.h>
 505 ])
 506 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 507
 508 CFLAGS="$orig_cflags"
 509
 510 dnl --------------
 511 dnl Check programs
 512 dnl --------------
 513 AC_PROG_INSTALL
 514 AC_PROG_LN_S
 515 AC_CHECK_TOOL([AR], [ar])
 516
 517 dnl -------
 518 dnl libtool
 519 dnl -------
 520 AC_ARG_ENABLE([static-bin],
 521   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 522 LT_INIT
 523 _LT_CONFIG_LIBTOOL([
 524   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 525     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 526 dnl the -i option is not POSIX sed and the BSDs implement it differently
 527 dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact
 528   sed -e 's%func_warning "relinking%true #\0%'                   libtool > libtool.sed && cat libtool.sed > libtool
 529   sed -e 's%func_warning "remember to run%true #\0%'             libtool > libtool.sed && cat libtool.sed > libtool
 530   sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool
 531   test -f libtool.sed && rm libtool.sed
 532 ])
 533 if test "$enable_static_bin" = "yes"; then
 534   AC_LDFLAGS_EXEC="-static"
 535   if test "$enable_static" != "yes"; then
 536     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 537   fi
 538 fi
 539 if test "$enable_shared" != "yes"; then
 540   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 541 fi
 542 AC_SUBST([AC_LDFLAGS])
 543 AC_SUBST([AC_LDFLAGS_EXEC])
 544 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 545
 546 dnl libtool, the repository of all knowledge related linkers, is too stupid to
 547 dnl correctly tell the linker how to build modules.
 548 if test -z "$module_cmds"; then
 549   module_cmds="`echo \"$archive_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 550 fi
 551 if test -z "$module_expsym_cmds"; then
 552   module_expsym_cmds="`echo \"$archive_expsym_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 553 fi
 554
 555 AC_ARG_ENABLE([rpath],
 556   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 557   [],
 558   [enable_rpath=yes])
 559
 560 dnl $AR and $RANLIB are set by LT_INIT above
 561 AC_MSG_CHECKING([whether $AR supports D option])
 562 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 563   AC_MSG_RESULT([yes])
 564   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 565   ARFLAGS="crD"
 566   AR_FLAGS="crD"
 567 else
 568   AC_MSG_RESULT([no])
 569   ARFLAGS="cru"
 570   AR_FLAGS="cru"
 571 fi
 572 AC_SUBST([ARFLAGS])
 573 AC_SUBST([AR_FLAGS])
 574
 575 AC_MSG_CHECKING([whether $RANLIB supports D option])
 576 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 577   if grep -q -- '-D' conftest.err; then
 578     AC_MSG_RESULT([no])
 579   else
 580     AC_MSG_RESULT([yes])
 581     RANLIB="$RANLIB -D"
 582   fi
 583 else
 584   AC_MSG_RESULT([no])
 585 fi
 586 AC_SUBST([RANLIB])
 587
 588 test -f conftest.err && rm conftest.err
 589 test -f conftest.a && rm conftest.a
 590
 591 dnl ----------------------
 592 dnl Packages configuration
 593 dnl ----------------------
 594 if test -f config.version; then
 595   . ./config.version
 596 elif test -f "${srcdir}/config.version"; then
 597   . "${srcdir}/config.version"
 598 fi
 599 AC_ARG_WITH([pkg-extra-version],
 600   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 601   if test "$withval" = "no"; then
 602     EXTRAVERSION=
 603   else
 604     EXTRAVERSION=$withval
 605   fi
 606 ], [])
 607 AC_ARG_WITH([pkg-git-version],
 608         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 609         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 610 AC_ARG_WITH([clippy],
 611   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 612 AC_ARG_WITH([vtysh_pager],
 613         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 614         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 615 AC_ARG_ENABLE([vtysh],
 616   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 617 AC_ARG_ENABLE([doc],
 618   AS_HELP_STRING([--disable-doc], [do not build docs]))
 619 AC_ARG_ENABLE([doc-html],
 620   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 621 AC_ARG_ENABLE([zebra],
 622   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 623 AC_ARG_ENABLE([bgpd],
 624   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 625 AC_ARG_ENABLE([mgmtd],
 626   AS_HELP_STRING([--disable-mgmtd], [do not build mgmtd]))
 627 AC_ARG_ENABLE([mgmtd_local_validations],
 628   AS_HELP_STRING([--enable-mgmtd-local-validations], [dev: unimplemented local validation]))
 629 AC_ARG_ENABLE([ripd],
 630   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 631 AC_ARG_ENABLE([ripngd],
 632   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 633 AC_ARG_ENABLE([ospfd],
 634   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 635 AC_ARG_ENABLE([ospf6d],
 636   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 637 AC_ARG_ENABLE([ldpd],
 638   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 639 AC_ARG_ENABLE([nhrpd],
 640   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 641 AC_ARG_ENABLE([eigrpd],
 642   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 643 AC_ARG_ENABLE([babeld],
 644   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 645 AC_ARG_ENABLE([watchfrr],
 646   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 647 AC_ARG_ENABLE([isisd],
 648   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 649 AC_ARG_ENABLE([pimd],
 650   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 651 AC_ARG_ENABLE([pim6d],
 652   AS_HELP_STRING([--disable-pim6d], [do not build pim6d]))
 653 AC_ARG_ENABLE([pbrd],
 654   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 655 AC_ARG_ENABLE([sharpd],
 656   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 657 AC_ARG_ENABLE([staticd],
 658   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 659 AC_ARG_ENABLE([fabricd],
 660   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 661 AC_ARG_ENABLE([vrrpd],
 662   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 663 AC_ARG_ENABLE([pathd],
 664   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 665 AC_ARG_ENABLE([bgp-announce],
 666   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 667 AC_ARG_ENABLE([bgp-vnc],
 668   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 669 AC_ARG_ENABLE([bgp-bmp],
 670   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 671 AC_ARG_ENABLE([snmp],
 672   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 673 AC_ARG_ENABLE([config_rollbacks],
 674   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 675 AC_ARG_ENABLE([confd],
 676   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 677 AC_ARG_ENABLE([sysrepo],
 678   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 679 AC_ARG_ENABLE([grpc],
 680   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 681 AC_ARG_ENABLE([zeromq],
 682   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 683 AC_ARG_ENABLE([lttng],
 684   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 685 AC_ARG_ENABLE([usdt],
 686   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 687 AC_ARG_WITH([libpam],
 688   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 689 AC_ARG_ENABLE([ospfapi],
 690   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 691 AC_ARG_ENABLE([ospfclient],
 692   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 693                           (this is the default if --disable-ospfapi is set)]))
 694 AC_ARG_WITH([log_timestamp_precision],
 695   AS_HELP_STRING([--with-log-timestamp-precision=ARG], [set startup log timestamp precision, ARG must be 0-12]))
 696 AC_ARG_ENABLE([multipath],
 697   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 698 AC_ARG_WITH([service_timeout],
 699   AS_HELP_STRING([--with-service-timeout=ARG], [set service timeout value (2 minutes by default), ARG must be digit]))
 700 AC_ARG_ENABLE([user],
 701   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 702 AC_ARG_ENABLE([group],
 703   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 704 AC_ARG_ENABLE([vty_group],
 705   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 706 AC_ARG_ENABLE([configfile_mask],
 707   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 708 AC_ARG_ENABLE([logfile_mask],
 709   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 710 AC_ARG_ENABLE([shell_access],
 711   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 712 AC_ARG_ENABLE([realms],
 713   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 714 AC_ARG_ENABLE([rtadv],
 715   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 716 AC_ARG_ENABLE([irdp],
 717   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 718 AC_ARG_ENABLE([capabilities],
 719   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 720 AC_ARG_ENABLE([gcc_ultra_verbose],
 721   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 722 AC_ARG_ENABLE([backtrace],
 723   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 724 AC_ARG_ENABLE([time-check],
 725   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 726 AC_ARG_ENABLE([cpu-time],
 727   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 728 AC_ARG_ENABLE([pcreposix],
 729   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 730 AC_ARG_ENABLE([pcre2posix],
 731   AS_HELP_STRING([--enable-pcre2posix], [enable using PCRE2 Posix libs for regex functions]))
 732 AC_ARG_ENABLE([fpm],
 733   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 734 AC_ARG_ENABLE([werror],
 735   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 736 AC_ARG_ENABLE([cumulus],
 737   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 738 AC_ARG_ENABLE([datacenter],
 739   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 740 AC_ARG_ENABLE([rr-semantics],
 741   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 742 AC_ARG_ENABLE([protobuf],
 743   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 744 AC_ARG_ENABLE([oldvpn_commands],
 745   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 746 AC_ARG_ENABLE([rpki],
 747   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 748 AC_ARG_ENABLE([clippy-only],
 749   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 750 AC_ARG_ENABLE([numeric_version],
 751   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 752 AC_ARG_ENABLE([gcov],
 753   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 754 AC_ARG_ENABLE([clang_coverage],
 755   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 756 AC_ARG_ENABLE([bfdd],
 757   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 758 AC_ARG_ENABLE([address-sanitizer],
 759   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 760 AC_ARG_ENABLE([thread-sanitizer],
 761   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 762 AC_ARG_ENABLE([memory-sanitizer],
 763   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 764 AC_ARG_ENABLE([undefined-sanitizer],
 765   AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 766 AC_ARG_WITH([crypto],
 767   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 768 AC_ARG_WITH([frr-format],
 769   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 770
 771 AC_ARG_ENABLE([version-build-config],
 772   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 773
 774 #if openssl, else use the internal
 775 AS_IF([test "$with_crypto" = "openssl"], [
 776 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 777 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 778   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 779 else
 780   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 781 fi
 782 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 783 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 784 )
 785
 786 AS_IF([test "$enable_clippy_only" != "yes"], [
 787 AC_CHECK_HEADERS([json-c/json.h])
 788 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 789 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 790   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 791   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 792       AC_MSG_ERROR([libjson is needed to compile])
 793   fi
 794 fi
 795 ])
 796
 797 AC_ARG_ENABLE([dev_build],
 798     AS_HELP_STRING([--enable-dev-build], [build for development]))
 799
 800 AC_ARG_ENABLE([scripting],
 801     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 802
 803 AC_ARG_ENABLE([netlink-debug],
 804   AS_HELP_STRING([--disable-netlink-debug], [don't pretty print netlink debug messages]))
 805
 806 if test "$enable_netlink_debug" != "no" ; then
 807   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 808 fi
 809
 810 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 811
 812 if test "$enable_time_check" != "no" ; then
 813   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 814     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 815   else
 816     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 817   fi
 818 fi
 819
 820 case "${enable_cpu_time}" in
 821   "no")
 822   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 823   ;;
 824   "*")
 825   ;;
 826 esac
 827
 828 if test "$enable_rr_semantics" != "no" ; then
 829   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 830 fi
 831
 832 if test "$enable_datacenter" = "yes" ; then
 833   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 834   DFLT_NAME="datacenter"
 835 else
 836   DFLT_NAME="traditional"
 837 fi
 838
 839 if test "$enable_cumulus" = "yes" ; then
 840   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 841 fi
 842
 843 AC_SUBST([DFLT_NAME])
 844 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 845
 846 if test "$enable_shell_access" = "yes"; then
 847    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 848 fi
 849
 850 #
 851 # Python for clippy
 852 #
 853
 854 AS_IF([test "$host" = "$build"], [
 855   AM_PATH_PYTHON([3])
 856   AC_CHECK_HEADER([gelf.h], [], [
 857     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 858   ])
 859
 860   LIBS_save="$LIBS"
 861   AC_CHECK_LIB([elf], [elf_memory], [], [
 862     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 863   ])
 864
 865   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 866     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 867   ])
 868   AC_CHECK_LIB([elf], [gelf_getnote], [
 869     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 870   ])
 871   LIBS="$LIBS_save"
 872   unset LIBS_save
 873
 874   FRR_PYTHON_DEV
 875 ], [
 876   FRR_PYTHON
 877 ])
 878
 879 FRR_PYTHON_MODULES([pytest])
 880
 881 if test "$enable_doc" != "no"; then
 882   FRR_PYTHON_MODULES([sphinx], , [
 883     if test "$enable_doc" = "yes"; then
 884       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 885     fi
 886   ])
 887 fi
 888 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 889 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 890
 891 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 892   PYSPHINX="-m sphinx"
 893 ], [
 894   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 895 ])
 896 AC_SUBST([PYSPHINX])
 897
 898 #
 899 # Logic for old vpn commands support.
 900 #
 901 if test "$enable_oldvpn_commands" = "yes"; then
 902    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 903 fi
 904
 905 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 906 if test "$enable_rtadv" != "no"; then
 907   AC_MSG_RESULT([yes])
 908   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 909 else
 910   AC_MSG_RESULT([no])
 911 fi
 912
 913 if test "$enable_user" = "no"; then
 914   enable_user=""
 915 else
 916   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 917     enable_user="frr"
 918   fi
 919   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 920 fi
 921
 922 if test "$enable_group" = "no"; then
 923   enable_group=""
 924 else
 925   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 926     enable_group="frr"
 927   fi
 928   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 929 fi
 930
 931 if test "$enable_vty_group" = "yes" ; then
 932   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 933 elif test "$enable_vty_group" != ""; then
 934   if test "$enable_vty_group" != "no"; then
 935     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 936   fi
 937 fi
 938 AC_SUBST([enable_user])
 939 AC_SUBST([enable_group])
 940 AC_SUBST([enable_vty_group])
 941
 942 enable_configfile_mask=${enable_configfile_mask:-0600}
 943 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 944 AC_SUBST([enable_configfile_mask])
 945
 946 enable_logfile_mask=${enable_logfile_mask:-0600}
 947 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 948
 949 MPATH_NUM=16
 950
 951 case "${enable_multipath}" in
 952   0)
 953     MPATH_NUM=64
 954     ;;
 955   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 956     MPATH_NUM="${enable_multipath}"
 957     ;;
 958   "")
 959     ;;
 960   *)
 961     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 962     ;;
 963 esac
 964
 965 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 966
 967 case "${with_log_timestamp_precision}" in
 968 [[0-9]|1[012]])
 969 ;;
 970 "")
 971 ;;
 972 *)
 973 AC_MSG_FAILURE([Please specify a number from 0-12 for log precision ARG])
 974 ;;
 975 esac
 976 with_log_timestamp_precision=${with_log_timestamp_precision:-0}
 977 AC_DEFINE_UNQUOTED([LOG_TIMESTAMP_PRECISION], [${with_log_timestamp_precision}], [Startup zlog timestamp precision])
 978
 979 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 980
 981 TIMEOUT_MIN=2
 982 case "${with_service_timeout}" in
 983   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 984     TIMEOUT_MIN="${with_service_timeout}"
 985     ;;
 986   0|"")
 987     ;;
 988   *)
 989     AC_MSG_FAILURE([Please specify digit for timeout ARG])
 990     ;;
 991 esac
 992 AC_SUBST([TIMEOUT_MIN])
 993
 994 dnl --------------------
 995 dnl Enable code coverage
 996 dnl --------------------
 997 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 998
 999 dnl ------------------------------------
1000 dnl Alpine only accepts numeric versions
1001 dnl ------------------------------------
1002 if test "$enable_numeric_version" != "" ; then
1003   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
1004   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
1005 fi
1006
1007 dnl -----------------------------------
1008 dnl Add extra version string to package
1009 dnl name, string and version fields.
1010 dnl -----------------------------------
1011 if test "$EXTRAVERSION" != "" ; then
1012   VERSION="${VERSION}${EXTRAVERSION}"
1013   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
1014   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
1015   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
1016 fi
1017 AC_SUBST([EXTRAVERSION])
1018
1019 if test "$with_pkg_git_version" = "yes"; then
1020         if test -e "${srcdir}/.git"; then
1021                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
1022         else    with_pkg_git_version="no"
1023                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
1024         fi
1025 fi
1026 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
1027
1028 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
1029 if test "$OBJCOPY" != ":"; then
1030   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
1031     frr_cv_interp=""
1032     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
1033       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
1034         frr_cv_interp="`xargs -0 echo < conftest.interp`"
1035       fi
1036       test -f conftest.interp && rm conftest.interp
1037     ])
1038   ])
1039 fi
1040 if test -n "$frr_cv_interp"; then
1041   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
1042 fi
1043
1044 dnl -------------------------
1045 dnl Check other header files.
1046 dnl -------------------------
1047 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
1048         linux/version.h asm/types.h endian.h sys/endian.h])
1049
1050 ac_stdatomic_ok=false
1051 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
1052 AC_CHECK_HEADER([stdatomic.h],[
1053
1054   AC_MSG_CHECKING([whether _Atomic qualifier works])
1055   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1056 #include <stdatomic.h>
1057 int main(int argc, char **argv) {
1058   _Atomic int i = 0;
1059   return i;
1060 }
1061 ]])], [
1062     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
1063     AC_MSG_RESULT([yes])
1064     ac_stdatomic_ok=true
1065   ], [
1066     AC_MSG_RESULT([no])
1067   ])
1068 ])
1069
1070 AS_IF([$ac_stdatomic_ok], [true], [
1071   AC_MSG_CHECKING([for __atomic_* builtins])
1072   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1073 int main(int argc, char **argv) {
1074   volatile int i = 1;
1075   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1076   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1077 }
1078 ]])], [
1079     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1080     AC_MSG_RESULT([yes])
1081   ], [
1082     AC_MSG_RESULT([no])
1083
1084     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1085     AC_MSG_CHECKING([for __sync_* builtins])
1086     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1087 int main(int argc, char **argv) {
1088   volatile int i = 1;
1089   __sync_fetch_and_sub (&i, 1);
1090   return __sync_val_compare_and_swap (&i, 0, 1);
1091 }
1092 ]])], [
1093       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1094       AC_MSG_RESULT([yes])
1095
1096       AC_MSG_CHECKING([for __sync_swap builtin])
1097       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1098 int main(int argc, char **argv) {
1099   volatile int i = 1;
1100   return __sync_swap (&i, 2);
1101 }
1102 ]])], [
1103         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1104         AC_MSG_RESULT([yes])
1105       ], [
1106         AC_MSG_RESULT([no])
1107       ])
1108
1109     ], [
1110       AC_MSG_RESULT([no])
1111       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1112     ])
1113   ])
1114 ])
1115
1116 needsync=true
1117
1118 AS_IF([$needsync], [
1119   dnl Linux
1120   AC_MSG_CHECKING([for Linux futex() support])
1121   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1122 #ifndef _GNU_SOURCE
1123 #define _GNU_SOURCE
1124 #endif
1125 #include <unistd.h>
1126 #include <limits.h>
1127 #include <sys/time.h>
1128 #include <sys/syscall.h>
1129 #include <linux/futex.h>
1130
1131 int main(void);
1132 ],
1133 [
1134 {
1135   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1136 }
1137 ])], [
1138     AC_MSG_RESULT([yes])
1139     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1140     needsync=false
1141   ], [
1142     AC_MSG_RESULT([no])
1143   ])
1144 ])
1145
1146 AS_IF([$needsync], [
1147   dnl FreeBSD
1148   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1149   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1150 #include <errno.h>
1151 #include <stdlib.h>
1152 #include <sys/types.h>
1153 #include <sys/umtx.h>
1154 int main(void);
1155 ],
1156 [
1157 {
1158   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1159 }
1160 ])], [
1161     AC_MSG_RESULT([yes])
1162     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1163     needsync=false
1164   ], [
1165     AC_MSG_RESULT([no])
1166   ])
1167 ])
1168
1169 AS_IF([$needsync], [
1170   dnl OpenBSD patch (not upstream at the time of writing this)
1171   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1172   AC_MSG_CHECKING([for OpenBSD futex() support])
1173   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1174 #include <sys/futex.h>
1175 int main(void);
1176 ],
1177 [
1178 {
1179   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1180 }
1181 ])], [
1182     AC_MSG_RESULT([yes])
1183     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1184     needsync=false
1185   ], [
1186     AC_MSG_RESULT([no])
1187   ])
1188 ])
1189
1190 dnl Utility macro to avoid retyping includes all the time
1191 m4_define([FRR_INCLUDES],
1192 [#ifdef SUNOS_5
1193 #define _POSIX_C_SOURCE 200809L
1194 #define __EXTENSIONS__
1195 #endif
1196 #include <stdio.h>
1197 #include <stdlib.h>
1198 #include <stddef.h>
1199 #include <sys/types.h>
1200 /* sys/conf.h depends on param.h on FBSD at least */
1201 #include <sys/param.h>
1202 /* Required for MAXSIG */
1203 #include <signal.h>
1204 #include <sys/socket.h>
1205 #ifdef __APPLE__
1206 # define __APPLE_USE_RFC_3542
1207 #endif
1208 #include <netinet/in.h>
1209 #include <sys/time.h>
1210 #include <time.h>
1211 #include <net/if.h>
1212 ])dnl
1213
1214 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1215 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1216 dnl an additional round for it.
1217
1218 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1219
1220 m4_define([FRR_INCLUDES],
1221 FRR_INCLUDES
1222 [#ifdef HAVE_NET_IF_VAR_H
1223 # include <net/if_var.h>
1224 #endif
1225 ])dnl
1226
1227 AC_CHECK_HEADERS([netinet/in_var.h \
1228         net/if_dl.h net/netopt.h \
1229         inet/nd.h netinet/ip_icmp.h \
1230         sys/sysctl.h sys/sockio.h sys/conf.h],
1231         [], [], [FRR_INCLUDES])
1232
1233 AC_CHECK_HEADERS([ucontext.h], [], [],
1234 [#ifndef __USE_GNU
1235 #define __USE_GNU
1236 #endif /* __USE_GNU */
1237 FRR_INCLUDES
1238 ])
1239
1240 m4_define([UCONTEXT_INCLUDES],
1241 [#include <ucontext.h>])dnl
1242
1243 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1244   [], [], [UCONTEXT_INCLUDES])
1245 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1246   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1247    [], [], [UCONTEXT_INCLUDES])],
1248   [], [UCONTEXT_INCLUDES])
1249 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1250   [], [], [UCONTEXT_INCLUDES])
1251
1252 m4_define([FRR_INCLUDES],
1253 FRR_INCLUDES
1254 [
1255 #include <sys/un.h>
1256 #include <netinet/in_systm.h>
1257 #ifdef HAVE_NETINET_IN_VAR_H
1258 # include <netinet/in_var.h>
1259 #endif
1260 #ifdef HAVE_NET_IF_DL_H
1261 # include <net/if_dl.h>
1262 #endif
1263 #ifdef HAVE_NET_NETOPT_H
1264 # include <net/netopt.h>
1265 #endif
1266 #include <net/route.h>
1267 #ifdef HAVE_INET_ND_H
1268 # include <inet/nd.h>
1269 #endif
1270 #include <arpa/inet.h>
1271 /* Required for IDRP */
1272 #ifdef HAVE_NETINET_IP_ICMP_H
1273 # include <netinet/ip_icmp.h>
1274 #endif
1275 ])dnl
1276
1277 dnl V6 headers are checked below, after we check for v6
1278
1279 is_linux=false
1280
1281 AC_MSG_CHECKING([which operating system interface to use])
1282 case "$host_os" in
1283   sunos* | solaris2*)
1284     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1285     ;;
1286   linux*)
1287     AC_MSG_RESULT([Linux])
1288
1289     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1290     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1291     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1292
1293     dnl Linux has a compilation problem with mixing
1294     dnl netinet/in.h and linux/in6.h they are not
1295     dnl compatible.  There has been discussion on
1296     dnl how to fix it but no real progress on implementation
1297     dnl when they fix it, remove this
1298     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1299
1300     is_linux=true
1301     ;;
1302   openbsd*)
1303     AC_MSG_RESULT([OpenBSD])
1304
1305     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1306     AC_DEFINE([KAME], [1], [KAME IPv6])
1307     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1308     ;;
1309   *)
1310     AC_MSG_RESULT([BSD])
1311
1312     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1313     AC_DEFINE([KAME], [1], [KAME IPv6])
1314     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1315     ;;
1316 esac
1317 AM_CONDITIONAL([LINUX], [${is_linux}])
1318
1319 AC_SYS_LARGEFILE
1320
1321 dnl ------------------------
1322 dnl Integrated REALMS option
1323 dnl ------------------------
1324 if test "$enable_realms" = "yes"; then
1325     case "$host_os" in
1326       linux*)
1327        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1328        ;;
1329       *)
1330        echo "Sorry, only Linux has REALMS support"
1331        exit 1
1332        ;;
1333     esac
1334 fi
1335
1336 dnl ---------------
1337 dnl other functions
1338 dnl ---------------
1339 AC_CHECK_FUNCS([ \
1340         strlcat strlcpy \
1341         getgrouplist \
1342         openat \
1343         unlinkat \
1344         posix_fallocate \
1345         sendmmsg \
1346         explicit_bzero \
1347         ])
1348
1349 AC_CHECK_MEMBERS([struct mmsghdr.msg_hdr], [], [], FRR_INCLUDES)
1350
1351 dnl ##########################################################################
1352 dnl LARGE if block spans a lot of "configure"!
1353 if test "$enable_clippy_only" != "yes"; then
1354 dnl ##########################################################################
1355
1356 #
1357 # Logic for protobuf support.
1358 #
1359 PROTO3=false
1360 # Enable Protobuf by default at all times.
1361 # Check for protoc & protoc-c
1362 # protoc is not required, it's only for a "be nice" helper target
1363 AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1364
1365 AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1366 if test "$PROTOC_C" = "/bin/false"; then
1367   AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1368 fi
1369
1370 PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 1.1.0],, [
1371   AC_MSG_FAILURE([minimum version (1.1.0) of libprotobuf-c not found.  Install minimum required version of protobuf-c.])
1372 ])
1373
1374 if test "$enable_protobuf3" = "yes"; then
1375   PROTO3=true
1376   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1377                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1378                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1379                                             [1], [Have Protobuf version 3]),
1380                                   [PROTO3=false],
1381                                   [#include <google/protobuf-c/protobuf-c.h>])],
1382                   [PROTO3=false && AC_MSG_FAILURE([protobuf3 requested but protobuf-c.h not found.  Install protobuf-c.])])
1383 fi
1384
1385 AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1386 #
1387 # End of logic for protobuf support.
1388 #
1389
1390
1391 dnl ---------------------
1392 dnl Integrated VTY option
1393 dnl ---------------------
1394 case "${enable_vtysh}" in
1395 "no")
1396   VTYSH="";;
1397 *)
1398   VTYSH="vtysh";
1399   AC_DEFINE([VTYSH], [1], [VTY shell])
1400
1401   prev_libs="$LIBS"
1402   AC_CHECK_LIB([readline], [readline], [
1403     LIBREADLINE="-lreadline"
1404   ], [
1405     dnl readline failed - it might be incorrectly linked and missing its
1406     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1407     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1408       LIBREADLINE="$ac_cv_search_tputs"
1409     ], [
1410       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1411     ])
1412
1413     dnl re-try with the lib we found above
1414     unset ac_cv_lib_readline_main
1415     AC_CHECK_LIB([readline], [main], [
1416       LIBREADLINE="-lreadline $LIBREADLINE"
1417     ], [
1418       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1419     ], [$LIBREADLINE])
1420   ], [])
1421   LIBS="$LIBS -lreadline"
1422   AC_CHECK_FUNCS([rl_clear_visible_line])
1423   LIBS="$prev_libs"
1424
1425   AC_CHECK_HEADER([readline/history.h])
1426   if test "$ac_cv_header_readline_history_h" = "no"; then
1427     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1428   fi
1429   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1430   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1431     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1432   fi
1433   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1434   if test "$frr_cv_append_history" = "yes"; then
1435     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1436   fi
1437   ;;
1438 esac
1439 AC_SUBST([LIBREADLINE])
1440
1441 dnl ----------
1442 dnl PAM module
1443 dnl
1444 dnl FRR detects the PAM library it is built against by checking for a
1445 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1446 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1447 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1448 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1449 dnl of OpenPAM.
1450 dnl ----------
1451 if test "$with_libpam" = "yes"; then
1452   AC_CHECK_HEADER([security/pam_misc.h],
1453     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1454      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1455      pam_conv_func="misc_conv"
1456     ],
1457     [], FRR_INCLUDES)
1458   AC_CHECK_HEADER([security/openpam.h],
1459     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1460      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1461      pam_conv_func="openpam_ttyconv"
1462     ],
1463     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1464   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1465     AC_MSG_WARN([*** pam support will not be built ***])
1466     with_libpam="no"
1467   fi
1468 fi
1469
1470 if test "$with_libpam" = "yes"; then
1471 dnl took this test from proftpds configure.in and suited to our needs
1472 dnl -------------------------------------------------------------------------
1473 dnl
1474 dnl This next check looks funky due to a linker problem with some versions
1475 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1476 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1477 dnl with RedHat 6.2 and Debian 2.2 or better.
1478 AC_CHECK_LIB([pam], [pam_start],
1479   [AC_CHECK_LIB([pam], [$pam_conv_func],
1480     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1481      LIBPAM="-lpam"],
1482     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1483      LIBPAM="-lpam -lpam_misc"]
1484     )
1485   ],
1486
1487   [AC_CHECK_LIB([pam], [pam_end],
1488     [AC_CHECK_LIB([pam], [$pam_conv_func],
1489       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1490        LIBPAM="-lpam -ldl"],
1491       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1492        LIBPAM="-lpam -ldl -lpam_misc"]
1493      )
1494   ],AC_MSG_WARN([*** pam support will not be built ***]),
1495   [-ldl])
1496   ]
1497 )
1498 fi
1499 AC_SUBST([LIBPAM])
1500
1501 dnl -------------------------------
1502 dnl bgpd needs pow() and hence libm
1503 dnl -------------------------------
1504 TMPLIBS="$LIBS"
1505 LIBS=""
1506 AC_SEARCH_LIBS([pow], [m], [
1507   LIBM="$LIBS"
1508 ], [
1509   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1510 ])
1511 LIBS="$TMPLIBS"
1512 AC_SUBST([LIBM])
1513
1514 AC_CHECK_FUNCS([ppoll], [
1515   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1516 ])
1517 AC_CHECK_FUNCS([pollts], [
1518   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1519 ])
1520
1521 AC_CHECK_HEADER([asm-generic/unistd.h],
1522                 [AC_CHECK_DECL(__NR_setns,
1523                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1524                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1525                                ])
1526                  AC_CHECK_FUNCS([setns])]
1527                )
1528
1529 dnl --------------------------
1530 dnl Determine IS-IS I/O method
1531 dnl --------------------------
1532 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1533 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1534 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1535 AC_CHECK_HEADER([net/bpf.h])
1536 AC_CHECK_HEADER([sys/dlpi.h])
1537 AC_MSG_CHECKING([zebra IS-IS I/O method])
1538
1539 case "$host_os" in
1540   linux*)
1541     AC_MSG_RESULT([pfpacket])
1542     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1543     ;;
1544   *)
1545     if test "$ac_cv_header_net_bpf_h" = "no"; then
1546       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1547         AC_MSG_RESULT([none])
1548         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1549           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1550         fi
1551         AC_MSG_WARN([*** IS-IS support will not be built ***])
1552         enable_isisd="no"
1553         enable_fabricd="no"
1554       else
1555         AC_MSG_RESULT([DLPI])
1556       fi
1557       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1558     else
1559       AC_MSG_RESULT([BPF])
1560       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1561     fi
1562     ;;
1563 esac
1564 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1565
1566 dnl ---------------------------------------------------------------
1567 dnl figure out how to specify an interface in multicast sockets API
1568 dnl ---------------------------------------------------------------
1569 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1570
1571 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1572         #include <sys/socket.h>
1573         #include <netinet/in.h>
1574         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1575         #include <linux/types.h>
1576 ])
1577
1578 AC_CHECK_HEADERS([linux/mroute6.h], [], [],[
1579         #include <sys/socket.h>
1580         #include <netinet/in.h>
1581         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1582         #include <linux/types.h>
1583 ])
1584
1585 m4_define([FRR_INCLUDES],
1586 FRR_INCLUDES
1587 [#ifdef HAVE_LINUX_MROUTE_H
1588 # include <linux/mroute.h>
1589 #endif
1590 ])dnl
1591
1592 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1593         #include <sys/socket.h>
1594         #include <sys/types.h>
1595         #include <netinet/in.h>
1596         #include <net/route.h>
1597 ])
1598
1599 m4_define([FRR_INCLUDES],
1600 FRR_INCLUDES
1601 [#ifdef HAVE_NETINET_IP_MROUTE_H
1602 # include <netinet/ip_mroute.h>
1603 #endif
1604 ])dnl
1605
1606 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1607 AC_COMPILE_IFELSE(
1608 [ AC_LANG_PROGRAM([[
1609       #include <sys/types.h>
1610       #include <netinet/in.h>
1611   ]], [[
1612       struct group_req gr;
1613       int sock;
1614       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1615   ]])
1616 ],[
1617   AC_MSG_RESULT([yes])
1618   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1619 ],[
1620   AC_MSG_RESULT(no)
1621 ])
1622
1623 dnl ---------------------------------------------------------------
1624 dnl figure out how to check link-state
1625 dnl ---------------------------------------------------------------
1626 AC_CHECK_HEADER([net/if_media.h],
1627   [m4_define([LINK_DETECT_INCLUDES],
1628     FRR_INCLUDES
1629     [#include <net/if_media.h>
1630   ])
1631   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1632     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1633     [], LINK_DETECT_INCLUDES)],
1634   [],
1635   FRR_INCLUDES)
1636
1637 dnl ---------------------------------------------------------------
1638 dnl Additional, newer way to check link-state using ifi_link_state.
1639 dnl Not available in all BSD's when ifmediareq available
1640 dnl ---------------------------------------------------------------
1641 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1642   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1643   [], FRR_INCLUDES)
1644
1645 dnl ------------------------
1646 dnl TCP_MD5SIG socket option
1647 dnl ------------------------
1648
1649 AC_CHECK_HEADER([netinet/tcp.h],
1650    [m4_define([MD5_INCLUDES],
1651       FRR_INCLUDES
1652       [#include <netinet/tcp.h>
1653     ])
1654     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1655    [],
1656    FRR_INCLUDES)
1657 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1658   AC_CHECK_HEADER([linux/tcp.h],
1659        [m4_define([MD5_INCLUDES],
1660           FRR_INCLUDES
1661           [#include <linux/tcp.h>
1662         ])
1663        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1664 fi
1665
1666 LIBS_save="$LIBS"
1667 AC_CHECK_LIB([crypt], [crypt], [], [
1668   AC_CHECK_LIB([crypto], [DES_crypt])
1669 ])
1670 LIBCRYPT="$LIBS"
1671 LIBCRYPT="${LIBCRYPT%$LIBS_save}"
1672 LIBCRYPT="${LIBCRYPT#$LIBS_save}"
1673 AC_SUBST([LIBCRYPT])
1674 LIBS="$LIBS_save"
1675 unset LIBS_save
1676
1677 AC_CHECK_LIB([resolv], [res_init])
1678
1679 dnl ---------------------------
1680 dnl check system has PCRE regexp
1681 dnl ---------------------------
1682 if test "$enable_pcreposix" = "yes"; then
1683   AC_CHECK_LIB([pcreposix], [regexec], [], [
1684     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1685   ])
1686 fi
1687 AC_SUBST([HAVE_LIBPCREPOSIX])
1688
1689 dnl ---------------------------
1690 dnl check system has PCRE2 regexp
1691 dnl ---------------------------
1692 if test "$enable_pcre2posix" = "yes"; then
1693   AC_CHECK_LIB([pcre2-posix], [regexec], [], [
1694     AC_MSG_ERROR([--enable-pcre2posix given but unable to find libpcre2-posix])
1695   ])
1696 fi
1697 AC_SUBST([HAVE_LIBPCRE2_POSIX])
1698
1699 dnl ##########################################################################
1700 dnl test "$enable_clippy_only" != "yes"
1701 fi
1702 dnl END OF LARGE if block
1703 dnl ##########################################################################
1704
1705 dnl ------------------
1706 dnl check C-Ares library
1707 dnl ------------------
1708 PKG_CHECK_MODULES([CARES], [libcares], [
1709   c_ares_found=true
1710 ],[
1711   c_ares_found=false
1712 ])
1713 AM_CONDITIONAL([CARES], [$c_ares_found])
1714
1715
1716 dnl ----------------------------------------------------------------------------
1717 dnl figure out if domainname is available in the utsname struct (GNU extension).
1718 dnl ----------------------------------------------------------------------------
1719 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1720
1721 dnl ------------------
1722 dnl IPv6 header checks
1723 dnl ------------------
1724 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1725         netinet6/in6_var.h netinet6/nd6.h], [], [],
1726         FRR_INCLUDES)
1727
1728 m4_define([FRR_INCLUDES],dnl
1729 FRR_INCLUDES
1730 [#ifdef HAVE_NETINET6_IN6_H
1731 #include <netinet6/in6.h>
1732 #endif
1733 #ifdef HAVE_NETINET_IN6_VAR_H
1734 #include <netinet/in6_var.h>
1735 #endif
1736 #include <netinet/icmp6.h>
1737 #ifdef HAVE_NETINET6_IN6_VAR_H
1738 # include <netinet6/in6_var.h>
1739 #endif
1740 #ifdef HAVE_NETINET6_ND6_H
1741 # include <netinet6/nd6.h>
1742 #endif
1743 ])dnl
1744
1745 dnl --------------------
1746 dnl Daemon disable check
1747 dnl --------------------
1748
1749 AS_IF([test "$enable_bgpd" != "no"], [
1750   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1751 ])
1752
1753 AS_IF([test "$enable_mgmtd" != "no"], [
1754
1755   AC_DEFINE([HAVE_MGMTD], [1], [mgmtd])
1756
1757   # Enable MGMTD local validations
1758   AS_IF([test "$enable_mgmtd_local_validations" == "yes"], [
1759     AC_DEFINE([MGMTD_LOCAL_VALIDATIONS_ENABLED], [1], [Enable mgmtd local validations.])
1760   ])
1761 ])
1762
1763 AS_IF([test "$enable_ripd" != "no"], [
1764   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1765 ])
1766
1767 AS_IF([test "$enable_ripngd" != "no"], [
1768   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1769 ])
1770
1771 AS_IF([test "$enable_ospfd" != "no"], [
1772   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1773 ])
1774
1775 AS_IF([test "$enable_ospf6d" != "no"], [
1776   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1777 ])
1778
1779 AS_IF([test "$enable_ldpd" != "no"], [
1780   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1781 ])
1782
1783 AS_IF([test "$enable_nhrpd" != "no"], [
1784   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1785 ])
1786
1787 AS_IF([test "$enable_eigrpd" != "no"], [
1788   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1789 ])
1790
1791 AS_IF([test "$enable_babeld" != "no"], [
1792   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1793 ])
1794
1795 AS_IF([test "$enable_isisd" != "no"], [
1796   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1797 ])
1798
1799 AS_IF([test "$enable_pimd" != "no"], [
1800   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1801 ])
1802
1803 AS_IF([test "$enable_pim6d" != "no"], [
1804   AC_DEFINE([HAVE_PIM6D], [1], [pim6d])
1805 ])
1806
1807 AS_IF([test "$enable_pbrd" != "no"], [
1808   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1809 ])
1810
1811 AS_IF([test "$enable_sharpd" = "yes"], [
1812   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1813 ])
1814
1815 AS_IF([test "$enable_staticd" != "no"], [
1816   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1817 ])
1818
1819 AS_IF([test "$enable_fabricd" != "no"], [
1820   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1821 ])
1822
1823 AS_IF([test "$enable_vrrpd" != "no"], [
1824   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1825 ])
1826
1827 if test "$enable_bfdd" = "no"; then
1828   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1829   BFDD=""
1830 else
1831   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1832   BFDD="bfdd"
1833
1834   case $host_os in
1835     linux*)
1836       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1837       ;;
1838
1839     *)
1840       AC_DEFINE([BFD_BSD], [1], [bfdd])
1841       ;;
1842   esac
1843 fi
1844
1845 AS_IF([test "$enable_pathd" != "no"], [
1846   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1847 ])
1848
1849 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1850   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1851 fi
1852
1853 NHRPD=""
1854 case "$host_os" in
1855   linux*)
1856     case "${enable_nhrpd}" in
1857       no)
1858         ;;
1859       yes)
1860         if test "$enable_clippy_only" != "yes"; then
1861         if test "$c_ares_found" != "true" ; then
1862           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1863         fi
1864         fi
1865         NHRPD="nhrpd"
1866         ;;
1867       *)
1868         if test "$c_ares_found" = "true" ; then
1869           NHRPD="nhrpd"
1870         fi
1871         ;;
1872     esac
1873     ;;
1874   *)
1875     if test "$enable_nhrpd" = "yes"; then
1876       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1877     fi
1878     ;;
1879 esac
1880
1881 if test "$enable_watchfrr" = "no";then
1882   WATCHFRR=""
1883 else
1884   WATCHFRR="watchfrr"
1885 fi
1886
1887 OSPFCLIENT=""
1888 if test "$enable_ospfapi" != "no";then
1889     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1890
1891   if test "$enable_ospfclient" != "no";then
1892       OSPFCLIENT="ospfclient"
1893   fi
1894 fi
1895
1896 if test "$enable_bgp_announce" = "no";then
1897   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1898 else
1899   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1900 fi
1901
1902 if test "$enable_bgp_vnc" != "no";then
1903   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1904 fi
1905
1906 bgpd_bmp=false
1907 case "${enable_bgp_bmp}" in
1908   no)
1909     ;;
1910   yes)
1911     if test "$c_ares_found" != "true" ; then
1912       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1913     fi
1914     bgpd_bmp=true
1915     ;;
1916   *)
1917     if test "$c_ares_found" = "true" ; then
1918       bgpd_bmp=true
1919     fi
1920     ;;
1921 esac
1922
1923 if test "$enable_version_build_config" != "no";then
1924   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1925 fi
1926
1927 dnl ##########################################################################
1928 dnl LARGE if block
1929 if test "$enable_clippy_only" != "yes"; then
1930 dnl ##########################################################################
1931
1932 dnl ------------------
1933 dnl check Net-SNMP library
1934 dnl ------------------
1935 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1936    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1937    if test "$NETSNMP_CONFIG" = "no"; then
1938       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1939    fi
1940    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1941    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1942    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1943    # among other things we avoid a GPL vs. OpenSSL license conflict here
1944    for removelib in crypto ssl sensors pci wrap; do
1945      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1946    done
1947    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1948    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1949 int main(void);
1950 ],
1951 [
1952 {
1953   return 0;
1954 }
1955 ])], [
1956      AC_MSG_RESULT([no])
1957      AC_MSG_ERROR([--enable-snmp given but not usable])])
1958    case "${enable_snmp}" in
1959      yes)
1960       SNMP_METHOD=agentx
1961       ;;
1962      agentx)
1963       SNMP_METHOD="${enable_snmp}"
1964       ;;
1965      *)
1966       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1967       ;;
1968    esac
1969    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1970    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1971 fi
1972 AC_SUBST([SNMP_LIBS])
1973 AC_SUBST([SNMP_CFLAGS])
1974
1975 dnl ---------------
1976 dnl libyang
1977 dnl ---------------
1978 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1979   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1980 ])
1981 ac_cflags_save="$CFLAGS"
1982 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1983 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1984   AC_MSG_ERROR([m4_normalize([
1985     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1986     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1987   ])
1988 ], [[#include <libyang/libyang.h>]])
1989 CFLAGS="$ac_cflags_save"
1990
1991 dnl ---------------
1992 dnl configuration rollbacks
1993 dnl ---------------
1994 SQLITE3=false
1995 if test "$enable_config_rollbacks" = "yes"; then
1996   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1997     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1998     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1999     SQLITE3=true
2000   ], [
2001     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
2002   ])
2003 fi
2004
2005 dnl ---------------
2006 dnl confd
2007 dnl ---------------
2008 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
2009    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
2010    if test "$CONFD" = "/bin/false"; then
2011       AC_MSG_ERROR([confd was not found on your system.])]
2012    fi
2013    AC_CHECK_PROG([CONFDC], [confdc], [confdc], [/bin/false], "${enable_confd}/bin")
2014    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
2015    AC_SUBST([CONFD_CFLAGS])
2016    CONFD_LIBS="-lconfd"
2017    AC_SUBST([CONFD_LIBS])
2018    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
2019 fi
2020
2021 dnl ---------------
2022 dnl sysrepo
2023 dnl ---------------
2024 if test "$enable_sysrepo" = "yes"; then
2025   PKG_CHECK_MODULES([SYSREPO], [sysrepo >= 2.1.42],
2026       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
2027       SYSREPO=true],
2028       [SYSREPO=false
2029       AC_MSG_ERROR([sysrepo was not found on your system.])]
2030   )
2031 fi
2032
2033 dnl ---------------
2034 dnl gRPC
2035 dnl ---------------
2036 if test "$enable_grpc" = "yes"; then
2037   AC_LANG_PUSH([C++])
2038   AX_CXX_COMPILE_STDCXX([11], [ext])
2039   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
2040     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
2041     if test "$PROTOC" = "/bin/false"; then
2042       AC_MSG_FAILURE([grpc requested but protoc not found.])
2043     fi
2044
2045     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
2046     GRPC=true
2047   ], [
2048     GRPC=false
2049     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
2050   ])
2051   AC_LANG_POP([C++])
2052 fi
2053
2054 dnl ---------
2055 dnl DPDK
2056 dnl ---------
2057 if test "$enable_dp_dpdk" = "yes"; then
2058   PKG_CHECK_MODULES([DPDK], [libdpdk], [
2059     AC_DEFINE([HAVE_DPDK], [1], [Enable DPDK backend])
2060     DPDK=true
2061   ], [
2062     AC_MSG_ERROR([configuration specifies --enable-dp-dpdk but DPDK libs were not found])
2063   ])
2064 fi
2065
2066 dnl -----
2067 dnl LTTng
2068 dnl -----
2069 if test "$enable_lttng" = "yes"; then
2070   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.9.0], [
2071     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
2072     LTTNG=true
2073   ], [
2074     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
2075   ])
2076 fi
2077
2078 dnl ----
2079 dnl USDT
2080 dnl ----
2081 if test "$enable_usdt" = "yes"; then
2082   AC_CHECK_HEADERS([sys/sdt.h], [
2083     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
2084     USDT=true
2085   ], [
2086     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
2087   ])
2088 fi
2089
2090 dnl ------
2091 dnl ZeroMQ
2092 dnl ------
2093 if test "$enable_zeromq" != "no"; then
2094   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2095     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2096     ZEROMQ=true
2097   ], [
2098     if test "$enable_zeromq" = "yes"; then
2099       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2100     fi
2101   ])
2102 fi
2103
2104 dnl ------------------------------------
2105 dnl Enable RPKI and add librtr to libs
2106 dnl ------------------------------------
2107 if test "$enable_rpki" = "yes"; then
2108   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.8.0],
2109       [RPKI=true],
2110       [RPKI=false
2111       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2112   )
2113 fi
2114
2115 dnl ------------------------------------
2116 dnl pimd and pim6d not supported on OpenBSD and MacOS
2117 dnl ------------------------------------
2118 if test "$enable_pimd" != "no"; then
2119 AC_MSG_CHECKING([for pimd OS support])
2120 case "$host_os" in
2121   darwin*)
2122     AC_MSG_RESULT([no])
2123     enable_pimd="no"
2124     ;;
2125   openbsd*)
2126     AC_MSG_RESULT([no])
2127     enable_pimd="no"
2128     ;;
2129   *)
2130     AC_MSG_RESULT([yes])
2131     ;;
2132 esac
2133 fi
2134
2135 if test "$enable_pim6d" != "no"; then
2136 AC_MSG_CHECKING([for pim6d OS support])
2137 case "$host_os" in
2138   linux*)
2139     AC_MSG_RESULT([yes])
2140     ;;
2141   *)
2142     AC_MSG_RESULT([no])
2143     enable_pim6d="no"
2144     ;;
2145 esac
2146 fi
2147
2148 dnl -------------------------------------
2149 dnl VRRP is only supported on linux
2150 dnl -------------------------------------
2151 if test "$enable_vrrpd" != "no"; then
2152 AC_MSG_CHECKING([for VRRP OS support])
2153 case "$host_os" in
2154   linux*)
2155     AC_MSG_RESULT([yes])
2156     ;;
2157   *)
2158     AC_MSG_RESULT([no])
2159     enable_vrrpd="no"
2160     ;;
2161 esac
2162 fi
2163
2164 dnl ------------------------------------------
2165 dnl Check whether rtrlib was build with ssh support
2166 dnl ------------------------------------------
2167 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2168 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2169                         [[struct tr_ssh_config config;]])],
2170         [AC_MSG_RESULT([yes])
2171         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2172         AC_MSG_RESULT([no])
2173 )
2174
2175 dnl ---------------
2176 dnl dlopen & dlinfo
2177 dnl ---------------
2178 LIBS_save="$LIBS"
2179 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2180   AC_MSG_ERROR([unable to find the dlopen()])
2181 ])
2182
2183 AC_CHECK_HEADERS([link.h])
2184
2185 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2186   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2187 #include <stdlib.h>
2188 #ifdef HAVE_LINK_H
2189 #include <link.h>
2190 #endif
2191 #include <dlfcn.h>
2192 ]], [[
2193   char origin[1];
2194   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2195 ]])], [
2196     frr_cv_rtld_di_origin=yes
2197   ], [
2198     frr_cv_rtld_di_origin=no
2199   ])
2200 ])
2201 if test "$frr_cv_rtld_di_origin" = "yes"; then
2202   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2203 fi
2204
2205 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2206   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2207 #include <stdlib.h>
2208 #ifdef HAVE_LINK_H
2209 #include <link.h>
2210 #endif
2211 #include <dlfcn.h>
2212 ]], [[
2213   struct link_map *lm = NULL;
2214   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2215 ]])], [
2216     frr_cv_rtld_di_linkmap=yes
2217   ], [
2218     frr_cv_rtld_di_linkmap=no
2219   ])
2220 ])
2221 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2222   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2223 fi
2224
2225 LIBDL="$LIBS"
2226 LIBDL="${LIBDL%$LIBS_save}"
2227 LIBDL="${LIBDL#$LIBS_save}"
2228 AC_SUBST([LIBDL])
2229 LIBS="$LIBS_save"
2230 unset LIBS_save
2231
2232 dnl ##########################################################################
2233 dnl test "$enable_clippy_only" != "yes"
2234 fi
2235 dnl END OF LARGE if block
2236 dnl ##########################################################################
2237
2238 dnl ---------------------------
2239 dnl sockaddr and netinet checks
2240 dnl ---------------------------
2241 AC_CHECK_TYPES([
2242         struct sockaddr_dl,
2243         struct vifctl, struct mfcctl, struct sioc_sg_req,
2244         vifi_t, struct sioc_vif_req, struct igmpmsg,
2245         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2246         struct nd_opt_adv_interval,
2247         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2248         struct nd_opt_rdnss, struct nd_opt_dnssl],
2249         [], [], FRR_INCLUDES)
2250
2251 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2252         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2253         struct sockaddr_dl.sdl_len,
2254         struct if6_aliasreq.ifra_lifetime,
2255         struct nd_opt_adv_interval.nd_opt_ai_type],
2256         [], [], FRR_INCLUDES)
2257
2258 dnl ---------------------------
2259 dnl IRDP/pktinfo/icmphdr checks
2260 dnl ---------------------------
2261
2262 AC_CHECK_TYPES([struct in_pktinfo], [
2263   AC_CHECK_TYPES([struct icmphdr], [
2264     IRDP=true
2265   ], [
2266     IRDP=false
2267   ], [FRR_INCLUDES])
2268 ], [
2269   IRDP=false
2270 ], [FRR_INCLUDES])
2271
2272 case "${enable_irdp}" in
2273 yes)
2274   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2275   ;;
2276 no)
2277   IRDP=false
2278   ;;
2279 esac
2280
2281
2282 dnl -----------------------
2283 dnl checking for IP_PKTINFO
2284 dnl -----------------------
2285 AC_MSG_CHECKING([for IP_PKTINFO])
2286 AC_COMPILE_IFELSE(
2287 [ AC_LANG_PROGRAM([[
2288         #include <netdb.h>
2289    ]], [[
2290         int opt = IP_PKTINFO;
2291    ]])
2292 ],[
2293   AC_MSG_RESULT([yes])
2294   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2295 ],[
2296   AC_MSG_RESULT([no])
2297 ])
2298
2299 dnl ---------------------------
2300 dnl checking for IP_RECVDSTADDR
2301 dnl ---------------------------
2302 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2303 AC_COMPILE_IFELSE(
2304 [ AC_LANG_PROGRAM([[
2305         #include <netinet/in.h>
2306   ]], [[
2307         int opt = IP_RECVDSTADDR;
2308   ]])
2309 ],[
2310   AC_MSG_RESULT([yes])
2311   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2312 ],[
2313   AC_MSG_RESULT([no])
2314 ])
2315
2316 dnl ----------------------
2317 dnl checking for IP_RECVIF
2318 dnl ----------------------
2319 AC_MSG_CHECKING([for IP_RECVIF])
2320 AC_COMPILE_IFELSE(
2321 [ AC_LANG_PROGRAM([[
2322         #include <netinet/in.h>
2323   ]], [[
2324         int opt = IP_RECVIF;
2325   ]])
2326 ],[
2327   AC_MSG_RESULT([yes])
2328   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2329 ],[
2330   AC_MSG_RESULT([no])
2331 ])
2332
2333 dnl ----------------------
2334 dnl checking for SO_BINDANY
2335 dnl ----------------------
2336 AC_MSG_CHECKING([for SO_BINDANY])
2337 AC_COMPILE_IFELSE(
2338 [ AC_LANG_PROGRAM([[
2339         #include <sys/socket.h>
2340   ]], [[
2341         int opt = SO_BINDANY;
2342   ]])
2343 ],[
2344   AC_MSG_RESULT([yes])
2345   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2346 ],[
2347   AC_MSG_RESULT([no])
2348 ])
2349
2350 dnl ----------------------
2351 dnl checking for IP_FREEBIND
2352 dnl ----------------------
2353 AC_MSG_CHECKING([for IP_FREEBIND])
2354 AC_COMPILE_IFELSE(
2355 [ AC_LANG_PROGRAM([[
2356         #include <netinet/in.h>
2357   ]], [[
2358         int opt = IP_FREEBIND;
2359   ]])
2360 ],[
2361   AC_MSG_RESULT([yes])
2362   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2363 ],[
2364   AC_MSG_RESULT([no])
2365 ])
2366
2367 dnl --------------------------------------
2368 dnl checking for be32dec existence or not
2369 dnl --------------------------------------
2370 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2371         #ifdef HAVE_SYS_ENDIAN_H
2372         #include <sys/endian.h>
2373         #endif
2374         #ifdef HAVE_ENDIAN_H
2375         #include <endian.h>
2376         #endif
2377 ])
2378
2379 dnl --------------------------------------
2380 dnl checking for clock_time monotonic struct and call
2381 dnl --------------------------------------
2382 AC_CHECK_DECL([CLOCK_MONOTONIC],
2383         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2384          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2385 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2386
2387 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2388          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2389 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2390
2391 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2392   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2393 ])
2394
2395 dnl --------------------------------------
2396 dnl checking for flex and bison
2397 dnl --------------------------------------
2398
2399 dnl autoconf 2.69 AC_PROG_LEX has no parameters
2400 dnl autoconf 2.70 AC_PROG_LEX prints a deprecation warning without params
2401 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
2402   dnl autoconf < 2.70
2403   AC_PROG_LEX
2404 ], [
2405   dnl autoconf >= 2.70
2406   AC_PROG_LEX([noyywrap])
2407 ])
2408
2409 AC_MSG_CHECKING([version of flex])
2410 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2411 frr_ac_flex_version="${frr_ac_flex_version##* }"
2412 AC_MSG_RESULT([$frr_ac_flex_version])
2413 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2414   LEX="$SHELL $missing_dir/missing flex"
2415   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2416     AC_MSG_WARN([using pregenerated flex output files])
2417   else
2418     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2419   fi
2420   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2421   AC_SUBST([LEXLIB], [''])
2422 ])
2423
2424 AC_PROG_YACC
2425 dnl thanks GNU bison for this b*llshit...
2426 AC_MSG_CHECKING([version of bison])
2427 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2428 frr_ac_bison_version="${frr_ac_bison_version##* }"
2429 frr_ac_bison_missing="false"
2430 case "x${frr_ac_bison_version}x" in
2431   x2.7*)
2432     BISON_OPENBRACE='"'
2433     BISON_CLOSEBRACE='"'
2434     BISON_VERBOSE=''
2435     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2436     ;;
2437   x2.*|x1.*)
2438     AC_MSG_RESULT([$frr_ac_bison_version])
2439     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2440     frr_ac_bison_missing="true"
2441     ;;
2442   x)
2443     AC_MSG_RESULT([none])
2444     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2445     frr_ac_bison_missing="true"
2446     ;;
2447   x3.[012][^0-9]*)
2448     BISON_OPENBRACE='{'
2449     BISON_CLOSEBRACE='}'
2450     BISON_VERBOSE='-Dparse.error=verbose'
2451     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2452     ;;
2453   *)
2454     BISON_OPENBRACE='{'
2455     BISON_CLOSEBRACE='}'
2456     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2457     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2458     ;;
2459 esac
2460 AC_SUBST([BISON_OPENBRACE])
2461 AC_SUBST([BISON_CLOSEBRACE])
2462 AC_SUBST([BISON_VERBOSE])
2463
2464 if $frr_ac_bison_missing; then
2465   YACC="$SHELL $missing_dir/missing bison -y"
2466   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2467     AC_MSG_WARN([using pregenerated bison output files])
2468   else
2469     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2470   fi
2471 fi
2472
2473 dnl -------------------
2474 dnl capabilities checks
2475 dnl -------------------
2476 if test "$enable_capabilities" != "no"; then
2477   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2478   AC_COMPILE_IFELSE(
2479   [ AC_LANG_PROGRAM([[
2480         #include <sys/prctl.h>
2481     ]], [[
2482         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2483     ]])
2484   ],[AC_MSG_RESULT([yes])
2485      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2486      frr_ac_keepcaps="yes"
2487   ],[AC_MSG_RESULT(no)
2488   ])
2489   if test "$frr_ac_keepcaps" = "yes"; then
2490     AC_CHECK_HEADERS([sys/capability.h])
2491   fi
2492   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2493     AC_CHECK_LIB([cap], [cap_init],
2494       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2495        LIBCAP="-lcap"
2496        frr_ac_lcaps="yes"]
2497     )
2498   fi
2499   if test "$frr_ac_scaps" = "yes" \
2500        -o "$frr_ac_lcaps" = "yes"; then
2501     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2502   fi
2503
2504   case "$host_os" in
2505   linux*)
2506     if test "$enable_clippy_only" != "yes"; then
2507     if test "$frr_ac_lcaps" != "yes"; then
2508       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2509     fi
2510     fi
2511     ;;
2512   esac
2513 else
2514   case "$host_os" in
2515   linux*)
2516     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2517     ;;
2518   esac
2519 fi
2520 AC_SUBST([LIBCAP])
2521
2522 dnl ---------------------------
2523 dnl check for glibc 'backtrace'
2524 dnl ---------------------------
2525 if test "$enable_backtrace" != "no" ; then
2526   backtrace_ok=no
2527   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2528     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2529     backtrace_ok=yes
2530   ], [
2531     true
2532   ])
2533
2534   if test "$backtrace_ok" = "no"; then
2535     AC_CHECK_HEADER([unwind.h], [
2536       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2537         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2538         backtrace_ok=yes
2539       ])
2540     ])
2541   fi
2542
2543   if test "$backtrace_ok" = "no"; then
2544     AC_CHECK_HEADER([execinfo.h], [
2545       AC_SEARCH_LIBS([backtrace], [execinfo], [
2546         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2547         backtrace_ok=yes
2548       ],, [-lm])
2549     ])
2550   fi
2551
2552   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2553     dnl user explicitly requested backtrace but we failed to find support
2554     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2555   fi
2556 fi
2557
2558 dnl -----------------------------------------
2559 dnl check for malloc mallinfo struct and call
2560 dnl this must try and link using LIBS, in
2561 dnl order to check no alternative allocator
2562 dnl has been specified, which might not provide
2563 dnl mallinfo
2564 dnl -----------------------------------------
2565 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2566
2567 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2568   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2569 #ifdef HAVE_MALLOC_H
2570 #include <malloc.h>
2571 #endif
2572 #ifdef HAVE_MALLOC_NP_H
2573 #include <malloc_np.h>
2574 #endif
2575 #ifdef HAVE_MALLOC_MALLOC_H
2576 #include <malloc/malloc.h>
2577 #endif
2578 ]], [[
2579 struct mallinfo ac_x; ac_x = mallinfo ();
2580 ]])], [
2581     frr_cv_mallinfo=yes
2582   ], [
2583     frr_cv_mallinfo=no
2584   ])
2585 ])
2586 if test "$frr_cv_mallinfo" = "yes"; then
2587   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2588 fi
2589
2590 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2591   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2592 #ifdef HAVE_MALLOC_H
2593 #include <malloc.h>
2594 #endif
2595 #ifdef HAVE_MALLOC_NP_H
2596 #include <malloc_np.h>
2597 #endif
2598 #ifdef HAVE_MALLOC_MALLOC_H
2599 #include <malloc/malloc.h>
2600 #endif
2601 ]], [[
2602 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2603 ]])], [
2604     frr_cv_mallinfo2=yes
2605   ], [
2606     frr_cv_mallinfo2=no
2607   ])
2608 ])
2609 if test "$frr_cv_mallinfo2" = "yes"; then
2610   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2611 fi
2612
2613 AC_MSG_CHECKING([whether malloc_usable_size is available])
2614 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2615 #ifdef HAVE_MALLOC_H
2616 #include <malloc.h>
2617 #endif
2618 #ifdef HAVE_MALLOC_MALLOC_H
2619 #include <malloc/malloc.h>
2620 #endif
2621 ]], [[
2622 size_t ac_x; ac_x = malloc_usable_size(NULL);
2623 ]])], [
2624   AC_MSG_RESULT([yes])
2625   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2626 ], [
2627   AC_MSG_RESULT([no])
2628
2629   AC_MSG_CHECKING([whether malloc_size is available])
2630   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2631 #ifdef HAVE_MALLOC_H
2632 #include <malloc.h>
2633 #endif
2634 #ifdef HAVE_MALLOC_MALLOC_H
2635 #include <malloc/malloc.h>
2636 #endif
2637 ]], [[
2638 size_t ac_x; ac_x = malloc_size(NULL);
2639 ]])], [
2640     AC_MSG_RESULT([yes])
2641     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2642   ], [
2643     AC_MSG_RESULT([no])
2644   ])
2645 ])
2646
2647 dnl ----------
2648 dnl configure date
2649 dnl ----------
2650 dev_version=`echo $VERSION | grep dev`
2651 #don't expire deprecated code in non 'dev' branch
2652 if test "$dev_version" = ""; then
2653    CONFDATE=0
2654 else
2655    CONFDATE=`date '+%Y%m%d'`
2656 fi
2657 AC_SUBST([CONFDATE])
2658
2659 dnl ------------------------------
2660 dnl set paths for state directory
2661 dnl ------------------------------
2662 AC_MSG_CHECKING([directory to use for state file])
2663 if test "$prefix" = "NONE"; then
2664   frr_statedir_prefix="";
2665 else
2666   frr_statedir_prefix=${prefix}
2667 fi
2668 if test "$localstatedir" = '${prefix}/var'; then
2669   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2670                         ${frr_statedir_prefix}/var/adm dnl
2671                         ${frr_statedir_prefix}/etc dnl
2672                         /var/run        dnl
2673                         /var/adm        dnl
2674                         /etc            dnl
2675                         /dev/null;
2676   do
2677     test -d $FRR_STATE_DIR && break
2678   done
2679   frr_statedir=$FRR_STATE_DIR
2680 else
2681   frr_statedir=${localstatedir}
2682 fi
2683 if test "$frr_statedir" = "/dev/null"; then
2684     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2685 fi
2686 AC_MSG_RESULT([${frr_statedir}])
2687 AC_SUBST([frr_statedir])
2688
2689 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2690 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2691 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2692 AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information])
2693 AC_DEFINE_UNQUOTED([MGMTD_FE_SERVER_PATH], ["$frr_statedir/mgmtd_fe.sock"], [mgmtd frontend server socket])
2694 AC_DEFINE_UNQUOTED([MGMTD_BE_SERVER_PATH], ["$frr_statedir/mgmtd_be.sock"], [mgmtd backend server socket])
2695 AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information])
2696 AC_DEFINE_UNQUOTED([ISISD_RESTART], ["$frr_statedir%s/isid-restart.json"], [isisd restart information])
2697 AC_DEFINE_UNQUOTED([OSPF6_AUTH_SEQ_NUM_FILE], ["$frr_statedir/ospf6d-at-seq-no.dat"], [ospf6d AT Sequence number information])
2698 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2699 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2700
2701 dnl autoconf does this, but it does it too late...
2702 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2703 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2704
2705 dnl get the full path, recursing through variables...
2706 vtysh_bin="$bindir/vtysh"
2707 for I in 1 2 3 4 5 6 7 8 9 10; do
2708         eval vtysh_bin="\"$vtysh_bin\""
2709 done
2710 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2711 AC_SUBST([vtysh_bin])
2712
2713 CFG_SYSCONF="$sysconfdir"
2714 CFG_SBIN="$sbindir"
2715 CFG_BIN="$bindir"
2716 CFG_STATE="$frr_statedir"
2717 CFG_MODULE="$moduledir"
2718 CFG_YANGMODELS="$yangmodelsdir"
2719 CFG_SCRIPT="$scriptdir"
2720 for I in 1 2 3 4 5 6 7 8 9 10; do
2721         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2722         eval CFG_SBIN="\"$CFG_SBIN\""
2723         eval CFG_BIN="\"$CFG_BIN\""
2724         eval CFG_STATE="\"$CFG_STATE\""
2725         eval CFG_MODULE="\"$CFG_MODULE\""
2726         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2727         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2728 done
2729 AC_SUBST([CFG_SYSCONF])
2730 AC_SUBST([CFG_SBIN])
2731 AC_SUBST([CFG_BIN])
2732 AC_SUBST([CFG_STATE])
2733 AC_SUBST([CFG_MODULE])
2734 AC_SUBST([CFG_SCRIPT])
2735 AC_SUBST([CFG_YANGMODELS])
2736 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2737 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2738 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2739 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2740
2741 dnl various features
2742 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2743 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2744 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2745 dnl northbound
2746 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2747 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2748 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2749 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2750 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2751 dnl plugins
2752 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2753 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2754 AM_CONDITIONAL([IRDP], [$IRDP])
2755 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2756 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" != "no"])
2757 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2758
2759 dnl PCEP plugin
2760 AS_IF([test "$enable_pathd" != "no"], [
2761        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2762        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2763        ])
2764 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2765 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2766 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2767 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2768
2769 dnl daemons
2770 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2771 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2772 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2773 AM_CONDITIONAL([MGMTD], [test "$enable_mgmtd" != "no"])
2774 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2775 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2776 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2777 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2778 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2779 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2780 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2781 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2782 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2783 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2784 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2785 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2786 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2787 AM_CONDITIONAL([PIM6D], [test "$enable_pim6d" != "no"])
2788 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2789 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2790 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2791 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2792 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2793 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2794 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2795 AM_CONDITIONAL([DP_DPDK], [test "$enable_dp_dpdk" = "yes"])
2796
2797 AC_CONFIG_FILES([Makefile],[
2798         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2799         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2800 ], [
2801         PYTHON="$PYTHON"
2802         enable_dev_build="$enable_dev_build"
2803 ])
2804
2805 AC_CONFIG_FILES([
2806           config.version
2807           redhat/frr.spec
2808           alpine/APKBUILD
2809           snapcraft/snapcraft.yaml
2810           lib/version.h
2811           tests/lib/cli/test_cli.refout pkgsrc/mgmtd.sh
2812           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2813           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2814           pkgsrc/eigrpd.sh])
2815
2816 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2817 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2818 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2819 AC_CONFIG_FILES([tools/frrcommon.sh])
2820 AC_CONFIG_FILES([tools/frr.service])
2821 AC_CONFIG_FILES([tools/frr@.service])
2822
2823 AS_IF([test "$with_pkg_git_version" = "yes"], [
2824     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2825         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2826         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2827                 "${ac_abs_top_srcdir}" \
2828                 > "${dst}.tmp"
2829         test -f "$dst" \
2830                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2831                 && rm "${dst}.tmp" \
2832                 || mv "${dst}.tmp" "${dst}"
2833     ], [
2834         PERL="$PERL"
2835     ])
2836 ])
2837
2838 ## Hack, but working solution to avoid rebuilding of frr.info.
2839 ## It's already in CVS until texinfo 4.7 is more common.
2840 AC_OUTPUT
2841
2842 if test "$enable_rpath" = "yes" ; then
2843         true
2844 else
2845         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2846         sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool
2847         sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g'         libtool > libtool.sed && cat libtool.sed > libtool
2848         test -f libtool.sed && rm libtool.sed
2849 fi
2850
2851 echo "
2852 FRRouting configuration
2853 ------------------------------
2854 FRR version             : ${PACKAGE_VERSION}
2855 host operating system   : ${host_os}
2856 source code location    : ${srcdir}
2857 compiler                : ${CC}
2858 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2859 make                    : ${MAKE-make}
2860 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2861 state file directory    : ${frr_statedir}
2862 config file directory   : `eval echo \`echo ${sysconfdir}\``
2863 module directory        : ${CFG_MODULE}
2864 script directory        : ${CFG_SCRIPT}
2865 user to run as          : ${enable_user}
2866 group to run as         : ${enable_group}
2867 group for vty sockets   : ${enable_vty_group}
2868 config file mask        : ${enable_configfile_mask}
2869 log file mask           : ${enable_logfile_mask}
2870 zebra protobuf enabled  : ${enable_protobuf:-no}
2871 vici socket path        : ${vici_socket}
2872
2873 The above user and group must have read/write access to the state file
2874 directory and to the config files in the config file directory."
2875
2876 if test -n "$enable_datacenter"; then
2877   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2878 fi
2879 if test -n "$enable_time_check"; then
2880   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2881 fi
2882 if test -n "$enable_cpu_time"; then
2883   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2884 fi
2885
2886 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2887   AC_MSG_WARN([sphinx is missing but required to build documentation])
2888 fi
2889 if test "$frr_py_mod_pytest" = "false"; then
2890   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2891 fi