meson.build

   1 project('qemu', ['c'], meson_version: '>=0.55.0',
   2         default_options: ['warning_level=1', 'c_std=gnu11', 'cpp_std=gnu++11', 'b_colorout=auto'] +
   3                          (meson.version().version_compare('>=0.56.0') ? [ 'b_staticpic=false' ] : []),
   4         version: run_command('head', meson.source_root() / 'VERSION').stdout().strip())
   5
   6 not_found = dependency('', required: false)
   7 if meson.version().version_compare('>=0.56.0')
   8   keyval = import('keyval')
   9 else
  10   keyval = import('unstable-keyval')
  11 endif
  12 ss = import('sourceset')
  13 fs = import('fs')
  14
  15 sh = find_program('sh')
  16 cc = meson.get_compiler('c')
  17 config_host = keyval.load(meson.current_build_dir() / 'config-host.mak')
  18 enable_modules = 'CONFIG_MODULES' in config_host
  19 enable_static = 'CONFIG_STATIC' in config_host
  20
  21 # Allow both shared and static libraries unless --enable-static
  22 static_kwargs = enable_static ? {'static': true} : {}
  23
  24 # Temporary directory used for files created while
  25 # configure runs. Since it is in the build directory
  26 # we can safely blow away any previous version of it
  27 # (and we need not jump through hoops to try to delete
  28 # it when configure exits.)
  29 tmpdir = meson.current_build_dir() / 'meson-private/temp'
  30
  31 if get_option('qemu_suffix').startswith('/')
  32   error('qemu_suffix cannot start with a /')
  33 endif
  34
  35 qemu_confdir = get_option('sysconfdir') / get_option('qemu_suffix')
  36 qemu_datadir = get_option('datadir') / get_option('qemu_suffix')
  37 qemu_docdir = get_option('docdir') / get_option('qemu_suffix')
  38 qemu_moddir = get_option('libdir') / get_option('qemu_suffix')
  39
  40 qemu_desktopdir = get_option('datadir') / 'applications'
  41 qemu_icondir = get_option('datadir') / 'icons'
  42
  43 config_host_data = configuration_data()
  44 genh = []
  45
  46 target_dirs = config_host['TARGET_DIRS'].split()
  47 have_user = false
  48 have_system = false
  49 foreach target : target_dirs
  50   have_user = have_user or target.endswith('-user')
  51   have_system = have_system or target.endswith('-softmmu')
  52 endforeach
  53 have_tools = 'CONFIG_TOOLS' in config_host
  54 have_block = have_system or have_tools
  55
  56 python = import('python').find_installation()
  57
  58 supported_oses = ['windows', 'freebsd', 'netbsd', 'openbsd', 'darwin', 'sunos', 'linux']
  59 supported_cpus = ['ppc', 'ppc64', 's390x', 'riscv32', 'riscv64', 'x86', 'x86_64',
  60   'arm', 'aarch64', 'mips', 'mips64', 'sparc', 'sparc64']
  61
  62 cpu = host_machine.cpu_family()
  63 targetos = host_machine.system()
  64
  65 if cpu in ['x86', 'x86_64']
  66   kvm_targets = ['i386-softmmu', 'x86_64-softmmu']
  67 elif cpu == 'aarch64'
  68   kvm_targets = ['aarch64-softmmu']
  69 elif cpu == 's390x'
  70   kvm_targets = ['s390x-softmmu']
  71 elif cpu in ['ppc', 'ppc64']
  72   kvm_targets = ['ppc-softmmu', 'ppc64-softmmu']
  73 elif cpu in ['mips', 'mips64']
  74   kvm_targets = ['mips-softmmu', 'mipsel-softmmu', 'mips64-softmmu', 'mips64el-softmmu']
  75 else
  76   kvm_targets = []
  77 endif
  78
  79 accelerator_targets = { 'CONFIG_KVM': kvm_targets }
  80 if cpu in ['x86', 'x86_64', 'arm', 'aarch64']
  81   # i368 emulator provides xenpv machine type for multiple architectures
  82   accelerator_targets += {
  83     'CONFIG_XEN': ['i386-softmmu', 'x86_64-softmmu'],
  84   }
  85 endif
  86 if cpu in ['x86', 'x86_64']
  87   accelerator_targets += {
  88     'CONFIG_HAX': ['i386-softmmu', 'x86_64-softmmu'],
  89     'CONFIG_HVF': ['x86_64-softmmu'],
  90     'CONFIG_NVMM': ['i386-softmmu', 'x86_64-softmmu'],
  91     'CONFIG_WHPX': ['i386-softmmu', 'x86_64-softmmu'],
  92   }
  93 endif
  94
  95 modular_tcg = ['i386-softmmu', 'x86_64-softmmu']
  96
  97 edk2_targets = [ 'arm-softmmu', 'aarch64-softmmu', 'i386-softmmu', 'x86_64-softmmu' ]
  98 install_edk2_blobs = false
  99 if get_option('install_blobs')
 100   foreach target : target_dirs
 101     install_edk2_blobs = install_edk2_blobs or target in edk2_targets
 102   endforeach
 103 endif
 104
 105 bzip2 = find_program('bzip2', required: install_edk2_blobs)
 106
 107 ##################
 108 # Compiler flags #
 109 ##################
 110
 111 # Specify linker-script with add_project_link_arguments so that it is not placed
 112 # within a linker --start-group/--end-group pair
 113 if 'CONFIG_FUZZ' in config_host
 114    add_project_link_arguments(['-Wl,-T,',
 115                                (meson.current_source_dir() / 'tests/qtest/fuzz/fork_fuzz.ld')],
 116                               native: false, language: ['c', 'cpp', 'objc'])
 117 endif
 118
 119 add_global_arguments(config_host['QEMU_CFLAGS'].split(),
 120                      native: false, language: ['c', 'objc'])
 121 add_global_arguments(config_host['QEMU_CXXFLAGS'].split(),
 122                      native: false, language: 'cpp')
 123 add_global_link_arguments(config_host['QEMU_LDFLAGS'].split(),
 124                           native: false, language: ['c', 'cpp', 'objc'])
 125
 126 if targetos == 'linux'
 127   add_project_arguments('-isystem', meson.current_source_dir() / 'linux-headers',
 128                         '-isystem', 'linux-headers',
 129                         language: ['c', 'cpp'])
 130 endif
 131
 132 add_project_arguments('-iquote', '.',
 133                       '-iquote', meson.current_source_dir(),
 134                       '-iquote', meson.current_source_dir() / 'include',
 135                       '-iquote', meson.current_source_dir() / 'disas/libvixl',
 136                       language: ['c', 'cpp', 'objc'])
 137
 138 link_language = meson.get_external_property('link_language', 'cpp')
 139 if link_language == 'cpp'
 140   add_languages('cpp', required: true, native: false)
 141 endif
 142 if host_machine.system() == 'darwin'
 143   add_languages('objc', required: false, native: false)
 144 endif
 145
 146 sparse = find_program('cgcc', required: get_option('sparse'))
 147 if sparse.found()
 148   run_target('sparse',
 149              command: [find_program('scripts/check_sparse.py'),
 150                        'compile_commands.json', sparse.full_path(), '-Wbitwise',
 151                        '-Wno-transparent-union', '-Wno-old-initializer',
 152                        '-Wno-non-pointer-null'])
 153 endif
 154
 155 ###########################################
 156 # Target-specific checks and dependencies #
 157 ###########################################
 158
 159 if targetos != 'linux' and get_option('mpath').enabled()
 160   error('Multipath is supported only on Linux')
 161 endif
 162
 163 if targetos != 'linux' and get_option('multiprocess').enabled()
 164   error('Multiprocess QEMU is supported only on Linux')
 165 endif
 166 multiprocess_allowed = targetos == 'linux' and not get_option('multiprocess').disabled()
 167
 168 libm = cc.find_library('m', required: false)
 169 threads = dependency('threads')
 170 util = cc.find_library('util', required: false)
 171 winmm = []
 172 socket = []
 173 version_res = []
 174 coref = []
 175 iokit = []
 176 emulator_link_args = []
 177 nvmm =not_found
 178 hvf = not_found
 179 if targetos == 'windows'
 180   socket = cc.find_library('ws2_32')
 181   winmm = cc.find_library('winmm')
 182
 183   win = import('windows')
 184   version_res = win.compile_resources('version.rc',
 185                                       depend_files: files('pc-bios/qemu-nsis.ico'),
 186                                       include_directories: include_directories('.'))
 187 elif targetos == 'darwin'
 188   coref = dependency('appleframeworks', modules: 'CoreFoundation')
 189   iokit = dependency('appleframeworks', modules: 'IOKit', required: false)
 190 elif targetos == 'sunos'
 191   socket = [cc.find_library('socket'),
 192             cc.find_library('nsl'),
 193             cc.find_library('resolv')]
 194 elif targetos == 'haiku'
 195   socket = [cc.find_library('posix_error_mapper'),
 196             cc.find_library('network'),
 197             cc.find_library('bsd')]
 198 elif targetos == 'openbsd'
 199   if not get_option('tcg').disabled() and target_dirs.length() > 0
 200     # Disable OpenBSD W^X if available
 201     emulator_link_args = cc.get_supported_link_arguments('-Wl,-z,wxneeded')
 202   endif
 203 endif
 204
 205 accelerators = []
 206 if not get_option('kvm').disabled() and targetos == 'linux'
 207   accelerators += 'CONFIG_KVM'
 208 endif
 209 if not get_option('xen').disabled() and 'CONFIG_XEN_BACKEND' in config_host
 210   accelerators += 'CONFIG_XEN'
 211   have_xen_pci_passthrough = not get_option('xen_pci_passthrough').disabled() and targetos == 'linux'
 212 else
 213   have_xen_pci_passthrough = false
 214 endif
 215 if not get_option('whpx').disabled() and targetos == 'windows'
 216   if get_option('whpx').enabled() and host_machine.cpu() != 'x86_64'
 217     error('WHPX requires 64-bit host')
 218   elif cc.has_header('WinHvPlatform.h', required: get_option('whpx')) and \
 219        cc.has_header('WinHvEmulation.h', required: get_option('whpx'))
 220     accelerators += 'CONFIG_WHPX'
 221   endif
 222 endif
 223 if not get_option('hvf').disabled()
 224   hvf = dependency('appleframeworks', modules: 'Hypervisor',
 225                    required: get_option('hvf'))
 226   if hvf.found()
 227     accelerators += 'CONFIG_HVF'
 228   endif
 229 endif
 230 if not get_option('hax').disabled()
 231   if get_option('hax').enabled() or targetos in ['windows', 'darwin', 'netbsd']
 232     accelerators += 'CONFIG_HAX'
 233   endif
 234 endif
 235 if targetos == 'netbsd'
 236   if cc.has_header_symbol('nvmm.h', 'nvmm_cpu_stop', required: get_option('nvmm'))
 237     nvmm = cc.find_library('nvmm', required: get_option('nvmm'))
 238   endif
 239   if nvmm.found()
 240     accelerators += 'CONFIG_NVMM'
 241   endif
 242 endif
 243
 244 tcg_arch = config_host['ARCH']
 245 if not get_option('tcg').disabled()
 246   if cpu not in supported_cpus
 247     if get_option('tcg_interpreter')
 248       warning('Unsupported CPU @0@, will use TCG with TCI (experimental and slow)'.format(cpu))
 249     else
 250       error('Unsupported CPU @0@, try --enable-tcg-interpreter'.format(cpu))
 251     endif
 252   elif get_option('tcg_interpreter')
 253     warning('Use of the TCG interpretor is not recommended on this host')
 254     warning('architecture. There is a native TCG execution backend available')
 255     warning('which provides substantially better performance and reliability.')
 256     warning('It is strongly recommended to remove the --enable-tcg-interpreter')
 257     warning('configuration option on this architecture to use the native')
 258     warning('backend.')
 259   endif
 260   if get_option('tcg_interpreter')
 261     tcg_arch = 'tci'
 262   elif config_host['ARCH'] == 'sparc64'
 263     tcg_arch = 'sparc'
 264   elif config_host['ARCH'] == 's390x'
 265     tcg_arch = 's390'
 266   elif config_host['ARCH'] in ['x86_64', 'x32']
 267     tcg_arch = 'i386'
 268   elif config_host['ARCH'] == 'ppc64'
 269     tcg_arch = 'ppc'
 270   elif config_host['ARCH'] in ['riscv32', 'riscv64']
 271     tcg_arch = 'riscv'
 272   endif
 273   add_project_arguments('-iquote', meson.current_source_dir() / 'tcg' / tcg_arch,
 274                         language: ['c', 'cpp', 'objc'])
 275
 276   accelerators += 'CONFIG_TCG'
 277   config_host += { 'CONFIG_TCG': 'y' }
 278 endif
 279
 280 if 'CONFIG_KVM' not in accelerators and get_option('kvm').enabled()
 281   error('KVM not available on this platform')
 282 endif
 283 if 'CONFIG_HVF' not in accelerators and get_option('hvf').enabled()
 284   error('HVF not available on this platform')
 285 endif
 286 if 'CONFIG_NVMM' not in accelerators and get_option('nvmm').enabled()
 287   error('NVMM not available on this platform')
 288 endif
 289 if 'CONFIG_WHPX' not in accelerators and get_option('whpx').enabled()
 290   error('WHPX not available on this platform')
 291 endif
 292 if not have_xen_pci_passthrough and get_option('xen_pci_passthrough').enabled()
 293   if 'CONFIG_XEN' in accelerators
 294     error('Xen PCI passthrough not available on this platform')
 295   else
 296     error('Xen PCI passthrough requested but Xen not enabled')
 297   endif
 298 endif
 299
 300 ################
 301 # Dependencies #
 302 ################
 303
 304 # The path to glib.h is added to all compilation commands.  This was
 305 # grandfathered in from the QEMU Makefiles.
 306 add_project_arguments(config_host['GLIB_CFLAGS'].split(),
 307                       native: false, language: ['c', 'cpp', 'objc'])
 308 glib = declare_dependency(compile_args: config_host['GLIB_CFLAGS'].split(),
 309                           link_args: config_host['GLIB_LIBS'].split())
 310 # override glib dep with the configure results (for subprojects)
 311 meson.override_dependency('glib-2.0', glib)
 312
 313 gio = not_found
 314 if 'CONFIG_GIO' in config_host
 315   gio = declare_dependency(compile_args: config_host['GIO_CFLAGS'].split(),
 316                            link_args: config_host['GIO_LIBS'].split())
 317 endif
 318 lttng = not_found
 319 if 'CONFIG_TRACE_UST' in config_host
 320   lttng = declare_dependency(link_args: config_host['LTTNG_UST_LIBS'].split())
 321 endif
 322 urcubp = not_found
 323 if 'CONFIG_TRACE_UST' in config_host
 324   urcubp = declare_dependency(link_args: config_host['URCU_BP_LIBS'].split())
 325 endif
 326 pixman = not_found
 327 if have_system or have_tools
 328   pixman = dependency('pixman-1', required: have_system, version:'>=0.21.8',
 329                       method: 'pkg-config', kwargs: static_kwargs)
 330 endif
 331 libaio = cc.find_library('aio', required: false)
 332 zlib = dependency('zlib', required: true, kwargs: static_kwargs)
 333
 334 linux_io_uring = not_found
 335 if not get_option('linux_io_uring').auto() or have_block
 336   linux_io_uring = dependency('liburing', required: get_option('linux_io_uring'),
 337                               method: 'pkg-config', kwargs: static_kwargs)
 338 endif
 339 libxml2 = not_found
 340 if not get_option('libxml2').auto() or have_block
 341   libxml2 = dependency('libxml-2.0', required: get_option('libxml2'),
 342                        method: 'pkg-config', kwargs: static_kwargs)
 343 endif
 344 libnfs = not_found
 345 if not get_option('libnfs').auto() or have_block
 346   libnfs = dependency('libnfs', version: '>=1.9.3',
 347                       required: get_option('libnfs'),
 348                       method: 'pkg-config', kwargs: static_kwargs)
 349 endif
 350
 351 libattr_test = '''
 352   #include <stddef.h>
 353   #include <sys/types.h>
 354   #ifdef CONFIG_LIBATTR
 355   #include <attr/xattr.h>
 356   #else
 357   #include <sys/xattr.h>
 358   #endif
 359   int main(void) { getxattr(NULL, NULL, NULL, 0); setxattr(NULL, NULL, NULL, 0, 0); return 0; }'''
 360
 361 libattr = not_found
 362 have_old_libattr = false
 363 if not get_option('attr').disabled()
 364   if cc.links(libattr_test)
 365     libattr = declare_dependency()
 366   else
 367     libattr = cc.find_library('attr', has_headers: ['attr/xattr.h'],
 368                               required: get_option('attr'),
 369                               kwargs: static_kwargs)
 370     if libattr.found() and not \
 371       cc.links(libattr_test, dependencies: libattr, args: '-DCONFIG_LIBATTR')
 372       libattr = not_found
 373       if get_option('attr').enabled()
 374         error('could not link libattr')
 375       else
 376         warning('could not link libattr, disabling')
 377       endif
 378     else
 379       have_old_libattr = libattr.found()
 380     endif
 381   endif
 382 endif
 383
 384 cocoa = dependency('appleframeworks', modules: 'Cocoa', required: get_option('cocoa'))
 385 if cocoa.found() and get_option('sdl').enabled()
 386   error('Cocoa and SDL cannot be enabled at the same time')
 387 endif
 388 if cocoa.found() and get_option('gtk').enabled()
 389   error('Cocoa and GTK+ cannot be enabled at the same time')
 390 endif
 391
 392 seccomp = not_found
 393 if not get_option('seccomp').auto() or have_system or have_tools
 394   seccomp = dependency('libseccomp', version: '>=2.3.0',
 395                        required: get_option('seccomp'),
 396                        method: 'pkg-config', kwargs: static_kwargs)
 397 endif
 398
 399 libcap_ng = not_found
 400 if not get_option('cap_ng').auto() or have_system or have_tools
 401   libcap_ng = cc.find_library('cap-ng', has_headers: ['cap-ng.h'],
 402                               required: get_option('cap_ng'),
 403                               kwargs: static_kwargs)
 404 endif
 405 if libcap_ng.found() and not cc.links('''
 406    #include <cap-ng.h>
 407    int main(void)
 408    {
 409      capng_capability_to_name(CAPNG_EFFECTIVE);
 410      return 0;
 411    }''', dependencies: libcap_ng)
 412   libcap_ng = not_found
 413   if get_option('cap_ng').enabled()
 414     error('could not link libcap-ng')
 415   else
 416     warning('could not link libcap-ng, disabling')
 417   endif
 418 endif
 419
 420 if get_option('xkbcommon').auto() and not have_system and not have_tools
 421   xkbcommon = not_found
 422 else
 423   xkbcommon = dependency('xkbcommon', required: get_option('xkbcommon'),
 424                          method: 'pkg-config', kwargs: static_kwargs)
 425 endif
 426 vde = not_found
 427 if config_host.has_key('CONFIG_VDE')
 428   vde = declare_dependency(link_args: config_host['VDE_LIBS'].split())
 429 endif
 430 pulse = not_found
 431 if 'CONFIG_LIBPULSE' in config_host
 432   pulse = declare_dependency(compile_args: config_host['PULSE_CFLAGS'].split(),
 433                              link_args: config_host['PULSE_LIBS'].split())
 434 endif
 435 alsa = not_found
 436 if 'CONFIG_ALSA' in config_host
 437   alsa = declare_dependency(compile_args: config_host['ALSA_CFLAGS'].split(),
 438                             link_args: config_host['ALSA_LIBS'].split())
 439 endif
 440 jack = not_found
 441 if 'CONFIG_LIBJACK' in config_host
 442   jack = declare_dependency(link_args: config_host['JACK_LIBS'].split())
 443 endif
 444 spice = not_found
 445 spice_headers = not_found
 446 spice_protocol = not_found
 447 if 'CONFIG_SPICE' in config_host
 448   spice = declare_dependency(compile_args: config_host['SPICE_CFLAGS'].split(),
 449                              link_args: config_host['SPICE_LIBS'].split())
 450   spice_headers = declare_dependency(compile_args: config_host['SPICE_CFLAGS'].split())
 451 endif
 452 if 'CONFIG_SPICE_PROTOCOL' in config_host
 453   spice_protocol = declare_dependency(compile_args: config_host['SPICE_PROTOCOL_CFLAGS'].split())
 454 endif
 455 rt = cc.find_library('rt', required: false)
 456 libdl = not_found
 457 if 'CONFIG_PLUGIN' in config_host
 458   libdl = cc.find_library('dl', required: true)
 459 endif
 460 libiscsi = not_found
 461 if not get_option('libiscsi').auto() or have_block
 462   libiscsi = dependency('libiscsi', version: '>=1.9.0',
 463                          required: get_option('libiscsi'),
 464                          method: 'pkg-config', kwargs: static_kwargs)
 465 endif
 466 zstd = not_found
 467 if not get_option('zstd').auto() or have_block
 468   zstd = dependency('libzstd', version: '>=1.4.0',
 469                     required: get_option('zstd'),
 470                     method: 'pkg-config', kwargs: static_kwargs)
 471 endif
 472 gbm = not_found
 473 if 'CONFIG_GBM' in config_host
 474   gbm = declare_dependency(compile_args: config_host['GBM_CFLAGS'].split(),
 475                            link_args: config_host['GBM_LIBS'].split())
 476 endif
 477 virgl = not_found
 478 if not get_option('virglrenderer').auto() or have_system
 479   virgl = dependency('virglrenderer',
 480                      method: 'pkg-config',
 481                      required: get_option('virglrenderer'),
 482                      kwargs: static_kwargs)
 483 endif
 484 curl = not_found
 485 if not get_option('curl').auto() or have_block
 486   curl = dependency('libcurl', version: '>=7.29.0',
 487                     method: 'pkg-config',
 488                     required: get_option('curl'),
 489                     kwargs: static_kwargs)
 490 endif
 491 libudev = not_found
 492 if targetos == 'linux' and (have_system or have_tools)
 493   libudev = dependency('libudev',
 494                        method: 'pkg-config',
 495                        required: get_option('libudev'),
 496                        kwargs: static_kwargs)
 497 endif
 498
 499 mpathlibs = [libudev]
 500 mpathpersist = not_found
 501 mpathpersist_new_api = false
 502 if targetos == 'linux' and have_tools and not get_option('mpath').disabled()
 503   mpath_test_source_new = '''
 504     #include <libudev.h>
 505     #include <mpath_persist.h>
 506     unsigned mpath_mx_alloc_len = 1024;
 507     int logsink;
 508     static struct config *multipath_conf;
 509     extern struct udev *udev;
 510     extern struct config *get_multipath_config(void);
 511     extern void put_multipath_config(struct config *conf);
 512     struct udev *udev;
 513     struct config *get_multipath_config(void) { return multipath_conf; }
 514     void put_multipath_config(struct config *conf) { }
 515     int main(void) {
 516         udev = udev_new();
 517         multipath_conf = mpath_lib_init();
 518         return 0;
 519     }'''
 520   mpath_test_source_old = '''
 521       #include <libudev.h>
 522       #include <mpath_persist.h>
 523       unsigned mpath_mx_alloc_len = 1024;
 524       int logsink;
 525       int main(void) {
 526           struct udev *udev = udev_new();
 527           mpath_lib_init(udev);
 528           return 0;
 529       }'''
 530   libmpathpersist = cc.find_library('mpathpersist',
 531                                     required: get_option('mpath'),
 532                                     kwargs: static_kwargs)
 533   if libmpathpersist.found()
 534     mpathlibs += libmpathpersist
 535     if enable_static
 536       mpathlibs += cc.find_library('devmapper',
 537                                      required: get_option('mpath'),
 538                                      kwargs: static_kwargs)
 539     endif
 540     mpathlibs += cc.find_library('multipath',
 541                                  required: get_option('mpath'),
 542                                  kwargs: static_kwargs)
 543     foreach lib: mpathlibs
 544       if not lib.found()
 545         mpathlibs = []
 546         break
 547       endif
 548     endforeach
 549     if mpathlibs.length() == 0
 550       msg = 'Dependencies missing for libmpathpersist'
 551     elif cc.links(mpath_test_source_new, dependencies: mpathlibs)
 552       mpathpersist = declare_dependency(dependencies: mpathlibs)
 553       mpathpersist_new_api = true
 554     elif cc.links(mpath_test_source_old, dependencies: mpathlibs)
 555       mpathpersist = declare_dependency(dependencies: mpathlibs)
 556     else
 557       msg = 'Cannot detect libmpathpersist API'
 558     endif
 559     if not mpathpersist.found()
 560       if get_option('mpath').enabled()
 561         error(msg)
 562       else
 563         warning(msg + ', disabling')
 564       endif
 565     endif
 566   endif
 567 endif
 568
 569 iconv = not_found
 570 curses = not_found
 571 if have_system and not get_option('curses').disabled()
 572   curses_test = '''
 573     #include <locale.h>
 574     #include <curses.h>
 575     #include <wchar.h>
 576     int main(void) {
 577       wchar_t wch = L'w';
 578       setlocale(LC_ALL, "");
 579       resize_term(0, 0);
 580       addwstr(L"wide chars\n");
 581       addnwstr(&wch, 1);
 582       add_wch(WACS_DEGREE);
 583       return 0;
 584     }'''
 585
 586   curses_dep_list = targetos == 'windows' ? ['ncurses', 'ncursesw'] : ['ncursesw']
 587   foreach curses_dep : curses_dep_list
 588     if not curses.found()
 589       curses = dependency(curses_dep,
 590                           required: false,
 591                           method: 'pkg-config',
 592                           kwargs: static_kwargs)
 593     endif
 594   endforeach
 595   msg = get_option('curses').enabled() ? 'curses library not found' : ''
 596   curses_compile_args = ['-DNCURSES_WIDECHAR']
 597   if curses.found()
 598     if cc.links(curses_test, args: curses_compile_args, dependencies: [curses])
 599       curses = declare_dependency(compile_args: curses_compile_args, dependencies: [curses])
 600     else
 601       msg = 'curses package not usable'
 602       curses = not_found
 603     endif
 604   endif
 605   if not curses.found()
 606     has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 607     if targetos != 'windows' and not has_curses_h
 608       message('Trying with /usr/include/ncursesw')
 609       curses_compile_args += ['-I/usr/include/ncursesw']
 610       has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 611     endif
 612     if has_curses_h
 613       curses_libname_list = (targetos == 'windows' ? ['pdcurses'] : ['ncursesw', 'cursesw'])
 614       foreach curses_libname : curses_libname_list
 615         libcurses = cc.find_library(curses_libname,
 616                                     required: false,
 617                                     kwargs: static_kwargs)
 618         if libcurses.found()
 619           if cc.links(curses_test, args: curses_compile_args, dependencies: libcurses)
 620             curses = declare_dependency(compile_args: curses_compile_args,
 621                                         dependencies: [libcurses])
 622             break
 623           else
 624             msg = 'curses library not usable'
 625           endif
 626         endif
 627       endforeach
 628     endif
 629   endif
 630   if not get_option('iconv').disabled()
 631     foreach link_args : [ ['-liconv'], [] ]
 632       # Programs will be linked with glib and this will bring in libiconv on FreeBSD.
 633       # We need to use libiconv if available because mixing libiconv's headers with
 634       # the system libc does not work.
 635       # However, without adding glib to the dependencies -L/usr/local/lib will not be
 636       # included in the command line and libiconv will not be found.
 637       if cc.links('''
 638         #include <iconv.h>
 639         int main(void) {
 640           iconv_t conv = iconv_open("WCHAR_T", "UCS-2");
 641           return conv != (iconv_t) -1;
 642         }''', args: config_host['GLIB_CFLAGS'].split() + config_host['GLIB_LIBS'].split() + link_args)
 643         iconv = declare_dependency(link_args: link_args, dependencies: glib)
 644         break
 645       endif
 646     endforeach
 647   endif
 648   if curses.found() and not iconv.found()
 649     if get_option('iconv').enabled()
 650       error('iconv not available')
 651     endif
 652     msg = 'iconv required for curses UI but not available'
 653     curses = not_found
 654   endif
 655   if not curses.found() and msg != ''
 656     if get_option('curses').enabled()
 657       error(msg)
 658     else
 659       warning(msg + ', disabling')
 660     endif
 661   endif
 662 endif
 663
 664 brlapi = not_found
 665 if not get_option('brlapi').auto() or have_system
 666   brlapi = cc.find_library('brlapi', has_headers: ['brlapi.h'],
 667                          required: get_option('brlapi'),
 668                          kwargs: static_kwargs)
 669   if brlapi.found() and not cc.links('''
 670      #include <brlapi.h>
 671      #include <stddef.h>
 672      int main(void) { return brlapi__openConnection (NULL, NULL, NULL); }''', dependencies: brlapi)
 673     brlapi = not_found
 674     if get_option('brlapi').enabled()
 675       error('could not link brlapi')
 676     else
 677       warning('could not link brlapi, disabling')
 678     endif
 679   endif
 680 endif
 681
 682 sdl = not_found
 683 if not get_option('sdl').auto() or (have_system and not cocoa.found())
 684   sdl = dependency('sdl2', required: get_option('sdl'), kwargs: static_kwargs)
 685   sdl_image = not_found
 686 endif
 687 if sdl.found()
 688   # work around 2.0.8 bug
 689   sdl = declare_dependency(compile_args: '-Wno-undef',
 690                            dependencies: sdl)
 691   sdl_image = dependency('SDL2_image', required: get_option('sdl_image'),
 692                          method: 'pkg-config', kwargs: static_kwargs)
 693 else
 694   if get_option('sdl_image').enabled()
 695     error('sdl-image required, but SDL was @0@'.format(
 696           get_option('sdl').disabled() ? 'disabled' : 'not found'))
 697   endif
 698   sdl_image = not_found
 699 endif
 700
 701 rbd = not_found
 702 if not get_option('rbd').auto() or have_block
 703   librados = cc.find_library('rados', required: get_option('rbd'),
 704                              kwargs: static_kwargs)
 705   librbd = cc.find_library('rbd', has_headers: ['rbd/librbd.h'],
 706                            required: get_option('rbd'),
 707                            kwargs: static_kwargs)
 708   if librados.found() and librbd.found()
 709     if cc.links('''
 710       #include <stdio.h>
 711       #include <rbd/librbd.h>
 712       int main(void) {
 713         rados_t cluster;
 714         rados_create(&cluster, NULL);
 715         return 0;
 716       }''', dependencies: [librbd, librados])
 717       rbd = declare_dependency(dependencies: [librbd, librados])
 718     elif get_option('rbd').enabled()
 719       error('could not link librados')
 720     else
 721       warning('could not link librados, disabling')
 722     endif
 723   endif
 724 endif
 725
 726 glusterfs = not_found
 727 glusterfs_ftruncate_has_stat = false
 728 glusterfs_iocb_has_stat = false
 729 if not get_option('glusterfs').auto() or have_block
 730   glusterfs = dependency('glusterfs-api', version: '>=3',
 731                          required: get_option('glusterfs'),
 732                          method: 'pkg-config', kwargs: static_kwargs)
 733   if glusterfs.found()
 734     glusterfs_ftruncate_has_stat = cc.links('''
 735       #include <glusterfs/api/glfs.h>
 736
 737       int
 738       main(void)
 739       {
 740           /* new glfs_ftruncate() passes two additional args */
 741           return glfs_ftruncate(NULL, 0, NULL, NULL);
 742       }
 743     ''', dependencies: glusterfs)
 744     glusterfs_iocb_has_stat = cc.links('''
 745       #include <glusterfs/api/glfs.h>
 746
 747       /* new glfs_io_cbk() passes two additional glfs_stat structs */
 748       static void
 749       glusterfs_iocb(glfs_fd_t *fd, ssize_t ret, struct glfs_stat *prestat, struct glfs_stat *poststat, void *data)
 750       {}
 751
 752       int
 753       main(void)
 754       {
 755           glfs_io_cbk iocb = &glusterfs_iocb;
 756           iocb(NULL, 0 , NULL, NULL, NULL);
 757           return 0;
 758       }
 759     ''', dependencies: glusterfs)
 760   endif
 761 endif
 762 libssh = not_found
 763 if 'CONFIG_LIBSSH' in config_host
 764   libssh = declare_dependency(compile_args: config_host['LIBSSH_CFLAGS'].split(),
 765                               link_args: config_host['LIBSSH_LIBS'].split())
 766 endif
 767 libbzip2 = not_found
 768 if not get_option('bzip2').auto() or have_block
 769   libbzip2 = cc.find_library('bz2', has_headers: ['bzlib.h'],
 770                              required: get_option('bzip2'),
 771                              kwargs: static_kwargs)
 772   if libbzip2.found() and not cc.links('''
 773      #include <bzlib.h>
 774      int main(void) { BZ2_bzlibVersion(); return 0; }''', dependencies: libbzip2)
 775     libbzip2 = not_found
 776     if get_option('bzip2').enabled()
 777       error('could not link libbzip2')
 778     else
 779       warning('could not link libbzip2, disabling')
 780     endif
 781   endif
 782 endif
 783
 784 liblzfse = not_found
 785 if not get_option('lzfse').auto() or have_block
 786   liblzfse = cc.find_library('lzfse', has_headers: ['lzfse.h'],
 787                              required: get_option('lzfse'),
 788                              kwargs: static_kwargs)
 789 endif
 790 if liblzfse.found() and not cc.links('''
 791    #include <lzfse.h>
 792    int main(void) { lzfse_decode_scratch_size(); return 0; }''', dependencies: liblzfse)
 793   liblzfse = not_found
 794   if get_option('lzfse').enabled()
 795     error('could not link liblzfse')
 796   else
 797     warning('could not link liblzfse, disabling')
 798   endif
 799 endif
 800
 801 oss = not_found
 802 if 'CONFIG_AUDIO_OSS' in config_host
 803   oss = declare_dependency(link_args: config_host['OSS_LIBS'].split())
 804 endif
 805 dsound = not_found
 806 if 'CONFIG_AUDIO_DSOUND' in config_host
 807   dsound = declare_dependency(link_args: config_host['DSOUND_LIBS'].split())
 808 endif
 809 coreaudio = not_found
 810 if 'CONFIG_AUDIO_COREAUDIO' in config_host
 811   coreaudio = declare_dependency(link_args: config_host['COREAUDIO_LIBS'].split())
 812 endif
 813 opengl = not_found
 814 if 'CONFIG_OPENGL' in config_host
 815   opengl = declare_dependency(compile_args: config_host['OPENGL_CFLAGS'].split(),
 816                               link_args: config_host['OPENGL_LIBS'].split())
 817 endif
 818
 819 gnutls = not_found
 820 if not get_option('gnutls').auto() or have_system
 821   gnutls = dependency('gnutls', version: '>=3.5.18',
 822                       method: 'pkg-config',
 823                       required: get_option('gnutls'),
 824                       kwargs: static_kwargs)
 825 endif
 826
 827 # Nettle has priority over gcrypt
 828 gcrypt = not_found
 829 nettle = not_found
 830 xts = 'private'
 831 if get_option('nettle').enabled() and get_option('gcrypt').enabled()
 832   error('Only one of gcrypt & nettle can be enabled')
 833 elif (not get_option('nettle').auto() or have_system) and not get_option('gcrypt').enabled()
 834   nettle = dependency('nettle', version: '>=3.4',
 835                       method: 'pkg-config',
 836                       required: get_option('nettle'),
 837                       kwargs: static_kwargs)
 838   if nettle.found() and cc.has_header('nettle/xts.h', dependencies: nettle)
 839     xts = 'nettle'
 840   endif
 841 endif
 842 if (not get_option('gcrypt').auto() or have_system) and not nettle.found()
 843   gcrypt = dependency('libgcrypt', version: '>=1.5',
 844                          method: 'config-tool',
 845                          required: get_option('gcrypt'),
 846                          kwargs: static_kwargs)
 847   if gcrypt.found() and cc.compiles('''
 848     #include <gcrypt.h>
 849     int main(void) {
 850       gcry_cipher_hd_t handle;
 851       gcry_cipher_open(&handle, GCRY_CIPHER_AES, GCRY_CIPHER_MODE_XTS, 0);
 852       return 0;
 853     }
 854     ''', dependencies: gcrypt)
 855     xts = 'gcrypt'
 856   endif
 857   # Debian has removed -lgpg-error from libgcrypt-config
 858   # as it "spreads unnecessary dependencies" which in
 859   # turn breaks static builds...
 860   if gcrypt.found() and enable_static
 861     gcrypt = declare_dependency(dependencies: [
 862       gcrypt,
 863       cc.find_library('gpg-error', required: true, kwargs: static_kwargs)])
 864   endif
 865 endif
 866
 867 gtk = not_found
 868 gtkx11 = not_found
 869 vte = not_found
 870 if not get_option('gtk').auto() or (have_system and not cocoa.found())
 871   gtk = dependency('gtk+-3.0', version: '>=3.22.0',
 872                    method: 'pkg-config',
 873                    required: get_option('gtk'),
 874                    kwargs: static_kwargs)
 875   if gtk.found()
 876     gtkx11 = dependency('gtk+-x11-3.0', version: '>=3.22.0',
 877                         method: 'pkg-config',
 878                         required: false,
 879                         kwargs: static_kwargs)
 880     gtk = declare_dependency(dependencies: [gtk, gtkx11])
 881
 882     if not get_option('vte').auto() or have_system
 883       vte = dependency('vte-2.91',
 884                        method: 'pkg-config',
 885                        required: get_option('vte'),
 886                        kwargs: static_kwargs)
 887     endif
 888   endif
 889 endif
 890
 891 x11 = not_found
 892 if gtkx11.found()
 893   x11 = dependency('x11', method: 'pkg-config', required: gtkx11.found(),
 894                    kwargs: static_kwargs)
 895 endif
 896 vnc = not_found
 897 png = not_found
 898 jpeg = not_found
 899 sasl = not_found
 900 if get_option('vnc').enabled()
 901   vnc = declare_dependency() # dummy dependency
 902   png = dependency('libpng', required: get_option('vnc_png'),
 903                    method: 'pkg-config', kwargs: static_kwargs)
 904   jpeg = dependency('libjpeg', required: get_option('vnc_jpeg'),
 905                     method: 'pkg-config', kwargs: static_kwargs)
 906   sasl = cc.find_library('sasl2', has_headers: ['sasl/sasl.h'],
 907                          required: get_option('vnc_sasl'),
 908                          kwargs: static_kwargs)
 909   if sasl.found()
 910     sasl = declare_dependency(dependencies: sasl,
 911                               compile_args: '-DSTRUCT_IOVEC_DEFINED')
 912   endif
 913 endif
 914
 915 pam = not_found
 916 if not get_option('auth_pam').auto() or have_system
 917   pam = cc.find_library('pam', has_headers: ['security/pam_appl.h'],
 918                         required: get_option('auth_pam'),
 919                         kwargs: static_kwargs)
 920 endif
 921 if pam.found() and not cc.links('''
 922    #include <stddef.h>
 923    #include <security/pam_appl.h>
 924    int main(void) {
 925      const char *service_name = "qemu";
 926      const char *user = "frank";
 927      const struct pam_conv pam_conv = { 0 };
 928      pam_handle_t *pamh = NULL;
 929      pam_start(service_name, user, &pam_conv, &pamh);
 930      return 0;
 931    }''', dependencies: pam)
 932   pam = not_found
 933   if get_option('auth_pam').enabled()
 934     error('could not link libpam')
 935   else
 936     warning('could not link libpam, disabling')
 937   endif
 938 endif
 939
 940 snappy = not_found
 941 if not get_option('snappy').auto() or have_system
 942   snappy = cc.find_library('snappy', has_headers: ['snappy-c.h'],
 943                            required: get_option('snappy'),
 944                            kwargs: static_kwargs)
 945 endif
 946 if snappy.found() and not cc.links('''
 947    #include <snappy-c.h>
 948    int main(void) { snappy_max_compressed_length(4096); return 0; }''', dependencies: snappy)
 949   snappy = not_found
 950   if get_option('snappy').enabled()
 951     error('could not link libsnappy')
 952   else
 953     warning('could not link libsnappy, disabling')
 954   endif
 955 endif
 956
 957 lzo = not_found
 958 if not get_option('lzo').auto() or have_system
 959   lzo = cc.find_library('lzo2', has_headers: ['lzo/lzo1x.h'],
 960                         required: get_option('lzo'),
 961                         kwargs: static_kwargs)
 962 endif
 963 if lzo.found() and not cc.links('''
 964    #include <lzo/lzo1x.h>
 965    int main(void) { lzo_version(); return 0; }''', dependencies: lzo)
 966   lzo = not_found
 967   if get_option('lzo').enabled()
 968     error('could not link liblzo2')
 969   else
 970     warning('could not link liblzo2, disabling')
 971   endif
 972 endif
 973
 974 rdma = not_found
 975 if 'CONFIG_RDMA' in config_host
 976   rdma = declare_dependency(link_args: config_host['RDMA_LIBS'].split())
 977 endif
 978 numa = not_found
 979 if 'CONFIG_NUMA' in config_host
 980   numa = declare_dependency(link_args: config_host['NUMA_LIBS'].split())
 981 endif
 982 xen = not_found
 983 if 'CONFIG_XEN_BACKEND' in config_host
 984   xen = declare_dependency(compile_args: config_host['XEN_CFLAGS'].split(),
 985                            link_args: config_host['XEN_LIBS'].split())
 986 endif
 987 cacard = not_found
 988 if not get_option('smartcard').auto() or have_system
 989   cacard = dependency('libcacard', required: get_option('smartcard'),
 990                       version: '>=2.5.1', method: 'pkg-config',
 991                       kwargs: static_kwargs)
 992 endif
 993 u2f = not_found
 994 if have_system
 995   u2f = dependency('u2f-emu', required: get_option('u2f'),
 996                    method: 'pkg-config',
 997                    kwargs: static_kwargs)
 998 endif
 999 usbredir = not_found
