configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.3-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183
 184 dnl Some special handling for ICC later on
 185 if test "$CC" = "icc"; then
 186     cc_is_icc="yes"
 187 fi
 188
 189 PKG_PROG_PKG_CONFIG
 190
 191 dnl it's 2019, sed is sed.
 192 SED=sed
 193 AC_SUBST([SED])
 194
 195 dnl try and enable CFLAGS that are useful for FRR
 196 dnl - specifically, options to control warnings
 197
 198 AC_SUBST([AC_CFLAGS])
 199 AC_USE_SYSTEM_EXTENSIONS
 200 AC_DEFUN([AC_C_FLAG], [{
 201     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 202     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 203         AC_LANG_PUSH([C])
 204         ac_c_flag_save="$CFLAGS"
 205         CFLAGS="$CFLAGS $1"
 206         AC_COMPILE_IFELSE(
 207                 [AC_LANG_PROGRAM([[$4]])],
 208                 [
 209                         cachename=yes
 210                 ], [
 211                         cachename=no
 212                 ])
 213         CFLAGS="$ac_c_flag_save"
 214         AC_LANG_POP([C])
 215     ])
 216     if test "$cachename" = "yes"; then
 217         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 218     else
 219         :
 220         $2
 221     fi
 222     m4_popdef([cachename])
 223 }])
 224
 225 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 226         AC_LANG_PUSH([C])
 227         ac_cflags_save="$CFLAGS"
 228         ac_libs_save="$LIBS"
 229         CFLAGS="$CFLAGS $1"
 230         LIBS="$LIBS $2"
 231         AC_LINK_IFELSE(
 232                 [$3],
 233                 [
 234                         CFLAGS="$ac_cflags_save"
 235                         LIBS="$ac_libs_save"
 236                         m4_default([$5], [
 237                                 AC_MSG_RESULT([yes])
 238                         ])
 239                 ], [
 240                         CFLAGS="$ac_cflags_save"
 241                         LIBS="$ac_libs_save"
 242                         m4_default([$4], [
 243                                 AC_MSG_RESULT([no])
 244                         ])
 245                 ])
 246         AC_LANG_POP([C])
 247         }])
 248
 249 dnl ICC won't bail on unknown options without -diag-error 10006
 250 dnl need to do this first so we get useful results for the other options
 251 if test "$cc_is_icc" = "yes"; then
 252     AC_C_FLAG([-diag-error 10006])
 253 fi
 254
 255 dnl autoconf 2.69 AC_PROG_CC_C99 is "state of the art"
 256 dnl autoconf 2.70 AC_PROG_CC_C99 is deprecated and AC_PROC_CC tries to do C11
 257 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
 258   dnl autoconf < 2.70
 259   AC_PROG_CC_C99
 260
 261   dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 262   ac_cc="$CC"
 263   CC="${CC% -std=gnu99}"
 264   CC="${CC% -std=c99}"
 265
 266   AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 267 ], [
 268   dnl autoconf >= 2.70
 269   if test "$ac_cv_prog_cc_c11" = "no"; then
 270     AC_MSG_ERROR([ISO C11 compiler support (with GNU extensions) is required.])
 271   fi
 272 ])
 273
 274 dnl if the user has specified any CFLAGS, override our settings
 275 if test "$enable_gcov" = "yes"; then
 276    if test "$orig_cflags" = ""; then
 277       AC_C_FLAG([--coverage])
 278       AC_C_FLAG([-O0])
 279    fi
 280
 281    AC_LDFLAGS="${AC_LDFLAGS} --coverage"
 282 fi
 283
 284 if test "$enable_clang_coverage" = "yes"; then
 285    AC_C_FLAG([-fprofile-instr-generate], [
 286      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 287    ])
 288    AC_C_FLAG([-fcoverage-mapping], [
 289      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 290    ])
 291 fi
 292
 293 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 294
 295 if test "$enable_scripting" = "yes"; then
 296    AX_PROG_LUA([5.3], [5.4], [], [
 297      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 298    ])
 299    AX_LUA_HEADERS([], [
 300      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 301    ])
 302    AX_LUA_LIBS([
 303      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 304      LIBS="$LIBS $LUA_LIB"
 305      SCRIPTING=true
 306    ], [
 307      SCRIPTING=false
 308      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 309    ])
 310 fi
 311
 312 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 313 dnl sense to be overridden by the user
 314 if test "$enable_dev_build" = "yes"; then
 315    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 316    if test "$orig_cflags" = ""; then
 317       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 318       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 319       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 320    fi
 321 else
 322    if test "$orig_cflags" = ""; then
 323       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 324       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 325    fi
 326 fi
 327
 328 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 329
 330 dnl always want these CFLAGS
 331 AC_C_FLAG([-fno-omit-frame-pointer])
 332 AC_C_FLAG([-funwind-tables])
 333 AC_C_FLAG([-Wall])
 334 AC_C_FLAG([-Wextra])
 335 AC_C_FLAG([-Wstrict-prototypes])
 336 AC_C_FLAG([-Wmissing-prototypes])
 337 AC_C_FLAG([-Wmissing-declarations])
 338 AC_C_FLAG([-Wpointer-arith])
 339 AC_C_FLAG([-Wbad-function-cast])
 340 AC_C_FLAG([-Wwrite-strings])
 341 AC_C_FLAG([-Wundef])
 342 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 343   AC_C_FLAG([-Wcast-qual])
 344   AC_C_FLAG([-Wmissing-noreturn])
 345   AC_C_FLAG([-Wmissing-format-attribute])
 346   AC_C_FLAG([-Wunreachable-code])
 347   AC_C_FLAG([-Wpacked])
 348   AC_C_FLAG([-Wpadded])
 349   AC_C_FLAG([-Wshadow])
 350 else
 351   AC_C_FLAG([-Wno-unused-result])
 352 fi
 353 AC_C_FLAG([-Wno-unused-parameter])
 354 AC_C_FLAG([-Wno-missing-field-initializers])
 355
 356 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 357 AC_SUBST([CXX_COMPAT_CFLAGS])
 358
 359 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 360 dnl for some reason the string consts get 'promoted' to char *,
 361 dnl triggering a const to non-const conversion warning.
 362 if test "$cc_is_icc" = "yes"; then
 363     AC_C_FLAG([-diag-disable 3179])
 364 fi
 365
 366 if test "$enable_werror" = "yes" ; then
 367   WERROR="-Werror"
 368 fi
 369 AC_SUBST([WERROR])
 370
 371 SAN_FLAGS=""
 372 if test "$enable_address_sanitizer" = "yes"; then
 373   AC_C_FLAG([-fsanitize=address], [
 374     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 375   ], [
 376     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 377   ])
 378 fi
 379 if test "$enable_thread_sanitizer" = "yes"; then
 380   AC_C_FLAG([-fsanitize=thread], [
 381     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 382   ], [
 383     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 384   ])
 385 fi
 386 if test "$enable_memory_sanitizer" = "yes"; then
 387   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 388     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 389   ], [
 390     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 391   ])
 392 fi
 393 if test "$enable_undefined_sanitizer" = "yes"; then
 394   AC_C_FLAG([-fsanitize=undefined], [
 395     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 396   ], [
 397     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 398   ])
 399 fi
 400 AC_SUBST([SAN_FLAGS])
 401
 402 dnl frr-format.so
 403 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 404   AC_C_FLAG([-fplugin=${with_frr_format}], [
 405     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 406   ],,[
 407 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 408 #error plugin not loaded
 409 #endif
 410 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 411 #error plugin too old
 412 #endif
 413   ])
 414 elif test "$with_frr_format" = "no"; then
 415   : #nothing
 416 else
 417   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 418     AC_C_FLAG([-fplugin=frr-format],[
 419       if test "$with_frr_format" = "yes"; then
 420         AC_MSG_ERROR([frr-format plugin requested but not found])
 421       fi
 422     ],,[
 423 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 424 #error plugin not loaded
 425 #endif
 426 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 427 #error plugin too old
 428 #endif
 429     ])
 430   ],,[
 431 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 432 #error plugin not loaded
 433 #endif
 434 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 435 #error plugin too old
 436 #endif
 437   ])
 438 fi
 439
 440 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 441 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 442 #include <stdio.h>
 443 int __attribute__((section("secttest"))) var = 1;
 444 extern int __start_secttest, __stop_secttest;
 445 ]], [[
 446   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 447   printf("%p %p %p\n", a, b, c);
 448 ]])], [
 449   AC_MSG_RESULT(yes)
 450   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 451 ], [
 452   AC_MSG_RESULT(no)
 453 ])
 454
 455 dnl ----------
 456 dnl Essentials
 457 dnl ----------
 458
 459 AX_PTHREAD([
 460   CC="$PTHREAD_CC"
 461   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 462   LIBS="$PTHREAD_LIBS $LIBS"
 463 ], [
 464   AC_MSG_FAILURE([This FRR version needs pthreads])
 465 ])
 466
 467 orig_cflags="$CFLAGS"
 468 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 469
 470 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 471                 [frr_cv_pthread_condattr_setclock=yes],
 472                 [frr_cv_pthread_condattr_setclock=no])
 473 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 474   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 475 fi
 476
 477 AC_CHECK_HEADERS([pthread_np.h],,, [
 478 #include <pthread.h>
 479 ])
 480 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 481
 482 CFLAGS="$orig_cflags"
 483
 484 dnl --------------
 485 dnl Check programs
 486 dnl --------------
 487 AC_PROG_INSTALL
 488 AC_PROG_LN_S
 489 AC_CHECK_TOOL([AR], [ar])
 490
 491 dnl -------
 492 dnl libtool
 493 dnl -------
 494 AC_ARG_ENABLE([static-bin],
 495   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 496 LT_INIT
 497 _LT_CONFIG_LIBTOOL([
 498   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 499     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 500 dnl the -i option is not POSIX sed and the BSDs implement it differently
 501 dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact
 502   sed -e 's%func_warning "relinking%true #\0%'                   libtool > libtool.sed && cat libtool.sed > libtool
 503   sed -e 's%func_warning "remember to run%true #\0%'             libtool > libtool.sed && cat libtool.sed > libtool
 504   sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool
 505   test -f libtool.sed && rm libtool.sed
 506 ])
 507 if test "$enable_static_bin" = "yes"; then
 508   AC_LDFLAGS_EXEC="-static"
 509   if test "$enable_static" != "yes"; then
 510     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 511   fi
 512 fi
 513 if test "$enable_shared" != "yes"; then
 514   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 515 fi
 516 AC_SUBST([AC_LDFLAGS])
 517 AC_SUBST([AC_LDFLAGS_EXEC])
 518 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 519
 520 dnl libtool, the repository of all knowledge related linkers, is too stupid to
 521 dnl correctly tell the linker how to build modules.
 522 if test -z "$module_cmds"; then
 523   module_cmds="`echo \"$archive_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 524 fi
 525 if test -z "$module_expsym_cmds"; then
 526   module_expsym_cmds="`echo \"$archive_expsym_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 527 fi
 528
 529 AC_ARG_ENABLE([rpath],
 530   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 531   [],
 532   [enable_rpath=yes])
 533
 534 dnl $AR and $RANLIB are set by LT_INIT above
 535 AC_MSG_CHECKING([whether $AR supports D option])
 536 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 537   AC_MSG_RESULT([yes])
 538   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 539   ARFLAGS="crD"
 540   AR_FLAGS="crD"
 541 else
 542   AC_MSG_RESULT([no])
 543   ARFLAGS="cru"
 544   AR_FLAGS="cru"
 545 fi
 546 AC_SUBST([ARFLAGS])
 547 AC_SUBST([AR_FLAGS])
 548
 549 AC_MSG_CHECKING([whether $RANLIB supports D option])
 550 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 551   if grep -q -- '-D' conftest.err; then
 552     AC_MSG_RESULT([no])
 553   else
 554     AC_MSG_RESULT([yes])
 555     RANLIB="$RANLIB -D"
 556   fi
 557 else
 558   AC_MSG_RESULT([no])
 559 fi
 560 AC_SUBST([RANLIB])
 561
 562 test -f conftest.err && rm conftest.err
 563 test -f conftest.a && rm conftest.a
 564
 565 dnl ----------------------
 566 dnl Packages configuration
 567 dnl ----------------------
 568 if test -f config.version; then
 569   . ./config.version
 570 elif test -f "${srcdir}/config.version"; then
 571   . "${srcdir}/config.version"
 572 fi
 573 AC_ARG_WITH([pkg-extra-version],
 574   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 575   if test "$withval" = "no"; then
 576     EXTRAVERSION=
 577   else
 578     EXTRAVERSION=$withval
 579   fi
 580 ], [])
 581 AC_ARG_WITH([pkg-git-version],
 582         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 583         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 584 AC_ARG_WITH([clippy],
 585   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 586 AC_ARG_WITH([vtysh_pager],
 587         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 588         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 589 AC_ARG_ENABLE([vtysh],
 590   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 591 AC_ARG_ENABLE([doc],
 592   AS_HELP_STRING([--disable-doc], [do not build docs]))
 593 AC_ARG_ENABLE([doc-html],
 594   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 595 AC_ARG_ENABLE([zebra],
 596   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 597 AC_ARG_ENABLE([bgpd],
 598   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 599 AC_ARG_ENABLE([ripd],
 600   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 601 AC_ARG_ENABLE([ripngd],
 602   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 603 AC_ARG_ENABLE([ospfd],
 604   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 605 AC_ARG_ENABLE([ospf6d],
 606   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 607 AC_ARG_ENABLE([ldpd],
 608   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 609 AC_ARG_ENABLE([nhrpd],
 610   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 611 AC_ARG_ENABLE([eigrpd],
 612   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 613 AC_ARG_ENABLE([babeld],
 614   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 615 AC_ARG_ENABLE([watchfrr],
 616   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 617 AC_ARG_ENABLE([isisd],
 618   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 619 AC_ARG_ENABLE([pimd],
 620   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 621 AC_ARG_ENABLE([pbrd],
 622   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 623 AC_ARG_ENABLE([sharpd],
 624   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 625 AC_ARG_ENABLE([staticd],
 626   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 627 AC_ARG_ENABLE([fabricd],
 628   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 629 AC_ARG_ENABLE([vrrpd],
 630   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 631 AC_ARG_ENABLE([pathd],
 632   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 633 AC_ARG_ENABLE([bgp-announce],
 634   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 635 AC_ARG_ENABLE([bgp-vnc],
 636   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 637 AC_ARG_ENABLE([bgp-bmp],
 638   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 639 AC_ARG_ENABLE([snmp],
 640   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 641 AC_ARG_ENABLE([config_rollbacks],
 642   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 643 AC_ARG_ENABLE([confd],
 644   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 645 AC_ARG_ENABLE([sysrepo],
 646   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 647 AC_ARG_ENABLE([grpc],
 648   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 649 AC_ARG_ENABLE([zeromq],
 650   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 651 AC_ARG_ENABLE([lttng],
 652   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 653 AC_ARG_ENABLE([usdt],
 654   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 655 AC_ARG_WITH([libpam],
 656   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 657 AC_ARG_ENABLE([ospfapi],
 658   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 659 AC_ARG_ENABLE([ospfclient],
 660   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 661                           (this is the default if --disable-ospfapi is set)]))
 662 AC_ARG_ENABLE([multipath],
 663   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 664 AC_ARG_WITH([service_timeout],
 665   AS_HELP_STRING([--with-service-timeout=ARG], [set service timeout value (2 minutes by default), ARG must be digit]))
 666 AC_ARG_ENABLE([user],
 667   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 668 AC_ARG_ENABLE([group],
 669   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 670 AC_ARG_ENABLE([vty_group],
 671   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 672 AC_ARG_ENABLE([configfile_mask],
 673   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 674 AC_ARG_ENABLE([logfile_mask],
 675   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 676 AC_ARG_ENABLE([shell_access],
 677   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 678 AC_ARG_ENABLE([realms],
 679   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 680 AC_ARG_ENABLE([rtadv],
 681   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 682 AC_ARG_ENABLE([irdp],
 683   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 684 AC_ARG_ENABLE([capabilities],
 685   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 686 AC_ARG_ENABLE([gcc_ultra_verbose],
 687   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 688 AC_ARG_ENABLE([backtrace],
 689   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 690 AC_ARG_ENABLE([time-check],
 691   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 692 AC_ARG_ENABLE([cpu-time],
 693   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 694 AC_ARG_ENABLE([pcreposix],
 695   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 696 AC_ARG_ENABLE([fpm],
 697   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 698 AC_ARG_ENABLE([werror],
 699   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 700 AC_ARG_ENABLE([cumulus],
 701   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 702 AC_ARG_ENABLE([datacenter],
 703   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 704 AC_ARG_ENABLE([rr-semantics],
 705   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 706 AC_ARG_ENABLE([protobuf],
 707   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 708 AC_ARG_ENABLE([oldvpn_commands],
 709   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 710 AC_ARG_ENABLE([rpki],
 711   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 712 AC_ARG_ENABLE([clippy-only],
 713   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 714 AC_ARG_ENABLE([numeric_version],
 715   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 716 AC_ARG_ENABLE([gcov],
 717   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 718 AC_ARG_ENABLE([clang_coverage],
 719   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 720 AC_ARG_ENABLE([bfdd],
 721   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 722 AC_ARG_ENABLE([address-sanitizer],
 723   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 724 AC_ARG_ENABLE([thread-sanitizer],
 725   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 726 AC_ARG_ENABLE([memory-sanitizer],
 727   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 728 AC_ARG_ENABLE([undefined-sanitizer],
 729   AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 730 AC_ARG_WITH([crypto],
 731   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 732 AC_ARG_WITH([frr-format],
 733   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 734
 735 AC_ARG_ENABLE([version-build-config],
 736   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 737
 738 #if openssl, else use the internal
 739 AS_IF([test "$with_crypto" = "openssl"], [
 740 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 741 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 742   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 743 else
 744   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 745 fi
 746 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 747 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 748 )
 749
 750 AS_IF([test "$enable_clippy_only" != "yes"], [
 751 AC_CHECK_HEADERS([json-c/json.h])
 752 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 753 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 754   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 755   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 756       AC_MSG_ERROR([libjson is needed to compile])
 757   fi
 758 fi
 759 ])
 760
 761 AC_ARG_ENABLE([dev_build],
 762     AS_HELP_STRING([--enable-dev-build], [build for development]))
 763
 764 AC_ARG_ENABLE([scripting],
 765     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 766
 767 AC_ARG_ENABLE([netlink-debug],
 768   AS_HELP_STRING([--disable-netlink-debug], [don't pretty print netlink debug messages]))
 769
 770 if test "$enable_netlink_debug" != "no" ; then
 771   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 772 fi
 773
 774 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 775
 776 if test "$enable_time_check" != "no" ; then
 777   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 778     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 779   else
 780     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 781   fi
 782 fi
 783
 784 case "${enable_cpu_time}" in
 785   "no")
 786   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 787   ;;
 788   "*")
 789   ;;
 790 esac
 791
 792 if test "$enable_rr_semantics" != "no" ; then
 793   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 794 fi
 795
 796 if test "$enable_datacenter" = "yes" ; then
 797   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 798   DFLT_NAME="datacenter"
 799 else
 800   DFLT_NAME="traditional"
 801 fi
 802
 803 if test "$enable_cumulus" = "yes" ; then
 804   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 805 fi
 806
 807 AC_SUBST([DFLT_NAME])
 808 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 809
 810 if test "$enable_shell_access" = "yes"; then
 811    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 812 fi
 813
 814 #
 815 # Python for clippy
 816 #
 817
 818 AS_IF([test "$host" = "$build"], [
 819   AM_PATH_PYTHON([3])
 820   AC_CHECK_HEADER([gelf.h], [], [
 821     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 822   ])
 823
 824   LIBS_save="$LIBS"
 825   AC_CHECK_LIB([elf], [elf_memory], [], [
 826     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 827   ])
 828
 829   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 830     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 831   ])
 832   AC_CHECK_LIB([elf], [gelf_getnote], [
 833     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 834   ])
 835   LIBS="$LIBS_save"
 836   unset LIBS_save
 837
 838   FRR_PYTHON_DEV
 839 ], [
 840   FRR_PYTHON
 841 ])
 842
 843 FRR_PYTHON_MODULES([pytest])
 844
 845 if test "$enable_doc" != "no"; then
 846   FRR_PYTHON_MODULES([sphinx], , [
 847     if test "$enable_doc" = "yes"; then
 848       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 849     fi
 850   ])
 851 fi
 852 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 853 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 854
 855 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 856   PYSPHINX="-m sphinx"
 857 ], [
 858   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 859 ])
 860 AC_SUBST([PYSPHINX])
 861
 862 #
 863 # Logic for old vpn commands support.
 864 #
 865 if test "$enable_oldvpn_commands" = "yes"; then
 866    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 867 fi
 868
 869 #
 870 # End of logic for protobuf support.
 871 #
 872
 873 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 874 if test "$enable_rtadv" != "no"; then
 875   AC_MSG_RESULT([yes])
 876   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 877 else
 878   AC_MSG_RESULT([no])
 879 fi
 880
 881 if test "$enable_user" = "no"; then
 882   enable_user=""
 883 else
 884   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 885     enable_user="frr"
 886   fi
 887   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 888 fi
 889
 890 if test "$enable_group" = "no"; then
 891   enable_group=""
 892 else
 893   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 894     enable_group="frr"
 895   fi
 896   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 897 fi
 898
 899 if test "$enable_vty_group" = "yes" ; then
 900   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 901 elif test "$enable_vty_group" != ""; then
 902   if test "$enable_vty_group" != "no"; then
 903     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 904   fi
 905 fi
 906 AC_SUBST([enable_user])
 907 AC_SUBST([enable_group])
 908 AC_SUBST([enable_vty_group])
 909
 910 enable_configfile_mask=${enable_configfile_mask:-0600}
 911 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 912 AC_SUBST([enable_configfile_mask])
 913
 914 enable_logfile_mask=${enable_logfile_mask:-0600}
 915 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 916
 917 MPATH_NUM=16
 918
 919 case "${enable_multipath}" in
 920   0)
 921     MPATH_NUM=64
 922     ;;
 923   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 924     MPATH_NUM="${enable_multipath}"
 925     ;;
 926   "")
 927     ;;
 928   *)
 929     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 930     ;;
 931 esac
 932
 933 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 934
 935 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 936
 937
 938 TIMEOUT_MIN=2
 939 case "${with_service_timeout}" in
 940   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 941     TIMEOUT_MIN="${with_service_timeout}"
 942     ;;
 943   0|"")
 944     ;;
 945   *)
 946     AC_MSG_FAILURE([Please specify digit for timeout ARG])
 947     ;;
 948 esac
 949 AC_SUBST([TIMEOUT_MIN])
 950
 951 dnl --------------------
 952 dnl Enable code coverage
 953 dnl --------------------
 954 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 955
 956 dnl ------------------------------------
 957 dnl Alpine only accepts numeric versions
 958 dnl ------------------------------------
 959 if test "$enable_numeric_version" != "" ; then
 960   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 961   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 962 fi
 963
 964 dnl -----------------------------------
 965 dnl Add extra version string to package
 966 dnl name, string and version fields.
 967 dnl -----------------------------------
 968 if test "$EXTRAVERSION" != "" ; then
 969   VERSION="${VERSION}${EXTRAVERSION}"
 970   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 971   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 972   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 973 fi
 974 AC_SUBST([EXTRAVERSION])
 975
 976 if test "$with_pkg_git_version" = "yes"; then
 977         if test -e "${srcdir}/.git"; then
 978                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 979         else    with_pkg_git_version="no"
 980                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 981         fi
 982 fi
 983 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 984
 985 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 986 if test "$OBJCOPY" != ":"; then
 987   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 988     frr_cv_interp=""
 989     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 990       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 991         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 992       fi
 993       test -f conftest.interp && rm conftest.interp
 994     ])
 995   ])
 996 fi
 997 if test -n "$frr_cv_interp"; then
 998   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 999 fi
1000
1001 dnl -------------------------
1002 dnl Check other header files.
1003 dnl -------------------------
1004 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
1005         linux/version.h asm/types.h endian.h sys/endian.h])
1006
1007 ac_stdatomic_ok=false
1008 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
1009 AC_CHECK_HEADER([stdatomic.h],[
1010
1011   AC_MSG_CHECKING([whether _Atomic qualifier works])
1012   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1013 #include <stdatomic.h>
1014 int main(int argc, char **argv) {
1015   _Atomic int i = 0;
1016   return i;
1017 }
1018 ]])], [
1019     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
1020     AC_MSG_RESULT([yes])
1021     ac_stdatomic_ok=true
1022   ], [
1023     AC_MSG_RESULT([no])
1024   ])
1025 ])
1026
1027 AS_IF([$ac_stdatomic_ok], [true], [
1028   AC_MSG_CHECKING([for __atomic_* builtins])
1029   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1030 int main(int argc, char **argv) {
1031   volatile int i = 1;
1032   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1033   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1034 }
1035 ]])], [
1036     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1037     AC_MSG_RESULT([yes])
1038   ], [
1039     AC_MSG_RESULT([no])
1040
1041     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1042     AC_MSG_CHECKING([for __sync_* builtins])
1043     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1044 int main(int argc, char **argv) {
1045   volatile int i = 1;
1046   __sync_fetch_and_sub (&i, 1);
1047   return __sync_val_compare_and_swap (&i, 0, 1);
1048 }
1049 ]])], [
1050       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1051       AC_MSG_RESULT([yes])
1052
1053       AC_MSG_CHECKING([for __sync_swap builtin])
1054       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1055 int main(int argc, char **argv) {
1056   volatile int i = 1;
1057   return __sync_swap (&i, 2);
1058 }
1059 ]])], [
1060         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1061         AC_MSG_RESULT([yes])
1062       ], [
1063         AC_MSG_RESULT([no])
1064       ])
1065
1066     ], [
1067       AC_MSG_RESULT([no])
1068       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1069     ])
1070   ])
1071 ])
1072
1073 needsync=true
1074
1075 AS_IF([$needsync], [
1076   dnl Linux
1077   AC_MSG_CHECKING([for Linux futex() support])
1078   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1079 #ifndef _GNU_SOURCE
1080 #define _GNU_SOURCE
1081 #endif
1082 #include <unistd.h>
1083 #include <limits.h>
1084 #include <sys/time.h>
1085 #include <sys/syscall.h>
1086 #include <linux/futex.h>
1087
1088 int main(void);
1089 ],
1090 [
1091 {
1092   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1093 }
1094 ])], [
1095     AC_MSG_RESULT([yes])
1096     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1097     needsync=false
1098   ], [
1099     AC_MSG_RESULT([no])
1100   ])
1101 ])
1102
1103 AS_IF([$needsync], [
1104   dnl FreeBSD
1105   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1106   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1107 #include <errno.h>
1108 #include <stdlib.h>
1109 #include <sys/types.h>
1110 #include <sys/umtx.h>
1111 int main(void);
1112 ],
1113 [
1114 {
1115   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1116 }
1117 ])], [
1118     AC_MSG_RESULT([yes])
1119     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1120     needsync=false
1121   ], [
1122     AC_MSG_RESULT([no])
1123   ])
1124 ])
1125
1126 AS_IF([$needsync], [
1127   dnl OpenBSD patch (not upstream at the time of writing this)
1128   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1129   AC_MSG_CHECKING([for OpenBSD futex() support])
1130   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1131 #include <sys/futex.h>
1132 int main(void);
1133 ],
1134 [
1135 {
1136   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1137 }
1138 ])], [
1139     AC_MSG_RESULT([yes])
1140     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1141     needsync=false
1142   ], [
1143     AC_MSG_RESULT([no])
1144   ])
1145 ])
1146
1147 dnl Utility macro to avoid retyping includes all the time
1148 m4_define([FRR_INCLUDES],
1149 [#ifdef SUNOS_5
1150 #define _POSIX_C_SOURCE 200809L
1151 #define __EXTENSIONS__
1152 #endif
1153 #include <stdio.h>
1154 #include <stdlib.h>
1155 #include <stddef.h>
1156 #include <sys/types.h>
1157 /* sys/conf.h depends on param.h on FBSD at least */
1158 #include <sys/param.h>
1159 /* Required for MAXSIG */
1160 #include <signal.h>
1161 #include <sys/socket.h>
1162 #ifdef __APPLE__
1163 # define __APPLE_USE_RFC_3542
1164 #endif
1165 #include <netinet/in.h>
1166 #include <sys/time.h>
1167 #include <time.h>
1168 #include <net/if.h>
1169 ])dnl
1170
1171 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1172 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1173 dnl an additional round for it.
1174
1175 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1176
1177 m4_define([FRR_INCLUDES],
1178 FRR_INCLUDES
1179 [#ifdef HAVE_NET_IF_VAR_H
1180 # include <net/if_var.h>
1181 #endif
1182 ])dnl
1183
1184 AC_CHECK_HEADERS([netinet/in_var.h \
1185         net/if_dl.h net/netopt.h \
1186         inet/nd.h netinet/ip_icmp.h \
1187         sys/sysctl.h sys/sockio.h sys/conf.h],
1188         [], [], [FRR_INCLUDES])
1189
1190 AC_CHECK_HEADERS([ucontext.h], [], [],
1191 [#ifndef __USE_GNU
1192 #define __USE_GNU
1193 #endif /* __USE_GNU */
1194 FRR_INCLUDES
1195 ])
1196
1197 m4_define([UCONTEXT_INCLUDES],
1198 [#include <ucontext.h>])dnl
1199
1200 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1201   [], [], [UCONTEXT_INCLUDES])
1202 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1203   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1204    [], [], [UCONTEXT_INCLUDES])],
1205   [], [UCONTEXT_INCLUDES])
1206 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1207   [], [], [UCONTEXT_INCLUDES])
1208
1209 m4_define([FRR_INCLUDES],
1210 FRR_INCLUDES
1211 [
1212 #include <sys/un.h>
1213 #include <netinet/in_systm.h>
1214 #ifdef HAVE_NETINET_IN_VAR_H
1215 # include <netinet/in_var.h>
1216 #endif
1217 #ifdef HAVE_NET_IF_DL_H
1218 # include <net/if_dl.h>
1219 #endif
1220 #ifdef HAVE_NET_NETOPT_H
1221 # include <net/netopt.h>
1222 #endif
1223 #include <net/route.h>
1224 #ifdef HAVE_INET_ND_H
1225 # include <inet/nd.h>
1226 #endif
1227 #include <arpa/inet.h>
1228 /* Required for IDRP */
1229 #ifdef HAVE_NETINET_IP_ICMP_H
1230 # include <netinet/ip_icmp.h>
1231 #endif
1232 ])dnl
1233
1234 dnl V6 headers are checked below, after we check for v6
1235
1236 is_linux=false
1237
1238 AC_MSG_CHECKING([which operating system interface to use])
1239 case "$host_os" in
1240   sunos* | solaris2*)
1241     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1242     ;;
1243   linux*)
1244     AC_MSG_RESULT([Linux])
1245
1246     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1247     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1248     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1249
1250     dnl Linux has a compilation problem with mixing
1251     dnl netinet/in.h and linux/in6.h they are not
1252     dnl compatible.  There has been discussion on
1253     dnl how to fix it but no real progress on implementation
1254     dnl when they fix it, remove this
1255     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1256
1257     is_linux=true
1258     ;;
1259   openbsd*)
1260     AC_MSG_RESULT([OpenBSD])
1261
1262     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1263     AC_DEFINE([KAME], [1], [KAME IPv6])
1264     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1265     ;;
1266   *)
1267     AC_MSG_RESULT([BSD])
1268
1269     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1270     AC_DEFINE([KAME], [1], [KAME IPv6])
1271     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1272     ;;
1273 esac
1274 AM_CONDITIONAL([LINUX], [${is_linux}])
1275
1276 AC_SYS_LARGEFILE
1277
1278 dnl ------------------------
1279 dnl Integrated REALMS option
1280 dnl ------------------------
1281 if test "$enable_realms" = "yes"; then
1282     case "$host_os" in
1283       linux*)
1284        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1285        ;;
1286       *)
1287        echo "Sorry, only Linux has REALMS support"
1288        exit 1
1289        ;;
1290     esac
1291 fi
1292
1293 dnl ---------------
1294 dnl other functions
1295 dnl ---------------
1296 AC_CHECK_FUNCS([ \
1297         strlcat strlcpy \
1298         getgrouplist \
1299         openat \
1300         unlinkat \
1301         posix_fallocate \
1302         sendmmsg \
1303         ])
1304
1305 AC_CHECK_MEMBERS([struct mmsghdr.msg_hdr], [], [], FRR_INCLUDES)
1306
1307 dnl ##########################################################################
1308 dnl LARGE if block spans a lot of "configure"!
1309 if test "$enable_clippy_only" != "yes"; then
1310 dnl ##########################################################################
1311
1312 #
1313 # Logic for protobuf support.
1314 #
1315 PROTO3=false
1316 if test "$enable_protobuf" = "yes"; then
1317   # Check for protoc & protoc-c
1318
1319   # protoc is not required, it's only for a "be nice" helper target
1320   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1321
1322   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1323   if test "$PROTOC_C" = "/bin/false"; then
1324     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1325   fi
1326
1327   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1328     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1329   ])
1330
1331   PROTO3=true
1332   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1333                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1334                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1335                                             [1], [Have Protobuf version 3]),
1336                                   [PROTO3=false],
1337                                   [#include <google/protobuf-c/protobuf-c.h>])],
1338                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1339
1340   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1341 fi
1342
1343
1344 dnl ---------------------
1345 dnl Integrated VTY option
1346 dnl ---------------------
1347 case "${enable_vtysh}" in
1348 "no")
1349   VTYSH="";;
1350 *)
1351   VTYSH="vtysh";
1352   AC_DEFINE([VTYSH], [1], [VTY shell])
1353
1354   prev_libs="$LIBS"
1355   AC_CHECK_LIB([readline], [main], [
1356     LIBREADLINE="-lreadline"
1357   ], [
1358     dnl readline failed - it might be incorrectly linked and missing its
1359     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1360     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1361       LIBREADLINE="$ac_cv_search_tputs"
1362     ], [
1363       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1364     ])
1365
1366     dnl re-try with the lib we found above
1367     unset ac_cv_lib_readline_main
1368     AC_CHECK_LIB([readline], [main], [
1369       LIBREADLINE="-lreadline $LIBREADLINE"
1370     ], [
1371       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1372     ], [$LIBREADLINE])
1373   ], [])
1374   LIBS="$prev_libs"
1375
1376   AC_CHECK_HEADER([readline/history.h])
1377   if test "$ac_cv_header_readline_history_h" = "no"; then
1378     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1379   fi
1380   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1381   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1382     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1383   fi
1384   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1385   if test "$frr_cv_append_history" = "yes"; then
1386     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1387   fi
1388   ;;
1389 esac
1390 AC_SUBST([LIBREADLINE])
1391
1392 dnl ----------
1393 dnl PAM module
1394 dnl
1395 dnl FRR detects the PAM library it is built against by checking for a
1396 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1397 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1398 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1399 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1400 dnl of OpenPAM.
1401 dnl ----------
1402 if test "$with_libpam" = "yes"; then
1403   AC_CHECK_HEADER([security/pam_misc.h],
1404     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1405      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1406      pam_conv_func="misc_conv"
1407     ],
1408     [], FRR_INCLUDES)
1409   AC_CHECK_HEADER([security/openpam.h],
1410     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1411      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1412      pam_conv_func="openpam_ttyconv"
1413     ],
1414     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1415   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1416     AC_MSG_WARN([*** pam support will not be built ***])
1417     with_libpam="no"
1418   fi
1419 fi
1420
1421 if test "$with_libpam" = "yes"; then
1422 dnl took this test from proftpds configure.in and suited to our needs
1423 dnl -------------------------------------------------------------------------
1424 dnl
1425 dnl This next check looks funky due to a linker problem with some versions
1426 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1427 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1428 dnl with RedHat 6.2 and Debian 2.2 or better.
1429 AC_CHECK_LIB([pam], [pam_start],
1430   [AC_CHECK_LIB([pam], [$pam_conv_func],
1431     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1432      LIBPAM="-lpam"],
1433     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1434      LIBPAM="-lpam -lpam_misc"]
1435     )
1436   ],
1437
1438   [AC_CHECK_LIB([pam], [pam_end],
1439     [AC_CHECK_LIB([pam], [$pam_conv_func],
1440       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1441        LIBPAM="-lpam -ldl"],
1442       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1443        LIBPAM="-lpam -ldl -lpam_misc"]
1444      )
1445   ],AC_MSG_WARN([*** pam support will not be built ***]),
1446   [-ldl])
1447   ]
1448 )
1449 fi
1450 AC_SUBST([LIBPAM])
1451
1452 dnl -------------------------------
1453 dnl bgpd needs pow() and hence libm
1454 dnl -------------------------------
1455 TMPLIBS="$LIBS"
1456 LIBS=""
1457 AC_SEARCH_LIBS([pow], [m], [
1458   LIBM="$LIBS"
1459 ], [
1460   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1461 ])
1462 LIBS="$TMPLIBS"
1463 AC_SUBST([LIBM])
1464
1465 AC_CHECK_FUNCS([ppoll], [
1466   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1467 ])
1468 AC_CHECK_FUNCS([pollts], [
1469   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1470 ])
1471
1472 AC_CHECK_HEADER([asm-generic/unistd.h],
1473                 [AC_CHECK_DECL(__NR_setns,
1474                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1475                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1476                                ])
1477                  AC_CHECK_FUNCS([setns])]
1478                )
1479
1480 dnl --------------------------
1481 dnl Determine IS-IS I/O method
1482 dnl --------------------------
1483 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1484 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1485 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1486 AC_CHECK_HEADER([net/bpf.h])
1487 AC_CHECK_HEADER([sys/dlpi.h])
1488 AC_MSG_CHECKING([zebra IS-IS I/O method])
1489
1490 case "$host_os" in
1491   linux*)
1492     AC_MSG_RESULT([pfpacket])
1493     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1494     ;;
1495   *)
1496     if test "$ac_cv_header_net_bpf_h" = "no"; then
1497       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1498         AC_MSG_RESULT([none])
1499         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1500           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1501         fi
1502         AC_MSG_WARN([*** IS-IS support will not be built ***])
1503         enable_isisd="no"
1504         enable_fabricd="no"
1505       else
1506         AC_MSG_RESULT([DLPI])
1507       fi
1508       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1509     else
1510       AC_MSG_RESULT([BPF])
1511       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1512     fi
1513     ;;
1514 esac
1515 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1516
1517 dnl ---------------------------------------------------------------
1518 dnl figure out how to specify an interface in multicast sockets API
1519 dnl ---------------------------------------------------------------
1520 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1521
1522 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1523         #include <sys/socket.h>
1524         #include <netinet/in.h>
1525         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1526         #include <linux/types.h>
1527 ])
1528
1529 m4_define([FRR_INCLUDES],
1530 FRR_INCLUDES
1531 [#ifdef HAVE_LINUX_MROUTE_H
1532 # include <linux/mroute.h>
1533 #endif
1534 ])dnl
1535
1536 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1537         #include <sys/socket.h>
1538         #include <sys/types.h>
1539         #include <netinet/in.h>
1540         #include <net/route.h>
1541 ])
1542
1543 m4_define([FRR_INCLUDES],
1544 FRR_INCLUDES
1545 [#ifdef HAVE_NETINET_IP_MROUTE_H
1546 # include <netinet/ip_mroute.h>
1547 #endif
1548 ])dnl
1549
1550 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1551 AC_COMPILE_IFELSE(
1552 [ AC_LANG_PROGRAM([[
1553       #include <sys/types.h>
1554       #include <netinet/in.h>
1555   ]], [[
1556       struct group_req gr;
1557       int sock;
1558       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1559   ]])
1560 ],[
1561   AC_MSG_RESULT([yes])
1562   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1563 ],[
1564   AC_MSG_RESULT(no)
1565 ])
1566
1567 dnl ---------------------------------------------------------------
1568 dnl figure out how to check link-state
1569 dnl ---------------------------------------------------------------
1570 AC_CHECK_HEADER([net/if_media.h],
1571   [m4_define([LINK_DETECT_INCLUDES],
1572     FRR_INCLUDES
1573     [#include <net/if_media.h>
1574   ])
1575   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1576     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1577     [], LINK_DETECT_INCLUDES)],
1578   [],
1579   FRR_INCLUDES)
1580
1581 dnl ---------------------------------------------------------------
1582 dnl Additional, newer way to check link-state using ifi_link_state.
1583 dnl Not available in all BSD's when ifmediareq available
1584 dnl ---------------------------------------------------------------
1585 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1586   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1587   [], FRR_INCLUDES)
1588
1589 dnl ------------------------
1590 dnl TCP_MD5SIG socket option
1591 dnl ------------------------
1592
1593 AC_CHECK_HEADER([netinet/tcp.h],
1594    [m4_define([MD5_INCLUDES],
1595       FRR_INCLUDES
1596       [#include <netinet/tcp.h>
1597     ])
1598     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1599    [],
1600    FRR_INCLUDES)
1601 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1602   AC_CHECK_HEADER([linux/tcp.h],
1603        [m4_define([MD5_INCLUDES],
1604           FRR_INCLUDES
1605           [#include <linux/tcp.h>
1606         ])
1607        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1608 fi
1609
1610 LIBS_save="$LIBS"
1611 AC_CHECK_LIB([crypt], [crypt], [], [
1612   AC_CHECK_LIB([crypto], [DES_crypt])
1613 ])
1614 LIBCRYPT="$LIBS"
1615 LIBCRYPT="${LIBCRYPT%$LIBS_save}"
1616 LIBCRYPT="${LIBCRYPT#$LIBS_save}"
1617 AC_SUBST([LIBCRYPT])
1618 LIBS="$LIBS_save"
1619 unset LIBS_save
1620
1621 AC_CHECK_LIB([resolv], [res_init])
1622
1623 dnl ---------------------------
1624 dnl check system has PCRE regexp
1625 dnl ---------------------------
1626 if test "$enable_pcreposix" = "yes"; then
1627   AC_CHECK_LIB([pcreposix], [regexec], [], [
1628     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1629   ])
1630 fi
1631 AC_SUBST([HAVE_LIBPCREPOSIX])
1632
1633 dnl ##########################################################################
1634 dnl test "$enable_clippy_only" != "yes"
1635 fi
1636 dnl END OF LARGE if block
1637 dnl ##########################################################################
1638
1639 dnl ------------------
1640 dnl check C-Ares library
1641 dnl ------------------
1642 PKG_CHECK_MODULES([CARES], [libcares], [
1643   c_ares_found=true
1644 ],[
1645   c_ares_found=false
1646 ])
1647 AM_CONDITIONAL([CARES], [$c_ares_found])
1648
1649
1650 dnl ----------------------------------------------------------------------------
1651 dnl figure out if domainname is available in the utsname struct (GNU extension).
1652 dnl ----------------------------------------------------------------------------
1653 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1654
1655 dnl ------------------
1656 dnl IPv6 header checks
1657 dnl ------------------
1658 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1659         netinet6/in6_var.h netinet6/nd6.h], [], [],
1660         FRR_INCLUDES)
1661
1662 m4_define([FRR_INCLUDES],dnl
1663 FRR_INCLUDES
1664 [#ifdef HAVE_NETINET6_IN6_H
1665 #include <netinet6/in6.h>
1666 #endif
1667 #ifdef HAVE_NETINET_IN6_VAR_H
1668 #include <netinet/in6_var.h>
1669 #endif
1670 #include <netinet/icmp6.h>
1671 #ifdef HAVE_NETINET6_IN6_VAR_H
1672 # include <netinet6/in6_var.h>
1673 #endif
1674 #ifdef HAVE_NETINET6_ND6_H
1675 # include <netinet6/nd6.h>
1676 #endif
1677 ])dnl
1678
1679 dnl --------------------
1680 dnl Daemon disable check
1681 dnl --------------------
1682
1683 AS_IF([test "$enable_bgpd" != "no"], [
1684   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1685 ])
1686
1687 AS_IF([test "$enable_ripd" != "no"], [
1688   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1689 ])
1690
1691 AS_IF([test "$enable_ripngd" != "no"], [
1692   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1693 ])
1694
1695 AS_IF([test "$enable_ospfd" != "no"], [
1696   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1697 ])
1698
1699 AS_IF([test "$enable_ospf6d" != "no"], [
1700   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1701 ])
1702
1703 AS_IF([test "$enable_ldpd" != "no"], [
1704   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1705 ])
1706
1707 AS_IF([test "$enable_nhrpd" != "no"], [
1708   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1709 ])
1710
1711 AS_IF([test "$enable_eigrpd" != "no"], [
1712   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1713 ])
1714
1715 AS_IF([test "$enable_babeld" != "no"], [
1716   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1717 ])
1718
1719 AS_IF([test "$enable_isisd" != "no"], [
1720   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1721 ])
1722
1723 AS_IF([test "$enable_pimd" != "no"], [
1724   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1725 ])
1726
1727 AS_IF([test "$enable_pbrd" != "no"], [
1728   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1729 ])
1730
1731 AS_IF([test "$enable_sharpd" = "yes"], [
1732   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1733 ])
1734
1735 AS_IF([test "$enable_staticd" != "no"], [
1736   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1737 ])
1738
1739 AS_IF([test "$enable_fabricd" != "no"], [
1740   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1741 ])
1742
1743 AS_IF([test "$enable_vrrpd" != "no"], [
1744   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1745 ])
1746
1747 if test "$enable_bfdd" = "no"; then
1748   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1749   BFDD=""
1750 else
1751   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1752   BFDD="bfdd"
1753
1754   case $host_os in
1755     linux*)
1756       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1757       ;;
1758
1759     *)
1760       AC_DEFINE([BFD_BSD], [1], [bfdd])
1761       ;;
1762   esac
1763 fi
1764
1765 AS_IF([test "$enable_pathd" != "no"], [
1766   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1767 ])
1768
1769
1770 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1771   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1772 fi
1773
1774 NHRPD=""
1775 case "$host_os" in
1776   linux*)
1777     case "${enable_nhrpd}" in
1778       no)
1779         ;;
1780       yes)
1781         if test "$enable_clippy_only" != "yes"; then
1782         if test "$c_ares_found" != "true" ; then
1783           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1784         fi
1785         fi
1786         NHRPD="nhrpd"
1787         ;;
1788       *)
1789         if test "$c_ares_found" = "true" ; then
1790           NHRPD="nhrpd"
1791         fi
1792         ;;
1793     esac
1794     ;;
1795   *)
1796     if test "$enable_nhrpd" = "yes"; then
1797       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1798     fi
1799     ;;
1800 esac
1801
1802 if test "$enable_watchfrr" = "no";then
1803   WATCHFRR=""
1804 else
1805   WATCHFRR="watchfrr"
1806 fi
1807
1808 OSPFCLIENT=""
1809 if test "$enable_ospfapi" != "no";then
1810     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1811
1812   if test "$enable_ospfclient" != "no";then
1813       OSPFCLIENT="ospfclient"
1814   fi
1815 fi
1816
1817 if test "$enable_bgp_announce" = "no";then
1818   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1819 else
1820   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1821 fi
1822
1823 if test "$enable_bgp_vnc" != "no";then
1824   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1825 fi
1826
1827 bgpd_bmp=false
1828 case "${enable_bgp_bmp}" in
1829   no)
1830     ;;
1831   yes)
1832     if test "$c_ares_found" != "true" ; then
1833       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1834     fi
1835     bgpd_bmp=true
1836     ;;
1837   *)
1838     if test "$c_ares_found" = "true" ; then
1839       bgpd_bmp=true
1840     fi
1841     ;;
1842 esac
1843
1844 if test "$enable_version_build_config" != "no";then
1845   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1846 fi
1847
1848 dnl ##########################################################################
1849 dnl LARGE if block
1850 if test "$enable_clippy_only" != "yes"; then
1851 dnl ##########################################################################
1852
1853 dnl ------------------
1854 dnl check Net-SNMP library
1855 dnl ------------------
1856 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1857    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1858    if test "$NETSNMP_CONFIG" = "no"; then
1859       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1860    fi
1861    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1862    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1863    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1864    # among other things we avoid a GPL vs. OpenSSL license conflict here
1865    for removelib in crypto ssl sensors pci wrap; do
1866      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1867    done
1868    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1869    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1870 int main(void);
1871 ],
1872 [
1873 {
1874   return 0;
1875 }
1876 ])], [
1877      AC_MSG_RESULT([no])
1878      AC_MSG_ERROR([--enable-snmp given but not usable])])
1879    case "${enable_snmp}" in
1880      yes)
1881       SNMP_METHOD=agentx
1882       ;;
1883      agentx)
1884       SNMP_METHOD="${enable_snmp}"
1885       ;;
1886      *)
1887       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1888       ;;
1889    esac
1890    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1891    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1892 fi
1893 AC_SUBST([SNMP_LIBS])
1894 AC_SUBST([SNMP_CFLAGS])
1895
1896 dnl ---------------
1897 dnl libyang
1898 dnl ---------------
1899 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1900   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1901 ])
1902 ac_cflags_save="$CFLAGS"
1903 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1904 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1905   AC_MSG_ERROR([m4_normalize([
1906     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1907     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1908   ])
1909 ], [[#include <libyang/libyang.h>]])
1910 CFLAGS="$ac_cflags_save"
1911
1912 dnl ---------------
1913 dnl configuration rollbacks
1914 dnl ---------------
1915 SQLITE3=false
1916 if test "$enable_config_rollbacks" = "yes"; then
1917   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1918     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1919     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1920     SQLITE3=true
1921   ], [
1922     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1923   ])
1924 fi
1925
1926 dnl ---------------
1927 dnl confd
1928 dnl ---------------
1929 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1930    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1931    if test "$CONFD" = "/bin/false"; then
1932       AC_MSG_ERROR([confd was not found on your system.])]
1933    fi
1934    AC_CHECK_PROG([CONFDC], [confdc], [confdc], [/bin/false], "${enable_confd}/bin")
1935    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1936    AC_SUBST([CONFD_CFLAGS])
1937    CONFD_LIBS="-lconfd"
1938    AC_SUBST([CONFD_LIBS])
1939    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1940 fi
1941
1942 dnl ---------------
1943 dnl sysrepo
1944 dnl ---------------
1945 if test "$enable_sysrepo" = "yes"; then
1946   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1947       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1948       SYSREPO=true],
1949       [SYSREPO=false
1950       AC_MSG_ERROR([sysrepo was not found on your system.])]
1951   )
1952 fi
1953
1954 dnl ---------------
1955 dnl gRPC
1956 dnl ---------------
1957 if test "$enable_grpc" = "yes"; then
1958   AC_LANG_PUSH([C++])
1959   AX_CXX_COMPILE_STDCXX([11], [ext])
1960   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
1961     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1962     if test "$PROTOC" = "/bin/false"; then
1963       AC_MSG_FAILURE([grpc requested but protoc not found.])
1964     fi
1965
1966     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1967     GRPC=true
1968   ], [
1969     GRPC=false
1970     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1971   ])
1972   AC_LANG_POP([C++])
1973 fi
1974
1975 dnl -----
1976 dnl LTTng
1977 dnl -----
1978 if test "$enable_lttng" = "yes"; then
1979   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.9.0], [
1980     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1981     LTTNG=true
1982   ], [
1983     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1984   ])
1985 fi
1986
1987 dnl ----
1988 dnl USDT
1989 dnl ----
1990 if test "$enable_usdt" = "yes"; then
1991   AC_CHECK_HEADERS([sys/sdt.h], [
1992     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1993     USDT=true
1994   ], [
1995     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1996   ])
1997 fi
1998
1999 dnl ------
2000 dnl ZeroMQ
2001 dnl ------
2002 if test "$enable_zeromq" != "no"; then
2003   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2004     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2005     ZEROMQ=true
2006   ], [
2007     if test "$enable_zeromq" = "yes"; then
2008       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2009     fi
2010   ])
2011 fi
2012
2013 dnl ------------------------------------
2014 dnl Enable RPKI and add librtr to libs
2015 dnl ------------------------------------
2016 if test "$enable_rpki" = "yes"; then
2017   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
2018       [RPKI=true],
2019       [RPKI=false
2020       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2021   )
2022 fi
2023
2024 dnl ------------------------------------
2025 dnl pimd is not supported on OpenBSD and MacOS
2026 dnl ------------------------------------
2027 if test "$enable_pimd" != "no"; then
2028 AC_MSG_CHECKING([for pimd OS support])
2029 case "$host_os" in
2030   darwin*)
2031     AC_MSG_RESULT([no])
2032     enable_pimd="no"
2033     ;;
2034   openbsd*)
2035     AC_MSG_RESULT([no])
2036     enable_pimd="no"
2037     ;;
2038   *)
2039     AC_MSG_RESULT([yes])
2040     ;;
2041 esac
2042 fi
2043
2044 dnl -------------------------------------
2045 dnl VRRP is only supported on linux
2046 dnl -------------------------------------
2047 if test "$enable_vrrpd" != "no"; then
2048 AC_MSG_CHECKING([for VRRP OS support])
2049 case "$host_os" in
2050   linux*)
2051     AC_MSG_RESULT([yes])
2052     ;;
2053   *)
2054     AC_MSG_RESULT([no])
2055     enable_vrrpd="no"
2056     ;;
2057 esac
2058 fi
2059
2060 dnl ------------------------------------------
2061 dnl Check whether rtrlib was build with ssh support
2062 dnl ------------------------------------------
2063 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2064 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2065                         [[struct tr_ssh_config config;]])],
2066         [AC_MSG_RESULT([yes])
2067         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2068         AC_MSG_RESULT([no])
2069 )
2070
2071 dnl ---------------
2072 dnl dlopen & dlinfo
2073 dnl ---------------
2074 LIBS_save="$LIBS"
2075 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2076   AC_MSG_ERROR([unable to find the dlopen()])
2077 ])
2078
2079 AC_CHECK_HEADERS([link.h])
2080
2081 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2082   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2083 #include <stdlib.h>
2084 #ifdef HAVE_LINK_H
2085 #include <link.h>
2086 #endif
2087 #include <dlfcn.h>
2088 ]], [[
2089   char origin[1];
2090   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2091 ]])], [
2092     frr_cv_rtld_di_origin=yes
2093   ], [
2094     frr_cv_rtld_di_origin=no
2095   ])
2096 ])
2097 if test "$frr_cv_rtld_di_origin" = "yes"; then
2098   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2099 fi
2100
2101 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2102   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2103 #include <stdlib.h>
2104 #ifdef HAVE_LINK_H
2105 #include <link.h>
2106 #endif
2107 #include <dlfcn.h>
2108 ]], [[
2109   struct link_map *lm = NULL;
2110   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2111 ]])], [
2112     frr_cv_rtld_di_linkmap=yes
2113   ], [
2114     frr_cv_rtld_di_linkmap=no
2115   ])
2116 ])
2117 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2118   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2119 fi
2120
2121 LIBDL="$LIBS"
2122 LIBDL="${LIBDL%$LIBS_save}"
2123 LIBDL="${LIBDL#$LIBS_save}"
2124 AC_SUBST([LIBDL])
2125 LIBS="$LIBS_save"
2126 unset LIBS_save
2127
2128 dnl ##########################################################################
2129 dnl test "$enable_clippy_only" != "yes"
2130 fi
2131 dnl END OF LARGE if block
2132 dnl ##########################################################################
2133
2134 dnl ---------------------------
2135 dnl sockaddr and netinet checks
2136 dnl ---------------------------
2137 AC_CHECK_TYPES([
2138         struct sockaddr_dl,
2139         struct vifctl, struct mfcctl, struct sioc_sg_req,
2140         vifi_t, struct sioc_vif_req, struct igmpmsg,
2141         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2142         struct nd_opt_adv_interval,
2143         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2144         struct nd_opt_rdnss, struct nd_opt_dnssl],
2145         [], [], FRR_INCLUDES)
2146
2147 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2148         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2149         struct sockaddr_dl.sdl_len,
2150         struct if6_aliasreq.ifra_lifetime,
2151         struct nd_opt_adv_interval.nd_opt_ai_type],
2152         [], [], FRR_INCLUDES)
2153
2154 dnl ---------------------------
2155 dnl IRDP/pktinfo/icmphdr checks
2156 dnl ---------------------------
2157
2158 AC_CHECK_TYPES([struct in_pktinfo], [
2159   AC_CHECK_TYPES([struct icmphdr], [
2160     IRDP=true
2161   ], [
2162     IRDP=false
2163   ], [FRR_INCLUDES])
2164 ], [
2165   IRDP=false
2166 ], [FRR_INCLUDES])
2167
2168 case "${enable_irdp}" in
2169 yes)
2170   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2171   ;;
2172 no)
2173   IRDP=false
2174   ;;
2175 esac
2176
2177
2178 dnl -----------------------
2179 dnl checking for IP_PKTINFO
2180 dnl -----------------------
2181 AC_MSG_CHECKING([for IP_PKTINFO])
2182 AC_COMPILE_IFELSE(
2183 [ AC_LANG_PROGRAM([[
2184         #include <netdb.h>
2185    ]], [[
2186         int opt = IP_PKTINFO;
2187    ]])
2188 ],[
2189   AC_MSG_RESULT([yes])
2190   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2191 ],[
2192   AC_MSG_RESULT([no])
2193 ])
2194
2195 dnl ---------------------------
2196 dnl checking for IP_RECVDSTADDR
2197 dnl ---------------------------
2198 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2199 AC_COMPILE_IFELSE(
2200 [ AC_LANG_PROGRAM([[
2201         #include <netinet/in.h>
2202   ]], [[
2203         int opt = IP_RECVDSTADDR;
2204   ]])
2205 ],[
2206   AC_MSG_RESULT([yes])
2207   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2208 ],[
2209   AC_MSG_RESULT([no])
2210 ])
2211
2212 dnl ----------------------
2213 dnl checking for IP_RECVIF
2214 dnl ----------------------
2215 AC_MSG_CHECKING([for IP_RECVIF])
2216 AC_COMPILE_IFELSE(
2217 [ AC_LANG_PROGRAM([[
2218         #include <netinet/in.h>
2219   ]], [[
2220         int opt = IP_RECVIF;
2221   ]])
2222 ],[
2223   AC_MSG_RESULT([yes])
2224   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2225 ],[
2226   AC_MSG_RESULT([no])
2227 ])
2228
2229 dnl ----------------------
2230 dnl checking for SO_BINDANY
2231 dnl ----------------------
2232 AC_MSG_CHECKING([for SO_BINDANY])
2233 AC_COMPILE_IFELSE(
2234 [ AC_LANG_PROGRAM([[
2235         #include <sys/socket.h>
2236   ]], [[
2237         int opt = SO_BINDANY;
2238   ]])
2239 ],[
2240   AC_MSG_RESULT([yes])
2241   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2242 ],[
2243   AC_MSG_RESULT([no])
2244 ])
2245
2246 dnl ----------------------
2247 dnl checking for IP_FREEBIND
2248 dnl ----------------------
2249 AC_MSG_CHECKING([for IP_FREEBIND])
2250 AC_COMPILE_IFELSE(
2251 [ AC_LANG_PROGRAM([[
2252         #include <netinet/in.h>
2253   ]], [[
2254         int opt = IP_FREEBIND;
2255   ]])
2256 ],[
2257   AC_MSG_RESULT([yes])
2258   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2259 ],[
2260   AC_MSG_RESULT([no])
2261 ])
2262
2263 dnl --------------------------------------
2264 dnl checking for be32dec existence or not
2265 dnl --------------------------------------
2266 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2267         #ifdef HAVE_SYS_ENDIAN_H
2268         #include <sys/endian.h>
2269         #endif
2270         #ifdef HAVE_ENDIAN_H
2271         #include <endian.h>
2272         #endif
2273 ])
2274
2275 dnl --------------------------------------
2276 dnl checking for clock_time monotonic struct and call
2277 dnl --------------------------------------
2278 AC_CHECK_DECL([CLOCK_MONOTONIC],
2279         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2280          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2281 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2282
2283 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2284          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2285 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2286
2287 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2288   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2289 ])
2290
2291 dnl --------------------------------------
2292 dnl checking for flex and bison
2293 dnl --------------------------------------
2294
2295 dnl autoconf 2.69 AC_PROG_LEX has no parameters
2296 dnl autoconf 2.70 AC_PROG_LEX prints a deprecation warning without params
2297 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
2298   dnl autoconf < 2.70
2299   AC_PROG_LEX
2300 ], [
2301   dnl autoconf >= 2.70
2302   AC_PROG_LEX([noyywrap])
2303 ])
2304
2305 AC_MSG_CHECKING([version of flex])
2306 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2307 frr_ac_flex_version="${frr_ac_flex_version##* }"
2308 AC_MSG_RESULT([$frr_ac_flex_version])
2309 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2310   LEX="$SHELL $missing_dir/missing flex"
2311   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2312     AC_MSG_WARN([using pregenerated flex output files])
2313   else
2314     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2315   fi
2316   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2317   AC_SUBST([LEXLIB], [''])
2318 ])
2319
2320 AC_PROG_YACC
2321 dnl thanks GNU bison for this b*llshit...
2322 AC_MSG_CHECKING([version of bison])
2323 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2324 frr_ac_bison_version="${frr_ac_bison_version##* }"
2325 frr_ac_bison_missing="false"
2326 case "x${frr_ac_bison_version}x" in
2327   x2.7*)
2328     BISON_OPENBRACE='"'
2329     BISON_CLOSEBRACE='"'
2330     BISON_VERBOSE=''
2331     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2332     ;;
2333   x2.*|x1.*)
2334     AC_MSG_RESULT([$frr_ac_bison_version])
2335     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2336     frr_ac_bison_missing="true"
2337     ;;
2338   x)
2339     AC_MSG_RESULT([none])
2340     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2341     frr_ac_bison_missing="true"
2342     ;;
2343   x3.[012][^0-9]*)
2344     BISON_OPENBRACE='{'
2345     BISON_CLOSEBRACE='}'
2346     BISON_VERBOSE='-Dparse.error=verbose'
2347     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2348     ;;
2349   *)
2350     BISON_OPENBRACE='{'
2351     BISON_CLOSEBRACE='}'
2352     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2353     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2354     ;;
2355 esac
2356 AC_SUBST([BISON_OPENBRACE])
2357 AC_SUBST([BISON_CLOSEBRACE])
2358 AC_SUBST([BISON_VERBOSE])
2359
2360 if $frr_ac_bison_missing; then
2361   YACC="$SHELL $missing_dir/missing bison -y"
2362   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2363     AC_MSG_WARN([using pregenerated bison output files])
2364   else
2365     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2366   fi
2367 fi
2368
2369 dnl -------------------
2370 dnl capabilities checks
2371 dnl -------------------
2372 if test "$enable_capabilities" != "no"; then
2373   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2374   AC_COMPILE_IFELSE(
2375   [ AC_LANG_PROGRAM([[
2376         #include <sys/prctl.h>
2377     ]], [[
2378         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2379     ]])
2380   ],[AC_MSG_RESULT([yes])
2381      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2382      frr_ac_keepcaps="yes"
2383   ],[AC_MSG_RESULT(no)
2384   ])
2385   if test "$frr_ac_keepcaps" = "yes"; then
2386     AC_CHECK_HEADERS([sys/capability.h])
2387   fi
2388   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2389     AC_CHECK_LIB([cap], [cap_init],
2390       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2391        LIBCAP="-lcap"
2392        frr_ac_lcaps="yes"]
2393     )
2394   fi
2395   if test "$frr_ac_scaps" = "yes" \
2396        -o "$frr_ac_lcaps" = "yes"; then
2397     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2398   fi
2399
2400   case "$host_os" in
2401   linux*)
2402     if test "$enable_clippy_only" != "yes"; then
2403     if test "$frr_ac_lcaps" != "yes"; then
2404       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2405     fi
2406     fi
2407     ;;
2408   esac
2409 else
2410   case "$host_os" in
2411   linux*)
2412     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2413     ;;
2414   esac
2415 fi
2416 AC_SUBST([LIBCAP])
2417
2418 dnl ---------------------------
2419 dnl check for glibc 'backtrace'
2420 dnl ---------------------------
2421 if test "$enable_backtrace" != "no" ; then
2422   backtrace_ok=no
2423   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2424     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2425     backtrace_ok=yes
2426   ], [
2427     true
2428   ])
2429
2430   if test "$backtrace_ok" = "no"; then
2431     AC_CHECK_HEADER([unwind.h], [
2432       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2433         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2434         backtrace_ok=yes
2435       ])
2436     ])
2437   fi
2438
2439   if test "$backtrace_ok" = "no"; then
2440     AC_CHECK_HEADER([execinfo.h], [
2441       AC_SEARCH_LIBS([backtrace], [execinfo], [
2442         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2443         backtrace_ok=yes
2444       ],, [-lm])
2445     ])
2446   fi
2447
2448   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2449     dnl user explicitly requested backtrace but we failed to find support
2450     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2451   fi
2452 fi
2453
2454 dnl -----------------------------------------
2455 dnl check for malloc mallinfo struct and call
2456 dnl this must try and link using LIBS, in
2457 dnl order to check no alternative allocator
2458 dnl has been specified, which might not provide
2459 dnl mallinfo
2460 dnl -----------------------------------------
2461 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2462
2463 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2464   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2465 #ifdef HAVE_MALLOC_H
2466 #include <malloc.h>
2467 #endif
2468 #ifdef HAVE_MALLOC_NP_H
2469 #include <malloc_np.h>
2470 #endif
2471 #ifdef HAVE_MALLOC_MALLOC_H
2472 #include <malloc/malloc.h>
2473 #endif
2474 ]], [[
2475 struct mallinfo ac_x; ac_x = mallinfo ();
2476 ]])], [
2477     frr_cv_mallinfo=yes
2478   ], [
2479     frr_cv_mallinfo=no
2480   ])
2481 ])
2482 if test "$frr_cv_mallinfo" = "yes"; then
2483   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2484 fi
2485
2486 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2487   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2488 #ifdef HAVE_MALLOC_H
2489 #include <malloc.h>
2490 #endif
2491 #ifdef HAVE_MALLOC_NP_H
2492 #include <malloc_np.h>
2493 #endif
2494 #ifdef HAVE_MALLOC_MALLOC_H
2495 #include <malloc/malloc.h>
2496 #endif
2497 ]], [[
2498 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2499 ]])], [
2500     frr_cv_mallinfo2=yes
2501   ], [
2502     frr_cv_mallinfo2=no
2503   ])
2504 ])
2505 if test "$frr_cv_mallinfo2" = "yes"; then
2506   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2507 fi
2508
2509 AC_MSG_CHECKING([whether malloc_usable_size is available])
2510 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2511 #ifdef HAVE_MALLOC_H
2512 #include <malloc.h>
2513 #endif
2514 #ifdef HAVE_MALLOC_MALLOC_H
2515 #include <malloc/malloc.h>
2516 #endif
2517 ]], [[
2518 size_t ac_x; ac_x = malloc_usable_size(NULL);
2519 ]])], [
2520   AC_MSG_RESULT([yes])
2521   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2522 ], [
2523   AC_MSG_RESULT([no])
2524
2525   AC_MSG_CHECKING([whether malloc_size is available])
2526   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2527 #ifdef HAVE_MALLOC_H
2528 #include <malloc.h>
2529 #endif
2530 #ifdef HAVE_MALLOC_MALLOC_H
2531 #include <malloc/malloc.h>
2532 #endif
2533 ]], [[
2534 size_t ac_x; ac_x = malloc_size(NULL);
2535 ]])], [
2536     AC_MSG_RESULT([yes])
2537     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2538   ], [
2539     AC_MSG_RESULT([no])
2540   ])
2541 ])
2542
2543 dnl ----------
2544 dnl configure date
2545 dnl ----------
2546 dev_version=`echo $VERSION | grep dev`
2547 #don't expire deprecated code in non 'dev' branch
2548 if test "$dev_version" = ""; then
2549    CONFDATE=0
2550 else
2551    CONFDATE=`date '+%Y%m%d'`
2552 fi
2553 AC_SUBST([CONFDATE])
2554
2555 dnl ------------------------------
2556 dnl set paths for state directory
2557 dnl ------------------------------
2558 AC_MSG_CHECKING([directory to use for state file])
2559 if test "$prefix" = "NONE"; then
2560   frr_statedir_prefix="";
2561 else
2562   frr_statedir_prefix=${prefix}
2563 fi
2564 if test "$localstatedir" = '${prefix}/var'; then
2565   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2566                         ${frr_statedir_prefix}/var/adm dnl
2567                         ${frr_statedir_prefix}/etc dnl
2568                         /var/run        dnl
2569                         /var/adm        dnl
2570                         /etc            dnl
2571                         /dev/null;
2572   do
2573     test -d $FRR_STATE_DIR && break
2574   done
2575   frr_statedir=$FRR_STATE_DIR
2576 else
2577   frr_statedir=${localstatedir}
2578 fi
2579 if test "$frr_statedir" = "/dev/null"; then
2580     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2581 fi
2582 AC_MSG_RESULT([${frr_statedir}])
2583 AC_SUBST([frr_statedir])
2584
2585 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2586 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2587 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2588 AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information])
2589 AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information])
2590 AC_DEFINE_UNQUOTED([OSPF6_AUTH_SEQ_NUM_FILE], ["$frr_statedir/ospf6d-at-seq-no.dat"], [ospf6d AT Sequence number information])
2591 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2592 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2593
2594 dnl autoconf does this, but it does it too late...
2595 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2596 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2597
2598 dnl get the full path, recursing through variables...
2599 vtysh_bin="$bindir/vtysh"
2600 for I in 1 2 3 4 5 6 7 8 9 10; do
2601         eval vtysh_bin="\"$vtysh_bin\""
2602 done
2603 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2604 AC_SUBST([vtysh_bin])
2605
2606 CFG_SYSCONF="$sysconfdir"
2607 CFG_SBIN="$sbindir"
2608 CFG_STATE="$frr_statedir"
2609 CFG_MODULE="$moduledir"
2610 CFG_YANGMODELS="$yangmodelsdir"
2611 CFG_SCRIPT="$scriptdir"
2612 for I in 1 2 3 4 5 6 7 8 9 10; do
2613         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2614         eval CFG_SBIN="\"$CFG_SBIN\""
2615         eval CFG_STATE="\"$CFG_STATE\""
2616         eval CFG_MODULE="\"$CFG_MODULE\""
2617         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2618         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2619 done
2620 AC_SUBST([CFG_SYSCONF])
2621 AC_SUBST([CFG_SBIN])
2622 AC_SUBST([CFG_STATE])
2623 AC_SUBST([CFG_MODULE])
2624 AC_SUBST([CFG_SCRIPT])
2625 AC_SUBST([CFG_YANGMODELS])
2626 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2627 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2628 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2629 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2630
2631 dnl various features
2632 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2633 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2634 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2635 dnl northbound
2636 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2637 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2638 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2639 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2640 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2641 dnl plugins
2642 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2643 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2644 AM_CONDITIONAL([IRDP], [$IRDP])
2645 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2646 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2647 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2648
2649 dnl PCEP plugin
2650 AS_IF([test "$enable_pathd" != "no"], [
2651        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2652        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2653        ])
2654 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2655 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2656 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2657 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2658
2659 dnl daemons
2660 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2661 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2662 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2663 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2664 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2665 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2666 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2667 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2668 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2669 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2670 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2671 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2672 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2673 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2674 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2675 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2676 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2677 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2678 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2679 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2680 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2681 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2682 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2683
2684 AC_CONFIG_FILES([Makefile],[
2685         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2686         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2687 ], [
2688         PYTHON="$PYTHON"
2689         enable_dev_build="$enable_dev_build"
2690 ])
2691
2692 AC_CONFIG_FILES([
2693           config.version
2694           redhat/frr.spec
2695           alpine/APKBUILD
2696           snapcraft/snapcraft.yaml
2697           lib/version.h
2698           tests/lib/cli/test_cli.refout
2699           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2700           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2701           pkgsrc/eigrpd.sh])
2702
2703 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2704 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2705 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2706 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2707 AC_CONFIG_FILES([tools/frrcommon.sh])
2708 AC_CONFIG_FILES([tools/frr.service])
2709 AC_CONFIG_FILES([tools/frr@.service])
2710
2711 AS_IF([test "$with_pkg_git_version" = "yes"], [
2712     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2713         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2714         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2715                 "${ac_abs_top_srcdir}" \
2716                 > "${dst}.tmp"
2717         test -f "$dst" \
2718                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2719                 && rm "${dst}.tmp" \
2720                 || mv "${dst}.tmp" "${dst}"
2721     ], [
2722         PERL="$PERL"
2723     ])
2724 ])
2725
2726 ## Hack, but working solution to avoid rebuilding of frr.info.
2727 ## It's already in CVS until texinfo 4.7 is more common.
2728 AC_OUTPUT
2729
2730 if test "$enable_rpath" = "yes" ; then
2731         true
2732 else
2733         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2734         sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool
2735         sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g'         libtool > libtool.sed && cat libtool.sed > libtool
2736         test -f libtool.sed && rm libtool.sed
2737 fi
2738
2739 echo "
2740 FRRouting configuration
2741 ------------------------------
2742 FRR version             : ${PACKAGE_VERSION}
2743 host operating system   : ${host_os}
2744 source code location    : ${srcdir}
2745 compiler                : ${CC}
2746 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2747 make                    : ${MAKE-make}
2748 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2749 state file directory    : ${frr_statedir}
2750 config file directory   : `eval echo \`echo ${sysconfdir}\``
2751 module directory        : ${CFG_MODULE}
2752 script directory        : ${CFG_SCRIPT}
2753 user to run as          : ${enable_user}
2754 group to run as         : ${enable_group}
2755 group for vty sockets   : ${enable_vty_group}
2756 config file mask        : ${enable_configfile_mask}
2757 log file mask           : ${enable_logfile_mask}
2758 zebra protobuf enabled  : ${enable_protobuf:-no}
2759 vici socket path        : ${vici_socket}
2760
2761 The above user and group must have read/write access to the state file
2762 directory and to the config files in the config file directory."
2763
2764 if test -n "$enable_datacenter"; then
2765   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2766 fi
2767 if test -n "$enable_time_check"; then
2768   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2769 fi
2770 if test -n "$enable_cpu_time"; then
2771   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2772 fi
2773
2774 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2775   AC_MSG_WARN([sphinx is missing but required to build documentation])
2776 fi
2777 if test "$frr_py_mod_pytest" = "false"; then
2778   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2779 fi