elf_ia32_efi.lds

   1 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
   2 OUTPUT_ARCH(i386)
   3 ENTRY(_start)
   4 SECTIONS
   5 {
   6   . = 0;
   7   ImageBase = .;
   8   .hash : { *(.hash) }  /* this MUST come first! */
   9   . = ALIGN(4096);
  10   .text :
  11   {
  12    _text = .;
  13    *(.text)
  14    *(.text.*)
  15    *(.gnu.linkonce.t.*)
  16    _etext = .;
  17   }
  18   .reloc :
  19   {
  20    *(.reloc)
  21   }
  22   . = ALIGN(4096);
  23   .note.gnu.build-id : {
  24     *(.note.gnu.build-id)
  25   }
  26   . = ALIGN(4096);
  27   .data.ident : {
  28     *(.data.ident)
  29   }
  30
  31   . = ALIGN(4096);
  32   .data :
  33   {
  34    _data = .;
  35    *(.rodata*)
  36    *(.data)
  37    *(.data1)
  38    *(.data.*)
  39    *(.sdata)
  40    *(.got.plt)
  41    *(.got)
  42    /* the EFI loader doesn't seem to like a .bss section, so we stick
  43       it all into .data: */
  44    *(.sbss)
  45    *(.scommon)
  46    *(.dynbss)
  47    *(.bss)
  48    *(COMMON)
  49   }
  50
  51   . = ALIGN(4096);
  52   .vendor_cert :
  53   {
  54    *(.vendor_cert)
  55   }
  56   . = ALIGN(4096);
  57   .dynamic  : { *(.dynamic) }
  58   . = ALIGN(4096);
  59   .rel :
  60   {
  61     *(.rel.data)
  62     *(.rel.data.*)
  63     *(.rel.got)
  64     *(.rel.stab)
  65     *(.data.rel.ro.local)
  66     *(.data.rel.local)
  67     *(.data.rel.ro)
  68     *(.data.rel*)
  69   }
  70   _edata = .;
  71   _data_size = . - _data;
  72   . = ALIGN(4096);
  73   .sbat :
  74   {
  75     _sbat = .;
  76     *(.sbat)
  77     *(.sbat.*)
  78   }
  79   _esbat = .;
  80   _sbat_size = . - _sbat;
  81
  82   . = ALIGN(4096);
  83   .dynsym   : { *(.dynsym) }
  84   . = ALIGN(4096);
  85   .dynstr   : { *(.dynstr) }
  86   . = ALIGN(4096);
  87   /DISCARD/ :
  88   {
  89     *(.rel.reloc)
  90     *(.eh_frame)
  91     *(.note.GNU-stack)
  92   }
  93   .comment 0 : { *(.comment) }
  94 }