elf_aarch64_efi.lds

   1 OUTPUT_FORMAT("elf64-littleaarch64", "elf64-littleaarch64", "elf64-littleaarch64")
   2 OUTPUT_ARCH(aarch64)
   3 ENTRY(_start)
   4 SECTIONS
   5 {
   6   .text 0x0 : {
   7     _text = .;
   8     *(.text.head)
   9     *(.text)
  10     *(.text.*)
  11     *(.gnu.linkonce.t.*)
  12     *(.srodata)
  13     *(.rodata*)
  14     . = ALIGN(16);
  15     _etext = .;
  16   }
  17
  18   . = ALIGN(4096);
  19   .dynamic  : { *(.dynamic) }
  20
  21   . = ALIGN(4096);
  22   .note.gnu.build-id : {
  23     *(.note.gnu.build-id)
  24   }
  25
  26   . = ALIGN(4096);
  27   .data.ident : {
  28     *(.data.ident)
  29   }
  30
  31   . = ALIGN(4096);
  32   .data :
  33   {
  34    _data = .;
  35    *(.sdata)
  36    *(.data)
  37    *(.data1)
  38    *(.data.*)
  39    *(.got.plt)
  40    *(.got)
  41
  42    /* the EFI loader doesn't seem to like a .bss section, so we stick
  43       it all into .data: */
  44    . = ALIGN(16);
  45    _bss = .;
  46    *(.sbss)
  47    *(.scommon)
  48    *(.dynbss)
  49    *(.bss)
  50    *(COMMON)
  51    . = ALIGN(16);
  52    _bss_end = .;
  53   }
  54
  55   . = ALIGN(4096);
  56   .vendor_cert :
  57   {
  58     *(.vendor_cert)
  59   }
  60   . = ALIGN(4096);
  61   .sbat :
  62   {
  63     _sbat = .;
  64     *(.sbat)
  65     *(.sbat.*)
  66     _esbat = .;
  67   }
  68   . = ALIGN(4096);
  69   .rela :
  70   {
  71     *(.rela.dyn)
  72     *(.rela.plt)
  73     *(.rela.got)
  74     *(.rela.data)
  75     *(.rela.data*)
  76   }
  77   _edata = .;
  78   _data_size = . - _data;
  79
  80   . = ALIGN(4096);
  81   .dynsym   : { *(.dynsym) }
  82   . = ALIGN(4096);
  83   .dynstr   : { *(.dynstr) }
  84   . = ALIGN(4096);
  85   /DISCARD/ :
  86   {
  87     *(.rel.reloc)
  88     *(.eh_frame)
  89     *(.note.GNU-stack)
  90   }
  91   .comment 0 : { *(.comment) }
  92 }