configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_version_major], 1)
   5 m4_define([lxc_version_minor], 0)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], [rc2])
   8
   9 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  10 m4_define([lxc_version],
  11           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  12
  13 AC_INIT([lxc], [lxc_version])
  14
  15 # We need pkg-config
  16 PKG_PROG_PKG_CONFIG
  17
  18 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  19 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  20
  21 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  22 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  23 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  24 AC_SUBST([LXC_VERSION], [lxc_version])
  25
  26 AC_CONFIG_SRCDIR([configure.ac])
  27 AC_CONFIG_AUX_DIR([config])
  28 AC_CONFIG_HEADERS([src/config.h])
  29 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  30 AC_CANONICAL_HOST
  31 AM_PROG_CC_C_O
  32 AC_GNU_SOURCE
  33
  34 # Detect the distribution. This is used for the default configuration and
  35 # for some distro-specific build options.
  36 AC_MSG_CHECKING([host distribution])
  37 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, paldo, openmandriva or pardus.]))
  38 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  39         with_distro=`lsb_release -is`
  40 fi
  41 if test "z$with_distro" = "z"; then
  42         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  43         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  44         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  45         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  46         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  47         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  48         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  49         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  50         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  51         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  52         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  53         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  54         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  55 fi
  56 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  57
  58 if test "z$with_distro" = "z"; then
  59         with_distro="unknown"
  60 fi
  61 case $with_distro in
  62         ubuntu)
  63                 distroconf=default.conf.ubuntu
  64                 ;;
  65         redhat|centos|fedora|oracle|oracleserver)
  66                 distroconf=default.conf.libvirt
  67                 ;;
  68         *)
  69                 distroconf=default.conf.unknown
  70                 ;;
  71 esac
  72 AC_MSG_RESULT([$with_distro])
  73 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"])
  74 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  75
  76 # Check for init system type
  77 AC_MSG_CHECKING([for init system type])
  78 AC_ARG_WITH([init-script],
  79             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  80                             [Type(s) of init script to install: sysvinit, systemd, upstart,
  81                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  82 case "$with_init_script" in
  83         distro)
  84                 case $with_distro in
  85                         fedora)
  86                                 init_script=systemd
  87                                 ;;
  88                         redhat|centos|oracle|oracleserver)
  89                                 init_script=sysvinit
  90                                 ;;
  91                         debian)
  92                                 init_script=upstart,systemd
  93                                 ;;
  94                         ubuntu)
  95                                 init_script=upstart
  96                                 ;;
  97                         *)
  98                                 echo -n "Linux distribution init system unknown."
  99                                 init_script=
 100                                 ;;
 101                 esac
 102                 ;;
 103         *)
 104                 init_script=$with_init_script
 105                 ;;
 106 esac
 107
 108 # Check valid init systems were given, run in subshell so we don't mess up IFS
 109 (IFS="," ; for init_sys in $init_script;
 110 do
 111         case "$init_sys" in
 112                 none|sysvinit|systemd|upstart)
 113                         ;;
 114                 *)
 115                         exit 1
 116                         ;;
 117         esac
 118 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 119
 120 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 121 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 122 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 123 AC_MSG_RESULT($init_script)
 124
 125 # Allow disabling rpath
 126 AC_ARG_ENABLE([rpath],
 127         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 128         [], [enable_rpath=no])
 129 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 130
 131 # Documentation (manpages)
 132 AC_ARG_ENABLE([doc],
 133         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 134         [], [enable_doc=auto])
 135
 136 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 137         db2xman=""
 138         dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 139
 140         AC_MSG_CHECKING(for docbook2x-man)
 141         for name in ${dbparsers}; do
 142                 if "$name" --help >/dev/null 2>&1; then
 143                         db2xman="$name"
 144                         break;
 145                 fi
 146         done
 147
 148         if test -n "${db2xman}"; then
 149                 AC_MSG_RESULT([${db2xman}])
 150                 enable_doc="yes"
 151         else
 152                 AC_MSG_RESULT([no])
 153                 if test "x$enable_doc" = "xyes"; then
 154                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 155                 fi
 156                 enable_doc="no"
 157         fi
 158
 159         AC_SUBST(db2xman)
 160 fi
 161 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 162 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 163
 164 if test "x$db2xman" = "xdocbook2man"; then
 165         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 166 else
 167         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 168 fi
 169 AC_SUBST(docdtd)
 170
 171 # Documentation (API)
 172 AC_ARG_ENABLE([api-docs],
 173         [AC_HELP_STRING([--enable-api-docs],
 174         [make API documentation [default=auto]])],
 175         [], [enable_api_docs=auto])
 176
 177 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 178         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 179         AC_SUBST([HAVE_DOXYGEN])
 180
 181         if test "x$HAVE_DOXYGEN" != "x"; then
 182                 enable_api_docs="yes"
 183         else
 184                 if test "x$enable_api_docs" = "xyes"; then
 185                         AC_MSG_ERROR([doxygen is required, but could not be found])
 186                 fi
 187                 enable_api_docs="no"
 188         fi
 189 fi
 190
 191 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 192
 193 # Apparmor
 194 AC_ARG_ENABLE([apparmor],
 195         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 196         [], [enable_apparmor=auto])
 197
 198 if test "$enable_apparmor" = "auto" ; then
 199         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 200 fi
 201 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 202
 203 AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 204
 205 AM_COND_IF([ENABLE_APPARMOR],
 206         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 207         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 208         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 209
 210 # SELinux
 211 AC_ARG_ENABLE([selinux],
 212         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 213         [], [enable_selinux=auto])
 214
 215 if test "x$enable_selinux" = xauto; then
 216         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 217 fi
 218 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 219 AM_COND_IF([ENABLE_SELINUX],
 220         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 221         AC_CHECK_LIB([selinux], [setexeccon_raw],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 222         AC_SUBST([SELINUX_LIBS])])
 223
 224 # Seccomp syscall filter
 225 AC_ARG_ENABLE([seccomp],
 226         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 227         [], [enable_seccomp=auto])
 228
 229 if test "x$enable_seccomp" = "xauto" ; then
 230         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 231 fi
 232 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 233
 234 AM_COND_IF([ENABLE_SECCOMP],
 235         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 236                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 237                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 238                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 239                 ])
 240         ])
 241
 242 # cgmanager
 243 AC_ARG_ENABLE([cgmanager],
 244         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 245         [], [enable_cgmanager=auto])
 246
 247 if test "x$enable_cgmanager" = "xauto" ; then
 248         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus])
 249 fi
 250 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 251
 252 AM_COND_IF([ENABLE_CGMANAGER],
 253         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 254         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 255         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 256         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 257         ])
 258
 259 # Linux capabilities
 260 AC_ARG_ENABLE([capabilities],
 261         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 262         [], [enable_capabilities=auto])
 263
 264 if test "x$enable_capabilities" = "xauto"; then
 265         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 266 fi
 267 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 268
 269 AM_COND_IF([ENABLE_CAP],
 270         [AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You are missing libcap support.])])
 271         AC_SUBST([CAP_LIBS], [-lcap])])
 272
 273 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 274 OLD_CFLAGS="$CFLAGS"
 275 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 276 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 277 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 278 CFLAGS="$OLD_CFLAGS"
 279
 280 # Configuration examples
 281 AC_ARG_ENABLE([examples],
 282         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 283         [], [enable_examples=yes])
 284 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 285
 286 # Python3 module and scripts
 287 AC_ARG_ENABLE([python],
 288         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 289         [], [enable_python=auto])
 290
 291 if test "x$enable_python" = "xauto"; then
 292         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 293         if test "$CC" = "clang"; then
 294                 enable_python=no
 295         fi
 296 fi
 297
 298 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 299         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 300 fi
 301
 302 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 303
 304 AM_COND_IF([ENABLE_PYTHON],
 305         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 306         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 307         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 308
 309 # Enable dumping stack traces
 310 AC_ARG_ENABLE([mutex-debugging],
 311         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 312         [], [enable_mutex_debugging=no])
 313 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 314
 315 AM_COND_IF([MUTEX_DEBUGGING],
 316         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 317
 318 # Not in older autoconf versions
 319 # AS_VAR_COPY(DEST, SOURCE)
 320 # -------------------------
 321 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 322 # shell variable SOURCE.
 323 m4_ifdef([AS_VAR_COPY], [],
 324 [AC_DEFUN([AS_VAR_COPY],
 325     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 326 ])
 327
 328 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 329 m4_ifdef([PKG_CHECK_VAR], [],
 330 [AC_DEFUN([PKG_CHECK_VAR],
 331     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 332      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 333      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 334      AS_VAR_COPY([$1], [pkg_cv_][$1])
 335      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 336     ])# PKG_CHECK_VAR
 337 ])
 338
 339 # Lua module and scripts
 340 AC_ARG_ENABLE([lua],
 341         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 342         [], [enable_lua=auto])
 343
 344 AC_ARG_WITH([lua-pc],
 345         [AS_HELP_STRING(
 346                 [--with-lua-pc=PKG],
 347                 [Specify pkg-config package name for lua]
 348         )], [], [with_lua_pc=no])
 349
 350 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 351         # exit with error if not found
 352         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 353 fi
 354
 355 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 356         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 357                 [LUAPKGCONFIG=$with_lua_pc
 358                 enable_lua=yes],
 359                 [enable_lua=no])
 360 fi
 361
 362 if test "x$enable_lua" != "xno"; then
 363         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 364                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 365                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 366                                 [AS_IF([test "x$enable_lua" = "xyes"],
 367                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 368                                         [enable_lua=no])]
 369                         )]
 370                 )])
 371         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 372 fi
 373
 374 AM_CONDITIONAL([ENABLE_LUA],
 375         [test "x$enable_lua" = "xyes"])
 376
 377 AM_COND_IF([ENABLE_LUA],
 378         [AC_MSG_CHECKING([Lua version])
 379         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 380                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 381         AC_MSG_RESULT([$LUA_VERSION])
 382         PKG_CHECK_VAR([LUA_INSTALL_CMOD], [$LUAPKGCONFIG], [INSTALL_CMOD],,
 383                 [LUA_INSTALL_CMOD=$libdir/lua/$LUA_VERSION])
 384         PKG_CHECK_VAR([LUA_INSTALL_LMOD], [$LUAPKGCONFIG], [INSTALL_LMOD],,
 385                 [LUA_INSTALL_LMOD=$datadir/lua/$LUA_VERSION])
 386         ])
 387
 388 # Optional bash integration
 389 AC_ARG_ENABLE([bash],
 390         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 391         [], [enable_bash=yes])
 392 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 393
 394 # Optional test binaries
 395 AC_ARG_ENABLE([tests],
 396         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 397         [], [enable_tests=no])
 398 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 399
 400 # Allow overriding the default runtime dir (/run)
 401 AC_ARG_WITH([runtime-path],
 402         [AC_HELP_STRING(
 403                 [--with-runtime-path=dir],
 404                 [runtime directory (default: /run)]
 405         )], [], [with_runtime_path=['/run']])
 406
 407 # LXC container path, where the containers are actually stored
 408 # This is overridden by an entry in the file called LXCCONF
 409 # (i.e. /etc/lxc/lxc.conf)
 410 AC_ARG_WITH([config-path],
 411         [AC_HELP_STRING(
 412                 [--with-config-path=dir],
 413                 [lxc configuration repository path]
 414         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 415
 416 # The path of the global lxc configuration file.
 417 AC_ARG_WITH([global-conf],
 418         [AC_HELP_STRING(
 419                 [--with-global-conf=dir],
 420                 [global lxc configuration file]
 421         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 422
 423 # The path of the userns network configuration file
 424 AC_ARG_WITH([usernic-conf],
 425         [AC_HELP_STRING(
 426                 [--with-usernic-conf],
 427                 [user network interface configuration file]
 428         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 429
 430 # The path of the runtime usernic database
 431 AC_ARG_WITH([usernic-db],
 432         [AC_HELP_STRING(
 433                 [--with-usernic-db],
 434                 [lxc user nic database]
 435         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 436
 437 # Rootfs path, where the container mount structure is assembled
 438 AC_ARG_WITH([rootfs-path],
 439         [AC_HELP_STRING(
 440                 [--with-rootfs-path=dir],
 441                 [lxc rootfs mount point]
 442         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 443
 444 # cgroup pattern specification
 445 AC_ARG_WITH([cgroup-pattern],
 446         [AC_HELP_STRING(
 447                 [--with-cgroup-pattern=pattern],
 448                 [pattern for container cgroups]
 449         )], [], [with_cgroup_pattern=['/lxc/%n']])
 450
 451 # Container log path.  By default, use $lxcpath.
 452 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 453 AC_ARG_ENABLE([configpath-log],
 454         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 455         [], [enable_configpath_log=no])
 456 AC_MSG_RESULT([$enable_configpath_log])
 457 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 458
 459 if test "$enable_configpath_log" = "yes"; then
 460         default_log_path="${with_config_path}"
 461 else
 462         default_log_path="${localstatedir}/log/lxc"
 463 fi
 464
 465 AC_ARG_WITH([log-path],
 466         [AC_HELP_STRING(
 467                 [--with-log-path=dir],
 468                 [per container log path]
 469         )], [], [with_log_path=['${default_log_path}']])
 470
 471 # Expand some useful variables
 472 AS_AC_EXPAND(PREFIX, "$prefix")
 473 AS_AC_EXPAND(LIBDIR, "$libdir")
 474 AS_AC_EXPAND(BINDIR, "$bindir")
 475 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 476 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 477 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 478 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 479 AS_AC_EXPAND(DATADIR, "$datadir")
 480 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 481 AS_AC_EXPAND(DOCDIR, "$docdir")
 482 AS_AC_EXPAND(LXC_DISTRO_CONF, "$distroconf")
 483 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 484 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 485 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 486 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 487 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 488 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 489 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 490 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 491 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 492 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 493 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 494 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 495 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 496
 497 # Check for some standard kernel headers
 498 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 499                                 [],
 500                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 501                                 [#include <sys/socket.h>])
 502
 503 # Check for alternate C libraries
 504 AC_MSG_CHECKING(for bionic libc)
 505 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 506         [[#ifndef __ANDROID__
 507 error: Not bionic!
 508 #endif]])],
 509         [is_bionic=yes],
 510         [is_bionic=no])
 511 if test "x$is_bionic" = "xyes"; then
 512         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 513         AC_MSG_RESULT([yes])
 514 else
 515         AC_MSG_RESULT([no])
 516 fi
 517 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 518
 519 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 520 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 521
 522 # Check for some headers
 523 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 524
 525 # Check for some syscalls functions
 526 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat])
 527
 528 # Check for some functions
 529 AC_CHECK_LIB(pthread, main)
 530 AC_CHECK_FUNCS(pthread_atfork)
 531 AC_CHECK_LIB(util, openpty)
 532 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 533 AC_CHECK_FUNCS([getline],
 534         AM_CONDITIONAL(HAVE_GETLINE, true)
 535         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 536         AM_CONDITIONAL(HAVE_GETLINE, false))
 537 AC_CHECK_FUNCS([fgetln],
 538         AM_CONDITIONAL(HAVE_FGETLN, true)
 539         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 540         AM_CONDITIONAL(HAVE_FGETLN, false))
 541
 542 # Check for some libraries
 543 AC_SEARCH_LIBS(sem_open, [rt pthread])
 544 AC_SEARCH_LIBS(clock_gettime, [rt])
 545
 546 # Check for some standard binaries
 547 AC_PROG_GCC_TRADITIONAL
 548 AC_PROG_SED
 549
 550 # See if we support thread-local storage.
 551 LXC_CHECK_TLS
 552
 553 if test "x$GCC" = "xyes"; then
 554         CFLAGS="$CFLAGS -Wall -Werror"
 555 fi
 556
 557 # Files requiring some variable expansion
 558 AC_CONFIG_FILES([
 559         Makefile
 560         lxc.pc
 561         lxc.spec
 562
 563         config/Makefile
 564         config/apparmor/Makefile
 565         config/bash/Makefile
 566         config/bash/lxc
 567         config/init/Makefile
 568         config/init/sysvinit/Makefile
 569         config/init/systemd/Makefile
 570         config/init/upstart/Makefile
 571         config/etc/Makefile
 572         config/templates/Makefile
 573         config/templates/centos.common.conf
 574         config/templates/centos.userns.conf
 575         config/templates/debian.common.conf
 576         config/templates/debian.userns.conf
 577         config/templates/fedora.common.conf
 578         config/templates/fedora.userns.conf
 579         config/templates/gentoo.common.conf
 580         config/templates/gentoo.moresecure.conf
 581         config/templates/gentoo.userns.conf
 582         config/templates/oracle.common.conf
 583         config/templates/oracle.userns.conf
 584         config/templates/plamo.common.conf
 585         config/templates/plamo.userns.conf
 586         config/templates/ubuntu-cloud.common.conf
 587         config/templates/ubuntu-cloud.lucid.conf
 588         config/templates/ubuntu-cloud.userns.conf
 589         config/templates/ubuntu.common.conf
 590         config/templates/ubuntu.lucid.conf
 591         config/templates/ubuntu.userns.conf
 592
 593         doc/Makefile
 594         doc/api/Makefile
 595         doc/legacy/lxc-ls.sgml
 596         doc/lxc-attach.sgml
 597         doc/lxc-autostart.sgml
 598         doc/lxc-cgroup.sgml
 599         doc/lxc-checkconfig.sgml
 600         doc/lxc-clone.sgml
 601         doc/lxc-config.sgml
 602         doc/lxc-console.sgml
 603         doc/lxc-create.sgml
 604         doc/lxc-destroy.sgml
 605         doc/lxc-device.sgml
 606         doc/lxc-execute.sgml
 607         doc/lxc-freeze.sgml
 608         doc/lxc-info.sgml
 609         doc/lxc-ls.sgml
 610         doc/lxc-monitor.sgml
 611         doc/lxc-snapshot.sgml
 612         doc/lxc-start-ephemeral.sgml
 613         doc/lxc-start.sgml
 614         doc/lxc-stop.sgml
 615         doc/lxc-top.sgml
 616         doc/lxc-unfreeze.sgml
 617         doc/lxc-unshare.sgml
 618         doc/lxc-user-nic.sgml
 619         doc/lxc-usernsexec.sgml
 620         doc/lxc-wait.sgml
 621
 622         doc/lxc.conf.sgml
 623         doc/lxc.container.conf.sgml
 624         doc/lxc.system.conf.sgml
 625         doc/lxc-usernet.sgml
 626         doc/lxc.sgml
 627         doc/common_options.sgml
 628         doc/see_also.sgml
 629
 630         doc/rootfs/Makefile
 631
 632         doc/examples/Makefile
 633         doc/examples/lxc-macvlan.conf
 634         doc/examples/lxc-vlan.conf
 635         doc/examples/lxc-no-netns.conf
 636         doc/examples/lxc-empty-netns.conf
 637         doc/examples/lxc-phys.conf
 638         doc/examples/lxc-veth.conf
 639         doc/examples/lxc-complex.conf
 640
 641         doc/ja/Makefile
 642         doc/ja/legacy/lxc-ls.sgml
 643         doc/ja/lxc-attach.sgml
 644         doc/ja/lxc-autostart.sgml
 645         doc/ja/lxc-cgroup.sgml
 646         doc/ja/lxc-checkconfig.sgml
 647         doc/ja/lxc-clone.sgml
 648         doc/ja/lxc-config.sgml
 649         doc/ja/lxc-console.sgml
 650         doc/ja/lxc-create.sgml
 651         doc/ja/lxc-destroy.sgml
 652         doc/ja/lxc-device.sgml
 653         doc/ja/lxc-execute.sgml
 654         doc/ja/lxc-freeze.sgml
 655         doc/ja/lxc-info.sgml
 656         doc/ja/lxc-ls.sgml
 657         doc/ja/lxc-monitor.sgml
 658         doc/ja/lxc-snapshot.sgml
 659         doc/ja/lxc-start-ephemeral.sgml
 660         doc/ja/lxc-start.sgml
 661         doc/ja/lxc-stop.sgml
 662         doc/ja/lxc-top.sgml
 663         doc/ja/lxc-unfreeze.sgml
 664         doc/ja/lxc-unshare.sgml
 665         doc/ja/lxc-user-nic.sgml
 666         doc/ja/lxc-usernsexec.sgml
 667         doc/ja/lxc-wait.sgml
 668
 669         doc/ja/lxc.conf.sgml
 670         doc/ja/lxc.container.conf.sgml
 671         doc/ja/lxc.system.conf.sgml
 672         doc/ja/lxc-usernet.sgml
 673         doc/ja/lxc.sgml
 674         doc/ja/common_options.sgml
 675         doc/ja/see_also.sgml
 676
 677         hooks/Makefile
 678
 679         templates/Makefile
 680         templates/lxc-alpine
 681         templates/lxc-altlinux
 682         templates/lxc-archlinux
 683         templates/lxc-busybox
 684         templates/lxc-centos
 685         templates/lxc-cirros
 686         templates/lxc-debian
 687         templates/lxc-download
 688         templates/lxc-fedora
 689         templates/lxc-gentoo
 690         templates/lxc-openmandriva
 691         templates/lxc-opensuse
 692         templates/lxc-oracle
 693         templates/lxc-plamo
 694         templates/lxc-sshd
 695         templates/lxc-ubuntu
 696         templates/lxc-ubuntu-cloud
 697
 698         src/Makefile
 699         src/lxc/Makefile
 700         src/lxc/lxc-checkconfig
 701         src/lxc/lxc-start-ephemeral
 702         src/lxc/legacy/lxc-ls
 703         src/lxc/lxc.functions
 704         src/lxc/version.h
 705         src/python-lxc/Makefile
 706
 707         src/lua-lxc/Makefile
 708
 709         src/tests/Makefile
 710         src/tests/lxc-test-usernic
 711 ])
 712 AC_CONFIG_COMMANDS([default],[[]],[[]])
 713 AC_OUTPUT
 714
 715 # Configuration overview
 716 cat << EOF
 717
 718 ----------------------------
 719 Environment:
 720  - compiler: $CC
 721  - distribution: $with_distro
 722  - init script type(s): $init_script
 723  - rpath: $enable_rpath
 724  - GnuTLS: $enable_gnutls
 725  - Bash integration: $enable_bash
 726
 727 Security features:
 728  - Apparmor: $enable_apparmor
 729  - Linux capabilities: $enable_capabilities
 730  - seccomp: $enable_seccomp
 731  - SELinux: $enable_selinux
 732  - cgmanager: $enable_cgmanager
 733
 734 Bindings:
 735  - lua: $enable_lua
 736  - python3: $enable_python
 737
 738 Documentation:
 739  - examples: $enable_examples
 740  - API documentation: $enable_api_docs
 741  - user documentation: $enable_doc
 742
 743 Debugging:
 744  - tests: $enable_tests
 745  - mutex debugging: $enable_mutex_debugging
 746
 747 Paths:
 748  - Logs in configpath: $enable_configpath_log
 749 EOF
 750
 751 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 752 cat << EOF
 753
 754 WARNING: Threading not supported on your platform
 755
 756         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 757         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 758 EOF
 759 fi