grub-core/lib/i386/setjmp.S

   1 /*
   2  *  GRUB  --  GRand Unified Bootloader
   3  *  Copyright (C) 2003,2007  Free Software Foundation, Inc.
   4  *
   5  *  GRUB is free software: you can redistribute it and/or modify
   6  *  it under the terms of the GNU General Public License as published by
   7  *  the Free Software Foundation, either version 3 of the License, or
   8  *  (at your option) any later version.
   9  *
  10  *  GRUB is distributed in the hope that it will be useful,
  11  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  *  GNU General Public License for more details.
  14  *
  15  *  You should have received a copy of the GNU General Public License
  16  *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 #include <grub/symbol.h>
  20 #include <grub/dl.h>
  21
  22         .file   "setjmp.S"
  23
  24 GRUB_MOD_LICENSE "GPLv3+"
  25
  26         .text
  27
  28 /*
  29  * int grub_setjmp (grub_jmp_buf env)
  30  */
  31 FUNCTION(grub_setjmp)
  32         movl    %ebx, 0(%eax)   /* EBX */
  33         movl    %esi, 4(%eax)   /* ESI */
  34         movl    %edi, 8(%eax)   /* EDI */
  35         movl    %ebp, 12(%eax)  /* EBP */
  36         popl    %ecx
  37         movl    %esp, 16(%eax)  /* ESP */
  38         movl    %ecx, 20(%eax)  /* EIP */
  39         xorl    %eax, %eax
  40         jmp     *%ecx
  41
  42
  43 /*
  44  * int grub_longjmp (grub_jmp_buf env, int val)
  45  */
  46 FUNCTION(grub_longjmp)
  47         movl    0(%eax), %ebx
  48         movl    4(%eax), %esi
  49         movl    8(%eax), %edi
  50         movl    12(%eax), %ebp
  51         movl    16(%eax), %esp
  52         movl    20(%eax), %ecx
  53
  54         movl    %edx, %eax
  55         testl   %eax, %eax
  56         jnz     1f
  57         incl    %eax
  58 1:      jmp     *%ecx
  59