hw/i386/acpi-dsdt-cpu-hotplug.dsl

   1 /*
   2  * This program is free software; you can redistribute it and/or modify
   3  * it under the terms of the GNU General Public License as published by
   4  * the Free Software Foundation; either version 2 of the License, or
   5  * (at your option) any later version.
   6
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11
  12  * You should have received a copy of the GNU General Public License along
  13  * with this program; if not, see <http://www.gnu.org/licenses/>.
  14  */
  15
  16 /****************************************************************
  17  * CPU hotplug
  18  ****************************************************************/
  19
  20 Scope(\_SB) {
  21     /* Objects filled in by run-time generated SSDT */
  22     External(NTFY, MethodObj)
  23     External(CPON, PkgObj)
  24     External(PRS, FieldUnitObj)
  25
  26     /* Methods called by run-time generated SSDT Processor objects */
  27     Method(CPMA, 1, NotSerialized) {
  28         // _MAT method - create an madt apic buffer
  29         // Arg0 = Processor ID = Local APIC ID
  30         // Local0 = CPON flag for this cpu
  31         Store(DerefOf(Index(CPON, Arg0)), Local0)
  32         // Local1 = Buffer (in madt apic form) to return
  33         Store(Buffer(8) {0x00, 0x08, 0x00, 0x00, 0x00, 0, 0, 0}, Local1)
  34         // Update the processor id, lapic id, and enable/disable status
  35         Store(Arg0, Index(Local1, 2))
  36         Store(Arg0, Index(Local1, 3))
  37         Store(Local0, Index(Local1, 4))
  38         Return (Local1)
  39     }
  40     Method(CPST, 1, NotSerialized) {
  41         // _STA method - return ON status of cpu
  42         // Arg0 = Processor ID = Local APIC ID
  43         // Local0 = CPON flag for this cpu
  44         Store(DerefOf(Index(CPON, Arg0)), Local0)
  45         If (Local0) {
  46             Return (0xF)
  47         } Else {
  48             Return (0x0)
  49         }
  50     }
  51     Method(CPEJ, 2, NotSerialized) {
  52         // _EJ0 method - eject callback
  53         Sleep(200)
  54     }
  55
  56 #define CPU_STATUS_LEN ACPI_GPE_PROC_LEN
  57     Method(PRSC, 0) {
  58         // Local5 = active cpu bitmap
  59         Store(PRS, Local5)
  60         // Local2 = last read byte from bitmap
  61         Store(Zero, Local2)
  62         // Local0 = Processor ID / APIC ID iterator
  63         Store(Zero, Local0)
  64         While (LLess(Local0, SizeOf(CPON))) {
  65             // Local1 = CPON flag for this cpu
  66             Store(DerefOf(Index(CPON, Local0)), Local1)
  67             If (And(Local0, 0x07)) {
  68                 // Shift down previously read bitmap byte
  69                 ShiftRight(Local2, 1, Local2)
  70             } Else {
  71                 // Read next byte from cpu bitmap
  72                 Store(DerefOf(Index(Local5, ShiftRight(Local0, 3))), Local2)
  73             }
  74             // Local3 = active state for this cpu
  75             Store(And(Local2, 1), Local3)
  76
  77             If (LNotEqual(Local1, Local3)) {
  78                 // State change - update CPON with new state
  79                 Store(Local3, Index(CPON, Local0))
  80                 // Do CPU notify
  81                 If (LEqual(Local3, 1)) {
  82                     NTFY(Local0, 1)
  83                 } Else {
  84                     NTFY(Local0, 3)
  85                 }
  86             }
  87             Increment(Local0)
  88         }
  89     }
  90 }