configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl if the user has specified any CFLAGS, override our settings
 193 if test "x${enable_gcov}" = "xyes"; then
 194    if test "z$orig_cflags" = "z"; then
 195       AC_C_FLAG([-coverage])
 196       AC_C_FLAG([-O0])
 197    fi
 198
 199    LDFLAGS="${LDFLAGS} -lgcov"
 200 elif test "x${enable_dev_build}" = "xyes"; then
 201    AC_DEFINE(DEV_BUILD,,Build for development)
 202    if test "z$orig_cflags" = "z"; then
 203       AC_C_FLAG([-g3])
 204       AC_C_FLAG([-O0])
 205    fi
 206 else
 207    if test "z$orig_cflags" = "z"; then
 208       AC_C_FLAG([-g])
 209       AC_C_FLAG([-Os], [
 210         AC_C_FLAG([-O2])
 211       ])
 212    fi
 213 fi
 214 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 215
 216 dnl always want these CFLAGS
 217 AC_C_FLAG([-fno-omit-frame-pointer])
 218 AC_C_FLAG([-funwind-tables])
 219 AC_C_FLAG([-Wall])
 220 AC_C_FLAG([-Wextra])
 221 AC_C_FLAG([-Wmissing-prototypes])
 222 AC_C_FLAG([-Wmissing-declarations])
 223 AC_C_FLAG([-Wpointer-arith])
 224 AC_C_FLAG([-Wbad-function-cast])
 225 AC_C_FLAG([-Wwrite-strings])
 226 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 227   AC_C_FLAG([-Wcast-qual])
 228   AC_C_FLAG([-Wstrict-prototypes])
 229   AC_C_FLAG([-Wmissing-noreturn])
 230   AC_C_FLAG([-Wmissing-format-attribute])
 231   AC_C_FLAG([-Wunreachable-code])
 232   AC_C_FLAG([-Wpacked])
 233   AC_C_FLAG([-Wpadded])
 234 else
 235   AC_C_FLAG([-Wno-unused-result])
 236 fi
 237 AC_C_FLAG([-Wno-unused-parameter])
 238 AC_C_FLAG([-Wno-missing-field-initializers])
 239
 240 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 241 dnl for some reason the string consts get 'promoted' to char *,
 242 dnl triggering a const to non-const conversion warning.
 243 AC_C_FLAG([-diag-disable 3179])
 244
 245 if test x"${enable_werror}" = x"yes" ; then
 246   WERROR="-Werror"
 247 fi
 248 AC_SUBST(WERROR)
 249
 250 SAN_FLAGS=""
 251 if test "$enable_address_sanitizer" = "yes"; then
 252   AC_C_FLAG([-fsanitize=address], [
 253     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 254   ], [
 255     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 256   ])
 257 fi
 258 if test "$enable_thread_sanitizer" = "yes"; then
 259   AC_C_FLAG([-fsanitize=thread], [
 260     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 261   ], [
 262     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 263   ])
 264 fi
 265 if test "$enable_memory_sanitizer" = "yes"; then
 266   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 267     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 268   ], [
 269     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 270   ])
 271 fi
 272 AC_SUBST([SAN_FLAGS])
 273
 274 dnl ----------
 275 dnl Essentials
 276 dnl ----------
 277
 278 AX_PTHREAD([
 279   CC="$PTHREAD_CC"
 280   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 281   LIBS="$PTHREAD_LIBS $LIBS"
 282 ], [
 283   AC_MSG_FAILURE([This FRR version needs pthreads])
 284 ])
 285
 286 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 287                 [frr_cv_pthread_condattr_setclock=yes],
 288                 [frr_cv_pthread_condattr_setclock=no])
 289 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 290   AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK, 1, [Have pthread.h pthread_condattr_setclock])
 291 fi
 292
 293 dnl --------------
 294 dnl Check programs
 295 dnl --------------
 296 AC_PROG_INSTALL
 297 AC_PROG_LN_S
 298 AC_PROG_MAKE_SET
 299 AC_CHECK_TOOL(AR, ar)
 300
 301 dnl -------
 302 dnl libtool
 303 dnl -------
 304 LT_INIT
 305
 306 dnl ----------------------
 307 dnl Packages configuration
 308 dnl ----------------------
 309 AC_ARG_WITH(pkg-extra-version,
 310         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 311         [EXTRAVERSION=$withval],)
 312 AC_ARG_WITH(pkg-git-version,
 313         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 314         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 315 AC_ARG_WITH(vtysh_pager,
 316         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 317         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 318 AC_ARG_ENABLE(vtysh,
 319   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 320 AC_ARG_ENABLE(doc,
 321   AS_HELP_STRING([--disable-doc], [do not build docs]))
 322 AC_ARG_ENABLE(doc-html,
 323   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 324 AC_ARG_ENABLE(zebra,
 325   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 326 AC_ARG_ENABLE(bgpd,
 327   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 328 AC_ARG_ENABLE(ripd,
 329   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 330 AC_ARG_ENABLE(ripngd,
 331   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 332 AC_ARG_ENABLE(ospfd,
 333   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 334 AC_ARG_ENABLE(ospf6d,
 335   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 336 AC_ARG_ENABLE(ldpd,
 337   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 338 AC_ARG_ENABLE(nhrpd,
 339   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 340 AC_ARG_ENABLE(eigrpd,
 341   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 342 AC_ARG_ENABLE(babeld,
 343   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 344 AC_ARG_ENABLE(watchfrr,
 345   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 346 AC_ARG_ENABLE(isisd,
 347   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 348 AC_ARG_ENABLE(pimd,
 349   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 350 AC_ARG_ENABLE(pbrd,
 351   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 352 AC_ARG_ENABLE(sharpd,
 353   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 354 AC_ARG_ENABLE(staticd,
 355   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 356 AC_ARG_ENABLE(fabricd,
 357   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 358 AC_ARG_ENABLE(bgp-announce,
 359   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 360 AC_ARG_ENABLE(bgp-vnc,
 361   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 362 AC_ARG_ENABLE(snmp,
 363   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 364 AC_ARG_ENABLE(zeromq,
 365   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 366 AC_ARG_WITH(libpam,
 367   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 368 AC_ARG_ENABLE(ospfapi,
 369   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 370 AC_ARG_ENABLE(ospfclient,
 371   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 372                           (this is the default if --disable-ospfapi is set)]))
 373 AC_ARG_ENABLE(multipath,
 374   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 375 AC_ARG_ENABLE(user,
 376   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 377 AC_ARG_ENABLE(group,
 378   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 379 AC_ARG_ENABLE(vty_group,
 380   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 381 AC_ARG_ENABLE(configfile_mask,
 382   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 383 AC_ARG_ENABLE(logfile_mask,
 384   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 385 AC_ARG_ENABLE(shell_access,
 386   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 387 AC_ARG_ENABLE(realms,
 388   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 389 AC_ARG_ENABLE(rtadv,
 390   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 391 AC_ARG_ENABLE(irdp,
 392   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 393 AC_ARG_ENABLE(capabilities,
 394   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 395 AC_ARG_ENABLE(rusage,
 396   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 397 AC_ARG_ENABLE(gcc_ultra_verbose,
 398   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 399 AC_ARG_ENABLE(backtrace,
 400   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 401 AC_ARG_ENABLE(time-check,
 402   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 403 AC_ARG_ENABLE(pcreposix,
 404   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 405 AC_ARG_ENABLE(fpm,
 406   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 407 AC_ARG_ENABLE(systemd,
 408   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 409 AC_ARG_ENABLE(werror,
 410   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 411 AC_ARG_ENABLE(cumulus,
 412   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 413 AC_ARG_ENABLE(datacenter,
 414   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 415 AC_ARG_ENABLE(fuzzing,
 416   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 417 AC_ARG_ENABLE(netlink_fuzzing,
 418   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 419 AC_ARG_ENABLE(rr-semantics,
 420   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 421 AC_ARG_ENABLE([protobuf],
 422   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 423 AC_ARG_ENABLE([oldvpn_commands],
 424   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 425 AC_ARG_ENABLE(rpki,
 426   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 427 AC_ARG_ENABLE([clippy-only],
 428   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 429 AC_ARG_ENABLE([numeric_version],
 430   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 431 AC_ARG_ENABLE([gcov],
 432   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 433 AC_ARG_ENABLE(bfdd,
 434   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 435 AC_ARG_ENABLE([address-sanitizer],
 436   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 437 AC_ARG_ENABLE([thread-sanitizer],
 438   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 439 AC_ARG_ENABLE([memory-sanitizer],
 440   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 441
 442 AS_IF([test "${enable_clippy_only}" != "yes"], [
 443 AC_CHECK_HEADERS(json-c/json.h)
 444 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 445 if test $ac_cv_lib_json_c_json_object_get = no; then
 446   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 447   if test $ac_cv_lib_json_json_object_get = no; then
 448       AC_MSG_ERROR([lib json is needed to compile])
 449   fi
 450 fi
 451 ])
 452
 453 AC_ARG_ENABLE([dev_build],
 454     AS_HELP_STRING([--enable-dev-build], [build for development]))
 455
 456 if test x"${enable_time_check}" != x"no" ; then
 457   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 458     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 459   else
 460     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 461   fi
 462 fi
 463
 464 case "${enable_systemd}" in
 465   "no") ;;
 466   "yes")
 467   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 468   if test $ac_cv_lib_systemd_sd_notify = no; then
 469     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 470   else
 471     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 472   fi
 473   ;;
 474   "*") ;;
 475 esac
 476
 477 if test "${enable_rr_semantics}" != "no" ; then
 478   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 479 fi
 480
 481 if test "${enable_datacenter}" = "yes" ; then
 482   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 483   DFLT_NAME="datacenter"
 484 else
 485   DFLT_NAME="traditional"
 486 fi
 487
 488 if test "${enable_fuzzing}" = "yes" ; then
 489   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 490 fi
 491
 492 if test "${enable_netlink_fuzzing}" = "yes" ; then
 493   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 494 fi
 495
 496 if test "${enable_cumulus}" = "yes" ; then
 497   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 498 fi
 499
 500 AC_SUBST(DFLT_NAME)
 501 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 502
 503 if test "${enable_shell_access}" = "yes"; then
 504    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 505 fi
 506
 507 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 508
 509 #
 510 # Python for clippy
 511 #
 512
 513 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 514   AC_MSG_CHECKING([whether we found a working Python version])
 515   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 516 #include <Python.h>
 517 #if PY_VERSION_HEX < 0x02070000
 518 #error python too old
 519 #endif
 520 int main(void);
 521 ],
 522 [
 523 {
 524   Py_Initialize();
 525   return 0;
 526 }
 527 ])], [
 528     # some python installs are missing the zlib dependency...
 529     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 530     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 531 #include <Python.h>
 532 #if PY_VERSION_HEX < 0x02070000
 533 #error python too old
 534 #endif
 535 int main(void);
 536 ],
 537 [
 538 {
 539   Py_Initialize();
 540   return 0;
 541 }
 542 ])], [
 543       m4_if([$1], [], [
 544         PYTHONCONFIG=""
 545         unset PYTHON_LIBS
 546         unset PYTHON_CFLAGS
 547       ], [$1])
 548     ])
 549   ])
 550 ])
 551
 552 AS_IF([test "$host" = "$build"], [
 553   PYTHONCONFIG=""
 554
 555   # ordering:
 556   # 1.  try python3, but respect the user's preference on which minor ver
 557   # 2.  try python, which might be py3 or py2 again on the user's preference
 558   # 3.  try python2 (can really only be 2.7 but eh)
 559   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 560   #
 561   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 562   # (AX_PYTHON does not do what we need)
 563
 564   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 565         python3-config \
 566         python-config \
 567         python2-config \
 568         python3.6-config \
 569         python3.5-config \
 570         python3.4-config \
 571         python3.3-config \
 572         python3.2-config \
 573         python2.7-config ])
 574   if test -n "$PYTHONCONFIG"; then
 575     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 576     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 577
 578     FRR_PYTHON_CHECK_WORKING([])
 579   fi
 580
 581   if test -z "$PYTHONCONFIG"; then
 582     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 583       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 584         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 585           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 586             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 587               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 588                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 589                 ])])])])])])
 590
 591
 592     FRR_PYTHON_CHECK_WORKING([
 593       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 594     ])
 595   fi
 596 ])
 597 AC_SUBST(PYTHON_CFLAGS)
 598 AC_SUBST(PYTHON_LIBS)
 599
 600 #
 601 # Logic for protobuf support.
 602 #
 603 if test "$enable_protobuf" = "yes"; then
 604   # Check for protoc & protoc-c
 605
 606   # protoc is not required, it's only for a "be nice" helper target
 607   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 608
 609   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 610   if test "$PROTOC_C" = "/bin/false"; then
 611     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 612   fi
 613
 614   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 615     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 616   ])
 617   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 618     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 619   ])
 620
 621   AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 622 fi
 623 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 624
 625 #
 626 # Logic for old vpn commans support.
 627 #
 628 if test "$enable_oldvpn_commands" = "yes"; then
 629    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 630 fi
 631
 632 #
 633 # End of logic for protobuf support.
 634 #
 635
 636 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 637 if test "${enable_rtadv}" != "no"; then
 638   AC_MSG_RESULT(yes)
 639   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 640 else
 641   AC_MSG_RESULT(no)
 642 fi
 643
 644 if test x"${enable_user}" = x"no"; then
 645   enable_user=""
 646 else
 647   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 648     enable_user="frr"
 649   fi
 650   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 651 fi
 652
 653 if test x"${enable_group}" = x"no"; then
 654   enable_group=""
 655 else
 656   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 657     enable_group="frr"
 658   fi
 659   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 660 fi
 661
 662 if test x"${enable_vty_group}" = x"yes" ; then
 663   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 664 elif test x"${enable_vty_group}" != x""; then
 665   if test x"${enable_vty_group}" != x"no"; then
 666     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 667   fi
 668 fi
 669 AC_SUBST([enable_user])
 670 AC_SUBST([enable_group])
 671 AC_SUBST([enable_vty_group])
 672
 673 enable_configfile_mask=${enable_configfile_mask:-0600}
 674 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 675
 676 enable_logfile_mask=${enable_logfile_mask:-0600}
 677 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 678
 679 MPATH_NUM=1
 680
 681 case "${enable_multipath}" in
 682   0)
 683     MPATH_NUM=64
 684     ;;
 685   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 686     MPATH_NUM="${enable_multipath}"
 687     ;;
 688   "")
 689     ;;
 690   *)
 691     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 692     ;;
 693 esac
 694
 695 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 696
 697 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 698
 699 dnl --------------------
 700 dnl Enable code coverage
 701 dnl --------------------
 702 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 703
 704 dnl ------------------------------------
 705 dnl Alpine only accepts numeric versions
 706 dnl ------------------------------------
 707 if test "x${enable_numeric_version}" != "x" ; then
 708   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 709   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 710 fi
 711
 712 dnl -----------------------------------
 713 dnl Add extra version string to package
 714 dnl name, string and version fields.
 715 dnl -----------------------------------
 716 if test "x${EXTRAVERSION}" != "x" ; then
 717   VERSION="${VERSION}${EXTRAVERSION}"
 718   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 719   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 720   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 721 fi
 722
 723 if test "x$with_pkg_git_version" = "xyes"; then
 724         if test -d "${srcdir}/.git"; then
 725                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 726         else    with_pkg_git_version="no"
 727                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 728         fi
 729 fi
 730 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 731
 732 dnl ------------------------------------
 733 dnl Check C keywords and standard  types
 734 dnl ------------------------------------
 735 AC_C_CONST
 736 AC_C_INLINE
 737 AC_C_VOLATILE
 738 AC_HEADER_STDC
 739 dnl AC_TYPE_PID_T
 740 AC_TYPE_UID_T
 741 AC_TYPE_MODE_T
 742 AC_TYPE_SIZE_T
 743 AC_STRUCT_TM
 744
 745 dnl -------------------------
 746 dnl Check other header files.
 747 dnl -------------------------
 748 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 749         linux/version.h asm/types.h \
 750         sys/cdefs.h])
 751
 752 ac_stdatomic_ok=false
 753 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 754 AC_CHECK_HEADER([stdatomic.h],[
 755
 756   AC_MSG_CHECKING([whether _Atomic qualifier works])
 757   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 758 #include <stdatomic.h>
 759 int main(int argc, char **argv) {
 760   _Atomic int i = 0;
 761   return i;
 762 }
 763 ]])], [
 764     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 765     AC_MSG_RESULT([yes])
 766     ac_stdatomic_ok=true
 767   ], [
 768     AC_MSG_RESULT([no])
 769   ])
 770 ])
 771
 772 AS_IF([$ac_stdatomic_ok], [true], [
 773   AC_MSG_CHECKING([for __atomic_* builtins])
 774   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 775 int main(int argc, char **argv) {
 776   volatile int i = 1;
 777   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 778   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 779 }
 780 ]])], [
 781     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 782     AC_MSG_RESULT([yes])
 783   ], [
 784     AC_MSG_RESULT([no])
 785
 786     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 787     AC_MSG_CHECKING([for __sync_* builtins])
 788     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 789 int main(int argc, char **argv) {
 790   volatile int i = 1;
 791   __sync_fetch_and_sub (&i, 1);
 792   return __sync_val_compare_and_swap (&i, 0, 1);
 793 }
 794 ]])], [
 795       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 796       AC_MSG_RESULT([yes])
 797
 798       AC_MSG_CHECKING([for __sync_swap builtin])
 799       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 800 int main(int argc, char **argv) {
 801   volatile int i = 1;
 802   return __sync_swap (&i, 2);
 803 }
 804 ]])], [
 805         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 806         AC_MSG_RESULT([yes])
 807       ], [
 808         AC_MSG_RESULT([no])
 809       ])
 810
 811     ], [
 812       AC_MSG_RESULT([no])
 813       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 814     ])
 815   ])
 816 ])
 817
 818 AC_CHECK_HEADERS([pthread_np.h],,, [
 819 #include <pthread.h>
 820 ])
 821 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 822
 823 dnl Utility macro to avoid retyping includes all the time
 824 m4_define([FRR_INCLUDES],
 825 [#ifdef SUNOS_5
 826 #define _POSIX_C_SOURCE 200809L
 827 #define __EXTENSIONS__
 828 #endif
 829 #include <stdio.h>
 830 #include <stdlib.h>
 831 #include <stddef.h>
 832 #include <sys/types.h>
 833 /* sys/conf.h depends on param.h on FBSD at least */
 834 #include <sys/param.h>
 835 /* Required for MAXSIG */
 836 #include <signal.h>
 837 #include <sys/socket.h>
 838 #ifdef __APPLE__
 839 # define __APPLE_USE_RFC_3542
 840 #endif
 841 #include <netinet/in.h>
 842 #include <sys/time.h>
 843 #include <time.h>
 844 #include <net/if.h>
 845 ])dnl
 846
 847 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 848 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 849 dnl an additional round for it.
 850
 851 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 852
 853 m4_define([FRR_INCLUDES],
 854 FRR_INCLUDES
 855 [#if HAVE_NET_IF_VAR_H
 856 # include <net/if_var.h>
 857 #endif
 858 ])dnl
 859
 860 AC_CHECK_HEADERS([netinet/in_var.h \
 861         net/if_dl.h net/netopt.h \
 862         inet/nd.h netinet/ip_icmp.h \
 863         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 864         [], [], FRR_INCLUDES)
 865
 866 AC_CHECK_HEADERS([ucontext.h], [], [],
 867 [#ifndef __USE_GNU
 868 #define __USE_GNU
 869 #endif /* __USE_GNU */
 870 FRR_INCLUDES
 871 ])
 872
 873 m4_define([UCONTEXT_INCLUDES],
 874 [#include <ucontext.h>])dnl
 875
 876 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 877   [], [], [UCONTEXT_INCLUDES])
 878 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 879   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 880    [], [], [UCONTEXT_INCLUDES])],
 881   [], [UCONTEXT_INCLUDES])
 882 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 883   [], [], [UCONTEXT_INCLUDES])
 884
 885 m4_define([FRR_INCLUDES],
 886 FRR_INCLUDES
 887 [
 888 #include <sys/un.h>
 889 #include <netinet/in_systm.h>
 890 #if HAVE_NETINET_IN_VAR_H
 891 # include <netinet/in_var.h>
 892 #endif
 893 #if HAVE_NET_IF_DL_H
 894 # include <net/if_dl.h>
 895 #endif
 896 #if HAVE_NET_NETOPT_H
 897 # include <net/netopt.h>
 898 #endif
 899 #include <net/route.h>
 900 #if HAVE_INET_ND_H
 901 # include <inet/nd.h>
 902 #endif
 903 #include <arpa/inet.h>
 904 /* Required for IDRP */
 905 #if HAVE_NETINET_IP_ICMP_H
 906 # include <netinet/ip_icmp.h>
 907 #endif
 908 ])dnl
 909
 910 dnl V6 headers are checked below, after we check for v6
 911
 912 AC_MSG_CHECKING([which operating system interface to use])
 913 case "$host_os" in
 914   sunos* | solaris2*)
 915     AC_MSG_RESULT([Solaris])
 916
 917     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 918     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 919     AC_DEFINE(_POSIX_C_SOURCE, 200809L, [enable POSIX.1-2008 and XPG7/SUSv4])
 920
 921     AC_CHECK_LIB(socket, main)
 922     AC_CHECK_LIB(nsl, main)
 923     AC_CHECK_LIB(umem, main)
 924     AC_CHECK_FUNCS([printstack], [
 925       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 926       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 927     ])
 928     CURSES=-lcurses
 929     SOLARIS="solaris"
 930     ;;
 931   linux*)
 932     AC_MSG_RESULT([Linux])
 933
 934     AC_DEFINE(GNU_LINUX,,GNU Linux)
 935     AC_DEFINE(HAVE_NETLINK,,netlink)
 936     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 937
 938     dnl Linux has a compilation problem with mixing
 939     dnl netinet/in.h and linux/in6.h they are not
 940     dnl compatible.  There has been discussion on
 941     dnl how to fix it but no real progress on implementation
 942     dnl when they fix it, remove this
 943     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 944     ;;
 945   openbsd*)
 946     AC_MSG_RESULT([OpenBSD])
 947
 948     AC_DEFINE(OPEN_BSD,,OpenBSD)
 949     AC_DEFINE(KAME,1,KAME IPv6)
 950     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 951
 952     if test "x${enable_pimd}" != "xno"; then
 953       case "$host_os" in
 954       openbsd6.0)
 955         ;;
 956       openbsd[6-9]*)
 957         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 958         ;;
 959       esac
 960     fi
 961     ;;
 962   *)
 963     AC_MSG_RESULT([BSD])
 964
 965     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 966     AC_DEFINE(KAME,1,KAME IPv6)
 967     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 968     ;;
 969 esac
 970 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 971
 972 AC_SYS_LARGEFILE
 973
 974 dnl ------------------------
 975 dnl Integrated REALMS option
 976 dnl ------------------------
 977 if test "${enable_realms}" = "yes"; then
 978     case "$host_os" in
 979       linux*)
 980        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 981        ;;
 982       *)
 983        echo "Sorry, only Linux has REALMS support"
 984        exit 1
 985        ;;
 986     esac
 987 fi
 988 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 989
 990 dnl ---------------------
 991 dnl Integrated VTY option
 992 dnl ---------------------
 993 case "${enable_vtysh}" in
 994   "no") VTYSH="";;
 995   *)    VTYSH="vtysh";
 996          AC_DEFINE(VTYSH,,VTY shell)
 997 dnl      Vtysh uses libreadline, which looks for termcap functions at
 998 dnl      configure time.  We follow readlines search order.
 999 dnl      The required procedures are in libtermcap on NetBSD, in
