meson.build

   1 project('qemu', ['c'], meson_version: '>=0.55.0',
   2         default_options: ['warning_level=1', 'c_std=gnu11', 'cpp_std=gnu++11', 'b_colorout=auto'] +
   3                          (meson.version().version_compare('>=0.56.0') ? [ 'b_staticpic=false' ] : []),
   4         version: run_command('head', meson.source_root() / 'VERSION').stdout().strip())
   5
   6 not_found = dependency('', required: false)
   7 if meson.version().version_compare('>=0.56.0')
   8   keyval = import('keyval')
   9 else
  10   keyval = import('unstable-keyval')
  11 endif
  12 ss = import('sourceset')
  13 fs = import('fs')
  14
  15 sh = find_program('sh')
  16 cc = meson.get_compiler('c')
  17 config_host = keyval.load(meson.current_build_dir() / 'config-host.mak')
  18 enable_modules = 'CONFIG_MODULES' in config_host
  19 enable_static = 'CONFIG_STATIC' in config_host
  20
  21 # Allow both shared and static libraries unless --enable-static
  22 static_kwargs = enable_static ? {'static': true} : {}
  23
  24 # Temporary directory used for files created while
  25 # configure runs. Since it is in the build directory
  26 # we can safely blow away any previous version of it
  27 # (and we need not jump through hoops to try to delete
  28 # it when configure exits.)
  29 tmpdir = meson.current_build_dir() / 'meson-private/temp'
  30
  31 if get_option('qemu_suffix').startswith('/')
  32   error('qemu_suffix cannot start with a /')
  33 endif
  34
  35 qemu_confdir = get_option('sysconfdir') / get_option('qemu_suffix')
  36 qemu_datadir = get_option('datadir') / get_option('qemu_suffix')
  37 qemu_docdir = get_option('docdir') / get_option('qemu_suffix')
  38 qemu_moddir = get_option('libdir') / get_option('qemu_suffix')
  39
  40 qemu_desktopdir = get_option('datadir') / 'applications'
  41 qemu_icondir = get_option('datadir') / 'icons'
  42
  43 config_host_data = configuration_data()
  44 genh = []
  45
  46 target_dirs = config_host['TARGET_DIRS'].split()
  47 have_user = false
  48 have_system = false
  49 foreach target : target_dirs
  50   have_user = have_user or target.endswith('-user')
  51   have_system = have_system or target.endswith('-softmmu')
  52 endforeach
  53 have_tools = 'CONFIG_TOOLS' in config_host
  54 have_block = have_system or have_tools
  55
  56 python = import('python').find_installation()
  57
  58 supported_oses = ['windows', 'freebsd', 'netbsd', 'openbsd', 'darwin', 'sunos', 'linux']
  59 supported_cpus = ['ppc', 'ppc64', 's390x', 'riscv32', 'riscv64', 'x86', 'x86_64',
  60   'arm', 'aarch64', 'mips', 'mips64', 'sparc', 'sparc64']
  61
  62 cpu = host_machine.cpu_family()
  63 targetos = host_machine.system()
  64
  65 if cpu in ['x86', 'x86_64']
  66   kvm_targets = ['i386-softmmu', 'x86_64-softmmu']
  67 elif cpu == 'aarch64'
  68   kvm_targets = ['aarch64-softmmu']
  69 elif cpu == 's390x'
  70   kvm_targets = ['s390x-softmmu']
  71 elif cpu in ['ppc', 'ppc64']
  72   kvm_targets = ['ppc-softmmu', 'ppc64-softmmu']
  73 elif cpu in ['mips', 'mips64']
  74   kvm_targets = ['mips-softmmu', 'mipsel-softmmu', 'mips64-softmmu', 'mips64el-softmmu']
  75 else
  76   kvm_targets = []
  77 endif
  78
  79 accelerator_targets = { 'CONFIG_KVM': kvm_targets }
  80 if cpu in ['x86', 'x86_64', 'arm', 'aarch64']
  81   # i368 emulator provides xenpv machine type for multiple architectures
  82   accelerator_targets += {
  83     'CONFIG_XEN': ['i386-softmmu', 'x86_64-softmmu'],
  84   }
  85 endif
  86 if cpu in ['x86', 'x86_64']
  87   accelerator_targets += {
  88     'CONFIG_HAX': ['i386-softmmu', 'x86_64-softmmu'],
  89     'CONFIG_HVF': ['x86_64-softmmu'],
  90     'CONFIG_NVMM': ['i386-softmmu', 'x86_64-softmmu'],
  91     'CONFIG_WHPX': ['i386-softmmu', 'x86_64-softmmu'],
  92   }
  93 endif
  94
  95 modular_tcg = ['i386-softmmu', 'x86_64-softmmu']
  96
  97 edk2_targets = [ 'arm-softmmu', 'aarch64-softmmu', 'i386-softmmu', 'x86_64-softmmu' ]
  98 install_edk2_blobs = false
  99 if get_option('install_blobs')
 100   foreach target : target_dirs
 101     install_edk2_blobs = install_edk2_blobs or target in edk2_targets
 102   endforeach
 103 endif
 104
 105 bzip2 = find_program('bzip2', required: install_edk2_blobs)
 106
 107 ##################
 108 # Compiler flags #
 109 ##################
 110
 111 # Specify linker-script with add_project_link_arguments so that it is not placed
 112 # within a linker --start-group/--end-group pair
 113 if 'CONFIG_FUZZ' in config_host
 114    add_project_link_arguments(['-Wl,-T,',
 115                                (meson.current_source_dir() / 'tests/qtest/fuzz/fork_fuzz.ld')],
 116                               native: false, language: ['c', 'cpp', 'objc'])
 117 endif
 118
 119 add_global_arguments(config_host['QEMU_CFLAGS'].split(),
 120                      native: false, language: ['c', 'objc'])
 121 add_global_arguments(config_host['QEMU_CXXFLAGS'].split(),
 122                      native: false, language: 'cpp')
 123 add_global_link_arguments(config_host['QEMU_LDFLAGS'].split(),
 124                           native: false, language: ['c', 'cpp', 'objc'])
 125
 126 if targetos == 'linux'
 127   add_project_arguments('-isystem', meson.current_source_dir() / 'linux-headers',
 128                         '-isystem', 'linux-headers',
 129                         language: ['c', 'cpp'])
 130 endif
 131
 132 add_project_arguments('-iquote', '.',
 133                       '-iquote', meson.current_source_dir(),
 134                       '-iquote', meson.current_source_dir() / 'include',
 135                       '-iquote', meson.current_source_dir() / 'disas/libvixl',
 136                       language: ['c', 'cpp', 'objc'])
 137
 138 link_language = meson.get_external_property('link_language', 'cpp')
 139 if link_language == 'cpp'
 140   add_languages('cpp', required: true, native: false)
 141 endif
 142 if host_machine.system() == 'darwin'
 143   add_languages('objc', required: false, native: false)
 144 endif
 145
 146 sparse = find_program('cgcc', required: get_option('sparse'))
 147 if sparse.found()
 148   run_target('sparse',
 149              command: [find_program('scripts/check_sparse.py'),
 150                        'compile_commands.json', sparse.full_path(), '-Wbitwise',
 151                        '-Wno-transparent-union', '-Wno-old-initializer',
 152                        '-Wno-non-pointer-null'])
 153 endif
 154
 155 ###########################################
 156 # Target-specific checks and dependencies #
 157 ###########################################
 158
 159 if targetos != 'linux' and get_option('mpath').enabled()
 160   error('Multipath is supported only on Linux')
 161 endif
 162
 163 if targetos != 'linux' and get_option('multiprocess').enabled()
 164   error('Multiprocess QEMU is supported only on Linux')
 165 endif
 166 multiprocess_allowed = targetos == 'linux' and not get_option('multiprocess').disabled()
 167
 168 libm = cc.find_library('m', required: false)
 169 threads = dependency('threads')
 170 util = cc.find_library('util', required: false)
 171 winmm = []
 172 socket = []
 173 version_res = []
 174 coref = []
 175 iokit = []
 176 emulator_link_args = []
 177 nvmm =not_found
 178 hvf = not_found
 179 if targetos == 'windows'
 180   socket = cc.find_library('ws2_32')
 181   winmm = cc.find_library('winmm')
 182
 183   win = import('windows')
 184   version_res = win.compile_resources('version.rc',
 185                                       depend_files: files('pc-bios/qemu-nsis.ico'),
 186                                       include_directories: include_directories('.'))
 187 elif targetos == 'darwin'
 188   coref = dependency('appleframeworks', modules: 'CoreFoundation')
 189   iokit = dependency('appleframeworks', modules: 'IOKit', required: false)
 190 elif targetos == 'sunos'
 191   socket = [cc.find_library('socket'),
 192             cc.find_library('nsl'),
 193             cc.find_library('resolv')]
 194 elif targetos == 'haiku'
 195   socket = [cc.find_library('posix_error_mapper'),
 196             cc.find_library('network'),
 197             cc.find_library('bsd')]
 198 elif targetos == 'openbsd'
 199   if not get_option('tcg').disabled() and target_dirs.length() > 0
 200     # Disable OpenBSD W^X if available
 201     emulator_link_args = cc.get_supported_link_arguments('-Wl,-z,wxneeded')
 202   endif
 203 endif
 204
 205 accelerators = []
 206 if not get_option('kvm').disabled() and targetos == 'linux'
 207   accelerators += 'CONFIG_KVM'
 208 endif
 209 if not get_option('xen').disabled() and 'CONFIG_XEN_BACKEND' in config_host
 210   accelerators += 'CONFIG_XEN'
 211   have_xen_pci_passthrough = not get_option('xen_pci_passthrough').disabled() and targetos == 'linux'
 212 else
 213   have_xen_pci_passthrough = false
 214 endif
 215 if not get_option('whpx').disabled() and targetos == 'windows'
 216   if get_option('whpx').enabled() and host_machine.cpu() != 'x86_64'
 217     error('WHPX requires 64-bit host')
 218   elif cc.has_header('WinHvPlatform.h', required: get_option('whpx')) and \
 219        cc.has_header('WinHvEmulation.h', required: get_option('whpx'))
 220     accelerators += 'CONFIG_WHPX'
 221   endif
 222 endif
 223 if not get_option('hvf').disabled()
 224   hvf = dependency('appleframeworks', modules: 'Hypervisor',
 225                    required: get_option('hvf'))
 226   if hvf.found()
 227     accelerators += 'CONFIG_HVF'
 228   endif
 229 endif
 230 if not get_option('hax').disabled()
 231   if get_option('hax').enabled() or targetos in ['windows', 'darwin', 'netbsd']
 232     accelerators += 'CONFIG_HAX'
 233   endif
 234 endif
 235 if targetos == 'netbsd'
 236   if cc.has_header_symbol('nvmm.h', 'nvmm_cpu_stop', required: get_option('nvmm'))
 237     nvmm = cc.find_library('nvmm', required: get_option('nvmm'))
 238   endif
 239   if nvmm.found()
 240     accelerators += 'CONFIG_NVMM'
 241   endif
 242 endif
 243
 244 tcg_arch = config_host['ARCH']
 245 if not get_option('tcg').disabled()
 246   if cpu not in supported_cpus
 247     if get_option('tcg_interpreter')
 248       warning('Unsupported CPU @0@, will use TCG with TCI (experimental and slow)'.format(cpu))
 249     else
 250       error('Unsupported CPU @0@, try --enable-tcg-interpreter'.format(cpu))
 251     endif
 252   elif get_option('tcg_interpreter')
 253     warning('Use of the TCG interpretor is not recommended on this host')
 254     warning('architecture. There is a native TCG execution backend available')
 255     warning('which provides substantially better performance and reliability.')
 256     warning('It is strongly recommended to remove the --enable-tcg-interpreter')
 257     warning('configuration option on this architecture to use the native')
 258     warning('backend.')
 259   endif
 260   if get_option('tcg_interpreter')
 261     tcg_arch = 'tci'
 262   elif config_host['ARCH'] == 'sparc64'
 263     tcg_arch = 'sparc'
 264   elif config_host['ARCH'] == 's390x'
 265     tcg_arch = 's390'
 266   elif config_host['ARCH'] in ['x86_64', 'x32']
 267     tcg_arch = 'i386'
 268   elif config_host['ARCH'] == 'ppc64'
 269     tcg_arch = 'ppc'
 270   elif config_host['ARCH'] in ['riscv32', 'riscv64']
 271     tcg_arch = 'riscv'
 272   endif
 273   add_project_arguments('-iquote', meson.current_source_dir() / 'tcg' / tcg_arch,
 274                         language: ['c', 'cpp', 'objc'])
 275
 276   accelerators += 'CONFIG_TCG'
 277   config_host += { 'CONFIG_TCG': 'y' }
 278 endif
 279
 280 if 'CONFIG_KVM' not in accelerators and get_option('kvm').enabled()
 281   error('KVM not available on this platform')
 282 endif
 283 if 'CONFIG_HVF' not in accelerators and get_option('hvf').enabled()
 284   error('HVF not available on this platform')
 285 endif
 286 if 'CONFIG_NVMM' not in accelerators and get_option('nvmm').enabled()
 287   error('NVMM not available on this platform')
 288 endif
 289 if 'CONFIG_WHPX' not in accelerators and get_option('whpx').enabled()
 290   error('WHPX not available on this platform')
 291 endif
 292 if not have_xen_pci_passthrough and get_option('xen_pci_passthrough').enabled()
 293   if 'CONFIG_XEN' in accelerators
 294     error('Xen PCI passthrough not available on this platform')
 295   else
 296     error('Xen PCI passthrough requested but Xen not enabled')
 297   endif
 298 endif
 299
 300 ################
 301 # Dependencies #
 302 ################
 303
 304 # The path to glib.h is added to all compilation commands.  This was
 305 # grandfathered in from the QEMU Makefiles.
 306 add_project_arguments(config_host['GLIB_CFLAGS'].split(),
 307                       native: false, language: ['c', 'cpp', 'objc'])
 308 glib = declare_dependency(compile_args: config_host['GLIB_CFLAGS'].split(),
 309                           link_args: config_host['GLIB_LIBS'].split())
 310 # override glib dep with the configure results (for subprojects)
 311 meson.override_dependency('glib-2.0', glib)
 312
 313 gio = not_found
 314 if 'CONFIG_GIO' in config_host
 315   gio = declare_dependency(compile_args: config_host['GIO_CFLAGS'].split(),
 316                            link_args: config_host['GIO_LIBS'].split())
 317 endif
 318 lttng = not_found
 319 if 'CONFIG_TRACE_UST' in config_host
 320   lttng = declare_dependency(link_args: config_host['LTTNG_UST_LIBS'].split())
 321 endif
 322 pixman = not_found
 323 if have_system or have_tools
 324   pixman = dependency('pixman-1', required: have_system, version:'>=0.21.8',
 325                       method: 'pkg-config', kwargs: static_kwargs)
 326 endif
 327 libaio = cc.find_library('aio', required: false)
 328 zlib = dependency('zlib', required: true, kwargs: static_kwargs)
 329
 330 linux_io_uring = not_found
 331 if not get_option('linux_io_uring').auto() or have_block
 332   linux_io_uring = dependency('liburing', required: get_option('linux_io_uring'),
 333                               method: 'pkg-config', kwargs: static_kwargs)
 334 endif
 335 libxml2 = not_found
 336 if not get_option('libxml2').auto() or have_block
 337   libxml2 = dependency('libxml-2.0', required: get_option('libxml2'),
 338                        method: 'pkg-config', kwargs: static_kwargs)
 339 endif
 340 libnfs = not_found
 341 if not get_option('libnfs').auto() or have_block
 342   libnfs = dependency('libnfs', version: '>=1.9.3',
 343                       required: get_option('libnfs'),
 344                       method: 'pkg-config', kwargs: static_kwargs)
 345 endif
 346
 347 libattr_test = '''
 348   #include <stddef.h>
 349   #include <sys/types.h>
 350   #ifdef CONFIG_LIBATTR
 351   #include <attr/xattr.h>
 352   #else
 353   #include <sys/xattr.h>
 354   #endif
 355   int main(void) { getxattr(NULL, NULL, NULL, 0); setxattr(NULL, NULL, NULL, 0, 0); return 0; }'''
 356
 357 libattr = not_found
 358 have_old_libattr = false
 359 if not get_option('attr').disabled()
 360   if cc.links(libattr_test)
 361     libattr = declare_dependency()
 362   else
 363     libattr = cc.find_library('attr', has_headers: ['attr/xattr.h'],
 364                               required: get_option('attr'),
 365                               kwargs: static_kwargs)
 366     if libattr.found() and not \
 367       cc.links(libattr_test, dependencies: libattr, args: '-DCONFIG_LIBATTR')
 368       libattr = not_found
 369       if get_option('attr').enabled()
 370         error('could not link libattr')
 371       else
 372         warning('could not link libattr, disabling')
 373       endif
 374     else
 375       have_old_libattr = libattr.found()
 376     endif
 377   endif
 378 endif
 379
 380 cocoa = dependency('appleframeworks', modules: 'Cocoa', required: get_option('cocoa'))
 381 if cocoa.found() and get_option('sdl').enabled()
 382   error('Cocoa and SDL cannot be enabled at the same time')
 383 endif
 384 if cocoa.found() and get_option('gtk').enabled()
 385   error('Cocoa and GTK+ cannot be enabled at the same time')
 386 endif
 387
 388 seccomp = not_found
 389 if not get_option('seccomp').auto() or have_system or have_tools
 390   seccomp = dependency('libseccomp', version: '>=2.3.0',
 391                        required: get_option('seccomp'),
 392                        method: 'pkg-config', kwargs: static_kwargs)
 393 endif
 394
 395 libcap_ng = not_found
 396 if not get_option('cap_ng').auto() or have_system or have_tools
 397   libcap_ng = cc.find_library('cap-ng', has_headers: ['cap-ng.h'],
 398                               required: get_option('cap_ng'),
 399                               kwargs: static_kwargs)
 400 endif
 401 if libcap_ng.found() and not cc.links('''
 402    #include <cap-ng.h>
 403    int main(void)
 404    {
 405      capng_capability_to_name(CAPNG_EFFECTIVE);
 406      return 0;
 407    }''', dependencies: libcap_ng)
 408   libcap_ng = not_found
 409   if get_option('cap_ng').enabled()
 410     error('could not link libcap-ng')
 411   else
 412     warning('could not link libcap-ng, disabling')
 413   endif
 414 endif
 415
 416 if get_option('xkbcommon').auto() and not have_system and not have_tools
 417   xkbcommon = not_found
 418 else
 419   xkbcommon = dependency('xkbcommon', required: get_option('xkbcommon'),
 420                          method: 'pkg-config', kwargs: static_kwargs)
 421 endif
 422 vde = not_found
 423 if config_host.has_key('CONFIG_VDE')
 424   vde = declare_dependency(link_args: config_host['VDE_LIBS'].split())
 425 endif
 426 pulse = not_found
 427 if 'CONFIG_LIBPULSE' in config_host
 428   pulse = declare_dependency(compile_args: config_host['PULSE_CFLAGS'].split(),
 429                              link_args: config_host['PULSE_LIBS'].split())
 430 endif
 431 alsa = not_found
 432 if 'CONFIG_ALSA' in config_host
 433   alsa = declare_dependency(compile_args: config_host['ALSA_CFLAGS'].split(),
 434                             link_args: config_host['ALSA_LIBS'].split())
 435 endif
 436 jack = not_found
 437 if 'CONFIG_LIBJACK' in config_host
 438   jack = declare_dependency(link_args: config_host['JACK_LIBS'].split())
 439 endif
 440 spice = not_found
 441 spice_headers = not_found
 442 spice_protocol = not_found
 443 if 'CONFIG_SPICE' in config_host
 444   spice = declare_dependency(compile_args: config_host['SPICE_CFLAGS'].split(),
 445                              link_args: config_host['SPICE_LIBS'].split())
 446   spice_headers = declare_dependency(compile_args: config_host['SPICE_CFLAGS'].split())
 447 endif
 448 if 'CONFIG_SPICE_PROTOCOL' in config_host
 449   spice_protocol = declare_dependency(compile_args: config_host['SPICE_PROTOCOL_CFLAGS'].split())
 450 endif
 451 rt = cc.find_library('rt', required: false)
 452 libdl = not_found
 453 if 'CONFIG_PLUGIN' in config_host
 454   libdl = cc.find_library('dl', required: true)
 455 endif
 456 libiscsi = not_found
 457 if not get_option('libiscsi').auto() or have_block
 458   libiscsi = dependency('libiscsi', version: '>=1.9.0',
 459                          required: get_option('libiscsi'),
 460                          method: 'pkg-config', kwargs: static_kwargs)
 461 endif
 462 zstd = not_found
 463 if not get_option('zstd').auto() or have_block
 464   zstd = dependency('libzstd', version: '>=1.4.0',
 465                     required: get_option('zstd'),
 466                     method: 'pkg-config', kwargs: static_kwargs)
 467 endif
 468 gbm = not_found
 469 if 'CONFIG_GBM' in config_host
 470   gbm = declare_dependency(compile_args: config_host['GBM_CFLAGS'].split(),
 471                            link_args: config_host['GBM_LIBS'].split())
 472 endif
 473 virgl = not_found
 474 if not get_option('virglrenderer').auto() or have_system
 475   virgl = dependency('virglrenderer',
 476                      method: 'pkg-config',
 477                      required: get_option('virglrenderer'),
 478                      kwargs: static_kwargs)
 479 endif
 480 curl = not_found
 481 if not get_option('curl').auto() or have_block
 482   curl = dependency('libcurl', version: '>=7.29.0',
 483                     method: 'pkg-config',
 484                     required: get_option('curl'),
 485                     kwargs: static_kwargs)
 486 endif
 487 libudev = not_found
 488 if targetos == 'linux' and (have_system or have_tools)
 489   libudev = dependency('libudev',
 490                        method: 'pkg-config',
 491                        required: get_option('libudev'),
 492                        kwargs: static_kwargs)
 493 endif
 494
 495 mpathlibs = [libudev]
 496 mpathpersist = not_found
 497 mpathpersist_new_api = false
 498 if targetos == 'linux' and have_tools and not get_option('mpath').disabled()
 499   mpath_test_source_new = '''
 500     #include <libudev.h>
 501     #include <mpath_persist.h>
 502     unsigned mpath_mx_alloc_len = 1024;
 503     int logsink;
 504     static struct config *multipath_conf;
 505     extern struct udev *udev;
 506     extern struct config *get_multipath_config(void);
 507     extern void put_multipath_config(struct config *conf);
 508     struct udev *udev;
 509     struct config *get_multipath_config(void) { return multipath_conf; }
 510     void put_multipath_config(struct config *conf) { }
 511     int main(void) {
 512         udev = udev_new();
 513         multipath_conf = mpath_lib_init();
 514         return 0;
 515     }'''
 516   mpath_test_source_old = '''
 517       #include <libudev.h>
 518       #include <mpath_persist.h>
 519       unsigned mpath_mx_alloc_len = 1024;
 520       int logsink;
 521       int main(void) {
 522           struct udev *udev = udev_new();
 523           mpath_lib_init(udev);
 524           return 0;
 525       }'''
 526   libmpathpersist = cc.find_library('mpathpersist',
 527                                     required: get_option('mpath'),
 528                                     kwargs: static_kwargs)
 529   if libmpathpersist.found()
 530     mpathlibs += libmpathpersist
 531     if enable_static
 532       mpathlibs += cc.find_library('devmapper',
 533                                      required: get_option('mpath'),
 534                                      kwargs: static_kwargs)
 535     endif
 536     mpathlibs += cc.find_library('multipath',
 537                                  required: get_option('mpath'),
 538                                  kwargs: static_kwargs)
 539     foreach lib: mpathlibs
 540       if not lib.found()
 541         mpathlibs = []
 542         break
 543       endif
 544     endforeach
 545     if mpathlibs.length() == 0
 546       msg = 'Dependencies missing for libmpathpersist'
 547     elif cc.links(mpath_test_source_new, dependencies: mpathlibs)
 548       mpathpersist = declare_dependency(dependencies: mpathlibs)
 549       mpathpersist_new_api = true
 550     elif cc.links(mpath_test_source_old, dependencies: mpathlibs)
 551       mpathpersist = declare_dependency(dependencies: mpathlibs)
 552     else
 553       msg = 'Cannot detect libmpathpersist API'
 554     endif
 555     if not mpathpersist.found()
 556       if get_option('mpath').enabled()
 557         error(msg)
 558       else
 559         warning(msg + ', disabling')
 560       endif
 561     endif
 562   endif
 563 endif
 564
 565 iconv = not_found
 566 curses = not_found
 567 if have_system and not get_option('curses').disabled()
 568   curses_test = '''
 569     #include <locale.h>
 570     #include <curses.h>
 571     #include <wchar.h>
 572     int main(void) {
 573       wchar_t wch = L'w';
 574       setlocale(LC_ALL, "");
 575       resize_term(0, 0);
 576       addwstr(L"wide chars\n");
 577       addnwstr(&wch, 1);
 578       add_wch(WACS_DEGREE);
 579       return 0;
 580     }'''
 581
 582   curses_dep_list = targetos == 'windows' ? ['ncurses', 'ncursesw'] : ['ncursesw']
 583   foreach curses_dep : curses_dep_list
 584     if not curses.found()
 585       curses = dependency(curses_dep,
 586                           required: false,
 587                           method: 'pkg-config',
 588                           kwargs: static_kwargs)
 589     endif
 590   endforeach
 591   msg = get_option('curses').enabled() ? 'curses library not found' : ''
 592   curses_compile_args = ['-DNCURSES_WIDECHAR']
 593   if curses.found()
 594     if cc.links(curses_test, args: curses_compile_args, dependencies: [curses])
 595       curses = declare_dependency(compile_args: curses_compile_args, dependencies: [curses])
 596     else
 597       msg = 'curses package not usable'
 598       curses = not_found
 599     endif
 600   endif
 601   if not curses.found()
 602     has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 603     if targetos != 'windows' and not has_curses_h
 604       message('Trying with /usr/include/ncursesw')
 605       curses_compile_args += ['-I/usr/include/ncursesw']
 606       has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 607     endif
 608     if has_curses_h
 609       curses_libname_list = (targetos == 'windows' ? ['pdcurses'] : ['ncursesw', 'cursesw'])
 610       foreach curses_libname : curses_libname_list
 611         libcurses = cc.find_library(curses_libname,
 612                                     required: false,
 613                                     kwargs: static_kwargs)
 614         if libcurses.found()
 615           if cc.links(curses_test, args: curses_compile_args, dependencies: libcurses)
 616             curses = declare_dependency(compile_args: curses_compile_args,
 617                                         dependencies: [libcurses])
 618             break
 619           else
 620             msg = 'curses library not usable'
 621           endif
 622         endif
 623       endforeach
 624     endif
 625   endif
 626   if not get_option('iconv').disabled()
 627     foreach link_args : [ ['-liconv'], [] ]
 628       # Programs will be linked with glib and this will bring in libiconv on FreeBSD.
 629       # We need to use libiconv if available because mixing libiconv's headers with
 630       # the system libc does not work.
 631       # However, without adding glib to the dependencies -L/usr/local/lib will not be
 632       # included in the command line and libiconv will not be found.
 633       if cc.links('''
 634         #include <iconv.h>
 635         int main(void) {
 636           iconv_t conv = iconv_open("WCHAR_T", "UCS-2");
 637           return conv != (iconv_t) -1;
 638         }''', args: config_host['GLIB_CFLAGS'].split() + config_host['GLIB_LIBS'].split() + link_args)
 639         iconv = declare_dependency(link_args: link_args, dependencies: glib)
 640         break
 641       endif
 642     endforeach
 643   endif
 644   if curses.found() and not iconv.found()
 645     if get_option('iconv').enabled()
 646       error('iconv not available')
 647     endif
 648     msg = 'iconv required for curses UI but not available'
 649     curses = not_found
 650   endif
 651   if not curses.found() and msg != ''
 652     if get_option('curses').enabled()
 653       error(msg)
 654     else
 655       warning(msg + ', disabling')
 656     endif
 657   endif
 658 endif
 659
 660 brlapi = not_found
 661 if not get_option('brlapi').auto() or have_system
 662   brlapi = cc.find_library('brlapi', has_headers: ['brlapi.h'],
 663                          required: get_option('brlapi'),
 664                          kwargs: static_kwargs)
 665   if brlapi.found() and not cc.links('''
 666      #include <brlapi.h>
 667      #include <stddef.h>
 668      int main(void) { return brlapi__openConnection (NULL, NULL, NULL); }''', dependencies: brlapi)
 669     brlapi = not_found
 670     if get_option('brlapi').enabled()
 671       error('could not link brlapi')
 672     else
 673       warning('could not link brlapi, disabling')
 674     endif
 675   endif
 676 endif
 677
 678 sdl = not_found
 679 if not get_option('sdl').auto() or (have_system and not cocoa.found())
 680   sdl = dependency('sdl2', required: get_option('sdl'), kwargs: static_kwargs)
 681   sdl_image = not_found
 682 endif
 683 if sdl.found()
 684   # work around 2.0.8 bug
 685   sdl = declare_dependency(compile_args: '-Wno-undef',
 686                            dependencies: sdl)
 687   sdl_image = dependency('SDL2_image', required: get_option('sdl_image'),
 688                          method: 'pkg-config', kwargs: static_kwargs)
 689 else
 690   if get_option('sdl_image').enabled()
 691     error('sdl-image required, but SDL was @0@'.format(
 692           get_option('sdl').disabled() ? 'disabled' : 'not found'))
 693   endif
 694   sdl_image = not_found
 695 endif
 696
 697 rbd = not_found
 698 if not get_option('rbd').auto() or have_block
 699   librados = cc.find_library('rados', required: get_option('rbd'),
 700                              kwargs: static_kwargs)
 701   librbd = cc.find_library('rbd', has_headers: ['rbd/librbd.h'],
 702                            required: get_option('rbd'),
 703                            kwargs: static_kwargs)
 704   if librados.found() and librbd.found()
 705     if cc.links('''
 706       #include <stdio.h>
 707       #include <rbd/librbd.h>
 708       int main(void) {
 709         rados_t cluster;
 710         rados_create(&cluster, NULL);
 711         #if LIBRBD_VERSION_CODE < LIBRBD_VERSION(1, 12, 0)
 712         #error
 713         #endif
 714         return 0;
 715       }''', dependencies: [librbd, librados])
 716       rbd = declare_dependency(dependencies: [librbd, librados])
 717     elif get_option('rbd').enabled()
 718       error('librbd >= 1.12.0 required')
 719     else
 720       warning('librbd >= 1.12.0 not found, disabling')
 721     endif
 722   endif
 723 endif
 724
 725 glusterfs = not_found
 726 glusterfs_ftruncate_has_stat = false
 727 glusterfs_iocb_has_stat = false
 728 if not get_option('glusterfs').auto() or have_block
 729   glusterfs = dependency('glusterfs-api', version: '>=3',
 730                          required: get_option('glusterfs'),
 731                          method: 'pkg-config', kwargs: static_kwargs)
 732   if glusterfs.found()
 733     glusterfs_ftruncate_has_stat = cc.links('''
 734       #include <glusterfs/api/glfs.h>
 735
 736       int
 737       main(void)
 738       {
 739           /* new glfs_ftruncate() passes two additional args */
 740           return glfs_ftruncate(NULL, 0, NULL, NULL);
 741       }
 742     ''', dependencies: glusterfs)
 743     glusterfs_iocb_has_stat = cc.links('''
 744       #include <glusterfs/api/glfs.h>
 745
 746       /* new glfs_io_cbk() passes two additional glfs_stat structs */
 747       static void
 748       glusterfs_iocb(glfs_fd_t *fd, ssize_t ret, struct glfs_stat *prestat, struct glfs_stat *poststat, void *data)
 749       {}
 750
 751       int
 752       main(void)
 753       {
 754           glfs_io_cbk iocb = &glusterfs_iocb;
 755           iocb(NULL, 0 , NULL, NULL, NULL);
 756           return 0;
 757       }
 758     ''', dependencies: glusterfs)
 759   endif
 760 endif
 761 libssh = not_found
 762 if 'CONFIG_LIBSSH' in config_host
 763   libssh = declare_dependency(compile_args: config_host['LIBSSH_CFLAGS'].split(),
 764                               link_args: config_host['LIBSSH_LIBS'].split())
 765 endif
 766 libbzip2 = not_found
 767 if not get_option('bzip2').auto() or have_block
 768   libbzip2 = cc.find_library('bz2', has_headers: ['bzlib.h'],
 769                              required: get_option('bzip2'),
 770                              kwargs: static_kwargs)
 771   if libbzip2.found() and not cc.links('''
 772      #include <bzlib.h>
 773      int main(void) { BZ2_bzlibVersion(); return 0; }''', dependencies: libbzip2)
 774     libbzip2 = not_found
 775     if get_option('bzip2').enabled()
 776       error('could not link libbzip2')
 777     else
 778       warning('could not link libbzip2, disabling')
 779     endif
 780   endif
 781 endif
 782
 783 liblzfse = not_found
 784 if not get_option('lzfse').auto() or have_block
 785   liblzfse = cc.find_library('lzfse', has_headers: ['lzfse.h'],
 786                              required: get_option('lzfse'),
 787                              kwargs: static_kwargs)
 788 endif
 789 if liblzfse.found() and not cc.links('''
 790    #include <lzfse.h>
 791    int main(void) { lzfse_decode_scratch_size(); return 0; }''', dependencies: liblzfse)
 792   liblzfse = not_found
 793   if get_option('lzfse').enabled()
 794     error('could not link liblzfse')
 795   else
 796     warning('could not link liblzfse, disabling')
 797   endif
 798 endif
 799
 800 oss = not_found
 801 if 'CONFIG_AUDIO_OSS' in config_host
 802   oss = declare_dependency(link_args: config_host['OSS_LIBS'].split())
 803 endif
 804 dsound = not_found
 805 if 'CONFIG_AUDIO_DSOUND' in config_host
 806   dsound = declare_dependency(link_args: config_host['DSOUND_LIBS'].split())
 807 endif
 808 coreaudio = not_found
 809 if 'CONFIG_AUDIO_COREAUDIO' in config_host
 810   coreaudio = declare_dependency(link_args: config_host['COREAUDIO_LIBS'].split())
 811 endif
 812 opengl = not_found
 813 if 'CONFIG_OPENGL' in config_host
 814   opengl = declare_dependency(compile_args: config_host['OPENGL_CFLAGS'].split(),
 815                               link_args: config_host['OPENGL_LIBS'].split())
 816 endif
 817
 818 gnutls = not_found
 819 if not get_option('gnutls').auto() or have_system
 820   gnutls = dependency('gnutls', version: '>=3.5.18',
 821                       method: 'pkg-config',
 822                       required: get_option('gnutls'),
 823                       kwargs: static_kwargs)
 824 endif
 825
 826 # Nettle has priority over gcrypt
 827 gcrypt = not_found
 828 nettle = not_found
 829 xts = 'none'
 830 if get_option('nettle').enabled() and get_option('gcrypt').enabled()
 831   error('Only one of gcrypt & nettle can be enabled')
 832 elif (not get_option('nettle').auto() or have_system) and not get_option('gcrypt').enabled()
 833   nettle = dependency('nettle', version: '>=3.4',
 834                       method: 'pkg-config',
 835                       required: get_option('nettle'),
 836                       kwargs: static_kwargs)
 837   if nettle.found() and not cc.has_header('nettle/xts.h', dependencies: nettle)
 838     xts = 'private'
 839   endif
 840 endif
 841 if (not get_option('gcrypt').auto() or have_system) and not nettle.found()
 842   gcrypt = dependency('libgcrypt', version: '>=1.8',
 843                          method: 'config-tool',
 844                          required: get_option('gcrypt'),
 845                          kwargs: static_kwargs)
 846   # Debian has removed -lgpg-error from libgcrypt-config
 847   # as it "spreads unnecessary dependencies" which in
 848   # turn breaks static builds...
 849   if gcrypt.found() and enable_static
 850     gcrypt = declare_dependency(dependencies: [
 851       gcrypt,
 852       cc.find_library('gpg-error', required: true, kwargs: static_kwargs)])
 853   endif
 854 endif
 855
 856 gtk = not_found
 857 gtkx11 = not_found
 858 vte = not_found
 859 if not get_option('gtk').auto() or (have_system and not cocoa.found())
 860   gtk = dependency('gtk+-3.0', version: '>=3.22.0',
 861                    method: 'pkg-config',
 862                    required: get_option('gtk'),
 863                    kwargs: static_kwargs)
 864   if gtk.found()
 865     gtkx11 = dependency('gtk+-x11-3.0', version: '>=3.22.0',
 866                         method: 'pkg-config',
 867                         required: false,
 868                         kwargs: static_kwargs)
 869     gtk = declare_dependency(dependencies: [gtk, gtkx11])
 870
 871     if not get_option('vte').auto() or have_system
 872       vte = dependency('vte-2.91',
 873                        method: 'pkg-config',
 874                        required: get_option('vte'),
 875                        kwargs: static_kwargs)
 876     endif
 877   endif
 878 endif
 879
 880 x11 = not_found
 881 if gtkx11.found()
 882   x11 = dependency('x11', method: 'pkg-config', required: gtkx11.found(),
 883                    kwargs: static_kwargs)
 884 endif
 885 vnc = not_found
 886 png = not_found
 887 jpeg = not_found
 888 sasl = not_found
 889 if get_option('vnc').enabled()
 890   vnc = declare_dependency() # dummy dependency
 891   png = dependency('libpng', required: get_option('vnc_png'),
 892                    method: 'pkg-config', kwargs: static_kwargs)
 893   jpeg = dependency('libjpeg', required: get_option('vnc_jpeg'),
 894                     method: 'pkg-config', kwargs: static_kwargs)
 895   sasl = cc.find_library('sasl2', has_headers: ['sasl/sasl.h'],
 896                          required: get_option('vnc_sasl'),
 897                          kwargs: static_kwargs)
 898   if sasl.found()
 899     sasl = declare_dependency(dependencies: sasl,
 900                               compile_args: '-DSTRUCT_IOVEC_DEFINED')
 901   endif
 902 endif
 903
 904 pam = not_found
 905 if not get_option('auth_pam').auto() or have_system
 906   pam = cc.find_library('pam', has_headers: ['security/pam_appl.h'],
 907                         required: get_option('auth_pam'),
 908                         kwargs: static_kwargs)
 909 endif
 910 if pam.found() and not cc.links('''
 911    #include <stddef.h>
 912    #include <security/pam_appl.h>
 913    int main(void) {
 914      const char *service_name = "qemu";
 915      const char *user = "frank";
 916      const struct pam_conv pam_conv = { 0 };
 917      pam_handle_t *pamh = NULL;
 918      pam_start(service_name, user, &pam_conv, &pamh);
 919      return 0;
 920    }''', dependencies: pam)
 921   pam = not_found
 922   if get_option('auth_pam').enabled()
 923     error('could not link libpam')
 924   else
 925     warning('could not link libpam, disabling')
 926   endif
 927 endif
 928
 929 snappy = not_found
 930 if not get_option('snappy').auto() or have_system
 931   snappy = cc.find_library('snappy', has_headers: ['snappy-c.h'],
 932                            required: get_option('snappy'),
 933                            kwargs: static_kwargs)
 934 endif
 935 if snappy.found() and not cc.links('''
 936    #include <snappy-c.h>
 937    int main(void) { snappy_max_compressed_length(4096); return 0; }''', dependencies: snappy)
 938   snappy = not_found
 939   if get_option('snappy').enabled()
 940     error('could not link libsnappy')
 941   else
 942     warning('could not link libsnappy, disabling')
 943   endif
 944 endif
 945
 946 lzo = not_found
 947 if not get_option('lzo').auto() or have_system
 948   lzo = cc.find_library('lzo2', has_headers: ['lzo/lzo1x.h'],
 949                         required: get_option('lzo'),
 950                         kwargs: static_kwargs)
 951 endif
 952 if lzo.found() and not cc.links('''
 953    #include <lzo/lzo1x.h>
 954    int main(void) { lzo_version(); return 0; }''', dependencies: lzo)
 955   lzo = not_found
 956   if get_option('lzo').enabled()
 957     error('could not link liblzo2')
 958   else
 959     warning('could not link liblzo2, disabling')
 960   endif
 961 endif
 962
 963 rdma = not_found
 964 if 'CONFIG_RDMA' in config_host
 965   rdma = declare_dependency(link_args: config_host['RDMA_LIBS'].split())
 966 endif
 967 numa = not_found
 968 if 'CONFIG_NUMA' in config_host
 969   numa = declare_dependency(link_args: config_host['NUMA_LIBS'].split())
 970 endif
 971 xen = not_found
 972 if 'CONFIG_XEN_BACKEND' in config_host
 973   xen = declare_dependency(compile_args: config_host['XEN_CFLAGS'].split(),
 974                            link_args: config_host['XEN_LIBS'].split())
 975 endif
 976 cacard = not_found
 977 if not get_option('smartcard').auto() or have_system
 978   cacard = dependency('libcacard', required: get_option('smartcard'),
 979                       version: '>=2.5.1', method: 'pkg-config',
 980                       kwargs: static_kwargs)
 981 endif
 982 u2f = not_found
 983 if have_system
 984   u2f = dependency('u2f-emu', required: get_option('u2f'),
 985                    method: 'pkg-config',
 986                    kwargs: static_kwargs)
 987 endif
 988 usbredir = not_found
 989 if not get_option('usb_redir').auto() or have_system
 990   usbredir = dependency('libusbredirparser-0.5', required: get_option('usb_redir'),
 991                         version: '>=0.6', method: 'pkg-config',
 992                         kwargs: static_kwargs)
 993 endif
 994 libusb = not_found
 995 if not get_option('libusb').auto() or have_system
 996   libusb = dependency('libusb-1.0', required: get_option('libusb'),
 997                       version: '>=1.0.13', method: 'pkg-config',
 998                       kwargs: static_kwargs)
 999 endif