1000 if not get_option('usb_redir').auto() or have_system
1001   usbredir = dependency('libusbredirparser-0.5', required: get_option('usb_redir'),
1002                         version: '>=0.6', method: 'pkg-config',
1003                         kwargs: static_kwargs)
1004 endif
1005 libusb = not_found
1006 if not get_option('libusb').auto() or have_system
1007   libusb = dependency('libusb-1.0', required: get_option('libusb'),
1008                       version: '>=1.0.13', method: 'pkg-config',
1009                       kwargs: static_kwargs)
1010 endif
1011
1012 libpmem = not_found
1013 if not get_option('libpmem').auto() or have_system
1014   libpmem = dependency('libpmem', required: get_option('libpmem'),
1015                        method: 'pkg-config', kwargs: static_kwargs)
1016 endif
1017 libdaxctl = not_found
1018 if not get_option('libdaxctl').auto() or have_system
1019   libdaxctl = dependency('libdaxctl', required: get_option('libdaxctl'),
1020                          version: '>=57', method: 'pkg-config',
1021                          kwargs: static_kwargs)
1022 endif
1023 tasn1 = not_found
1024 if gnutls.found()
1025   tasn1 = dependency('libtasn1',
1026                      method: 'pkg-config',
1027                      kwargs: static_kwargs)
1028 endif
1029 keyutils = dependency('libkeyutils', required: false,
1030                       method: 'pkg-config', kwargs: static_kwargs)
1031
1032 has_gettid = cc.has_function('gettid')
1033
1034 # Malloc tests
1035
1036 malloc = []
1037 if get_option('malloc') == 'system'
1038   has_malloc_trim = \
1039     not get_option('malloc_trim').disabled() and \
1040     cc.links('''#include <malloc.h>
1041                 int main(void) { malloc_trim(0); return 0; }''')
1042 else
1043   has_malloc_trim = false
1044   malloc = cc.find_library(get_option('malloc'), required: true)
1045 endif
1046 if not has_malloc_trim and get_option('malloc_trim').enabled()
1047   if get_option('malloc') == 'system'
1048     error('malloc_trim not available on this platform.')
1049   else
1050     error('malloc_trim not available with non-libc memory allocator')
1051   endif
1052 endif
1053
1054 # Check whether the glibc provides statx()
1055
1056 gnu_source_prefix = '''
1057   #ifndef _GNU_SOURCE
1058   #define _GNU_SOURCE
1059   #endif
1060 '''
1061 statx_test = gnu_source_prefix + '''
1062   #include <sys/stat.h>
1063   int main(void) {
1064     struct statx statxbuf;
1065     statx(0, "", 0, STATX_BASIC_STATS, &statxbuf);
1066     return 0;
1067   }'''
1068
1069 has_statx = cc.links(statx_test)
1070
1071 have_vhost_user_blk_server = (targetos == 'linux' and
1072     'CONFIG_VHOST_USER' in config_host)
1073
1074 if get_option('vhost_user_blk_server').enabled()
1075     if targetos != 'linux'
1076         error('vhost_user_blk_server requires linux')
1077     elif 'CONFIG_VHOST_USER' not in config_host
1078         error('vhost_user_blk_server requires vhost-user support')
1079     endif
1080 elif get_option('vhost_user_blk_server').disabled() or not have_system
1081     have_vhost_user_blk_server = false
1082 endif
1083
1084
1085 if get_option('fuse').disabled() and get_option('fuse_lseek').enabled()
1086   error('Cannot enable fuse-lseek while fuse is disabled')
1087 endif
1088
1089 fuse = dependency('fuse3', required: get_option('fuse'),
1090                   version: '>=3.1', method: 'pkg-config',
1091                   kwargs: static_kwargs)
1092
1093 fuse_lseek = not_found
1094 if not get_option('fuse_lseek').disabled()
1095   if fuse.version().version_compare('>=3.8')
1096     # Dummy dependency
1097     fuse_lseek = declare_dependency()
1098   elif get_option('fuse_lseek').enabled()
1099     if fuse.found()
1100       error('fuse-lseek requires libfuse >=3.8, found ' + fuse.version())
1101     else
1102       error('fuse-lseek requires libfuse, which was not found')
1103     endif
1104   endif
1105 endif
1106
1107 # libbpf
1108 libbpf = dependency('libbpf', required: get_option('bpf'), method: 'pkg-config')
1109 if libbpf.found() and not cc.links('''
1110    #include <bpf/libbpf.h>
1111    int main(void)
1112    {
1113      bpf_object__destroy_skeleton(NULL);
1114      return 0;
1115    }''', dependencies: libbpf)
1116   libbpf = not_found
1117   if get_option('bpf').enabled()
1118     error('libbpf skeleton test failed')
1119   else
1120     warning('libbpf skeleton test failed, disabling')
1121   endif
1122 endif
1123
1124 if get_option('cfi')
1125   cfi_flags=[]
1126   # Check for dependency on LTO
1127   if not get_option('b_lto')
1128     error('Selected Control-Flow Integrity but LTO is disabled')
1129   endif
1130   if config_host.has_key('CONFIG_MODULES')
1131     error('Selected Control-Flow Integrity is not compatible with modules')
1132   endif
1133   # Check for cfi flags. CFI requires LTO so we can't use
1134   # get_supported_arguments, but need a more complex "compiles" which allows
1135   # custom arguments
1136   if cc.compiles('int main () { return 0; }', name: '-fsanitize=cfi-icall',
1137                  args: ['-flto', '-fsanitize=cfi-icall'] )
1138     cfi_flags += '-fsanitize=cfi-icall'
1139   else
1140     error('-fsanitize=cfi-icall is not supported by the compiler')
1141   endif
1142   if cc.compiles('int main () { return 0; }',
1143                  name: '-fsanitize-cfi-icall-generalize-pointers',
1144                  args: ['-flto', '-fsanitize=cfi-icall',
1145                         '-fsanitize-cfi-icall-generalize-pointers'] )
1146     cfi_flags += '-fsanitize-cfi-icall-generalize-pointers'
1147   else
1148     error('-fsanitize-cfi-icall-generalize-pointers is not supported by the compiler')
1149   endif
1150   if get_option('cfi_debug')
1151     if cc.compiles('int main () { return 0; }',
1152                    name: '-fno-sanitize-trap=cfi-icall',
1153                    args: ['-flto', '-fsanitize=cfi-icall',
1154                           '-fno-sanitize-trap=cfi-icall'] )
1155       cfi_flags += '-fno-sanitize-trap=cfi-icall'
1156     else
1157       error('-fno-sanitize-trap=cfi-icall is not supported by the compiler')
1158     endif
1159   endif
1160   add_global_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1161   add_global_link_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1162 endif
1163
1164 have_host_block_device = (targetos != 'darwin' or
1165     cc.has_header('IOKit/storage/IOMedia.h'))
1166
1167 #################
1168 # config-host.h #
1169 #################
1170
1171 have_virtfs = (targetos == 'linux' and
1172     have_system and
1173     libattr.found() and
1174     libcap_ng.found())
1175
1176 have_virtfs_proxy_helper = have_virtfs and have_tools
1177
1178 if get_option('virtfs').enabled()
1179   if not have_virtfs
1180     if targetos != 'linux'
1181       error('virtio-9p (virtfs) requires Linux')
1182     elif not libcap_ng.found() or not libattr.found()
1183       error('virtio-9p (virtfs) requires libcap-ng-devel and libattr-devel')
1184     elif not have_system
1185       error('virtio-9p (virtfs) needs system emulation support')
1186     endif
1187   endif
1188 elif get_option('virtfs').disabled()
1189   have_virtfs = false
1190 endif
1191
1192 config_host_data.set_quoted('CONFIG_BINDIR', get_option('prefix') / get_option('bindir'))
1193 config_host_data.set_quoted('CONFIG_PREFIX', get_option('prefix'))
1194 config_host_data.set_quoted('CONFIG_QEMU_CONFDIR', get_option('prefix') / qemu_confdir)
1195 config_host_data.set_quoted('CONFIG_QEMU_DATADIR', get_option('prefix') / qemu_datadir)
1196 config_host_data.set_quoted('CONFIG_QEMU_DESKTOPDIR', get_option('prefix') / qemu_desktopdir)
1197 config_host_data.set_quoted('CONFIG_QEMU_FIRMWAREPATH', get_option('qemu_firmwarepath'))
1198 config_host_data.set_quoted('CONFIG_QEMU_HELPERDIR', get_option('prefix') / get_option('libexecdir'))
1199 config_host_data.set_quoted('CONFIG_QEMU_ICONDIR', get_option('prefix') / qemu_icondir)
1200 config_host_data.set_quoted('CONFIG_QEMU_LOCALEDIR', get_option('prefix') / get_option('localedir'))
1201 config_host_data.set_quoted('CONFIG_QEMU_LOCALSTATEDIR', get_option('prefix') / get_option('localstatedir'))
1202 config_host_data.set_quoted('CONFIG_QEMU_MODDIR', get_option('prefix') / qemu_moddir)
1203 config_host_data.set_quoted('CONFIG_SYSCONFDIR', get_option('prefix') / get_option('sysconfdir'))
1204
1205 config_host_data.set('CONFIG_ATTR', libattr.found())
1206 config_host_data.set('CONFIG_BRLAPI', brlapi.found())
1207 config_host_data.set('CONFIG_COCOA', cocoa.found())
1208 config_host_data.set('CONFIG_LIBUDEV', libudev.found())
1209 config_host_data.set('CONFIG_LZO', lzo.found())
1210 config_host_data.set('CONFIG_MPATH', mpathpersist.found())
1211 config_host_data.set('CONFIG_MPATH_NEW_API', mpathpersist_new_api)
1212 config_host_data.set('CONFIG_CURL', curl.found())
1213 config_host_data.set('CONFIG_CURSES', curses.found())
1214 config_host_data.set('CONFIG_GLUSTERFS', glusterfs.found())
1215 if glusterfs.found()
1216   config_host_data.set('CONFIG_GLUSTERFS_XLATOR_OPT', glusterfs.version().version_compare('>=4'))
1217   config_host_data.set('CONFIG_GLUSTERFS_DISCARD', glusterfs.version().version_compare('>=5'))
1218   config_host_data.set('CONFIG_GLUSTERFS_FALLOCATE', glusterfs.version().version_compare('>=6'))
1219   config_host_data.set('CONFIG_GLUSTERFS_ZEROFILL', glusterfs.version().version_compare('>=6'))
1220   config_host_data.set('CONFIG_GLUSTERFS_FTRUNCATE_HAS_STAT', glusterfs_ftruncate_has_stat)
1221   config_host_data.set('CONFIG_GLUSTERFS_IOCB_HAS_STAT', glusterfs_iocb_has_stat)
1222 endif
1223 config_host_data.set('CONFIG_GTK', gtk.found())
1224 config_host_data.set('CONFIG_VTE', vte.found())
1225 config_host_data.set('CONFIG_LIBATTR', have_old_libattr)
1226 config_host_data.set('CONFIG_LIBCAP_NG', libcap_ng.found())
1227 config_host_data.set('CONFIG_EBPF', libbpf.found())
1228 config_host_data.set('CONFIG_LIBDAXCTL', libdaxctl.found())
1229 config_host_data.set('CONFIG_LIBISCSI', libiscsi.found())
1230 config_host_data.set('CONFIG_LIBNFS', libnfs.found())
1231 config_host_data.set('CONFIG_LINUX_IO_URING', linux_io_uring.found())
1232 config_host_data.set('CONFIG_LIBPMEM', libpmem.found())
1233 config_host_data.set('CONFIG_RBD', rbd.found())
1234 config_host_data.set('CONFIG_SDL', sdl.found())
1235 config_host_data.set('CONFIG_SDL_IMAGE', sdl_image.found())
1236 config_host_data.set('CONFIG_SECCOMP', seccomp.found())
1237 config_host_data.set('CONFIG_SNAPPY', snappy.found())
1238 config_host_data.set('CONFIG_USB_LIBUSB', libusb.found())
1239 config_host_data.set('CONFIG_VHOST_USER_BLK_SERVER', have_vhost_user_blk_server)
1240 config_host_data.set('CONFIG_VNC', vnc.found())
1241 config_host_data.set('CONFIG_VNC_JPEG', jpeg.found())
1242 config_host_data.set('CONFIG_VNC_PNG', png.found())
1243 config_host_data.set('CONFIG_VNC_SASL', sasl.found())
1244 config_host_data.set('CONFIG_VIRTFS', have_virtfs)
1245 config_host_data.set('CONFIG_VTE', vte.found())
1246 config_host_data.set('CONFIG_XKBCOMMON', xkbcommon.found())
1247 config_host_data.set('CONFIG_KEYUTILS', keyutils.found())
1248 config_host_data.set('CONFIG_GETTID', has_gettid)
1249 config_host_data.set('CONFIG_GNUTLS', gnutls.found())
1250 config_host_data.set('CONFIG_GCRYPT', gcrypt.found())
1251 config_host_data.set('CONFIG_NETTLE', nettle.found())
1252 config_host_data.set('CONFIG_QEMU_PRIVATE_XTS', xts == 'private')
1253 config_host_data.set('CONFIG_MALLOC_TRIM', has_malloc_trim)
1254 config_host_data.set('CONFIG_STATX', has_statx)
1255 config_host_data.set('CONFIG_ZSTD', zstd.found())
1256 config_host_data.set('CONFIG_FUSE', fuse.found())
1257 config_host_data.set('CONFIG_FUSE_LSEEK', fuse_lseek.found())
1258 config_host_data.set('CONFIG_X11', x11.found())
1259 config_host_data.set('CONFIG_CFI', get_option('cfi'))
1260 config_host_data.set('QEMU_VERSION', '"@0@"'.format(meson.project_version()))
1261 config_host_data.set('QEMU_VERSION_MAJOR', meson.project_version().split('.')[0])
1262 config_host_data.set('QEMU_VERSION_MINOR', meson.project_version().split('.')[1])
1263 config_host_data.set('QEMU_VERSION_MICRO', meson.project_version().split('.')[2])
1264
1265 config_host_data.set('HAVE_HOST_BLOCK_DEVICE', have_host_block_device)
1266
1267 # has_header
1268 config_host_data.set('CONFIG_EPOLL', cc.has_header('sys/epoll.h'))
1269 config_host_data.set('CONFIG_LINUX_MAGIC_H', cc.has_header('linux/magic.h'))
1270 config_host_data.set('CONFIG_VALGRIND_H', cc.has_header('valgrind/valgrind.h'))
1271 config_host_data.set('HAVE_BTRFS_H', cc.has_header('linux/btrfs.h'))
1272 config_host_data.set('HAVE_DRM_H', cc.has_header('libdrm/drm.h'))
1273 config_host_data.set('HAVE_PTY_H', cc.has_header('pty.h'))
1274 config_host_data.set('HAVE_SYS_DISK_H', cc.has_header('sys/disk.h'))
1275 config_host_data.set('HAVE_SYS_IOCCOM_H', cc.has_header('sys/ioccom.h'))
1276 config_host_data.set('HAVE_SYS_KCOV_H', cc.has_header('sys/kcov.h'))
1277
1278 # has_function
1279 config_host_data.set('CONFIG_ACCEPT4', cc.has_function('accept4'))
1280 config_host_data.set('CONFIG_CLOCK_ADJTIME', cc.has_function('clock_adjtime'))
1281 config_host_data.set('CONFIG_DUP3', cc.has_function('dup3'))
1282 config_host_data.set('CONFIG_FALLOCATE', cc.has_function('fallocate'))
1283 config_host_data.set('CONFIG_POSIX_FALLOCATE', cc.has_function('posix_fallocate'))
1284 config_host_data.set('CONFIG_POSIX_MEMALIGN', cc.has_function('posix_memalign'))
1285 config_host_data.set('CONFIG_PPOLL', cc.has_function('ppoll'))
1286 config_host_data.set('CONFIG_PREADV', cc.has_function('preadv', prefix: '#include <sys/uio.h>'))
1287 config_host_data.set('CONFIG_SEM_TIMEDWAIT', cc.has_function('sem_timedwait', dependencies: threads))
1288 config_host_data.set('CONFIG_SENDFILE', cc.has_function('sendfile'))
1289 config_host_data.set('CONFIG_SETNS', cc.has_function('setns') and cc.has_function('unshare'))
1290 config_host_data.set('CONFIG_SYNCFS', cc.has_function('syncfs'))
1291 config_host_data.set('CONFIG_SYNC_FILE_RANGE', cc.has_function('sync_file_range'))
1292 config_host_data.set('CONFIG_TIMERFD', cc.has_function('timerfd_create'))
1293 config_host_data.set('HAVE_COPY_FILE_RANGE', cc.has_function('copy_file_range'))
1294 config_host_data.set('HAVE_OPENPTY', cc.has_function('openpty', dependencies: util))
1295 config_host_data.set('HAVE_STRCHRNUL', cc.has_function('strchrnul'))
1296 config_host_data.set('HAVE_SYSTEM_FUNCTION', cc.has_function('system', prefix: '#include <stdlib.h>'))
1297
1298 # has_header_symbol
1299 config_host_data.set('CONFIG_BYTESWAP_H',
1300                      cc.has_header_symbol('byteswap.h', 'bswap_32'))
1301 config_host_data.set('CONFIG_EPOLL_CREATE1',
1302                      cc.has_header_symbol('sys/epoll.h', 'epoll_create1'))
1303 config_host_data.set('CONFIG_HAS_ENVIRON',
1304                      cc.has_header_symbol('unistd.h', 'environ', prefix: gnu_source_prefix))
1305 config_host_data.set('CONFIG_FALLOCATE_PUNCH_HOLE',
1306                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_PUNCH_HOLE') and
1307                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_KEEP_SIZE'))
1308 config_host_data.set('CONFIG_FALLOCATE_ZERO_RANGE',
1309                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_ZERO_RANGE'))
1310 config_host_data.set('CONFIG_FIEMAP',
1311                      cc.has_header('linux/fiemap.h') and
1312                      cc.has_header_symbol('linux/fs.h', 'FS_IOC_FIEMAP'))
1313 config_host_data.set('CONFIG_GETRANDOM',
1314                      cc.has_function('getrandom') and
1315                      cc.has_header_symbol('sys/random.h', 'GRND_NONBLOCK'))
1316 config_host_data.set('CONFIG_INOTIFY',
1317                      cc.has_header_symbol('sys/inotify.h', 'inotify_init'))
1318 config_host_data.set('CONFIG_INOTIFY1',
1319                      cc.has_header_symbol('sys/inotify.h', 'inotify_init1'))
1320 config_host_data.set('CONFIG_MACHINE_BSWAP_H',
1321                      cc.has_header_symbol('machine/bswap.h', 'bswap32',
1322                                           prefix: '''#include <sys/endian.h>
1323                                                      #include <sys/types.h>'''))
1324 config_host_data.set('CONFIG_PRCTL_PR_SET_TIMERSLACK',
1325                      cc.has_header_symbol('sys/prctl.h', 'PR_SET_TIMERSLACK'))
1326 config_host_data.set('CONFIG_RTNETLINK',
1327                      cc.has_header_symbol('linux/rtnetlink.h', 'IFLA_PROTO_DOWN'))
1328 config_host_data.set('CONFIG_SYSMACROS',
1329                      cc.has_header_symbol('sys/sysmacros.h', 'makedev'))
1330 config_host_data.set('HAVE_OPTRESET',
1331                      cc.has_header_symbol('getopt.h', 'optreset'))
1332 config_host_data.set('HAVE_UTMPX',
1333                      cc.has_header_symbol('utmpx.h', 'struct utmpx'))
1334
1335 # has_member
1336 config_host_data.set('HAVE_SIGEV_NOTIFY_THREAD_ID',
1337                      cc.has_member('struct sigevent', 'sigev_notify_thread_id',
1338                                    prefix: '#include <signal.h>'))
1339 config_host_data.set('HAVE_STRUCT_STAT_ST_ATIM',
1340                      cc.has_member('struct stat', 'st_atim',
1341                                    prefix: '#include <sys/stat.h>'))
1342
1343 config_host_data.set('CONFIG_EVENTFD', cc.links('''
1344   #include <sys/eventfd.h>
1345   int main(void) { return eventfd(0, EFD_NONBLOCK | EFD_CLOEXEC); }'''))
1346 config_host_data.set('CONFIG_FDATASYNC', cc.links(gnu_source_prefix + '''
1347   #include <unistd.h>
1348   int main(void) {
1349   #if defined(_POSIX_SYNCHRONIZED_IO) && _POSIX_SYNCHRONIZED_IO > 0
1350   return fdatasync(0);
1351   #else
1352   #error Not supported
1353   #endif
1354   }'''))
1355 config_host_data.set('CONFIG_MADVISE', cc.links(gnu_source_prefix + '''
1356   #include <sys/types.h>
1357   #include <sys/mman.h>
1358   #include <stddef.h>
1359   int main(void) { return madvise(NULL, 0, MADV_DONTNEED); }'''))
1360 config_host_data.set('CONFIG_MEMFD', cc.links(gnu_source_prefix + '''
1361   #include <sys/mman.h>
1362   int main(void) { return memfd_create("foo", MFD_ALLOW_SEALING); }'''))
1363 config_host_data.set('CONFIG_OPEN_BY_HANDLE', cc.links(gnu_source_prefix + '''
1364   #include <fcntl.h>
1365   #if !defined(AT_EMPTY_PATH)
1366   # error missing definition
1367   #else
1368   int main(void) { struct file_handle fh; return open_by_handle_at(0, &fh, 0); }
1369   #endif'''))
1370 config_host_data.set('CONFIG_PIPE2', cc.links(gnu_source_prefix + '''
1371   #include <unistd.h>
1372   #include <fcntl.h>
1373
1374   int main(void)
1375   {
1376       int pipefd[2];
1377       return pipe2(pipefd, O_CLOEXEC);
1378   }'''))
1379 config_host_data.set('CONFIG_POSIX_MADVISE', cc.links(gnu_source_prefix + '''
1380   #include <sys/mman.h>
1381   #include <stddef.h>
1382   int main(void) { return posix_madvise(NULL, 0, POSIX_MADV_DONTNEED); }'''))
1383 config_host_data.set('CONFIG_SIGNALFD', cc.links(gnu_source_prefix + '''
1384   #include <unistd.h>
1385   #include <sys/syscall.h>
1386   #include <signal.h>
1387   int main(void) { return syscall(SYS_signalfd, -1, NULL, _NSIG / 8); }'''))
1388 config_host_data.set('CONFIG_SPLICE', cc.links(gnu_source_prefix + '''
1389   #include <unistd.h>
1390   #include <fcntl.h>
1391   #include <limits.h>
1392
1393   int main(void)
1394   {
1395     int len, fd = 0;
1396     len = tee(STDIN_FILENO, STDOUT_FILENO, INT_MAX, SPLICE_F_NONBLOCK);
1397     splice(STDIN_FILENO, NULL, fd, NULL, len, SPLICE_F_MOVE);
1398     return 0;
1399   }'''))
1400
1401 # Some versions of Mac OS X incorrectly define SIZE_MAX
1402 config_host_data.set('HAVE_BROKEN_SIZE_MAX', not cc.compiles('''
1403     #include <stdint.h>
1404     #include <stdio.h>
1405     int main(int argc, char *argv[]) {
1406         return printf("%zu", SIZE_MAX);
1407     }''', args: ['-Werror']))
1408
1409
1410 ignored = ['CONFIG_QEMU_INTERP_PREFIX'] # actually per-target
1411 arrays = ['CONFIG_AUDIO_DRIVERS', 'CONFIG_BDRV_RW_WHITELIST', 'CONFIG_BDRV_RO_WHITELIST']
1412 strings = ['HOST_DSOSUF', 'CONFIG_IASL']
1413 foreach k, v: config_host
1414   if ignored.contains(k)
1415     # do nothing
1416   elif arrays.contains(k)
1417     if v != ''
1418       v = '"' + '", "'.join(v.split()) + '", '
1419     endif
1420     config_host_data.set(k, v)
1421   elif k == 'ARCH'
1422     config_host_data.set('HOST_' + v.to_upper(), 1)
1423   elif strings.contains(k)
1424     if not k.startswith('CONFIG_')
1425       k = 'CONFIG_' + k.to_upper()
1426     endif
1427     config_host_data.set_quoted(k, v)
1428   elif k.startswith('CONFIG_') or k.startswith('HAVE_') or k.startswith('HOST_')
1429     config_host_data.set(k, v == 'y' ? 1 : v)
1430   endif
1431 endforeach
1432
1433 ########################
1434 # Target configuration #
1435 ########################
1436
1437 minikconf = find_program('scripts/minikconf.py')
1438 config_all = {}
1439 config_all_devices = {}
1440 config_all_disas = {}
1441 config_devices_mak_list = []
1442 config_devices_h = {}
1443 config_target_h = {}
1444 config_target_mak = {}
1445
1446 disassemblers = {
1447   'alpha' : ['CONFIG_ALPHA_DIS'],
1448   'arm' : ['CONFIG_ARM_DIS'],
1449   'avr' : ['CONFIG_AVR_DIS'],
1450   'cris' : ['CONFIG_CRIS_DIS'],
1451   'hexagon' : ['CONFIG_HEXAGON_DIS'],
1452   'hppa' : ['CONFIG_HPPA_DIS'],
1453   'i386' : ['CONFIG_I386_DIS'],
1454   'x86_64' : ['CONFIG_I386_DIS'],
1455   'x32' : ['CONFIG_I386_DIS'],
1456   'm68k' : ['CONFIG_M68K_DIS'],
1457   'microblaze' : ['CONFIG_MICROBLAZE_DIS'],
1458   'mips' : ['CONFIG_MIPS_DIS'],
1459   'nios2' : ['CONFIG_NIOS2_DIS'],
1460   'or1k' : ['CONFIG_OPENRISC_DIS'],
1461   'ppc' : ['CONFIG_PPC_DIS'],
1462   'riscv' : ['CONFIG_RISCV_DIS'],
1463   'rx' : ['CONFIG_RX_DIS'],
1464   's390' : ['CONFIG_S390_DIS'],
1465   'sh4' : ['CONFIG_SH4_DIS'],
1466   'sparc' : ['CONFIG_SPARC_DIS'],
1467   'xtensa' : ['CONFIG_XTENSA_DIS'],
1468 }
1469 if link_language == 'cpp'
1470   disassemblers += {
1471     'aarch64' : [ 'CONFIG_ARM_A64_DIS'],
1472     'arm' : [ 'CONFIG_ARM_DIS', 'CONFIG_ARM_A64_DIS'],
1473     'mips' : [ 'CONFIG_MIPS_DIS', 'CONFIG_NANOMIPS_DIS'],
1474   }
1475 endif
1476
1477 have_ivshmem = config_host_data.get('CONFIG_EVENTFD')
1478 host_kconfig = \
1479   ('CONFIG_TPM' in config_host ? ['CONFIG_TPM=y'] : []) + \
1480   ('CONFIG_SPICE' in config_host ? ['CONFIG_SPICE=y'] : []) + \
1481   (have_ivshmem ? ['CONFIG_IVSHMEM=y'] : []) + \
1482   ('CONFIG_OPENGL' in config_host ? ['CONFIG_OPENGL=y'] : []) + \
1483   (x11.found() ? ['CONFIG_X11=y'] : []) + \
1484   ('CONFIG_VHOST_USER' in config_host ? ['CONFIG_VHOST_USER=y'] : []) + \
1485   ('CONFIG_VHOST_VDPA' in config_host ? ['CONFIG_VHOST_VDPA=y'] : []) + \
1486   ('CONFIG_VHOST_KERNEL' in config_host ? ['CONFIG_VHOST_KERNEL=y'] : []) + \
1487   (have_virtfs ? ['CONFIG_VIRTFS=y'] : []) + \
1488   ('CONFIG_LINUX' in config_host ? ['CONFIG_LINUX=y'] : []) + \
1489   ('CONFIG_PVRDMA' in config_host ? ['CONFIG_PVRDMA=y'] : []) + \
1490   (multiprocess_allowed ? ['CONFIG_MULTIPROCESS_ALLOWED=y'] : [])
1491
1492 ignored = [ 'TARGET_XML_FILES', 'TARGET_ABI_DIR', 'TARGET_ARCH' ]
1493
1494 default_targets = 'CONFIG_DEFAULT_TARGETS' in config_host
1495 actual_target_dirs = []
1496 fdt_required = []
1497 foreach target : target_dirs
1498   config_target = { 'TARGET_NAME': target.split('-')[0] }
1499   if target.endswith('linux-user')
1500     if targetos != 'linux'
1501       if default_targets
1502         continue
1503       endif
1504       error('Target @0@ is only available on a Linux host'.format(target))
1505     endif
1506     config_target += { 'CONFIG_LINUX_USER': 'y' }
1507   elif target.endswith('bsd-user')
1508     if 'CONFIG_BSD' not in config_host
1509       if default_targets
1510         continue
1511       endif
1512       error('Target @0@ is only available on a BSD host'.format(target))
1513     endif
1514     config_target += { 'CONFIG_BSD_USER': 'y' }
1515   elif target.endswith('softmmu')
1516     config_target += { 'CONFIG_SOFTMMU': 'y' }
1517   endif
1518   if target.endswith('-user')
1519     config_target += {
1520       'CONFIG_USER_ONLY': 'y',
1521       'CONFIG_QEMU_INTERP_PREFIX':
1522         config_host['CONFIG_QEMU_INTERP_PREFIX'].format(config_target['TARGET_NAME'])
1523     }
1524   endif
1525
1526   accel_kconfig = []
1527   foreach sym: accelerators
1528     if sym == 'CONFIG_TCG' or target in accelerator_targets.get(sym, [])
1529       config_target += { sym: 'y' }
1530       config_all += { sym: 'y' }
1531       if sym == 'CONFIG_TCG' and tcg_arch == 'tci'
1532         config_target += { 'CONFIG_TCG_INTERPRETER': 'y' }
1533       elif sym == 'CONFIG_XEN' and have_xen_pci_passthrough
1534         config_target += { 'CONFIG_XEN_PCI_PASSTHROUGH': 'y' }
1535       endif
1536       if target in modular_tcg
1537         config_target += { 'CONFIG_TCG_MODULAR': 'y' }
1538       else
1539         config_target += { 'CONFIG_TCG_BUILTIN': 'y' }
1540       endif
1541       accel_kconfig += [ sym + '=y' ]
1542     endif
1543   endforeach
1544   if accel_kconfig.length() == 0
1545     if default_targets
1546       continue
1547     endif
1548     error('No accelerator available for target @0@'.format(target))
1549   endif
1550
1551   actual_target_dirs += target
1552   config_target += keyval.load('configs/targets' / target + '.mak')
1553   config_target += { 'TARGET_' + config_target['TARGET_ARCH'].to_upper(): 'y' }
1554
1555   if 'TARGET_NEED_FDT' in config_target
1556     fdt_required += target
1557   endif
1558
1559   # Add default keys
1560   if 'TARGET_BASE_ARCH' not in config_target
1561     config_target += {'TARGET_BASE_ARCH': config_target['TARGET_ARCH']}
1562   endif
1563   if 'TARGET_ABI_DIR' not in config_target
1564     config_target += {'TARGET_ABI_DIR': config_target['TARGET_ARCH']}
1565   endif
1566
1567   foreach k, v: disassemblers
1568     if config_host['ARCH'].startswith(k) or config_target['TARGET_BASE_ARCH'].startswith(k)
1569       foreach sym: v
1570         config_target += { sym: 'y' }
1571         config_all_disas += { sym: 'y' }
1572       endforeach
1573     endif
1574   endforeach
1575
1576   config_target_data = configuration_data()
1577   foreach k, v: config_target
1578     if not k.startswith('TARGET_') and not k.startswith('CONFIG_')
1579       # do nothing
1580     elif ignored.contains(k)
1581       # do nothing
1582     elif k == 'TARGET_BASE_ARCH'
1583       # Note that TARGET_BASE_ARCH ends up in config-target.h but it is
1584       # not used to select files from sourcesets.
1585       config_target_data.set('TARGET_' + v.to_upper(), 1)
1586     elif k == 'TARGET_NAME' or k == 'CONFIG_QEMU_INTERP_PREFIX'
1587       config_target_data.set_quoted(k, v)
1588     elif v == 'y'
1589       config_target_data.set(k, 1)
1590     else
1591       config_target_data.set(k, v)
1592     endif
1593   endforeach
1594   config_target_h += {target: configure_file(output: target + '-config-target.h',
1595                                                configuration: config_target_data)}
1596
1597   if target.endswith('-softmmu')
1598     config_input = meson.get_external_property(target, 'default')
1599     config_devices_mak = target + '-config-devices.mak'
1600     config_devices_mak = configure_file(
1601       input: ['configs/devices' / target / config_input + '.mak', 'Kconfig'],
1602       output: config_devices_mak,
1603       depfile: config_devices_mak + '.d',
1604       capture: true,
1605       command: [minikconf,
1606                 get_option('default_devices') ? '--defconfig' : '--allnoconfig',
1607                 config_devices_mak, '@DEPFILE@', '@INPUT@',
1608                 host_kconfig, accel_kconfig,
1609                 'CONFIG_' + config_target['TARGET_ARCH'].to_upper() + '=y'])
1610
1611     config_devices_data = configuration_data()
1612     config_devices = keyval.load(config_devices_mak)
1613     foreach k, v: config_devices
1614       config_devices_data.set(k, 1)
1615     endforeach
1616     config_devices_mak_list += config_devices_mak
1617     config_devices_h += {target: configure_file(output: target + '-config-devices.h',
1618                                                 configuration: config_devices_data)}
1619     config_target += config_devices
1620     config_all_devices += config_devices
1621   endif
1622   config_target_mak += {target: config_target}
1623 endforeach
1624 target_dirs = actual_target_dirs
1625
1626 # This configuration is used to build files that are shared by
1627 # multiple binaries, and then extracted out of the "common"
1628 # static_library target.
1629 #
1630 # We do not use all_sources()/all_dependencies(), because it would
1631 # build literally all source files, including devices only used by
1632 # targets that are not built for this compilation.  The CONFIG_ALL
1633 # pseudo symbol replaces it.
1634
1635 config_all += config_all_devices
1636 config_all += config_host
1637 config_all += config_all_disas
1638 config_all += {
1639   'CONFIG_XEN': config_host.has_key('CONFIG_XEN_BACKEND'),
1640   'CONFIG_SOFTMMU': have_system,
1641   'CONFIG_USER_ONLY': have_user,
1642   'CONFIG_ALL': true,
1643 }
1644
1645 ##############
1646 # Submodules #
1647 ##############
1648
1649 capstone = not_found
1650 capstone_opt = get_option('capstone')
1651 if capstone_opt in ['enabled', 'auto', 'system']
1652   have_internal = fs.exists(meson.current_source_dir() / 'capstone/Makefile')
1653   capstone = dependency('capstone', version: '>=4.0',
1654                         kwargs: static_kwargs, method: 'pkg-config',
1655                         required: capstone_opt == 'system' or
1656                                   capstone_opt == 'enabled' and not have_internal)
1657   if capstone.found()
1658     capstone_opt = 'system'
1659   elif have_internal
1660     capstone_opt = 'internal'
1661   else
1662     capstone_opt = 'disabled'
1663   endif
1664 endif
1665 if capstone_opt == 'internal'
1666   capstone_data = configuration_data()
1667   capstone_data.set('CAPSTONE_USE_SYS_DYN_MEM', '1')
1668
1669   capstone_files = files(
1670     'capstone/cs.c',
1671     'capstone/MCInst.c',
1672     'capstone/MCInstrDesc.c',
1673     'capstone/MCRegisterInfo.c',
1674     'capstone/SStream.c',
1675     'capstone/utils.c'
1676   )
1677
1678   if 'CONFIG_ARM_DIS' in config_all_disas
1679     capstone_data.set('CAPSTONE_HAS_ARM', '1')
1680     capstone_files += files(
1681       'capstone/arch/ARM/ARMDisassembler.c',
1682       'capstone/arch/ARM/ARMInstPrinter.c',
1683       'capstone/arch/ARM/ARMMapping.c',
1684       'capstone/arch/ARM/ARMModule.c'
1685     )
1686   endif
1687
1688   # FIXME: This config entry currently depends on a c++ compiler.
1689   # Which is needed for building libvixl, but not for capstone.
1690   if 'CONFIG_ARM_A64_DIS' in config_all_disas
1691     capstone_data.set('CAPSTONE_HAS_ARM64', '1')
1692     capstone_files += files(
1693       'capstone/arch/AArch64/AArch64BaseInfo.c',
1694       'capstone/arch/AArch64/AArch64Disassembler.c',
1695       'capstone/arch/AArch64/AArch64InstPrinter.c',
1696       'capstone/arch/AArch64/AArch64Mapping.c',
1697       'capstone/arch/AArch64/AArch64Module.c'
1698     )
1699   endif
1700
1701   if 'CONFIG_PPC_DIS' in config_all_disas
1702     capstone_data.set('CAPSTONE_HAS_POWERPC', '1')
1703     capstone_files += files(
1704       'capstone/arch/PowerPC/PPCDisassembler.c',
1705       'capstone/arch/PowerPC/PPCInstPrinter.c',
1706       'capstone/arch/PowerPC/PPCMapping.c',
1707       'capstone/arch/PowerPC/PPCModule.c'
1708     )
1709   endif
1710
1711   if 'CONFIG_S390_DIS' in config_all_disas
1712     capstone_data.set('CAPSTONE_HAS_SYSZ', '1')
1713     capstone_files += files(
1714       'capstone/arch/SystemZ/SystemZDisassembler.c',
1715       'capstone/arch/SystemZ/SystemZInstPrinter.c',
1716       'capstone/arch/SystemZ/SystemZMapping.c',
1717       'capstone/arch/SystemZ/SystemZModule.c',
1718       'capstone/arch/SystemZ/SystemZMCTargetDesc.c'
1719     )
1720   endif
1721
1722   if 'CONFIG_I386_DIS' in config_all_disas
1723     capstone_data.set('CAPSTONE_HAS_X86', 1)
1724     capstone_files += files(
1725       'capstone/arch/X86/X86Disassembler.c',
1726       'capstone/arch/X86/X86DisassemblerDecoder.c',
1727       'capstone/arch/X86/X86ATTInstPrinter.c',
1728       'capstone/arch/X86/X86IntelInstPrinter.c',
1729       'capstone/arch/X86/X86InstPrinterCommon.c',
1730       'capstone/arch/X86/X86Mapping.c',
1731       'capstone/arch/X86/X86Module.c'
1732     )
1733   endif
1734
1735   configure_file(output: 'capstone-defs.h', configuration: capstone_data)
1736
1737   capstone_cargs = [
1738     # FIXME: There does not seem to be a way to completely replace the c_args
1739     # that come from add_project_arguments() -- we can only add to them.
1740     # So: disable all warnings with a big hammer.
1741     '-Wno-error', '-w',
1742
1743     # Include all configuration defines via a header file, which will wind up
1744     # as a dependency on the object file, and thus changes here will result
1745     # in a rebuild.
1746     '-include', 'capstone-defs.h'
1747   ]
1748
1749   libcapstone = static_library('capstone',
1750                                build_by_default: false,
1751                                sources: capstone_files,
1752                                c_args: capstone_cargs,
1753                                include_directories: 'capstone/include')
1754   capstone = declare_dependency(link_with: libcapstone,
1755                                 include_directories: 'capstone/include/capstone')
1756 endif
1757
1758 slirp = not_found
1759 slirp_opt = 'disabled'
1760 if have_system
1761   slirp_opt = get_option('slirp')
1762   if slirp_opt in ['enabled', 'auto', 'system']
1763     have_internal = fs.exists(meson.current_source_dir() / 'slirp/meson.build')
1764     slirp = dependency('slirp', kwargs: static_kwargs,
1765                        method: 'pkg-config',
1766                        required: slirp_opt == 'system' or
1767                                  slirp_opt == 'enabled' and not have_internal)
1768     if slirp.found()
1769       slirp_opt = 'system'
1770     elif have_internal
1771       slirp_opt = 'internal'
1772     else
1773       slirp_opt = 'disabled'
1774     endif
1775   endif
1776   if slirp_opt == 'internal'
1777     slirp_deps = []
1778     if targetos == 'windows'
1779       slirp_deps = cc.find_library('iphlpapi')
1780     endif
1781     slirp_conf = configuration_data()
1782     slirp_conf.set('SLIRP_MAJOR_VERSION', meson.project_version().split('.')[0])
1783     slirp_conf.set('SLIRP_MINOR_VERSION', meson.project_version().split('.')[1])
1784     slirp_conf.set('SLIRP_MICRO_VERSION', meson.project_version().split('.')[2])
1785     slirp_conf.set_quoted('SLIRP_VERSION_STRING', meson.project_version())
1786     slirp_cargs = ['-DG_LOG_DOMAIN="Slirp"']
1787     slirp_files = [
1788       'slirp/src/arp_table.c',
1789       'slirp/src/bootp.c',
1790       'slirp/src/cksum.c',
1791       'slirp/src/dhcpv6.c',
1792       'slirp/src/dnssearch.c',
1793       'slirp/src/if.c',
1794       'slirp/src/ip6_icmp.c',
1795       'slirp/src/ip6_input.c',
1796       'slirp/src/ip6_output.c',
1797       'slirp/src/ip_icmp.c',
1798       'slirp/src/ip_input.c',
1799       'slirp/src/ip_output.c',
1800       'slirp/src/mbuf.c',
1801       'slirp/src/misc.c',
1802       'slirp/src/ncsi.c',
1803       'slirp/src/ndp_table.c',
1804       'slirp/src/sbuf.c',
1805       'slirp/src/slirp.c',
1806       'slirp/src/socket.c',
1807       'slirp/src/state.c',
1808       'slirp/src/stream.c',
1809       'slirp/src/tcp_input.c',
1810       'slirp/src/tcp_output.c',
1811       'slirp/src/tcp_subr.c',
1812       'slirp/src/tcp_timer.c',
1813       'slirp/src/tftp.c',
1814       'slirp/src/udp.c',
1815       'slirp/src/udp6.c',
1816       'slirp/src/util.c',
1817       'slirp/src/version.c',
1818       'slirp/src/vmstate.c',
1819     ]
1820
1821     configure_file(
1822       input : 'slirp/src/libslirp-version.h.in',
1823       output : 'libslirp-version.h',
1824       configuration: slirp_conf)
1825
1826     slirp_inc = include_directories('slirp', 'slirp/src')
1827     libslirp = static_library('slirp',
1828                               build_by_default: false,
1829                               sources: slirp_files,
1830                               c_args: slirp_cargs,
1831                               include_directories: slirp_inc)
1832     slirp = declare_dependency(link_with: libslirp,
1833                                dependencies: slirp_deps,
1834                                include_directories: slirp_inc)
1835   endif
1836 endif
1837
1838 # For CFI, we need to compile slirp as a static library together with qemu.
1839 # This is because we register slirp functions as callbacks for QEMU Timers.
1840 # When using a system-wide shared libslirp, the type information for the
1841 # callback is missing and the timer call produces a false positive with CFI.
1842 #
1843 # Now that slirp_opt has been defined, check if the selected slirp is compatible
1844 # with control-flow integrity.
1845 if get_option('cfi') and slirp_opt == 'system'
1846   error('Control-Flow Integrity is not compatible with system-wide slirp.' \
1847          + ' Please configure with --enable-slirp=git')
1848 endif
1849
1850 fdt = not_found
1851 fdt_opt = get_option('fdt')
1852 if have_system
1853   if fdt_opt in ['enabled', 'auto', 'system']
1854     have_internal = fs.exists(meson.current_source_dir() / 'dtc/libfdt/Makefile.libfdt')
1855     fdt = cc.find_library('fdt', kwargs: static_kwargs,
1856                           required: fdt_opt == 'system' or
1857                                     fdt_opt == 'enabled' and not have_internal)
1858     if fdt.found() and cc.links('''
1859        #include <libfdt.h>
1860        #include <libfdt_env.h>
1861        int main(void) { fdt_check_full(NULL, 0); return 0; }''',
1862          dependencies: fdt)
1863       fdt_opt = 'system'
1864     elif have_internal
1865       fdt_opt = 'internal'
1866     else
1867       fdt_opt = 'disabled'
1868     endif
1869   endif
1870   if fdt_opt == 'internal'
1871     fdt_files = files(
1872       'dtc/libfdt/fdt.c',
1873       'dtc/libfdt/fdt_ro.c',
1874       'dtc/libfdt/fdt_wip.c',
1875       'dtc/libfdt/fdt_sw.c',
1876       'dtc/libfdt/fdt_rw.c',
1877       'dtc/libfdt/fdt_strerror.c',
1878       'dtc/libfdt/fdt_empty_tree.c',
1879       'dtc/libfdt/fdt_addresses.c',
1880       'dtc/libfdt/fdt_overlay.c',
1881       'dtc/libfdt/fdt_check.c',
1882     )
1883
1884     fdt_inc = include_directories('dtc/libfdt')
1885     libfdt = static_library('fdt',
1886                             build_by_default: false,
1887                             sources: fdt_files,
1888                             include_directories: fdt_inc)
1889     fdt = declare_dependency(link_with: libfdt,
1890                              include_directories: fdt_inc)
1891   endif
1892 endif
1893 if not fdt.found() and fdt_required.length() > 0
1894   error('fdt not available but required by targets ' + ', '.join(fdt_required))
1895 endif
1896
1897 config_host_data.set('CONFIG_CAPSTONE', capstone.found())
1898 config_host_data.set('CONFIG_FDT', fdt.found())
1899 config_host_data.set('CONFIG_SLIRP', slirp.found())
1900
1901 #####################
1902 # Generated sources #
1903 #####################
1904
1905 genh += configure_file(output: 'config-host.h', configuration: config_host_data)
1906
1907 hxtool = find_program('scripts/hxtool')
1908 shaderinclude = find_program('scripts/shaderinclude.pl')
1909 qapi_gen = find_program('scripts/qapi-gen.py')
1910 qapi_gen_depends = [ meson.source_root() / 'scripts/qapi/__init__.py',
1911                      meson.source_root() / 'scripts/qapi/commands.py',
1912                      meson.source_root() / 'scripts/qapi/common.py',
1913                      meson.source_root() / 'scripts/qapi/error.py',
1914                      meson.source_root() / 'scripts/qapi/events.py',
1915                      meson.source_root() / 'scripts/qapi/expr.py',
1916                      meson.source_root() / 'scripts/qapi/gen.py',
1917                      meson.source_root() / 'scripts/qapi/introspect.py',
1918                      meson.source_root() / 'scripts/qapi/parser.py',
1919                      meson.source_root() / 'scripts/qapi/schema.py',
1920                      meson.source_root() / 'scripts/qapi/source.py',
1921                      meson.source_root() / 'scripts/qapi/types.py',
1922                      meson.source_root() / 'scripts/qapi/visit.py',
1923                      meson.source_root() / 'scripts/qapi/common.py',
1924                      meson.source_root() / 'scripts/qapi-gen.py'
1925 ]
1926
1927 tracetool = [
1928   python, files('scripts/tracetool.py'),
1929    '--backend=' + config_host['TRACE_BACKENDS']
1930 ]
1931 tracetool_depends = files(
1932   'scripts/tracetool/backend/log.py',
1933   'scripts/tracetool/backend/__init__.py',
1934   'scripts/tracetool/backend/dtrace.py',
1935   'scripts/tracetool/backend/ftrace.py',
1936   'scripts/tracetool/backend/simple.py',
1937   'scripts/tracetool/backend/syslog.py',
1938   'scripts/tracetool/backend/ust.py',
1939   'scripts/tracetool/format/tcg_h.py',
1940   'scripts/tracetool/format/ust_events_c.py',
1941   'scripts/tracetool/format/ust_events_h.py',
1942   'scripts/tracetool/format/__init__.py',
1943   'scripts/tracetool/format/d.py',
1944   'scripts/tracetool/format/tcg_helper_c.py',
1945   'scripts/tracetool/format/simpletrace_stap.py',
1946   'scripts/tracetool/format/c.py',
1947   'scripts/tracetool/format/h.py',
1948   'scripts/tracetool/format/tcg_helper_h.py',
1949   'scripts/tracetool/format/log_stap.py',
1950   'scripts/tracetool/format/stap.py',
1951   'scripts/tracetool/format/tcg_helper_wrapper_h.py',
1952   'scripts/tracetool/__init__.py',
1953   'scripts/tracetool/transform.py',
1954   'scripts/tracetool/vcpu.py'
1955 )
1956
1957 qemu_version_cmd = [find_program('scripts/qemu-version.sh'),
1958                     meson.current_source_dir(),
1959                     config_host['PKGVERSION'], meson.project_version()]
1960 qemu_version = custom_target('qemu-version.h',
1961                              output: 'qemu-version.h',
1962                              command: qemu_version_cmd,
1963                              capture: true,
1964                              build_by_default: true,
1965                              build_always_stale: true)
1966 genh += qemu_version
1967
1968 hxdep = []
1969 hx_headers = [
1970   ['qemu-options.hx', 'qemu-options.def'],
1971   ['qemu-img-cmds.hx', 'qemu-img-cmds.h'],
1972 ]
1973 if have_system
1974   hx_headers += [
1975     ['hmp-commands.hx', 'hmp-commands.h'],
1976     ['hmp-commands-info.hx', 'hmp-commands-info.h'],
1977   ]
1978 endif
1979 foreach d : hx_headers
1980   hxdep += custom_target(d[1],
1981                 input: files(d[0]),
1982                 output: d[1],
1983                 capture: true,
1984                 build_by_default: true, # to be removed when added to a target
1985                 command: [hxtool, '-h', '@INPUT0@'])
1986 endforeach
1987 genh += hxdep
1988
1989 ###################
1990 # Collect sources #
1991 ###################
1992
1993 authz_ss = ss.source_set()
1994 blockdev_ss = ss.source_set()
1995 block_ss = ss.source_set()
1996 bsd_user_ss = ss.source_set()
1997 chardev_ss = ss.source_set()
1998 common_ss = ss.source_set()
1999 crypto_ss = ss.source_set()
2000 io_ss = ss.source_set()
2001 linux_user_ss = ss.source_set()
2002 qmp_ss = ss.source_set()
2003 qom_ss = ss.source_set()
2004 softmmu_ss = ss.source_set()
2005 specific_fuzz_ss = ss.source_set()
2006 specific_ss = ss.source_set()
2007 stub_ss = ss.source_set()
2008 trace_ss = ss.source_set()
2009 user_ss = ss.source_set()
2010 util_ss = ss.source_set()
2011
2012 # accel modules
2013 qtest_module_ss = ss.source_set()
2014 tcg_module_ss = ss.source_set()
2015
2016 modules = {}
2017 target_modules = {}
2018 hw_arch = {}
2019 target_arch = {}
2020 target_softmmu_arch = {}
2021 target_user_arch = {}
2022
2023 ###############
2024 # Trace files #
2025 ###############
2026
2027 # TODO: add each directory to the subdirs from its own meson.build, once
2028 # we have those
2029 trace_events_subdirs = [
2030   'crypto',
2031   'qapi',
2032   'qom',
2033   'monitor',
2034   'util',
2035 ]
2036 if have_user
2037   trace_events_subdirs += [ 'linux-user' ]
2038 endif
2039 if have_block
2040   trace_events_subdirs += [
2041     'authz',
2042     'block',
2043     'io',
2044     'nbd',
2045     'scsi',
2046   ]
2047 endif
2048 if have_system
2049   trace_events_subdirs += [
2050     'accel/kvm',
2051     'audio',
2052     'backends',
2053     'backends/tpm',
2054     'chardev',
2055     'ebpf',
2056     'hw/9pfs',
2057     'hw/acpi',
2058     'hw/adc',
2059     'hw/alpha',
2060     'hw/arm',
2061     'hw/audio',
2062     'hw/block',
2063     'hw/block/dataplane',
2064     'hw/char',
2065     'hw/display',
2066     'hw/dma',
2067     'hw/hppa',
2068     'hw/hyperv',
2069     'hw/i2c',
2070     'hw/i386',
2071     'hw/i386/xen',
2072     'hw/ide',
2073     'hw/input',
2074     'hw/intc',
2075     'hw/isa',
2076     'hw/mem',
2077     'hw/mips',
2078     'hw/misc',
2079     'hw/misc/macio',
2080     'hw/net',
2081     'hw/net/can',
2082     'hw/nvme',
2083     'hw/nvram',
2084     'hw/pci',
2085     'hw/pci-host',
2086     'hw/ppc',
2087     'hw/rdma',
2088     'hw/rdma/vmw',
2089     'hw/rtc',
2090     'hw/s390x',
2091     'hw/scsi',
2092     'hw/sd',
2093     'hw/sparc',
2094     'hw/sparc64',
2095     'hw/ssi',
2096     'hw/timer',
2097     'hw/tpm',
2098     'hw/usb',
2099     'hw/vfio',
2100     'hw/virtio',
2101     'hw/watchdog',
2102     'hw/xen',
2103     'hw/gpio',
2104     'migration',
2105     'net',
2106     'softmmu',
2107     'ui',
2108     'hw/remote',
2109   ]
2110 endif
2111 if have_system or have_user
2112   trace_events_subdirs += [
2113     'accel/tcg',
2114     'hw/core',
2115     'target/arm',
2116     'target/hppa',
2117     'target/i386',
2118     'target/i386/kvm',
2119     'target/mips/tcg',
2120     'target/ppc',
2121     'target/riscv',
2122     'target/s390x',
2123     'target/sparc',
2124   ]
2125 endif
2126
2127 vhost_user = not_found
2128 if 'CONFIG_VHOST_USER' in config_host
2129   libvhost_user = subproject('libvhost-user')
2130   vhost_user = libvhost_user.get_variable('vhost_user_dep')
2131 endif
2132
2133 subdir('qapi')
2134 subdir('qobject')
2135 subdir('stubs')
2136 subdir('trace')
2137 subdir('util')
2138 subdir('qom')
2139 subdir('authz')
2140 subdir('crypto')
2141 subdir('ui')
2142
2143
2144 if enable_modules
2145   libmodulecommon = static_library('module-common', files('module-common.c') + genh, pic: true, c_args: '-DBUILD_DSO')
2146   modulecommon = declare_dependency(link_whole: libmodulecommon, compile_args: '-DBUILD_DSO')
2147 endif
2148
2149 stub_ss = stub_ss.apply(config_all, strict: false)
2150
2151 util_ss.add_all(trace_ss)
2152 util_ss = util_ss.apply(config_all, strict: false)
2153 libqemuutil = static_library('qemuutil',
2154                              sources: util_ss.sources() + stub_ss.sources() + genh,
2155                              dependencies: [util_ss.dependencies(), libm, threads, glib, socket, malloc, pixman])
2156 qemuutil = declare_dependency(link_with: libqemuutil,
2157                               sources: genh + version_res)
2158
2159 if have_system or have_user
2160   decodetree = generator(find_program('scripts/decodetree.py'),
2161                          output: 'decode-@BASENAME@.c.inc',
2162                          arguments: ['@INPUT@', '@EXTRA_ARGS@', '-o', '@OUTPUT@'])
2163   subdir('libdecnumber')
2164   subdir('target')
2165 endif
2166
2167 subdir('audio')
2168 subdir('io')
2169 subdir('chardev')
2170 subdir('fsdev')
2171 subdir('dump')
2172
2173 if have_block
2174   block_ss.add(files(
2175     'block.c',
2176     'blockjob.c',
2177     'job.c',
2178     'qemu-io-cmds.c',
2179   ))
2180   block_ss.add(when: 'CONFIG_REPLICATION', if_true: files('replication.c'))
2181
2182   subdir('nbd')
2183   subdir('scsi')
2184   subdir('block')
2185
2186   blockdev_ss.add(files(
2187     'blockdev.c',
2188     'blockdev-nbd.c',
2189     'iothread.c',
2190     'job-qmp.c',
2191   ), gnutls)
2192
2193   # os-posix.c contains POSIX-specific functions used by qemu-storage-daemon,
2194   # os-win32.c does not
2195   blockdev_ss.add(when: 'CONFIG_POSIX', if_true: files('os-posix.c'))
2196   softmmu_ss.add(when: 'CONFIG_WIN32', if_true: [files('os-win32.c')])
2197 endif
2198
2199 common_ss.add(files('cpus-common.c'))
2200
2201 subdir('softmmu')
2202
2203 common_ss.add(capstone)
2204 specific_ss.add(files('cpu.c', 'disas.c', 'gdbstub.c'), capstone)
2205
2206 # Work around a gcc bug/misfeature wherein constant propagation looks
2207 # through an alias:
2208 #   https://gcc.gnu.org/bugzilla/show_bug.cgi?id=99696
2209 # to guess that a const variable is always zero.  Without lto, this is
2210 # impossible, as the alias is restricted to page-vary-common.c.  Indeed,
2211 # without lto, not even the alias is required -- we simply use different
2212 # declarations in different compilation units.
2213 pagevary = files('page-vary-common.c')
2214 if get_option('b_lto')
2215   pagevary_flags = ['-fno-lto']
2216   if get_option('cfi')
2217     pagevary_flags += '-fno-sanitize=cfi-icall'
2218   endif
2219   pagevary = static_library('page-vary-common', sources: pagevary,
2220                             c_args: pagevary_flags)
2221   pagevary = declare_dependency(link_with: pagevary)
2222 endif
2223 common_ss.add(pagevary)
2224 specific_ss.add(files('page-vary.c'))
2225
2226 subdir('backends')
2227 subdir('disas')
2228 subdir('migration')
2229 subdir('monitor')
2230 subdir('net')
2231 subdir('replay')
2232 subdir('semihosting')
2233 subdir('hw')
2234 subdir('tcg')
2235 subdir('fpu')
2236 subdir('accel')
2237 subdir('plugins')
2238 subdir('bsd-user')
2239 subdir('linux-user')
2240 subdir('ebpf')
2241
2242 common_ss.add(libbpf)
2243
2244 bsd_user_ss.add(files('gdbstub.c'))
2245 specific_ss.add_all(when: 'CONFIG_BSD_USER', if_true: bsd_user_ss)
2246
2247 linux_user_ss.add(files('gdbstub.c', 'thunk.c'))
2248 specific_ss.add_all(when: 'CONFIG_LINUX_USER', if_true: linux_user_ss)
2249
2250 # needed for fuzzing binaries
2251 subdir('tests/qtest/libqos')
2252 subdir('tests/qtest/fuzz')
2253
2254 # accel modules
2255 tcg_real_module_ss = ss.source_set()
2256 tcg_real_module_ss.add_all(when: 'CONFIG_TCG_MODULAR', if_true: tcg_module_ss)
2257 specific_ss.add_all(when: 'CONFIG_TCG_BUILTIN', if_true: tcg_module_ss)
2258 target_modules += { 'accel' : { 'qtest': qtest_module_ss,
2259                                 'tcg': tcg_real_module_ss }}
2260
2261 ########################
2262 # Library dependencies #
2263 ########################
2264
2265 modinfo_collect = find_program('scripts/modinfo-collect.py')
2266 modinfo_generate = find_program('scripts/modinfo-generate.py')
2267 modinfo_files = []
2268
2269 block_mods = []
2270 softmmu_mods = []
2271 foreach d, list : modules
2272   foreach m, module_ss : list
2273     if enable_modules and targetos != 'windows'
2274       module_ss = module_ss.apply(config_all, strict: false)
2275       sl = static_library(d + '-' + m, [genh, module_ss.sources()],
2276                           dependencies: [modulecommon, module_ss.dependencies()], pic: true)
2277       if d == 'block'
2278         block_mods += sl
2279       else
2280         softmmu_mods += sl
2281       endif
2282       if module_ss.sources() != []
2283         # FIXME: Should use sl.extract_all_objects(recursive: true) as
2284         # input. Sources can be used multiple times but objects are
2285         # unique when it comes to lookup in compile_commands.json.
2286         # Depnds on a mesion version with
2287         # https://github.com/mesonbuild/meson/pull/8900
2288         modinfo_files += custom_target(d + '-' + m + '.modinfo',
2289                                        output: d + '-' + m + '.modinfo',
2290                                        input: module_ss.sources(),
2291                                        capture: true,
2292                                        command: [modinfo_collect, '@INPUT@'])
2293       endif
2294     else
2295       if d == 'block'
2296         block_ss.add_all(module_ss)
2297       else
2298         softmmu_ss.add_all(module_ss)
2299       endif
2300     endif
2301   endforeach
2302 endforeach
2303
2304 foreach d, list : target_modules
2305   foreach m, module_ss : list
2306     if enable_modules and targetos != 'windows'
2307       foreach target : target_dirs
2308         if target.endswith('-softmmu')
2309           config_target = config_target_mak[target]
2310           config_target += config_host
2311           target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
2312           c_args = ['-DNEED_CPU_H',
2313                     '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
2314                     '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
2315           target_module_ss = module_ss.apply(config_target, strict: false)
2316           if target_module_ss.sources() != []
2317             module_name = d + '-' + m + '-' + config_target['TARGET_NAME']
2318             sl = static_library(module_name,
2319                                 [genh, target_module_ss.sources()],
2320                                 dependencies: [modulecommon, target_module_ss.dependencies()],
2321                                 include_directories: target_inc,
2322                                 c_args: c_args,
2323                                 pic: true)
2324             softmmu_mods += sl
2325             # FIXME: Should use sl.extract_all_objects(recursive: true) too.
2326             modinfo_files += custom_target(module_name + '.modinfo',
2327                                            output: module_name + '.modinfo',
2328                                            input: target_module_ss.sources(),
2329                                            capture: true,
2330                                            command: [modinfo_collect, '--target', target, '@INPUT@'])
2331           endif
2332         endif
2333       endforeach
2334     else
2335       specific_ss.add_all(module_ss)
2336     endif
2337   endforeach
2338 endforeach
2339
2340 if enable_modules
2341   modinfo_src = custom_target('modinfo.c',
2342                               output: 'modinfo.c',
2343                               input: modinfo_files,
2344                               command: [modinfo_generate, '@INPUT@'],
2345                               capture: true)
2346   modinfo_lib = static_library('modinfo', modinfo_src)
2347   modinfo_dep = declare_dependency(link_whole: modinfo_lib)
2348   softmmu_ss.add(modinfo_dep)
2349 endif
2350
2351 nm = find_program('nm')
2352 undefsym = find_program('scripts/undefsym.py')
2353 block_syms = custom_target('block.syms', output: 'block.syms',
2354                              input: [libqemuutil, block_mods],
2355                              capture: true,
2356                              command: [undefsym, nm, '@INPUT@'])
2357 qemu_syms = custom_target('qemu.syms', output: 'qemu.syms',
2358                              input: [libqemuutil, softmmu_mods],
2359                              capture: true,
2360                              command: [undefsym, nm, '@INPUT@'])
2361
2362 qom_ss = qom_ss.apply(config_host, strict: false)
2363 libqom = static_library('qom', qom_ss.sources() + genh,
2364                         dependencies: [qom_ss.dependencies()],
2365                         name_suffix: 'fa')
2366
2367 qom = declare_dependency(link_whole: libqom)
2368
2369 authz_ss = authz_ss.apply(config_host, strict: false)
2370 libauthz = static_library('authz', authz_ss.sources() + genh,
2371                           dependencies: [authz_ss.dependencies()],
2372                           name_suffix: 'fa',
2373                           build_by_default: false)
2374
2375 authz = declare_dependency(link_whole: libauthz,
2376                            dependencies: qom)
2377
2378 crypto_ss = crypto_ss.apply(config_host, strict: false)
2379 libcrypto = static_library('crypto', crypto_ss.sources() + genh,
2380                            dependencies: [crypto_ss.dependencies()],
2381                            name_suffix: 'fa',
2382                            build_by_default: false)
2383
2384 crypto = declare_dependency(link_whole: libcrypto,
2385                             dependencies: [authz, qom])
2386
2387 io_ss = io_ss.apply(config_host, strict: false)
2388 libio = static_library('io', io_ss.sources() + genh,
2389                        dependencies: [io_ss.dependencies()],
2390                        link_with: libqemuutil,
2391                        name_suffix: 'fa',
2392                        build_by_default: false)
2393
2394 io = declare_dependency(link_whole: libio, dependencies: [crypto, qom])
2395
2396 libmigration = static_library('migration', sources: migration_files + genh,
2397                               name_suffix: 'fa',
2398                               build_by_default: false)
2399 migration = declare_dependency(link_with: libmigration,
2400                                dependencies: [zlib, qom, io])
2401 softmmu_ss.add(migration)
2402
2403 block_ss = block_ss.apply(config_host, strict: false)
2404 libblock = static_library('block', block_ss.sources() + genh,
2405                           dependencies: block_ss.dependencies(),
2406                           link_depends: block_syms,
2407                           name_suffix: 'fa',
2408                           build_by_default: false)
2409
2410 block = declare_dependency(link_whole: [libblock],
2411                            link_args: '@block.syms',
2412                            dependencies: [crypto, io])
2413
2414 blockdev_ss = blockdev_ss.apply(config_host, strict: false)
2415 libblockdev = static_library('blockdev', blockdev_ss.sources() + genh,
2416                              dependencies: blockdev_ss.dependencies(),
2417                              name_suffix: 'fa',
2418                              build_by_default: false)
2419
2420 blockdev = declare_dependency(link_whole: [libblockdev],
2421                               dependencies: [block])
2422
2423 qmp_ss = qmp_ss.apply(config_host, strict: false)
2424 libqmp = static_library('qmp', qmp_ss.sources() + genh,
2425                         dependencies: qmp_ss.dependencies(),
2426                         name_suffix: 'fa',
2427                         build_by_default: false)
2428
2429 qmp = declare_dependency(link_whole: [libqmp])
2430
2431 libchardev = static_library('chardev', chardev_ss.sources() + genh,
2432                             name_suffix: 'fa',
2433                             dependencies: [gnutls],
2434                             build_by_default: false)
2435
2436 chardev = declare_dependency(link_whole: libchardev)
2437
2438 libhwcore = static_library('hwcore', sources: hwcore_files + genh,
2439                            name_suffix: 'fa',
2440                            build_by_default: false)
2441 hwcore = declare_dependency(link_whole: libhwcore)
2442 common_ss.add(hwcore)
2443
2444 ###########
2445 # Targets #
2446 ###########
2447
2448 foreach m : block_mods + softmmu_mods
2449   shared_module(m.name(),
2450                 name_prefix: '',
2451                 link_whole: m,
2452                 install: true,
2453                 install_dir: qemu_moddir)
2454 endforeach
2455
2456 softmmu_ss.add(authz, blockdev, chardev, crypto, io, qmp)
2457 common_ss.add(qom, qemuutil)
2458
2459 common_ss.add_all(when: 'CONFIG_SOFTMMU', if_true: [softmmu_ss])
2460 common_ss.add_all(when: 'CONFIG_USER_ONLY', if_true: user_ss)
2461
2462 common_all = common_ss.apply(config_all, strict: false)
2463 common_all = static_library('common',
2464                             build_by_default: false,
2465                             sources: common_all.sources() + genh,
2466                             implicit_include_directories: false,
2467                             dependencies: common_all.dependencies(),
2468                             name_suffix: 'fa')
2469
2470 feature_to_c = find_program('scripts/feature_to_c.sh')
2471
2472 emulators = {}
2473 foreach target : target_dirs
2474   config_target = config_target_mak[target]
2475   target_name = config_target['TARGET_NAME']
2476   arch = config_target['TARGET_BASE_ARCH']
2477   arch_srcs = [config_target_h[target]]
2478   arch_deps = []
2479   c_args = ['-DNEED_CPU_H',
2480             '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
2481             '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
2482   link_args = emulator_link_args
2483
2484   config_target += config_host
2485   target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
2486   if targetos == 'linux'
2487     target_inc += include_directories('linux-headers', is_system: true)
2488   endif
2489   if target.endswith('-softmmu')
2490     qemu_target_name = 'qemu-system-' + target_name
2491     target_type='system'
2492     t = target_softmmu_arch[arch].apply(config_target, strict: false)
2493     arch_srcs += t.sources()
2494     arch_deps += t.dependencies()
2495
2496     hw_dir = target_name == 'sparc64' ? 'sparc64' : arch
2497     hw = hw_arch[hw_dir].apply(config_target, strict: false)
2498     arch_srcs += hw.sources()
2499     arch_deps += hw.dependencies()
2500
2501     arch_srcs += config_devices_h[target]
2502     link_args += ['@block.syms', '@qemu.syms']
2503   else
2504     abi = config_target['TARGET_ABI_DIR']
2505     target_type='user'
2506     qemu_target_name = 'qemu-' + target_name
2507     if arch in target_user_arch
2508       t = target_user_arch[arch].apply(config_target, strict: false)
2509       arch_srcs += t.sources()
2510       arch_deps += t.dependencies()
2511     endif
2512     if 'CONFIG_LINUX_USER' in config_target
2513       base_dir = 'linux-user'
2514       target_inc += include_directories('linux-user/host/' / config_host['ARCH'])
2515     else
2516       base_dir = 'bsd-user'
2517       target_inc += include_directories('bsd-user/freebsd')
2518     endif
2519     target_inc += include_directories(
2520       base_dir,
2521       base_dir / abi,
2522     )
2523     if 'CONFIG_LINUX_USER' in config_target
2524       dir = base_dir / abi
2525       arch_srcs += files(dir / 'signal.c', dir / 'cpu_loop.c')
2526       if config_target.has_key('TARGET_SYSTBL_ABI')
2527         arch_srcs += \
2528           syscall_nr_generators[abi].process(base_dir / abi / config_target['TARGET_SYSTBL'],
2529                                              extra_args : config_target['TARGET_SYSTBL_ABI'])
2530       endif
2531     endif
2532   endif
2533
2534   if 'TARGET_XML_FILES' in config_target
2535     gdbstub_xml = custom_target(target + '-gdbstub-xml.c',
2536                                 output: target + '-gdbstub-xml.c',
2537                                 input: files(config_target['TARGET_XML_FILES'].split()),
2538                                 command: [feature_to_c, '@INPUT@'],
2539                                 capture: true)
2540     arch_srcs += gdbstub_xml
2541   endif
2542
2543   t = target_arch[arch].apply(config_target, strict: false)
2544   arch_srcs += t.sources()
2545   arch_deps += t.dependencies()
2546
2547   target_common = common_ss.apply(config_target, strict: false)
2548   objects = common_all.extract_objects(target_common.sources())
2549   deps = target_common.dependencies()
2550
2551   target_specific = specific_ss.apply(config_target, strict: false)
2552   arch_srcs += target_specific.sources()
2553   arch_deps += target_specific.dependencies()
2554
2555   lib = static_library('qemu-' + target,
2556                  sources: arch_srcs + genh,
2557                  dependencies: arch_deps,
2558                  objects: objects,
2559                  include_directories: target_inc,
2560                  c_args: c_args,
2561                  build_by_default: false,
2562                  name_suffix: 'fa')
2563
2564   if target.endswith('-softmmu')
2565     execs = [{
2566       'name': 'qemu-system-' + target_name,
2567       'gui': false,
2568       'sources': files('softmmu/main.c'),
2569       'dependencies': []
2570     }]
2571     if targetos == 'windows' and (sdl.found() or gtk.found())
2572       execs += [{
2573         'name': 'qemu-system-' + target_name + 'w',
2574         'gui': true,
2575         'sources': files('softmmu/main.c'),
2576         'dependencies': []
2577       }]
2578     endif
2579     if config_host.has_key('CONFIG_FUZZ')
2580       specific_fuzz = specific_fuzz_ss.apply(config_target, strict: false)
2581       execs += [{
2582         'name': 'qemu-fuzz-' + target_name,
2583         'gui': false,
2584         'sources': specific_fuzz.sources(),
2585         'dependencies': specific_fuzz.dependencies(),
2586       }]
2587     endif
2588   else
2589     execs = [{
2590       'name': 'qemu-' + target_name,
2591       'gui': false,
2592       'sources': [],
2593       'dependencies': []
2594     }]
2595   endif
2596   foreach exe: execs
2597     exe_name = exe['name']
2598     if targetos == 'darwin'
2599       exe_name += '-unsigned'
2600     endif
2601
2602     emulator = executable(exe_name, exe['sources'],
2603                install: true,
2604                c_args: c_args,
2605                dependencies: arch_deps + deps + exe['dependencies'],
2606                objects: lib.extract_all_objects(recursive: true),
2607                link_language: link_language,
2608                link_depends: [block_syms, qemu_syms] + exe.get('link_depends', []),
2609                link_args: link_args,
2610                gui_app: exe['gui'])
2611
2612     if targetos == 'darwin'
2613       icon = 'pc-bios/qemu.rsrc'
2614       build_input = [emulator, files(icon)]
2615       install_input = [
2616         get_option('bindir') / exe_name,
2617         meson.current_source_dir() / icon
2618       ]
2619       if 'CONFIG_HVF' in config_target
2620         entitlements = 'accel/hvf/entitlements.plist'
2621         build_input += files(entitlements)
2622         install_input += meson.current_source_dir() / entitlements
2623       endif
2624
2625       emulators += {exe['name'] : custom_target(exe['name'],
2626                    input: build_input,
2627                    output: exe['name'],
2628                    command: [
2629                      files('scripts/entitlement.sh'),
2630                      '@OUTPUT@',
2631                      '@INPUT@'
2632                    ])
2633       }
2634
2635       meson.add_install_script('scripts/entitlement.sh', '--install',
2636                                get_option('bindir') / exe['name'],
2637                                install_input)
2638     else
2639       emulators += {exe['name']: emulator}
2640     endif
2641
2642     if 'CONFIG_TRACE_SYSTEMTAP' in config_host
2643       foreach stp: [
2644         {'ext': '.stp-build', 'fmt': 'stap', 'bin': meson.current_build_dir() / exe['name'], 'install': false},
2645         {'ext': '.stp', 'fmt': 'stap', 'bin': get_option('prefix') / get_option('bindir') / exe['name'], 'install': true},
2646         {'ext': '-simpletrace.stp', 'fmt': 'simpletrace-stap', 'bin': '', 'install': true},
2647         {'ext': '-log.stp', 'fmt': 'log-stap', 'bin': '', 'install': true},
2648       ]
2649         custom_target(exe['name'] + stp['ext'],
2650                       input: trace_events_all,
2651                       output: exe['name'] + stp['ext'],
2652                       install: stp['install'],
2653                       install_dir: get_option('datadir') / 'systemtap/tapset',
2654                       command: [
2655                         tracetool, '--group=all', '--format=' + stp['fmt'],
2656                         '--binary=' + stp['bin'],
2657                         '--target-name=' + target_name,
2658                         '--target-type=' + target_type,
2659                         '--probe-prefix=qemu.' + target_type + '.' + target_name,
2660                         '@INPUT@', '@OUTPUT@'
2661                       ],
2662                       depend_files: tracetool_depends)
2663       endforeach
2664     endif
2665   endforeach
2666 endforeach
2667
2668 # Other build targets
2669
2670 if 'CONFIG_PLUGIN' in config_host
2671   install_headers('include/qemu/qemu-plugin.h')
2672 endif
2673
2674 if 'CONFIG_GUEST_AGENT' in config_host
2675   subdir('qga')
2676 elif get_option('guest_agent_msi').enabled()
2677   error('Guest agent MSI requested, but the guest agent is not being built')
2678 endif
2679
2680 # Don't build qemu-keymap if xkbcommon is not explicitly enabled
2681 # when we don't build tools or system
2682 if xkbcommon.found()
2683   # used for the update-keymaps target, so include rules even if !have_tools
2684   qemu_keymap = executable('qemu-keymap', files('qemu-keymap.c', 'ui/input-keymap.c') + genh,
2685                            dependencies: [qemuutil, xkbcommon], install: have_tools)
2686 endif
2687
2688 if have_tools
2689   qemu_img = executable('qemu-img', [files('qemu-img.c'), hxdep],
2690              dependencies: [authz, block, crypto, io, qom, qemuutil], install: true)
2691   qemu_io = executable('qemu-io', files('qemu-io.c'),
2692              dependencies: [block, qemuutil], install: true)
2693   qemu_nbd = executable('qemu-nbd', files('qemu-nbd.c'),
2694                dependencies: [blockdev, qemuutil, gnutls], install: true)
2695
2696   subdir('storage-daemon')
2697   subdir('contrib/rdmacm-mux')
2698   subdir('contrib/elf2dmp')
2699
2700   executable('qemu-edid', files('qemu-edid.c', 'hw/display/edid-generate.c'),
2701              dependencies: qemuutil,
2702              install: true)
2703
2704   if 'CONFIG_VHOST_USER' in config_host
2705     subdir('contrib/vhost-user-blk')
2706     subdir('contrib/vhost-user-gpu')
2707     subdir('contrib/vhost-user-input')
2708     subdir('contrib/vhost-user-scsi')
2709   endif
2710
2711   if targetos == 'linux'
2712     executable('qemu-bridge-helper', files('qemu-bridge-helper.c'),
2713                dependencies: [qemuutil, libcap_ng],
2714                install: true,
2715                install_dir: get_option('libexecdir'))
2716
2717     executable('qemu-pr-helper', files('scsi/qemu-pr-helper.c', 'scsi/utils.c'),
2718                dependencies: [authz, crypto, io, qom, qemuutil,
2719                               libcap_ng, mpathpersist],
2720                install: true)
2721   endif
2722
2723   if have_ivshmem
2724     subdir('contrib/ivshmem-client')
2725     subdir('contrib/ivshmem-server')
2726   endif
2727 endif
2728
2729 subdir('scripts')
2730 subdir('tools')
2731 subdir('pc-bios')
2732 subdir('docs')
2733 subdir('tests')
2734 if gtk.found()
2735   subdir('po')
2736 endif
2737
2738 if host_machine.system() == 'windows'
2739   nsis_cmd = [
2740     find_program('scripts/nsis.py'),
2741     '@OUTPUT@',
2742     get_option('prefix'),
2743     meson.current_source_dir(),
2744     host_machine.cpu(),
2745     '--',
2746     '-DDISPLAYVERSION=' + meson.project_version(),
2747   ]
2748   if build_docs
2749     nsis_cmd += '-DCONFIG_DOCUMENTATION=y'
2750   endif
2751   if gtk.found()
2752     nsis_cmd += '-DCONFIG_GTK=y'
2753   endif
2754
2755   nsis = custom_target('nsis',
2756                        output: 'qemu-setup-' + meson.project_version() + '.exe',
2757                        input: files('qemu.nsi'),
2758                        build_always_stale: true,
2759                        command: nsis_cmd + ['@INPUT@'])
2760   alias_target('installer', nsis)
2761 endif
2762
2763 #########################
2764 # Configuration summary #
2765 #########################
2766
2767 # Directories
2768 summary_info = {}
2769 summary_info += {'Install prefix':    get_option('prefix')}
2770 summary_info += {'BIOS directory':    qemu_datadir}
2771 summary_info += {'firmware path':     get_option('qemu_firmwarepath')}
2772 summary_info += {'binary directory':  get_option('bindir')}
2773 summary_info += {'library directory': get_option('libdir')}
2774 summary_info += {'module directory':  qemu_moddir}
2775 summary_info += {'libexec directory': get_option('libexecdir')}
2776 summary_info += {'include directory': get_option('includedir')}
2777 summary_info += {'config directory':  get_option('sysconfdir')}
2778 if targetos != 'windows'
2779   summary_info += {'local state directory': get_option('localstatedir')}
2780   summary_info += {'Manual directory':      get_option('mandir')}
2781 else
2782   summary_info += {'local state directory': 'queried at runtime'}
2783 endif
2784 summary_info += {'Doc directory':     get_option('docdir')}
2785 summary_info += {'Build directory':   meson.current_build_dir()}
2786 summary_info += {'Source path':       meson.current_source_dir()}
2787 summary_info += {'GIT submodules':    config_host['GIT_SUBMODULES']}
2788 summary(summary_info, bool_yn: true, section: 'Directories')
2789
2790 # Host binaries
2791 summary_info = {}
2792 summary_info += {'git':               config_host['GIT']}
2793 summary_info += {'make':              config_host['MAKE']}
2794 summary_info += {'python':            '@0@ (version: @1@)'.format(python.full_path(), python.language_version())}
2795 summary_info += {'sphinx-build':      sphinx_build.found()}
2796 if config_host.has_key('HAVE_GDB_BIN')
2797   summary_info += {'gdb':             config_host['HAVE_GDB_BIN']}
2798 endif
2799 summary_info += {'genisoimage':       config_host['GENISOIMAGE']}
2800 if targetos == 'windows' and config_host.has_key('CONFIG_GUEST_AGENT')
2801   summary_info += {'wixl':            wixl.found() ? wixl.full_path() : false}
2802 endif
2803 if slirp_opt != 'disabled' and 'CONFIG_SLIRP_SMBD' in config_host
2804   summary_info += {'smbd':            config_host['CONFIG_SMBD_COMMAND']}
2805 endif
2806 summary(summary_info, bool_yn: true, section: 'Host binaries')
2807
2808 # Configurable features
2809 summary_info = {}
2810 summary_info += {'Documentation':     build_docs}
2811 summary_info += {'system-mode emulation': have_system}
2812 summary_info += {'user-mode emulation': have_user}
2813 summary_info += {'block layer':       have_block}
2814 summary_info += {'Install blobs':     get_option('install_blobs')}
2815 summary_info += {'module support':    config_host.has_key('CONFIG_MODULES')}
2816 if config_host.has_key('CONFIG_MODULES')
2817   summary_info += {'alternative module path': config_host.has_key('CONFIG_MODULE_UPGRADES')}
2818 endif
2819 summary_info += {'plugin support':    config_host.has_key('CONFIG_PLUGIN')}
2820 summary_info += {'fuzzing support':   config_host.has_key('CONFIG_FUZZ')}
2821 if have_system
2822   summary_info += {'Audio drivers':     config_host['CONFIG_AUDIO_DRIVERS']}
2823 endif
2824 summary_info += {'Trace backends':    config_host['TRACE_BACKENDS']}
2825 if config_host['TRACE_BACKENDS'].split().contains('simple')
2826   summary_info += {'Trace output file': config_host['CONFIG_TRACE_FILE'] + '-<pid>'}
2827 endif
2828 summary_info += {'QOM debugging':     config_host.has_key('CONFIG_QOM_CAST_DEBUG')}
2829 summary_info += {'vhost-kernel support': config_host.has_key('CONFIG_VHOST_KERNEL')}
2830 summary_info += {'vhost-net support': config_host.has_key('CONFIG_VHOST_NET')}
2831 summary_info += {'vhost-crypto support': config_host.has_key('CONFIG_VHOST_CRYPTO')}
2832 summary_info += {'vhost-scsi support': config_host.has_key('CONFIG_VHOST_SCSI')}
2833 summary_info += {'vhost-vsock support': config_host.has_key('CONFIG_VHOST_VSOCK')}
2834 summary_info += {'vhost-user support': config_host.has_key('CONFIG_VHOST_USER')}
2835 summary_info += {'vhost-user-blk server support': have_vhost_user_blk_server}
2836 summary_info += {'vhost-user-fs support': config_host.has_key('CONFIG_VHOST_USER_FS')}
2837 summary_info += {'vhost-vdpa support': config_host.has_key('CONFIG_VHOST_VDPA')}
2838 summary_info += {'build guest agent': config_host.has_key('CONFIG_GUEST_AGENT')}
2839 summary(summary_info, bool_yn: true, section: 'Configurable features')
2840
2841 # Compilation information
2842 summary_info = {}
2843 summary_info += {'host CPU':          cpu}
2844 summary_info += {'host endianness':   build_machine.endian()}
2845 summary_info += {'C compiler':        ' '.join(meson.get_compiler('c').cmd_array())}
2846 summary_info += {'Host C compiler':   ' '.join(meson.get_compiler('c', native: true).cmd_array())}
2847 if link_language == 'cpp'
2848   summary_info += {'C++ compiler':    ' '.join(meson.get_compiler('cpp').cmd_array())}
2849 else
2850   summary_info += {'C++ compiler':      false}
2851 endif
2852 if targetos == 'darwin'
2853   summary_info += {'Objective-C compiler': ' '.join(meson.get_compiler('objc').cmd_array())}
2854 endif
2855 if targetos == 'windows'
2856   if 'WIN_SDK' in config_host
2857     summary_info += {'Windows SDK':   config_host['WIN_SDK']}
2858   endif
2859 endif
2860 summary_info += {'CFLAGS':            ' '.join(get_option('c_args')
2861                                                + ['-O' + get_option('optimization')]
2862                                                + (get_option('debug') ? ['-g'] : []))}
2863 if link_language == 'cpp'
2864   summary_info += {'CXXFLAGS':        ' '.join(get_option('cpp_args')
2865                                                + ['-O' + get_option('optimization')]
2866                                                + (get_option('debug') ? ['-g'] : []))}
2867 endif
2868 link_args = get_option(link_language + '_link_args')
2869 if link_args.length() > 0
2870   summary_info += {'LDFLAGS':         ' '.join(link_args)}
2871 endif
2872 summary_info += {'QEMU_CFLAGS':       config_host['QEMU_CFLAGS']}
2873 summary_info += {'QEMU_LDFLAGS':      config_host['QEMU_LDFLAGS']}
2874 summary_info += {'profiler':          config_host.has_key('CONFIG_PROFILER')}
2875 summary_info += {'link-time optimization (LTO)': get_option('b_lto')}
2876 summary_info += {'PIE':               get_option('b_pie')}
2877 summary_info += {'static build':      config_host.has_key('CONFIG_STATIC')}
2878 summary_info += {'malloc trim support': has_malloc_trim}
2879 summary_info += {'membarrier':        config_host.has_key('CONFIG_MEMBARRIER')}
2880 summary_info += {'debug stack usage': config_host.has_key('CONFIG_DEBUG_STACK_USAGE')}
2881 summary_info += {'mutex debugging':   config_host.has_key('CONFIG_DEBUG_MUTEX')}
2882 summary_info += {'memory allocator':  get_option('malloc')}
2883 summary_info += {'avx2 optimization': config_host.has_key('CONFIG_AVX2_OPT')}
2884 summary_info += {'avx512f optimization': config_host.has_key('CONFIG_AVX512F_OPT')}
2885 summary_info += {'gprof enabled':     config_host.has_key('CONFIG_GPROF')}
2886 summary_info += {'gcov':              get_option('b_coverage')}
2887 summary_info += {'thread sanitizer':  config_host.has_key('CONFIG_TSAN')}
2888 summary_info += {'CFI support':       get_option('cfi')}
2889 if get_option('cfi')
2890   summary_info += {'CFI debug support': get_option('cfi_debug')}
2891 endif
2892 summary_info += {'strip binaries':    get_option('strip')}
2893 summary_info += {'sparse':            sparse.found() ? sparse.full_path() : false}
2894 summary_info += {'mingw32 support':   targetos == 'windows'}
2895
2896 # snarf the cross-compilation information for tests
2897 foreach target: target_dirs
2898   tcg_mak = meson.current_build_dir() / 'tests/tcg' / 'config-' + target + '.mak'
2899   if fs.exists(tcg_mak)
2900     config_cross_tcg = keyval.load(tcg_mak)
2901     target = config_cross_tcg['TARGET_NAME']
2902     compiler = ''
2903     if 'DOCKER_CROSS_CC_GUEST' in config_cross_tcg
2904       summary_info += {target + ' tests': config_cross_tcg['DOCKER_CROSS_CC_GUEST'] +
2905                                           ' via ' + config_cross_tcg['DOCKER_IMAGE']}
2906     elif 'CROSS_CC_GUEST' in config_cross_tcg
2907       summary_info += {target + ' tests'
2908                                 : config_cross_tcg['CROSS_CC_GUEST'] }
2909     endif
2910    endif
2911 endforeach
2912
2913 summary(summary_info, bool_yn: true, section: 'Compilation')
2914
2915 # Targets and accelerators
2916 summary_info = {}
2917 if have_system
2918   summary_info += {'KVM support':       config_all.has_key('CONFIG_KVM')}
2919   summary_info += {'HAX support':       config_all.has_key('CONFIG_HAX')}
2920   summary_info += {'HVF support':       config_all.has_key('CONFIG_HVF')}
2921   summary_info += {'WHPX support':      config_all.has_key('CONFIG_WHPX')}
2922   summary_info += {'NVMM support':      config_all.has_key('CONFIG_NVMM')}
2923   summary_info += {'Xen support':       config_host.has_key('CONFIG_XEN_BACKEND')}
2924   if config_host.has_key('CONFIG_XEN_BACKEND')
2925     summary_info += {'xen ctrl version':  config_host['CONFIG_XEN_CTRL_INTERFACE_VERSION']}
2926   endif
2927 endif
2928 summary_info += {'TCG support':       config_all.has_key('CONFIG_TCG')}
2929 if config_all.has_key('CONFIG_TCG')
2930   if get_option('tcg_interpreter')
2931     summary_info += {'TCG backend':   'TCI (TCG with bytecode interpreter, experimental and slow)'}
2932   else
2933     summary_info += {'TCG backend':   'native (@0@)'.format(cpu)}
2934   endif
2935   summary_info += {'TCG debug enabled': config_host.has_key('CONFIG_DEBUG_TCG')}
2936 endif
2937 summary_info += {'target list':       ' '.join(target_dirs)}
2938 if have_system
2939   summary_info += {'default devices':   get_option('default_devices')}
2940   summary_info += {'out of process emulation': multiprocess_allowed}
2941 endif
2942 summary(summary_info, bool_yn: true, section: 'Targets and accelerators')
2943
2944 # Block layer
2945 summary_info = {}
2946 summary_info += {'coroutine backend': config_host['CONFIG_COROUTINE_BACKEND']}
2947 summary_info += {'coroutine pool':    config_host['CONFIG_COROUTINE_POOL'] == '1'}
2948 if have_block
2949   summary_info += {'Block whitelist (rw)': config_host['CONFIG_BDRV_RW_WHITELIST']}
2950   summary_info += {'Block whitelist (ro)': config_host['CONFIG_BDRV_RO_WHITELIST']}
2951   summary_info += {'VirtFS support':    have_virtfs}
2952   summary_info += {'build virtiofs daemon': have_virtiofsd}
2953   summary_info += {'Live block migration': config_host.has_key('CONFIG_LIVE_BLOCK_MIGRATION')}
2954   summary_info += {'replication support': config_host.has_key('CONFIG_REPLICATION')}
2955   summary_info += {'bochs support':     config_host.has_key('CONFIG_BOCHS')}
2956   summary_info += {'cloop support':     config_host.has_key('CONFIG_CLOOP')}
2957   summary_info += {'dmg support':       config_host.has_key('CONFIG_DMG')}
2958   summary_info += {'qcow v1 support':   config_host.has_key('CONFIG_QCOW1')}
2959   summary_info += {'vdi support':       config_host.has_key('CONFIG_VDI')}
2960   summary_info += {'vvfat support':     config_host.has_key('CONFIG_VVFAT')}
2961   summary_info += {'qed support':       config_host.has_key('CONFIG_QED')}
2962   summary_info += {'parallels support': config_host.has_key('CONFIG_PARALLELS')}
2963   summary_info += {'FUSE exports':      fuse.found()}
2964 endif
2965 summary(summary_info, bool_yn: true, section: 'Block layer support')
2966
2967 # Crypto
2968 summary_info = {}
2969 summary_info += {'TLS priority':      config_host['CONFIG_TLS_PRIORITY']}
2970 summary_info += {'GNUTLS support':    gnutls.found()}
2971 # TODO: add back version
2972 summary_info += {'libgcrypt':         gcrypt.found()}
2973 if gcrypt.found()
2974    summary_info += {'  XTS':             xts != 'private'}
2975 endif
2976 # TODO: add back version
2977 summary_info += {'nettle':            nettle.found()}
2978 if nettle.found()
2979    summary_info += {'  XTS':             xts != 'private'}
2980 endif
2981 summary_info += {'crypto afalg':      config_host.has_key('CONFIG_AF_ALG')}
2982 summary_info += {'rng-none':          config_host.has_key('CONFIG_RNG_NONE')}
2983 summary_info += {'Linux keyring':     config_host.has_key('CONFIG_SECRET_KEYRING')}
2984 summary(summary_info, bool_yn: true, section: 'Crypto')
2985
2986 # Libraries
2987 summary_info = {}
2988 if targetos == 'darwin'
2989   summary_info += {'Cocoa support':   cocoa.found()}
2990 endif
2991 # TODO: add back version
2992 summary_info += {'SDL support':       sdl.found()}
2993 summary_info += {'SDL image support': sdl_image.found()}
2994 # TODO: add back version
2995 summary_info += {'GTK support':       gtk.found()}
2996 summary_info += {'pixman':            pixman.found()}
2997 # TODO: add back version
2998 summary_info += {'VTE support':       vte.found()}
2999 # TODO: add back version
3000 summary_info += {'slirp support':     slirp_opt == 'disabled' ? false : slirp_opt}
3001 summary_info += {'libtasn1':          tasn1.found()}
3002 summary_info += {'PAM':               pam.found()}
3003 summary_info += {'iconv support':     iconv.found()}
3004 summary_info += {'curses support':    curses.found()}
3005 # TODO: add back version
3006 summary_info += {'virgl support':     virgl.found()}
3007 summary_info += {'curl support':      curl.found()}
3008 summary_info += {'Multipath support': mpathpersist.found()}
3009 summary_info += {'VNC support':       vnc.found()}
3010 if vnc.found()
3011   summary_info += {'VNC SASL support':  sasl.found()}
3012   summary_info += {'VNC JPEG support':  jpeg.found()}
3013   summary_info += {'VNC PNG support':   png.found()}
3014 endif
3015 summary_info += {'brlapi support':    brlapi.found()}
3016 summary_info += {'vde support':       config_host.has_key('CONFIG_VDE')}
3017 summary_info += {'netmap support':    config_host.has_key('CONFIG_NETMAP')}
3018 summary_info += {'Linux AIO support': config_host.has_key('CONFIG_LINUX_AIO')}
3019 summary_info += {'Linux io_uring support': linux_io_uring.found()}
3020 summary_info += {'ATTR/XATTR support': libattr.found()}
3021 summary_info += {'RDMA support':      config_host.has_key('CONFIG_RDMA')}
3022 summary_info += {'PVRDMA support':    config_host.has_key('CONFIG_PVRDMA')}
3023 summary_info += {'fdt support':       fdt_opt == 'disabled' ? false : fdt_opt}
3024 summary_info += {'libcap-ng support': libcap_ng.found()}
3025 summary_info += {'bpf support': libbpf.found()}
3026 # TODO: add back protocol and server version
3027 summary_info += {'spice support':     config_host.has_key('CONFIG_SPICE')}
3028 summary_info += {'rbd support':       rbd.found()}
3029 summary_info += {'xfsctl support':    config_host.has_key('CONFIG_XFS')}
3030 summary_info += {'smartcard support': cacard.found()}
3031 summary_info += {'U2F support':       u2f.found()}
3032 summary_info += {'libusb':            libusb.found()}
3033 summary_info += {'usb net redir':     usbredir.found()}
3034 summary_info += {'OpenGL support':    config_host.has_key('CONFIG_OPENGL')}
3035 summary_info += {'GBM':               config_host.has_key('CONFIG_GBM')}
3036 summary_info += {'libiscsi support':  libiscsi.found()}
3037 summary_info += {'libnfs support':    libnfs.found()}
3038 if targetos == 'windows'
3039   if config_host.has_key('CONFIG_GUEST_AGENT')
3040     summary_info += {'QGA VSS support':   config_host.has_key('CONFIG_QGA_VSS')}
3041     summary_info += {'QGA w32 disk info': config_host.has_key('CONFIG_QGA_NTDDSCSI')}
3042   endif
3043 endif
3044 summary_info += {'seccomp support':   seccomp.found()}
3045 summary_info += {'GlusterFS support': glusterfs.found()}
3046 summary_info += {'TPM support':       config_host.has_key('CONFIG_TPM')}
3047 summary_info += {'libssh support':    config_host.has_key('CONFIG_LIBSSH')}
3048 summary_info += {'lzo support':       lzo.found()}
3049 summary_info += {'snappy support':    snappy.found()}
3050 summary_info += {'bzip2 support':     libbzip2.found()}
3051 summary_info += {'lzfse support':     liblzfse.found()}
3052 summary_info += {'zstd support':      zstd.found()}
3053 summary_info += {'NUMA host support': config_host.has_key('CONFIG_NUMA')}
3054 summary_info += {'libxml2':           libxml2.found()}
3055 summary_info += {'capstone':          capstone_opt == 'disabled' ? false : capstone_opt}
3056 summary_info += {'libpmem support':   libpmem.found()}
3057 summary_info += {'libdaxctl support': libdaxctl.found()}
3058 summary_info += {'libudev':           libudev.found()}
3059 summary_info += {'FUSE lseek':        fuse_lseek.found()}
3060 summary(summary_info, bool_yn: true, section: 'Dependencies')
3061
3062 if not supported_cpus.contains(cpu)
3063   message()
3064   warning('SUPPORT FOR THIS HOST CPU WILL GO AWAY IN FUTURE RELEASES!')
3065   message()
3066   message('CPU host architecture ' + cpu + ' support is not currently maintained.')
3067   message('The QEMU project intends to remove support for this host CPU in')
3068   message('a future release if nobody volunteers to maintain it and to')
3069   message('provide a build host for our continuous integration setup.')
3070   message('configure has succeeded and you can continue to build, but')
3071   message('if you care about QEMU on this platform you should contact')
3072   message('us upstream at qemu-devel@nongnu.org.')
3073 endif
3074
3075 if not supported_oses.contains(targetos)
3076   message()
3077   warning('WARNING: SUPPORT FOR THIS HOST OS WILL GO AWAY IN FUTURE RELEASES!')
3078   message()
3079   message('Host OS ' + targetos + 'support is not currently maintained.')
3080   message('The QEMU project intends to remove support for this host OS in')
3081   message('a future release if nobody volunteers to maintain it and to')
3082   message('provide a build host for our continuous integration setup.')
3083   message('configure has succeeded and you can continue to build, but')
3084   message('if you care about QEMU on this platform you should contact')
3085   message('us upstream at qemu-devel@nongnu.org.')
3086 endif