m4/wctype_h.m4

   1 # wctype_h.m4 serial 8
   2
   3 dnl A placeholder for ISO C99 <wctype.h>, for platforms that lack it.
   4
   5 dnl Copyright (C) 2006-2010 Free Software Foundation, Inc.
   6 dnl This file is free software; the Free Software Foundation
   7 dnl gives unlimited permission to copy and/or distribute it,
   8 dnl with or without modifications, as long as this notice is preserved.
   9
  10 dnl Written by Paul Eggert.
  11
  12 AC_DEFUN([gl_WCTYPE_H],
  13 [
  14   AC_REQUIRE([AC_PROG_CC])
  15   AC_REQUIRE([AC_CANONICAL_HOST])
  16   AC_CHECK_FUNCS_ONCE([iswcntrl])
  17   if test $ac_cv_func_iswcntrl = yes; then
  18     HAVE_ISWCNTRL=1
  19   else
  20     HAVE_ISWCNTRL=0
  21   fi
  22   AC_SUBST([HAVE_ISWCNTRL])
  23   AC_CHECK_FUNCS_ONCE([iswblank])
  24   AC_CHECK_DECLS_ONCE([iswblank])
  25   if test $ac_cv_func_iswblank = yes; then
  26     HAVE_ISWBLANK=1
  27     REPLACE_ISWBLANK=0
  28   else
  29     HAVE_ISWBLANK=0
  30     if test $ac_cv_have_decl_iswblank = yes; then
  31       REPLACE_ISWBLANK=1
  32     else
  33       REPLACE_ISWBLANK=0
  34     fi
  35   fi
  36   AC_SUBST([HAVE_ISWBLANK])
  37   AC_SUBST([REPLACE_ISWBLANK])
  38
  39   AC_CHECK_HEADERS_ONCE([wctype.h])
  40   AC_REQUIRE([AC_C_INLINE])
  41
  42   AC_REQUIRE([gt_TYPE_WINT_T])
  43   if test $gt_cv_c_wint_t = yes; then
  44     HAVE_WINT_T=1
  45   else
  46     HAVE_WINT_T=0
  47   fi
  48   AC_SUBST([HAVE_WINT_T])
  49
  50   if test $ac_cv_header_wctype_h = yes; then
  51     if test $ac_cv_func_iswcntrl = yes; then
  52       dnl Linux libc5 has an iswprint function that returns 0 for all arguments.
  53       dnl The other functions are likely broken in the same way.
  54       AC_CACHE_CHECK([whether iswcntrl works], [gl_cv_func_iswcntrl_works],
  55         [
  56           AC_RUN_IFELSE([AC_LANG_SOURCE([[
  57                             #include <stddef.h>
  58                             #include <stdio.h>
  59                             #include <time.h>
  60                             #include <wchar.h>
  61                             #include <wctype.h>
  62                             int main () { return iswprint ('x') == 0; }]])],
  63             [gl_cv_func_iswcntrl_works=yes], [gl_cv_func_iswcntrl_works=no],
  64             [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
  65                           #if __GNU_LIBRARY__ == 1
  66                           Linux libc5 i18n is broken.
  67                           #endif]], [])],
  68               [gl_cv_func_iswcntrl_works=yes], [gl_cv_func_iswcntrl_works=no])
  69             ])
  70         ])
  71     fi
  72     gl_CHECK_NEXT_HEADERS([wctype.h])
  73     HAVE_WCTYPE_H=1
  74   else
  75     HAVE_WCTYPE_H=0
  76   fi
  77   AC_SUBST([HAVE_WCTYPE_H])
  78
  79   if test "$gl_cv_func_iswcntrl_works" = no; then
  80     REPLACE_ISWCNTRL=1
  81   else
  82     REPLACE_ISWCNTRL=0
  83   fi
  84   AC_SUBST([REPLACE_ISWCNTRL])
  85 ])