1000
1001 libpmem = not_found
1002 if not get_option('libpmem').auto() or have_system
1003   libpmem = dependency('libpmem', required: get_option('libpmem'),
1004                        method: 'pkg-config', kwargs: static_kwargs)
1005 endif
1006 libdaxctl = not_found
1007 if not get_option('libdaxctl').auto() or have_system
1008   libdaxctl = dependency('libdaxctl', required: get_option('libdaxctl'),
1009                          version: '>=57', method: 'pkg-config',
1010                          kwargs: static_kwargs)
1011 endif
1012 tasn1 = not_found
1013 if gnutls.found()
1014   tasn1 = dependency('libtasn1',
1015                      method: 'pkg-config',
1016                      kwargs: static_kwargs)
1017 endif
1018 keyutils = dependency('libkeyutils', required: false,
1019                       method: 'pkg-config', kwargs: static_kwargs)
1020
1021 has_gettid = cc.has_function('gettid')
1022
1023 # Malloc tests
1024
1025 malloc = []
1026 if get_option('malloc') == 'system'
1027   has_malloc_trim = \
1028     not get_option('malloc_trim').disabled() and \
1029     cc.links('''#include <malloc.h>
1030                 int main(void) { malloc_trim(0); return 0; }''')
1031 else
1032   has_malloc_trim = false
1033   malloc = cc.find_library(get_option('malloc'), required: true)
1034 endif
1035 if not has_malloc_trim and get_option('malloc_trim').enabled()
1036   if get_option('malloc') == 'system'
1037     error('malloc_trim not available on this platform.')
1038   else
1039     error('malloc_trim not available with non-libc memory allocator')
1040   endif
1041 endif
1042
1043 # Check whether the glibc provides statx()
1044
1045 gnu_source_prefix = '''
1046   #ifndef _GNU_SOURCE
1047   #define _GNU_SOURCE
1048   #endif
1049 '''
1050 statx_test = gnu_source_prefix + '''
1051   #include <sys/stat.h>
1052   int main(void) {
1053     struct statx statxbuf;
1054     statx(0, "", 0, STATX_BASIC_STATS, &statxbuf);
1055     return 0;
1056   }'''
1057
1058 has_statx = cc.links(statx_test)
1059
1060 have_vhost_user_blk_server = (targetos == 'linux' and
1061     'CONFIG_VHOST_USER' in config_host)
1062
1063 if get_option('vhost_user_blk_server').enabled()
1064     if targetos != 'linux'
1065         error('vhost_user_blk_server requires linux')
1066     elif 'CONFIG_VHOST_USER' not in config_host
1067         error('vhost_user_blk_server requires vhost-user support')
1068     endif
1069 elif get_option('vhost_user_blk_server').disabled() or not have_system
1070     have_vhost_user_blk_server = false
1071 endif
1072
1073
1074 if get_option('fuse').disabled() and get_option('fuse_lseek').enabled()
1075   error('Cannot enable fuse-lseek while fuse is disabled')
1076 endif
1077
1078 fuse = dependency('fuse3', required: get_option('fuse'),
1079                   version: '>=3.1', method: 'pkg-config',
1080                   kwargs: static_kwargs)
1081
1082 fuse_lseek = not_found
1083 if not get_option('fuse_lseek').disabled()
1084   if fuse.version().version_compare('>=3.8')
1085     # Dummy dependency
1086     fuse_lseek = declare_dependency()
1087   elif get_option('fuse_lseek').enabled()
1088     if fuse.found()
1089       error('fuse-lseek requires libfuse >=3.8, found ' + fuse.version())
1090     else
1091       error('fuse-lseek requires libfuse, which was not found')
1092     endif
1093   endif
1094 endif
1095
1096 # libbpf
1097 libbpf = dependency('libbpf', required: get_option('bpf'), method: 'pkg-config')
1098 if libbpf.found() and not cc.links('''
1099    #include <bpf/libbpf.h>
1100    int main(void)
1101    {
1102      bpf_object__destroy_skeleton(NULL);
1103      return 0;
1104    }''', dependencies: libbpf)
1105   libbpf = not_found
1106   if get_option('bpf').enabled()
1107     error('libbpf skeleton test failed')
1108   else
1109     warning('libbpf skeleton test failed, disabling')
1110   endif
1111 endif
1112
1113 if get_option('cfi')
1114   cfi_flags=[]
1115   # Check for dependency on LTO
1116   if not get_option('b_lto')
1117     error('Selected Control-Flow Integrity but LTO is disabled')
1118   endif
1119   if config_host.has_key('CONFIG_MODULES')
1120     error('Selected Control-Flow Integrity is not compatible with modules')
1121   endif
1122   # Check for cfi flags. CFI requires LTO so we can't use
1123   # get_supported_arguments, but need a more complex "compiles" which allows
1124   # custom arguments
1125   if cc.compiles('int main () { return 0; }', name: '-fsanitize=cfi-icall',
1126                  args: ['-flto', '-fsanitize=cfi-icall'] )
1127     cfi_flags += '-fsanitize=cfi-icall'
1128   else
1129     error('-fsanitize=cfi-icall is not supported by the compiler')
1130   endif
1131   if cc.compiles('int main () { return 0; }',
1132                  name: '-fsanitize-cfi-icall-generalize-pointers',
1133                  args: ['-flto', '-fsanitize=cfi-icall',
1134                         '-fsanitize-cfi-icall-generalize-pointers'] )
1135     cfi_flags += '-fsanitize-cfi-icall-generalize-pointers'
1136   else
1137     error('-fsanitize-cfi-icall-generalize-pointers is not supported by the compiler')
1138   endif
1139   if get_option('cfi_debug')
1140     if cc.compiles('int main () { return 0; }',
1141                    name: '-fno-sanitize-trap=cfi-icall',
1142                    args: ['-flto', '-fsanitize=cfi-icall',
1143                           '-fno-sanitize-trap=cfi-icall'] )
1144       cfi_flags += '-fno-sanitize-trap=cfi-icall'
1145     else
1146       error('-fno-sanitize-trap=cfi-icall is not supported by the compiler')
1147     endif
1148   endif
1149   add_global_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1150   add_global_link_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1151 endif
1152
1153 have_host_block_device = (targetos != 'darwin' or
1154     cc.has_header('IOKit/storage/IOMedia.h'))
1155
1156 #################
1157 # config-host.h #
1158 #################
1159
1160 have_virtfs = (targetos == 'linux' and
1161     have_system and
1162     libattr.found() and
1163     libcap_ng.found())
1164
1165 have_virtfs_proxy_helper = have_virtfs and have_tools
1166
1167 if get_option('virtfs').enabled()
1168   if not have_virtfs
1169     if targetos != 'linux'
1170       error('virtio-9p (virtfs) requires Linux')
1171     elif not libcap_ng.found() or not libattr.found()
1172       error('virtio-9p (virtfs) requires libcap-ng-devel and libattr-devel')
1173     elif not have_system
1174       error('virtio-9p (virtfs) needs system emulation support')
1175     endif
1176   endif
1177 elif get_option('virtfs').disabled()
1178   have_virtfs = false
1179 endif
1180
1181 config_host_data.set_quoted('CONFIG_BINDIR', get_option('prefix') / get_option('bindir'))
1182 config_host_data.set_quoted('CONFIG_PREFIX', get_option('prefix'))
1183 config_host_data.set_quoted('CONFIG_QEMU_CONFDIR', get_option('prefix') / qemu_confdir)
1184 config_host_data.set_quoted('CONFIG_QEMU_DATADIR', get_option('prefix') / qemu_datadir)
1185 config_host_data.set_quoted('CONFIG_QEMU_DESKTOPDIR', get_option('prefix') / qemu_desktopdir)
1186 config_host_data.set_quoted('CONFIG_QEMU_FIRMWAREPATH', get_option('qemu_firmwarepath'))
1187 config_host_data.set_quoted('CONFIG_QEMU_HELPERDIR', get_option('prefix') / get_option('libexecdir'))
1188 config_host_data.set_quoted('CONFIG_QEMU_ICONDIR', get_option('prefix') / qemu_icondir)
1189 config_host_data.set_quoted('CONFIG_QEMU_LOCALEDIR', get_option('prefix') / get_option('localedir'))
1190 config_host_data.set_quoted('CONFIG_QEMU_LOCALSTATEDIR', get_option('prefix') / get_option('localstatedir'))
1191 config_host_data.set_quoted('CONFIG_QEMU_MODDIR', get_option('prefix') / qemu_moddir)
1192 config_host_data.set_quoted('CONFIG_SYSCONFDIR', get_option('prefix') / get_option('sysconfdir'))
1193
1194 config_host_data.set('CONFIG_ATTR', libattr.found())
1195 config_host_data.set('CONFIG_BRLAPI', brlapi.found())
1196 config_host_data.set('CONFIG_COCOA', cocoa.found())
1197 config_host_data.set('CONFIG_LIBUDEV', libudev.found())
1198 config_host_data.set('CONFIG_LZO', lzo.found())
1199 config_host_data.set('CONFIG_MPATH', mpathpersist.found())
1200 config_host_data.set('CONFIG_MPATH_NEW_API', mpathpersist_new_api)
1201 config_host_data.set('CONFIG_CURL', curl.found())
1202 config_host_data.set('CONFIG_CURSES', curses.found())
1203 config_host_data.set('CONFIG_GLUSTERFS', glusterfs.found())
1204 if glusterfs.found()
1205   config_host_data.set('CONFIG_GLUSTERFS_XLATOR_OPT', glusterfs.version().version_compare('>=4'))
1206   config_host_data.set('CONFIG_GLUSTERFS_DISCARD', glusterfs.version().version_compare('>=5'))
1207   config_host_data.set('CONFIG_GLUSTERFS_FALLOCATE', glusterfs.version().version_compare('>=6'))
1208   config_host_data.set('CONFIG_GLUSTERFS_ZEROFILL', glusterfs.version().version_compare('>=6'))
1209   config_host_data.set('CONFIG_GLUSTERFS_FTRUNCATE_HAS_STAT', glusterfs_ftruncate_has_stat)
1210   config_host_data.set('CONFIG_GLUSTERFS_IOCB_HAS_STAT', glusterfs_iocb_has_stat)
1211 endif
1212 config_host_data.set('CONFIG_GTK', gtk.found())
1213 config_host_data.set('CONFIG_VTE', vte.found())
1214 config_host_data.set('CONFIG_LIBATTR', have_old_libattr)
1215 config_host_data.set('CONFIG_LIBCAP_NG', libcap_ng.found())
1216 config_host_data.set('CONFIG_EBPF', libbpf.found())
1217 config_host_data.set('CONFIG_LIBDAXCTL', libdaxctl.found())
1218 config_host_data.set('CONFIG_LIBISCSI', libiscsi.found())
1219 config_host_data.set('CONFIG_LIBNFS', libnfs.found())
1220 config_host_data.set('CONFIG_LINUX_IO_URING', linux_io_uring.found())
1221 config_host_data.set('CONFIG_LIBPMEM', libpmem.found())
1222 config_host_data.set('CONFIG_RBD', rbd.found())
1223 config_host_data.set('CONFIG_SDL', sdl.found())
1224 config_host_data.set('CONFIG_SDL_IMAGE', sdl_image.found())
1225 config_host_data.set('CONFIG_SECCOMP', seccomp.found())
1226 config_host_data.set('CONFIG_SNAPPY', snappy.found())
1227 config_host_data.set('CONFIG_USB_LIBUSB', libusb.found())
1228 config_host_data.set('CONFIG_VHOST_USER_BLK_SERVER', have_vhost_user_blk_server)
1229 config_host_data.set('CONFIG_VNC', vnc.found())
1230 config_host_data.set('CONFIG_VNC_JPEG', jpeg.found())
1231 config_host_data.set('CONFIG_VNC_PNG', png.found())
1232 config_host_data.set('CONFIG_VNC_SASL', sasl.found())
1233 config_host_data.set('CONFIG_VIRTFS', have_virtfs)
1234 config_host_data.set('CONFIG_VTE', vte.found())
1235 config_host_data.set('CONFIG_XKBCOMMON', xkbcommon.found())
1236 config_host_data.set('CONFIG_KEYUTILS', keyutils.found())
1237 config_host_data.set('CONFIG_GETTID', has_gettid)
1238 config_host_data.set('CONFIG_GNUTLS', gnutls.found())
1239 config_host_data.set('CONFIG_GCRYPT', gcrypt.found())
1240 config_host_data.set('CONFIG_NETTLE', nettle.found())
1241 config_host_data.set('CONFIG_QEMU_PRIVATE_XTS', xts == 'private')
1242 config_host_data.set('CONFIG_MALLOC_TRIM', has_malloc_trim)
1243 config_host_data.set('CONFIG_STATX', has_statx)
1244 config_host_data.set('CONFIG_ZSTD', zstd.found())
1245 config_host_data.set('CONFIG_FUSE', fuse.found())
1246 config_host_data.set('CONFIG_FUSE_LSEEK', fuse_lseek.found())
1247 config_host_data.set('CONFIG_X11', x11.found())
1248 config_host_data.set('CONFIG_CFI', get_option('cfi'))
1249 config_host_data.set('QEMU_VERSION', '"@0@"'.format(meson.project_version()))
1250 config_host_data.set('QEMU_VERSION_MAJOR', meson.project_version().split('.')[0])
1251 config_host_data.set('QEMU_VERSION_MINOR', meson.project_version().split('.')[1])
1252 config_host_data.set('QEMU_VERSION_MICRO', meson.project_version().split('.')[2])
1253
1254 config_host_data.set('HAVE_HOST_BLOCK_DEVICE', have_host_block_device)
1255
1256 # has_header
1257 config_host_data.set('CONFIG_EPOLL', cc.has_header('sys/epoll.h'))
1258 config_host_data.set('CONFIG_LINUX_MAGIC_H', cc.has_header('linux/magic.h'))
1259 config_host_data.set('CONFIG_VALGRIND_H', cc.has_header('valgrind/valgrind.h'))
1260 config_host_data.set('HAVE_BTRFS_H', cc.has_header('linux/btrfs.h'))
1261 config_host_data.set('HAVE_DRM_H', cc.has_header('libdrm/drm.h'))
1262 config_host_data.set('HAVE_PTY_H', cc.has_header('pty.h'))
1263 config_host_data.set('HAVE_SYS_DISK_H', cc.has_header('sys/disk.h'))
1264 config_host_data.set('HAVE_SYS_IOCCOM_H', cc.has_header('sys/ioccom.h'))
1265 config_host_data.set('HAVE_SYS_KCOV_H', cc.has_header('sys/kcov.h'))
1266
1267 # has_function
1268 config_host_data.set('CONFIG_ACCEPT4', cc.has_function('accept4'))
1269 config_host_data.set('CONFIG_CLOCK_ADJTIME', cc.has_function('clock_adjtime'))
1270 config_host_data.set('CONFIG_DUP3', cc.has_function('dup3'))
1271 config_host_data.set('CONFIG_FALLOCATE', cc.has_function('fallocate'))
1272 config_host_data.set('CONFIG_POSIX_FALLOCATE', cc.has_function('posix_fallocate'))
1273 config_host_data.set('CONFIG_POSIX_MEMALIGN', cc.has_function('posix_memalign'))
1274 config_host_data.set('CONFIG_PPOLL', cc.has_function('ppoll'))
1275 config_host_data.set('CONFIG_PREADV', cc.has_function('preadv', prefix: '#include <sys/uio.h>'))
1276 config_host_data.set('CONFIG_SEM_TIMEDWAIT', cc.has_function('sem_timedwait', dependencies: threads))
1277 config_host_data.set('CONFIG_SENDFILE', cc.has_function('sendfile'))
1278 config_host_data.set('CONFIG_SETNS', cc.has_function('setns') and cc.has_function('unshare'))
1279 config_host_data.set('CONFIG_SYNCFS', cc.has_function('syncfs'))
1280 config_host_data.set('CONFIG_SYNC_FILE_RANGE', cc.has_function('sync_file_range'))
1281 config_host_data.set('CONFIG_TIMERFD', cc.has_function('timerfd_create'))
1282 config_host_data.set('HAVE_COPY_FILE_RANGE', cc.has_function('copy_file_range'))
1283 config_host_data.set('HAVE_OPENPTY', cc.has_function('openpty', dependencies: util))
1284 config_host_data.set('HAVE_STRCHRNUL', cc.has_function('strchrnul'))
1285 config_host_data.set('HAVE_SYSTEM_FUNCTION', cc.has_function('system', prefix: '#include <stdlib.h>'))
1286
1287 # has_header_symbol
1288 config_host_data.set('CONFIG_BYTESWAP_H',
1289                      cc.has_header_symbol('byteswap.h', 'bswap_32'))
1290 config_host_data.set('CONFIG_EPOLL_CREATE1',
1291                      cc.has_header_symbol('sys/epoll.h', 'epoll_create1'))
1292 config_host_data.set('CONFIG_HAS_ENVIRON',
1293                      cc.has_header_symbol('unistd.h', 'environ', prefix: gnu_source_prefix))
1294 config_host_data.set('CONFIG_FALLOCATE_PUNCH_HOLE',
1295                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_PUNCH_HOLE') and
1296                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_KEEP_SIZE'))
1297 config_host_data.set('CONFIG_FALLOCATE_ZERO_RANGE',
1298                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_ZERO_RANGE'))
1299 config_host_data.set('CONFIG_FIEMAP',
1300                      cc.has_header('linux/fiemap.h') and
1301                      cc.has_header_symbol('linux/fs.h', 'FS_IOC_FIEMAP'))
1302 config_host_data.set('CONFIG_GETRANDOM',
1303                      cc.has_function('getrandom') and
1304                      cc.has_header_symbol('sys/random.h', 'GRND_NONBLOCK'))
1305 config_host_data.set('CONFIG_INOTIFY',
1306                      cc.has_header_symbol('sys/inotify.h', 'inotify_init'))
1307 config_host_data.set('CONFIG_INOTIFY1',
1308                      cc.has_header_symbol('sys/inotify.h', 'inotify_init1'))
1309 config_host_data.set('CONFIG_MACHINE_BSWAP_H',
1310                      cc.has_header_symbol('machine/bswap.h', 'bswap32',
1311                                           prefix: '''#include <sys/endian.h>
1312                                                      #include <sys/types.h>'''))
1313 config_host_data.set('CONFIG_PRCTL_PR_SET_TIMERSLACK',
1314                      cc.has_header_symbol('sys/prctl.h', 'PR_SET_TIMERSLACK'))
1315 config_host_data.set('CONFIG_RTNETLINK',
1316                      cc.has_header_symbol('linux/rtnetlink.h', 'IFLA_PROTO_DOWN'))
1317 config_host_data.set('CONFIG_SYSMACROS',
1318                      cc.has_header_symbol('sys/sysmacros.h', 'makedev'))
1319 config_host_data.set('HAVE_OPTRESET',
1320                      cc.has_header_symbol('getopt.h', 'optreset'))
1321 config_host_data.set('HAVE_UTMPX',
1322                      cc.has_header_symbol('utmpx.h', 'struct utmpx'))
1323
1324 # has_member
1325 config_host_data.set('HAVE_SIGEV_NOTIFY_THREAD_ID',
1326                      cc.has_member('struct sigevent', 'sigev_notify_thread_id',
1327                                    prefix: '#include <signal.h>'))
1328 config_host_data.set('HAVE_STRUCT_STAT_ST_ATIM',
1329                      cc.has_member('struct stat', 'st_atim',
1330                                    prefix: '#include <sys/stat.h>'))
1331
1332 config_host_data.set('CONFIG_EVENTFD', cc.links('''
1333   #include <sys/eventfd.h>
1334   int main(void) { return eventfd(0, EFD_NONBLOCK | EFD_CLOEXEC); }'''))
1335 config_host_data.set('CONFIG_FDATASYNC', cc.links(gnu_source_prefix + '''
1336   #include <unistd.h>
1337   int main(void) {
1338   #if defined(_POSIX_SYNCHRONIZED_IO) && _POSIX_SYNCHRONIZED_IO > 0
1339   return fdatasync(0);
1340   #else
1341   #error Not supported
1342   #endif
1343   }'''))
1344 config_host_data.set('CONFIG_MADVISE', cc.links(gnu_source_prefix + '''
1345   #include <sys/types.h>
1346   #include <sys/mman.h>
1347   #include <stddef.h>
1348   int main(void) { return madvise(NULL, 0, MADV_DONTNEED); }'''))
1349 config_host_data.set('CONFIG_MEMFD', cc.links(gnu_source_prefix + '''
1350   #include <sys/mman.h>
1351   int main(void) { return memfd_create("foo", MFD_ALLOW_SEALING); }'''))
1352 config_host_data.set('CONFIG_OPEN_BY_HANDLE', cc.links(gnu_source_prefix + '''
1353   #include <fcntl.h>
1354   #if !defined(AT_EMPTY_PATH)
1355   # error missing definition
1356   #else
1357   int main(void) { struct file_handle fh; return open_by_handle_at(0, &fh, 0); }
1358   #endif'''))
1359 config_host_data.set('CONFIG_PIPE2', cc.links(gnu_source_prefix + '''
1360   #include <unistd.h>
1361   #include <fcntl.h>
1362
1363   int main(void)
1364   {
1365       int pipefd[2];
1366       return pipe2(pipefd, O_CLOEXEC);
1367   }'''))
1368 config_host_data.set('CONFIG_POSIX_MADVISE', cc.links(gnu_source_prefix + '''
1369   #include <sys/mman.h>
1370   #include <stddef.h>
1371   int main(void) { return posix_madvise(NULL, 0, POSIX_MADV_DONTNEED); }'''))
1372 config_host_data.set('CONFIG_SIGNALFD', cc.links(gnu_source_prefix + '''
1373   #include <unistd.h>
1374   #include <sys/syscall.h>
1375   #include <signal.h>
1376   int main(void) { return syscall(SYS_signalfd, -1, NULL, _NSIG / 8); }'''))
1377 config_host_data.set('CONFIG_SPLICE', cc.links(gnu_source_prefix + '''
1378   #include <unistd.h>
1379   #include <fcntl.h>
1380   #include <limits.h>
1381
1382   int main(void)
1383   {
1384     int len, fd = 0;
1385     len = tee(STDIN_FILENO, STDOUT_FILENO, INT_MAX, SPLICE_F_NONBLOCK);
1386     splice(STDIN_FILENO, NULL, fd, NULL, len, SPLICE_F_MOVE);
1387     return 0;
1388   }'''))
1389
1390 # Some versions of Mac OS X incorrectly define SIZE_MAX
1391 config_host_data.set('HAVE_BROKEN_SIZE_MAX', not cc.compiles('''
1392     #include <stdint.h>
1393     #include <stdio.h>
1394     int main(int argc, char *argv[]) {
1395         return printf("%zu", SIZE_MAX);
1396     }''', args: ['-Werror']))
1397
1398
1399 ignored = ['CONFIG_QEMU_INTERP_PREFIX'] # actually per-target
1400 arrays = ['CONFIG_AUDIO_DRIVERS', 'CONFIG_BDRV_RW_WHITELIST', 'CONFIG_BDRV_RO_WHITELIST']
1401 strings = ['HOST_DSOSUF', 'CONFIG_IASL']
1402 foreach k, v: config_host
1403   if ignored.contains(k)
1404     # do nothing
1405   elif arrays.contains(k)
1406     if v != ''
1407       v = '"' + '", "'.join(v.split()) + '", '
1408     endif
1409     config_host_data.set(k, v)
1410   elif k == 'ARCH'
1411     config_host_data.set('HOST_' + v.to_upper(), 1)
1412   elif strings.contains(k)
1413     if not k.startswith('CONFIG_')
1414       k = 'CONFIG_' + k.to_upper()
1415     endif
1416     config_host_data.set_quoted(k, v)
1417   elif k.startswith('CONFIG_') or k.startswith('HAVE_') or k.startswith('HOST_')
1418     config_host_data.set(k, v == 'y' ? 1 : v)
1419   endif
1420 endforeach
1421
1422 ########################
1423 # Target configuration #
1424 ########################
1425
1426 minikconf = find_program('scripts/minikconf.py')
1427 config_all = {}
1428 config_all_devices = {}
1429 config_all_disas = {}
1430 config_devices_mak_list = []
1431 config_devices_h = {}
1432 config_target_h = {}
1433 config_target_mak = {}
1434
1435 disassemblers = {
1436   'alpha' : ['CONFIG_ALPHA_DIS'],
1437   'arm' : ['CONFIG_ARM_DIS'],
1438   'avr' : ['CONFIG_AVR_DIS'],
1439   'cris' : ['CONFIG_CRIS_DIS'],
1440   'hexagon' : ['CONFIG_HEXAGON_DIS'],
1441   'hppa' : ['CONFIG_HPPA_DIS'],
1442   'i386' : ['CONFIG_I386_DIS'],
1443   'x86_64' : ['CONFIG_I386_DIS'],
1444   'x32' : ['CONFIG_I386_DIS'],
1445   'm68k' : ['CONFIG_M68K_DIS'],
1446   'microblaze' : ['CONFIG_MICROBLAZE_DIS'],
1447   'mips' : ['CONFIG_MIPS_DIS'],
1448   'nios2' : ['CONFIG_NIOS2_DIS'],
1449   'or1k' : ['CONFIG_OPENRISC_DIS'],
1450   'ppc' : ['CONFIG_PPC_DIS'],
1451   'riscv' : ['CONFIG_RISCV_DIS'],
1452   'rx' : ['CONFIG_RX_DIS'],
1453   's390' : ['CONFIG_S390_DIS'],
1454   'sh4' : ['CONFIG_SH4_DIS'],
1455   'sparc' : ['CONFIG_SPARC_DIS'],
1456   'xtensa' : ['CONFIG_XTENSA_DIS'],
1457 }
1458 if link_language == 'cpp'
1459   disassemblers += {
1460     'aarch64' : [ 'CONFIG_ARM_A64_DIS'],
1461     'arm' : [ 'CONFIG_ARM_DIS', 'CONFIG_ARM_A64_DIS'],
1462     'mips' : [ 'CONFIG_MIPS_DIS', 'CONFIG_NANOMIPS_DIS'],
1463   }
1464 endif
1465
1466 have_ivshmem = config_host_data.get('CONFIG_EVENTFD')
1467 host_kconfig = \
1468   ('CONFIG_TPM' in config_host ? ['CONFIG_TPM=y'] : []) + \
1469   ('CONFIG_SPICE' in config_host ? ['CONFIG_SPICE=y'] : []) + \
1470   (have_ivshmem ? ['CONFIG_IVSHMEM=y'] : []) + \
1471   ('CONFIG_OPENGL' in config_host ? ['CONFIG_OPENGL=y'] : []) + \
1472   (x11.found() ? ['CONFIG_X11=y'] : []) + \
1473   ('CONFIG_VHOST_USER' in config_host ? ['CONFIG_VHOST_USER=y'] : []) + \
1474   ('CONFIG_VHOST_VDPA' in config_host ? ['CONFIG_VHOST_VDPA=y'] : []) + \
1475   ('CONFIG_VHOST_KERNEL' in config_host ? ['CONFIG_VHOST_KERNEL=y'] : []) + \
1476   (have_virtfs ? ['CONFIG_VIRTFS=y'] : []) + \
1477   ('CONFIG_LINUX' in config_host ? ['CONFIG_LINUX=y'] : []) + \
1478   ('CONFIG_PVRDMA' in config_host ? ['CONFIG_PVRDMA=y'] : []) + \
1479   (multiprocess_allowed ? ['CONFIG_MULTIPROCESS_ALLOWED=y'] : [])
1480
1481 ignored = [ 'TARGET_XML_FILES', 'TARGET_ABI_DIR', 'TARGET_ARCH' ]
1482
1483 default_targets = 'CONFIG_DEFAULT_TARGETS' in config_host
1484 actual_target_dirs = []
1485 fdt_required = []
1486 foreach target : target_dirs
1487   config_target = { 'TARGET_NAME': target.split('-')[0] }
1488   if target.endswith('linux-user')
1489     if targetos != 'linux'
1490       if default_targets
1491         continue
1492       endif
1493       error('Target @0@ is only available on a Linux host'.format(target))
1494     endif
1495     config_target += { 'CONFIG_LINUX_USER': 'y' }
1496   elif target.endswith('bsd-user')
1497     if 'CONFIG_BSD' not in config_host
1498       if default_targets
1499         continue
1500       endif
1501       error('Target @0@ is only available on a BSD host'.format(target))
1502     endif
1503     config_target += { 'CONFIG_BSD_USER': 'y' }
1504   elif target.endswith('softmmu')
1505     config_target += { 'CONFIG_SOFTMMU': 'y' }
1506   endif
1507   if target.endswith('-user')
1508     config_target += {
1509       'CONFIG_USER_ONLY': 'y',
1510       'CONFIG_QEMU_INTERP_PREFIX':
1511         config_host['CONFIG_QEMU_INTERP_PREFIX'].format(config_target['TARGET_NAME'])
1512     }
1513   endif
1514
1515   accel_kconfig = []
1516   foreach sym: accelerators
1517     if sym == 'CONFIG_TCG' or target in accelerator_targets.get(sym, [])
1518       config_target += { sym: 'y' }
1519       config_all += { sym: 'y' }
1520       if sym == 'CONFIG_TCG' and tcg_arch == 'tci'
1521         config_target += { 'CONFIG_TCG_INTERPRETER': 'y' }
1522       elif sym == 'CONFIG_XEN' and have_xen_pci_passthrough
1523         config_target += { 'CONFIG_XEN_PCI_PASSTHROUGH': 'y' }
1524       endif
1525       if target in modular_tcg
1526         config_target += { 'CONFIG_TCG_MODULAR': 'y' }
1527       else
1528         config_target += { 'CONFIG_TCG_BUILTIN': 'y' }
1529       endif
1530       accel_kconfig += [ sym + '=y' ]
1531     endif
1532   endforeach
1533   if accel_kconfig.length() == 0
1534     if default_targets
1535       continue
1536     endif
1537     error('No accelerator available for target @0@'.format(target))
1538   endif
1539
1540   actual_target_dirs += target
1541   config_target += keyval.load('configs/targets' / target + '.mak')
1542   config_target += { 'TARGET_' + config_target['TARGET_ARCH'].to_upper(): 'y' }
1543
1544   if 'TARGET_NEED_FDT' in config_target
1545     fdt_required += target
1546   endif
1547
1548   # Add default keys
1549   if 'TARGET_BASE_ARCH' not in config_target
1550     config_target += {'TARGET_BASE_ARCH': config_target['TARGET_ARCH']}
1551   endif
1552   if 'TARGET_ABI_DIR' not in config_target
1553     config_target += {'TARGET_ABI_DIR': config_target['TARGET_ARCH']}
1554   endif
1555
1556   foreach k, v: disassemblers
1557     if config_host['ARCH'].startswith(k) or config_target['TARGET_BASE_ARCH'].startswith(k)
1558       foreach sym: v
1559         config_target += { sym: 'y' }
1560         config_all_disas += { sym: 'y' }
1561       endforeach
1562     endif
1563   endforeach
1564
1565   config_target_data = configuration_data()
1566   foreach k, v: config_target
1567     if not k.startswith('TARGET_') and not k.startswith('CONFIG_')
1568       # do nothing
1569     elif ignored.contains(k)
1570       # do nothing
1571     elif k == 'TARGET_BASE_ARCH'
1572       # Note that TARGET_BASE_ARCH ends up in config-target.h but it is
1573       # not used to select files from sourcesets.
1574       config_target_data.set('TARGET_' + v.to_upper(), 1)
1575     elif k == 'TARGET_NAME' or k == 'CONFIG_QEMU_INTERP_PREFIX'
1576       config_target_data.set_quoted(k, v)
1577     elif v == 'y'
1578       config_target_data.set(k, 1)
1579     else
1580       config_target_data.set(k, v)
1581     endif
1582   endforeach
1583   config_target_h += {target: configure_file(output: target + '-config-target.h',
1584                                                configuration: config_target_data)}
1585
1586   if target.endswith('-softmmu')
1587     config_input = meson.get_external_property(target, 'default')
1588     config_devices_mak = target + '-config-devices.mak'
1589     config_devices_mak = configure_file(
1590       input: ['configs/devices' / target / config_input + '.mak', 'Kconfig'],
1591       output: config_devices_mak,
1592       depfile: config_devices_mak + '.d',
1593       capture: true,
1594       command: [minikconf,
1595                 get_option('default_devices') ? '--defconfig' : '--allnoconfig',
1596                 config_devices_mak, '@DEPFILE@', '@INPUT@',
1597                 host_kconfig, accel_kconfig,
1598                 'CONFIG_' + config_target['TARGET_ARCH'].to_upper() + '=y'])
1599
1600     config_devices_data = configuration_data()
1601     config_devices = keyval.load(config_devices_mak)
1602     foreach k, v: config_devices
1603       config_devices_data.set(k, 1)
1604     endforeach
1605     config_devices_mak_list += config_devices_mak
1606     config_devices_h += {target: configure_file(output: target + '-config-devices.h',
1607                                                 configuration: config_devices_data)}
1608     config_target += config_devices
1609     config_all_devices += config_devices
1610   endif
1611   config_target_mak += {target: config_target}
1612 endforeach
1613 target_dirs = actual_target_dirs
1614
1615 # This configuration is used to build files that are shared by
1616 # multiple binaries, and then extracted out of the "common"
1617 # static_library target.
1618 #
1619 # We do not use all_sources()/all_dependencies(), because it would
1620 # build literally all source files, including devices only used by
1621 # targets that are not built for this compilation.  The CONFIG_ALL
1622 # pseudo symbol replaces it.
1623
1624 config_all += config_all_devices
1625 config_all += config_host
1626 config_all += config_all_disas
1627 config_all += {
1628   'CONFIG_XEN': config_host.has_key('CONFIG_XEN_BACKEND'),
1629   'CONFIG_SOFTMMU': have_system,
1630   'CONFIG_USER_ONLY': have_user,
1631   'CONFIG_ALL': true,
1632 }
1633
1634 ##############
1635 # Submodules #
1636 ##############
1637
1638 capstone = not_found
1639 capstone_opt = get_option('capstone')
1640 if capstone_opt in ['enabled', 'auto', 'system']
1641   have_internal = fs.exists(meson.current_source_dir() / 'capstone/Makefile')
1642   capstone = dependency('capstone', version: '>=4.0',
1643                         kwargs: static_kwargs, method: 'pkg-config',
1644                         required: capstone_opt == 'system' or
1645                                   capstone_opt == 'enabled' and not have_internal)
1646   if capstone.found()
1647     capstone_opt = 'system'
1648   elif have_internal
1649     capstone_opt = 'internal'
1650   else
1651     capstone_opt = 'disabled'
1652   endif
1653 endif
1654 if capstone_opt == 'internal'
1655   capstone_data = configuration_data()
1656   capstone_data.set('CAPSTONE_USE_SYS_DYN_MEM', '1')
1657
1658   capstone_files = files(
1659     'capstone/cs.c',
1660     'capstone/MCInst.c',
1661     'capstone/MCInstrDesc.c',
1662     'capstone/MCRegisterInfo.c',
1663     'capstone/SStream.c',
1664     'capstone/utils.c'
1665   )
1666
1667   if 'CONFIG_ARM_DIS' in config_all_disas
1668     capstone_data.set('CAPSTONE_HAS_ARM', '1')
1669     capstone_files += files(
1670       'capstone/arch/ARM/ARMDisassembler.c',
1671       'capstone/arch/ARM/ARMInstPrinter.c',
1672       'capstone/arch/ARM/ARMMapping.c',
1673       'capstone/arch/ARM/ARMModule.c'
1674     )
1675   endif
1676
1677   # FIXME: This config entry currently depends on a c++ compiler.
1678   # Which is needed for building libvixl, but not for capstone.
1679   if 'CONFIG_ARM_A64_DIS' in config_all_disas
1680     capstone_data.set('CAPSTONE_HAS_ARM64', '1')
1681     capstone_files += files(
1682       'capstone/arch/AArch64/AArch64BaseInfo.c',
1683       'capstone/arch/AArch64/AArch64Disassembler.c',
1684       'capstone/arch/AArch64/AArch64InstPrinter.c',
1685       'capstone/arch/AArch64/AArch64Mapping.c',
1686       'capstone/arch/AArch64/AArch64Module.c'
1687     )
1688   endif
1689
1690   if 'CONFIG_PPC_DIS' in config_all_disas
1691     capstone_data.set('CAPSTONE_HAS_POWERPC', '1')
1692     capstone_files += files(
1693       'capstone/arch/PowerPC/PPCDisassembler.c',
1694       'capstone/arch/PowerPC/PPCInstPrinter.c',
1695       'capstone/arch/PowerPC/PPCMapping.c',
1696       'capstone/arch/PowerPC/PPCModule.c'
1697     )
1698   endif
1699
1700   if 'CONFIG_S390_DIS' in config_all_disas
1701     capstone_data.set('CAPSTONE_HAS_SYSZ', '1')
1702     capstone_files += files(
1703       'capstone/arch/SystemZ/SystemZDisassembler.c',
1704       'capstone/arch/SystemZ/SystemZInstPrinter.c',
1705       'capstone/arch/SystemZ/SystemZMapping.c',
1706       'capstone/arch/SystemZ/SystemZModule.c',
1707       'capstone/arch/SystemZ/SystemZMCTargetDesc.c'
1708     )
1709   endif
1710
1711   if 'CONFIG_I386_DIS' in config_all_disas
1712     capstone_data.set('CAPSTONE_HAS_X86', 1)
1713     capstone_files += files(
1714       'capstone/arch/X86/X86Disassembler.c',
1715       'capstone/arch/X86/X86DisassemblerDecoder.c',
1716       'capstone/arch/X86/X86ATTInstPrinter.c',
1717       'capstone/arch/X86/X86IntelInstPrinter.c',
1718       'capstone/arch/X86/X86InstPrinterCommon.c',
1719       'capstone/arch/X86/X86Mapping.c',
1720       'capstone/arch/X86/X86Module.c'
1721     )
1722   endif
1723
1724   configure_file(output: 'capstone-defs.h', configuration: capstone_data)
1725
1726   capstone_cargs = [
1727     # FIXME: There does not seem to be a way to completely replace the c_args
1728     # that come from add_project_arguments() -- we can only add to them.
1729     # So: disable all warnings with a big hammer.
1730     '-Wno-error', '-w',
1731
1732     # Include all configuration defines via a header file, which will wind up
1733     # as a dependency on the object file, and thus changes here will result
1734     # in a rebuild.
1735     '-include', 'capstone-defs.h'
1736   ]
1737
1738   libcapstone = static_library('capstone',
1739                                build_by_default: false,
1740                                sources: capstone_files,
1741                                c_args: capstone_cargs,
1742                                include_directories: 'capstone/include')
1743   capstone = declare_dependency(link_with: libcapstone,
1744                                 include_directories: 'capstone/include/capstone')
1745 endif
1746
1747 slirp = not_found
1748 slirp_opt = 'disabled'
1749 if have_system
1750   slirp_opt = get_option('slirp')
1751   if slirp_opt in ['enabled', 'auto', 'system']
1752     have_internal = fs.exists(meson.current_source_dir() / 'slirp/meson.build')
1753     slirp = dependency('slirp', kwargs: static_kwargs,
1754                        method: 'pkg-config',
1755                        required: slirp_opt == 'system' or
1756                                  slirp_opt == 'enabled' and not have_internal)
1757     if slirp.found()
1758       slirp_opt = 'system'
1759     elif have_internal
1760       slirp_opt = 'internal'
1761     else
1762       slirp_opt = 'disabled'
1763     endif
1764   endif
1765   if slirp_opt == 'internal'
1766     slirp_deps = []
1767     if targetos == 'windows'
1768       slirp_deps = cc.find_library('iphlpapi')
1769     endif
1770     slirp_conf = configuration_data()
1771     slirp_conf.set('SLIRP_MAJOR_VERSION', meson.project_version().split('.')[0])
1772     slirp_conf.set('SLIRP_MINOR_VERSION', meson.project_version().split('.')[1])
1773     slirp_conf.set('SLIRP_MICRO_VERSION', meson.project_version().split('.')[2])
1774     slirp_conf.set_quoted('SLIRP_VERSION_STRING', meson.project_version())
1775     slirp_cargs = ['-DG_LOG_DOMAIN="Slirp"']
1776     slirp_files = [
1777       'slirp/src/arp_table.c',
1778       'slirp/src/bootp.c',
1779       'slirp/src/cksum.c',
1780       'slirp/src/dhcpv6.c',
1781       'slirp/src/dnssearch.c',
1782       'slirp/src/if.c',
1783       'slirp/src/ip6_icmp.c',
1784       'slirp/src/ip6_input.c',
1785       'slirp/src/ip6_output.c',
1786       'slirp/src/ip_icmp.c',
1787       'slirp/src/ip_input.c',
1788       'slirp/src/ip_output.c',
1789       'slirp/src/mbuf.c',
1790       'slirp/src/misc.c',
1791       'slirp/src/ncsi.c',
1792       'slirp/src/ndp_table.c',
1793       'slirp/src/sbuf.c',
1794       'slirp/src/slirp.c',
1795       'slirp/src/socket.c',
1796       'slirp/src/state.c',
1797       'slirp/src/stream.c',
1798       'slirp/src/tcp_input.c',
1799       'slirp/src/tcp_output.c',
1800       'slirp/src/tcp_subr.c',
1801       'slirp/src/tcp_timer.c',
1802       'slirp/src/tftp.c',
1803       'slirp/src/udp.c',
1804       'slirp/src/udp6.c',
1805       'slirp/src/util.c',
1806       'slirp/src/version.c',
1807       'slirp/src/vmstate.c',
1808     ]
1809
1810     configure_file(
1811       input : 'slirp/src/libslirp-version.h.in',
1812       output : 'libslirp-version.h',
1813       configuration: slirp_conf)
1814
1815     slirp_inc = include_directories('slirp', 'slirp/src')
1816     libslirp = static_library('slirp',
1817                               build_by_default: false,
1818                               sources: slirp_files,
1819                               c_args: slirp_cargs,
1820                               include_directories: slirp_inc)
1821     slirp = declare_dependency(link_with: libslirp,
1822                                dependencies: slirp_deps,
1823                                include_directories: slirp_inc)
1824   endif
1825 endif
1826
1827 # For CFI, we need to compile slirp as a static library together with qemu.
1828 # This is because we register slirp functions as callbacks for QEMU Timers.
1829 # When using a system-wide shared libslirp, the type information for the
1830 # callback is missing and the timer call produces a false positive with CFI.
1831 #
1832 # Now that slirp_opt has been defined, check if the selected slirp is compatible
1833 # with control-flow integrity.
1834 if get_option('cfi') and slirp_opt == 'system'
1835   error('Control-Flow Integrity is not compatible with system-wide slirp.' \
1836          + ' Please configure with --enable-slirp=git')
1837 endif
1838
1839 fdt = not_found
1840 fdt_opt = get_option('fdt')
1841 if have_system
1842   if fdt_opt in ['enabled', 'auto', 'system']
1843     have_internal = fs.exists(meson.current_source_dir() / 'dtc/libfdt/Makefile.libfdt')
1844     fdt = cc.find_library('fdt', kwargs: static_kwargs,
1845                           required: fdt_opt == 'system' or
1846                                     fdt_opt == 'enabled' and not have_internal)
1847     if fdt.found() and cc.links('''
1848        #include <libfdt.h>
1849        #include <libfdt_env.h>
1850        int main(void) { fdt_check_full(NULL, 0); return 0; }''',
1851          dependencies: fdt)
1852       fdt_opt = 'system'
1853     elif have_internal
1854       fdt_opt = 'internal'
1855     else
1856       fdt_opt = 'disabled'
1857     endif
1858   endif
1859   if fdt_opt == 'internal'
1860     fdt_files = files(
1861       'dtc/libfdt/fdt.c',
1862       'dtc/libfdt/fdt_ro.c',
1863       'dtc/libfdt/fdt_wip.c',
1864       'dtc/libfdt/fdt_sw.c',
1865       'dtc/libfdt/fdt_rw.c',
1866       'dtc/libfdt/fdt_strerror.c',
1867       'dtc/libfdt/fdt_empty_tree.c',
1868       'dtc/libfdt/fdt_addresses.c',
1869       'dtc/libfdt/fdt_overlay.c',
1870       'dtc/libfdt/fdt_check.c',
1871     )
1872
1873     fdt_inc = include_directories('dtc/libfdt')
1874     libfdt = static_library('fdt',
1875                             build_by_default: false,
1876                             sources: fdt_files,
1877                             include_directories: fdt_inc)
1878     fdt = declare_dependency(link_with: libfdt,
1879                              include_directories: fdt_inc)
1880   endif
1881 endif
1882 if not fdt.found() and fdt_required.length() > 0
1883   error('fdt not available but required by targets ' + ', '.join(fdt_required))
1884 endif
1885
1886 config_host_data.set('CONFIG_CAPSTONE', capstone.found())
1887 config_host_data.set('CONFIG_FDT', fdt.found())
1888 config_host_data.set('CONFIG_SLIRP', slirp.found())
1889
1890 #####################
1891 # Generated sources #
1892 #####################
1893
1894 genh += configure_file(output: 'config-host.h', configuration: config_host_data)
1895
1896 hxtool = find_program('scripts/hxtool')
1897 shaderinclude = find_program('scripts/shaderinclude.pl')
1898 qapi_gen = find_program('scripts/qapi-gen.py')
1899 qapi_gen_depends = [ meson.source_root() / 'scripts/qapi/__init__.py',
1900                      meson.source_root() / 'scripts/qapi/commands.py',
1901                      meson.source_root() / 'scripts/qapi/common.py',
1902                      meson.source_root() / 'scripts/qapi/error.py',
1903                      meson.source_root() / 'scripts/qapi/events.py',
1904                      meson.source_root() / 'scripts/qapi/expr.py',
1905                      meson.source_root() / 'scripts/qapi/gen.py',
1906                      meson.source_root() / 'scripts/qapi/introspect.py',
1907                      meson.source_root() / 'scripts/qapi/parser.py',
1908                      meson.source_root() / 'scripts/qapi/schema.py',
1909                      meson.source_root() / 'scripts/qapi/source.py',
1910                      meson.source_root() / 'scripts/qapi/types.py',
1911                      meson.source_root() / 'scripts/qapi/visit.py',
1912                      meson.source_root() / 'scripts/qapi/common.py',
1913                      meson.source_root() / 'scripts/qapi-gen.py'
1914 ]
1915
1916 tracetool = [
1917   python, files('scripts/tracetool.py'),
1918    '--backend=' + config_host['TRACE_BACKENDS']
1919 ]
1920 tracetool_depends = files(
1921   'scripts/tracetool/backend/log.py',
1922   'scripts/tracetool/backend/__init__.py',
1923   'scripts/tracetool/backend/dtrace.py',
1924   'scripts/tracetool/backend/ftrace.py',
1925   'scripts/tracetool/backend/simple.py',
1926   'scripts/tracetool/backend/syslog.py',
1927   'scripts/tracetool/backend/ust.py',
1928   'scripts/tracetool/format/tcg_h.py',
1929   'scripts/tracetool/format/ust_events_c.py',
1930   'scripts/tracetool/format/ust_events_h.py',
1931   'scripts/tracetool/format/__init__.py',
1932   'scripts/tracetool/format/d.py',
1933   'scripts/tracetool/format/tcg_helper_c.py',
1934   'scripts/tracetool/format/simpletrace_stap.py',
1935   'scripts/tracetool/format/c.py',
1936   'scripts/tracetool/format/h.py',
1937   'scripts/tracetool/format/tcg_helper_h.py',
1938   'scripts/tracetool/format/log_stap.py',
1939   'scripts/tracetool/format/stap.py',
1940   'scripts/tracetool/format/tcg_helper_wrapper_h.py',
1941   'scripts/tracetool/__init__.py',
1942   'scripts/tracetool/transform.py',
1943   'scripts/tracetool/vcpu.py'
1944 )
1945
1946 qemu_version_cmd = [find_program('scripts/qemu-version.sh'),
1947                     meson.current_source_dir(),
1948                     config_host['PKGVERSION'], meson.project_version()]
1949 qemu_version = custom_target('qemu-version.h',
1950                              output: 'qemu-version.h',
1951                              command: qemu_version_cmd,
1952                              capture: true,
1953                              build_by_default: true,
1954                              build_always_stale: true)
1955 genh += qemu_version
1956
1957 hxdep = []
1958 hx_headers = [
1959   ['qemu-options.hx', 'qemu-options.def'],
1960   ['qemu-img-cmds.hx', 'qemu-img-cmds.h'],
1961 ]
1962 if have_system
1963   hx_headers += [
1964     ['hmp-commands.hx', 'hmp-commands.h'],
1965     ['hmp-commands-info.hx', 'hmp-commands-info.h'],
1966   ]
1967 endif
1968 foreach d : hx_headers
1969   hxdep += custom_target(d[1],
1970                 input: files(d[0]),
1971                 output: d[1],
1972                 capture: true,
1973                 build_by_default: true, # to be removed when added to a target
1974                 command: [hxtool, '-h', '@INPUT0@'])
1975 endforeach
1976 genh += hxdep
1977
1978 ###################
1979 # Collect sources #
1980 ###################
1981
1982 authz_ss = ss.source_set()
1983 blockdev_ss = ss.source_set()
1984 block_ss = ss.source_set()
1985 bsd_user_ss = ss.source_set()
1986 chardev_ss = ss.source_set()
1987 common_ss = ss.source_set()
1988 crypto_ss = ss.source_set()
1989 io_ss = ss.source_set()
1990 linux_user_ss = ss.source_set()
1991 qmp_ss = ss.source_set()
1992 qom_ss = ss.source_set()
1993 softmmu_ss = ss.source_set()
1994 specific_fuzz_ss = ss.source_set()
1995 specific_ss = ss.source_set()
1996 stub_ss = ss.source_set()
1997 trace_ss = ss.source_set()
1998 user_ss = ss.source_set()
1999 util_ss = ss.source_set()
2000
2001 # accel modules
2002 qtest_module_ss = ss.source_set()
2003 tcg_module_ss = ss.source_set()
2004
2005 modules = {}
2006 target_modules = {}
2007 hw_arch = {}
2008 target_arch = {}
2009 target_softmmu_arch = {}
2010 target_user_arch = {}
2011
2012 ###############
2013 # Trace files #
2014 ###############
2015
2016 # TODO: add each directory to the subdirs from its own meson.build, once
2017 # we have those
2018 trace_events_subdirs = [
2019   'crypto',
2020   'qapi',
2021   'qom',
2022   'monitor',
2023   'util',
2024 ]
2025 if have_user
2026   trace_events_subdirs += [ 'linux-user' ]
2027 endif
2028 if have_block
2029   trace_events_subdirs += [
2030     'authz',
2031     'block',
2032     'io',
2033     'nbd',
2034     'scsi',
2035   ]
2036 endif
2037 if have_system
2038   trace_events_subdirs += [
2039     'accel/kvm',
2040     'audio',
2041     'backends',
2042     'backends/tpm',
2043     'chardev',
2044     'ebpf',
2045     'hw/9pfs',
2046     'hw/acpi',
2047     'hw/adc',
2048     'hw/alpha',
2049     'hw/arm',
2050     'hw/audio',
2051     'hw/block',
2052     'hw/block/dataplane',
2053     'hw/char',
2054     'hw/display',
2055     'hw/dma',
2056     'hw/hppa',
2057     'hw/hyperv',
2058     'hw/i2c',
2059     'hw/i386',
2060     'hw/i386/xen',
2061     'hw/ide',
2062     'hw/input',
2063     'hw/intc',
2064     'hw/isa',
2065     'hw/mem',
2066     'hw/mips',
2067     'hw/misc',
2068     'hw/misc/macio',
2069     'hw/net',
2070     'hw/net/can',
2071     'hw/nvme',
2072     'hw/nvram',
2073     'hw/pci',
2074     'hw/pci-host',
2075     'hw/ppc',
2076     'hw/rdma',
2077     'hw/rdma/vmw',
2078     'hw/rtc',
2079     'hw/s390x',
2080     'hw/scsi',
2081     'hw/sd',
2082     'hw/sparc',
2083     'hw/sparc64',
2084     'hw/ssi',
2085     'hw/timer',
2086     'hw/tpm',
2087     'hw/usb',
2088     'hw/vfio',
2089     'hw/virtio',
2090     'hw/watchdog',
2091     'hw/xen',
2092     'hw/gpio',
2093     'migration',
2094     'net',
2095     'softmmu',
2096     'ui',
2097     'hw/remote',
2098   ]
2099 endif
2100 if have_system or have_user
2101   trace_events_subdirs += [
2102     'accel/tcg',
2103     'hw/core',
2104     'target/arm',
2105     'target/hppa',
2106     'target/i386',
2107     'target/i386/kvm',
2108     'target/mips/tcg',
2109     'target/ppc',
2110     'target/riscv',
2111     'target/s390x',
2112     'target/s390x/kvm',
2113     'target/sparc',
2114   ]
2115 endif
2116
2117 vhost_user = not_found
2118 if 'CONFIG_VHOST_USER' in config_host
2119   libvhost_user = subproject('libvhost-user')
2120   vhost_user = libvhost_user.get_variable('vhost_user_dep')
2121 endif
2122
2123 subdir('qapi')
2124 subdir('qobject')
2125 subdir('stubs')
2126 subdir('trace')
2127 subdir('util')
2128 subdir('qom')
2129 subdir('authz')
2130 subdir('crypto')
2131 subdir('ui')
2132
2133
2134 if enable_modules
2135   libmodulecommon = static_library('module-common', files('module-common.c') + genh, pic: true, c_args: '-DBUILD_DSO')
2136   modulecommon = declare_dependency(link_whole: libmodulecommon, compile_args: '-DBUILD_DSO')
2137 endif
2138
2139 stub_ss = stub_ss.apply(config_all, strict: false)
2140
2141 util_ss.add_all(trace_ss)
2142 util_ss = util_ss.apply(config_all, strict: false)
2143 libqemuutil = static_library('qemuutil',
2144                              sources: util_ss.sources() + stub_ss.sources() + genh,
2145                              dependencies: [util_ss.dependencies(), libm, threads, glib, socket, malloc, pixman])
2146 qemuutil = declare_dependency(link_with: libqemuutil,
2147                               sources: genh + version_res)
2148
2149 if have_system or have_user
2150   decodetree = generator(find_program('scripts/decodetree.py'),
2151                          output: 'decode-@BASENAME@.c.inc',
2152                          arguments: ['@INPUT@', '@EXTRA_ARGS@', '-o', '@OUTPUT@'])
2153   subdir('libdecnumber')
2154   subdir('target')
2155 endif
2156
2157 subdir('audio')
2158 subdir('io')
2159 subdir('chardev')
2160 subdir('fsdev')
2161 subdir('dump')
2162
2163 if have_block
2164   block_ss.add(files(
2165     'block.c',
2166     'blockjob.c',
2167     'job.c',
2168     'qemu-io-cmds.c',
2169   ))
2170   block_ss.add(when: 'CONFIG_REPLICATION', if_true: files('replication.c'))
2171
2172   subdir('nbd')
2173   subdir('scsi')
2174   subdir('block')
2175
2176   blockdev_ss.add(files(
2177     'blockdev.c',
2178     'blockdev-nbd.c',
2179     'iothread.c',
2180     'job-qmp.c',
2181   ), gnutls)
2182
2183   # os-posix.c contains POSIX-specific functions used by qemu-storage-daemon,
2184   # os-win32.c does not
2185   blockdev_ss.add(when: 'CONFIG_POSIX', if_true: files('os-posix.c'))
2186   softmmu_ss.add(when: 'CONFIG_WIN32', if_true: [files('os-win32.c')])
2187 endif
2188
2189 common_ss.add(files('cpus-common.c'))
2190
2191 subdir('softmmu')
2192
2193 common_ss.add(capstone)
2194 specific_ss.add(files('cpu.c', 'disas.c', 'gdbstub.c'), capstone)
2195
2196 # Work around a gcc bug/misfeature wherein constant propagation looks
2197 # through an alias:
2198 #   https://gcc.gnu.org/bugzilla/show_bug.cgi?id=99696
2199 # to guess that a const variable is always zero.  Without lto, this is
2200 # impossible, as the alias is restricted to page-vary-common.c.  Indeed,
2201 # without lto, not even the alias is required -- we simply use different
2202 # declarations in different compilation units.
2203 pagevary = files('page-vary-common.c')
2204 if get_option('b_lto')
2205   pagevary_flags = ['-fno-lto']
2206   if get_option('cfi')
2207     pagevary_flags += '-fno-sanitize=cfi-icall'
2208   endif
2209   pagevary = static_library('page-vary-common', sources: pagevary,
2210                             c_args: pagevary_flags)
2211   pagevary = declare_dependency(link_with: pagevary)
2212 endif
2213 common_ss.add(pagevary)
2214 specific_ss.add(files('page-vary.c'))
2215
2216 subdir('backends')
2217 subdir('disas')
2218 subdir('migration')
2219 subdir('monitor')
2220 subdir('net')
2221 subdir('replay')
2222 subdir('semihosting')
2223 subdir('hw')
2224 subdir('tcg')
2225 subdir('fpu')
2226 subdir('accel')
2227 subdir('plugins')
2228 subdir('bsd-user')
2229 subdir('linux-user')
2230 subdir('ebpf')
2231
2232 common_ss.add(libbpf)
2233
2234 bsd_user_ss.add(files('gdbstub.c'))
2235 specific_ss.add_all(when: 'CONFIG_BSD_USER', if_true: bsd_user_ss)
2236
2237 linux_user_ss.add(files('gdbstub.c', 'thunk.c'))
2238 specific_ss.add_all(when: 'CONFIG_LINUX_USER', if_true: linux_user_ss)
2239
2240 # needed for fuzzing binaries
2241 subdir('tests/qtest/libqos')
2242 subdir('tests/qtest/fuzz')
2243
2244 # accel modules
2245 tcg_real_module_ss = ss.source_set()
2246 tcg_real_module_ss.add_all(when: 'CONFIG_TCG_MODULAR', if_true: tcg_module_ss)
2247 specific_ss.add_all(when: 'CONFIG_TCG_BUILTIN', if_true: tcg_module_ss)
2248 target_modules += { 'accel' : { 'qtest': qtest_module_ss,
2249                                 'tcg': tcg_real_module_ss }}
2250
2251 ########################
2252 # Library dependencies #
2253 ########################
2254
2255 modinfo_collect = find_program('scripts/modinfo-collect.py')
2256 modinfo_generate = find_program('scripts/modinfo-generate.py')
2257 modinfo_files = []
2258
2259 block_mods = []
2260 softmmu_mods = []
2261 foreach d, list : modules
2262   foreach m, module_ss : list
2263     if enable_modules and targetos != 'windows'
2264       module_ss = module_ss.apply(config_all, strict: false)
2265       sl = static_library(d + '-' + m, [genh, module_ss.sources()],
2266                           dependencies: [modulecommon, module_ss.dependencies()], pic: true)
2267       if d == 'block'
2268         block_mods += sl
2269       else
2270         softmmu_mods += sl
2271       endif
2272       if module_ss.sources() != []
2273         # FIXME: Should use sl.extract_all_objects(recursive: true) as
2274         # input. Sources can be used multiple times but objects are
2275         # unique when it comes to lookup in compile_commands.json.
2276         # Depnds on a mesion version with
2277         # https://github.com/mesonbuild/meson/pull/8900
2278         modinfo_files += custom_target(d + '-' + m + '.modinfo',
2279                                        output: d + '-' + m + '.modinfo',
2280                                        input: module_ss.sources(),
2281                                        capture: true,
2282                                        command: [modinfo_collect, '@INPUT@'])
2283       endif
2284     else
2285       if d == 'block'
2286         block_ss.add_all(module_ss)
2287       else
2288         softmmu_ss.add_all(module_ss)
2289       endif
2290     endif
2291   endforeach
2292 endforeach
2293
2294 foreach d, list : target_modules
2295   foreach m, module_ss : list
2296     if enable_modules and targetos != 'windows'
2297       foreach target : target_dirs
2298         if target.endswith('-softmmu')
2299           config_target = config_target_mak[target]
2300           config_target += config_host
2301           target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
2302           c_args = ['-DNEED_CPU_H',
2303                     '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
2304                     '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
2305           target_module_ss = module_ss.apply(config_target, strict: false)
2306           if target_module_ss.sources() != []
2307             module_name = d + '-' + m + '-' + config_target['TARGET_NAME']
2308             sl = static_library(module_name,
2309                                 [genh, target_module_ss.sources()],
2310                                 dependencies: [modulecommon, target_module_ss.dependencies()],
2311                                 include_directories: target_inc,
2312                                 c_args: c_args,
2313                                 pic: true)
2314             softmmu_mods += sl
2315             # FIXME: Should use sl.extract_all_objects(recursive: true) too.
2316             modinfo_files += custom_target(module_name + '.modinfo',
2317                                            output: module_name + '.modinfo',
2318                                            input: target_module_ss.sources(),
2319                                            capture: true,
2320                                            command: [modinfo_collect, '--target', target, '@INPUT@'])
2321           endif
2322         endif
2323       endforeach
2324     else
2325       specific_ss.add_all(module_ss)
2326     endif
2327   endforeach
2328 endforeach
2329
2330 if enable_modules
2331   modinfo_src = custom_target('modinfo.c',
2332                               output: 'modinfo.c',
2333                               input: modinfo_files,
2334                               command: [modinfo_generate, '@INPUT@'],
2335                               capture: true)
2336   modinfo_lib = static_library('modinfo', modinfo_src)
2337   modinfo_dep = declare_dependency(link_whole: modinfo_lib)
2338   softmmu_ss.add(modinfo_dep)
2339 endif
2340
2341 nm = find_program('nm')
2342 undefsym = find_program('scripts/undefsym.py')
2343 block_syms = custom_target('block.syms', output: 'block.syms',
2344                              input: [libqemuutil, block_mods],
2345                              capture: true,
2346                              command: [undefsym, nm, '@INPUT@'])
2347 qemu_syms = custom_target('qemu.syms', output: 'qemu.syms',
2348                              input: [libqemuutil, softmmu_mods],
2349                              capture: true,
2350                              command: [undefsym, nm, '@INPUT@'])
2351
2352 qom_ss = qom_ss.apply(config_host, strict: false)
2353 libqom = static_library('qom', qom_ss.sources() + genh,
2354                         dependencies: [qom_ss.dependencies()],
2355                         name_suffix: 'fa')
2356
2357 qom = declare_dependency(link_whole: libqom)
2358
2359 authz_ss = authz_ss.apply(config_host, strict: false)
2360 libauthz = static_library('authz', authz_ss.sources() + genh,
2361                           dependencies: [authz_ss.dependencies()],
2362                           name_suffix: 'fa',
2363                           build_by_default: false)
2364
2365 authz = declare_dependency(link_whole: libauthz,
2366                            dependencies: qom)
2367
2368 crypto_ss = crypto_ss.apply(config_host, strict: false)
2369 libcrypto = static_library('crypto', crypto_ss.sources() + genh,
2370                            dependencies: [crypto_ss.dependencies()],
2371                            name_suffix: 'fa',
2372                            build_by_default: false)
2373
2374 crypto = declare_dependency(link_whole: libcrypto,
2375                             dependencies: [authz, qom])
2376
2377 io_ss = io_ss.apply(config_host, strict: false)
2378 libio = static_library('io', io_ss.sources() + genh,
2379                        dependencies: [io_ss.dependencies()],
2380                        link_with: libqemuutil,
2381                        name_suffix: 'fa',
2382                        build_by_default: false)
2383
2384 io = declare_dependency(link_whole: libio, dependencies: [crypto, qom])
2385
2386 libmigration = static_library('migration', sources: migration_files + genh,
2387                               name_suffix: 'fa',
2388                               build_by_default: false)
2389 migration = declare_dependency(link_with: libmigration,
2390                                dependencies: [zlib, qom, io])
2391 softmmu_ss.add(migration)
2392
2393 block_ss = block_ss.apply(config_host, strict: false)
2394 libblock = static_library('block', block_ss.sources() + genh,
2395                           dependencies: block_ss.dependencies(),
2396                           link_depends: block_syms,
2397                           name_suffix: 'fa',
2398                           build_by_default: false)
2399
2400 block = declare_dependency(link_whole: [libblock],
2401                            link_args: '@block.syms',
2402                            dependencies: [crypto, io])
2403
2404 blockdev_ss = blockdev_ss.apply(config_host, strict: false)
2405 libblockdev = static_library('blockdev', blockdev_ss.sources() + genh,
2406                              dependencies: blockdev_ss.dependencies(),
2407                              name_suffix: 'fa',
2408                              build_by_default: false)
2409
2410 blockdev = declare_dependency(link_whole: [libblockdev],
2411                               dependencies: [block])
2412
2413 qmp_ss = qmp_ss.apply(config_host, strict: false)
2414 libqmp = static_library('qmp', qmp_ss.sources() + genh,
2415                         dependencies: qmp_ss.dependencies(),
2416                         name_suffix: 'fa',
2417                         build_by_default: false)
2418
2419 qmp = declare_dependency(link_whole: [libqmp])
2420
2421 libchardev = static_library('chardev', chardev_ss.sources() + genh,
2422                             name_suffix: 'fa',
2423                             dependencies: [gnutls],
2424                             build_by_default: false)
2425
2426 chardev = declare_dependency(link_whole: libchardev)
2427
2428 libhwcore = static_library('hwcore', sources: hwcore_files + genh,
2429                            name_suffix: 'fa',
2430                            build_by_default: false)
2431 hwcore = declare_dependency(link_whole: libhwcore)
2432 common_ss.add(hwcore)
2433
2434 ###########
2435 # Targets #
2436 ###########
2437
2438 foreach m : block_mods + softmmu_mods
2439   shared_module(m.name(),
2440                 name_prefix: '',
2441                 link_whole: m,
2442                 install: true,
2443                 install_dir: qemu_moddir)
2444 endforeach
2445
2446 softmmu_ss.add(authz, blockdev, chardev, crypto, io, qmp)
2447 common_ss.add(qom, qemuutil)
2448
2449 common_ss.add_all(when: 'CONFIG_SOFTMMU', if_true: [softmmu_ss])
2450 common_ss.add_all(when: 'CONFIG_USER_ONLY', if_true: user_ss)
2451
2452 common_all = common_ss.apply(config_all, strict: false)
2453 common_all = static_library('common',
2454                             build_by_default: false,
2455                             sources: common_all.sources() + genh,
2456                             implicit_include_directories: false,
2457                             dependencies: common_all.dependencies(),
2458                             name_suffix: 'fa')
2459
2460 feature_to_c = find_program('scripts/feature_to_c.sh')
2461
2462 emulators = {}
2463 foreach target : target_dirs
2464   config_target = config_target_mak[target]
2465   target_name = config_target['TARGET_NAME']
2466   arch = config_target['TARGET_BASE_ARCH']
2467   arch_srcs = [config_target_h[target]]
2468   arch_deps = []
2469   c_args = ['-DNEED_CPU_H',
2470             '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
2471             '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
2472   link_args = emulator_link_args
2473
2474   config_target += config_host
2475   target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
2476   if targetos == 'linux'
2477     target_inc += include_directories('linux-headers', is_system: true)
2478   endif
2479   if target.endswith('-softmmu')
2480     qemu_target_name = 'qemu-system-' + target_name
2481     target_type='system'
2482     t = target_softmmu_arch[arch].apply(config_target, strict: false)
2483     arch_srcs += t.sources()
2484     arch_deps += t.dependencies()
2485
2486     hw_dir = target_name == 'sparc64' ? 'sparc64' : arch
2487     hw = hw_arch[hw_dir].apply(config_target, strict: false)
2488     arch_srcs += hw.sources()
2489     arch_deps += hw.dependencies()
2490
2491     arch_srcs += config_devices_h[target]
2492     link_args += ['@block.syms', '@qemu.syms']
2493   else
2494     abi = config_target['TARGET_ABI_DIR']
2495     target_type='user'
2496     qemu_target_name = 'qemu-' + target_name
2497     if arch in target_user_arch
2498       t = target_user_arch[arch].apply(config_target, strict: false)
2499       arch_srcs += t.sources()
2500       arch_deps += t.dependencies()
2501     endif
2502     if 'CONFIG_LINUX_USER' in config_target
2503       base_dir = 'linux-user'
2504       target_inc += include_directories('linux-user/host/' / config_host['ARCH'])
2505     else
2506       base_dir = 'bsd-user'
2507       target_inc += include_directories('bsd-user/freebsd')
2508     endif
2509     target_inc += include_directories(
2510       base_dir,
2511       base_dir / abi,
2512     )
2513     if 'CONFIG_LINUX_USER' in config_target
2514       dir = base_dir / abi
2515       arch_srcs += files(dir / 'signal.c', dir / 'cpu_loop.c')
2516       if config_target.has_key('TARGET_SYSTBL_ABI')
2517         arch_srcs += \
2518           syscall_nr_generators[abi].process(base_dir / abi / config_target['TARGET_SYSTBL'],
2519                                              extra_args : config_target['TARGET_SYSTBL_ABI'])
2520       endif
2521     endif
2522   endif
2523
2524   if 'TARGET_XML_FILES' in config_target
2525     gdbstub_xml = custom_target(target + '-gdbstub-xml.c',
2526                                 output: target + '-gdbstub-xml.c',
2527                                 input: files(config_target['TARGET_XML_FILES'].split()),
2528                                 command: [feature_to_c, '@INPUT@'],
2529                                 capture: true)
2530     arch_srcs += gdbstub_xml
2531   endif
2532
2533   t = target_arch[arch].apply(config_target, strict: false)
2534   arch_srcs += t.sources()
2535   arch_deps += t.dependencies()
2536
2537   target_common = common_ss.apply(config_target, strict: false)
2538   objects = common_all.extract_objects(target_common.sources())
2539   deps = target_common.dependencies()
2540
2541   target_specific = specific_ss.apply(config_target, strict: false)
2542   arch_srcs += target_specific.sources()
2543   arch_deps += target_specific.dependencies()
2544
2545   lib = static_library('qemu-' + target,
2546                  sources: arch_srcs + genh,
2547                  dependencies: arch_deps,
2548                  objects: objects,
2549                  include_directories: target_inc,
2550                  c_args: c_args,
2551                  build_by_default: false,
2552                  name_suffix: 'fa')
2553
2554   if target.endswith('-softmmu')
2555     execs = [{
2556       'name': 'qemu-system-' + target_name,
2557       'gui': false,
2558       'sources': files('softmmu/main.c'),
2559       'dependencies': []
2560     }]
2561     if targetos == 'windows' and (sdl.found() or gtk.found())
2562       execs += [{
2563         'name': 'qemu-system-' + target_name + 'w',
2564         'gui': true,
2565         'sources': files('softmmu/main.c'),
2566         'dependencies': []
2567       }]
2568     endif
2569     if config_host.has_key('CONFIG_FUZZ')
2570       specific_fuzz = specific_fuzz_ss.apply(config_target, strict: false)
2571       execs += [{
2572         'name': 'qemu-fuzz-' + target_name,
2573         'gui': false,
2574         'sources': specific_fuzz.sources(),
2575         'dependencies': specific_fuzz.dependencies(),
2576       }]
2577     endif
2578   else
2579     execs = [{
2580       'name': 'qemu-' + target_name,
2581       'gui': false,
2582       'sources': [],
2583       'dependencies': []
2584     }]
2585   endif
2586   foreach exe: execs
2587     exe_name = exe['name']
2588     if targetos == 'darwin'
2589       exe_name += '-unsigned'
2590     endif
2591
2592     emulator = executable(exe_name, exe['sources'],
2593                install: true,
2594                c_args: c_args,
2595                dependencies: arch_deps + deps + exe['dependencies'],
2596                objects: lib.extract_all_objects(recursive: true),
2597                link_language: link_language,
2598                link_depends: [block_syms, qemu_syms] + exe.get('link_depends', []),
2599                link_args: link_args,
2600                gui_app: exe['gui'])
2601
2602     if targetos == 'darwin'
2603       icon = 'pc-bios/qemu.rsrc'
2604       build_input = [emulator, files(icon)]
2605       install_input = [
2606         get_option('bindir') / exe_name,
2607         meson.current_source_dir() / icon
2608       ]
2609       if 'CONFIG_HVF' in config_target
2610         entitlements = 'accel/hvf/entitlements.plist'
2611         build_input += files(entitlements)
2612         install_input += meson.current_source_dir() / entitlements
2613       endif
2614
2615       emulators += {exe['name'] : custom_target(exe['name'],
2616                    input: build_input,
2617                    output: exe['name'],
2618                    command: [
2619                      files('scripts/entitlement.sh'),
2620                      '@OUTPUT@',
2621                      '@INPUT@'
2622                    ])
2623       }
2624
2625       meson.add_install_script('scripts/entitlement.sh', '--install',
2626                                get_option('bindir') / exe['name'],
2627                                install_input)
2628     else
2629       emulators += {exe['name']: emulator}
2630     endif
2631
2632     if 'CONFIG_TRACE_SYSTEMTAP' in config_host
2633       foreach stp: [
2634         {'ext': '.stp-build', 'fmt': 'stap', 'bin': meson.current_build_dir() / exe['name'], 'install': false},
2635         {'ext': '.stp', 'fmt': 'stap', 'bin': get_option('prefix') / get_option('bindir') / exe['name'], 'install': true},
2636         {'ext': '-simpletrace.stp', 'fmt': 'simpletrace-stap', 'bin': '', 'install': true},
2637         {'ext': '-log.stp', 'fmt': 'log-stap', 'bin': '', 'install': true},
2638       ]
2639         custom_target(exe['name'] + stp['ext'],
2640                       input: trace_events_all,
2641                       output: exe['name'] + stp['ext'],
2642                       install: stp['install'],
2643                       install_dir: get_option('datadir') / 'systemtap/tapset',
2644                       command: [
2645                         tracetool, '--group=all', '--format=' + stp['fmt'],
2646                         '--binary=' + stp['bin'],
2647                         '--target-name=' + target_name,
2648                         '--target-type=' + target_type,
2649                         '--probe-prefix=qemu.' + target_type + '.' + target_name,
2650                         '@INPUT@', '@OUTPUT@'
2651                       ],
2652                       depend_files: tracetool_depends)
2653       endforeach
2654     endif
2655   endforeach
2656 endforeach
2657
2658 # Other build targets
2659
2660 if 'CONFIG_PLUGIN' in config_host
2661   install_headers('include/qemu/qemu-plugin.h')
2662 endif
2663
2664 if 'CONFIG_GUEST_AGENT' in config_host
2665   subdir('qga')
2666 elif get_option('guest_agent_msi').enabled()
2667   error('Guest agent MSI requested, but the guest agent is not being built')
2668 endif
2669
2670 # Don't build qemu-keymap if xkbcommon is not explicitly enabled
2671 # when we don't build tools or system
2672 if xkbcommon.found()
2673   # used for the update-keymaps target, so include rules even if !have_tools
2674   qemu_keymap = executable('qemu-keymap', files('qemu-keymap.c', 'ui/input-keymap.c') + genh,
2675                            dependencies: [qemuutil, xkbcommon], install: have_tools)
2676 endif
2677
2678 if have_tools
2679   qemu_img = executable('qemu-img', [files('qemu-img.c'), hxdep],
2680              dependencies: [authz, block, crypto, io, qom, qemuutil], install: true)
2681   qemu_io = executable('qemu-io', files('qemu-io.c'),
2682              dependencies: [block, qemuutil], install: true)
2683   qemu_nbd = executable('qemu-nbd', files('qemu-nbd.c'),
2684                dependencies: [blockdev, qemuutil, gnutls], install: true)
2685
2686   subdir('storage-daemon')
2687   subdir('contrib/rdmacm-mux')
2688   subdir('contrib/elf2dmp')
2689
2690   executable('qemu-edid', files('qemu-edid.c', 'hw/display/edid-generate.c'),
2691              dependencies: qemuutil,
2692              install: true)
2693
2694   if 'CONFIG_VHOST_USER' in config_host
2695     subdir('contrib/vhost-user-blk')
2696     subdir('contrib/vhost-user-gpu')
2697     subdir('contrib/vhost-user-input')
2698     subdir('contrib/vhost-user-scsi')
2699   endif
2700
2701   if targetos == 'linux'
2702     executable('qemu-bridge-helper', files('qemu-bridge-helper.c'),
2703                dependencies: [qemuutil, libcap_ng],
2704                install: true,
2705                install_dir: get_option('libexecdir'))
2706
2707     executable('qemu-pr-helper', files('scsi/qemu-pr-helper.c', 'scsi/utils.c'),
2708                dependencies: [authz, crypto, io, qom, qemuutil,
2709                               libcap_ng, mpathpersist],
2710                install: true)
2711   endif
2712
2713   if have_ivshmem
2714     subdir('contrib/ivshmem-client')
2715     subdir('contrib/ivshmem-server')
2716   endif
2717 endif
2718
2719 subdir('scripts')
2720 subdir('tools')
2721 subdir('pc-bios')
2722 subdir('docs')
2723 subdir('tests')
2724 if gtk.found()
2725   subdir('po')
2726 endif
2727
2728 if host_machine.system() == 'windows'
2729   nsis_cmd = [
2730     find_program('scripts/nsis.py'),
2731     '@OUTPUT@',
2732     get_option('prefix'),
2733     meson.current_source_dir(),
2734     host_machine.cpu(),
2735     '--',
2736     '-DDISPLAYVERSION=' + meson.project_version(),
2737   ]
2738   if build_docs
2739     nsis_cmd += '-DCONFIG_DOCUMENTATION=y'
2740   endif
2741   if gtk.found()
2742     nsis_cmd += '-DCONFIG_GTK=y'
2743   endif
2744
2745   nsis = custom_target('nsis',
2746                        output: 'qemu-setup-' + meson.project_version() + '.exe',
2747                        input: files('qemu.nsi'),
2748                        build_always_stale: true,
2749                        command: nsis_cmd + ['@INPUT@'])
2750   alias_target('installer', nsis)
2751 endif
2752
2753 #########################
2754 # Configuration summary #
2755 #########################
2756
2757 # Directories
2758 summary_info = {}
2759 summary_info += {'Install prefix':    get_option('prefix')}
2760 summary_info += {'BIOS directory':    qemu_datadir}
2761 summary_info += {'firmware path':     get_option('qemu_firmwarepath')}
2762 summary_info += {'binary directory':  get_option('bindir')}
2763 summary_info += {'library directory': get_option('libdir')}
2764 summary_info += {'module directory':  qemu_moddir}
2765 summary_info += {'libexec directory': get_option('libexecdir')}
2766 summary_info += {'include directory': get_option('includedir')}
2767 summary_info += {'config directory':  get_option('sysconfdir')}
2768 if targetos != 'windows'
2769   summary_info += {'local state directory': get_option('localstatedir')}
2770   summary_info += {'Manual directory':      get_option('mandir')}
2771 else
2772   summary_info += {'local state directory': 'queried at runtime'}
2773 endif
2774 summary_info += {'Doc directory':     get_option('docdir')}
2775 summary_info += {'Build directory':   meson.current_build_dir()}
2776 summary_info += {'Source path':       meson.current_source_dir()}
2777 summary_info += {'GIT submodules':    config_host['GIT_SUBMODULES']}
2778 summary(summary_info, bool_yn: true, section: 'Directories')
2779
2780 # Host binaries
2781 summary_info = {}
2782 summary_info += {'git':               config_host['GIT']}
2783 summary_info += {'make':              config_host['MAKE']}
2784 summary_info += {'python':            '@0@ (version: @1@)'.format(python.full_path(), python.language_version())}
2785 summary_info += {'sphinx-build':      sphinx_build.found()}
2786 if config_host.has_key('HAVE_GDB_BIN')
2787   summary_info += {'gdb':             config_host['HAVE_GDB_BIN']}
2788 endif
2789 summary_info += {'genisoimage':       config_host['GENISOIMAGE']}
2790 if targetos == 'windows' and config_host.has_key('CONFIG_GUEST_AGENT')
2791   summary_info += {'wixl':            wixl.found() ? wixl.full_path() : false}
2792 endif
2793 if slirp_opt != 'disabled' and 'CONFIG_SLIRP_SMBD' in config_host
2794   summary_info += {'smbd':            config_host['CONFIG_SMBD_COMMAND']}
2795 endif
2796 summary(summary_info, bool_yn: true, section: 'Host binaries')
2797
2798 # Configurable features
2799 summary_info = {}
2800 summary_info += {'Documentation':     build_docs}
2801 summary_info += {'system-mode emulation': have_system}
2802 summary_info += {'user-mode emulation': have_user}
2803 summary_info += {'block layer':       have_block}
2804 summary_info += {'Install blobs':     get_option('install_blobs')}
2805 summary_info += {'module support':    config_host.has_key('CONFIG_MODULES')}
2806 if config_host.has_key('CONFIG_MODULES')
2807   summary_info += {'alternative module path': config_host.has_key('CONFIG_MODULE_UPGRADES')}
2808 endif
2809 summary_info += {'plugin support':    config_host.has_key('CONFIG_PLUGIN')}
2810 summary_info += {'fuzzing support':   config_host.has_key('CONFIG_FUZZ')}
2811 if have_system
2812   summary_info += {'Audio drivers':     config_host['CONFIG_AUDIO_DRIVERS']}
2813 endif
2814 summary_info += {'Trace backends':    config_host['TRACE_BACKENDS']}
2815 if config_host['TRACE_BACKENDS'].split().contains('simple')
2816   summary_info += {'Trace output file': config_host['CONFIG_TRACE_FILE'] + '-<pid>'}
2817 endif
2818 summary_info += {'QOM debugging':     config_host.has_key('CONFIG_QOM_CAST_DEBUG')}
2819 summary_info += {'vhost-kernel support': config_host.has_key('CONFIG_VHOST_KERNEL')}
2820 summary_info += {'vhost-net support': config_host.has_key('CONFIG_VHOST_NET')}
2821 summary_info += {'vhost-crypto support': config_host.has_key('CONFIG_VHOST_CRYPTO')}
2822 summary_info += {'vhost-scsi support': config_host.has_key('CONFIG_VHOST_SCSI')}
2823 summary_info += {'vhost-vsock support': config_host.has_key('CONFIG_VHOST_VSOCK')}
2824 summary_info += {'vhost-user support': config_host.has_key('CONFIG_VHOST_USER')}
2825 summary_info += {'vhost-user-blk server support': have_vhost_user_blk_server}
2826 summary_info += {'vhost-user-fs support': config_host.has_key('CONFIG_VHOST_USER_FS')}
2827 summary_info += {'vhost-vdpa support': config_host.has_key('CONFIG_VHOST_VDPA')}
2828 summary_info += {'build guest agent': config_host.has_key('CONFIG_GUEST_AGENT')}
2829 summary(summary_info, bool_yn: true, section: 'Configurable features')
2830
2831 # Compilation information
2832 summary_info = {}
2833 summary_info += {'host CPU':          cpu}
2834 summary_info += {'host endianness':   build_machine.endian()}
2835 summary_info += {'C compiler':        ' '.join(meson.get_compiler('c').cmd_array())}
2836 summary_info += {'Host C compiler':   ' '.join(meson.get_compiler('c', native: true).cmd_array())}
2837 if link_language == 'cpp'
2838   summary_info += {'C++ compiler':    ' '.join(meson.get_compiler('cpp').cmd_array())}
2839 else
2840   summary_info += {'C++ compiler':      false}
2841 endif
2842 if targetos == 'darwin'
2843   summary_info += {'Objective-C compiler': ' '.join(meson.get_compiler('objc').cmd_array())}
2844 endif
2845 if targetos == 'windows'
2846   if 'WIN_SDK' in config_host
2847     summary_info += {'Windows SDK':   config_host['WIN_SDK']}
2848   endif
2849 endif
2850 summary_info += {'CFLAGS':            ' '.join(get_option('c_args')
2851                                                + ['-O' + get_option('optimization')]
2852                                                + (get_option('debug') ? ['-g'] : []))}
2853 if link_language == 'cpp'
2854   summary_info += {'CXXFLAGS':        ' '.join(get_option('cpp_args')
2855                                                + ['-O' + get_option('optimization')]
2856                                                + (get_option('debug') ? ['-g'] : []))}
2857 endif
2858 link_args = get_option(link_language + '_link_args')
2859 if link_args.length() > 0
2860   summary_info += {'LDFLAGS':         ' '.join(link_args)}
2861 endif
2862 summary_info += {'QEMU_CFLAGS':       config_host['QEMU_CFLAGS']}
2863 summary_info += {'QEMU_LDFLAGS':      config_host['QEMU_LDFLAGS']}
2864 summary_info += {'profiler':          config_host.has_key('CONFIG_PROFILER')}
2865 summary_info += {'link-time optimization (LTO)': get_option('b_lto')}
2866 summary_info += {'PIE':               get_option('b_pie')}
2867 summary_info += {'static build':      config_host.has_key('CONFIG_STATIC')}
2868 summary_info += {'malloc trim support': has_malloc_trim}
2869 summary_info += {'membarrier':        config_host.has_key('CONFIG_MEMBARRIER')}
2870 summary_info += {'debug stack usage': config_host.has_key('CONFIG_DEBUG_STACK_USAGE')}
2871 summary_info += {'mutex debugging':   config_host.has_key('CONFIG_DEBUG_MUTEX')}
2872 summary_info += {'memory allocator':  get_option('malloc')}
2873 summary_info += {'avx2 optimization': config_host.has_key('CONFIG_AVX2_OPT')}
2874 summary_info += {'avx512f optimization': config_host.has_key('CONFIG_AVX512F_OPT')}
2875 summary_info += {'gprof enabled':     config_host.has_key('CONFIG_GPROF')}
2876 summary_info += {'gcov':              get_option('b_coverage')}
2877 summary_info += {'thread sanitizer':  config_host.has_key('CONFIG_TSAN')}
2878 summary_info += {'CFI support':       get_option('cfi')}
2879 if get_option('cfi')
2880   summary_info += {'CFI debug support': get_option('cfi_debug')}
2881 endif
2882 summary_info += {'strip binaries':    get_option('strip')}
2883 summary_info += {'sparse':            sparse.found() ? sparse.full_path() : false}
2884 summary_info += {'mingw32 support':   targetos == 'windows'}
2885
2886 # snarf the cross-compilation information for tests
2887 foreach target: target_dirs
2888   tcg_mak = meson.current_build_dir() / 'tests/tcg' / 'config-' + target + '.mak'
2889   if fs.exists(tcg_mak)
2890     config_cross_tcg = keyval.load(tcg_mak)
2891     target = config_cross_tcg['TARGET_NAME']
2892     compiler = ''
2893     if 'DOCKER_CROSS_CC_GUEST' in config_cross_tcg
2894       summary_info += {target + ' tests': config_cross_tcg['DOCKER_CROSS_CC_GUEST'] +
2895                                           ' via ' + config_cross_tcg['DOCKER_IMAGE']}
2896     elif 'CROSS_CC_GUEST' in config_cross_tcg
2897       summary_info += {target + ' tests'
2898                                 : config_cross_tcg['CROSS_CC_GUEST'] }
2899     endif
2900    endif
2901 endforeach
2902
2903 summary(summary_info, bool_yn: true, section: 'Compilation')
2904
2905 # Targets and accelerators
2906 summary_info = {}
2907 if have_system
2908   summary_info += {'KVM support':       config_all.has_key('CONFIG_KVM')}
2909   summary_info += {'HAX support':       config_all.has_key('CONFIG_HAX')}
2910   summary_info += {'HVF support':       config_all.has_key('CONFIG_HVF')}
2911   summary_info += {'WHPX support':      config_all.has_key('CONFIG_WHPX')}
2912   summary_info += {'NVMM support':      config_all.has_key('CONFIG_NVMM')}
2913   summary_info += {'Xen support':       config_host.has_key('CONFIG_XEN_BACKEND')}
2914   if config_host.has_key('CONFIG_XEN_BACKEND')
2915     summary_info += {'xen ctrl version':  config_host['CONFIG_XEN_CTRL_INTERFACE_VERSION']}
2916   endif
2917 endif
2918 summary_info += {'TCG support':       config_all.has_key('CONFIG_TCG')}
2919 if config_all.has_key('CONFIG_TCG')
2920   if get_option('tcg_interpreter')
2921     summary_info += {'TCG backend':   'TCI (TCG with bytecode interpreter, experimental and slow)'}
2922   else
2923     summary_info += {'TCG backend':   'native (@0@)'.format(cpu)}
2924   endif
2925   summary_info += {'TCG debug enabled': config_host.has_key('CONFIG_DEBUG_TCG')}
2926 endif
2927 summary_info += {'target list':       ' '.join(target_dirs)}
2928 if have_system
2929   summary_info += {'default devices':   get_option('default_devices')}
2930   summary_info += {'out of process emulation': multiprocess_allowed}
2931 endif
2932 summary(summary_info, bool_yn: true, section: 'Targets and accelerators')
2933
2934 # Block layer
2935 summary_info = {}
2936 summary_info += {'coroutine backend': config_host['CONFIG_COROUTINE_BACKEND']}
2937 summary_info += {'coroutine pool':    config_host['CONFIG_COROUTINE_POOL'] == '1'}
2938 if have_block
2939   summary_info += {'Block whitelist (rw)': config_host['CONFIG_BDRV_RW_WHITELIST']}
2940   summary_info += {'Block whitelist (ro)': config_host['CONFIG_BDRV_RO_WHITELIST']}
2941   summary_info += {'VirtFS support':    have_virtfs}
2942   summary_info += {'build virtiofs daemon': have_virtiofsd}
2943   summary_info += {'Live block migration': config_host.has_key('CONFIG_LIVE_BLOCK_MIGRATION')}
2944   summary_info += {'replication support': config_host.has_key('CONFIG_REPLICATION')}
2945   summary_info += {'bochs support':     config_host.has_key('CONFIG_BOCHS')}
2946   summary_info += {'cloop support':     config_host.has_key('CONFIG_CLOOP')}
2947   summary_info += {'dmg support':       config_host.has_key('CONFIG_DMG')}
2948   summary_info += {'qcow v1 support':   config_host.has_key('CONFIG_QCOW1')}
2949   summary_info += {'vdi support':       config_host.has_key('CONFIG_VDI')}
2950   summary_info += {'vvfat support':     config_host.has_key('CONFIG_VVFAT')}
2951   summary_info += {'qed support':       config_host.has_key('CONFIG_QED')}
2952   summary_info += {'parallels support': config_host.has_key('CONFIG_PARALLELS')}
2953   summary_info += {'FUSE exports':      fuse.found()}
2954 endif
2955 summary(summary_info, bool_yn: true, section: 'Block layer support')
2956
2957 # Crypto
2958 summary_info = {}
2959 summary_info += {'TLS priority':      config_host['CONFIG_TLS_PRIORITY']}
2960 summary_info += {'GNUTLS support':    gnutls.found()}
2961 # TODO: add back version
2962 summary_info += {'libgcrypt':         gcrypt.found()}
2963 # TODO: add back version
2964 summary_info += {'nettle':            nettle.found()}
2965 if nettle.found()
2966    summary_info += {'  XTS':             xts != 'private'}
2967 endif
2968 summary_info += {'crypto afalg':      config_host.has_key('CONFIG_AF_ALG')}
2969 summary_info += {'rng-none':          config_host.has_key('CONFIG_RNG_NONE')}
2970 summary_info += {'Linux keyring':     config_host.has_key('CONFIG_SECRET_KEYRING')}
2971 summary(summary_info, bool_yn: true, section: 'Crypto')
2972
2973 # Libraries
2974 summary_info = {}
2975 if targetos == 'darwin'
2976   summary_info += {'Cocoa support':   cocoa.found()}
2977 endif
2978 # TODO: add back version
2979 summary_info += {'SDL support':       sdl.found()}
2980 summary_info += {'SDL image support': sdl_image.found()}
2981 # TODO: add back version
2982 summary_info += {'GTK support':       gtk.found()}
2983 summary_info += {'pixman':            pixman.found()}
2984 # TODO: add back version
2985 summary_info += {'VTE support':       vte.found()}
2986 # TODO: add back version
2987 summary_info += {'slirp support':     slirp_opt == 'disabled' ? false : slirp_opt}
2988 summary_info += {'libtasn1':          tasn1.found()}
2989 summary_info += {'PAM':               pam.found()}
2990 summary_info += {'iconv support':     iconv.found()}
2991 summary_info += {'curses support':    curses.found()}
2992 # TODO: add back version
2993 summary_info += {'virgl support':     virgl.found()}
2994 summary_info += {'curl support':      curl.found()}
2995 summary_info += {'Multipath support': mpathpersist.found()}
2996 summary_info += {'VNC support':       vnc.found()}
2997 if vnc.found()
2998   summary_info += {'VNC SASL support':  sasl.found()}
2999   summary_info += {'VNC JPEG support':  jpeg.found()}
3000   summary_info += {'VNC PNG support':   png.found()}
3001 endif
3002 summary_info += {'brlapi support':    brlapi.found()}
3003 summary_info += {'vde support':       config_host.has_key('CONFIG_VDE')}
3004 summary_info += {'netmap support':    config_host.has_key('CONFIG_NETMAP')}
3005 summary_info += {'Linux AIO support': config_host.has_key('CONFIG_LINUX_AIO')}
3006 summary_info += {'Linux io_uring support': linux_io_uring.found()}
3007 summary_info += {'ATTR/XATTR support': libattr.found()}
3008 summary_info += {'RDMA support':      config_host.has_key('CONFIG_RDMA')}
3009 summary_info += {'PVRDMA support':    config_host.has_key('CONFIG_PVRDMA')}
3010 summary_info += {'fdt support':       fdt_opt == 'disabled' ? false : fdt_opt}
3011 summary_info += {'libcap-ng support': libcap_ng.found()}
3012 summary_info += {'bpf support': libbpf.found()}
3013 # TODO: add back protocol and server version
3014 summary_info += {'spice support':     config_host.has_key('CONFIG_SPICE')}
3015 summary_info += {'rbd support':       rbd.found()}
3016 summary_info += {'xfsctl support':    config_host.has_key('CONFIG_XFS')}
3017 summary_info += {'smartcard support': cacard.found()}
3018 summary_info += {'U2F support':       u2f.found()}
3019 summary_info += {'libusb':            libusb.found()}
3020 summary_info += {'usb net redir':     usbredir.found()}
3021 summary_info += {'OpenGL support':    config_host.has_key('CONFIG_OPENGL')}
3022 summary_info += {'GBM':               config_host.has_key('CONFIG_GBM')}
3023 summary_info += {'libiscsi support':  libiscsi.found()}
3024 summary_info += {'libnfs support':    libnfs.found()}
3025 if targetos == 'windows'
3026   if config_host.has_key('CONFIG_GUEST_AGENT')
3027     summary_info += {'QGA VSS support':   config_host.has_key('CONFIG_QGA_VSS')}
3028     summary_info += {'QGA w32 disk info': config_host.has_key('CONFIG_QGA_NTDDSCSI')}
3029   endif
3030 endif
3031 summary_info += {'seccomp support':   seccomp.found()}
3032 summary_info += {'GlusterFS support': glusterfs.found()}
3033 summary_info += {'TPM support':       config_host.has_key('CONFIG_TPM')}
3034 summary_info += {'libssh support':    config_host.has_key('CONFIG_LIBSSH')}
3035 summary_info += {'lzo support':       lzo.found()}
3036 summary_info += {'snappy support':    snappy.found()}
3037 summary_info += {'bzip2 support':     libbzip2.found()}
3038 summary_info += {'lzfse support':     liblzfse.found()}
3039 summary_info += {'zstd support':      zstd.found()}
3040 summary_info += {'NUMA host support': config_host.has_key('CONFIG_NUMA')}
3041 summary_info += {'libxml2':           libxml2.found()}
3042 summary_info += {'capstone':          capstone_opt == 'disabled' ? false : capstone_opt}
3043 summary_info += {'libpmem support':   libpmem.found()}
3044 summary_info += {'libdaxctl support': libdaxctl.found()}
3045 summary_info += {'libudev':           libudev.found()}
3046 summary_info += {'FUSE lseek':        fuse_lseek.found()}
3047 summary(summary_info, bool_yn: true, section: 'Dependencies')
3048
3049 if not supported_cpus.contains(cpu)
3050   message()
3051   warning('SUPPORT FOR THIS HOST CPU WILL GO AWAY IN FUTURE RELEASES!')
3052   message()
3053   message('CPU host architecture ' + cpu + ' support is not currently maintained.')
3054   message('The QEMU project intends to remove support for this host CPU in')
3055   message('a future release if nobody volunteers to maintain it and to')
3056   message('provide a build host for our continuous integration setup.')
3057   message('configure has succeeded and you can continue to build, but')
3058   message('if you care about QEMU on this platform you should contact')
3059   message('us upstream at qemu-devel@nongnu.org.')
3060 endif
3061
3062 if not supported_oses.contains(targetos)
3063   message()
3064   warning('WARNING: SUPPORT FOR THIS HOST OS WILL GO AWAY IN FUTURE RELEASES!')
3065   message()
3066   message('Host OS ' + targetos + 'support is not currently maintained.')
3067   message('The QEMU project intends to remove support for this host OS in')
3068   message('a future release if nobody volunteers to maintain it and to')
3069   message('provide a build host for our continuous integration setup.')
3070   message('configure has succeeded and you can continue to build, but')
3071   message('if you care about QEMU on this platform you should contact')
3072   message('us upstream at qemu-devel@nongnu.org.')
3073 endif