configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.1-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST([HOSTTOOLS])
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS([config.h])
  64
  65 AC_PATH_PROG([PERL], [perl])
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST([exampledir])
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST([pkgsrcrcdir])
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94
  95 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
  96         yangmodelsdir="$withval"
  97 ], [
  98         yangmodelsdir="\${datarootdir}/yang"
  99 ])
 100 AC_SUBST([yangmodelsdir])
 101
 102 AC_ARG_WITH([libyang_pluginsdir], [AS_HELP_STRING([--with-libyang-pluginsdir=DIR], [yangmodule plugins directory (${libdir}/frr/libyang_plugins)])], [
 103         libyang_pluginsdir="$withval"
 104 ], [
 105    libyang_pluginsdir="\${libdir}/frr/libyang_plugins"
 106 ])
 107 AC_SUBST([libyang_pluginsdir])
 108
 109 AC_ARG_ENABLE(tcmalloc,
 110         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 111 [case "${enableval}" in
 112   yes) tcmalloc_enabled=true
 113 LIBS="$LIBS -ltcmalloc_minimal"
 114  ;;
 115   no)  tcmalloc_enabled=false ;;
 116   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 117 esac],[tcmalloc_enabled=false])
 118
 119
 120 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 121 dnl flag determination logic.
 122 CFLAGS="${CFLAGS:-}"
 123
 124 dnl --------------------
 125 dnl Check CC and friends
 126 dnl --------------------
 127 dnl note orig_cflags is also used further down
 128 orig_cflags="$CFLAGS"
 129 orig_cxxflags="$CXXFLAGS"
 130 AC_LANG([C])
 131 AC_PROG_CC
 132 AC_PROG_CPP
 133 AC_PROG_CXX
 134 AM_PROG_CC_C_O
 135 dnl remove autoconf default "-g -O2"
 136 CFLAGS="$orig_cflags"
 137 CXXFLAGS="$orig_cxxflags"
 138 AC_PROG_CC_C99
 139 dnl NB: see C11 below
 140
 141 AC_PROG_EGREP
 142 PKG_PROG_PKG_CONFIG
 143
 144 dnl autoconf 2.59 appears not to support AC_PROG_SED
 145 dnl AC_PROG_SED
 146 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 147
 148 dnl try and enable CFLAGS that are useful for FRR
 149 dnl - specifically, options to control warnings
 150
 151 AC_USE_SYSTEM_EXTENSIONS
 152 AC_DEFUN([AC_C_FLAG], [{
 153     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 154     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 155         AC_LANG_PUSH([C])
 156         ac_c_flag_save="$CFLAGS"
 157         CFLAGS="$CFLAGS $1"
 158         AC_COMPILE_IFELSE(
 159                 [AC_LANG_PROGRAM([[]])],
 160                 [
 161                         cachename=yes
 162                 ], [
 163                         cachename=no
 164                 ])
 165         CFLAGS="$ac_c_flag_save"
 166         AC_LANG_POP([C])
 167     ])
 168     if test "${cachename}" = yes; then
 169         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 170     else
 171         :
 172         $2
 173     fi
 174     m4_popdef([cachename])
 175 }])
 176
 177 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 178         AC_LANG_PUSH([C])
 179         ac_cflags_save="$CFLAGS"
 180         ac_libs_save="$LIBS"
 181         CFLAGS="$CFLAGS $1"
 182         LIBS="$LIBS $2"
 183         AC_LINK_IFELSE(
 184                 [$3],
 185                 [
 186                         AC_MSG_RESULT([yes])
 187                         CFLAGS="$ac_cflags_save"
 188                         LIBS="$ac_libs_save"
 189                         $5
 190                 ], [
 191                         AC_MSG_RESULT([no])
 192                         CFLAGS="$ac_cflags_save"
 193                         LIBS="$ac_libs_save"
 194                         $4
 195                 ])
 196         AC_LANG_POP([C])
 197         }])
 198
 199 dnl ICC won't bail on unknown options without -diag-error 10006
 200 dnl need to do this first so we get useful results for the other options
 201 AC_C_FLAG([-diag-error 10006])
 202
 203 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 204 ac_cc="$CC"
 205 CC="${CC% -std=gnu99}"
 206 CC="${CC% -std=c99}"
 207
 208 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 209
 210 dnl if the user has specified any CFLAGS, override our settings
 211 if test "x${enable_gcov}" = "xyes"; then
 212    if test "z$orig_cflags" = "z"; then
 213       AC_C_FLAG([-coverage])
 214       AC_C_FLAG([-O0])
 215    fi
 216
 217    LDFLAGS="${LDFLAGS} -lgcov"
 218 elif test "x${enable_dev_build}" = "xyes"; then
 219    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 220    if test "z$orig_cflags" = "z"; then
 221       AC_C_FLAG([-g3])
 222       AC_C_FLAG([-O0])
 223    fi
 224    if test "x${enable_lua}" = "xyes"; then
 225       AC_CHECK_LIB([lua], [lua_newstate],
 226       [LIBS="$LIBS -llua"])
 227       AC_DEFINE([HAVE_LUA], [1], [Lua enabled for development])
 228    fi
 229 else
 230    if test "x${enable_lua}" = "xyes"; then
 231       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 232    fi
 233    if test "z$orig_cflags" = "z"; then
 234       AC_C_FLAG([-g])
 235       AC_C_FLAG([-Os], [
 236         AC_C_FLAG([-O2])
 237       ])
 238    fi
 239 fi
 240 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 241
 242 dnl always want these CFLAGS
 243 AC_C_FLAG([-fno-omit-frame-pointer])
 244 AC_C_FLAG([-funwind-tables])
 245 AC_C_FLAG([-Wall])
 246 AC_C_FLAG([-Wextra])
 247 AC_C_FLAG([-Wmissing-prototypes])
 248 AC_C_FLAG([-Wmissing-declarations])
 249 AC_C_FLAG([-Wpointer-arith])
 250 AC_C_FLAG([-Wbad-function-cast])
 251 AC_C_FLAG([-Wwrite-strings])
 252 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 253   AC_C_FLAG([-Wcast-qual])
 254   AC_C_FLAG([-Wstrict-prototypes])
 255   AC_C_FLAG([-Wmissing-noreturn])
 256   AC_C_FLAG([-Wmissing-format-attribute])
 257   AC_C_FLAG([-Wunreachable-code])
 258   AC_C_FLAG([-Wpacked])
 259   AC_C_FLAG([-Wpadded])
 260   AC_C_FLAG([-Wshadow])
 261 else
 262   AC_C_FLAG([-Wno-unused-result])
 263 fi
 264 AC_C_FLAG([-Wno-unused-parameter])
 265 AC_C_FLAG([-Wno-missing-field-initializers])
 266
 267 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 268 AC_SUBST([CXX_COMPAT_CFLAGS])
 269
 270 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 271 dnl for some reason the string consts get 'promoted' to char *,
 272 dnl triggering a const to non-const conversion warning.
 273 AC_C_FLAG([-diag-disable 3179])
 274
 275 if test x"${enable_werror}" = x"yes" ; then
 276   WERROR="-Werror"
 277 fi
 278 AC_SUBST([WERROR])
 279
 280 SAN_FLAGS=""
 281 if test "$enable_address_sanitizer" = "yes"; then
 282   AC_C_FLAG([-fsanitize=address], [
 283     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 284   ], [
 285     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 286   ])
 287 fi
 288 if test "$enable_thread_sanitizer" = "yes"; then
 289   AC_C_FLAG([-fsanitize=thread], [
 290     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 291   ], [
 292     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 293   ])
 294 fi
 295 if test "$enable_memory_sanitizer" = "yes"; then
 296   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 297     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 298   ], [
 299     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 300   ])
 301 fi
 302 AC_SUBST([SAN_FLAGS])
 303
 304 dnl ----------
 305 dnl Essentials
 306 dnl ----------
 307
 308 AX_PTHREAD([
 309   CC="$PTHREAD_CC"
 310   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 311   LIBS="$PTHREAD_LIBS $LIBS"
 312 ], [
 313   AC_MSG_FAILURE([This FRR version needs pthreads])
 314 ])
 315
 316 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 317                 [frr_cv_pthread_condattr_setclock=yes],
 318                 [frr_cv_pthread_condattr_setclock=no])
 319 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 320   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 321 fi
 322
 323 dnl --------------
 324 dnl Check programs
 325 dnl --------------
 326 AC_PROG_INSTALL
 327 AC_PROG_LN_S
 328 AC_PROG_MAKE_SET
 329 AC_CHECK_TOOL([AR], [ar])
 330
 331 dnl -------
 332 dnl libtool
 333 dnl -------
 334 AC_ARG_ENABLE([static-bin],
 335   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 336 LT_INIT
 337 _LT_CONFIG_LIBTOOL([
 338   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 339     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 340 ])
 341 if test "$enable_static_bin" = "yes"; then
 342   AC_LDFLAGS="-static"
 343   if test "$enable_static" != "yes"; then
 344     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 345   fi
 346 fi
 347 if test "$enable_shared" != "yes"; then
 348   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 349 fi
 350 AC_SUBST([AC_LDFLAGS])
 351 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 352
 353 dnl $AR and $RANLIB are set by LT_INIT above
 354 AC_MSG_CHECKING([whether $AR supports D option])
 355 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 356   AC_MSG_RESULT([yes])
 357   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 358   ARFLAGS="crD"
 359   AR_FLAGS="crD"
 360 else
 361   AC_MSG_RESULT([no])
 362   ARFLAGS="cru"
 363   AR_FLAGS="cru"
 364 fi
 365 AC_SUBST([ARFLAGS])
 366 AC_SUBST([AR_FLAGS])
 367
 368 AC_MSG_CHECKING([whether $RANLIB supports D option])
 369 if $RANLIB -D conftest.a >/dev/null 2>/dev/null; then
 370   AC_MSG_RESULT([yes])
 371   RANLIB="$RANLIB -D"
 372 else
 373   AC_MSG_RESULT([no])
 374 fi
 375 AC_SUBST([RANLIB])
 376
 377 test -f conftest.a && rm conftest.a
 378
 379 dnl ----------------------
 380 dnl Packages configuration
 381 dnl ----------------------
 382 if test -f config.version; then
 383   . ./config.version
 384 elif test -f "${srcdir}/config.version"; then
 385   . "${srcdir}/config.version"
 386 fi
 387 AC_ARG_WITH([pkg-extra-version],
 388   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 389   if test "$withval" = "no"; then
 390     EXTRAVERSION=
 391   else
 392     EXTRAVERSION=$withval
 393   fi
 394 ], [])
 395 AC_ARG_WITH([pkg-git-version],
 396         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 397         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 398 AC_ARG_WITH([vtysh_pager],
 399         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 400         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 401 AC_ARG_ENABLE([vtysh],
 402   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 403 AC_ARG_ENABLE([doc],
 404   AS_HELP_STRING([--disable-doc], [do not build docs]))
 405 AC_ARG_ENABLE([doc-html],
 406   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 407 AC_ARG_ENABLE([zebra],
 408   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 409 AC_ARG_ENABLE([bgpd],
 410   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 411 AC_ARG_ENABLE([ripd],
 412   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 413 AC_ARG_ENABLE([ripngd],
 414   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 415 AC_ARG_ENABLE([ospfd],
 416   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 417 AC_ARG_ENABLE([ospf6d],
 418   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 419 AC_ARG_ENABLE([ldpd],
 420   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 421 AC_ARG_ENABLE([nhrpd],
 422   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 423 AC_ARG_ENABLE([eigrpd],
 424   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 425 AC_ARG_ENABLE([babeld],
 426   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 427 AC_ARG_ENABLE([watchfrr],
 428   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 429 AC_ARG_ENABLE([isisd],
 430   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 431 AC_ARG_ENABLE([pimd],
 432   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 433 AC_ARG_ENABLE([pbrd],
 434   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 435 AC_ARG_ENABLE([sharpd],
 436   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 437 AC_ARG_ENABLE([staticd],
 438   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 439 AC_ARG_ENABLE([fabricd],
 440   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 441 AC_ARG_ENABLE([bgp-announce],
 442   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 443 AC_ARG_ENABLE([bgp-vnc],
 444   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 445 AC_ARG_ENABLE([snmp],
 446   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 447 AC_ARG_ENABLE([config_rollbacks],
 448   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 449 AC_ARG_ENABLE([confd],
 450   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 451 AC_ARG_ENABLE([sysrepo],
 452   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 453 AC_ARG_ENABLE([grpc],
 454   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 455 AC_ARG_ENABLE([zeromq],
 456   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 457 AC_ARG_WITH([libpam],
 458   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 459 AC_ARG_ENABLE([ospfapi],
 460   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 461 AC_ARG_ENABLE([ospfclient],
 462   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 463                           (this is the default if --disable-ospfapi is set)]))
 464 AC_ARG_ENABLE([multipath],
 465   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 466 AC_ARG_ENABLE([user],
 467   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 468 AC_ARG_ENABLE([group],
 469   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 470 AC_ARG_ENABLE([vty_group],
 471   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 472 AC_ARG_ENABLE([configfile_mask],
 473   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 474 AC_ARG_ENABLE([logfile_mask],
 475   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 476 AC_ARG_ENABLE([shell_access],
 477   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 478 AC_ARG_ENABLE([realms],
 479   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 480 AC_ARG_ENABLE([rtadv],
 481   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 482 AC_ARG_ENABLE([irdp],
 483   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 484 AC_ARG_ENABLE([capabilities],
 485   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 486 AC_ARG_ENABLE([rusage],
 487   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 488 AC_ARG_ENABLE([gcc_ultra_verbose],
 489   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 490 AC_ARG_ENABLE([backtrace],
 491   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 492 AC_ARG_ENABLE([time-check],
 493   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 494 AC_ARG_ENABLE([pcreposix],
 495   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 496 AC_ARG_ENABLE([fpm],
 497   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 498 AC_ARG_ENABLE([systemd],
 499   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 500 AC_ARG_ENABLE([werror],
 501   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 502 AC_ARG_ENABLE([cumulus],
 503   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 504 AC_ARG_ENABLE([datacenter],
 505   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 506 AC_ARG_ENABLE([fuzzing],
 507   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 508 AC_ARG_ENABLE([netlink_fuzzing],
 509   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 510 AC_ARG_ENABLE([rr-semantics],
 511   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 512 AC_ARG_ENABLE([protobuf],
 513   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 514 AC_ARG_ENABLE([oldvpn_commands],
 515   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 516 AC_ARG_ENABLE([rpki],
 517   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 518 AC_ARG_ENABLE([clippy-only],
 519   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 520 AC_ARG_ENABLE([numeric_version],
 521   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 522 AC_ARG_ENABLE([gcov],
 523   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 524 AC_ARG_ENABLE([bfdd],
 525   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 526 AC_ARG_ENABLE([address-sanitizer],
 527   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 528 AC_ARG_ENABLE([thread-sanitizer],
 529   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 530 AC_ARG_ENABLE([memory-sanitizer],
 531   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 532
 533 AS_IF([test "${enable_clippy_only}" != "yes"], [
 534 AC_CHECK_HEADERS([json-c/json.h])
 535 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 536 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 537   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 538   if test "$ac_cv_lib_json_json_object_get" = no; then
 539       AC_MSG_ERROR([libjson is needed to compile])
 540   fi
 541 fi
 542 ])
 543
 544 AC_ARG_ENABLE([dev_build],
 545     AS_HELP_STRING([--enable-dev-build], [build for development]))
 546
 547 AC_ARG_ENABLE([lua],
 548     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 549
 550 if test x"${enable_time_check}" != x"no" ; then
 551   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 552     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 553   else
 554     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 555   fi
 556 fi
 557
 558 case "${enable_systemd}" in
 559   "no") ;;
 560   "yes")
 561   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 562   if test $ac_cv_lib_systemd_sd_notify = no; then
 563     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 564   else
 565     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 566   fi
 567   ;;
 568   "*") ;;
 569 esac
 570
 571 if test "${enable_rr_semantics}" != "no" ; then
 572   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 573 fi
 574
 575 if test "${enable_datacenter}" = "yes" ; then
 576   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 577   DFLT_NAME="datacenter"
 578 else
 579   DFLT_NAME="traditional"
 580 fi
 581
 582 if test "${enable_fuzzing}" = "yes" ; then
 583   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 584 fi
 585
 586 if test "${enable_netlink_fuzzing}" = "yes" ; then
 587   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 588 fi
 589
 590 if test "${enable_cumulus}" = "yes" ; then
 591   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 592 fi
 593
 594 AC_SUBST([DFLT_NAME])
 595 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 596
 597 if test "${enable_shell_access}" = "yes"; then
 598    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 599 fi
 600
 601 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 602
 603 #
 604 # Python for clippy
 605 #
 606
 607 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 608   AC_MSG_CHECKING([whether we found a working Python version])
 609   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 610 #include <Python.h>
 611 #if PY_VERSION_HEX < 0x02070000
 612 #error python too old
 613 #endif
 614 int main(void);
 615 ],
 616 [
 617 {
 618   Py_Initialize();
 619   return 0;
 620 }
 621 ])], [
 622     # some python installs are missing the zlib dependency...
 623     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 624     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 625 #include <Python.h>
 626 #if PY_VERSION_HEX < 0x02070000
 627 #error python too old
 628 #endif
 629 int main(void);
 630 ],
 631 [
 632 {
 633   Py_Initialize();
 634   return 0;
 635 }
 636 ])], [
 637       m4_if([$1], [], [
 638         PYTHONCONFIG=""
 639         unset PYTHON_LIBS
 640         unset PYTHON_CFLAGS
 641       ], [$1])
 642     ])
 643   ])
 644 ])
 645
 646 AS_IF([test "$host" = "$build"], [
 647   PYTHONCONFIG=""
 648
 649   # ordering:
 650   # 1.  try python3, but respect the user's preference on which minor ver
 651   # 2.  try python, which might be py3 or py2 again on the user's preference
 652   # 3.  try python2 (can really only be 2.7 but eh)
 653   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 654   #
 655   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 656   # (AX_PYTHON does not do what we need)
 657
 658   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 659         python3-config \
 660         python-config \
 661         python2-config \
 662         python3.6-config \
 663         python3.5-config \
 664         python3.4-config \
 665         python3.3-config \
 666         python3.2-config \
 667         python2.7-config ])
 668   if test -n "$PYTHONCONFIG"; then
 669     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 670     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 671
 672     FRR_PYTHON_CHECK_WORKING([])
 673   fi
 674
 675   if test -z "$PYTHONCONFIG"; then
 676     PKG_CHECK_MODULES([PYTHON], [python-3.6], [], [
 677       PKG_CHECK_MODULES([PYTHON], [python-3.5], [], [
 678         PKG_CHECK_MODULES([PYTHON], [python-3.4], [], [
 679           PKG_CHECK_MODULES([PYTHON], [python-3.3], [], [
 680             PKG_CHECK_MODULES([PYTHON], [python-3.2], [], [
 681               PKG_CHECK_MODULES([PYTHON], [python-2.7], [], [
 682                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 683                 ])])])])])])
 684
 685
 686     FRR_PYTHON_CHECK_WORKING([
 687       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 688     ])
 689   fi
 690 ])
 691 AC_SUBST([PYTHON_CFLAGS])
 692 AC_SUBST([PYTHON_LIBS])
 693
 694 #
 695 # Logic for protobuf support.
 696 #
 697 if test "$enable_protobuf" = "yes"; then
 698   # Check for protoc & protoc-c
 699
 700   # protoc is not required, it's only for a "be nice" helper target
 701   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 702
 703   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 704   if test "$PROTOC_C" = "/bin/false"; then
 705     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 706   fi
 707
 708   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 709     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 710   ])
 711   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 712     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 713   ])
 714
 715   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
 716 fi
 717 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 718
 719 #
 720 # Logic for old vpn commands support.
 721 #
 722 if test "$enable_oldvpn_commands" = "yes"; then
 723    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 724 fi
 725
 726 #
 727 # End of logic for protobuf support.
 728 #
 729
 730 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 731 if test "${enable_rtadv}" != "no"; then
 732   AC_MSG_RESULT([yes])
 733   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 734 else
 735   AC_MSG_RESULT([no])
 736 fi
 737
 738 if test x"${enable_user}" = x"no"; then
 739   enable_user=""
 740 else
 741   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 742     enable_user="frr"
 743   fi
 744   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 745 fi
 746
 747 if test x"${enable_group}" = x"no"; then
 748   enable_group=""
 749 else
 750   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 751     enable_group="frr"
 752   fi
 753   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 754 fi
 755
 756 if test x"${enable_vty_group}" = x"yes" ; then
 757   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 758 elif test x"${enable_vty_group}" != x""; then
 759   if test x"${enable_vty_group}" != x"no"; then
 760     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 761   fi
 762 fi
 763 AC_SUBST([enable_user])
 764 AC_SUBST([enable_group])
 765 AC_SUBST([enable_vty_group])
 766
 767 enable_configfile_mask=${enable_configfile_mask:-0600}
 768 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 769
 770 enable_logfile_mask=${enable_logfile_mask:-0600}
 771 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 772
 773 MPATH_NUM=16
 774
 775 case "${enable_multipath}" in
 776   0)
 777     MPATH_NUM=64
 778     ;;
 779   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 780     MPATH_NUM="${enable_multipath}"
 781     ;;
 782   "")
 783     ;;
 784   *)
 785     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 786     ;;
 787 esac
 788
 789 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 790
 791 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 792
 793 dnl --------------------
 794 dnl Enable code coverage
 795 dnl --------------------
 796 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 797
 798 dnl ------------------------------------
 799 dnl Alpine only accepts numeric versions
 800 dnl ------------------------------------
 801 if test "x${enable_numeric_version}" != "x" ; then
 802   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 803   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 804 fi
 805
 806 dnl -----------------------------------
 807 dnl Add extra version string to package
 808 dnl name, string and version fields.
 809 dnl -----------------------------------
 810 if test "x${EXTRAVERSION}" != "x" ; then
 811   VERSION="${VERSION}${EXTRAVERSION}"
 812   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 813   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 814   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 815 fi
 816 AC_SUBST([EXTRAVERSION])
 817
 818 if test "x$with_pkg_git_version" = "xyes"; then
 819         if test -d "${srcdir}/.git"; then
 820                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 821         else    with_pkg_git_version="no"
 822                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 823         fi
 824 fi
 825 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 826
 827 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 828 if test "x${OBJCOPY}" != "x:"; then
 829   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 830     frr_cv_interp=""
 831     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 832       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 833         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 834       fi
 835       test -f conftest.interp && rm conftest.interp
 836     ])
 837   ])
 838 fi
 839 if test -n "$frr_cv_interp"; then
 840   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 841 fi
 842
 843 dnl ------------------------------------
 844 dnl Check C keywords and standard  types
 845 dnl ------------------------------------
 846 AC_C_CONST
 847 AC_C_INLINE
 848 AC_C_VOLATILE
 849 AC_HEADER_STDC
 850 dnl AC_TYPE_PID_T
 851 AC_TYPE_UID_T
 852 AC_TYPE_MODE_T
 853 AC_TYPE_SIZE_T
 854 AC_STRUCT_TM
 855
 856 dnl -------------------------
 857 dnl Check other header files.
 858 dnl -------------------------
 859 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 860         linux/version.h asm/types.h \
 861         sys/cdefs.h])
 862
 863 ac_stdatomic_ok=false
 864 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 865 AC_CHECK_HEADER([stdatomic.h],[
 866
 867   AC_MSG_CHECKING([whether _Atomic qualifier works])
 868   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 869 #include <stdatomic.h>
 870 int main(int argc, char **argv) {
 871   _Atomic int i = 0;
 872   return i;
 873 }
 874 ]])], [
 875     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 876     AC_MSG_RESULT([yes])
 877     ac_stdatomic_ok=true
 878   ], [
 879     AC_MSG_RESULT([no])
 880   ])
 881 ])
 882
 883 AS_IF([$ac_stdatomic_ok], [true], [
 884   AC_MSG_CHECKING([for __atomic_* builtins])
 885   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 886 int main(int argc, char **argv) {
 887   volatile int i = 1;
 888   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 889   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 890 }
 891 ]])], [
 892     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 893     AC_MSG_RESULT([yes])
 894   ], [
 895     AC_MSG_RESULT([no])
 896
 897     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 898     AC_MSG_CHECKING([for __sync_* builtins])
 899     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 900 int main(int argc, char **argv) {
 901   volatile int i = 1;
 902   __sync_fetch_and_sub (&i, 1);
 903   return __sync_val_compare_and_swap (&i, 0, 1);
 904 }
 905 ]])], [
 906       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 907       AC_MSG_RESULT([yes])
 908
 909       AC_MSG_CHECKING([for __sync_swap builtin])
 910       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 911 int main(int argc, char **argv) {
 912   volatile int i = 1;
 913   return __sync_swap (&i, 2);
 914 }
 915 ]])], [
 916         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 917         AC_MSG_RESULT([yes])
 918       ], [
 919         AC_MSG_RESULT([no])
 920       ])
 921
 922     ], [
 923       AC_MSG_RESULT([no])
 924       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 925     ])
 926   ])
 927 ])
 928
 929 AC_CHECK_HEADERS([pthread_np.h],,, [
 930 #include <pthread.h>
 931 ])
 932 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 933
 934 dnl Utility macro to avoid retyping includes all the time
 935 m4_define([FRR_INCLUDES],
 936 [#ifdef SUNOS_5
 937 #define _POSIX_C_SOURCE 200809L
 938 #define __EXTENSIONS__
 939 #endif
 940 #include <stdio.h>
 941 #include <stdlib.h>
 942 #include <stddef.h>
 943 #include <sys/types.h>
 944 /* sys/conf.h depends on param.h on FBSD at least */
 945 #include <sys/param.h>
 946 /* Required for MAXSIG */
 947 #include <signal.h>
 948 #include <sys/socket.h>
 949 #ifdef __APPLE__
 950 # define __APPLE_USE_RFC_3542
 951 #endif
 952 #include <netinet/in.h>
 953 #include <sys/time.h>
 954 #include <time.h>
 955 #include <net/if.h>
 956 ])dnl
 957
 958 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 959 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 960 dnl an additional round for it.
 961
 962 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
 963
 964 m4_define([FRR_INCLUDES],
 965 FRR_INCLUDES
 966 [#if HAVE_NET_IF_VAR_H
 967 # include <net/if_var.h>
 968 #endif
 969 ])dnl
 970
 971 AC_CHECK_HEADERS([netinet/in_var.h \
 972         net/if_dl.h net/netopt.h \
 973         inet/nd.h netinet/ip_icmp.h \
 974         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 975         [], [], [FRR_INCLUDES])
 976
 977 AC_CHECK_HEADERS([ucontext.h], [], [],
 978 [#ifndef __USE_GNU
 979 #define __USE_GNU
 980 #endif /* __USE_GNU */
 981 FRR_INCLUDES
 982 ])
 983
 984 m4_define([UCONTEXT_INCLUDES],
 985 [#include <ucontext.h>])dnl
 986
 987 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 988   [], [], [UCONTEXT_INCLUDES])
 989 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 990   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 991    [], [], [UCONTEXT_INCLUDES])],
 992   [], [UCONTEXT_INCLUDES])
 993 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 994   [], [], [UCONTEXT_INCLUDES])
 995
 996 m4_define([FRR_INCLUDES],
 997 FRR_INCLUDES
 998 [
 999 #include <sys/un.h>
1000 #include <netinet/in_systm.h>
1001 #if HAVE_NETINET_IN_VAR_H
1002 # include <netinet/in_var.h>
1003 #endif
1004 #if HAVE_NET_IF_DL_H
1005 # include <net/if_dl.h>
1006 #endif
1007 #if HAVE_NET_NETOPT_H
1008 # include <net/netopt.h>
1009 #endif
1010 #include <net/route.h>
1011 #if HAVE_INET_ND_H
1012 # include <inet/nd.h>
1013 #endif
1014 #include <arpa/inet.h>
1015 /* Required for IDRP */
1016 #if HAVE_NETINET_IP_ICMP_H
1017 # include <netinet/ip_icmp.h>
1018 #endif
1019 ])dnl
1020
1021 dnl V6 headers are checked below, after we check for v6
1022
1023 AC_MSG_CHECKING([which operating system interface to use])
1024 case "$host_os" in
1025   sunos* | solaris2*)
1026     AC_MSG_RESULT([Solaris])
1027
1028     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1029     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1030     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1031
1032     AC_CHECK_LIB([socket], [main])
1033     AC_CHECK_LIB([nsl], [main])
1034     AC_CHECK_LIB([umem], [main])
1035     SOLARIS="solaris"
1036     ;;
1037   linux*)
1038     AC_MSG_RESULT([Linux])
1039
1040     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1041     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1042     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1043
1044     dnl Linux has a compilation problem with mixing
1045     dnl netinet/in.h and linux/in6.h they are not
1046     dnl compatible.  There has been discussion on
1047     dnl how to fix it but no real progress on implementation
1048     dnl when they fix it, remove this
1049     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1050     ;;
1051   openbsd*)
1052     AC_MSG_RESULT([OpenBSD])
1053
1054     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1055     AC_DEFINE([KAME], [1], [KAME IPv6])
1056     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1057
1058     if test "x${enable_pimd}" != "xno"; then
1059       case "$host_os" in
1060       openbsd6.0)
1061         ;;
1062       openbsd[6-9]*)
1063         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1064         ;;
1065       esac
1066     fi
1067     ;;
1068   *)
1069     AC_MSG_RESULT([BSD])
1070
1071     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1072     AC_DEFINE([KAME], [1], [KAME IPv6])
1073     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1074     ;;
1075 esac
1076 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1077
1078 AC_SYS_LARGEFILE
1079
1080 dnl ------------------------
1081 dnl Integrated REALMS option
1082 dnl ------------------------
1083 if test "${enable_realms}" = "yes"; then
1084     case "$host_os" in
1085       linux*)
1086        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1087        ;;
1088       *)
1089        echo "Sorry, only Linux has REALMS support"
1090        exit 1
1091        ;;
1092     esac
1093 fi
1094 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1095
1096 dnl ---------------------
1097 dnl Integrated VTY option
1098 dnl ---------------------
1099 case "${enable_vtysh}" in
1100 "no")
1101   VTYSH="";;
1102 *)
1103   VTYSH="vtysh";
1104   AC_DEFINE([VTYSH], [1], [VTY shell])
1105
1106   prev_libs="$LIBS"
1107   AC_CHECK_LIB([readline], [main], [
1108     LIBREADLINE="-lreadline"
1109   ], [
1110     dnl readline failed - it might be incorrectly linked and missing its
1111     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1112     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1113       LIBREADLINE="$ac_cv_search_tputs"
1114     ], [
1115       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1116     ])
1117
1118     dnl re-try with the lib we found above
1119     unset ac_cv_lib_readline_main
1120     AC_CHECK_LIB([readline], [main], [
1121       LIBREADLINE="-lreadline $LIBREADLINE"
1122     ], [
1123       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1124     ], [$LIBREADLINE])
1125   ], [])
1126   LIBS="$prev_libs"
1127
1128   AC_CHECK_HEADER([readline/history.h])
1129   if test $ac_cv_header_readline_history_h = no;then
1130     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1131   fi
1132   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1133   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1134     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1135   fi
1136   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1137   if test "$frr_cv_append_history" = yes; then
1138     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1139   fi
1140   ;;
1141 esac
1142 AC_SUBST([LIBREADLINE])
1143 AM_CONDITIONAL([VTYSH], test "x$VTYSH" = "xvtysh")
1144
1145 dnl ----------
1146 dnl PAM module
1147 dnl
1148 dnl FRR detects the PAM library it is built against by checking for a
1149 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1150 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1151 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1152 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1153 dnl of OpenPAM.
1154 dnl ----------
1155 if test "$with_libpam" = "yes"; then
1156   AC_CHECK_HEADER([security/pam_misc.h],
1157     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1158      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1159      pam_conv_func="misc_conv"
1160     ],
1161     [], FRR_INCLUDES)
1162   AC_CHECK_HEADER([security/openpam.h],
1163     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1164      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1165      pam_conv_func="openpam_ttyconv"
1166     ],
1167     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1168   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1169     AC_MSG_WARN([*** pam support will not be built ***])
1170     with_libpam="no"
1171   fi
1172 fi
1173
1174 if test "$with_libpam" = "yes"; then
1175 dnl took this test from proftpds configure.in and suited to our needs
1176 dnl -------------------------------------------------------------------------
1177 dnl
1178 dnl This next check looks funky due to a linker problem with some versions
1179 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1180 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1181 dnl with RedHat 6.2 and Debian 2.2 or better.
1182 AC_CHECK_LIB([pam], [pam_start],
1183   [AC_CHECK_LIB([pam], [$pam_conv_func],
1184     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1185      LIBPAM="-lpam"],
1186     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1187      LIBPAM="-lpam -lpam_misc"]
1188     )
1189   ],
1190
1191   [AC_CHECK_LIB([pam], [pam_end],
1192     [AC_CHECK_LIB([pam], [$pam_conv_func],
1193       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1194        LIBPAM="-lpam -ldl"],
1195       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1196        LIBPAM="-lpam -ldl -lpam_misc"]
1197      )
1198   ],AC_MSG_WARN([*** pam support will not be built ***]),
1199   [-ldl])
1200   ]
1201 )
1202 fi
1203 AC_SUBST([LIBPAM])
1204
1205 dnl -------------------------------
1206 dnl Endian-ness check
1207 dnl -------------------------------
1208 AC_WORDS_BIGENDIAN
1209
1210 dnl -------------------------------
1211 dnl check the size in byte of the C
1212 dnl -------------------------------
1213 dnl AC_CHECK_SIZEOF(char)
1214 dnl AC_CHECK_SIZEOF(int)
1215 dnl AC_CHECK_SIZEOF(short)
1216 dnl AC_CHECK_SIZEOF(long)
1217
1218 dnl ----------------------------
1219 dnl check existance of functions
1220 dnl ----------------------------
1221 AC_FUNC_FNMATCH
1222 AC_FUNC_FORK
1223 AC_FUNC_MKTIME
1224 AC_FUNC_STAT
1225
1226 dnl -------------------------------
1227 dnl bgpd needs pow() and hence libm
1228 dnl -------------------------------
1229 TMPLIBS="$LIBS"
1230 AC_CHECK_HEADER([math.h],
1231   [AC_CHECK_LIB([m], [pow],
1232     [LIBM="-lm"
1233      LIBS="$LIBS $LIBM"
1234      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1235     ])
1236 ])
1237 if test x"$LIBM" = x ; then
1238   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1239 fi
1240 LIBS="$TMPLIBS"
1241
1242 AC_SUBST([LIBM])
1243
1244 AC_CHECK_FUNCS([ppoll], [
1245   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1246 ])
1247 AC_CHECK_FUNCS([pollts], [
1248   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1249 ])
1250
1251 dnl ---------------
1252 dnl other functions
1253 dnl ---------------
1254 AC_CHECK_FUNCS([ \
1255         strlcat strlcpy \
1256         getgrouplist])
1257
1258 AC_CHECK_HEADER([asm-generic/unistd.h],
1259                 [AC_CHECK_DECL(__NR_setns,
1260                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1261                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1262                                ])
1263                  AC_CHECK_FUNCS([setns])]
1264                )
1265
1266 dnl --------------------------
1267 dnl Determine IS-IS I/O method
1268 dnl --------------------------
1269 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1270 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1271 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1272 AC_CHECK_HEADER([net/bpf.h])
1273 AC_CHECK_HEADER([sys/dlpi.h])
1274 AC_MSG_CHECKING([zebra IS-IS I/O method])
1275
1276 case "$host_os" in
1277   linux*)
1278     AC_MSG_RESULT([pfpacket])
1279     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1280     ;;
1281   solaris* | sunos*)
1282     AC_MSG_RESULT([DLPI])
1283     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1284     ;;
1285   *)
1286     if test $ac_cv_header_net_bpf_h = no; then
1287       if test $ac_cv_header_sys_dlpi_h = no; then
1288         AC_MSG_RESULT([none])
1289         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1290           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1291         fi
1292         AC_MSG_WARN([*** IS-IS support will not be built ***])
1293         enable_isisd="no"
1294         enable_fabricd="no"
1295       else
1296         AC_MSG_RESULT([DLPI])
1297       fi
1298       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1299     else
1300       AC_MSG_RESULT([BPF])
1301       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1302     fi
1303     ;;
1304 esac
1305 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1306
1307 dnl ---------------------------------------------------------------
1308 dnl figure out how to specify an interface in multicast sockets API
1309 dnl ---------------------------------------------------------------
1310 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1311
1312 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1313         #include <sys/socket.h>
1314         #include <netinet/in.h>
1315         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1316         #include <linux/types.h>
1317 ])
1318
1319 m4_define([FRR_INCLUDES],
1320 FRR_INCLUDES
1321 [#if HAVE_LINUX_MROUTE_H
1322 # include <linux/mroute.h>
1323 #endif
1324 ])dnl
1325
1326 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1327         #include <sys/socket.h>
1328         #include <sys/types.h>
1329         #include <netinet/in.h>
1330         #include <net/route.h>
1331 ])
1332
1333 m4_define([FRR_INCLUDES],
1334 FRR_INCLUDES
1335 [#if HAVE_NETINET_IP_MROUTE_H
1336 # include <netinet/ip_mroute.h>
1337 #endif
1338 ])dnl
1339
1340 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1341 AC_TRY_COMPILE([#include <sys/param.h>],
1342 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1343   return (0);
1344 #else
1345   #error No support for BSD struct ip_mreq hack detected
1346 #endif],[AC_MSG_RESULT([yes])
1347 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1348 AC_MSG_RESULT([no]))
1349
1350 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1351 AC_TRY_COMPILE([
1352 #include <sys/types.h>
1353 #include <netinet/in.h>
1354 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1355 ], [AC_MSG_RESULT([yes])
1356 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1357 AC_MSG_RESULT([no]))
1358
1359 dnl ---------------------------------------------------------------
1360 dnl figure out how to check link-state
1361 dnl ---------------------------------------------------------------
1362 AC_CHECK_HEADER([net/if_media.h],
1363   [m4_define([LINK_DETECT_INCLUDES],
1364     FRR_INCLUDES
1365     [#include <net/if_media.h>
1366   ])
1367   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1368     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1369     [], LINK_DETECT_INCLUDES)],
1370   [],
1371   FRR_INCLUDES)
1372
1373 dnl ---------------------------------------------------------------
1374 dnl Additional, newer way to check link-state using ifi_link_state.
1375 dnl Not available in all BSD's when ifmediareq available
1376 dnl ---------------------------------------------------------------
1377 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1378   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1379   [], FRR_INCLUDES)
1380
1381 dnl ------------------------
1382 dnl TCP_MD5SIG socket option
1383 dnl ------------------------
1384
1385 AC_CHECK_HEADER([netinet/tcp.h],
1386    [m4_define([MD5_INCLUDES],
1387       FRR_INCLUDES
1388       [#include <netinet/tcp.h>
1389     ])
1390     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1391    [],
1392    FRR_INCLUDES)
1393 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1394   AC_CHECK_HEADER([linux/tcp.h],
1395        [m4_define([MD5_INCLUDES],
1396           FRR_INCLUDES
1397           [#include <linux/tcp.h>
1398         ])
1399        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1400 fi
1401
1402 dnl ----------------------------------------------------------------------------
1403 dnl figure out if domainname is available in the utsname struct (GNU extension).
1404 dnl ----------------------------------------------------------------------------
1405 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1406
1407 dnl ------------------
1408 dnl IPv6 header checks
1409 dnl ------------------
1410 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1411         netinet6/in6_var.h netinet6/nd6.h], [], [],
1412         FRR_INCLUDES)
1413
1414 m4_define([FRR_INCLUDES],dnl
1415 FRR_INCLUDES
1416 [#if HAVE_NETINET6_IN6_H
1417 #include <netinet6/in6.h>
1418 #endif
1419 #if HAVE_NETINET_IN6_VAR_H
1420 #include <netinet/in6_var.h>
1421 #endif
1422 #include <netinet/icmp6.h>
1423 #if HAVE_NETINET6_IN6_VAR_H
1424 # include <netinet6/in6_var.h>
1425 #endif
1426 #if HAVE_NETINET6_ND6_H
1427 # include <netinet6/nd6.h>
1428 #endif
1429 ])dnl
1430
1431 dnl disable doc check
1432 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1433 if test "$SPHINXBUILD" = "/bin/false"; then
1434   if test "${enable_doc}" = "yes"; then
1435     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1436   fi
1437 fi
1438 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false"])
1439 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
1440
1441 dnl --------------------
1442 dnl Daemon disable check
1443 dnl --------------------
1444 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
1445
1446 if test "${enable_bgpd}" = "no";then
1447   BGPD=""
1448 else
1449   BGPD="bgpd"
1450 fi
1451 AM_CONDITIONAL([BGPD], [test "x$BGPD" = "xbgpd"])
1452
1453 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
1454 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
1455 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
1456
1457 AS_IF([test "${enable_ldpd}" != "no"], [
1458   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1459 ])
1460
1461 if test "$enable_bfdd" = "no"; then
1462   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1463   BFDD=""
1464 else
1465   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1466   BFDD="bfdd"
1467
1468   case $host_os in
1469     linux*)
1470       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1471       ;;
1472
1473     *)
1474       AC_DEFINE([BFD_BSD], [1], [bfdd])
1475       ;;
1476   esac
1477 fi
1478
1479 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
1480
1481 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1482   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1483 fi
1484
1485 NHRPD=""
1486 case "$host_os" in
1487   linux*)
1488     if test "${enable_nhrpd}" != "no"; then
1489       NHRPD="nhrpd"
1490     fi
1491     ;;
1492   *)
1493     if test "${enable_nhrpd}" = "yes"; then
1494       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1495     fi
1496     ;;
1497 esac
1498 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
1499
1500 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
1501
1502 if test "${enable_watchfrr}" = "no";then
1503   WATCHFRR=""
1504 else
1505   WATCHFRR="watchfrr"
1506 fi
1507 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
1508
1509 OSPFCLIENT=""
1510 if test "${enable_ospfapi}" != "no";then
1511     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1512
1513   if test "${enable_ospfclient}" != "no";then
1514       OSPFCLIENT="ospfclient"
1515   fi
1516 fi
1517
1518 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
1519 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
1520 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
1521 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
1522 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
1523 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
1524 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
1525 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
1526 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
1527 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
1528
1529 if test "${enable_bgp_announce}" = "no";then
1530   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1531 else
1532   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1533 fi
1534
1535 if test "${enable_bgp_vnc}" != "no";then
1536   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1537 fi
1538 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1539
1540 AC_SUBST([SOLARIS])
1541 AC_CHECK_LIB([crypt], [crypt], [],
1542                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1543 AC_CHECK_LIB([resolv], [res_init])
1544
1545 dnl ---------------------------
1546 dnl check system has PCRE regexp
1547 dnl ---------------------------
1548 if test "x$enable_pcreposix" = "xyes"; then
1549   AC_CHECK_LIB([pcreposix], [regexec], [], [
1550     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1551   ])
1552 fi
1553 AC_SUBST([HAVE_LIBPCREPOSIX])
1554
1555 dnl ------------------
1556 dnl check C-Ares library
1557 dnl ------------------
1558 if test "${NHRPD}" != ""; then
1559   PKG_CHECK_MODULES([CARES], [libcares], ,[
1560     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1561   ])
1562 fi
1563
1564
1565 dnl ------------------
1566 dnl check Net-SNMP library
1567 dnl ------------------
1568 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1569    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1570    if test x"$NETSNMP_CONFIG" = x"no"; then
1571       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1572    fi
1573    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1574    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1575    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1576    # among other things we avoid a GPL vs. OpenSSL license conflict here
1577    for removelib in crypto ssl sensors pci wrap; do
1578      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1579    done
1580    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1581    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1582 int main(void);
1583 ],
1584 [
1585 {
1586   return 0;
1587 }
1588 ])], [
1589      AC_MSG_ERROR([--enable-snmp given but not usable])])
1590    case "${enable_snmp}" in
1591      yes)
1592       SNMP_METHOD=agentx
1593       ;;
1594      agentx)
1595       SNMP_METHOD="${enable_snmp}"
1596       ;;
1597      *)
1598       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1599       ;;
1600    esac
1601    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1602    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1603 fi
1604 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1605 AC_SUBST([SNMP_LIBS])
1606 AC_SUBST([SNMP_CFLAGS])
1607
1608 dnl ---------------
1609 dnl libyang
1610 dnl ---------------
1611 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.7], , [
1612   AC_MSG_ERROR([libyang (>= 0.16.7) was not found on your system.])
1613 ])
1614 ac_cflags_save="$CFLAGS"
1615 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1616 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1617   AC_MSG_ERROR([m4_normalize([
1618     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1619     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1620   ])
1621 ], [[#include <libyang/libyang.h>]])
1622 CFLAGS="$ac_cflags_save"
1623
1624 ac_libs_save="$LIBS"
1625 LIBS="$LIBS $LIBYANG_LIBS"
1626 AC_CHECK_FUNC([ly_register_types], [
1627   libyang_ext_builtin=true
1628   AC_DEFINE([LIBYANG_EXT_BUILTIN], [1], [have ly_register_types()])
1629 ], [
1630   libyang_ext_builtin=false
1631   AC_MSG_WARN([===== old libyang (before 0.16.74) detected =====])
1632   AC_MSG_WARN([The available version of libyang does not seem to support])
1633   AC_MSG_WARN([built-in YANG extension modules.  This will cause "make check"])
1634   AC_MSG_WARN([to fail and may create installation and version mismatch issues.])
1635   AC_MSG_WARN([Support for the old mechanism will be removed at some point.])
1636   AC_MSG_WARN([Please update libyang to version 0.16.74 or newer.])
1637   AC_MSG_WARN([===== old libyang (before 0.16.74) detected =====])
1638 ])
1639 AM_CONDITIONAL([LIBYANG_EXT_BUILTIN], [$libyang_ext_builtin])
1640 LIBS="$ac_libs_save"
1641
1642 dnl ---------------
1643 dnl configuration rollbacks
1644 dnl ---------------
1645 SQLITE3=false
1646 if test "$enable_config_rollbacks" = "yes"; then
1647   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1648     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1649     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1650     SQLITE3=true
1651   ], [
1652     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1653   ])
1654 fi
1655 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
1656
1657 dnl ---------------
1658 dnl confd
1659 dnl ---------------
1660 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1661    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1662    if test "x$CONFD" = "x/bin/false"; then
1663       AC_MSG_ERROR([confd was not found on your system.])]
1664    fi
1665    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1666    AC_SUBST([CONFD_CFLAGS])
1667    CONFD_LIBS="-lconfd"
1668    AC_SUBST([CONFD_LIBS])
1669    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1670 fi
1671 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
1672
1673 dnl ---------------
1674 dnl sysrepo
1675 dnl ---------------
1676 if test "$enable_sysrepo" = "yes"; then
1677   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1678       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1679       SYSREPO=true],
1680       [SYSREPO=false
1681       AC_MSG_ERROR([sysrepo was not found on your system.])]
1682   )
1683 fi
1684 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
1685
1686 dnl ---------------
1687 dnl gRPC
1688 dnl ---------------
1689 if test "$enable_grpc" = "yes"; then
1690   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1691     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1692     if test "$PROTOC" = "/bin/false"; then
1693       AC_MSG_FAILURE([grpc requested but protoc not found.])
1694     fi
1695
1696     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1697     GRPC=true
1698   ], [
1699     GRPC=false
1700     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1701   ])
1702 fi
1703 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
1704
1705 dnl ---------------
1706 dnl math
1707 dnl ---------------
1708 AC_SEARCH_LIBS([sqrt], [m])
1709
1710 dnl ---------------
1711 dnl dlopen & dlinfo
1712 dnl ---------------
1713 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1714   AC_MSG_ERROR([unable to find the dlopen()])
1715 ])
1716
1717 AC_CHECK_HEADERS([link.h])
1718
1719 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1720   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1721 #include <stdlib.h>
1722 #ifdef HAVE_LINK_H
1723 #include <link.h>
1724 #endif
1725 #include <dlfcn.h>
1726 ]], [[
1727   char origin[1];
1728   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1729 ]])], [
1730     frr_cv_rtld_di_origin=yes
1731   ], [
1732     frr_cv_rtld_di_origin=no
1733   ])
1734 ])
1735 if test "$frr_cv_rtld_di_origin" = yes; then
1736   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1737 fi
1738
1739 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1740   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1741 #include <stdlib.h>
1742 #ifdef HAVE_LINK_H
1743 #include <link.h>
1744 #endif
1745 #include <dlfcn.h>
1746 ]], [[
1747   struct link_map *lm = NULL;
1748   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1749 ]])], [
1750     frr_cv_rtld_di_linkmap=yes
1751   ], [
1752     frr_cv_rtld_di_linkmap=no
1753   ])
1754 ])
1755 if test "$frr_cv_rtld_di_linkmap" = yes; then
1756   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1757 fi
1758
1759 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
1760
1761 dnl ---------------------------
1762 dnl sockaddr and netinet checks
1763 dnl ---------------------------
1764 AC_CHECK_TYPES([
1765         struct sockaddr_dl,
1766         struct vifctl, struct mfcctl, struct sioc_sg_req,
1767         vifi_t, struct sioc_vif_req, struct igmpmsg,
1768         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1769         struct nd_opt_adv_interval, struct rt_addrinfo,
1770         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1771         struct nd_opt_rdnss, struct nd_opt_dnssl],
1772         [], [], FRR_INCLUDES)
1773
1774 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1775         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1776         struct sockaddr_dl.sdl_len,
1777         struct if6_aliasreq.ifra_lifetime,
1778         struct nd_opt_adv_interval.nd_opt_ai_type],
1779         [], [], FRR_INCLUDES)
1780
1781 dnl ---------------------------
1782 dnl IRDP/pktinfo/icmphdr checks
1783 dnl ---------------------------
1784
1785 AC_CHECK_TYPES([struct in_pktinfo], [
1786   AC_CHECK_TYPES([struct icmphdr], [
1787     IRDP=true
1788   ], [
1789     IRDP=false
1790   ], [FRR_INCLUDES])
1791 ], [
1792   IRDP=false
1793 ], [FRR_INCLUDES])
1794
1795 case "${enable_irdp}" in
1796 yes)
1797   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1798   ;;
1799 no)
1800   IRDP=false
1801   ;;
1802 esac
1803
1804 AM_CONDITIONAL([IRDP], [$IRDP])
1805
1806 dnl -----------------------
1807 dnl checking for IP_PKTINFO
1808 dnl -----------------------
1809 AC_MSG_CHECKING([for IP_PKTINFO])
1810 AC_TRY_COMPILE([#include <netdb.h>], [
1811   int opt = IP_PKTINFO;
1812 ], [
1813   AC_MSG_RESULT([yes])
1814   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1815 ], [
1816   AC_MSG_RESULT([no])
1817 ])
1818
1819 dnl ---------------------------
1820 dnl checking for IP_RECVDSTADDR
1821 dnl ---------------------------
1822 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1823 AC_TRY_COMPILE([#include <netinet/in.h>], [
1824   int opt = IP_RECVDSTADDR;
1825 ], [
1826   AC_MSG_RESULT([yes])
1827   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1828 ], [
1829   AC_MSG_RESULT([no])
1830 ])
1831
1832 dnl ----------------------
1833 dnl checking for IP_RECVIF
1834 dnl ----------------------
1835 AC_MSG_CHECKING([for IP_RECVIF])
1836 AC_TRY_COMPILE([#include <netinet/in.h>], [
1837   int opt = IP_RECVIF;
1838 ], [
1839   AC_MSG_RESULT([yes])
1840   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1841 ], [
1842   AC_MSG_RESULT([no])
1843 ])
1844
1845 dnl ----------------------
1846 dnl checking for SO_BINDANY
1847 dnl ----------------------
1848 AC_MSG_CHECKING([for SO_BINDANY])
1849 AC_TRY_COMPILE([#include <sys/socket.h>], [
1850   int opt = SO_BINDANY;
1851 ], [
1852   AC_MSG_RESULT([yes])
1853   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1854 ], [
1855   AC_MSG_RESULT([no])
1856 ])
1857
1858 dnl ----------------------
1859 dnl checking for IP_FREEBIND
1860 dnl ----------------------
1861 AC_MSG_CHECKING([for IP_FREEBIND])
1862 AC_TRY_COMPILE([#include <netinet/in.h>], [
1863   int opt = IP_FREEBIND;
1864 ], [
1865   AC_MSG_RESULT([yes])
1866   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1867 ], [
1868   AC_MSG_RESULT([no])
1869 ])
1870
1871 dnl --------------------------------------
1872 dnl checking for be32dec existence or not
1873 dnl --------------------------------------
1874 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1875                [#include <sys/endian.h>])
1876
1877 dnl --------------------------------------
1878 dnl checking for clock_time monotonic struct and call
1879 dnl --------------------------------------
1880 AC_CHECK_DECL([CLOCK_MONOTONIC],
1881         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1882          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1883 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1884
1885 dnl --------------------------------------
1886 dnl checking for flex and bison
1887 dnl --------------------------------------
1888
1889 AM_PROG_LEX
1890 AC_MSG_CHECKING([version of flex])
1891 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1892 frr_ac_flex_version="${frr_ac_flex_version##* }"
1893 AC_MSG_RESULT([$frr_ac_flex_version])
1894 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1895   LEX="$SHELL $missing_dir/missing flex"
1896   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1897     AC_MSG_WARN([using pregenerated flex output files])
1898   else
1899     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1900   fi
1901   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1902   AC_SUBST([LEXLIB], [''])
1903 ])
1904
1905 AC_PROG_YACC
1906 dnl thanks GNU bison for this b*llshit...
1907 AC_MSG_CHECKING([version of bison])
1908 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1909 frr_ac_bison_version="${frr_ac_bison_version##* }"
1910 frr_ac_bison_missing="false"
1911 case "x${frr_ac_bison_version}" in
1912   x2.7*)
1913     BISON_OPENBRACE='"'
1914     BISON_CLOSEBRACE='"'
1915     BISON_VERBOSE=''
1916     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1917     ;;
1918   x2.*|x1.*)
1919     AC_MSG_RESULT([$frr_ac_bison_version])
1920     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1921     frr_ac_bison_missing="true"
1922     ;;
1923   x)
1924     AC_MSG_RESULT([none])
1925     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1926     frr_ac_bison_missing="true"
1927     ;;
1928   *)
1929     BISON_OPENBRACE='{'
1930     BISON_CLOSEBRACE='}'
1931     BISON_VERBOSE='-Dparse.error=verbose'
1932     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1933     ;;
1934 esac
1935 AC_SUBST([BISON_OPENBRACE])
1936 AC_SUBST([BISON_CLOSEBRACE])
1937 AC_SUBST([BISON_VERBOSE])
1938
1939 if $frr_ac_bison_missing; then
1940   YACC="$SHELL $missing_dir/missing bison -y"
1941   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1942     AC_MSG_WARN([using pregenerated bison output files])
1943   else
1944     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1945   fi
1946 fi
1947
1948 dnl -------------------
1949 dnl capabilities checks
1950 dnl -------------------
1951 if test "${enable_capabilities}" != "no"; then
1952   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
1953   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1954     [AC_MSG_RESULT([yes])
1955      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
1956      frr_ac_keepcaps="yes"],
1957      AC_MSG_RESULT([no])
1958   )
1959   if test x"${frr_ac_keepcaps}" = x"yes"; then
1960     AC_CHECK_HEADERS([sys/capability.h])
1961   fi
1962   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1963     AC_CHECK_LIB([cap], [cap_init],
1964       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
1965        LIBCAP="-lcap"
1966        frr_ac_lcaps="yes"]
1967     )
1968   else
1969     AC_CHECK_HEADERS([priv.h],
1970      [AC_MSG_CHECKING([Solaris style privileges are available])
1971       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
1972           [AC_MSG_RESULT([yes])
1973            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
1974            frr_ac_scaps="yes"],
1975            AC_MSG_RESULT(no)
1976       )
1977      ]
1978    )
1979   fi
1980   if test x"${frr_ac_scaps}" = x"yes" \
1981        -o x"${frr_ac_lcaps}" = x"yes"; then
1982     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
1983   fi
1984 fi
1985 AC_SUBST([LIBCAP])
1986
1987 dnl ---------------------------
1988 dnl check for glibc 'backtrace'
1989 dnl ---------------------------
1990 if test x"${enable_backtrace}" != x"no" ; then
1991   backtrace_ok=no
1992   PKG_CHECK_MODULES([UNWIND], [libunwind], [
1993     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
1994     backtrace_ok=yes
1995   ], [
1996     case "$host_os" in
1997     sunos* | solaris2*)
1998       AC_CHECK_FUNCS([printstack], [
1999         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2000         backtrace_ok=yes
2001       ])
2002       ;;
2003     esac
2004     if test "$backtrace_ok" = no; then
2005       AC_CHECK_HEADER([execinfo.h], [
2006         AC_SEARCH_LIBS([backtrace], [execinfo], [
2007           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2008           backtrace_ok=yes
2009         ],, [-lm])
2010       ])
2011     fi
2012   ])
2013
2014   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2015     dnl user explicitly requested backtrace but we failed to find support
2016     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2017   fi
2018 fi
2019
2020 dnl -----------------------------------------
2021 dnl check for malloc mallinfo struct and call
2022 dnl this must try and link using LIBS, in
2023 dnl order to check no alternative allocator
2024 dnl has been specified, which might not provide
2025 dnl mallinfo, e.g. such as Umem on Solaris.
2026 dnl -----------------------------------------
2027 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2028
2029 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2030   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2031 #ifdef HAVE_MALLOC_H
2032 #include <malloc.h>
2033 #endif
2034 #ifdef HAVE_MALLOC_NP_H
2035 #include <malloc_np.h>
2036 #endif
2037 #ifdef HAVE_MALLOC_MALLOC_H
2038 #include <malloc/malloc.h>
2039 #endif
2040 ]], [[
2041 struct mallinfo ac_x; ac_x = mallinfo ();
2042 ]])], [
2043     frr_cv_mallinfo=yes
2044   ], [
2045     frr_cv_mallinfo=no
2046   ])
2047 ])
2048 if test "$frr_cv_mallinfo" = yes; then
2049   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2050 fi
2051
2052 AC_MSG_CHECKING([whether malloc_usable_size is available])
2053 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2054 #ifdef HAVE_MALLOC_H
2055 #include <malloc.h>
2056 #endif
2057 #ifdef HAVE_MALLOC_MALLOC_H
2058 #include <malloc/malloc.h>
2059 #endif
2060 ]], [[
2061 size_t ac_x; ac_x = malloc_usable_size(NULL);
2062 ]])], [
2063   AC_MSG_RESULT([yes])
2064   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2065 ], [
2066   AC_MSG_RESULT([no])
2067
2068   AC_MSG_CHECKING([whether malloc_size is available])
2069   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2070 #ifdef HAVE_MALLOC_H
2071 #include <malloc.h>
2072 #endif
2073 #ifdef HAVE_MALLOC_MALLOC_H
2074 #include <malloc/malloc.h>
2075 #endif
2076 ]], [[
2077 size_t ac_x; ac_x = malloc_size(NULL);
2078 ]])], [
2079     AC_MSG_RESULT([yes])
2080     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2081   ], [
2082     AC_MSG_RESULT([no])
2083   ])
2084 ])
2085
2086 dnl ------
2087 dnl ZeroMQ
2088 dnl ------
2089 if test "x$enable_zeromq" != "xno"; then
2090   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2091     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2092     ZEROMQ=true
2093   ], [
2094     if test "x$enable_zeromq" = "xyes"; then
2095       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2096     fi
2097   ])
2098 fi
2099 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2100
2101 dnl ----------
2102 dnl configure date
2103 dnl ----------
2104 dev_version=`echo $VERSION | grep dev`
2105 #don't expire deprecated code in non 'dev' branch
2106 if test "${dev_version}" = ""; then
2107    CONFDATE=0
2108 else
2109    CONFDATE=`date '+%Y%m%d'`
2110 fi
2111 AC_SUBST([CONFDATE])
2112
2113 dnl ------------------------------
2114 dnl set paths for state directory
2115 dnl ------------------------------
2116 AC_MSG_CHECKING([directory to use for state file])
2117 if test "${prefix}" = "NONE"; then
2118   frr_statedir_prefix="";
2119 else
2120   frr_statedir_prefix=${prefix}
2121 fi
2122 if test "${localstatedir}" = '${prefix}/var'; then
2123   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2124                         ${frr_statedir_prefix}/var/adm dnl
2125                         ${frr_statedir_prefix}/etc dnl
2126                         /var/run        dnl
2127                         /var/adm        dnl
2128                         /etc            dnl
2129                         /dev/null;
2130   do
2131     test -d $FRR_STATE_DIR && break
2132   done
2133   frr_statedir=$FRR_STATE_DIR
2134 else
2135   frr_statedir=${localstatedir}
2136 fi
2137 if test $frr_statedir = "/dev/null"; then
2138     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2139 fi
2140 AC_MSG_RESULT([${frr_statedir}])
2141 AC_SUBST([frr_statedir])
2142
2143 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir/ldpd.sock"], [ldpd control socket])
2144 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir/zserv.api"], [zebra api socket])
2145 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir/bfdd.sock"], [bfdd control socket])
2146 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir"], [daemon vty directory])
2147 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2148
2149 dnl autoconf does this, but it does it too late...
2150 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2151 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2152
2153 dnl get the full path, recursing through variables...
2154 vtysh_bin="$bindir/vtysh"
2155 for I in 1 2 3 4 5 6 7 8 9 10; do
2156         eval vtysh_bin="\"$vtysh_bin\""
2157 done
2158 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2159 AC_SUBST([vtysh_bin])
2160
2161 CFG_SYSCONF="$sysconfdir"
2162 CFG_SBIN="$sbindir"
2163 CFG_STATE="$frr_statedir"
2164 CFG_MODULE="$moduledir"
2165 CFG_YANGMODELS="$yangmodelsdir"
2166 CFG_LIBYANG_PLUGINS="$libyang_pluginsdir"
2167 for I in 1 2 3 4 5 6 7 8 9 10; do
2168         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2169         eval CFG_SBIN="\"$CFG_SBIN\""
2170         eval CFG_STATE="\"$CFG_STATE\""
2171         eval CFG_MODULE="\"$CFG_MODULE\""
2172         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2173         eval CFG_LIBYANG_PLUGINS="\"$CFG_LIBYANG_PLUGINS\""
2174 done
2175 AC_SUBST([CFG_SYSCONF])
2176 AC_SUBST([CFG_SBIN])
2177 AC_SUBST([CFG_STATE])
2178 AC_SUBST([CFG_MODULE])
2179 AC_SUBST([CFG_YANGMODELS])
2180 AC_SUBST([CFG_LIBYANG_PLUGINS])
2181 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2182 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2183 AC_DEFINE_UNQUOTED([LIBYANG_PLUGINS_PATH], ["$CFG_LIBYANG_PLUGINS"], [path to libyang plugins])
2184 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2185
2186 dnl ------------------------------------
2187 dnl Enable RPKI and add librtr to libs
2188 dnl ------------------------------------
2189 if test "${enable_rpki}" = "yes"; then
2190   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
2191       [RPKI=true],
2192       [RPKI=false
2193       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2194   )
2195 fi
2196 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2197
2198 dnl ------------------------------------------
2199 dnl Check whether rtrlib was build with ssh support
2200 dnl ------------------------------------------
2201 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2202 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2203                         [[struct tr_ssh_config config;]])],
2204         [AC_MSG_RESULT([yes])
2205         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2206         AC_MSG_RESULT([no])
2207 )
2208
2209 dnl ---------------------------
2210 dnl Check htonl works correctly
2211 dnl ---------------------------
2212 AC_MSG_CHECKING([for working htonl])
2213 AC_CACHE_VAL(ac_cv_htonl_works,
2214  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2215                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2216  ]
2217 )
2218 AC_MSG_RESULT([$ac_cv_htonl_works])
2219
2220 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2221
2222 AC_CONFIG_FILES([
2223           config.version
2224           changelog-auto
2225           redhat/frr.spec
2226           solaris/Makefile
2227           alpine/APKBUILD
2228           snapcraft/snapcraft.yaml
2229           lib/version.h
2230           tests/lib/cli/test_cli.refout
2231           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2232           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2233           pkgsrc/eigrpd.sh])
2234
2235 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2236 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2237 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2238 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2239 AC_CONFIG_FILES([tools/frrcommon.sh])
2240
2241 AC_CONFIG_COMMANDS([lib/route_types.h], [
2242         dst="${ac_abs_top_builddir}/lib/route_types.h"
2243         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2244                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2245                 > "${dst}.tmp"
2246         test -f "${dst}" \
2247                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2248                 && rm "${dst}.tmp" \
2249                 || mv "${dst}.tmp" "${dst}"
2250 ], [
2251         PERL="$PERL"
2252 ])
2253
2254 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2255     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2256         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2257         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2258                 "${ac_abs_top_srcdir}" \
2259                 > "${dst}.tmp"
2260         test -f "${dst}" \
2261                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2262                 && rm "${dst}.tmp" \
2263                 || mv "${dst}.tmp" "${dst}"
2264     ], [
2265         PERL="$PERL"
2266     ])
2267 ])
2268
2269 ## Hack, but working solution to avoid rebuilding of frr.info.
2270 ## It's already in CVS until texinfo 4.7 is more common.
2271 AC_OUTPUT
2272
2273 echo "
2274 FRRouting configuration
2275 ------------------------------
2276 FRR version             : ${PACKAGE_VERSION}
2277 host operating system   : ${host_os}
2278 source code location    : ${srcdir}
2279 compiler                : ${CC}
2280 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2281 make                    : ${MAKE-make}
2282 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2283 state file directory    : ${frr_statedir}
2284 config file directory   : `eval echo \`echo ${sysconfdir}\``
2285 example directory       : `eval echo \`echo ${exampledir}\``
2286 module directory        : ${CFG_MODULE}
2287 user to run as          : ${enable_user}
2288 group to run as         : ${enable_group}
2289 group for vty sockets   : ${enable_vty_group}
2290 config file mask        : ${enable_configfile_mask}
2291 log file mask           : ${enable_logfile_mask}
2292 zebra protobuf enabled  : ${enable_protobuf:-no}
2293
2294 The above user and group must have read/write access to the state file
2295 directory and to the config files in the config file directory."
2296
2297 if test "${enable_doc}" != "no";then
2298   AS_IF([test "$SPHINXBUILD" = /bin/false],
2299      AC_MSG_WARN([sphinx-build is missing but required to build documentation]))
2300 fi