meson.build

   1 project('qemu', ['c'], meson_version: '>=0.55.0',
   2         default_options: ['warning_level=1', 'c_std=gnu11', 'cpp_std=gnu++11', 'b_colorout=auto'] +
   3                          (meson.version().version_compare('>=0.56.0') ? [ 'b_staticpic=false' ] : []),
   4         version: run_command('head', meson.source_root() / 'VERSION').stdout().strip())
   5
   6 not_found = dependency('', required: false)
   7 if meson.version().version_compare('>=0.56.0')
   8   keyval = import('keyval')
   9 else
  10   keyval = import('unstable-keyval')
  11 endif
  12 ss = import('sourceset')
  13 fs = import('fs')
  14
  15 sh = find_program('sh')
  16 cc = meson.get_compiler('c')
  17 config_host = keyval.load(meson.current_build_dir() / 'config-host.mak')
  18 enable_modules = 'CONFIG_MODULES' in config_host
  19 enable_static = 'CONFIG_STATIC' in config_host
  20
  21 # Allow both shared and static libraries unless --enable-static
  22 static_kwargs = enable_static ? {'static': true} : {}
  23
  24 # Temporary directory used for files created while
  25 # configure runs. Since it is in the build directory
  26 # we can safely blow away any previous version of it
  27 # (and we need not jump through hoops to try to delete
  28 # it when configure exits.)
  29 tmpdir = meson.current_build_dir() / 'meson-private/temp'
  30
  31 if get_option('qemu_suffix').startswith('/')
  32   error('qemu_suffix cannot start with a /')
  33 endif
  34
  35 qemu_confdir = get_option('sysconfdir') / get_option('qemu_suffix')
  36 qemu_datadir = get_option('datadir') / get_option('qemu_suffix')
  37 qemu_docdir = get_option('docdir') / get_option('qemu_suffix')
  38 qemu_moddir = get_option('libdir') / get_option('qemu_suffix')
  39
  40 qemu_desktopdir = get_option('datadir') / 'applications'
  41 qemu_icondir = get_option('datadir') / 'icons'
  42
  43 config_host_data = configuration_data()
  44 genh = []
  45
  46 target_dirs = config_host['TARGET_DIRS'].split()
  47 have_user = false
  48 have_system = false
  49 foreach target : target_dirs
  50   have_user = have_user or target.endswith('-user')
  51   have_system = have_system or target.endswith('-softmmu')
  52 endforeach
  53 have_tools = 'CONFIG_TOOLS' in config_host
  54 have_block = have_system or have_tools
  55
  56 python = import('python').find_installation()
  57
  58 supported_oses = ['windows', 'freebsd', 'netbsd', 'openbsd', 'darwin', 'sunos', 'linux']
  59 supported_cpus = ['ppc', 'ppc64', 's390x', 'riscv32', 'riscv64', 'x86', 'x86_64',
  60   'arm', 'aarch64', 'mips', 'mips64', 'sparc', 'sparc64']
  61
  62 cpu = host_machine.cpu_family()
  63 targetos = host_machine.system()
  64
  65 if cpu in ['x86', 'x86_64']
  66   kvm_targets = ['i386-softmmu', 'x86_64-softmmu']
  67 elif cpu == 'aarch64'
  68   kvm_targets = ['aarch64-softmmu']
  69 elif cpu == 's390x'
  70   kvm_targets = ['s390x-softmmu']
  71 elif cpu in ['ppc', 'ppc64']
  72   kvm_targets = ['ppc-softmmu', 'ppc64-softmmu']
  73 elif cpu in ['mips', 'mips64']
  74   kvm_targets = ['mips-softmmu', 'mipsel-softmmu', 'mips64-softmmu', 'mips64el-softmmu']
  75 else
  76   kvm_targets = []
  77 endif
  78
  79 accelerator_targets = { 'CONFIG_KVM': kvm_targets }
  80 if cpu in ['x86', 'x86_64', 'arm', 'aarch64']
  81   # i368 emulator provides xenpv machine type for multiple architectures
  82   accelerator_targets += {
  83     'CONFIG_XEN': ['i386-softmmu', 'x86_64-softmmu'],
  84   }
  85 endif
  86 if cpu in ['x86', 'x86_64']
  87   accelerator_targets += {
  88     'CONFIG_HAX': ['i386-softmmu', 'x86_64-softmmu'],
  89     'CONFIG_HVF': ['x86_64-softmmu'],
  90     'CONFIG_NVMM': ['i386-softmmu', 'x86_64-softmmu'],
  91     'CONFIG_WHPX': ['i386-softmmu', 'x86_64-softmmu'],
  92   }
  93 endif
  94
  95 modular_tcg = []
  96 # Darwin does not support references to thread-local variables in modules
  97 if targetos != 'darwin'
  98   modular_tcg = ['i386-softmmu', 'x86_64-softmmu']
  99 endif
 100
 101 edk2_targets = [ 'arm-softmmu', 'aarch64-softmmu', 'i386-softmmu', 'x86_64-softmmu' ]
 102 install_edk2_blobs = false
 103 if get_option('install_blobs')
 104   foreach target : target_dirs
 105     install_edk2_blobs = install_edk2_blobs or target in edk2_targets
 106   endforeach
 107 endif
 108
 109 bzip2 = find_program('bzip2', required: install_edk2_blobs)
 110
 111 ##################
 112 # Compiler flags #
 113 ##################
 114
 115 # Specify linker-script with add_project_link_arguments so that it is not placed
 116 # within a linker --start-group/--end-group pair
 117 if 'CONFIG_FUZZ' in config_host
 118    add_project_link_arguments(['-Wl,-T,',
 119                                (meson.current_source_dir() / 'tests/qtest/fuzz/fork_fuzz.ld')],
 120                               native: false, language: ['c', 'cpp', 'objc'])
 121 endif
 122
 123 add_global_arguments(config_host['QEMU_CFLAGS'].split(),
 124                      native: false, language: ['c', 'objc'])
 125 add_global_arguments(config_host['QEMU_CXXFLAGS'].split(),
 126                      native: false, language: 'cpp')
 127 add_global_link_arguments(config_host['QEMU_LDFLAGS'].split(),
 128                           native: false, language: ['c', 'cpp', 'objc'])
 129
 130 if targetos == 'linux'
 131   add_project_arguments('-isystem', meson.current_source_dir() / 'linux-headers',
 132                         '-isystem', 'linux-headers',
 133                         language: ['c', 'cpp'])
 134 endif
 135
 136 add_project_arguments('-iquote', '.',
 137                       '-iquote', meson.current_source_dir(),
 138                       '-iquote', meson.current_source_dir() / 'include',
 139                       '-iquote', meson.current_source_dir() / 'disas/libvixl',
 140                       language: ['c', 'cpp', 'objc'])
 141
 142 link_language = meson.get_external_property('link_language', 'cpp')
 143 if link_language == 'cpp'
 144   add_languages('cpp', required: true, native: false)
 145 endif
 146 if host_machine.system() == 'darwin'
 147   add_languages('objc', required: false, native: false)
 148 endif
 149
 150 sparse = find_program('cgcc', required: get_option('sparse'))
 151 if sparse.found()
 152   run_target('sparse',
 153              command: [find_program('scripts/check_sparse.py'),
 154                        'compile_commands.json', sparse.full_path(), '-Wbitwise',
 155                        '-Wno-transparent-union', '-Wno-old-initializer',
 156                        '-Wno-non-pointer-null'])
 157 endif
 158
 159 ###########################################
 160 # Target-specific checks and dependencies #
 161 ###########################################
 162
 163 if targetos != 'linux' and get_option('mpath').enabled()
 164   error('Multipath is supported only on Linux')
 165 endif
 166
 167 if targetos != 'linux' and get_option('multiprocess').enabled()
 168   error('Multiprocess QEMU is supported only on Linux')
 169 endif
 170 multiprocess_allowed = targetos == 'linux' and not get_option('multiprocess').disabled()
 171
 172 libm = cc.find_library('m', required: false)
 173 threads = dependency('threads')
 174 util = cc.find_library('util', required: false)
 175 winmm = []
 176 socket = []
 177 version_res = []
 178 coref = []
 179 iokit = []
 180 emulator_link_args = []
 181 nvmm =not_found
 182 hvf = not_found
 183 if targetos == 'windows'
 184   socket = cc.find_library('ws2_32')
 185   winmm = cc.find_library('winmm')
 186
 187   win = import('windows')
 188   version_res = win.compile_resources('version.rc',
 189                                       depend_files: files('pc-bios/qemu-nsis.ico'),
 190                                       include_directories: include_directories('.'))
 191 elif targetos == 'darwin'
 192   coref = dependency('appleframeworks', modules: 'CoreFoundation')
 193   iokit = dependency('appleframeworks', modules: 'IOKit', required: false)
 194 elif targetos == 'sunos'
 195   socket = [cc.find_library('socket'),
 196             cc.find_library('nsl'),
 197             cc.find_library('resolv')]
 198 elif targetos == 'haiku'
 199   socket = [cc.find_library('posix_error_mapper'),
 200             cc.find_library('network'),
 201             cc.find_library('bsd')]
 202 elif targetos == 'openbsd'
 203   if not get_option('tcg').disabled() and target_dirs.length() > 0
 204     # Disable OpenBSD W^X if available
 205     emulator_link_args = cc.get_supported_link_arguments('-Wl,-z,wxneeded')
 206   endif
 207 endif
 208
 209 accelerators = []
 210 if not get_option('kvm').disabled() and targetos == 'linux'
 211   accelerators += 'CONFIG_KVM'
 212 endif
 213 if not get_option('xen').disabled() and 'CONFIG_XEN_BACKEND' in config_host
 214   accelerators += 'CONFIG_XEN'
 215   have_xen_pci_passthrough = not get_option('xen_pci_passthrough').disabled() and targetos == 'linux'
 216 else
 217   have_xen_pci_passthrough = false
 218 endif
 219 if not get_option('whpx').disabled() and targetos == 'windows'
 220   if get_option('whpx').enabled() and host_machine.cpu() != 'x86_64'
 221     error('WHPX requires 64-bit host')
 222   elif cc.has_header('WinHvPlatform.h', required: get_option('whpx')) and \
 223        cc.has_header('WinHvEmulation.h', required: get_option('whpx'))
 224     accelerators += 'CONFIG_WHPX'
 225   endif
 226 endif
 227 if not get_option('hvf').disabled()
 228   hvf = dependency('appleframeworks', modules: 'Hypervisor',
 229                    required: get_option('hvf'))
 230   if hvf.found()
 231     accelerators += 'CONFIG_HVF'
 232   endif
 233 endif
 234 if not get_option('hax').disabled()
 235   if get_option('hax').enabled() or targetos in ['windows', 'darwin', 'netbsd']
 236     accelerators += 'CONFIG_HAX'
 237   endif
 238 endif
 239 if targetos == 'netbsd'
 240   if cc.has_header_symbol('nvmm.h', 'nvmm_cpu_stop', required: get_option('nvmm'))
 241     nvmm = cc.find_library('nvmm', required: get_option('nvmm'))
 242   endif
 243   if nvmm.found()
 244     accelerators += 'CONFIG_NVMM'
 245   endif
 246 endif
 247
 248 tcg_arch = config_host['ARCH']
 249 if not get_option('tcg').disabled()
 250   if cpu not in supported_cpus
 251     if get_option('tcg_interpreter')
 252       warning('Unsupported CPU @0@, will use TCG with TCI (experimental and slow)'.format(cpu))
 253     else
 254       error('Unsupported CPU @0@, try --enable-tcg-interpreter'.format(cpu))
 255     endif
 256   elif get_option('tcg_interpreter')
 257     warning('Use of the TCG interpretor is not recommended on this host')
 258     warning('architecture. There is a native TCG execution backend available')
 259     warning('which provides substantially better performance and reliability.')
 260     warning('It is strongly recommended to remove the --enable-tcg-interpreter')
 261     warning('configuration option on this architecture to use the native')
 262     warning('backend.')
 263   endif
 264   if get_option('tcg_interpreter')
 265     tcg_arch = 'tci'
 266   elif config_host['ARCH'] == 'sparc64'
 267     tcg_arch = 'sparc'
 268   elif config_host['ARCH'] == 's390x'
 269     tcg_arch = 's390'
 270   elif config_host['ARCH'] in ['x86_64', 'x32']
 271     tcg_arch = 'i386'
 272   elif config_host['ARCH'] == 'ppc64'
 273     tcg_arch = 'ppc'
 274   elif config_host['ARCH'] in ['riscv32', 'riscv64']
 275     tcg_arch = 'riscv'
 276   endif
 277   add_project_arguments('-iquote', meson.current_source_dir() / 'tcg' / tcg_arch,
 278                         language: ['c', 'cpp', 'objc'])
 279
 280   accelerators += 'CONFIG_TCG'
 281   config_host += { 'CONFIG_TCG': 'y' }
 282 endif
 283
 284 if 'CONFIG_KVM' not in accelerators and get_option('kvm').enabled()
 285   error('KVM not available on this platform')
 286 endif
 287 if 'CONFIG_HVF' not in accelerators and get_option('hvf').enabled()
 288   error('HVF not available on this platform')
 289 endif
 290 if 'CONFIG_NVMM' not in accelerators and get_option('nvmm').enabled()
 291   error('NVMM not available on this platform')
 292 endif
 293 if 'CONFIG_WHPX' not in accelerators and get_option('whpx').enabled()
 294   error('WHPX not available on this platform')
 295 endif
 296 if not have_xen_pci_passthrough and get_option('xen_pci_passthrough').enabled()
 297   if 'CONFIG_XEN' in accelerators
 298     error('Xen PCI passthrough not available on this platform')
 299   else
 300     error('Xen PCI passthrough requested but Xen not enabled')
 301   endif
 302 endif
 303
 304 ################
 305 # Dependencies #
 306 ################
 307
 308 # The path to glib.h is added to all compilation commands.  This was
 309 # grandfathered in from the QEMU Makefiles.
 310 add_project_arguments(config_host['GLIB_CFLAGS'].split(),
 311                       native: false, language: ['c', 'cpp', 'objc'])
 312 glib = declare_dependency(compile_args: config_host['GLIB_CFLAGS'].split(),
 313                           link_args: config_host['GLIB_LIBS'].split())
 314 # override glib dep with the configure results (for subprojects)
 315 meson.override_dependency('glib-2.0', glib)
 316
 317 gio = not_found
 318 if 'CONFIG_GIO' in config_host
 319   gio = declare_dependency(compile_args: config_host['GIO_CFLAGS'].split(),
 320                            link_args: config_host['GIO_LIBS'].split())
 321 endif
 322 lttng = not_found
 323 if 'CONFIG_TRACE_UST' in config_host
 324   lttng = declare_dependency(link_args: config_host['LTTNG_UST_LIBS'].split())
 325 endif
 326 pixman = not_found
 327 if have_system or have_tools
 328   pixman = dependency('pixman-1', required: have_system, version:'>=0.21.8',
 329                       method: 'pkg-config', kwargs: static_kwargs)
 330 endif
 331 libaio = cc.find_library('aio', required: false)
 332 zlib = dependency('zlib', required: true, kwargs: static_kwargs)
 333
 334 linux_io_uring = not_found
 335 if not get_option('linux_io_uring').auto() or have_block
 336   linux_io_uring = dependency('liburing', required: get_option('linux_io_uring'),
 337                               method: 'pkg-config', kwargs: static_kwargs)
 338 endif
 339 libxml2 = not_found
 340 if not get_option('libxml2').auto() or have_block
 341   libxml2 = dependency('libxml-2.0', required: get_option('libxml2'),
 342                        method: 'pkg-config', kwargs: static_kwargs)
 343 endif
 344 libnfs = not_found
 345 if not get_option('libnfs').auto() or have_block
 346   libnfs = dependency('libnfs', version: '>=1.9.3',
 347                       required: get_option('libnfs'),
 348                       method: 'pkg-config', kwargs: static_kwargs)
 349 endif
 350
 351 libattr_test = '''
 352   #include <stddef.h>
 353   #include <sys/types.h>
 354   #ifdef CONFIG_LIBATTR
 355   #include <attr/xattr.h>
 356   #else
 357   #include <sys/xattr.h>
 358   #endif
 359   int main(void) { getxattr(NULL, NULL, NULL, 0); setxattr(NULL, NULL, NULL, 0, 0); return 0; }'''
 360
 361 libattr = not_found
 362 have_old_libattr = false
 363 if not get_option('attr').disabled()
 364   if cc.links(libattr_test)
 365     libattr = declare_dependency()
 366   else
 367     libattr = cc.find_library('attr', has_headers: ['attr/xattr.h'],
 368                               required: get_option('attr'),
 369                               kwargs: static_kwargs)
 370     if libattr.found() and not \
 371       cc.links(libattr_test, dependencies: libattr, args: '-DCONFIG_LIBATTR')
 372       libattr = not_found
 373       if get_option('attr').enabled()
 374         error('could not link libattr')
 375       else
 376         warning('could not link libattr, disabling')
 377       endif
 378     else
 379       have_old_libattr = libattr.found()
 380     endif
 381   endif
 382 endif
 383
 384 cocoa = dependency('appleframeworks', modules: 'Cocoa', required: get_option('cocoa'))
 385 if cocoa.found() and get_option('sdl').enabled()
 386   error('Cocoa and SDL cannot be enabled at the same time')
 387 endif
 388 if cocoa.found() and get_option('gtk').enabled()
 389   error('Cocoa and GTK+ cannot be enabled at the same time')
 390 endif
 391
 392 seccomp = not_found
 393 if not get_option('seccomp').auto() or have_system or have_tools
 394   seccomp = dependency('libseccomp', version: '>=2.3.0',
 395                        required: get_option('seccomp'),
 396                        method: 'pkg-config', kwargs: static_kwargs)
 397 endif
 398
 399 libcap_ng = not_found
 400 if not get_option('cap_ng').auto() or have_system or have_tools
 401   libcap_ng = cc.find_library('cap-ng', has_headers: ['cap-ng.h'],
 402                               required: get_option('cap_ng'),
 403                               kwargs: static_kwargs)
 404 endif
 405 if libcap_ng.found() and not cc.links('''
 406    #include <cap-ng.h>
 407    int main(void)
 408    {
 409      capng_capability_to_name(CAPNG_EFFECTIVE);
 410      return 0;
 411    }''', dependencies: libcap_ng)
 412   libcap_ng = not_found
 413   if get_option('cap_ng').enabled()
 414     error('could not link libcap-ng')
 415   else
 416     warning('could not link libcap-ng, disabling')
 417   endif
 418 endif
 419
 420 if get_option('xkbcommon').auto() and not have_system and not have_tools
 421   xkbcommon = not_found
 422 else
 423   xkbcommon = dependency('xkbcommon', required: get_option('xkbcommon'),
 424                          method: 'pkg-config', kwargs: static_kwargs)
 425 endif
 426 vde = not_found
 427 if config_host.has_key('CONFIG_VDE')
 428   vde = declare_dependency(link_args: config_host['VDE_LIBS'].split())
 429 endif
 430 pulse = not_found
 431 if 'CONFIG_LIBPULSE' in config_host
 432   pulse = declare_dependency(compile_args: config_host['PULSE_CFLAGS'].split(),
 433                              link_args: config_host['PULSE_LIBS'].split())
 434 endif
 435 alsa = not_found
 436 if 'CONFIG_ALSA' in config_host
 437   alsa = declare_dependency(compile_args: config_host['ALSA_CFLAGS'].split(),
 438                             link_args: config_host['ALSA_LIBS'].split())
 439 endif
 440 jack = not_found
 441 if 'CONFIG_LIBJACK' in config_host
 442   jack = declare_dependency(link_args: config_host['JACK_LIBS'].split())
 443 endif
 444 spice = not_found
 445 spice_headers = not_found
 446 spice_protocol = not_found
 447 if 'CONFIG_SPICE' in config_host
 448   spice = declare_dependency(compile_args: config_host['SPICE_CFLAGS'].split(),
 449                              link_args: config_host['SPICE_LIBS'].split())
 450   spice_headers = declare_dependency(compile_args: config_host['SPICE_CFLAGS'].split())
 451 endif
 452 if 'CONFIG_SPICE_PROTOCOL' in config_host
 453   spice_protocol = declare_dependency(compile_args: config_host['SPICE_PROTOCOL_CFLAGS'].split())
 454 endif
 455 rt = cc.find_library('rt', required: false)
 456 libdl = not_found
 457 if 'CONFIG_PLUGIN' in config_host
 458   libdl = cc.find_library('dl', required: true)
 459 endif
 460 libiscsi = not_found
 461 if not get_option('libiscsi').auto() or have_block
 462   libiscsi = dependency('libiscsi', version: '>=1.9.0',
 463                          required: get_option('libiscsi'),
 464                          method: 'pkg-config', kwargs: static_kwargs)
 465 endif
 466 zstd = not_found
 467 if not get_option('zstd').auto() or have_block
 468   zstd = dependency('libzstd', version: '>=1.4.0',
 469                     required: get_option('zstd'),
 470                     method: 'pkg-config', kwargs: static_kwargs)
 471 endif
 472 gbm = not_found
 473 if 'CONFIG_GBM' in config_host
 474   gbm = declare_dependency(compile_args: config_host['GBM_CFLAGS'].split(),
 475                            link_args: config_host['GBM_LIBS'].split())
 476 endif
 477 virgl = not_found
 478 if not get_option('virglrenderer').auto() or have_system
 479   virgl = dependency('virglrenderer',
 480                      method: 'pkg-config',
 481                      required: get_option('virglrenderer'),
 482                      kwargs: static_kwargs)
 483 endif
 484 curl = not_found
 485 if not get_option('curl').auto() or have_block
 486   curl = dependency('libcurl', version: '>=7.29.0',
 487                     method: 'pkg-config',
 488                     required: get_option('curl'),
 489                     kwargs: static_kwargs)
 490 endif
 491 libudev = not_found
 492 if targetos == 'linux' and (have_system or have_tools)
 493   libudev = dependency('libudev',
 494                        method: 'pkg-config',
 495                        required: get_option('libudev'),
 496                        kwargs: static_kwargs)
 497 endif
 498
 499 mpathlibs = [libudev]
 500 mpathpersist = not_found
 501 mpathpersist_new_api = false
 502 if targetos == 'linux' and have_tools and not get_option('mpath').disabled()
 503   mpath_test_source_new = '''
 504     #include <libudev.h>
 505     #include <mpath_persist.h>
 506     unsigned mpath_mx_alloc_len = 1024;
 507     int logsink;
 508     static struct config *multipath_conf;
 509     extern struct udev *udev;
 510     extern struct config *get_multipath_config(void);
 511     extern void put_multipath_config(struct config *conf);
 512     struct udev *udev;
 513     struct config *get_multipath_config(void) { return multipath_conf; }
 514     void put_multipath_config(struct config *conf) { }
 515     int main(void) {
 516         udev = udev_new();
 517         multipath_conf = mpath_lib_init();
 518         return 0;
 519     }'''
 520   mpath_test_source_old = '''
 521       #include <libudev.h>
 522       #include <mpath_persist.h>
 523       unsigned mpath_mx_alloc_len = 1024;
 524       int logsink;
 525       int main(void) {
 526           struct udev *udev = udev_new();
 527           mpath_lib_init(udev);
 528           return 0;
 529       }'''
 530   libmpathpersist = cc.find_library('mpathpersist',
 531                                     required: get_option('mpath'),
 532                                     kwargs: static_kwargs)
 533   if libmpathpersist.found()
 534     mpathlibs += libmpathpersist
 535     if enable_static
 536       mpathlibs += cc.find_library('devmapper',
 537                                      required: get_option('mpath'),
 538                                      kwargs: static_kwargs)
 539     endif
 540     mpathlibs += cc.find_library('multipath',
 541                                  required: get_option('mpath'),
 542                                  kwargs: static_kwargs)
 543     foreach lib: mpathlibs
 544       if not lib.found()
 545         mpathlibs = []
 546         break
 547       endif
 548     endforeach
 549     if mpathlibs.length() == 0
 550       msg = 'Dependencies missing for libmpathpersist'
 551     elif cc.links(mpath_test_source_new, dependencies: mpathlibs)
 552       mpathpersist = declare_dependency(dependencies: mpathlibs)
 553       mpathpersist_new_api = true
 554     elif cc.links(mpath_test_source_old, dependencies: mpathlibs)
 555       mpathpersist = declare_dependency(dependencies: mpathlibs)
 556     else
 557       msg = 'Cannot detect libmpathpersist API'
 558     endif
 559     if not mpathpersist.found()
 560       if get_option('mpath').enabled()
 561         error(msg)
 562       else
 563         warning(msg + ', disabling')
 564       endif
 565     endif
 566   endif
 567 endif
 568
 569 iconv = not_found
 570 curses = not_found
 571 if have_system and not get_option('curses').disabled()
 572   curses_test = '''
 573     #include <locale.h>
 574     #include <curses.h>
 575     #include <wchar.h>
 576     int main(void) {
 577       wchar_t wch = L'w';
 578       setlocale(LC_ALL, "");
 579       resize_term(0, 0);
 580       addwstr(L"wide chars\n");
 581       addnwstr(&wch, 1);
 582       add_wch(WACS_DEGREE);
 583       return 0;
 584     }'''
 585
 586   curses_dep_list = targetos == 'windows' ? ['ncurses', 'ncursesw'] : ['ncursesw']
 587   foreach curses_dep : curses_dep_list
 588     if not curses.found()
 589       curses = dependency(curses_dep,
 590                           required: false,
 591                           method: 'pkg-config',
 592                           kwargs: static_kwargs)
 593     endif
 594   endforeach
 595   msg = get_option('curses').enabled() ? 'curses library not found' : ''
 596   curses_compile_args = ['-DNCURSES_WIDECHAR']
 597   if curses.found()
 598     if cc.links(curses_test, args: curses_compile_args, dependencies: [curses])
 599       curses = declare_dependency(compile_args: curses_compile_args, dependencies: [curses])
 600     else
 601       msg = 'curses package not usable'
 602       curses = not_found
 603     endif
 604   endif
 605   if not curses.found()
 606     has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 607     if targetos != 'windows' and not has_curses_h
 608       message('Trying with /usr/include/ncursesw')
 609       curses_compile_args += ['-I/usr/include/ncursesw']
 610       has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 611     endif
 612     if has_curses_h
 613       curses_libname_list = (targetos == 'windows' ? ['pdcurses'] : ['ncursesw', 'cursesw'])
 614       foreach curses_libname : curses_libname_list
 615         libcurses = cc.find_library(curses_libname,
 616                                     required: false,
 617                                     kwargs: static_kwargs)
 618         if libcurses.found()
 619           if cc.links(curses_test, args: curses_compile_args, dependencies: libcurses)
 620             curses = declare_dependency(compile_args: curses_compile_args,
 621                                         dependencies: [libcurses])
 622             break
 623           else
 624             msg = 'curses library not usable'
 625           endif
 626         endif
 627       endforeach
 628     endif
 629   endif
 630   if not get_option('iconv').disabled()
 631     foreach link_args : [ ['-liconv'], [] ]
 632       # Programs will be linked with glib and this will bring in libiconv on FreeBSD.
 633       # We need to use libiconv if available because mixing libiconv's headers with
 634       # the system libc does not work.
 635       # However, without adding glib to the dependencies -L/usr/local/lib will not be
 636       # included in the command line and libiconv will not be found.
 637       if cc.links('''
 638         #include <iconv.h>
 639         int main(void) {
 640           iconv_t conv = iconv_open("WCHAR_T", "UCS-2");
 641           return conv != (iconv_t) -1;
 642         }''', args: config_host['GLIB_CFLAGS'].split() + config_host['GLIB_LIBS'].split() + link_args)
 643         iconv = declare_dependency(link_args: link_args, dependencies: glib)
 644         break
 645       endif
 646     endforeach
 647   endif
 648   if curses.found() and not iconv.found()
 649     if get_option('iconv').enabled()
 650       error('iconv not available')
 651     endif
 652     msg = 'iconv required for curses UI but not available'
 653     curses = not_found
 654   endif
 655   if not curses.found() and msg != ''
 656     if get_option('curses').enabled()
 657       error(msg)
 658     else
 659       warning(msg + ', disabling')
 660     endif
 661   endif
 662 endif
 663
 664 brlapi = not_found
 665 if not get_option('brlapi').auto() or have_system
 666   brlapi = cc.find_library('brlapi', has_headers: ['brlapi.h'],
 667                          required: get_option('brlapi'),
 668                          kwargs: static_kwargs)
 669   if brlapi.found() and not cc.links('''
 670      #include <brlapi.h>
 671      #include <stddef.h>
 672      int main(void) { return brlapi__openConnection (NULL, NULL, NULL); }''', dependencies: brlapi)
 673     brlapi = not_found
 674     if get_option('brlapi').enabled()
 675       error('could not link brlapi')
 676     else
 677       warning('could not link brlapi, disabling')
 678     endif
 679   endif
 680 endif
 681
 682 sdl = not_found
 683 if not get_option('sdl').auto() or (have_system and not cocoa.found())
 684   sdl = dependency('sdl2', required: get_option('sdl'), kwargs: static_kwargs)
 685   sdl_image = not_found
 686 endif
 687 if sdl.found()
 688   # work around 2.0.8 bug
 689   sdl = declare_dependency(compile_args: '-Wno-undef',
 690                            dependencies: sdl)
 691   sdl_image = dependency('SDL2_image', required: get_option('sdl_image'),
 692                          method: 'pkg-config', kwargs: static_kwargs)
 693 else
 694   if get_option('sdl_image').enabled()
 695     error('sdl-image required, but SDL was @0@'.format(
 696           get_option('sdl').disabled() ? 'disabled' : 'not found'))
 697   endif
 698   sdl_image = not_found
 699 endif
 700
 701 rbd = not_found
 702 if not get_option('rbd').auto() or have_block
 703   librados = cc.find_library('rados', required: get_option('rbd'),
 704                              kwargs: static_kwargs)
 705   librbd = cc.find_library('rbd', has_headers: ['rbd/librbd.h'],
 706                            required: get_option('rbd'),
 707                            kwargs: static_kwargs)
 708   if librados.found() and librbd.found()
 709     if cc.links('''
 710       #include <stdio.h>
 711       #include <rbd/librbd.h>
 712       int main(void) {
 713         rados_t cluster;
 714         rados_create(&cluster, NULL);
 715         #if LIBRBD_VERSION_CODE < LIBRBD_VERSION(1, 12, 0)
 716         #error
 717         #endif
 718         return 0;
 719       }''', dependencies: [librbd, librados])
 720       rbd = declare_dependency(dependencies: [librbd, librados])
 721     elif get_option('rbd').enabled()
 722       error('librbd >= 1.12.0 required')
 723     else
 724       warning('librbd >= 1.12.0 not found, disabling')
 725     endif
 726   endif
 727 endif
 728
 729 glusterfs = not_found
 730 glusterfs_ftruncate_has_stat = false
 731 glusterfs_iocb_has_stat = false
 732 if not get_option('glusterfs').auto() or have_block
 733   glusterfs = dependency('glusterfs-api', version: '>=3',
 734                          required: get_option('glusterfs'),
 735                          method: 'pkg-config', kwargs: static_kwargs)
 736   if glusterfs.found()
 737     glusterfs_ftruncate_has_stat = cc.links('''
 738       #include <glusterfs/api/glfs.h>
 739
 740       int
 741       main(void)
 742       {
 743           /* new glfs_ftruncate() passes two additional args */
 744           return glfs_ftruncate(NULL, 0, NULL, NULL);
 745       }
 746     ''', dependencies: glusterfs)
 747     glusterfs_iocb_has_stat = cc.links('''
 748       #include <glusterfs/api/glfs.h>
 749
 750       /* new glfs_io_cbk() passes two additional glfs_stat structs */
 751       static void
 752       glusterfs_iocb(glfs_fd_t *fd, ssize_t ret, struct glfs_stat *prestat, struct glfs_stat *poststat, void *data)
 753       {}
 754
 755       int
 756       main(void)
 757       {
 758           glfs_io_cbk iocb = &glusterfs_iocb;
 759           iocb(NULL, 0 , NULL, NULL, NULL);
 760           return 0;
 761       }
 762     ''', dependencies: glusterfs)
 763   endif
 764 endif
 765 libssh = not_found
 766 if 'CONFIG_LIBSSH' in config_host
 767   libssh = declare_dependency(compile_args: config_host['LIBSSH_CFLAGS'].split(),
 768                               link_args: config_host['LIBSSH_LIBS'].split())
 769 endif
 770 libbzip2 = not_found
 771 if not get_option('bzip2').auto() or have_block
 772   libbzip2 = cc.find_library('bz2', has_headers: ['bzlib.h'],
 773                              required: get_option('bzip2'),
 774                              kwargs: static_kwargs)
 775   if libbzip2.found() and not cc.links('''
 776      #include <bzlib.h>
 777      int main(void) { BZ2_bzlibVersion(); return 0; }''', dependencies: libbzip2)
 778     libbzip2 = not_found
 779     if get_option('bzip2').enabled()
 780       error('could not link libbzip2')
 781     else
 782       warning('could not link libbzip2, disabling')
 783     endif
 784   endif
 785 endif
 786
 787 liblzfse = not_found
 788 if not get_option('lzfse').auto() or have_block
 789   liblzfse = cc.find_library('lzfse', has_headers: ['lzfse.h'],
 790                              required: get_option('lzfse'),
 791                              kwargs: static_kwargs)
 792 endif
 793 if liblzfse.found() and not cc.links('''
 794    #include <lzfse.h>
 795    int main(void) { lzfse_decode_scratch_size(); return 0; }''', dependencies: liblzfse)
 796   liblzfse = not_found
 797   if get_option('lzfse').enabled()
 798     error('could not link liblzfse')
 799   else
 800     warning('could not link liblzfse, disabling')
 801   endif
 802 endif
 803
 804 oss = not_found
 805 if 'CONFIG_AUDIO_OSS' in config_host
 806   oss = declare_dependency(link_args: config_host['OSS_LIBS'].split())
 807 endif
 808 dsound = not_found
 809 if 'CONFIG_AUDIO_DSOUND' in config_host
 810   dsound = declare_dependency(link_args: config_host['DSOUND_LIBS'].split())
 811 endif
 812 coreaudio = not_found
 813 if 'CONFIG_AUDIO_COREAUDIO' in config_host
 814   coreaudio = declare_dependency(link_args: config_host['COREAUDIO_LIBS'].split())
 815 endif
 816 opengl = not_found
 817 if 'CONFIG_OPENGL' in config_host
 818   opengl = declare_dependency(compile_args: config_host['OPENGL_CFLAGS'].split(),
 819                               link_args: config_host['OPENGL_LIBS'].split())
 820 endif
 821
 822 gnutls = not_found
 823 if not get_option('gnutls').auto() or have_system
 824   gnutls = dependency('gnutls', version: '>=3.5.18',
 825                       method: 'pkg-config',
 826                       required: get_option('gnutls'),
 827                       kwargs: static_kwargs)
 828 endif
 829
 830 # Nettle has priority over gcrypt
 831 gcrypt = not_found
 832 nettle = not_found
 833 xts = 'private'
 834 if get_option('nettle').enabled() and get_option('gcrypt').enabled()
 835   error('Only one of gcrypt & nettle can be enabled')
 836 elif (not get_option('nettle').auto() or have_system) and not get_option('gcrypt').enabled()
 837   nettle = dependency('nettle', version: '>=3.4',
 838                       method: 'pkg-config',
 839                       required: get_option('nettle'),
 840                       kwargs: static_kwargs)
 841   if nettle.found() and cc.has_header('nettle/xts.h', dependencies: nettle)
 842     xts = 'nettle'
 843   endif
 844 endif
 845 if (not get_option('gcrypt').auto() or have_system) and not nettle.found()
 846   gcrypt = dependency('libgcrypt', version: '>=1.5',
 847                          method: 'config-tool',
 848                          required: get_option('gcrypt'),
 849                          kwargs: static_kwargs)
 850   if gcrypt.found() and cc.compiles('''
 851     #include <gcrypt.h>
 852     int main(void) {
 853       gcry_cipher_hd_t handle;
 854       gcry_cipher_open(&handle, GCRY_CIPHER_AES, GCRY_CIPHER_MODE_XTS, 0);
 855       return 0;
 856     }
 857     ''', dependencies: gcrypt)
 858     xts = 'gcrypt'
 859   endif
 860   # Debian has removed -lgpg-error from libgcrypt-config
 861   # as it "spreads unnecessary dependencies" which in
 862   # turn breaks static builds...
 863   if gcrypt.found() and enable_static
 864     gcrypt = declare_dependency(dependencies: [
 865       gcrypt,
 866       cc.find_library('gpg-error', required: true, kwargs: static_kwargs)])
 867   endif
 868 endif
 869
 870 gtk = not_found
 871 gtkx11 = not_found
 872 vte = not_found
 873 if not get_option('gtk').auto() or (have_system and not cocoa.found())
 874   gtk = dependency('gtk+-3.0', version: '>=3.22.0',
 875                    method: 'pkg-config',
 876                    required: get_option('gtk'),
 877                    kwargs: static_kwargs)
 878   if gtk.found()
 879     gtkx11 = dependency('gtk+-x11-3.0', version: '>=3.22.0',
 880                         method: 'pkg-config',
 881                         required: false,
 882                         kwargs: static_kwargs)
 883     gtk = declare_dependency(dependencies: [gtk, gtkx11])
 884
 885     if not get_option('vte').auto() or have_system
 886       vte = dependency('vte-2.91',
 887                        method: 'pkg-config',
 888                        required: get_option('vte'),
 889                        kwargs: static_kwargs)
 890     endif
 891   endif
 892 endif
 893
 894 x11 = not_found
 895 if gtkx11.found()
 896   x11 = dependency('x11', method: 'pkg-config', required: gtkx11.found(),
 897                    kwargs: static_kwargs)
 898 endif
 899 vnc = not_found
 900 png = not_found
 901 jpeg = not_found
 902 sasl = not_found
 903 if get_option('vnc').enabled()
 904   vnc = declare_dependency() # dummy dependency
 905   png = dependency('libpng', required: get_option('vnc_png'),
 906                    method: 'pkg-config', kwargs: static_kwargs)
 907   jpeg = dependency('libjpeg', required: get_option('vnc_jpeg'),
 908                     method: 'pkg-config', kwargs: static_kwargs)
 909   sasl = cc.find_library('sasl2', has_headers: ['sasl/sasl.h'],
 910                          required: get_option('vnc_sasl'),
 911                          kwargs: static_kwargs)
 912   if sasl.found()
 913     sasl = declare_dependency(dependencies: sasl,
 914                               compile_args: '-DSTRUCT_IOVEC_DEFINED')
 915   endif
 916 endif
 917
 918 pam = not_found
 919 if not get_option('auth_pam').auto() or have_system
 920   pam = cc.find_library('pam', has_headers: ['security/pam_appl.h'],
 921                         required: get_option('auth_pam'),
 922                         kwargs: static_kwargs)
 923 endif
 924 if pam.found() and not cc.links('''
 925    #include <stddef.h>
 926    #include <security/pam_appl.h>
 927    int main(void) {
 928      const char *service_name = "qemu";
 929      const char *user = "frank";
 930      const struct pam_conv pam_conv = { 0 };
 931      pam_handle_t *pamh = NULL;
 932      pam_start(service_name, user, &pam_conv, &pamh);
 933      return 0;
 934    }''', dependencies: pam)
 935   pam = not_found
 936   if get_option('auth_pam').enabled()
 937     error('could not link libpam')
 938   else
 939     warning('could not link libpam, disabling')
 940   endif
 941 endif
 942
 943 snappy = not_found
 944 if not get_option('snappy').auto() or have_system
 945   snappy = cc.find_library('snappy', has_headers: ['snappy-c.h'],
 946                            required: get_option('snappy'),
 947                            kwargs: static_kwargs)
 948 endif
 949 if snappy.found() and not cc.links('''
 950    #include <snappy-c.h>
 951    int main(void) { snappy_max_compressed_length(4096); return 0; }''', dependencies: snappy)
 952   snappy = not_found
 953   if get_option('snappy').enabled()
 954     error('could not link libsnappy')
 955   else
 956     warning('could not link libsnappy, disabling')
 957   endif
 958 endif
 959
 960 lzo = not_found
 961 if not get_option('lzo').auto() or have_system
 962   lzo = cc.find_library('lzo2', has_headers: ['lzo/lzo1x.h'],
 963                         required: get_option('lzo'),
 964                         kwargs: static_kwargs)
 965 endif
 966 if lzo.found() and not cc.links('''
 967    #include <lzo/lzo1x.h>
 968    int main(void) { lzo_version(); return 0; }''', dependencies: lzo)
 969   lzo = not_found
 970   if get_option('lzo').enabled()
 971     error('could not link liblzo2')
 972   else
 973     warning('could not link liblzo2, disabling')
 974   endif
 975 endif
 976
 977 rdma = not_found
 978 if 'CONFIG_RDMA' in config_host
 979   rdma = declare_dependency(link_args: config_host['RDMA_LIBS'].split())
 980 endif
 981 numa = not_found
 982 if 'CONFIG_NUMA' in config_host
 983   numa = declare_dependency(link_args: config_host['NUMA_LIBS'].split())
 984 endif
 985 xen = not_found
 986 if 'CONFIG_XEN_BACKEND' in config_host
 987   xen = declare_dependency(compile_args: config_host['XEN_CFLAGS'].split(),
 988                            link_args: config_host['XEN_LIBS'].split())
 989 endif
 990 cacard = not_found
 991 if not get_option('smartcard').auto() or have_system
 992   cacard = dependency('libcacard', required: get_option('smartcard'),
 993                       version: '>=2.5.1', method: 'pkg-config',
 994                       kwargs: static_kwargs)
 995 endif
 996 u2f = not_found
 997 if have_system
 998   u2f = dependency('u2f-emu', required: get_option('u2f'),
 999                    method: 'pkg-config',
1000                    kwargs: static_kwargs)
1001 endif
1002 usbredir = not_found
1003 if not get_option('usb_redir').auto() or have_system
1004   usbredir = dependency('libusbredirparser-0.5', required: get_option('usb_redir'),
1005                         version: '>=0.6', method: 'pkg-config',
1006                         kwargs: static_kwargs)
1007 endif
1008 libusb = not_found
1009 if not get_option('libusb').auto() or have_system
1010   libusb = dependency('libusb-1.0', required: get_option('libusb'),
1011                       version: '>=1.0.13', method: 'pkg-config',
1012                       kwargs: static_kwargs)
1013 endif
1014
1015 libpmem = not_found
1016 if not get_option('libpmem').auto() or have_system
1017   libpmem = dependency('libpmem', required: get_option('libpmem'),
1018                        method: 'pkg-config', kwargs: static_kwargs)
1019 endif
1020 libdaxctl = not_found
1021 if not get_option('libdaxctl').auto() or have_system
1022   libdaxctl = dependency('libdaxctl', required: get_option('libdaxctl'),
1023                          version: '>=57', method: 'pkg-config',
1024                          kwargs: static_kwargs)
1025 endif
1026 tasn1 = not_found
1027 if gnutls.found()
1028   tasn1 = dependency('libtasn1',
1029                      method: 'pkg-config',
1030                      kwargs: static_kwargs)
1031 endif
1032 keyutils = dependency('libkeyutils', required: false,
1033                       method: 'pkg-config', kwargs: static_kwargs)
1034
1035 has_gettid = cc.has_function('gettid')
1036
1037 # Malloc tests
1038
1039 malloc = []
1040 if get_option('malloc') == 'system'
1041   has_malloc_trim = \
1042     not get_option('malloc_trim').disabled() and \
1043     cc.links('''#include <malloc.h>
1044                 int main(void) { malloc_trim(0); return 0; }''')
1045 else
1046   has_malloc_trim = false
1047   malloc = cc.find_library(get_option('malloc'), required: true)
1048 endif
1049 if not has_malloc_trim and get_option('malloc_trim').enabled()
1050   if get_option('malloc') == 'system'
1051     error('malloc_trim not available on this platform.')
1052   else
1053     error('malloc_trim not available with non-libc memory allocator')
1054   endif
1055 endif
1056
1057 # Check whether the glibc provides statx()
1058
1059 gnu_source_prefix = '''
1060   #ifndef _GNU_SOURCE
1061   #define _GNU_SOURCE
1062   #endif
1063 '''
1064 statx_test = gnu_source_prefix + '''
1065   #include <sys/stat.h>
1066   int main(void) {
1067     struct statx statxbuf;
1068     statx(0, "", 0, STATX_BASIC_STATS, &statxbuf);
1069     return 0;
1070   }'''
1071
1072 has_statx = cc.links(statx_test)
1073
1074 have_vhost_user_blk_server = (targetos == 'linux' and
1075     'CONFIG_VHOST_USER' in config_host)
1076
1077 if get_option('vhost_user_blk_server').enabled()
1078     if targetos != 'linux'
1079         error('vhost_user_blk_server requires linux')
1080     elif 'CONFIG_VHOST_USER' not in config_host
1081         error('vhost_user_blk_server requires vhost-user support')
1082     endif
1083 elif get_option('vhost_user_blk_server').disabled() or not have_system
1084     have_vhost_user_blk_server = false
1085 endif
1086
1087
1088 if get_option('fuse').disabled() and get_option('fuse_lseek').enabled()
1089   error('Cannot enable fuse-lseek while fuse is disabled')
1090 endif
1091
1092 fuse = dependency('fuse3', required: get_option('fuse'),
1093                   version: '>=3.1', method: 'pkg-config',
1094                   kwargs: static_kwargs)
1095
1096 fuse_lseek = not_found
1097 if not get_option('fuse_lseek').disabled()
1098   if fuse.version().version_compare('>=3.8')
1099     # Dummy dependency
1100     fuse_lseek = declare_dependency()
1101   elif get_option('fuse_lseek').enabled()
1102     if fuse.found()
1103       error('fuse-lseek requires libfuse >=3.8, found ' + fuse.version())
1104     else
1105       error('fuse-lseek requires libfuse, which was not found')
1106     endif
1107   endif
1108 endif
1109
1110 # libbpf
1111 libbpf = dependency('libbpf', required: get_option('bpf'), method: 'pkg-config')
1112 if libbpf.found() and not cc.links('''
1113    #include <bpf/libbpf.h>
1114    int main(void)
1115    {
1116      bpf_object__destroy_skeleton(NULL);
1117      return 0;
1118    }''', dependencies: libbpf)
1119   libbpf = not_found
1120   if get_option('bpf').enabled()
1121     error('libbpf skeleton test failed')
1122   else
1123     warning('libbpf skeleton test failed, disabling')
1124   endif
1125 endif
1126
1127 if get_option('cfi')
1128   cfi_flags=[]
1129   # Check for dependency on LTO
1130   if not get_option('b_lto')
1131     error('Selected Control-Flow Integrity but LTO is disabled')
1132   endif
1133   if config_host.has_key('CONFIG_MODULES')
1134     error('Selected Control-Flow Integrity is not compatible with modules')
1135   endif
1136   # Check for cfi flags. CFI requires LTO so we can't use
1137   # get_supported_arguments, but need a more complex "compiles" which allows
1138   # custom arguments
1139   if cc.compiles('int main () { return 0; }', name: '-fsanitize=cfi-icall',
1140                  args: ['-flto', '-fsanitize=cfi-icall'] )
1141     cfi_flags += '-fsanitize=cfi-icall'
1142   else
1143     error('-fsanitize=cfi-icall is not supported by the compiler')
1144   endif
1145   if cc.compiles('int main () { return 0; }',
1146                  name: '-fsanitize-cfi-icall-generalize-pointers',
1147                  args: ['-flto', '-fsanitize=cfi-icall',
1148                         '-fsanitize-cfi-icall-generalize-pointers'] )
1149     cfi_flags += '-fsanitize-cfi-icall-generalize-pointers'
1150   else
1151     error('-fsanitize-cfi-icall-generalize-pointers is not supported by the compiler')
1152   endif
1153   if get_option('cfi_debug')
1154     if cc.compiles('int main () { return 0; }',
1155                    name: '-fno-sanitize-trap=cfi-icall',
1156                    args: ['-flto', '-fsanitize=cfi-icall',
1157                           '-fno-sanitize-trap=cfi-icall'] )
1158       cfi_flags += '-fno-sanitize-trap=cfi-icall'
1159     else
1160       error('-fno-sanitize-trap=cfi-icall is not supported by the compiler')
1161     endif
1162   endif
1163   add_global_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1164   add_global_link_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1165 endif
1166
1167 have_host_block_device = (targetos != 'darwin' or
1168     cc.has_header('IOKit/storage/IOMedia.h'))
1169
1170 #################
1171 # config-host.h #
1172 #################
1173
1174 have_virtfs = (targetos == 'linux' and
1175     have_system and
1176     libattr.found() and
1177     libcap_ng.found())
1178
1179 have_virtfs_proxy_helper = have_virtfs and have_tools
1180
1181 if get_option('virtfs').enabled()
1182   if not have_virtfs
1183     if targetos != 'linux'
1184       error('virtio-9p (virtfs) requires Linux')
1185     elif not libcap_ng.found() or not libattr.found()
1186       error('virtio-9p (virtfs) requires libcap-ng-devel and libattr-devel')
1187     elif not have_system
1188       error('virtio-9p (virtfs) needs system emulation support')
1189     endif
1190   endif
1191 elif get_option('virtfs').disabled()
1192   have_virtfs = false
1193 endif
1194
1195 config_host_data.set_quoted('CONFIG_BINDIR', get_option('prefix') / get_option('bindir'))
1196 config_host_data.set_quoted('CONFIG_PREFIX', get_option('prefix'))
1197 config_host_data.set_quoted('CONFIG_QEMU_CONFDIR', get_option('prefix') / qemu_confdir)
1198 config_host_data.set_quoted('CONFIG_QEMU_DATADIR', get_option('prefix') / qemu_datadir)
1199 config_host_data.set_quoted('CONFIG_QEMU_DESKTOPDIR', get_option('prefix') / qemu_desktopdir)
1200 config_host_data.set_quoted('CONFIG_QEMU_FIRMWAREPATH', get_option('qemu_firmwarepath'))
1201 config_host_data.set_quoted('CONFIG_QEMU_HELPERDIR', get_option('prefix') / get_option('libexecdir'))
1202 config_host_data.set_quoted('CONFIG_QEMU_ICONDIR', get_option('prefix') / qemu_icondir)
1203 config_host_data.set_quoted('CONFIG_QEMU_LOCALEDIR', get_option('prefix') / get_option('localedir'))
1204 config_host_data.set_quoted('CONFIG_QEMU_LOCALSTATEDIR', get_option('prefix') / get_option('localstatedir'))
1205 config_host_data.set_quoted('CONFIG_QEMU_MODDIR', get_option('prefix') / qemu_moddir)
1206 config_host_data.set_quoted('CONFIG_SYSCONFDIR', get_option('prefix') / get_option('sysconfdir'))
1207
1208 config_host_data.set('CONFIG_ATTR', libattr.found())
1209 config_host_data.set('CONFIG_BRLAPI', brlapi.found())
1210 config_host_data.set('CONFIG_COCOA', cocoa.found())
1211 config_host_data.set('CONFIG_LIBUDEV', libudev.found())
1212 config_host_data.set('CONFIG_LZO', lzo.found())
1213 config_host_data.set('CONFIG_MPATH', mpathpersist.found())
1214 config_host_data.set('CONFIG_MPATH_NEW_API', mpathpersist_new_api)
1215 config_host_data.set('CONFIG_CURL', curl.found())
1216 config_host_data.set('CONFIG_CURSES', curses.found())
1217 config_host_data.set('CONFIG_GLUSTERFS', glusterfs.found())
1218 if glusterfs.found()
1219   config_host_data.set('CONFIG_GLUSTERFS_XLATOR_OPT', glusterfs.version().version_compare('>=4'))
1220   config_host_data.set('CONFIG_GLUSTERFS_DISCARD', glusterfs.version().version_compare('>=5'))
1221   config_host_data.set('CONFIG_GLUSTERFS_FALLOCATE', glusterfs.version().version_compare('>=6'))
1222   config_host_data.set('CONFIG_GLUSTERFS_ZEROFILL', glusterfs.version().version_compare('>=6'))
1223   config_host_data.set('CONFIG_GLUSTERFS_FTRUNCATE_HAS_STAT', glusterfs_ftruncate_has_stat)
1224   config_host_data.set('CONFIG_GLUSTERFS_IOCB_HAS_STAT', glusterfs_iocb_has_stat)
1225 endif
1226 config_host_data.set('CONFIG_GTK', gtk.found())
1227 config_host_data.set('CONFIG_VTE', vte.found())
1228 config_host_data.set('CONFIG_LIBATTR', have_old_libattr)
1229 config_host_data.set('CONFIG_LIBCAP_NG', libcap_ng.found())
1230 config_host_data.set('CONFIG_EBPF', libbpf.found())
1231 config_host_data.set('CONFIG_LIBDAXCTL', libdaxctl.found())
1232 config_host_data.set('CONFIG_LIBISCSI', libiscsi.found())
1233 config_host_data.set('CONFIG_LIBNFS', libnfs.found())
1234 config_host_data.set('CONFIG_LINUX_IO_URING', linux_io_uring.found())
1235 config_host_data.set('CONFIG_LIBPMEM', libpmem.found())
1236 config_host_data.set('CONFIG_RBD', rbd.found())
1237 config_host_data.set('CONFIG_SDL', sdl.found())
1238 config_host_data.set('CONFIG_SDL_IMAGE', sdl_image.found())
1239 config_host_data.set('CONFIG_SECCOMP', seccomp.found())
1240 config_host_data.set('CONFIG_SNAPPY', snappy.found())
1241 config_host_data.set('CONFIG_USB_LIBUSB', libusb.found())
1242 config_host_data.set('CONFIG_VHOST_USER_BLK_SERVER', have_vhost_user_blk_server)
1243 config_host_data.set('CONFIG_VNC', vnc.found())
1244 config_host_data.set('CONFIG_VNC_JPEG', jpeg.found())
1245 config_host_data.set('CONFIG_VNC_PNG', png.found())
1246 config_host_data.set('CONFIG_VNC_SASL', sasl.found())
1247 config_host_data.set('CONFIG_VIRTFS', have_virtfs)
1248 config_host_data.set('CONFIG_VTE', vte.found())
1249 config_host_data.set('CONFIG_XKBCOMMON', xkbcommon.found())
1250 config_host_data.set('CONFIG_KEYUTILS', keyutils.found())
1251 config_host_data.set('CONFIG_GETTID', has_gettid)
1252 config_host_data.set('CONFIG_GNUTLS', gnutls.found())
1253 config_host_data.set('CONFIG_GCRYPT', gcrypt.found())
1254 config_host_data.set('CONFIG_NETTLE', nettle.found())
1255 config_host_data.set('CONFIG_QEMU_PRIVATE_XTS', xts == 'private')
1256 config_host_data.set('CONFIG_MALLOC_TRIM', has_malloc_trim)
1257 config_host_data.set('CONFIG_STATX', has_statx)
1258 config_host_data.set('CONFIG_ZSTD', zstd.found())
1259 config_host_data.set('CONFIG_FUSE', fuse.found())
1260 config_host_data.set('CONFIG_FUSE_LSEEK', fuse_lseek.found())
1261 config_host_data.set('CONFIG_X11', x11.found())
1262 config_host_data.set('CONFIG_CFI', get_option('cfi'))
1263 config_host_data.set('QEMU_VERSION', '"@0@"'.format(meson.project_version()))
1264 config_host_data.set('QEMU_VERSION_MAJOR', meson.project_version().split('.')[0])
1265 config_host_data.set('QEMU_VERSION_MINOR', meson.project_version().split('.')[1])
1266 config_host_data.set('QEMU_VERSION_MICRO', meson.project_version().split('.')[2])
1267
1268 config_host_data.set('HAVE_HOST_BLOCK_DEVICE', have_host_block_device)
1269
1270 # has_header
1271 config_host_data.set('CONFIG_EPOLL', cc.has_header('sys/epoll.h'))
1272 config_host_data.set('CONFIG_LINUX_MAGIC_H', cc.has_header('linux/magic.h'))
1273 config_host_data.set('CONFIG_VALGRIND_H', cc.has_header('valgrind/valgrind.h'))
1274 config_host_data.set('HAVE_BTRFS_H', cc.has_header('linux/btrfs.h'))
1275 config_host_data.set('HAVE_DRM_H', cc.has_header('libdrm/drm.h'))
1276 config_host_data.set('HAVE_PTY_H', cc.has_header('pty.h'))
1277 config_host_data.set('HAVE_SYS_DISK_H', cc.has_header('sys/disk.h'))
1278 config_host_data.set('HAVE_SYS_IOCCOM_H', cc.has_header('sys/ioccom.h'))
1279 config_host_data.set('HAVE_SYS_KCOV_H', cc.has_header('sys/kcov.h'))
1280
1281 # has_function
1282 config_host_data.set('CONFIG_ACCEPT4', cc.has_function('accept4'))
1283 config_host_data.set('CONFIG_CLOCK_ADJTIME', cc.has_function('clock_adjtime'))
1284 config_host_data.set('CONFIG_DUP3', cc.has_function('dup3'))
1285 config_host_data.set('CONFIG_FALLOCATE', cc.has_function('fallocate'))
1286 config_host_data.set('CONFIG_POSIX_FALLOCATE', cc.has_function('posix_fallocate'))
1287 config_host_data.set('CONFIG_POSIX_MEMALIGN', cc.has_function('posix_memalign'))
1288 config_host_data.set('CONFIG_PPOLL', cc.has_function('ppoll'))
1289 config_host_data.set('CONFIG_PREADV', cc.has_function('preadv', prefix: '#include <sys/uio.h>'))
1290 config_host_data.set('CONFIG_SEM_TIMEDWAIT', cc.has_function('sem_timedwait', dependencies: threads))
1291 config_host_data.set('CONFIG_SENDFILE', cc.has_function('sendfile'))
1292 config_host_data.set('CONFIG_SETNS', cc.has_function('setns') and cc.has_function('unshare'))
1293 config_host_data.set('CONFIG_SYNCFS', cc.has_function('syncfs'))
1294 config_host_data.set('CONFIG_SYNC_FILE_RANGE', cc.has_function('sync_file_range'))
1295 config_host_data.set('CONFIG_TIMERFD', cc.has_function('timerfd_create'))
1296 config_host_data.set('HAVE_COPY_FILE_RANGE', cc.has_function('copy_file_range'))
1297 config_host_data.set('HAVE_OPENPTY', cc.has_function('openpty', dependencies: util))
1298 config_host_data.set('HAVE_STRCHRNUL', cc.has_function('strchrnul'))
1299 config_host_data.set('HAVE_SYSTEM_FUNCTION', cc.has_function('system', prefix: '#include <stdlib.h>'))
1300
1301 # has_header_symbol
1302 config_host_data.set('CONFIG_BYTESWAP_H',
1303                      cc.has_header_symbol('byteswap.h', 'bswap_32'))
1304 config_host_data.set('CONFIG_EPOLL_CREATE1',
1305                      cc.has_header_symbol('sys/epoll.h', 'epoll_create1'))
1306 config_host_data.set('CONFIG_HAS_ENVIRON',
1307                      cc.has_header_symbol('unistd.h', 'environ', prefix: gnu_source_prefix))
1308 config_host_data.set('CONFIG_FALLOCATE_PUNCH_HOLE',
1309                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_PUNCH_HOLE') and
1310                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_KEEP_SIZE'))
1311 config_host_data.set('CONFIG_FALLOCATE_ZERO_RANGE',
1312                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_ZERO_RANGE'))
1313 config_host_data.set('CONFIG_FIEMAP',
1314                      cc.has_header('linux/fiemap.h') and
1315                      cc.has_header_symbol('linux/fs.h', 'FS_IOC_FIEMAP'))
1316 config_host_data.set('CONFIG_GETRANDOM',
1317                      cc.has_function('getrandom') and
1318                      cc.has_header_symbol('sys/random.h', 'GRND_NONBLOCK'))
1319 config_host_data.set('CONFIG_INOTIFY',
1320                      cc.has_header_symbol('sys/inotify.h', 'inotify_init'))
1321 config_host_data.set('CONFIG_INOTIFY1',
1322                      cc.has_header_symbol('sys/inotify.h', 'inotify_init1'))
1323 config_host_data.set('CONFIG_MACHINE_BSWAP_H',
1324                      cc.has_header_symbol('machine/bswap.h', 'bswap32',
1325                                           prefix: '''#include <sys/endian.h>
1326                                                      #include <sys/types.h>'''))
1327 config_host_data.set('CONFIG_PRCTL_PR_SET_TIMERSLACK',
1328                      cc.has_header_symbol('sys/prctl.h', 'PR_SET_TIMERSLACK'))
1329 config_host_data.set('CONFIG_RTNETLINK',
1330                      cc.has_header_symbol('linux/rtnetlink.h', 'IFLA_PROTO_DOWN'))
1331 config_host_data.set('CONFIG_SYSMACROS',
1332                      cc.has_header_symbol('sys/sysmacros.h', 'makedev'))
1333 config_host_data.set('HAVE_OPTRESET',
1334                      cc.has_header_symbol('getopt.h', 'optreset'))
1335 config_host_data.set('HAVE_UTMPX',
1336                      cc.has_header_symbol('utmpx.h', 'struct utmpx'))
1337
1338 # has_member
1339 config_host_data.set('HAVE_SIGEV_NOTIFY_THREAD_ID',
1340                      cc.has_member('struct sigevent', 'sigev_notify_thread_id',
1341                                    prefix: '#include <signal.h>'))
1342 config_host_data.set('HAVE_STRUCT_STAT_ST_ATIM',
1343                      cc.has_member('struct stat', 'st_atim',
1344                                    prefix: '#include <sys/stat.h>'))
1345
1346 config_host_data.set('CONFIG_EVENTFD', cc.links('''
1347   #include <sys/eventfd.h>
1348   int main(void) { return eventfd(0, EFD_NONBLOCK | EFD_CLOEXEC); }'''))
1349 config_host_data.set('CONFIG_FDATASYNC', cc.links(gnu_source_prefix + '''
1350   #include <unistd.h>
1351   int main(void) {
1352   #if defined(_POSIX_SYNCHRONIZED_IO) && _POSIX_SYNCHRONIZED_IO > 0
1353   return fdatasync(0);
1354   #else
1355   #error Not supported
1356   #endif
1357   }'''))
1358 config_host_data.set('CONFIG_MADVISE', cc.links(gnu_source_prefix + '''
1359   #include <sys/types.h>
1360   #include <sys/mman.h>
1361   #include <stddef.h>
1362   int main(void) { return madvise(NULL, 0, MADV_DONTNEED); }'''))
1363 config_host_data.set('CONFIG_MEMFD', cc.links(gnu_source_prefix + '''
1364   #include <sys/mman.h>
1365   int main(void) { return memfd_create("foo", MFD_ALLOW_SEALING); }'''))
1366 config_host_data.set('CONFIG_OPEN_BY_HANDLE', cc.links(gnu_source_prefix + '''
1367   #include <fcntl.h>
1368   #if !defined(AT_EMPTY_PATH)
1369   # error missing definition
1370   #else
1371   int main(void) { struct file_handle fh; return open_by_handle_at(0, &fh, 0); }
1372   #endif'''))
1373 config_host_data.set('CONFIG_PIPE2', cc.links(gnu_source_prefix + '''
1374   #include <unistd.h>
1375   #include <fcntl.h>
1376
1377   int main(void)
1378   {
1379       int pipefd[2];
1380       return pipe2(pipefd, O_CLOEXEC);
1381   }'''))
1382 config_host_data.set('CONFIG_POSIX_MADVISE', cc.links(gnu_source_prefix + '''
1383   #include <sys/mman.h>
1384   #include <stddef.h>
1385   int main(void) { return posix_madvise(NULL, 0, POSIX_MADV_DONTNEED); }'''))
1386 config_host_data.set('CONFIG_SIGNALFD', cc.links(gnu_source_prefix + '''
1387   #include <unistd.h>
1388   #include <sys/syscall.h>
1389   #include <signal.h>
1390   int main(void) { return syscall(SYS_signalfd, -1, NULL, _NSIG / 8); }'''))
1391 config_host_data.set('CONFIG_SPLICE', cc.links(gnu_source_prefix + '''
1392   #include <unistd.h>
1393   #include <fcntl.h>
1394   #include <limits.h>
1395
1396   int main(void)
1397   {
1398     int len, fd = 0;
1399     len = tee(STDIN_FILENO, STDOUT_FILENO, INT_MAX, SPLICE_F_NONBLOCK);
1400     splice(STDIN_FILENO, NULL, fd, NULL, len, SPLICE_F_MOVE);
1401     return 0;
1402   }'''))
1403
1404 # Some versions of Mac OS X incorrectly define SIZE_MAX
1405 config_host_data.set('HAVE_BROKEN_SIZE_MAX', not cc.compiles('''
1406     #include <stdint.h>
1407     #include <stdio.h>
1408     int main(int argc, char *argv[]) {
1409         return printf("%zu", SIZE_MAX);
1410     }''', args: ['-Werror']))
1411
1412
1413 ignored = ['CONFIG_QEMU_INTERP_PREFIX'] # actually per-target
1414 arrays = ['CONFIG_AUDIO_DRIVERS', 'CONFIG_BDRV_RW_WHITELIST', 'CONFIG_BDRV_RO_WHITELIST']
1415 strings = ['HOST_DSOSUF', 'CONFIG_IASL']
1416 foreach k, v: config_host
1417   if ignored.contains(k)
1418     # do nothing
1419   elif arrays.contains(k)
1420     if v != ''
1421       v = '"' + '", "'.join(v.split()) + '", '
1422     endif
1423     config_host_data.set(k, v)
1424   elif k == 'ARCH'
1425     config_host_data.set('HOST_' + v.to_upper(), 1)
1426   elif strings.contains(k)
1427     if not k.startswith('CONFIG_')
1428       k = 'CONFIG_' + k.to_upper()
1429     endif
1430     config_host_data.set_quoted(k, v)
1431   elif k.startswith('CONFIG_') or k.startswith('HAVE_') or k.startswith('HOST_')
1432     config_host_data.set(k, v == 'y' ? 1 : v)
1433   endif
1434 endforeach
1435
1436 ########################
1437 # Target configuration #
1438 ########################
1439
1440 minikconf = find_program('scripts/minikconf.py')
1441 config_all = {}
1442 config_all_devices = {}
1443 config_all_disas = {}
1444 config_devices_mak_list = []
1445 config_devices_h = {}
1446 config_target_h = {}
1447 config_target_mak = {}
1448
1449 disassemblers = {
1450   'alpha' : ['CONFIG_ALPHA_DIS'],
1451   'arm' : ['CONFIG_ARM_DIS'],
1452   'avr' : ['CONFIG_AVR_DIS'],
1453   'cris' : ['CONFIG_CRIS_DIS'],
1454   'hexagon' : ['CONFIG_HEXAGON_DIS'],
1455   'hppa' : ['CONFIG_HPPA_DIS'],
1456   'i386' : ['CONFIG_I386_DIS'],
1457   'x86_64' : ['CONFIG_I386_DIS'],
1458   'x32' : ['CONFIG_I386_DIS'],
1459   'm68k' : ['CONFIG_M68K_DIS'],
1460   'microblaze' : ['CONFIG_MICROBLAZE_DIS'],
1461   'mips' : ['CONFIG_MIPS_DIS'],
1462   'nios2' : ['CONFIG_NIOS2_DIS'],
1463   'or1k' : ['CONFIG_OPENRISC_DIS'],
1464   'ppc' : ['CONFIG_PPC_DIS'],
1465   'riscv' : ['CONFIG_RISCV_DIS'],
1466   'rx' : ['CONFIG_RX_DIS'],
1467   's390' : ['CONFIG_S390_DIS'],
1468   'sh4' : ['CONFIG_SH4_DIS'],
1469   'sparc' : ['CONFIG_SPARC_DIS'],
1470   'xtensa' : ['CONFIG_XTENSA_DIS'],
1471 }
1472 if link_language == 'cpp'
1473   disassemblers += {
1474     'aarch64' : [ 'CONFIG_ARM_A64_DIS'],
1475     'arm' : [ 'CONFIG_ARM_DIS', 'CONFIG_ARM_A64_DIS'],
1476     'mips' : [ 'CONFIG_MIPS_DIS', 'CONFIG_NANOMIPS_DIS'],
1477   }
1478 endif
1479
1480 have_ivshmem = config_host_data.get('CONFIG_EVENTFD')
1481 host_kconfig = \
1482   ('CONFIG_TPM' in config_host ? ['CONFIG_TPM=y'] : []) + \
1483   ('CONFIG_SPICE' in config_host ? ['CONFIG_SPICE=y'] : []) + \
1484   (have_ivshmem ? ['CONFIG_IVSHMEM=y'] : []) + \
1485   ('CONFIG_OPENGL' in config_host ? ['CONFIG_OPENGL=y'] : []) + \
1486   (x11.found() ? ['CONFIG_X11=y'] : []) + \
1487   ('CONFIG_VHOST_USER' in config_host ? ['CONFIG_VHOST_USER=y'] : []) + \
1488   ('CONFIG_VHOST_VDPA' in config_host ? ['CONFIG_VHOST_VDPA=y'] : []) + \
1489   ('CONFIG_VHOST_KERNEL' in config_host ? ['CONFIG_VHOST_KERNEL=y'] : []) + \
1490   (have_virtfs ? ['CONFIG_VIRTFS=y'] : []) + \
1491   ('CONFIG_LINUX' in config_host ? ['CONFIG_LINUX=y'] : []) + \
1492   ('CONFIG_PVRDMA' in config_host ? ['CONFIG_PVRDMA=y'] : []) + \
1493   (multiprocess_allowed ? ['CONFIG_MULTIPROCESS_ALLOWED=y'] : [])
1494
1495 ignored = [ 'TARGET_XML_FILES', 'TARGET_ABI_DIR', 'TARGET_ARCH' ]
1496
1497 default_targets = 'CONFIG_DEFAULT_TARGETS' in config_host
1498 actual_target_dirs = []
1499 fdt_required = []
1500 foreach target : target_dirs
1501   config_target = { 'TARGET_NAME': target.split('-')[0] }
1502   if target.endswith('linux-user')
1503     if targetos != 'linux'
1504       if default_targets
1505         continue
1506       endif
1507       error('Target @0@ is only available on a Linux host'.format(target))
1508     endif
1509     config_target += { 'CONFIG_LINUX_USER': 'y' }
1510   elif target.endswith('bsd-user')
1511     if 'CONFIG_BSD' not in config_host
1512       if default_targets
1513         continue
1514       endif
1515       error('Target @0@ is only available on a BSD host'.format(target))
1516     endif
1517     config_target += { 'CONFIG_BSD_USER': 'y' }
1518   elif target.endswith('softmmu')
1519     config_target += { 'CONFIG_SOFTMMU': 'y' }
1520   endif
1521   if target.endswith('-user')
1522     config_target += {
1523       'CONFIG_USER_ONLY': 'y',
1524       'CONFIG_QEMU_INTERP_PREFIX':
1525         config_host['CONFIG_QEMU_INTERP_PREFIX'].format(config_target['TARGET_NAME'])
1526     }
1527   endif
1528
1529   accel_kconfig = []
1530   foreach sym: accelerators
1531     if sym == 'CONFIG_TCG' or target in accelerator_targets.get(sym, [])
1532       config_target += { sym: 'y' }
1533       config_all += { sym: 'y' }
1534       if sym == 'CONFIG_TCG' and tcg_arch == 'tci'
1535         config_target += { 'CONFIG_TCG_INTERPRETER': 'y' }
1536       elif sym == 'CONFIG_XEN' and have_xen_pci_passthrough
1537         config_target += { 'CONFIG_XEN_PCI_PASSTHROUGH': 'y' }
1538       endif
1539       if target in modular_tcg
1540         config_target += { 'CONFIG_TCG_MODULAR': 'y' }
1541       else
1542         config_target += { 'CONFIG_TCG_BUILTIN': 'y' }
1543       endif
1544       accel_kconfig += [ sym + '=y' ]
1545     endif
1546   endforeach
1547   if accel_kconfig.length() == 0
1548     if default_targets
1549       continue
1550     endif
1551     error('No accelerator available for target @0@'.format(target))
1552   endif
1553
1554   actual_target_dirs += target
1555   config_target += keyval.load('configs/targets' / target + '.mak')
1556   config_target += { 'TARGET_' + config_target['TARGET_ARCH'].to_upper(): 'y' }
1557
1558   if 'TARGET_NEED_FDT' in config_target
1559     fdt_required += target
1560   endif
1561
1562   # Add default keys
1563   if 'TARGET_BASE_ARCH' not in config_target
1564     config_target += {'TARGET_BASE_ARCH': config_target['TARGET_ARCH']}
1565   endif
1566   if 'TARGET_ABI_DIR' not in config_target
1567     config_target += {'TARGET_ABI_DIR': config_target['TARGET_ARCH']}
1568   endif
1569
1570   foreach k, v: disassemblers
1571     if config_host['ARCH'].startswith(k) or config_target['TARGET_BASE_ARCH'].startswith(k)
1572       foreach sym: v
1573         config_target += { sym: 'y' }
1574         config_all_disas += { sym: 'y' }
1575       endforeach
1576     endif
1577   endforeach
1578
1579   config_target_data = configuration_data()
1580   foreach k, v: config_target
1581     if not k.startswith('TARGET_') and not k.startswith('CONFIG_')
1582       # do nothing
1583     elif ignored.contains(k)
1584       # do nothing
1585     elif k == 'TARGET_BASE_ARCH'
1586       # Note that TARGET_BASE_ARCH ends up in config-target.h but it is
1587       # not used to select files from sourcesets.
1588       config_target_data.set('TARGET_' + v.to_upper(), 1)
1589     elif k == 'TARGET_NAME' or k == 'CONFIG_QEMU_INTERP_PREFIX'
1590       config_target_data.set_quoted(k, v)
1591     elif v == 'y'
1592       config_target_data.set(k, 1)
1593     else
1594       config_target_data.set(k, v)
1595     endif
1596   endforeach
1597   config_target_h += {target: configure_file(output: target + '-config-target.h',
1598                                                configuration: config_target_data)}
1599
1600   if target.endswith('-softmmu')
1601     config_input = meson.get_external_property(target, 'default')
1602     config_devices_mak = target + '-config-devices.mak'
1603     config_devices_mak = configure_file(
1604       input: ['configs/devices' / target / config_input + '.mak', 'Kconfig'],
1605       output: config_devices_mak,
1606       depfile: config_devices_mak + '.d',
1607       capture: true,
1608       command: [minikconf,
1609                 get_option('default_devices') ? '--defconfig' : '--allnoconfig',
1610                 config_devices_mak, '@DEPFILE@', '@INPUT@',
1611                 host_kconfig, accel_kconfig,
1612                 'CONFIG_' + config_target['TARGET_ARCH'].to_upper() + '=y'])
1613
1614     config_devices_data = configuration_data()
1615     config_devices = keyval.load(config_devices_mak)
1616     foreach k, v: config_devices
1617       config_devices_data.set(k, 1)
1618     endforeach
1619     config_devices_mak_list += config_devices_mak
1620     config_devices_h += {target: configure_file(output: target + '-config-devices.h',
1621                                                 configuration: config_devices_data)}
1622     config_target += config_devices
1623     config_all_devices += config_devices
1624   endif
1625   config_target_mak += {target: config_target}
1626 endforeach
1627 target_dirs = actual_target_dirs
1628
1629 # This configuration is used to build files that are shared by
1630 # multiple binaries, and then extracted out of the "common"
1631 # static_library target.
1632 #
1633 # We do not use all_sources()/all_dependencies(), because it would
1634 # build literally all source files, including devices only used by
1635 # targets that are not built for this compilation.  The CONFIG_ALL
1636 # pseudo symbol replaces it.
1637
1638 config_all += config_all_devices
1639 config_all += config_host
1640 config_all += config_all_disas
1641 config_all += {
1642   'CONFIG_XEN': config_host.has_key('CONFIG_XEN_BACKEND'),
1643   'CONFIG_SOFTMMU': have_system,
1644   'CONFIG_USER_ONLY': have_user,
1645   'CONFIG_ALL': true,
1646 }
1647
1648 ##############
1649 # Submodules #
1650 ##############
1651
1652 capstone = not_found
1653 capstone_opt = get_option('capstone')
1654 if capstone_opt in ['enabled', 'auto', 'system']
1655   have_internal = fs.exists(meson.current_source_dir() / 'capstone/Makefile')
1656   capstone = dependency('capstone', version: '>=4.0',
1657                         kwargs: static_kwargs, method: 'pkg-config',
1658                         required: capstone_opt == 'system' or
1659                                   capstone_opt == 'enabled' and not have_internal)
1660
1661   # Some versions of capstone have broken pkg-config file
1662   # that reports a wrong -I path, causing the #include to
1663   # fail later. If the system has such a broken version
1664   # do not use it.
1665   if capstone.found() and not cc.compiles('#include <capstone.h>',
1666                                           dependencies: [capstone])
1667     capstone = not_found
1668     if capstone_opt == 'system'
1669       error('system capstone requested, it does not appear to work')
1670     endif
1671   endif
1672
1673   if capstone.found()
1674     capstone_opt = 'system'
1675   elif have_internal
1676     capstone_opt = 'internal'
1677   else
1678     capstone_opt = 'disabled'
1679   endif
1680 endif
1681 if capstone_opt == 'internal'
1682   capstone_data = configuration_data()
1683   capstone_data.set('CAPSTONE_USE_SYS_DYN_MEM', '1')
1684
1685   capstone_files = files(
1686     'capstone/cs.c',
1687     'capstone/MCInst.c',
1688     'capstone/MCInstrDesc.c',
1689     'capstone/MCRegisterInfo.c',
1690     'capstone/SStream.c',
1691     'capstone/utils.c'
1692   )
1693
1694   if 'CONFIG_ARM_DIS' in config_all_disas
1695     capstone_data.set('CAPSTONE_HAS_ARM', '1')
1696     capstone_files += files(
1697       'capstone/arch/ARM/ARMDisassembler.c',
1698       'capstone/arch/ARM/ARMInstPrinter.c',
1699       'capstone/arch/ARM/ARMMapping.c',
1700       'capstone/arch/ARM/ARMModule.c'
1701     )
1702   endif
1703
1704   # FIXME: This config entry currently depends on a c++ compiler.
1705   # Which is needed for building libvixl, but not for capstone.
1706   if 'CONFIG_ARM_A64_DIS' in config_all_disas
1707     capstone_data.set('CAPSTONE_HAS_ARM64', '1')
1708     capstone_files += files(
1709       'capstone/arch/AArch64/AArch64BaseInfo.c',
1710       'capstone/arch/AArch64/AArch64Disassembler.c',
1711       'capstone/arch/AArch64/AArch64InstPrinter.c',
1712       'capstone/arch/AArch64/AArch64Mapping.c',
1713       'capstone/arch/AArch64/AArch64Module.c'
1714     )
1715   endif
1716
1717   if 'CONFIG_PPC_DIS' in config_all_disas
1718     capstone_data.set('CAPSTONE_HAS_POWERPC', '1')
1719     capstone_files += files(
1720       'capstone/arch/PowerPC/PPCDisassembler.c',
1721       'capstone/arch/PowerPC/PPCInstPrinter.c',
1722       'capstone/arch/PowerPC/PPCMapping.c',
1723       'capstone/arch/PowerPC/PPCModule.c'
1724     )
1725   endif
1726
1727   if 'CONFIG_S390_DIS' in config_all_disas
1728     capstone_data.set('CAPSTONE_HAS_SYSZ', '1')
1729     capstone_files += files(
1730       'capstone/arch/SystemZ/SystemZDisassembler.c',
1731       'capstone/arch/SystemZ/SystemZInstPrinter.c',
1732       'capstone/arch/SystemZ/SystemZMapping.c',
1733       'capstone/arch/SystemZ/SystemZModule.c',
1734       'capstone/arch/SystemZ/SystemZMCTargetDesc.c'
1735     )
1736   endif
1737
1738   if 'CONFIG_I386_DIS' in config_all_disas
1739     capstone_data.set('CAPSTONE_HAS_X86', 1)
1740     capstone_files += files(
1741       'capstone/arch/X86/X86Disassembler.c',
1742       'capstone/arch/X86/X86DisassemblerDecoder.c',
1743       'capstone/arch/X86/X86ATTInstPrinter.c',
1744       'capstone/arch/X86/X86IntelInstPrinter.c',
1745       'capstone/arch/X86/X86InstPrinterCommon.c',
1746       'capstone/arch/X86/X86Mapping.c',
1747       'capstone/arch/X86/X86Module.c'
1748     )
1749   endif
1750
1751   configure_file(output: 'capstone-defs.h', configuration: capstone_data)
1752
1753   capstone_cargs = [
1754     # FIXME: There does not seem to be a way to completely replace the c_args
1755     # that come from add_project_arguments() -- we can only add to them.
1756     # So: disable all warnings with a big hammer.
1757     '-Wno-error', '-w',
1758
1759     # Include all configuration defines via a header file, which will wind up
1760     # as a dependency on the object file, and thus changes here will result
1761     # in a rebuild.
1762     '-include', 'capstone-defs.h'
1763   ]
1764
1765   libcapstone = static_library('capstone',
1766                                build_by_default: false,
1767                                sources: capstone_files,
1768                                c_args: capstone_cargs,
1769                                include_directories: 'capstone/include')
1770   capstone = declare_dependency(link_with: libcapstone,
1771                                 include_directories: 'capstone/include/capstone')
1772 endif
1773
1774 slirp = not_found
1775 slirp_opt = 'disabled'
1776 if have_system
1777   slirp_opt = get_option('slirp')
1778   if slirp_opt in ['enabled', 'auto', 'system']
1779     have_internal = fs.exists(meson.current_source_dir() / 'slirp/meson.build')
1780     slirp = dependency('slirp', kwargs: static_kwargs,
1781                        method: 'pkg-config',
1782                        required: slirp_opt == 'system' or
1783                                  slirp_opt == 'enabled' and not have_internal)
1784     if slirp.found()
1785       slirp_opt = 'system'
1786     elif have_internal
1787       slirp_opt = 'internal'
1788     else
1789       slirp_opt = 'disabled'
1790     endif
1791   endif
1792   if slirp_opt == 'internal'
1793     slirp_deps = []
1794     if targetos == 'windows'
1795       slirp_deps = cc.find_library('iphlpapi')
1796     endif
1797     slirp_conf = configuration_data()
1798     slirp_conf.set('SLIRP_MAJOR_VERSION', meson.project_version().split('.')[0])
1799     slirp_conf.set('SLIRP_MINOR_VERSION', meson.project_version().split('.')[1])
1800     slirp_conf.set('SLIRP_MICRO_VERSION', meson.project_version().split('.')[2])
1801     slirp_conf.set_quoted('SLIRP_VERSION_STRING', meson.project_version())
1802     slirp_cargs = ['-DG_LOG_DOMAIN="Slirp"']
1803     slirp_files = [
1804       'slirp/src/arp_table.c',
1805       'slirp/src/bootp.c',
1806       'slirp/src/cksum.c',
1807       'slirp/src/dhcpv6.c',
1808       'slirp/src/dnssearch.c',
1809       'slirp/src/if.c',
1810       'slirp/src/ip6_icmp.c',
1811       'slirp/src/ip6_input.c',
1812       'slirp/src/ip6_output.c',
1813       'slirp/src/ip_icmp.c',
1814       'slirp/src/ip_input.c',
1815       'slirp/src/ip_output.c',
1816       'slirp/src/mbuf.c',
1817       'slirp/src/misc.c',
1818       'slirp/src/ncsi.c',
1819       'slirp/src/ndp_table.c',
1820       'slirp/src/sbuf.c',
1821       'slirp/src/slirp.c',
1822       'slirp/src/socket.c',
1823       'slirp/src/state.c',
1824       'slirp/src/stream.c',
1825       'slirp/src/tcp_input.c',
1826       'slirp/src/tcp_output.c',
1827       'slirp/src/tcp_subr.c',
1828       'slirp/src/tcp_timer.c',
1829       'slirp/src/tftp.c',
1830       'slirp/src/udp.c',
1831       'slirp/src/udp6.c',
1832       'slirp/src/util.c',
1833       'slirp/src/version.c',
1834       'slirp/src/vmstate.c',
1835     ]
1836
1837     configure_file(
1838       input : 'slirp/src/libslirp-version.h.in',
1839       output : 'libslirp-version.h',
1840       configuration: slirp_conf)
1841
1842     slirp_inc = include_directories('slirp', 'slirp/src')
1843     libslirp = static_library('slirp',
1844                               build_by_default: false,
1845                               sources: slirp_files,
1846                               c_args: slirp_cargs,
1847                               include_directories: slirp_inc)
1848     slirp = declare_dependency(link_with: libslirp,
1849                                dependencies: slirp_deps,
1850                                include_directories: slirp_inc)
1851   endif
1852 endif
1853
1854 # For CFI, we need to compile slirp as a static library together with qemu.
1855 # This is because we register slirp functions as callbacks for QEMU Timers.
1856 # When using a system-wide shared libslirp, the type information for the
1857 # callback is missing and the timer call produces a false positive with CFI.
1858 #
1859 # Now that slirp_opt has been defined, check if the selected slirp is compatible
1860 # with control-flow integrity.
1861 if get_option('cfi') and slirp_opt == 'system'
1862   error('Control-Flow Integrity is not compatible with system-wide slirp.' \
1863          + ' Please configure with --enable-slirp=git')
1864 endif
1865
1866 fdt = not_found
1867 fdt_opt = get_option('fdt')
1868 if have_system
1869   if fdt_opt in ['enabled', 'auto', 'system']
1870     have_internal = fs.exists(meson.current_source_dir() / 'dtc/libfdt/Makefile.libfdt')
1871     fdt = cc.find_library('fdt', kwargs: static_kwargs,
1872                           required: fdt_opt == 'system' or
1873                                     fdt_opt == 'enabled' and not have_internal)
1874     if fdt.found() and cc.links('''
1875        #include <libfdt.h>
1876        #include <libfdt_env.h>
1877        int main(void) { fdt_check_full(NULL, 0); return 0; }''',
1878          dependencies: fdt)
1879       fdt_opt = 'system'
1880     elif have_internal
1881       fdt_opt = 'internal'
1882     else
1883       fdt_opt = 'disabled'
1884     endif
1885   endif
1886   if fdt_opt == 'internal'
1887     fdt_files = files(
1888       'dtc/libfdt/fdt.c',
1889       'dtc/libfdt/fdt_ro.c',
1890       'dtc/libfdt/fdt_wip.c',
1891       'dtc/libfdt/fdt_sw.c',
1892       'dtc/libfdt/fdt_rw.c',
1893       'dtc/libfdt/fdt_strerror.c',
1894       'dtc/libfdt/fdt_empty_tree.c',
1895       'dtc/libfdt/fdt_addresses.c',
1896       'dtc/libfdt/fdt_overlay.c',
1897       'dtc/libfdt/fdt_check.c',
1898     )
1899
1900     fdt_inc = include_directories('dtc/libfdt')
1901     libfdt = static_library('fdt',
1902                             build_by_default: false,
1903                             sources: fdt_files,
1904                             include_directories: fdt_inc)
1905     fdt = declare_dependency(link_with: libfdt,
1906                              include_directories: fdt_inc)
1907   endif
1908 endif
1909 if not fdt.found() and fdt_required.length() > 0
1910   error('fdt not available but required by targets ' + ', '.join(fdt_required))
1911 endif
1912
1913 config_host_data.set('CONFIG_CAPSTONE', capstone.found())
1914 config_host_data.set('CONFIG_FDT', fdt.found())
1915 config_host_data.set('CONFIG_SLIRP', slirp.found())
1916
1917 #####################
1918 # Generated sources #
1919 #####################
1920
1921 genh += configure_file(output: 'config-host.h', configuration: config_host_data)
1922
1923 hxtool = find_program('scripts/hxtool')
1924 shaderinclude = find_program('scripts/shaderinclude.pl')
1925 qapi_gen = find_program('scripts/qapi-gen.py')
1926 qapi_gen_depends = [ meson.source_root() / 'scripts/qapi/__init__.py',
1927                      meson.source_root() / 'scripts/qapi/commands.py',
1928                      meson.source_root() / 'scripts/qapi/common.py',
1929                      meson.source_root() / 'scripts/qapi/error.py',
1930                      meson.source_root() / 'scripts/qapi/events.py',
1931                      meson.source_root() / 'scripts/qapi/expr.py',
1932                      meson.source_root() / 'scripts/qapi/gen.py',
1933                      meson.source_root() / 'scripts/qapi/introspect.py',
1934                      meson.source_root() / 'scripts/qapi/parser.py',
1935                      meson.source_root() / 'scripts/qapi/schema.py',
1936                      meson.source_root() / 'scripts/qapi/source.py',
1937                      meson.source_root() / 'scripts/qapi/types.py',
1938                      meson.source_root() / 'scripts/qapi/visit.py',
1939                      meson.source_root() / 'scripts/qapi/common.py',
1940                      meson.source_root() / 'scripts/qapi-gen.py'
1941 ]
1942
1943 tracetool = [
1944   python, files('scripts/tracetool.py'),
1945    '--backend=' + config_host['TRACE_BACKENDS']
1946 ]
1947 tracetool_depends = files(
1948   'scripts/tracetool/backend/log.py',
1949   'scripts/tracetool/backend/__init__.py',
1950   'scripts/tracetool/backend/dtrace.py',
1951   'scripts/tracetool/backend/ftrace.py',
1952   'scripts/tracetool/backend/simple.py',
1953   'scripts/tracetool/backend/syslog.py',
1954   'scripts/tracetool/backend/ust.py',
1955   'scripts/tracetool/format/tcg_h.py',
1956   'scripts/tracetool/format/ust_events_c.py',
1957   'scripts/tracetool/format/ust_events_h.py',
1958   'scripts/tracetool/format/__init__.py',
1959   'scripts/tracetool/format/d.py',
1960   'scripts/tracetool/format/tcg_helper_c.py',
1961   'scripts/tracetool/format/simpletrace_stap.py',
1962   'scripts/tracetool/format/c.py',
1963   'scripts/tracetool/format/h.py',
1964   'scripts/tracetool/format/tcg_helper_h.py',
1965   'scripts/tracetool/format/log_stap.py',
1966   'scripts/tracetool/format/stap.py',
1967   'scripts/tracetool/format/tcg_helper_wrapper_h.py',
1968   'scripts/tracetool/__init__.py',
1969   'scripts/tracetool/transform.py',
1970   'scripts/tracetool/vcpu.py'
1971 )
1972
1973 qemu_version_cmd = [find_program('scripts/qemu-version.sh'),
1974                     meson.current_source_dir(),
1975                     config_host['PKGVERSION'], meson.project_version()]
1976 qemu_version = custom_target('qemu-version.h',
1977                              output: 'qemu-version.h',
1978                              command: qemu_version_cmd,
1979                              capture: true,
1980                              build_by_default: true,
1981                              build_always_stale: true)
1982 genh += qemu_version
1983
1984 hxdep = []
1985 hx_headers = [
1986   ['qemu-options.hx', 'qemu-options.def'],
1987   ['qemu-img-cmds.hx', 'qemu-img-cmds.h'],
1988 ]
1989 if have_system
1990   hx_headers += [
1991     ['hmp-commands.hx', 'hmp-commands.h'],
1992     ['hmp-commands-info.hx', 'hmp-commands-info.h'],
1993   ]
1994 endif
1995 foreach d : hx_headers
1996   hxdep += custom_target(d[1],
1997                 input: files(d[0]),
1998                 output: d[1],
1999                 capture: true,
2000                 build_by_default: true, # to be removed when added to a target
2001                 command: [hxtool, '-h', '@INPUT0@'])
2002 endforeach
2003 genh += hxdep
2004
2005 ###################
2006 # Collect sources #
2007 ###################
2008
2009 authz_ss = ss.source_set()
2010 blockdev_ss = ss.source_set()
2011 block_ss = ss.source_set()
2012 bsd_user_ss = ss.source_set()
2013 chardev_ss = ss.source_set()
2014 common_ss = ss.source_set()
2015 crypto_ss = ss.source_set()
2016 io_ss = ss.source_set()
2017 linux_user_ss = ss.source_set()
2018 qmp_ss = ss.source_set()
2019 qom_ss = ss.source_set()
2020 softmmu_ss = ss.source_set()
2021 specific_fuzz_ss = ss.source_set()
2022 specific_ss = ss.source_set()
2023 stub_ss = ss.source_set()
2024 trace_ss = ss.source_set()
2025 user_ss = ss.source_set()
2026 util_ss = ss.source_set()
2027
2028 # accel modules
2029 qtest_module_ss = ss.source_set()
2030 tcg_module_ss = ss.source_set()
2031
2032 modules = {}
2033 target_modules = {}
2034 hw_arch = {}
2035 target_arch = {}
2036 target_softmmu_arch = {}
2037 target_user_arch = {}
2038
2039 ###############
2040 # Trace files #
2041 ###############
2042
2043 # TODO: add each directory to the subdirs from its own meson.build, once
2044 # we have those
2045 trace_events_subdirs = [
2046   'crypto',
2047   'qapi',
2048   'qom',
2049   'monitor',
2050   'util',
2051 ]
2052 if have_user
2053   trace_events_subdirs += [ 'linux-user' ]
2054 endif
2055 if have_block
2056   trace_events_subdirs += [
2057     'authz',
2058     'block',
2059     'io',
2060     'nbd',
2061     'scsi',
2062   ]
2063 endif
2064 if have_system
2065   trace_events_subdirs += [
2066     'accel/kvm',
2067     'audio',
2068     'backends',
2069     'backends/tpm',
2070     'chardev',
2071     'ebpf',
2072     'hw/9pfs',
2073     'hw/acpi',
2074     'hw/adc',
2075     'hw/alpha',
2076     'hw/arm',
2077     'hw/audio',
2078     'hw/block',
2079     'hw/block/dataplane',
2080     'hw/char',
2081     'hw/display',
2082     'hw/dma',
2083     'hw/hppa',
2084     'hw/hyperv',
2085     'hw/i2c',
2086     'hw/i386',
2087     'hw/i386/xen',
2088     'hw/ide',
2089     'hw/input',
2090     'hw/intc',
2091     'hw/isa',
2092     'hw/mem',
2093     'hw/mips',
2094     'hw/misc',
2095     'hw/misc/macio',
2096     'hw/net',
2097     'hw/net/can',
2098     'hw/nvme',
2099     'hw/nvram',
2100     'hw/pci',
2101     'hw/pci-host',
2102     'hw/ppc',
2103     'hw/rdma',
2104     'hw/rdma/vmw',
2105     'hw/rtc',
2106     'hw/s390x',
2107     'hw/scsi',
2108     'hw/sd',
2109     'hw/sparc',
2110     'hw/sparc64',
2111     'hw/ssi',
2112     'hw/timer',
2113     'hw/tpm',
2114     'hw/usb',
2115     'hw/vfio',
2116     'hw/virtio',
2117     'hw/watchdog',
2118     'hw/xen',
2119     'hw/gpio',
2120     'migration',
2121     'net',
2122     'softmmu',
2123     'ui',
2124     'hw/remote',
2125   ]
2126 endif
2127 if have_system or have_user
2128   trace_events_subdirs += [
2129     'accel/tcg',
2130     'hw/core',
2131     'target/arm',
2132     'target/hppa',
2133     'target/i386',
2134     'target/i386/kvm',
2135     'target/mips/tcg',
2136     'target/ppc',
2137     'target/riscv',
2138     'target/s390x',
2139     'target/s390x/kvm',
2140     'target/sparc',
2141   ]
2142 endif
2143
2144 vhost_user = not_found
2145 if 'CONFIG_VHOST_USER' in config_host
2146   libvhost_user = subproject('libvhost-user')
2147   vhost_user = libvhost_user.get_variable('vhost_user_dep')
2148 endif
2149
2150 subdir('qapi')
2151 subdir('qobject')
2152 subdir('stubs')
2153 subdir('trace')
2154 subdir('util')
2155 subdir('qom')
2156 subdir('authz')
2157 subdir('crypto')
2158 subdir('ui')
2159
2160
2161 if enable_modules
2162   libmodulecommon = static_library('module-common', files('module-common.c') + genh, pic: true, c_args: '-DBUILD_DSO')
2163   modulecommon = declare_dependency(link_whole: libmodulecommon, compile_args: '-DBUILD_DSO')
2164 endif
2165
2166 stub_ss = stub_ss.apply(config_all, strict: false)
2167
2168 util_ss.add_all(trace_ss)
2169 util_ss = util_ss.apply(config_all, strict: false)
2170 libqemuutil = static_library('qemuutil',
2171                              sources: util_ss.sources() + stub_ss.sources() + genh,
2172                              dependencies: [util_ss.dependencies(), libm, threads, glib, socket, malloc, pixman])
2173 qemuutil = declare_dependency(link_with: libqemuutil,
2174                               sources: genh + version_res)
2175
2176 if have_system or have_user
2177   decodetree = generator(find_program('scripts/decodetree.py'),
2178                          output: 'decode-@BASENAME@.c.inc',
2179                          arguments: ['@INPUT@', '@EXTRA_ARGS@', '-o', '@OUTPUT@'])
2180   subdir('libdecnumber')
2181   subdir('target')
2182 endif
2183
2184 subdir('audio')
2185 subdir('io')
2186 subdir('chardev')
2187 subdir('fsdev')
2188 subdir('dump')
2189
2190 if have_block
2191   block_ss.add(files(
2192     'block.c',
2193     'blockjob.c',
2194     'job.c',
2195     'qemu-io-cmds.c',
2196   ))
2197   block_ss.add(when: 'CONFIG_REPLICATION', if_true: files('replication.c'))
2198
2199   subdir('nbd')
2200   subdir('scsi')
2201   subdir('block')
2202
2203   blockdev_ss.add(files(
2204     'blockdev.c',
2205     'blockdev-nbd.c',
2206     'iothread.c',
2207     'job-qmp.c',
2208   ), gnutls)
2209
2210   # os-posix.c contains POSIX-specific functions used by qemu-storage-daemon,
2211   # os-win32.c does not
2212   blockdev_ss.add(when: 'CONFIG_POSIX', if_true: files('os-posix.c'))
2213   softmmu_ss.add(when: 'CONFIG_WIN32', if_true: [files('os-win32.c')])
2214 endif
2215
2216 common_ss.add(files('cpus-common.c'))
2217
2218 subdir('softmmu')
2219
2220 common_ss.add(capstone)
2221 specific_ss.add(files('cpu.c', 'disas.c', 'gdbstub.c'), capstone)
2222
2223 # Work around a gcc bug/misfeature wherein constant propagation looks
2224 # through an alias:
2225 #   https://gcc.gnu.org/bugzilla/show_bug.cgi?id=99696
2226 # to guess that a const variable is always zero.  Without lto, this is
2227 # impossible, as the alias is restricted to page-vary-common.c.  Indeed,
2228 # without lto, not even the alias is required -- we simply use different
2229 # declarations in different compilation units.
2230 pagevary = files('page-vary-common.c')
2231 if get_option('b_lto')
2232   pagevary_flags = ['-fno-lto']
2233   if get_option('cfi')
2234     pagevary_flags += '-fno-sanitize=cfi-icall'
2235   endif
2236   pagevary = static_library('page-vary-common', sources: pagevary,
2237                             c_args: pagevary_flags)
2238   pagevary = declare_dependency(link_with: pagevary)
2239 endif
2240 common_ss.add(pagevary)
2241 specific_ss.add(files('page-vary.c'))
2242
2243 subdir('backends')
2244 subdir('disas')
2245 subdir('migration')
2246 subdir('monitor')
2247 subdir('net')
2248 subdir('replay')
2249 subdir('semihosting')
2250 subdir('hw')
2251 subdir('tcg')
2252 subdir('fpu')
2253 subdir('accel')
2254 subdir('plugins')
2255 subdir('bsd-user')
2256 subdir('linux-user')
2257 subdir('ebpf')
2258
2259 common_ss.add(libbpf)
2260
2261 bsd_user_ss.add(files('gdbstub.c'))
2262 specific_ss.add_all(when: 'CONFIG_BSD_USER', if_true: bsd_user_ss)
2263
2264 linux_user_ss.add(files('gdbstub.c', 'thunk.c'))
2265 specific_ss.add_all(when: 'CONFIG_LINUX_USER', if_true: linux_user_ss)
2266
2267 # needed for fuzzing binaries
2268 subdir('tests/qtest/libqos')
2269 subdir('tests/qtest/fuzz')
2270
2271 # accel modules
2272 tcg_real_module_ss = ss.source_set()
2273 tcg_real_module_ss.add_all(when: 'CONFIG_TCG_MODULAR', if_true: tcg_module_ss)
2274 specific_ss.add_all(when: 'CONFIG_TCG_BUILTIN', if_true: tcg_module_ss)
2275 target_modules += { 'accel' : { 'qtest': qtest_module_ss,
2276                                 'tcg': tcg_real_module_ss }}
2277
2278 ########################
2279 # Library dependencies #
2280 ########################
2281
2282 modinfo_collect = find_program('scripts/modinfo-collect.py')
2283 modinfo_generate = find_program('scripts/modinfo-generate.py')
2284 modinfo_files = []
2285
2286 block_mods = []
2287 softmmu_mods = []
2288 foreach d, list : modules
2289   foreach m, module_ss : list
2290     if enable_modules and targetos != 'windows'
2291       module_ss = module_ss.apply(config_all, strict: false)
2292       sl = static_library(d + '-' + m, [genh, module_ss.sources()],
2293                           dependencies: [modulecommon, module_ss.dependencies()], pic: true)
2294       if d == 'block'
2295         block_mods += sl
2296       else
2297         softmmu_mods += sl
2298       endif
2299       if module_ss.sources() != []
2300         # FIXME: Should use sl.extract_all_objects(recursive: true) as
2301         # input. Sources can be used multiple times but objects are
2302         # unique when it comes to lookup in compile_commands.json.
2303         # Depnds on a mesion version with
2304         # https://github.com/mesonbuild/meson/pull/8900
2305         modinfo_files += custom_target(d + '-' + m + '.modinfo',
2306                                        output: d + '-' + m + '.modinfo',
2307                                        input: module_ss.sources(),
2308                                        capture: true,
2309                                        command: [modinfo_collect, '@INPUT@'])
2310       endif
2311     else
2312       if d == 'block'
2313         block_ss.add_all(module_ss)
2314       else
2315         softmmu_ss.add_all(module_ss)
2316       endif
2317     endif
2318   endforeach
2319 endforeach
2320
2321 foreach d, list : target_modules
2322   foreach m, module_ss : list
2323     if enable_modules and targetos != 'windows'
2324       foreach target : target_dirs
2325         if target.endswith('-softmmu')
2326           config_target = config_target_mak[target]
2327           config_target += config_host
2328           target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
2329           c_args = ['-DNEED_CPU_H',
2330                     '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
2331                     '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
2332           target_module_ss = module_ss.apply(config_target, strict: false)
2333           if target_module_ss.sources() != []
2334             module_name = d + '-' + m + '-' + config_target['TARGET_NAME']
2335             sl = static_library(module_name,
2336                                 [genh, target_module_ss.sources()],
2337                                 dependencies: [modulecommon, target_module_ss.dependencies()],
2338                                 include_directories: target_inc,
2339                                 c_args: c_args,
2340                                 pic: true)
2341             softmmu_mods += sl
2342             # FIXME: Should use sl.extract_all_objects(recursive: true) too.
2343             modinfo_files += custom_target(module_name + '.modinfo',
2344                                            output: module_name + '.modinfo',
2345                                            input: target_module_ss.sources(),
2346                                            capture: true,
2347                                            command: [modinfo_collect, '--target', target, '@INPUT@'])
2348           endif
2349         endif
2350       endforeach
2351     else
2352       specific_ss.add_all(module_ss)
2353     endif
2354   endforeach
2355 endforeach
2356
2357 if enable_modules
2358   modinfo_src = custom_target('modinfo.c',
2359                               output: 'modinfo.c',
2360                               input: modinfo_files,
2361                               command: [modinfo_generate, '@INPUT@'],
2362                               capture: true)
2363   modinfo_lib = static_library('modinfo', modinfo_src)
2364   modinfo_dep = declare_dependency(link_whole: modinfo_lib)
2365   softmmu_ss.add(modinfo_dep)
2366 endif
2367
2368 nm = find_program('nm')
2369 undefsym = find_program('scripts/undefsym.py')
2370 block_syms = custom_target('block.syms', output: 'block.syms',
2371                              input: [libqemuutil, block_mods],
2372                              capture: true,
2373                              command: [undefsym, nm, '@INPUT@'])
2374 qemu_syms = custom_target('qemu.syms', output: 'qemu.syms',
2375                              input: [libqemuutil, softmmu_mods],
2376                              capture: true,
2377                              command: [undefsym, nm, '@INPUT@'])
2378
2379 qom_ss = qom_ss.apply(config_host, strict: false)
2380 libqom = static_library('qom', qom_ss.sources() + genh,
2381                         dependencies: [qom_ss.dependencies()],
2382                         name_suffix: 'fa')
2383
2384 qom = declare_dependency(link_whole: libqom)
2385
2386 authz_ss = authz_ss.apply(config_host, strict: false)
2387 libauthz = static_library('authz', authz_ss.sources() + genh,
2388                           dependencies: [authz_ss.dependencies()],
2389                           name_suffix: 'fa',
2390                           build_by_default: false)
2391
2392 authz = declare_dependency(link_whole: libauthz,
2393                            dependencies: qom)
2394
2395 crypto_ss = crypto_ss.apply(config_host, strict: false)
2396 libcrypto = static_library('crypto', crypto_ss.sources() + genh,
2397                            dependencies: [crypto_ss.dependencies()],
2398                            name_suffix: 'fa',
2399                            build_by_default: false)
2400
2401 crypto = declare_dependency(link_whole: libcrypto,
2402                             dependencies: [authz, qom])
2403
2404 io_ss = io_ss.apply(config_host, strict: false)
2405 libio = static_library('io', io_ss.sources() + genh,
2406                        dependencies: [io_ss.dependencies()],
2407                        link_with: libqemuutil,
2408                        name_suffix: 'fa',
2409                        build_by_default: false)
2410
2411 io = declare_dependency(link_whole: libio, dependencies: [crypto, qom])
2412
2413 libmigration = static_library('migration', sources: migration_files + genh,
2414                               name_suffix: 'fa',
2415                               build_by_default: false)
2416 migration = declare_dependency(link_with: libmigration,
2417                                dependencies: [zlib, qom, io])
2418 softmmu_ss.add(migration)
2419
2420 block_ss = block_ss.apply(config_host, strict: false)
2421 libblock = static_library('block', block_ss.sources() + genh,
2422                           dependencies: block_ss.dependencies(),
2423                           link_depends: block_syms,
2424                           name_suffix: 'fa',
2425                           build_by_default: false)
2426
2427 block = declare_dependency(link_whole: [libblock],
2428                            link_args: '@block.syms',
2429                            dependencies: [crypto, io])
2430
2431 blockdev_ss = blockdev_ss.apply(config_host, strict: false)
2432 libblockdev = static_library('blockdev', blockdev_ss.sources() + genh,
2433                              dependencies: blockdev_ss.dependencies(),
2434                              name_suffix: 'fa',
2435                              build_by_default: false)
2436
2437 blockdev = declare_dependency(link_whole: [libblockdev],
2438                               dependencies: [block])
2439
2440 qmp_ss = qmp_ss.apply(config_host, strict: false)
2441 libqmp = static_library('qmp', qmp_ss.sources() + genh,
2442                         dependencies: qmp_ss.dependencies(),
2443                         name_suffix: 'fa',
2444                         build_by_default: false)
2445
2446 qmp = declare_dependency(link_whole: [libqmp])
2447
2448 libchardev = static_library('chardev', chardev_ss.sources() + genh,
2449                             name_suffix: 'fa',
2450                             dependencies: [gnutls],
2451                             build_by_default: false)
2452
2453 chardev = declare_dependency(link_whole: libchardev)
2454
2455 libhwcore = static_library('hwcore', sources: hwcore_files + genh,
2456                            name_suffix: 'fa',
2457                            build_by_default: false)
2458 hwcore = declare_dependency(link_whole: libhwcore)
2459 common_ss.add(hwcore)
2460
2461 ###########
2462 # Targets #
2463 ###########
2464
2465 foreach m : block_mods + softmmu_mods
2466   shared_module(m.name(),
2467                 name_prefix: '',
2468                 link_whole: m,
2469                 install: true,
2470                 install_dir: qemu_moddir)
2471 endforeach
2472
2473 softmmu_ss.add(authz, blockdev, chardev, crypto, io, qmp)
2474 common_ss.add(qom, qemuutil)
2475
2476 common_ss.add_all(when: 'CONFIG_SOFTMMU', if_true: [softmmu_ss])
2477 common_ss.add_all(when: 'CONFIG_USER_ONLY', if_true: user_ss)
2478
2479 common_all = common_ss.apply(config_all, strict: false)
2480 common_all = static_library('common',
2481                             build_by_default: false,
2482                             sources: common_all.sources() + genh,
2483                             implicit_include_directories: false,
2484                             dependencies: common_all.dependencies(),
2485                             name_suffix: 'fa')
2486
2487 feature_to_c = find_program('scripts/feature_to_c.sh')
2488
2489 emulators = {}
2490 foreach target : target_dirs
2491   config_target = config_target_mak[target]
2492   target_name = config_target['TARGET_NAME']
2493   arch = config_target['TARGET_BASE_ARCH']
2494   arch_srcs = [config_target_h[target]]
2495   arch_deps = []
2496   c_args = ['-DNEED_CPU_H',
2497             '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
2498             '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
2499   link_args = emulator_link_args
2500
2501   config_target += config_host
2502   target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
2503   if targetos == 'linux'
2504     target_inc += include_directories('linux-headers', is_system: true)
2505   endif
2506   if target.endswith('-softmmu')
2507     qemu_target_name = 'qemu-system-' + target_name
2508     target_type='system'
2509     t = target_softmmu_arch[arch].apply(config_target, strict: false)
2510     arch_srcs += t.sources()
2511     arch_deps += t.dependencies()
2512
2513     hw_dir = target_name == 'sparc64' ? 'sparc64' : arch
2514     hw = hw_arch[hw_dir].apply(config_target, strict: false)
2515     arch_srcs += hw.sources()
2516     arch_deps += hw.dependencies()
2517
2518     arch_srcs += config_devices_h[target]
2519     link_args += ['@block.syms', '@qemu.syms']
2520   else
2521     abi = config_target['TARGET_ABI_DIR']
2522     target_type='user'
2523     qemu_target_name = 'qemu-' + target_name
2524     if arch in target_user_arch
2525       t = target_user_arch[arch].apply(config_target, strict: false)
2526       arch_srcs += t.sources()
2527       arch_deps += t.dependencies()
2528     endif
2529     if 'CONFIG_LINUX_USER' in config_target
2530       base_dir = 'linux-user'
2531       target_inc += include_directories('linux-user/host/' / config_host['ARCH'])
2532     else
2533       base_dir = 'bsd-user'
2534       target_inc += include_directories('bsd-user/freebsd')
2535     endif
2536     target_inc += include_directories(
2537       base_dir,
2538       base_dir / abi,
2539     )
2540     if 'CONFIG_LINUX_USER' in config_target
2541       dir = base_dir / abi
2542       arch_srcs += files(dir / 'signal.c', dir / 'cpu_loop.c')
2543       if config_target.has_key('TARGET_SYSTBL_ABI')
2544         arch_srcs += \
2545           syscall_nr_generators[abi].process(base_dir / abi / config_target['TARGET_SYSTBL'],
2546                                              extra_args : config_target['TARGET_SYSTBL_ABI'])
2547       endif
2548     endif
2549   endif
2550
2551   if 'TARGET_XML_FILES' in config_target
2552     gdbstub_xml = custom_target(target + '-gdbstub-xml.c',
2553                                 output: target + '-gdbstub-xml.c',
2554                                 input: files(config_target['TARGET_XML_FILES'].split()),
2555                                 command: [feature_to_c, '@INPUT@'],
2556                                 capture: true)
2557     arch_srcs += gdbstub_xml
2558   endif
2559
2560   t = target_arch[arch].apply(config_target, strict: false)
2561   arch_srcs += t.sources()
2562   arch_deps += t.dependencies()
2563
2564   target_common = common_ss.apply(config_target, strict: false)
2565   objects = common_all.extract_objects(target_common.sources())
2566   deps = target_common.dependencies()
2567
2568   target_specific = specific_ss.apply(config_target, strict: false)
2569   arch_srcs += target_specific.sources()
2570   arch_deps += target_specific.dependencies()
2571
2572   lib = static_library('qemu-' + target,
2573                  sources: arch_srcs + genh,
2574                  dependencies: arch_deps,
2575                  objects: objects,
2576                  include_directories: target_inc,
2577                  c_args: c_args,
2578                  build_by_default: false,
2579                  name_suffix: 'fa')
2580
2581   if target.endswith('-softmmu')
2582     execs = [{
2583       'name': 'qemu-system-' + target_name,
2584       'gui': false,
2585       'sources': files('softmmu/main.c'),
2586       'dependencies': []
2587     }]
2588     if targetos == 'windows' and (sdl.found() or gtk.found())
2589       execs += [{
2590         'name': 'qemu-system-' + target_name + 'w',
2591         'gui': true,
2592         'sources': files('softmmu/main.c'),
2593         'dependencies': []
2594       }]
2595     endif
2596     if config_host.has_key('CONFIG_FUZZ')
2597       specific_fuzz = specific_fuzz_ss.apply(config_target, strict: false)
2598       execs += [{
2599         'name': 'qemu-fuzz-' + target_name,
2600         'gui': false,
2601         'sources': specific_fuzz.sources(),
2602         'dependencies': specific_fuzz.dependencies(),
2603       }]
2604     endif
2605   else
2606     execs = [{
2607       'name': 'qemu-' + target_name,
2608       'gui': false,
2609       'sources': [],
2610       'dependencies': []
2611     }]
2612   endif
2613   foreach exe: execs
2614     exe_name = exe['name']
2615     if targetos == 'darwin'
2616       exe_name += '-unsigned'
2617     endif
2618
2619     emulator = executable(exe_name, exe['sources'],
2620                install: true,
2621                c_args: c_args,
2622                dependencies: arch_deps + deps + exe['dependencies'],
2623                objects: lib.extract_all_objects(recursive: true),
2624                link_language: link_language,
2625                link_depends: [block_syms, qemu_syms] + exe.get('link_depends', []),
2626                link_args: link_args,
2627                gui_app: exe['gui'])
2628
2629     if targetos == 'darwin'
2630       icon = 'pc-bios/qemu.rsrc'
2631       build_input = [emulator, files(icon)]
2632       install_input = [
2633         get_option('bindir') / exe_name,
2634         meson.current_source_dir() / icon
2635       ]
2636       if 'CONFIG_HVF' in config_target
2637         entitlements = 'accel/hvf/entitlements.plist'
2638         build_input += files(entitlements)
2639         install_input += meson.current_source_dir() / entitlements
2640       endif
2641
2642       emulators += {exe['name'] : custom_target(exe['name'],
2643                    input: build_input,
2644                    output: exe['name'],
2645                    command: [
2646                      files('scripts/entitlement.sh'),
2647                      '@OUTPUT@',
2648                      '@INPUT@'
2649                    ])
2650       }
2651
2652       meson.add_install_script('scripts/entitlement.sh', '--install',
2653                                get_option('bindir') / exe['name'],
2654                                install_input)
2655     else
2656       emulators += {exe['name']: emulator}
2657     endif
2658
2659     if 'CONFIG_TRACE_SYSTEMTAP' in config_host
2660       foreach stp: [
2661         {'ext': '.stp-build', 'fmt': 'stap', 'bin': meson.current_build_dir() / exe['name'], 'install': false},
2662         {'ext': '.stp', 'fmt': 'stap', 'bin': get_option('prefix') / get_option('bindir') / exe['name'], 'install': true},
2663         {'ext': '-simpletrace.stp', 'fmt': 'simpletrace-stap', 'bin': '', 'install': true},
2664         {'ext': '-log.stp', 'fmt': 'log-stap', 'bin': '', 'install': true},
2665       ]
2666         custom_target(exe['name'] + stp['ext'],
2667                       input: trace_events_all,
2668                       output: exe['name'] + stp['ext'],
2669                       install: stp['install'],
2670                       install_dir: get_option('datadir') / 'systemtap/tapset',
2671                       command: [
2672                         tracetool, '--group=all', '--format=' + stp['fmt'],
2673                         '--binary=' + stp['bin'],
2674                         '--target-name=' + target_name,
2675                         '--target-type=' + target_type,
2676                         '--probe-prefix=qemu.' + target_type + '.' + target_name,
2677                         '@INPUT@', '@OUTPUT@'
2678                       ],
2679                       depend_files: tracetool_depends)
2680       endforeach
2681     endif
2682   endforeach
2683 endforeach
2684
2685 # Other build targets
2686
2687 if 'CONFIG_PLUGIN' in config_host
2688   install_headers('include/qemu/qemu-plugin.h')
2689 endif
2690
2691 if 'CONFIG_GUEST_AGENT' in config_host
2692   subdir('qga')
2693 elif get_option('guest_agent_msi').enabled()
2694   error('Guest agent MSI requested, but the guest agent is not being built')
2695 endif
2696
2697 # Don't build qemu-keymap if xkbcommon is not explicitly enabled
2698 # when we don't build tools or system
2699 if xkbcommon.found()
2700   # used for the update-keymaps target, so include rules even if !have_tools
2701   qemu_keymap = executable('qemu-keymap', files('qemu-keymap.c', 'ui/input-keymap.c') + genh,
2702                            dependencies: [qemuutil, xkbcommon], install: have_tools)
2703 endif
2704
2705 if have_tools
2706   qemu_img = executable('qemu-img', [files('qemu-img.c'), hxdep],
2707              dependencies: [authz, block, crypto, io, qom, qemuutil], install: true)
2708   qemu_io = executable('qemu-io', files('qemu-io.c'),
2709              dependencies: [block, qemuutil], install: true)
2710   qemu_nbd = executable('qemu-nbd', files('qemu-nbd.c'),
2711                dependencies: [blockdev, qemuutil, gnutls], install: true)
2712
2713   subdir('storage-daemon')
2714   subdir('contrib/rdmacm-mux')
2715   subdir('contrib/elf2dmp')
2716
2717   executable('qemu-edid', files('qemu-edid.c', 'hw/display/edid-generate.c'),
2718              dependencies: qemuutil,
2719              install: true)
2720
2721   if 'CONFIG_VHOST_USER' in config_host
2722     subdir('contrib/vhost-user-blk')
2723     subdir('contrib/vhost-user-gpu')
2724     subdir('contrib/vhost-user-input')
2725     subdir('contrib/vhost-user-scsi')
2726   endif
2727
2728   if targetos == 'linux'
2729     executable('qemu-bridge-helper', files('qemu-bridge-helper.c'),
2730                dependencies: [qemuutil, libcap_ng],
2731                install: true,
2732                install_dir: get_option('libexecdir'))
2733
2734     executable('qemu-pr-helper', files('scsi/qemu-pr-helper.c', 'scsi/utils.c'),
2735                dependencies: [authz, crypto, io, qom, qemuutil,
2736                               libcap_ng, mpathpersist],
2737                install: true)
2738   endif
2739
2740   if have_ivshmem
2741     subdir('contrib/ivshmem-client')
2742     subdir('contrib/ivshmem-server')
2743   endif
2744 endif
2745
2746 subdir('scripts')
2747 subdir('tools')
2748 subdir('pc-bios')
2749 subdir('docs')
2750 subdir('tests')
2751 if gtk.found()
2752   subdir('po')
2753 endif
2754
2755 if host_machine.system() == 'windows'
2756   nsis_cmd = [
2757     find_program('scripts/nsis.py'),
2758     '@OUTPUT@',
2759     get_option('prefix'),
2760     meson.current_source_dir(),
2761     host_machine.cpu(),
2762     '--',
2763     '-DDISPLAYVERSION=' + meson.project_version(),
2764   ]
2765   if build_docs
2766     nsis_cmd += '-DCONFIG_DOCUMENTATION=y'
2767   endif
2768   if gtk.found()
2769     nsis_cmd += '-DCONFIG_GTK=y'
2770   endif
2771
2772   nsis = custom_target('nsis',
2773                        output: 'qemu-setup-' + meson.project_version() + '.exe',
2774                        input: files('qemu.nsi'),
2775                        build_always_stale: true,
2776                        command: nsis_cmd + ['@INPUT@'])
2777   alias_target('installer', nsis)
2778 endif
2779
2780 #########################
2781 # Configuration summary #
2782 #########################
2783
2784 # Directories
2785 summary_info = {}
2786 summary_info += {'Install prefix':    get_option('prefix')}
2787 summary_info += {'BIOS directory':    qemu_datadir}
2788 summary_info += {'firmware path':     get_option('qemu_firmwarepath')}
2789 summary_info += {'binary directory':  get_option('bindir')}
2790 summary_info += {'library directory': get_option('libdir')}
2791 summary_info += {'module directory':  qemu_moddir}
2792 summary_info += {'libexec directory': get_option('libexecdir')}
2793 summary_info += {'include directory': get_option('includedir')}
2794 summary_info += {'config directory':  get_option('sysconfdir')}
2795 if targetos != 'windows'
2796   summary_info += {'local state directory': get_option('localstatedir')}
2797   summary_info += {'Manual directory':      get_option('mandir')}
2798 else
2799   summary_info += {'local state directory': 'queried at runtime'}
2800 endif
2801 summary_info += {'Doc directory':     get_option('docdir')}
2802 summary_info += {'Build directory':   meson.current_build_dir()}
2803 summary_info += {'Source path':       meson.current_source_dir()}
2804 summary_info += {'GIT submodules':    config_host['GIT_SUBMODULES']}
2805 summary(summary_info, bool_yn: true, section: 'Directories')
2806
2807 # Host binaries
2808 summary_info = {}
2809 summary_info += {'git':               config_host['GIT']}
2810 summary_info += {'make':              config_host['MAKE']}
2811 summary_info += {'python':            '@0@ (version: @1@)'.format(python.full_path(), python.language_version())}
2812 summary_info += {'sphinx-build':      sphinx_build.found()}
2813 if config_host.has_key('HAVE_GDB_BIN')
2814   summary_info += {'gdb':             config_host['HAVE_GDB_BIN']}
2815 endif
2816 summary_info += {'genisoimage':       config_host['GENISOIMAGE']}
2817 if targetos == 'windows' and config_host.has_key('CONFIG_GUEST_AGENT')
2818   summary_info += {'wixl':            wixl.found() ? wixl.full_path() : false}
2819 endif
2820 if slirp_opt != 'disabled' and 'CONFIG_SLIRP_SMBD' in config_host
2821   summary_info += {'smbd':            config_host['CONFIG_SMBD_COMMAND']}
2822 endif
2823 summary(summary_info, bool_yn: true, section: 'Host binaries')
2824
2825 # Configurable features
2826 summary_info = {}
2827 summary_info += {'Documentation':     build_docs}
2828 summary_info += {'system-mode emulation': have_system}
2829 summary_info += {'user-mode emulation': have_user}
2830 summary_info += {'block layer':       have_block}
2831 summary_info += {'Install blobs':     get_option('install_blobs')}
2832 summary_info += {'module support':    config_host.has_key('CONFIG_MODULES')}
2833 if config_host.has_key('CONFIG_MODULES')
2834   summary_info += {'alternative module path': config_host.has_key('CONFIG_MODULE_UPGRADES')}
2835 endif
2836 summary_info += {'plugin support':    config_host.has_key('CONFIG_PLUGIN')}
2837 summary_info += {'fuzzing support':   config_host.has_key('CONFIG_FUZZ')}
2838 if have_system
2839   summary_info += {'Audio drivers':     config_host['CONFIG_AUDIO_DRIVERS']}
2840 endif
2841 summary_info += {'Trace backends':    config_host['TRACE_BACKENDS']}
2842 if config_host['TRACE_BACKENDS'].split().contains('simple')
2843   summary_info += {'Trace output file': config_host['CONFIG_TRACE_FILE'] + '-<pid>'}
2844 endif
2845 summary_info += {'QOM debugging':     config_host.has_key('CONFIG_QOM_CAST_DEBUG')}
2846 summary_info += {'vhost-kernel support': config_host.has_key('CONFIG_VHOST_KERNEL')}
2847 summary_info += {'vhost-net support': config_host.has_key('CONFIG_VHOST_NET')}
2848 summary_info += {'vhost-crypto support': config_host.has_key('CONFIG_VHOST_CRYPTO')}
2849 summary_info += {'vhost-scsi support': config_host.has_key('CONFIG_VHOST_SCSI')}
2850 summary_info += {'vhost-vsock support': config_host.has_key('CONFIG_VHOST_VSOCK')}
2851 summary_info += {'vhost-user support': config_host.has_key('CONFIG_VHOST_USER')}
2852 summary_info += {'vhost-user-blk server support': have_vhost_user_blk_server}
2853 summary_info += {'vhost-user-fs support': config_host.has_key('CONFIG_VHOST_USER_FS')}
2854 summary_info += {'vhost-vdpa support': config_host.has_key('CONFIG_VHOST_VDPA')}
2855 summary_info += {'build guest agent': config_host.has_key('CONFIG_GUEST_AGENT')}
2856 summary(summary_info, bool_yn: true, section: 'Configurable features')
2857
2858 # Compilation information
2859 summary_info = {}
2860 summary_info += {'host CPU':          cpu}
2861 summary_info += {'host endianness':   build_machine.endian()}
2862 summary_info += {'C compiler':        ' '.join(meson.get_compiler('c').cmd_array())}
2863 summary_info += {'Host C compiler':   ' '.join(meson.get_compiler('c', native: true).cmd_array())}
2864 if link_language == 'cpp'
2865   summary_info += {'C++ compiler':    ' '.join(meson.get_compiler('cpp').cmd_array())}
2866 else
2867   summary_info += {'C++ compiler':      false}
2868 endif
2869 if targetos == 'darwin'
2870   summary_info += {'Objective-C compiler': ' '.join(meson.get_compiler('objc').cmd_array())}
2871 endif
2872 if targetos == 'windows'
2873   if 'WIN_SDK' in config_host
2874     summary_info += {'Windows SDK':   config_host['WIN_SDK']}
2875   endif
2876 endif
2877 summary_info += {'CFLAGS':            ' '.join(get_option('c_args')
2878                                                + ['-O' + get_option('optimization')]
2879                                                + (get_option('debug') ? ['-g'] : []))}
2880 if link_language == 'cpp'
2881   summary_info += {'CXXFLAGS':        ' '.join(get_option('cpp_args')
2882                                                + ['-O' + get_option('optimization')]
2883                                                + (get_option('debug') ? ['-g'] : []))}
2884 endif
2885 link_args = get_option(link_language + '_link_args')
2886 if link_args.length() > 0
2887   summary_info += {'LDFLAGS':         ' '.join(link_args)}
2888 endif
2889 summary_info += {'QEMU_CFLAGS':       config_host['QEMU_CFLAGS']}
2890 summary_info += {'QEMU_LDFLAGS':      config_host['QEMU_LDFLAGS']}
2891 summary_info += {'profiler':          config_host.has_key('CONFIG_PROFILER')}
2892 summary_info += {'link-time optimization (LTO)': get_option('b_lto')}
2893 summary_info += {'PIE':               get_option('b_pie')}
2894 summary_info += {'static build':      config_host.has_key('CONFIG_STATIC')}
2895 summary_info += {'malloc trim support': has_malloc_trim}
2896 summary_info += {'membarrier':        config_host.has_key('CONFIG_MEMBARRIER')}
2897 summary_info += {'debug stack usage': config_host.has_key('CONFIG_DEBUG_STACK_USAGE')}
2898 summary_info += {'mutex debugging':   config_host.has_key('CONFIG_DEBUG_MUTEX')}
2899 summary_info += {'memory allocator':  get_option('malloc')}
2900 summary_info += {'avx2 optimization': config_host.has_key('CONFIG_AVX2_OPT')}
2901 summary_info += {'avx512f optimization': config_host.has_key('CONFIG_AVX512F_OPT')}
2902 summary_info += {'gprof enabled':     config_host.has_key('CONFIG_GPROF')}
2903 summary_info += {'gcov':              get_option('b_coverage')}
2904 summary_info += {'thread sanitizer':  config_host.has_key('CONFIG_TSAN')}
2905 summary_info += {'CFI support':       get_option('cfi')}
2906 if get_option('cfi')
2907   summary_info += {'CFI debug support': get_option('cfi_debug')}
2908 endif
2909 summary_info += {'strip binaries':    get_option('strip')}
2910 summary_info += {'sparse':            sparse.found() ? sparse.full_path() : false}
2911 summary_info += {'mingw32 support':   targetos == 'windows'}
2912
2913 # snarf the cross-compilation information for tests
2914 foreach target: target_dirs
2915   tcg_mak = meson.current_build_dir() / 'tests/tcg' / 'config-' + target + '.mak'
2916   if fs.exists(tcg_mak)
2917     config_cross_tcg = keyval.load(tcg_mak)
2918     target = config_cross_tcg['TARGET_NAME']
2919     compiler = ''
2920     if 'DOCKER_CROSS_CC_GUEST' in config_cross_tcg
2921       summary_info += {target + ' tests': config_cross_tcg['DOCKER_CROSS_CC_GUEST'] +
2922                                           ' via ' + config_cross_tcg['DOCKER_IMAGE']}
2923     elif 'CROSS_CC_GUEST' in config_cross_tcg
2924       summary_info += {target + ' tests'
2925                                 : config_cross_tcg['CROSS_CC_GUEST'] }
2926     endif
2927    endif
2928 endforeach
2929
2930 summary(summary_info, bool_yn: true, section: 'Compilation')
2931
2932 # Targets and accelerators
2933 summary_info = {}
2934 if have_system
2935   summary_info += {'KVM support':       config_all.has_key('CONFIG_KVM')}
2936   summary_info += {'HAX support':       config_all.has_key('CONFIG_HAX')}
2937   summary_info += {'HVF support':       config_all.has_key('CONFIG_HVF')}
2938   summary_info += {'WHPX support':      config_all.has_key('CONFIG_WHPX')}
2939   summary_info += {'NVMM support':      config_all.has_key('CONFIG_NVMM')}
2940   summary_info += {'Xen support':       config_host.has_key('CONFIG_XEN_BACKEND')}
2941   if config_host.has_key('CONFIG_XEN_BACKEND')
2942     summary_info += {'xen ctrl version':  config_host['CONFIG_XEN_CTRL_INTERFACE_VERSION']}
2943   endif
2944 endif
2945 summary_info += {'TCG support':       config_all.has_key('CONFIG_TCG')}
2946 if config_all.has_key('CONFIG_TCG')
2947   if get_option('tcg_interpreter')
2948     summary_info += {'TCG backend':   'TCI (TCG with bytecode interpreter, experimental and slow)'}
2949   else
2950     summary_info += {'TCG backend':   'native (@0@)'.format(cpu)}
2951   endif
2952   summary_info += {'TCG debug enabled': config_host.has_key('CONFIG_DEBUG_TCG')}
2953 endif
2954 summary_info += {'target list':       ' '.join(target_dirs)}
2955 if have_system
2956   summary_info += {'default devices':   get_option('default_devices')}
2957   summary_info += {'out of process emulation': multiprocess_allowed}
2958 endif
2959 summary(summary_info, bool_yn: true, section: 'Targets and accelerators')
2960
2961 # Block layer
2962 summary_info = {}
2963 summary_info += {'coroutine backend': config_host['CONFIG_COROUTINE_BACKEND']}
2964 summary_info += {'coroutine pool':    config_host['CONFIG_COROUTINE_POOL'] == '1'}
2965 if have_block
2966   summary_info += {'Block whitelist (rw)': config_host['CONFIG_BDRV_RW_WHITELIST']}
2967   summary_info += {'Block whitelist (ro)': config_host['CONFIG_BDRV_RO_WHITELIST']}
2968   summary_info += {'VirtFS support':    have_virtfs}
2969   summary_info += {'build virtiofs daemon': have_virtiofsd}
2970   summary_info += {'Live block migration': config_host.has_key('CONFIG_LIVE_BLOCK_MIGRATION')}
2971   summary_info += {'replication support': config_host.has_key('CONFIG_REPLICATION')}
2972   summary_info += {'bochs support':     config_host.has_key('CONFIG_BOCHS')}
2973   summary_info += {'cloop support':     config_host.has_key('CONFIG_CLOOP')}
2974   summary_info += {'dmg support':       config_host.has_key('CONFIG_DMG')}
2975   summary_info += {'qcow v1 support':   config_host.has_key('CONFIG_QCOW1')}
2976   summary_info += {'vdi support':       config_host.has_key('CONFIG_VDI')}
2977   summary_info += {'vvfat support':     config_host.has_key('CONFIG_VVFAT')}
2978   summary_info += {'qed support':       config_host.has_key('CONFIG_QED')}
2979   summary_info += {'parallels support': config_host.has_key('CONFIG_PARALLELS')}
2980   summary_info += {'FUSE exports':      fuse.found()}
2981 endif
2982 summary(summary_info, bool_yn: true, section: 'Block layer support')
2983
2984 # Crypto
2985 summary_info = {}
2986 summary_info += {'TLS priority':      config_host['CONFIG_TLS_PRIORITY']}
2987 summary_info += {'GNUTLS support':    gnutls.found()}
2988 # TODO: add back version
2989 summary_info += {'libgcrypt':         gcrypt.found()}
2990 if gcrypt.found()
2991    summary_info += {'  XTS':             xts != 'private'}
2992 endif
2993 # TODO: add back version
2994 summary_info += {'nettle':            nettle.found()}
2995 if nettle.found()
2996    summary_info += {'  XTS':             xts != 'private'}
2997 endif
2998 summary_info += {'crypto afalg':      config_host.has_key('CONFIG_AF_ALG')}
2999 summary_info += {'rng-none':          config_host.has_key('CONFIG_RNG_NONE')}
3000 summary_info += {'Linux keyring':     config_host.has_key('CONFIG_SECRET_KEYRING')}
3001 summary(summary_info, bool_yn: true, section: 'Crypto')
3002
3003 # Libraries
3004 summary_info = {}
3005 if targetos == 'darwin'
3006   summary_info += {'Cocoa support':   cocoa.found()}
3007 endif
3008 # TODO: add back version
3009 summary_info += {'SDL support':       sdl.found()}
3010 summary_info += {'SDL image support': sdl_image.found()}
3011 # TODO: add back version
3012 summary_info += {'GTK support':       gtk.found()}
3013 summary_info += {'pixman':            pixman.found()}
3014 # TODO: add back version
3015 summary_info += {'VTE support':       vte.found()}
3016 # TODO: add back version
3017 summary_info += {'slirp support':     slirp_opt == 'disabled' ? false : slirp_opt}
3018 summary_info += {'libtasn1':          tasn1.found()}
3019 summary_info += {'PAM':               pam.found()}
3020 summary_info += {'iconv support':     iconv.found()}
3021 summary_info += {'curses support':    curses.found()}
3022 # TODO: add back version
3023 summary_info += {'virgl support':     virgl.found()}
3024 summary_info += {'curl support':      curl.found()}
3025 summary_info += {'Multipath support': mpathpersist.found()}
3026 summary_info += {'VNC support':       vnc.found()}
3027 if vnc.found()
3028   summary_info += {'VNC SASL support':  sasl.found()}
3029   summary_info += {'VNC JPEG support':  jpeg.found()}
3030   summary_info += {'VNC PNG support':   png.found()}
3031 endif
3032 summary_info += {'brlapi support':    brlapi.found()}
3033 summary_info += {'vde support':       config_host.has_key('CONFIG_VDE')}
3034 summary_info += {'netmap support':    config_host.has_key('CONFIG_NETMAP')}
3035 summary_info += {'Linux AIO support': config_host.has_key('CONFIG_LINUX_AIO')}
3036 summary_info += {'Linux io_uring support': linux_io_uring.found()}
3037 summary_info += {'ATTR/XATTR support': libattr.found()}
3038 summary_info += {'RDMA support':      config_host.has_key('CONFIG_RDMA')}
3039 summary_info += {'PVRDMA support':    config_host.has_key('CONFIG_PVRDMA')}
3040 summary_info += {'fdt support':       fdt_opt == 'disabled' ? false : fdt_opt}
3041 summary_info += {'libcap-ng support': libcap_ng.found()}
3042 summary_info += {'bpf support': libbpf.found()}
3043 # TODO: add back protocol and server version
3044 summary_info += {'spice support':     config_host.has_key('CONFIG_SPICE')}
3045 summary_info += {'rbd support':       rbd.found()}
3046 summary_info += {'xfsctl support':    config_host.has_key('CONFIG_XFS')}
3047 summary_info += {'smartcard support': cacard.found()}
3048 summary_info += {'U2F support':       u2f.found()}
3049 summary_info += {'libusb':            libusb.found()}
3050 summary_info += {'usb net redir':     usbredir.found()}
3051 summary_info += {'OpenGL support':    config_host.has_key('CONFIG_OPENGL')}
3052 summary_info += {'GBM':               config_host.has_key('CONFIG_GBM')}
3053 summary_info += {'libiscsi support':  libiscsi.found()}
3054 summary_info += {'libnfs support':    libnfs.found()}
3055 if targetos == 'windows'
3056   if config_host.has_key('CONFIG_GUEST_AGENT')
3057     summary_info += {'QGA VSS support':   config_host.has_key('CONFIG_QGA_VSS')}
3058     summary_info += {'QGA w32 disk info': config_host.has_key('CONFIG_QGA_NTDDSCSI')}
3059   endif
3060 endif
3061 summary_info += {'seccomp support':   seccomp.found()}
3062 summary_info += {'GlusterFS support': glusterfs.found()}
3063 summary_info += {'TPM support':       config_host.has_key('CONFIG_TPM')}
3064 summary_info += {'libssh support':    config_host.has_key('CONFIG_LIBSSH')}
3065 summary_info += {'lzo support':       lzo.found()}
3066 summary_info += {'snappy support':    snappy.found()}
3067 summary_info += {'bzip2 support':     libbzip2.found()}
3068 summary_info += {'lzfse support':     liblzfse.found()}
3069 summary_info += {'zstd support':      zstd.found()}
3070 summary_info += {'NUMA host support': config_host.has_key('CONFIG_NUMA')}
3071 summary_info += {'libxml2':           libxml2.found()}
3072 summary_info += {'capstone':          capstone_opt == 'disabled' ? false : capstone_opt}
3073 summary_info += {'libpmem support':   libpmem.found()}
3074 summary_info += {'libdaxctl support': libdaxctl.found()}
3075 summary_info += {'libudev':           libudev.found()}
3076 summary_info += {'FUSE lseek':        fuse_lseek.found()}
3077 summary(summary_info, bool_yn: true, section: 'Dependencies')
3078
3079 if not supported_cpus.contains(cpu)
3080   message()
3081   warning('SUPPORT FOR THIS HOST CPU WILL GO AWAY IN FUTURE RELEASES!')
3082   message()
3083   message('CPU host architecture ' + cpu + ' support is not currently maintained.')
3084   message('The QEMU project intends to remove support for this host CPU in')
3085   message('a future release if nobody volunteers to maintain it and to')
3086   message('provide a build host for our continuous integration setup.')
3087   message('configure has succeeded and you can continue to build, but')
3088   message('if you care about QEMU on this platform you should contact')
3089   message('us upstream at qemu-devel@nongnu.org.')
3090 endif
3091
3092 if not supported_oses.contains(targetos)
3093   message()
3094   warning('WARNING: SUPPORT FOR THIS HOST OS WILL GO AWAY IN FUTURE RELEASES!')
3095   message()
3096   message('Host OS ' + targetos + 'support is not currently maintained.')
3097   message('The QEMU project intends to remove support for this host OS in')
3098   message('a future release if nobody volunteers to maintain it and to')
3099   message('provide a build host for our continuous integration setup.')
3100   message('configure has succeeded and you can continue to build, but')
3101   message('if you care about QEMU on this platform you should contact')
3102   message('us upstream at qemu-devel@nongnu.org.')
3103 endif