configure.ac

   1 ##
   2 ## Configure template file for Quagga.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.53)
   9
  10 AC_INIT(quagga, 0.96.4, [bug-zebra@gnu.org])
  11 AC_CONFIG_SRCDIR(lib/zebra.h)
  12 AM_INIT_AUTOMAKE()
  13 AM_CONFIG_HEADER(config.h)
  14
  15 dnl -----------------------------------
  16 dnl Get hostname and other information.
  17 dnl -----------------------------------
  18 AC_CANONICAL_HOST
  19
  20 dnl ------------
  21 dnl Check CFLAGS
  22 dnl ------------
  23 AC_ARG_WITH(cflags,
  24 [  --with-cflags           Set CFLAGS for use in compilation.])
  25 if test "x$with_cflags" != "x" ; then
  26   CFLAGS="$with_cflags" ; cflags_specified=yes ;
  27 elif test -n "$CFLAGS" ; then
  28   cflags_specified=yes ;
  29 fi
  30
  31 dnl --------
  32 dnl Check CC
  33 dnl --------
  34 AC_PROG_CC
  35
  36 dnl -----------------------------------------
  37 dnl If CLFAGS doesn\'t exist set default value
  38 dnl -----------------------------------------
  39 if test "x$cflags_specified" = "x" ; then
  40   CFLAGS="$CFLAGS -Wall"
  41 fi
  42
  43 dnl --------------
  44 dnl Check programs
  45 dnl --------------
  46 AC_PROG_CPP
  47 AC_PROG_INSTALL
  48 AC_PROG_MAKE_SET
  49 AC_CHECK_TOOL(AR, ar)
  50 AC_CHECK_TOOL(RANLIB, ranlib, :)
  51
  52 dnl ---------
  53 dnl AIX check
  54 dnl ---------
  55 AC_AIX
  56
  57 dnl ----------------------
  58 dnl Packages configuration
  59 dnl ----------------------
  60 AC_ARG_ENABLE(vtysh,
  61 [  --enable-vtysh,       Make integrated vty shell for Quagga])
  62 AC_ARG_ENABLE(ipv6,
  63 [  --disable-ipv6          turn off IPv6 related features and daemons])
  64 AC_ARG_ENABLE(zebra,
  65 [  --disable-zebra         do not build zebra daemon])
  66 AC_ARG_ENABLE(bgpd,
  67 [  --disable-bgpd          do not build bgpd])
  68 AC_ARG_ENABLE(ripd,
  69 [  --disable-ripd          do not build ripd])
  70 AC_ARG_ENABLE(ripngd,
  71 [  --disable-ripngd        do not build ripngd])
  72 AC_ARG_ENABLE(ospfd,
  73 [  --disable-ospfd         do not build ospfd])
  74 AC_ARG_ENABLE(ospf6d,
  75 [  --disable-ospf6d        do not build ospf6d])
  76 AC_ARG_ENABLE(bgp-announce,
  77 [  --disable-bgp-announce, turn off BGP route announcement])
  78 AC_ARG_ENABLE(netlink,
  79 [  --enable-netlink        force to use Linux netlink interface])
  80 AC_ARG_ENABLE(broken-aliases,
  81 [  --enable-broken-aliases enable aliases as distinct interfaces for Linux 2.2.X])
  82 AC_ARG_ENABLE(snmp,
  83 [  --enable-snmp           enable SNMP support])
  84 AC_ARG_WITH(libpam,
  85 [  --with-libpam           use libpam for PAM support in vtysh])
  86 AC_ARG_ENABLE(tcp-zebra,
  87 [  --enable-tcp-zebra      enable TCP/IP socket connection between zebra and protocol daemon])
  88 dnl Temporary option until OSPF NSSA implementation complete
  89 AC_ARG_ENABLE(nssa,
  90 [  --enable-nssa           enable OSPF NSSA option])
  91 AC_ARG_ENABLE(opaque-lsa,
  92 [  --enable-opaque-lsa     enable OSPF Opaque-LSA with OSPFAPI support (RFC2370)])
  93 AC_ARG_ENABLE(ospfapi,
  94 [  --disable-ospfapi       do not build OSPFAPI to access the OSPF LSA Database,
  95                           (this is the default if --enable-opaque-lsa is not set)])
  96 AC_ARG_ENABLE(ospfclient,
  97 [  --disable-ospfclient    do not build OSPFAPI client for OSPFAPI,
  98                           (this is the default if --disable-ospfapi is set)])
  99 AC_ARG_ENABLE(ospf-te,
 100 [  --enable-ospf-te        enable Traffic Engineering Extension to OSPF])
 101 AC_ARG_ENABLE(multipath,
 102 [  --enable-multipath=ARG  enable multipath function, ARG must be digit])
 103 AC_ARG_ENABLE(quagga_user,
 104 [  --enable-user=ARG       user to run Quagga suite as (default quagga)])
 105 AC_ARG_ENABLE(quagga_group,
 106 [  --enable-group=ARG      group to run Quagga suite as (default quagga)])
 107 AC_ARG_ENABLE(vty_group,
 108 [  --enable-vty-group=ARG      set vty sockets to have specified group as owner])
 109
 110 AC_ARG_ENABLE(rtadv,
 111 [  --enable-rtadv         enable IPV6 router advertisement feature])
 112
 113 if test "${enable_broken_aliases}" = "yes"; then
 114   if test "${enable_netlink}" = "yes"
 115   then
 116     echo "Sorry, you can't use netlink with broken aliases"
 117     exit 1
 118   fi
 119   AC_DEFINE(HAVE_BROKEN_ALIASES,,Broken Alias)
 120   enable_netlink=no
 121 fi
 122
 123 if test "${enable_tcp_zebra}" = "yes"; then
 124   AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
 125 fi
 126
 127 if test "${enable_nssa}" = "yes"; then
 128   AC_DEFINE(HAVE_NSSA,,OSPF NSSA)
 129 fi
 130
 131 if test "${enable_opaque_lsa}" = "yes"; then
 132   AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
 133 fi
 134
 135 if test "${enable_ospf_te}" = "yes"; then
 136   AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
 137   AC_DEFINE(HAVE_OSPF_TE,,OSPF TE)
 138 fi
 139
 140 AC_MSG_CHECKING(Should zebra's RTADV be used)
 141 if test "${enable_rtadv}" = "yes"; then
 142   AC_MSG_RESULT(yes)
 143   AC_DEFINE(HAVE_RTADV,,Enable zebra IPv6 Routing Advertisements)
 144 else
 145   AC_MSG_RESULT(no)
 146 fi
 147
 148 if test "${enable_user}" = "yes" || test x"${enable_user}" = x""; then
 149   enable_user="quagga"
 150 elif test "${enable_user}" = "no"; then
 151   enable_user="root"
 152 fi
 153 AC_DEFINE_UNQUOTED(QUAGGA_USER, "${enable_user}", Quagga User)
 154
 155 if test "${enable_group}" = "yes" || test x"${enable_group}" = x""; then
 156   enable_group="quagga"
 157 elif test "${enable_group}" = "no"; then
 158   enable_group="root"
 159 fi
 160 AC_DEFINE_UNQUOTED(QUAGGA_GROUP, "${enable_group}", Quagga Group)
 161
 162 if test x"${enable_vty_group}" = x"yes" ; then
 163   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 164 elif test x"${enable_vty_group}" != x""; then
 165   if test x"${enable_vty_group}" != x"no"; then
 166     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 167   fi
 168 fi
 169
 170 changequote(, )dnl
 171
 172 MULTIPATH_NUM=1
 173
 174 case "${enable_multipath}" in
 175   [0-9]|[1-9][0-9])
 176     MULTIPATH_NUM="${enable_multipath}"
 177     ;;
 178   "")
 179     ;;
 180   *)
 181     echo "Please specify digit to --enable-multipath ARG."
 182     exit 1
 183     ;;
 184 esac
 185
 186 changequote([, ])dnl
 187
 188 AC_SUBST(MULTIPATH_NUM)
 189
 190 dnl -------------------
 191 dnl Check header files.
 192 dnl -------------------
 193 AC_STDC_HEADERS
 194 AC_CHECK_HEADERS(string.h stropts.h sys/conf.h sys/ksym.h sys/time.h sys/times.h sys/select.h sys/sysctl.h sys/sockio.h sys/types.h net/if_dl.h net/if_var.h linux/version.h kvm.h netdb.h netinet/in.h net/netopt.h netinet/in_var.h netinet/in6_var.h netinet6/in6_var.h netinet/in6.h inet/nd.h asm/types.h netinet/icmp6.h netinet6/nd6.h libutil.h)
 195
 196 dnl check some types
 197 AC_C_CONST
 198 dnl AC_TYPE_PID_T
 199 AC_TYPE_SIGNAL
 200
 201 dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
 202 case "$host" in
 203   *-sunos5.6* | *-solaris2.6*)
 204       opsys=sol2-6
 205       AC_DEFINE(SUNOS_5,,SunOS 5)
 206       AC_CHECK_LIB(xnet, main)
 207       CURSES=-lcurses
 208   ;;
 209   *-sunos5* | *-solaris2*)
 210       AC_DEFINE(SUNOS_5,,SunOS 5)
 211       AC_CHECK_LIB(socket, main)
 212       AC_CHECK_LIB(nsl, main)
 213       CURSES=-lcurses
 214   ;;
 215   *-linux-*)
 216       opsys=gnu-linux
 217       AC_DEFINE(GNU_LINUX,,GNU Linux)
 218   ;;
 219   *-nec-sysv4*)
 220       AC_CHECK_LIB(nsl, gethostbyname)
 221       AC_CHECK_LIB(socket, socket)
 222   ;;
 223   *-freebsd3.2)
 224       AC_DEFINE(FREEBSD_32,,FreeBSD 3.2)
 225   ;;
 226   *-openbsd*)
 227       opsys=openbsd
 228       AC_DEFINE(OPEN_BSD,,OpenBSD)
 229   ;;
 230   *-bsdi*)
 231       opsys=bsdi
 232       OTHER_METHOD="mtu_kvm.o"
 233       AC_CHECK_LIB(kvm, main)
 234   ;;
 235 esac
 236
 237 dnl ---------------------
 238 dnl Integrated VTY option
 239 dnl ---------------------
 240 case "${enable_vtysh}" in
 241   "yes") VTYSH="vtysh";
 242          AC_DEFINE(VTYSH,,VTY shell)
 243          AC_CHECK_LIB(tinfo, tputs, , AC_CHECK_LIB(ncurses, tputs))
 244          AC_CHECK_LIB(readline, main)
 245          if test $ac_cv_lib_readline_main = no; then
 246            AC_MSG_ERROR([vtysh needs libreadline but was not found on your system.])
 247          fi
 248          AC_CHECK_HEADER(readline/history.h)
 249          if test $ac_cv_header_readline_history_h = no;then
 250            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 251          fi
 252          AC_CHECK_LIB(readline, rl_completion_matches)
 253          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 254            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 255          fi
 256          ;;
 257   "no" ) VTYSH="";;
 258   *    ) ;;
 259 esac
 260
 261 dnl ----------
 262 dnl PAM module
 263 dnl ----------
 264 if test "$with_libpam" = "yes"; then
 265   AC_CHECK_HEADER(security/pam_misc.h)
 266   if test "$ac_cv_header_security_pam_misc_h" = yes; then
 267     AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 268     AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 269     pam_conv_func="misc_conv"
 270   fi
 271   AC_CHECK_HEADER(security/openpam.h)
 272   if test "$ac_cv_header_security_openpam_h" = yes; then
 273     AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 274     AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 275     pam_conv_func="openpam_ttyconv"
 276   fi
 277   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 278     AC_MSG_WARN([*** pam support will not be built ***])
 279     with_libpam="no"
 280   fi
 281 fi
 282
 283 if test "$with_libpam" = "yes"; then
 284 dnl took this test from proftpd's configure.in and suited to our needs
 285 dnl -------------------------------------------------------------------------
 286 dnl
 287 dnl This next check looks funky due to a linker problem with some versions
 288 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 289 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 290 dnl with RedHat 6.2 and Debian 2.2 or better.
 291 AC_CHECK_LIB(pam, pam_start,
 292   [AC_CHECK_LIB(pam, $pam_conv_func,
 293     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 294      LIBPAM="-lpam"],
 295     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 296      LIBPAM="-lpam -lpam_misc"]
 297     )
 298   ],
 299
 300   [AC_CHECK_LIB(pam, pam_end,
 301     [AC_CHECK_LIB(pam, $pam_conv_func,
 302       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 303        LIBPAM="-lpam -ldl"],
 304       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 305        LIBPAM="-lpam -ldl -lpam_misc"]
 306      )
 307   ],AC_MSG_WARN([*** pam support will not be built ***]),
 308   [-ldl])
 309   ]
 310 )
 311 fi
 312 AC_SUBST(LIBPAM)
 313
 314 dnl -------------------------------
 315 dnl Endian-ness check
 316 dnl -------------------------------
 317 AC_WORDS_BIGENDIAN
 318
 319 dnl -------------------------------
 320 dnl check the size in byte of the C
 321 dnl -------------------------------
 322 dnl AC_CHECK_SIZEOF(char)
 323 dnl AC_CHECK_SIZEOF(int)
 324 dnl AC_CHECK_SIZEOF(short)
 325 dnl AC_CHECK_SIZEOF(long)
 326
 327 dnl ----------------------------
 328 dnl check existance of functions
 329 dnl ----------------------------
 330 AC_CHECK_FUNCS(bcopy bzero strerror inet_aton daemon snprintf vsnprintf strlcat strlcpy if_nametoindex if_indextoname getifaddrs)
 331 AC_CHECK_FUNCS(setproctitle, ,
 332   [AC_CHECK_LIB(util, setproctitle,
 333      [LIBS="$LIBS -lutil"
 334       AC_DEFINE(HAVE_SETPROCTITLE,, Have setproctitle)
 335      ]
 336    )
 337   ]
 338 )
 339
 340 dnl ------------------------------------
 341 dnl Determine routing get and set method
 342 dnl ------------------------------------
 343 AC_MSG_CHECKING(zebra between kernel interface method)
 344 if test x"$opsys" = x"gnu-linux"; then
 345   if test "${enable_netlink}" = "yes";then
 346     AC_MSG_RESULT(netlink)
 347     RT_METHOD=rt_netlink.o
 348     AC_DEFINE(HAVE_NETLINK,,netlink)
 349     netlink=yes
 350   elif test "${enable_netlink}" = "no"; then
 351     AC_MSG_RESULT(ioctl)
 352     RT_METHOD=rt_ioctl.o
 353     netlink=no
 354   else
 355     AC_MSG_RESULT(netlink)
 356     RT_METHOD=rt_netlink.o
 357     AC_DEFINE(HAVE_NETLINK,,netlink)
 358     netlink=yes
 359   fi
 360 else
 361   if test "$opsys" = "sol2-6";then
 362     AC_MSG_RESULT(solaris)
 363     KERNEL_METHOD="kernel_socket.o"
 364     RT_METHOD="rt_socket.o"
 365   else
 366     AC_TRY_RUN([#include <errno.h>
 367 #include <sys/types.h>
 368 #include <sys/socket.h>
 369
 370 main ()
 371 {
 372   int ac_sock;
 373
 374   ac_sock = socket (AF_ROUTE, SOCK_RAW, 0);
 375   if (ac_sock < 0 && errno == EINVAL)
 376     exit (1);
 377   exit (0);
 378 }],
 379   [KERNEL_METHOD=kernel_socket.o
 380    RT_METHOD=rt_socket.o
 381    AC_MSG_RESULT(socket)],
 382   [RT_METHOD=rt_ioctl.o
 383    AC_MSG_RESULT(ioctl)],
 384   [KERNEL_METHOD=kernel_socket.o
 385    RT_METHOD=rt_socket.o
 386    AC_MSG_RESULT(socket)])
 387   fi
 388 fi
 389 AC_SUBST(RT_METHOD)
 390 AC_SUBST(KERNEL_METHOD)
 391 AC_SUBST(OTHER_METHOD)
 392
 393 dnl ------------------------------
 394 dnl check kernel route read method
 395 dnl ------------------------------
 396 AC_CACHE_CHECK(route read method check, zebra_rtread,
 397 [if test "$netlink" = yes; then
 398   RTREAD_METHOD="rtread_netlink.o"
 399   zebra_rtread="netlink"
 400 else
 401 for zebra_rtread in /proc/net/route /dev/ip /dev/null;
 402 do
 403   test x`ls $zebra_rtread 2>/dev/null` = x"$zebra_rtread" && break
 404 done
 405 case $zebra_rtread in
 406   "/proc/net/route") RTREAD_METHOD="rtread_proc.o"
 407                      zebra_rtread="proc";;
 408   "/dev/ip")
 409                      case "$host" in
 410                        *-freebsd*)    RTREAD_METHOD=rtread_sysctl.o
 411                                       zebra_rtread="sysctl";;
 412                        *)             RTREAD_METHOD="rtread_getmsg.o"
 413                                       zebra_rtread="getmsg";;
 414                      esac;;
 415   *)                 RTREAD_METHOD="rtread_sysctl.o"
 416                      zebra_rtread="sysctl";;
 417 esac
 418 fi])
 419 AC_SUBST(RTREAD_METHOD)
 420
 421 dnl -----------------------------
 422 dnl check interface lookup method
 423 dnl -----------------------------
 424 AC_MSG_CHECKING(interface looking up method)
 425 if test "$netlink" = yes; then
 426   AC_MSG_RESULT(netlink)
 427   IF_METHOD=if_netlink.o
 428 else
 429   if test "$opsys" = "sol2-6";then
 430     AC_MSG_RESULT(solaris)
 431     IF_METHOD=if_ioctl.o
 432   elif test "$opsys" = "openbsd";then
 433     AC_MSG_RESULT(openbsd)
 434     IF_METHOD=if_ioctl.o
 435   elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
 436     AC_MSG_RESULT(sysctl)
 437     IF_METHOD=if_sysctl.o
 438     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 439   else
 440     AC_MSG_RESULT(ioctl)
 441     IF_METHOD=if_ioctl.o
 442   fi
 443 fi
 444 AC_SUBST(IF_METHOD)
 445
 446 dnl -----------------------
 447 dnl check proc file system.
 448 dnl -----------------------
 449 if test -r /proc/net/dev; then
 450   AC_DEFINE(HAVE_PROC_NET_DEV,,/proc/net/dev)
 451   IF_PROC=if_proc.o
 452 fi
 453
 454 if test -r /proc/net/if_inet6; then
 455   AC_DEFINE(HAVE_PROC_NET_IF_INET6,,/proc/net/if_inet6)
 456   IF_PROC=if_proc.o
 457 fi
 458 AC_SUBST(IF_PROC)
 459
 460 dnl -----------------------------
 461 dnl check ipforward detect method
 462 dnl -----------------------------
 463 AC_CACHE_CHECK(ipforward method check, zebra_ipforward_path,
 464 [for zebra_ipforward_path in /proc/net/snmp /dev/ip /dev/null;
 465 do
 466   test x`ls $zebra_ipforward_path 2>/dev/null` = x"$zebra_ipforward_path" && break
 467 done
 468 case $zebra_ipforward_path in
 469   "/proc/net/snmp")  IPFORWARD=ipforward_proc.o
 470                      zebra_ipforward_path="proc";;
 471   "/dev/ip")
 472                      case "$host" in
 473                        *-nec-sysv4*)  IPFORWARD=ipforward_ews.o
 474                                       zebra_ipforward_path="ews";;
 475                        *-freebsd*)    IPFORWARD=ipforward_sysctl.o
 476                                       zebra_ipforward_path="sysctl";;
 477                        *)             IPFORWARD=ipforward_solaris.o
 478                                       zebra_ipforward_path="solaris";;
 479                      esac;;
 480   *)                 IPFORWARD=ipforward_sysctl.o
 481                      zebra_ipforward_path="sysctl";;
 482 esac])
 483 AC_SUBST(IPFORWARD)
 484
 485 AC_CHECK_FUNCS(getaddrinfo, [have_getaddrinfo=yes], [have_getaddrinfo=no])
 486
 487 dnl ----------
 488 dnl IPv6 check
 489 dnl ----------
 490 AC_MSG_CHECKING(whether does this OS have IPv6 stack)
 491 if test "${enable_ipv6}" = "no"; then
 492   AC_MSG_RESULT(disabled)
 493 else
 494 dnl ----------
 495 dnl INRIA IPv6
 496 dnl ----------
 497   if grep IPV6_INRIA_VERSION /usr/include/netinet/in.h >/dev/null 2>&1; then
 498     zebra_cv_ipv6=yes
 499     AC_DEFINE(HAVE_IPV6,1,INRIA IPv6)
 500     AC_DEFINE(INRIA_IPV6,1,INRIA IPv6)
 501     RIPNGD="ripngd"
 502     OSPF6D="ospf6d"
 503     LIB_IPV6=""
 504     AC_MSG_RESULT(INRIA IPv6)
 505 dnl ---------
 506 dnl KAME IPv6
 507 dnl ---------
 508   elif grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
 509     zebra_cv_ipv6=yes
 510     AC_DEFINE(HAVE_IPV6,1,KAME IPv6)
 511     AC_DEFINE(KAME,1,KAME IPv6)
 512     RIPNGD="ripngd"
 513     OSPF6D="ospf6d"
 514     if test -d /usr/local/v6/lib -a -f /usr/local/v6/lib/libinet6.a; then
 515       LIB_IPV6="-L/usr/local/v6/lib -linet6"
 516     fi
 517     AC_MSG_RESULT(KAME)
 518 dnl -------------------------
 519 dnl MUSICA IPv6
 520 dnl  default host check
 521 dnl  It is not used by Kheops
 522 dnl -------------------------
 523   elif grep MUSICA /usr/include6/netinet6/in6.h >/dev/null 2>&1; then
 524     zebra_cv_ipv6=yes
 525     AC_DEFINE(HAVE_IPV6,1,Musicia IPv6)
 526     AC_DEFINE(MUSICA,1,Musica IPv6 stack)
 527     AC_DEFINE(KAME,1,KAME IPv6 stack)
 528     RIPNGD="ripngd"
 529     OSPF6D="ospf6d"
 530     if test -d /usr/local/v6/lib -a -f /usr/local/v6/lib/libinet6.a; then
 531       LIB_IPV6="-L/usr/local/v6/lib -linet6"
 532     fi
 533     AC_MSG_RESULT(MUSICA)
 534 dnl ---------
 535 dnl NRL check
 536 dnl ---------
 537   elif grep NRL /usr/include/netinet6/in6.h >/dev/null 2>&1; then
 538     zebra_cv_ipv6=yes
 539     AC_DEFINE(HAVE_IPV6,1,NRL IPv6)
 540     AC_DEFINE(NRL,1,NRL)
 541     RIPNGD="ripngd"
 542     OSPF6D="ospf6d"
 543     if test x"$opsys" = x"bsdi";then
 544       AC_DEFINE(BSDI_NRL,,BSDI)
 545       AC_MSG_RESULT(BSDI_NRL)
 546     else
 547       AC_MSG_RESULT(NRL)
 548     fi
 549 dnl ----------
 550 dnl Linux IPv6
 551 dnl ----------
 552   elif test "${enable_ipv6}" = "yes"; then
 553     AC_EGREP_CPP(yes, [
 554       #include <linux/version.h>
 555       /* 2.1.128 or later */
 556       #if LINUX_VERSION_CODE >= 0x020180
 557       yes
 558       #endif],
 559       [zebra_cv_ipv6=yes
 560        zebra_cv_linux_ipv6=yes
 561        AC_MSG_RESULT(Linux IPv6)])
 562   else
 563     if test x`ls /proc/net/ipv6_route 2>/dev/null` = x"/proc/net/ipv6_route"
 564      then
 565       zebra_cv_ipv6=yes
 566       zebra_cv_linux_ipv6=yes
 567       AC_MSG_RESULT(Linux IPv6)
 568     fi
 569   fi
 570
 571   if test "$zebra_cv_linux_ipv6" = "yes";then
 572     AC_MSG_CHECKING(for GNU libc >= 2.1)
 573     AC_DEFINE(HAVE_IPV6,1,Linux IPv6)
 574     AC_EGREP_CPP(yes, [
 575 #include <features.h>
 576 #if __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 577   yes
 578 #endif],
 579       [glibc=yes
 580        AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 581        AC_MSG_RESULT(yes)],
 582       AC_MSG_RESULT(no)
 583     )
 584     RIPNGD="ripngd"
 585     OSPF6D="ospf6d"
 586     if test "$glibc" != "yes"; then
 587       INCLUDES="-I/usr/inet6/include"
 588       if test x`ls /usr/inet6/lib/libinet6.a 2>/dev/null` != x;then
 589          LIB_IPV6="-L/usr/inet6/lib -linet6"
 590       fi
 591     fi
 592   fi
 593
 594 dnl -----------------------
 595 dnl Set IPv6 related values
 596 dnl -----------------------
 597   LIBS="$LIB_IPV6 $LIBS"
 598   AC_SUBST(LIB_IPV6)
 599
 600   if test x"$RIPNGD" = x""; then
 601     AC_MSG_RESULT(IPv4 only)
 602   fi
 603 fi
 604
 605 dnl --------------------
 606 dnl Daemon disable check
 607 dnl --------------------
 608 if test "${enable_zebra}" = "no";then
 609   ZEBRA=""
 610 else
 611   ZEBRA="zebra"
 612 fi
 613
 614 if test "${enable_bgpd}" = "no";then
 615   BGPD=""
 616 else
 617   BGPD="bgpd"
 618 fi
 619
 620 if test "${enable_ripd}" = "no";then
 621   RIPD=""
 622 else
 623   RIPD="ripd"
 624 fi
 625
 626 if test "${enable_ospfd}" = "no";then
 627   OSPFD=""
 628 else
 629   OSPFD="ospfd"
 630 fi
 631
 632 OSPFCLIENT=""
 633 if test "${enable_opaque_lsa}" = "yes"; then
 634   if test "${enable_ospfapi}" != "no";then
 635     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
 636
 637     if test "${enable_ospfclient}" != "no";then
 638       OSPFCLIENT="ospfclient"
 639     fi
 640   fi
 641
 642 fi
 643
 644 case "${enable_ripngd}" in
 645   "yes") RIPNGD="ripngd";;
 646   "no" ) RIPNGD="";;
 647   *    ) ;;
 648 esac
 649
 650 case "${enable_ospf6d}" in
 651   "yes") OSPF6D="ospf6d";;
 652   "no" ) OSPF6D="";;
 653   *    ) ;;
 654 esac
 655
 656 if test "${enable_bgp_announce}" = "no";then
 657   AC_DEFINE(DISABLE_BGP_ANNOUNCE,,Disable BGP installation to zebra)
 658 fi
 659
 660 AC_SUBST(ZEBRA)
 661 AC_SUBST(BGPD)
 662 AC_SUBST(RIPD)
 663 AC_SUBST(RIPNGD)
 664 AC_SUBST(OSPFD)
 665 AC_SUBST(OSPF6D)
 666 AC_SUBST(VTYSH)
 667 AC_SUBST(INCLUDES)
 668 AC_SUBST(CURSES)
 669 AC_SUBST(OSPFCLIENT)
 670 AC_SUBST(OSPFAPI)
 671 AC_CHECK_LIB(c, inet_ntop, [AC_DEFINE(HAVE_INET_NTOP,,inet_ntop)])
 672 AC_CHECK_LIB(c, inet_pton, [AC_DEFINE(HAVE_INET_PTON,,inet_pton)])
 673 AC_CHECK_LIB(crypt, crypt)
 674 AC_CHECK_LIB(resolv, res_init)
 675 AC_CHECK_LIB(m, main)
 676
 677 dnl ---------------------------------------------------
 678 dnl BSD/OS 4.1 define inet_XtoY function as __inet_XtoY
 679 dnl ---------------------------------------------------
 680 AC_CHECK_FUNC(__inet_ntop, AC_DEFINE(HAVE_INET_NTOP,,__inet_ntop))
 681 AC_CHECK_FUNC(__inet_pton, AC_DEFINE(HAVE_INET_PTON,,__inet_pton))
 682 AC_CHECK_FUNC(__inet_aton, AC_DEFINE(HAVE_INET_ATON,,__inet_aton))
 683
 684 dnl ---------------------------
 685 dnl check system has GNU regexp
 686 dnl ---------------------------
 687 dnl AC_MSG_CHECKING(whether system has GNU regex)
 688 AC_CHECK_LIB(c, regexec,
 689 [AC_DEFINE(HAVE_GNU_REGEX,,GNU regexp library)
 690  LIB_REGEX=""],
 691 [LIB_REGEX="regex.o"])
 692 AC_SUBST(LIB_REGEX)
 693
 694 dnl ------------------
 695 dnl check SNMP library
 696 dnl ------------------
 697 if test "${enable_snmp}" = "yes";then
 698 dnl  AC_CHECK_LIB(snmp, asn_parse_int, HAVE_SNMP=yes)
 699   if test "${HAVE_SNMP}" = ""; then
 700     old_libs="${LIBS}"
 701     LIBS="-L/usr/lib"
 702     unset ac_cv_lib_snmp_asn_parse_int
 703     AC_CHECK_LIB(crypto, main, NEED_CRYPTO=yes, )
 704     if test "${NEED_CRYPTO}" = ""; then
 705       AC_CHECK_LIB(netsnmp, asn_parse_int, [HAVE_NETSNMP=yes; HAVE_SNMP=yes ])
 706     else
 707       AC_CHECK_LIB(netsnmp, asn_parse_int, [HAVE_NETSNMP=yes; HAVE_SNMP=yes; NEED_CRYPTO=yes;LIBS="$LIBS -lcrypto" ],,"-lcrypto")
 708     fi
 709     LIBS="${old_libs}"
 710   fi
 711   if test "${HAVE_SNMP}" = ""; then
 712     old_libs="${LIBS}"
 713     LIBS="-L/usr/lib"
 714     unset ac_cv_lib_snmp_asn_parse_int
 715     AC_CHECK_LIB(snmp, asn_parse_int, HAVE_SNMP=yes, )
 716     if test "${HAVE_SNMP}" = ""; then
 717       unset ac_cv_lib_snmp_asn_parse_int
 718       AC_CHECK_LIB(crypto, main, NEED_CRYPTO=yes, )
 719       if test "${NEED_CRYPTO}" = "yes"; then
 720         AC_CHECK_LIB(snmp, asn_parse_int, [HAVE_SNMP=yes; NEED_CRYPTO=yes; LIBS="$LIBS -lcrypto" ],,"-lcrypto")
 721       fi
 722     fi
 723     LIBS="${old_libs}"
 724   fi
 725
 726   if test "${HAVE_SNMP}" = ""; then
 727     old_libs="${LIBS}"
 728     LIBS="-L/usr/local/lib"
 729     unset ac_cv_lib_snmp_asn_parse_int
 730     AC_CHECK_LIB(snmp, asn_parse_int, HAVE_SNMP=yes)
 731     if test "${HAVE_SNMP}" = ""; then
 732       unset ac_cv_lib_snmp_asn_parse_int
 733       AC_CHECK_LIB(crypto, main, NEED_CRYPTO=yes, )
 734       if test "${NEED_CRYPTO}" = "yes"; then
 735         AC_CHECK_LIB(snmp, asn_parse_int, [HAVE_SNMP=yes; NEED_CRYPTO=yes; LIBS="$LIBS -lcrypto" ],,"-lcrypto")
 736       fi
 737     fi
 738     LIBS="${old_libs}"
 739   fi
 740
 741   if test "${HAVE_SNMP}" = "yes"; then
 742     for ac_snmp in /usr/include/net-snmp/library/asn1.h /usr/include/ucd-snmp/asn1.h /usr/local/include/ucd-snmp/asn1.h /dev/null
 743     do
 744       test -f "${ac_snmp}" && break
 745     done
 746
 747     case ${ac_snmp} in
 748       /usr/include/net-snmp/*)
 749                   AC_DEFINE(HAVE_SNMP,,SNMP)
 750                   AC_DEFINE(HAVE_NETSNMP,,SNMP)
 751                   AC_DEFINE(UCD_COMPATIBLE,,SNMP)
 752                   CFLAGS="${CFLAGS} -I/usr/include/net-snmp -I/usr/include/net-snmp/library"
 753                   if test "${HAVE_NETSNMP}" = "yes"; then
 754                         LIBS="${LIBS} -lnetsnmp"
 755                   else
 756                         LIBS="${LIBS} -lsnmp"
 757                   fi
 758                   ;;
 759       /usr/include/ucd-snmp/*)
 760                   AC_DEFINE(HAVE_SNMP,,SNMP)
 761                   CFLAGS="${CFLAGS} -I/usr/include/ucd-snmp"
 762                   LIBS="${LIBS} -lsnmp"
 763                   ;;
 764       /usr/local/include/ucd-snmp/*)
 765                   AC_DEFINE(HAVE_SNMP,,SNMP)
 766                   CFLAGS="${CFLAGS} -I/usr/local/include/ucd-snmp"
 767                   LIBS="${LIBS} -L/usr/local/lib -lsnmp"
 768                   ;;
 769     esac
 770     if test "${NEED_CRYPTO}" = "yes"; then
 771       LIBS="${LIBS} -lcrypto"
 772     fi
 773   fi
 774 fi
 775
 776 dnl ----------------------------
 777 dnl check sa_len of sockaddr
 778 dnl ----------------------------
 779 AC_MSG_CHECKING(whether struct sockaddr has a sa_len field)
 780 AC_TRY_COMPILE([#include <sys/types.h>
 781 #include <sys/socket.h>
 782 ],[static struct sockaddr ac_i;int ac_j = sizeof (ac_i.sa_len);],
 783 [AC_MSG_RESULT(yes)
 784  AC_DEFINE(HAVE_SA_LEN,,sa_len)],
 785  AC_MSG_RESULT(no))
 786
 787 dnl ----------------------------
 788 dnl check sin_len of sockaddr_in
 789 dnl ----------------------------
 790 AC_MSG_CHECKING(whether struct sockaddr_in has a sin_len field)
 791 AC_TRY_COMPILE([#include <sys/types.h>
 792 #include <netinet/in.h>
 793 ],[static struct sockaddr_in ac_i;int ac_j = sizeof (ac_i.sin_len);],
 794 [AC_MSG_RESULT(yes)
 795  AC_DEFINE(HAVE_SIN_LEN,,sin_len)],
 796  AC_MSG_RESULT(no))
 797
 798 dnl ----------------------------
 799 dnl check sun_len of sockaddr_un
 800 dnl ----------------------------
 801 AC_MSG_CHECKING(whether struct sockaddr_un has a sun_len field)
 802 AC_TRY_COMPILE([#include <sys/types.h>
 803 #include <sys/un.h>
 804 ],[static struct sockaddr_un ac_i;int ac_j = sizeof (ac_i.sun_len);],
 805 [AC_MSG_RESULT(yes)
 806  AC_DEFINE(HAVE_SUN_LEN,,sun_len)],
 807  AC_MSG_RESULT(no))
 808
 809 dnl -----------------------------------
 810 dnl check sin6_scope_id of sockaddr_in6
 811 dnl -----------------------------------
 812 if test "$zebra_cv_ipv6" = yes; then
 813   AC_MSG_CHECKING(whether struct sockaddr_in6 has a sin6_scope_id field)
 814   AC_TRY_COMPILE([#include <sys/types.h>
 815 #include <netinet/in.h>
 816 ],[static struct sockaddr_in6 ac_i;int ac_j = sizeof (ac_i.sin6_scope_id);],
 817 [AC_MSG_RESULT(yes)
 818  AC_DEFINE(HAVE_SIN6_SCOPE_ID,,scope id)],
 819  AC_MSG_RESULT(no))
 820 fi
 821
 822 dnl ----------------------------
 823 dnl check socklen_t exist or not
 824 dnl ----------------------------
 825 AC_MSG_CHECKING(whther socklen_t is defined)
 826 AC_TRY_COMPILE([#include <sys/types.h>
 827 #include <sys/socket.h>
 828 #include <netinet/in.h>
 829 ],[socklen_t ac_x;],
 830 [AC_MSG_RESULT(yes)
 831  AC_DEFINE(HAVE_SOCKLEN_T,,socklen_t)],
 832  AC_MSG_RESULT(no))
 833
 834 dnl ------------------------
 835 dnl check struct sockaddr_dl
 836 dnl ------------------------
 837 AC_MSG_CHECKING(whether struct sockaddr_dl exist)
 838 AC_EGREP_HEADER(sockaddr_dl,
 839 net/if_dl.h,
 840 [AC_MSG_RESULT(yes)
 841  AC_DEFINE(HAVE_SOCKADDR_DL,,sockaddr_dl)],
 842  AC_MSG_RESULT(no))
 843
 844 dnl --------------------------
 845 dnl check structure ifaliasreq
 846 dnl --------------------------
 847 AC_MSG_CHECKING(whether struct ifaliasreq exist)
 848 AC_EGREP_HEADER(ifaliasreq,
 849 net/if.h,
 850 [AC_MSG_RESULT(yes)
 851  AC_DEFINE(HAVE_IFALIASREQ,,ifaliasreq)],
 852  AC_MSG_RESULT(no))
 853
 854 dnl ----------------------------
 855 dnl check structure in6_aliasreq
 856 dnl ----------------------------
 857 AC_MSG_CHECKING(whether struct in6_aliasreq exist)
 858 AC_EGREP_HEADER(in6_aliasreq,
 859 netinet6/in6_var.h,
 860 [AC_MSG_RESULT(yes)
 861  AC_DEFINE(HAVE_IN6_ALIASREQ,,in6_aliasreq)],
 862  AC_MSG_RESULT(no))
 863
 864 dnl -----------------------------------
 865 dnl check ifra_lifetime of in6_aliasreq
 866 dnl -----------------------------------
 867 AC_MSG_CHECKING(whether in6_aliasreq.ifra_lifetime exist)
 868 AC_TRY_COMPILE([#include <sys/types.h>
 869 #include <netinet6/in6_var.h>
 870 ],[static struct if6_aliasreq ac_i;int ac_j = sizeof (ac_i.ifra_lifetime);],
 871 [AC_MSG_RESULT(yes)
 872  AC_DEFINE(HAVE_IFRA_LIFETIME,,Have in6_aliasreq.ifra_lifetime)],
 873  AC_MSG_RESULT(no))
 874
 875 dnl ---------------------------
 876 dnl check structure rt_addrinfo
 877 dnl ---------------------------
 878 AC_MSG_CHECKING(whether struct rt_addrinfo exist)
 879 AC_EGREP_HEADER(rt_addrinfo,
 880 net/route.h,
 881 [AC_MSG_RESULT(yes)
 882  AC_DEFINE(HAVE_RT_ADDRINFO,,rt_addrinfo)],
 883  AC_MSG_RESULT(no))
 884
 885 dnl --------------------------
 886 dnl check structure in_pktinfo
 887 dnl --------------------------
 888 AC_MSG_CHECKING(whether struct in_pktinfo exist)
 889 AC_TRY_COMPILE([#include <netinet/in.h>
 890 ],[struct in_pktinfo ac_x;],
 891 [AC_MSG_RESULT(yes)
 892  AC_DEFINE(HAVE_INPKTINFO,,in_pktinfo)],
 893  AC_MSG_RESULT(no))
 894
 895 dnl --------------------------------------
 896 dnl checking for getrusage struct and call
 897 dnl --------------------------------------
 898 AC_MSG_CHECKING(whether getrusage is available)
 899 AC_TRY_COMPILE([#include <sys/resource.h>
 900 ],[struct rusage ac_x; getrusage (RUSAGE_SELF, &ac_x);],
 901 [AC_MSG_RESULT(yes)
 902  AC_DEFINE(HAVE_RUSAGE,,rusage)],
 903  AC_MSG_RESULT(no))
 904
 905 dnl -------------------
 906 dnl capabilities checks
 907 dnl -------------------
 908 AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
 909 AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
 910   [AC_MSG_RESULT(yes)
 911    AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
 912    quagga_ac_keepcaps="yes"],
 913    AC_MSG_RESULT(no)
 914 )
 915 if test x"${quagga_ac_keepcaps}" = x"yes"; then
 916   AC_CHECK_HEADERS(sys/capability.h)
 917 fi
 918 if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
 919   AC_CHECK_LIB(cap, cap_init,
 920     [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
 921      LIBCAP="-lcap"
 922     ]
 923   )
 924 fi
 925 AC_SUBST(LIBCAP)
 926
 927 dnl ---------------------------
 928 dnl check for glibc 'backtrace'
 929 dnl ---------------------------
 930 if test "${glibc}" = "yes"; then
 931    AC_CHECK_HEADER(execinfo.h)
 932 fi
 933 if test x"${ac_cv_header_execinfo_h}" = x"yes"; then
 934   AC_CHECK_FUNC(backtrace,
 935     [AC_DEFINE(HAVE_GLIBC_BACKTRACE,,Glibc backtrace)]
 936   )
 937 fi
 938
 939 dnl ----------
 940 dnl configure date
 941 dnl ----------
 942 CONFDATE=`date '+%Y%m%d'`
 943 AC_SUBST(CONFDATE)
 944
 945 dnl ------------------------------
 946 dnl set paths for state directory
 947 dnl ------------------------------
 948 if test "${prefix}" = "NONE"; then
 949   quagga_statedir_prefix="";
 950 else
 951   quagga_statedir_prefix=${prefix}
 952 fi
 953 if test "${localstatedir}" = '${prefix}/var'; then
 954   AC_CACHE_CHECK(state directory,ac_statedir,
 955   [for QUAGGA_STATE_DIR in ${quagga_statedir_prefix}/var/run dnl
 956                         ${quagga_statedir_prefix}/var/adm dnl
 957                         ${quagga_statedir_prefix}/etc dnl
 958                         /var/run        dnl
 959                         /var/adm        dnl
 960                         /etc            dnl
 961                         /dev/null;
 962   do
 963     test -d $QUAGGA_STATE_DIR && break
 964   done
 965   quagga_statedir=$QUAGGA_STATE_DIR])
 966 else
 967   quagga_statedir=${localstatedir}
 968   AC_MSG_CHECKING(directory to use for state file)
 969   AC_MSG_RESULT(${quagga_statedir})
 970 fi
 971 if test $quagga_statedir = "/dev/null"; then
 972     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
 973 fi
 974
 975 AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$quagga_statedir/zebra.pid",zebra PID)
 976 AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$quagga_statedir/ripd.pid",ripd PID)
 977 AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$quagga_statedir/ripngd.pid",ripngd PID)
 978 AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$quagga_statedir/bgpd.pid",bgpd PID)
 979 AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$quagga_statedir/ospfd.pid",ospfd PID)
 980 AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$quagga_statedir/ospf6d.pid",ospf6d PID)
 981 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$quagga_statedir/zserv.api",zebra api socket)
 982 AC_DEFINE_UNQUOTED(ZEBRA_VTYSH_PATH, "$quagga_statedir/zebra.vty",zebra vty socket)
 983 AC_DEFINE_UNQUOTED(RIP_VTYSH_PATH, "$quagga_statedir/ripd.vty",rip vty socket)
 984 AC_DEFINE_UNQUOTED(RIPNG_VTYSH_PATH, "$quagga_statedir/ripngd.vty",ripng vty socket)
 985 AC_DEFINE_UNQUOTED(BGP_VTYSH_PATH, "$quagga_statedir/bgpd.vty",bgpd vty socket)
 986 AC_DEFINE_UNQUOTED(OSPF_VTYSH_PATH, "$quagga_statedir/ospfd.vty",ospfd vty socket)
 987 AC_DEFINE_UNQUOTED(OSPF6_VTYSH_PATH, "$quagga_statedir/ospf6d.vty",ospf6d vty socket)
 988
 989 dnl ---------------------------
 990 dnl Check htonl works correctly
 991 dnl ---------------------------
 992 AC_MSG_CHECKING(for working htonl)
 993 AC_CACHE_VAL(ac_cv_htonl_works, [
 994 AC_TRY_LINK([#ifdef HAVE_SYS_TYPES_H
 995 #include <sys/types.h>
 996 #endif
 997 #ifdef HAVE_NETDB_H
 998 #include <netdb.h>
 999 #endif
1000 #ifdef HAVE_NETINET_IN_H
1001 #include <netinet/in.h>
1002 #endif],
1003 [htonl (0);],
1004 ac_cv_htonl_works=yes,
1005 ac_cv_htonl_works=no)])
1006 AC_MSG_RESULT($ac_cv_htonl_works)
1007
1008 AC_OUTPUT(Makefile lib/Makefile zebra/Makefile ripd/Makefile
1009           ripngd/Makefile bgpd/Makefile ospfd/Makefile
1010           ospf6d/Makefile vtysh/Makefile doc/Makefile
1011           ospfclient/Makefile
1012           redhat/quagga.spec
1013           lib/version.h)
1014
1015 echo "
1016 zebra configuration
1017 -------------------
1018 quagga version           : ${PACKAGE_VERSION}
1019 host operationg system  : ${host_os}
1020 source code location    : ${srcdir}
1021 compiler                : ${CC}
1022 compiler flags          : ${CFLAGS}
1023 linker flags            : ${LDFLAGS} ${LIBS}
1024 state file directory    : ${quagga_statedir}
1025 user to run as          : ${enable_user}
1026 group to run as         : ${enable_group}
1027 group for vty sockets   : ${enable_vty_group}
1028 "