]> git.proxmox.com Git - mirror_ubuntu-artful-kernel.git/blob - include/asm-generic/vmlinux.lds.h
projects / mirror_ubuntu-artful-kernel.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
scsi: qedf: Fix a potential NULL pointer dereference
[mirror_ubuntu-artful-kernel.git] / include / asm-generic / vmlinux.lds.h
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53 #ifndef LOAD_OFFSET
54 #define LOAD_OFFSET 0
55 #endif
56
57 #include <linux/export.h>
58
59 /* Align . to a 8 byte boundary equals to maximum function alignment. */
60 #define ALIGN_FUNCTION() . = ALIGN(8)
61
62 /*
63 * Align to a 32 byte boundary equal to the
64 * alignment gcc 4.5 uses for a struct
65 */
66 #define STRUCT_ALIGNMENT 32
67 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
68
69 /* The actual configuration determine if the init/exit sections
70 * are handled as text/data or they can be discarded (which
71 * often happens at runtime)
72 */
73 #ifdef CONFIG_HOTPLUG_CPU
74 #define CPU_KEEP(sec) *(.cpu##sec)
75 #define CPU_DISCARD(sec)
76 #else
77 #define CPU_KEEP(sec)
78 #define CPU_DISCARD(sec) *(.cpu##sec)
79 #endif
80
81 #if defined(CONFIG_MEMORY_HOTPLUG)
82 #define MEM_KEEP(sec) *(.mem##sec)
83 #define MEM_DISCARD(sec)
84 #else
85 #define MEM_KEEP(sec)
86 #define MEM_DISCARD(sec) *(.mem##sec)
87 #endif
88
89 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
90 #define MCOUNT_REC() . = ALIGN(8); \
91 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
92 *(__mcount_loc) \
93 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
94 #else
95 #define MCOUNT_REC()
96 #endif
97
98 #ifdef CONFIG_TRACE_BRANCH_PROFILING
99 #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
100 *(_ftrace_annotated_branch) \
101 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
102 #else
103 #define LIKELY_PROFILE()
104 #endif
105
106 #ifdef CONFIG_PROFILE_ALL_BRANCHES
107 #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
108 *(_ftrace_branch) \
109 VMLINUX_SYMBOL(__stop_branch_profile) = .;
110 #else
111 #define BRANCH_PROFILE()
112 #endif
113
114 #ifdef CONFIG_KPROBES
115 #define KPROBE_BLACKLIST() . = ALIGN(8); \
116 VMLINUX_SYMBOL(__start_kprobe_blacklist) = .; \
117 KEEP(*(_kprobe_blacklist)) \
118 VMLINUX_SYMBOL(__stop_kprobe_blacklist) = .;
119 #else
120 #define KPROBE_BLACKLIST()
121 #endif
122
123 #ifdef CONFIG_EVENT_TRACING
124 #define FTRACE_EVENTS() . = ALIGN(8); \
125 VMLINUX_SYMBOL(__start_ftrace_events) = .; \
126 KEEP(*(_ftrace_events)) \
127 VMLINUX_SYMBOL(__stop_ftrace_events) = .; \
128 VMLINUX_SYMBOL(__start_ftrace_eval_maps) = .; \
129 KEEP(*(_ftrace_eval_map)) \
130 VMLINUX_SYMBOL(__stop_ftrace_eval_maps) = .;
131 #else
132 #define FTRACE_EVENTS()
133 #endif
134
135 #ifdef CONFIG_TRACING
136 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
137 KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
138 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
139 #define TRACEPOINT_STR() VMLINUX_SYMBOL(__start___tracepoint_str) = .; \
140 KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
141 VMLINUX_SYMBOL(__stop___tracepoint_str) = .;
142 #else
143 #define TRACE_PRINTKS()
144 #define TRACEPOINT_STR()
145 #endif
146
147 #ifdef CONFIG_FTRACE_SYSCALLS
148 #define TRACE_SYSCALLS() . = ALIGN(8); \
149 VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
150 KEEP(*(__syscalls_metadata)) \
151 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
152 #else
153 #define TRACE_SYSCALLS()
154 #endif
155
156 #ifdef CONFIG_SERIAL_EARLYCON
157 #define EARLYCON_TABLE() STRUCT_ALIGN(); \
158 VMLINUX_SYMBOL(__earlycon_table) = .; \
159 KEEP(*(__earlycon_table)) \
160 VMLINUX_SYMBOL(__earlycon_table_end) = .;
161 #else
162 #define EARLYCON_TABLE()
163 #endif
164
165 #define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
166 #define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
167 #define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
168 #define _OF_TABLE_0(name)
169 #define _OF_TABLE_1(name) \
170 . = ALIGN(8); \
171 VMLINUX_SYMBOL(__##name##_of_table) = .; \
172 KEEP(*(__##name##_of_table)) \
173 KEEP(*(__##name##_of_table_end))
174
175 #define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
176 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
177 #define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
178 #define IOMMU_OF_TABLES() OF_TABLE(CONFIG_OF_IOMMU, iommu)
179 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
180 #define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
181 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
182
183 #ifdef CONFIG_ACPI
184 #define ACPI_PROBE_TABLE(name) \
185 . = ALIGN(8); \
186 VMLINUX_SYMBOL(__##name##_acpi_probe_table) = .; \
187 KEEP(*(__##name##_acpi_probe_table)) \
188 VMLINUX_SYMBOL(__##name##_acpi_probe_table_end) = .;
189 #else
190 #define ACPI_PROBE_TABLE(name)
191 #endif
192
193 #define KERNEL_DTB() \
194 STRUCT_ALIGN(); \
195 VMLINUX_SYMBOL(__dtb_start) = .; \
196 KEEP(*(.dtb.init.rodata)) \
197 VMLINUX_SYMBOL(__dtb_end) = .;
198
199 /*
200 * .data section
201 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections generates
202 * .data.identifier which needs to be pulled in with .data, but don't want to
203 * pull in .data..stuff which has its own requirements. Same for bss.
204 */
205 #define DATA_DATA \
206 *(.data .data.[0-9a-zA-Z_]*) \
207 *(.ref.data) \
208 *(.data..shared_aligned) /* percpu related */ \
209 MEM_KEEP(init.data) \
210 MEM_KEEP(exit.data) \
211 *(.data.unlikely) \
212 STRUCT_ALIGN(); \
213 *(__tracepoints) \
214 /* implement dynamic printk debug */ \
215 . = ALIGN(8); \
216 VMLINUX_SYMBOL(__start___jump_table) = .; \
217 KEEP(*(__jump_table)) \
218 VMLINUX_SYMBOL(__stop___jump_table) = .; \
219 . = ALIGN(8); \
220 VMLINUX_SYMBOL(__start___verbose) = .; \
221 KEEP(*(__verbose)) \
222 VMLINUX_SYMBOL(__stop___verbose) = .; \
223 LIKELY_PROFILE() \
224 BRANCH_PROFILE() \
225 TRACE_PRINTKS() \
226 TRACEPOINT_STR()
227
228 /*
229 * Data section helpers
230 */
231 #define NOSAVE_DATA \
232 . = ALIGN(PAGE_SIZE); \
233 VMLINUX_SYMBOL(__nosave_begin) = .; \
234 *(.data..nosave) \
235 . = ALIGN(PAGE_SIZE); \
236 VMLINUX_SYMBOL(__nosave_end) = .;
237
238 #define PAGE_ALIGNED_DATA(page_align) \
239 . = ALIGN(page_align); \
240 *(.data..page_aligned)
241
242 #define READ_MOSTLY_DATA(align) \
243 . = ALIGN(align); \
244 *(.data..read_mostly) \
245 . = ALIGN(align);
246
247 #define CACHELINE_ALIGNED_DATA(align) \
248 . = ALIGN(align); \
249 *(.data..cacheline_aligned)
250
251 #define INIT_TASK_DATA(align) \
252 . = ALIGN(align); \
253 VMLINUX_SYMBOL(__start_init_task) = .; \
254 *(.data..init_task) \
255 VMLINUX_SYMBOL(__end_init_task) = .;
256
257 /*
258 * Allow architectures to handle ro_after_init data on their
259 * own by defining an empty RO_AFTER_INIT_DATA.
260 */
261 #ifndef RO_AFTER_INIT_DATA
262 #define RO_AFTER_INIT_DATA \
263 VMLINUX_SYMBOL(__start_ro_after_init) = .; \
264 *(.data..ro_after_init) \
265 VMLINUX_SYMBOL(__end_ro_after_init) = .;
266 #endif
267
268 /*
269 * Read only Data
270 */
271 #define RO_DATA_SECTION(align) \
272 . = ALIGN((align)); \
273 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
274 VMLINUX_SYMBOL(__start_rodata) = .; \
275 *(.rodata) *(.rodata.*) \
276 RO_AFTER_INIT_DATA /* Read only after init */ \
277 KEEP(*(__vermagic)) /* Kernel version magic */ \
278 . = ALIGN(8); \
279 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .; \
280 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
281 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .; \
282 *(__tracepoints_strings)/* Tracepoints: strings */ \
283 } \
284 \
285 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
286 *(.rodata1) \
287 } \
288 \
289 /* PCI quirks */ \
290 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
291 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
292 KEEP(*(.pci_fixup_early)) \
293 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
294 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
295 KEEP(*(.pci_fixup_header)) \
296 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
297 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
298 KEEP(*(.pci_fixup_final)) \
299 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
300 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
301 KEEP(*(.pci_fixup_enable)) \
302 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
303 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
304 KEEP(*(.pci_fixup_resume)) \
305 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
306 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
307 KEEP(*(.pci_fixup_resume_early)) \
308 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
309 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
310 KEEP(*(.pci_fixup_suspend)) \
311 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
312 VMLINUX_SYMBOL(__start_pci_fixups_suspend_late) = .; \
313 KEEP(*(.pci_fixup_suspend_late)) \
314 VMLINUX_SYMBOL(__end_pci_fixups_suspend_late) = .; \
315 } \
316 \
317 /* Built-in firmware blobs */ \
318 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
319 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
320 KEEP(*(.builtin_fw)) \
321 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
322 } \
323 \
324 TRACEDATA \
325 \
326 /* Kernel symbol table: Normal symbols */ \
327 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
328 VMLINUX_SYMBOL(__start___ksymtab) = .; \
329 KEEP(*(SORT(___ksymtab+*))) \
330 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
331 } \
332 \
333 /* Kernel symbol table: GPL-only symbols */ \
334 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
335 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
336 KEEP(*(SORT(___ksymtab_gpl+*))) \
337 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
338 } \
339 \
340 /* Kernel symbol table: Normal unused symbols */ \
341 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
342 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
343 KEEP(*(SORT(___ksymtab_unused+*))) \
344 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
345 } \
346 \
347 /* Kernel symbol table: GPL-only unused symbols */ \
348 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
349 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
350 KEEP(*(SORT(___ksymtab_unused_gpl+*))) \
351 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
352 } \
353 \
354 /* Kernel symbol table: GPL-future-only symbols */ \
355 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
356 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
357 KEEP(*(SORT(___ksymtab_gpl_future+*))) \
358 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
359 } \
360 \
361 /* Kernel symbol table: Normal symbols */ \
362 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
363 VMLINUX_SYMBOL(__start___kcrctab) = .; \
364 KEEP(*(SORT(___kcrctab+*))) \
365 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
366 } \
367 \
368 /* Kernel symbol table: GPL-only symbols */ \
369 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
370 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
371 KEEP(*(SORT(___kcrctab_gpl+*))) \
372 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
373 } \
374 \
375 /* Kernel symbol table: Normal unused symbols */ \
376 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
377 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
378 KEEP(*(SORT(___kcrctab_unused+*))) \
379 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
380 } \
381 \
382 /* Kernel symbol table: GPL-only unused symbols */ \
383 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
384 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
385 KEEP(*(SORT(___kcrctab_unused_gpl+*))) \
386 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
387 } \
388 \
389 /* Kernel symbol table: GPL-future-only symbols */ \
390 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
391 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
392 KEEP(*(SORT(___kcrctab_gpl_future+*))) \
393 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
394 } \
395 \
396 /* Kernel symbol table: strings */ \
397 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
398 *(__ksymtab_strings) \
399 } \
400 \
401 /* __*init sections */ \
402 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
403 *(.ref.rodata) \
404 MEM_KEEP(init.rodata) \
405 MEM_KEEP(exit.rodata) \
406 } \
407 \
408 /* Built-in module parameters. */ \
409 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
410 VMLINUX_SYMBOL(__start___param) = .; \
411 KEEP(*(__param)) \
412 VMLINUX_SYMBOL(__stop___param) = .; \
413 } \
414 \
415 /* Built-in module versions. */ \
416 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
417 VMLINUX_SYMBOL(__start___modver) = .; \
418 KEEP(*(__modver)) \
419 VMLINUX_SYMBOL(__stop___modver) = .; \
420 . = ALIGN((align)); \
421 VMLINUX_SYMBOL(__end_rodata) = .; \
422 } \
423 . = ALIGN((align));
424
425 /* RODATA & RO_DATA provided for backward compatibility.
426 * All archs are supposed to use RO_DATA() */
427 #define RODATA RO_DATA_SECTION(4096)
428 #define RO_DATA(align) RO_DATA_SECTION(align)
429
430 #define SECURITY_INIT \
431 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
432 VMLINUX_SYMBOL(__security_initcall_start) = .; \
433 KEEP(*(.security_initcall.init)) \
434 VMLINUX_SYMBOL(__security_initcall_end) = .; \
435 }
436
437 /* .text section. Map to function alignment to avoid address changes
438 * during second ld run in second ld pass when generating System.map
439 * LD_DEAD_CODE_DATA_ELIMINATION option enables -ffunction-sections generates
440 * .text.identifier which needs to be pulled in with .text , but some
441 * architectures define .text.foo which is not intended to be pulled in here.
442 * Those enabling LD_DEAD_CODE_DATA_ELIMINATION must ensure they don't have
443 * conflicting section names, and must pull in .text.[0-9a-zA-Z_]* */
444 #define TEXT_TEXT \
445 ALIGN_FUNCTION(); \
446 *(.text.hot .text .text.fixup .text.unlikely) \
447 *(.ref.text) \
448 MEM_KEEP(init.text) \
449 MEM_KEEP(exit.text) \
450
451
452 /* sched.text is aling to function alignment to secure we have same
453 * address even at second ld pass when generating System.map */
454 #define SCHED_TEXT \
455 ALIGN_FUNCTION(); \
456 VMLINUX_SYMBOL(__sched_text_start) = .; \
457 *(.sched.text) \
458 VMLINUX_SYMBOL(__sched_text_end) = .;
459
460 /* spinlock.text is aling to function alignment to secure we have same
461 * address even at second ld pass when generating System.map */
462 #define LOCK_TEXT \
463 ALIGN_FUNCTION(); \
464 VMLINUX_SYMBOL(__lock_text_start) = .; \
465 *(.spinlock.text) \
466 VMLINUX_SYMBOL(__lock_text_end) = .;
467
468 #define CPUIDLE_TEXT \
469 ALIGN_FUNCTION(); \
470 VMLINUX_SYMBOL(__cpuidle_text_start) = .; \
471 *(.cpuidle.text) \
472 VMLINUX_SYMBOL(__cpuidle_text_end) = .;
473
474 #define KPROBES_TEXT \
475 ALIGN_FUNCTION(); \
476 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
477 *(.kprobes.text) \
478 VMLINUX_SYMBOL(__kprobes_text_end) = .;
479
480 #define ENTRY_TEXT \
481 ALIGN_FUNCTION(); \
482 VMLINUX_SYMBOL(__entry_text_start) = .; \
483 *(.entry.text) \
484 VMLINUX_SYMBOL(__entry_text_end) = .;
485
486 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
487 #define IRQENTRY_TEXT \
488 ALIGN_FUNCTION(); \
489 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
490 *(.irqentry.text) \
491 VMLINUX_SYMBOL(__irqentry_text_end) = .;
492 #else
493 #define IRQENTRY_TEXT
494 #endif
495
496 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
497 #define SOFTIRQENTRY_TEXT \
498 ALIGN_FUNCTION(); \
499 VMLINUX_SYMBOL(__softirqentry_text_start) = .; \
500 *(.softirqentry.text) \
501 VMLINUX_SYMBOL(__softirqentry_text_end) = .;
502 #else
503 #define SOFTIRQENTRY_TEXT
504 #endif
505
506 /* Section used for early init (in .S files) */
507 #define HEAD_TEXT *(.head.text)
508
509 #define HEAD_TEXT_SECTION \
510 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
511 HEAD_TEXT \
512 }
513
514 /*
515 * Exception table
516 */
517 #define EXCEPTION_TABLE(align) \
518 . = ALIGN(align); \
519 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
520 VMLINUX_SYMBOL(__start___ex_table) = .; \
521 KEEP(*(__ex_table)) \
522 VMLINUX_SYMBOL(__stop___ex_table) = .; \
523 }
524
525 /*
526 * Init task
527 */
528 #define INIT_TASK_DATA_SECTION(align) \
529 . = ALIGN(align); \
530 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
531 INIT_TASK_DATA(align) \
532 }
533
534 #ifdef CONFIG_CONSTRUCTORS
535 #define KERNEL_CTORS() . = ALIGN(8); \
536 VMLINUX_SYMBOL(__ctors_start) = .; \
537 KEEP(*(.ctors)) \
538 KEEP(*(SORT(.init_array.*))) \
539 KEEP(*(.init_array)) \
540 VMLINUX_SYMBOL(__ctors_end) = .;
541 #else
542 #define KERNEL_CTORS()
543 #endif
544
545 /* init and exit section handling */
546 #define INIT_DATA \
547 KEEP(*(SORT(___kentry+*))) \
548 *(.init.data) \
549 MEM_DISCARD(init.data) \
550 KERNEL_CTORS() \
551 MCOUNT_REC() \
552 *(.init.rodata) \
553 FTRACE_EVENTS() \
554 TRACE_SYSCALLS() \
555 KPROBE_BLACKLIST() \
556 MEM_DISCARD(init.rodata) \
557 CLK_OF_TABLES() \
558 RESERVEDMEM_OF_TABLES() \
559 TIMER_OF_TABLES() \
560 IOMMU_OF_TABLES() \
561 CPU_METHOD_OF_TABLES() \
562 CPUIDLE_METHOD_OF_TABLES() \
563 KERNEL_DTB() \
564 IRQCHIP_OF_MATCH_TABLE() \
565 ACPI_PROBE_TABLE(irqchip) \
566 ACPI_PROBE_TABLE(timer) \
567 ACPI_PROBE_TABLE(iort) \
568 EARLYCON_TABLE()
569
570 #define INIT_TEXT \
571 *(.init.text) \
572 *(.text.startup) \
573 MEM_DISCARD(init.text)
574
575 #define EXIT_DATA \
576 *(.exit.data) \
577 *(.fini_array) \
578 *(.dtors) \
579 MEM_DISCARD(exit.data) \
580 MEM_DISCARD(exit.rodata)
581
582 #define EXIT_TEXT \
583 *(.exit.text) \
584 *(.text.exit) \
585 MEM_DISCARD(exit.text)
586
587 #define EXIT_CALL \
588 *(.exitcall.exit)
589
590 /*
591 * bss (Block Started by Symbol) - uninitialized data
592 * zeroed during startup
593 */
594 #define SBSS(sbss_align) \
595 . = ALIGN(sbss_align); \
596 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
597 *(.dynsbss) \
598 *(.sbss) \
599 *(.scommon) \
600 }
601
602 /*
603 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
604 * sections to the front of bss.
605 */
606 #ifndef BSS_FIRST_SECTIONS
607 #define BSS_FIRST_SECTIONS
608 #endif
609
610 #define BSS(bss_align) \
611 . = ALIGN(bss_align); \
612 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
613 BSS_FIRST_SECTIONS \
614 *(.bss..page_aligned) \
615 *(.dynbss) \
616 *(.bss .bss.[0-9a-zA-Z_]*) \
617 *(COMMON) \
618 }
619
620 /*
621 * DWARF debug sections.
622 * Symbols in the DWARF debugging sections are relative to
623 * the beginning of the section so we begin them at 0.
624 */
625 #define DWARF_DEBUG \
626 /* DWARF 1 */ \
627 .debug 0 : { *(.debug) } \
628 .line 0 : { *(.line) } \
629 /* GNU DWARF 1 extensions */ \
630 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
631 .debug_sfnames 0 : { *(.debug_sfnames) } \
632 /* DWARF 1.1 and DWARF 2 */ \
633 .debug_aranges 0 : { *(.debug_aranges) } \
634 .debug_pubnames 0 : { *(.debug_pubnames) } \
635 /* DWARF 2 */ \
636 .debug_info 0 : { *(.debug_info \
637 .gnu.linkonce.wi.*) } \
638 .debug_abbrev 0 : { *(.debug_abbrev) } \
639 .debug_line 0 : { *(.debug_line) } \
640 .debug_frame 0 : { *(.debug_frame) } \
641 .debug_str 0 : { *(.debug_str) } \
642 .debug_loc 0 : { *(.debug_loc) } \
643 .debug_macinfo 0 : { *(.debug_macinfo) } \
644 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
645 /* DWARF 3 */ \
646 .debug_ranges 0 : { *(.debug_ranges) } \
647 /* SGI/MIPS DWARF 2 extensions */ \
648 .debug_weaknames 0 : { *(.debug_weaknames) } \
649 .debug_funcnames 0 : { *(.debug_funcnames) } \
650 .debug_typenames 0 : { *(.debug_typenames) } \
651 .debug_varnames 0 : { *(.debug_varnames) } \
652 /* GNU DWARF 2 extensions */ \
653 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
654 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
655 /* DWARF 4 */ \
656 .debug_types 0 : { *(.debug_types) } \
657 /* DWARF 5 */ \
658 .debug_macro 0 : { *(.debug_macro) } \
659 .debug_addr 0 : { *(.debug_addr) }
660
661 /* Stabs debugging sections. */
662 #define STABS_DEBUG \
663 .stab 0 : { *(.stab) } \
664 .stabstr 0 : { *(.stabstr) } \
665 .stab.excl 0 : { *(.stab.excl) } \
666 .stab.exclstr 0 : { *(.stab.exclstr) } \
667 .stab.index 0 : { *(.stab.index) } \
668 .stab.indexstr 0 : { *(.stab.indexstr) } \
669 .comment 0 : { *(.comment) }
670
671 #ifdef CONFIG_GENERIC_BUG
672 #define BUG_TABLE \
673 . = ALIGN(8); \
674 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
675 VMLINUX_SYMBOL(__start___bug_table) = .; \
676 KEEP(*(__bug_table)) \
677 VMLINUX_SYMBOL(__stop___bug_table) = .; \
678 }
679 #else
680 #define BUG_TABLE
681 #endif
682
683 #ifdef CONFIG_PM_TRACE
684 #define TRACEDATA \
685 . = ALIGN(4); \
686 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
687 VMLINUX_SYMBOL(__tracedata_start) = .; \
688 KEEP(*(.tracedata)) \
689 VMLINUX_SYMBOL(__tracedata_end) = .; \
690 }
691 #else
692 #define TRACEDATA
693 #endif
694
695 #define NOTES \
696 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
697 VMLINUX_SYMBOL(__start_notes) = .; \
698 *(.note.*) \
699 VMLINUX_SYMBOL(__stop_notes) = .; \
700 }
701
702 #define INIT_SETUP(initsetup_align) \
703 . = ALIGN(initsetup_align); \
704 VMLINUX_SYMBOL(__setup_start) = .; \
705 KEEP(*(.init.setup)) \
706 VMLINUX_SYMBOL(__setup_end) = .;
707
708 #define INIT_CALLS_LEVEL(level) \
709 VMLINUX_SYMBOL(__initcall##level##_start) = .; \
710 KEEP(*(.initcall##level##.init)) \
711 KEEP(*(.initcall##level##s.init)) \
712
713 #define INIT_CALLS \
714 VMLINUX_SYMBOL(__initcall_start) = .; \
715 KEEP(*(.initcallearly.init)) \
716 INIT_CALLS_LEVEL(0) \
717 INIT_CALLS_LEVEL(1) \
718 INIT_CALLS_LEVEL(2) \
719 INIT_CALLS_LEVEL(3) \
720 INIT_CALLS_LEVEL(4) \
721 INIT_CALLS_LEVEL(5) \
722 INIT_CALLS_LEVEL(rootfs) \
723 INIT_CALLS_LEVEL(6) \
724 INIT_CALLS_LEVEL(7) \
725 VMLINUX_SYMBOL(__initcall_end) = .;
726
727 #define CON_INITCALL \
728 VMLINUX_SYMBOL(__con_initcall_start) = .; \
729 KEEP(*(.con_initcall.init)) \
730 VMLINUX_SYMBOL(__con_initcall_end) = .;
731
732 #define SECURITY_INITCALL \
733 VMLINUX_SYMBOL(__security_initcall_start) = .; \
734 KEEP(*(.security_initcall.init)) \
735 VMLINUX_SYMBOL(__security_initcall_end) = .;
736
737 #ifdef CONFIG_BLK_DEV_INITRD
738 #define INIT_RAM_FS \
739 . = ALIGN(4); \
740 VMLINUX_SYMBOL(__initramfs_start) = .; \
741 KEEP(*(.init.ramfs)) \
742 . = ALIGN(8); \
743 KEEP(*(.init.ramfs.info))
744 #else
745 #define INIT_RAM_FS
746 #endif
747
748 /*
749 * Default discarded sections.
750 *
751 * Some archs want to discard exit text/data at runtime rather than
752 * link time due to cross-section references such as alt instructions,
753 * bug table, eh_frame, etc. DISCARDS must be the last of output
754 * section definitions so that such archs put those in earlier section
755 * definitions.
756 */
757 #define DISCARDS \
758 /DISCARD/ : { \
759 EXIT_TEXT \
760 EXIT_DATA \
761 EXIT_CALL \
762 *(.discard) \
763 *(.discard.*) \
764 }
765
766 /**
767 * PERCPU_INPUT - the percpu input sections
768 * @cacheline: cacheline size
769 *
770 * The core percpu section names and core symbols which do not rely
771 * directly upon load addresses.
772 *
773 * @cacheline is used to align subsections to avoid false cacheline
774 * sharing between subsections for different purposes.
775 */
776 #define PERCPU_INPUT(cacheline) \
777 VMLINUX_SYMBOL(__per_cpu_start) = .; \
778 *(.data..percpu..first) \
779 . = ALIGN(PAGE_SIZE); \
780 *(.data..percpu..page_aligned) \
781 . = ALIGN(cacheline); \
782 *(.data..percpu..read_mostly) \
783 . = ALIGN(cacheline); \
784 *(.data..percpu) \
785 *(.data..percpu..shared_aligned) \
786 VMLINUX_SYMBOL(__per_cpu_end) = .;
787
788 /**
789 * PERCPU_VADDR - define output section for percpu area
790 * @cacheline: cacheline size
791 * @vaddr: explicit base address (optional)
792 * @phdr: destination PHDR (optional)
793 *
794 * Macro which expands to output section for percpu area.
795 *
796 * @cacheline is used to align subsections to avoid false cacheline
797 * sharing between subsections for different purposes.
798 *
799 * If @vaddr is not blank, it specifies explicit base address and all
800 * percpu symbols will be offset from the given address. If blank,
801 * @vaddr always equals @laddr + LOAD_OFFSET.
802 *
803 * @phdr defines the output PHDR to use if not blank. Be warned that
804 * output PHDR is sticky. If @phdr is specified, the next output
805 * section in the linker script will go there too. @phdr should have
806 * a leading colon.
807 *
808 * Note that this macros defines __per_cpu_load as an absolute symbol.
809 * If there is no need to put the percpu section at a predetermined
810 * address, use PERCPU_SECTION.
811 */
812 #define PERCPU_VADDR(cacheline, vaddr, phdr) \
813 VMLINUX_SYMBOL(__per_cpu_load) = .; \
814 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
815 - LOAD_OFFSET) { \
816 PERCPU_INPUT(cacheline) \
817 } phdr \
818 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
819
820 /**
821 * PERCPU_SECTION - define output section for percpu area, simple version
822 * @cacheline: cacheline size
823 *
824 * Align to PAGE_SIZE and outputs output section for percpu area. This
825 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
826 * __per_cpu_start will be identical.
827 *
828 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
829 * except that __per_cpu_load is defined as a relative symbol against
830 * .data..percpu which is required for relocatable x86_32 configuration.
831 */
832 #define PERCPU_SECTION(cacheline) \
833 . = ALIGN(PAGE_SIZE); \
834 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
835 VMLINUX_SYMBOL(__per_cpu_load) = .; \
836 PERCPU_INPUT(cacheline) \
837 }
838
839
840 /*
841 * Definition of the high level *_SECTION macros
842 * They will fit only a subset of the architectures
843 */
844
845
846 /*
847 * Writeable data.
848 * All sections are combined in a single .data section.
849 * The sections following CONSTRUCTORS are arranged so their
850 * typical alignment matches.
851 * A cacheline is typical/always less than a PAGE_SIZE so
852 * the sections that has this restriction (or similar)
853 * is located before the ones requiring PAGE_SIZE alignment.
854 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
855 * matches the requirement of PAGE_ALIGNED_DATA.
856 *
857 * use 0 as page_align if page_aligned data is not used */
858 #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
859 . = ALIGN(PAGE_SIZE); \
860 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
861 INIT_TASK_DATA(inittask) \
862 NOSAVE_DATA \
863 PAGE_ALIGNED_DATA(pagealigned) \
864 CACHELINE_ALIGNED_DATA(cacheline) \
865 READ_MOSTLY_DATA(cacheline) \
866 DATA_DATA \
867 CONSTRUCTORS \
868 } \
869 BUG_TABLE
870
871 #define INIT_TEXT_SECTION(inittext_align) \
872 . = ALIGN(inittext_align); \
873 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
874 VMLINUX_SYMBOL(_sinittext) = .; \
875 INIT_TEXT \
876 VMLINUX_SYMBOL(_einittext) = .; \
877 }
878
879 #define INIT_DATA_SECTION(initsetup_align) \
880 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
881 INIT_DATA \
882 INIT_SETUP(initsetup_align) \
883 INIT_CALLS \
884 CON_INITCALL \
885 SECURITY_INITCALL \
886 INIT_RAM_FS \
887 }
888
889 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
890 . = ALIGN(sbss_align); \
891 VMLINUX_SYMBOL(__bss_start) = .; \
892 SBSS(sbss_align) \
893 BSS(bss_align) \
894 . = ALIGN(stop_align); \
895 VMLINUX_SYMBOL(__bss_stop) = .;
Ubuntu Artful kernel mirror