]> git.proxmox.com Git - mirror_ubuntu-bionic-kernel.git/blob - include/asm-generic/vmlinux.lds.h
projects / mirror_ubuntu-bionic-kernel.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
macvlan: do not assume mac_header is set in macvlan_broadcast()
[mirror_ubuntu-bionic-kernel.git] / include / asm-generic / vmlinux.lds.h
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53 #ifndef LOAD_OFFSET
54 #define LOAD_OFFSET 0
55 #endif
56
57 #include <linux/export.h>
58
59 /* Align . to a 8 byte boundary equals to maximum function alignment. */
60 #define ALIGN_FUNCTION() . = ALIGN(8)
61
62 /*
63 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
64 * generates .data.identifier sections, which need to be pulled in with
65 * .data. We don't want to pull in .data..other sections, which Linux
66 * has defined. Same for text and bss.
67 */
68 #ifdef CONFIG_LD_DEAD_CODE_DATA_ELIMINATION
69 #define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
70 #define DATA_MAIN .data .data.[0-9a-zA-Z_]*
71 #define BSS_MAIN .bss .bss.[0-9a-zA-Z_]*
72 #else
73 #define TEXT_MAIN .text
74 #define DATA_MAIN .data
75 #define BSS_MAIN .bss
76 #endif
77
78 /*
79 * Align to a 32 byte boundary equal to the
80 * alignment gcc 4.5 uses for a struct
81 */
82 #define STRUCT_ALIGNMENT 32
83 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
84
85 /* The actual configuration determine if the init/exit sections
86 * are handled as text/data or they can be discarded (which
87 * often happens at runtime)
88 */
89 #ifdef CONFIG_HOTPLUG_CPU
90 #define CPU_KEEP(sec) *(.cpu##sec)
91 #define CPU_DISCARD(sec)
92 #else
93 #define CPU_KEEP(sec)
94 #define CPU_DISCARD(sec) *(.cpu##sec)
95 #endif
96
97 #if defined(CONFIG_MEMORY_HOTPLUG)
98 #define MEM_KEEP(sec) *(.mem##sec)
99 #define MEM_DISCARD(sec)
100 #else
101 #define MEM_KEEP(sec)
102 #define MEM_DISCARD(sec) *(.mem##sec)
103 #endif
104
105 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
106 #define MCOUNT_REC() . = ALIGN(8); \
107 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
108 *(__mcount_loc) \
109 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
110 #else
111 #define MCOUNT_REC()
112 #endif
113
114 #ifdef CONFIG_TRACE_BRANCH_PROFILING
115 #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
116 *(_ftrace_annotated_branch) \
117 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
118 #else
119 #define LIKELY_PROFILE()
120 #endif
121
122 #ifdef CONFIG_PROFILE_ALL_BRANCHES
123 #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
124 *(_ftrace_branch) \
125 VMLINUX_SYMBOL(__stop_branch_profile) = .;
126 #else
127 #define BRANCH_PROFILE()
128 #endif
129
130 #ifdef CONFIG_KPROBES
131 #define KPROBE_BLACKLIST() . = ALIGN(8); \
132 VMLINUX_SYMBOL(__start_kprobe_blacklist) = .; \
133 KEEP(*(_kprobe_blacklist)) \
134 VMLINUX_SYMBOL(__stop_kprobe_blacklist) = .;
135 #else
136 #define KPROBE_BLACKLIST()
137 #endif
138
139 #ifdef CONFIG_EVENT_TRACING
140 #define FTRACE_EVENTS() . = ALIGN(8); \
141 VMLINUX_SYMBOL(__start_ftrace_events) = .; \
142 KEEP(*(_ftrace_events)) \
143 VMLINUX_SYMBOL(__stop_ftrace_events) = .; \
144 VMLINUX_SYMBOL(__start_ftrace_eval_maps) = .; \
145 KEEP(*(_ftrace_eval_map)) \
146 VMLINUX_SYMBOL(__stop_ftrace_eval_maps) = .;
147 #else
148 #define FTRACE_EVENTS()
149 #endif
150
151 #ifdef CONFIG_TRACING
152 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
153 KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
154 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
155 #define TRACEPOINT_STR() VMLINUX_SYMBOL(__start___tracepoint_str) = .; \
156 KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
157 VMLINUX_SYMBOL(__stop___tracepoint_str) = .;
158 #else
159 #define TRACE_PRINTKS()
160 #define TRACEPOINT_STR()
161 #endif
162
163 #ifdef CONFIG_FTRACE_SYSCALLS
164 #define TRACE_SYSCALLS() . = ALIGN(8); \
165 VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
166 KEEP(*(__syscalls_metadata)) \
167 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
168 #else
169 #define TRACE_SYSCALLS()
170 #endif
171
172 #ifdef CONFIG_SERIAL_EARLYCON
173 #define EARLYCON_TABLE() . = ALIGN(8); \
174 VMLINUX_SYMBOL(__earlycon_table) = .; \
175 KEEP(*(__earlycon_table)) \
176 VMLINUX_SYMBOL(__earlycon_table_end) = .;
177 #else
178 #define EARLYCON_TABLE()
179 #endif
180
181 #define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
182 #define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
183 #define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
184 #define _OF_TABLE_0(name)
185 #define _OF_TABLE_1(name) \
186 . = ALIGN(8); \
187 VMLINUX_SYMBOL(__##name##_of_table) = .; \
188 KEEP(*(__##name##_of_table)) \
189 KEEP(*(__##name##_of_table_end))
190
191 #define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
192 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
193 #define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
194 #define IOMMU_OF_TABLES() OF_TABLE(CONFIG_OF_IOMMU, iommu)
195 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
196 #define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
197 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
198
199 #ifdef CONFIG_ACPI
200 #define ACPI_PROBE_TABLE(name) \
201 . = ALIGN(8); \
202 VMLINUX_SYMBOL(__##name##_acpi_probe_table) = .; \
203 KEEP(*(__##name##_acpi_probe_table)) \
204 VMLINUX_SYMBOL(__##name##_acpi_probe_table_end) = .;
205 #else
206 #define ACPI_PROBE_TABLE(name)
207 #endif
208
209 #define KERNEL_DTB() \
210 STRUCT_ALIGN(); \
211 VMLINUX_SYMBOL(__dtb_start) = .; \
212 KEEP(*(.dtb.init.rodata)) \
213 VMLINUX_SYMBOL(__dtb_end) = .;
214
215 /*
216 * .data section
217 */
218 #define DATA_DATA \
219 *(.xiptext) \
220 *(DATA_MAIN) \
221 *(.ref.data) \
222 *(.data..shared_aligned) /* percpu related */ \
223 MEM_KEEP(init.data) \
224 MEM_KEEP(exit.data) \
225 *(.data.unlikely) \
226 VMLINUX_SYMBOL(__start_once) = .; \
227 *(.data.once) \
228 VMLINUX_SYMBOL(__end_once) = .; \
229 STRUCT_ALIGN(); \
230 *(__tracepoints) \
231 /* implement dynamic printk debug */ \
232 . = ALIGN(8); \
233 VMLINUX_SYMBOL(__start___jump_table) = .; \
234 KEEP(*(__jump_table)) \
235 VMLINUX_SYMBOL(__stop___jump_table) = .; \
236 . = ALIGN(8); \
237 VMLINUX_SYMBOL(__start___verbose) = .; \
238 KEEP(*(__verbose)) \
239 VMLINUX_SYMBOL(__stop___verbose) = .; \
240 LIKELY_PROFILE() \
241 BRANCH_PROFILE() \
242 TRACE_PRINTKS() \
243 TRACEPOINT_STR()
244
245 /*
246 * Data section helpers
247 */
248 #define NOSAVE_DATA \
249 . = ALIGN(PAGE_SIZE); \
250 VMLINUX_SYMBOL(__nosave_begin) = .; \
251 *(.data..nosave) \
252 . = ALIGN(PAGE_SIZE); \
253 VMLINUX_SYMBOL(__nosave_end) = .;
254
255 #define PAGE_ALIGNED_DATA(page_align) \
256 . = ALIGN(page_align); \
257 *(.data..page_aligned)
258
259 #define READ_MOSTLY_DATA(align) \
260 . = ALIGN(align); \
261 *(.data..read_mostly) \
262 . = ALIGN(align);
263
264 #define CACHELINE_ALIGNED_DATA(align) \
265 . = ALIGN(align); \
266 *(.data..cacheline_aligned)
267
268 #define INIT_TASK_DATA(align) \
269 . = ALIGN(align); \
270 VMLINUX_SYMBOL(__start_init_task) = .; \
271 *(.data..init_task) \
272 VMLINUX_SYMBOL(__end_init_task) = .;
273
274 /*
275 * Allow architectures to handle ro_after_init data on their
276 * own by defining an empty RO_AFTER_INIT_DATA.
277 */
278 #ifndef RO_AFTER_INIT_DATA
279 #define RO_AFTER_INIT_DATA \
280 VMLINUX_SYMBOL(__start_ro_after_init) = .; \
281 *(.data..ro_after_init) \
282 VMLINUX_SYMBOL(__end_ro_after_init) = .;
283 #endif
284
285 /*
286 * Read only Data
287 */
288 #define RO_DATA_SECTION(align) \
289 . = ALIGN((align)); \
290 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
291 VMLINUX_SYMBOL(__start_rodata) = .; \
292 *(.rodata) *(.rodata.*) \
293 RO_AFTER_INIT_DATA /* Read only after init */ \
294 KEEP(*(__vermagic)) /* Kernel version magic */ \
295 . = ALIGN(8); \
296 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .; \
297 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
298 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .; \
299 *(__tracepoints_strings)/* Tracepoints: strings */ \
300 } \
301 \
302 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
303 *(.rodata1) \
304 } \
305 \
306 /* PCI quirks */ \
307 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
308 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
309 KEEP(*(.pci_fixup_early)) \
310 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
311 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
312 KEEP(*(.pci_fixup_header)) \
313 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
314 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
315 KEEP(*(.pci_fixup_final)) \
316 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
317 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
318 KEEP(*(.pci_fixup_enable)) \
319 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
320 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
321 KEEP(*(.pci_fixup_resume)) \
322 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
323 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
324 KEEP(*(.pci_fixup_resume_early)) \
325 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
326 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
327 KEEP(*(.pci_fixup_suspend)) \
328 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
329 VMLINUX_SYMBOL(__start_pci_fixups_suspend_late) = .; \
330 KEEP(*(.pci_fixup_suspend_late)) \
331 VMLINUX_SYMBOL(__end_pci_fixups_suspend_late) = .; \
332 } \
333 \
334 /* Built-in firmware blobs */ \
335 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
336 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
337 KEEP(*(.builtin_fw)) \
338 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
339 } \
340 \
341 TRACEDATA \
342 \
343 /* Kernel symbol table: Normal symbols */ \
344 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
345 VMLINUX_SYMBOL(__start___ksymtab) = .; \
346 KEEP(*(SORT(___ksymtab+*))) \
347 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
348 } \
349 \
350 /* Kernel symbol table: GPL-only symbols */ \
351 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
352 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
353 KEEP(*(SORT(___ksymtab_gpl+*))) \
354 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
355 } \
356 \
357 /* Kernel symbol table: Normal unused symbols */ \
358 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
359 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
360 KEEP(*(SORT(___ksymtab_unused+*))) \
361 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
362 } \
363 \
364 /* Kernel symbol table: GPL-only unused symbols */ \
365 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
366 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
367 KEEP(*(SORT(___ksymtab_unused_gpl+*))) \
368 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
369 } \
370 \
371 /* Kernel symbol table: GPL-future-only symbols */ \
372 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
373 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
374 KEEP(*(SORT(___ksymtab_gpl_future+*))) \
375 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
376 } \
377 \
378 /* Kernel symbol table: Normal symbols */ \
379 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
380 VMLINUX_SYMBOL(__start___kcrctab) = .; \
381 KEEP(*(SORT(___kcrctab+*))) \
382 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
383 } \
384 \
385 /* Kernel symbol table: GPL-only symbols */ \
386 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
387 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
388 KEEP(*(SORT(___kcrctab_gpl+*))) \
389 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
390 } \
391 \
392 /* Kernel symbol table: Normal unused symbols */ \
393 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
394 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
395 KEEP(*(SORT(___kcrctab_unused+*))) \
396 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
397 } \
398 \
399 /* Kernel symbol table: GPL-only unused symbols */ \
400 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
401 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
402 KEEP(*(SORT(___kcrctab_unused_gpl+*))) \
403 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
404 } \
405 \
406 /* Kernel symbol table: GPL-future-only symbols */ \
407 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
408 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
409 KEEP(*(SORT(___kcrctab_gpl_future+*))) \
410 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
411 } \
412 \
413 /* Kernel symbol table: strings */ \
414 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
415 *(__ksymtab_strings) \
416 } \
417 \
418 /* __*init sections */ \
419 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
420 *(.ref.rodata) \
421 MEM_KEEP(init.rodata) \
422 MEM_KEEP(exit.rodata) \
423 } \
424 \
425 /* Built-in module parameters. */ \
426 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
427 VMLINUX_SYMBOL(__start___param) = .; \
428 KEEP(*(__param)) \
429 VMLINUX_SYMBOL(__stop___param) = .; \
430 } \
431 \
432 /* Built-in module versions. */ \
433 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
434 VMLINUX_SYMBOL(__start___modver) = .; \
435 KEEP(*(__modver)) \
436 VMLINUX_SYMBOL(__stop___modver) = .; \
437 . = ALIGN((align)); \
438 VMLINUX_SYMBOL(__end_rodata) = .; \
439 } \
440 . = ALIGN((align));
441
442 /* RODATA & RO_DATA provided for backward compatibility.
443 * All archs are supposed to use RO_DATA() */
444 #define RODATA RO_DATA_SECTION(4096)
445 #define RO_DATA(align) RO_DATA_SECTION(align)
446
447 #define SECURITY_INIT \
448 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
449 VMLINUX_SYMBOL(__security_initcall_start) = .; \
450 KEEP(*(.security_initcall.init)) \
451 VMLINUX_SYMBOL(__security_initcall_end) = .; \
452 }
453
454 /*
455 * .text section. Map to function alignment to avoid address changes
456 * during second ld run in second ld pass when generating System.map
457 *
458 * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
459 * code elimination is enabled, so these sections should be converted
460 * to use ".." first.
461 */
462 #define TEXT_TEXT \
463 ALIGN_FUNCTION(); \
464 *(.text.hot TEXT_MAIN .text.fixup .text.unlikely) \
465 *(.text..refcount) \
466 *(.ref.text) \
467 MEM_KEEP(init.text) \
468 MEM_KEEP(exit.text) \
469
470
471 /* sched.text is aling to function alignment to secure we have same
472 * address even at second ld pass when generating System.map */
473 #define SCHED_TEXT \
474 ALIGN_FUNCTION(); \
475 VMLINUX_SYMBOL(__sched_text_start) = .; \
476 *(.sched.text) \
477 VMLINUX_SYMBOL(__sched_text_end) = .;
478
479 /* spinlock.text is aling to function alignment to secure we have same
480 * address even at second ld pass when generating System.map */
481 #define LOCK_TEXT \
482 ALIGN_FUNCTION(); \
483 VMLINUX_SYMBOL(__lock_text_start) = .; \
484 *(.spinlock.text) \
485 VMLINUX_SYMBOL(__lock_text_end) = .;
486
487 #define CPUIDLE_TEXT \
488 ALIGN_FUNCTION(); \
489 VMLINUX_SYMBOL(__cpuidle_text_start) = .; \
490 *(.cpuidle.text) \
491 VMLINUX_SYMBOL(__cpuidle_text_end) = .;
492
493 #define KPROBES_TEXT \
494 ALIGN_FUNCTION(); \
495 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
496 *(.kprobes.text) \
497 VMLINUX_SYMBOL(__kprobes_text_end) = .;
498
499 #define ENTRY_TEXT \
500 ALIGN_FUNCTION(); \
501 VMLINUX_SYMBOL(__entry_text_start) = .; \
502 *(.entry.text) \
503 VMLINUX_SYMBOL(__entry_text_end) = .;
504
505 #define IRQENTRY_TEXT \
506 ALIGN_FUNCTION(); \
507 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
508 *(.irqentry.text) \
509 VMLINUX_SYMBOL(__irqentry_text_end) = .;
510
511 #define SOFTIRQENTRY_TEXT \
512 ALIGN_FUNCTION(); \
513 VMLINUX_SYMBOL(__softirqentry_text_start) = .; \
514 *(.softirqentry.text) \
515 VMLINUX_SYMBOL(__softirqentry_text_end) = .;
516
517 /* Section used for early init (in .S files) */
518 #define HEAD_TEXT *(.head.text)
519
520 #define HEAD_TEXT_SECTION \
521 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
522 HEAD_TEXT \
523 }
524
525 /*
526 * Exception table
527 */
528 #define EXCEPTION_TABLE(align) \
529 . = ALIGN(align); \
530 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
531 VMLINUX_SYMBOL(__start___ex_table) = .; \
532 KEEP(*(__ex_table)) \
533 VMLINUX_SYMBOL(__stop___ex_table) = .; \
534 }
535
536 /*
537 * Init task
538 */
539 #define INIT_TASK_DATA_SECTION(align) \
540 . = ALIGN(align); \
541 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
542 INIT_TASK_DATA(align) \
543 }
544
545 #ifdef CONFIG_CONSTRUCTORS
546 #define KERNEL_CTORS() . = ALIGN(8); \
547 VMLINUX_SYMBOL(__ctors_start) = .; \
548 KEEP(*(.ctors)) \
549 KEEP(*(SORT(.init_array.*))) \
550 KEEP(*(.init_array)) \
551 VMLINUX_SYMBOL(__ctors_end) = .;
552 #else
553 #define KERNEL_CTORS()
554 #endif
555
556 /* init and exit section handling */
557 #define INIT_DATA \
558 KEEP(*(SORT(___kentry+*))) \
559 *(.init.data) \
560 MEM_DISCARD(init.data) \
561 KERNEL_CTORS() \
562 MCOUNT_REC() \
563 *(.init.rodata) \
564 FTRACE_EVENTS() \
565 TRACE_SYSCALLS() \
566 KPROBE_BLACKLIST() \
567 MEM_DISCARD(init.rodata) \
568 CLK_OF_TABLES() \
569 RESERVEDMEM_OF_TABLES() \
570 TIMER_OF_TABLES() \
571 IOMMU_OF_TABLES() \
572 CPU_METHOD_OF_TABLES() \
573 CPUIDLE_METHOD_OF_TABLES() \
574 KERNEL_DTB() \
575 IRQCHIP_OF_MATCH_TABLE() \
576 ACPI_PROBE_TABLE(irqchip) \
577 ACPI_PROBE_TABLE(timer) \
578 ACPI_PROBE_TABLE(iort) \
579 EARLYCON_TABLE()
580
581 #define INIT_TEXT \
582 *(.init.text) \
583 *(.text.startup) \
584 MEM_DISCARD(init.text)
585
586 #define EXIT_DATA \
587 *(.exit.data) \
588 *(.fini_array) \
589 *(.dtors) \
590 MEM_DISCARD(exit.data) \
591 MEM_DISCARD(exit.rodata)
592
593 #define EXIT_TEXT \
594 *(.exit.text) \
595 *(.text.exit) \
596 MEM_DISCARD(exit.text)
597
598 #define EXIT_CALL \
599 *(.exitcall.exit)
600
601 /*
602 * bss (Block Started by Symbol) - uninitialized data
603 * zeroed during startup
604 */
605 #define SBSS(sbss_align) \
606 . = ALIGN(sbss_align); \
607 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
608 *(.dynsbss) \
609 *(.sbss) \
610 *(.scommon) \
611 }
612
613 /*
614 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
615 * sections to the front of bss.
616 */
617 #ifndef BSS_FIRST_SECTIONS
618 #define BSS_FIRST_SECTIONS
619 #endif
620
621 #define BSS(bss_align) \
622 . = ALIGN(bss_align); \
623 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
624 BSS_FIRST_SECTIONS \
625 *(.bss..page_aligned) \
626 *(.dynbss) \
627 *(BSS_MAIN) \
628 *(COMMON) \
629 }
630
631 /*
632 * DWARF debug sections.
633 * Symbols in the DWARF debugging sections are relative to
634 * the beginning of the section so we begin them at 0.
635 */
636 #define DWARF_DEBUG \
637 /* DWARF 1 */ \
638 .debug 0 : { *(.debug) } \
639 .line 0 : { *(.line) } \
640 /* GNU DWARF 1 extensions */ \
641 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
642 .debug_sfnames 0 : { *(.debug_sfnames) } \
643 /* DWARF 1.1 and DWARF 2 */ \
644 .debug_aranges 0 : { *(.debug_aranges) } \
645 .debug_pubnames 0 : { *(.debug_pubnames) } \
646 /* DWARF 2 */ \
647 .debug_info 0 : { *(.debug_info \
648 .gnu.linkonce.wi.*) } \
649 .debug_abbrev 0 : { *(.debug_abbrev) } \
650 .debug_line 0 : { *(.debug_line) } \
651 .debug_frame 0 : { *(.debug_frame) } \
652 .debug_str 0 : { *(.debug_str) } \
653 .debug_loc 0 : { *(.debug_loc) } \
654 .debug_macinfo 0 : { *(.debug_macinfo) } \
655 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
656 /* DWARF 3 */ \
657 .debug_ranges 0 : { *(.debug_ranges) } \
658 /* SGI/MIPS DWARF 2 extensions */ \
659 .debug_weaknames 0 : { *(.debug_weaknames) } \
660 .debug_funcnames 0 : { *(.debug_funcnames) } \
661 .debug_typenames 0 : { *(.debug_typenames) } \
662 .debug_varnames 0 : { *(.debug_varnames) } \
663 /* GNU DWARF 2 extensions */ \
664 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
665 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
666 /* DWARF 4 */ \
667 .debug_types 0 : { *(.debug_types) } \
668 /* DWARF 5 */ \
669 .debug_macro 0 : { *(.debug_macro) } \
670 .debug_addr 0 : { *(.debug_addr) }
671
672 /* Stabs debugging sections. */
673 #define STABS_DEBUG \
674 .stab 0 : { *(.stab) } \
675 .stabstr 0 : { *(.stabstr) } \
676 .stab.excl 0 : { *(.stab.excl) } \
677 .stab.exclstr 0 : { *(.stab.exclstr) } \
678 .stab.index 0 : { *(.stab.index) } \
679 .stab.indexstr 0 : { *(.stab.indexstr) } \
680 .comment 0 : { *(.comment) }
681
682 #ifdef CONFIG_GENERIC_BUG
683 #define BUG_TABLE \
684 . = ALIGN(8); \
685 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
686 VMLINUX_SYMBOL(__start___bug_table) = .; \
687 KEEP(*(__bug_table)) \
688 VMLINUX_SYMBOL(__stop___bug_table) = .; \
689 }
690 #else
691 #define BUG_TABLE
692 #endif
693
694 #ifdef CONFIG_UNWINDER_ORC
695 #define ORC_UNWIND_TABLE \
696 . = ALIGN(4); \
697 .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) { \
698 VMLINUX_SYMBOL(__start_orc_unwind_ip) = .; \
699 KEEP(*(.orc_unwind_ip)) \
700 VMLINUX_SYMBOL(__stop_orc_unwind_ip) = .; \
701 } \
702 . = ALIGN(2); \
703 .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) { \
704 VMLINUX_SYMBOL(__start_orc_unwind) = .; \
705 KEEP(*(.orc_unwind)) \
706 VMLINUX_SYMBOL(__stop_orc_unwind) = .; \
707 } \
708 . = ALIGN(4); \
709 .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) { \
710 VMLINUX_SYMBOL(orc_lookup) = .; \
711 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) / \
712 LOOKUP_BLOCK_SIZE) + 1) * 4; \
713 VMLINUX_SYMBOL(orc_lookup_end) = .; \
714 }
715 #else
716 #define ORC_UNWIND_TABLE
717 #endif
718
719 #ifdef CONFIG_PM_TRACE
720 #define TRACEDATA \
721 . = ALIGN(4); \
722 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
723 VMLINUX_SYMBOL(__tracedata_start) = .; \
724 KEEP(*(.tracedata)) \
725 VMLINUX_SYMBOL(__tracedata_end) = .; \
726 }
727 #else
728 #define TRACEDATA
729 #endif
730
731 #define NOTES \
732 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
733 VMLINUX_SYMBOL(__start_notes) = .; \
734 *(.note.*) \
735 VMLINUX_SYMBOL(__stop_notes) = .; \
736 }
737
738 #define INIT_SETUP(initsetup_align) \
739 . = ALIGN(initsetup_align); \
740 VMLINUX_SYMBOL(__setup_start) = .; \
741 KEEP(*(.init.setup)) \
742 VMLINUX_SYMBOL(__setup_end) = .;
743
744 #define INIT_CALLS_LEVEL(level) \
745 VMLINUX_SYMBOL(__initcall##level##_start) = .; \
746 KEEP(*(.initcall##level##.init)) \
747 KEEP(*(.initcall##level##s.init)) \
748
749 #define INIT_CALLS \
750 VMLINUX_SYMBOL(__initcall_start) = .; \
751 KEEP(*(.initcallearly.init)) \
752 INIT_CALLS_LEVEL(0) \
753 INIT_CALLS_LEVEL(1) \
754 INIT_CALLS_LEVEL(2) \
755 INIT_CALLS_LEVEL(3) \
756 INIT_CALLS_LEVEL(4) \
757 INIT_CALLS_LEVEL(5) \
758 INIT_CALLS_LEVEL(rootfs) \
759 INIT_CALLS_LEVEL(6) \
760 INIT_CALLS_LEVEL(7) \
761 VMLINUX_SYMBOL(__initcall_end) = .;
762
763 #define CON_INITCALL \
764 VMLINUX_SYMBOL(__con_initcall_start) = .; \
765 KEEP(*(.con_initcall.init)) \
766 VMLINUX_SYMBOL(__con_initcall_end) = .;
767
768 #define SECURITY_INITCALL \
769 VMLINUX_SYMBOL(__security_initcall_start) = .; \
770 KEEP(*(.security_initcall.init)) \
771 VMLINUX_SYMBOL(__security_initcall_end) = .;
772
773 #ifdef CONFIG_BLK_DEV_INITRD
774 #define INIT_RAM_FS \
775 . = ALIGN(4); \
776 VMLINUX_SYMBOL(__initramfs_start) = .; \
777 KEEP(*(.init.ramfs)) \
778 . = ALIGN(8); \
779 KEEP(*(.init.ramfs.info))
780 #else
781 #define INIT_RAM_FS
782 #endif
783
784 /*
785 * Memory encryption operates on a page basis. Since we need to clear
786 * the memory encryption mask for this section, it needs to be aligned
787 * on a page boundary and be a page-size multiple in length.
788 *
789 * Note: We use a separate section so that only this section gets
790 * decrypted to avoid exposing more than we wish.
791 */
792 #ifdef CONFIG_AMD_MEM_ENCRYPT
793 #define PERCPU_DECRYPTED_SECTION \
794 . = ALIGN(PAGE_SIZE); \
795 *(.data..percpu..decrypted) \
796 . = ALIGN(PAGE_SIZE);
797 #else
798 #define PERCPU_DECRYPTED_SECTION
799 #endif
800
801
802 /*
803 * Default discarded sections.
804 *
805 * Some archs want to discard exit text/data at runtime rather than
806 * link time due to cross-section references such as alt instructions,
807 * bug table, eh_frame, etc. DISCARDS must be the last of output
808 * section definitions so that such archs put those in earlier section
809 * definitions.
810 */
811 #define DISCARDS \
812 /DISCARD/ : { \
813 EXIT_TEXT \
814 EXIT_DATA \
815 EXIT_CALL \
816 *(.discard) \
817 *(.discard.*) \
818 }
819
820 /**
821 * PERCPU_INPUT - the percpu input sections
822 * @cacheline: cacheline size
823 *
824 * The core percpu section names and core symbols which do not rely
825 * directly upon load addresses.
826 *
827 * @cacheline is used to align subsections to avoid false cacheline
828 * sharing between subsections for different purposes.
829 */
830 #define PERCPU_INPUT(cacheline) \
831 VMLINUX_SYMBOL(__per_cpu_start) = .; \
832 *(.data..percpu..first) \
833 . = ALIGN(PAGE_SIZE); \
834 *(.data..percpu..page_aligned) \
835 . = ALIGN(cacheline); \
836 *(.data..percpu..read_mostly) \
837 . = ALIGN(cacheline); \
838 *(.data..percpu) \
839 *(.data..percpu..shared_aligned) \
840 PERCPU_DECRYPTED_SECTION \
841 VMLINUX_SYMBOL(__per_cpu_end) = .;
842
843 /**
844 * PERCPU_VADDR - define output section for percpu area
845 * @cacheline: cacheline size
846 * @vaddr: explicit base address (optional)
847 * @phdr: destination PHDR (optional)
848 *
849 * Macro which expands to output section for percpu area.
850 *
851 * @cacheline is used to align subsections to avoid false cacheline
852 * sharing between subsections for different purposes.
853 *
854 * If @vaddr is not blank, it specifies explicit base address and all
855 * percpu symbols will be offset from the given address. If blank,
856 * @vaddr always equals @laddr + LOAD_OFFSET.
857 *
858 * @phdr defines the output PHDR to use if not blank. Be warned that
859 * output PHDR is sticky. If @phdr is specified, the next output
860 * section in the linker script will go there too. @phdr should have
861 * a leading colon.
862 *
863 * Note that this macros defines __per_cpu_load as an absolute symbol.
864 * If there is no need to put the percpu section at a predetermined
865 * address, use PERCPU_SECTION.
866 */
867 #define PERCPU_VADDR(cacheline, vaddr, phdr) \
868 VMLINUX_SYMBOL(__per_cpu_load) = .; \
869 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
870 - LOAD_OFFSET) { \
871 PERCPU_INPUT(cacheline) \
872 } phdr \
873 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
874
875 /**
876 * PERCPU_SECTION - define output section for percpu area, simple version
877 * @cacheline: cacheline size
878 *
879 * Align to PAGE_SIZE and outputs output section for percpu area. This
880 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
881 * __per_cpu_start will be identical.
882 *
883 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
884 * except that __per_cpu_load is defined as a relative symbol against
885 * .data..percpu which is required for relocatable x86_32 configuration.
886 */
887 #define PERCPU_SECTION(cacheline) \
888 . = ALIGN(PAGE_SIZE); \
889 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
890 VMLINUX_SYMBOL(__per_cpu_load) = .; \
891 PERCPU_INPUT(cacheline) \
892 }
893
894
895 /*
896 * Definition of the high level *_SECTION macros
897 * They will fit only a subset of the architectures
898 */
899
900
901 /*
902 * Writeable data.
903 * All sections are combined in a single .data section.
904 * The sections following CONSTRUCTORS are arranged so their
905 * typical alignment matches.
906 * A cacheline is typical/always less than a PAGE_SIZE so
907 * the sections that has this restriction (or similar)
908 * is located before the ones requiring PAGE_SIZE alignment.
909 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
910 * matches the requirement of PAGE_ALIGNED_DATA.
911 *
912 * use 0 as page_align if page_aligned data is not used */
913 #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
914 . = ALIGN(PAGE_SIZE); \
915 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
916 INIT_TASK_DATA(inittask) \
917 NOSAVE_DATA \
918 PAGE_ALIGNED_DATA(pagealigned) \
919 CACHELINE_ALIGNED_DATA(cacheline) \
920 READ_MOSTLY_DATA(cacheline) \
921 DATA_DATA \
922 CONSTRUCTORS \
923 } \
924 BUG_TABLE \
925
926 #define INIT_TEXT_SECTION(inittext_align) \
927 . = ALIGN(inittext_align); \
928 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
929 VMLINUX_SYMBOL(_sinittext) = .; \
930 INIT_TEXT \
931 VMLINUX_SYMBOL(_einittext) = .; \
932 }
933
934 #define INIT_DATA_SECTION(initsetup_align) \
935 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
936 INIT_DATA \
937 INIT_SETUP(initsetup_align) \
938 INIT_CALLS \
939 CON_INITCALL \
940 SECURITY_INITCALL \
941 INIT_RAM_FS \
942 }
943
944 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
945 . = ALIGN(sbss_align); \
946 VMLINUX_SYMBOL(__bss_start) = .; \
947 SBSS(sbss_align) \
948 BSS(bss_align) \
949 . = ALIGN(stop_align); \
950 VMLINUX_SYMBOL(__bss_stop) = .;
ubuntu-bionic-kernel mirror