configure.in

   1 ##
   2 ## Configure template file for Zebra.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##
   7 AC_PREREQ(2.13)
   8
   9 AC_INIT(lib/zebra.h)
  10 AM_INIT_AUTOMAKE(zebra, 0.93)
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl -----------------------------------
  14 dnl Get hostname and other information.
  15 dnl -----------------------------------
  16 AC_CANONICAL_HOST
  17
  18 dnl ------------
  19 dnl Check CFLAGS
  20 dnl ------------
  21 AC_ARG_WITH(cflags,
  22 [  --with-cflags           Set CFLAGS for use in compilation.])
  23 if test "x$with_cflags" != "x" ; then
  24   CFLAGS="$with_cflags" ; cflags_specified=yes ;
  25 elif test -n "$CFLAGS" ; then
  26   cflags_specified=yes ;
  27 fi
  28
  29 dnl --------
  30 dnl Check CC
  31 dnl --------
  32 AC_PROG_CC
  33
  34 dnl -----------------------------------------
  35 dnl If CLFAGS doesn\'t exist set default value
  36 dnl -----------------------------------------
  37 if test "x$cflags_specified" = "x" ; then
  38   CFLAGS="$CFLAGS -Wall"
  39 fi
  40
  41 dnl --------------
  42 dnl Check programs
  43 dnl --------------
  44 AC_PROG_CPP
  45 AC_PROG_INSTALL
  46 AC_PROG_MAKE_SET
  47 AC_CHECK_TOOL(AR, ar)
  48 AC_CHECK_TOOL(RANLIB, ranlib, :)
  49
  50 dnl ---------
  51 dnl AIX check
  52 dnl ---------
  53 AC_AIX
  54
  55 dnl ----------------------
  56 dnl Packages configuration
  57 dnl ----------------------
  58 AC_ARG_ENABLE(vtysh,
  59 [  --enable-vtysh,       Make integrated VTY version of zebra])
  60 AC_ARG_ENABLE(ipv6,
  61 [  --disable-ipv6          turn off IPv6 related features and daemons])
  62 AC_ARG_ENABLE(zebra,
  63 [  --disable-zebra         do not build zebra daemon])
  64 AC_ARG_ENABLE(bgpd,
  65 [  --disable-bgpd          do not build bgpd])
  66 AC_ARG_ENABLE(ripd,
  67 [  --disable-ripd          do not build ripd])
  68 AC_ARG_ENABLE(ripngd,
  69 [  --disable-ripngd        do not build ripngd])
  70 AC_ARG_ENABLE(ospfd,
  71 [  --disable-ospfd         do not build ospfd])
  72 AC_ARG_ENABLE(ospf6d,
  73 [  --disable-ospf6d        do not build ospf6d])
  74 AC_ARG_ENABLE(bgp-announce,
  75 [  --disable-bgp-announce, turn off BGP route announcement])
  76 AC_ARG_ENABLE(netlink,
  77 [  --enable-netlink        force to use Linux netlink interface])
  78 AC_ARG_ENABLE(broken-aliases,
  79 [  --enable-broken-aliases enable aliases as distinct interfaces for Linux 2.2.X])
  80 AC_ARG_ENABLE(snmp,
  81 [  --enable-snmp           enable SNMP support])
  82 AC_ARG_WITH(libpam,
  83 [  --with-libpam           use libpam for PAM support in vtysh])
  84 AC_ARG_ENABLE(tcpsock,
  85 [  --enable-tcp-zebra      enable TCP/IP socket connection between zebra and protocol daemon])
  86 dnl Temporary option until OSPF NSSA implementation complete
  87 AC_ARG_ENABLE(nssa,
  88 [  --enable-nssa           enable OSPF NSSA option])
  89 AC_ARG_ENABLE(opaque-lsa,
  90 [  --enable-opaque-lsa     enable OSPF Opaque-LSA support (RFC2370)])
  91 AC_ARG_ENABLE(ospf-te,
  92 [  --enable-ospf-te        enable Traffic Engineering Extension to OSPF])
  93 AC_ARG_ENABLE(multipath,
  94 [  --enable-multipath=ARG  enable multipath function, ARG must be digit])
  95
  96 dnl AC_ARG_ENABLE(rtadv,
  97 dnl [  --enable-rtadv          enable IPV6 router advertisment option])
  98
  99 if test "${enable_broken_aliases}" = "yes"; then
 100   if test "${enable_netlink}" = "yes"
 101   then
 102     echo "Sorry, you can't use netlink with broken aliases"
 103     exit 1
 104   fi
 105   AC_DEFINE(HAVE_BROKEN_ALIASES)
 106   enable_netlink=no
 107 fi
 108
 109 if test "${enable_tcp_zebra}" = "yes"; then
 110   AC_DEFINE(HAVE_TCP_ZEBRA)
 111 fi
 112
 113 if test "${enable_nssa}" = "yes"; then
 114   AC_DEFINE(HAVE_NSSA)
 115 fi
 116
 117 if test "${enable_opaque_lsa}" = "yes"; then
 118   AC_DEFINE(HAVE_OPAQUE_LSA)
 119 fi
 120
 121 if test "${enable_ospf_te}" = "yes"; then
 122   AC_DEFINE(HAVE_OPAQUE_LSA)
 123   AC_DEFINE(HAVE_OSPF_TE)
 124 fi
 125
 126 dnl if test "${enable_rtadv}" = "yes"; then
 127 dnl   AC_DEFINE(HAVE_RTADV)
 128 dnl fi
 129
 130 changequote(, )dnl
 131
 132 MULTIPATH_NUM=1
 133
 134 case "${enable_multipath}" in
 135   [0-9]|[1-9][0-9])
 136     MULTIPATH_NUM="${enable_multipath}"
 137     ;;
 138   "")
 139     ;;
 140   *)
 141     echo "Please specify digit to --enable-multipath ARG."
 142     exit 1
 143     ;;
 144 esac
 145
 146 changequote([, ])dnl
 147
 148 AC_SUBST(MULTIPATH_NUM)
 149
 150 dnl -------------------
 151 dnl Check header files.
 152 dnl -------------------
 153 AC_STDC_HEADERS
 154 AC_CHECK_HEADERS(string.h stropts.h sys/conf.h sys/ksym.h sys/time.h sys/times.h sys/select.h sys/sysctl.h sys/sockio.h sys/types.h net/if_dl.h net/if_var.h linux/version.h kvm.h netdb.h netinet/in.h net/netopt.h netinet/in_var.h netinet/in6_var.h netinet/in6.h inet/nd.h asm/types.h netinet/icmp6.h netinet6/nd6.h libutil.h)
 155
 156 dnl check some types
 157 AC_C_CONST
 158 dnl AC_TYPE_PID_T
 159 AC_TYPE_SIGNAL
 160
 161 dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
 162 case "$host" in
 163   *-sunos5.6* | *-solaris2.6*)
 164       opsys=sol2-6
 165       AC_DEFINE(SUNOS_5)
 166       AC_CHECK_LIB(xnet, main)
 167       CURSES=-lcurses
 168   ;;
 169   *-sunos5* | *-solaris2*)
 170       AC_DEFINE(SUNOS_5)
 171       AC_CHECK_LIB(socket, main)
 172       AC_CHECK_LIB(nsl, main)
 173       CURSES=-lcurses
 174   ;;
 175   *-linux-*)
 176       opsys=gnu-linux
 177       AC_DEFINE(GNU_LINUX)
 178   ;;
 179   *-nec-sysv4*)
 180       AC_CHECK_LIB(nsl, gethostbyname)
 181       AC_CHECK_LIB(socket, socket)
 182   ;;
 183   *-freebsd3.2)
 184       AC_DEFINE(FREEBSD_32)
 185   ;;
 186   *-openbsd*)
 187       opsys=openbsd
 188       AC_DEFINE(OPEN_BSD)
 189   ;;
 190   *-bsdi*)
 191       opsys=bsdi
 192       OTHER_METHOD="mtu_kvm.o"
 193       AC_CHECK_LIB(kvm, main)
 194   ;;
 195 esac
 196
 197 case "${host_cpu}-${host_os}" in
 198   i?86-solaris*)
 199     AC_DEFINE(SOLARIS_X86)
 200   ;;
 201 esac
 202
 203 dnl ---------------------
 204 dnl Integrated VTY option
 205 dnl ---------------------
 206 case "${enable_vtysh}" in
 207   "yes") VTYSH="vtysh";
 208          AC_DEFINE(VTYSH)
 209          AC_CHECK_LIB(tinfo, tputs, , AC_CHECK_LIB(ncurses, tputs))
 210          AC_CHECK_LIB(readline, main)
 211          if test $ac_cv_lib_readline_main = no; then
 212            AC_MSG_ERROR([vtysh needs libreadline but was not found on your system.])
 213          fi
 214          AC_CHECK_HEADER(readline/history.h)
 215          if test $ac_cv_header_readline_history_h = no;then
 216            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 217          fi
 218          ;;
 219   "no" ) VTYSH="";;
 220   *    ) ;;
 221 esac
 222
 223 dnl ----------
 224 dnl PAM module
 225 dnl ----------
 226 if test "$with_libpam" = "yes"; then
 227 dnl took this test from proftpd's configure.in and suited to our needs
 228 dnl -------------------------------------------------------------------------
 229 dnl
 230 dnl This next check looks funky due to a linker problem with some versions
 231 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 232 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 233 dnl with RedHat 6.2 and Debian 2.2 or better.
 234 AC_CHECK_LIB(pam, pam_start,
 235   [AC_CHECK_LIB(pam, misc_conv,
 236     [AC_DEFINE(USE_PAM)
 237      LIBPAM="-lpam"],
 238     [AC_DEFINE(USE_PAM)
 239      LIBPAM="-lpam -lpam_misc"]
 240     )
 241   ],
 242
 243   [AC_CHECK_LIB(pam, pam_end,
 244     [AC_CHECK_LIB(pam, misc_conv,
 245       [AC_DEFINE(USE_PAM)
 246        LIBPAM="-lpam -ldl"],
 247       [AC_DEFINE(USE_PAM)
 248        LIBPAM="-lpam -ldl -lpam_misc"]
 249      )
 250   ],AC_MSG_WARN([*** pam support will not be built ***]),
 251   [-ldl])
 252   ]
 253 )
 254 fi
 255 AC_SUBST(LIBPAM)
 256
 257 dnl -------------------------------
 258 dnl Endian-ness check
 259 dnl -------------------------------
 260 AC_DEFUN(ZEBRA_AC_C_BIGENDIAN,
 261 [AC_CACHE_CHECK(whether byte ordering is bigendian, ac_cv_c_bigendian,
 262 [ac_cv_c_bigendian=unknown
 263 # See if sys/param.h defines the BYTE_ORDER macro.
 264 AC_TRY_COMPILE([#include <sys/types.h>
 265 #include <sys/param.h>], [
 266 #if !BYTE_ORDER || !BIG_ENDIAN || !LITTLE_ENDIAN
 267  bogus endian macros
 268 #endif], [# It does; now see whether it defined to BIG_ENDIAN or not.
 269 AC_TRY_COMPILE([#include <sys/types.h>
 270 #include <sys/param.h>], [
 271 #if BYTE_ORDER != BIG_ENDIAN
 272  not big endian
 273 #endif], ac_cv_c_bigendian=yes, ac_cv_c_bigendian=no)])
 274 if test $ac_cv_c_bigendian = unknown; then
 275 AC_TRY_RUN([main () {
 276   /* Are we little or big endian?  From Harbison&Steele.  */
 277   union
 278   {
 279     long l;
 280     char c[sizeof (long)];
 281   } u;
 282   u.l = 1;
 283   exit (u.c[sizeof (long) - 1] == 1);
 284 }], ac_cv_c_bigendian=no, ac_cv_c_bigendian=yes, ac_cv_c_bigendian=no)
 285 fi])
 286 if test $ac_cv_c_bigendian = yes; then
 287   AC_DEFINE(WORDS_BIGENDIAN,1,Big endian words)
 288 fi
 289 ])
 290
 291 dnl -------------------------------
 292 dnl check the size in byte of the C
 293 dnl -------------------------------
 294 dnl AC_CHECK_SIZEOF(char)
 295 dnl AC_CHECK_SIZEOF(int)
 296 dnl AC_CHECK_SIZEOF(short)
 297 dnl AC_CHECK_SIZEOF(long)
 298
 299 dnl ----------------------------
 300 dnl check existance of functions
 301 dnl ----------------------------
 302 AC_CHECK_FUNCS(bcopy bzero strerror inet_aton daemon snprintf vsnprintf strlcat strlcpy if_nametoindex if_indextoname getifaddrs)
 303 AC_CHECK_FUNCS(setproctitle, ,[AC_CHECK_LIB(util, setproctitle, [LIBS="$LIBS -lutil"; AC_DEFINE(HAVE_SETPROCTITLE)])])
 304
 305 dnl ------------------------------------
 306 dnl Determine routing get and set method
 307 dnl ------------------------------------
 308 AC_MSG_CHECKING(zebra between kernel interface method)
 309 if test x"$opsys" = x"gnu-linux"; then
 310   if test "${enable_netlink}" = "yes";then
 311     AC_MSG_RESULT(netlink)
 312     RT_METHOD=rt_netlink.o
 313     AC_DEFINE(HAVE_NETLINK)
 314     netlink=yes
 315   elif test "${enable_netlink}" = "no"; then
 316     AC_MSG_RESULT(ioctl)
 317     RT_METHOD=rt_ioctl.o
 318     netlink=no
 319   else
 320     AC_EGREP_CPP(yes,
 321     [#include <linux/autoconf.h>
 322 #include <linux/version.h>
 323 #if LINUX_VERSION_CODE > 131328  /* 2.1.0 or later */
 324 #ifdef CONFIG_RTNETLINK
 325   yes
 326 #endif
 327 #endif
 328 #if LINUX_VERSION_CODE > 132112  /* 2.4.17 or later */
 329   yes
 330 #endif
 331     ],
 332    [AC_MSG_RESULT(netlink)
 333     RT_METHOD=rt_netlink.o
 334     AC_DEFINE(HAVE_NETLINK)
 335     netlink=yes],
 336    [AC_MSG_RESULT(ioctl)
 337     RT_METHOD=rt_ioctl.o])
 338   fi
 339 else
 340   if test "$opsys" = "sol2-6";then
 341     AC_MSG_RESULT(solaris)
 342     KERNEL_METHOD="kernel_socket.o"
 343     RT_METHOD="rt_socket.o"
 344   else
 345     AC_TRY_RUN([#include <errno.h>
 346 #include <sys/types.h>
 347 #include <sys/socket.h>
 348
 349 main ()
 350 {
 351   int ac_sock;
 352
 353   ac_sock = socket (AF_ROUTE, SOCK_RAW, 0);
 354   if (ac_sock < 0 && errno == EINVAL)
 355     exit (1);
 356   exit (0);
 357 }],
 358   [AC_DEFINE(HAVE_AF_ROUTE)
 359    KERNEL_METHOD=kernel_socket.o
 360    RT_METHOD=rt_socket.o
 361    AC_MSG_RESULT(socket)],
 362   [RT_METHOD=rt_ioctl.o
 363    AC_MSG_RESULT(ioctl)],
 364   [KERNEL_METHOD=kernel_socket.o
 365    RT_METHOD=rt_socket.o
 366    AC_MSG_RESULT(socket)])
 367   fi
 368 fi
 369 AC_SUBST(RT_METHOD)
 370 AC_SUBST(KERNEL_METHOD)
 371 AC_SUBST(OTHER_METHOD)
 372
 373 dnl ------------------------------
 374 dnl check kernel route read method
 375 dnl ------------------------------
 376 AC_CACHE_CHECK(route read method check, zebra_rtread,
 377 [if test "$netlink" = yes; then
 378   RTREAD_METHOD="rtread_netlink.o"
 379   zebra_rtread="netlink"
 380 else
 381 for zebra_rtread in /proc/net/route /dev/ip /dev/null;
 382 do
 383   test x`ls $zebra_rtread 2>/dev/null` = x"$zebra_rtread" && break
 384 done
 385 case $zebra_rtread in
 386   "/proc/net/route") RTREAD_METHOD="rtread_proc.o"
 387                      zebra_rtread="proc";;
 388   "/dev/ip")         RTREAD_METHOD="rtread_getmsg.o"
 389                      zebra_rtread="getmsg";;
 390   *)                 RTREAD_METHOD="rtread_sysctl.o"
 391                      zebra_rtread="sysctl";;
 392 esac
 393 fi])
 394 AC_SUBST(RTREAD_METHOD)
 395
 396 dnl -----------------------------
 397 dnl check interface lookup method
 398 dnl -----------------------------
 399 AC_MSG_CHECKING(interface looking up method)
 400 if test "$netlink" = yes; then
 401   AC_MSG_RESULT(netlink)
 402   IF_METHOD=if_netlink.o
 403 else
 404   if test "$opsys" = "sol2-6";then
 405     AC_MSG_RESULT(solaris)
 406     IF_METHOD=if_ioctl.o
 407   elif test "$opsys" = "openbsd";then
 408     AC_MSG_RESULT(openbsd)
 409     IF_METHOD=if_ioctl.o
 410   elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
 411     AC_MSG_RESULT(sysctl)
 412     IF_METHOD=if_sysctl.o
 413     AC_DEFINE(HAVE_NET_RT_IFLIST)
 414   else
 415     AC_MSG_RESULT(ioctl)
 416     IF_METHOD=if_ioctl.o
 417   fi
 418 fi
 419 AC_SUBST(IF_METHOD)
 420
 421 dnl -----------------------
 422 dnl check proc file system.
 423 dnl -----------------------
 424 if test -r /proc/net/dev; then
 425   AC_DEFINE(HAVE_PROC_NET_DEV)
 426   IF_PROC=if_proc.o
 427 fi
 428
 429 if test -r /proc/net/if_inet6; then
 430   AC_DEFINE(HAVE_PROC_NET_IF_INET6)
 431   IF_PROC=if_proc.o
 432 fi
 433 AC_SUBST(IF_PROC)
 434
 435 dnl -----------------------------
 436 dnl check ipforward detect method
 437 dnl -----------------------------
 438 AC_CACHE_CHECK(ipforward method check, zebra_ipforward_path,
 439 [for zebra_ipforward_path in /proc/net/snmp /dev/ip /dev/null;
 440 do
 441   test x`ls $zebra_ipforward_path 2>/dev/null` = x"$zebra_ipforward_path" && break
 442 done
 443 case $zebra_ipforward_path in
 444   "/proc/net/snmp")  IPFORWARD=ipforward_proc.o
 445                      zebra_ipforward_path="proc";;
 446   "/dev/ip")
 447                      case "$host" in
 448                        *-nec-sysv4*)  IPFORWARD=ipforward_ews.o
 449                                       zebra_ipforward_path="ews";;
 450                        *)             IPFORWARD=ipforward_solaris.o
 451                                       zebra_ipforward_path="solaris";;
 452                      esac;;
 453   *)                 IPFORWARD=ipforward_sysctl.o
 454                      zebra_ipforward_path="sysctl";;
 455 esac])
 456 AC_SUBST(IPFORWARD)
 457
 458 AC_CHECK_FUNCS(getaddrinfo, [have_getaddrinfo=yes], [have_getaddrinfo=no])
 459
 460 dnl ----------
 461 dnl IPv6 check
 462 dnl ----------
 463 AC_MSG_CHECKING(whether does this OS have IPv6 stack)
 464 if test "${enable_ipv6}" = "no"; then
 465   AC_MSG_RESULT(disabled)
 466 else
 467 dnl ----------
 468 dnl INRIA IPv6
 469 dnl ----------
 470 if grep IPV6_INRIA_VERSION /usr/include/netinet/in.h >/dev/null 2>&1; then
 471    zebra_cv_ipv6=yes
 472    AC_DEFINE(HAVE_IPV6)
 473    AC_DEFINE(INRIA_IPV6)
 474    RIPNGD="ripngd"
 475    OSPF6D="ospf6d"
 476    LIB_IPV6=""
 477    AC_MSG_RESULT(INRIA IPv6)
 478 fi
 479 dnl ---------
 480 dnl KAME IPv6
 481 dnl ---------
 482 if grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
 483    zebra_cv_ipv6=yes
 484    AC_DEFINE(HAVE_IPV6)
 485    AC_DEFINE(KAME)
 486    RIPNGD="ripngd"
 487    OSPF6D="ospf6d"
 488    if test -d /usr/local/v6/lib -a -f /usr/local/v6/lib/libinet6.a; then
 489       LIB_IPV6="-L/usr/local/v6/lib -linet6"
 490    fi
 491    AC_MSG_RESULT(KAME)
 492 fi
 493 dnl ---------
 494 dnl NRL check
 495 dnl ---------
 496 if grep NRL /usr/include/netinet6/in6.h >/dev/null 2>&1; then
 497    zebra_cv_ipv6=yes
 498    AC_DEFINE(HAVE_IPV6)
 499    AC_DEFINE(NRL)
 500    RIPNGD="ripngd"
 501    OSPF6D="ospf6d"
 502    if test x"$opsys" = x"bsdi";then
 503       AC_DEFINE(BSDI_NRL)
 504       AC_MSG_RESULT(BSDI_NRL)
 505    else
 506       AC_MSG_RESULT(NRL)
 507    fi
 508 fi
 509
 510 dnl ----------
 511 dnl Linux IPv6
 512 dnl ----------
 513 if test "${enable_ipv6}" = "yes"; then
 514    AC_EGREP_CPP(yes, [
 515    #include <linux/version.h>
 516    /* 2.1.128 or later */
 517    #if LINUX_VERSION_CODE >= 0x020180
 518    yes
 519    #endif],
 520    [zebra_cv_ipv6=yes; zebra_cv_linux_ipv6=yes;AC_MSG_RESULT(Linux IPv6)])
 521 else
 522    if test x`ls /proc/net/ipv6_route 2>/dev/null` = x"/proc/net/ipv6_route"
 523    then
 524       zebra_cv_ipv6=yes
 525       zebra_cv_linux_ipv6=yes
 526       AC_MSG_RESULT(Linux IPv6)
 527    fi
 528 fi
 529
 530 if test "$zebra_cv_linux_ipv6" = "yes";then
 531    AC_DEFINE(HAVE_IPV6)
 532    AC_MSG_CHECKING(for GNU libc 2.1)
 533    AC_EGREP_CPP(yes, [
 534 #include <features.h>
 535 #if __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 536   yes
 537 #endif], [glibc=yes; AC_MSG_RESULT(yes)], AC_MSG_RESULT(no))
 538    AC_DEFINE(LINUX_IPV6)
 539    RIPNGD="ripngd"
 540    OSPF6D="ospf6d"
 541    if test "$glibc" != "yes"; then
 542       INCLUDES="-I/usr/inet6/include"
 543       if test x`ls /usr/inet6/lib/libinet6.a 2>/dev/null` != x;then
 544          LIB_IPV6="-L/usr/inet6/lib -linet6"
 545       fi
 546    fi
 547 fi
 548
 549 dnl -----------------------
 550 dnl Set IPv6 related values
 551 dnl -----------------------
 552 LIBS="$LIB_IPV6 $LIBS"
 553 AC_SUBST(LIB_IPV6)
 554
 555 if test x"$RIPNGD" = x""; then
 556   AC_MSG_RESULT(IPv4 only)
 557 fi
 558 fi
 559
 560 dnl --------------------
 561 dnl Daemon disable check
 562 dnl --------------------
 563 if test "${enable_zebra}" = "no";then
 564   ZEBRA=""
 565 else
 566   ZEBRA="zebra"
 567 fi
 568
 569 if test "${enable_bgpd}" = "no";then
 570   BGPD=""
 571 else
 572   BGPD="bgpd"
 573 fi
 574
 575 if test "${enable_ripd}" = "no";then
 576   RIPD=""
 577 else
 578   RIPD="ripd"
 579 fi
 580
 581 if test "${enable_ospfd}" = "no";then
 582   OSPFD=""
 583 else
 584   OSPFD="ospfd"
 585 fi
 586
 587 case "${enable_ripngd}" in
 588   "yes") RIPNGD="ripngd";;
 589   "no" ) RIPNGD="";;
 590   *    ) ;;
 591 esac
 592
 593 case "${enable_ospf6d}" in
 594   "yes") OSPF6D="ospf6d";;
 595   "no" ) OSPF6D="";;
 596   *    ) ;;
 597 esac
 598
 599 if test "${enable_bgp_announce}" = "no";then
 600   AC_DEFINE(DISABLE_BGP_ANNOUNCE)
 601 fi
 602
 603 AC_SUBST(ZEBRA)
 604 AC_SUBST(BGPD)
 605 AC_SUBST(RIPD)
 606 AC_SUBST(RIPNGD)
 607 AC_SUBST(OSPFD)
 608 AC_SUBST(OSPF6D)
 609 AC_SUBST(VTYSH)
 610 AC_SUBST(INCLUDES)
 611 AC_SUBST(CURSES)
 612 AC_CHECK_LIB(c, inet_ntop, [AC_DEFINE(HAVE_INET_NTOP)])
 613 AC_CHECK_LIB(c, inet_pton, [AC_DEFINE(HAVE_INET_PTON)])
 614 AC_CHECK_LIB(crypt, crypt)
 615 AC_CHECK_LIB(resolv, res_init)
 616 AC_CHECK_LIB(m, main)
 617
 618 dnl ---------------------------------------------------
 619 dnl BSD/OS 4.1 define inet_XtoY function as __inet_XtoY
 620 dnl ---------------------------------------------------
 621 AC_CHECK_FUNC(__inet_ntop, AC_DEFINE(HAVE_INET_NTOP))
 622 AC_CHECK_FUNC(__inet_pton, AC_DEFINE(HAVE_INET_PTON))
 623 AC_CHECK_FUNC(__inet_aton, AC_DEFINE(HAVE_INET_ATON))
 624
 625 dnl ---------------------------
 626 dnl check system has GNU regexp
 627 dnl ---------------------------
 628 dnl AC_MSG_CHECKING(whether system has GNU regex)
 629 AC_CHECK_LIB(c, regexec,
 630 [AC_DEFINE(HAVE_GNU_REGEX)
 631  LIB_REGEX=""],
 632 [LIB_REGEX="regex.o"])
 633 AC_SUBST(LIB_REGEX)
 634
 635 dnl AC_MSG_CHECKING(whether system has GNU regex)
 636 dnl if grep RE_NO_GNU_OPS /usr/include/regex.h >/dev/null 2>&1; then
 637 dnl   AC_MSG_RESULT(yes)
 638 dnl   AC_DEFINE(HAVE_GNU_REGEX)
 639 dnl   LIB_REGEX=""
 640 dnl else
 641 dnl   AC_MSG_RESULT(no)
 642 dnl   LIB_REGEX="regex.o"
 643 dnl fi
 644 dnl AC_SUBST(LIB_REGEX)
 645
 646 dnl ------------------
 647 dnl check SNMP library
 648 dnl ------------------
 649 if test "${enable_snmp}" = "yes";then
 650 dnl  AC_CHECK_LIB(snmp, asn_parse_int, HAVE_SNMP=yes)
 651   old_libs="${LIBS}"
 652   LIBS="-L/usr/local/lib"
 653   unset ac_cv_lib_snmp_asn_parse_int
 654   AC_CHECK_LIB(snmp, asn_parse_int, HAVE_SNMP=yes, )
 655   if test "${HAVE_SNMP}" = ""; then
 656     unset ac_cv_lib_snmp_asn_parse_int
 657     AC_CHECK_LIB(crypto, main, [NEED_CRYPTO=yes ], )
 658         if test "${NEED_CRYPTO}" = ""; then
 659                 AC_CHECK_LIB(snmp, asn_parse_int, [HAVE_SNMP=yes; NEED_CRYPTO=yes ],)
 660         else
 661             AC_CHECK_LIB(snmp, asn_parse_int, [HAVE_SNMP=yes; NEED_CRYPTO=yes;LIBS="$LIBS -lcrypto" ],,"-lcrypto")
 662         fi
 663   fi
 664   LIBS="${old_libs}"
 665
 666   if test "${HAVE_SNMP}" = ""; then
 667         old_libs="${LIBS}"
 668         LIBS="-L/usr/local/lib"
 669         AC_CHECK_LIB(snmp, asn_parse_int, HAVE_SNMP=yes)
 670         LIBS="${old_libs}"
 671   fi
 672   if test "${HAVE_SNMP}" = "yes"; then
 673     for ac_snmp in /usr/include/ucd-snmp/asn1.h /usr/local/include/ucd-snmp/asn1.h /dev/null
 674     do
 675       test -f "${ac_snmp}" && break
 676     done
 677     case ${ac_snmp} in
 678       /usr/include/ucd-snmp/*)
 679                   AC_DEFINE(HAVE_SNMP)
 680                   CFLAGS="${CFLAGS} -I/usr/include/ucd-snmp"
 681                   LIBS="${LIBS} -lsnmp"
 682                   ;;
 683       /usr/local/include/ucd-snmp/*)
 684                   AC_DEFINE(HAVE_SNMP)
 685                   CFLAGS="${CFLAGS} -I/usr/local/include/ucd-snmp"
 686                   LIBS="${LIBS} -L/usr/local/lib -lsnmp"
 687                   ;;
 688     esac
 689     if test "${NEED_CRYPTO}" = "yes"; then
 690       LIBS="${LIBS} -lcrypto"
 691     fi
 692   fi
 693 fi
 694
 695 dnl ----------------------------
 696 dnl check sa_len of sockaddr
 697 dnl ----------------------------
 698 AC_MSG_CHECKING(whether struct sockaddr has a sa_len field)
 699 AC_TRY_COMPILE([#include <sys/types.h>
 700 #include <sys/socket.h>
 701 ],[static struct sockaddr ac_i;int ac_j = sizeof (ac_i.sa_len);],
 702 [AC_MSG_RESULT(yes)
 703  AC_DEFINE(HAVE_SA_LEN)],
 704  AC_MSG_RESULT(no))
 705
 706 dnl ----------------------------
 707 dnl check sin_len of sockaddr_in
 708 dnl ----------------------------
 709 AC_MSG_CHECKING(whether struct sockaddr_in has a sin_len field)
 710 AC_TRY_COMPILE([#include <sys/types.h>
 711 #include <netinet/in.h>
 712 ],[static struct sockaddr_in ac_i;int ac_j = sizeof (ac_i.sin_len);],
 713 [AC_MSG_RESULT(yes)
 714  AC_DEFINE(HAVE_SIN_LEN)],
 715  AC_MSG_RESULT(no))
 716
 717 dnl ----------------------------
 718 dnl check sun_len of sockaddr_un
 719 dnl ----------------------------
 720 AC_MSG_CHECKING(whether struct sockaddr_un has a sun_len field)
 721 AC_TRY_COMPILE([#include <sys/types.h>
 722 #include <sys/un.h>
 723 ],[static struct sockaddr_un ac_i;int ac_j = sizeof (ac_i.sun_len);],
 724 [AC_MSG_RESULT(yes)
 725  AC_DEFINE(HAVE_SUN_LEN)],
 726  AC_MSG_RESULT(no))
 727
 728 dnl -----------------------------------
 729 dnl check sin6_scope_id of sockaddr_in6
 730 dnl -----------------------------------
 731 if test "$zebra_cv_ipv6" = yes; then
 732   AC_MSG_CHECKING(whether struct sockaddr_in6 has a sin6_scope_id field)
 733   AC_TRY_COMPILE([#include <sys/types.h>
 734 #include <netinet/in.h>
 735 ],[static struct sockaddr_in6 ac_i;int ac_j = sizeof (ac_i.sin6_scope_id);],
 736 [AC_MSG_RESULT(yes)
 737  AC_DEFINE(HAVE_SIN6_SCOPE_ID)],
 738  AC_MSG_RESULT(no))
 739 fi
 740
 741 dnl ----------------------------
 742 dnl check socklen_t exist or not
 743 dnl ----------------------------
 744 AC_MSG_CHECKING(whther socklen_t is defined)
 745 AC_TRY_COMPILE([#include <sys/types.h>
 746 #include <sys/socket.h>
 747 #include <netinet/in.h>
 748 ],[socklen_t ac_x;],
 749 [AC_MSG_RESULT(yes)
 750  AC_DEFINE(HAVE_SOCKLEN_T)],
 751  AC_MSG_RESULT(no))
 752
 753 dnl ------------------------
 754 dnl check struct sockaddr_dl
 755 dnl ------------------------
 756 AC_MSG_CHECKING(whether struct sockaddr_dl exist)
 757 AC_EGREP_HEADER(sockaddr_dl,
 758 net/if_dl.h,
 759 [AC_MSG_RESULT(yes)
 760  AC_DEFINE(HAVE_SOCKADDR_DL)],
 761  AC_MSG_RESULT(no))
 762
 763 dnl --------------------------
 764 dnl check structure ifaliasreq
 765 dnl --------------------------
 766 AC_MSG_CHECKING(whether struct ifaliasreq exist)
 767 AC_EGREP_HEADER(ifaliasreq,
 768 net/if.h,
 769 [AC_MSG_RESULT(yes)
 770  AC_DEFINE(HAVE_IFALIASREQ)],
 771  AC_MSG_RESULT(no))
 772
 773 dnl ----------------------------
 774 dnl check structure in6_aliasreq
 775 dnl ----------------------------
 776 AC_MSG_CHECKING(whether struct if6_aliasreq exist)
 777 AC_EGREP_HEADER(in6_aliasreq,
 778 netinet6/in6_var.h,
 779 [AC_MSG_RESULT(yes)
 780  AC_DEFINE(HAVE_IN6_ALIASREQ)],
 781  AC_MSG_RESULT(no))
 782
 783 dnl ---------------------------
 784 dnl check structure rt_addrinfo
 785 dnl ---------------------------
 786 AC_MSG_CHECKING(whether struct rt_addrinfo exist)
 787 AC_EGREP_HEADER(rt_addrinfo,
 788 net/route.h,
 789 [AC_MSG_RESULT(yes)
 790  AC_DEFINE(HAVE_RT_ADDRINFO)],
 791  AC_MSG_RESULT(no))
 792
 793 dnl --------------------------
 794 dnl check structure in_pktinfo
 795 dnl --------------------------
 796 AC_MSG_CHECKING(whether struct in_pktinfo exist)
 797 AC_TRY_COMPILE([#include <netinet/in.h>
 798 ],[struct in_pktinfo ac_x;],
 799 [AC_MSG_RESULT(yes)
 800  AC_DEFINE(HAVE_INPKTINFO)],
 801  AC_MSG_RESULT(no))
 802
 803 dnl --------------------------------------
 804 dnl checking for getrusage struct and call
 805 dnl --------------------------------------
 806 AC_MSG_CHECKING(whether getrusage is available)
 807 AC_TRY_COMPILE([#include <sys/resource.h>
 808 ],[struct rusage ac_x; getrusage (RUSAGE_SELF, &ac_x);],
 809 [AC_MSG_RESULT(yes)
 810  AC_DEFINE(HAVE_RUSAGE)],
 811  AC_MSG_RESULT(no))
 812
 813 dnl -------------
 814 dnl check version
 815 dnl -------------
 816 file="${srcdir}/lib/version.h"
 817 VERSION=`sed -ne 's/^#.*ZEBRA_VERSION.*\"\([^\"]*\)\"$/\1/p' $file`
 818 AC_SUBST(VERSION)
 819
 820 dnl ------------------------------
 821 dnl set paths for process id files
 822 dnl ------------------------------
 823 AC_CACHE_CHECK(pid file directory,ac_piddir,
 824 [for ZEBRA_PID_DIR in /var/run  dnl
 825                    /var/adm     dnl
 826                    /etc         dnl
 827                    /dev/null;
 828 do
 829   test -d $ZEBRA_PID_DIR && break
 830 done
 831 ac_piddir=$ZEBRA_PID_DIR
 832 if test $ZEBRA_PID_DIR = "/dev/null"; then
 833   echo "PID DIRECTORY NOT FOUND!"
 834 fi])
 835 AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$ac_piddir/zebra.pid")
 836 AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$ac_piddir/ripd.pid")
 837 AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$ac_piddir/ripngd.pid")
 838 AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$ac_piddir/bgpd.pid")
 839 AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$ac_piddir/ospfd.pid")
 840 AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$ac_piddir/ospf6d.pid")
 841
 842
 843 dnl ---------------------------
 844 dnl Check htonl works correctly
 845 dnl ---------------------------
 846 AC_MSG_CHECKING(for working htonl)
 847 AC_CACHE_VAL(ac_cv_htonl_works, [
 848 AC_TRY_LINK([#ifdef HAVE_SYS_TYPES_H
 849 #include <sys/types.h>
 850 #endif
 851 #ifdef HAVE_NETDB_H
 852 #include <netdb.h>
 853 #endif
 854 #ifdef HAVE_NETINET_IN_H
 855 #include <netinet/in.h>
 856 #endif],
 857 [htonl (0);],
 858 ac_cv_htonl_works=yes,
 859 ac_cv_htonl_works=no)])
 860 AC_MSG_RESULT($ac_cv_htonl_works)
 861
 862 AC_OUTPUT(Makefile lib/Makefile zebra/Makefile ripd/Makefile ripngd/Makefile bgpd/Makefile ospfd/Makefile ospf6d/Makefile vtysh/Makefile doc/Makefile)
 863
 864 echo "
 865 zebra configuration
 866 -------------------
 867 zebra version           : ${VERSION}
 868 host operationg system  : ${host_os}
 869 source code location    : ${srcdir}
 870 compiler                : ${CC}
 871 compiler flags          : ${CFLAGS}
 872 directory for pid files : ${ac_piddir}
 873 "