]> git.proxmox.com Git - mirror_ubuntu-bionic-kernel.git/blob - include/asm-generic/vmlinux.lds.h
projects / mirror_ubuntu-bionic-kernel.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
Merge remote-tracking branches 'spi/topic/devprop', 'spi/topic/fsl', 'spi/topic/fsl...
[mirror_ubuntu-bionic-kernel.git] / include / asm-generic / vmlinux.lds.h
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53 #ifndef LOAD_OFFSET
54 #define LOAD_OFFSET 0
55 #endif
56
57 #include <linux/export.h>
58
59 /* Align . to a 8 byte boundary equals to maximum function alignment. */
60 #define ALIGN_FUNCTION() . = ALIGN(8)
61
62 /*
63 * Align to a 32 byte boundary equal to the
64 * alignment gcc 4.5 uses for a struct
65 */
66 #define STRUCT_ALIGNMENT 32
67 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
68
69 /* The actual configuration determine if the init/exit sections
70 * are handled as text/data or they can be discarded (which
71 * often happens at runtime)
72 */
73 #ifdef CONFIG_HOTPLUG_CPU
74 #define CPU_KEEP(sec) *(.cpu##sec)
75 #define CPU_DISCARD(sec)
76 #else
77 #define CPU_KEEP(sec)
78 #define CPU_DISCARD(sec) *(.cpu##sec)
79 #endif
80
81 #if defined(CONFIG_MEMORY_HOTPLUG)
82 #define MEM_KEEP(sec) *(.mem##sec)
83 #define MEM_DISCARD(sec)
84 #else
85 #define MEM_KEEP(sec)
86 #define MEM_DISCARD(sec) *(.mem##sec)
87 #endif
88
89 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
90 #define MCOUNT_REC() . = ALIGN(8); \
91 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
92 *(__mcount_loc) \
93 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
94 #else
95 #define MCOUNT_REC()
96 #endif
97
98 #ifdef CONFIG_TRACE_BRANCH_PROFILING
99 #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
100 *(_ftrace_annotated_branch) \
101 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
102 #else
103 #define LIKELY_PROFILE()
104 #endif
105
106 #ifdef CONFIG_PROFILE_ALL_BRANCHES
107 #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
108 *(_ftrace_branch) \
109 VMLINUX_SYMBOL(__stop_branch_profile) = .;
110 #else
111 #define BRANCH_PROFILE()
112 #endif
113
114 #ifdef CONFIG_KPROBES
115 #define KPROBE_BLACKLIST() . = ALIGN(8); \
116 VMLINUX_SYMBOL(__start_kprobe_blacklist) = .; \
117 KEEP(*(_kprobe_blacklist)) \
118 VMLINUX_SYMBOL(__stop_kprobe_blacklist) = .;
119 #else
120 #define KPROBE_BLACKLIST()
121 #endif
122
123 #ifdef CONFIG_EVENT_TRACING
124 #define FTRACE_EVENTS() . = ALIGN(8); \
125 VMLINUX_SYMBOL(__start_ftrace_events) = .; \
126 KEEP(*(_ftrace_events)) \
127 VMLINUX_SYMBOL(__stop_ftrace_events) = .; \
128 VMLINUX_SYMBOL(__start_ftrace_enum_maps) = .; \
129 KEEP(*(_ftrace_enum_map)) \
130 VMLINUX_SYMBOL(__stop_ftrace_enum_maps) = .;
131 #else
132 #define FTRACE_EVENTS()
133 #endif
134
135 #ifdef CONFIG_TRACING
136 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
137 KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
138 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
139 #define TRACEPOINT_STR() VMLINUX_SYMBOL(__start___tracepoint_str) = .; \
140 KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
141 VMLINUX_SYMBOL(__stop___tracepoint_str) = .;
142 #else
143 #define TRACE_PRINTKS()
144 #define TRACEPOINT_STR()
145 #endif
146
147 #ifdef CONFIG_FTRACE_SYSCALLS
148 #define TRACE_SYSCALLS() . = ALIGN(8); \
149 VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
150 KEEP(*(__syscalls_metadata)) \
151 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
152 #else
153 #define TRACE_SYSCALLS()
154 #endif
155
156 #ifdef CONFIG_SERIAL_EARLYCON
157 #define EARLYCON_TABLE() STRUCT_ALIGN(); \
158 VMLINUX_SYMBOL(__earlycon_table) = .; \
159 KEEP(*(__earlycon_table)) \
160 VMLINUX_SYMBOL(__earlycon_table_end) = .;
161 #else
162 #define EARLYCON_TABLE()
163 #endif
164
165 #define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
166 #define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
167 #define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
168 #define _OF_TABLE_0(name)
169 #define _OF_TABLE_1(name) \
170 . = ALIGN(8); \
171 VMLINUX_SYMBOL(__##name##_of_table) = .; \
172 KEEP(*(__##name##_of_table)) \
173 KEEP(*(__##name##_of_table_end))
174
175 #define CLKSRC_OF_TABLES() OF_TABLE(CONFIG_CLKSRC_OF, clksrc)
176 #define CLKEVT_OF_TABLES() OF_TABLE(CONFIG_CLKEVT_OF, clkevt)
177 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
178 #define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
179 #define IOMMU_OF_TABLES() OF_TABLE(CONFIG_OF_IOMMU, iommu)
180 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
181 #define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
182 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
183
184 #ifdef CONFIG_ACPI
185 #define ACPI_PROBE_TABLE(name) \
186 . = ALIGN(8); \
187 VMLINUX_SYMBOL(__##name##_acpi_probe_table) = .; \
188 KEEP(*(__##name##_acpi_probe_table)) \
189 VMLINUX_SYMBOL(__##name##_acpi_probe_table_end) = .;
190 #else
191 #define ACPI_PROBE_TABLE(name)
192 #endif
193
194 #define KERNEL_DTB() \
195 STRUCT_ALIGN(); \
196 VMLINUX_SYMBOL(__dtb_start) = .; \
197 KEEP(*(.dtb.init.rodata)) \
198 VMLINUX_SYMBOL(__dtb_end) = .;
199
200 /*
201 * .data section
202 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections generates
203 * .data.identifier which needs to be pulled in with .data, but don't want to
204 * pull in .data..stuff which has its own requirements. Same for bss.
205 */
206 #define DATA_DATA \
207 *(.data .data.[0-9a-zA-Z_]*) \
208 *(.ref.data) \
209 *(.data..shared_aligned) /* percpu related */ \
210 MEM_KEEP(init.data) \
211 MEM_KEEP(exit.data) \
212 *(.data.unlikely) \
213 STRUCT_ALIGN(); \
214 *(__tracepoints) \
215 /* implement dynamic printk debug */ \
216 . = ALIGN(8); \
217 VMLINUX_SYMBOL(__start___jump_table) = .; \
218 KEEP(*(__jump_table)) \
219 VMLINUX_SYMBOL(__stop___jump_table) = .; \
220 . = ALIGN(8); \
221 VMLINUX_SYMBOL(__start___verbose) = .; \
222 KEEP(*(__verbose)) \
223 VMLINUX_SYMBOL(__stop___verbose) = .; \
224 LIKELY_PROFILE() \
225 BRANCH_PROFILE() \
226 TRACE_PRINTKS() \
227 TRACEPOINT_STR()
228
229 /*
230 * Data section helpers
231 */
232 #define NOSAVE_DATA \
233 . = ALIGN(PAGE_SIZE); \
234 VMLINUX_SYMBOL(__nosave_begin) = .; \
235 *(.data..nosave) \
236 . = ALIGN(PAGE_SIZE); \
237 VMLINUX_SYMBOL(__nosave_end) = .;
238
239 #define PAGE_ALIGNED_DATA(page_align) \
240 . = ALIGN(page_align); \
241 *(.data..page_aligned)
242
243 #define READ_MOSTLY_DATA(align) \
244 . = ALIGN(align); \
245 *(.data..read_mostly) \
246 . = ALIGN(align);
247
248 #define CACHELINE_ALIGNED_DATA(align) \
249 . = ALIGN(align); \
250 *(.data..cacheline_aligned)
251
252 #define INIT_TASK_DATA(align) \
253 . = ALIGN(align); \
254 VMLINUX_SYMBOL(__start_init_task) = .; \
255 *(.data..init_task) \
256 VMLINUX_SYMBOL(__end_init_task) = .;
257
258 /*
259 * Allow architectures to handle ro_after_init data on their
260 * own by defining an empty RO_AFTER_INIT_DATA.
261 */
262 #ifndef RO_AFTER_INIT_DATA
263 #define RO_AFTER_INIT_DATA \
264 VMLINUX_SYMBOL(__start_ro_after_init) = .; \
265 *(.data..ro_after_init) \
266 VMLINUX_SYMBOL(__end_ro_after_init) = .;
267 #endif
268
269 /*
270 * Read only Data
271 */
272 #define RO_DATA_SECTION(align) \
273 . = ALIGN((align)); \
274 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
275 VMLINUX_SYMBOL(__start_rodata) = .; \
276 *(.rodata) *(.rodata.*) \
277 RO_AFTER_INIT_DATA /* Read only after init */ \
278 KEEP(*(__vermagic)) /* Kernel version magic */ \
279 . = ALIGN(8); \
280 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .; \
281 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
282 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .; \
283 *(__tracepoints_strings)/* Tracepoints: strings */ \
284 } \
285 \
286 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
287 *(.rodata1) \
288 } \
289 \
290 BUG_TABLE \
291 \
292 /* PCI quirks */ \
293 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
294 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
295 KEEP(*(.pci_fixup_early)) \
296 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
297 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
298 KEEP(*(.pci_fixup_header)) \
299 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
300 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
301 KEEP(*(.pci_fixup_final)) \
302 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
303 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
304 KEEP(*(.pci_fixup_enable)) \
305 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
306 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
307 KEEP(*(.pci_fixup_resume)) \
308 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
309 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
310 KEEP(*(.pci_fixup_resume_early)) \
311 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
312 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
313 KEEP(*(.pci_fixup_suspend)) \
314 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
315 VMLINUX_SYMBOL(__start_pci_fixups_suspend_late) = .; \
316 KEEP(*(.pci_fixup_suspend_late)) \
317 VMLINUX_SYMBOL(__end_pci_fixups_suspend_late) = .; \
318 } \
319 \
320 /* Built-in firmware blobs */ \
321 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
322 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
323 KEEP(*(.builtin_fw)) \
324 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
325 } \
326 \
327 TRACEDATA \
328 \
329 /* Kernel symbol table: Normal symbols */ \
330 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
331 VMLINUX_SYMBOL(__start___ksymtab) = .; \
332 KEEP(*(SORT(___ksymtab+*))) \
333 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
334 } \
335 \
336 /* Kernel symbol table: GPL-only symbols */ \
337 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
338 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
339 KEEP(*(SORT(___ksymtab_gpl+*))) \
340 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
341 } \
342 \
343 /* Kernel symbol table: Normal unused symbols */ \
344 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
345 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
346 KEEP(*(SORT(___ksymtab_unused+*))) \
347 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
348 } \
349 \
350 /* Kernel symbol table: GPL-only unused symbols */ \
351 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
352 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
353 KEEP(*(SORT(___ksymtab_unused_gpl+*))) \
354 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
355 } \
356 \
357 /* Kernel symbol table: GPL-future-only symbols */ \
358 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
359 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
360 KEEP(*(SORT(___ksymtab_gpl_future+*))) \
361 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
362 } \
363 \
364 /* Kernel symbol table: Normal symbols */ \
365 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
366 VMLINUX_SYMBOL(__start___kcrctab) = .; \
367 KEEP(*(SORT(___kcrctab+*))) \
368 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
369 } \
370 \
371 /* Kernel symbol table: GPL-only symbols */ \
372 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
373 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
374 KEEP(*(SORT(___kcrctab_gpl+*))) \
375 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
376 } \
377 \
378 /* Kernel symbol table: Normal unused symbols */ \
379 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
380 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
381 KEEP(*(SORT(___kcrctab_unused+*))) \
382 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
383 } \
384 \
385 /* Kernel symbol table: GPL-only unused symbols */ \
386 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
387 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
388 KEEP(*(SORT(___kcrctab_unused_gpl+*))) \
389 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
390 } \
391 \
392 /* Kernel symbol table: GPL-future-only symbols */ \
393 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
394 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
395 KEEP(*(SORT(___kcrctab_gpl_future+*))) \
396 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
397 } \
398 \
399 /* Kernel symbol table: strings */ \
400 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
401 *(__ksymtab_strings) \
402 } \
403 \
404 /* __*init sections */ \
405 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
406 *(.ref.rodata) \
407 MEM_KEEP(init.rodata) \
408 MEM_KEEP(exit.rodata) \
409 } \
410 \
411 /* Built-in module parameters. */ \
412 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
413 VMLINUX_SYMBOL(__start___param) = .; \
414 KEEP(*(__param)) \
415 VMLINUX_SYMBOL(__stop___param) = .; \
416 } \
417 \
418 /* Built-in module versions. */ \
419 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
420 VMLINUX_SYMBOL(__start___modver) = .; \
421 KEEP(*(__modver)) \
422 VMLINUX_SYMBOL(__stop___modver) = .; \
423 . = ALIGN((align)); \
424 VMLINUX_SYMBOL(__end_rodata) = .; \
425 } \
426 . = ALIGN((align));
427
428 /* RODATA & RO_DATA provided for backward compatibility.
429 * All archs are supposed to use RO_DATA() */
430 #define RODATA RO_DATA_SECTION(4096)
431 #define RO_DATA(align) RO_DATA_SECTION(align)
432
433 #define SECURITY_INIT \
434 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
435 VMLINUX_SYMBOL(__security_initcall_start) = .; \
436 KEEP(*(.security_initcall.init)) \
437 VMLINUX_SYMBOL(__security_initcall_end) = .; \
438 }
439
440 /* .text section. Map to function alignment to avoid address changes
441 * during second ld run in second ld pass when generating System.map
442 * LD_DEAD_CODE_DATA_ELIMINATION option enables -ffunction-sections generates
443 * .text.identifier which needs to be pulled in with .text , but some
444 * architectures define .text.foo which is not intended to be pulled in here.
445 * Those enabling LD_DEAD_CODE_DATA_ELIMINATION must ensure they don't have
446 * conflicting section names, and must pull in .text.[0-9a-zA-Z_]* */
447 #define TEXT_TEXT \
448 ALIGN_FUNCTION(); \
449 *(.text.hot .text .text.fixup .text.unlikely) \
450 *(.ref.text) \
451 MEM_KEEP(init.text) \
452 MEM_KEEP(exit.text) \
453
454
455 /* sched.text is aling to function alignment to secure we have same
456 * address even at second ld pass when generating System.map */
457 #define SCHED_TEXT \
458 ALIGN_FUNCTION(); \
459 VMLINUX_SYMBOL(__sched_text_start) = .; \
460 *(.sched.text) \
461 VMLINUX_SYMBOL(__sched_text_end) = .;
462
463 /* spinlock.text is aling to function alignment to secure we have same
464 * address even at second ld pass when generating System.map */
465 #define LOCK_TEXT \
466 ALIGN_FUNCTION(); \
467 VMLINUX_SYMBOL(__lock_text_start) = .; \
468 *(.spinlock.text) \
469 VMLINUX_SYMBOL(__lock_text_end) = .;
470
471 #define CPUIDLE_TEXT \
472 ALIGN_FUNCTION(); \
473 VMLINUX_SYMBOL(__cpuidle_text_start) = .; \
474 *(.cpuidle.text) \
475 VMLINUX_SYMBOL(__cpuidle_text_end) = .;
476
477 #define KPROBES_TEXT \
478 ALIGN_FUNCTION(); \
479 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
480 *(.kprobes.text) \
481 VMLINUX_SYMBOL(__kprobes_text_end) = .;
482
483 #define ENTRY_TEXT \
484 ALIGN_FUNCTION(); \
485 VMLINUX_SYMBOL(__entry_text_start) = .; \
486 *(.entry.text) \
487 VMLINUX_SYMBOL(__entry_text_end) = .;
488
489 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
490 #define IRQENTRY_TEXT \
491 ALIGN_FUNCTION(); \
492 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
493 *(.irqentry.text) \
494 VMLINUX_SYMBOL(__irqentry_text_end) = .;
495 #else
496 #define IRQENTRY_TEXT
497 #endif
498
499 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
500 #define SOFTIRQENTRY_TEXT \
501 ALIGN_FUNCTION(); \
502 VMLINUX_SYMBOL(__softirqentry_text_start) = .; \
503 *(.softirqentry.text) \
504 VMLINUX_SYMBOL(__softirqentry_text_end) = .;
505 #else
506 #define SOFTIRQENTRY_TEXT
507 #endif
508
509 /* Section used for early init (in .S files) */
510 #define HEAD_TEXT *(.head.text)
511
512 #define HEAD_TEXT_SECTION \
513 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
514 HEAD_TEXT \
515 }
516
517 /*
518 * Exception table
519 */
520 #define EXCEPTION_TABLE(align) \
521 . = ALIGN(align); \
522 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
523 VMLINUX_SYMBOL(__start___ex_table) = .; \
524 KEEP(*(__ex_table)) \
525 VMLINUX_SYMBOL(__stop___ex_table) = .; \
526 }
527
528 /*
529 * Init task
530 */
531 #define INIT_TASK_DATA_SECTION(align) \
532 . = ALIGN(align); \
533 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
534 INIT_TASK_DATA(align) \
535 }
536
537 #ifdef CONFIG_CONSTRUCTORS
538 #define KERNEL_CTORS() . = ALIGN(8); \
539 VMLINUX_SYMBOL(__ctors_start) = .; \
540 KEEP(*(.ctors)) \
541 KEEP(*(SORT(.init_array.*))) \
542 KEEP(*(.init_array)) \
543 VMLINUX_SYMBOL(__ctors_end) = .;
544 #else
545 #define KERNEL_CTORS()
546 #endif
547
548 /* init and exit section handling */
549 #define INIT_DATA \
550 KEEP(*(SORT(___kentry+*))) \
551 *(.init.data) \
552 MEM_DISCARD(init.data) \
553 KERNEL_CTORS() \
554 MCOUNT_REC() \
555 *(.init.rodata) \
556 FTRACE_EVENTS() \
557 TRACE_SYSCALLS() \
558 KPROBE_BLACKLIST() \
559 MEM_DISCARD(init.rodata) \
560 CLK_OF_TABLES() \
561 RESERVEDMEM_OF_TABLES() \
562 CLKSRC_OF_TABLES() \
563 CLKEVT_OF_TABLES() \
564 IOMMU_OF_TABLES() \
565 CPU_METHOD_OF_TABLES() \
566 CPUIDLE_METHOD_OF_TABLES() \
567 KERNEL_DTB() \
568 IRQCHIP_OF_MATCH_TABLE() \
569 ACPI_PROBE_TABLE(irqchip) \
570 ACPI_PROBE_TABLE(clksrc) \
571 ACPI_PROBE_TABLE(iort) \
572 EARLYCON_TABLE()
573
574 #define INIT_TEXT \
575 *(.init.text) \
576 *(.text.startup) \
577 MEM_DISCARD(init.text)
578
579 #define EXIT_DATA \
580 *(.exit.data) \
581 *(.fini_array) \
582 *(.dtors) \
583 MEM_DISCARD(exit.data) \
584 MEM_DISCARD(exit.rodata)
585
586 #define EXIT_TEXT \
587 *(.exit.text) \
588 *(.text.exit) \
589 MEM_DISCARD(exit.text)
590
591 #define EXIT_CALL \
592 *(.exitcall.exit)
593
594 /*
595 * bss (Block Started by Symbol) - uninitialized data
596 * zeroed during startup
597 */
598 #define SBSS(sbss_align) \
599 . = ALIGN(sbss_align); \
600 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
601 *(.sbss) \
602 *(.scommon) \
603 }
604
605 /*
606 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
607 * sections to the front of bss.
608 */
609 #ifndef BSS_FIRST_SECTIONS
610 #define BSS_FIRST_SECTIONS
611 #endif
612
613 #define BSS(bss_align) \
614 . = ALIGN(bss_align); \
615 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
616 BSS_FIRST_SECTIONS \
617 *(.bss..page_aligned) \
618 *(.dynbss) \
619 *(.bss .bss.[0-9a-zA-Z_]*) \
620 *(COMMON) \
621 }
622
623 /*
624 * DWARF debug sections.
625 * Symbols in the DWARF debugging sections are relative to
626 * the beginning of the section so we begin them at 0.
627 */
628 #define DWARF_DEBUG \
629 /* DWARF 1 */ \
630 .debug 0 : { *(.debug) } \
631 .line 0 : { *(.line) } \
632 /* GNU DWARF 1 extensions */ \
633 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
634 .debug_sfnames 0 : { *(.debug_sfnames) } \
635 /* DWARF 1.1 and DWARF 2 */ \
636 .debug_aranges 0 : { *(.debug_aranges) } \
637 .debug_pubnames 0 : { *(.debug_pubnames) } \
638 /* DWARF 2 */ \
639 .debug_info 0 : { *(.debug_info \
640 .gnu.linkonce.wi.*) } \
641 .debug_abbrev 0 : { *(.debug_abbrev) } \
642 .debug_line 0 : { *(.debug_line) } \
643 .debug_frame 0 : { *(.debug_frame) } \
644 .debug_str 0 : { *(.debug_str) } \
645 .debug_loc 0 : { *(.debug_loc) } \
646 .debug_macinfo 0 : { *(.debug_macinfo) } \
647 /* SGI/MIPS DWARF 2 extensions */ \
648 .debug_weaknames 0 : { *(.debug_weaknames) } \
649 .debug_funcnames 0 : { *(.debug_funcnames) } \
650 .debug_typenames 0 : { *(.debug_typenames) } \
651 .debug_varnames 0 : { *(.debug_varnames) } \
652
653 /* Stabs debugging sections. */
654 #define STABS_DEBUG \
655 .stab 0 : { *(.stab) } \
656 .stabstr 0 : { *(.stabstr) } \
657 .stab.excl 0 : { *(.stab.excl) } \
658 .stab.exclstr 0 : { *(.stab.exclstr) } \
659 .stab.index 0 : { *(.stab.index) } \
660 .stab.indexstr 0 : { *(.stab.indexstr) } \
661 .comment 0 : { *(.comment) }
662
663 #ifdef CONFIG_GENERIC_BUG
664 #define BUG_TABLE \
665 . = ALIGN(8); \
666 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
667 VMLINUX_SYMBOL(__start___bug_table) = .; \
668 KEEP(*(__bug_table)) \
669 VMLINUX_SYMBOL(__stop___bug_table) = .; \
670 }
671 #else
672 #define BUG_TABLE
673 #endif
674
675 #ifdef CONFIG_PM_TRACE
676 #define TRACEDATA \
677 . = ALIGN(4); \
678 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
679 VMLINUX_SYMBOL(__tracedata_start) = .; \
680 KEEP(*(.tracedata)) \
681 VMLINUX_SYMBOL(__tracedata_end) = .; \
682 }
683 #else
684 #define TRACEDATA
685 #endif
686
687 #define NOTES \
688 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
689 VMLINUX_SYMBOL(__start_notes) = .; \
690 *(.note.*) \
691 VMLINUX_SYMBOL(__stop_notes) = .; \
692 }
693
694 #define INIT_SETUP(initsetup_align) \
695 . = ALIGN(initsetup_align); \
696 VMLINUX_SYMBOL(__setup_start) = .; \
697 KEEP(*(.init.setup)) \
698 VMLINUX_SYMBOL(__setup_end) = .;
699
700 #define INIT_CALLS_LEVEL(level) \
701 VMLINUX_SYMBOL(__initcall##level##_start) = .; \
702 KEEP(*(.initcall##level##.init)) \
703 KEEP(*(.initcall##level##s.init)) \
704
705 #define INIT_CALLS \
706 VMLINUX_SYMBOL(__initcall_start) = .; \
707 KEEP(*(.initcallearly.init)) \
708 INIT_CALLS_LEVEL(0) \
709 INIT_CALLS_LEVEL(1) \
710 INIT_CALLS_LEVEL(2) \
711 INIT_CALLS_LEVEL(3) \
712 INIT_CALLS_LEVEL(4) \
713 INIT_CALLS_LEVEL(5) \
714 INIT_CALLS_LEVEL(rootfs) \
715 INIT_CALLS_LEVEL(6) \
716 INIT_CALLS_LEVEL(7) \
717 VMLINUX_SYMBOL(__initcall_end) = .;
718
719 #define CON_INITCALL \
720 VMLINUX_SYMBOL(__con_initcall_start) = .; \
721 KEEP(*(.con_initcall.init)) \
722 VMLINUX_SYMBOL(__con_initcall_end) = .;
723
724 #define SECURITY_INITCALL \
725 VMLINUX_SYMBOL(__security_initcall_start) = .; \
726 KEEP(*(.security_initcall.init)) \
727 VMLINUX_SYMBOL(__security_initcall_end) = .;
728
729 #ifdef CONFIG_BLK_DEV_INITRD
730 #define INIT_RAM_FS \
731 . = ALIGN(4); \
732 VMLINUX_SYMBOL(__initramfs_start) = .; \
733 KEEP(*(.init.ramfs)) \
734 . = ALIGN(8); \
735 KEEP(*(.init.ramfs.info))
736 #else
737 #define INIT_RAM_FS
738 #endif
739
740 /*
741 * Default discarded sections.
742 *
743 * Some archs want to discard exit text/data at runtime rather than
744 * link time due to cross-section references such as alt instructions,
745 * bug table, eh_frame, etc. DISCARDS must be the last of output
746 * section definitions so that such archs put those in earlier section
747 * definitions.
748 */
749 #define DISCARDS \
750 /DISCARD/ : { \
751 EXIT_TEXT \
752 EXIT_DATA \
753 EXIT_CALL \
754 *(.discard) \
755 *(.discard.*) \
756 }
757
758 /**
759 * PERCPU_INPUT - the percpu input sections
760 * @cacheline: cacheline size
761 *
762 * The core percpu section names and core symbols which do not rely
763 * directly upon load addresses.
764 *
765 * @cacheline is used to align subsections to avoid false cacheline
766 * sharing between subsections for different purposes.
767 */
768 #define PERCPU_INPUT(cacheline) \
769 VMLINUX_SYMBOL(__per_cpu_start) = .; \
770 *(.data..percpu..first) \
771 . = ALIGN(PAGE_SIZE); \
772 *(.data..percpu..page_aligned) \
773 . = ALIGN(cacheline); \
774 *(.data..percpu..read_mostly) \
775 . = ALIGN(cacheline); \
776 *(.data..percpu) \
777 *(.data..percpu..shared_aligned) \
778 VMLINUX_SYMBOL(__per_cpu_end) = .;
779
780 /**
781 * PERCPU_VADDR - define output section for percpu area
782 * @cacheline: cacheline size
783 * @vaddr: explicit base address (optional)
784 * @phdr: destination PHDR (optional)
785 *
786 * Macro which expands to output section for percpu area.
787 *
788 * @cacheline is used to align subsections to avoid false cacheline
789 * sharing between subsections for different purposes.
790 *
791 * If @vaddr is not blank, it specifies explicit base address and all
792 * percpu symbols will be offset from the given address. If blank,
793 * @vaddr always equals @laddr + LOAD_OFFSET.
794 *
795 * @phdr defines the output PHDR to use if not blank. Be warned that
796 * output PHDR is sticky. If @phdr is specified, the next output
797 * section in the linker script will go there too. @phdr should have
798 * a leading colon.
799 *
800 * Note that this macros defines __per_cpu_load as an absolute symbol.
801 * If there is no need to put the percpu section at a predetermined
802 * address, use PERCPU_SECTION.
803 */
804 #define PERCPU_VADDR(cacheline, vaddr, phdr) \
805 VMLINUX_SYMBOL(__per_cpu_load) = .; \
806 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
807 - LOAD_OFFSET) { \
808 PERCPU_INPUT(cacheline) \
809 } phdr \
810 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
811
812 /**
813 * PERCPU_SECTION - define output section for percpu area, simple version
814 * @cacheline: cacheline size
815 *
816 * Align to PAGE_SIZE and outputs output section for percpu area. This
817 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
818 * __per_cpu_start will be identical.
819 *
820 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
821 * except that __per_cpu_load is defined as a relative symbol against
822 * .data..percpu which is required for relocatable x86_32 configuration.
823 */
824 #define PERCPU_SECTION(cacheline) \
825 . = ALIGN(PAGE_SIZE); \
826 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
827 VMLINUX_SYMBOL(__per_cpu_load) = .; \
828 PERCPU_INPUT(cacheline) \
829 }
830
831
832 /*
833 * Definition of the high level *_SECTION macros
834 * They will fit only a subset of the architectures
835 */
836
837
838 /*
839 * Writeable data.
840 * All sections are combined in a single .data section.
841 * The sections following CONSTRUCTORS are arranged so their
842 * typical alignment matches.
843 * A cacheline is typical/always less than a PAGE_SIZE so
844 * the sections that has this restriction (or similar)
845 * is located before the ones requiring PAGE_SIZE alignment.
846 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
847 * matches the requirement of PAGE_ALIGNED_DATA.
848 *
849 * use 0 as page_align if page_aligned data is not used */
850 #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
851 . = ALIGN(PAGE_SIZE); \
852 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
853 INIT_TASK_DATA(inittask) \
854 NOSAVE_DATA \
855 PAGE_ALIGNED_DATA(pagealigned) \
856 CACHELINE_ALIGNED_DATA(cacheline) \
857 READ_MOSTLY_DATA(cacheline) \
858 DATA_DATA \
859 CONSTRUCTORS \
860 }
861
862 #define INIT_TEXT_SECTION(inittext_align) \
863 . = ALIGN(inittext_align); \
864 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
865 VMLINUX_SYMBOL(_sinittext) = .; \
866 INIT_TEXT \
867 VMLINUX_SYMBOL(_einittext) = .; \
868 }
869
870 #define INIT_DATA_SECTION(initsetup_align) \
871 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
872 INIT_DATA \
873 INIT_SETUP(initsetup_align) \
874 INIT_CALLS \
875 CON_INITCALL \
876 SECURITY_INITCALL \
877 INIT_RAM_FS \
878 }
879
880 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
881 . = ALIGN(sbss_align); \
882 VMLINUX_SYMBOL(__bss_start) = .; \
883 SBSS(sbss_align) \
884 BSS(bss_align) \
885 . = ALIGN(stop_align); \
886 VMLINUX_SYMBOL(__bss_stop) = .;
ubuntu-bionic-kernel mirror