elf_arm_efi.lds

   1 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
   2 OUTPUT_ARCH(arm)
   3 ENTRY(_start)
   4 SECTIONS
   5 {
   6   .text 0x0 : {
   7     _text = .;
   8     *(.text.head)
   9     *(.text)
  10     *(.text.*)
  11     *(.gnu.linkonce.t.*)
  12     *(.srodata)
  13     *(.rodata*)
  14     . = ALIGN(16);
  15     _etext = .;
  16   }
  17   .dynamic  : { *(.dynamic) }
  18   .data :
  19   {
  20    _data = .;
  21    *(.sdata)
  22    *(.data)
  23    *(.data1)
  24    *(.data*)
  25    *(.got.plt)
  26    *(.got)
  27
  28    /* the EFI loader doesn't seem to like a .bss section, so we stick
  29       it all into .data: */
  30    . = ALIGN(16);
  31    _bss = .;
  32    *(.sbss)
  33    *(.scommon)
  34    *(.dynbss)
  35    *(.bss)
  36    *(COMMON)
  37    . = ALIGN(16);
  38    _bss_end = .;
  39   }
  40   .note.gnu.build-id : { *(.note.gnu.build-id) }
  41
  42    . = ALIGN(4096);
  43   .vendor_cert :
  44   {
  45     *(.vendor_cert)
  46   }
  47   . = ALIGN(4096);
  48
  49   .rel.dyn : { *(.rel.dyn) }
  50   .rel.plt : { *(.rel.plt) }
  51   .rel.got : { *(.rel.got) }
  52   .rel.data : { *(.rel.data) *(.rel.data*) }
  53   _edata = .;
  54   _data_size = . - _data;
  55
  56   . = ALIGN(4096);
  57   .dynsym   : { *(.dynsym) }
  58   . = ALIGN(4096);
  59   .dynstr   : { *(.dynstr) }
  60   . = ALIGN(4096);
  61   /DISCARD/ :
  62   {
  63     *(.rel.reloc)
  64     *(.eh_frame)
  65     *(.note.GNU-stack)
  66   }
  67   .comment 0 : { *(.comment) }
  68 }