elf_arm_efi.lds

   1 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
   2 OUTPUT_ARCH(arm)
   3 ENTRY(_start)
   4 SECTIONS
   5 {
   6   .text 0x0 : {
   7     *(.text.head)
   8     *(.text)
   9     *(.text.*)
  10     *(.gnu.linkonce.t.*)
  11     *(.srodata)
  12     *(.rodata*)
  13     . = ALIGN(16);
  14     _etext = .;
  15   }
  16   .dynamic  : { *(.dynamic) }
  17   .data :
  18   {
  19    *(.sdata)
  20    *(.data)
  21    *(.data1)
  22    *(.data*)
  23    *(.got.plt)
  24    *(.got)
  25
  26    /* the EFI loader doesn't seem to like a .bss section, so we stick
  27       it all into .data: */
  28    . = ALIGN(16);
  29    _bss = .;
  30    *(.sbss)
  31    *(.scommon)
  32    *(.dynbss)
  33    *(.bss)
  34    *(COMMON)
  35    . = ALIGN(16);
  36    _bss_end = .;
  37   }
  38
  39    . = ALIGN(4096);
  40   .vendor_cert :
  41   {
  42     *(.vendor_cert)
  43   }
  44   . = ALIGN(4096);
  45
  46   .rel.dyn : { *(.rel.dyn) }
  47   .rel.plt : { *(.rel.plt) }
  48   .rel.got : { *(.rel.got) }
  49   .rel.data : { *(.rel.data) *(.rel.data*) }
  50   _edata = .;
  51   _data_size = . - _etext;
  52
  53   . = ALIGN(4096);
  54   .dynsym   : { *(.dynsym) }
  55   . = ALIGN(4096);
  56   .dynstr   : { *(.dynstr) }
  57   . = ALIGN(4096);
  58   /DISCARD/ :
  59   {
  60     *(.rel.reloc)
  61     *(.eh_frame)
  62     *(.note.GNU-stack)
  63   }
  64   .comment 0 : { *(.comment) }
  65 }