]> git.proxmox.com Git - mirror_ubuntu-bionic-kernel.git/blob - include/asm-generic/vmlinux.lds.h
projects / mirror_ubuntu-bionic-kernel.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
Merge branch 'x86-amd-nb-for-linus' of git://git.kernel.org/pub/scm/linux/kernel...
[mirror_ubuntu-bionic-kernel.git] / include / asm-generic / vmlinux.lds.h
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU(PAGE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * [_stext, _etext] is the text section
44 * [_sdata, _edata] is the data section
45 *
46 * Some of the included output section have their own set of constants.
47 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
48 * [__nosave_begin, __nosave_end] for the nosave data
49 */
50
51 #ifndef LOAD_OFFSET
52 #define LOAD_OFFSET 0
53 #endif
54
55 #ifndef SYMBOL_PREFIX
56 #define VMLINUX_SYMBOL(sym) sym
57 #else
58 #define PASTE2(x,y) x##y
59 #define PASTE(x,y) PASTE2(x,y)
60 #define VMLINUX_SYMBOL(sym) PASTE(SYMBOL_PREFIX, sym)
61 #endif
62
63 /* Align . to a 8 byte boundary equals to maximum function alignment. */
64 #define ALIGN_FUNCTION() . = ALIGN(8)
65
66 /*
67 * Align to a 32 byte boundary equal to the
68 * alignment gcc 4.5 uses for a struct
69 */
70 #define STRUCT_ALIGN() . = ALIGN(32)
71
72 /* The actual configuration determine if the init/exit sections
73 * are handled as text/data or they can be discarded (which
74 * often happens at runtime)
75 */
76 #ifdef CONFIG_HOTPLUG
77 #define DEV_KEEP(sec) *(.dev##sec)
78 #define DEV_DISCARD(sec)
79 #else
80 #define DEV_KEEP(sec)
81 #define DEV_DISCARD(sec) *(.dev##sec)
82 #endif
83
84 #ifdef CONFIG_HOTPLUG_CPU
85 #define CPU_KEEP(sec) *(.cpu##sec)
86 #define CPU_DISCARD(sec)
87 #else
88 #define CPU_KEEP(sec)
89 #define CPU_DISCARD(sec) *(.cpu##sec)
90 #endif
91
92 #if defined(CONFIG_MEMORY_HOTPLUG)
93 #define MEM_KEEP(sec) *(.mem##sec)
94 #define MEM_DISCARD(sec)
95 #else
96 #define MEM_KEEP(sec)
97 #define MEM_DISCARD(sec) *(.mem##sec)
98 #endif
99
100 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
101 #define MCOUNT_REC() . = ALIGN(8); \
102 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
103 *(__mcount_loc) \
104 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
105 #else
106 #define MCOUNT_REC()
107 #endif
108
109 #ifdef CONFIG_TRACE_BRANCH_PROFILING
110 #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
111 *(_ftrace_annotated_branch) \
112 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
113 #else
114 #define LIKELY_PROFILE()
115 #endif
116
117 #ifdef CONFIG_PROFILE_ALL_BRANCHES
118 #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
119 *(_ftrace_branch) \
120 VMLINUX_SYMBOL(__stop_branch_profile) = .;
121 #else
122 #define BRANCH_PROFILE()
123 #endif
124
125 #ifdef CONFIG_EVENT_TRACING
126 #define FTRACE_EVENTS() VMLINUX_SYMBOL(__start_ftrace_events) = .; \
127 *(_ftrace_events) \
128 VMLINUX_SYMBOL(__stop_ftrace_events) = .;
129 #else
130 #define FTRACE_EVENTS()
131 #endif
132
133 #ifdef CONFIG_TRACING
134 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
135 *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
136 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
137 #else
138 #define TRACE_PRINTKS()
139 #endif
140
141 #ifdef CONFIG_FTRACE_SYSCALLS
142 #define TRACE_SYSCALLS() VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
143 *(__syscalls_metadata) \
144 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
145 #else
146 #define TRACE_SYSCALLS()
147 #endif
148
149 /* .data section */
150 #define DATA_DATA \
151 *(.data) \
152 *(.ref.data) \
153 DEV_KEEP(init.data) \
154 DEV_KEEP(exit.data) \
155 CPU_KEEP(init.data) \
156 CPU_KEEP(exit.data) \
157 MEM_KEEP(init.data) \
158 MEM_KEEP(exit.data) \
159 . = ALIGN(32); \
160 VMLINUX_SYMBOL(__start___tracepoints) = .; \
161 *(__tracepoints) \
162 VMLINUX_SYMBOL(__stop___tracepoints) = .; \
163 /* implement dynamic printk debug */ \
164 . = ALIGN(8); \
165 VMLINUX_SYMBOL(__start___verbose) = .; \
166 *(__verbose) \
167 VMLINUX_SYMBOL(__stop___verbose) = .; \
168 LIKELY_PROFILE() \
169 BRANCH_PROFILE() \
170 TRACE_PRINTKS() \
171 \
172 STRUCT_ALIGN(); \
173 FTRACE_EVENTS() \
174 \
175 STRUCT_ALIGN(); \
176 TRACE_SYSCALLS()
177
178 /*
179 * Data section helpers
180 */
181 #define NOSAVE_DATA \
182 . = ALIGN(PAGE_SIZE); \
183 VMLINUX_SYMBOL(__nosave_begin) = .; \
184 *(.data..nosave) \
185 . = ALIGN(PAGE_SIZE); \
186 VMLINUX_SYMBOL(__nosave_end) = .;
187
188 #define PAGE_ALIGNED_DATA(page_align) \
189 . = ALIGN(page_align); \
190 *(.data..page_aligned)
191
192 #define READ_MOSTLY_DATA(align) \
193 . = ALIGN(align); \
194 *(.data..read_mostly)
195
196 #define CACHELINE_ALIGNED_DATA(align) \
197 . = ALIGN(align); \
198 *(.data..cacheline_aligned)
199
200 #define INIT_TASK_DATA(align) \
201 . = ALIGN(align); \
202 *(.data..init_task)
203
204 /*
205 * Read only Data
206 */
207 #define RO_DATA_SECTION(align) \
208 . = ALIGN((align)); \
209 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
210 VMLINUX_SYMBOL(__start_rodata) = .; \
211 *(.rodata) *(.rodata.*) \
212 *(__vermagic) /* Kernel version magic */ \
213 *(__markers_strings) /* Markers: strings */ \
214 *(__tracepoints_strings)/* Tracepoints: strings */ \
215 } \
216 \
217 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
218 *(.rodata1) \
219 } \
220 \
221 BUG_TABLE \
222 \
223 JUMP_TABLE \
224 \
225 /* PCI quirks */ \
226 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
227 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
228 *(.pci_fixup_early) \
229 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
230 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
231 *(.pci_fixup_header) \
232 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
233 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
234 *(.pci_fixup_final) \
235 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
236 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
237 *(.pci_fixup_enable) \
238 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
239 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
240 *(.pci_fixup_resume) \
241 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
242 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
243 *(.pci_fixup_resume_early) \
244 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
245 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
246 *(.pci_fixup_suspend) \
247 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
248 } \
249 \
250 /* Built-in firmware blobs */ \
251 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
252 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
253 *(.builtin_fw) \
254 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
255 } \
256 \
257 /* RapidIO route ops */ \
258 .rio_ops : AT(ADDR(.rio_ops) - LOAD_OFFSET) { \
259 VMLINUX_SYMBOL(__start_rio_switch_ops) = .; \
260 *(.rio_switch_ops) \
261 VMLINUX_SYMBOL(__end_rio_switch_ops) = .; \
262 } \
263 \
264 TRACEDATA \
265 \
266 /* Kernel symbol table: Normal symbols */ \
267 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
268 VMLINUX_SYMBOL(__start___ksymtab) = .; \
269 *(__ksymtab) \
270 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
271 } \
272 \
273 /* Kernel symbol table: GPL-only symbols */ \
274 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
275 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
276 *(__ksymtab_gpl) \
277 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
278 } \
279 \
280 /* Kernel symbol table: Normal unused symbols */ \
281 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
282 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
283 *(__ksymtab_unused) \
284 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
285 } \
286 \
287 /* Kernel symbol table: GPL-only unused symbols */ \
288 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
289 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
290 *(__ksymtab_unused_gpl) \
291 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
292 } \
293 \
294 /* Kernel symbol table: GPL-future-only symbols */ \
295 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
296 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
297 *(__ksymtab_gpl_future) \
298 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
299 } \
300 \
301 /* Kernel symbol table: Normal symbols */ \
302 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
303 VMLINUX_SYMBOL(__start___kcrctab) = .; \
304 *(__kcrctab) \
305 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
306 } \
307 \
308 /* Kernel symbol table: GPL-only symbols */ \
309 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
310 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
311 *(__kcrctab_gpl) \
312 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
313 } \
314 \
315 /* Kernel symbol table: Normal unused symbols */ \
316 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
317 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
318 *(__kcrctab_unused) \
319 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
320 } \
321 \
322 /* Kernel symbol table: GPL-only unused symbols */ \
323 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
324 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
325 *(__kcrctab_unused_gpl) \
326 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
327 } \
328 \
329 /* Kernel symbol table: GPL-future-only symbols */ \
330 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
331 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
332 *(__kcrctab_gpl_future) \
333 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
334 } \
335 \
336 /* Kernel symbol table: strings */ \
337 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
338 *(__ksymtab_strings) \
339 } \
340 \
341 /* __*init sections */ \
342 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
343 *(.ref.rodata) \
344 DEV_KEEP(init.rodata) \
345 DEV_KEEP(exit.rodata) \
346 CPU_KEEP(init.rodata) \
347 CPU_KEEP(exit.rodata) \
348 MEM_KEEP(init.rodata) \
349 MEM_KEEP(exit.rodata) \
350 } \
351 \
352 /* Built-in module parameters. */ \
353 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
354 VMLINUX_SYMBOL(__start___param) = .; \
355 *(__param) \
356 VMLINUX_SYMBOL(__stop___param) = .; \
357 . = ALIGN((align)); \
358 VMLINUX_SYMBOL(__end_rodata) = .; \
359 } \
360 . = ALIGN((align));
361
362 /* RODATA & RO_DATA provided for backward compatibility.
363 * All archs are supposed to use RO_DATA() */
364 #define RODATA RO_DATA_SECTION(4096)
365 #define RO_DATA(align) RO_DATA_SECTION(align)
366
367 #define SECURITY_INIT \
368 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
369 VMLINUX_SYMBOL(__security_initcall_start) = .; \
370 *(.security_initcall.init) \
371 VMLINUX_SYMBOL(__security_initcall_end) = .; \
372 }
373
374 /* .text section. Map to function alignment to avoid address changes
375 * during second ld run in second ld pass when generating System.map */
376 #define TEXT_TEXT \
377 ALIGN_FUNCTION(); \
378 *(.text.hot) \
379 *(.text) \
380 *(.ref.text) \
381 DEV_KEEP(init.text) \
382 DEV_KEEP(exit.text) \
383 CPU_KEEP(init.text) \
384 CPU_KEEP(exit.text) \
385 MEM_KEEP(init.text) \
386 MEM_KEEP(exit.text) \
387 *(.text.unlikely)
388
389
390 /* sched.text is aling to function alignment to secure we have same
391 * address even at second ld pass when generating System.map */
392 #define SCHED_TEXT \
393 ALIGN_FUNCTION(); \
394 VMLINUX_SYMBOL(__sched_text_start) = .; \
395 *(.sched.text) \
396 VMLINUX_SYMBOL(__sched_text_end) = .;
397
398 /* spinlock.text is aling to function alignment to secure we have same
399 * address even at second ld pass when generating System.map */
400 #define LOCK_TEXT \
401 ALIGN_FUNCTION(); \
402 VMLINUX_SYMBOL(__lock_text_start) = .; \
403 *(.spinlock.text) \
404 VMLINUX_SYMBOL(__lock_text_end) = .;
405
406 #define KPROBES_TEXT \
407 ALIGN_FUNCTION(); \
408 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
409 *(.kprobes.text) \
410 VMLINUX_SYMBOL(__kprobes_text_end) = .;
411
412 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
413 #define IRQENTRY_TEXT \
414 ALIGN_FUNCTION(); \
415 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
416 *(.irqentry.text) \
417 VMLINUX_SYMBOL(__irqentry_text_end) = .;
418 #else
419 #define IRQENTRY_TEXT
420 #endif
421
422 /* Section used for early init (in .S files) */
423 #define HEAD_TEXT *(.head.text)
424
425 #define HEAD_TEXT_SECTION \
426 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
427 HEAD_TEXT \
428 }
429
430 /*
431 * Exception table
432 */
433 #define EXCEPTION_TABLE(align) \
434 . = ALIGN(align); \
435 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
436 VMLINUX_SYMBOL(__start___ex_table) = .; \
437 *(__ex_table) \
438 VMLINUX_SYMBOL(__stop___ex_table) = .; \
439 }
440
441 /*
442 * Init task
443 */
444 #define INIT_TASK_DATA_SECTION(align) \
445 . = ALIGN(align); \
446 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
447 INIT_TASK_DATA(align) \
448 }
449
450 #ifdef CONFIG_CONSTRUCTORS
451 #define KERNEL_CTORS() . = ALIGN(8); \
452 VMLINUX_SYMBOL(__ctors_start) = .; \
453 *(.ctors) \
454 VMLINUX_SYMBOL(__ctors_end) = .;
455 #else
456 #define KERNEL_CTORS()
457 #endif
458
459 /* init and exit section handling */
460 #define INIT_DATA \
461 *(.init.data) \
462 DEV_DISCARD(init.data) \
463 CPU_DISCARD(init.data) \
464 MEM_DISCARD(init.data) \
465 KERNEL_CTORS() \
466 *(.init.rodata) \
467 MCOUNT_REC() \
468 DEV_DISCARD(init.rodata) \
469 CPU_DISCARD(init.rodata) \
470 MEM_DISCARD(init.rodata)
471
472 #define INIT_TEXT \
473 *(.init.text) \
474 DEV_DISCARD(init.text) \
475 CPU_DISCARD(init.text) \
476 MEM_DISCARD(init.text)
477
478 #define EXIT_DATA \
479 *(.exit.data) \
480 DEV_DISCARD(exit.data) \
481 DEV_DISCARD(exit.rodata) \
482 CPU_DISCARD(exit.data) \
483 CPU_DISCARD(exit.rodata) \
484 MEM_DISCARD(exit.data) \
485 MEM_DISCARD(exit.rodata)
486
487 #define EXIT_TEXT \
488 *(.exit.text) \
489 DEV_DISCARD(exit.text) \
490 CPU_DISCARD(exit.text) \
491 MEM_DISCARD(exit.text)
492
493 #define EXIT_CALL \
494 *(.exitcall.exit)
495
496 /*
497 * bss (Block Started by Symbol) - uninitialized data
498 * zeroed during startup
499 */
500 #define SBSS(sbss_align) \
501 . = ALIGN(sbss_align); \
502 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
503 *(.sbss) \
504 *(.scommon) \
505 }
506
507 #define BSS(bss_align) \
508 . = ALIGN(bss_align); \
509 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
510 *(.bss..page_aligned) \
511 *(.dynbss) \
512 *(.bss) \
513 *(COMMON) \
514 }
515
516 /*
517 * DWARF debug sections.
518 * Symbols in the DWARF debugging sections are relative to
519 * the beginning of the section so we begin them at 0.
520 */
521 #define DWARF_DEBUG \
522 /* DWARF 1 */ \
523 .debug 0 : { *(.debug) } \
524 .line 0 : { *(.line) } \
525 /* GNU DWARF 1 extensions */ \
526 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
527 .debug_sfnames 0 : { *(.debug_sfnames) } \
528 /* DWARF 1.1 and DWARF 2 */ \
529 .debug_aranges 0 : { *(.debug_aranges) } \
530 .debug_pubnames 0 : { *(.debug_pubnames) } \
531 /* DWARF 2 */ \
532 .debug_info 0 : { *(.debug_info \
533 .gnu.linkonce.wi.*) } \
534 .debug_abbrev 0 : { *(.debug_abbrev) } \
535 .debug_line 0 : { *(.debug_line) } \
536 .debug_frame 0 : { *(.debug_frame) } \
537 .debug_str 0 : { *(.debug_str) } \
538 .debug_loc 0 : { *(.debug_loc) } \
539 .debug_macinfo 0 : { *(.debug_macinfo) } \
540 /* SGI/MIPS DWARF 2 extensions */ \
541 .debug_weaknames 0 : { *(.debug_weaknames) } \
542 .debug_funcnames 0 : { *(.debug_funcnames) } \
543 .debug_typenames 0 : { *(.debug_typenames) } \
544 .debug_varnames 0 : { *(.debug_varnames) } \
545
546 /* Stabs debugging sections. */
547 #define STABS_DEBUG \
548 .stab 0 : { *(.stab) } \
549 .stabstr 0 : { *(.stabstr) } \
550 .stab.excl 0 : { *(.stab.excl) } \
551 .stab.exclstr 0 : { *(.stab.exclstr) } \
552 .stab.index 0 : { *(.stab.index) } \
553 .stab.indexstr 0 : { *(.stab.indexstr) } \
554 .comment 0 : { *(.comment) }
555
556 #ifdef CONFIG_GENERIC_BUG
557 #define BUG_TABLE \
558 . = ALIGN(8); \
559 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
560 VMLINUX_SYMBOL(__start___bug_table) = .; \
561 *(__bug_table) \
562 VMLINUX_SYMBOL(__stop___bug_table) = .; \
563 }
564 #else
565 #define BUG_TABLE
566 #endif
567
568 #define JUMP_TABLE \
569 . = ALIGN(8); \
570 __jump_table : AT(ADDR(__jump_table) - LOAD_OFFSET) { \
571 VMLINUX_SYMBOL(__start___jump_table) = .; \
572 *(__jump_table) \
573 VMLINUX_SYMBOL(__stop___jump_table) = .; \
574 }
575
576 #ifdef CONFIG_PM_TRACE
577 #define TRACEDATA \
578 . = ALIGN(4); \
579 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
580 VMLINUX_SYMBOL(__tracedata_start) = .; \
581 *(.tracedata) \
582 VMLINUX_SYMBOL(__tracedata_end) = .; \
583 }
584 #else
585 #define TRACEDATA
586 #endif
587
588 #define NOTES \
589 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
590 VMLINUX_SYMBOL(__start_notes) = .; \
591 *(.note.*) \
592 VMLINUX_SYMBOL(__stop_notes) = .; \
593 }
594
595 #define INIT_SETUP(initsetup_align) \
596 . = ALIGN(initsetup_align); \
597 VMLINUX_SYMBOL(__setup_start) = .; \
598 *(.init.setup) \
599 VMLINUX_SYMBOL(__setup_end) = .;
600
601 #define INITCALLS \
602 *(.initcallearly.init) \
603 VMLINUX_SYMBOL(__early_initcall_end) = .; \
604 *(.initcall0.init) \
605 *(.initcall0s.init) \
606 *(.initcall1.init) \
607 *(.initcall1s.init) \
608 *(.initcall2.init) \
609 *(.initcall2s.init) \
610 *(.initcall3.init) \
611 *(.initcall3s.init) \
612 *(.initcall4.init) \
613 *(.initcall4s.init) \
614 *(.initcall5.init) \
615 *(.initcall5s.init) \
616 *(.initcallrootfs.init) \
617 *(.initcall6.init) \
618 *(.initcall6s.init) \
619 *(.initcall7.init) \
620 *(.initcall7s.init)
621
622 #define INIT_CALLS \
623 VMLINUX_SYMBOL(__initcall_start) = .; \
624 INITCALLS \
625 VMLINUX_SYMBOL(__initcall_end) = .;
626
627 #define CON_INITCALL \
628 VMLINUX_SYMBOL(__con_initcall_start) = .; \
629 *(.con_initcall.init) \
630 VMLINUX_SYMBOL(__con_initcall_end) = .;
631
632 #define SECURITY_INITCALL \
633 VMLINUX_SYMBOL(__security_initcall_start) = .; \
634 *(.security_initcall.init) \
635 VMLINUX_SYMBOL(__security_initcall_end) = .;
636
637 #ifdef CONFIG_BLK_DEV_INITRD
638 #define INIT_RAM_FS \
639 . = ALIGN(PAGE_SIZE); \
640 VMLINUX_SYMBOL(__initramfs_start) = .; \
641 *(.init.ramfs) \
642 VMLINUX_SYMBOL(__initramfs_end) = .;
643 #else
644 #define INIT_RAM_FS
645 #endif
646
647 /*
648 * Default discarded sections.
649 *
650 * Some archs want to discard exit text/data at runtime rather than
651 * link time due to cross-section references such as alt instructions,
652 * bug table, eh_frame, etc. DISCARDS must be the last of output
653 * section definitions so that such archs put those in earlier section
654 * definitions.
655 */
656 #define DISCARDS \
657 /DISCARD/ : { \
658 EXIT_TEXT \
659 EXIT_DATA \
660 EXIT_CALL \
661 *(.discard) \
662 *(.discard.*) \
663 }
664
665 /**
666 * PERCPU_VADDR - define output section for percpu area
667 * @vaddr: explicit base address (optional)
668 * @phdr: destination PHDR (optional)
669 *
670 * Macro which expands to output section for percpu area. If @vaddr
671 * is not blank, it specifies explicit base address and all percpu
672 * symbols will be offset from the given address. If blank, @vaddr
673 * always equals @laddr + LOAD_OFFSET.
674 *
675 * @phdr defines the output PHDR to use if not blank. Be warned that
676 * output PHDR is sticky. If @phdr is specified, the next output
677 * section in the linker script will go there too. @phdr should have
678 * a leading colon.
679 *
680 * Note that this macros defines __per_cpu_load as an absolute symbol.
681 * If there is no need to put the percpu section at a predetermined
682 * address, use PERCPU().
683 */
684 #define PERCPU_VADDR(vaddr, phdr) \
685 VMLINUX_SYMBOL(__per_cpu_load) = .; \
686 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
687 - LOAD_OFFSET) { \
688 VMLINUX_SYMBOL(__per_cpu_start) = .; \
689 *(.data..percpu..first) \
690 *(.data..percpu..page_aligned) \
691 *(.data..percpu) \
692 *(.data..percpu..shared_aligned) \
693 VMLINUX_SYMBOL(__per_cpu_end) = .; \
694 } phdr \
695 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
696
697 /**
698 * PERCPU - define output section for percpu area, simple version
699 * @align: required alignment
700 *
701 * Align to @align and outputs output section for percpu area. This
702 * macro doesn't maniuplate @vaddr or @phdr and __per_cpu_load and
703 * __per_cpu_start will be identical.
704 *
705 * This macro is equivalent to ALIGN(align); PERCPU_VADDR( , ) except
706 * that __per_cpu_load is defined as a relative symbol against
707 * .data..percpu which is required for relocatable x86_32
708 * configuration.
709 */
710 #define PERCPU(align) \
711 . = ALIGN(align); \
712 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
713 VMLINUX_SYMBOL(__per_cpu_load) = .; \
714 VMLINUX_SYMBOL(__per_cpu_start) = .; \
715 *(.data..percpu..first) \
716 *(.data..percpu..page_aligned) \
717 *(.data..percpu) \
718 *(.data..percpu..shared_aligned) \
719 VMLINUX_SYMBOL(__per_cpu_end) = .; \
720 }
721
722
723 /*
724 * Definition of the high level *_SECTION macros
725 * They will fit only a subset of the architectures
726 */
727
728
729 /*
730 * Writeable data.
731 * All sections are combined in a single .data section.
732 * The sections following CONSTRUCTORS are arranged so their
733 * typical alignment matches.
734 * A cacheline is typical/always less than a PAGE_SIZE so
735 * the sections that has this restriction (or similar)
736 * is located before the ones requiring PAGE_SIZE alignment.
737 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
738 * matches the requirment of PAGE_ALIGNED_DATA.
739 *
740 * use 0 as page_align if page_aligned data is not used */
741 #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
742 . = ALIGN(PAGE_SIZE); \
743 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
744 INIT_TASK_DATA(inittask) \
745 NOSAVE_DATA \
746 PAGE_ALIGNED_DATA(pagealigned) \
747 CACHELINE_ALIGNED_DATA(cacheline) \
748 READ_MOSTLY_DATA(cacheline) \
749 DATA_DATA \
750 CONSTRUCTORS \
751 }
752
753 #define INIT_TEXT_SECTION(inittext_align) \
754 . = ALIGN(inittext_align); \
755 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
756 VMLINUX_SYMBOL(_sinittext) = .; \
757 INIT_TEXT \
758 VMLINUX_SYMBOL(_einittext) = .; \
759 }
760
761 #define INIT_DATA_SECTION(initsetup_align) \
762 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
763 INIT_DATA \
764 INIT_SETUP(initsetup_align) \
765 INIT_CALLS \
766 CON_INITCALL \
767 SECURITY_INITCALL \
768 INIT_RAM_FS \
769 }
770
771 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
772 . = ALIGN(sbss_align); \
773 VMLINUX_SYMBOL(__bss_start) = .; \
774 SBSS(sbss_align) \
775 BSS(bss_align) \
776 . = ALIGN(stop_align); \
777 VMLINUX_SYMBOL(__bss_stop) = .;
ubuntu-bionic-kernel mirror