docs/meson.build

   1 if get_option('sphinx_build') == ''
   2   sphinx_build = find_program(['sphinx-build-3', 'sphinx-build'],
   3                               required: get_option('docs'))
   4 else
   5   sphinx_build = find_program(get_option('sphinx_build'),
   6                               required: get_option('docs'))
   7 endif
   8
   9 # Check if tools are available to build documentation.
  10 build_docs = false
  11 if sphinx_build.found()
  12   SPHINX_ARGS = [sphinx_build]
  13   # If we're making warnings fatal, apply this to Sphinx runs as well
  14   if get_option('werror')
  15     SPHINX_ARGS += [ '-W' ]
  16   endif
  17
  18   # This is a bit awkward but works: create a trivial document and
  19   # try to run it with our configuration file (which enforces a
  20   # version requirement). This will fail if sphinx-build is too old.
  21   run_command('mkdir', ['-p', tmpdir / 'sphinx'])
  22   run_command('touch', [tmpdir / 'sphinx/index.rst'])
  23   sphinx_build_test_out = run_command(SPHINX_ARGS + [
  24     '-c', meson.current_source_dir(),
  25     '-b', 'html', tmpdir / 'sphinx',
  26     tmpdir / 'sphinx/out'])
  27   build_docs = (sphinx_build_test_out.returncode() == 0)
  28
  29   if not build_docs
  30     warning('@0@ is either too old or uses too old a Python version'
  31             .format(sphinx_build.full_path()))
  32     if get_option('docs').enabled()
  33       error('Install a Python 3 version of python-sphinx')
  34     endif
  35   endif
  36 endif
  37
  38 if build_docs
  39   SPHINX_ARGS += ['-Dversion=' + meson.project_version(), '-Drelease=' + config_host['PKGVERSION']]
  40
  41   sphinx_extn_depends = [ meson.source_root() / 'docs/sphinx/depfile.py',
  42                           meson.source_root() / 'docs/sphinx/hxtool.py',
  43                           meson.source_root() / 'docs/sphinx/kerneldoc.py',
  44                           meson.source_root() / 'docs/sphinx/kernellog.py',
  45                           meson.source_root() / 'docs/sphinx/qapidoc.py',
  46                           meson.source_root() / 'docs/sphinx/qmp_lexer.py',
  47                           qapi_gen_depends ]
  48
  49   configure_file(output: 'index.html',
  50                  input: files('index.html.in'),
  51                  configuration: {'VERSION': meson.project_version()},
  52                  install_dir: qemu_docdir)
  53   manuals = [ 'devel', 'interop', 'tools', 'specs', 'system', 'user' ]
  54   man_pages = {
  55     'interop' : {
  56         'qemu-ga.8': (have_tools ? 'man8' : ''),
  57         'qemu-ga-ref.7': 'man7',
  58         'qemu-qmp-ref.7': 'man7',
  59     },
  60     'tools': {
  61         'qemu-img.1': (have_tools ? 'man1' : ''),
  62         'qemu-nbd.8': (have_tools ? 'man8' : ''),
  63         'qemu-trace-stap.1': (config_host.has_key('CONFIG_TRACE_SYSTEMTAP') ? 'man1' : ''),
  64         'virtfs-proxy-helper.1': (have_virtfs_proxy_helper ? 'man1' : ''),
  65         'virtiofsd.1': (have_virtiofsd ? 'man1' : ''),
  66     },
  67     'system': {
  68         'qemu.1': 'man1',
  69         'qemu-block-drivers.7': 'man7',
  70         'qemu-cpu-models.7': 'man7'
  71     },
  72   }
  73
  74   sphinxdocs = []
  75   sphinxmans = []
  76   foreach manual : manuals
  77     private_dir = meson.current_build_dir() / (manual + '.p')
  78     output_dir = meson.current_build_dir() / manual
  79     input_dir = meson.current_source_dir() / manual
  80
  81     this_manual = custom_target(manual + ' manual',
  82                 build_by_default: build_docs,
  83                 output: [manual + '.stamp'],
  84                 input: [files('conf.py'), files(manual / 'conf.py')],
  85                 depfile: manual + '.d',
  86                 depend_files: sphinx_extn_depends,
  87                 command: [SPHINX_ARGS, '-Ddepfile=@DEPFILE@',
  88                           '-Ddepfile_stamp=@OUTPUT0@',
  89                           '-b', 'html', '-d', private_dir,
  90                           input_dir, output_dir])
  91     sphinxdocs += this_manual
  92     if build_docs and manual != 'devel'
  93       install_subdir(output_dir, install_dir: qemu_docdir)
  94     endif
  95
  96     these_man_pages = []
  97     install_dirs = []
  98     foreach page, section : man_pages.get(manual, {})
  99       these_man_pages += page
 100       install_dirs += section == '' ? false : get_option('mandir') / section
 101     endforeach
 102     if these_man_pages.length() > 0
 103       sphinxmans += custom_target(manual + ' man pages',
 104                          build_by_default: build_docs,
 105                          output: these_man_pages,
 106                          input: this_manual,
 107                          install: build_docs,
 108                          install_dir: install_dirs,
 109                          command: [SPHINX_ARGS, '-b', 'man', '-d', private_dir,
 110                                    input_dir, meson.current_build_dir()])
 111     endif
 112   endforeach
 113   alias_target('sphinxdocs', sphinxdocs)
 114   alias_target('html', sphinxdocs)
 115   alias_target('man', sphinxmans)
 116 endif