configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.1-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST([HOSTTOOLS])
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS([config.h])
  64
  65 AC_PATH_PROG([PERL], [perl])
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST([exampledir])
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST([pkgsrcrcdir])
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94
  95 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
  96         yangmodelsdir="$withval"
  97 ], [
  98         yangmodelsdir="\${datarootdir}/yang"
  99 ])
 100 AC_SUBST([yangmodelsdir])
 101
 102 AC_ARG_WITH([libyang_pluginsdir], [AS_HELP_STRING([--with-libyang-pluginsdir=DIR], [yangmodule plugins directory (${libdir}/frr/libyang_plugins)])], [
 103         libyang_pluginsdir="$withval"
 104 ], [
 105    libyang_pluginsdir="\${libdir}/frr/libyang_plugins"
 106 ])
 107 AC_SUBST([libyang_pluginsdir])
 108
 109 AC_ARG_ENABLE(tcmalloc,
 110         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 111 [case "${enableval}" in
 112   yes) tcmalloc_enabled=true
 113 LIBS="$LIBS -ltcmalloc_minimal"
 114  ;;
 115   no)  tcmalloc_enabled=false ;;
 116   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 117 esac],[tcmalloc_enabled=false])
 118
 119
 120 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 121 dnl flag determination logic.
 122 CFLAGS="${CFLAGS:-}"
 123
 124 dnl --------------------
 125 dnl Check CC and friends
 126 dnl --------------------
 127 dnl note orig_cflags is also used further down
 128 orig_cflags="$CFLAGS"
 129 AC_LANG([C])
 130 AC_PROG_CC
 131 AC_PROG_CPP
 132 AM_PROG_CC_C_O
 133 dnl remove autoconf default "-g -O2"
 134 CFLAGS="$orig_cflags"
 135 AC_PROG_CC_C99
 136 dnl NB: see C11 below
 137
 138 AC_PROG_EGREP
 139 PKG_PROG_PKG_CONFIG
 140
 141 dnl autoconf 2.59 appears not to support AC_PROG_SED
 142 dnl AC_PROG_SED
 143 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 144
 145 dnl try and enable CFLAGS that are useful for FRR
 146 dnl - specifically, options to control warnings
 147
 148 AC_USE_SYSTEM_EXTENSIONS
 149 AC_DEFUN([AC_C_FLAG], [{
 150     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 151     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 152         AC_LANG_PUSH([C])
 153         ac_c_flag_save="$CFLAGS"
 154         CFLAGS="$CFLAGS $1"
 155         AC_COMPILE_IFELSE(
 156                 [AC_LANG_PROGRAM([[]])],
 157                 [
 158                         cachename=yes
 159                 ], [
 160                         cachename=no
 161                 ])
 162         CFLAGS="$ac_c_flag_save"
 163         AC_LANG_POP([C])
 164     ])
 165     if test "${cachename}" = yes; then
 166         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 167     else
 168         :
 169         $2
 170     fi
 171     m4_popdef([cachename])
 172 }])
 173
 174 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 175         AC_LANG_PUSH([C])
 176         ac_cflags_save="$CFLAGS"
 177         ac_libs_save="$LIBS"
 178         CFLAGS="$CFLAGS $1"
 179         LIBS="$LIBS $2"
 180         AC_LINK_IFELSE(
 181                 [$3],
 182                 [
 183                         AC_MSG_RESULT([yes])
 184                         CFLAGS="$ac_cflags_save"
 185                         LIBS="$ac_libs_save"
 186                         $5
 187                 ], [
 188                         AC_MSG_RESULT([no])
 189                         CFLAGS="$ac_cflags_save"
 190                         LIBS="$ac_libs_save"
 191                         $4
 192                 ])
 193         AC_LANG_POP([C])
 194         }])
 195
 196 dnl ICC won't bail on unknown options without -diag-error 10006
 197 dnl need to do this first so we get useful results for the other options
 198 AC_C_FLAG([-diag-error 10006])
 199
 200 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 201 ac_cc="$CC"
 202 CC="${CC% -std=gnu99}"
 203 CC="${CC% -std=c99}"
 204
 205 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 206
 207 dnl if the user has specified any CFLAGS, override our settings
 208 if test "x${enable_gcov}" = "xyes"; then
 209    if test "z$orig_cflags" = "z"; then
 210       AC_C_FLAG([-coverage])
 211       AC_C_FLAG([-O0])
 212    fi
 213
 214    LDFLAGS="${LDFLAGS} -lgcov"
 215 elif test "x${enable_dev_build}" = "xyes"; then
 216    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 217    if test "z$orig_cflags" = "z"; then
 218       AC_C_FLAG([-g3])
 219       AC_C_FLAG([-O0])
 220    fi
 221    if test "x${enable_lua}" = "xyes"; then
 222       AC_CHECK_LIB([lua], [lua_newstate],
 223       [LIBS="$LIBS -llua"])
 224       AC_DEFINE([HAVE_LUA], [1], [Lua enabled for development])
 225    fi
 226 else
 227    if test "x${enable_lua}" = "xyes"; then
 228       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 229    fi
 230    if test "z$orig_cflags" = "z"; then
 231       AC_C_FLAG([-g])
 232       AC_C_FLAG([-Os], [
 233         AC_C_FLAG([-O2])
 234       ])
 235    fi
 236 fi
 237 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 238
 239 dnl always want these CFLAGS
 240 AC_C_FLAG([-fno-omit-frame-pointer])
 241 AC_C_FLAG([-funwind-tables])
 242 AC_C_FLAG([-Wall])
 243 AC_C_FLAG([-Wextra])
 244 AC_C_FLAG([-Wmissing-prototypes])
 245 AC_C_FLAG([-Wmissing-declarations])
 246 AC_C_FLAG([-Wpointer-arith])
 247 AC_C_FLAG([-Wbad-function-cast])
 248 AC_C_FLAG([-Wwrite-strings])
 249 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 250   AC_C_FLAG([-Wcast-qual])
 251   AC_C_FLAG([-Wstrict-prototypes])
 252   AC_C_FLAG([-Wmissing-noreturn])
 253   AC_C_FLAG([-Wmissing-format-attribute])
 254   AC_C_FLAG([-Wunreachable-code])
 255   AC_C_FLAG([-Wpacked])
 256   AC_C_FLAG([-Wpadded])
 257   AC_C_FLAG([-Wshadow])
 258 else
 259   AC_C_FLAG([-Wno-unused-result])
 260 fi
 261 AC_C_FLAG([-Wno-unused-parameter])
 262 AC_C_FLAG([-Wno-missing-field-initializers])
 263
 264 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 265 dnl for some reason the string consts get 'promoted' to char *,
 266 dnl triggering a const to non-const conversion warning.
 267 AC_C_FLAG([-diag-disable 3179])
 268
 269 if test x"${enable_werror}" = x"yes" ; then
 270   WERROR="-Werror"
 271 fi
 272 AC_SUBST([WERROR])
 273
 274 SAN_FLAGS=""
 275 if test "$enable_address_sanitizer" = "yes"; then
 276   AC_C_FLAG([-fsanitize=address], [
 277     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 278   ], [
 279     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 280   ])
 281 fi
 282 if test "$enable_thread_sanitizer" = "yes"; then
 283   AC_C_FLAG([-fsanitize=thread], [
 284     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 285   ], [
 286     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 287   ])
 288 fi
 289 if test "$enable_memory_sanitizer" = "yes"; then
 290   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 291     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 292   ], [
 293     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 294   ])
 295 fi
 296 AC_SUBST([SAN_FLAGS])
 297
 298 dnl ----------
 299 dnl Essentials
 300 dnl ----------
 301
 302 AX_PTHREAD([
 303   CC="$PTHREAD_CC"
 304   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 305   LIBS="$PTHREAD_LIBS $LIBS"
 306 ], [
 307   AC_MSG_FAILURE([This FRR version needs pthreads])
 308 ])
 309
 310 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 311                 [frr_cv_pthread_condattr_setclock=yes],
 312                 [frr_cv_pthread_condattr_setclock=no])
 313 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 314   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 315 fi
 316
 317 dnl --------------
 318 dnl Check programs
 319 dnl --------------
 320 AC_PROG_INSTALL
 321 AC_PROG_LN_S
 322 AC_PROG_MAKE_SET
 323 AC_CHECK_TOOL([AR], [ar])
 324
 325 dnl -------
 326 dnl libtool
 327 dnl -------
 328 AC_ARG_ENABLE([static-bin],
 329   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 330 LT_INIT
 331 _LT_CONFIG_LIBTOOL([
 332   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 333     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 334 ])
 335 if test "$enable_static_bin" = "yes"; then
 336   AC_LDFLAGS="-static"
 337   if test "$enable_static" != "yes"; then
 338     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 339   fi
 340 fi
 341 if test "$enable_shared" != "yes"; then
 342   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 343 fi
 344 AC_SUBST([AC_LDFLAGS])
 345 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 346
 347 dnl $AR and $RANLIB are set by LT_INIT above
 348 AC_MSG_CHECKING([whether $AR supports D option])
 349 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 350   AC_MSG_RESULT([yes])
 351   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 352   ARFLAGS="crD"
 353   AR_FLAGS="crD"
 354 else
 355   AC_MSG_RESULT([no])
 356   ARFLAGS="cru"
 357   AR_FLAGS="cru"
 358 fi
 359 AC_SUBST([ARFLAGS])
 360 AC_SUBST([AR_FLAGS])
 361
 362 AC_MSG_CHECKING([whether $RANLIB supports D option])
 363 if $RANLIB -D conftest.a >/dev/null 2>/dev/null; then
 364   AC_MSG_RESULT([yes])
 365   RANLIB="$RANLIB -D"
 366 else
 367   AC_MSG_RESULT([no])
 368 fi
 369 AC_SUBST([RANLIB])
 370
 371 test -f conftest.a && rm conftest.a
 372
 373 dnl ----------------------
 374 dnl Packages configuration
 375 dnl ----------------------
 376 if test -f config.version; then
 377   . ./config.version
 378 elif test -f "${srcdir}/config.version"; then
 379   . "${srcdir}/config.version"
 380 fi
 381 AC_ARG_WITH([pkg-extra-version],
 382   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 383   if test "$withval" = "no"; then
 384     EXTRAVERSION=
 385   else
 386     EXTRAVERSION=$withval
 387   fi
 388 ], [])
 389 AC_ARG_WITH([pkg-git-version],
 390         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 391         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 392 AC_ARG_WITH([vtysh_pager],
 393         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 394         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 395 AC_ARG_ENABLE([vtysh],
 396   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 397 AC_ARG_ENABLE([doc],
 398   AS_HELP_STRING([--disable-doc], [do not build docs]))
 399 AC_ARG_ENABLE([doc-html],
 400   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 401 AC_ARG_ENABLE([zebra],
 402   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 403 AC_ARG_ENABLE([bgpd],
 404   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 405 AC_ARG_ENABLE([ripd],
 406   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 407 AC_ARG_ENABLE([ripngd],
 408   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 409 AC_ARG_ENABLE([ospfd],
 410   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 411 AC_ARG_ENABLE([ospf6d],
 412   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 413 AC_ARG_ENABLE([ldpd],
 414   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 415 AC_ARG_ENABLE([nhrpd],
 416   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 417 AC_ARG_ENABLE([eigrpd],
 418   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 419 AC_ARG_ENABLE([babeld],
 420   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 421 AC_ARG_ENABLE([watchfrr],
 422   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 423 AC_ARG_ENABLE([isisd],
 424   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 425 AC_ARG_ENABLE([pimd],
 426   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 427 AC_ARG_ENABLE([pbrd],
 428   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 429 AC_ARG_ENABLE([sharpd],
 430   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 431 AC_ARG_ENABLE([staticd],
 432   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 433 AC_ARG_ENABLE([fabricd],
 434   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 435 AC_ARG_ENABLE([bgp-announce],
 436   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 437 AC_ARG_ENABLE([bgp-vnc],
 438   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 439 AC_ARG_ENABLE([snmp],
 440   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 441 AC_ARG_ENABLE([config_rollbacks],
 442   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 443 AC_ARG_ENABLE([confd],
 444   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 445 AC_ARG_ENABLE([sysrepo],
 446   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 447 AC_ARG_ENABLE([zeromq],
 448   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 449 AC_ARG_WITH([libpam],
 450   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 451 AC_ARG_ENABLE([ospfapi],
 452   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 453 AC_ARG_ENABLE([ospfclient],
 454   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 455                           (this is the default if --disable-ospfapi is set)]))
 456 AC_ARG_ENABLE([multipath],
 457   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 458 AC_ARG_ENABLE([user],
 459   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 460 AC_ARG_ENABLE([group],
 461   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 462 AC_ARG_ENABLE([vty_group],
 463   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 464 AC_ARG_ENABLE([configfile_mask],
 465   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 466 AC_ARG_ENABLE([logfile_mask],
 467   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 468 AC_ARG_ENABLE([shell_access],
 469   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 470 AC_ARG_ENABLE([realms],
 471   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 472 AC_ARG_ENABLE([rtadv],
 473   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 474 AC_ARG_ENABLE([irdp],
 475   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 476 AC_ARG_ENABLE([capabilities],
 477   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 478 AC_ARG_ENABLE([rusage],
 479   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 480 AC_ARG_ENABLE([gcc_ultra_verbose],
 481   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 482 AC_ARG_ENABLE([backtrace],
 483   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 484 AC_ARG_ENABLE([time-check],
 485   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 486 AC_ARG_ENABLE([pcreposix],
 487   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 488 AC_ARG_ENABLE([fpm],
 489   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 490 AC_ARG_ENABLE([systemd],
 491   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 492 AC_ARG_ENABLE([werror],
 493   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 494 AC_ARG_ENABLE([cumulus],
 495   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 496 AC_ARG_ENABLE([datacenter],
 497   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 498 AC_ARG_ENABLE([fuzzing],
 499   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 500 AC_ARG_ENABLE([netlink_fuzzing],
 501   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 502 AC_ARG_ENABLE([rr-semantics],
 503   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 504 AC_ARG_ENABLE([protobuf],
 505   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 506 AC_ARG_ENABLE([oldvpn_commands],
 507   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 508 AC_ARG_ENABLE([rpki],
 509   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 510 AC_ARG_ENABLE([clippy-only],
 511   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 512 AC_ARG_ENABLE([numeric_version],
 513   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 514 AC_ARG_ENABLE([gcov],
 515   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 516 AC_ARG_ENABLE([bfdd],
 517   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 518 AC_ARG_ENABLE([address-sanitizer],
 519   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 520 AC_ARG_ENABLE([thread-sanitizer],
 521   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 522 AC_ARG_ENABLE([memory-sanitizer],
 523   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 524
 525 AS_IF([test "${enable_clippy_only}" != "yes"], [
 526 AC_CHECK_HEADERS([json-c/json.h])
 527 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 528 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 529   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 530   if test "$ac_cv_lib_json_json_object_get" = no; then
 531       AC_MSG_ERROR([libjson is needed to compile])
 532   fi
 533 fi
 534 ])
 535
 536 AC_ARG_ENABLE([dev_build],
 537     AS_HELP_STRING([--enable-dev-build], [build for development]))
 538
 539 AC_ARG_ENABLE([lua],
 540     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 541
 542 if test x"${enable_time_check}" != x"no" ; then
 543   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 544     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 545   else
 546     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 547   fi
 548 fi
 549
 550 case "${enable_systemd}" in
 551   "no") ;;
 552   "yes")
 553   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 554   if test $ac_cv_lib_systemd_sd_notify = no; then
 555     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 556   else
 557     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 558   fi
 559   ;;
 560   "*") ;;
 561 esac
 562
 563 if test "${enable_rr_semantics}" != "no" ; then
 564   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 565 fi
 566
 567 if test "${enable_datacenter}" = "yes" ; then
 568   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 569   DFLT_NAME="datacenter"
 570 else
 571   DFLT_NAME="traditional"
 572 fi
 573
 574 if test "${enable_fuzzing}" = "yes" ; then
 575   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 576 fi
 577
 578 if test "${enable_netlink_fuzzing}" = "yes" ; then
 579   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 580 fi
 581
 582 if test "${enable_cumulus}" = "yes" ; then
 583   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 584 fi
 585
 586 AC_SUBST([DFLT_NAME])
 587 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 588
 589 if test "${enable_shell_access}" = "yes"; then
 590    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 591 fi
 592
 593 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 594
 595 #
 596 # Python for clippy
 597 #
 598
 599 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 600   AC_MSG_CHECKING([whether we found a working Python version])
 601   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 602 #include <Python.h>
 603 #if PY_VERSION_HEX < 0x02070000
 604 #error python too old
 605 #endif
 606 int main(void);
 607 ],
 608 [
 609 {
 610   Py_Initialize();
 611   return 0;
 612 }
 613 ])], [
 614     # some python installs are missing the zlib dependency...
 615     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 616     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 617 #include <Python.h>
 618 #if PY_VERSION_HEX < 0x02070000
 619 #error python too old
 620 #endif
 621 int main(void);
 622 ],
 623 [
 624 {
 625   Py_Initialize();
 626   return 0;
 627 }
 628 ])], [
 629       m4_if([$1], [], [
 630         PYTHONCONFIG=""
 631         unset PYTHON_LIBS
 632         unset PYTHON_CFLAGS
 633       ], [$1])
 634     ])
 635   ])
 636 ])
 637
 638 AS_IF([test "$host" = "$build"], [
 639   PYTHONCONFIG=""
 640
 641   # ordering:
 642   # 1.  try python3, but respect the user's preference on which minor ver
 643   # 2.  try python, which might be py3 or py2 again on the user's preference
 644   # 3.  try python2 (can really only be 2.7 but eh)
 645   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 646   #
 647   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 648   # (AX_PYTHON does not do what we need)
 649
 650   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 651         python3-config \
 652         python-config \
 653         python2-config \
 654         python3.6-config \
 655         python3.5-config \
 656         python3.4-config \
 657         python3.3-config \
 658         python3.2-config \
 659         python2.7-config ])
 660   if test -n "$PYTHONCONFIG"; then
 661     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 662     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 663
 664     FRR_PYTHON_CHECK_WORKING([])
 665   fi
 666
 667   if test -z "$PYTHONCONFIG"; then
 668     PKG_CHECK_MODULES([PYTHON], [python-3.6], [], [
 669       PKG_CHECK_MODULES([PYTHON], [python-3.5], [], [
 670         PKG_CHECK_MODULES([PYTHON], [python-3.4], [], [
 671           PKG_CHECK_MODULES([PYTHON], [python-3.3], [], [
 672             PKG_CHECK_MODULES([PYTHON], [python-3.2], [], [
 673               PKG_CHECK_MODULES([PYTHON], [python-2.7], [], [
 674                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 675                 ])])])])])])
 676
 677
 678     FRR_PYTHON_CHECK_WORKING([
 679       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 680     ])
 681   fi
 682 ])
 683 AC_SUBST([PYTHON_CFLAGS])
 684 AC_SUBST([PYTHON_LIBS])
 685
 686 #
 687 # Logic for protobuf support.
 688 #
 689 if test "$enable_protobuf" = "yes"; then
 690   # Check for protoc & protoc-c
 691
 692   # protoc is not required, it's only for a "be nice" helper target
 693   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 694
 695   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 696   if test "$PROTOC_C" = "/bin/false"; then
 697     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 698   fi
 699
 700   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 701     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 702   ])
 703   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 704     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 705   ])
 706
 707   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
 708 fi
 709 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 710
 711 #
 712 # Logic for old vpn commands support.
 713 #
 714 if test "$enable_oldvpn_commands" = "yes"; then
 715    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 716 fi
 717
 718 #
 719 # End of logic for protobuf support.
 720 #
 721
 722 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 723 if test "${enable_rtadv}" != "no"; then
 724   AC_MSG_RESULT([yes])
 725   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 726 else
 727   AC_MSG_RESULT([no])
 728 fi
 729
 730 if test x"${enable_user}" = x"no"; then
 731   enable_user=""
 732 else
 733   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 734     enable_user="frr"
 735   fi
 736   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 737 fi
 738
 739 if test x"${enable_group}" = x"no"; then
 740   enable_group=""
 741 else
 742   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 743     enable_group="frr"
 744   fi
 745   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 746 fi
 747
 748 if test x"${enable_vty_group}" = x"yes" ; then
 749   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 750 elif test x"${enable_vty_group}" != x""; then
 751   if test x"${enable_vty_group}" != x"no"; then
 752     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 753   fi
 754 fi
 755 AC_SUBST([enable_user])
 756 AC_SUBST([enable_group])
 757 AC_SUBST([enable_vty_group])
 758
 759 enable_configfile_mask=${enable_configfile_mask:-0600}
 760 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 761
 762 enable_logfile_mask=${enable_logfile_mask:-0600}
 763 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 764
 765 MPATH_NUM=1
 766
 767 case "${enable_multipath}" in
 768   0)
 769     MPATH_NUM=64
 770     ;;
 771   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 772     MPATH_NUM="${enable_multipath}"
 773     ;;
 774   "")
 775     ;;
 776   *)
 777     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 778     ;;
 779 esac
 780
 781 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 782
 783 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 784
 785 dnl --------------------
 786 dnl Enable code coverage
 787 dnl --------------------
 788 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 789
 790 dnl ------------------------------------
 791 dnl Alpine only accepts numeric versions
 792 dnl ------------------------------------
 793 if test "x${enable_numeric_version}" != "x" ; then
 794   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 795   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 796 fi
 797
 798 dnl -----------------------------------
 799 dnl Add extra version string to package
 800 dnl name, string and version fields.
 801 dnl -----------------------------------
 802 if test "x${EXTRAVERSION}" != "x" ; then
 803   VERSION="${VERSION}${EXTRAVERSION}"
 804   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 805   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 806   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 807 fi
 808 AC_SUBST([EXTRAVERSION])
 809
 810 if test "x$with_pkg_git_version" = "xyes"; then
 811         if test -d "${srcdir}/.git"; then
 812                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 813         else    with_pkg_git_version="no"
 814                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 815         fi
 816 fi
 817 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 818
 819 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 820 if test "x${OBJCOPY}" != "x:"; then
 821   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 822     frr_cv_interp=""
 823     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 824       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 825         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 826       fi
 827       test -f conftest.interp && rm conftest.interp
 828     ])
 829   ])
 830 fi
 831 if test -n "$frr_cv_interp"; then
 832   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 833 fi
 834
 835 dnl ------------------------------------
 836 dnl Check C keywords and standard  types
 837 dnl ------------------------------------
 838 AC_C_CONST
 839 AC_C_INLINE
 840 AC_C_VOLATILE
 841 AC_HEADER_STDC
 842 dnl AC_TYPE_PID_T
 843 AC_TYPE_UID_T
 844 AC_TYPE_MODE_T
 845 AC_TYPE_SIZE_T
 846 AC_STRUCT_TM
 847
 848 dnl -------------------------
 849 dnl Check other header files.
 850 dnl -------------------------
 851 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 852         linux/version.h asm/types.h \
 853         sys/cdefs.h])
 854
 855 ac_stdatomic_ok=false
 856 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 857 AC_CHECK_HEADER([stdatomic.h],[
 858
 859   AC_MSG_CHECKING([whether _Atomic qualifier works])
 860   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 861 #include <stdatomic.h>
 862 int main(int argc, char **argv) {
 863   _Atomic int i = 0;
 864   return i;
 865 }
 866 ]])], [
 867     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 868     AC_MSG_RESULT([yes])
 869     ac_stdatomic_ok=true
 870   ], [
 871     AC_MSG_RESULT([no])
 872   ])
 873 ])
 874
 875 AS_IF([$ac_stdatomic_ok], [true], [
 876   AC_MSG_CHECKING([for __atomic_* builtins])
 877   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 878 int main(int argc, char **argv) {
 879   volatile int i = 1;
 880   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 881   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 882 }
 883 ]])], [
 884     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 885     AC_MSG_RESULT([yes])
 886   ], [
 887     AC_MSG_RESULT([no])
 888
 889     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 890     AC_MSG_CHECKING([for __sync_* builtins])
 891     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 892 int main(int argc, char **argv) {
 893   volatile int i = 1;
 894   __sync_fetch_and_sub (&i, 1);
 895   return __sync_val_compare_and_swap (&i, 0, 1);
 896 }
 897 ]])], [
 898       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 899       AC_MSG_RESULT([yes])
 900
 901       AC_MSG_CHECKING([for __sync_swap builtin])
 902       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 903 int main(int argc, char **argv) {
 904   volatile int i = 1;
 905   return __sync_swap (&i, 2);
 906 }
 907 ]])], [
 908         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 909         AC_MSG_RESULT([yes])
 910       ], [
 911         AC_MSG_RESULT([no])
 912       ])
 913
 914     ], [
 915       AC_MSG_RESULT([no])
 916       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 917     ])
 918   ])
 919 ])
 920
 921 AC_CHECK_HEADERS([pthread_np.h],,, [
 922 #include <pthread.h>
 923 ])
 924 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 925
 926 dnl Utility macro to avoid retyping includes all the time
 927 m4_define([FRR_INCLUDES],
 928 [#ifdef SUNOS_5
 929 #define _POSIX_C_SOURCE 200809L
 930 #define __EXTENSIONS__
 931 #endif
 932 #include <stdio.h>
 933 #include <stdlib.h>
 934 #include <stddef.h>
 935 #include <sys/types.h>
 936 /* sys/conf.h depends on param.h on FBSD at least */
 937 #include <sys/param.h>
 938 /* Required for MAXSIG */
 939 #include <signal.h>
 940 #include <sys/socket.h>
 941 #ifdef __APPLE__
 942 # define __APPLE_USE_RFC_3542
 943 #endif
 944 #include <netinet/in.h>
 945 #include <sys/time.h>
 946 #include <time.h>
 947 #include <net/if.h>
 948 ])dnl
 949
 950 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 951 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 952 dnl an additional round for it.
 953
 954 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
 955
 956 m4_define([FRR_INCLUDES],
 957 FRR_INCLUDES
 958 [#if HAVE_NET_IF_VAR_H
 959 # include <net/if_var.h>
 960 #endif
 961 ])dnl
 962
 963 AC_CHECK_HEADERS([netinet/in_var.h \
 964         net/if_dl.h net/netopt.h \
 965         inet/nd.h netinet/ip_icmp.h \
 966         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 967         [], [], [FRR_INCLUDES])
 968
 969 AC_CHECK_HEADERS([ucontext.h], [], [],
 970 [#ifndef __USE_GNU
 971 #define __USE_GNU
 972 #endif /* __USE_GNU */
 973 FRR_INCLUDES
 974 ])
 975
 976 m4_define([UCONTEXT_INCLUDES],
 977 [#include <ucontext.h>])dnl
 978
 979 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 980   [], [], [UCONTEXT_INCLUDES])
 981 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 982   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 983    [], [], [UCONTEXT_INCLUDES])],
 984   [], [UCONTEXT_INCLUDES])
 985 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 986   [], [], [UCONTEXT_INCLUDES])
 987
 988 m4_define([FRR_INCLUDES],
 989 FRR_INCLUDES
 990 [
 991 #include <sys/un.h>
 992 #include <netinet/in_systm.h>
 993 #if HAVE_NETINET_IN_VAR_H
 994 # include <netinet/in_var.h>
 995 #endif
 996 #if HAVE_NET_IF_DL_H
 997 # include <net/if_dl.h>
 998 #endif
 999 #if HAVE_NET_NETOPT_H
1000 # include <net/netopt.h>
1001 #endif
1002 #include <net/route.h>
1003 #if HAVE_INET_ND_H
1004 # include <inet/nd.h>
1005 #endif
1006 #include <arpa/inet.h>
1007 /* Required for IDRP */
1008 #if HAVE_NETINET_IP_ICMP_H
1009 # include <netinet/ip_icmp.h>
1010 #endif
1011 ])dnl
1012
1013 dnl V6 headers are checked below, after we check for v6
1014
1015 AC_MSG_CHECKING([which operating system interface to use])
1016 case "$host_os" in
1017   sunos* | solaris2*)
1018     AC_MSG_RESULT([Solaris])
1019
1020     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1021     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1022     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1023
1024     AC_CHECK_LIB([socket], [main])
1025     AC_CHECK_LIB([nsl], [main])
1026     AC_CHECK_LIB([umem], [main])
1027     SOLARIS="solaris"
1028     ;;
1029   linux*)
1030     AC_MSG_RESULT([Linux])
1031
1032     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1033     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1034     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1035
1036     dnl Linux has a compilation problem with mixing
1037     dnl netinet/in.h and linux/in6.h they are not
1038     dnl compatible.  There has been discussion on
1039     dnl how to fix it but no real progress on implementation
1040     dnl when they fix it, remove this
1041     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1042     ;;
1043   openbsd*)
1044     AC_MSG_RESULT([OpenBSD])
1045
1046     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1047     AC_DEFINE([KAME], [1], [KAME IPv6])
1048     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1049
1050     if test "x${enable_pimd}" != "xno"; then
1051       case "$host_os" in
1052       openbsd6.0)
1053         ;;
1054       openbsd[6-9]*)
1055         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1056         ;;
1057       esac
1058     fi
1059     ;;
1060   *)
1061     AC_MSG_RESULT([BSD])
1062
1063     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1064     AC_DEFINE([KAME], [1], [KAME IPv6])
1065     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1066     ;;
1067 esac
1068 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1069
1070 AC_SYS_LARGEFILE
1071
1072 dnl ------------------------
1073 dnl Integrated REALMS option
1074 dnl ------------------------
1075 if test "${enable_realms}" = "yes"; then
1076     case "$host_os" in
1077       linux*)
1078        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1079        ;;
1080       *)
1081        echo "Sorry, only Linux has REALMS support"
1082        exit 1
1083        ;;
1084     esac
1085 fi
1086 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1087
1088 dnl ---------------------
1089 dnl Integrated VTY option
1090 dnl ---------------------
1091 case "${enable_vtysh}" in
1092 "no")
1093   VTYSH="";;
1094 *)
1095   VTYSH="vtysh";
1096   AC_DEFINE([VTYSH], [1], [VTY shell])
1097
1098   prev_libs="$LIBS"
1099   AC_CHECK_LIB([readline], [main], [
1100     LIBREADLINE="-lreadline"
1101   ], [
1102     dnl readline failed - it might be incorrectly linked and missing its
1103     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1104     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1105       LIBREADLINE="$ac_cv_search_tputs"
1106     ], [
1107       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1108     ])
1109
1110     dnl re-try with the lib we found above
1111     unset ac_cv_lib_readline_main
1112     AC_CHECK_LIB([readline], [main], [
1113       LIBREADLINE="-lreadline $LIBREADLINE"
1114     ], [
1115       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1116     ], [$LIBREADLINE])
1117   ], [])
1118   LIBS="$prev_libs"
1119
1120   AC_CHECK_HEADER([readline/history.h])
1121   if test $ac_cv_header_readline_history_h = no;then
1122     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1123   fi
1124   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1125   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1126     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1127   fi
1128   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1129   if test "$frr_cv_append_history" = yes; then
1130     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1131   fi
1132   ;;
1133 esac
1134 AC_SUBST([LIBREADLINE])
1135 AM_CONDITIONAL([VTYSH], test "x$VTYSH" = "xvtysh")
1136
1137 dnl ----------
1138 dnl PAM module
1139 dnl
1140 dnl FRR detects the PAM library it is built against by checking for a
1141 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1142 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1143 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1144 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1145 dnl of OpenPAM.
1146 dnl ----------
1147 if test "$with_libpam" = "yes"; then
1148   AC_CHECK_HEADER([security/pam_misc.h],
1149     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1150      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1151      pam_conv_func="misc_conv"
1152     ],
1153     [], FRR_INCLUDES)
1154   AC_CHECK_HEADER([security/openpam.h],
1155     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1156      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1157      pam_conv_func="openpam_ttyconv"
1158     ],
1159     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1160   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1161     AC_MSG_WARN([*** pam support will not be built ***])
1162     with_libpam="no"
1163   fi
1164 fi
1165
1166 if test "$with_libpam" = "yes"; then
1167 dnl took this test from proftpds configure.in and suited to our needs
1168 dnl -------------------------------------------------------------------------
1169 dnl
1170 dnl This next check looks funky due to a linker problem with some versions
1171 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1172 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1173 dnl with RedHat 6.2 and Debian 2.2 or better.
1174 AC_CHECK_LIB([pam], [pam_start],
1175   [AC_CHECK_LIB([pam], [$pam_conv_func],
1176     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1177      LIBPAM="-lpam"],
1178     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1179      LIBPAM="-lpam -lpam_misc"]
1180     )
1181   ],
1182
1183   [AC_CHECK_LIB([pam], [pam_end],
1184     [AC_CHECK_LIB([pam], [$pam_conv_func],
1185       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1186        LIBPAM="-lpam -ldl"],
1187       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1188        LIBPAM="-lpam -ldl -lpam_misc"]
1189      )
1190   ],AC_MSG_WARN([*** pam support will not be built ***]),
1191   [-ldl])
1192   ]
1193 )
1194 fi
1195 AC_SUBST([LIBPAM])
1196
1197 dnl -------------------------------
1198 dnl Endian-ness check
1199 dnl -------------------------------
1200 AC_WORDS_BIGENDIAN
1201
1202 dnl -------------------------------
1203 dnl check the size in byte of the C
1204 dnl -------------------------------
1205 dnl AC_CHECK_SIZEOF(char)
1206 dnl AC_CHECK_SIZEOF(int)
1207 dnl AC_CHECK_SIZEOF(short)
1208 dnl AC_CHECK_SIZEOF(long)
1209
1210 dnl ----------------------------
1211 dnl check existance of functions
1212 dnl ----------------------------
1213 AC_FUNC_FNMATCH
1214 AC_FUNC_FORK
1215 AC_FUNC_MKTIME
1216 AC_FUNC_STAT
1217
1218 dnl -------------------------------
1219 dnl bgpd needs pow() and hence libm
1220 dnl -------------------------------
1221 TMPLIBS="$LIBS"
1222 AC_CHECK_HEADER([math.h],
1223   [AC_CHECK_LIB([m], [pow],
1224     [LIBM="-lm"
1225      LIBS="$LIBS $LIBM"
1226      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1227     ])
1228 ])
1229 if test x"$LIBM" = x ; then
1230   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1231 fi
1232 LIBS="$TMPLIBS"
1233
1234 AC_SUBST([LIBM])
1235
1236 AC_CHECK_FUNCS([ppoll], [
1237   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1238 ])
1239 AC_CHECK_FUNCS([pollts], [
1240   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1241 ])
1242
1243 dnl ---------------
1244 dnl other functions
1245 dnl ---------------
1246 AC_CHECK_FUNCS([ \
1247         strlcat strlcpy \
1248         getgrouplist])
1249
1250 AC_CHECK_HEADER([asm-generic/unistd.h],
1251                 [AC_CHECK_DECL(__NR_setns,
1252                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1253                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1254                                ])
1255                  AC_CHECK_FUNCS([setns])]
1256                )
1257
1258 dnl --------------------------
1259 dnl Determine IS-IS I/O method
1260 dnl --------------------------
1261 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1262 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1263 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1264 AC_CHECK_HEADER([net/bpf.h])
1265 AC_CHECK_HEADER([sys/dlpi.h])
1266 AC_MSG_CHECKING([zebra IS-IS I/O method])
1267
1268 case "$host_os" in
1269   linux*)
1270     AC_MSG_RESULT([pfpacket])
1271     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1272     ;;
1273   solaris* | sunos*)
1274     AC_MSG_RESULT([DLPI])
1275     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1276     ;;
1277   *)
1278     if test $ac_cv_header_net_bpf_h = no; then
1279       if test $ac_cv_header_sys_dlpi_h = no; then
1280         AC_MSG_RESULT([none])
1281         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1282           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1283         fi
1284         AC_MSG_WARN([*** IS-IS support will not be built ***])
1285         enable_isisd="no"
1286         enable_fabricd="no"
1287       else
1288         AC_MSG_RESULT([DLPI])
1289       fi
1290       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1291     else
1292       AC_MSG_RESULT([BPF])
1293       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1294     fi
1295     ;;
1296 esac
1297 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1298
1299 dnl ---------------------------------------------------------------
1300 dnl figure out how to specify an interface in multicast sockets API
1301 dnl ---------------------------------------------------------------
1302 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1303
1304 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1305         #include <sys/socket.h>
1306         #include <netinet/in.h>
1307         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1308         #include <linux/types.h>
1309 ])
1310
1311 m4_define([FRR_INCLUDES],
1312 FRR_INCLUDES
1313 [#if HAVE_LINUX_MROUTE_H
1314 # include <linux/mroute.h>
1315 #endif
1316 ])dnl
1317
1318 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1319         #include <sys/socket.h>
1320         #include <sys/types.h>
1321         #include <netinet/in.h>
1322         #include <net/route.h>
1323 ])
1324
1325 m4_define([FRR_INCLUDES],
1326 FRR_INCLUDES
1327 [#if HAVE_NETINET_IP_MROUTE_H
1328 # include <netinet/ip_mroute.h>
1329 #endif
1330 ])dnl
1331
1332 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1333 AC_TRY_COMPILE([#include <sys/param.h>],
1334 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1335   return (0);
1336 #else
1337   #error No support for BSD struct ip_mreq hack detected
1338 #endif],[AC_MSG_RESULT([yes])
1339 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1340 AC_MSG_RESULT([no]))
1341
1342 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1343 AC_TRY_COMPILE([
1344 #include <sys/types.h>
1345 #include <netinet/in.h>
1346 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1347 ], [AC_MSG_RESULT([yes])
1348 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1349 AC_MSG_RESULT([no]))
1350
1351 dnl ---------------------------------------------------------------
1352 dnl figure out how to check link-state
1353 dnl ---------------------------------------------------------------
1354 AC_CHECK_HEADER([net/if_media.h],
1355   [m4_define([LINK_DETECT_INCLUDES],
1356     FRR_INCLUDES
1357     [#include <net/if_media.h>
1358   ])
1359   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1360     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1361     [], LINK_DETECT_INCLUDES)],
1362   [],
1363   FRR_INCLUDES)
1364
1365 dnl ---------------------------------------------------------------
1366 dnl Additional, newer way to check link-state using ifi_link_state.
1367 dnl Not available in all BSD's when ifmediareq available
1368 dnl ---------------------------------------------------------------
1369 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1370   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1371   [], FRR_INCLUDES)
1372
1373 dnl ------------------------
1374 dnl TCP_MD5SIG socket option
1375 dnl ------------------------
1376
1377 AC_CHECK_HEADER([netinet/tcp.h],
1378    [m4_define([MD5_INCLUDES],
1379       FRR_INCLUDES
1380       [#include <netinet/tcp.h>
1381     ])
1382     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1383    [],
1384    FRR_INCLUDES)
1385 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1386   AC_CHECK_HEADER([linux/tcp.h],
1387        [m4_define([MD5_INCLUDES],
1388           FRR_INCLUDES
1389           [#include <linux/tcp.h>
1390         ])
1391        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1392 fi
1393
1394 dnl ----------------------------------------------------------------------------
1395 dnl figure out if domainname is available in the utsname struct (GNU extension).
1396 dnl ----------------------------------------------------------------------------
1397 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1398
1399 dnl ------------------
1400 dnl IPv6 header checks
1401 dnl ------------------
1402 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1403         netinet6/in6_var.h netinet6/nd6.h], [], [],
1404         FRR_INCLUDES)
1405
1406 m4_define([FRR_INCLUDES],dnl
1407 FRR_INCLUDES
1408 [#if HAVE_NETINET6_IN6_H
1409 #include <netinet6/in6.h>
1410 #endif
1411 #if HAVE_NETINET_IN6_VAR_H
1412 #include <netinet/in6_var.h>
1413 #endif
1414 #include <netinet/icmp6.h>
1415 #if HAVE_NETINET6_IN6_VAR_H
1416 # include <netinet6/in6_var.h>
1417 #endif
1418 #if HAVE_NETINET6_ND6_H
1419 # include <netinet6/nd6.h>
1420 #endif
1421 ])dnl
1422
1423 dnl disable doc check
1424 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1425 if test "$SPHINXBUILD" = "/bin/false"; then
1426   if test "${enable_doc}" = "yes"; then
1427     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1428   fi
1429 fi
1430 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false"])
1431 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
1432
1433 dnl --------------------
1434 dnl Daemon disable check
1435 dnl --------------------
1436 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
1437
1438 if test "${enable_bgpd}" = "no";then
1439   BGPD=""
1440 else
1441   BGPD="bgpd"
1442 fi
1443 AM_CONDITIONAL([BGPD], [test "x$BGPD" = "xbgpd"])
1444
1445 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
1446 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
1447 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
1448
1449 AS_IF([test "${enable_ldpd}" != "no"], [
1450   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1451 ])
1452
1453 if test "$enable_bfdd" = "no"; then
1454   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1455   BFDD=""
1456 else
1457   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1458   BFDD="bfdd"
1459
1460   case $host_os in
1461     linux*)
1462       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1463       ;;
1464
1465     *)
1466       AC_DEFINE([BFD_BSD], [1], [bfdd])
1467       ;;
1468   esac
1469 fi
1470
1471 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
1472
1473 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1474   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1475 fi
1476
1477 NHRPD=""
1478 case "$host_os" in
1479   linux*)
1480     if test "${enable_nhrpd}" != "no"; then
1481       NHRPD="nhrpd"
1482     fi
1483     ;;
1484   *)
1485     if test "${enable_nhrpd}" = "yes"; then
1486       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1487     fi
1488     ;;
1489 esac
1490 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
1491
1492 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
1493
1494 if test "${enable_watchfrr}" = "no";then
1495   WATCHFRR=""
1496 else
1497   WATCHFRR="watchfrr"
1498 fi
1499 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
1500
1501 OSPFCLIENT=""
1502 if test "${enable_ospfapi}" != "no";then
1503     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1504
1505   if test "${enable_ospfclient}" != "no";then
1506       OSPFCLIENT="ospfclient"
1507   fi
1508 fi
1509
1510 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
1511 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
1512 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
1513 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
1514 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
1515 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
1516 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
1517 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
1518 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
1519 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
1520
1521 if test "${enable_bgp_announce}" = "no";then
1522   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1523 else
1524   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1525 fi
1526
1527 if test "${enable_bgp_vnc}" != "no";then
1528   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1529 fi
1530 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1531
1532 AC_SUBST([SOLARIS])
1533 AC_CHECK_LIB([crypt], [crypt], [],
1534                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1535 AC_CHECK_LIB([resolv], [res_init])
1536
1537 dnl ---------------------------
1538 dnl check system has PCRE regexp
1539 dnl ---------------------------
1540 if test "x$enable_pcreposix" = "xyes"; then
1541   AC_CHECK_LIB([pcreposix], [regexec], [], [
1542     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1543   ])
1544 fi
1545 AC_SUBST([HAVE_LIBPCREPOSIX])
1546
1547 dnl ------------------
1548 dnl check C-Ares library
1549 dnl ------------------
1550 if test "${NHRPD}" != ""; then
1551   PKG_CHECK_MODULES([CARES], [libcares], ,[
1552     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1553   ])
1554 fi
1555
1556
1557 dnl ------------------
1558 dnl check Net-SNMP library
1559 dnl ------------------
1560 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1561    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1562    if test x"$NETSNMP_CONFIG" = x"no"; then
1563       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1564    fi
1565    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1566    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1567    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1568    # among other things we avoid a GPL vs. OpenSSL license conflict here
1569    for removelib in crypto ssl sensors pci wrap; do
1570      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1571    done
1572    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1573    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1574 int main(void);
1575 ],
1576 [
1577 {
1578   return 0;
1579 }
1580 ])], [
1581      AC_MSG_ERROR([--enable-snmp given but not usable])])
1582    case "${enable_snmp}" in
1583      yes)
1584       SNMP_METHOD=agentx
1585       ;;
1586      agentx)
1587       SNMP_METHOD="${enable_snmp}"
1588       ;;
1589      *)
1590       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1591       ;;
1592    esac
1593    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1594    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1595 fi
1596 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1597 AC_SUBST([SNMP_LIBS])
1598 AC_SUBST([SNMP_CFLAGS])
1599
1600 dnl ---------------
1601 dnl libyang
1602 dnl ---------------
1603 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.7], , [
1604   AC_MSG_ERROR([libyang (>= 0.16.7) was not found on your system.])
1605 ])
1606 ac_cflags_save="$CFLAGS"
1607 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1608 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1609   AC_MSG_ERROR([m4_normalize([
1610     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1611     See http://docs.frrouting.org/projects/dev-guide/en/latest/building-libyang.html for details.])
1612   ])
1613 ], [[#include <libyang/libyang.h>]])
1614 CFLAGS="$ac_cflags_save"
1615
1616 ac_libs_save="$LIBS"
1617 LIBS="$LIBS $LIBYANG_LIBS"
1618 AC_CHECK_FUNC([ly_register_types], [
1619   libyang_ext_builtin=true
1620   AC_DEFINE([LIBYANG_EXT_BUILTIN], [1], [have ly_register_types()])
1621 ], [
1622   libyang_ext_builtin=false
1623   AC_MSG_WARN([===== old libyang (before 0.16.74) detected =====])
1624   AC_MSG_WARN([The available version of libyang does not seem to support])
1625   AC_MSG_WARN([built-in YANG extension modules.  This will cause "make check"])
1626   AC_MSG_WARN([to fail and may create installation and version mismatch issues.])
1627   AC_MSG_WARN([Support for the old mechanism will be removed at some point.])
1628   AC_MSG_WARN([Please update libyang to version 0.16.74 or newer.])
1629   AC_MSG_WARN([===== old libyang (before 0.16.74) detected =====])
1630 ])
1631 AM_CONDITIONAL([LIBYANG_EXT_BUILTIN], [$libyang_ext_builtin])
1632 LIBS="$ac_libs_save"
1633
1634 dnl ---------------
1635 dnl configuration rollbacks
1636 dnl ---------------
1637 SQLITE3=false
1638 if test "$enable_config_rollbacks" = "yes"; then
1639   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1640     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1641     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1642     SQLITE3=true
1643   ], [
1644     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1645   ])
1646 fi
1647 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
1648
1649 dnl ---------------
1650 dnl confd
1651 dnl ---------------
1652 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1653    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1654    if test "x$CONFD" = "x/bin/false"; then
1655       AC_MSG_ERROR([confd was not found on your system.])]
1656    fi
1657    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1658    AC_SUBST([CONFD_CFLAGS])
1659    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1660 fi
1661 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
1662
1663 dnl ---------------
1664 dnl sysrepo
1665 dnl ---------------
1666 if test "$enable_sysrepo" = "yes"; then
1667   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1668       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1669       SYSREPO=true],
1670       [SYSREPO=false
1671       AC_MSG_ERROR([sysrepo was not found on your system.])]
1672   )
1673 fi
1674 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
1675
1676 dnl ---------------
1677 dnl math
1678 dnl ---------------
1679 AC_SEARCH_LIBS([sqrt], [m])
1680
1681 dnl ---------------
1682 dnl dlopen & dlinfo
1683 dnl ---------------
1684 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1685   AC_MSG_ERROR([unable to find the dlopen()])
1686 ])
1687
1688 AC_CHECK_HEADERS([link.h])
1689
1690 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1691   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1692 #include <stdlib.h>
1693 #ifdef HAVE_LINK_H
1694 #include <link.h>
1695 #endif
1696 #include <dlfcn.h>
1697 ]], [[
1698   char origin[1];
1699   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1700 ]])], [
1701     frr_cv_rtld_di_origin=yes
1702   ], [
1703     frr_cv_rtld_di_origin=no
1704   ])
1705 ])
1706 if test "$frr_cv_rtld_di_origin" = yes; then
1707   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1708 fi
1709
1710 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1711   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1712 #include <stdlib.h>
1713 #ifdef HAVE_LINK_H
1714 #include <link.h>
1715 #endif
1716 #include <dlfcn.h>
1717 ]], [[
1718   struct link_map *lm = NULL;
1719   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1720 ]])], [
1721     frr_cv_rtld_di_linkmap=yes
1722   ], [
1723     frr_cv_rtld_di_linkmap=no
1724   ])
1725 ])
1726 if test "$frr_cv_rtld_di_linkmap" = yes; then
1727   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1728 fi
1729
1730 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
1731
1732 dnl ---------------------------
1733 dnl sockaddr and netinet checks
1734 dnl ---------------------------
1735 AC_CHECK_TYPES([
1736         struct sockaddr_dl,
1737         struct vifctl, struct mfcctl, struct sioc_sg_req,
1738         vifi_t, struct sioc_vif_req, struct igmpmsg,
1739         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1740         struct nd_opt_adv_interval, struct rt_addrinfo,
1741         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1742         struct nd_opt_rdnss, struct nd_opt_dnssl],
1743         [], [], FRR_INCLUDES)
1744
1745 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1746         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1747         struct sockaddr_dl.sdl_len,
1748         struct if6_aliasreq.ifra_lifetime,
1749         struct nd_opt_adv_interval.nd_opt_ai_type],
1750         [], [], FRR_INCLUDES)
1751
1752 dnl ---------------------------
1753 dnl IRDP/pktinfo/icmphdr checks
1754 dnl ---------------------------
1755
1756 AC_CHECK_TYPES([struct in_pktinfo], [
1757   AC_CHECK_TYPES([struct icmphdr], [
1758     IRDP=true
1759   ], [
1760     IRDP=false
1761   ], [FRR_INCLUDES])
1762 ], [
1763   IRDP=false
1764 ], [FRR_INCLUDES])
1765
1766 case "${enable_irdp}" in
1767 yes)
1768   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1769   ;;
1770 no)
1771   IRDP=false
1772   ;;
1773 esac
1774
1775 AM_CONDITIONAL([IRDP], [$IRDP])
1776
1777 dnl -----------------------
1778 dnl checking for IP_PKTINFO
1779 dnl -----------------------
1780 AC_MSG_CHECKING([for IP_PKTINFO])
1781 AC_TRY_COMPILE([#include <netdb.h>], [
1782   int opt = IP_PKTINFO;
1783 ], [
1784   AC_MSG_RESULT([yes])
1785   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1786 ], [
1787   AC_MSG_RESULT([no])
1788 ])
1789
1790 dnl ---------------------------
1791 dnl checking for IP_RECVDSTADDR
1792 dnl ---------------------------
1793 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1794 AC_TRY_COMPILE([#include <netinet/in.h>], [
1795   int opt = IP_RECVDSTADDR;
1796 ], [
1797   AC_MSG_RESULT([yes])
1798   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1799 ], [
1800   AC_MSG_RESULT([no])
1801 ])
1802
1803 dnl ----------------------
1804 dnl checking for IP_RECVIF
1805 dnl ----------------------
1806 AC_MSG_CHECKING([for IP_RECVIF])
1807 AC_TRY_COMPILE([#include <netinet/in.h>], [
1808   int opt = IP_RECVIF;
1809 ], [
1810   AC_MSG_RESULT([yes])
1811   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1812 ], [
1813   AC_MSG_RESULT([no])
1814 ])
1815
1816 dnl ----------------------
1817 dnl checking for SO_BINDANY
1818 dnl ----------------------
1819 AC_MSG_CHECKING([for SO_BINDANY])
1820 AC_TRY_COMPILE([#include <sys/socket.h>], [
1821   int opt = SO_BINDANY;
1822 ], [
1823   AC_MSG_RESULT([yes])
1824   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1825 ], [
1826   AC_MSG_RESULT([no])
1827 ])
1828
1829 dnl ----------------------
1830 dnl checking for IP_FREEBIND
1831 dnl ----------------------
1832 AC_MSG_CHECKING([for IP_FREEBIND])
1833 AC_TRY_COMPILE([#include <netinet/in.h>], [
1834   int opt = IP_FREEBIND;
1835 ], [
1836   AC_MSG_RESULT([yes])
1837   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1838 ], [
1839   AC_MSG_RESULT([no])
1840 ])
1841
1842 dnl --------------------------------------
1843 dnl checking for be32dec existence or not
1844 dnl --------------------------------------
1845 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1846                [#include <sys/endian.h>])
1847
1848 dnl --------------------------------------
1849 dnl checking for clock_time monotonic struct and call
1850 dnl --------------------------------------
1851 AC_CHECK_DECL([CLOCK_MONOTONIC],
1852         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1853          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1854 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1855
1856 dnl --------------------------------------
1857 dnl checking for flex and bison
1858 dnl --------------------------------------
1859
1860 AM_PROG_LEX
1861 AC_MSG_CHECKING([version of flex])
1862 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1863 frr_ac_flex_version="${frr_ac_flex_version##* }"
1864 AC_MSG_RESULT([$frr_ac_flex_version])
1865 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1866   LEX="$SHELL $missing_dir/missing flex"
1867   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1868     AC_MSG_WARN([using pregenerated flex output files])
1869   else
1870     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1871   fi
1872   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1873   AC_SUBST([LEXLIB], [''])
1874 ])
1875
1876 AC_PROG_YACC
1877 dnl thanks GNU bison for this b*llshit...
1878 AC_MSG_CHECKING([version of bison])
1879 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1880 frr_ac_bison_version="${frr_ac_bison_version##* }"
1881 frr_ac_bison_missing="false"
1882 case "x${frr_ac_bison_version}" in
1883   x2.7*)
1884     BISON_OPENBRACE='"'
1885     BISON_CLOSEBRACE='"'
1886     BISON_VERBOSE=''
1887     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1888     ;;
1889   x2.*|x1.*)
1890     AC_MSG_RESULT([$frr_ac_bison_version])
1891     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1892     frr_ac_bison_missing="true"
1893     ;;
1894   x)
1895     AC_MSG_RESULT([none])
1896     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1897     frr_ac_bison_missing="true"
1898     ;;
1899   *)
1900     BISON_OPENBRACE='{'
1901     BISON_CLOSEBRACE='}'
1902     BISON_VERBOSE='-Dparse.error=verbose'
1903     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1904     ;;
1905 esac
1906 AC_SUBST([BISON_OPENBRACE])
1907 AC_SUBST([BISON_CLOSEBRACE])
1908 AC_SUBST([BISON_VERBOSE])
1909
1910 if $frr_ac_bison_missing; then
1911   YACC="$SHELL $missing_dir/missing bison -y"
1912   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1913     AC_MSG_WARN([using pregenerated bison output files])
1914   else
1915     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1916   fi
1917 fi
1918
1919 dnl -------------------
1920 dnl capabilities checks
1921 dnl -------------------
1922 if test "${enable_capabilities}" != "no"; then
1923   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
1924   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1925     [AC_MSG_RESULT([yes])
1926      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
1927      frr_ac_keepcaps="yes"],
1928      AC_MSG_RESULT([no])
1929   )
1930   if test x"${frr_ac_keepcaps}" = x"yes"; then
1931     AC_CHECK_HEADERS([sys/capability.h])
1932   fi
1933   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1934     AC_CHECK_LIB([cap], [cap_init],
1935       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
1936        LIBCAP="-lcap"
1937        frr_ac_lcaps="yes"]
1938     )
1939   else
1940     AC_CHECK_HEADERS([priv.h],
1941      [AC_MSG_CHECKING([Solaris style privileges are available])
1942       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
1943           [AC_MSG_RESULT([yes])
1944            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
1945            frr_ac_scaps="yes"],
1946            AC_MSG_RESULT(no)
1947       )
1948      ]
1949    )
1950   fi
1951   if test x"${frr_ac_scaps}" = x"yes" \
1952        -o x"${frr_ac_lcaps}" = x"yes"; then
1953     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
1954   fi
1955 fi
1956 AC_SUBST([LIBCAP])
1957
1958 dnl ---------------------------
1959 dnl check for glibc 'backtrace'
1960 dnl ---------------------------
1961 if test x"${enable_backtrace}" != x"no" ; then
1962   backtrace_ok=no
1963   PKG_CHECK_MODULES([UNWIND], [libunwind], [
1964     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
1965     backtrace_ok=yes
1966   ], [
1967     case "$host_os" in
1968     sunos* | solaris2*)
1969       AC_CHECK_FUNCS([printstack], [
1970         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
1971         backtrace_ok=yes
1972       ])
1973       ;;
1974     esac
1975     if test "$backtrace_ok" = no; then
1976       AC_CHECK_HEADER([execinfo.h], [
1977         AC_SEARCH_LIBS([backtrace], [execinfo], [
1978           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
1979           backtrace_ok=yes
1980         ],, [-lm])
1981       ])
1982     fi
1983   ])
1984
1985   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1986     dnl user explicitly requested backtrace but we failed to find support
1987     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
1988   fi
1989 fi
1990
1991 dnl -----------------------------------------
1992 dnl check for malloc mallinfo struct and call
1993 dnl this must try and link using LIBS, in
1994 dnl order to check no alternative allocator
1995 dnl has been specified, which might not provide
1996 dnl mallinfo, e.g. such as Umem on Solaris.
1997 dnl -----------------------------------------
1998 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
1999
2000 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2001   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2002 #ifdef HAVE_MALLOC_H
2003 #include <malloc.h>
2004 #endif
2005 #ifdef HAVE_MALLOC_NP_H
2006 #include <malloc_np.h>
2007 #endif
2008 #ifdef HAVE_MALLOC_MALLOC_H
2009 #include <malloc/malloc.h>
2010 #endif
2011 ]], [[
2012 struct mallinfo ac_x; ac_x = mallinfo ();
2013 ]])], [
2014     frr_cv_mallinfo=yes
2015   ], [
2016     frr_cv_mallinfo=no
2017   ])
2018 ])
2019 if test "$frr_cv_mallinfo" = yes; then
2020   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2021 fi
2022
2023 AC_MSG_CHECKING([whether malloc_usable_size is available])
2024 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2025 #ifdef HAVE_MALLOC_H
2026 #include <malloc.h>
2027 #endif
2028 #ifdef HAVE_MALLOC_MALLOC_H
2029 #include <malloc/malloc.h>
2030 #endif
2031 ]], [[
2032 size_t ac_x; ac_x = malloc_usable_size(NULL);
2033 ]])], [
2034   AC_MSG_RESULT([yes])
2035   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2036 ], [
2037   AC_MSG_RESULT([no])
2038
2039   AC_MSG_CHECKING([whether malloc_size is available])
2040   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2041 #ifdef HAVE_MALLOC_H
2042 #include <malloc.h>
2043 #endif
2044 #ifdef HAVE_MALLOC_MALLOC_H
2045 #include <malloc/malloc.h>
2046 #endif
2047 ]], [[
2048 size_t ac_x; ac_x = malloc_size(NULL);
2049 ]])], [
2050     AC_MSG_RESULT([yes])
2051     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2052   ], [
2053     AC_MSG_RESULT([no])
2054   ])
2055 ])
2056
2057 dnl ------
2058 dnl ZeroMQ
2059 dnl ------
2060 if test "x$enable_zeromq" != "xno"; then
2061   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2062     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2063     ZEROMQ=true
2064   ], [
2065     if test "x$enable_zeromq" = "xyes"; then
2066       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2067     fi
2068   ])
2069 fi
2070 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2071
2072 dnl ----------
2073 dnl configure date
2074 dnl ----------
2075 dev_version=`echo $VERSION | grep dev`
2076 #don't expire deprecated code in non 'dev' branch
2077 if test "${dev_version}" = ""; then
2078    CONFDATE=0
2079 else
2080    CONFDATE=`date '+%Y%m%d'`
2081 fi
2082 AC_SUBST([CONFDATE])
2083
2084 dnl ------------------------------
2085 dnl set paths for state directory
2086 dnl ------------------------------
2087 AC_MSG_CHECKING([directory to use for state file])
2088 if test "${prefix}" = "NONE"; then
2089   frr_statedir_prefix="";
2090 else
2091   frr_statedir_prefix=${prefix}
2092 fi
2093 if test "${localstatedir}" = '${prefix}/var'; then
2094   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2095                         ${frr_statedir_prefix}/var/adm dnl
2096                         ${frr_statedir_prefix}/etc dnl
2097                         /var/run        dnl
2098                         /var/adm        dnl
2099                         /etc            dnl
2100                         /dev/null;
2101   do
2102     test -d $FRR_STATE_DIR && break
2103   done
2104   frr_statedir=$FRR_STATE_DIR
2105 else
2106   frr_statedir=${localstatedir}
2107 fi
2108 if test $frr_statedir = "/dev/null"; then
2109     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2110 fi
2111 AC_MSG_RESULT([${frr_statedir}])
2112 AC_SUBST([frr_statedir])
2113
2114 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir/ldpd.sock"], [ldpd control socket])
2115 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir/zserv.api"], [zebra api socket])
2116 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir/bfdd.sock"], [bfdd control socket])
2117 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir"], [daemon vty directory])
2118 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2119
2120 dnl autoconf does this, but it does it too late...
2121 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2122 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2123
2124 dnl get the full path, recursing through variables...
2125 vtysh_bin="$bindir/vtysh"
2126 for I in 1 2 3 4 5 6 7 8 9 10; do
2127         eval vtysh_bin="\"$vtysh_bin\""
2128 done
2129 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2130 AC_SUBST([vtysh_bin])
2131
2132 CFG_SYSCONF="$sysconfdir"
2133 CFG_SBIN="$sbindir"
2134 CFG_STATE="$frr_statedir"
2135 CFG_MODULE="$moduledir"
2136 CFG_YANGMODELS="$yangmodelsdir"
2137 CFG_LIBYANG_PLUGINS="$libyang_pluginsdir"
2138 for I in 1 2 3 4 5 6 7 8 9 10; do
2139         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2140         eval CFG_SBIN="\"$CFG_SBIN\""
2141         eval CFG_STATE="\"$CFG_STATE\""
2142         eval CFG_MODULE="\"$CFG_MODULE\""
2143         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2144         eval CFG_LIBYANG_PLUGINS="\"$CFG_LIBYANG_PLUGINS\""
2145 done
2146 AC_SUBST([CFG_SYSCONF])
2147 AC_SUBST([CFG_SBIN])
2148 AC_SUBST([CFG_STATE])
2149 AC_SUBST([CFG_MODULE])
2150 AC_SUBST([CFG_YANGMODELS])
2151 AC_SUBST([CFG_LIBYANG_PLUGINS])
2152 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2153 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2154 AC_DEFINE_UNQUOTED([LIBYANG_PLUGINS_PATH], ["$CFG_LIBYANG_PLUGINS"], [path to libyang plugins])
2155
2156 dnl ------------------------------------
2157 dnl Enable RPKI and add librtr to libs
2158 dnl ------------------------------------
2159 if test "${enable_rpki}" = "yes"; then
2160   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
2161       [RPKI=true],
2162       [RPKI=false
2163       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2164   )
2165 fi
2166 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2167
2168 dnl ------------------------------------------
2169 dnl Check whether rtrlib was build with ssh support
2170 dnl ------------------------------------------
2171 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2172 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2173                         [[struct tr_ssh_config config;]])],
2174         [AC_MSG_RESULT([yes])
2175         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2176         AC_MSG_RESULT([no])
2177 )
2178
2179 dnl ---------------------------
2180 dnl Check htonl works correctly
2181 dnl ---------------------------
2182 AC_MSG_CHECKING([for working htonl])
2183 AC_CACHE_VAL(ac_cv_htonl_works,
2184  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2185                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2186  ]
2187 )
2188 AC_MSG_RESULT([$ac_cv_htonl_works])
2189
2190 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2191
2192 AC_CONFIG_FILES([
2193           config.version
2194           redhat/frr.spec
2195           solaris/Makefile
2196           debianpkg/changelog
2197           alpine/APKBUILD
2198           snapcraft/snapcraft.yaml
2199           lib/version.h
2200           tests/lib/cli/test_cli.refout
2201           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2202           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2203           pkgsrc/eigrpd.sh])
2204
2205 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2206 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2207 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2208 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2209 AC_CONFIG_FILES([tools/frrcommon.sh])
2210
2211 AC_CONFIG_COMMANDS([lib/route_types.h], [
2212         dst="${ac_abs_top_builddir}/lib/route_types.h"
2213         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2214                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2215                 > "${dst}.tmp"
2216         test -f "${dst}" \
2217                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2218                 && rm "${dst}.tmp" \
2219                 || mv "${dst}.tmp" "${dst}"
2220 ], [
2221         PERL="$PERL"
2222 ])
2223
2224 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2225     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2226         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2227         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2228                 "${ac_abs_top_srcdir}" \
2229                 > "${dst}.tmp"
2230         test -f "${dst}" \
2231                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2232                 && rm "${dst}.tmp" \
2233                 || mv "${dst}.tmp" "${dst}"
2234     ], [
2235         PERL="$PERL"
2236     ])
2237 ])
2238
2239 ## Hack, but working solution to avoid rebuilding of frr.info.
2240 ## It's already in CVS until texinfo 4.7 is more common.
2241 AC_OUTPUT
2242
2243 echo "
2244 FRRouting configuration
2245 ------------------------------
2246 FRR version             : ${PACKAGE_VERSION}
2247 host operating system   : ${host_os}
2248 source code location    : ${srcdir}
2249 compiler                : ${CC}
2250 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2251 make                    : ${MAKE-make}
2252 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2253 state file directory    : ${frr_statedir}
2254 config file directory   : `eval echo \`echo ${sysconfdir}\``
2255 example directory       : `eval echo \`echo ${exampledir}\``
2256 module directory        : ${CFG_MODULE}
2257 user to run as          : ${enable_user}
2258 group to run as         : ${enable_group}
2259 group for vty sockets   : ${enable_vty_group}
2260 config file mask        : ${enable_configfile_mask}
2261 log file mask           : ${enable_logfile_mask}
2262 zebra protobuf enabled  : ${enable_protobuf:-no}
2263
2264 The above user and group must have read/write access to the state file
2265 directory and to the config files in the config file directory."
2266
2267 if test "${enable_doc}" != "no";then
2268   AS_IF([test "$SPHINXBUILD" = /bin/false],
2269      AC_MSG_WARN([sphinx-build is missing but required to build documentation]))
2270 fi