lib/command_lex.l

   1 /*
   2  * Command format string lexer for CLI backend.
   3  *
   4  * --
   5  * Copyright (C) 2015 Cumulus Networks, Inc.
   6  *
   7  * This file is part of GNU Zebra.
   8  *
   9  * GNU Zebra is free software; you can redistribute it and/or modify it
  10  * under the terms of the GNU General Public License as published by the
  11  * Free Software Foundation; either version 2, or (at your option) any
  12  * later version.
  13  *
  14  * GNU Zebra is distributed in the hope that it will be useful, but
  15  * WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with GNU Zebra; see the file COPYING.  If not, write to the Free
  21  * Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  22  * 02111-1307, USA.
  23  */
  24
  25 %{
  26 /* ignore harmless bug in old versions of flex */
  27 #pragma GCC diagnostic ignored "-Wsign-compare"
  28
  29 #include "command_parse.h"
  30
  31 #define YY_USER_ACTION yylloc->last_column += yyleng;
  32 #define LOC_STEP do { if (yylloc) { \
  33         yylloc->first_column = yylloc->last_column; \
  34         yylloc->first_line = yylloc->last_line; \
  35         } } while(0)
  36 %}
  37
  38 WORD            (\-|\+)?[a-z0-9\*][-+_a-zA-Z0-9\*]*
  39 IPV4            A\.B\.C\.D
  40 IPV4_PREFIX     A\.B\.C\.D\/M
  41 IPV6            X:X::X:X
  42 IPV6_PREFIX     X:X::X:X\/M
  43 MAC             M:A:C
  44 MAC_PREFIX      M:A:C\/M
  45 VARIABLE        [A-Z][-_a-zA-Z:0-9]+
  46 NUMBER          (\-|\+)?[0-9]{1,20}
  47 RANGE           \({NUMBER}[ ]?\-[ ]?{NUMBER}\)
  48
  49 /* yytext shall be a pointer */
  50 %pointer
  51 %option noyywrap
  52 %option nounput
  53 %option noinput
  54 %option outfile="lib/command_lex.c"
  55 %option header-file="lib/command_lex.h"
  56 %option prefix="cmd_yy"
  57 %option reentrant
  58 %option bison-bridge
  59 %option bison-locations
  60
  61 %%
  62 %{
  63                 LOC_STEP;
  64 %}
  65
  66 [ \t]+          LOC_STEP /* ignore whitespace */;
  67 {WORD}          {yylval->string = XSTRDUP(MTYPE_LEX, yytext); return WORD;}
  68 {IPV4}          {yylval->string = XSTRDUP(MTYPE_LEX, yytext); return IPV4;}
  69 {IPV4_PREFIX}   {yylval->string = XSTRDUP(MTYPE_LEX, yytext); return IPV4_PREFIX;}
  70 {IPV6}          {yylval->string = XSTRDUP(MTYPE_LEX, yytext); return IPV6;}
  71 {IPV6_PREFIX}   {yylval->string = XSTRDUP(MTYPE_LEX, yytext); return IPV6_PREFIX;}
  72 {MAC}           {yylval->string = XSTRDUP(MTYPE_LEX, yytext); return MAC;}
  73 {MAC_PREFIX}    {yylval->string = XSTRDUP(MTYPE_LEX, yytext); return MAC_PREFIX;}
  74 {VARIABLE}      {yylval->string = XSTRDUP(MTYPE_LEX, yytext); return VARIABLE;}
  75 {RANGE}         {yylval->string = XSTRDUP(MTYPE_LEX, yytext); return RANGE;}
  76 .               {return yytext[0];}
  77 %%
  78
  79 YY_BUFFER_STATE buffer;
  80
  81 void set_lexer_string (yyscan_t *scn, const char *string)
  82 {
  83   *scn = NULL;
  84   yylex_init(scn);
  85   buffer = yy_scan_string (string, *scn);
  86 }
  87
  88 void cleanup_lexer (yyscan_t *scn)
  89 {
  90   // yy_delete_buffer (buffer, *scn);
  91   yylex_destroy(*scn);
  92 }