1000 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1001          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1002            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1003              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1004                [AC_CHECK_LIB(ncurses, tputs,
1005                              LIBREADLINE="$LIBREADLINE -lncurses")]
1006               )]
1007             )]
1008           )
1009          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1010                       "$LIBREADLINE")
1011          if test $ac_cv_lib_readline_main = no; then
1012            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1013          fi
1014          AC_CHECK_HEADER(readline/history.h)
1015          if test $ac_cv_header_readline_history_h = no;then
1016            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1017          fi
1018          AC_CHECK_LIB(readline, rl_completion_matches,
1019                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1020          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1021            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1022          fi
1023          AC_SEARCH_LIBS([append_history], [readline], [frr_cv_append_history=yes], [frr_cv_append_history=no])
1024          if test "$frr_cv_append_history" = yes; then
1025            AC_DEFINE(HAVE_APPEND_HISTORY, 1, [Have history.h append_history])
1026          fi
1027          ;;
1028 esac
1029 AC_SUBST(LIBREADLINE)
1030 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1031
1032 dnl ----------
1033 dnl PAM module
1034 dnl
1035 dnl FRR detects the PAM library it is built against by checking for a
1036 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1037 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1038 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1039 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1040 dnl of OpenPAM.
1041 dnl ----------
1042 if test "$with_libpam" = "yes"; then
1043   AC_CHECK_HEADER([security/pam_misc.h],
1044     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1045      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1046      pam_conv_func="misc_conv"
1047     ],
1048     [], FRR_INCLUDES)
1049   AC_CHECK_HEADER([security/openpam.h],
1050     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1051      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1052      pam_conv_func="openpam_ttyconv"
1053     ],
1054     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1055   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1056     AC_MSG_WARN([*** pam support will not be built ***])
1057     with_libpam="no"
1058   fi
1059 fi
1060
1061 if test "$with_libpam" = "yes"; then
1062 dnl took this test from proftpds configure.in and suited to our needs
1063 dnl -------------------------------------------------------------------------
1064 dnl
1065 dnl This next check looks funky due to a linker problem with some versions
1066 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1067 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1068 dnl with RedHat 6.2 and Debian 2.2 or better.
1069 AC_CHECK_LIB(pam, pam_start,
1070   [AC_CHECK_LIB(pam, $pam_conv_func,
1071     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1072      LIBPAM="-lpam"],
1073     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1074      LIBPAM="-lpam -lpam_misc"]
1075     )
1076   ],
1077
1078   [AC_CHECK_LIB(pam, pam_end,
1079     [AC_CHECK_LIB(pam, $pam_conv_func,
1080       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1081        LIBPAM="-lpam -ldl"],
1082       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1083        LIBPAM="-lpam -ldl -lpam_misc"]
1084      )
1085   ],AC_MSG_WARN([*** pam support will not be built ***]),
1086   [-ldl])
1087   ]
1088 )
1089 fi
1090 AC_SUBST(LIBPAM)
1091
1092 dnl -------------------------------
1093 dnl Endian-ness check
1094 dnl -------------------------------
1095 AC_WORDS_BIGENDIAN
1096
1097 dnl -------------------------------
1098 dnl check the size in byte of the C
1099 dnl -------------------------------
1100 dnl AC_CHECK_SIZEOF(char)
1101 dnl AC_CHECK_SIZEOF(int)
1102 dnl AC_CHECK_SIZEOF(short)
1103 dnl AC_CHECK_SIZEOF(long)
1104
1105 dnl ----------------------------
1106 dnl check existance of functions
1107 dnl ----------------------------
1108 AC_FUNC_FNMATCH
1109 AC_FUNC_FORK
1110 AC_FUNC_MKTIME
1111 AC_FUNC_STAT
1112
1113 dnl -------------------------------
1114 dnl bgpd needs pow() and hence libm
1115 dnl -------------------------------
1116 TMPLIBS="$LIBS"
1117 AC_CHECK_HEADER([math.h],
1118   [AC_CHECK_LIB([m], [pow],
1119     [LIBM="-lm"
1120      LIBS="$LIBS $LIBM"
1121      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1122     ])
1123 ])
1124 if test x"$LIBM" = x ; then
1125   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1126 fi
1127 LIBS="$TMPLIBS"
1128 AC_SUBST(LIBM)
1129
1130 AC_CHECK_FUNCS([ppoll], [
1131   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1132 ])
1133 AC_CHECK_FUNCS([pollts], [
1134   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1135 ])
1136
1137 dnl ---------------
1138 dnl other functions
1139 dnl ---------------
1140 AC_CHECK_FUNCS([ \
1141         strlcat strlcpy \
1142         getgrouplist])
1143
1144 AC_CHECK_HEADER([asm-generic/unistd.h],
1145                 [AC_CHECK_DECL(__NR_setns,
1146                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1147                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1148                                ])
1149                  AC_CHECK_FUNCS(setns)]
1150                )
1151
1152 dnl --------------------------
1153 dnl Determine IS-IS I/O method
1154 dnl --------------------------
1155 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1156 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1157 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1158 AC_CHECK_HEADER(net/bpf.h)
1159 AC_CHECK_HEADER(sys/dlpi.h)
1160 AC_MSG_CHECKING(zebra IS-IS I/O method)
1161
1162 case "$host_os" in
1163   linux*)
1164     AC_MSG_RESULT(pfpacket)
1165     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1166     ;;
1167   solaris* | sunos*)
1168     AC_MSG_RESULT(DLPI)
1169     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1170     ;;
1171   *)
1172     if test $ac_cv_header_net_bpf_h = no; then
1173       if test $ac_cv_header_sys_dlpi_h = no; then
1174         AC_MSG_RESULT(none)
1175         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1176           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1177         fi
1178         AC_MSG_WARN([*** IS-IS support will not be built ***])
1179         enable_isisd="no"
1180         enable_fabricd="no"
1181       else
1182         AC_MSG_RESULT(DLPI)
1183       fi
1184       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1185     else
1186       AC_MSG_RESULT(BPF)
1187       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1188     fi
1189     ;;
1190 esac
1191 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1192
1193 dnl ---------------------------------------------------------------
1194 dnl figure out how to specify an interface in multicast sockets API
1195 dnl ---------------------------------------------------------------
1196 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1197
1198 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1199         #include <sys/socket.h>
1200         #include <netinet/in.h>
1201         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1202         #include <linux/types.h>
1203 ])
1204
1205 m4_define([FRR_INCLUDES],
1206 FRR_INCLUDES
1207 [#if HAVE_LINUX_MROUTE_H
1208 # include <linux/mroute.h>
1209 #endif
1210 ])dnl
1211
1212 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1213         #include <sys/socket.h>
1214         #include <sys/types.h>
1215         #include <netinet/in.h>
1216         #include <net/route.h>
1217 ])
1218
1219 m4_define([FRR_INCLUDES],
1220 FRR_INCLUDES
1221 [#if HAVE_NETINET_IP_MROUTE_H
1222 # include <netinet/ip_mroute.h>
1223 #endif
1224 ])dnl
1225
1226 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1227 AC_TRY_COMPILE([#include <sys/param.h>],
1228 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1229   return (0);
1230 #else
1231   #error No support for BSD struct ip_mreq hack detected
1232 #endif],[AC_MSG_RESULT(yes)
1233 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1234 AC_MSG_RESULT(no))
1235
1236 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1237 AC_TRY_COMPILE([
1238 #include <sys/types.h>
1239 #include <netinet/in.h>
1240 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1241 ], [AC_MSG_RESULT(yes)
1242 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1243 AC_MSG_RESULT(no))
1244
1245 dnl ---------------------------------------------------------------
1246 dnl figure out how to check link-state
1247 dnl ---------------------------------------------------------------
1248 AC_CHECK_HEADER( [net/if_media.h],
1249   [m4_define([LINK_DETECT_INCLUDES],
1250     FRR_INCLUDES
1251     [#include <net/if_media.h>
1252   ])
1253   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1254     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1255     [], LINK_DETECT_INCLUDES)],
1256   [],
1257   FRR_INCLUDES)
1258
1259 dnl ---------------------------------------------------------------
1260 dnl Additional, newer way to check link-state using ifi_link_state.
1261 dnl Not available in all BSD's when ifmediareq available
1262 dnl ---------------------------------------------------------------
1263 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1264   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1265   [], FRR_INCLUDES)
1266
1267 dnl ------------------------
1268 dnl TCP_MD5SIG socket option
1269 dnl ------------------------
1270
1271 AC_CHECK_HEADER([netinet/tcp.h],
1272    [m4_define([MD5_INCLUDES],
1273       FRR_INCLUDES
1274       [#include <netinet/tcp.h>
1275     ])
1276     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1277    [],
1278    FRR_INCLUDES)
1279 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1280   AC_CHECK_HEADER([linux/tcp.h],
1281        [m4_define([MD5_INCLUDES],
1282           FRR_INCLUDES
1283           [#include <linux/tcp.h>
1284         ])
1285        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1286 fi
1287
1288 dnl ----------------------------------------------------------------------------
1289 dnl figure out if domainname is available in the utsname struct (GNU extension).
1290 dnl ----------------------------------------------------------------------------
1291 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1292
1293 dnl ------------------
1294 dnl IPv6 header checks
1295 dnl ------------------
1296 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1297         netinet6/in6_var.h netinet6/nd6.h], [], [],
1298         FRR_INCLUDES)
1299
1300 m4_define([FRR_INCLUDES],dnl
1301 FRR_INCLUDES
1302 [#if HAVE_NETINET6_IN6_H
1303 #include <netinet6/in6.h>
1304 #endif
1305 #if HAVE_NETINET_IN6_VAR_H
1306 #include <netinet/in6_var.h>
1307 #endif
1308 #include <netinet/icmp6.h>
1309 #if HAVE_NETINET6_IN6_VAR_H
1310 # include <netinet6/in6_var.h>
1311 #endif
1312 #if HAVE_NETINET6_ND6_H
1313 # include <netinet6/nd6.h>
1314 #endif
1315 ])dnl
1316
1317 dnl disable doc check
1318 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1319 if test "$SPHINXBUILD" = "/bin/false"; then
1320   if test "${enable_doc}" = "yes"; then
1321     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1322   fi
1323 fi
1324 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false")
1325 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1326
1327 dnl --------------------
1328 dnl Daemon disable check
1329 dnl --------------------
1330 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1331
1332 if test "${enable_bgpd}" = "no";then
1333   BGPD=""
1334 else
1335   BGPD="bgpd"
1336 fi
1337 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1338
1339 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1340 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1341 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1342
1343 AS_IF([test "${enable_ldpd}" != "no"], [
1344   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1345 ])
1346
1347 if test "$enable_bfdd" = "no"; then
1348   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1349   BFDD=""
1350 else
1351   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1352   BFDD="bfdd"
1353
1354   case $host_os in
1355     linux*)
1356       AC_DEFINE(BFD_LINUX, 1, bfdd)
1357       ;;
1358
1359     *)
1360       AC_DEFINE(BFD_BSD, 1, bfdd)
1361       ;;
1362   esac
1363 fi
1364
1365 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1366
1367 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1368   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1369 fi
1370
1371 NHRPD=""
1372 case "$host_os" in
1373   linux*)
1374     if test "${enable_nhrpd}" != "no"; then
1375       NHRPD="nhrpd"
1376     fi
1377     ;;
1378   *)
1379     if test "${enable_nhrpd}" = "yes"; then
1380       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1381     fi
1382     ;;
1383 esac
1384 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1385
1386 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1387
1388 if test "${enable_watchfrr}" = "no";then
1389   WATCHFRR=""
1390 else
1391   WATCHFRR="watchfrr"
1392 fi
1393 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1394
1395 OSPFCLIENT=""
1396 if test "${enable_ospfapi}" != "no";then
1397     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1398
1399   if test "${enable_ospfclient}" != "no";then
1400       OSPFCLIENT="ospfclient"
1401   fi
1402 fi
1403
1404 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1405 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1406 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1407 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1408 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1409 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1410 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1411 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1412 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1413 AM_CONDITIONAL(FABRICD, test "${enable_fabricd}" != "no")
1414
1415 if test "${enable_bgp_announce}" = "no";then
1416   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1417 else
1418   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1419 fi
1420
1421 if test "${enable_bgp_vnc}" != "no";then
1422   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1423 fi
1424 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1425
1426 AC_SUBST(SOLARIS)
1427 AC_SUBST(CURSES)
1428 AC_CHECK_LIB(crypt, crypt, [],
1429                     [AC_CHECK_LIB(crypto, DES_crypt)])
1430 AC_CHECK_LIB(resolv, res_init)
1431
1432 dnl ---------------------------
1433 dnl check system has PCRE regexp
1434 dnl ---------------------------
1435 if test "x$enable_pcreposix" = "xyes"; then
1436   AC_CHECK_LIB(pcreposix, regexec, [], [
1437     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1438   ])
1439 fi
1440 AC_SUBST(HAVE_LIBPCREPOSIX)
1441
1442 dnl ------------------
1443 dnl check C-Ares library
1444 dnl ------------------
1445 if test "${NHRPD}" != ""; then
1446   PKG_CHECK_MODULES([CARES], [libcares], , [
1447     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1448   ])
1449 fi
1450
1451
1452 dnl ------------------
1453 dnl check Net-SNMP library
1454 dnl ------------------
1455 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1456    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1457    if test x"$NETSNMP_CONFIG" = x"no"; then
1458       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1459    fi
1460    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1461    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1462    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1463    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1464 int main(void);
1465 ],
1466 [
1467 {
1468   return 0;
1469 }
1470 ])], [
1471      AC_MSG_ERROR([--enable-snmp given but not usable])])
1472    case "${enable_snmp}" in
1473      yes)
1474       SNMP_METHOD=agentx
1475       ;;
1476      agentx)
1477       SNMP_METHOD="${enable_snmp}"
1478       ;;
1479      *)
1480       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1481       ;;
1482    esac
1483    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1484    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1485 fi
1486 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1487 AC_SUBST(SNMP_LIBS)
1488 AC_SUBST(SNMP_CFLAGS)
1489
1490 dnl ---------------
1491 dnl math
1492 dnl ---------------
1493 AC_SEARCH_LIBS([sqrt], [m])
1494
1495 dnl ---------------
1496 dnl dlopen & dlinfo
1497 dnl ---------------
1498 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1499   AC_MSG_ERROR([unable to find the dlopen()])
1500 ])
1501
1502 AC_CHECK_HEADERS([link.h])
1503
1504 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1505   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1506 #include <stdlib.h>
1507 #ifdef HAVE_LINK_H
1508 #include <link.h>
1509 #endif
1510 #include <dlfcn.h>
1511 ]], [[
1512   char origin[1];
1513   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1514 ]])], [
1515     frr_cv_rtld_di_origin=yes
1516   ], [
1517     frr_cv_rtld_di_origin=no
1518   ])
1519 ])
1520 if test "$frr_cv_rtld_di_origin" = yes; then
1521   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1522 fi
1523
1524 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1525   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1526 #include <stdlib.h>
1527 #ifdef HAVE_LINK_H
1528 #include <link.h>
1529 #endif
1530 #include <dlfcn.h>
1531 ]], [[
1532   struct link_map *lm = NULL;
1533   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1534 ]])], [
1535     frr_cv_rtld_di_linkmap=yes
1536   ], [
1537     frr_cv_rtld_di_linkmap=no
1538   ])
1539 ])
1540 if test "$frr_cv_rtld_di_linkmap" = yes; then
1541   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1542 fi
1543
1544 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1545
1546 dnl ---------------------------
1547 dnl sockaddr and netinet checks
1548 dnl ---------------------------
1549 AC_CHECK_TYPES([
1550         struct sockaddr_dl,
1551         struct vifctl, struct mfcctl, struct sioc_sg_req,
1552         vifi_t, struct sioc_vif_req, struct igmpmsg,
1553         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1554         struct nd_opt_adv_interval, struct rt_addrinfo,
1555         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1556         [], [], FRR_INCLUDES)
1557
1558 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1559         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1560         struct sockaddr_dl.sdl_len,
1561         struct if6_aliasreq.ifra_lifetime,
1562         struct nd_opt_adv_interval.nd_opt_ai_type],
1563         [], [], FRR_INCLUDES)
1564
1565 dnl ---------------------------
1566 dnl IRDP/pktinfo/icmphdr checks
1567 dnl ---------------------------
1568
1569 AC_CHECK_TYPES([struct in_pktinfo], [
1570   AC_CHECK_TYPES([struct icmphdr], [
1571     IRDP=true
1572   ], [
1573     IRDP=false
1574   ], [FRR_INCLUDES])
1575 ], [
1576   IRDP=false
1577 ], [FRR_INCLUDES])
1578
1579 case "${enable_irdp}" in
1580 yes)
1581   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1582   ;;
1583 no)
1584   IRDP=false
1585   ;;
1586 esac
1587
1588 AM_CONDITIONAL(IRDP, $IRDP)
1589
1590 dnl -----------------------
1591 dnl checking for IP_PKTINFO
1592 dnl -----------------------
1593 AC_MSG_CHECKING(for IP_PKTINFO)
1594 AC_TRY_COMPILE([#include <netdb.h>], [
1595   int opt = IP_PKTINFO;
1596 ], [
1597   AC_MSG_RESULT(yes)
1598   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1599 ], [
1600   AC_MSG_RESULT(no)
1601 ])
1602
1603 dnl ---------------------------
1604 dnl checking for IP_RECVDSTADDR
1605 dnl ---------------------------
1606 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1607 AC_TRY_COMPILE([#include <netinet/in.h>], [
1608   int opt = IP_RECVDSTADDR;
1609 ], [
1610   AC_MSG_RESULT(yes)
1611   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1612 ], [
1613   AC_MSG_RESULT(no)
1614 ])
1615
1616 dnl ----------------------
1617 dnl checking for IP_RECVIF
1618 dnl ----------------------
1619 AC_MSG_CHECKING(for IP_RECVIF)
1620 AC_TRY_COMPILE([#include <netinet/in.h>], [
1621   int opt = IP_RECVIF;
1622 ], [
1623   AC_MSG_RESULT(yes)
1624   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1625 ], [
1626   AC_MSG_RESULT(no)
1627 ])
1628
1629 dnl ----------------------
1630 dnl checking for SO_BINDANY
1631 dnl ----------------------
1632 AC_MSG_CHECKING(for SO_BINDANY)
1633 AC_TRY_COMPILE([#include <sys/socket.h>], [
1634   int opt = SO_BINDANY;
1635 ], [
1636   AC_MSG_RESULT(yes)
1637   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1638 ], [
1639   AC_MSG_RESULT(no)
1640 ])
1641
1642 dnl ----------------------
1643 dnl checking for IP_FREEBIND
1644 dnl ----------------------
1645 AC_MSG_CHECKING(for IP_FREEBIND)
1646 AC_TRY_COMPILE([#include <netinet/in.h>], [
1647   int opt = IP_FREEBIND;
1648 ], [
1649   AC_MSG_RESULT(yes)
1650   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1651 ], [
1652   AC_MSG_RESULT(no)
1653 ])
1654
1655 dnl --------------------------------------
1656 dnl checking for be32dec existence or not
1657 dnl --------------------------------------
1658 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1659                [#include <sys/endian.h>])
1660
1661 dnl --------------------------------------
1662 dnl checking for clock_time monotonic struct and call
1663 dnl --------------------------------------
1664 AC_CHECK_DECL(CLOCK_MONOTONIC,
1665         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1666          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1667 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1668
1669 dnl --------------------------------------
1670 dnl checking for flex and bison
1671 dnl --------------------------------------
1672
1673 AM_PROG_LEX
1674 AC_MSG_CHECKING(version of flex)
1675 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1676 frr_ac_flex_version="${frr_ac_flex_version##* }"
1677 AC_MSG_RESULT([$frr_ac_flex_version])
1678 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1679   LEX="$SHELL $missing_dir/missing flex"
1680   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1681     AC_MSG_WARN([using pregenerated flex output files])
1682   else
1683     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1684   fi
1685   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1686   AC_SUBST([LEXLIB], [''])
1687 ])
1688
1689 AC_PROG_YACC
1690 dnl thanks GNU bison for this b*llshit...
1691 AC_MSG_CHECKING(version of bison)
1692 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1693 frr_ac_bison_version="${frr_ac_bison_version##* }"
1694 frr_ac_bison_missing="false"
1695 case "x${frr_ac_bison_version}" in
1696   x2.7*)
1697     BISON_OPENBRACE='"'
1698     BISON_CLOSEBRACE='"'
1699     BISON_VERBOSE=''
1700     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1701     ;;
1702   x2.*|x1.*)
1703     AC_MSG_RESULT([$frr_ac_bison_version])
1704     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1705     frr_ac_bison_missing="true"
1706     ;;
1707   x)
1708     AC_MSG_RESULT([none])
1709     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1710     frr_ac_bison_missing="true"
1711     ;;
1712   *)
1713     BISON_OPENBRACE='{'
1714     BISON_CLOSEBRACE='}'
1715     BISON_VERBOSE='-Dparse.error=verbose'
1716     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1717     ;;
1718 esac
1719 AC_SUBST(BISON_OPENBRACE)
1720 AC_SUBST(BISON_CLOSEBRACE)
1721 AC_SUBST(BISON_VERBOSE)
1722
1723 if $frr_ac_bison_missing; then
1724   YACC="$SHELL $missing_dir/missing bison -y"
1725   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1726     AC_MSG_WARN([using pregenerated bison output files])
1727   else
1728     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1729   fi
1730 fi
1731
1732 dnl -------------------
1733 dnl capabilities checks
1734 dnl -------------------
1735 if test "${enable_capabilities}" != "no"; then
1736   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1737   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1738     [AC_MSG_RESULT(yes)
1739      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1740      frr_ac_keepcaps="yes"],
1741      AC_MSG_RESULT(no)
1742   )
1743   if test x"${frr_ac_keepcaps}" = x"yes"; then
1744     AC_CHECK_HEADERS(sys/capability.h)
1745   fi
1746   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1747     AC_CHECK_LIB(cap, cap_init,
1748       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1749        LIBCAP="-lcap"
1750        frr_ac_lcaps="yes"]
1751     )
1752   else
1753     AC_CHECK_HEADERS(priv.h,
1754      [AC_MSG_CHECKING(Solaris style privileges are available)
1755       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1756           [AC_MSG_RESULT(yes)
1757            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1758            frr_ac_scaps="yes"],
1759            AC_MSG_RESULT(no)
1760       )
1761      ]
1762    )
1763   fi
1764   if test x"${frr_ac_scaps}" = x"yes" \
1765        -o x"${frr_ac_lcaps}" = x"yes"; then
1766     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1767   fi
1768 fi
1769 AC_SUBST(LIBCAP)
1770
1771 dnl ---------------------------
1772 dnl check for glibc 'backtrace'
1773 dnl ---------------------------
1774 if test x"${enable_backtrace}" != x"no" ; then
1775   backtrace_ok=no
1776   AC_CHECK_HEADER([execinfo.h], [
1777     AC_SEARCH_LIBS([backtrace], [execinfo], [
1778       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1779       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1780       backtrace_ok=yes
1781     ],, [-lm])
1782   ])
1783
1784   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1785     dnl user explicitly requested backtrace but we failed to find support
1786     AC_MSG_FAILURE([failed to find backtrace support])
1787   fi
1788 fi
1789
1790 dnl -----------------------------------------
1791 dnl check for malloc mallinfo struct and call
1792 dnl this must try and link using LIBS, in
1793 dnl order to check no alternative allocator
1794 dnl has been specified, which might not provide
1795 dnl mallinfo, e.g. such as Umem on Solaris.
1796 dnl -----------------------------------------
1797 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
1798
1799 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1800   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1801 #ifdef HAVE_MALLOC_H
1802 #include <malloc.h>
1803 #endif
1804 #ifdef HAVE_MALLOC_NP_H
1805 #include <malloc_np.h>
1806 #endif
1807 #ifdef HAVE_MALLOC_MALLOC_H
1808 #include <malloc/malloc.h>
1809 #endif
1810 ]], [[
1811 struct mallinfo ac_x; ac_x = mallinfo ();
1812 ]])], [
1813     frr_cv_mallinfo=yes
1814   ], [
1815     frr_cv_mallinfo=no
1816   ])
1817 ])
1818 if test "$frr_cv_mallinfo" = yes; then
1819   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1820 fi
1821
1822 AC_MSG_CHECKING(whether malloc_usable_size is available)
1823 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1824 #ifdef HAVE_MALLOC_H
1825 #include <malloc.h>
1826 #endif
1827 #ifdef HAVE_MALLOC_MALLOC_H
1828 #include <malloc/malloc.h>
1829 #endif
1830 ]], [[
1831 size_t ac_x; ac_x = malloc_usable_size(NULL);
1832 ]])], [
1833   AC_MSG_RESULT(yes)
1834   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1835 ], [
1836   AC_MSG_RESULT(no)
1837
1838   AC_MSG_CHECKING(whether malloc_size is available)
1839   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1840 #ifdef HAVE_MALLOC_H
1841 #include <malloc.h>
1842 #endif
1843 #ifdef HAVE_MALLOC_MALLOC_H
1844 #include <malloc/malloc.h>
1845 #endif
1846 ]], [[
1847 size_t ac_x; ac_x = malloc_size(NULL);
1848 ]])], [
1849     AC_MSG_RESULT(yes)
1850     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1851   ], [
1852     AC_MSG_RESULT(no)
1853   ])
1854 ])
1855
1856 dnl ------
1857 dnl ZeroMQ
1858 dnl ------
1859 if test "x$enable_zeromq" != "xno"; then
1860   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1861     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1862     ZEROMQ=true
1863   ], [
1864     if test "x$enable_zeromq" = "xyes"; then
1865       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1866     fi
1867   ])
1868 fi
1869 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1870
1871 dnl ----------
1872 dnl configure date
1873 dnl ----------
1874 dev_version=`echo $VERSION | grep dev`
1875 #don't expire deprecated code in non 'dev' branch
1876 if test "${dev_version}" = ""; then
1877    CONFDATE=0
1878 else
1879    CONFDATE=`date '+%Y%m%d'`
1880 fi
1881 AC_SUBST(CONFDATE)
1882
1883 dnl ------------------------------
1884 dnl set paths for state directory
1885 dnl ------------------------------
1886 AC_MSG_CHECKING(directory to use for state file)
1887 if test "${prefix}" = "NONE"; then
1888   frr_statedir_prefix="";
1889 else
1890   frr_statedir_prefix=${prefix}
1891 fi
1892 if test "${localstatedir}" = '${prefix}/var'; then
1893   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1894                         ${frr_statedir_prefix}/var/adm dnl
1895                         ${frr_statedir_prefix}/etc dnl
1896                         /var/run        dnl
1897                         /var/adm        dnl
1898                         /etc            dnl
1899                         /dev/null;
1900   do
1901     test -d $FRR_STATE_DIR && break
1902   done
1903   frr_statedir=$FRR_STATE_DIR
1904 else
1905   frr_statedir=${localstatedir}
1906 fi
1907 if test $frr_statedir = "/dev/null"; then
1908     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1909 fi
1910 AC_MSG_RESULT(${frr_statedir})
1911 AC_SUBST(frr_statedir)
1912
1913 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1914 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1915 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1916 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1917
1918 dnl autoconf does this, but it does it too late...
1919 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1920 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1921
1922 dnl get the full path, recursing through variables...
1923 vtysh_bin="$bindir/vtysh"
1924 for I in 1 2 3 4 5 6 7 8 9 10; do
1925         eval vtysh_bin="\"$vtysh_bin\""
1926 done
1927 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1928
1929 CFG_SYSCONF="$sysconfdir"
1930 CFG_SBIN="$sbindir"
1931 CFG_STATE="$frr_statedir"
1932 CFG_MODULE="$moduledir"
1933 for I in 1 2 3 4 5 6 7 8 9 10; do
1934         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1935         eval CFG_SBIN="\"$CFG_SBIN\""
1936         eval CFG_STATE="\"$CFG_STATE\""
1937         eval CFG_MODULE="\"$CFG_MODULE\""
1938 done
1939 AC_SUBST(CFG_SYSCONF)
1940 AC_SUBST(CFG_SBIN)
1941 AC_SUBST(CFG_STATE)
1942 AC_SUBST(CFG_MODULE)
1943 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1944
1945 dnl ------------------------------------
1946 dnl Enable RPKI and add librtr to libs
1947 dnl ------------------------------------
1948 if test "${enable_rpki}" = "yes"; then
1949   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1950       [RPKI=true],
1951       [RPKI=false
1952       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1953   )
1954 fi
1955 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1956
1957 dnl ------------------------------------------
1958 dnl Check whether rtrlib was build with ssh support
1959 dnl ------------------------------------------
1960 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1961 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1962                         [[struct tr_ssh_config config;]])],
1963         [AC_MSG_RESULT(yes)
1964         AC_DEFINE(FOUND_SSH,,found_ssh)],
1965         AC_MSG_RESULT(no)
1966 )
1967
1968 dnl ---------------------------
1969 dnl Check htonl works correctly
1970 dnl ---------------------------
1971 AC_MSG_CHECKING(for working htonl)
1972 AC_CACHE_VAL(ac_cv_htonl_works,
1973  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1974                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1975  ]
1976 )
1977 AC_MSG_RESULT($ac_cv_htonl_works)
1978
1979 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
1980
1981 AC_CONFIG_FILES([
1982           redhat/frr.spec
1983           solaris/Makefile
1984           debianpkg/changelog
1985           alpine/APKBUILD
1986           snapcraft/snapcraft.yaml
1987           lib/version.h
1988           tests/lib/cli/test_cli.refout
1989           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1990           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1991           pkgsrc/eigrpd.sh])
1992
1993 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1994
1995 AC_CONFIG_COMMANDS([lib/route_types.h], [
1996         dst="${ac_abs_top_builddir}/lib/route_types.h"
1997         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1998                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1999                 > "${dst}.tmp"
2000         test -f "${dst}" \
2001                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2002                 && rm "${dst}.tmp" \
2003                 || mv "${dst}.tmp" "${dst}"
2004 ], [
2005         PERL="$PERL"
2006 ])
2007
2008 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2009     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2010         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2011         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2012                 "${ac_abs_top_srcdir}" \
2013                 > "${dst}.tmp"
2014         test -f "${dst}" \
2015                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2016                 && rm "${dst}.tmp" \
2017                 || mv "${dst}.tmp" "${dst}"
2018     ], [
2019         PERL="$PERL"
2020     ])
2021 ])
2022
2023 ## Hack, but working solution to avoid rebuilding of frr.info.
2024 ## It's already in CVS until texinfo 4.7 is more common.
2025 AC_OUTPUT
2026
2027 echo "
2028 FRRouting configuration
2029 ------------------------------
2030 FRR version             : ${PACKAGE_VERSION}
2031 host operating system   : ${host_os}
2032 source code location    : ${srcdir}
2033 compiler                : ${CC}
2034 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2035 make                    : ${MAKE-make}
2036 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2037 state file directory    : ${frr_statedir}
2038 config file directory   : `eval echo \`echo ${sysconfdir}\``
2039 example directory       : `eval echo \`echo ${exampledir}\``
2040 module directory        : ${CFG_MODULE}
2041 user to run as          : ${enable_user}
2042 group to run as         : ${enable_group}
2043 group for vty sockets   : ${enable_vty_group}
2044 config file mask        : ${enable_configfile_mask}
2045 log file mask           : ${enable_logfile_mask}
2046 zebra protobuf enabled  : ${enable_protobuf:-no}
2047
2048 The above user and group must have read/write access to the state file
2049 directory and to the config files in the config file directory."
2050
2051 if test "${enable_doc}" != "no";then
2052   AS_IF([test "$SPHINXBUILD" = /bin/false],
2053      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2054 fi