elf_ia32_efi.lds

   1 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
   2 OUTPUT_ARCH(i386)
   3 ENTRY(_start)
   4 SECTIONS
   5 {
   6   . = 0;
   7   ImageBase = .;
   8   .hash : { *(.hash) }  /* this MUST come first! */
   9   . = ALIGN(4096);
  10   .text :
  11   {
  12    _text = .;
  13    *(.text)
  14    *(.text.*)
  15    *(.gnu.linkonce.t.*)
  16    _etext = .;
  17   }
  18   . = ALIGN(4096);
  19   .reloc :
  20   {
  21    *(.reloc)
  22   }
  23   . = ALIGN(4096);
  24   .note.gnu.build-id : {
  25     *(.note.gnu.build-id)
  26   }
  27   . = ALIGN(4096);
  28   .data.ident : {
  29     *(.data.ident)
  30   }
  31
  32   . = ALIGN(4096);
  33   .data :
  34   {
  35    _data = .;
  36    *(.rodata*)
  37    *(.data)
  38    *(.data1)
  39    *(.data.*)
  40    *(.sdata)
  41    *(.got.plt)
  42    *(.got)
  43    /* the EFI loader doesn't seem to like a .bss section, so we stick
  44       it all into .data: */
  45    *(.sbss)
  46    *(.scommon)
  47    *(.dynbss)
  48    *(.bss)
  49    *(COMMON)
  50   }
  51
  52   . = ALIGN(4096);
  53   .vendor_cert :
  54   {
  55    *(.vendor_cert)
  56   }
  57   . = ALIGN(4096);
  58   .dynamic  : { *(.dynamic) }
  59   . = ALIGN(4096);
  60   .rel :
  61   {
  62     *(.rel.data)
  63     *(.rel.data.*)
  64     *(.rel.got)
  65     *(.rel.stab)
  66     *(.data.rel.ro.local)
  67     *(.data.rel.local)
  68     *(.data.rel.ro)
  69     *(.data.rel*)
  70   }
  71   _edata = .;
  72   _data_size = . - _data;
  73   . = ALIGN(4096);
  74   .sbat :
  75   {
  76     _sbat = .;
  77     *(.sbat)
  78     *(.sbat.*)
  79   }
  80   _esbat = .;
  81   _sbat_size = . - _sbat;
  82
  83   . = ALIGN(4096);
  84   .dynsym   : { *(.dynsym) }
  85   . = ALIGN(4096);
  86   .dynstr   : { *(.dynstr) }
  87   . = ALIGN(4096);
  88   /DISCARD/ :
  89   {
  90     *(.rel.reloc)
  91     *(.eh_frame)
  92     *(.note.GNU-stack)
  93   }
  94   .comment 0 : { *(.comment) }
  95 }