configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_version_major], 1)
   5 m4_define([lxc_version_minor], 1)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], [alpha3])
   8
   9 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  10 m4_define([lxc_version],
  11           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  12
  13 AC_INIT([lxc], [lxc_version])
  14
  15 # We need pkg-config
  16 PKG_PROG_PKG_CONFIG
  17
  18 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  19 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  20
  21 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  22 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  23 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  24 AC_SUBST([LXC_VERSION], [lxc_version])
  25
  26 AC_CONFIG_SRCDIR([configure.ac])
  27 AC_CONFIG_AUX_DIR([config])
  28 AC_CONFIG_HEADERS([src/config.h])
  29 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  30 AC_CANONICAL_HOST
  31 AM_PROG_CC_C_O
  32 AC_GNU_SOURCE
  33
  34 # Detect the distribution. This is used for the default configuration and
  35 # for some distro-specific build options.
  36 AC_MSG_CHECKING([host distribution])
  37 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, paldo, openmandriva or pardus.]))
  38 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  39         with_distro=`lsb_release -is`
  40 fi
  41 if test "z$with_distro" = "z"; then
  42         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  43         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  44         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  45         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  46         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  47         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  48         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  49         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  50         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  51         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  52         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  53         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  54         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  55 fi
  56 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  57
  58 if test "z$with_distro" = "z"; then
  59         with_distro="unknown"
  60 fi
  61 case $with_distro in
  62         ubuntu|raspbian)
  63                 distroconf=default.conf.lxcbr
  64                 distrosysconf="$sysconfdir/default"
  65                 ;;
  66         redhat|centos|fedora|oracle|oracleserver|suse|opensuse*)
  67                 distroconf=default.conf.lxcbr
  68                 distrosysconf="$sysconfdir/sysconfig"
  69                 ;;
  70         *)
  71                 distroconf=default.conf.unknown
  72                 distrosysconf="$sysconfdir/default"
  73                 ;;
  74 esac
  75 AC_MSG_RESULT([$with_distro])
  76 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
  77 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  78
  79 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
  80
  81 # Check for init system type
  82 AC_MSG_CHECKING([for init system type])
  83 AC_ARG_WITH([init-script],
  84             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  85                             [Type(s) of init script to install: sysvinit, systemd, upstart,
  86                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  87 case "$with_init_script" in
  88         distro)
  89                 case $with_distro in
  90                         fedora|opensuse*)
  91                                 init_script=systemd
  92                                 ;;
  93                         redhat|centos|oracle|oracleserver)
  94                                 init_script=sysvinit
  95                                 ;;
  96                         debian|raspbian)
  97                                 init_script=upstart,systemd
  98                                 ;;
  99                         ubuntu)
 100                                 init_script=upstart,systemd
 101                                 ;;
 102                         *)
 103                                 echo -n "Linux distribution init system unknown."
 104                                 init_script=
 105                                 ;;
 106                 esac
 107                 ;;
 108         *)
 109                 init_script=$with_init_script
 110                 ;;
 111 esac
 112
 113 # Check valid init systems were given, run in subshell so we don't mess up IFS
 114 (IFS="," ; for init_sys in $init_script;
 115 do
 116         case "$init_sys" in
 117                 none|sysvinit|systemd|upstart)
 118                         ;;
 119                 *)
 120                         exit 1
 121                         ;;
 122         esac
 123 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 124
 125 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 126 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 127 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 128 AC_MSG_RESULT($init_script)
 129
 130 # systemd unit dir
 131 AC_ARG_WITH([systemdsystemunitdir],
 132             AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 133             [],
 134             [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 135 if test -z "$with_systemdsystemunitdir"; then
 136   with_systemdsystemunitdir=/lib/systemd/system
 137 fi
 138 if test "x$with_systemdsystemunitdir" != "xno"; then
 139   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 140 fi
 141
 142 # Allow disabling rpath
 143 AC_ARG_ENABLE([rpath],
 144         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 145         [], [enable_rpath=no])
 146 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 147
 148 # Documentation (manpages)
 149 AC_ARG_ENABLE([doc],
 150         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 151         [], [enable_doc=auto])
 152
 153 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 154         db2xman=""
 155         dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 156
 157         AC_MSG_CHECKING(for docbook2x-man)
 158         for name in ${dbparsers}; do
 159                 if "$name" --help >/dev/null 2>&1; then
 160                         db2xman="$name"
 161                         break;
 162                 fi
 163         done
 164
 165         if test -n "${db2xman}"; then
 166                 AC_MSG_RESULT([${db2xman}])
 167                 enable_doc="yes"
 168         else
 169                 AC_MSG_RESULT([no])
 170                 if test "x$enable_doc" = "xyes"; then
 171                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 172                 fi
 173                 enable_doc="no"
 174         fi
 175
 176         AC_SUBST(db2xman)
 177 fi
 178 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 179 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 180
 181 if test "x$db2xman" = "xdocbook2man"; then
 182         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 183 else
 184         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 185 fi
 186 AC_SUBST(docdtd)
 187
 188 # Documentation (API)
 189 AC_ARG_ENABLE([api-docs],
 190         [AC_HELP_STRING([--enable-api-docs],
 191         [make API documentation [default=auto]])],
 192         [], [enable_api_docs=auto])
 193
 194 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 195         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 196         AC_SUBST([HAVE_DOXYGEN])
 197
 198         if test "x$HAVE_DOXYGEN" != "x"; then
 199                 enable_api_docs="yes"
 200         else
 201                 if test "x$enable_api_docs" = "xyes"; then
 202                         AC_MSG_ERROR([doxygen is required, but could not be found])
 203                 fi
 204                 enable_api_docs="no"
 205         fi
 206 fi
 207
 208 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 209
 210 # Apparmor
 211 AC_ARG_ENABLE([apparmor],
 212         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 213         [], [enable_apparmor=auto])
 214
 215 if test "$enable_apparmor" = "auto" ; then
 216         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 217 fi
 218 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 219
 220 AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 221
 222 AM_COND_IF([ENABLE_APPARMOR],
 223         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 224         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 225         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 226
 227 # SELinux
 228 AC_ARG_ENABLE([selinux],
 229         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 230         [], [enable_selinux=auto])
 231
 232 if test "x$enable_selinux" = xauto; then
 233         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 234 fi
 235 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 236 AM_COND_IF([ENABLE_SELINUX],
 237         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 238         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 239         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 240
 241 # Seccomp syscall filter
 242 AC_ARG_ENABLE([seccomp],
 243         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 244         [], [enable_seccomp=auto])
 245
 246 if test "x$enable_seccomp" = "xauto" ; then
 247         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 248 fi
 249 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 250
 251 AM_COND_IF([ENABLE_SECCOMP],
 252         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 253                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 254                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 255                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 256                 ])
 257         ])
 258
 259 # cgmanager
 260 AC_ARG_ENABLE([cgmanager],
 261         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 262         [], [enable_cgmanager=auto])
 263
 264 if test "x$enable_cgmanager" = "xauto" ; then
 265         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1])
 266 fi
 267 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 268
 269 AM_COND_IF([ENABLE_CGMANAGER],
 270         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 271         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 272         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 273         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 274         ])
 275
 276 AC_MSG_CHECKING(for get_pid_cgroup_abs_sync)
 277 save_LIBS=$LIBS
 278 AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1])
 279 LIBS=$save_LIBS
 280 if test "x$have_abs_cgroups" = "xyes"; then
 281         AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync])
 282         AC_MSG_RESULT([yes])
 283 else
 284         AC_MSG_RESULT([no])
 285 fi
 286
 287 # Check for static libcap, make sure the function checked for differs from the
 288 # the one checked below so the cache doesn't give a wrong answer
 289 OLD_CFLAGS="$CFLAGS"
 290 CFLAGS="$CFLAGS -static"
 291 AC_CHECK_LIB([cap],[cap_init],[have_static_libcap=yes],[have_static_libcap=no])
 292 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 293 if test "x$have_static_libcap" = "xyes"; then
 294         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 295 fi
 296 CFLAGS="$OLD_CFLAGS"
 297
 298
 299 # Linux capabilities
 300 AC_ARG_ENABLE([capabilities],
 301         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 302         [], [enable_capabilities=auto])
 303
 304 if test "x$enable_capabilities" = "xauto"; then
 305         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 306 fi
 307 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 308
 309 AM_COND_IF([ENABLE_CAP],
 310         [AC_CHECK_LIB(cap,cap_set_proc,[true],[AC_MSG_ERROR([You are missing libcap support.])])
 311         AC_SUBST([CAP_LIBS], [-lcap])])
 312
 313 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 314 OLD_CFLAGS="$CFLAGS"
 315 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 316 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 317 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 318 CFLAGS="$OLD_CFLAGS"
 319
 320 # Configuration examples
 321 AC_ARG_ENABLE([examples],
 322         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 323         [], [enable_examples=yes])
 324 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 325
 326 # Python3 module and scripts
 327 AC_ARG_ENABLE([python],
 328         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 329         [], [enable_python=auto])
 330
 331 if test "x$enable_python" = "xauto"; then
 332         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 333         if test "$CC" = "clang"; then
 334                 enable_python=no
 335         fi
 336 fi
 337
 338 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 339         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 340 fi
 341
 342 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 343
 344 AM_COND_IF([ENABLE_PYTHON],
 345         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 346         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 347         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 348
 349 # Enable dumping stack traces
 350 AC_ARG_ENABLE([mutex-debugging],
 351         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 352         [], [enable_mutex_debugging=no])
 353 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 354
 355 AM_COND_IF([MUTEX_DEBUGGING],
 356         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 357
 358 # Not in older autoconf versions
 359 # AS_VAR_COPY(DEST, SOURCE)
 360 # -------------------------
 361 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 362 # shell variable SOURCE.
 363 m4_ifdef([AS_VAR_COPY], [],
 364 [AC_DEFUN([AS_VAR_COPY],
 365     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 366 ])
 367
 368 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 369 m4_ifdef([PKG_CHECK_VAR], [],
 370 [AC_DEFUN([PKG_CHECK_VAR],
 371     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 372      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 373      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 374      AS_VAR_COPY([$1], [pkg_cv_][$1])
 375      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 376     ])# PKG_CHECK_VAR
 377 ])
 378
 379 # Lua module and scripts
 380 AC_ARG_ENABLE([lua],
 381         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 382         [], [enable_lua=auto])
 383
 384 AC_ARG_WITH([lua-pc],
 385         [AS_HELP_STRING(
 386                 [--with-lua-pc=PKG],
 387                 [Specify pkg-config package name for lua]
 388         )], [], [with_lua_pc=no])
 389
 390 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 391         # exit with error if not found
 392         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 393 fi
 394
 395 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 396         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 397                 [LUAPKGCONFIG=$with_lua_pc
 398                 enable_lua=yes],
 399                 [enable_lua=no])
 400 fi
 401
 402 if test "x$enable_lua" != "xno"; then
 403         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 404                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 405                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 406                                 [AS_IF([test "x$enable_lua" = "xyes"],
 407                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 408                                         [enable_lua=no])]
 409                         )]
 410                 )])
 411         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 412 fi
 413
 414 AM_CONDITIONAL([ENABLE_LUA],
 415         [test "x$enable_lua" = "xyes"])
 416
 417 AM_COND_IF([ENABLE_LUA],
 418         [AC_MSG_CHECKING([Lua version])
 419         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 420                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 421         AC_MSG_RESULT([$LUA_VERSION])
 422         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 423         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 424         ])
 425
 426 # Optional bash integration
 427 AC_ARG_ENABLE([bash],
 428         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 429         [], [enable_bash=yes])
 430 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 431
 432 # Optional test binaries
 433 AC_ARG_ENABLE([tests],
 434         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 435         [], [enable_tests=no])
 436 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 437
 438 # Allow overriding the default runtime dir (/run)
 439 AC_ARG_WITH([runtime-path],
 440         [AC_HELP_STRING(
 441                 [--with-runtime-path=dir],
 442                 [runtime directory (default: /run)]
 443         )], [], [with_runtime_path=['/run']])
 444
 445 # LXC container path, where the containers are actually stored
 446 # This is overridden by an entry in the file called LXCCONF
 447 # (i.e. /etc/lxc/lxc.conf)
 448 AC_ARG_WITH([config-path],
 449         [AC_HELP_STRING(
 450                 [--with-config-path=dir],
 451                 [lxc configuration repository path]
 452         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 453
 454 # The path of the global lxc configuration file.
 455 AC_ARG_WITH([global-conf],
 456         [AC_HELP_STRING(
 457                 [--with-global-conf=dir],
 458                 [global lxc configuration file]
 459         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 460
 461 # The path of the userns network configuration file
 462 AC_ARG_WITH([usernic-conf],
 463         [AC_HELP_STRING(
 464                 [--with-usernic-conf],
 465                 [user network interface configuration file]
 466         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 467
 468 # The path of the runtime usernic database
 469 AC_ARG_WITH([usernic-db],
 470         [AC_HELP_STRING(
 471                 [--with-usernic-db],
 472                 [lxc user nic database]
 473         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 474
 475 # Rootfs path, where the container mount structure is assembled
 476 AC_ARG_WITH([rootfs-path],
 477         [AC_HELP_STRING(
 478                 [--with-rootfs-path=dir],
 479                 [lxc rootfs mount point]
 480         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 481
 482 # cgroup pattern specification
 483 AC_ARG_WITH([cgroup-pattern],
 484         [AC_HELP_STRING(
 485                 [--with-cgroup-pattern=pattern],
 486                 [pattern for container cgroups]
 487         )], [], [with_cgroup_pattern=['/lxc/%n']])
 488
 489 # Container log path.  By default, use $lxcpath.
 490 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 491 AC_ARG_ENABLE([configpath-log],
 492         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 493         [], [enable_configpath_log=no])
 494 AC_MSG_RESULT([$enable_configpath_log])
 495 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 496
 497 if test "$enable_configpath_log" = "yes"; then
 498         default_log_path="${with_config_path}"
 499 else
 500         default_log_path="${localstatedir}/log/lxc"
 501 fi
 502
 503 AC_ARG_WITH([log-path],
 504         [AC_HELP_STRING(
 505                 [--with-log-path=dir],
 506                 [per container log path]
 507         )], [], [with_log_path=['${default_log_path}']])
 508
 509 # Expand some useful variables
 510 AS_AC_EXPAND(PREFIX, "$prefix")
 511 AS_AC_EXPAND(LIBDIR, "$libdir")
 512 AS_AC_EXPAND(BINDIR, "$bindir")
 513 AS_AC_EXPAND(SBINDIR, "$sbindir")
 514 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 515 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 516 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 517 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 518 AS_AC_EXPAND(DATADIR, "$datadir")
 519 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 520 AS_AC_EXPAND(DOCDIR, "$docdir")
 521 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 522 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 523 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 524 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 525 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 526 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 527 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 528 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 529 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 530 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 531 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 532 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 533 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 534 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 535
 536 # We need the install path so criu knows where to reference the hook scripts.
 537 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 538
 539 # Check for some standard kernel headers
 540 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 541                                 [],
 542                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 543                                 [#include <sys/socket.h>])
 544
 545 # Check for alternate C libraries
 546 AC_MSG_CHECKING(for bionic libc)
 547 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 548         [[#ifndef __ANDROID__
 549 error: Not bionic!
 550 #endif]])],
 551         [is_bionic=yes],
 552         [is_bionic=no])
 553 if test "x$is_bionic" = "xyes"; then
 554         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 555         AC_MSG_RESULT([yes])
 556 else
 557         AC_MSG_RESULT([no])
 558 fi
 559 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 560
 561 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 562 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 563
 564 # Check for some headers
 565 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 566
 567 # Check for some syscalls functions
 568 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat])
 569
 570 # Check for some functions
 571 AC_CHECK_LIB(pthread, main)
 572 AC_CHECK_FUNCS(pthread_atfork)
 573 AC_CHECK_FUNCS(statvfs)
 574 AC_CHECK_LIB(util, openpty)
 575 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 576 AC_CHECK_FUNCS([getline],
 577         AM_CONDITIONAL(HAVE_GETLINE, true)
 578         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 579         AM_CONDITIONAL(HAVE_GETLINE, false))
 580 AC_CHECK_FUNCS([fgetln],
 581         AM_CONDITIONAL(HAVE_FGETLN, true)
 582         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 583         AM_CONDITIONAL(HAVE_FGETLN, false))
 584
 585 # Check for some libraries
 586 AC_SEARCH_LIBS(sem_open, [rt pthread])
 587 AC_SEARCH_LIBS(clock_gettime, [rt])
 588
 589 # Check for some standard binaries
 590 AC_PROG_GCC_TRADITIONAL
 591 AC_PROG_SED
 592
 593 # See if we support thread-local storage.
 594 LXC_CHECK_TLS
 595
 596 if test "x$GCC" = "xyes"; then
 597         CFLAGS="$CFLAGS -Wall -Werror"
 598 fi
 599
 600 # Files requiring some variable expansion
 601 AC_CONFIG_FILES([
 602         Makefile
 603         lxc.pc
 604         lxc.spec
 605
 606         config/Makefile
 607         config/apparmor/Makefile
 608         config/selinux/Makefile
 609         config/bash/Makefile
 610         config/bash/lxc
 611         config/init/Makefile
 612         config/init/common/Makefile
 613         config/init/common/lxc-containers
 614         config/init/common/lxc-net
 615         config/init/systemd/Makefile
 616         config/init/systemd/lxc.service
 617         config/init/systemd/lxc-net.service
 618         config/init/sysvinit/Makefile
 619         config/init/sysvinit/lxc-containers
 620         config/init/sysvinit/lxc-net
 621         config/init/upstart/lxc-net.conf
 622         config/init/upstart/Makefile
 623         config/etc/Makefile
 624         config/templates/Makefile
 625         config/templates/archlinux.common.conf
 626         config/templates/archlinux.userns.conf
 627         config/templates/centos.common.conf
 628         config/templates/centos.userns.conf
 629         config/templates/common.conf
 630         config/templates/debian.common.conf
 631         config/templates/debian.userns.conf
 632         config/templates/fedora.common.conf
 633         config/templates/fedora.userns.conf
 634         config/templates/gentoo.common.conf
 635         config/templates/gentoo.moresecure.conf
 636         config/templates/gentoo.userns.conf
 637         config/templates/opensuse.common.conf
 638         config/templates/opensuse.userns.conf
 639         config/templates/oracle.common.conf
 640         config/templates/oracle.userns.conf
 641         config/templates/plamo.common.conf
 642         config/templates/plamo.userns.conf
 643         config/templates/ubuntu-cloud.common.conf
 644         config/templates/ubuntu-cloud.lucid.conf
 645         config/templates/ubuntu-cloud.userns.conf
 646         config/templates/ubuntu.common.conf
 647         config/templates/ubuntu.lucid.conf
 648         config/templates/ubuntu.userns.conf
 649         config/templates/openwrt.common.conf
 650         config/templates/userns.conf
 651         config/yum/Makefile
 652         config/sysconfig/Makefile
 653         config/sysconfig/lxc
 654
 655         doc/Makefile
 656         doc/api/Makefile
 657         doc/legacy/lxc-ls.sgml
 658         doc/lxc-attach.sgml
 659         doc/lxc-autostart.sgml
 660         doc/lxc-cgroup.sgml
 661         doc/lxc-checkconfig.sgml
 662         doc/lxc-checkpoint.sgml
 663         doc/lxc-clone.sgml
 664         doc/lxc-config.sgml
 665         doc/lxc-console.sgml
 666         doc/lxc-create.sgml
 667         doc/lxc-destroy.sgml
 668         doc/lxc-device.sgml
 669         doc/lxc-execute.sgml
 670         doc/lxc-freeze.sgml
 671         doc/lxc-info.sgml
 672         doc/lxc-ls.sgml
 673         doc/lxc-monitor.sgml
 674         doc/lxc-snapshot.sgml
 675         doc/lxc-start-ephemeral.sgml
 676         doc/lxc-start.sgml
 677         doc/lxc-stop.sgml
 678         doc/lxc-top.sgml
 679         doc/lxc-unfreeze.sgml
 680         doc/lxc-unshare.sgml
 681         doc/lxc-user-nic.sgml
 682         doc/lxc-usernsexec.sgml
 683         doc/lxc-wait.sgml
 684
 685         doc/lxc.conf.sgml
 686         doc/lxc.container.conf.sgml
 687         doc/lxc.system.conf.sgml
 688         doc/lxc-usernet.sgml
 689         doc/lxc.sgml
 690         doc/common_options.sgml
 691         doc/see_also.sgml
 692
 693         doc/rootfs/Makefile
 694
 695         doc/examples/Makefile
 696         doc/examples/lxc-macvlan.conf
 697         doc/examples/lxc-vlan.conf
 698         doc/examples/lxc-no-netns.conf
 699         doc/examples/lxc-empty-netns.conf
 700         doc/examples/lxc-phys.conf
 701         doc/examples/lxc-veth.conf
 702         doc/examples/lxc-complex.conf
 703
 704         doc/ja/Makefile
 705         doc/ja/legacy/lxc-ls.sgml
 706         doc/ja/lxc-attach.sgml
 707         doc/ja/lxc-autostart.sgml
 708         doc/ja/lxc-cgroup.sgml
 709         doc/ja/lxc-checkconfig.sgml
 710         doc/ja/lxc-checkpoint.sgml
 711         doc/ja/lxc-clone.sgml
 712         doc/ja/lxc-config.sgml
 713         doc/ja/lxc-console.sgml
 714         doc/ja/lxc-create.sgml
 715         doc/ja/lxc-destroy.sgml
 716         doc/ja/lxc-device.sgml
 717         doc/ja/lxc-execute.sgml
 718         doc/ja/lxc-freeze.sgml
 719         doc/ja/lxc-info.sgml
 720         doc/ja/lxc-ls.sgml
 721         doc/ja/lxc-monitor.sgml
 722         doc/ja/lxc-snapshot.sgml
 723         doc/ja/lxc-start-ephemeral.sgml
 724         doc/ja/lxc-start.sgml
 725         doc/ja/lxc-stop.sgml
 726         doc/ja/lxc-top.sgml
 727         doc/ja/lxc-unfreeze.sgml
 728         doc/ja/lxc-unshare.sgml
 729         doc/ja/lxc-user-nic.sgml
 730         doc/ja/lxc-usernsexec.sgml
 731         doc/ja/lxc-wait.sgml
 732
 733         doc/ja/lxc.conf.sgml
 734         doc/ja/lxc.container.conf.sgml
 735         doc/ja/lxc.system.conf.sgml
 736         doc/ja/lxc-usernet.sgml
 737         doc/ja/lxc.sgml
 738         doc/ja/common_options.sgml
 739         doc/ja/see_also.sgml
 740
 741         hooks/Makefile
 742
 743         templates/Makefile
 744         templates/lxc-alpine
 745         templates/lxc-altlinux
 746         templates/lxc-archlinux
 747         templates/lxc-busybox
 748         templates/lxc-centos
 749         templates/lxc-cirros
 750         templates/lxc-debian
 751         templates/lxc-download
 752         templates/lxc-fedora
 753         templates/lxc-gentoo
 754         templates/lxc-openmandriva
 755         templates/lxc-opensuse
 756         templates/lxc-oracle
 757         templates/lxc-plamo
 758         templates/lxc-sshd
 759         templates/lxc-ubuntu
 760         templates/lxc-ubuntu-cloud
 761
 762         src/Makefile
 763         src/lxc/Makefile
 764         src/lxc/lxc-checkconfig
 765         src/lxc/lxc-ls
 766         src/lxc/lxc-start-ephemeral
 767         src/lxc/legacy/lxc-ls
 768         src/lxc/lxc.functions
 769         src/lxc/version.h
 770         src/python-lxc/Makefile
 771         src/python-lxc/setup.py
 772
 773         src/lua-lxc/Makefile
 774
 775         src/tests/Makefile
 776         src/tests/lxc-test-usernic
 777 ])
 778 AC_CONFIG_COMMANDS([default],[[]],[[]])
 779 AC_OUTPUT
 780
 781 # Configuration overview
 782 cat << EOF
 783
 784 ----------------------------
 785 Environment:
 786  - compiler: $CC
 787  - distribution: $with_distro
 788  - init script type(s): $init_script
 789  - rpath: $enable_rpath
 790  - GnuTLS: $enable_gnutls
 791  - Bash integration: $enable_bash
 792
 793 Security features:
 794  - Apparmor: $enable_apparmor
 795  - Linux capabilities: $enable_capabilities
 796  - seccomp: $enable_seccomp
 797  - SELinux: $enable_selinux
 798  - cgmanager: $enable_cgmanager
 799
 800 Bindings:
 801  - lua: $enable_lua
 802  - python3: $enable_python
 803
 804 Documentation:
 805  - examples: $enable_examples
 806  - API documentation: $enable_api_docs
 807  - user documentation: $enable_doc
 808
 809 Debugging:
 810  - tests: $enable_tests
 811  - mutex debugging: $enable_mutex_debugging
 812
 813 Paths:
 814  - Logs in configpath: $enable_configpath_log
 815 EOF
 816
 817 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 818 cat << EOF
 819
 820 WARNING: Threading not supported on your platform
 821
 822         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 823         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 824 EOF
 825 fi