configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.6-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AC_ARG_VAR([AR],[archiver command])
  29 AC_ARG_VAR([LD],[linker command])
  30 AC_ARG_VAR([OBJCOPY],[objcopy command])
  31 AC_ARG_VAR([OBJDUMP],[objdump command])
  32 AC_ARG_VAR([RANLIB],[ranlib command])
  33 AC_ARG_VAR([STRIP],[strip command])
  34
  35 hosttools_clippy="false"
  36 build_clippy="true"
  37
  38 dnl case 1: external clippy
  39 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  40   if test "$enable_clippy_only" = "yes"; then
  41     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  42   fi
  43
  44   CLIPPY="$with_clippy"
  45   build_clippy="false"
  46   if test ! -x "$with_clippy"; then
  47     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  48   fi
  49
  50 dnl case 2: cross-compiling internal clippy
  51 elif test "$host" != "$build"; then
  52   if test "$srcdir" = "."; then
  53     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  54   fi
  55   test -d hosttools || mkdir hosttools
  56   abssrc="`cd \"${srcdir}\"; pwd`"
  57
  58   AC_MSG_NOTICE([...])
  59   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  60   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  61   AC_MSG_NOTICE([...])
  62
  63   (
  64     for var in $ac_precious_vars; do
  65       dnl special cases
  66       case "$var" in
  67       YACC|YFLAGS) continue;;
  68       PYTHON*)     retain=true;;
  69       *)           retain=false;
  70       esac
  71
  72       eval "hostvar=\"\${HOST_$var}\""
  73       eval "targetvar=\"\${$var}\""
  74       if test -n "$hostvar"; then
  75         eval "$var='$hostvar'"
  76         _AS_ECHO_LOG([host $var='$hostvar'])
  77       elif $retain; then
  78         _AS_ECHO_LOG([host retain $var='$targetvar'])
  79       else
  80         eval "unset $var"
  81         _AS_ECHO_LOG([host unset $var])
  82       fi
  83     done
  84     cd hosttools
  85     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  86   ) || exit 1
  87
  88   AC_MSG_NOTICE([...])
  89   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  90   AC_MSG_NOTICE([...])
  91
  92   build_clippy="false"
  93   hosttools_clippy="true"
  94   CLIPPY="hosttools/lib/clippy"
  95
  96 dnl case 3: normal build internal clippy
  97 else
  98   CLIPPY="lib/clippy\$(EXEEXT)"
  99 fi
 100 AC_SUBST([CLIPPY])
 101 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 102 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 103 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 104
 105 # Disable portability warnings -- our automake code (in particular
 106 # common.am) uses some constructs specific to gmake.
 107 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 108 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 109 AM_SILENT_RULES([yes])
 110 AC_CONFIG_HEADERS([config.h])
 111
 112 AC_PATH_PROG([PERL], [perl])
 113 PKG_PROG_PKG_CONFIG
 114
 115 dnl default is to match previous behavior
 116 exampledir=${sysconfdir}
 117 AC_ARG_ENABLE([exampledir],
 118           AS_HELP_STRING([--enable-exampledir],
 119                          [specify alternate directory for examples]),
 120                          exampledir="$enableval",)
 121 dnl XXX add --exampledir to autoconf standard directory list somehow
 122 AC_SUBST([exampledir])
 123
 124 dnl default is to match previous behavior
 125 pkgsrcrcdir=""
 126 AC_ARG_ENABLE([pkgsrcrcdir],
 127           AS_HELP_STRING([--enable-pkgsrcrcdir],
 128                          [specify directory for rc.d scripts]),
 129                          pkgsrcrcdir="$enableval",)
 130 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 131 AC_SUBST([pkgsrcrcdir])
 132 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 133
 134 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 135         moduledir="$withval"
 136 ], [
 137         moduledir="\${libdir}/frr/modules"
 138 ])
 139 AC_SUBST([moduledir], [$moduledir])
 140
 141
 142 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 143         yangmodelsdir="$withval"
 144 ], [
 145         yangmodelsdir="\${datarootdir}/yang"
 146 ])
 147 AC_SUBST([yangmodelsdir])
 148
 149 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 150         vici_socket="$withval"
 151 ], [
 152         vici_socket="/var/run/charon.vici"
 153 ])
 154 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 155
 156 AC_ARG_ENABLE(tcmalloc,
 157         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 158 [case "${enableval}" in
 159   yes) tcmalloc_enabled=true
 160 LIBS="$LIBS -ltcmalloc_minimal"
 161  ;;
 162   no)  tcmalloc_enabled=false ;;
 163   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 164 esac],[tcmalloc_enabled=false])
 165
 166
 167 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 168 dnl flag determination logic.
 169 CFLAGS="${CFLAGS:-}"
 170
 171 dnl --------------------
 172 dnl Check CC and friends
 173 dnl --------------------
 174 dnl note orig_cflags is also used further down
 175 orig_cflags="$CFLAGS"
 176 orig_cxxflags="$CXXFLAGS"
 177 AC_LANG([C])
 178 AC_PROG_CC
 179 AC_PROG_CPP
 180 AC_PROG_CXX
 181 AM_PROG_CC_C_O
 182 dnl remove autoconf default "-g -O2"
 183 CFLAGS="$orig_cflags"
 184 CXXFLAGS="$orig_cxxflags"
 185 AC_PROG_CC_C99
 186 dnl NB: see C11 below
 187
 188 PKG_PROG_PKG_CONFIG
 189
 190 dnl it's 2019, sed is sed.
 191 SED=sed
 192 AC_SUBST([SED])
 193
 194 dnl try and enable CFLAGS that are useful for FRR
 195 dnl - specifically, options to control warnings
 196
 197 AC_USE_SYSTEM_EXTENSIONS
 198 AC_DEFUN([AC_C_FLAG], [{
 199     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 200     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 201         AC_LANG_PUSH([C])
 202         ac_c_flag_save="$CFLAGS"
 203         CFLAGS="$CFLAGS $1"
 204         AC_COMPILE_IFELSE(
 205                 [AC_LANG_PROGRAM([[$4]])],
 206                 [
 207                         cachename=yes
 208                 ], [
 209                         cachename=no
 210                 ])
 211         CFLAGS="$ac_c_flag_save"
 212         AC_LANG_POP([C])
 213     ])
 214     if test "$cachename" = "yes"; then
 215         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 216     else
 217         :
 218         $2
 219     fi
 220     m4_popdef([cachename])
 221 }])
 222
 223 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 224         AC_LANG_PUSH([C])
 225         ac_cflags_save="$CFLAGS"
 226         ac_libs_save="$LIBS"
 227         CFLAGS="$CFLAGS $1"
 228         LIBS="$LIBS $2"
 229         AC_LINK_IFELSE(
 230                 [$3],
 231                 [
 232                         CFLAGS="$ac_cflags_save"
 233                         LIBS="$ac_libs_save"
 234                         m4_default([$5], [
 235                                 AC_MSG_RESULT([yes])
 236                         ])
 237                 ], [
 238                         CFLAGS="$ac_cflags_save"
 239                         LIBS="$ac_libs_save"
 240                         m4_default([$4], [
 241                                 AC_MSG_RESULT([no])
 242                         ])
 243                 ])
 244         AC_LANG_POP([C])
 245         }])
 246
 247 dnl ICC won't bail on unknown options without -diag-error 10006
 248 dnl need to do this first so we get useful results for the other options
 249 AC_C_FLAG([-diag-error 10006])
 250
 251 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 252 ac_cc="$CC"
 253 CC="${CC% -std=gnu99}"
 254 CC="${CC% -std=c99}"
 255
 256 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 257
 258 dnl if the user has specified any CFLAGS, override our settings
 259 if test "$enable_gcov" = "yes"; then
 260    if test "$orig_cflags" = ""; then
 261       AC_C_FLAG([-coverage])
 262       AC_C_FLAG([-O0])
 263    fi
 264
 265    LDFLAGS="${LDFLAGS} -lgcov"
 266 fi
 267
 268 if test "$enable_clang_coverage" = "yes"; then
 269    AC_C_FLAG([-fprofile-instr-generate], [
 270      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 271    ])
 272    AC_C_FLAG([-fcoverage-mapping], [
 273      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 274    ])
 275 fi
 276
 277 if test "$enable_scripting" = "yes"; then
 278    AX_PROG_LUA([5.3])
 279    AX_LUA_HEADERS
 280    AX_LUA_LIBS([
 281       AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 282       LIBS="$LIBS $LUA_LIB"
 283    ])
 284 fi
 285
 286 if test "$enable_dev_build" = "yes"; then
 287    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 288    if test "$orig_cflags" = ""; then
 289       AC_C_FLAG([-g3])
 290       AC_C_FLAG([-O0])
 291    fi
 292 else
 293    if test "$orig_cflags" = ""; then
 294       AC_C_FLAG([-g])
 295       AC_C_FLAG([-O2])
 296    fi
 297 fi
 298 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 299
 300 dnl always want these CFLAGS
 301 AC_C_FLAG([-fno-omit-frame-pointer])
 302 AC_C_FLAG([-funwind-tables])
 303 AC_C_FLAG([-Wall])
 304 AC_C_FLAG([-Wextra])
 305 AC_C_FLAG([-Wmissing-prototypes])
 306 AC_C_FLAG([-Wmissing-declarations])
 307 AC_C_FLAG([-Wpointer-arith])
 308 AC_C_FLAG([-Wbad-function-cast])
 309 AC_C_FLAG([-Wwrite-strings])
 310 AC_C_FLAG([-Wundef])
 311 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 312   AC_C_FLAG([-Wcast-qual])
 313   AC_C_FLAG([-Wstrict-prototypes])
 314   AC_C_FLAG([-Wmissing-noreturn])
 315   AC_C_FLAG([-Wmissing-format-attribute])
 316   AC_C_FLAG([-Wunreachable-code])
 317   AC_C_FLAG([-Wpacked])
 318   AC_C_FLAG([-Wpadded])
 319   AC_C_FLAG([-Wshadow])
 320 else
 321   AC_C_FLAG([-Wno-unused-result])
 322 fi
 323 AC_C_FLAG([-Wno-unused-parameter])
 324 AC_C_FLAG([-Wno-missing-field-initializers])
 325
 326 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 327 AC_SUBST([CXX_COMPAT_CFLAGS])
 328
 329 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 330 dnl for some reason the string consts get 'promoted' to char *,
 331 dnl triggering a const to non-const conversion warning.
 332 AC_C_FLAG([-diag-disable 3179])
 333
 334 if test "$enable_werror" = "yes" ; then
 335   WERROR="-Werror"
 336 fi
 337 AC_SUBST([WERROR])
 338
 339 SAN_FLAGS=""
 340 if test "$enable_address_sanitizer" = "yes"; then
 341   AC_C_FLAG([-fsanitize=address], [
 342     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 343   ], [
 344     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 345   ])
 346 fi
 347 if test "$enable_thread_sanitizer" = "yes"; then
 348   AC_C_FLAG([-fsanitize=thread], [
 349     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 350   ], [
 351     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 352   ])
 353 fi
 354 if test "$enable_memory_sanitizer" = "yes"; then
 355   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 356     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 357   ], [
 358     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 359   ])
 360 fi
 361 if test "$enable_undefined_sanitizer" = "yes"; then
 362   AC_C_FLAG([-fsanitize=undefined], [
 363     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 364   ], [
 365     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 366   ])
 367 fi
 368 AC_SUBST([SAN_FLAGS])
 369
 370 dnl frr-format.so
 371 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 372   AC_C_FLAG([-fplugin=${with_frr_format}], [
 373     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 374   ],,[
 375 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 376 #error plugin not loaded
 377 #endif
 378 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 379 #error plugin too old
 380 #endif
 381   ])
 382 elif test "$with_frr_format" = "no"; then
 383   : #nothing
 384 else
 385   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 386     AC_C_FLAG([-fplugin=frr-format],[
 387       if test "$with_frr_format" = "yes"; then
 388         AC_MSG_ERROR([frr-format plugin requested but not found])
 389       fi
 390     ],,[
 391 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 392 #error plugin not loaded
 393 #endif
 394 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 395 #error plugin too old
 396 #endif
 397     ])
 398   ],,[
 399 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 400 #error plugin not loaded
 401 #endif
 402 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 403 #error plugin too old
 404 #endif
 405   ])
 406 fi
 407
 408 dnl ----------
 409 dnl Essentials
 410 dnl ----------
 411
 412 AX_PTHREAD([
 413   CC="$PTHREAD_CC"
 414   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 415   LIBS="$PTHREAD_LIBS $LIBS"
 416 ], [
 417   AC_MSG_FAILURE([This FRR version needs pthreads])
 418 ])
 419
 420 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 421                 [frr_cv_pthread_condattr_setclock=yes],
 422                 [frr_cv_pthread_condattr_setclock=no])
 423 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 424   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 425 fi
 426
 427 dnl --------------
 428 dnl Check programs
 429 dnl --------------
 430 AC_PROG_INSTALL
 431 AC_PROG_LN_S
 432 AC_CHECK_TOOL([AR], [ar])
 433
 434 dnl -------
 435 dnl libtool
 436 dnl -------
 437 AC_ARG_ENABLE([static-bin],
 438   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 439 LT_INIT
 440 _LT_CONFIG_LIBTOOL([
 441   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 442     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 443   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 444   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 445   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 446 ])
 447 if test "$enable_static_bin" = "yes"; then
 448   AC_LDFLAGS="-static"
 449   if test "$enable_static" != "yes"; then
 450     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 451   fi
 452 fi
 453 if test "$enable_shared" != "yes"; then
 454   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 455 fi
 456 AC_SUBST([AC_LDFLAGS])
 457 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 458
 459 AC_ARG_ENABLE([rpath],
 460   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 461   [],
 462   [enable_rpath=yes])
 463
 464 dnl $AR and $RANLIB are set by LT_INIT above
 465 AC_MSG_CHECKING([whether $AR supports D option])
 466 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 467   AC_MSG_RESULT([yes])
 468   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 469   ARFLAGS="crD"
 470   AR_FLAGS="crD"
 471 else
 472   AC_MSG_RESULT([no])
 473   ARFLAGS="cru"
 474   AR_FLAGS="cru"
 475 fi
 476 AC_SUBST([ARFLAGS])
 477 AC_SUBST([AR_FLAGS])
 478
 479 AC_MSG_CHECKING([whether $RANLIB supports D option])
 480 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 481   if grep -q -- '-D' conftest.err; then
 482     AC_MSG_RESULT([no])
 483   else
 484     AC_MSG_RESULT([yes])
 485     RANLIB="$RANLIB -D"
 486   fi
 487 else
 488   AC_MSG_RESULT([no])
 489 fi
 490 AC_SUBST([RANLIB])
 491
 492 test -f conftest.err && rm conftest.err
 493 test -f conftest.a && rm conftest.a
 494
 495 dnl ----------------------
 496 dnl Packages configuration
 497 dnl ----------------------
 498 if test -f config.version; then
 499   . ./config.version
 500 elif test -f "${srcdir}/config.version"; then
 501   . "${srcdir}/config.version"
 502 fi
 503 AC_ARG_WITH([pkg-extra-version],
 504   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 505   if test "$withval" = "no"; then
 506     EXTRAVERSION=
 507   else
 508     EXTRAVERSION=$withval
 509   fi
 510 ], [])
 511 AC_ARG_WITH([pkg-git-version],
 512         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 513         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 514 AC_ARG_WITH([clippy],
 515   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 516 AC_ARG_WITH([vtysh_pager],
 517         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 518         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 519 AC_ARG_ENABLE([vtysh],
 520   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 521 AC_ARG_ENABLE([doc],
 522   AS_HELP_STRING([--disable-doc], [do not build docs]))
 523 AC_ARG_ENABLE([doc-html],
 524   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 525 AC_ARG_ENABLE([zebra],
 526   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 527 AC_ARG_ENABLE([bgpd],
 528   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 529 AC_ARG_ENABLE([ripd],
 530   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 531 AC_ARG_ENABLE([ripngd],
 532   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 533 AC_ARG_ENABLE([ospfd],
 534   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 535 AC_ARG_ENABLE([ospf6d],
 536   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 537 AC_ARG_ENABLE([ldpd],
 538   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 539 AC_ARG_ENABLE([nhrpd],
 540   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 541 AC_ARG_ENABLE([eigrpd],
 542   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 543 AC_ARG_ENABLE([babeld],
 544   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 545 AC_ARG_ENABLE([watchfrr],
 546   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 547 AC_ARG_ENABLE([isisd],
 548   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 549 AC_ARG_ENABLE([pimd],
 550   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 551 AC_ARG_ENABLE([pbrd],
 552   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 553 AC_ARG_ENABLE([sharpd],
 554   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 555 AC_ARG_ENABLE([staticd],
 556   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 557 AC_ARG_ENABLE([fabricd],
 558   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 559 AC_ARG_ENABLE([vrrpd],
 560   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 561 AC_ARG_ENABLE([bgp-announce],
 562   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 563 AC_ARG_ENABLE([bgp-vnc],
 564   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 565 AC_ARG_ENABLE([bgp-bmp],
 566   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 567 AC_ARG_ENABLE([snmp],
 568   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 569 AC_ARG_ENABLE([config_rollbacks],
 570   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 571 AC_ARG_ENABLE([confd],
 572   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 573 AC_ARG_ENABLE([sysrepo],
 574   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 575 AC_ARG_ENABLE([grpc],
 576   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 577 AC_ARG_ENABLE([zeromq],
 578   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 579 AC_ARG_ENABLE([lttng],
 580   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 581 AC_ARG_ENABLE([usdt],
 582   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 583 AC_ARG_WITH([libpam],
 584   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 585 AC_ARG_ENABLE([ospfapi],
 586   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 587 AC_ARG_ENABLE([ospfclient],
 588   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 589                           (this is the default if --disable-ospfapi is set)]))
 590 AC_ARG_ENABLE([multipath],
 591   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 592 AC_ARG_ENABLE([user],
 593   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 594 AC_ARG_ENABLE([group],
 595   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 596 AC_ARG_ENABLE([vty_group],
 597   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 598 AC_ARG_ENABLE([configfile_mask],
 599   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 600 AC_ARG_ENABLE([logfile_mask],
 601   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 602 AC_ARG_ENABLE([shell_access],
 603   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 604 AC_ARG_ENABLE([realms],
 605   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 606 AC_ARG_ENABLE([rtadv],
 607   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 608 AC_ARG_ENABLE([irdp],
 609   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 610 AC_ARG_ENABLE([capabilities],
 611   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 612 AC_ARG_ENABLE([rusage],
 613   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 614 AC_ARG_ENABLE([gcc_ultra_verbose],
 615   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 616 AC_ARG_ENABLE([backtrace],
 617   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 618 AC_ARG_ENABLE([time-check],
 619   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 620 AC_ARG_ENABLE([cpu-time],
 621   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 622 AC_ARG_ENABLE([pcreposix],
 623   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 624 AC_ARG_ENABLE([fpm],
 625   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 626 AC_ARG_ENABLE([systemd],
 627   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 628 AC_ARG_ENABLE([werror],
 629   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 630 AC_ARG_ENABLE([cumulus],
 631   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 632 AC_ARG_ENABLE([datacenter],
 633   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 634 AC_ARG_ENABLE([rr-semantics],
 635   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 636 AC_ARG_ENABLE([protobuf],
 637   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 638 AC_ARG_ENABLE([oldvpn_commands],
 639   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 640 AC_ARG_ENABLE([rpki],
 641   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 642 AC_ARG_ENABLE([clippy-only],
 643   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 644 AC_ARG_ENABLE([numeric_version],
 645   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 646 AC_ARG_ENABLE([gcov],
 647   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 648 AC_ARG_ENABLE([clang_coverage],
 649   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 650 AC_ARG_ENABLE([bfdd],
 651   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 652 AC_ARG_ENABLE([address-sanitizer],
 653   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 654 AC_ARG_ENABLE([thread-sanitizer],
 655   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 656 AC_ARG_ENABLE([memory-sanitizer],
 657   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 658 AC_ARG_ENABLE([undefined-sanitizer],
 659   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 660 AC_ARG_WITH([crypto],
 661   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 662 AC_ARG_WITH([frr-format],
 663   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 664
 665 AC_ARG_ENABLE([version-build-config],
 666   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 667
 668 #if openssl, else use the internal
 669 AS_IF([test "$with_crypto" = "openssl"], [
 670 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 671 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 672   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 673 else
 674   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 675 fi
 676 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 677 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 678 )
 679
 680 AS_IF([test "$enable_clippy_only" != "yes"], [
 681 AC_CHECK_HEADERS([json-c/json.h])
 682 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 683 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 684   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 685   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 686       AC_MSG_ERROR([libjson is needed to compile])
 687   fi
 688 fi
 689 ])
 690
 691 AC_ARG_ENABLE([dev_build],
 692     AS_HELP_STRING([--enable-dev-build], [build for development]))
 693
 694 AC_ARG_ENABLE([scripting],
 695     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 696
 697 if test "$enable_time_check" != "no" ; then
 698   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 699     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 700   else
 701     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 702   fi
 703 fi
 704
 705 case "${enable_cpu_time}" in
 706   "no")
 707   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 708   ;;
 709   "*")
 710   ;;
 711 esac
 712
 713 case "${enable_systemd}" in
 714   "no") ;;
 715   "yes")
 716   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 717   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 718     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 719   else
 720     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 721   fi
 722   ;;
 723   "*") ;;
 724 esac
 725
 726 if test "$enable_rr_semantics" != "no" ; then
 727   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 728 fi
 729
 730 if test "$enable_datacenter" = "yes" ; then
 731   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 732   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 733   DFLT_NAME="datacenter"
 734 else
 735   DFLT_NAME="traditional"
 736 fi
 737
 738 if test "$enable_cumulus" = "yes" ; then
 739   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 740 fi
 741
 742 AC_SUBST([DFLT_NAME])
 743 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 744
 745 if test "$enable_shell_access" = "yes"; then
 746    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 747 fi
 748
 749 #
 750 # Python for clippy
 751 #
 752
 753 AS_IF([test "$host" = "$build"], [
 754   FRR_PYTHON_DEV
 755 ], [
 756   FRR_PYTHON
 757 ])
 758
 759 FRR_PYTHON_MODULES([pytest])
 760
 761 if test "$enable_doc" != "no"; then
 762   FRR_PYTHON_MODULES([sphinx], , [
 763     if test "$enable_doc" = "yes"; then
 764       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 765     fi
 766   ])
 767 fi
 768 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 769 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 770
 771 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 772   PYSPHINX="-m sphinx"
 773 ], [
 774   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 775 ])
 776 AC_SUBST([PYSPHINX])
 777
 778 #
 779 # Logic for old vpn commands support.
 780 #
 781 if test "$enable_oldvpn_commands" = "yes"; then
 782    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 783 fi
 784
 785 #
 786 # End of logic for protobuf support.
 787 #
 788
 789 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 790 if test "$enable_rtadv" != "no"; then
 791   AC_MSG_RESULT([yes])
 792   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 793 else
 794   AC_MSG_RESULT([no])
 795 fi
 796
 797 if test "$enable_user" = "no"; then
 798   enable_user=""
 799 else
 800   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 801     enable_user="frr"
 802   fi
 803   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 804 fi
 805
 806 if test "$enable_group" = "no"; then
 807   enable_group=""
 808 else
 809   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 810     enable_group="frr"
 811   fi
 812   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 813 fi
 814
 815 if test "$enable_vty_group" = "yes" ; then
 816   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 817 elif test "$enable_vty_group" != ""; then
 818   if test "$enable_vty_group" != "no"; then
 819     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 820   fi
 821 fi
 822 AC_SUBST([enable_user])
 823 AC_SUBST([enable_group])
 824 AC_SUBST([enable_vty_group])
 825
 826 enable_configfile_mask=${enable_configfile_mask:-0600}
 827 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 828 AC_SUBST([enable_configfile_mask])
 829
 830 enable_logfile_mask=${enable_logfile_mask:-0600}
 831 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 832
 833 MPATH_NUM=16
 834
 835 case "${enable_multipath}" in
 836   0)
 837     MPATH_NUM=64
 838     ;;
 839   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 840     MPATH_NUM="${enable_multipath}"
 841     ;;
 842   "")
 843     ;;
 844   *)
 845     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 846     ;;
 847 esac
 848
 849 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 850
 851 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 852
 853 dnl --------------------
 854 dnl Enable code coverage
 855 dnl --------------------
 856 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 857
 858 dnl ------------------------------------
 859 dnl Alpine only accepts numeric versions
 860 dnl ------------------------------------
 861 if test "$enable_numeric_version" != "" ; then
 862   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 863   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 864 fi
 865
 866 dnl -----------------------------------
 867 dnl Add extra version string to package
 868 dnl name, string and version fields.
 869 dnl -----------------------------------
 870 if test "$EXTRAVERSION" != "" ; then
 871   VERSION="${VERSION}${EXTRAVERSION}"
 872   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 873   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 874   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 875 fi
 876 AC_SUBST([EXTRAVERSION])
 877
 878 if test "$with_pkg_git_version" = "yes"; then
 879         if test -e "${srcdir}/.git"; then
 880                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 881         else    with_pkg_git_version="no"
 882                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 883         fi
 884 fi
 885 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 886
 887 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 888 if test "$OBJCOPY" != ":"; then
 889   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 890     frr_cv_interp=""
 891     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 892       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 893         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 894       fi
 895       test -f conftest.interp && rm conftest.interp
 896     ])
 897   ])
 898 fi
 899 if test -n "$frr_cv_interp"; then
 900   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 901 fi
 902
 903 dnl -------------------------
 904 dnl Check other header files.
 905 dnl -------------------------
 906 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 907         linux/version.h asm/types.h])
 908
 909 ac_stdatomic_ok=false
 910 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 911 AC_CHECK_HEADER([stdatomic.h],[
 912
 913   AC_MSG_CHECKING([whether _Atomic qualifier works])
 914   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 915 #include <stdatomic.h>
 916 int main(int argc, char **argv) {
 917   _Atomic int i = 0;
 918   return i;
 919 }
 920 ]])], [
 921     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 922     AC_MSG_RESULT([yes])
 923     ac_stdatomic_ok=true
 924   ], [
 925     AC_MSG_RESULT([no])
 926   ])
 927 ])
 928
 929 AS_IF([$ac_stdatomic_ok], [true], [
 930   AC_MSG_CHECKING([for __atomic_* builtins])
 931   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 932 int main(int argc, char **argv) {
 933   volatile int i = 1;
 934   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 935   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 936 }
 937 ]])], [
 938     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 939     AC_MSG_RESULT([yes])
 940   ], [
 941     AC_MSG_RESULT([no])
 942
 943     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 944     AC_MSG_CHECKING([for __sync_* builtins])
 945     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 946 int main(int argc, char **argv) {
 947   volatile int i = 1;
 948   __sync_fetch_and_sub (&i, 1);
 949   return __sync_val_compare_and_swap (&i, 0, 1);
 950 }
 951 ]])], [
 952       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 953       AC_MSG_RESULT([yes])
 954
 955       AC_MSG_CHECKING([for __sync_swap builtin])
 956       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 957 int main(int argc, char **argv) {
 958   volatile int i = 1;
 959   return __sync_swap (&i, 2);
 960 }
 961 ]])], [
 962         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 963         AC_MSG_RESULT([yes])
 964       ], [
 965         AC_MSG_RESULT([no])
 966       ])
 967
 968     ], [
 969       AC_MSG_RESULT([no])
 970       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 971     ])
 972   ])
 973 ])
 974
 975 AC_CHECK_HEADERS([pthread_np.h],,, [
 976 #include <pthread.h>
 977 ])
 978 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 979
 980 needsync=true
 981
 982 AS_IF([$needsync], [
 983   dnl Linux
 984   AC_MSG_CHECKING([for Linux futex() support])
 985   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 986 #ifndef _GNU_SOURCE
 987 #define _GNU_SOURCE
 988 #endif
 989 #include <unistd.h>
 990 #include <limits.h>
 991 #include <sys/time.h>
 992 #include <sys/syscall.h>
 993 #include <linux/futex.h>
 994
 995 int main(void);
 996 ],
 997 [
 998 {
 999   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1000 }
1001 ])], [
1002     AC_MSG_RESULT([yes])
1003     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1004     needsync=false
1005   ], [
1006     AC_MSG_RESULT([no])
1007   ])
1008 ])
1009
1010 AS_IF([$needsync], [
1011   dnl FreeBSD
1012   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1013   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1014 #include <errno.h>
1015 #include <stdlib.h>
1016 #include <sys/types.h>
1017 #include <sys/umtx.h>
1018 int main(void);
1019 ],
1020 [
1021 {
1022   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1023 }
1024 ])], [
1025     AC_MSG_RESULT([yes])
1026     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1027     needsync=false
1028   ], [
1029     AC_MSG_RESULT([no])
1030   ])
1031 ])
1032
1033 AS_IF([$needsync], [
1034   dnl OpenBSD patch (not upstream at the time of writing this)
1035   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1036   AC_MSG_CHECKING([for OpenBSD futex() support])
1037   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1038 #include <sys/futex.h>
1039 int main(void);
1040 ],
1041 [
1042 {
1043   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1044 }
1045 ])], [
1046     AC_MSG_RESULT([yes])
1047     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1048     needsync=false
1049   ], [
1050     AC_MSG_RESULT([no])
1051   ])
1052 ])
1053
1054 dnl Utility macro to avoid retyping includes all the time
1055 m4_define([FRR_INCLUDES],
1056 [#ifdef SUNOS_5
1057 #define _POSIX_C_SOURCE 200809L
1058 #define __EXTENSIONS__
1059 #endif
1060 #include <stdio.h>
1061 #include <stdlib.h>
1062 #include <stddef.h>
1063 #include <sys/types.h>
1064 /* sys/conf.h depends on param.h on FBSD at least */
1065 #include <sys/param.h>
1066 /* Required for MAXSIG */
1067 #include <signal.h>
1068 #include <sys/socket.h>
1069 #ifdef __APPLE__
1070 # define __APPLE_USE_RFC_3542
1071 #endif
1072 #include <netinet/in.h>
1073 #include <sys/time.h>
1074 #include <time.h>
1075 #include <net/if.h>
1076 ])dnl
1077
1078 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1079 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1080 dnl an additional round for it.
1081
1082 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1083
1084 m4_define([FRR_INCLUDES],
1085 FRR_INCLUDES
1086 [#ifdef HAVE_NET_IF_VAR_H
1087 # include <net/if_var.h>
1088 #endif
1089 ])dnl
1090
1091 AC_CHECK_HEADERS([netinet/in_var.h \
1092         net/if_dl.h net/netopt.h \
1093         inet/nd.h netinet/ip_icmp.h \
1094         sys/sysctl.h sys/sockio.h sys/conf.h],
1095         [], [], [FRR_INCLUDES])
1096
1097 AC_CHECK_HEADERS([ucontext.h], [], [],
1098 [#ifndef __USE_GNU
1099 #define __USE_GNU
1100 #endif /* __USE_GNU */
1101 FRR_INCLUDES
1102 ])
1103
1104 m4_define([UCONTEXT_INCLUDES],
1105 [#include <ucontext.h>])dnl
1106
1107 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1108   [], [], [UCONTEXT_INCLUDES])
1109 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1110   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1111    [], [], [UCONTEXT_INCLUDES])],
1112   [], [UCONTEXT_INCLUDES])
1113 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1114   [], [], [UCONTEXT_INCLUDES])
1115
1116 m4_define([FRR_INCLUDES],
1117 FRR_INCLUDES
1118 [
1119 #include <sys/un.h>
1120 #include <netinet/in_systm.h>
1121 #ifdef HAVE_NETINET_IN_VAR_H
1122 # include <netinet/in_var.h>
1123 #endif
1124 #ifdef HAVE_NET_IF_DL_H
1125 # include <net/if_dl.h>
1126 #endif
1127 #ifdef HAVE_NET_NETOPT_H
1128 # include <net/netopt.h>
1129 #endif
1130 #include <net/route.h>
1131 #ifdef HAVE_INET_ND_H
1132 # include <inet/nd.h>
1133 #endif
1134 #include <arpa/inet.h>
1135 /* Required for IDRP */
1136 #ifdef HAVE_NETINET_IP_ICMP_H
1137 # include <netinet/ip_icmp.h>
1138 #endif
1139 ])dnl
1140
1141 dnl V6 headers are checked below, after we check for v6
1142
1143 is_linux=false
1144
1145 AC_MSG_CHECKING([which operating system interface to use])
1146 case "$host_os" in
1147   sunos* | solaris2*)
1148     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1149     ;;
1150   linux*)
1151     AC_MSG_RESULT([Linux])
1152
1153     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1154     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1155     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1156
1157     dnl Linux has a compilation problem with mixing
1158     dnl netinet/in.h and linux/in6.h they are not
1159     dnl compatible.  There has been discussion on
1160     dnl how to fix it but no real progress on implementation
1161     dnl when they fix it, remove this
1162     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1163
1164     is_linux=true
1165     ;;
1166   openbsd*)
1167     AC_MSG_RESULT([OpenBSD])
1168
1169     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1170     AC_DEFINE([KAME], [1], [KAME IPv6])
1171     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1172     ;;
1173   *)
1174     AC_MSG_RESULT([BSD])
1175
1176     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1177     AC_DEFINE([KAME], [1], [KAME IPv6])
1178     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1179     ;;
1180 esac
1181 AM_CONDITIONAL([LINUX], [${is_linux}])
1182
1183 AC_SYS_LARGEFILE
1184
1185 dnl ------------------------
1186 dnl Integrated REALMS option
1187 dnl ------------------------
1188 if test "$enable_realms" = "yes"; then
1189     case "$host_os" in
1190       linux*)
1191        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1192        ;;
1193       *)
1194        echo "Sorry, only Linux has REALMS support"
1195        exit 1
1196        ;;
1197     esac
1198 fi
1199
1200 dnl -------------------------------
1201 dnl Endian-ness check
1202 dnl -------------------------------
1203 AC_WORDS_BIGENDIAN
1204
1205 dnl ---------------
1206 dnl other functions
1207 dnl ---------------
1208 AC_CHECK_FUNCS([ \
1209         strlcat strlcpy \
1210         getgrouplist \
1211         openat \
1212         unlinkat \
1213         posix_fallocate \
1214         ])
1215
1216 dnl ##########################################################################
1217 dnl LARGE if block spans a lot of "configure"!
1218 if test "$enable_clippy_only" != "yes"; then
1219 dnl ##########################################################################
1220
1221 #
1222 # Logic for protobuf support.
1223 #
1224 PROTO3=false
1225 if test "$enable_protobuf" = "yes"; then
1226   # Check for protoc & protoc-c
1227
1228   # protoc is not required, it's only for a "be nice" helper target
1229   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1230
1231   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1232   if test "$PROTOC_C" = "/bin/false"; then
1233     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1234   fi
1235
1236   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1237     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1238   ])
1239
1240   PROTO3=true
1241   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1242                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1243                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1244                                             [1], [Have Protobuf version 3]),
1245                                   [PROTO3=false],
1246                                   [#include <google/protobuf-c/protobuf-c.h>])],
1247                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1248
1249   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1250 fi
1251
1252
1253 dnl ---------------------
1254 dnl Integrated VTY option
1255 dnl ---------------------
1256 case "${enable_vtysh}" in
1257 "no")
1258   VTYSH="";;
1259 *)
1260   VTYSH="vtysh";
1261   AC_DEFINE([VTYSH], [1], [VTY shell])
1262
1263   prev_libs="$LIBS"
1264   AC_CHECK_LIB([readline], [main], [
1265     LIBREADLINE="-lreadline"
1266   ], [
1267     dnl readline failed - it might be incorrectly linked and missing its
1268     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1269     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1270       LIBREADLINE="$ac_cv_search_tputs"
1271     ], [
1272       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1273     ])
1274
1275     dnl re-try with the lib we found above
1276     unset ac_cv_lib_readline_main
1277     AC_CHECK_LIB([readline], [main], [
1278       LIBREADLINE="-lreadline $LIBREADLINE"
1279     ], [
1280       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1281     ], [$LIBREADLINE])
1282   ], [])
1283   LIBS="$prev_libs"
1284
1285   AC_CHECK_HEADER([readline/history.h])
1286   if test "$ac_cv_header_readline_history_h" = "no"; then
1287     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1288   fi
1289   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1290   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1291     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1292   fi
1293   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1294   if test "$frr_cv_append_history" = "yes"; then
1295     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1296   fi
1297   ;;
1298 esac
1299 AC_SUBST([LIBREADLINE])
1300
1301 dnl ----------
1302 dnl PAM module
1303 dnl
1304 dnl FRR detects the PAM library it is built against by checking for a
1305 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1306 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1307 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1308 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1309 dnl of OpenPAM.
1310 dnl ----------
1311 if test "$with_libpam" = "yes"; then
1312   AC_CHECK_HEADER([security/pam_misc.h],
1313     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1314      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1315      pam_conv_func="misc_conv"
1316     ],
1317     [], FRR_INCLUDES)
1318   AC_CHECK_HEADER([security/openpam.h],
1319     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1320      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1321      pam_conv_func="openpam_ttyconv"
1322     ],
1323     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1324   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1325     AC_MSG_WARN([*** pam support will not be built ***])
1326     with_libpam="no"
1327   fi
1328 fi
1329
1330 if test "$with_libpam" = "yes"; then
1331 dnl took this test from proftpds configure.in and suited to our needs
1332 dnl -------------------------------------------------------------------------
1333 dnl
1334 dnl This next check looks funky due to a linker problem with some versions
1335 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1336 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1337 dnl with RedHat 6.2 and Debian 2.2 or better.
1338 AC_CHECK_LIB([pam], [pam_start],
1339   [AC_CHECK_LIB([pam], [$pam_conv_func],
1340     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1341      LIBPAM="-lpam"],
1342     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1343      LIBPAM="-lpam -lpam_misc"]
1344     )
1345   ],
1346
1347   [AC_CHECK_LIB([pam], [pam_end],
1348     [AC_CHECK_LIB([pam], [$pam_conv_func],
1349       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1350        LIBPAM="-lpam -ldl"],
1351       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1352        LIBPAM="-lpam -ldl -lpam_misc"]
1353      )
1354   ],AC_MSG_WARN([*** pam support will not be built ***]),
1355   [-ldl])
1356   ]
1357 )
1358 fi
1359 AC_SUBST([LIBPAM])
1360
1361 dnl -------------------------------
1362 dnl bgpd needs pow() and hence libm
1363 dnl -------------------------------
1364 TMPLIBS="$LIBS"
1365 LIBS=""
1366 AC_SEARCH_LIBS([pow], [m], [
1367   LIBM="$LIBS"
1368 ], [
1369   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1370 ])
1371 LIBS="$TMPLIBS"
1372 AC_SUBST([LIBM])
1373
1374 AC_CHECK_FUNCS([ppoll], [
1375   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1376 ])
1377 AC_CHECK_FUNCS([pollts], [
1378   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1379 ])
1380
1381 AC_CHECK_HEADER([asm-generic/unistd.h],
1382                 [AC_CHECK_DECL(__NR_setns,
1383                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1384                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1385                                ])
1386                  AC_CHECK_FUNCS([setns])]
1387                )
1388
1389 dnl --------------------------
1390 dnl Determine IS-IS I/O method
1391 dnl --------------------------
1392 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1393 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1394 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1395 AC_CHECK_HEADER([net/bpf.h])
1396 AC_CHECK_HEADER([sys/dlpi.h])
1397 AC_MSG_CHECKING([zebra IS-IS I/O method])
1398
1399 case "$host_os" in
1400   linux*)
1401     AC_MSG_RESULT([pfpacket])
1402     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1403     ;;
1404   *)
1405     if test "$ac_cv_header_net_bpf_h" = "no"; then
1406       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1407         AC_MSG_RESULT([none])
1408         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1409           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1410         fi
1411         AC_MSG_WARN([*** IS-IS support will not be built ***])
1412         enable_isisd="no"
1413         enable_fabricd="no"
1414       else
1415         AC_MSG_RESULT([DLPI])
1416       fi
1417       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1418     else
1419       AC_MSG_RESULT([BPF])
1420       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1421     fi
1422     ;;
1423 esac
1424 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1425
1426 dnl ---------------------------------------------------------------
1427 dnl figure out how to specify an interface in multicast sockets API
1428 dnl ---------------------------------------------------------------
1429 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1430
1431 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1432         #include <sys/socket.h>
1433         #include <netinet/in.h>
1434         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1435         #include <linux/types.h>
1436 ])
1437
1438 m4_define([FRR_INCLUDES],
1439 FRR_INCLUDES
1440 [#ifdef HAVE_LINUX_MROUTE_H
1441 # include <linux/mroute.h>
1442 #endif
1443 ])dnl
1444
1445 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1446         #include <sys/socket.h>
1447         #include <sys/types.h>
1448         #include <netinet/in.h>
1449         #include <net/route.h>
1450 ])
1451
1452 m4_define([FRR_INCLUDES],
1453 FRR_INCLUDES
1454 [#ifdef HAVE_NETINET_IP_MROUTE_H
1455 # include <netinet/ip_mroute.h>
1456 #endif
1457 ])dnl
1458
1459 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1460 AC_TRY_COMPILE([#include <sys/param.h>],
1461 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1462   return (0);
1463 #else
1464   #error No support for BSD struct ip_mreq hack detected
1465 #endif],[AC_MSG_RESULT([yes])
1466 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1467 AC_MSG_RESULT([no]))
1468
1469 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1470 AC_TRY_COMPILE([
1471 #include <sys/types.h>
1472 #include <netinet/in.h>
1473 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1474 ], [AC_MSG_RESULT([yes])
1475 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1476 AC_MSG_RESULT([no]))
1477
1478 dnl ---------------------------------------------------------------
1479 dnl figure out how to check link-state
1480 dnl ---------------------------------------------------------------
1481 AC_CHECK_HEADER([net/if_media.h],
1482   [m4_define([LINK_DETECT_INCLUDES],
1483     FRR_INCLUDES
1484     [#include <net/if_media.h>
1485   ])
1486   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1487     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1488     [], LINK_DETECT_INCLUDES)],
1489   [],
1490   FRR_INCLUDES)
1491
1492 dnl ---------------------------------------------------------------
1493 dnl Additional, newer way to check link-state using ifi_link_state.
1494 dnl Not available in all BSD's when ifmediareq available
1495 dnl ---------------------------------------------------------------
1496 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1497   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1498   [], FRR_INCLUDES)
1499
1500 dnl ------------------------
1501 dnl TCP_MD5SIG socket option
1502 dnl ------------------------
1503
1504 AC_CHECK_HEADER([netinet/tcp.h],
1505    [m4_define([MD5_INCLUDES],
1506       FRR_INCLUDES
1507       [#include <netinet/tcp.h>
1508     ])
1509     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1510    [],
1511    FRR_INCLUDES)
1512 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1513   AC_CHECK_HEADER([linux/tcp.h],
1514        [m4_define([MD5_INCLUDES],
1515           FRR_INCLUDES
1516           [#include <linux/tcp.h>
1517         ])
1518        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1519 fi
1520
1521 AC_CHECK_LIB([crypt], [crypt], [],
1522                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1523 AC_CHECK_LIB([resolv], [res_init])
1524
1525 dnl ---------------------------
1526 dnl check system has PCRE regexp
1527 dnl ---------------------------
1528 if test "$enable_pcreposix" = "yes"; then
1529   AC_CHECK_LIB([pcreposix], [regexec], [], [
1530     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1531   ])
1532 fi
1533 AC_SUBST([HAVE_LIBPCREPOSIX])
1534
1535 dnl ##########################################################################
1536 dnl test "$enable_clippy_only" != "yes"
1537 fi
1538 dnl END OF LARGE if block
1539 dnl ##########################################################################
1540
1541 dnl ------------------
1542 dnl check C-Ares library
1543 dnl ------------------
1544 PKG_CHECK_MODULES([CARES], [libcares], [
1545   c_ares_found=true
1546 ],[
1547   c_ares_found=false
1548 ])
1549 AM_CONDITIONAL([CARES], [$c_ares_found])
1550
1551
1552 dnl ----------------------------------------------------------------------------
1553 dnl figure out if domainname is available in the utsname struct (GNU extension).
1554 dnl ----------------------------------------------------------------------------
1555 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1556
1557 dnl ------------------
1558 dnl IPv6 header checks
1559 dnl ------------------
1560 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1561         netinet6/in6_var.h netinet6/nd6.h], [], [],
1562         FRR_INCLUDES)
1563
1564 m4_define([FRR_INCLUDES],dnl
1565 FRR_INCLUDES
1566 [#ifdef HAVE_NETINET6_IN6_H
1567 #include <netinet6/in6.h>
1568 #endif
1569 #ifdef HAVE_NETINET_IN6_VAR_H
1570 #include <netinet/in6_var.h>
1571 #endif
1572 #include <netinet/icmp6.h>
1573 #ifdef HAVE_NETINET6_IN6_VAR_H
1574 # include <netinet6/in6_var.h>
1575 #endif
1576 #ifdef HAVE_NETINET6_ND6_H
1577 # include <netinet6/nd6.h>
1578 #endif
1579 ])dnl
1580
1581 dnl --------------------
1582 dnl Daemon disable check
1583 dnl --------------------
1584
1585 AS_IF([test "$enable_bgpd" != "no"], [
1586   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1587 ])
1588
1589 AS_IF([test "$enable_ripd" != "no"], [
1590   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1591 ])
1592
1593 AS_IF([test "$enable_ripngd" != "no"], [
1594   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1595 ])
1596
1597 AS_IF([test "$enable_ospfd" != "no"], [
1598   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1599 ])
1600
1601 AS_IF([test "$enable_ospf6d" != "no"], [
1602   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1603 ])
1604
1605 AS_IF([test "$enable_ldpd" != "no"], [
1606   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1607 ])
1608
1609 AS_IF([test "$enable_nhrpd" != "no"], [
1610   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1611 ])
1612
1613 AS_IF([test "$enable_eigrpd" != "no"], [
1614   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1615 ])
1616
1617 AS_IF([test "$enable_babeld" != "no"], [
1618   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1619 ])
1620
1621 AS_IF([test "$enable_isisd" != "no"], [
1622   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1623 ])
1624
1625 AS_IF([test "$enable_pimd" != "no"], [
1626   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1627 ])
1628
1629 AS_IF([test "$enable_pbrd" != "no"], [
1630   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1631 ])
1632
1633 AS_IF([test "$enable_sharpd" = "yes"], [
1634   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1635 ])
1636
1637 AS_IF([test "$enable_staticd" != "no"], [
1638   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1639 ])
1640
1641 AS_IF([test "$enable_fabricd" != "no"], [
1642   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1643 ])
1644
1645 AS_IF([test "$enable_vrrpd" != "no"], [
1646   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1647 ])
1648
1649 if test "$enable_bfdd" = "no"; then
1650   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1651   BFDD=""
1652 else
1653   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1654   BFDD="bfdd"
1655
1656   case $host_os in
1657     linux*)
1658       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1659       ;;
1660
1661     *)
1662       AC_DEFINE([BFD_BSD], [1], [bfdd])
1663       ;;
1664   esac
1665 fi
1666
1667 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1668   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1669 fi
1670
1671 NHRPD=""
1672 case "$host_os" in
1673   linux*)
1674     case "${enable_nhrpd}" in
1675       no)
1676         ;;
1677       yes)
1678         if test "$enable_clippy_only" != "yes"; then
1679         if test "$c_ares_found" != "true" ; then
1680           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1681         fi
1682         fi
1683         NHRPD="nhrpd"
1684         ;;
1685       *)
1686         if test "$c_ares_found" = "true" ; then
1687           NHRPD="nhrpd"
1688         fi
1689         ;;
1690     esac
1691     ;;
1692   *)
1693     if test "$enable_nhrpd" = "yes"; then
1694       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1695     fi
1696     ;;
1697 esac
1698
1699 if test "$enable_watchfrr" = "no";then
1700   WATCHFRR=""
1701 else
1702   WATCHFRR="watchfrr"
1703 fi
1704
1705 OSPFCLIENT=""
1706 if test "$enable_ospfapi" != "no";then
1707     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1708
1709   if test "$enable_ospfclient" != "no";then
1710       OSPFCLIENT="ospfclient"
1711   fi
1712 fi
1713
1714 if test "$enable_bgp_announce" = "no";then
1715   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1716 else
1717   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1718 fi
1719
1720 if test "$enable_bgp_vnc" != "no";then
1721   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1722 fi
1723
1724 bgpd_bmp=false
1725 case "${enable_bmp}" in
1726   no)
1727     ;;
1728   yes)
1729     if test "$c_ares_found" != "true" ; then
1730       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1731     fi
1732     bgpd_bmp=true
1733     ;;
1734   *)
1735     if test "$c_ares_found" = "true" ; then
1736       bgpd_bmp=true
1737     fi
1738     ;;
1739 esac
1740
1741 if test "$enable_version_build_config" != "no";then
1742   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1743 fi
1744
1745 dnl ##########################################################################
1746 dnl LARGE if block
1747 if test "$enable_clippy_only" != "yes"; then
1748 dnl ##########################################################################
1749
1750 dnl ------------------
1751 dnl check Net-SNMP library
1752 dnl ------------------
1753 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1754    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1755    if test "$NETSNMP_CONFIG" = "no"; then
1756       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1757    fi
1758    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1759    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1760    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1761    # among other things we avoid a GPL vs. OpenSSL license conflict here
1762    for removelib in crypto ssl sensors pci wrap; do
1763      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1764    done
1765    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1766    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1767 int main(void);
1768 ],
1769 [
1770 {
1771   return 0;
1772 }
1773 ])], [
1774      AC_MSG_RESULT([no])
1775      AC_MSG_ERROR([--enable-snmp given but not usable])])
1776    case "${enable_snmp}" in
1777      yes)
1778       SNMP_METHOD=agentx
1779       ;;
1780      agentx)
1781       SNMP_METHOD="${enable_snmp}"
1782       ;;
1783      *)
1784       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1785       ;;
1786    esac
1787    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1788    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1789 fi
1790 AC_SUBST([SNMP_LIBS])
1791 AC_SUBST([SNMP_CFLAGS])
1792
1793 dnl ---------------
1794 dnl libyang
1795 dnl ---------------
1796 PKG_CHECK_MODULES([LIBYANG], [libyang >= 1.0.184], , [
1797   AC_MSG_ERROR([libyang (>= 1.0.184) was not found on your system.])
1798 ])
1799 ac_cflags_save="$CFLAGS"
1800 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1801 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1802   AC_MSG_ERROR([m4_normalize([
1803     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1804     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1805   ])
1806 ], [[#include <libyang/libyang.h>]])
1807 CFLAGS="$ac_cflags_save"
1808
1809 dnl ---------------
1810 dnl configuration rollbacks
1811 dnl ---------------
1812 SQLITE3=false
1813 if test "$enable_config_rollbacks" = "yes"; then
1814   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1815     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1816     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1817     SQLITE3=true
1818   ], [
1819     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1820   ])
1821 fi
1822
1823 dnl ---------------
1824 dnl confd
1825 dnl ---------------
1826 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1827    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1828    if test "$CONFD" = "/bin/false"; then
1829       AC_MSG_ERROR([confd was not found on your system.])]
1830    fi
1831    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1832    AC_SUBST([CONFD_CFLAGS])
1833    CONFD_LIBS="-lconfd"
1834    AC_SUBST([CONFD_LIBS])
1835    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1836 fi
1837
1838 dnl ---------------
1839 dnl sysrepo
1840 dnl ---------------
1841 if test "$enable_sysrepo" = "yes"; then
1842   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1843       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1844       SYSREPO=true],
1845       [SYSREPO=false
1846       AC_MSG_ERROR([sysrepo was not found on your system.])]
1847   )
1848 fi
1849
1850 dnl ---------------
1851 dnl gRPC
1852 dnl ---------------
1853 if test "$enable_grpc" = "yes"; then
1854   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1855     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1856     if test "$PROTOC" = "/bin/false"; then
1857       AC_MSG_FAILURE([grpc requested but protoc not found.])
1858     fi
1859
1860     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1861     GRPC=true
1862   ], [
1863     GRPC=false
1864     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1865   ])
1866 fi
1867
1868 dnl -----
1869 dnl LTTng
1870 dnl -----
1871 if test "$enable_lttng" = "yes"; then
1872   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.12.0], [
1873     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1874     LTTNG=true
1875   ], [
1876     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1877   ])
1878 fi
1879
1880 dnl ----
1881 dnl USDT
1882 dnl ----
1883 if test "$enable_usdt" = "yes"; then
1884   AC_CHECK_HEADERS([sys/sdt.h], [
1885     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1886     USDT=true
1887   ], [
1888     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1889   ])
1890 fi
1891
1892 dnl ------
1893 dnl ZeroMQ
1894 dnl ------
1895 if test "$enable_zeromq" != "no"; then
1896   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1897     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1898     ZEROMQ=true
1899   ], [
1900     if test "$enable_zeromq" = "yes"; then
1901       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1902     fi
1903   ])
1904 fi
1905
1906 dnl ------------------------------------
1907 dnl Enable RPKI and add librtr to libs
1908 dnl ------------------------------------
1909 if test "$enable_rpki" = "yes"; then
1910   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1911       [RPKI=true],
1912       [RPKI=false
1913       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1914   )
1915 fi
1916
1917 dnl ------------------------------------
1918 dnl pimd is not supported on OpenBSD and MacOS
1919 dnl ------------------------------------
1920 if test "$enable_pimd" != "no"; then
1921 AC_MSG_CHECKING([for pimd OS support])
1922 case "$host_os" in
1923   darwin*)
1924     AC_MSG_RESULT([no])
1925     enable_pimd="no"
1926     ;;
1927   openbsd*)
1928     AC_MSG_RESULT([no])
1929     enable_pimd="no"
1930     ;;
1931   *)
1932     AC_MSG_RESULT([yes])
1933     ;;
1934 esac
1935 fi
1936
1937 dnl -------------------------------------
1938 dnl VRRP is only supported on linux
1939 dnl -------------------------------------
1940 if test "$enable_vrrpd" != "no"; then
1941 AC_MSG_CHECKING([for VRRP OS support])
1942 case "$host_os" in
1943   linux*)
1944     AC_MSG_RESULT([yes])
1945     ;;
1946   *)
1947     AC_MSG_RESULT([no])
1948     enable_vrrpd="no"
1949     ;;
1950 esac
1951 fi
1952
1953 dnl ------------------------------------------
1954 dnl Check whether rtrlib was build with ssh support
1955 dnl ------------------------------------------
1956 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1957 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1958                         [[struct tr_ssh_config config;]])],
1959         [AC_MSG_RESULT([yes])
1960         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1961         AC_MSG_RESULT([no])
1962 )
1963
1964 dnl ---------------
1965 dnl dlopen & dlinfo
1966 dnl ---------------
1967 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1968   AC_MSG_ERROR([unable to find the dlopen()])
1969 ])
1970
1971 AC_CHECK_HEADERS([link.h])
1972
1973 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1974   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1975 #include <stdlib.h>
1976 #ifdef HAVE_LINK_H
1977 #include <link.h>
1978 #endif
1979 #include <dlfcn.h>
1980 ]], [[
1981   char origin[1];
1982   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1983 ]])], [
1984     frr_cv_rtld_di_origin=yes
1985   ], [
1986     frr_cv_rtld_di_origin=no
1987   ])
1988 ])
1989 if test "$frr_cv_rtld_di_origin" = "yes"; then
1990   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1991 fi
1992
1993 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1994   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1995 #include <stdlib.h>
1996 #ifdef HAVE_LINK_H
1997 #include <link.h>
1998 #endif
1999 #include <dlfcn.h>
2000 ]], [[
2001   struct link_map *lm = NULL;
2002   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2003 ]])], [
2004     frr_cv_rtld_di_linkmap=yes
2005   ], [
2006     frr_cv_rtld_di_linkmap=no
2007   ])
2008 ])
2009 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2010   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2011 fi
2012
2013 dnl ##########################################################################
2014 dnl test "$enable_clippy_only" != "yes"
2015 fi
2016 dnl END OF LARGE if block
2017 dnl ##########################################################################
2018
2019 dnl ---------------------------
2020 dnl sockaddr and netinet checks
2021 dnl ---------------------------
2022 AC_CHECK_TYPES([
2023         struct sockaddr_dl,
2024         struct vifctl, struct mfcctl, struct sioc_sg_req,
2025         vifi_t, struct sioc_vif_req, struct igmpmsg,
2026         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2027         struct nd_opt_adv_interval,
2028         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2029         struct nd_opt_rdnss, struct nd_opt_dnssl],
2030         [], [], FRR_INCLUDES)
2031
2032 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2033         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2034         struct sockaddr_dl.sdl_len,
2035         struct if6_aliasreq.ifra_lifetime,
2036         struct nd_opt_adv_interval.nd_opt_ai_type],
2037         [], [], FRR_INCLUDES)
2038
2039 dnl ---------------------------
2040 dnl IRDP/pktinfo/icmphdr checks
2041 dnl ---------------------------
2042
2043 AC_CHECK_TYPES([struct in_pktinfo], [
2044   AC_CHECK_TYPES([struct icmphdr], [
2045     IRDP=true
2046   ], [
2047     IRDP=false
2048   ], [FRR_INCLUDES])
2049 ], [
2050   IRDP=false
2051 ], [FRR_INCLUDES])
2052
2053 case "${enable_irdp}" in
2054 yes)
2055   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2056   ;;
2057 no)
2058   IRDP=false
2059   ;;
2060 esac
2061
2062
2063 dnl -----------------------
2064 dnl checking for IP_PKTINFO
2065 dnl -----------------------
2066 AC_MSG_CHECKING([for IP_PKTINFO])
2067 AC_TRY_COMPILE([#include <netdb.h>], [
2068   int opt = IP_PKTINFO;
2069 ], [
2070   AC_MSG_RESULT([yes])
2071   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2072 ], [
2073   AC_MSG_RESULT([no])
2074 ])
2075
2076 dnl ---------------------------
2077 dnl checking for IP_RECVDSTADDR
2078 dnl ---------------------------
2079 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2080 AC_TRY_COMPILE([#include <netinet/in.h>], [
2081   int opt = IP_RECVDSTADDR;
2082 ], [
2083   AC_MSG_RESULT([yes])
2084   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2085 ], [
2086   AC_MSG_RESULT([no])
2087 ])
2088
2089 dnl ----------------------
2090 dnl checking for IP_RECVIF
2091 dnl ----------------------
2092 AC_MSG_CHECKING([for IP_RECVIF])
2093 AC_TRY_COMPILE([#include <netinet/in.h>], [
2094   int opt = IP_RECVIF;
2095 ], [
2096   AC_MSG_RESULT([yes])
2097   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2098 ], [
2099   AC_MSG_RESULT([no])
2100 ])
2101
2102 dnl ----------------------
2103 dnl checking for SO_BINDANY
2104 dnl ----------------------
2105 AC_MSG_CHECKING([for SO_BINDANY])
2106 AC_TRY_COMPILE([#include <sys/socket.h>], [
2107   int opt = SO_BINDANY;
2108 ], [
2109   AC_MSG_RESULT([yes])
2110   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2111 ], [
2112   AC_MSG_RESULT([no])
2113 ])
2114
2115 dnl ----------------------
2116 dnl checking for IP_FREEBIND
2117 dnl ----------------------
2118 AC_MSG_CHECKING([for IP_FREEBIND])
2119 AC_TRY_COMPILE([#include <netinet/in.h>], [
2120   int opt = IP_FREEBIND;
2121 ], [
2122   AC_MSG_RESULT([yes])
2123   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2124 ], [
2125   AC_MSG_RESULT([no])
2126 ])
2127
2128 dnl --------------------------------------
2129 dnl checking for be32dec existence or not
2130 dnl --------------------------------------
2131 AC_CHECK_DECLS([be32enc, be32dec], [], [],
2132                [#include <sys/endian.h>])
2133
2134 dnl --------------------------------------
2135 dnl checking for clock_time monotonic struct and call
2136 dnl --------------------------------------
2137 AC_CHECK_DECL([CLOCK_MONOTONIC],
2138         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2139          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2140 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2141
2142 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2143   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2144 ])
2145
2146 dnl --------------------------------------
2147 dnl checking for flex and bison
2148 dnl --------------------------------------
2149
2150 AM_PROG_LEX
2151 AC_MSG_CHECKING([version of flex])
2152 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2153 frr_ac_flex_version="${frr_ac_flex_version##* }"
2154 AC_MSG_RESULT([$frr_ac_flex_version])
2155 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2156   LEX="$SHELL $missing_dir/missing flex"
2157   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2158     AC_MSG_WARN([using pregenerated flex output files])
2159   else
2160     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2161   fi
2162   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2163   AC_SUBST([LEXLIB], [''])
2164 ])
2165
2166 AC_PROG_YACC
2167 dnl thanks GNU bison for this b*llshit...
2168 AC_MSG_CHECKING([version of bison])
2169 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2170 frr_ac_bison_version="${frr_ac_bison_version##* }"
2171 frr_ac_bison_missing="false"
2172 case "x${frr_ac_bison_version}x" in
2173   x2.7*)
2174     BISON_OPENBRACE='"'
2175     BISON_CLOSEBRACE='"'
2176     BISON_VERBOSE=''
2177     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2178     ;;
2179   x2.*|x1.*)
2180     AC_MSG_RESULT([$frr_ac_bison_version])
2181     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2182     frr_ac_bison_missing="true"
2183     ;;
2184   x)
2185     AC_MSG_RESULT([none])
2186     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2187     frr_ac_bison_missing="true"
2188     ;;
2189   x3.[012][^0-9]*)
2190     BISON_OPENBRACE='{'
2191     BISON_CLOSEBRACE='}'
2192     BISON_VERBOSE='-Dparse.error=verbose'
2193     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2194     ;;
2195   *)
2196     BISON_OPENBRACE='{'
2197     BISON_CLOSEBRACE='}'
2198     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2199     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2200     ;;
2201 esac
2202 AC_SUBST([BISON_OPENBRACE])
2203 AC_SUBST([BISON_CLOSEBRACE])
2204 AC_SUBST([BISON_VERBOSE])
2205
2206 if $frr_ac_bison_missing; then
2207   YACC="$SHELL $missing_dir/missing bison -y"
2208   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2209     AC_MSG_WARN([using pregenerated bison output files])
2210   else
2211     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2212   fi
2213 fi
2214
2215 dnl -------------------
2216 dnl capabilities checks
2217 dnl -------------------
2218 if test "$enable_capabilities" != "no"; then
2219   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2220   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2221     [AC_MSG_RESULT([yes])
2222      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2223      frr_ac_keepcaps="yes"],
2224      AC_MSG_RESULT([no])
2225   )
2226   if test "$frr_ac_keepcaps" = "yes"; then
2227     AC_CHECK_HEADERS([sys/capability.h])
2228   fi
2229   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2230     AC_CHECK_LIB([cap], [cap_init],
2231       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2232        LIBCAP="-lcap"
2233        frr_ac_lcaps="yes"]
2234     )
2235   fi
2236   if test "$frr_ac_scaps" = "yes" \
2237        -o "$frr_ac_lcaps" = "yes"; then
2238     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2239   fi
2240
2241   case "$host_os" in
2242   linux*)
2243     if test "$enable_clippy_only" != "yes"; then
2244     if test "$frr_ac_lcaps" != "yes"; then
2245       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2246     fi
2247     fi
2248     ;;
2249   esac
2250 else
2251   case "$host_os" in
2252   linux*)
2253     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2254     ;;
2255   esac
2256 fi
2257 AC_SUBST([LIBCAP])
2258
2259 dnl ---------------------------
2260 dnl check for glibc 'backtrace'
2261 dnl ---------------------------
2262 if test "$enable_backtrace" != "no" ; then
2263   backtrace_ok=no
2264   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2265     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2266     backtrace_ok=yes
2267   ], [
2268     true
2269   ])
2270
2271   if test "$backtrace_ok" = "no"; then
2272     AC_CHECK_HEADER([unwind.h], [
2273       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2274         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2275         backtrace_ok=yes
2276       ])
2277     ])
2278   fi
2279
2280   if test "$backtrace_ok" = "no"; then
2281     AC_CHECK_HEADER([execinfo.h], [
2282       AC_SEARCH_LIBS([backtrace], [execinfo], [
2283         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2284         backtrace_ok=yes
2285       ],, [-lm])
2286     ])
2287   fi
2288
2289   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2290     dnl user explicitly requested backtrace but we failed to find support
2291     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2292   fi
2293 fi
2294
2295 dnl -----------------------------------------
2296 dnl check for malloc mallinfo struct and call
2297 dnl this must try and link using LIBS, in
2298 dnl order to check no alternative allocator
2299 dnl has been specified, which might not provide
2300 dnl mallinfo
2301 dnl -----------------------------------------
2302 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2303
2304 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2305   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2306 #ifdef HAVE_MALLOC_H
2307 #include <malloc.h>
2308 #endif
2309 #ifdef HAVE_MALLOC_NP_H
2310 #include <malloc_np.h>
2311 #endif
2312 #ifdef HAVE_MALLOC_MALLOC_H
2313 #include <malloc/malloc.h>
2314 #endif
2315 ]], [[
2316 struct mallinfo ac_x; ac_x = mallinfo ();
2317 ]])], [
2318     frr_cv_mallinfo=yes
2319   ], [
2320     frr_cv_mallinfo=no
2321   ])
2322 ])
2323 if test "$frr_cv_mallinfo" = "yes"; then
2324   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2325 fi
2326
2327 AC_MSG_CHECKING([whether malloc_usable_size is available])
2328 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2329 #ifdef HAVE_MALLOC_H
2330 #include <malloc.h>
2331 #endif
2332 #ifdef HAVE_MALLOC_MALLOC_H
2333 #include <malloc/malloc.h>
2334 #endif
2335 ]], [[
2336 size_t ac_x; ac_x = malloc_usable_size(NULL);
2337 ]])], [
2338   AC_MSG_RESULT([yes])
2339   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2340 ], [
2341   AC_MSG_RESULT([no])
2342
2343   AC_MSG_CHECKING([whether malloc_size is available])
2344   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2345 #ifdef HAVE_MALLOC_H
2346 #include <malloc.h>
2347 #endif
2348 #ifdef HAVE_MALLOC_MALLOC_H
2349 #include <malloc/malloc.h>
2350 #endif
2351 ]], [[
2352 size_t ac_x; ac_x = malloc_size(NULL);
2353 ]])], [
2354     AC_MSG_RESULT([yes])
2355     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2356   ], [
2357     AC_MSG_RESULT([no])
2358   ])
2359 ])
2360
2361 dnl ----------
2362 dnl configure date
2363 dnl ----------
2364 dev_version=`echo $VERSION | grep dev`
2365 #don't expire deprecated code in non 'dev' branch
2366 if test "$dev_version" = ""; then
2367    CONFDATE=0
2368 else
2369    CONFDATE=`date '+%Y%m%d'`
2370 fi
2371 AC_SUBST([CONFDATE])
2372
2373 dnl ------------------------------
2374 dnl set paths for state directory
2375 dnl ------------------------------
2376 AC_MSG_CHECKING([directory to use for state file])
2377 if test "$prefix" = "NONE"; then
2378   frr_statedir_prefix="";
2379 else
2380   frr_statedir_prefix=${prefix}
2381 fi
2382 if test "$localstatedir" = '${prefix}/var'; then
2383   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2384                         ${frr_statedir_prefix}/var/adm dnl
2385                         ${frr_statedir_prefix}/etc dnl
2386                         /var/run        dnl
2387                         /var/adm        dnl
2388                         /etc            dnl
2389                         /dev/null;
2390   do
2391     test -d $FRR_STATE_DIR && break
2392   done
2393   frr_statedir=$FRR_STATE_DIR
2394 else
2395   frr_statedir=${localstatedir}
2396 fi
2397 if test "$frr_statedir" = "/dev/null"; then
2398     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2399 fi
2400 AC_MSG_RESULT([${frr_statedir}])
2401 AC_SUBST([frr_statedir])
2402
2403 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2404 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2405 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2406 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2407 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2408
2409 dnl autoconf does this, but it does it too late...
2410 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2411 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2412
2413 dnl get the full path, recursing through variables...
2414 vtysh_bin="$bindir/vtysh"
2415 for I in 1 2 3 4 5 6 7 8 9 10; do
2416         eval vtysh_bin="\"$vtysh_bin\""
2417 done
2418 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2419 AC_SUBST([vtysh_bin])
2420
2421 CFG_SYSCONF="$sysconfdir"
2422 CFG_SBIN="$sbindir"
2423 CFG_STATE="$frr_statedir"
2424 CFG_MODULE="$moduledir"
2425 CFG_YANGMODELS="$yangmodelsdir"
2426 for I in 1 2 3 4 5 6 7 8 9 10; do
2427         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2428         eval CFG_SBIN="\"$CFG_SBIN\""
2429         eval CFG_STATE="\"$CFG_STATE\""
2430         eval CFG_MODULE="\"$CFG_MODULE\""
2431         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2432 done
2433 AC_SUBST([CFG_SYSCONF])
2434 AC_SUBST([CFG_SBIN])
2435 AC_SUBST([CFG_STATE])
2436 AC_SUBST([CFG_MODULE])
2437 AC_SUBST([CFG_YANGMODELS])
2438 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2439 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2440 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2441
2442 dnl various features
2443 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2444 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2445 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2446 dnl northbound
2447 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2448 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2449 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2450 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2451 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2452 dnl plugins
2453 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2454 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2455 AM_CONDITIONAL([IRDP], [$IRDP])
2456 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2457 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2458 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2459 dnl daemons
2460 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2461 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2462 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2463 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2464 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2465 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2466 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2467 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2468 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2469 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2470 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2471 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2472 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2473 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2474 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2475 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2476 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2477 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2478 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2479 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2480 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2481
2482 AC_CONFIG_FILES([Makefile],[
2483         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2484         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2485 ], [
2486         PYTHON="$PYTHON"
2487         enable_dev_build="$enable_dev_build"
2488 ])
2489
2490 AC_CONFIG_FILES([
2491           config.version
2492           changelog-auto
2493           redhat/frr.spec
2494           alpine/APKBUILD
2495           snapcraft/snapcraft.yaml
2496           lib/version.h
2497           tests/lib/cli/test_cli.refout
2498           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2499           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2500           pkgsrc/eigrpd.sh])
2501
2502 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2503 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2504 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2505 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2506 AC_CONFIG_FILES([tools/frrcommon.sh])
2507
2508 AS_IF([test "$with_pkg_git_version" = "yes"], [
2509     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2510         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2511         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2512                 "${ac_abs_top_srcdir}" \
2513                 > "${dst}.tmp"
2514         test -f "$dst" \
2515                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2516                 && rm "${dst}.tmp" \
2517                 || mv "${dst}.tmp" "${dst}"
2518     ], [
2519         PERL="$PERL"
2520     ])
2521 ])
2522
2523 ## Hack, but working solution to avoid rebuilding of frr.info.
2524 ## It's already in CVS until texinfo 4.7 is more common.
2525 AC_OUTPUT
2526
2527 if test "$enable_rpath" = "yes" ; then
2528         true
2529 else
2530         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2531         sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
2532         sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
2533 fi
2534
2535 echo "
2536 FRRouting configuration
2537 ------------------------------
2538 FRR version             : ${PACKAGE_VERSION}
2539 host operating system   : ${host_os}
2540 source code location    : ${srcdir}
2541 compiler                : ${CC}
2542 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2543 make                    : ${MAKE-make}
2544 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2545 state file directory    : ${frr_statedir}
2546 config file directory   : `eval echo \`echo ${sysconfdir}\``
2547 example directory       : `eval echo \`echo ${exampledir}\``
2548 module directory        : ${CFG_MODULE}
2549 user to run as          : ${enable_user}
2550 group to run as         : ${enable_group}
2551 group for vty sockets   : ${enable_vty_group}
2552 config file mask        : ${enable_configfile_mask}
2553 log file mask           : ${enable_logfile_mask}
2554 zebra protobuf enabled  : ${enable_protobuf:-no}
2555 vici socket path        : ${vici_socket}
2556
2557 The above user and group must have read/write access to the state file
2558 directory and to the config files in the config file directory."
2559
2560 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2561   AC_MSG_WARN([sphinx is missing but required to build documentation])
2562 fi
2563 if test "$frr_py_mod_pytest" = "false"; then
2564   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2565 fi