configure.ac

   1 ##
   2 ## Configure template file for Quagga.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.53)
   9
  10 AC_INIT(quagga, 0.96.4, [bug-zebra@gnu.org])
  11 AC_CONFIG_SRCDIR(lib/zebra.h)
  12 AM_INIT_AUTOMAKE()
  13 AM_CONFIG_HEADER(config.h)
  14
  15 dnl default is to match previous behavior
  16 exampledir='${sysconfdir}'
  17 AC_ARG_ENABLE([exampledir],
  18           AC_HELP_STRING([--enable-exampledir],
  19                          [specify alternate directory for examples]),
  20                          exampledir="$enableval",)
  21 dnl XXX hook into argument processing
  22 AC_SUBST(exampledir)
  23
  24 dnl -----------------------------------
  25 dnl Get hostname and other information.
  26 dnl -----------------------------------
  27 AC_CANONICAL_HOST
  28
  29 dnl ------------
  30 dnl Check CFLAGS
  31 dnl ------------
  32 AC_ARG_WITH(cflags,
  33 [  --with-cflags           Set CFLAGS for use in compilation.])
  34 if test "x$with_cflags" != "x" ; then
  35   CFLAGS="$with_cflags" ; cflags_specified=yes ;
  36 elif test -n "$CFLAGS" ; then
  37   cflags_specified=yes ;
  38 fi
  39
  40 dnl --------
  41 dnl Check CC
  42 dnl --------
  43 AC_PROG_CC
  44
  45 dnl -----------------------------------------
  46 dnl If CLFAGS doesn\'t exist set default value
  47 dnl -----------------------------------------
  48 if test "x$cflags_specified" = "x" ; then
  49   CFLAGS="$CFLAGS -Wall"
  50 fi
  51
  52 dnl --------------
  53 dnl Check programs
  54 dnl --------------
  55 AC_PROG_CPP
  56 AC_PROG_INSTALL
  57 AC_PROG_MAKE_SET
  58 AC_CHECK_TOOL(AR, ar)
  59 AC_CHECK_TOOL(RANLIB, ranlib, :)
  60
  61 dnl ---------
  62 dnl AIX check
  63 dnl ---------
  64 AC_AIX
  65
  66 dnl ----------------------
  67 dnl Packages configuration
  68 dnl ----------------------
  69 AC_ARG_ENABLE(vtysh,
  70 [  --enable-vtysh,       Make integrated vty shell for Quagga])
  71 AC_ARG_ENABLE(ipv6,
  72 [  --disable-ipv6          turn off IPv6 related features and daemons])
  73 AC_ARG_ENABLE(zebra,
  74 [  --disable-zebra         do not build zebra daemon])
  75 AC_ARG_ENABLE(bgpd,
  76 [  --disable-bgpd          do not build bgpd])
  77 AC_ARG_ENABLE(ripd,
  78 [  --disable-ripd          do not build ripd])
  79 AC_ARG_ENABLE(ripngd,
  80 [  --disable-ripngd        do not build ripngd])
  81 AC_ARG_ENABLE(ospfd,
  82 [  --disable-ospfd         do not build ospfd])
  83 AC_ARG_ENABLE(ospf6d,
  84 [  --disable-ospf6d        do not build ospf6d])
  85 AC_ARG_ENABLE(bgp-announce,
  86 [  --disable-bgp-announce, turn off BGP route announcement])
  87 AC_ARG_ENABLE(netlink,
  88 [  --enable-netlink        force to use Linux netlink interface])
  89 AC_ARG_ENABLE(broken-aliases,
  90 [  --enable-broken-aliases enable aliases as distinct interfaces for Linux 2.2.X])
  91 AC_ARG_ENABLE(snmp,
  92 [  --enable-snmp           enable SNMP support])
  93 AC_ARG_WITH(libpam,
  94 [  --with-libpam           use libpam for PAM support in vtysh])
  95 AC_ARG_ENABLE(tcp-zebra,
  96 [  --enable-tcp-zebra      enable TCP/IP socket connection between zebra and protocol daemon])
  97 dnl Temporary option until OSPF NSSA implementation complete
  98 AC_ARG_ENABLE(nssa,
  99 [  --enable-nssa           enable OSPF NSSA option])
 100 AC_ARG_ENABLE(opaque-lsa,
 101 [  --enable-opaque-lsa     enable OSPF Opaque-LSA with OSPFAPI support (RFC2370)])
 102 AC_ARG_ENABLE(ospfapi,
 103 [  --disable-ospfapi       do not build OSPFAPI to access the OSPF LSA Database,
 104                           (this is the default if --enable-opaque-lsa is not set)])
 105 AC_ARG_ENABLE(ospfclient,
 106 [  --disable-ospfclient    do not build OSPFAPI client for OSPFAPI,
 107                           (this is the default if --disable-ospfapi is set)])
 108 AC_ARG_ENABLE(ospf-te,
 109 [  --enable-ospf-te        enable Traffic Engineering Extension to OSPF])
 110 AC_ARG_ENABLE(multipath,
 111 [  --enable-multipath=ARG  enable multipath function, ARG must be digit])
 112 AC_ARG_ENABLE(quagga_user,
 113 [  --enable-user=ARG       user to run Quagga suite as (default quagga)])
 114 AC_ARG_ENABLE(quagga_group,
 115 [  --enable-group=ARG      group to run Quagga suite as (default quagga)])
 116 AC_ARG_ENABLE(vty_group,
 117 [  --enable-vty-group=ARG      set vty sockets to have specified group as owner])
 118
 119 AC_ARG_ENABLE(rtadv,
 120 [  --enable-rtadv         enable IPV6 router advertisement feature])
 121
 122 if test "${enable_broken_aliases}" = "yes"; then
 123   if test "${enable_netlink}" = "yes"
 124   then
 125     echo "Sorry, you can't use netlink with broken aliases"
 126     exit 1
 127   fi
 128   AC_DEFINE(HAVE_BROKEN_ALIASES,,Broken Alias)
 129   enable_netlink=no
 130 fi
 131
 132 if test "${enable_tcp_zebra}" = "yes"; then
 133   AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
 134 fi
 135
 136 if test "${enable_nssa}" = "yes"; then
 137   AC_DEFINE(HAVE_NSSA,,OSPF NSSA)
 138 fi
 139
 140 if test "${enable_opaque_lsa}" = "yes"; then
 141   AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
 142 fi
 143
 144 if test "${enable_ospf_te}" = "yes"; then
 145   AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
 146   AC_DEFINE(HAVE_OSPF_TE,,OSPF TE)
 147 fi
 148
 149 AC_MSG_CHECKING(Should zebra's RTADV be used)
 150 if test "${enable_rtadv}" = "yes"; then
 151   AC_MSG_RESULT(yes)
 152   AC_DEFINE(HAVE_RTADV,,Enable zebra IPv6 Routing Advertisements)
 153 else
 154   AC_MSG_RESULT(no)
 155 fi
 156
 157 if test "${enable_user}" = "yes" || test x"${enable_user}" = x""; then
 158   enable_user="quagga"
 159 elif test "${enable_user}" = "no"; then
 160   enable_user="root"
 161 fi
 162 AC_DEFINE_UNQUOTED(QUAGGA_USER, "${enable_user}", Quagga User)
 163
 164 if test "${enable_group}" = "yes" || test x"${enable_group}" = x""; then
 165   enable_group="quagga"
 166 elif test "${enable_group}" = "no"; then
 167   enable_group="root"
 168 fi
 169 AC_DEFINE_UNQUOTED(QUAGGA_GROUP, "${enable_group}", Quagga Group)
 170
 171 if test x"${enable_vty_group}" = x"yes" ; then
 172   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 173 elif test x"${enable_vty_group}" != x""; then
 174   if test x"${enable_vty_group}" != x"no"; then
 175     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 176   fi
 177 fi
 178
 179 changequote(, )dnl
 180
 181 MULTIPATH_NUM=1
 182
 183 case "${enable_multipath}" in
 184   [0-9]|[1-9][0-9])
 185     MULTIPATH_NUM="${enable_multipath}"
 186     ;;
 187   "")
 188     ;;
 189   *)
 190     echo "Please specify digit to --enable-multipath ARG."
 191     exit 1
 192     ;;
 193 esac
 194
 195 changequote([, ])dnl
 196
 197 AC_SUBST(MULTIPATH_NUM)
 198
 199 dnl -------------------
 200 dnl Check header files.
 201 dnl -------------------
 202 AC_HEADER_STDC
 203 AC_CHECK_HEADERS([string.h stropts.h sys/conf.h sys/ksym.h sys/time.h \
 204                  sys/times.h sys/select.h sys/sysctl.h sys/sockio.h \
 205                  sys/types.h linux/version.h kvm.h netdb.h asm/types.h \
 206                  libutil.h limits.h])
 207
 208 AC_CHECK_HEADERS([sys/socket.h netinet/in_systm.h netinet/in.h \
 209                  net/if_dl.h net/netopt.h inet/nd.h net/route.h \
 210                  net/if.h net/if_var.h netinet/in_var.h])
 211
 212 dnl V6 headers are checked below, after we check for v6
 213
 214 dnl check some types
 215 AC_C_CONST
 216 dnl AC_TYPE_PID_T
 217 AC_TYPE_SIGNAL
 218
 219 dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
 220 case "$host" in
 221   *-sunos5.6* | *-solaris2.6*)
 222       opsys=sol2-6
 223       AC_DEFINE(SUNOS_5,,SunOS 5)
 224       AC_CHECK_LIB(xnet, main)
 225       CURSES=-lcurses
 226   ;;
 227   *-sunos5* | *-solaris2*)
 228       AC_DEFINE(SUNOS_5,,SunOS 5)
 229       AC_CHECK_LIB(socket, main)
 230       AC_CHECK_LIB(nsl, main)
 231       CURSES=-lcurses
 232   ;;
 233   *-linux-*)
 234       opsys=gnu-linux
 235       AC_DEFINE(GNU_LINUX,,GNU Linux)
 236   ;;
 237   *-nec-sysv4*)
 238       AC_CHECK_LIB(nsl, gethostbyname)
 239       AC_CHECK_LIB(socket, socket)
 240   ;;
 241   *-freebsd3.2)
 242       AC_DEFINE(FREEBSD_32,,FreeBSD 3.2)
 243   ;;
 244   *-openbsd*)
 245       opsys=openbsd
 246       AC_DEFINE(OPEN_BSD,,OpenBSD)
 247   ;;
 248   *-bsdi*)
 249       opsys=bsdi
 250       OTHER_METHOD="mtu_kvm.o"
 251       AC_CHECK_LIB(kvm, main)
 252   ;;
 253   *-irix6.5)
 254       opsys=irix
 255       AC_DEFINE(IRIX_65,,IRIX 6.5)
 256   ;;
 257 esac
 258
 259 dnl ---------------------
 260 dnl Integrated VTY option
 261 dnl ---------------------
 262 case "${enable_vtysh}" in
 263   "yes") VTYSH="vtysh";
 264          AC_DEFINE(VTYSH,,VTY shell)
 265          AC_CHECK_LIB(tinfo, tputs, , AC_CHECK_LIB(ncurses, tputs))
 266          AC_CHECK_LIB(readline, main)
 267          if test $ac_cv_lib_readline_main = no; then
 268            AC_MSG_ERROR([vtysh needs libreadline but was not found on your system.])
 269          fi
 270          AC_CHECK_HEADER(readline/history.h)
 271          if test $ac_cv_header_readline_history_h = no;then
 272            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 273          fi
 274          AC_CHECK_LIB(readline, rl_completion_matches)
 275          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 276            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 277          fi
 278          ;;
 279   "no" ) VTYSH="";;
 280   *    ) ;;
 281 esac
 282
 283 dnl ----------
 284 dnl PAM module
 285 dnl ----------
 286 if test "$with_libpam" = "yes"; then
 287   AC_CHECK_HEADER(security/pam_misc.h)
 288   if test "$ac_cv_header_security_pam_misc_h" = yes; then
 289     AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 290     AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 291     pam_conv_func="misc_conv"
 292   fi
 293   AC_CHECK_HEADER(security/openpam.h)
 294   if test "$ac_cv_header_security_openpam_h" = yes; then
 295     AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 296     AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 297     pam_conv_func="openpam_ttyconv"
 298   fi
 299   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 300     AC_MSG_WARN([*** pam support will not be built ***])
 301     with_libpam="no"
 302   fi
 303 fi
 304
 305 if test "$with_libpam" = "yes"; then
 306 dnl took this test from proftpd's configure.in and suited to our needs
 307 dnl -------------------------------------------------------------------------
 308 dnl
 309 dnl This next check looks funky due to a linker problem with some versions
 310 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 311 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 312 dnl with RedHat 6.2 and Debian 2.2 or better.
 313 AC_CHECK_LIB(pam, pam_start,
 314   [AC_CHECK_LIB(pam, $pam_conv_func,
 315     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 316      LIBPAM="-lpam"],
 317     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 318      LIBPAM="-lpam -lpam_misc"]
 319     )
 320   ],
 321
 322   [AC_CHECK_LIB(pam, pam_end,
 323     [AC_CHECK_LIB(pam, $pam_conv_func,
 324       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 325        LIBPAM="-lpam -ldl"],
 326       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 327        LIBPAM="-lpam -ldl -lpam_misc"]
 328      )
 329   ],AC_MSG_WARN([*** pam support will not be built ***]),
 330   [-ldl])
 331   ]
 332 )
 333 fi
 334 AC_SUBST(LIBPAM)
 335
 336 dnl -------------------------------
 337 dnl Endian-ness check
 338 dnl -------------------------------
 339 AC_WORDS_BIGENDIAN
 340
 341 dnl -------------------------------
 342 dnl check the size in byte of the C
 343 dnl -------------------------------
 344 dnl AC_CHECK_SIZEOF(char)
 345 dnl AC_CHECK_SIZEOF(int)
 346 dnl AC_CHECK_SIZEOF(short)
 347 dnl AC_CHECK_SIZEOF(long)
 348
 349 dnl ----------------------------
 350 dnl check existance of functions
 351 dnl ----------------------------
 352 AC_CHECK_FUNCS(memset memcpy strerror inet_aton daemon snprintf vsnprintf \
 353                strlcat strlcpy if_nametoindex if_indextoname getifaddrs \
 354                fcntl)
 355 AC_CHECK_FUNCS(setproctitle, ,
 356   [AC_CHECK_LIB(util, setproctitle,
 357      [LIBS="$LIBS -lutil"
 358       AC_DEFINE(HAVE_SETPROCTITLE,, Have setproctitle)
 359      ]
 360    )
 361   ]
 362 )
 363
 364 dnl ------------------------------------
 365 dnl Determine routing get and set method
 366 dnl ------------------------------------
 367 AC_MSG_CHECKING(zebra between kernel interface method)
 368 if test x"$opsys" = x"gnu-linux"; then
 369   if test "${enable_netlink}" = "yes";then
 370     AC_MSG_RESULT(netlink)
 371     RT_METHOD=rt_netlink.o
 372     AC_DEFINE(HAVE_NETLINK,,netlink)
 373     netlink=yes
 374   elif test "${enable_netlink}" = "no"; then
 375     AC_MSG_RESULT(ioctl)
 376     RT_METHOD=rt_ioctl.o
 377     netlink=no
 378   else
 379     AC_MSG_RESULT(netlink)
 380     RT_METHOD=rt_netlink.o
 381     AC_DEFINE(HAVE_NETLINK,,netlink)
 382     netlink=yes
 383   fi
 384 else
 385   if test "$opsys" = "sol2-6";then
 386     AC_MSG_RESULT(solaris)
 387     KERNEL_METHOD="kernel_socket.o"
 388     RT_METHOD="rt_socket.o"
 389   elif test "$opsys" = "irix" ; then
 390     AC_MSG_RESULT(irix)
 391     KERNEL_METHOD="kernel_socket.o"
 392     RT_METHOD="rt_socket.o"
 393   else
 394     AC_TRY_RUN([#include <errno.h>
 395 #include <sys/types.h>
 396 #include <sys/socket.h>
 397
 398 main ()
 399 {
 400   int ac_sock;
 401
 402   ac_sock = socket (AF_ROUTE, SOCK_RAW, 0);
 403   if (ac_sock < 0 && errno == EINVAL)
 404     exit (1);
 405   exit (0);
 406 }],
 407   [KERNEL_METHOD=kernel_socket.o
 408    RT_METHOD=rt_socket.o
 409    AC_MSG_RESULT(socket)],
 410   [RT_METHOD=rt_ioctl.o
 411    AC_MSG_RESULT(ioctl)],
 412   [KERNEL_METHOD=kernel_socket.o
 413    RT_METHOD=rt_socket.o
 414    AC_MSG_RESULT(socket)])
 415   fi
 416 fi
 417 AC_SUBST(RT_METHOD)
 418 AC_SUBST(KERNEL_METHOD)
 419 AC_SUBST(OTHER_METHOD)
 420
 421 dnl ------------------------------
 422 dnl check kernel route read method
 423 dnl ------------------------------
 424 AC_CACHE_CHECK(route read method check, zebra_rtread,
 425 [if test "$netlink" = yes; then
 426   RTREAD_METHOD="rtread_netlink.o"
 427   zebra_rtread="netlink"
 428 else
 429 for zebra_rtread in /proc/net/route /dev/ip /dev/null;
 430 do
 431   test x`ls $zebra_rtread 2>/dev/null` = x"$zebra_rtread" && break
 432 done
 433 case $zebra_rtread in
 434   "/proc/net/route") RTREAD_METHOD="rtread_proc.o"
 435                      zebra_rtread="proc";;
 436   "/dev/ip")
 437                      case "$host" in
 438                        *-freebsd*)    RTREAD_METHOD=rtread_sysctl.o
 439                                       zebra_rtread="sysctl";;
 440                        *)             RTREAD_METHOD="rtread_getmsg.o"
 441                                       zebra_rtread="getmsg";;
 442                      esac;;
 443   *)                 RTREAD_METHOD="rtread_sysctl.o"
 444                      zebra_rtread="sysctl";;
 445 esac
 446 fi])
 447 AC_SUBST(RTREAD_METHOD)
 448
 449 dnl -----------------------------
 450 dnl check interface lookup method
 451 dnl -----------------------------
 452 AC_MSG_CHECKING(interface looking up method)
 453 if test "$netlink" = yes; then
 454   AC_MSG_RESULT(netlink)
 455   IF_METHOD=if_netlink.o
 456 else
 457   if test "$opsys" = "sol2-6";then
 458     AC_MSG_RESULT(solaris)
 459     IF_METHOD=if_ioctl.o
 460   elif test "$opsys" = "irix" ; then
 461     AC_MSG_RESULT(irix)
 462      IF_METHOD=if_ioctl.o
 463   elif test "$opsys" = "openbsd";then
 464     AC_MSG_RESULT(openbsd)
 465     IF_METHOD=if_ioctl.o
 466   elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
 467     AC_MSG_RESULT(sysctl)
 468     IF_METHOD=if_sysctl.o
 469     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 470   else
 471     AC_MSG_RESULT(ioctl)
 472     IF_METHOD=if_ioctl.o
 473   fi
 474 fi
 475 AC_SUBST(IF_METHOD)
 476
 477 dnl -----------------------
 478 dnl check proc file system.
 479 dnl -----------------------
 480 if test -r /proc/net/dev; then
 481   AC_DEFINE(HAVE_PROC_NET_DEV,,/proc/net/dev)
 482   IF_PROC=if_proc.o
 483 fi
 484
 485 if test -r /proc/net/if_inet6; then
 486   AC_DEFINE(HAVE_PROC_NET_IF_INET6,,/proc/net/if_inet6)
 487   IF_PROC=if_proc.o
 488 fi
 489 AC_SUBST(IF_PROC)
 490
 491 dnl -----------------------------
 492 dnl check ipforward detect method
 493 dnl -----------------------------
 494 AC_CACHE_CHECK(ipforward method check, zebra_ipforward_path,
 495 [for zebra_ipforward_path in /proc/net/snmp /dev/ip /dev/null;
 496 do
 497   test x`ls $zebra_ipforward_path 2>/dev/null` = x"$zebra_ipforward_path" && break
 498 done
 499 case $zebra_ipforward_path in
 500   "/proc/net/snmp")  IPFORWARD=ipforward_proc.o
 501                      zebra_ipforward_path="proc";;
 502   "/dev/ip")
 503                      case "$host" in
 504                        *-nec-sysv4*)  IPFORWARD=ipforward_ews.o
 505                                       zebra_ipforward_path="ews";;
 506                        *-freebsd*)    IPFORWARD=ipforward_sysctl.o
 507                                       zebra_ipforward_path="sysctl";;
 508                        *)             IPFORWARD=ipforward_solaris.o
 509                                       zebra_ipforward_path="solaris";;
 510                      esac;;
 511   *)                 IPFORWARD=ipforward_sysctl.o
 512                      zebra_ipforward_path="sysctl";;
 513 esac])
 514 AC_SUBST(IPFORWARD)
 515
 516 AC_CHECK_FUNCS(getaddrinfo, [have_getaddrinfo=yes], [have_getaddrinfo=no])
 517
 518 dnl ----------
 519 dnl IPv6 check
 520 dnl ----------
 521 AC_MSG_CHECKING(whether does this OS have IPv6 stack)
 522 if test "${enable_ipv6}" = "no"; then
 523   AC_MSG_RESULT(disabled)
 524 else
 525 dnl ----------
 526 dnl INRIA IPv6
 527 dnl ----------
 528   if grep IPV6_INRIA_VERSION /usr/include/netinet/in.h >/dev/null 2>&1; then
 529     zebra_cv_ipv6=yes
 530     AC_DEFINE(HAVE_IPV6,1,INRIA IPv6)
 531     AC_DEFINE(INRIA_IPV6,1,INRIA IPv6)
 532     RIPNGD="ripngd"
 533     OSPF6D="ospf6d"
 534     LIB_IPV6=""
 535     AC_MSG_RESULT(INRIA IPv6)
 536 dnl ---------
 537 dnl KAME IPv6
 538 dnl ---------
 539   elif grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
 540     zebra_cv_ipv6=yes
 541     AC_DEFINE(HAVE_IPV6,1,KAME IPv6)
 542     AC_DEFINE(KAME,1,KAME IPv6)
 543     RIPNGD="ripngd"
 544     OSPF6D="ospf6d"
 545     if test -d /usr/local/v6/lib -a -f /usr/local/v6/lib/libinet6.a; then
 546       LIB_IPV6="-L/usr/local/v6/lib -linet6"
 547     fi
 548     AC_MSG_RESULT(KAME)
 549 dnl -------------------------
 550 dnl MUSICA IPv6
 551 dnl  default host check
 552 dnl  It is not used by Kheops
 553 dnl -------------------------
 554   elif grep MUSICA /usr/include6/netinet6/in6.h >/dev/null 2>&1; then
 555     zebra_cv_ipv6=yes
 556     AC_DEFINE(HAVE_IPV6,1,Musicia IPv6)
 557     AC_DEFINE(MUSICA,1,Musica IPv6 stack)
 558     AC_DEFINE(KAME,1,KAME IPv6 stack)
 559     RIPNGD="ripngd"
 560     OSPF6D="ospf6d"
 561     if test -d /usr/local/v6/lib -a -f /usr/local/v6/lib/libinet6.a; then
 562       LIB_IPV6="-L/usr/local/v6/lib -linet6"
 563     fi
 564     AC_MSG_RESULT(MUSICA)
 565 dnl ---------
 566 dnl NRL check
 567 dnl ---------
 568   elif grep NRL /usr/include/netinet6/in6.h >/dev/null 2>&1; then
 569     zebra_cv_ipv6=yes
 570     AC_DEFINE(HAVE_IPV6,1,NRL IPv6)
 571     AC_DEFINE(NRL,1,NRL)
 572     RIPNGD="ripngd"
 573     OSPF6D="ospf6d"
 574     if test x"$opsys" = x"bsdi";then
 575       AC_DEFINE(BSDI_NRL,,BSDI)
 576       AC_MSG_RESULT(BSDI_NRL)
 577     else
 578       AC_MSG_RESULT(NRL)
 579     fi
 580 dnl ----------
 581 dnl Linux IPv6
 582 dnl ----------
 583   elif test "${enable_ipv6}" = "yes"; then
 584     AC_EGREP_CPP(yes, [
 585       #include <linux/version.h>
 586       /* 2.1.128 or later */
 587       #if LINUX_VERSION_CODE >= 0x020180
 588       yes
 589       #endif],
 590       [zebra_cv_ipv6=yes
 591        zebra_cv_linux_ipv6=yes
 592        AC_MSG_RESULT(Linux IPv6)])
 593   else
 594     if test x`ls /proc/net/ipv6_route 2>/dev/null` = x"/proc/net/ipv6_route"
 595      then
 596       zebra_cv_ipv6=yes
 597       zebra_cv_linux_ipv6=yes
 598       AC_MSG_RESULT(Linux IPv6)
 599     fi
 600   fi
 601
 602   if test "$zebra_cv_linux_ipv6" = "yes";then
 603     AC_MSG_CHECKING(for GNU libc >= 2.1)
 604     AC_DEFINE(HAVE_IPV6,1,Linux IPv6)
 605     AC_EGREP_CPP(yes, [
 606 #include <features.h>
 607 #if __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 608   yes
 609 #endif],
 610       [glibc=yes
 611        AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 612        AC_MSG_RESULT(yes)],
 613       AC_MSG_RESULT(no)
 614     )
 615     RIPNGD="ripngd"
 616     OSPF6D="ospf6d"
 617     if test "$glibc" != "yes"; then
 618       INCLUDES="-I/usr/inet6/include"
 619       if test x`ls /usr/inet6/lib/libinet6.a 2>/dev/null` != x;then
 620          LIB_IPV6="-L/usr/inet6/lib -linet6"
 621       fi
 622     fi
 623   fi
 624
 625 dnl -----------------------
 626 dnl Set IPv6 related values
 627 dnl -----------------------
 628   LIBS="$LIB_IPV6 $LIBS"
 629   AC_SUBST(LIB_IPV6)
 630
 631   if test x"$RIPNGD" = x""; then
 632     AC_MSG_RESULT(IPv4 only)
 633   fi
 634 fi
 635
 636 dnl ------------------
 637 dnl IPv6 header checks
 638 dnl ------------------
 639 if test "x${zebra_cv_ipv6}" = "xyes"; then
 640 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h netinet/icmp6.h \
 641                  netinet6/in6_var.h netinet6/nd6.h])
 642 fi
 643
 644 dnl --------------------
 645 dnl Daemon disable check
 646 dnl --------------------
 647 if test "${enable_zebra}" = "no";then
 648   ZEBRA=""
 649 else
 650   ZEBRA="zebra"
 651 fi
 652
 653 if test "${enable_bgpd}" = "no";then
 654   BGPD=""
 655 else
 656   BGPD="bgpd"
 657 fi
 658
 659 if test "${enable_ripd}" = "no";then
 660   RIPD=""
 661 else
 662   RIPD="ripd"
 663 fi
 664
 665 if test "${enable_ospfd}" = "no";then
 666   OSPFD=""
 667 else
 668   OSPFD="ospfd"
 669 fi
 670
 671 OSPFCLIENT=""
 672 if test "${enable_opaque_lsa}" = "yes"; then
 673   if test "${enable_ospfapi}" != "no";then
 674     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
 675
 676     if test "${enable_ospfclient}" != "no";then
 677       OSPFCLIENT="ospfclient"
 678     fi
 679   fi
 680
 681 fi
 682
 683 case "${enable_ripngd}" in
 684   "yes") RIPNGD="ripngd";;
 685   "no" ) RIPNGD="";;
 686   *    ) ;;
 687 esac
 688
 689 case "${enable_ospf6d}" in
 690   "yes") OSPF6D="ospf6d";;
 691   "no" ) OSPF6D="";;
 692   *    ) ;;
 693 esac
 694
 695 if test "${enable_bgp_announce}" = "no";then
 696   AC_DEFINE(DISABLE_BGP_ANNOUNCE,,Disable BGP installation to zebra)
 697 fi
 698
 699 AC_SUBST(ZEBRA)
 700 AC_SUBST(BGPD)
 701 AC_SUBST(RIPD)
 702 AC_SUBST(RIPNGD)
 703 AC_SUBST(OSPFD)
 704 AC_SUBST(OSPF6D)
 705 AC_SUBST(VTYSH)
 706 AC_SUBST(INCLUDES)
 707 AC_SUBST(CURSES)
 708 AC_SUBST(OSPFCLIENT)
 709 AC_SUBST(OSPFAPI)
 710 AC_CHECK_LIB(c, inet_ntop, [AC_DEFINE(HAVE_INET_NTOP,,inet_ntop)])
 711 AC_CHECK_LIB(c, inet_pton, [AC_DEFINE(HAVE_INET_PTON,,inet_pton)])
 712 AC_CHECK_LIB(crypt, crypt)
 713 AC_CHECK_LIB(resolv, res_init)
 714 AC_CHECK_LIB(m, main)
 715
 716 dnl ---------------------------------------------------
 717 dnl BSD/OS 4.1 define inet_XtoY function as __inet_XtoY
 718 dnl ---------------------------------------------------
 719 AC_CHECK_FUNC(__inet_ntop, AC_DEFINE(HAVE_INET_NTOP,,__inet_ntop))
 720 AC_CHECK_FUNC(__inet_pton, AC_DEFINE(HAVE_INET_PTON,,__inet_pton))
 721 AC_CHECK_FUNC(__inet_aton, AC_DEFINE(HAVE_INET_ATON,,__inet_aton))
 722
 723 dnl ---------------------------
 724 dnl check system has GNU regexp
 725 dnl ---------------------------
 726 dnl AC_MSG_CHECKING(whether system has GNU regex)
 727 AC_CHECK_LIB(c, regexec,
 728 [AC_DEFINE(HAVE_GNU_REGEX,,GNU regexp library)
 729  LIB_REGEX=""],
 730 [LIB_REGEX="regex.o"])
 731 AC_SUBST(LIB_REGEX)
 732
 733 dnl ------------------
 734 dnl check SNMP library
 735 dnl ------------------
 736 if test "${enable_snmp}" = "yes";then
 737 dnl  AC_CHECK_LIB(snmp, asn_parse_int, HAVE_SNMP=yes)
 738   if test "${HAVE_SNMP}" = ""; then
 739     old_libs="${LIBS}"
 740     LIBS="-L/usr/lib"
 741     unset ac_cv_lib_snmp_asn_parse_int
 742     AC_CHECK_LIB(crypto, main, NEED_CRYPTO=yes, )
 743     if test "${NEED_CRYPTO}" = ""; then
 744       AC_CHECK_LIB(netsnmp, asn_parse_int, [HAVE_NETSNMP=yes; HAVE_SNMP=yes ])
 745     else
 746       AC_CHECK_LIB(netsnmp, asn_parse_int, [HAVE_NETSNMP=yes; HAVE_SNMP=yes; NEED_CRYPTO=yes;LIBS="$LIBS -lcrypto" ],,"-lcrypto")
 747     fi
 748     LIBS="${old_libs}"
 749   fi
 750   if test "${HAVE_SNMP}" = ""; then
 751     old_libs="${LIBS}"
 752     LIBS="-L/usr/lib"
 753     unset ac_cv_lib_snmp_asn_parse_int
 754     AC_CHECK_LIB(snmp, asn_parse_int, HAVE_SNMP=yes, )
 755     if test "${HAVE_SNMP}" = ""; then
 756       unset ac_cv_lib_snmp_asn_parse_int
 757       AC_CHECK_LIB(crypto, main, NEED_CRYPTO=yes, )
 758       if test "${NEED_CRYPTO}" = "yes"; then
 759         AC_CHECK_LIB(snmp, asn_parse_int, [HAVE_SNMP=yes; NEED_CRYPTO=yes; LIBS="$LIBS -lcrypto" ],,"-lcrypto")
 760       fi
 761     fi
 762     LIBS="${old_libs}"
 763   fi
 764
 765   if test "${HAVE_SNMP}" = ""; then
 766     old_libs="${LIBS}"
 767     LIBS="-L/usr/local/lib"
 768     unset ac_cv_lib_snmp_asn_parse_int
 769     AC_CHECK_LIB(snmp, asn_parse_int, HAVE_SNMP=yes)
 770     if test "${HAVE_SNMP}" = ""; then
 771       unset ac_cv_lib_snmp_asn_parse_int
 772       AC_CHECK_LIB(crypto, main, NEED_CRYPTO=yes, )
 773       if test "${NEED_CRYPTO}" = "yes"; then
 774         AC_CHECK_LIB(snmp, asn_parse_int, [HAVE_SNMP=yes; NEED_CRYPTO=yes; LIBS="$LIBS -lcrypto" ],,"-lcrypto")
 775       fi
 776     fi
 777     LIBS="${old_libs}"
 778   fi
 779
 780   if test "${HAVE_SNMP}" = "yes"; then
 781     for ac_snmp in /usr/include/net-snmp/library/asn1.h /usr/include/ucd-snmp/asn1.h /usr/local/include/ucd-snmp/asn1.h /dev/null
 782     do
 783       test -f "${ac_snmp}" && break
 784     done
 785
 786     case ${ac_snmp} in
 787       /usr/include/net-snmp/*)
 788                   AC_DEFINE(HAVE_SNMP,,SNMP)
 789                   AC_DEFINE(HAVE_NETSNMP,,SNMP)
 790                   AC_DEFINE(UCD_COMPATIBLE,,SNMP)
 791                   CFLAGS="${CFLAGS} -I/usr/include/net-snmp -I/usr/include/net-snmp/library"
 792                   if test "${HAVE_NETSNMP}" = "yes"; then
 793                         LIBS="${LIBS} -lnetsnmp"
 794                   else
 795                         LIBS="${LIBS} -lsnmp"
 796                   fi
 797                   ;;
 798       /usr/include/ucd-snmp/*)
 799                   AC_DEFINE(HAVE_SNMP,,SNMP)
 800                   CFLAGS="${CFLAGS} -I/usr/include/ucd-snmp"
 801                   LIBS="${LIBS} -lsnmp"
 802                   ;;
 803       /usr/local/include/ucd-snmp/*)
 804                   AC_DEFINE(HAVE_SNMP,,SNMP)
 805                   CFLAGS="${CFLAGS} -I/usr/local/include/ucd-snmp"
 806                   LIBS="${LIBS} -L/usr/local/lib -lsnmp"
 807                   ;;
 808       /usr/local/include/net-snmp/*)
 809                 AC_DEFINE(HAVE_SNMP,,SNMP)
 810                 AC_DEFINE(HAVE_NET_SNMP,,SNMP)
 811                 AC_DEFINE(UCD_COMPATIBLE,,SNMP)
 812                 CFLAGS="${CFLAGS} -I/usr/local/include/net-snmp"
 813                 LIBS="${LIBS} -L/usr/local/lib -lnetsnmp"
 814                 ;;
 815     esac
 816     if test "${NEED_CRYPTO}" = "yes"; then
 817       LIBS="${LIBS} -lcrypto"
 818     fi
 819   fi
 820 fi
 821
 822 dnl ----------------------------
 823 dnl check sa_len of sockaddr
 824 dnl ----------------------------
 825 AC_MSG_CHECKING(whether struct sockaddr has a sa_len field)
 826 AC_TRY_COMPILE([#include <sys/types.h>
 827 #include <sys/socket.h>
 828 ],[static struct sockaddr ac_i;int ac_j = sizeof (ac_i.sa_len);],
 829 [AC_MSG_RESULT(yes)
 830  AC_DEFINE(HAVE_SA_LEN,,sa_len)],
 831  AC_MSG_RESULT(no))
 832
 833 dnl ----------------------------
 834 dnl check sin_len of sockaddr_in
 835 dnl ----------------------------
 836 AC_MSG_CHECKING(whether struct sockaddr_in has a sin_len field)
 837 AC_TRY_COMPILE([#include <sys/types.h>
 838 #include <netinet/in.h>
 839 ],[static struct sockaddr_in ac_i;int ac_j = sizeof (ac_i.sin_len);],
 840 [AC_MSG_RESULT(yes)
 841  AC_DEFINE(HAVE_SIN_LEN,,sin_len)],
 842  AC_MSG_RESULT(no))
 843
 844 dnl ----------------------------
 845 dnl check sun_len of sockaddr_un
 846 dnl ----------------------------
 847 AC_MSG_CHECKING(whether struct sockaddr_un has a sun_len field)
 848 AC_TRY_COMPILE([#include <sys/types.h>
 849 #include <sys/un.h>
 850 ],[static struct sockaddr_un ac_i;int ac_j = sizeof (ac_i.sun_len);],
 851 [AC_MSG_RESULT(yes)
 852  AC_DEFINE(HAVE_SUN_LEN,,sun_len)],
 853  AC_MSG_RESULT(no))
 854
 855 dnl -----------------------------------
 856 dnl check sin6_scope_id of sockaddr_in6
 857 dnl -----------------------------------
 858 if test "$zebra_cv_ipv6" = yes; then
 859   AC_MSG_CHECKING(whether struct sockaddr_in6 has a sin6_scope_id field)
 860   AC_TRY_COMPILE([#include <sys/types.h>
 861 #include <netinet/in.h>
 862 ],[static struct sockaddr_in6 ac_i;int ac_j = sizeof (ac_i.sin6_scope_id);],
 863 [AC_MSG_RESULT(yes)
 864  AC_DEFINE(HAVE_SIN6_SCOPE_ID,,scope id)],
 865  AC_MSG_RESULT(no))
 866 fi
 867
 868 dnl ----------------------------
 869 dnl check socklen_t exist or not
 870 dnl ----------------------------
 871 AC_MSG_CHECKING(whther socklen_t is defined)
 872 AC_TRY_COMPILE([#include <sys/types.h>
 873 #include <sys/socket.h>
 874 #include <netinet/in.h>
 875 ],[socklen_t ac_x;],
 876 [AC_MSG_RESULT(yes)
 877  AC_DEFINE(HAVE_SOCKLEN_T,,socklen_t)],
 878  AC_MSG_RESULT(no))
 879
 880 dnl ------------------------
 881 dnl check struct sockaddr_dl
 882 dnl ------------------------
 883 AC_MSG_CHECKING(whether struct sockaddr_dl exist)
 884 AC_EGREP_HEADER(sockaddr_dl,
 885 net/if_dl.h,
 886 [AC_MSG_RESULT(yes)
 887  AC_DEFINE(HAVE_SOCKADDR_DL,,sockaddr_dl)],
 888  AC_MSG_RESULT(no))
 889
 890 dnl --------------------------
 891 dnl check structure ifaliasreq
 892 dnl --------------------------
 893 AC_MSG_CHECKING(whether struct ifaliasreq exist)
 894 AC_EGREP_HEADER(ifaliasreq,
 895 net/if.h,
 896 [AC_MSG_RESULT(yes)
 897  AC_DEFINE(HAVE_IFALIASREQ,,ifaliasreq)],
 898  AC_MSG_RESULT(no))
 899
 900 dnl ----------------------------
 901 dnl check structure in6_aliasreq
 902 dnl ----------------------------
 903 AC_MSG_CHECKING(whether struct in6_aliasreq exist)
 904 AC_EGREP_HEADER(in6_aliasreq,
 905 netinet6/in6_var.h,
 906 [AC_MSG_RESULT(yes)
 907  AC_DEFINE(HAVE_IN6_ALIASREQ,,in6_aliasreq)],
 908  AC_MSG_RESULT(no))
 909
 910 dnl -----------------------------------
 911 dnl check ifra_lifetime of in6_aliasreq
 912 dnl -----------------------------------
 913 AC_MSG_CHECKING(whether in6_aliasreq.ifra_lifetime exist)
 914 AC_TRY_COMPILE([#include <sys/types.h>
 915 #include <netinet6/in6_var.h>
 916 ],[static struct if6_aliasreq ac_i;int ac_j = sizeof (ac_i.ifra_lifetime);],
 917 [AC_MSG_RESULT(yes)
 918  AC_DEFINE(HAVE_IFRA_LIFETIME,,Have in6_aliasreq.ifra_lifetime)],
 919  AC_MSG_RESULT(no))
 920
 921 dnl ---------------------------
 922 dnl check structure rt_addrinfo
 923 dnl ---------------------------
 924 AC_MSG_CHECKING(whether struct rt_addrinfo exist)
 925 AC_EGREP_HEADER(rt_addrinfo,
 926 net/route.h,
 927 [AC_MSG_RESULT(yes)
 928  AC_DEFINE(HAVE_RT_ADDRINFO,,rt_addrinfo)],
 929  AC_MSG_RESULT(no))
 930
 931 dnl --------------------------
 932 dnl check structure in_pktinfo
 933 dnl --------------------------
 934 AC_MSG_CHECKING(whether struct in_pktinfo exist)
 935 AC_TRY_COMPILE([#include <netinet/in.h>
 936 ],[struct in_pktinfo ac_x;],
 937 [AC_MSG_RESULT(yes)
 938  AC_DEFINE(HAVE_INPKTINFO,,in_pktinfo)],
 939  AC_MSG_RESULT(no))
 940
 941 dnl --------------------------------------
 942 dnl checking for getrusage struct and call
 943 dnl --------------------------------------
 944 AC_MSG_CHECKING(whether getrusage is available)
 945 AC_TRY_COMPILE([#include <sys/resource.h>
 946 ],[struct rusage ac_x; getrusage (RUSAGE_SELF, &ac_x);],
 947 [AC_MSG_RESULT(yes)
 948  AC_DEFINE(HAVE_RUSAGE,,rusage)],
 949  AC_MSG_RESULT(no))
 950
 951 dnl -------------------
 952 dnl capabilities checks
 953 dnl -------------------
 954 AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
 955 AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
 956   [AC_MSG_RESULT(yes)
 957    AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
 958    quagga_ac_keepcaps="yes"],
 959    AC_MSG_RESULT(no)
 960 )
 961 if test x"${quagga_ac_keepcaps}" = x"yes"; then
 962   AC_CHECK_HEADERS(sys/capability.h)
 963 fi
 964 if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
 965   AC_CHECK_LIB(cap, cap_init,
 966     [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
 967      LIBCAP="-lcap"
 968     ]
 969   )
 970 fi
 971 AC_SUBST(LIBCAP)
 972
 973 dnl ---------------------------
 974 dnl check for glibc 'backtrace'
 975 dnl ---------------------------
 976 if test "${glibc}" = "yes"; then
 977    AC_CHECK_HEADER(execinfo.h)
 978 fi
 979 if test x"${ac_cv_header_execinfo_h}" = x"yes"; then
 980   AC_CHECK_FUNC(backtrace,
 981     [AC_DEFINE(HAVE_GLIBC_BACKTRACE,,Glibc backtrace)]
 982   )
 983 fi
 984
 985 dnl ----------
 986 dnl configure date
 987 dnl ----------
 988 CONFDATE=`date '+%Y%m%d'`
 989 AC_SUBST(CONFDATE)
 990
 991 dnl ------------------------------
 992 dnl set paths for state directory
 993 dnl ------------------------------
 994 if test "${prefix}" = "NONE"; then
 995   quagga_statedir_prefix="";
 996 else
 997   quagga_statedir_prefix=${prefix}
 998 fi
 999 if test "${localstatedir}" = '${prefix}/var'; then
1000   AC_CACHE_CHECK(state directory,ac_statedir,
1001   [for QUAGGA_STATE_DIR in ${quagga_statedir_prefix}/var/run dnl
1002                         ${quagga_statedir_prefix}/var/adm dnl
1003                         ${quagga_statedir_prefix}/etc dnl
1004                         /var/run        dnl
1005                         /var/adm        dnl
1006                         /etc            dnl
1007                         /dev/null;
1008   do
1009     test -d $QUAGGA_STATE_DIR && break
1010   done
1011   quagga_statedir=$QUAGGA_STATE_DIR])
1012 else
1013   quagga_statedir=${localstatedir}
1014   AC_MSG_CHECKING(directory to use for state file)
1015   AC_MSG_RESULT(${quagga_statedir})
1016 fi
1017 if test $quagga_statedir = "/dev/null"; then
1018     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1019 fi
1020
1021 AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$quagga_statedir/zebra.pid",zebra PID)
1022 AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$quagga_statedir/ripd.pid",ripd PID)
1023 AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$quagga_statedir/ripngd.pid",ripngd PID)
1024 AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$quagga_statedir/bgpd.pid",bgpd PID)
1025 AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$quagga_statedir/ospfd.pid",ospfd PID)
1026 AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$quagga_statedir/ospf6d.pid",ospf6d PID)
1027 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$quagga_statedir/zserv.api",zebra api socket)
1028 AC_DEFINE_UNQUOTED(ZEBRA_VTYSH_PATH, "$quagga_statedir/zebra.vty",zebra vty socket)
1029 AC_DEFINE_UNQUOTED(RIP_VTYSH_PATH, "$quagga_statedir/ripd.vty",rip vty socket)
1030 AC_DEFINE_UNQUOTED(RIPNG_VTYSH_PATH, "$quagga_statedir/ripngd.vty",ripng vty socket)
1031 AC_DEFINE_UNQUOTED(BGP_VTYSH_PATH, "$quagga_statedir/bgpd.vty",bgpd vty socket)
1032 AC_DEFINE_UNQUOTED(OSPF_VTYSH_PATH, "$quagga_statedir/ospfd.vty",ospfd vty socket)
1033 AC_DEFINE_UNQUOTED(OSPF6_VTYSH_PATH, "$quagga_statedir/ospf6d.vty",ospf6d vty socket)
1034
1035 dnl ---------------------------
1036 dnl Check htonl works correctly
1037 dnl ---------------------------
1038 AC_MSG_CHECKING(for working htonl)
1039 AC_CACHE_VAL(ac_cv_htonl_works, [
1040 AC_TRY_LINK([#ifdef HAVE_SYS_TYPES_H
1041 #include <sys/types.h>
1042 #endif
1043 #ifdef HAVE_NETDB_H
1044 #include <netdb.h>
1045 #endif
1046 #ifdef HAVE_NETINET_IN_H
1047 #include <netinet/in.h>
1048 #endif],
1049 [htonl (0);],
1050 ac_cv_htonl_works=yes,
1051 ac_cv_htonl_works=no)])
1052 AC_MSG_RESULT($ac_cv_htonl_works)
1053
1054 AC_OUTPUT(Makefile lib/Makefile zebra/Makefile ripd/Makefile
1055           ripngd/Makefile bgpd/Makefile ospfd/Makefile
1056           ospf6d/Makefile vtysh/Makefile doc/Makefile
1057           ospfclient/Makefile
1058           redhat/quagga.spec
1059           lib/version.h)
1060
1061 echo "
1062 zebra configuration
1063 -------------------
1064 quagga version           : ${PACKAGE_VERSION}
1065 host operationg system  : ${host_os}
1066 source code location    : ${srcdir}
1067 compiler                : ${CC}
1068 compiler flags          : ${CFLAGS}
1069 linker flags            : ${LDFLAGS} ${LIBS}
1070 state file directory    : ${quagga_statedir}
1071 config file directory   : `eval echo \`echo ${sysconfdir}\``
1072 example directory       : `eval echo \`echo ${exampledir}\``
1073 user to run as          : ${enable_user}
1074 group to run as         : ${enable_group}
1075 group for vty sockets   : ${enable_vty_group}
1076
1077 The above user and group must have read/write access to the state file
1078 directory and to the config files in the config file directory.
1079 "