elf_ia32_efi.lds

   1 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
   2 OUTPUT_ARCH(i386)
   3 ENTRY(_start)
   4 SECTIONS
   5 {
   6   . = 0;
   7   ImageBase = .;
   8   .hash : { *(.hash) }  /* this MUST come first! */
   9   . = ALIGN(4096);
  10   .text :
  11   {
  12    _text = .;
  13    *(.text)
  14    *(.text.*)
  15    *(.gnu.linkonce.t.*)
  16    _etext = .;
  17   }
  18   .reloc :
  19   {
  20    *(.reloc)
  21   }
  22   . = ALIGN(4096);
  23   .note.gnu.build-id : {
  24     *(.note.gnu.build-id)
  25   }
  26   . = ALIGN(4096);
  27   .data.ident : {
  28     *(.data.ident)
  29   }
  30
  31   . = ALIGN(4096);
  32   .data :
  33   {
  34    _data = .;
  35    *(.rodata*)
  36    *(.data)
  37    *(.data1)
  38    *(.data.*)
  39    *(.sdata)
  40    *(.got.plt)
  41    *(.got)
  42    /* the EFI loader doesn't seem to like a .bss section, so we stick
  43       it all into .data: */
  44    *(.sbss)
  45    *(.scommon)
  46    *(.dynbss)
  47    *(.bss)
  48    *(COMMON)
  49   }
  50
  51   . = ALIGN(4096);
  52   .vendor_cert :
  53   {
  54    *(.vendor_cert)
  55   }
  56   . = ALIGN(4096);
  57   .sbat :
  58   {
  59     _sbat = .;
  60     *(.sbat)
  61     *(.sbat.*)
  62     _esbat = .;
  63   }
  64   . = ALIGN(4096);
  65   .dynamic  : { *(.dynamic) }
  66   . = ALIGN(4096);
  67   .rel :
  68   {
  69     *(.rel.data)
  70     *(.rel.data.*)
  71     *(.rel.got)
  72     *(.rel.stab)
  73     *(.data.rel.ro.local)
  74     *(.data.rel.local)
  75     *(.data.rel.ro)
  76     *(.data.rel*)
  77   }
  78   _edata = .;
  79   _data_size = . - _data;
  80   . = ALIGN(4096);
  81   .dynsym   : { *(.dynsym) }
  82   . = ALIGN(4096);
  83   .dynstr   : { *(.dynstr) }
  84   . = ALIGN(4096);
  85   /DISCARD/ :
  86   {
  87     *(.rel.reloc)
  88     *(.eh_frame)
  89     *(.note.GNU-stack)
  90   }
  91   .comment 0 : { *(.comment) }
  92 }